t/op/lfs.t

   1 # NOTE: this file tests how large files (>2GB) work with perlio (stdio/sfio).
   2 # sysopen(), sysseek(), syswrite(), sysread() are tested in t/lib/syslfs.t.
   3 # If you modify/add tests here, remember to update also ext/Fcntl/t/syslfs.t.
   4
   5 BEGIN {
   6         chdir 't' if -d 't';
   7         @INC = '../lib';
   8         # Don't bother if there are no quad offsets.
   9         require Config; import Config;
  10         if ($Config{lseeksize} < 8) {
  11                 print "1..0 # Skip: no 64-bit file offsets\n";
  12                 exit(0);
  13         }
  14         require './test.pl';
  15 }
  16
  17 use strict;
  18
  19 our @s;
  20
  21 my $big0 = tempfile();
  22 my $big1 = tempfile();
  23 my $big2 = tempfile();
  24
  25 my $explained;
  26
  27 sub explain {
  28     unless ($explained++) {
  29         print <<EOM;
  30 #
  31 # If the lfs (large file support: large meaning larger than two
  32 # gigabytes) tests are skipped or fail, it may mean either that your
  33 # process (or process group) is not allowed to write large files
  34 # (resource limits) or that the file system (the network filesystem?)
  35 # you are running the tests on doesn't let your user/group have large
  36 # files (quota) or the filesystem simply doesn't support large files.
  37 # You may even need to reconfigure your kernel.  (This is all very
  38 # operating system and site-dependent.)
  39 #
  40 # Perl may still be able to support large files, once you have
  41 # such a process, enough quota, and such a (file) system.
  42 # It is just that the test failed now.
  43 #
  44 EOM
  45     }
  46     if (@_) {
  47         skip_all(@_);
  48     }
  49 }
  50
  51 $| = 1;
  52
  53 print "# checking whether we have sparse files...\n";
  54
  55 # Known have-nots.
  56 if ($^O eq 'MSWin32' || $^O eq 'NetWare' || $^O eq 'VMS') {
  57     skip_all("no sparse files in $^O");
  58 }
  59
  60 # Known haves that have problems running this test
  61 # (for example because they do not support sparse files, like UNICOS)
  62 if ($^O eq 'unicos') {
  63     skip_all("no sparse files in $^O, unable to test large files");
  64 }
  65
  66 # Then try heuristically to deduce whether we have sparse files.
  67
  68 # Let's not depend on Fcntl or any other extension.
  69
  70 sub SEEK_SET () {0}
  71 sub SEEK_CUR () {1}
  72 sub SEEK_END () {2}
  73
  74 # We'll start off by creating a one megabyte file which has
  75 # only three "true" bytes.  If we have sparseness, we should
  76 # consume less blocks than one megabyte (assuming nobody has
  77 # one megabyte blocks...)
  78
  79 open(BIG, ">$big1") or
  80     die "open $big1 failed: $!";
  81 binmode(BIG) or
  82     die "binmode $big1 failed: $!";
  83 seek(BIG, 1_000_000, SEEK_SET) or
  84     die "seek $big1 failed: $!";
  85 print BIG "big" or
  86     die "print $big1 failed: $!";
  87 close(BIG) or
  88     die "close $big1 failed: $!";
  89
  90 my @s1 = stat($big1);
  91
  92 print "# s1 = @s1\n";
  93
  94 open(BIG, ">$big2") or
  95     die "open $big2 failed: $!";
  96 binmode(BIG) or
  97     die "binmode $big2 failed: $!";
  98 seek(BIG, 2_000_000, SEEK_SET) or
  99     die "seek $big2 failed: $!";
 100 print BIG "big" or
 101     die "print $big2 failed: $!";
 102 close(BIG) or
 103     die "close $big2 failed: $!";
 104
 105 my @s2 = stat($big2);
 106
 107 print "# s2 = @s2\n";
 108
 109 unless ($s1[7] == 1_000_003 && $s2[7] == 2_000_003 &&
 110         $s1[11] == $s2[11] && $s1[12] == $s2[12] &&
 111         $s1[12] > 0) {
 112     skip_all("no sparse files?");
 113 }
 114
 115 print "# we seem to have sparse files...\n";
 116
 117 # By now we better be sure that we do have sparse files:
 118 # if we are not, the following will hog 5 gigabytes of disk.  Ooops.
 119 # This may fail by producing some signal; run in a subprocess first for safety
 120
 121 $ENV{LC_ALL} = "C";
 122
 123 my $r = system '../perl', '-e', <<"EOF";
 124 open my \$big, '>', q{$big0} or die qq{open $big0: $!};
 125 seek \$big, 5_000_000_000, 0 or die qq{seek $big0: $!};
 126 print \$big "big" or die qq{print $big0: $!};
 127 close \$big or die qq{close $big0: $!};
 128 exit 0;
 129 EOF
 130
 131 open(BIG, ">$big0") or die "open failed: $!";
 132 binmode BIG;
 133 if ($r or not seek(BIG, 5_000_000_000, SEEK_SET)) {
 134     my $err = $r ? 'signal '.($r & 0x7f) : $!;
 135     explain("seeking past 2GB failed: $err");
 136 }
 137
 138 # Either the print or (more likely, thanks to buffering) the close will
 139 # fail if there are are filesize limitations (process or fs).
 140 my $print = print BIG "big";
 141 print "# print failed: $!\n" unless $print;
 142 my $close = close BIG;
 143 print "# close failed: $!\n" unless $close;
 144 unless ($print && $close) {
 145     if ($! =~/too large/i) {
 146         explain("writing past 2GB failed: process limits?");
 147     } elsif ($! =~ /quota/i) {
 148         explain("filesystem quota limits?");
 149     } else {
 150         explain("error: $!");
 151     }
 152 }
 153
 154 @s = stat($big0);
 155
 156 print "# @s\n";
 157
 158 unless ($s[7] == 5_000_000_003) {
 159     explain("kernel/fs not configured to use large files?");
 160 }
 161
 162 sub offset ($$) {
 163     local $::Level = $::Level + 1;
 164     my ($offset_will_be, $offset_want) = @_;
 165     my $offset_is = eval $offset_will_be;
 166     unless ($offset_is == $offset_want) {
 167         print "# bad offset $offset_is, want $offset_want\n";
 168         my ($offset_func) = ($offset_will_be =~ /^(\w+)/);
 169         if (unpack("L", pack("L", $offset_want)) == $offset_is) {
 170             print "# 32-bit wraparound suspected in $offset_func() since\n";
 171             print "# $offset_want cast into 32 bits equals $offset_is.\n";
 172         } elsif ($offset_want - unpack("L", pack("L", $offset_want)) - 1
 173                  == $offset_is) {
 174             print "# 32-bit wraparound suspected in $offset_func() since\n";
 175             printf "# %s - unpack('L', pack('L', %s)) - 1 equals %s.\n",
 176                 $offset_want,
 177                 $offset_want,
 178                 $offset_is;
 179         }
 180         fail($offset_will_be);
 181     } else {
 182         pass($offset_will_be);
 183     }
 184 }
 185
 186 plan(tests => 17);
 187
 188 is($s[7], 5_000_000_003, 'exercises pp_stat');
 189 is(-s $big0, 5_000_000_003, 'exercises pp_ftsize');
 190
 191 is(-e $big0, 1);
 192 is(-f $big0, 1);
 193
 194 open(BIG, $big0) or die "open failed: $!";
 195 binmode BIG;
 196
 197 isnt(seek(BIG, 4_500_000_000, SEEK_SET), undef);
 198
 199 offset('tell(BIG)', 4_500_000_000);
 200
 201 isnt(seek(BIG, 1, SEEK_CUR), undef);
 202
 203 # If you get 205_032_705 from here it means that
 204 # your tell() is returning 32-bit values since (I32)4_500_000_001
 205 # is exactly 205_032_705.
 206 offset('tell(BIG)', 4_500_000_001);
 207
 208 isnt(seek(BIG, -1, SEEK_CUR), undef);
 209
 210 offset('tell(BIG)', 4_500_000_000);
 211
 212 isnt(seek(BIG, -3, SEEK_END), undef);
 213
 214 offset('tell(BIG)', 5_000_000_000);
 215
 216 my $big;
 217
 218 is(read(BIG, $big, 3), 3);
 219
 220 is($big, "big");
 221
 222 # 705_032_704 = (I32)5_000_000_000
 223 # See that we don't have "big" in the 705_... spot:
 224 # that would mean that we have a wraparound.
 225 isnt(seek(BIG, 705_032_704, SEEK_SET), undef);
 226
 227 my $zero;
 228
 229 is(read(BIG, $zero, 3), 3);
 230
 231 is($zero, "\0\0\0");
 232
 233 explain() unless $::Tests_Are_Passing;
 234
 235 END {
 236     # unlink may fail if applied directly to a large file
 237     # be paranoid about leaving 5 gig files lying around
 238     open(BIG, ">$big0"); # truncate
 239     close(BIG);
 240 }
 241
 242 # eof