lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<$filename>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34)>.
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 use strict;
 514
 515 use Cwd ();
 516
 517 my $_initial_cwd;
 518
 519 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
 520
 521 BEGIN {
 522     require feature;
 523     $^V =~ /^v(\d+\.\d+)/;
 524     feature->import(":$1");
 525     $_initial_cwd = Cwd::getcwd();
 526 }
 527
 528 # Debugger for Perl 5.00x; perl5db.pl patch level:
 529 use vars qw($VERSION $header);
 530
 531 # bump to X.XX in blead, only use X.XX_XX in maint
 532 $VERSION = '1.54';
 533
 534 $header = "perl5db.pl version $VERSION";
 535
 536 =head1 DEBUGGER ROUTINES
 537
 538 =head2 C<DB::eval()>
 539
 540 This function replaces straight C<eval()> inside the debugger; it simplifies
 541 the process of evaluating code in the user's context.
 542
 543 The code to be evaluated is passed via the package global variable
 544 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 545
 546 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 547 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 548 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 549 user's current package, grabbed when C<DB::DB> got control.  This causes the
 550 proper context to be used when the eval is actually done.  Afterward, we
 551 restore C<$trace>, C<$single>, and C<$^D>.
 552
 553 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 554 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 555 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 556 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 557 considered sane by the debugger. If there was an C<eval()> error, we print
 558 it on the debugger's output. If C<$onetimedump> is defined, we call
 559 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 560 'methods'. Setting it to something else causes the debugger to do the eval
 561 but not print the result - handy if you want to do something else with it
 562 (the "watch expressions" code does this to get the value of the watch
 563 expression but not show it unless it matters).
 564
 565 In any case, we then return the list of output from C<eval> to the caller,
 566 and unwinding restores the former version of C<$@> in C<@saved> as well
 567 (the localization of C<$saved[0]> goes away at the end of this scope).
 568
 569 =head3 Parameters and variables influencing execution of DB::eval()
 570
 571 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 572 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 573 The variables listed below influence C<DB::eval()>'s execution directly.
 574
 575 =over 4
 576
 577 =item C<$evalarg> - the thing to actually be eval'ed
 578
 579 =item C<$trace> - Current state of execution tracing
 580
 581 =item C<$single> - Current state of single-stepping
 582
 583 =item C<$onetimeDump> - what is to be displayed after the evaluation
 584
 585 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 586
 587 =back
 588
 589 The following variables are altered by C<DB::eval()> during its execution. They
 590 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 591
 592 =over 4
 593
 594 =item C<@res> - used to capture output from actual C<eval>.
 595
 596 =item C<$otrace> - saved value of C<$trace>.
 597
 598 =item C<$osingle> - saved value of C<$single>.
 599
 600 =item C<$od> - saved value of C<$^D>.
 601
 602 =item C<$saved[0]> - saved value of C<$@>.
 603
 604 =item $\ - for output of C<$@> if there is an evaluation error.
 605
 606 =back
 607
 608 =head3 The problem of lexicals
 609
 610 The context of C<DB::eval()> presents us with some problems. Obviously,
 611 we want to be 'sandboxed' away from the debugger's internals when we do
 612 the eval, but we need some way to control how punctuation variables and
 613 debugger globals are used.
 614
 615 We can't use local, because the code inside C<DB::eval> can see localized
 616 variables; and we can't use C<my> either for the same reason. The code
 617 in this routine compromises and uses C<my>.
 618
 619 After this routine is over, we don't have user code executing in the debugger's
 620 context, so we can use C<my> freely.
 621
 622 =cut
 623
 624 ############################################## Begin lexical danger zone
 625
 626 # 'my' variables used here could leak into (that is, be visible in)
 627 # the context that the code being evaluated is executing in. This means that
 628 # the code could modify the debugger's variables.
 629 #
 630 # Fiddling with the debugger's context could be Bad. We insulate things as
 631 # much as we can.
 632
 633 use vars qw(
 634     @args
 635     %break_on_load
 636     $CommandSet
 637     $CreateTTY
 638     $DBGR
 639     @dbline
 640     $dbline
 641     %dbline
 642     $dieLevel
 643     $filename
 644     $histfile
 645     $histsize
 646     $IN
 647     $inhibit_exit
 648     @ini_INC
 649     $ini_warn
 650     $maxtrace
 651     $od
 652     @options
 653     $osingle
 654     $otrace
 655     $pager
 656     $post
 657     %postponed
 658     $prc
 659     $pre
 660     $pretype
 661     $psh
 662     @RememberOnROptions
 663     $remoteport
 664     @res
 665     $rl
 666     @saved
 667     $signalLevel
 668     $sub
 669     $term
 670     $usercontext
 671     $warnLevel
 672 );
 673
 674 our (
 675     @cmdfhs,
 676     $evalarg,
 677     $frame,
 678     $hist,
 679     $ImmediateStop,
 680     $line,
 681     $onetimeDump,
 682     $onetimedumpDepth,
 683     %option,
 684     $OUT,
 685     $packname,
 686     $signal,
 687     $single,
 688     $start,
 689     %sub,
 690     $subname,
 691     $trace,
 692     $window,
 693 );
 694
 695 # Used to save @ARGV and extract any debugger-related flags.
 696 use vars qw(@ARGS);
 697
 698 # Used to prevent multiple entries to diesignal()
 699 # (if for instance diesignal() itself dies)
 700 use vars qw($panic);
 701
 702 # Used to prevent the debugger from running nonstop
 703 # after a restart
 704 our ($second_time);
 705
 706 sub _calc_usercontext {
 707     my ($package) = @_;
 708
 709     # Cancel strict completely for the evaluated code, so the code
 710     # the user evaluates won't be affected by it. (Shlomi Fish)
 711     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
 712     . "package $package;";    # this won't let them modify, alas
 713 }
 714
 715 sub eval {
 716
 717     # 'my' would make it visible from user code
 718     #    but so does local! --tchrist
 719     # Remember: this localizes @DB::res, not @main::res.
 720     local @res;
 721     {
 722
 723         # Try to keep the user code from messing  with us. Save these so that
 724         # even if the eval'ed code changes them, we can put them back again.
 725         # Needed because the user could refer directly to the debugger's
 726         # package globals (and any 'my' variables in this containing scope)
 727         # inside the eval(), and we want to try to stay safe.
 728         local $otrace  = $trace;
 729         local $osingle = $single;
 730         local $od      = $^D;
 731
 732         # Untaint the incoming eval() argument.
 733         { ($evalarg) = $evalarg =~ /(.*)/s; }
 734
 735         # $usercontext built in DB::DB near the comment
 736         # "set up the context for DB::eval ..."
 737         # Evaluate and save any results.
 738         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 739
 740         # Restore those old values.
 741         $trace  = $otrace;
 742         $single = $osingle;
 743         $^D     = $od;
 744     }
 745
 746     # Save the current value of $@, and preserve it in the debugger's copy
 747     # of the saved precious globals.
 748     my $at = $@;
 749
 750     # Since we're only saving $@, we only have to localize the array element
 751     # that it will be stored in.
 752     local $saved[0];    # Preserve the old value of $@
 753     eval { &DB::save };
 754
 755     # Now see whether we need to report an error back to the user.
 756     if ($at) {
 757         local $\ = '';
 758         print $OUT $at;
 759     }
 760
 761     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 762     # are package globals.
 763     elsif ($onetimeDump) {
 764         if ( $onetimeDump eq 'dump' ) {
 765             local $option{dumpDepth} = $onetimedumpDepth
 766               if defined $onetimedumpDepth;
 767             dumpit( $OUT, \@res );
 768         }
 769         elsif ( $onetimeDump eq 'methods' ) {
 770             methods( $res[0] );
 771         }
 772     } ## end elsif ($onetimeDump)
 773     @res;
 774 } ## end sub eval
 775
 776 ############################################## End lexical danger zone
 777
 778 # After this point it is safe to introduce lexicals.
 779 # The code being debugged will be executing in its own context, and
 780 # can't see the inside of the debugger.
 781 #
 782 # However, one should not overdo it: leave as much control from outside as
 783 # possible. If you make something a lexical, it's not going to be addressable
 784 # from outside the debugger even if you know its name.
 785
 786 # This file is automatically included if you do perl -d.
 787 # It's probably not useful to include this yourself.
 788 #
 789 # Before venturing further into these twisty passages, it is
 790 # wise to read the perldebguts man page or risk the ire of dragons.
 791 #
 792 # (It should be noted that perldebguts will tell you a lot about
 793 # the underlying mechanics of how the debugger interfaces into the
 794 # Perl interpreter, but not a lot about the debugger itself. The new
 795 # comments in this code try to address this problem.)
 796
 797 # Note that no subroutine call is possible until &DB::sub is defined
 798 # (for subroutines defined outside of the package DB). In fact the same is
 799 # true if $deep is not defined.
 800
 801 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 802
 803 # modified Perl debugger, to be run from Emacs in perldb-mode
 804 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 805 # Johan Vromans -- upgrade to 4.0 pl 10
 806 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 807 ########################################################################
 808
 809 =head1 DEBUGGER INITIALIZATION
 810
 811 The debugger starts up in phases.
 812
 813 =head2 BASIC SETUP
 814
 815 First, it initializes the environment it wants to run in: turning off
 816 warnings during its own compilation, defining variables which it will need
 817 to avoid warnings later, setting itself up to not exit when the program
 818 terminates, and defaulting to printing return values for the C<r> command.
 819
 820 =cut
 821
 822 # Needed for the statement after exec():
 823 #
 824 # This BEGIN block is simply used to switch off warnings during debugger
 825 # compilation. Probably it would be better practice to fix the warnings,
 826 # but this is how it's done at the moment.
 827
 828 BEGIN {
 829     $ini_warn = $^W;
 830     $^W       = 0;
 831 }    # Switch compilation warnings off until another BEGIN.
 832
 833 local ($^W) = 0;    # Switch run-time warnings off during init.
 834
 835 =head2 THREADS SUPPORT
 836
 837 If we are running under a threaded Perl, we require threads and threads::shared
 838 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 839 threaded debugger control.  C<-dt> can also be used to set this.
 840
 841 Each new thread will be announced and the debugger prompt will always inform
 842 you of each new thread created.  It will also indicate the thread id in which
 843 we are currently running within the prompt like this:
 844
 845     [tid] DB<$i>
 846
 847 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 848 command prompt.  The prompt will show: C<[0]> when running under threads, but
 849 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 850
 851 While running under threads, when you set or delete a breakpoint (etc.), this
 852 will apply to all threads, not just the currently running one.  When you are
 853 in a currently executing thread, you will stay there until it completes.  With
 854 the current implementation it is not currently possible to hop from one thread
 855 to another.
 856
 857 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 858
 859 Note that threading support was built into the debugger as of Perl version
 860 C<5.8.6> and debugger version C<1.2.8>.
 861
 862 =cut
 863
 864 BEGIN {
 865     # ensure we can share our non-threaded variables or no-op
 866     if ($ENV{PERL5DB_THREADED}) {
 867         require threads;
 868         require threads::shared;
 869         import threads::shared qw(share);
 870         $DBGR;
 871         share(\$DBGR);
 872         lock($DBGR);
 873         print "Threads support enabled\n";
 874     } else {
 875         *lock = sub(*) {};
 876         *share = sub(\[$@%]) {};
 877     }
 878 }
 879
 880 # These variables control the execution of 'dumpvar.pl'.
 881 {
 882     package dumpvar;
 883     use vars qw(
 884     $hashDepth
 885     $arrayDepth
 886     $dumpDBFiles
 887     $dumpPackages
 888     $quoteHighBit
 889     $printUndef
 890     $globPrint
 891     $usageOnly
 892     );
 893 }
 894
 895 # used to control die() reporting in diesignal()
 896 {
 897     package Carp;
 898     use vars qw($CarpLevel);
 899 }
 900
 901 # without threads, $filename is not defined until DB::DB is called
 902 share($main::{'_<'.$filename}) if defined $filename;
 903
 904 # Command-line + PERLLIB:
 905 # Save the contents of @INC before they are modified elsewhere.
 906 @ini_INC = @INC;
 907
 908 # This was an attempt to clear out the previous values of various
 909 # trapped errors. Apparently it didn't help. XXX More info needed!
 910 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 911
 912 # We set these variables to safe values. We don't want to blindly turn
 913 # off warnings, because other packages may still want them.
 914 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 915                                    # (local $^W cannot help - other packages!).
 916
 917 # Default to not exiting when program finishes; print the return
 918 # value when the 'r' command is used to return from a subroutine.
 919 $inhibit_exit = $option{PrintRet} = 1;
 920
 921 use vars qw($trace_to_depth);
 922
 923 # Default to 1E9 so it won't be limited to a certain recursion depth.
 924 $trace_to_depth = 1E9;
 925
 926 =head1 OPTION PROCESSING
 927
 928 The debugger's options are actually spread out over the debugger itself and
 929 C<dumpvar.pl>; some of these are variables to be set, while others are
 930 subs to be called with a value. To try to make this a little easier to
 931 manage, the debugger uses a few data structures to define what options
 932 are legal and how they are to be processed.
 933
 934 First, the C<@options> array defines the I<names> of all the options that
 935 are to be accepted.
 936
 937 =cut
 938
 939 @options = qw(
 940   CommandSet   HistFile      HistSize
 941   hashDepth    arrayDepth    dumpDepth
 942   DumpDBFiles  DumpPackages  DumpReused
 943   compactDump  veryCompact   quote
 944   HighBit      undefPrint    globPrint
 945   PrintRet     UsageOnly     frame
 946   AutoTrace    TTY           noTTY
 947   ReadLine     NonStop       LineInfo
 948   maxTraceLen  recallCommand ShellBang
 949   pager        tkRunning     ornaments
 950   signalLevel  warnLevel     dieLevel
 951   inhibit_exit ImmediateStop bareStringify
 952   CreateTTY    RemotePort    windowSize
 953   DollarCaretP
 954 );
 955
 956 @RememberOnROptions = qw(DollarCaretP);
 957
 958 =pod
 959
 960 Second, C<optionVars> lists the variables that each option uses to save its
 961 state.
 962
 963 =cut
 964
 965 use vars qw(%optionVars);
 966
 967 %optionVars = (
 968     hashDepth     => \$dumpvar::hashDepth,
 969     arrayDepth    => \$dumpvar::arrayDepth,
 970     CommandSet    => \$CommandSet,
 971     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 972     DumpPackages  => \$dumpvar::dumpPackages,
 973     DumpReused    => \$dumpvar::dumpReused,
 974     HighBit       => \$dumpvar::quoteHighBit,
 975     undefPrint    => \$dumpvar::printUndef,
 976     globPrint     => \$dumpvar::globPrint,
 977     UsageOnly     => \$dumpvar::usageOnly,
 978     CreateTTY     => \$CreateTTY,
 979     bareStringify => \$dumpvar::bareStringify,
 980     frame         => \$frame,
 981     AutoTrace     => \$trace,
 982     inhibit_exit  => \$inhibit_exit,
 983     maxTraceLen   => \$maxtrace,
 984     ImmediateStop => \$ImmediateStop,
 985     RemotePort    => \$remoteport,
 986     windowSize    => \$window,
 987     HistFile      => \$histfile,
 988     HistSize      => \$histsize,
 989 );
 990
 991 =pod
 992
 993 Third, C<%optionAction> defines the subroutine to be called to process each
 994 option.
 995
 996 =cut
 997
 998 use vars qw(%optionAction);
 999
1000 %optionAction = (
1001     compactDump   => \&dumpvar::compactDump,
1002     veryCompact   => \&dumpvar::veryCompact,
1003     quote         => \&dumpvar::quote,
1004     TTY           => \&TTY,
1005     noTTY         => \&noTTY,
1006     ReadLine      => \&ReadLine,
1007     NonStop       => \&NonStop,
1008     LineInfo      => \&LineInfo,
1009     recallCommand => \&recallCommand,
1010     ShellBang     => \&shellBang,
1011     pager         => \&pager,
1012     signalLevel   => \&signalLevel,
1013     warnLevel     => \&warnLevel,
1014     dieLevel      => \&dieLevel,
1015     tkRunning     => \&tkRunning,
1016     ornaments     => \&ornaments,
1017     RemotePort    => \&RemotePort,
1018     DollarCaretP  => \&DollarCaretP,
1019 );
1020
1021 =pod
1022
1023 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1024 option is used.
1025
1026 =cut
1027
1028 # Note that this list is not complete: several options not listed here
1029 # actually require that dumpvar.pl be loaded for them to work, but are
1030 # not in the table. A subsequent patch will correct this problem; for
1031 # the moment, we're just recommenting, and we are NOT going to change
1032 # function.
1033 use vars qw(%optionRequire);
1034
1035 %optionRequire = (
1036     compactDump => 'dumpvar.pl',
1037     veryCompact => 'dumpvar.pl',
1038     quote       => 'dumpvar.pl',
1039 );
1040
1041 =pod
1042
1043 There are a number of initialization-related variables which can be set
1044 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1045 variable. These are:
1046
1047 =over 4
1048
1049 =item C<$rl> - readline control XXX needs more explanation
1050
1051 =item C<$warnLevel> - whether or not debugger takes over warning handling
1052
1053 =item C<$dieLevel> - whether or not debugger takes over die handling
1054
1055 =item C<$signalLevel> - whether or not debugger takes over signal handling
1056
1057 =item C<$pre> - preprompt actions (array reference)
1058
1059 =item C<$post> - postprompt actions (array reference)
1060
1061 =item C<$pretype>
1062
1063 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1064
1065 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1066
1067 =back
1068
1069 =cut
1070
1071 # These guys may be defined in $ENV{PERL5DB} :
1072 $rl          = 1     unless defined $rl;
1073 $warnLevel   = 1     unless defined $warnLevel;
1074 $dieLevel    = 1     unless defined $dieLevel;
1075 $signalLevel = 1     unless defined $signalLevel;
1076 $pre         = []    unless defined $pre;
1077 $post        = []    unless defined $post;
1078 $pretype     = []    unless defined $pretype;
1079 $CreateTTY   = 3     unless defined $CreateTTY;
1080 $CommandSet  = '580' unless defined $CommandSet;
1081
1082 share($rl);
1083 share($warnLevel);
1084 share($dieLevel);
1085 share($signalLevel);
1086 share($pre);
1087 share($post);
1088 share($pretype);
1089 share($rl);
1090 share($CreateTTY);
1091 share($CommandSet);
1092
1093 =pod
1094
1095 The default C<die>, C<warn>, and C<signal> handlers are set up.
1096
1097 =cut
1098
1099 warnLevel($warnLevel);
1100 dieLevel($dieLevel);
1101 signalLevel($signalLevel);
1102
1103 =pod
1104
1105 The pager to be used is needed next. We try to get it from the
1106 environment first.  If it's not defined there, we try to find it in
1107 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1108 then call the C<pager()> function to save the pager name.
1109
1110 =cut
1111
1112 # This routine makes sure $pager is set up so that '|' can use it.
1113 pager(
1114
1115     # If PAGER is defined in the environment, use it.
1116     defined $ENV{PAGER}
1117     ? $ENV{PAGER}
1118
1119       # If not, see if Config.pm defines it.
1120     : eval { require Config }
1121       && defined $Config::Config{pager}
1122     ? $Config::Config{pager}
1123
1124       # If not, fall back to 'more'.
1125     : 'more'
1126   )
1127   unless defined $pager;
1128
1129 =pod
1130
1131 We set up the command to be used to access the man pages, the command
1132 recall character (C<!> unless otherwise defined) and the shell escape
1133 character (C<!> unless otherwise defined). Yes, these do conflict, and
1134 neither works in the debugger at the moment.
1135
1136 =cut
1137
1138 setman();
1139
1140 # Set up defaults for command recall and shell escape (note:
1141 # these currently don't work in linemode debugging).
1142 recallCommand("!") unless defined $prc;
1143 shellBang("!")     unless defined $psh;
1144
1145 =pod
1146
1147 We then set up the gigantic string containing the debugger help.
1148 We also set the limit on the number of arguments we'll display during a
1149 trace.
1150
1151 =cut
1152
1153 sethelp();
1154
1155 # If we didn't get a default for the length of eval/stack trace args,
1156 # set it here.
1157 $maxtrace = 400 unless defined $maxtrace;
1158
1159 =head2 SETTING UP THE DEBUGGER GREETING
1160
1161 The debugger I<greeting> helps to inform the user how many debuggers are
1162 running, and whether the current debugger is the primary or a child.
1163
1164 If we are the primary, we just hang onto our pid so we'll have it when
1165 or if we start a child debugger. If we are a child, we'll set things up
1166 so we'll have a unique greeting and so the parent will give us our own
1167 TTY later.
1168
1169 We save the current contents of the C<PERLDB_PIDS> environment variable
1170 because we mess around with it. We'll also need to hang onto it because
1171 we'll need it if we restart.
1172
1173 Child debuggers make a label out of the current PID structure recorded in
1174 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1175 yet so the parent will give them one later via C<resetterm()>.
1176
1177 =cut
1178
1179 # Save the current contents of the environment; we're about to
1180 # much with it. We'll need this if we have to restart.
1181 use vars qw($ini_pids);
1182 $ini_pids = $ENV{PERLDB_PIDS};
1183
1184 use vars qw ($pids $term_pid);
1185
1186 if ( defined $ENV{PERLDB_PIDS} ) {
1187
1188     # We're a child. Make us a label out of the current PID structure
1189     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1190     # a term yet so the parent will give us one later via resetterm().
1191
1192     my $env_pids = $ENV{PERLDB_PIDS};
1193     $pids = "[$env_pids]";
1194
1195     # Unless we are on OpenVMS, all programs under the DCL shell run under
1196     # the same PID.
1197
1198     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1199         $term_pid         = $$;
1200     }
1201     else {
1202         $ENV{PERLDB_PIDS} .= "->$$";
1203         $term_pid = -1;
1204     }
1205
1206 } ## end if (defined $ENV{PERLDB_PIDS...
1207 else {
1208
1209     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1210     # child debugger, and mark us as the parent, so we'll know to set up
1211     # more TTY's is we have to.
1212     $ENV{PERLDB_PIDS} = "$$";
1213     $pids             = "[pid=$$]";
1214     $term_pid         = $$;
1215 }
1216
1217 use vars qw($pidprompt);
1218 $pidprompt = '';
1219
1220 # Sets up $emacs as a synonym for $slave_editor.
1221 our ($slave_editor);
1222 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1223
1224 =head2 READING THE RC FILE
1225
1226 The debugger will read a file of initialization options if supplied. If
1227 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1228
1229 =cut
1230
1231 # As noted, this test really doesn't check accurately that the debugger
1232 # is running at a terminal or not.
1233
1234 use vars qw($rcfile);
1235 {
1236     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1237     # this is the wrong metric!
1238     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1239 }
1240
1241 =pod
1242
1243 The debugger does a safety test of the file to be read. It must be owned
1244 either by the current user or root, and must only be writable by the owner.
1245
1246 =cut
1247
1248 # This wraps a safety test around "do" to read and evaluate the init file.
1249 #
1250 # This isn't really safe, because there's a race
1251 # between checking and opening.  The solution is to
1252 # open and fstat the handle, but then you have to read and
1253 # eval the contents.  But then the silly thing gets
1254 # your lexical scope, which is unfortunate at best.
1255 sub safe_do {
1256     my $file = shift;
1257
1258     # Just exactly what part of the word "CORE::" don't you understand?
1259     local $SIG{__WARN__};
1260     local $SIG{__DIE__};
1261
1262     unless ( is_safe_file($file) ) {
1263         CORE::warn <<EO_GRIPE;
1264 perldb: Must not source insecure rcfile $file.
1265         You or the superuser must be the owner, and it must not
1266         be writable by anyone but its owner.
1267 EO_GRIPE
1268         return;
1269     } ## end unless (is_safe_file($file...
1270
1271     do $file;
1272     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1273 } ## end sub safe_do
1274
1275 # This is the safety test itself.
1276 #
1277 # Verifies that owner is either real user or superuser and that no
1278 # one but owner may write to it.  This function is of limited use
1279 # when called on a path instead of upon a handle, because there are
1280 # no guarantees that filename (by dirent) whose file (by ino) is
1281 # eventually accessed is the same as the one tested.
1282 # Assumes that the file's existence is not in doubt.
1283 sub is_safe_file {
1284     my $path = shift;
1285     stat($path) || return;    # mysteriously vaporized
1286     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1287
1288     return 0 if $uid != 0 && $uid != $<;
1289     return 0 if $mode & 022;
1290     return 1;
1291 } ## end sub is_safe_file
1292
1293 # If the rcfile (whichever one we decided was the right one to read)
1294 # exists, we safely do it.
1295 if ( -f $rcfile ) {
1296     safe_do("./$rcfile");
1297 }
1298
1299 # If there isn't one here, try the user's home directory.
1300 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1301     safe_do("$ENV{HOME}/$rcfile");
1302 }
1303
1304 # Else try the login directory.
1305 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1306     safe_do("$ENV{LOGDIR}/$rcfile");
1307 }
1308
1309 # If the PERLDB_OPTS variable has options in it, parse those out next.
1310 if ( defined $ENV{PERLDB_OPTS} ) {
1311     parse_options( $ENV{PERLDB_OPTS} );
1312 }
1313
1314 =pod
1315
1316 The last thing we do during initialization is determine which subroutine is
1317 to be used to obtain a new terminal when a new debugger is started. Right now,
1318 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1319 (darwin).
1320
1321 =cut
1322
1323 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1324 # Works if you're running an xterm or xterm-like window, or you're on
1325 # OS/2, or on Mac OS X. This may need some expansion.
1326
1327 if (not defined &get_fork_TTY)       # only if no routine exists
1328 {
1329     if ( defined $remoteport ) {
1330                                                  # Expect an inetd-like server
1331         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1332     }
1333     elsif (defined $ENV{TERM}                    # If we know what kind
1334                                                  # of terminal this is,
1335         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1336         and defined $ENV{DISPLAY}                # and what display it's on,
1337       )
1338     {
1339         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1340     }
1341     elsif ( $ENV{TMUX} ) {
1342         *get_fork_TTY = \&tmux_get_fork_TTY;
1343     }
1344     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1345         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1346     }
1347     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1348             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1349             and $ENV{TERM_PROGRAM}
1350                 eq 'Apple_Terminal'              # Terminal.app
1351             )
1352     {
1353         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1354     }
1355 } ## end if (not defined &get_fork_TTY...
1356
1357 # untaint $^O, which may have been tainted by the last statement.
1358 # see bug [perl #24674]
1359 $^O =~ m/^(.*)\z/;
1360 $^O = $1;
1361
1362 # Here begin the unreadable code.  It needs fixing.
1363
1364 =head2 RESTART PROCESSING
1365
1366 This section handles the restart command. When the C<R> command is invoked, it
1367 tries to capture all of the state it can into environment variables, and
1368 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1369 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1370 the R command stuffed into the environment variables.
1371
1372   PERLDB_RESTART   - flag only, contains no restart data itself.
1373   PERLDB_HIST      - command history, if it's available
1374   PERLDB_ON_LOAD   - breakpoints set by the rc file
1375   PERLDB_POSTPONE  - subs that have been loaded/not executed,
1376                      and have actions
1377   PERLDB_VISITED   - files that had breakpoints
1378   PERLDB_FILE_...  - breakpoints for a file
1379   PERLDB_OPT       - active options
1380   PERLDB_INC       - the original @INC
1381   PERLDB_PRETYPE   - preprompt debugger actions
1382   PERLDB_PRE       - preprompt Perl code
1383   PERLDB_POST      - post-prompt Perl code
1384   PERLDB_TYPEAHEAD - typeahead captured by readline()
1385
1386 We chug through all these variables and plug the values saved in them
1387 back into the appropriate spots in the debugger.
1388
1389 =cut
1390
1391 use vars qw(%postponed_file @typeahead);
1392
1393 our (@hist, @truehist);
1394
1395 sub _restore_shared_globals_after_restart
1396 {
1397     @hist          = get_list('PERLDB_HIST');
1398     %break_on_load = get_list("PERLDB_ON_LOAD");
1399     %postponed     = get_list("PERLDB_POSTPONE");
1400
1401     share(@hist);
1402     share(@truehist);
1403     share(%break_on_load);
1404     share(%postponed);
1405 }
1406
1407 sub _restore_breakpoints_and_actions {
1408
1409     my @had_breakpoints = get_list("PERLDB_VISITED");
1410
1411     for my $file_idx ( 0 .. $#had_breakpoints ) {
1412         my $filename = $had_breakpoints[$file_idx];
1413         my %pf = get_list("PERLDB_FILE_$file_idx");
1414         $postponed_file{ $filename } = \%pf if %pf;
1415         my @lines = sort {$a <=> $b} keys(%pf);
1416         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1417         for my $line_idx (0 .. $#lines) {
1418             _set_breakpoint_enabled_status(
1419                 $filename,
1420                 $lines[$line_idx],
1421                 ($enabled_statuses[$line_idx] ? 1 : ''),
1422             );
1423         }
1424     }
1425
1426     return;
1427 }
1428
1429 sub _restore_options_after_restart
1430 {
1431     my %options_map = get_list("PERLDB_OPT");
1432
1433     while ( my ( $opt, $val ) = each %options_map ) {
1434         $val =~ s/[\\\']/\\$1/g;
1435         parse_options("$opt'$val'");
1436     }
1437
1438     return;
1439 }
1440
1441 sub _restore_globals_after_restart
1442 {
1443     # restore original @INC
1444     @INC     = get_list("PERLDB_INC");
1445     @ini_INC = @INC;
1446
1447     # return pre/postprompt actions and typeahead buffer
1448     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1449     $pre       = [ get_list("PERLDB_PRE") ];
1450     $post      = [ get_list("PERLDB_POST") ];
1451     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1452
1453     return;
1454 }
1455
1456
1457 if ( exists $ENV{PERLDB_RESTART} ) {
1458
1459     # We're restarting, so we don't need the flag that says to restart anymore.
1460     delete $ENV{PERLDB_RESTART};
1461
1462     # $restart = 1;
1463     _restore_shared_globals_after_restart();
1464
1465     _restore_breakpoints_and_actions();
1466
1467     # restore options
1468     _restore_options_after_restart();
1469
1470     _restore_globals_after_restart();
1471 } ## end if (exists $ENV{PERLDB_RESTART...
1472
1473 =head2 SETTING UP THE TERMINAL
1474
1475 Now, we'll decide how the debugger is going to interact with the user.
1476 If there's no TTY, we set the debugger to run non-stop; there's not going
1477 to be anyone there to enter commands.
1478
1479 =cut
1480
1481 use vars qw($notty $console $tty $LINEINFO);
1482 use vars qw($lineinfo $doccmd);
1483
1484 our ($runnonstop);
1485
1486 # Local autoflush to avoid rt#116769,
1487 # as calling IO::File methods causes an unresolvable loop
1488 # that results in debugger failure.
1489 sub _autoflush {
1490     my $o = select($_[0]);
1491     $|++;
1492     select($o);
1493 }
1494
1495 if ($notty) {
1496     $runnonstop = 1;
1497     share($runnonstop);
1498 }
1499
1500 =pod
1501
1502 If there is a TTY, we have to determine who it belongs to before we can
1503 proceed. If this is a slave editor or graphical debugger (denoted by
1504 the first command-line switch being '-emacs'), we shift this off and
1505 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1506
1507 =cut
1508
1509 else {
1510
1511     # Is Perl being run from a slave editor or graphical debugger?
1512     # If so, don't use readline, and set $slave_editor = 1.
1513     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1514         $rl = 0;
1515         shift(@main::ARGV);
1516     }
1517
1518     #require Term::ReadLine;
1519
1520 =pod
1521
1522 We then determine what the console should be on various systems:
1523
1524 =over 4
1525
1526 =item * Cygwin - We use C<stdin> instead of a separate device.
1527
1528 =cut
1529
1530     if ( $^O eq 'cygwin' ) {
1531
1532         # /dev/tty is binary. use stdin for textmode
1533         undef $console;
1534     }
1535
1536 =item * Windows or MSDOS - use C<con>.
1537
1538 =cut
1539
1540     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1541         $console = "con";
1542     }
1543
1544 =item * AmigaOS - use C<CONSOLE:>.
1545
1546 =cut
1547
1548     elsif ( $^O eq 'amigaos' ) {
1549         $console = "CONSOLE:";
1550     }
1551
1552 =item * VMS - use C<sys$command>.
1553
1554 =cut
1555
1556     elsif ($^O eq 'VMS') {
1557         $console = 'sys$command';
1558     }
1559
1560 # Keep this penultimate, on the grounds that it satisfies a wide variety of
1561 # Unix-like systems that would otherwise need to be identified individually.
1562
1563 =item * Unix - use F</dev/tty>.
1564
1565 =cut
1566
1567     elsif ( -e "/dev/tty" ) {
1568         $console = "/dev/tty";
1569     }
1570
1571 # Keep this last.
1572
1573     else {
1574         _db_warn("Can't figure out your console, using stdin");
1575         undef $console;
1576     }
1577
1578 =pod
1579
1580 =back
1581
1582 Several other systems don't use a specific console. We C<undef $console>
1583 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1584 with a slave editor).
1585
1586 =cut
1587
1588     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1589
1590         # /dev/tty is binary. use stdin for textmode
1591         $console = undef;
1592     }
1593
1594     if ( $^O eq 'NetWare' ) {
1595
1596         # /dev/tty is binary. use stdin for textmode
1597         $console = undef;
1598     }
1599
1600     # In OS/2, we need to use STDIN to get textmode too, even though
1601     # it pretty much looks like Unix otherwise.
1602     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1603     {    # In OS/2
1604         $console = undef;
1605     }
1606
1607 =pod
1608
1609 If there is a TTY hanging around from a parent, we use that as the console.
1610
1611 =cut
1612
1613     $console = $tty if defined $tty;
1614
1615 =head2 SOCKET HANDLING
1616
1617 The debugger is capable of opening a socket and carrying out a debugging
1618 session over the socket.
1619
1620 If C<RemotePort> was defined in the options, the debugger assumes that it
1621 should try to start a debugging session on that port. It builds the socket
1622 and then tries to connect the input and output filehandles to it.
1623
1624 =cut
1625
1626     # Handle socket stuff.
1627
1628     if ( defined $remoteport ) {
1629
1630         # If RemotePort was defined in the options, connect input and output
1631         # to the socket.
1632         $IN = $OUT = connect_remoteport();
1633     } ## end if (defined $remoteport)
1634
1635 =pod
1636
1637 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1638 this is probably a situation where multiple debuggers are running (for example,
1639 a backticked command that starts up another debugger). We create a new IN and
1640 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1641 and if we can.
1642
1643 =cut
1644
1645     # Non-socket.
1646     else {
1647
1648         # Two debuggers running (probably a system or a backtick that invokes
1649         # the debugger itself under the running one). create a new IN and OUT
1650         # filehandle, and do the necessary mojo to create a new tty if we
1651         # know how, and we can.
1652         create_IN_OUT(4) if $CreateTTY & 4;
1653         if ($console) {
1654
1655             # If we have a console, check to see if there are separate ins and
1656             # outs to open. (They are assumed identical if not.)
1657
1658             my ( $i, $o ) = split /,/, $console;
1659             $o = $i unless defined $o;
1660
1661             # read/write on in, or just read, or read on STDIN.
1662                  open( IN, '+<', $i )
1663               || open( IN, '<',  $i )
1664               || open( IN, "<&STDIN" );
1665
1666             # read/write/create/clobber out, or write/create/clobber out,
1667             # or merge with STDERR, or merge with STDOUT.
1668                  open( OUT, '+>', $o )
1669               || open( OUT, '>',  $o )
1670               || open( OUT, ">&STDERR" )
1671               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1672
1673         } ## end if ($console)
1674         elsif ( not defined $console ) {
1675
1676             # No console. Open STDIN.
1677             open( IN, "<&STDIN" );
1678
1679             # merge with STDERR, or with STDOUT.
1680             open( OUT,      ">&STDERR" )
1681               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1682             $console = 'STDIN/OUT';
1683         } ## end elsif (not defined $console)
1684
1685         # Keep copies of the filehandles so that when the pager runs, it
1686         # can close standard input without clobbering ours.
1687         if ($console or (not defined($console))) {
1688             $IN = \*IN;
1689             $OUT = \*OUT;
1690         }
1691     } ## end elsif (from if(defined $remoteport))
1692
1693     # Unbuffer DB::OUT. We need to see responses right away.
1694     _autoflush($OUT);
1695
1696     # Line info goes to debugger output unless pointed elsewhere.
1697     # Pointing elsewhere makes it possible for slave editors to
1698     # keep track of file and position. We have both a filehandle
1699     # and a I/O description to keep track of.
1700     $LINEINFO = $OUT     unless defined $LINEINFO;
1701     $lineinfo = $console unless defined $lineinfo;
1702     # share($LINEINFO); # <- unable to share globs
1703     share($lineinfo);   #
1704
1705 =pod
1706
1707 To finish initialization, we show the debugger greeting,
1708 and then call the C<afterinit()> subroutine if there is one.
1709
1710 =cut
1711
1712     # Show the debugger greeting.
1713     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1714     unless ($runnonstop) {
1715         local $\ = '';
1716         local $, = '';
1717         if ( $term_pid eq '-1' ) {
1718             print $OUT "\nDaughter DB session started...\n";
1719         }
1720         else {
1721             print $OUT "\nLoading DB routines from $header\n";
1722             print $OUT (
1723                 "Editor support ",
1724                 $slave_editor ? "enabled" : "available", ".\n"
1725             );
1726             print $OUT
1727 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1728         } ## end else [ if ($term_pid eq '-1')
1729     } ## end unless ($runnonstop)
1730 } ## end else [ if ($notty)
1731
1732 # XXX This looks like a bug to me.
1733 # Why copy to @ARGS and then futz with @args?
1734 @ARGS = @ARGV;
1735 # for (@args) {
1736     # Make sure backslashes before single quotes are stripped out, and
1737     # keep args unless they are numeric (XXX why?)
1738     # s/\'/\\\'/g;                      # removed while not justified understandably
1739     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1740 # }
1741
1742 # If there was an afterinit() sub defined, call it. It will get
1743 # executed in our scope, so it can fiddle with debugger globals.
1744 if ( defined &afterinit ) {    # May be defined in $rcfile
1745     afterinit();
1746 }
1747
1748 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1749 use vars qw($I_m_init);
1750
1751 $I_m_init = 1;
1752
1753 ############################################################ Subroutines
1754
1755 =head1 SUBROUTINES
1756
1757 =head2 DB
1758
1759 This gigantic subroutine is the heart of the debugger. Called before every
1760 statement, its job is to determine if a breakpoint has been reached, and
1761 stop if so; read commands from the user, parse them, and execute
1762 them, and then send execution off to the next statement.
1763
1764 Note that the order in which the commands are processed is very important;
1765 some commands earlier in the loop will actually alter the C<$cmd> variable
1766 to create other commands to be executed later. This is all highly I<optimized>
1767 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1768 see what's happening in any given command.
1769
1770 =cut
1771
1772 # $cmd cannot be an our() variable unfortunately (possible perl bug?).
1773
1774 use vars qw(
1775     $action
1776     $cmd
1777     $file
1778     $filename_ini
1779     $finished
1780     %had_breakpoints
1781     $level
1782     $max
1783     $package
1784     $try
1785 );
1786
1787 our (
1788     %alias,
1789     $doret,
1790     $end,
1791     $fall_off_end,
1792     $incr,
1793     $laststep,
1794     $rc,
1795     $sh,
1796     $stack_depth,
1797     @stack,
1798     @to_watch,
1799     @old_watch,
1800 );
1801
1802 sub _DB__determine_if_we_should_break
1803 {
1804     # if we have something here, see if we should break.
1805     # $stop is lexical and local to this block - $action on the other hand
1806     # is global.
1807     my $stop;
1808
1809     if ( $dbline{$line}
1810         && _is_breakpoint_enabled($filename, $line)
1811         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1812     {
1813
1814         # Stop if the stop criterion says to just stop.
1815         if ( $stop eq '1' ) {
1816             $signal |= 1;
1817         }
1818
1819         # It's a conditional stop; eval it in the user's context and
1820         # see if we should stop. If so, remove the one-time sigil.
1821         elsif ($stop) {
1822             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1823             # The &-call is here to ascertain the mutability of @_.
1824             &DB::eval;
1825             # If the breakpoint is temporary, then delete its enabled status.
1826             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1827                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1828             }
1829         }
1830     } ## end if ($dbline{$line} && ...
1831 }
1832
1833 sub _DB__is_finished {
1834     if ($finished and $level <= 1) {
1835         end_report();
1836         return 1;
1837     }
1838     else {
1839         return;
1840     }
1841 }
1842
1843 sub _DB__read_next_cmd
1844 {
1845     my ($tid) = @_;
1846
1847     # We have a terminal, or can get one ...
1848     if (!$term) {
1849         setterm();
1850     }
1851
1852     # ... and it belongs to this PID or we get one for this PID ...
1853     if ($term_pid != $$) {
1854         resetterm(1);
1855     }
1856
1857     # ... and we got a line of command input ...
1858     $cmd = DB::readline(
1859         "$pidprompt $tid DB"
1860         . ( '<' x $level )
1861         . ( $#hist + 1 )
1862         . ( '>' x $level ) . " "
1863     );
1864
1865     return defined($cmd);
1866 }
1867
1868 sub _DB__trim_command_and_return_first_component {
1869     my ($obj) = @_;
1870
1871     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1872     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1873
1874     # A single-character debugger command can be immediately followed by its
1875     # argument if they aren't both alphanumeric; otherwise require space
1876     # between commands and arguments:
1877     my ($verb, $args) = $cmd =~ m{\A(.\b|\S*)\s*(.*)}s;
1878
1879     $obj->cmd_verb($verb);
1880     $obj->cmd_args($args);
1881
1882     return;
1883 }
1884
1885 sub _DB__handle_f_command {
1886     my ($obj) = @_;
1887
1888     if ($file = $obj->cmd_args) {
1889         # help for no arguments (old-style was return from sub).
1890         if ( !$file ) {
1891             print $OUT
1892             "The old f command is now the r command.\n";    # hint
1893             print $OUT "The new f command switches filenames.\n";
1894             next CMD;
1895         } ## end if (!$file)
1896
1897         # if not in magic file list, try a close match.
1898         if ( !defined $main::{ '_<' . $file } ) {
1899             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1900                 {
1901                     $try = substr( $try, 2 );
1902                     print $OUT "Choosing $try matching '$file':\n";
1903                     $file = $try;
1904                 }
1905             } ## end if (($try) = grep(m#^_<.*$file#...
1906         } ## end if (!defined $main::{ ...
1907
1908         # If not successfully switched now, we failed.
1909         if ( !defined $main::{ '_<' . $file } ) {
1910             print $OUT "No file matching '$file' is loaded.\n";
1911             next CMD;
1912         }
1913
1914         # We switched, so switch the debugger internals around.
1915         elsif ( $file ne $filename ) {
1916             *dbline   = $main::{ '_<' . $file };
1917             $max      = $#dbline;
1918             $filename = $file;
1919             $start    = 1;
1920             $cmd      = "l";
1921         } ## end elsif ($file ne $filename)
1922
1923         # We didn't switch; say we didn't.
1924         else {
1925             print $OUT "Already in $file.\n";
1926             next CMD;
1927         }
1928     }
1929
1930     return;
1931 }
1932
1933 sub _DB__handle_dot_command {
1934     my ($obj) = @_;
1935
1936     # . command.
1937     if ($obj->_is_full('.')) {
1938         $incr = -1;    # stay at current line
1939
1940         # Reset everything to the old location.
1941         $start    = $line;
1942         $filename = $filename_ini;
1943         *dbline   = $main::{ '_<' . $filename };
1944         $max      = $#dbline;
1945
1946         # Now where are we?
1947         print_lineinfo($obj->position());
1948         next CMD;
1949     }
1950
1951     return;
1952 }
1953
1954 sub _DB__handle_y_command {
1955     my ($obj) = @_;
1956
1957     if (my ($match_level, $match_vars)
1958         = $obj->cmd_args =~ /\A(?:(\d*)\s*(.*))?\z/) {
1959
1960         # See if we've got the necessary support.
1961         if (!eval {
1962             local @INC = @INC;
1963             pop @INC if $INC[-1] eq '.';
1964             require PadWalker; PadWalker->VERSION(0.08) }) {
1965             my $Err = $@;
1966             _db_warn(
1967                 $Err =~ /locate/
1968                 ? "PadWalker module not found - please install\n"
1969                 : $Err
1970             );
1971             next CMD;
1972         }
1973
1974         # Load up dumpvar if we don't have it. If we can, that is.
1975         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
1976         defined &main::dumpvar
1977             or print $OUT "dumpvar.pl not available.\n"
1978             and next CMD;
1979
1980         # Got all the modules we need. Find them and print them.
1981         my @vars = split( ' ', $match_vars || '' );
1982
1983         # Find the pad.
1984         my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 2 ) };
1985
1986         # Oops. Can't find it.
1987         if (my $Err = $@) {
1988             $Err =~ s/ at .*//;
1989             _db_warn($Err);
1990             next CMD;
1991         }
1992
1993         # Show the desired vars with dumplex().
1994         my $savout = select($OUT);
1995
1996         # Have dumplex dump the lexicals.
1997         foreach my $key (sort keys %$h) {
1998             dumpvar::dumplex( $key, $h->{$key},
1999                 defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2000                 @vars );
2001         }
2002         select($savout);
2003         next CMD;
2004     }
2005 }
2006
2007 sub _DB__handle_c_command {
2008     my ($obj) = @_;
2009
2010     my $i = $obj->cmd_args;
2011
2012     if ($i =~ m#\A[\w:]*\z#) {
2013
2014         # Hey, show's over. The debugged program finished
2015         # executing already.
2016         next CMD if _DB__is_finished();
2017
2018         # Capture the place to put a one-time break.
2019         $subname = $i;
2020
2021         #  Probably not needed, since we finish an interactive
2022         #  sub-session anyway...
2023         # local $filename = $filename;
2024         # local *dbline = *dbline; # XXX Would this work?!
2025         #
2026         # The above question wonders if localizing the alias
2027         # to the magic array works or not. Since it's commented
2028         # out, we'll just leave that to speculation for now.
2029
2030         # If the "subname" isn't all digits, we'll assume it
2031         # is a subroutine name, and try to find it.
2032         if ( $subname =~ /\D/ ) {    # subroutine name
2033             # Qualify it to the current package unless it's
2034             # already qualified.
2035             $subname = $package . "::" . $subname
2036             unless $subname =~ /::/;
2037
2038             # find_sub will return "file:line_number" corresponding
2039             # to where the subroutine is defined; we call find_sub,
2040             # break up the return value, and assign it in one
2041             # operation.
2042             ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2043
2044             # Force the line number to be numeric.
2045             $i = $i + 0;
2046
2047             # If we got a line number, we found the sub.
2048             if ($i) {
2049
2050                 # Switch all the debugger's internals around so
2051                 # we're actually working with that file.
2052                 $filename = $file;
2053                 *dbline   = $main::{ '_<' . $filename };
2054
2055                 # Mark that there's a breakpoint in this file.
2056                 $had_breakpoints{$filename} |= 1;
2057
2058                 # Scan forward to the first executable line
2059                 # after the 'sub whatever' line.
2060                 $max = $#dbline;
2061                 my $_line_num = $i;
2062                 while ($dbline[$_line_num] == 0 && $_line_num< $max)
2063                 {
2064                     $_line_num++;
2065                 }
2066                 $i = $_line_num;
2067             } ## end if ($i)
2068
2069             # We didn't find a sub by that name.
2070             else {
2071                 print $OUT "Subroutine $subname not found.\n";
2072                 next CMD;
2073             }
2074         } ## end if ($subname =~ /\D/)
2075
2076         # At this point, either the subname was all digits (an
2077         # absolute line-break request) or we've scanned through
2078         # the code following the definition of the sub, looking
2079         # for an executable, which we may or may not have found.
2080         #
2081         # If $i (which we set $subname from) is non-zero, we
2082         # got a request to break at some line somewhere. On
2083         # one hand, if there wasn't any real subroutine name
2084         # involved, this will be a request to break in the current
2085         # file at the specified line, so we have to check to make
2086         # sure that the line specified really is breakable.
2087         #
2088         # On the other hand, if there was a subname supplied, the
2089         # preceding block has moved us to the proper file and
2090         # location within that file, and then scanned forward
2091         # looking for the next executable line. We have to make
2092         # sure that one was found.
2093         #
2094         # On the gripping hand, we can't do anything unless the
2095         # current value of $i points to a valid breakable line.
2096         # Check that.
2097         if ($i) {
2098
2099             # Breakable?
2100             if ( $dbline[$i] == 0 ) {
2101                 print $OUT "Line $i not breakable.\n";
2102                 next CMD;
2103             }
2104
2105             # Yes. Set up the one-time-break sigil.
2106             $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2107             _enable_breakpoint_temp_enabled_status($filename, $i);
2108         } ## end if ($i)
2109
2110         # Turn off stack tracing from here up.
2111         for my $j (0 .. $stack_depth) {
2112             $stack[ $j ] &= ~1;
2113         }
2114         last CMD;
2115     }
2116
2117     return;
2118 }
2119
2120 sub _DB__handle_forward_slash_command {
2121     my ($obj) = @_;
2122
2123     # The pattern as a string.
2124     use vars qw($inpat);
2125
2126     if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2127
2128         # Remove the final slash.
2129         $inpat =~ s:([^\\])/$:$1:;
2130
2131         # If the pattern isn't null ...
2132         if ( $inpat ne "" ) {
2133
2134             # Turn off warn and die processing for a bit.
2135             local $SIG{__DIE__};
2136             local $SIG{__WARN__};
2137
2138             # Create the pattern.
2139             eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2140             if ( $@ ne "" ) {
2141
2142                 # Oops. Bad pattern. No biscuit.
2143                 # Print the eval error and go back for more
2144                 # commands.
2145                 print {$OUT} "$@";
2146                 next CMD;
2147             }
2148             $obj->pat($inpat);
2149         } ## end if ($inpat ne "")
2150
2151         # Set up to stop on wrap-around.
2152         $end = $start;
2153
2154         # Don't move off the current line.
2155         $incr = -1;
2156
2157         my $pat = $obj->pat;
2158
2159         # Done in eval so nothing breaks if the pattern
2160         # does something weird.
2161         eval
2162         {
2163             no strict q/vars/;
2164             for (;;) {
2165                 # Move ahead one line.
2166                 ++$start;
2167
2168                 # Wrap if we pass the last line.
2169                 if ($start > $max) {
2170                     $start = 1;
2171                 }
2172
2173                 # Stop if we have gotten back to this line again,
2174                 last if ($start == $end);
2175
2176                 # A hit! (Note, though, that we are doing
2177                 # case-insensitive matching. Maybe a qr//
2178                 # expression would be better, so the user could
2179                 # do case-sensitive matching if desired.
2180                 if ($dbline[$start] =~ m/$pat/i) {
2181                     if ($slave_editor) {
2182                         # Handle proper escaping in the slave.
2183                         print {$OUT} "\032\032$filename:$start:0\n";
2184                     }
2185                     else {
2186                         # Just print the line normally.
2187                         print {$OUT} "$start:\t",$dbline[$start],"\n";
2188                     }
2189                     # And quit since we found something.
2190                     last;
2191                 }
2192             }
2193         };
2194
2195         if ($@) {
2196             warn $@;
2197         }
2198
2199         # If we wrapped, there never was a match.
2200         if ( $start == $end ) {
2201             print {$OUT} "/$pat/: not found\n";
2202         }
2203         next CMD;
2204     }
2205
2206     return;
2207 }
2208
2209 sub _DB__handle_question_mark_command {
2210     my ($obj) = @_;
2211
2212     # ? - backward pattern search.
2213     if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2214
2215         # Get the pattern, remove trailing question mark.
2216         $inpat =~ s:([^\\])\?$:$1:;
2217
2218         # If we've got one ...
2219         if ( $inpat ne "" ) {
2220
2221             # Turn off die & warn handlers.
2222             local $SIG{__DIE__};
2223             local $SIG{__WARN__};
2224             eval '$inpat =~ m' . "\a$inpat\a";
2225
2226             if ( $@ ne "" ) {
2227
2228                 # Ouch. Not good. Print the error.
2229                 print $OUT $@;
2230                 next CMD;
2231             }
2232             $obj->pat($inpat);
2233         } ## end if ($inpat ne "")
2234
2235         # Where we are now is where to stop after wraparound.
2236         $end = $start;
2237
2238         # Don't move away from this line.
2239         $incr = -1;
2240
2241         my $pat = $obj->pat;
2242         # Search inside the eval to prevent pattern badness
2243         # from killing us.
2244         eval {
2245             no strict q/vars/;
2246             for (;;) {
2247                 # Back up a line.
2248                 --$start;
2249
2250                 # Wrap if we pass the first line.
2251
2252                 $start = $max if ($start <= 0);
2253
2254                 # Quit if we get back where we started,
2255                 last if ($start == $end);
2256
2257                 # Match?
2258                 if ($dbline[$start] =~ m/$pat/i) {
2259                     if ($slave_editor) {
2260                         # Yep, follow slave editor requirements.
2261                         print $OUT "\032\032$filename:$start:0\n";
2262                     }
2263                     else {
2264                         # Yep, just print normally.
2265                         print $OUT "$start:\t",$dbline[$start],"\n";
2266                     }
2267
2268                     # Found, so done.
2269                     last;
2270                 }
2271             }
2272         };
2273
2274         # Say we failed if the loop never found anything,
2275         if ( $start == $end ) {
2276             print {$OUT} "?$pat?: not found\n";
2277         }
2278         next CMD;
2279     }
2280
2281     return;
2282 }
2283
2284 sub _DB__handle_restart_and_rerun_commands {
2285     my ($obj) = @_;
2286
2287     my $cmd_cmd = $obj->cmd_verb;
2288     my $cmd_params = $obj->cmd_args;
2289     # R - restart execution.
2290     # rerun - controlled restart execution.
2291     if ($cmd_cmd eq 'rerun' or $cmd_params eq '') {
2292
2293         # Change directory to the initial current working directory on
2294         # the script startup, so if the debugged program changed the
2295         # directory, then we will still be able to find the path to the
2296         # the program. (perl 5 RT #121509 ).
2297         chdir ($_initial_cwd);
2298
2299         my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
2300
2301         # Close all non-system fds for a clean restart.  A more
2302         # correct method would be to close all fds that were not
2303         # open when the process started, but this seems to be
2304         # hard.  See "debugger 'R'estart and open database
2305         # connections" on p5p.
2306
2307         my $max_fd = 1024; # default if POSIX can't be loaded
2308         if (eval { require POSIX }) {
2309             eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
2310         }
2311
2312         if (defined $max_fd) {
2313             foreach ($^F+1 .. $max_fd-1) {
2314                 next unless open FD_TO_CLOSE, "<&=$_";
2315                 close(FD_TO_CLOSE);
2316             }
2317         }
2318
2319         # And run Perl again.  We use exec() to keep the
2320         # PID stable (and that way $ini_pids is still valid).
2321         exec(@args) or print {$OUT} "exec failed: $!\n";
2322
2323         last CMD;
2324     }
2325
2326     return;
2327 }
2328
2329 sub _DB__handle_run_command_in_pager_command {
2330     my ($obj) = @_;
2331
2332     if ($cmd =~ m#\A\|\|?\s*[^|]#) {
2333         if ( $pager =~ /^\|/ ) {
2334
2335             # Default pager is into a pipe. Redirect I/O.
2336             open( SAVEOUT, ">&STDOUT" )
2337             || _db_warn("Can't save STDOUT");
2338             open( STDOUT, ">&OUT" )
2339             || _db_warn("Can't redirect STDOUT");
2340         } ## end if ($pager =~ /^\|/)
2341         else {
2342
2343             # Not into a pipe. STDOUT is safe.
2344             open( SAVEOUT, ">&OUT" ) || _db_warn("Can't save DB::OUT");
2345         }
2346
2347         # Fix up environment to record we have less if so.
2348         fix_less();
2349
2350         unless ( $obj->piped(scalar ( open( OUT, $pager ) ) ) ) {
2351
2352             # Couldn't open pipe to pager.
2353             _db_warn("Can't pipe output to '$pager'");
2354             if ( $pager =~ /^\|/ ) {
2355
2356                 # Redirect I/O back again.
2357                 open( OUT, ">&STDOUT" )    # XXX: lost message
2358                 || _db_warn("Can't restore DB::OUT");
2359                 open( STDOUT, ">&SAVEOUT" )
2360                 || _db_warn("Can't restore STDOUT");
2361                 close(SAVEOUT);
2362             } ## end if ($pager =~ /^\|/)
2363             else {
2364
2365                 # Redirect I/O. STDOUT already safe.
2366                 open( OUT, ">&STDOUT" )    # XXX: lost message
2367                 || _db_warn("Can't restore DB::OUT");
2368             }
2369             next CMD;
2370         } ## end unless ($piped = open(OUT,...
2371
2372         # Set up broken-pipe handler if necessary.
2373         $SIG{PIPE} = \&DB::catch
2374         if $pager =~ /^\|/
2375         && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
2376
2377         _autoflush(\*OUT);
2378         # Save current filehandle, and put it back.
2379         $obj->selected(scalar( select(OUT) ));
2380         # Don't put it back if pager was a pipe.
2381         if ($cmd !~ /\A\|\|/)
2382         {
2383             select($obj->selected());
2384             $obj->selected("");
2385         }
2386
2387         # Trim off the pipe symbols and run the command now.
2388         $cmd =~ s#\A\|+\s*##;
2389         redo PIPE;
2390     }
2391
2392     return;
2393 }
2394
2395 sub _DB__handle_m_command {
2396     my ($obj) = @_;
2397
2398     if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2399         methods($1);
2400         next CMD;
2401     }
2402
2403     # m expr - set up DB::eval to do the work
2404     if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2405         $onetimeDump = 'methods';   #  method output gets used there
2406     }
2407
2408     return;
2409 }
2410
2411 sub _DB__at_end_of_every_command {
2412     my ($obj) = @_;
2413
2414     # At the end of every command:
2415     if ($obj->piped) {
2416
2417         # Unhook the pipe mechanism now.
2418         if ( $pager =~ /^\|/ ) {
2419
2420             # No error from the child.
2421             $? = 0;
2422
2423             # we cannot warn here: the handle is missing --tchrist
2424             close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
2425
2426             # most of the $? crud was coping with broken cshisms
2427             # $? is explicitly set to 0, so this never runs.
2428             if ($?) {
2429                 print SAVEOUT "Pager '$pager' failed: ";
2430                 if ( $? == -1 ) {
2431                     print SAVEOUT "shell returned -1\n";
2432                 }
2433                 elsif ( $? >> 8 ) {
2434                     print SAVEOUT ( $? & 127 )
2435                     ? " (SIG#" . ( $? & 127 ) . ")"
2436                     : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
2437                 }
2438                 else {
2439                     print SAVEOUT "status ", ( $? >> 8 ), "\n";
2440                 }
2441             } ## end if ($?)
2442
2443             # Reopen filehandle for our output (if we can) and
2444             # restore STDOUT (if we can).
2445             open( OUT, ">&STDOUT" ) || _db_warn("Can't restore DB::OUT");
2446             open( STDOUT, ">&SAVEOUT" )
2447             || _db_warn("Can't restore STDOUT");
2448
2449             # Turn off pipe exception handler if necessary.
2450             $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
2451
2452             # Will stop ignoring SIGPIPE if done like nohup(1)
2453             # does SIGINT but Perl doesn't give us a choice.
2454         } ## end if ($pager =~ /^\|/)
2455         else {
2456
2457             # Non-piped "pager". Just restore STDOUT.
2458             open( OUT, ">&SAVEOUT" ) || _db_warn("Can't restore DB::OUT");
2459         }
2460
2461         # Let Readline know about the new filehandles.
2462         reset_IN_OUT( \*IN, \*OUT );
2463
2464         # Close filehandle pager was using, restore the normal one
2465         # if necessary,
2466         close(SAVEOUT);
2467
2468         if ($obj->selected() ne "") {
2469             select($obj->selected);
2470             $obj->selected("");
2471         }
2472
2473         # No pipes now.
2474         $obj->piped("");
2475     } ## end if ($piped)
2476
2477     return;
2478 }
2479
2480 sub _DB__handle_watch_expressions
2481 {
2482     my $self = shift;
2483
2484     if ( $DB::trace & 2 ) {
2485         for my $n (0 .. $#DB::to_watch) {
2486             $DB::evalarg = $DB::to_watch[$n];
2487             local $DB::onetimeDump;    # Tell DB::eval() to not output results
2488
2489             # Fix context DB::eval() wants to return an array, but
2490             # we need a scalar here.
2491             my ($val) = join( "', '", DB::eval(@_) );
2492             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
2493
2494             # Did it change?
2495             if ( $val ne $DB::old_watch[$n] ) {
2496
2497                 # Yep! Show the difference, and fake an interrupt.
2498                 $DB::signal = 1;
2499                 print {$DB::OUT} <<EOP;
2500 Watchpoint $n:\t$DB::to_watch[$n] changed:
2501     old value:\t$DB::old_watch[$n]
2502     new value:\t$val
2503 EOP
2504                 $DB::old_watch[$n] = $val;
2505             } ## end if ($val ne $old_watch...
2506         } ## end for my $n (0 ..
2507     } ## end if ($trace & 2)
2508
2509     return;
2510 }
2511
2512 # 't' is type.
2513 # 'm' is method.
2514 # 'v' is the value (i.e: method name or subroutine ref).
2515 # 's' is subroutine.
2516 my %cmd_lookup;
2517
2518 BEGIN
2519 {
2520     %cmd_lookup =
2521 (
2522     '-' => { t => 'm', v => '_handle_dash_command', },
2523     '.' => { t => 's', v => \&_DB__handle_dot_command, },
2524     '=' => { t => 'm', v => '_handle_equal_sign_command', },
2525     'H' => { t => 'm', v => '_handle_H_command', },
2526     'S' => { t => 'm', v => '_handle_S_command', },
2527     'T' => { t => 'm', v => '_handle_T_command', },
2528     'W' => { t => 'm', v => '_handle_W_command', },
2529     'c' => { t => 's', v => \&_DB__handle_c_command, },
2530     'f' => { t => 's', v => \&_DB__handle_f_command, },
2531     'm' => { t => 's', v => \&_DB__handle_m_command, },
2532     'n' => { t => 'm', v => '_handle_n_command', },
2533     'p' => { t => 'm', v => '_handle_p_command', },
2534     'q' => { t => 'm', v => '_handle_q_command', },
2535     'r' => { t => 'm', v => '_handle_r_command', },
2536     's' => { t => 'm', v => '_handle_s_command', },
2537     'save' => { t => 'm', v => '_handle_save_command', },
2538     'source' => { t => 'm', v => '_handle_source_command', },
2539     't' => { t => 'm', v => '_handle_t_command', },
2540     'w' => { t => 'm', v => '_handle_w_command', },
2541     'x' => { t => 'm', v => '_handle_x_command', },
2542     'y' => { t => 's', v => \&_DB__handle_y_command, },
2543     (map { $_ => { t => 'm', v => '_handle_V_command_and_X_command', }, }
2544         ('X', 'V')),
2545     (map { $_ => { t => 'm', v => '_handle_enable_disable_commands', }, }
2546         qw(enable disable)),
2547     (map { $_ =>
2548         { t => 's', v => \&_DB__handle_restart_and_rerun_commands, },
2549         } qw(R rerun)),
2550     (map { $_ => {t => 'm', v => '_handle_cmd_wrapper_commands' }, }
2551         qw(a A b B e E h i l L M o O v w W)),
2552 );
2553 };
2554
2555 sub DB {
2556
2557     # lock the debugger and get the thread id for the prompt
2558     lock($DBGR);
2559     my $tid;
2560     my $position;
2561     my ($prefix, $after, $infix);
2562     my $pat;
2563     my $explicit_stop;
2564     my $piped;
2565     my $selected;
2566
2567     if ($ENV{PERL5DB_THREADED}) {
2568         $tid = eval { "[".threads->tid."]" };
2569     }
2570
2571     my $cmd_verb;
2572     my $cmd_args;
2573
2574     my $obj = DB::Obj->new(
2575         {
2576             position => \$position,
2577             prefix => \$prefix,
2578             after => \$after,
2579             explicit_stop => \$explicit_stop,
2580             infix => \$infix,
2581             cmd_args => \$cmd_args,
2582             cmd_verb => \$cmd_verb,
2583             pat => \$pat,
2584             piped => \$piped,
2585             selected => \$selected,
2586         },
2587     );
2588
2589     $obj->_DB_on_init__initialize_globals(@_);
2590
2591     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
2592     # The code being debugged may have altered them.
2593     DB::save();
2594
2595     # Since DB::DB gets called after every line, we can use caller() to
2596     # figure out where we last were executing. Sneaky, eh? This works because
2597     # caller is returning all the extra information when called from the
2598     # debugger.
2599     local ( $package, $filename, $line ) = caller;
2600     $filename_ini = $filename;
2601
2602     # set up the context for DB::eval, so it can properly execute
2603     # code on behalf of the user. We add the package in so that the
2604     # code is eval'ed in the proper package (not in the debugger!).
2605     local $usercontext = _calc_usercontext($package);
2606
2607     # Create an alias to the active file magical array to simplify
2608     # the code here.
2609     local (*dbline) = $main::{ '_<' . $filename };
2610
2611     # Last line in the program.
2612     $max = $#dbline;
2613
2614     # The &-call is here to ascertain the mutability of @_.
2615     &_DB__determine_if_we_should_break;
2616
2617     # Preserve the current stop-or-not, and see if any of the W
2618     # (watch expressions) has changed.
2619     my $was_signal = $signal;
2620
2621     # If we have any watch expressions ...
2622     _DB__handle_watch_expressions($obj);
2623
2624 =head2 C<watchfunction()>
2625
2626 C<watchfunction()> is a function that can be defined by the user; it is a
2627 function which will be run on each entry to C<DB::DB>; it gets the
2628 current package, filename, and line as its parameters.
2629
2630 The watchfunction can do anything it likes; it is executing in the
2631 debugger's context, so it has access to all of the debugger's internal
2632 data structures and functions.
2633
2634 C<watchfunction()> can control the debugger's actions. Any of the following
2635 will cause the debugger to return control to the user's program after
2636 C<watchfunction()> executes:
2637
2638 =over 4
2639
2640 =item *
2641
2642 Returning a false value from the C<watchfunction()> itself.
2643
2644 =item *
2645
2646 Altering C<$single> to a false value.
2647
2648 =item *
2649
2650 Altering C<$signal> to a false value.
2651
2652 =item *
2653
2654 Turning off the C<4> bit in C<$trace> (this also disables the
2655 check for C<watchfunction()>. This can be done with
2656
2657     $trace &= ~4;
2658
2659 =back
2660
2661 =cut
2662
2663     # If there's a user-defined DB::watchfunction, call it with the
2664     # current package, filename, and line. The function executes in
2665     # the DB:: package.
2666     if ( $trace & 4 ) {    # User-installed watch
2667         return
2668           if watchfunction( $package, $filename, $line )
2669           and not $single
2670           and not $was_signal
2671           and not( $trace & ~4 );
2672     } ## end if ($trace & 4)
2673
2674     # Pick up any alteration to $signal in the watchfunction, and
2675     # turn off the signal now.
2676     $was_signal = $signal;
2677     $signal     = 0;
2678
2679 =head2 GETTING READY TO EXECUTE COMMANDS
2680
2681 The debugger decides to take control if single-step mode is on, the
2682 C<t> command was entered, or the user generated a signal. If the program
2683 has fallen off the end, we set things up so that entering further commands
2684 won't cause trouble, and we say that the program is over.
2685
2686 =cut
2687
2688     # Make sure that we always print if asked for explicitly regardless
2689     # of $trace_to_depth .
2690     $explicit_stop = ($single || $was_signal);
2691
2692     # Check to see if we should grab control ($single true,
2693     # trace set appropriately, or we got a signal).
2694     if ( $explicit_stop || ( $trace & 1 ) ) {
2695         $obj->_DB__grab_control(@_);
2696     } ## end if ($single || ($trace...
2697
2698 =pod
2699
2700 If there's an action to be executed for the line we stopped at, execute it.
2701 If there are any preprompt actions, execute those as well.
2702
2703 =cut
2704
2705     # If there's an action, do it now.
2706     if ($action) {
2707         $evalarg = $action;
2708         # The &-call is here to ascertain the mutability of @_.
2709         &DB::eval;
2710     }
2711
2712     # Are we nested another level (e.g., did we evaluate a function
2713     # that had a breakpoint in it at the debugger prompt)?
2714     if ( $single || $was_signal ) {
2715
2716         # Yes, go down a level.
2717         local $level = $level + 1;
2718
2719         # Do any pre-prompt actions.
2720         foreach $evalarg (@$pre) {
2721             # The &-call is here to ascertain the mutability of @_.
2722             &DB::eval;
2723         }
2724
2725         # Complain about too much recursion if we passed the limit.
2726         if ($single & 4) {
2727             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2728         }
2729
2730         # The line we're currently on. Set $incr to -1 to stay here
2731         # until we get a command that tells us to advance.
2732         $start = $line;
2733         $incr  = -1;      # for backward motion.
2734
2735         # Tack preprompt debugger actions ahead of any actual input.
2736         @typeahead = ( @$pretype, @typeahead );
2737
2738 =head2 WHERE ARE WE?
2739
2740 XXX Relocate this section?
2741
2742 The debugger normally shows the line corresponding to the current line of
2743 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2744 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2745
2746 C<$incr> controls by how many lines the I<current> line should move forward
2747 after a command is executed. If set to -1, this indicates that the I<current>
2748 line shouldn't change.
2749
2750 C<$start> is the I<current> line. It is used for things like knowing where to
2751 move forwards or backwards from when doing an C<L> or C<-> command.
2752
2753 C<$max> tells the debugger where the last line of the current file is. It's
2754 used to terminate loops most often.
2755
2756 =head2 THE COMMAND LOOP
2757
2758 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2759 in two parts:
2760
2761 =over 4
2762
2763 =item *
2764
2765 The outer part of the loop, starting at the C<CMD> label. This loop
2766 reads a command and then executes it.
2767
2768 =item *
2769
2770 The inner part of the loop, starting at the C<PIPE> label. This part
2771 is wholly contained inside the C<CMD> block and only executes a command.
2772 Used to handle commands running inside a pager.
2773
2774 =back
2775
2776 So why have two labels to restart the loop? Because sometimes, it's easier to
2777 have a command I<generate> another command and then re-execute the loop to do
2778 the new command. This is faster, but perhaps a bit more convoluted.
2779
2780 =cut
2781
2782         # The big command dispatch loop. It keeps running until the
2783         # user yields up control again.
2784         #
2785         # If we have a terminal for input, and we get something back
2786         # from readline(), keep on processing.
2787
2788       CMD:
2789         while (_DB__read_next_cmd($tid))
2790         {
2791
2792             share($cmd);
2793             # ... try to execute the input as debugger commands.
2794
2795             # Don't stop running.
2796             $single = 0;
2797
2798             # No signal is active.
2799             $signal = 0;
2800
2801             # Handle continued commands (ending with \):
2802             if ($cmd =~ s/\\\z/\n/) {
2803                 $cmd .= DB::readline("  cont: ");
2804                 redo CMD;
2805             }
2806
2807 =head4 The null command
2808
2809 A newline entered by itself means I<re-execute the last command>. We grab the
2810 command out of C<$laststep> (where it was recorded previously), and copy it
2811 back into C<$cmd> to be executed below. If there wasn't any previous command,
2812 we'll do nothing below (no command will match). If there was, we also save it
2813 in the command history and fall through to allow the command parsing to pick
2814 it up.
2815
2816 =cut
2817
2818             # Empty input means repeat the last command.
2819             if ($cmd eq '') {
2820                 $cmd = $laststep;
2821             }
2822             chomp($cmd);    # get rid of the annoying extra newline
2823             if (length($cmd) >= 2) {
2824                 push( @hist, $cmd );
2825             }
2826             push( @truehist, $cmd );
2827             share(@hist);
2828             share(@truehist);
2829
2830             # This is a restart point for commands that didn't arrive
2831             # via direct user input. It allows us to 'redo PIPE' to
2832             # re-execute command processing without reading a new command.
2833           PIPE: {
2834                 _DB__trim_command_and_return_first_component($obj);
2835
2836 =head3 COMMAND ALIASES
2837
2838 The debugger can create aliases for commands (these are stored in the
2839 C<%alias> hash). Before a command is executed, the command loop looks it up
2840 in the alias hash and substitutes the contents of the alias for the command,
2841 completely replacing it.
2842
2843 =cut
2844
2845                 # See if there's an alias for the command, and set it up if so.
2846                 if ( $alias{$cmd_verb} ) {
2847
2848                     # Squelch signal handling; we want to keep control here
2849                     # if something goes loco during the alias eval.
2850                     local $SIG{__DIE__};
2851                     local $SIG{__WARN__};
2852
2853                     # This is a command, so we eval it in the DEBUGGER's
2854                     # scope! Otherwise, we can't see the special debugger
2855                     # variables, or get to the debugger's subs. (Well, we
2856                     # _could_, but why make it even more complicated?)
2857                     eval "\$cmd =~ $alias{$cmd_verb}";
2858                     if ($@) {
2859                         local $\ = '';
2860                         print $OUT "Couldn't evaluate '$cmd_verb' alias: $@";
2861                         next CMD;
2862                     }
2863                     _DB__trim_command_and_return_first_component($obj);
2864                 } ## end if ($alias{$cmd_verb})
2865
2866 =head3 MAIN-LINE COMMANDS
2867
2868 All of these commands work up to and after the program being debugged has
2869 terminated.
2870
2871 =head4 C<q> - quit
2872
2873 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2874 try to execute further, cleaning any restart-related stuff out of the
2875 environment, and executing with the last value of C<$?>.
2876
2877 =cut
2878
2879                 # All of these commands were remapped in perl 5.8.0;
2880                 # we send them off to the secondary dispatcher (see below).
2881                 $obj->_handle_special_char_cmd_wrapper_commands;
2882                 _DB__trim_command_and_return_first_component($obj);
2883
2884                 if (my $cmd_rec = $cmd_lookup{$cmd_verb}) {
2885                     my $type = $cmd_rec->{t};
2886                     my $val = $cmd_rec->{v};
2887                     if ($type eq 'm') {
2888                         $obj->$val();
2889                     }
2890                     elsif ($type eq 's') {
2891                         $val->($obj);
2892                     }
2893                 }
2894
2895 =head4 C<t> - trace [n]
2896
2897 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2898 If level is specified, set C<$trace_to_depth>.
2899
2900 =head4 C<S> - list subroutines matching/not matching a pattern
2901
2902 Walks through C<%sub>, checking to see whether or not to print the name.
2903
2904 =head4 C<X> - list variables in current package
2905
2906 Since the C<V> command actually processes this, just change this to the
2907 appropriate C<V> command and fall through.
2908
2909 =head4 C<V> - list variables
2910
2911 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2912
2913 =head4 C<x> - evaluate and print an expression
2914
2915 Hands the expression off to C<DB::eval>, setting it up to print the value
2916 via C<dumpvar.pl> instead of just printing it directly.
2917
2918 =head4 C<m> - print methods
2919
2920 Just uses C<DB::methods> to determine what methods are available.
2921
2922 =head4 C<f> - switch files
2923
2924 Switch to a different filename.
2925
2926 =head4 C<.> - return to last-executed line.
2927
2928 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2929 and then we look up the line in the magical C<%dbline> hash.
2930
2931 =head4 C<-> - back one window
2932
2933 We change C<$start> to be one window back; if we go back past the first line,
2934 we set it to be the first line. We set C<$incr> to put us back at the
2935 currently-executing line, and then put a C<l $start +> (list one window from
2936 C<$start>) in C<$cmd> to be executed later.
2937
2938 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2939
2940 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2941 problems, most notably that the default case of several commands destroying
2942 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2943 retain the old commands for those who were used to using them or who preferred
2944 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2945 deal with them instead of processing them in-line.
2946
2947 =head4 C<y> - List lexicals in higher scope
2948
2949 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2950 above the current one and then displays then using C<dumpvar.pl>.
2951
2952 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2953
2954 All of the commands below this point don't work after the program being
2955 debugged has ended. All of them check to see if the program has ended; this
2956 allows the commands to be relocated without worrying about a 'line of
2957 demarcation' above which commands can be entered anytime, and below which
2958 they can't.
2959
2960 =head4 C<n> - single step, but don't trace down into subs
2961
2962 Done by setting C<$single> to 2, which forces subs to execute straight through
2963 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2964 so a null command knows what to re-execute.
2965
2966 =head4 C<s> - single-step, entering subs
2967
2968 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2969 subs. Also saves C<s> as C<$lastcmd>.
2970
2971 =head4 C<c> - run continuously, setting an optional breakpoint
2972
2973 Most of the code for this command is taken up with locating the optional
2974 breakpoint, which is either a subroutine name or a line number. We set
2975 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2976 in this and all call levels above this one.
2977
2978 =head4 C<r> - return from a subroutine
2979
2980 For C<r> to work properly, the debugger has to stop execution again
2981 immediately after the return is executed. This is done by forcing
2982 single-stepping to be on in the call level above the current one. If
2983 we are printing return values when a C<r> is executed, set C<$doret>
2984 appropriately, and force us out of the command loop.
2985
2986 =head4 C<T> - stack trace
2987
2988 Just calls C<DB::print_trace>.
2989
2990 =head4 C<w> - List window around current line.
2991
2992 Just calls C<DB::cmd_w>.
2993
2994 =head4 C<W> - watch-expression processing.
2995
2996 Just calls C<DB::cmd_W>.
2997
2998 =head4 C</> - search forward for a string in the source
2999
3000 We take the argument and treat it as a pattern. If it turns out to be a
3001 bad one, we return the error we got from trying to C<eval> it and exit.
3002 If not, we create some code to do the search and C<eval> it so it can't
3003 mess us up.
3004
3005 =cut
3006
3007                 _DB__handle_forward_slash_command($obj);
3008
3009 =head4 C<?> - search backward for a string in the source
3010
3011 Same as for C</>, except the loop runs backwards.
3012
3013 =cut
3014
3015                 _DB__handle_question_mark_command($obj);
3016
3017 =head4 C<$rc> - Recall command
3018
3019 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
3020 that the terminal supports history). It finds the command required, puts it
3021 into C<$cmd>, and redoes the loop to execute it.
3022
3023 =cut
3024
3025                 # $rc - recall command.
3026                 $obj->_handle_rc_recall_command;
3027
3028 =head4 C<$sh$sh> - C<system()> command
3029
3030 Calls the C<_db_system()> to handle the command. This keeps the C<STDIN> and
3031 C<STDOUT> from getting messed up.
3032
3033 =cut
3034
3035                 $obj->_handle_sh_command;
3036
3037 =head4 C<$rc I<pattern> $rc> - Search command history
3038
3039 Another command to manipulate C<@hist>: this one searches it with a pattern.
3040 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
3041
3042 =cut
3043
3044                 $obj->_handle_rc_search_history_command;
3045
3046 =head4 C<$sh> - Invoke a shell
3047
3048 Uses C<_db_system()> to invoke a shell.
3049
3050 =cut
3051
3052 =head4 C<$sh I<command>> - Force execution of a command in a shell
3053
3054 Like the above, but the command is passed to the shell. Again, we use
3055 C<_db_system()> to avoid problems with C<STDIN> and C<STDOUT>.
3056
3057 =head4 C<H> - display commands in history
3058
3059 Prints the contents of C<@hist> (if any).
3060
3061 =head4 C<man, doc, perldoc> - look up documentation
3062
3063 Just calls C<runman()> to print the appropriate document.
3064
3065 =cut
3066
3067                 $obj->_handle_doc_command;
3068
3069 =head4 C<p> - print
3070
3071 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3072 the bottom of the loop.
3073
3074 =head4 C<=> - define command alias
3075
3076 Manipulates C<%alias> to add or list command aliases.
3077
3078 =head4 C<source> - read commands from a file.
3079
3080 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3081 pick it up.
3082
3083 =head4 C<enable> C<disable> - enable or disable breakpoints
3084
3085 This enables or disables breakpoints.
3086
3087 =head4 C<save> - send current history to a file
3088
3089 Takes the complete history, (not the shrunken version you see with C<H>),
3090 and saves it to the given filename, so it can be replayed using C<source>.
3091
3092 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3093
3094 =head4 C<R> - restart
3095
3096 Restart the debugger session.
3097
3098 =head4 C<rerun> - rerun the current session
3099
3100 Return to any given position in the B<true>-history list
3101
3102 =head4 C<|, ||> - pipe output through the pager.
3103
3104 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3105 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3106 pipe to the pager (restoring the output filehandles if this fails). If this
3107 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3108 set C<$signal>, sending us back into the debugger.
3109
3110 We then trim off the pipe symbols and C<redo> the command loop at the
3111 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3112 reading another.
3113
3114 =cut
3115
3116                 # || - run command in the pager, with output to DB::OUT.
3117                 _DB__handle_run_command_in_pager_command($obj);
3118
3119 =head3 END OF COMMAND PARSING
3120
3121 Anything left in C<$cmd> at this point is a Perl expression that we want to
3122 evaluate. We'll always evaluate in the user's context, and fully qualify
3123 any variables we might want to address in the C<DB> package.
3124
3125 =cut
3126
3127             }    # PIPE:
3128
3129             # trace an expression
3130             $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3131
3132             # Make sure the flag that says "the debugger's running" is
3133             # still on, to make sure we get control again.
3134             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3135
3136             # Run *our* eval that executes in the caller's context.
3137             # The &-call is here to ascertain the mutability of @_.
3138             &DB::eval;
3139
3140             # Turn off the one-time-dump stuff now.
3141             if ($onetimeDump) {
3142                 $onetimeDump      = undef;
3143                 $onetimedumpDepth = undef;
3144             }
3145             elsif ( $term_pid == $$ ) {
3146                 eval { # May run under miniperl, when not available...
3147                     STDOUT->flush();
3148                     STDERR->flush();
3149                 };
3150
3151                 # XXX If this is the master pid, print a newline.
3152                 print {$OUT} "\n";
3153             }
3154         } ## end while (($term || &setterm...
3155
3156 =head3 POST-COMMAND PROCESSING
3157
3158 After each command, we check to see if the command output was piped anywhere.
3159 If so, we go through the necessary code to unhook the pipe and go back to
3160 our standard filehandles for input and output.
3161
3162 =cut
3163
3164         continue {    # CMD:
3165             _DB__at_end_of_every_command($obj);
3166         }    # CMD:
3167
3168 =head3 COMMAND LOOP TERMINATION
3169
3170 When commands have finished executing, we come here. If the user closed the
3171 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3172 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3173 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3174 The interpreter will then execute the next line and then return control to us
3175 again.
3176
3177 =cut
3178
3179         # No more commands? Quit.
3180         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3181
3182         # Evaluate post-prompt commands.
3183         foreach $evalarg (@$post) {
3184             # The &-call is here to ascertain the mutability of @_.
3185             &DB::eval;
3186         }
3187     }    # if ($single || $signal)
3188
3189     # Put the user's globals back where you found them.
3190     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3191     ();
3192 } ## end sub DB
3193
3194 # Because DB::Obj is used above,
3195 #
3196 #   my $obj = DB::Obj->new(
3197 #
3198 # The following package declaration must come before that,
3199 # or else runtime errors will occur with
3200 #
3201 #   PERLDB_OPTS="autotrace nonstop"
3202 #
3203 # ( rt#116771 )
3204 BEGIN {
3205
3206 package DB::Obj;
3207
3208 sub new {
3209     my $class = shift;
3210
3211     my $self = bless {}, $class;
3212
3213     $self->_init(@_);
3214
3215     return $self;
3216 }
3217
3218 sub _init {
3219     my ($self, $args) = @_;
3220
3221     %{$self} = (%$self, %$args);
3222
3223     return;
3224 }
3225
3226 {
3227     no strict 'refs';
3228     foreach my $slot_name (qw(
3229         after explicit_stop infix pat piped position prefix selected cmd_verb
3230         cmd_args
3231         )) {
3232         my $slot = $slot_name;
3233         *{$slot} = sub {
3234             my $self = shift;
3235
3236             if (@_) {
3237                 ${ $self->{$slot} } = shift;
3238             }
3239
3240             return ${ $self->{$slot} };
3241         };
3242
3243         *{"append_to_$slot"} = sub {
3244             my $self = shift;
3245             my $s = shift;
3246
3247             return $self->$slot($self->$slot . $s);
3248         };
3249     }
3250 }
3251
3252 sub _DB_on_init__initialize_globals
3253 {
3254     my $self = shift;
3255
3256     # Check for whether we should be running continuously or not.
3257     # _After_ the perl program is compiled, $single is set to 1:
3258     if ( $single and not $second_time++ ) {
3259
3260         # Options say run non-stop. Run until we get an interrupt.
3261         if ($runnonstop) {    # Disable until signal
3262                 # If there's any call stack in place, turn off single
3263                 # stepping into subs throughout the stack.
3264             for my $i (0 .. $stack_depth) {
3265                 $stack[ $i ] &= ~1;
3266             }
3267
3268             # And we are now no longer in single-step mode.
3269             $single = 0;
3270
3271             # If we simply returned at this point, we wouldn't get
3272             # the trace info. Fall on through.
3273             # return;
3274         } ## end if ($runnonstop)
3275
3276         elsif ($ImmediateStop) {
3277
3278             # We are supposed to stop here; XXX probably a break.
3279             $ImmediateStop = 0;    # We've processed it; turn it off
3280             $signal        = 1;    # Simulate an interrupt to force
3281                                    # us into the command loop
3282         }
3283     } ## end if ($single and not $second_time...
3284
3285     # If we're in single-step mode, or an interrupt (real or fake)
3286     # has occurred, turn off non-stop mode.
3287     $runnonstop = 0 if $single or $signal;
3288
3289     return;
3290 }
3291
3292 sub _my_print_lineinfo
3293 {
3294     my ($self, $i, $incr_pos) = @_;
3295
3296     if ($frame) {
3297         # Print it indented if tracing is on.
3298         DB::print_lineinfo( ' ' x $stack_depth,
3299             "$i:\t$DB::dbline[$i]" . $self->after );
3300     }
3301     else {
3302         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3303     }
3304 }
3305
3306 sub _curr_line {
3307     return $DB::dbline[$line];
3308 }
3309
3310 sub _is_full {
3311     my ($self, $letter) = @_;
3312
3313     return ($DB::cmd eq $letter);
3314 }
3315
3316 sub _DB__grab_control
3317 {
3318     my $self = shift;
3319
3320     # Yes, grab control.
3321     if ($slave_editor) {
3322
3323         # Tell the editor to update its position.
3324         $self->position("\032\032${DB::filename}:$line:0\n");
3325         DB::print_lineinfo($self->position());
3326     }
3327
3328 =pod
3329
3330 Special check: if we're in package C<DB::fake>, we've gone through the
3331 C<END> block at least once. We set up everything so that we can continue
3332 to enter commands and have a valid context to be in.
3333
3334 =cut
3335
3336     elsif ( $DB::package eq 'DB::fake' ) {
3337
3338         # Fallen off the end already.
3339         if (!$DB::term) {
3340             DB::setterm();
3341         }
3342
3343         DB::print_help(<<EOP);
3344 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3345 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3346 B<h q>, B<h R> or B<h o> to get additional info.
3347 EOP
3348
3349         # Set the DB::eval context appropriately.
3350         # At program termination disable any user actions.
3351         $DB::action = undef;
3352
3353         $DB::package     = 'main';
3354         $DB::usercontext = DB::_calc_usercontext($DB::package);
3355     } ## end elsif ($package eq 'DB::fake')
3356
3357 =pod
3358
3359 If the program hasn't finished executing, we scan forward to the
3360 next executable line, print that out, build the prompt from the file and line
3361 number information, and print that.
3362
3363 =cut
3364
3365     else {
3366
3367
3368         # Still somewhere in the midst of execution. Set up the
3369         #  debugger prompt.
3370         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3371                              # Perl 5 ones (sorry, we don't print Klingon
3372                              #module names)
3373
3374         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3375         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3376         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3377
3378         # Break up the prompt if it's really long.
3379         if ( length($self->prefix()) > 30 ) {
3380             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3381             $self->prefix("");
3382             $self->infix(":\t");
3383         }
3384         else {
3385             $self->infix("):\t");
3386             $self->position(
3387                 $self->prefix . $line. $self->infix
3388                 . $self->_curr_line . $self->after
3389             );
3390         }
3391
3392         # Print current line info, indenting if necessary.
3393         $self->_my_print_lineinfo($line, $self->position);
3394
3395         my $i;
3396         my $line_i = sub { return $DB::dbline[$i]; };
3397
3398         # Scan forward, stopping at either the end or the next
3399         # unbreakable line.
3400         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3401         {    #{ vi
3402
3403             # Drop out on null statements, block closers, and comments.
3404             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3405
3406             # Drop out if the user interrupted us.
3407             last if $signal;
3408
3409             # Append a newline if the line doesn't have one. Can happen
3410             # in eval'ed text, for instance.
3411             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3412
3413             # Next executable line.
3414             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3415                 . $self->after;
3416             $self->append_to_position($incr_pos);
3417             $self->_my_print_lineinfo($i, $incr_pos);
3418         } ## end for ($i = $line + 1 ; $i...
3419     } ## end else [ if ($slave_editor)
3420
3421     return;
3422 }
3423
3424 sub _handle_t_command {
3425     my $self = shift;
3426
3427     my $levels = $self->cmd_args();
3428
3429     if ((!length($levels)) or ($levels !~ /\D/)) {
3430         $trace ^= 1;
3431         local $\ = '';
3432         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3433         print {$OUT} "Trace = "
3434         . ( ( $trace & 1 )
3435             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3436             : "off" ) . "\n";
3437         next CMD;
3438     }
3439
3440     return;
3441 }
3442
3443
3444 sub _handle_S_command {
3445     my $self = shift;
3446
3447     if (my ($print_all_subs, $should_reverse, $Spatt)
3448         = $self->cmd_args =~ /\A((!)?(.+))?\z/) {
3449         # $Spatt is the pattern (if any) to use.
3450         # Reverse scan?
3451         my $Srev     = defined $should_reverse;
3452         # No args - print all subs.
3453         my $Snocheck = !defined $print_all_subs;
3454
3455         # Need to make these sane here.
3456         local $\ = '';
3457         local $, = '';
3458
3459         # Search through the debugger's magical hash of subs.
3460         # If $nocheck is true, just print the sub name.
3461         # Otherwise, check it against the pattern. We then use
3462         # the XOR trick to reverse the condition as required.
3463         foreach $subname ( sort( keys %sub ) ) {
3464             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3465                 print $OUT $subname, "\n";
3466             }
3467         }
3468         next CMD;
3469     }
3470
3471     return;
3472 }
3473
3474 sub _handle_V_command_and_X_command {
3475     my $self = shift;
3476
3477     $DB::cmd =~ s/^X\b/V $DB::package/;
3478
3479     # Bare V commands get the currently-being-debugged package
3480     # added.
3481     if ($self->_is_full('V')) {
3482         $DB::cmd = "V $DB::package";
3483     }
3484
3485     # V - show variables in package.
3486     if (my ($new_packname, $new_vars_str) =
3487         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3488
3489         # Save the currently selected filehandle and
3490         # force output to debugger's filehandle (dumpvar
3491         # just does "print" for output).
3492         my $savout = select($OUT);
3493
3494         # Grab package name and variables to dump.
3495         $packname = $new_packname;
3496         my @vars     = split( ' ', $new_vars_str );
3497
3498         # If main::dumpvar isn't here, get it.
3499         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3500         if ( defined &main::dumpvar ) {
3501
3502             # We got it. Turn off subroutine entry/exit messages
3503             # for the moment, along with return values.
3504             local $frame = 0;
3505             local $doret = -2;
3506
3507             # must detect sigpipe failures  - not catching
3508             # then will cause the debugger to die.
3509             eval {
3510                 main::dumpvar(
3511                     $packname,
3512                     defined $option{dumpDepth}
3513                     ? $option{dumpDepth}
3514                     : -1,    # assume -1 unless specified
3515                     @vars
3516                 );
3517             };
3518
3519             # The die doesn't need to include the $@, because
3520             # it will automatically get propagated for us.
3521             if ($@) {
3522                 die unless $@ =~ /dumpvar print failed/;
3523             }
3524         } ## end if (defined &main::dumpvar)
3525         else {
3526
3527             # Couldn't load dumpvar.
3528             print $OUT "dumpvar.pl not available.\n";
3529         }
3530
3531         # Restore the output filehandle, and go round again.
3532         select($savout);
3533         next CMD;
3534     }
3535
3536     return;
3537 }
3538
3539 sub _handle_dash_command {
3540     my $self = shift;
3541
3542     if ($self->_is_full('-')) {
3543
3544         # back up by a window; go to 1 if back too far.
3545         $start -= $incr + $window + 1;
3546         $start = 1 if $start <= 0;
3547         $incr  = $window - 1;
3548
3549         # Generate and execute a "l +" command (handled below).
3550         $DB::cmd = 'l ' . ($start) . '+';
3551         redo CMD;
3552     }
3553     return;
3554 }
3555
3556 sub _n_or_s_commands_generic {
3557     my ($self, $new_val) = @_;
3558     # n - next
3559     next CMD if DB::_DB__is_finished();
3560
3561     # Single step, but don't enter subs.
3562     $single = $new_val;
3563
3564     # Save for empty command (repeat last).
3565     $laststep = $DB::cmd;
3566     last CMD;
3567 }
3568
3569 sub _n_or_s {
3570     my ($self, $letter, $new_val) = @_;
3571
3572     if ($self->_is_full($letter)) {
3573         $self->_n_or_s_commands_generic($new_val);
3574     }
3575     else {
3576         $self->_n_or_s_and_arg_commands_generic($letter, $new_val);
3577     }
3578
3579     return;
3580 }
3581
3582 sub _handle_n_command {
3583     my $self = shift;
3584
3585     return $self->_n_or_s('n', 2);
3586 }
3587
3588 sub _handle_s_command {
3589     my $self = shift;
3590
3591     return $self->_n_or_s('s', 1);
3592 }
3593
3594 sub _handle_r_command {
3595     my $self = shift;
3596
3597     # r - return from the current subroutine.
3598     if ($self->_is_full('r')) {
3599
3600         # Can't do anything if the program's over.
3601         next CMD if DB::_DB__is_finished();
3602
3603         # Turn on stack trace.
3604         $stack[$stack_depth] |= 1;
3605
3606         # Print return value unless the stack is empty.
3607         $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
3608         last CMD;
3609     }
3610
3611     return;
3612 }
3613
3614 sub _handle_T_command {
3615     my $self = shift;
3616
3617     if ($self->_is_full('T')) {
3618         DB::print_trace( $OUT, 1 );    # skip DB
3619         next CMD;
3620     }
3621
3622     return;
3623 }
3624
3625 sub _handle_w_command {
3626     my $self = shift;
3627
3628     DB::cmd_w( 'w', $self->cmd_args() );
3629     next CMD;
3630
3631     return;
3632 }
3633
3634 sub _handle_W_command {
3635     my $self = shift;
3636
3637     if (my $arg = $self->cmd_args) {
3638         DB::cmd_W( 'W', $arg );
3639         next CMD;
3640     }
3641
3642     return;
3643 }
3644
3645 sub _handle_rc_recall_command {
3646     my $self = shift;
3647
3648     # $rc - recall command.
3649     if (my ($minus, $arg) = $DB::cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
3650
3651         # No arguments, take one thing off history.
3652         pop(@hist) if length($DB::cmd) > 1;
3653
3654         # Relative (- found)?
3655         #  Y - index back from most recent (by 1 if bare minus)
3656         #  N - go to that particular command slot or the last
3657         #      thing if nothing following.
3658
3659         $self->cmd_verb(
3660             scalar($minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist ))
3661         );
3662
3663         # Pick out the command desired.
3664         $DB::cmd = $hist[$self->cmd_verb];
3665
3666         # Print the command to be executed and restart the loop
3667         # with that command in the buffer.
3668         print {$OUT} $DB::cmd, "\n";
3669         redo CMD;
3670     }
3671
3672     return;
3673 }
3674
3675 sub _handle_rc_search_history_command {
3676     my $self = shift;
3677
3678     # $rc pattern $rc - find a command in the history.
3679     if (my ($arg) = $DB::cmd =~ /\A$rc([^$rc].*)\z/) {
3680
3681         # Create the pattern to use.
3682         my $pat = "^$arg";
3683         $self->pat($pat);
3684
3685         # Toss off last entry if length is >1 (and it always is).
3686         pop(@hist) if length($DB::cmd) > 1;
3687
3688         my $i;
3689
3690         # Look backward through the history.
3691         SEARCH_HIST:
3692         for ( $i = $#hist ; $i ; --$i ) {
3693             # Stop if we find it.
3694             last SEARCH_HIST if $hist[$i] =~ /$pat/;
3695         }
3696
3697         if ( !$i ) {
3698
3699             # Never found it.
3700             print $OUT "No such command!\n\n";
3701             next CMD;
3702         }
3703
3704         # Found it. Put it in the buffer, print it, and process it.
3705         $DB::cmd = $hist[$i];
3706         print $OUT $DB::cmd, "\n";
3707         redo CMD;
3708     }
3709
3710     return;
3711 }
3712
3713 sub _handle_H_command {
3714     my $self = shift;
3715
3716     if ($self->cmd_args =~ m#\A\*#) {
3717         @hist = @truehist = ();
3718         print $OUT "History cleansed\n";
3719         next CMD;
3720     }
3721
3722     if (my ($num) = $self->cmd_args =~ /\A(?:-(\d+))?/) {
3723
3724         # Anything other than negative numbers is ignored by
3725         # the (incorrect) pattern, so this test does nothing.
3726         $end = $num ? ( $#hist - $num ) : 0;
3727
3728         # Set to the minimum if less than zero.
3729         $hist = 0 if $hist < 0;
3730
3731         # Start at the end of the array.
3732         # Stay in while we're still above the ending value.
3733         # Tick back by one each time around the loop.
3734         my $i;
3735
3736         for ( $i = $#hist ; $i > $end ; $i-- ) {
3737
3738             # Print the command  unless it has no arguments.
3739             print $OUT "$i: ", $hist[$i], "\n"
3740             unless $hist[$i] =~ /^.?$/;
3741         }
3742
3743         next CMD;
3744     }
3745
3746     return;
3747 }
3748
3749 sub _handle_doc_command {
3750     my $self = shift;
3751
3752     # man, perldoc, doc - show manual pages.
3753     if (my ($man_page)
3754         = $DB::cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3755         DB::runman($man_page);
3756         next CMD;
3757     }
3758
3759     return;
3760 }
3761
3762 sub _handle_p_command {
3763     my $self = shift;
3764
3765     my $print_cmd = 'print {$DB::OUT} ';
3766     # p - print (no args): print $_.
3767     if ($self->_is_full('p')) {
3768         $DB::cmd = $print_cmd . '$_';
3769     }
3770     else {
3771         # p - print the given expression.
3772         $DB::cmd =~ s/\Ap\b/$print_cmd /;
3773     }
3774
3775     return;
3776 }
3777
3778 sub _handle_equal_sign_command {
3779     my $self = shift;
3780
3781     if ($DB::cmd =~ s/\A=\s*//) {
3782         my @keys;
3783         if ( length $DB::cmd == 0 ) {
3784
3785             # No args, get current aliases.
3786             @keys = sort keys %alias;
3787         }
3788         elsif ( my ( $k, $v ) = ( $DB::cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3789
3790             # Creating a new alias. $k is alias name, $v is
3791             # alias value.
3792
3793             # can't use $_ or kill //g state
3794             for my $x ( $k, $v ) {
3795
3796                 # Escape "alarm" characters.
3797                 $x =~ s/\a/\\a/g;
3798             }
3799
3800             # Substitute key for value, using alarm chars
3801             # as separators (which is why we escaped them in
3802             # the command).
3803             $alias{$k} = "s\a$k\a$v\a";
3804
3805             # Turn off standard warn and die behavior.
3806             local $SIG{__DIE__};
3807             local $SIG{__WARN__};
3808
3809             # Is it valid Perl?
3810             unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3811
3812                 # Nope. Bad alias. Say so and get out.
3813                 print $OUT "Can't alias $k to $v: $@\n";
3814                 delete $alias{$k};
3815                 next CMD;
3816             }
3817
3818             # We'll only list the new one.
3819             @keys = ($k);
3820         } ## end elsif (my ($k, $v) = ($DB::cmd...
3821
3822         # The argument is the alias to list.
3823         else {
3824             @keys = ($DB::cmd);
3825         }
3826
3827         # List aliases.
3828         for my $k (@keys) {
3829
3830             # Messy metaquoting: Trim the substitution code off.
3831             # We use control-G as the delimiter because it's not
3832             # likely to appear in the alias.
3833             if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3834
3835                 # Print the alias.
3836                 print $OUT "$k\t= $1\n";
3837             }
3838             elsif ( defined $alias{$k} ) {
3839
3840                 # Couldn't trim it off; just print the alias code.
3841                 print $OUT "$k\t$alias{$k}\n";
3842             }
3843             else {
3844
3845                 # No such, dude.
3846                 print "No alias for $k\n";
3847             }
3848         } ## end for my $k (@keys)
3849         next CMD;
3850     }
3851
3852     return;
3853 }
3854
3855 sub _handle_source_command {
3856     my $self = shift;
3857
3858     # source - read commands from a file (or pipe!) and execute.
3859     if (my $sourced_fn = $self->cmd_args) {
3860         if ( open my $fh, $sourced_fn ) {
3861
3862             # Opened OK; stick it in the list of file handles.
3863             push @cmdfhs, $fh;
3864         }
3865         else {
3866
3867             # Couldn't open it.
3868             DB::_db_warn("Can't execute '$sourced_fn': $!\n");
3869         }
3870         next CMD;
3871     }
3872
3873     return;
3874 }
3875
3876 sub _handle_enable_disable_commands {
3877     my $self = shift;
3878
3879     my $which_cmd = $self->cmd_verb;
3880     my $position = $self->cmd_args;
3881
3882     if ($position !~ /\s/) {
3883         my ($fn, $line_num);
3884         if ($position =~ m{\A\d+\z})
3885         {
3886             $fn = $DB::filename;
3887             $line_num = $position;
3888         }
3889         elsif (my ($new_fn, $new_line_num)
3890             = $position =~ m{\A(.*):(\d+)\z}) {
3891             ($fn, $line_num) = ($new_fn, $new_line_num);
3892         }
3893         else
3894         {
3895             DB::_db_warn("Wrong spec for enable/disable argument.\n");
3896         }
3897
3898         if (defined($fn)) {
3899             if (DB::_has_breakpoint_data_ref($fn, $line_num)) {
3900                 DB::_set_breakpoint_enabled_status($fn, $line_num,
3901                     ($which_cmd eq 'enable' ? 1 : '')
3902                 );
3903             }
3904             else {
3905                 DB::_db_warn("No breakpoint set at ${fn}:${line_num}\n");
3906             }
3907         }
3908
3909         next CMD;
3910     }
3911
3912     return;
3913 }
3914
3915 sub _handle_save_command {
3916     my $self = shift;
3917
3918     if (my $new_fn = $self->cmd_args) {
3919         my $filename = $new_fn || '.perl5dbrc';    # default?
3920         if ( open my $fh, '>', $filename ) {
3921
3922             # chomp to remove extraneous newlines from source'd files
3923             chomp( my @truelist =
3924                 map { m/\A\s*(save|source)/ ? "#$_" : $_ }
3925                 @truehist );
3926             print {$fh} join( "\n", @truelist );
3927             print "commands saved in $filename\n";
3928         }
3929         else {
3930             DB::_db_warn("Can't save debugger commands in '$new_fn': $!\n");
3931         }
3932         next CMD;
3933     }
3934
3935     return;
3936 }
3937
3938 sub _n_or_s_and_arg_commands_generic {
3939     my ($self, $letter, $new_val) = @_;
3940
3941     # s - single-step. Remember the last command was 's'.
3942     if ($DB::cmd =~ s#\A\Q$letter\E\s#\$DB::single = $new_val;\n#) {
3943         $laststep = $letter;
3944     }
3945
3946     return;
3947 }
3948
3949 sub _handle_sh_command {
3950     my $self = shift;
3951
3952     # $sh$sh - run a shell command (if it's all ASCII).
3953     # Can't run shell commands with Unicode in the debugger, hmm.
3954     my $my_cmd = $DB::cmd;
3955     if ($my_cmd =~ m#\A$sh#gms) {
3956
3957         if ($my_cmd =~ m#\G\z#cgms) {
3958             # Run the user's shell. If none defined, run Bourne.
3959             # We resume execution when the shell terminates.
3960             DB::_db_system( $ENV{SHELL} || "/bin/sh" );
3961             next CMD;
3962         }
3963         elsif ($my_cmd =~ m#\G$sh\s*(.*)#cgms) {
3964             # System it.
3965             DB::_db_system($1);
3966             next CMD;
3967         }
3968         elsif ($my_cmd =~ m#\G\s*(.*)#cgms) {
3969             DB::_db_system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3970             next CMD;
3971         }
3972     }
3973 }
3974
3975 sub _handle_x_command {
3976     my $self = shift;
3977
3978     if ($DB::cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
3979         $onetimeDump = 'dump';    # main::dumpvar shows the output
3980
3981         # handle special  "x 3 blah" syntax XXX propagate
3982         # doc back to special variables.
3983         if ( $DB::cmd =~ s#\A\s*(\d+)(?=\s)# #) {
3984             $onetimedumpDepth = $1;
3985         }
3986     }
3987
3988     return;
3989 }
3990
3991 sub _handle_q_command {
3992     my $self = shift;
3993
3994     if ($self->_is_full('q')) {
3995         $fall_off_end = 1;
3996         DB::clean_ENV();
3997         exit $?;
3998     }
3999
4000     return;
4001 }
4002
4003 sub _handle_cmd_wrapper_commands {
4004     my $self = shift;
4005
4006     DB::cmd_wrapper( $self->cmd_verb, $self->cmd_args, $line );
4007     next CMD;
4008 }
4009
4010 sub _handle_special_char_cmd_wrapper_commands {
4011     my $self = shift;
4012
4013     # All of these commands were remapped in perl 5.8.0;
4014     # we send them off to the secondary dispatcher (see below).
4015     if (my ($cmd_letter, $my_arg) = $DB::cmd =~ /\A([<>\{]{1,2})\s*(.*)/so) {
4016         DB::cmd_wrapper( $cmd_letter, $my_arg, $line );
4017         next CMD;
4018     }
4019
4020     return;
4021 }
4022
4023 } ## end DB::Obj
4024
4025 package DB;
4026
4027 # The following code may be executed now:
4028 # BEGIN {warn 4}
4029
4030 =head2 sub
4031
4032 C<sub> is called whenever a subroutine call happens in the program being
4033 debugged. The variable C<$DB::sub> contains the name of the subroutine
4034 being called.
4035
4036 The core function of this subroutine is to actually call the sub in the proper
4037 context, capturing its output. This of course causes C<DB::DB> to get called
4038 again, repeating until the subroutine ends and returns control to C<DB::sub>
4039 again. Once control returns, C<DB::sub> figures out whether or not to dump the
4040 return value, and returns its captured copy of the return value as its own
4041 return value. The value then feeds back into the program being debugged as if
4042 C<DB::sub> hadn't been there at all.
4043
4044 C<sub> does all the work of printing the subroutine entry and exit messages
4045 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
4046 and also prints the return value if needed (for the C<r> command and if
4047 the 16 bit is set in C<$frame>).
4048
4049 It also tracks the subroutine call depth by saving the current setting of
4050 C<$single> in the C<@stack> package global; if this exceeds the value in
4051 C<$deep>, C<sub> automatically turns on printing of the current depth by
4052 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
4053 of stop/don't stop on entry to subs set as it currently is set.
4054
4055 =head3 C<caller()> support
4056
4057 If C<caller()> is called from the package C<DB>, it provides some
4058 additional data, in the following order:
4059
4060 =over 4
4061
4062 =item * C<$package>
4063
4064 The package name the sub was in
4065
4066 =item * C<$filename>
4067
4068 The filename it was defined in
4069
4070 =item * C<$line>
4071
4072 The line number it was defined on
4073
4074 =item * C<$subroutine>
4075
4076 The subroutine name; C<(eval)> if an C<eval>().
4077
4078 =item * C<$hasargs>
4079
4080 1 if it has arguments, 0 if not
4081
4082 =item * C<$wantarray>
4083
4084 1 if array context, 0 if scalar context
4085
4086 =item * C<$evaltext>
4087
4088 The C<eval>() text, if any (undefined for C<eval BLOCK>)
4089
4090 =item * C<$is_require>
4091
4092 frame was created by a C<use> or C<require> statement
4093
4094 =item * C<$hints>
4095
4096 pragma information; subject to change between versions
4097
4098 =item * C<$bitmask>
4099
4100 pragma information; subject to change between versions
4101
4102 =item * C<@DB::args>
4103
4104 arguments with which the subroutine was invoked
4105
4106 =back
4107
4108 =cut
4109
4110 use vars qw($deep);
4111
4112 # We need to fully qualify the name ("DB::sub") to make "use strict;"
4113 # happy. -- Shlomi Fish
4114
4115 sub _indent_print_line_info {
4116     my ($offset, $str) = @_;
4117
4118     print_lineinfo( ' ' x ($stack_depth - $offset), $str);
4119
4120     return;
4121 }
4122
4123 sub _print_frame_message {
4124     my ($al) = @_;
4125
4126     if ($frame) {
4127         if ($frame & 4) {   # Extended frame entry message
4128             _indent_print_line_info(-1, "in  ");
4129
4130             # Why -1? But it works! :-(
4131             # Because print_trace will call add 1 to it and then call
4132             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4133             # in dump_trace.
4134             #
4135             # Now it's 0 because we extracted a function.
4136             print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4137         }
4138         else {
4139             _indent_print_line_info(-1, "entering $sub$al\n" );
4140         }
4141     }
4142
4143     return;
4144 }
4145
4146 sub DB::sub {
4147     # lock ourselves under threads
4148     lock($DBGR);
4149
4150     # Whether or not the autoloader was running, a scalar to put the
4151     # sub's return value in (if needed), and an array to put the sub's
4152     # return value in (if needed).
4153     my ( $al, $ret, @ret ) = "";
4154     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
4155         print "creating new thread\n";
4156     }
4157
4158     # If the last ten characters are '::AUTOLOAD', note we've traced
4159     # into AUTOLOAD for $sub.
4160     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4161         no strict 'refs';
4162         $al = " for $$sub" if defined $$sub;
4163     }
4164
4165     # We stack the stack pointer and then increment it to protect us
4166     # from a situation that might unwind a whole bunch of call frames
4167     # at once. Localizing the stack pointer means that it will automatically
4168     # unwind the same amount when multiple stack frames are unwound.
4169     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4170
4171     # Expand @stack.
4172     $#stack = $stack_depth;
4173
4174     # Save current single-step setting.
4175     $stack[-1] = $single;
4176
4177     # Turn off all flags except single-stepping.
4178     $single &= 1;
4179
4180     # If we've gotten really deeply recursed, turn on the flag that will
4181     # make us stop with the 'deep recursion' message.
4182     $single |= 4 if $stack_depth == $deep;
4183
4184     # If frame messages are on ...
4185
4186     _print_frame_message($al);
4187     # standard frame entry message
4188
4189     my $print_exit_msg = sub {
4190         # Check for exit trace messages...
4191         if ($frame & 2)
4192         {
4193             if ($frame & 4)    # Extended exit message
4194             {
4195                 _indent_print_line_info(0, "out ");
4196                 print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4197             }
4198             else
4199             {
4200                 _indent_print_line_info(0, "exited $sub$al\n" );
4201             }
4202         }
4203         return;
4204     };
4205
4206     # Determine the sub's return type, and capture appropriately.
4207     if (wantarray) {
4208
4209         # Called in array context. call sub and capture output.
4210         # DB::DB will recursively get control again if appropriate; we'll come
4211         # back here when the sub is finished.
4212         {
4213             no strict 'refs';
4214             @ret = &$sub;
4215         }
4216
4217         # Pop the single-step value back off the stack.
4218         $single |= $stack[ $stack_depth-- ];
4219
4220         $print_exit_msg->();
4221
4222         # Print the return info if we need to.
4223         if ( $doret eq $stack_depth or $frame & 16 ) {
4224
4225             # Turn off output record separator.
4226             local $\ = '';
4227             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4228
4229             # Indent if we're printing because of $frame tracing.
4230             if ($frame & 16)
4231             {
4232                 print {$fh} ' ' x $stack_depth;
4233             }
4234
4235             # Print the return value.
4236             print {$fh} "list context return from $sub:\n";
4237             dumpit( $fh, \@ret );
4238
4239             # And don't print it again.
4240             $doret = -2;
4241         } ## end if ($doret eq $stack_depth...
4242             # And we have to return the return value now.
4243         @ret;
4244     } ## end if (wantarray)
4245
4246     # Scalar context.
4247     else {
4248         if ( defined wantarray ) {
4249             no strict 'refs';
4250             # Save the value if it's wanted at all.
4251             $ret = &$sub;
4252         }
4253         else {
4254             no strict 'refs';
4255             # Void return, explicitly.
4256             &$sub;
4257             undef $ret;
4258         }
4259
4260         # Pop the single-step value off the stack.
4261         $single |= $stack[ $stack_depth-- ];
4262
4263         # If we're doing exit messages...
4264         $print_exit_msg->();
4265
4266         # If we are supposed to show the return value... same as before.
4267         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
4268             local $\ = '';
4269             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4270             print $fh ( ' ' x $stack_depth ) if $frame & 16;
4271             print $fh (
4272                 defined wantarray
4273                 ? "scalar context return from $sub: "
4274                 : "void context return from $sub\n"
4275             );
4276             dumpit( $fh, $ret ) if defined wantarray;
4277             $doret = -2;
4278         } ## end if ($doret eq $stack_depth...
4279
4280         # Return the appropriate scalar value.
4281         $ret;
4282     } ## end else [ if (wantarray)
4283 } ## end sub _sub
4284
4285 sub lsub : lvalue {
4286
4287     no strict 'refs';
4288
4289     # lock ourselves under threads
4290     lock($DBGR);
4291
4292     # Whether or not the autoloader was running, a scalar to put the
4293     # sub's return value in (if needed), and an array to put the sub's
4294     # return value in (if needed).
4295     my ( $al, $ret, @ret ) = "";
4296     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
4297         print "creating new thread\n";
4298     }
4299
4300     # If the last ten characters are C'::AUTOLOAD', note we've traced
4301     # into AUTOLOAD for $sub.
4302     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4303         $al = " for $$sub";
4304     }
4305
4306     # We stack the stack pointer and then increment it to protect us
4307     # from a situation that might unwind a whole bunch of call frames
4308     # at once. Localizing the stack pointer means that it will automatically
4309     # unwind the same amount when multiple stack frames are unwound.
4310     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4311
4312     # Expand @stack.
4313     $#stack = $stack_depth;
4314
4315     # Save current single-step setting.
4316     $stack[-1] = $single;
4317
4318     # Turn off all flags except single-stepping.
4319     # Use local so the single-step value is popped back off the
4320     # stack for us.
4321     local $single = $single & 1;
4322
4323     # If we've gotten really deeply recursed, turn on the flag that will
4324     # make us stop with the 'deep recursion' message.
4325     $single |= 4 if $stack_depth == $deep;
4326
4327     # If frame messages are on ...
4328     _print_frame_message($al);
4329
4330     # call the original lvalue sub.
4331     &$sub;
4332 }
4333
4334 # Abstracting common code from multiple places elsewhere:
4335 sub depth_print_lineinfo {
4336     my $always_print = shift;
4337
4338     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4339 }
4340
4341 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4342
4343 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4344 Most of the changes were to systematize the command structure and to eliminate
4345 commands that threw away user input without checking.
4346
4347 The following sections describe the code added to make it easy to support
4348 multiple command sets with conflicting command names. This section is a start
4349 at unifying all command processing to make it simpler to develop commands.
4350
4351 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4352 number, and C<$dbline> (the current line) as arguments.
4353
4354 Support functions in this section which have multiple modes of failure C<die>
4355 on error; the rest simply return a false value.
4356
4357 The user-interface functions (all of the C<cmd_*> functions) just output
4358 error messages.
4359
4360 =head2 C<%set>
4361
4362 The C<%set> hash defines the mapping from command letter to subroutine
4363 name suffix.
4364
4365 C<%set> is a two-level hash, indexed by set name and then by command name.
4366 Note that trying to set the CommandSet to C<foobar> simply results in the
4367 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4368
4369 =cut
4370
4371 ### The API section
4372
4373 my %set = (    #
4374     'pre580' => {
4375         'a' => 'pre580_a',
4376         'A' => 'pre580_null',
4377         'b' => 'pre580_b',
4378         'B' => 'pre580_null',
4379         'd' => 'pre580_null',
4380         'D' => 'pre580_D',
4381         'h' => 'pre580_h',
4382         'M' => 'pre580_null',
4383         'O' => 'o',
4384         'o' => 'pre580_null',
4385         'v' => 'M',
4386         'w' => 'v',
4387         'W' => 'pre580_W',
4388     },
4389     'pre590' => {
4390         '<'  => 'pre590_prepost',
4391         '<<' => 'pre590_prepost',
4392         '>'  => 'pre590_prepost',
4393         '>>' => 'pre590_prepost',
4394         '{'  => 'pre590_prepost',
4395         '{{' => 'pre590_prepost',
4396     },
4397 );
4398
4399 my %breakpoints_data;
4400
4401 sub _has_breakpoint_data_ref {
4402     my ($filename, $line) = @_;
4403
4404     return (
4405         exists( $breakpoints_data{$filename} )
4406             and
4407         exists( $breakpoints_data{$filename}{$line} )
4408     );
4409 }
4410
4411 sub _get_breakpoint_data_ref {
4412     my ($filename, $line) = @_;
4413
4414     return ($breakpoints_data{$filename}{$line} ||= +{});
4415 }
4416
4417 sub _delete_breakpoint_data_ref {
4418     my ($filename, $line) = @_;
4419
4420     delete($breakpoints_data{$filename}{$line});
4421     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4422         delete($breakpoints_data{$filename});
4423     }
4424
4425     return;
4426 }
4427
4428 sub _set_breakpoint_enabled_status {
4429     my ($filename, $line, $status) = @_;
4430
4431     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4432         ($status ? 1 : '')
4433         ;
4434
4435     return;
4436 }
4437
4438 sub _enable_breakpoint_temp_enabled_status {
4439     my ($filename, $line) = @_;
4440
4441     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4442
4443     return;
4444 }
4445
4446 sub _cancel_breakpoint_temp_enabled_status {
4447     my ($filename, $line) = @_;
4448
4449     my $ref = _get_breakpoint_data_ref($filename, $line);
4450
4451     delete ($ref->{'temp_enabled'});
4452
4453     if (! %$ref) {
4454         _delete_breakpoint_data_ref($filename, $line);
4455     }
4456
4457     return;
4458 }
4459
4460 sub _is_breakpoint_enabled {
4461     my ($filename, $line) = @_;
4462
4463     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4464     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4465 }
4466
4467 =head2 C<cmd_wrapper()> (API)
4468
4469 C<cmd_wrapper()> allows the debugger to switch command sets
4470 depending on the value of the C<CommandSet> option.
4471
4472 It tries to look up the command in the C<%set> package-level I<lexical>
4473 (which means external entities can't fiddle with it) and create the name of
4474 the sub to call based on the value found in the hash (if it's there). I<All>
4475 of the commands to be handled in a set have to be added to C<%set>; if they
4476 aren't found, the 5.8.0 equivalent is called (if there is one).
4477
4478 This code uses symbolic references.
4479
4480 =cut
4481
4482 sub cmd_wrapper {
4483     my $cmd      = shift;
4484     my $line     = shift;
4485     my $dblineno = shift;
4486
4487     # Assemble the command subroutine's name by looking up the
4488     # command set and command name in %set. If we can't find it,
4489     # default to the older version of the command.
4490     my $call = 'cmd_'
4491       . ( $set{$CommandSet}{$cmd}
4492           || ( $cmd =~ /\A[<>{]+/o ? 'prepost' : $cmd ) );
4493
4494     # Call the command subroutine, call it by name.
4495     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4496 } ## end sub cmd_wrapper
4497
4498 =head3 C<cmd_a> (command)
4499
4500 The C<a> command handles pre-execution actions. These are associated with a
4501 particular line, so they're stored in C<%dbline>. We default to the current
4502 line if none is specified.
4503
4504 =cut
4505
4506 sub cmd_a {
4507     my $cmd    = shift;
4508     my $line   = shift || '';    # [.|line] expr
4509     my $dbline = shift;
4510
4511     # If it's dot (here), or not all digits,  use the current line.
4512     $line =~ s/\A\./$dbline/;
4513
4514     # Should be a line number followed by an expression.
4515     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4516
4517         if (! length($lineno)) {
4518             $lineno = $dbline;
4519         }
4520
4521         # If we have an expression ...
4522         if ( length $expr ) {
4523
4524             # ... but the line isn't breakable, complain.
4525             if ( $dbline[$lineno] == 0 ) {
4526                 print $OUT
4527                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4528             }
4529             else {
4530
4531                 # It's executable. Record that the line has an action.
4532                 $had_breakpoints{$filename} |= 2;
4533
4534                 # Remove any action, temp breakpoint, etc.
4535                 $dbline{$lineno} =~ s/\0[^\0]*//;
4536
4537                 # Add the action to the line.
4538                 $dbline{$lineno} .= "\0" . action($expr);
4539
4540                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4541             }
4542         } ## end if (length $expr)
4543     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4544     else {
4545
4546         # Syntax wrong.
4547         print $OUT
4548           "Adding an action requires an optional lineno and an expression\n"
4549           ;    # hint
4550     }
4551 } ## end sub cmd_a
4552
4553 =head3 C<cmd_A> (command)
4554
4555 Delete actions. Similar to above, except the delete code is in a separate
4556 subroutine, C<delete_action>.
4557
4558 =cut
4559
4560 sub cmd_A {
4561     my $cmd    = shift;
4562     my $line   = shift || '';
4563     my $dbline = shift;
4564
4565     # Dot is this line.
4566     $line =~ s/^\./$dbline/;
4567
4568     # Call delete_action with a null param to delete them all.
4569     # The '1' forces the eval to be true. It'll be false only
4570     # if delete_action blows up for some reason, in which case
4571     # we print $@ and get out.
4572     if ( $line eq '*' ) {
4573         if (! eval { _delete_all_actions(); 1 }) {
4574             print {$OUT} $@;
4575             return;
4576         }
4577     }
4578
4579     # There's a real line  number. Pass it to delete_action.
4580     # Error trapping is as above.
4581     elsif ( $line =~ /^(\S.*)/ ) {
4582         if (! eval { delete_action($1); 1 }) {
4583             print {$OUT} $@;
4584             return;
4585         }
4586     }
4587
4588     # Swing and a miss. Bad syntax.
4589     else {
4590         print $OUT
4591           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4592     }
4593 } ## end sub cmd_A
4594
4595 =head3 C<delete_action> (API)
4596
4597 C<delete_action> accepts either a line number or C<undef>. If a line number
4598 is specified, we check for the line being executable (if it's not, it
4599 couldn't have had an  action). If it is, we just take the action off (this
4600 will get any kind of an action, including breakpoints).
4601
4602 =cut
4603
4604 sub _remove_action_from_dbline {
4605     my $i = shift;
4606
4607     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4608     delete $dbline{$i} if $dbline{$i} eq '';
4609
4610     return;
4611 }
4612
4613 sub _delete_all_actions {
4614     print {$OUT} "Deleting all actions...\n";
4615
4616     for my $file ( keys %had_breakpoints ) {
4617         local *dbline = $main::{ '_<' . $file };
4618         $max = $#dbline;
4619         my $was;
4620         for my $i (1 .. $max) {
4621             if ( defined $dbline{$i} ) {
4622                 _remove_action_from_dbline($i);
4623             }
4624         }
4625
4626         unless ( $had_breakpoints{$file} &= ~2 ) {
4627             delete $had_breakpoints{$file};
4628         }
4629     }
4630
4631     return;
4632 }
4633
4634 sub delete_action {
4635     my $i = shift;
4636
4637     if ( defined($i) ) {
4638         # Can there be one?
4639         die "Line $i has no action .\n" if $dbline[$i] == 0;
4640
4641         # Nuke whatever's there.
4642         _remove_action_from_dbline($i);
4643     }
4644     else {
4645         _delete_all_actions();
4646     }
4647 }
4648
4649 =head3 C<cmd_b> (command)
4650
4651 Set breakpoints. Since breakpoints can be set in so many places, in so many
4652 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4653 we try to parse the command type, and then shuttle it off to an appropriate
4654 subroutine to actually do the work of setting the breakpoint in the right
4655 place.
4656
4657 =cut
4658
4659 sub cmd_b {
4660     my $cmd    = shift;
4661     my $line   = shift;    # [.|line] [cond]
4662     my $dbline = shift;
4663
4664     my $default_cond = sub {
4665         my $cond = shift;
4666         return length($cond) ? $cond : '1';
4667     };
4668
4669     # Make . the current line number if it's there..
4670     $line =~ s/^\.(\s|\z)/$dbline$1/;
4671
4672     # No line number, no condition. Simple break on current line.
4673     if ( $line =~ /^\s*$/ ) {
4674         cmd_b_line( $dbline, 1 );
4675     }
4676
4677     # Break on load for a file.
4678     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4679         $file =~ s/\s+\z//;
4680         cmd_b_load($file);
4681     }
4682
4683     # b compile|postpone <some sub> [<condition>]
4684     # The interpreter actually traps this one for us; we just put the
4685     # necessary condition in the %postponed hash.
4686     elsif ( my ($action, $subname, $cond)
4687         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4688
4689         # De-Perl4-ify the name - ' separators to ::.
4690         $subname =~ s/'/::/g;
4691
4692         # Qualify it into the current package unless it's already qualified.
4693         $subname = "${package}::" . $subname unless $subname =~ /::/;
4694
4695         # Add main if it starts with ::.
4696         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4697
4698         # Save the break type for this sub.
4699         $postponed{$subname} = (($action eq 'postpone')
4700             ? ( "break +0 if " . $default_cond->($cond) )
4701             : "compile");
4702     } ## end elsif ($line =~ ...
4703     # b <filename>:<line> [<condition>]
4704     elsif (my ($filename, $line_num, $cond)
4705         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4706         cmd_b_filename_line(
4707             $filename,
4708             $line_num,
4709             (length($cond) ? $cond : '1'),
4710         );
4711     }
4712     # b <sub name> [<condition>]
4713     elsif ( my ($new_subname, $new_cond) =
4714         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4715
4716         #
4717         $subname = $new_subname;
4718         cmd_b_sub( $subname, $default_cond->($new_cond) );
4719     }
4720
4721     # b <line> [<condition>].
4722     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4723
4724         # Capture the line. If none, it's the current line.
4725         $line = $line_n || $dbline;
4726
4727         # Break on line.
4728         cmd_b_line( $line, $default_cond->($cond) );
4729     }
4730
4731     # Line didn't make sense.
4732     else {
4733         print "confused by line($line)?\n";
4734     }
4735
4736     return;
4737 } ## end sub cmd_b
4738
4739 =head3 C<break_on_load> (API)
4740
4741 We want to break when this file is loaded. Mark this file in the
4742 C<%break_on_load> hash, and note that it has a breakpoint in
4743 C<%had_breakpoints>.
4744
4745 =cut
4746
4747 sub break_on_load {
4748     my $file = shift;
4749     $break_on_load{$file} = 1;
4750     $had_breakpoints{$file} |= 1;
4751 }
4752
4753 =head3 C<report_break_on_load> (API)
4754
4755 Gives us an array of filenames that are set to break on load. Note that
4756 only files with break-on-load are in here, so simply showing the keys
4757 suffices.
4758
4759 =cut
4760
4761 sub report_break_on_load {
4762     sort keys %break_on_load;
4763 }
4764
4765 =head3 C<cmd_b_load> (command)
4766
4767 We take the file passed in and try to find it in C<%INC> (which maps modules
4768 to files they came from). We mark those files for break-on-load via
4769 C<break_on_load> and then report that it was done.
4770
4771 =cut
4772
4773 sub cmd_b_load {
4774     my $file = shift;
4775     my @files;
4776
4777     # This is a block because that way we can use a redo inside it
4778     # even without there being any looping structure at all outside it.
4779     {
4780
4781         # Save short name and full path if found.
4782         push @files, $file;
4783         push @files, $::INC{$file} if $::INC{$file};
4784
4785         # Tack on .pm and do it again unless there was a '.' in the name
4786         # already.
4787         $file .= '.pm', redo unless $file =~ /\./;
4788     }
4789
4790     # Do the real work here.
4791     break_on_load($_) for @files;
4792
4793     # All the files that have break-on-load breakpoints.
4794     @files = report_break_on_load;
4795
4796     # Normalize for the purposes of our printing this.
4797     local $\ = '';
4798     local $" = ' ';
4799     print $OUT "Will stop on load of '@files'.\n";
4800 } ## end sub cmd_b_load
4801
4802 =head3 C<$filename_error> (API package global)
4803
4804 Several of the functions we need to implement in the API need to work both
4805 on the current file and on other files. We don't want to duplicate code, so
4806 C<$filename_error> is used to contain the name of the file that's being
4807 worked on (if it's not the current one).
4808
4809 We can now build functions in pairs: the basic function works on the current
4810 file, and uses C<$filename_error> as part of its error message. Since this is
4811 initialized to C<"">, no filename will appear when we are working on the
4812 current file.
4813
4814 The second function is a wrapper which does the following:
4815
4816 =over 4
4817
4818 =item *
4819
4820 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4821
4822 =item *
4823
4824 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4825
4826 =item *
4827
4828 Calls the first function.
4829
4830 The first function works on the I<current> file (i.e., the one we changed to),
4831 and prints C<$filename_error> in the error message (the name of the other file)
4832 if it needs to. When the functions return, C<*dbline> is restored to point
4833 to the actual current file (the one we're executing in) and
4834 C<$filename_error> is restored to C<"">. This restores everything to
4835 the way it was before the second function was called at all.
4836
4837 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4838 details.
4839
4840 =back
4841
4842 =cut
4843
4844 use vars qw($filename_error);
4845 $filename_error = '';
4846
4847 =head3 breakable_line(from, to) (API)
4848
4849 The subroutine decides whether or not a line in the current file is breakable.
4850 It walks through C<@dbline> within the range of lines specified, looking for
4851 the first line that is breakable.
4852
4853 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4854 first line I<after> C<$to> that's breakable, if there is one.
4855
4856 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4857 first line I<before> C<$to> that's breakable, if there is one.
4858
4859 =cut
4860
4861 sub breakable_line {
4862
4863     my ( $from, $to ) = @_;
4864
4865     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4866     my $i = $from;
4867
4868     # If there are at least 2 arguments, we're trying to search a range.
4869     if ( @_ >= 2 ) {
4870
4871         # $delta is positive for a forward search, negative for a backward one.
4872         my $delta = $from < $to ? +1 : -1;
4873
4874         # Keep us from running off the ends of the file.
4875         my $limit = $delta > 0 ? $#dbline : 1;
4876
4877         # Clever test. If you're a mathematician, it's obvious why this
4878         # test works. If not:
4879         # If $delta is positive (going forward), $limit will be $#dbline.
4880         #    If $to is less than $limit, ($limit - $to) will be positive, times
4881         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4882         #    as the stopping point.
4883         #
4884         #    If $to is greater than $limit, ($limit - $to) is negative,
4885         #    times $delta of 1 (positive), so the result is < 0 and we should
4886         #    use $limit ($#dbline) as the stopping point.
4887         #
4888         # If $delta is negative (going backward), $limit will be 1.
4889         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4890         #    (negative) so the result is > 0, and we use $to as the stopping
4891         #    point.
4892         #
4893         #    If $to is less than zero, ($limit - $to) will be positive,
4894         #    times $delta of -1 (negative), so the result is not > 0, and
4895         #    we use $limit (1) as the stopping point.
4896         #
4897         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4898         #    (negative), still giving zero; the result is not > 0, and
4899         #    we use $limit (1) as the stopping point.
4900         #
4901         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4902         #    (negative), giving a positive (>0) value, so we'll set $limit to
4903         #    $to.
4904
4905         $limit = $to if ( $limit - $to ) * $delta > 0;
4906
4907         # The real search loop.
4908         # $i starts at $from (the point we want to start searching from).
4909         # We move through @dbline in the appropriate direction (determined
4910         # by $delta: either -1 (back) or +1 (ahead).
4911         # We stay in as long as we haven't hit an executable line
4912         # ($dbline[$i] == 0 means not executable) and we haven't reached
4913         # the limit yet (test similar to the above).
4914         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4915
4916     } ## end if (@_ >= 2)
4917
4918     # If $i points to a line that is executable, return that.
4919     return $i unless $dbline[$i] == 0;
4920
4921     # Format the message and print it: no breakable lines in range.
4922     my ( $pl, $upto ) = ( '', '' );
4923     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4924
4925     # If there's a filename in filename_error, we'll see it.
4926     # If not, not.
4927     die "Line$pl $from$upto$filename_error not breakable\n";
4928 } ## end sub breakable_line
4929
4930 =head3 breakable_line_in_filename(file, from, to) (API)
4931
4932 Like C<breakable_line>, but look in another file.
4933
4934 =cut
4935
4936 sub breakable_line_in_filename {
4937
4938     # Capture the file name.
4939     my ($f) = shift;
4940
4941     # Swap the magic line array over there temporarily.
4942     local *dbline = $main::{ '_<' . $f };
4943
4944     # If there's an error, it's in this other file.
4945     local $filename_error = " of '$f'";
4946
4947     # Find the breakable line.
4948     breakable_line(@_);
4949
4950     # *dbline and $filename_error get restored when this block ends.
4951
4952 } ## end sub breakable_line_in_filename
4953
4954 =head3 break_on_line(lineno, [condition]) (API)
4955
4956 Adds a breakpoint with the specified condition (or 1 if no condition was
4957 specified) to the specified line. Dies if it can't.
4958
4959 =cut
4960
4961 sub break_on_line {
4962     my $i = shift;
4963     my $cond = @_ ? shift(@_) : 1;
4964
4965     my $inii  = $i;
4966     my $after = '';
4967     my $pl    = '';
4968
4969     # Woops, not a breakable line. $filename_error allows us to say
4970     # if it was in a different file.
4971     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4972
4973     # Mark this file as having breakpoints in it.
4974     $had_breakpoints{$filename} |= 1;
4975
4976     # If there is an action or condition here already ...
4977     if ( $dbline{$i} ) {
4978
4979         # ... swap this condition for the existing one.
4980         $dbline{$i} =~ s/^[^\0]*/$cond/;
4981     }
4982     else {
4983
4984         # Nothing here - just add the condition.
4985         $dbline{$i} = $cond;
4986
4987         _set_breakpoint_enabled_status($filename, $i, 1);
4988     }
4989
4990     return;
4991 } ## end sub break_on_line
4992
4993 =head3 cmd_b_line(line, [condition]) (command)
4994
4995 Wrapper for C<break_on_line>. Prints the failure message if it
4996 doesn't work.
4997
4998 =cut
4999
5000 sub cmd_b_line {
5001     if (not eval { break_on_line(@_); 1 }) {
5002         local $\ = '';
5003         print $OUT $@ and return;
5004     }
5005
5006     return;
5007 } ## end sub cmd_b_line
5008
5009 =head3 cmd_b_filename_line(line, [condition]) (command)
5010
5011 Wrapper for C<break_on_filename_line>. Prints the failure message if it
5012 doesn't work.
5013
5014 =cut
5015
5016 sub cmd_b_filename_line {
5017     if (not eval { break_on_filename_line(@_); 1 }) {
5018         local $\ = '';
5019         print $OUT $@ and return;
5020     }
5021
5022     return;
5023 }
5024
5025 =head3 break_on_filename_line(file, line, [condition]) (API)
5026
5027 Switches to the file specified and then calls C<break_on_line> to set
5028 the breakpoint.
5029
5030 =cut
5031
5032 sub break_on_filename_line {
5033     my $f = shift;
5034     my $i = shift;
5035     my $cond = @_ ? shift(@_) : 1;
5036
5037     # Switch the magical hash temporarily.
5038     local *dbline = $main::{ '_<' . $f };
5039
5040     # Localize the variables that break_on_line uses to make its message.
5041     local $filename_error = " of '$f'";
5042     local $filename       = $f;
5043
5044     # Add the breakpoint.
5045     break_on_line( $i, $cond );
5046
5047     return;
5048 } ## end sub break_on_filename_line
5049
5050 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
5051
5052 Switch to another file, search the range of lines specified for an
5053 executable one, and put a breakpoint on the first one you find.
5054
5055 =cut
5056
5057 sub break_on_filename_line_range {
5058     my $f = shift;
5059     my $from = shift;
5060     my $to = shift;
5061     my $cond = @_ ? shift(@_) : 1;
5062
5063     # Find a breakable line if there is one.
5064     my $i = breakable_line_in_filename( $f, $from, $to );
5065
5066     # Add the breakpoint.
5067     break_on_filename_line( $f, $i, $cond );
5068
5069     return;
5070 } ## end sub break_on_filename_line_range
5071
5072 =head3 subroutine_filename_lines(subname, [condition]) (API)
5073
5074 Search for a subroutine within a given file. The condition is ignored.
5075 Uses C<find_sub> to locate the desired subroutine.
5076
5077 =cut
5078
5079 sub subroutine_filename_lines {
5080     my ( $subname ) = @_;
5081
5082     # Returned value from find_sub() is fullpathname:startline-endline.
5083     # The match creates the list (fullpathname, start, end).
5084     return (find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/);
5085 } ## end sub subroutine_filename_lines
5086
5087 =head3 break_subroutine(subname) (API)
5088
5089 Places a break on the first line possible in the specified subroutine. Uses
5090 C<subroutine_filename_lines> to find the subroutine, and
5091 C<break_on_filename_line_range> to place the break.
5092
5093 =cut
5094
5095 sub break_subroutine {
5096     my $subname = shift;
5097
5098     # Get filename, start, and end.
5099     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
5100       or die "Subroutine $subname not found.\n";
5101
5102
5103     # Null condition changes to '1' (always true).
5104     my $cond = @_ ? shift(@_) : 1;
5105
5106     # Put a break the first place possible in the range of lines
5107     # that make up this subroutine.
5108     break_on_filename_line_range( $file, $s, $e, $cond );
5109
5110     return;
5111 } ## end sub break_subroutine
5112
5113 =head3 cmd_b_sub(subname, [condition]) (command)
5114
5115 We take the incoming subroutine name and fully-qualify it as best we can.
5116
5117 =over 4
5118
5119 =item 1. If it's already fully-qualified, leave it alone.
5120
5121 =item 2. Try putting it in the current package.
5122
5123 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
5124
5125 =item 4. If it starts with '::', put it in 'main::'.
5126
5127 =back
5128
5129 After all this cleanup, we call C<break_subroutine> to try to set the
5130 breakpoint.
5131
5132 =cut
5133
5134 sub cmd_b_sub {
5135     my $subname = shift;
5136     my $cond = @_ ? shift : 1;
5137
5138     # If the subname isn't a code reference, qualify it so that
5139     # break_subroutine() will work right.
5140     if ( ref($subname) ne 'CODE' ) {
5141
5142         # Not Perl 4.
5143         $subname =~ s/'/::/g;
5144         my $s = $subname;
5145
5146         # Put it in this package unless it's already qualified.
5147         if ($subname !~ /::/)
5148         {
5149             $subname = $package . '::' . $subname;
5150         };
5151
5152         # Requalify it into CORE::GLOBAL if qualifying it into this
5153         # package resulted in its not being defined, but only do so
5154         # if it really is in CORE::GLOBAL.
5155         my $core_name = "CORE::GLOBAL::$s";
5156         if ((!defined(&$subname))
5157                 and ($s !~ /::/)
5158                 and (defined &{$core_name}))
5159         {
5160             $subname = $core_name;
5161         }
5162
5163         # Put it in package 'main' if it has a leading ::.
5164         if ($subname =~ /\A::/)
5165         {
5166             $subname = "main" . $subname;
5167         }
5168     } ## end if ( ref($subname) ne 'CODE' ) {
5169
5170     # Try to set the breakpoint.
5171     if (not eval { break_subroutine( $subname, $cond ); 1 }) {
5172         local $\ = '';
5173         print {$OUT} $@;
5174         return;
5175     }
5176
5177     return;
5178 } ## end sub cmd_b_sub
5179
5180 =head3 C<cmd_B> - delete breakpoint(s) (command)
5181
5182 The command mostly parses the command line and tries to turn the argument
5183 into a line spec. If it can't, it uses the current line. It then calls
5184 C<delete_breakpoint> to actually do the work.
5185
5186 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
5187 thereby deleting all the breakpoints.
5188
5189 =cut
5190
5191 sub cmd_B {
5192     my $cmd = shift;
5193
5194     # No line spec? Use dbline.
5195     # If there is one, use it if it's non-zero, or wipe it out if it is.
5196     my $line   = ( $_[0] =~ /\A\./ ) ? $dbline : (shift || '');
5197     my $dbline = shift;
5198
5199     # If the line was dot, make the line the current one.
5200     $line =~ s/^\./$dbline/;
5201
5202     # If it's * we're deleting all the breakpoints.
5203     if ( $line eq '*' ) {
5204         if (not eval { delete_breakpoint(); 1 }) {
5205             print {$OUT} $@;
5206         }
5207     }
5208
5209     # If there is a line spec, delete the breakpoint on that line.
5210     elsif ( $line =~ /\A(\S.*)/ ) {
5211         if (not eval { delete_breakpoint( $line || $dbline ); 1 }) {
5212             local $\ = '';
5213             print {$OUT} $@;
5214         }
5215     } ## end elsif ($line =~ /^(\S.*)/)
5216
5217     # No line spec.
5218     else {
5219         print {$OUT}
5220           "Deleting a breakpoint requires a line number, or '*' for all\n"
5221           ;    # hint
5222     }
5223
5224     return;
5225 } ## end sub cmd_B
5226
5227 =head3 delete_breakpoint([line]) (API)
5228
5229 This actually does the work of deleting either a single breakpoint, or all
5230 of them.
5231
5232 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
5233 just drop out with a message saying so. If it is, we remove the condition
5234 part of the 'condition\0action' that says there's a breakpoint here. If,
5235 after we've done that, there's nothing left, we delete the corresponding
5236 line in C<%dbline> to signal that no action needs to be taken for this line.
5237
5238 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
5239 which lists all currently-loaded files which have breakpoints. We then look
5240 at each line in each of these files, temporarily switching the C<%dbline>
5241 and C<@dbline> structures to point to the files in question, and do what
5242 we did in the single line case: delete the condition in C<@dbline>, and
5243 delete the key in C<%dbline> if nothing's left.
5244
5245 We then wholesale delete C<%postponed>, C<%postponed_file>, and
5246 C<%break_on_load>, because these structures contain breakpoints for files
5247 and code that haven't been loaded yet. We can just kill these off because there
5248 are no magical debugger structures associated with them.
5249
5250 =cut
5251
5252 sub _remove_breakpoint_entry {
5253     my ($fn, $i) = @_;
5254
5255     delete $dbline{$i};
5256     _delete_breakpoint_data_ref($fn, $i);
5257
5258     return;
5259 }
5260
5261 sub _delete_all_breakpoints {
5262     print {$OUT} "Deleting all breakpoints...\n";
5263
5264     # %had_breakpoints lists every file that had at least one
5265     # breakpoint in it.
5266     for my $fn ( keys %had_breakpoints ) {
5267
5268         # Switch to the desired file temporarily.
5269         local *dbline = $main::{ '_<' . $fn };
5270
5271         $max = $#dbline;
5272
5273         # For all lines in this file ...
5274         for my $i (1 .. $max) {
5275
5276             # If there's a breakpoint or action on this line ...
5277             if ( defined $dbline{$i} ) {
5278
5279                 # ... remove the breakpoint.
5280                 $dbline{$i} =~ s/\A[^\0]+//;
5281                 if ( $dbline{$i} =~ s/\A\0?\z// ) {
5282                     # Remove the entry altogether if no action is there.
5283                     _remove_breakpoint_entry($fn, $i);
5284                 }
5285             } ## end if (defined $dbline{$i...
5286         } ## end for $i (1 .. $max)
5287
5288         # If, after we turn off the "there were breakpoints in this file"
5289         # bit, the entry in %had_breakpoints for this file is zero,
5290         # we should remove this file from the hash.
5291         if ( not $had_breakpoints{$fn} &= (~1) ) {
5292             delete $had_breakpoints{$fn};
5293         }
5294     } ## end for my $fn (keys %had_breakpoints)
5295
5296     # Kill off all the other breakpoints that are waiting for files that
5297     # haven't been loaded yet.
5298     undef %postponed;
5299     undef %postponed_file;
5300     undef %break_on_load;
5301
5302     return;
5303 }
5304
5305 sub _delete_breakpoint_from_line {
5306     my ($i) = @_;
5307
5308     # Woops. This line wasn't breakable at all.
5309     die "Line $i not breakable.\n" if $dbline[$i] == 0;
5310
5311     # Kill the condition, but leave any action.
5312     $dbline{$i} =~ s/\A[^\0]*//;
5313
5314     # Remove the entry entirely if there's no action left.
5315     if ($dbline{$i} eq '') {
5316         _remove_breakpoint_entry($filename, $i);
5317     }
5318
5319     return;
5320 }
5321
5322 sub delete_breakpoint {
5323     my $i = shift;
5324
5325     # If we got a line, delete just that one.
5326     if ( defined($i) ) {
5327         _delete_breakpoint_from_line($i);
5328     }
5329     # No line; delete them all.
5330     else {
5331         _delete_all_breakpoints();
5332     }
5333
5334     return;
5335 }
5336
5337 =head3 cmd_stop (command)
5338
5339 This is meant to be part of the new command API, but it isn't called or used
5340 anywhere else in the debugger. XXX It is probably meant for use in development
5341 of new commands.
5342
5343 =cut
5344
5345 sub cmd_stop {    # As on ^C, but not signal-safy.
5346     $signal = 1;
5347 }
5348
5349 =head3 C<cmd_e> - threads
5350
5351 Display the current thread id:
5352
5353     e
5354
5355 This could be how (when implemented) to send commands to this thread id (e cmd)
5356 or that thread id (e tid cmd).
5357
5358 =cut
5359
5360 sub cmd_e {
5361     my $cmd  = shift;
5362     my $line = shift;
5363     unless (exists($INC{'threads.pm'})) {
5364         print "threads not loaded($ENV{PERL5DB_THREADED})
5365         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5366     } else {
5367         my $tid = threads->tid;
5368         print "thread id: $tid\n";
5369     }
5370 } ## end sub cmd_e
5371
5372 =head3 C<cmd_E> - list of thread ids
5373
5374 Display the list of available thread ids:
5375
5376     E
5377
5378 This could be used (when implemented) to send commands to all threads (E cmd).
5379
5380 =cut
5381
5382 sub cmd_E {
5383     my $cmd  = shift;
5384     my $line = shift;
5385     unless (exists($INC{'threads.pm'})) {
5386         print "threads not loaded($ENV{PERL5DB_THREADED})
5387         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5388     } else {
5389         my $tid = threads->tid;
5390         print "thread ids: ".join(', ',
5391             map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
5392         )."\n";
5393     }
5394 } ## end sub cmd_E
5395
5396 =head3 C<cmd_h> - help command (command)
5397
5398 Does the work of either
5399
5400 =over 4
5401
5402 =item *
5403
5404 Showing all the debugger help
5405
5406 =item *
5407
5408 Showing help for a specific command
5409
5410 =back
5411
5412 =cut
5413
5414 use vars qw($help);
5415 use vars qw($summary);
5416
5417 sub cmd_h {
5418     my $cmd = shift;
5419
5420     # If we have no operand, assume null.
5421     my $line = shift || '';
5422
5423     # 'h h'. Print the long-format help.
5424     if ( $line =~ /\Ah\s*\z/ ) {
5425         print_help($help);
5426     }
5427
5428     # 'h <something>'. Search for the command and print only its help.
5429     elsif ( my ($asked) = $line =~ /\A(\S.*)\z/ ) {
5430
5431         # support long commands; otherwise bogus errors
5432         # happen when you ask for h on <CR> for example
5433         my $qasked = quotemeta($asked);    # for searching; we don't
5434                                            # want to use it as a pattern.
5435                                            # XXX: finds CR but not <CR>
5436
5437         # Search the help string for the command.
5438         if (
5439             $help =~ /^                    # Start of a line
5440                       <?                   # Optional '<'
5441                       (?:[IB]<)            # Optional markup
5442                       $qasked              # The requested command
5443                      /mx
5444           )
5445         {
5446
5447             # It's there; pull it out and print it.
5448             while (
5449                 $help =~ /^
5450                               (<?            # Optional '<'
5451                                  (?:[IB]<)   # Optional markup
5452                                  $qasked     # The command
5453                                  ([\s\S]*?)  # Description line(s)
5454                               \n)            # End of last description line
5455                               (?!\s)         # Next line not starting with
5456                                              # whitespace
5457                              /mgx
5458               )
5459             {
5460                 print_help($1);
5461             }
5462         }
5463
5464         # Not found; not a debugger command.
5465         else {
5466             print_help("B<$asked> is not a debugger command.\n");
5467         }
5468     } ## end elsif ($line =~ /^(\S.*)$/)
5469
5470     # 'h' - print the summary help.
5471     else {
5472         print_help($summary);
5473     }
5474 } ## end sub cmd_h
5475
5476 =head3 C<cmd_i> - inheritance display
5477
5478 Display the (nested) parentage of the module or object given.
5479
5480 =cut
5481
5482 sub cmd_i {
5483     my $cmd  = shift;
5484     my $line = shift;
5485     foreach my $isa ( split( /\s+/, $line ) ) {
5486         $evalarg = $isa;
5487         # The &-call is here to ascertain the mutability of @_.
5488         ($isa) = &DB::eval;
5489         no strict 'refs';
5490         print join(
5491             ', ',
5492             map {
5493                 "$_"
5494                   . (
5495                     defined( ${"$_\::VERSION"} )
5496                     ? ' ' . ${"$_\::VERSION"}
5497                     : undef )
5498               } @{mro::get_linear_isa(ref($isa) || $isa)}
5499         );
5500         print "\n";
5501     }
5502 } ## end sub cmd_i
5503
5504 =head3 C<cmd_l> - list lines (command)
5505
5506 Most of the command is taken up with transforming all the different line
5507 specification syntaxes into 'start-stop'. After that is done, the command
5508 runs a loop over C<@dbline> for the specified range of lines. It handles
5509 the printing of each line and any markers (C<==E<gt>> for current line,
5510 C<b> for break on this line, C<a> for action on this line, C<:> for this
5511 line breakable).
5512
5513 We save the last line listed in the C<$start> global for further listing
5514 later.
5515
5516 =cut
5517
5518 sub _min {
5519     my $min = shift;
5520     foreach my $v (@_) {
5521         if ($min > $v) {
5522             $min = $v;
5523         }
5524     }
5525     return $min;
5526 }
5527
5528 sub _max {
5529     my $max = shift;
5530     foreach my $v (@_) {
5531         if ($max < $v) {
5532             $max = $v;
5533         }
5534     }
5535     return $max;
5536 }
5537
5538 sub _minify_to_max {
5539     my $ref = shift;
5540
5541     $$ref = _min($$ref, $max);
5542
5543     return;
5544 }
5545
5546 sub _cmd_l_handle_var_name {
5547     my $var_name = shift;
5548
5549     $evalarg = $var_name;
5550
5551     my ($s) = DB::eval();
5552
5553     # Ooops. Bad scalar.
5554     if ($@) {
5555         print {$OUT} "Error: $@\n";
5556         next CMD;
5557     }
5558
5559     # Good scalar. If it's a reference, find what it points to.
5560     $s = CvGV_name($s);
5561     print {$OUT} "Interpreted as: $1 $s\n";
5562     $line = "$1 $s";
5563
5564     # Call self recursively to really do the command.
5565     return _cmd_l_main( $s );
5566 }
5567
5568 sub _cmd_l_handle_subname {
5569
5570     my $s = $subname;
5571
5572     # De-Perl4.
5573     $subname =~ s/\'/::/;
5574
5575     # Put it in this package unless it starts with ::.
5576     $subname = $package . "::" . $subname unless $subname =~ /::/;
5577
5578     # Put it in CORE::GLOBAL if t doesn't start with :: and
5579     # it doesn't live in this package and it lives in CORE::GLOBAL.
5580     $subname = "CORE::GLOBAL::$s"
5581     if not defined &$subname
5582         and $s !~ /::/
5583         and defined &{"CORE::GLOBAL::$s"};
5584
5585     # Put leading '::' names into 'main::'.
5586     $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
5587
5588     # Get name:start-stop from find_sub, and break this up at
5589     # colons.
5590     my @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
5591
5592     # Pull off start-stop.
5593     my $subrange = pop @pieces;
5594
5595     # If the name contained colons, the split broke it up.
5596     # Put it back together.
5597     $file = join( ':', @pieces );
5598
5599     # If we're not in that file, switch over to it.
5600     if ( $file ne $filename ) {
5601         if (! $slave_editor) {
5602             print {$OUT} "Switching to file '$file'.\n";
5603         }
5604
5605         # Switch debugger's magic structures.
5606         *dbline   = $main::{ '_<' . $file };
5607         $max      = $#dbline;
5608         $filename = $file;
5609     } ## end if ($file ne $filename)
5610
5611     # Subrange is 'start-stop'. If this is less than a window full,
5612     # swap it to 'start+', which will list a window from the start point.
5613     if ($subrange) {
5614         if ( eval($subrange) < -$window ) {
5615             $subrange =~ s/-.*/+/;
5616         }
5617
5618         # Call self recursively to list the range.
5619         return _cmd_l_main( $subrange );
5620     } ## end if ($subrange)
5621
5622     # Couldn't find it.
5623     else {
5624         print {$OUT} "Subroutine $subname not found.\n";
5625         return;
5626     }
5627 }
5628
5629 sub _cmd_l_empty {
5630     # Compute new range to list.
5631     $incr = $window - 1;
5632
5633     # Recurse to do it.
5634     return _cmd_l_main( $start . '-' . ( $start + $incr ) );
5635 }
5636
5637 sub _cmd_l_plus {
5638     my ($new_start, $new_incr) = @_;
5639
5640     # Don't reset start for 'l +nnn'.
5641     $start = $new_start if $new_start;
5642
5643     # Increment for list. Use window size if not specified.
5644     # (Allows 'l +' to work.)
5645     $incr = $new_incr || ($window - 1);
5646
5647     # Create a line range we'll understand, and recurse to do it.
5648     return _cmd_l_main( $start . '-' . ( $start + $incr ) );
5649 }
5650
5651 sub _cmd_l_calc_initial_end_and_i {
5652     my ($spec, $start_match, $end_match) = @_;
5653
5654     # Determine end point; use end of file if not specified.
5655     my $end = ( !defined $start_match ) ? $max :
5656     ( $end_match ? $end_match : $start_match );
5657
5658     # Go on to the end, and then stop.
5659     _minify_to_max(\$end);
5660
5661     # Determine start line.
5662     my $i = $start_match;
5663
5664     if ($i eq '.') {
5665         $i = $spec;
5666     }
5667
5668     $i = _max($i, 1);
5669
5670     $incr = $end - $i;
5671
5672     return ($end, $i);
5673 }
5674
5675 sub _cmd_l_range {
5676     my ($spec, $current_line, $start_match, $end_match) = @_;
5677
5678     my ($end, $i) =
5679         _cmd_l_calc_initial_end_and_i($spec, $start_match, $end_match);
5680
5681     # If we're running under a slave editor, force it to show the lines.
5682     if ($slave_editor) {
5683         print {$OUT} "\032\032$filename:$i:0\n";
5684         $i = $end;
5685     }
5686     # We're doing it ourselves. We want to show the line and special
5687     # markers for:
5688     # - the current line in execution
5689     # - whether a line is breakable or not
5690     # - whether a line has a break or not
5691     # - whether a line has an action or not
5692     else {
5693         I_TO_END:
5694         for ( ; $i <= $end ; $i++ ) {
5695
5696             # Check for breakpoints and actions.
5697             my ( $stop, $action );
5698             if ($dbline{$i}) {
5699                 ( $stop, $action ) = split( /\0/, $dbline{$i} );
5700             }
5701
5702             # ==> if this is the current line in execution,
5703             # : if it's breakable.
5704             my $arrow =
5705             ( $i == $current_line and $filename eq $filename_ini )
5706             ? '==>'
5707             : ( $dbline[$i] + 0 ? ':' : ' ' );
5708
5709             # Add break and action indicators.
5710             $arrow .= 'b' if $stop;
5711             $arrow .= 'a' if $action;
5712
5713             # Print the line.
5714             print {$OUT} "$i$arrow\t", $dbline[$i];
5715
5716             # Move on to the next line. Drop out on an interrupt.
5717             if ($signal) {
5718                 $i++;
5719                 last I_TO_END;
5720             }
5721         } ## end for (; $i <= $end ; $i++)
5722
5723         # Line the prompt up; print a newline if the last line listed
5724         # didn't have a newline.
5725         if ($dbline[ $i - 1 ] !~ /\n\z/) {
5726             print {$OUT} "\n";
5727         }
5728     } ## end else [ if ($slave_editor)
5729
5730     # Save the point we last listed to in case another relative 'l'
5731     # command is desired. Don't let it run off the end.
5732     $start = $i;
5733     _minify_to_max(\$start);
5734
5735     return;
5736 }
5737
5738 sub _cmd_l_main {
5739     my $spec = shift;
5740
5741     # If this is '-something', delete any spaces after the dash.
5742     $spec =~ s/\A-\s*\z/-/;
5743
5744     # If the line is '$something', assume this is a scalar containing a
5745     # line number.
5746     # Set up for DB::eval() - evaluate in *user* context.
5747     if ( my ($var_name) = $spec =~ /\A(\$.*)/s ) {
5748         return _cmd_l_handle_var_name($var_name);
5749     }
5750     # l name. Try to find a sub by that name.
5751     elsif ( ($subname) = $spec =~ /\A([\':A-Za-z_][\':\w]*(?:\[.*\])?)/s ) {
5752         return _cmd_l_handle_subname();
5753     }
5754     # Bare 'l' command.
5755     elsif ( $spec !~ /\S/ ) {
5756         return _cmd_l_empty();
5757     }
5758     # l [start]+number_of_lines
5759     elsif ( my ($new_start, $new_incr) = $spec =~ /\A(\d*)\+(\d*)\z/ ) {
5760         return _cmd_l_plus($new_start, $new_incr);
5761     }
5762     # l start-stop or l start,stop
5763     elsif (my ($s, $e) = $spec =~ /^(?:(-?[\d\$\.]+)(?:[-,]([\d\$\.]+))?)?/ ) {
5764         return _cmd_l_range($spec, $line, $s, $e);
5765     }
5766
5767     return;
5768 } ## end sub cmd_l
5769
5770 sub cmd_l {
5771     my (undef, $line) = @_;
5772
5773     return _cmd_l_main($line);
5774 }
5775
5776 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5777
5778 To list breakpoints, the command has to look determine where all of them are
5779 first. It starts a C<%had_breakpoints>, which tells us what all files have
5780 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5781 magic source and breakpoint data structures) to the file, and then look
5782 through C<%dbline> for lines with breakpoints and/or actions, listing them
5783 out. We look through C<%postponed> not-yet-compiled subroutines that have
5784 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5785 that have breakpoints.
5786
5787 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5788
5789 =cut
5790
5791 sub _cmd_L_calc_arg {
5792     # If no argument, list everything. Pre-5.8.0 version always lists
5793     # everything
5794     my $arg = shift || 'abw';
5795     if ($CommandSet ne '580')
5796     {
5797         $arg = 'abw';
5798     }
5799
5800     return $arg;
5801 }
5802
5803 sub _cmd_L_calc_wanted_flags {
5804     my $arg = _cmd_L_calc_arg(shift);
5805
5806     return (map { index($arg, $_) >= 0 ? 1 : 0 } qw(a b w));
5807 }
5808
5809
5810 sub _cmd_L_handle_breakpoints {
5811     my ($handle_db_line) = @_;
5812
5813     BREAKPOINTS_SCAN:
5814     # Look in all the files with breakpoints...
5815     for my $file ( keys %had_breakpoints ) {
5816
5817         # Temporary switch to this file.
5818         local *dbline = $main::{ '_<' . $file };
5819
5820         # Set up to look through the whole file.
5821         $max = $#dbline;
5822         my $was;    # Flag: did we print something
5823         # in this file?
5824
5825         # For each line in the file ...
5826         for my $i (1 .. $max) {
5827
5828             # We've got something on this line.
5829             if ( defined $dbline{$i} ) {
5830
5831                 # Print the header if we haven't.
5832                 if (not $was++) {
5833                     print {$OUT} "$file:\n";
5834                 }
5835
5836                 # Print the line.
5837                 print {$OUT} " $i:\t", $dbline[$i];
5838
5839                 $handle_db_line->($dbline{$i});
5840
5841                 # Quit if the user hit interrupt.
5842                 if ($signal) {
5843                     last BREAKPOINTS_SCAN;
5844                 }
5845             } ## end if (defined $dbline{$i...
5846         } ## end for my $i (1 .. $max)
5847     } ## end for my $file (keys %had_breakpoints)
5848
5849     return;
5850 }
5851
5852 sub _cmd_L_handle_postponed_breakpoints {
5853     my ($handle_db_line) = @_;
5854
5855     print {$OUT} "Postponed breakpoints in files:\n";
5856
5857     POSTPONED_SCANS:
5858     for my $file ( keys %postponed_file ) {
5859         my $db = $postponed_file{$file};
5860         print {$OUT} " $file:\n";
5861         for my $line ( sort { $a <=> $b } keys %$db ) {
5862             print {$OUT} "  $line:\n";
5863
5864             $handle_db_line->($db->{$line});
5865
5866             if ($signal) {
5867                 last POSTPONED_SCANS;
5868             }
5869         }
5870         if ($signal) {
5871             last POSTPONED_SCANS;
5872         }
5873     }
5874
5875     return;
5876 }
5877
5878
5879 sub cmd_L {
5880     my $cmd = shift;
5881
5882     my ($action_wanted, $break_wanted, $watch_wanted) =
5883         _cmd_L_calc_wanted_flags(shift);
5884
5885     my $handle_db_line = sub {
5886         my ($l) = @_;
5887
5888         my ( $stop, $action ) = split( /\0/, $l );
5889
5890         if ($stop and $break_wanted) {
5891             print {$OUT} "    break if (", $stop, ")\n"
5892         }
5893
5894         if ($action && $action_wanted) {
5895             print {$OUT} "    action:  ", $action, "\n"
5896         }
5897
5898         return;
5899     };
5900
5901     # Breaks and actions are found together, so we look in the same place
5902     # for both.
5903     if ( $break_wanted or $action_wanted ) {
5904         _cmd_L_handle_breakpoints($handle_db_line);
5905     }
5906
5907     # Look for breaks in not-yet-compiled subs:
5908     if ( %postponed and $break_wanted ) {
5909         print {$OUT} "Postponed breakpoints in subroutines:\n";
5910         my $subname;
5911         SUBS_SCAN:
5912         for $subname ( keys %postponed ) {
5913             print {$OUT} " $subname\t$postponed{$subname}\n";
5914             if ($signal) {
5915                 last SUBS_SCAN;
5916             }
5917         }
5918     } ## end if (%postponed and $break_wanted)
5919
5920     # Find files that have not-yet-loaded breaks:
5921     my @have = map {    # Combined keys
5922         keys %{ $postponed_file{$_} }
5923     } keys %postponed_file;
5924
5925     # If there are any, list them.
5926     if ( @have and ( $break_wanted or $action_wanted ) ) {
5927         _cmd_L_handle_postponed_breakpoints($handle_db_line);
5928     } ## end if (@have and ($break_wanted...
5929
5930     if ( %break_on_load and $break_wanted ) {
5931         print {$OUT} "Breakpoints on load:\n";
5932         BREAK_ON_LOAD: for my $filename ( keys %break_on_load ) {
5933             print {$OUT} " $filename\n";
5934             last BREAK_ON_LOAD if $signal;
5935         }
5936     } ## end if (%break_on_load and...
5937
5938     if ($watch_wanted and ( $trace & 2 )) {
5939         print {$OUT} "Watch-expressions:\n" if @to_watch;
5940         TO_WATCH: for my $expr (@to_watch) {
5941             print {$OUT} " $expr\n";
5942             last TO_WATCH if $signal;
5943         }
5944     }
5945
5946     return;
5947 } ## end sub cmd_L
5948
5949 =head3 C<cmd_M> - list modules (command)
5950
5951 Just call C<list_modules>.
5952
5953 =cut
5954
5955 sub cmd_M {
5956     list_modules();
5957
5958     return;
5959 }
5960
5961 =head3 C<cmd_o> - options (command)
5962
5963 If this is just C<o> by itself, we list the current settings via
5964 C<dump_option>. If there's a nonblank value following it, we pass that on to
5965 C<parse_options> for processing.
5966
5967 =cut
5968
5969 sub cmd_o {
5970     my $cmd = shift;
5971     my $opt = shift || '';    # opt[=val]
5972
5973     # Nonblank. Try to parse and process.
5974     if ( $opt =~ /^(\S.*)/ ) {
5975         parse_options($1);
5976     }
5977
5978     # Blank. List the current option settings.
5979     else {
5980         for (@options) {
5981             dump_option($_);
5982         }
5983     }
5984 } ## end sub cmd_o
5985
5986 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5987
5988 Advises the user that the O command has been renamed.
5989
5990 =cut
5991
5992 sub cmd_O {
5993     print $OUT "The old O command is now the o command.\n";             # hint
5994     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5995     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5996 }
5997
5998 =head3 C<cmd_v> - view window (command)
5999
6000 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
6001 move back a few lines to list the selected line in context. Uses C<cmd_l>
6002 to do the actual listing after figuring out the range of line to request.
6003
6004 =cut
6005
6006 use vars qw($preview);
6007
6008 sub cmd_v {
6009     my $cmd  = shift;
6010     my $line = shift;
6011
6012     # Extract the line to list around. (Astute readers will have noted that
6013     # this pattern will match whether or not a numeric line is specified,
6014     # which means that we'll always enter this loop (though a non-numeric
6015     # argument results in no action at all)).
6016     if ( $line =~ /^(\d*)$/ ) {
6017
6018         # Total number of lines to list (a windowful).
6019         $incr = $window - 1;
6020
6021         # Set the start to the argument given (if there was one).
6022         $start = $1 if $1;
6023
6024         # Back up by the context amount.
6025         $start -= $preview;
6026
6027         # Put together a linespec that cmd_l will like.
6028         $line = $start . '-' . ( $start + $incr );
6029
6030         # List the lines.
6031         cmd_l( 'l', $line );
6032     } ## end if ($line =~ /^(\d*)$/)
6033 } ## end sub cmd_v
6034
6035 =head3 C<cmd_w> - add a watch expression (command)
6036
6037 The 5.8 version of this command adds a watch expression if one is specified;
6038 it does nothing if entered with no operands.
6039
6040 We extract the expression, save it, evaluate it in the user's context, and
6041 save the value. We'll re-evaluate it each time the debugger passes a line,
6042 and will stop (see the code at the top of the command loop) if the value
6043 of any of the expressions changes.
6044
6045 =cut
6046
6047 sub _add_watch_expr {
6048     my $expr = shift;
6049
6050     # ... save it.
6051     push @to_watch, $expr;
6052
6053     # Parameterize DB::eval and call it to get the expression's value
6054     # in the user's context. This version can handle expressions which
6055     # return a list value.
6056     $evalarg = $expr;
6057     # The &-call is here to ascertain the mutability of @_.
6058     my ($val) = join( ' ', &DB::eval);
6059     $val = ( defined $val ) ? "'$val'" : 'undef';
6060
6061     # Save the current value of the expression.
6062     push @old_watch, $val;
6063
6064     # We are now watching expressions.
6065     $trace |= 2;
6066
6067     return;
6068 }
6069
6070 sub cmd_w {
6071     my $cmd = shift;
6072
6073     # Null expression if no arguments.
6074     my $expr = shift || '';
6075
6076     # If expression is not null ...
6077     if ( $expr =~ /\A\S/ ) {
6078         _add_watch_expr($expr);
6079     } ## end if ($expr =~ /^(\S.*)/)
6080
6081     # You have to give one to get one.
6082     else {
6083         print $OUT "Adding a watch-expression requires an expression\n";  # hint
6084     }
6085
6086     return;
6087 }
6088
6089 =head3 C<cmd_W> - delete watch expressions (command)
6090
6091 This command accepts either a watch expression to be removed from the list
6092 of watch expressions, or C<*> to delete them all.
6093
6094 If C<*> is specified, we simply empty the watch expression list and the
6095 watch expression value list. We also turn off the bit that says we've got
6096 watch expressions.
6097
6098 If an expression (or partial expression) is specified, we pattern-match
6099 through the expressions and remove the ones that match. We also discard
6100 the corresponding values. If no watch expressions are left, we turn off
6101 the I<watching expressions> bit.
6102
6103 =cut
6104
6105 sub cmd_W {
6106     my $cmd  = shift;
6107     my $expr = shift || '';
6108
6109     # Delete them all.
6110     if ( $expr eq '*' ) {
6111
6112         # Not watching now.
6113         $trace &= ~2;
6114
6115         print $OUT "Deleting all watch expressions ...\n";
6116
6117         # And all gone.
6118         @to_watch = @old_watch = ();
6119     }
6120
6121     # Delete one of them.
6122     elsif ( $expr =~ /^(\S.*)/ ) {
6123
6124         # Where we are in the list.
6125         my $i_cnt = 0;
6126
6127         # For each expression ...
6128         foreach (@to_watch) {
6129             my $val = $to_watch[$i_cnt];
6130
6131             # Does this one match the command argument?
6132             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
6133                                       # Yes. Turn it off, and its value too.
6134                 splice( @to_watch,  $i_cnt, 1 );
6135                 splice( @old_watch, $i_cnt, 1 );
6136             }
6137             $i_cnt++;
6138         } ## end foreach (@to_watch)
6139
6140         # We don't bother to turn watching off because
6141         #  a) we don't want to stop calling watchfunction() if it exists
6142         #  b) foreach over a null list doesn't do anything anyway
6143
6144     } ## end elsif ($expr =~ /^(\S.*)/)
6145
6146     # No command arguments entered.
6147     else {
6148         print $OUT
6149           "Deleting a watch-expression requires an expression, or '*' for all\n"
6150           ;    # hint
6151     }
6152 } ## end sub cmd_W
6153
6154 ### END of the API section
6155
6156 =head1 SUPPORT ROUTINES
6157
6158 These are general support routines that are used in a number of places
6159 throughout the debugger.
6160
6161 =head2 save
6162
6163 save() saves the user's versions of globals that would mess us up in C<@saved>,
6164 and installs the versions we like better.
6165
6166 =cut
6167
6168 sub save {
6169
6170     # Save eval failure, command failure, extended OS error, output field
6171     # separator, input record separator, output record separator and
6172     # the warning setting.
6173     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
6174
6175     $,  = "";      # output field separator is null string
6176     $/  = "\n";    # input record separator is newline
6177     $\  = "";      # output record separator is null string
6178     $^W = 0;       # warnings are off
6179 } ## end sub save
6180
6181 =head2 C<print_lineinfo> - show where we are now
6182
6183 print_lineinfo prints whatever it is that it is handed; it prints it to the
6184 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
6185 us to feed line information to a slave editor without messing up the
6186 debugger output.
6187
6188 =cut
6189
6190 sub print_lineinfo {
6191
6192     # Make the terminal sensible if we're not the primary debugger.
6193     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
6194     local $\ = '';
6195     local $, = '';
6196     # $LINEINFO may be undef if $noTTY is set or some other issue.
6197     if ($LINEINFO)
6198     {
6199         print {$LINEINFO} @_;
6200     }
6201 } ## end sub print_lineinfo
6202
6203 =head2 C<postponed_sub>
6204
6205 Handles setting postponed breakpoints in subroutines once they're compiled.
6206 For breakpoints, we use C<DB::find_sub> to locate the source file and line
6207 range for the subroutine, then mark the file as having a breakpoint,
6208 temporarily switch the C<*dbline> glob over to the source file, and then
6209 search the given range of lines to find a breakable line. If we find one,
6210 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
6211
6212 =cut
6213
6214 # The following takes its argument via $evalarg to preserve current @_
6215
6216 sub postponed_sub {
6217
6218     # Get the subroutine name.
6219     my $subname = shift;
6220
6221     # If this is a 'break +<n> if <condition>' ...
6222     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
6223
6224         # If there's no offset, use '+0'.
6225         my $offset = $1 || 0;
6226
6227         # find_sub's value is 'fullpath-filename:start-stop'. It's
6228         # possible that the filename might have colons in it too.
6229         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
6230         if ($i) {
6231
6232             # We got the start line. Add the offset '+<n>' from
6233             # $postponed{subname}.
6234             $i += $offset;
6235
6236             # Switch to the file this sub is in, temporarily.
6237             local *dbline = $main::{ '_<' . $file };
6238
6239             # No warnings, please.
6240             local $^W = 0;    # != 0 is magical below
6241
6242             # This file's got a breakpoint in it.
6243             $had_breakpoints{$file} |= 1;
6244
6245             # Last line in file.
6246             $max = $#dbline;
6247
6248             # Search forward until we hit a breakable line or get to
6249             # the end of the file.
6250             ++$i until $dbline[$i] != 0 or $i >= $max;
6251
6252             # Copy the breakpoint in and delete it from %postponed.
6253             $dbline{$i} = delete $postponed{$subname};
6254         } ## end if ($i)
6255
6256         # find_sub didn't find the sub.
6257         else {
6258             local $\ = '';
6259             print $OUT "Subroutine $subname not found.\n";
6260         }
6261         return;
6262     } ## end if ($postponed{$subname...
6263     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
6264
6265     #print $OUT "In postponed_sub for '$subname'.\n";
6266 } ## end sub postponed_sub
6267
6268 =head2 C<postponed>
6269
6270 Called after each required file is compiled, but before it is executed;
6271 also called if the name of a just-compiled subroutine is a key of
6272 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
6273 etc.) into the just-compiled code.
6274
6275 If this is a C<require>'d file, the incoming parameter is the glob
6276 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
6277
6278 If it's a subroutine, the incoming parameter is the subroutine name.
6279
6280 =cut
6281
6282 sub postponed {
6283
6284     # If there's a break, process it.
6285     if ($ImmediateStop) {
6286
6287         # Right, we've stopped. Turn it off.
6288         $ImmediateStop = 0;
6289
6290         # Enter the command loop when DB::DB gets called.
6291         $signal = 1;
6292     }
6293
6294     # If this is a subroutine, let postponed_sub() deal with it.
6295     if (ref(\$_[0]) ne 'GLOB') {
6296         return postponed_sub(@_);
6297     }
6298
6299     # Not a subroutine. Deal with the file.
6300     local *dbline = shift;
6301     my $filename = $dbline;
6302     $filename =~ s/^_<//;
6303     local $\ = '';
6304     $signal = 1, print $OUT "'$filename' loaded...\n"
6305       if $break_on_load{$filename};
6306     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
6307
6308     # Do we have any breakpoints to put in this file?
6309     return unless $postponed_file{$filename};
6310
6311     # Yes. Mark this file as having breakpoints.
6312     $had_breakpoints{$filename} |= 1;
6313
6314     # "Cannot be done: insufficient magic" - we can't just put the
6315     # breakpoints saved in %postponed_file into %dbline by assigning
6316     # the whole hash; we have to do it one item at a time for the
6317     # breakpoints to be set properly.
6318     #%dbline = %{$postponed_file{$filename}};
6319
6320     # Set the breakpoints, one at a time.
6321     my $key;
6322
6323     for $key ( keys %{ $postponed_file{$filename} } ) {
6324
6325         # Stash the saved breakpoint into the current file's magic line array.
6326         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
6327     }
6328
6329     # This file's been compiled; discard the stored breakpoints.
6330     delete $postponed_file{$filename};
6331
6332 } ## end sub postponed
6333
6334 =head2 C<dumpit>
6335
6336 C<dumpit> is the debugger's wrapper around dumpvar.pl.
6337
6338 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
6339 a reference to a variable (the thing to be dumped) as its input.
6340
6341 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
6342 the currently-selected filehandle, thank you very much). The current
6343 values of the package globals C<$single> and C<$trace> are backed up in
6344 lexicals, and they are turned off (this keeps the debugger from trying
6345 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
6346 preserve its current value and it is set to zero to prevent entry/exit
6347 messages from printing, and C<$doret> is localized as well and set to -2 to
6348 prevent return values from being shown.
6349
6350 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
6351 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
6352 installed version in C<@INC>, yours will be used instead. Possible security
6353 problem?).
6354
6355 It then checks to see if the subroutine C<main::dumpValue> is now defined
6356 it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
6357 localizes the globals necessary for things to be sane when C<main::dumpValue()>
6358 is called, and picks up the variable to be dumped from the parameter list.
6359
6360 It checks the package global C<%options> to see if there's a C<dumpDepth>
6361 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
6362 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
6363 structure: -1 means dump everything.
6364
6365 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
6366 warning.
6367
6368 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
6369 and we then return to the caller.
6370
6371 =cut
6372
6373 sub dumpit {
6374
6375     # Save the current output filehandle and switch to the one
6376     # passed in as the first parameter.
6377     my $savout = select(shift);
6378
6379     # Save current settings of $single and $trace, and then turn them off.
6380     my $osingle = $single;
6381     my $otrace  = $trace;
6382     $single = $trace = 0;
6383
6384     # XXX Okay, what do $frame and $doret do, again?
6385     local $frame = 0;
6386     local $doret = -2;
6387
6388     # Load dumpvar.pl unless we've already got the sub we need from it.
6389     unless ( defined &main::dumpValue ) {
6390         do 'dumpvar.pl' or die $@;
6391     }
6392
6393     # If the load succeeded (or we already had dumpvalue()), go ahead
6394     # and dump things.
6395     if ( defined &main::dumpValue ) {
6396         local $\ = '';
6397         local $, = '';
6398         local $" = ' ';
6399         my $v = shift;
6400         my $maxdepth = shift || $option{dumpDepth};
6401         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
6402         main::dumpValue( $v, $maxdepth );
6403     } ## end if (defined &main::dumpValue)
6404
6405     # Oops, couldn't load dumpvar.pl.
6406     else {
6407         local $\ = '';
6408         print $OUT "dumpvar.pl not available.\n";
6409     }
6410
6411     # Reset $single and $trace to their old values.
6412     $single = $osingle;
6413     $trace  = $otrace;
6414
6415     # Restore the old filehandle.
6416     select($savout);
6417 } ## end sub dumpit
6418
6419 =head2 C<print_trace>
6420
6421 C<print_trace>'s job is to print a stack trace. It does this via the
6422 C<dump_trace> routine, which actually does all the ferreting-out of the
6423 stack trace data. C<print_trace> takes care of formatting it nicely and
6424 printing it to the proper filehandle.
6425
6426 Parameters:
6427
6428 =over 4
6429
6430 =item *
6431
6432 The filehandle to print to.
6433
6434 =item *
6435
6436 How many frames to skip before starting trace.
6437
6438 =item *
6439
6440 How many frames to print.
6441
6442 =item *
6443
6444 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
6445
6446 =back
6447
6448 The original comment below seems to be noting that the traceback may not be
6449 correct if this routine is called in a tied method.
6450
6451 =cut
6452
6453 # Tied method do not create a context, so may get wrong message:
6454
6455 sub print_trace {
6456     local $\ = '';
6457     my $fh = shift;
6458
6459     # If this is going to a slave editor, but we're not the primary
6460     # debugger, reset it first.
6461     resetterm(1)
6462       if $fh        eq $LINEINFO    # slave editor
6463       and $LINEINFO eq $OUT         # normal output
6464       and $term_pid != $$;          # not the primary
6465
6466     # Collect the actual trace information to be formatted.
6467     # This is an array of hashes of subroutine call info.
6468     my @sub = dump_trace( $_[0] + 1, $_[1] );
6469
6470     # Grab the "short report" flag from @_.
6471     my $short = $_[2];              # Print short report, next one for sub name
6472
6473     # Run through the traceback info, format it, and print it.
6474     my $s;
6475     for my $i (0 .. $#sub) {
6476
6477         # Drop out if the user has lost interest and hit control-C.
6478         last if $signal;
6479
6480         # Set the separator so arrays print nice.
6481         local $" = ', ';
6482
6483         # Grab and stringify the arguments if they are there.
6484         my $args =
6485           defined $sub[$i]{args}
6486           ? "(@{ $sub[$i]{args} })"
6487           : '';
6488
6489         # Shorten them up if $maxtrace says they're too long.
6490         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
6491           if length $args > $maxtrace;
6492
6493         # Get the file name.
6494         my $file = $sub[$i]{file};
6495
6496         # Put in a filename header if short is off.
6497         $file = $file eq '-e' ? $file : "file '$file'" unless $short;
6498
6499         # Get the actual sub's name, and shorten to $maxtrace's requirement.
6500         $s = $sub[$i]{'sub'};
6501         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
6502
6503         # Short report uses trimmed file and sub names.
6504         if ($short) {
6505             my $sub = @_ >= 4 ? $_[3] : $s;
6506             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
6507         } ## end if ($short)
6508
6509         # Non-short report includes full names.
6510         else {
6511             print $fh "$sub[$i]{context} = $s$args"
6512               . " called from $file"
6513               . " line $sub[$i]{line}\n";
6514         }
6515     } ## end for my $i (0 .. $#sub)
6516 } ## end sub print_trace
6517
6518 =head2 dump_trace(skip[,count])
6519
6520 Actually collect the traceback information available via C<caller()>. It does
6521 some filtering and cleanup of the data, but mostly it just collects it to
6522 make C<print_trace()>'s job easier.
6523
6524 C<skip> defines the number of stack frames to be skipped, working backwards
6525 from the most current. C<count> determines the total number of frames to
6526 be returned; all of them (well, the first 10^9) are returned if C<count>
6527 is omitted.
6528
6529 This routine returns a list of hashes, from most-recent to least-recent
6530 stack frame. Each has the following keys and values:
6531
6532 =over 4
6533
6534 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
6535
6536 =item * C<sub> - subroutine name, or C<eval> information
6537
6538 =item * C<args> - undef, or a reference to an array of arguments
6539
6540 =item * C<file> - the file in which this item was defined (if any)
6541
6542 =item * C<line> - the line on which it was defined
6543
6544 =back
6545
6546 =cut
6547
6548 sub _dump_trace_calc_saved_single_arg
6549 {
6550     my ($nothard, $arg) = @_;
6551
6552     my $type;
6553     if ( not defined $arg ) {    # undefined parameter
6554         return "undef";
6555     }
6556
6557     elsif ( $nothard and tied $arg ) {    # tied parameter
6558         return "tied";
6559     }
6560     elsif ( $nothard and $type = ref $arg ) {    # reference
6561         return "ref($type)";
6562     }
6563     else {                                       # can be stringified
6564         local $_ =
6565         "$arg";    # Safe to stringify now - should not call f().
6566
6567         # Backslash any single-quotes or backslashes.
6568         s/([\'\\])/\\$1/g;
6569
6570         # Single-quote it unless it's a number or a colon-separated
6571         # name.
6572         s/(.*)/'$1'/s
6573         unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
6574
6575         # Turn high-bit characters into meta-whatever, and controls into like
6576         # '^D'.
6577         require 'meta_notation.pm';
6578         $_ = _meta_notation($_) if /[[:^print:]]/a;
6579
6580         return $_;
6581     }
6582 }
6583
6584 sub _dump_trace_calc_save_args {
6585     my ($nothard) = @_;
6586
6587     return [
6588         map { _dump_trace_calc_saved_single_arg($nothard, $_) } @args
6589     ];
6590 }
6591
6592 sub dump_trace {
6593
6594     # How many levels to skip.
6595     my $skip = shift;
6596
6597     # How many levels to show. (1e9 is a cheap way of saying "all of them";
6598     # it's unlikely that we'll have more than a billion stack frames. If you
6599     # do, you've got an awfully big machine...)
6600     my $count = shift || 1e9;
6601
6602     # We increment skip because caller(1) is the first level *back* from
6603     # the current one.  Add $skip to the count of frames so we have a
6604     # simple stop criterion, counting from $skip to $count+$skip.
6605     $skip++;
6606     $count += $skip;
6607
6608     # These variables are used to capture output from caller();
6609     my ( $p, $file, $line, $sub, $h, $context );
6610
6611     my ( $e, $r, @sub, $args );
6612
6613     # XXX Okay... why'd we do that?
6614     my $nothard = not $frame & 8;
6615     local $frame = 0;
6616
6617     # Do not want to trace this.
6618     my $otrace = $trace;
6619     $trace = 0;
6620
6621     # Start out at the skip count.
6622     # If we haven't reached the number of frames requested, and caller() is
6623     # still returning something, stay in the loop. (If we pass the requested
6624     # number of stack frames, or we run out - caller() returns nothing - we
6625     # quit.
6626     # Up the stack frame index to go back one more level each time.
6627     for (
6628         my $i = $skip ;
6629         $i < $count
6630         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
6631         $i++
6632     )
6633     {
6634         # if the sub has args ($h true), make an anonymous array of the
6635         # dumped args.
6636         my $args = $h ? _dump_trace_calc_save_args($nothard) : undef;
6637
6638         # If context is true, this is array (@)context.
6639         # If context is false, this is scalar ($) context.
6640         # If neither, context isn't defined. (This is apparently a 'can't
6641         # happen' trap.)
6642         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
6643
6644         # remove trailing newline-whitespace-semicolon-end of line sequence
6645         # from the eval text, if any.
6646         $e =~ s/\n\s*\;\s*\Z// if $e;
6647
6648         # Escape backslashed single-quotes again if necessary.
6649         $e =~ s/([\\\'])/\\$1/g if $e;
6650
6651         # if the require flag is true, the eval text is from a require.
6652         if ($r) {
6653             $sub = "require '$e'";
6654         }
6655
6656         # if it's false, the eval text is really from an eval.
6657         elsif ( defined $r ) {
6658             $sub = "eval '$e'";
6659         }
6660
6661         # If the sub is '(eval)', this is a block eval, meaning we don't
6662         # know what the eval'ed text actually was.
6663         elsif ( $sub eq '(eval)' ) {
6664             $sub = "eval {...}";
6665         }
6666
6667         # Stick the collected information into @sub as an anonymous hash.
6668         push(
6669             @sub,
6670             {
6671                 context => $context,
6672                 sub     => $sub,
6673                 args    => $args,
6674                 file    => $file,
6675                 line    => $line
6676             }
6677         );
6678
6679         # Stop processing frames if the user hit control-C.
6680         last if $signal;
6681     } ## end for ($i = $skip ; $i < ...
6682
6683     # Restore the trace value again.
6684     $trace = $otrace;
6685     @sub;
6686 } ## end sub dump_trace
6687
6688 =head2 C<action()>
6689
6690 C<action()> takes input provided as the argument to an add-action command,
6691 either pre- or post-, and makes sure it's a complete command. It doesn't do
6692 any fancy parsing; it just keeps reading input until it gets a string
6693 without a trailing backslash.
6694
6695 =cut
6696
6697 sub action {
6698     my $action = shift;
6699
6700     while ( $action =~ s/\\$// ) {
6701
6702         # We have a backslash on the end. Read more.
6703         $action .= gets();
6704     } ## end while ($action =~ s/\\$//)
6705
6706     # Return the assembled action.
6707     $action;
6708 } ## end sub action
6709
6710 =head2 unbalanced
6711
6712 This routine mostly just packages up a regular expression to be used
6713 to check that the thing it's being matched against has properly-matched
6714 curly braces.
6715
6716 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
6717 speeds things up by only creating the qr//'ed expression once; if it's
6718 already defined, we don't try to define it again. A speed hack.
6719
6720 =cut
6721
6722 use vars qw($balanced_brace_re);
6723
6724 sub unbalanced {
6725
6726     # I hate using globals!
6727     $balanced_brace_re ||= qr{
6728         ^ \{
6729              (?:
6730                  (?> [^{}] + )              # Non-parens without backtracking
6731                 |
6732                  (??{ $balanced_brace_re }) # Group with matching parens
6733               ) *
6734           \} $
6735    }x;
6736     return $_[0] !~ m/$balanced_brace_re/;
6737 } ## end sub unbalanced
6738
6739 =head2 C<gets()>
6740
6741 C<gets()> is a primitive (very primitive) routine to read continuations.
6742 It was devised for reading continuations for actions.
6743 it just reads more input with C<readline()> and returns it.
6744
6745 =cut
6746
6747 sub gets {
6748     return DB::readline("cont: ");
6749 }
6750
6751 =head2 C<_db_system()> - handle calls to<system()> without messing up the debugger
6752
6753 The C<system()> function assumes that it can just go ahead and use STDIN and
6754 STDOUT, but under the debugger, we want it to use the debugger's input and
6755 outout filehandles.
6756
6757 C<_db_system()> socks away the program's STDIN and STDOUT, and then substitutes
6758 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
6759 and then puts everything back again.
6760
6761 =cut
6762
6763 sub _db_system {
6764
6765     # We save, change, then restore STDIN and STDOUT to avoid fork() since
6766     # some non-Unix systems can do system() but have problems with fork().
6767     open( SAVEIN,  "<&STDIN" )  || _db_warn("Can't save STDIN");
6768     open( SAVEOUT, ">&STDOUT" ) || _db_warn("Can't save STDOUT");
6769     open( STDIN,   "<&IN" )     || _db_warn("Can't redirect STDIN");
6770     open( STDOUT,  ">&OUT" )    || _db_warn("Can't redirect STDOUT");
6771
6772     # XXX: using csh or tcsh destroys sigint retvals!
6773     system(@_);
6774     open( STDIN,  "<&SAVEIN" )  || _db_warn("Can't restore STDIN");
6775     open( STDOUT, ">&SAVEOUT" ) || _db_warn("Can't restore STDOUT");
6776     close(SAVEIN);
6777     close(SAVEOUT);
6778
6779     # most of the $? crud was coping with broken cshisms
6780     if ( $? >> 8 ) {
6781         _db_warn( "(Command exited ", ( $? >> 8 ), ")\n" );
6782     }
6783     elsif ($?) {
6784         _db_warn(
6785             "(Command died of SIG#",
6786             ( $? & 127 ),
6787             ( ( $? & 128 ) ? " -- core dumped" : "" ),
6788             ")", "\n"
6789         );
6790     } ## end elsif ($?)
6791
6792     return $?;
6793
6794 } ## end sub system
6795
6796 *system = \&_db_system;
6797
6798 =head1 TTY MANAGEMENT
6799
6800 The subs here do some of the terminal management for multiple debuggers.
6801
6802 =head2 setterm
6803
6804 Top-level function called when we want to set up a new terminal for use
6805 by the debugger.
6806
6807 If the C<noTTY> debugger option was set, we'll either use the terminal
6808 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6809 to find one. If we're a forked debugger, we call C<resetterm> to try to
6810 get a whole new terminal if we can.
6811
6812 In either case, we set up the terminal next. If the C<ReadLine> option was
6813 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6814 the appropriate attributes. We then
6815
6816 =cut
6817
6818 use vars qw($ornaments);
6819 use vars qw($rl_attribs);
6820
6821 sub setterm {
6822
6823     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6824     local $frame = 0;
6825     local $doret = -2;
6826     require Term::ReadLine;
6827
6828     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6829     if ($notty) {
6830         if ($tty) {
6831             my ( $i, $o ) = split $tty, /,/;
6832             $o = $i unless defined $o;
6833             open( IN,  '<', $i ) or die "Cannot open TTY '$i' for read: $!";
6834             open( OUT, '>', $o ) or die "Cannot open TTY '$o' for write: $!";
6835             $IN  = \*IN;
6836             $OUT = \*OUT;
6837             _autoflush($OUT);
6838         } ## end if ($tty)
6839
6840         # We don't have a TTY - try to find one via Term::Rendezvous.
6841         else {
6842             require Term::Rendezvous;
6843
6844             # See if we have anything to pass to Term::Rendezvous.
6845             # Use $HOME/.perldbtty$$ if not.
6846             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6847
6848             # Rendezvous and get the filehandles.
6849             my $term_rv = Term::Rendezvous->new( $rv );
6850             $IN  = $term_rv->IN;
6851             $OUT = $term_rv->OUT;
6852         } ## end else [ if ($tty)
6853     } ## end if ($notty)
6854
6855     # We're a daughter debugger. Try to fork off another TTY.
6856     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6857         resetterm(2);
6858     }
6859
6860     # If we shouldn't use Term::ReadLine, don't.
6861     if ( !$rl ) {
6862         $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6863     }
6864
6865     # We're using Term::ReadLine. Get all the attributes for this terminal.
6866     else {
6867         $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6868
6869         $rl_attribs = $term->Attribs;
6870         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6871           if defined $rl_attribs->{basic_word_break_characters}
6872           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6873         $rl_attribs->{special_prefixes} = '$@&%';
6874         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6875         $rl_attribs->{completion_function} = \&db_complete;
6876     } ## end else [ if (!$rl)
6877
6878     # Set up the LINEINFO filehandle.
6879     $LINEINFO = $OUT     unless defined $LINEINFO;
6880     $lineinfo = $console unless defined $lineinfo;
6881
6882     $term->MinLine(2);
6883
6884     load_hist();
6885
6886     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6887         $term->SetHistory(@hist);
6888     }
6889
6890     # XXX Ornaments are turned on unconditionally, which is not
6891     # always a good thing.
6892     ornaments($ornaments) if defined $ornaments;
6893     $term_pid = $$;
6894 } ## end sub setterm
6895
6896 sub load_hist {
6897     $histfile //= option_val("HistFile", undef);
6898     return unless defined $histfile;
6899     open my $fh, "<", $histfile or return;
6900     local $/ = "\n";
6901     @hist = ();
6902     while (<$fh>) {
6903         chomp;
6904         push @hist, $_;
6905     }
6906     close $fh;
6907 }
6908
6909 sub save_hist {
6910     return unless defined $histfile;
6911     eval { require File::Path } or return;
6912     eval { require File::Basename } or return;
6913     File::Path::mkpath(File::Basename::dirname($histfile));
6914     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6915     $histsize //= option_val("HistSize",100);
6916     my @copy = grep { $_ ne '?' } @hist;
6917     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6918     for ($start .. $#copy) {
6919         print $fh "$copy[$_]\n";
6920     }
6921     close $fh or die "Could not write '$histfile': $!";
6922 }
6923
6924 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6925
6926 When the process being debugged forks, or the process invokes a command
6927 via C<system()> which starts a new debugger, we need to be able to get a new
6928 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6929 fight over the terminal, and you can never quite be sure who's going to get the
6930 input you're typing.
6931
6932 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6933 is tasked with doing all the necessary operating system mojo to get a new
6934 TTY (and probably another window) and to direct the new debugger to read and
6935 write there.
6936
6937 The debugger provides C<get_fork_TTY> functions which work for TCP
6938 socket servers, X11, OS/2, and Mac OS X. Other systems are not
6939 supported. You are encouraged to write C<get_fork_TTY> functions which
6940 work for I<your> platform and contribute them.
6941
6942 =head3 C<socket_get_fork_TTY>
6943
6944 =cut
6945
6946 sub connect_remoteport {
6947     require IO::Socket;
6948
6949     my $socket = IO::Socket::INET->new(
6950         Timeout  => '10',
6951         PeerAddr => $remoteport,
6952         Proto    => 'tcp',
6953     );
6954     if ( ! $socket ) {
6955         die "Unable to connect to remote host: $remoteport\n";
6956     }
6957     return $socket;
6958 }
6959
6960 sub socket_get_fork_TTY {
6961     $tty = $LINEINFO = $IN = $OUT = connect_remoteport();
6962
6963     # Do I need to worry about setting $term?
6964
6965     reset_IN_OUT( $IN, $OUT );
6966     return '';
6967 }
6968
6969 =head3 C<xterm_get_fork_TTY>
6970
6971 This function provides the C<get_fork_TTY> function for X11. If a
6972 program running under the debugger forks, a new <xterm> window is opened and
6973 the subsidiary debugger is directed there.
6974
6975 The C<open()> call is of particular note here. We have the new C<xterm>
6976 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6977 command (which prints the device name of the TTY we'll want to use for input
6978 and output to STDOUT, then C<sleep> for a very long time, routing this output
6979 to file number 3. This way we can simply read from the <XT> filehandle (which
6980 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6981
6982 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6983 properly set up.
6984
6985 =cut
6986
6987 sub xterm_get_fork_TTY {
6988     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6989     open XT,
6990 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6991  sleep 10000000' |];
6992
6993     # Get the output from 'tty' and clean it up a little.
6994     my $tty = <XT>;
6995     chomp $tty;
6996
6997     $pidprompt = '';    # Shown anyway in titlebar
6998
6999     # We need $term defined or we can not switch to the newly created xterm
7000     if ($tty ne '' && !defined $term) {
7001         require Term::ReadLine;
7002         if ( !$rl ) {
7003             $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
7004         }
7005         else {
7006             $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
7007         }
7008     }
7009     # There's our new TTY.
7010     return $tty;
7011 } ## end sub xterm_get_fork_TTY
7012
7013 =head3 C<os2_get_fork_TTY>
7014
7015 XXX It behooves an OS/2 expert to write the necessary documentation for this!
7016
7017 =cut
7018
7019 # This example function resets $IN, $OUT itself
7020 my $c_pipe = 0;
7021 sub os2_get_fork_TTY { # A simplification of the following (and works without):
7022     local $\  = '';
7023     ( my $name = $0 ) =~ s,^.*[/\\],,s;
7024     my %opt = ( title => "Daughter Perl debugger $pids $name",
7025         ($rl ? (read_by_key => 1) : ()) );
7026     require OS2::Process;
7027     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
7028       or return;
7029     $pidprompt = '';    # Shown anyway in titlebar
7030     reset_IN_OUT($in, $out);
7031     $tty = '*reset*';
7032     return '';          # Indicate that reset_IN_OUT is called
7033 } ## end sub os2_get_fork_TTY
7034
7035 =head3 C<macosx_get_fork_TTY>
7036
7037 The Mac OS X version uses AppleScript to tell Terminal.app to create
7038 a new window.
7039
7040 =cut
7041
7042 # Notes about Terminal.app's AppleScript support,
7043 # (aka things that might break in future OS versions).
7044 #
7045 # The "do script" command doesn't return a reference to the new window
7046 # it creates, but since it appears frontmost and windows are enumerated
7047 # front to back, we can use "first window" === "window 1".
7048 #
7049 # Since "do script" is implemented by supplying the argument (plus a
7050 # return character) as terminal input, there's a potential race condition
7051 # where the debugger could beat the shell to reading the command.
7052 # To prevent this, we wait for the screen to clear before proceeding.
7053 #
7054 # 10.3 and 10.4:
7055 # There's no direct accessor for the tty device name, so we fiddle
7056 # with the window title options until it says what we want.
7057 #
7058 # 10.5:
7059 # There _is_ a direct accessor for the tty device name, _and_ there's
7060 # a new possible component of the window title (the name of the settings
7061 # set).  A separate version is needed.
7062
7063 my @script_versions=
7064
7065     ([237, <<'__LEOPARD__'],
7066 tell application "Terminal"
7067     do script "clear;exec sleep 100000"
7068     tell first tab of first window
7069         copy tty to thetty
7070         set custom title to "forked perl debugger"
7071         set title displays custom title to true
7072         repeat while (length of first paragraph of (get contents)) > 0
7073             delay 0.1
7074         end repeat
7075     end tell
7076 end tell
7077 thetty
7078 __LEOPARD__
7079
7080      [100, <<'__JAGUAR_TIGER__'],
7081 tell application "Terminal"
7082     do script "clear;exec sleep 100000"
7083     tell first window
7084         set title displays shell path to false
7085         set title displays window size to false
7086         set title displays file name to false
7087         set title displays device name to true
7088         set title displays custom title to true
7089         set custom title to ""
7090         copy "/dev/" & name to thetty
7091         set custom title to "forked perl debugger"
7092         repeat while (length of first paragraph of (get contents)) > 0
7093             delay 0.1
7094         end repeat
7095     end tell
7096 end tell
7097 thetty
7098 __JAGUAR_TIGER__
7099
7100 );
7101
7102 sub macosx_get_fork_TTY
7103 {
7104     my($version,$script,$pipe,$tty);
7105
7106     return unless $version=$ENV{TERM_PROGRAM_VERSION};
7107     foreach my $entry (@script_versions) {
7108         if ($version>=$entry->[0]) {
7109             $script=$entry->[1];
7110             last;
7111         }
7112     }
7113     return unless defined($script);
7114     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
7115     $tty=readline($pipe);
7116     close($pipe);
7117     return unless defined($tty) && $tty =~ m(^/dev/);
7118     chomp $tty;
7119     return $tty;
7120 }
7121
7122 =head3 C<tmux_get_fork_TTY>
7123
7124 Creates a split window for subprocesses when a process running under the
7125 perl debugger in Tmux forks.
7126
7127 =cut
7128
7129 sub tmux_get_fork_TTY {
7130     return unless $ENV{TMUX};
7131
7132     my $pipe;
7133
7134     my $status = open $pipe, '-|', 'tmux', 'split-window',
7135         '-P', '-F', '#{pane_tty}', 'sleep 100000';
7136
7137     if ( !$status ) {
7138         return;
7139     }
7140
7141     my $tty = <$pipe>;
7142     close $pipe;
7143
7144     if ( $tty ) {
7145         chomp $tty;
7146
7147         if ( !defined $term ) {
7148             require Term::ReadLine;
7149             if ( !$rl ) {
7150                 $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
7151             }
7152             else {
7153                 $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
7154             }
7155         }
7156     }
7157
7158     return $tty;
7159 }
7160
7161 =head2 C<create_IN_OUT($flags)>
7162
7163 Create a new pair of filehandles, pointing to a new TTY. If impossible,
7164 try to diagnose why.
7165
7166 Flags are:
7167
7168 =over 4
7169
7170 =item * 1 - Don't know how to create a new TTY.
7171
7172 =item * 2 - Debugger has forked, but we can't get a new TTY.
7173
7174 =item * 4 - standard debugger startup is happening.
7175
7176 =back
7177
7178 =cut
7179
7180 use vars qw($fork_TTY);
7181
7182 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
7183
7184     # If we know how to get a new TTY, do it! $in will have
7185     # the TTY name if get_fork_TTY works.
7186     my $in = get_fork_TTY(@_) if defined &get_fork_TTY;
7187
7188     # It used to be that
7189     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
7190
7191     if ( not defined $in ) {
7192         my $why = shift;
7193
7194         # We don't know how.
7195         print_help(<<EOP) if $why == 1;
7196 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
7197 EOP
7198
7199         # Forked debugger.
7200         print_help(<<EOP) if $why == 2;
7201 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
7202   This may be an asynchronous session, so the parent debugger may be active.
7203 EOP
7204
7205         # Note that both debuggers are fighting over the same input.
7206         print_help(<<EOP) if $why != 4;
7207   Since two debuggers fight for the same TTY, input is severely entangled.
7208
7209 EOP
7210         print_help(<<EOP);
7211   I know how to switch the output to a different window in xterms, OS/2
7212   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
7213   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
7214   B<DB::get_fork_TTY()> returning this.
7215
7216   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
7217   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
7218
7219 EOP
7220     } ## end if (not defined $in)
7221     elsif ( $in ne '' ) {
7222         TTY($in);
7223     }
7224     else {
7225         $console = '';    # Indicate no need to open-from-the-console
7226     }
7227     undef $fork_TTY;
7228 } ## end sub create_IN_OUT
7229
7230 =head2 C<resetterm>
7231
7232 Handles rejiggering the prompt when we've forked off a new debugger.
7233
7234 If the new debugger happened because of a C<system()> that invoked a
7235 program under the debugger, the arrow between the old pid and the new
7236 in the prompt has I<two> dashes instead of one.
7237
7238 We take the current list of pids and add this one to the end. If there
7239 isn't any list yet, we make one up out of the initial pid associated with
7240 the terminal and our new pid, sticking an arrow (either one-dashed or
7241 two dashed) in between them.
7242
7243 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
7244 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
7245 and try to do that.
7246
7247 =cut
7248
7249 sub resetterm {    # We forked, so we need a different TTY
7250
7251     # Needs to be passed to create_IN_OUT() as well.
7252     my $in = shift;
7253
7254     # resetterm(2): got in here because of a system() starting a debugger.
7255     # resetterm(1): just forked.
7256     my $systemed = $in > 1 ? '-' : '';
7257
7258     # If there's already a list of pids, add this to the end.
7259     if ($pids) {
7260         $pids =~ s/\]/$systemed->$$]/;
7261     }
7262
7263     # No pid list. Time to make one.
7264     else {
7265         $pids = "[$term_pid->$$]";
7266     }
7267
7268     # The prompt we're going to be using for this debugger.
7269     $pidprompt = $pids;
7270
7271     # We now 0wnz this terminal.
7272     $term_pid = $$;
7273
7274     # Just return if we're not supposed to try to create a new TTY.
7275     return unless $CreateTTY & $in;
7276
7277     # Try to create a new IN/OUT pair.
7278     create_IN_OUT($in);
7279 } ## end sub resetterm
7280
7281 =head2 C<readline>
7282
7283 First, we handle stuff in the typeahead buffer. If there is any, we shift off
7284 the next line, print a message saying we got it, add it to the terminal
7285 history (if possible), and return it.
7286
7287 If there's nothing in the typeahead buffer, check the command filehandle stack.
7288 If there are any filehandles there, read from the last one, and return the line
7289 if we got one. If not, we pop the filehandle off and close it, and try the
7290 next one up the stack.
7291
7292 If we've emptied the filehandle stack, we check to see if we've got a socket
7293 open, and we read that and return it if we do. If we don't, we just call the
7294 core C<readline()> and return its value.
7295
7296 =cut
7297
7298 sub readline {
7299
7300     # Localize to prevent it from being smashed in the program being debugged.
7301     local $.;
7302
7303     # If there are stacked filehandles to read from ...
7304     # (Handle it before the typeahead, because we may call source/etc. from
7305     # the typeahead.)
7306     while (@cmdfhs) {
7307
7308         # Read from the last one in the stack.
7309         my $line = CORE::readline( $cmdfhs[-1] );
7310
7311         # If we got a line ...
7312         defined $line
7313           ? ( print $OUT ">> $line" and return $line )    # Echo and return
7314           : close pop @cmdfhs;                            # Pop and close
7315     } ## end while (@cmdfhs)
7316
7317     # Pull a line out of the typeahead if there's stuff there.
7318     if (@typeahead) {
7319
7320         # How many lines left.
7321         my $left = @typeahead;
7322
7323         # Get the next line.
7324         my $got = shift @typeahead;
7325
7326         # Print a message saying we got input from the typeahead.
7327         local $\ = '';
7328         print $OUT "auto(-$left)", shift, $got, "\n";
7329
7330         # Add it to the terminal history (if possible).
7331         $term->AddHistory($got)
7332           if length($got) > 1
7333           and defined $term->Features->{addHistory};
7334         return $got;
7335     } ## end if (@typeahead)
7336
7337     # We really need to read some input. Turn off entry/exit trace and
7338     # return value printing.
7339     local $frame = 0;
7340     local $doret = -2;
7341
7342     # Nothing on the filehandle stack. Socket?
7343     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
7344
7345         # Send anything we have to send.
7346         $OUT->write( join( '', @_ ) );
7347
7348         # Receive anything there is to receive.
7349         my $stuff = '';
7350         my $buf;
7351         my $first_time = 1;
7352
7353         while ($first_time or (length($buf) && ($stuff .= $buf) !~ /\n/))
7354         {
7355             $first_time = 0;
7356             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
7357                                             # XXX Don't know. You tell me.
7358         }
7359
7360         # What we got.
7361         return $stuff;
7362     } ## end if (ref $OUT and UNIVERSAL::isa...
7363
7364     # No socket. Just read from the terminal.
7365     else {
7366         return $term->readline(@_);
7367     }
7368 } ## end sub readline
7369
7370 =head1 OPTIONS SUPPORT ROUTINES
7371
7372 These routines handle listing and setting option values.
7373
7374 =head2 C<dump_option> - list the current value of an option setting
7375
7376 This routine uses C<option_val> to look up the value for an option.
7377 It cleans up escaped single-quotes and then displays the option and
7378 its value.
7379
7380 =cut
7381
7382 sub dump_option {
7383     my ( $opt, $val ) = @_;
7384     $val = option_val( $opt, 'N/A' );
7385     $val =~ s/([\\\'])/\\$1/g;
7386     printf $OUT "%20s = '%s'\n", $opt, $val;
7387 } ## end sub dump_option
7388
7389 sub options2remember {
7390     foreach my $k (@RememberOnROptions) {
7391         $option{$k} = option_val( $k, 'N/A' );
7392     }
7393     return %option;
7394 }
7395
7396 =head2 C<option_val> - find the current value of an option
7397
7398 This can't just be a simple hash lookup because of the indirect way that
7399 the option values are stored. Some are retrieved by calling a subroutine,
7400 some are just variables.
7401
7402 You must supply a default value to be used in case the option isn't set.
7403
7404 =cut
7405
7406 sub option_val {
7407     my ( $opt, $default ) = @_;
7408     my $val;
7409
7410     # Does this option exist, and is it a variable?
7411     # If so, retrieve the value via the value in %optionVars.
7412     if (    defined $optionVars{$opt}
7413         and defined ${ $optionVars{$opt} } )
7414     {
7415         $val = ${ $optionVars{$opt} };
7416     }
7417
7418     # Does this option exist, and it's a subroutine?
7419     # If so, call the subroutine via the ref in %optionAction
7420     # and capture the value.
7421     elsif ( defined $optionAction{$opt}
7422         and defined &{ $optionAction{$opt} } )
7423     {
7424         $val = &{ $optionAction{$opt} }();
7425     }
7426
7427     # If there's an action or variable for the supplied option,
7428     # but no value was set, use the default.
7429     elsif (defined $optionAction{$opt} and not defined $option{$opt}
7430         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
7431     {
7432         $val = $default;
7433     }
7434
7435     # Otherwise, do the simple hash lookup.
7436     else {
7437         $val = $option{$opt};
7438     }
7439
7440     # If the value isn't defined, use the default.
7441     # Then return whatever the value is.
7442     $val = $default unless defined $val;
7443     $val;
7444 } ## end sub option_val
7445
7446 =head2 C<parse_options>
7447
7448 Handles the parsing and execution of option setting/displaying commands.
7449
7450 An option entered by itself is assumed to be I<set me to 1> (the default value)
7451 if the option is a boolean one. If not, the user is prompted to enter a valid
7452 value or to query the current value (via C<option? >).
7453
7454 If C<option=value> is entered, we try to extract a quoted string from the
7455 value (if it is quoted). If it's not, we just use the whole value as-is.
7456
7457 We load any modules required to service this option, and then we set it: if
7458 it just gets stuck in a variable, we do that; if there's a subroutine to
7459 handle setting the option, we call that.
7460
7461 Finally, if we're running in interactive mode, we display the effect of the
7462 user's command back to the terminal, skipping this if we're setting things
7463 during initialization.
7464
7465 =cut
7466
7467 sub parse_options {
7468     my ($s) = @_;
7469     local $\ = '';
7470
7471     my $option;
7472
7473     # These options need a value. Don't allow them to be clobbered by accident.
7474     my %opt_needs_val = map { ( $_ => 1 ) } qw{
7475       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
7476       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
7477     };
7478
7479     while (length($s)) {
7480         my $val_defaulted;
7481
7482         # Clean off excess leading whitespace.
7483         $s =~ s/^\s+// && next;
7484
7485         # Options are always all word characters, followed by a non-word
7486         # separator.
7487         if ($s !~ s/^(\w+)(\W?)//) {
7488             print {$OUT} "Invalid option '$s'\n";
7489             last;
7490         }
7491         my ( $opt, $sep ) = ( $1, $2 );
7492
7493         # Make sure that such an option exists.
7494         my $matches = ( grep { /^\Q$opt/ && ( $option = $_ ) } @options )
7495           || ( grep { /^\Q$opt/i && ( $option = $_ ) } @options );
7496
7497         unless ($matches) {
7498             print {$OUT} "Unknown option '$opt'\n";
7499             next;
7500         }
7501         if ($matches > 1) {
7502             print {$OUT} "Ambiguous option '$opt'\n";
7503             next;
7504         }
7505         my $val;
7506
7507         # '?' as separator means query, but must have whitespace after it.
7508         if ( "?" eq $sep ) {
7509             if ($s =~ /\A\S/) {
7510                 print {$OUT} "Option query '$opt?' followed by non-space '$s'\n" ;
7511
7512                 last;
7513             }
7514
7515             #&dump_option($opt);
7516         } ## end if ("?" eq $sep)
7517
7518         # Separator is whitespace (or just a carriage return).
7519         # They're going for a default, which we assume is 1.
7520         elsif ( $sep !~ /\S/ ) {
7521             $val_defaulted = 1;
7522             $val           = "1";   #  this is an evil default; make 'em set it!
7523         }
7524
7525         # Separator is =. Trying to set a value.
7526         elsif ( $sep eq "=" ) {
7527
7528             # If quoted, extract a quoted string.
7529             if ($s =~ s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
7530                 my $quote = $1;
7531                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
7532             }
7533
7534             # Not quoted. Use the whole thing. Warn about 'option='.
7535             else {
7536                 $s =~ s/^(\S*)//;
7537                 $val = $1;
7538                 print OUT qq(Option better cleared using $opt=""\n)
7539                   unless length $val;
7540             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
7541
7542         } ## end elsif ($sep eq "=")
7543
7544         # "Quoted" with [], <>, or {}.
7545         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
7546             my ($end) =
7547               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
7548             $s =~ s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
7549               or print( $OUT "Unclosed option value '$opt$sep$_'\n" ), last;
7550             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
7551         } ## end else [ if ("?" eq $sep)
7552
7553         # Exclude non-booleans from getting set to 1 by default.
7554         if ( $opt_needs_val{$option} && $val_defaulted ) {
7555             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
7556             print {$OUT}
7557 "Option '$opt' is non-boolean.  Use '$cmd $option=VAL' to set, '$cmd $option?' to query\n";
7558             next;
7559         } ## end if ($opt_needs_val{$option...
7560
7561         # Save the option value.
7562         $option{$option} = $val if defined $val;
7563
7564         # Load any module that this option requires.
7565         if ( defined($optionRequire{$option}) && defined($val) ) {
7566             eval qq{
7567             local \$frame = 0;
7568             local \$doret = -2;
7569             require '$optionRequire{$option}';
7570             1;
7571             } || die $@   # XXX: shouldn't happen
7572         }
7573
7574         # Set it.
7575         # Stick it in the proper variable if it goes in a variable.
7576         if (defined($optionVars{$option}) && defined($val)) {
7577             ${ $optionVars{$option} } = $val;
7578         }
7579
7580         # Call the appropriate sub if it gets set via sub.
7581         if (defined($optionAction{$option})
7582           && defined (&{ $optionAction{$option} })
7583           && defined ($val))
7584         {
7585           &{ $optionAction{$option} }($val);
7586         }
7587
7588         # Not initialization - echo the value we set it to.
7589         dump_option($option) if ($OUT ne \*STDERR);
7590     } ## end while (length)
7591 } ## end sub parse_options
7592
7593 =head1 RESTART SUPPORT
7594
7595 These routines are used to store (and restore) lists of items in environment
7596 variables during a restart.
7597
7598 =head2 set_list
7599
7600 Set_list packages up items to be stored in a set of environment variables
7601 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
7602 the values). Values outside the standard ASCII charset are stored by encoding
7603 them as hexadecimal values.
7604
7605 =cut
7606
7607 sub set_list {
7608     my ( $stem, @list ) = @_;
7609     my $val;
7610
7611     # VAR_n: how many we have. Scalar assignment gets the number of items.
7612     $ENV{"${stem}_n"} = @list;
7613
7614     # Grab each item in the list, escape the backslashes, encode the non-ASCII
7615     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
7616     for my $i ( 0 .. $#list ) {
7617         $val = $list[$i];
7618         $val =~ s/\\/\\\\/g;
7619         no warnings 'experimental::regex_sets';
7620         $val =~ s/ ( (?[ [\000-\xFF] & [:^print:] ]) ) /
7621                                                 "\\0x" . unpack('H2',$1)/xaeg;
7622         $ENV{"${stem}_$i"} = $val;
7623     } ## end for $i (0 .. $#list)
7624 } ## end sub set_list
7625
7626 =head2 get_list
7627
7628 Reverse the set_list operation: grab VAR_n to see how many we should be getting
7629 back, and then pull VAR_0, VAR_1. etc. back out.
7630
7631 =cut
7632
7633 sub get_list {
7634     my $stem = shift;
7635     my @list;
7636     my $n = delete $ENV{"${stem}_n"};
7637     my $val;
7638     for my $i ( 0 .. $n - 1 ) {
7639         $val = delete $ENV{"${stem}_$i"};
7640         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
7641         push @list, $val;
7642     }
7643     @list;
7644 } ## end sub get_list
7645
7646 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
7647
7648 =head2 catch()
7649
7650 The C<catch()> subroutine is the essence of fast and low-impact. We simply
7651 set an already-existing global scalar variable to a constant value. This
7652 avoids allocating any memory possibly in the middle of something that will
7653 get all confused if we do, particularly under I<unsafe signals>.
7654
7655 =cut
7656
7657 sub catch {
7658     $signal = 1;
7659     return;    # Put nothing on the stack - malloc/free land!
7660 }
7661
7662 =head2 C<warn()>
7663
7664 C<warn> emits a warning, by joining together its arguments and printing
7665 them, with couple of fillips.
7666
7667 If the composited message I<doesn't> end with a newline, we automatically
7668 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
7669 to be set to the filehandle to be used to output warnings; it makes no
7670 assumptions about what filehandles are available.
7671
7672 =cut
7673
7674 sub _db_warn {
7675     my ($msg) = join( "", @_ );
7676     $msg .= ": $!\n" unless $msg =~ /\n$/;
7677     local $\ = '';
7678     print $OUT $msg;
7679 } ## end sub warn
7680
7681 *warn = \&_db_warn;
7682
7683 =head1 INITIALIZATION TTY SUPPORT
7684
7685 =head2 C<reset_IN_OUT>
7686
7687 This routine handles restoring the debugger's input and output filehandles
7688 after we've tried and failed to move them elsewhere.  In addition, it assigns
7689 the debugger's output filehandle to $LINEINFO if it was already open there.
7690
7691 =cut
7692
7693 sub reset_IN_OUT {
7694     my $switch_li = $LINEINFO eq $OUT;
7695
7696     # If there's a term and it's able to get a new tty, try to get one.
7697     if ( $term and $term->Features->{newTTY} ) {
7698         ( $IN, $OUT ) = ( shift, shift );
7699         $term->newTTY( $IN, $OUT );
7700     }
7701
7702     # This term can't get a new tty now. Better luck later.
7703     elsif ($term) {
7704         _db_warn("Too late to set IN/OUT filehandles, enabled on next 'R'!\n");
7705     }
7706
7707     # Set the filehndles up as they were.
7708     else {
7709         ( $IN, $OUT ) = ( shift, shift );
7710     }
7711
7712     # Unbuffer the output filehandle.
7713     _autoflush($OUT);
7714
7715     # Point LINEINFO to the same output filehandle if it was there before.
7716     $LINEINFO = $OUT if $switch_li;
7717 } ## end sub reset_IN_OUT
7718
7719 =head1 OPTION SUPPORT ROUTINES
7720
7721 The following routines are used to process some of the more complicated
7722 debugger options.
7723
7724 =head2 C<TTY>
7725
7726 Sets the input and output filehandles to the specified files or pipes.
7727 If the terminal supports switching, we go ahead and do it. If not, and
7728 there's already a terminal in place, we save the information to take effect
7729 on restart.
7730
7731 If there's no terminal yet (for instance, during debugger initialization),
7732 we go ahead and set C<$console> and C<$tty> to the file indicated.
7733
7734 =cut
7735
7736 sub TTY {
7737
7738     if ( @_ and $term and $term->Features->{newTTY} ) {
7739
7740         # This terminal supports switching to a new TTY.
7741         # Can be a list of two files, or on string containing both names,
7742         # comma-separated.
7743         # XXX Should this perhaps be an assignment from @_?
7744         my ( $in, $out ) = shift;
7745         if ( $in =~ /,/ ) {
7746
7747             # Split list apart if supplied.
7748             ( $in, $out ) = split /,/, $in, 2;
7749         }
7750         else {
7751
7752             # Use the same file for both input and output.
7753             $out = $in;
7754         }
7755
7756         # Open file onto the debugger's filehandles, if you can.
7757         open IN,  '<', $in or die "cannot open '$in' for read: $!";
7758         open OUT, '>', $out or die "cannot open '$out' for write: $!";
7759
7760         # Swap to the new filehandles.
7761         reset_IN_OUT( \*IN, \*OUT );
7762
7763         # Save the setting for later.
7764         return $tty = $in;
7765     } ## end if (@_ and $term and $term...
7766
7767     # Terminal doesn't support new TTY, or doesn't support readline.
7768     # Can't do it now, try restarting.
7769     if ($term and @_) {
7770         _db_warn("Too late to set TTY, enabled on next 'R'!\n");
7771     }
7772
7773     # Useful if done through PERLDB_OPTS:
7774     $console = $tty = shift if @_;
7775
7776     # Return whatever the TTY is.
7777     $tty or $console;
7778 } ## end sub TTY
7779
7780 =head2 C<noTTY>
7781
7782 Sets the C<$notty> global, controlling whether or not the debugger tries to
7783 get a terminal to read from. If called after a terminal is already in place,
7784 we save the value to use it if we're restarted.
7785
7786 =cut
7787
7788 sub noTTY {
7789     if ($term) {
7790         _db_warn("Too late to set noTTY, enabled on next 'R'!\n") if @_;
7791     }
7792     $notty = shift if @_;
7793     $notty;
7794 } ## end sub noTTY
7795
7796 =head2 C<ReadLine>
7797
7798 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
7799 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
7800 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
7801 the value in case a restart is done so we can change it then.
7802
7803 =cut
7804
7805 sub ReadLine {
7806     if ($term) {
7807         _db_warn("Too late to set ReadLine, enabled on next 'R'!\n") if @_;
7808     }
7809     $rl = shift if @_;
7810     $rl;
7811 } ## end sub ReadLine
7812
7813 =head2 C<RemotePort>
7814
7815 Sets the port that the debugger will try to connect to when starting up.
7816 If the terminal's already been set up, we can't do it, but we remember the
7817 setting in case the user does a restart.
7818
7819 =cut
7820
7821 sub RemotePort {
7822     if ($term) {
7823         _db_warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
7824     }
7825     $remoteport = shift if @_;
7826     $remoteport;
7827 } ## end sub RemotePort
7828
7829 =head2 C<tkRunning>
7830
7831 Checks with the terminal to see if C<Tk> is running, and returns true or
7832 false. Returns false if the current terminal doesn't support C<readline>.
7833
7834 =cut
7835
7836 sub tkRunning {
7837     if ( ${ $term->Features }{tkRunning} ) {
7838         return $term->tkRunning(@_);
7839     }
7840     else {
7841         local $\ = '';
7842         print $OUT "tkRunning not supported by current ReadLine package.\n";
7843         0;
7844     }
7845 } ## end sub tkRunning
7846
7847 =head2 C<NonStop>
7848
7849 Sets nonstop mode. If a terminal's already been set up, it's too late; the
7850 debugger remembers the setting in case you restart, though.
7851
7852 =cut
7853
7854 sub NonStop {
7855     if ($term) {
7856         _db_warn("Too late to set up NonStop mode, enabled on next 'R'!\n")
7857           if @_;
7858     }
7859     $runnonstop = shift if @_;
7860     $runnonstop;
7861 } ## end sub NonStop
7862
7863 sub DollarCaretP {
7864     if ($term) {
7865         _db_warn("Some flag changes could not take effect until next 'R'!\n")
7866           if @_;
7867     }
7868     $^P = parse_DollarCaretP_flags(shift) if @_;
7869     expand_DollarCaretP_flags($^P);
7870 }
7871
7872 =head2 C<pager>
7873
7874 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
7875 there already.
7876
7877 =cut
7878
7879 sub pager {
7880     if (@_) {
7881         $pager = shift;
7882         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
7883     }
7884     $pager;
7885 } ## end sub pager
7886
7887 =head2 C<shellBang>
7888
7889 Sets the shell escape command, and generates a printable copy to be used
7890 in the help.
7891
7892 =cut
7893
7894 sub shellBang {
7895
7896     # If we got an argument, meta-quote it, and add '\b' if it
7897     # ends in a word character.
7898     if (@_) {
7899         $sh = quotemeta shift;
7900         $sh .= "\\b" if $sh =~ /\w$/;
7901     }
7902
7903     # Generate the printable version for the help:
7904     $psh = $sh;    # copy it
7905     $psh =~ s/\\b$//;        # Take off trailing \b if any
7906     $psh =~ s/\\(.)/$1/g;    # De-escape
7907     $psh;                    # return the printable version
7908 } ## end sub shellBang
7909
7910 =head2 C<ornaments>
7911
7912 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7913 was passed as the argument. (This means you can't override the terminal's
7914 ornaments.)
7915
7916 =cut
7917
7918 sub ornaments {
7919     if ( defined $term ) {
7920
7921         # We don't want to show warning backtraces, but we do want die() ones.
7922         local $warnLevel = 0;
7923         local $dieLevel = 1;
7924
7925         # No ornaments if the terminal doesn't support them.
7926         if (not $term->Features->{ornaments}) {
7927             return '';
7928         }
7929
7930         return (eval { $term->ornaments(@_) } || '');
7931     }
7932
7933     # Use what was passed in if we can't determine it ourselves.
7934     else {
7935         $ornaments = shift;
7936
7937         return $ornaments;
7938     }
7939
7940 } ## end sub ornaments
7941
7942 =head2 C<recallCommand>
7943
7944 Sets the recall command, and builds a printable version which will appear in
7945 the help text.
7946
7947 =cut
7948
7949 sub recallCommand {
7950
7951     # If there is input, metaquote it. Add '\b' if it ends with a word
7952     # character.
7953     if (@_) {
7954         $rc = quotemeta shift;
7955         $rc .= "\\b" if $rc =~ /\w$/;
7956     }
7957
7958     # Build it into a printable version.
7959     $prc = $rc;              # Copy it
7960     $prc =~ s/\\b$//;        # Remove trailing \b
7961     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7962     return $prc;             # Return the printable version
7963 } ## end sub recallCommand
7964
7965 =head2 C<LineInfo> - where the line number information goes
7966
7967 Called with no arguments, returns the file or pipe that line info should go to.
7968
7969 Called with an argument (a file or a pipe), it opens that onto the
7970 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7971 file or pipe again to the caller.
7972
7973 =cut
7974
7975 sub LineInfo {
7976     if (@_) {
7977         $lineinfo = shift;
7978
7979         #  If this is a valid "thing to be opened for output", tack a
7980         # '>' onto the front.
7981         my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7982
7983         # If this is a pipe, the stream points to a slave editor.
7984         $slave_editor = ( $stream =~ /^\|/ );
7985
7986         my $new_lineinfo_fh;
7987         # Open it up and unbuffer it.
7988         open ($new_lineinfo_fh , $stream )
7989             or _db_warn("Cannot open '$stream' for write");
7990         $LINEINFO = $new_lineinfo_fh;
7991         _autoflush($LINEINFO);
7992     }
7993
7994     return $lineinfo;
7995 } ## end sub LineInfo
7996
7997 =head1 COMMAND SUPPORT ROUTINES
7998
7999 These subroutines provide functionality for various commands.
8000
8001 =head2 C<list_modules>
8002
8003 For the C<M> command: list modules loaded and their versions.
8004 Essentially just runs through the keys in %INC, picks each package's
8005 C<$VERSION> variable, gets the file name, and formats the information
8006 for output.
8007
8008 =cut
8009
8010 sub list_modules {    # versions
8011     my %version;
8012     my $file;
8013
8014     # keys are the "as-loaded" name, values are the fully-qualified path
8015     # to the file itself.
8016     for ( keys %INC ) {
8017         $file = $_;                                # get the module name
8018         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
8019         s,/,::,g;                                  # change '/' to '::'
8020         s/^perl5db$/DB/;                           # Special case: debugger
8021                                                    # moves to package DB
8022         s/^Term::ReadLine::readline$/readline/;    # simplify readline
8023
8024         # If the package has a $VERSION package global (as all good packages
8025         # should!) decode it and save as partial message.
8026         my $pkg_version = do { no strict 'refs'; ${ $_ . '::VERSION' } };
8027         if ( defined $pkg_version ) {
8028             $version{$file} = "$pkg_version from ";
8029         }
8030
8031         # Finish up the message with the file the package came from.
8032         $version{$file} .= $INC{$file};
8033     } ## end for (keys %INC)
8034
8035     # Hey, dumpit() formats a hash nicely, so why not use it?
8036     dumpit( $OUT, \%version );
8037 } ## end sub list_modules
8038
8039 =head2 C<sethelp()>
8040
8041 Sets up the monster string used to format and print the help.
8042
8043 =head3 HELP MESSAGE FORMAT
8044
8045 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
8046 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
8047 easy to parse and portable, but which still allows the help to be a little
8048 nicer than just plain text.
8049
8050 Essentially, you define the command name (usually marked up with C<< B<> >>
8051 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
8052 newline. The descriptive text can also be marked up in the same way. If you
8053 need to continue the descriptive text to another line, start that line with
8054 just tabs and then enter the marked-up text.
8055
8056 If you are modifying the help text, I<be careful>. The help-string parser is
8057 not very sophisticated, and if you don't follow these rules it will mangle the
8058 help beyond hope until you fix the string.
8059
8060 =cut
8061
8062 use vars qw($pre580_help);
8063 use vars qw($pre580_summary);
8064
8065 sub sethelp {
8066
8067     # XXX: make sure there are tabs between the command and explanation,
8068     #      or print_help will screw up your formatting if you have
8069     #      eeevil ornaments enabled.  This is an insane mess.
8070
8071     $help = "
8072 Help is currently only available for the new 5.8 command set.
8073 No help is available for the old command set.
8074 We assume you know what you're doing if you switch to it.
8075
8076 B<T>        Stack trace.
8077 B<s> [I<expr>]    Single step [in I<expr>].
8078 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
8079 <B<CR>>        Repeat last B<n> or B<s> command.
8080 B<r>        Return from current subroutine.
8081 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
8082         at the specified position.
8083 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
8084 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
8085 B<l> I<line>        List single I<line>.
8086 B<l> I<subname>    List first window of lines from subroutine.
8087 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
8088 B<l>        List next window of lines.
8089 B<->        List previous window of lines.
8090 B<v> [I<line>]    View window around I<line>.
8091 B<.>        Return to the executed line.
8092 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
8093         I<filename> may be either the full name of the file, or a regular
8094         expression matching the full file name:
8095         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
8096         Evals (with saved bodies) are considered to be filenames:
8097         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
8098         (in the order of execution).
8099 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
8100 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
8101 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
8102 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
8103 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth).
8104 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
8105 B<b>        Sets breakpoint on current line)
8106 B<b> [I<line>] [I<condition>]
8107         Set breakpoint; I<line> defaults to the current execution line;
8108         I<condition> breaks if it evaluates to true, defaults to '1'.
8109 B<b> I<subname> [I<condition>]
8110         Set breakpoint at first line of subroutine.
8111 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
8112 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
8113 B<b> B<postpone> I<subname> [I<condition>]
8114         Set breakpoint at first line of subroutine after
8115         it is compiled.
8116 B<b> B<compile> I<subname>
8117         Stop after the subroutine is compiled.
8118 B<B> [I<line>]    Delete the breakpoint for I<line>.
8119 B<B> I<*>             Delete all breakpoints.
8120 B<a> [I<line>] I<command>
8121         Set an action to be done before the I<line> is executed;
8122         I<line> defaults to the current execution line.
8123         Sequence is: check for breakpoint/watchpoint, print line
8124         if necessary, do action, prompt user if necessary,
8125         execute line.
8126 B<a>        Does nothing
8127 B<A> [I<line>]    Delete the action for I<line>.
8128 B<A> I<*>             Delete all actions.
8129 B<w> I<expr>        Add a global watch-expression.
8130 B<w>             Does nothing
8131 B<W> I<expr>        Delete a global watch-expression.
8132 B<W> I<*>             Delete all watch-expressions.
8133 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
8134         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
8135 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
8136 B<x> I<expr>        Evals expression in list context, dumps the result.
8137 B<m> I<expr>        Evals expression in list context, prints methods callable
8138         on the first element of the result.
8139 B<m> I<class>        Prints methods callable via the given class.
8140 B<M>        Show versions of loaded modules.
8141 B<i> I<class>       Prints nested parents of given class.
8142 B<e>         Display current thread id.
8143 B<E>         Display all thread ids the current one will be identified: <n>.
8144 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8145
8146 B<<> ?            List Perl commands to run before each prompt.
8147 B<<> I<expr>        Define Perl command to run before each prompt.
8148 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
8149 B<< *>                Delete the list of perl commands to run before each prompt.
8150 B<>> ?            List Perl commands to run after each prompt.
8151 B<>> I<expr>        Define Perl command to run after each prompt.
8152 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
8153 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
8154 B<{> I<db_command>    Define debugger command to run before each prompt.
8155 B<{> ?            List debugger commands to run before each prompt.
8156 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
8157 B<{ *>             Delete the list of debugger commands to run before each prompt.
8158 B<$prc> I<number>    Redo a previous command (default previous command).
8159 B<$prc> I<-number>    Redo number'th-to-last command.
8160 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
8161         See 'B<O> I<recallCommand>' too.
8162 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
8163       . (
8164         $rc eq $sh
8165         ? ""
8166         : "
8167 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
8168       ) . "
8169         See 'B<O> I<shellBang>' too.
8170 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
8171 B<save> I<file>       Save current debugger session (actual history) to I<file>.
8172 B<rerun>           Rerun session to current position.
8173 B<rerun> I<n>         Rerun session to numbered command.
8174 B<rerun> I<-n>        Rerun session to number'th-to-last command.
8175 B<H> I<-number>    Display last number commands (default all).
8176 B<H> I<*>          Delete complete history.
8177 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
8178 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
8179 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarily select()ed as well.
8180 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
8181 I<command>        Execute as a perl statement in current package.
8182 B<R>        Pure-man-restart of debugger, some of debugger state
8183         and command-line options may be lost.
8184         Currently the following settings are preserved:
8185         history, breakpoints and actions, debugger B<O>ptions
8186         and the following command-line options: I<-w>, I<-I>, I<-e>.
8187
8188 B<o> [I<opt>] ...    Set boolean option to true
8189 B<o> [I<opt>B<?>]    Query options
8190 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
8191         Set options.  Use quotes if spaces in value.
8192     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
8193     I<pager>            program for output of \"|cmd\";
8194     I<tkRunning>            run Tk while prompting (with ReadLine);
8195     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
8196     I<inhibit_exit>        Allows stepping off the end of the script.
8197     I<ImmediateStop>        Debugger should stop as early as possible.
8198     I<RemotePort>            Remote hostname:port for remote debugging
8199   The following options affect what happens with B<V>, B<X>, and B<x> commands:
8200     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
8201     I<compactDump>, I<veryCompact>     change style of array and hash dump;
8202     I<globPrint>             whether to print contents of globs;
8203     I<DumpDBFiles>         dump arrays holding debugged files;
8204     I<DumpPackages>         dump symbol tables of packages;
8205     I<DumpReused>             dump contents of \"reused\" addresses;
8206     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
8207     I<bareStringify>         Do not print the overload-stringified value;
8208   Other options include:
8209     I<PrintRet>        affects printing of return value after B<r> command,
8210     I<frame>        affects printing messages on subroutine entry/exit.
8211     I<AutoTrace>    affects printing messages on possible breaking points.
8212     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
8213     I<ornaments>     affects screen appearance of the command line.
8214     I<CreateTTY>     bits control attempts to create a new TTY on events:
8215             1: on fork()    2: debugger is started inside debugger
8216             4: on startup
8217     During startup options are initialized from \$ENV{PERLDB_OPTS}.
8218     You can put additional initialization options I<TTY>, I<noTTY>,
8219     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
8220     B<R> after you set them).
8221
8222 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
8223 B<h>        Summary of debugger commands.
8224 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
8225 B<h h>        Long help for debugger commands
8226 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
8227         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
8228         Set B<\$DB::doccmd> to change viewer.
8229
8230 Type '|h h' for a paged display if this was too hard to read.
8231
8232 ";    # Fix balance of vi % matching: }}}}
8233
8234     #  note: tabs in the following section are not-so-helpful
8235     $summary = <<"END_SUM";
8236 I<List/search source lines:>               I<Control script execution:>
8237   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
8238   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
8239   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
8240   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
8241   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
8242   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
8243 I<Debugger controls:>                        B<L>           List break/watch/actions
8244   B<o> [...]     Set debugger options        B<t> [I<n>] [I<expr>] Toggle trace [max depth] ][trace expr]
8245   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
8246   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
8247   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
8248   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
8249   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
8250   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
8251   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
8252   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
8253 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
8254   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
8255   B<p> I<expr>         Print expression (uses script's current package).
8256   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
8257   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
8258   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
8259   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8260   B<e>     Display thread id     B<E> Display all thread ids.
8261 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
8262 END_SUM
8263
8264     # ')}}; # Fix balance of vi % matching
8265
8266     # and this is really numb...
8267     $pre580_help = "
8268 B<T>        Stack trace.
8269 B<s> [I<expr>]    Single step [in I<expr>].
8270 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
8271 B<CR>>        Repeat last B<n> or B<s> command.
8272 B<r>        Return from current subroutine.
8273 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
8274         at the specified position.
8275 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
8276 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
8277 B<l> I<line>        List single I<line>.
8278 B<l> I<subname>    List first window of lines from subroutine.
8279 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
8280 B<l>        List next window of lines.
8281 B<->        List previous window of lines.
8282 B<w> [I<line>]    List window around I<line>.
8283 B<.>        Return to the executed line.
8284 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
8285         I<filename> may be either the full name of the file, or a regular
8286         expression matching the full file name:
8287         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
8288         Evals (with saved bodies) are considered to be filenames:
8289         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
8290         (in the order of execution).
8291 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
8292 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
8293 B<L>        List all breakpoints and actions.
8294 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
8295 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth) .
8296 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
8297 B<b> [I<line>] [I<condition>]
8298         Set breakpoint; I<line> defaults to the current execution line;
8299         I<condition> breaks if it evaluates to true, defaults to '1'.
8300 B<b> I<subname> [I<condition>]
8301         Set breakpoint at first line of subroutine.
8302 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
8303 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
8304 B<b> B<postpone> I<subname> [I<condition>]
8305         Set breakpoint at first line of subroutine after
8306         it is compiled.
8307 B<b> B<compile> I<subname>
8308         Stop after the subroutine is compiled.
8309 B<d> [I<line>]    Delete the breakpoint for I<line>.
8310 B<D>        Delete all breakpoints.
8311 B<a> [I<line>] I<command>
8312         Set an action to be done before the I<line> is executed;
8313         I<line> defaults to the current execution line.
8314         Sequence is: check for breakpoint/watchpoint, print line
8315         if necessary, do action, prompt user if necessary,
8316         execute line.
8317 B<a> [I<line>]    Delete the action for I<line>.
8318 B<A>        Delete all actions.
8319 B<W> I<expr>        Add a global watch-expression.
8320 B<W>        Delete all watch-expressions.
8321 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
8322         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
8323 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
8324 B<x> I<expr>        Evals expression in list context, dumps the result.
8325 B<m> I<expr>        Evals expression in list context, prints methods callable
8326         on the first element of the result.
8327 B<m> I<class>        Prints methods callable via the given class.
8328
8329 B<<> ?            List Perl commands to run before each prompt.
8330 B<<> I<expr>        Define Perl command to run before each prompt.
8331 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
8332 B<>> ?            List Perl commands to run after each prompt.
8333 B<>> I<expr>        Define Perl command to run after each prompt.
8334 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
8335 B<{> I<db_command>    Define debugger command to run before each prompt.
8336 B<{> ?            List debugger commands to run before each prompt.
8337 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
8338 B<$prc> I<number>    Redo a previous command (default previous command).
8339 B<$prc> I<-number>    Redo number'th-to-last command.
8340 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
8341         See 'B<O> I<recallCommand>' too.
8342 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
8343       . (
8344         $rc eq $sh
8345         ? ""
8346         : "
8347 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
8348       ) . "
8349         See 'B<O> I<shellBang>' too.
8350 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
8351 B<H> I<-number>    Display last number commands (default all).
8352 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
8353 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
8354 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
8355 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
8356 I<command>        Execute as a perl statement in current package.
8357 B<v>        Show versions of loaded modules.
8358 B<R>        Pure-man-restart of debugger, some of debugger state
8359         and command-line options may be lost.
8360         Currently the following settings are preserved:
8361         history, breakpoints and actions, debugger B<O>ptions
8362         and the following command-line options: I<-w>, I<-I>, I<-e>.
8363
8364 B<O> [I<opt>] ...    Set boolean option to true
8365 B<O> [I<opt>B<?>]    Query options
8366 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
8367         Set options.  Use quotes if spaces in value.
8368     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
8369     I<pager>            program for output of \"|cmd\";
8370     I<tkRunning>            run Tk while prompting (with ReadLine);
8371     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
8372     I<inhibit_exit>        Allows stepping off the end of the script.
8373     I<ImmediateStop>        Debugger should stop as early as possible.
8374     I<RemotePort>            Remote hostname:port for remote debugging
8375   The following options affect what happens with B<V>, B<X>, and B<x> commands:
8376     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
8377     I<compactDump>, I<veryCompact>     change style of array and hash dump;
8378     I<globPrint>             whether to print contents of globs;
8379     I<DumpDBFiles>         dump arrays holding debugged files;
8380     I<DumpPackages>         dump symbol tables of packages;
8381     I<DumpReused>             dump contents of \"reused\" addresses;
8382     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
8383     I<bareStringify>         Do not print the overload-stringified value;
8384   Other options include:
8385     I<PrintRet>        affects printing of return value after B<r> command,
8386     I<frame>        affects printing messages on subroutine entry/exit.
8387     I<AutoTrace>    affects printing messages on possible breaking points.
8388     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
8389     I<ornaments>     affects screen appearance of the command line.
8390     I<CreateTTY>     bits control attempts to create a new TTY on events:
8391             1: on fork()    2: debugger is started inside debugger
8392             4: on startup
8393     During startup options are initialized from \$ENV{PERLDB_OPTS}.
8394     You can put additional initialization options I<TTY>, I<noTTY>,
8395     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
8396     B<R> after you set them).
8397
8398 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
8399 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
8400 B<h h>        Summary of debugger commands.
8401 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
8402         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
8403         Set B<\$DB::doccmd> to change viewer.
8404
8405 Type '|h' for a paged display if this was too hard to read.
8406
8407 ";    # Fix balance of vi % matching: }}}}
8408
8409     #  note: tabs in the following section are not-so-helpful
8410     $pre580_summary = <<"END_SUM";
8411 I<List/search source lines:>               I<Control script execution:>
8412   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
8413   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
8414   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
8415   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
8416   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
8417   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
8418 I<Debugger controls:>                        B<L>           List break/watch/actions
8419   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
8420   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
8421   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
8422   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
8423   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
8424   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
8425   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
8426   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
8427 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
8428   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
8429   B<p> I<expr>         Print expression (uses script's current package).
8430   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
8431   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
8432   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
8433   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8434 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
8435 END_SUM
8436
8437     # ')}}; # Fix balance of vi % matching
8438
8439 } ## end sub sethelp
8440
8441 =head2 C<print_help()>
8442
8443 Most of what C<print_help> does is just text formatting. It finds the
8444 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
8445 terminal control characters to simulate them (courtesy of
8446 C<Term::ReadLine::TermCap>).
8447
8448 =cut
8449
8450 sub print_help {
8451     my $help_str = shift;
8452
8453     # Restore proper alignment destroyed by eeevil I<> and B<>
8454     # ornaments: A pox on both their houses!
8455     #
8456     # A help command will have everything up to and including
8457     # the first tab sequence padded into a field 16 (or if indented 20)
8458     # wide.  If it's wider than that, an extra space will be added.
8459     $help_str =~ s{
8460         ^                       # only matters at start of line
8461           ( \ {4} | \t )*       # some subcommands are indented
8462           ( < ?                 # so <CR> works
8463             [BI] < [^\t\n] + )  # find an eeevil ornament
8464           ( \t+ )               # original separation, discarded
8465           ( .* )                # this will now start (no earlier) than
8466                                 # column 16
8467     } {
8468         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
8469         my $clean = $command;
8470         $clean =~ s/[BI]<([^>]*)>/$1/g;
8471
8472         # replace with this whole string:
8473         ($leadwhite ? " " x 4 : "")
8474       . $command
8475       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
8476       . $text;
8477
8478     }mgex;
8479
8480     $help_str =~ s{                          # handle bold ornaments
8481        B < ( [^>] + | > ) >
8482     } {
8483           $Term::ReadLine::TermCap::rl_term_set[2]
8484         . $1
8485         . $Term::ReadLine::TermCap::rl_term_set[3]
8486     }gex;
8487
8488     $help_str =~ s{                         # handle italic ornaments
8489        I < ( [^>] + | > ) >
8490     } {
8491           $Term::ReadLine::TermCap::rl_term_set[0]
8492         . $1
8493         . $Term::ReadLine::TermCap::rl_term_set[1]
8494     }gex;
8495
8496     local $\ = '';
8497     print {$OUT} $help_str;
8498
8499     return;
8500 } ## end sub print_help
8501
8502 =head2 C<fix_less>
8503
8504 This routine does a lot of gyrations to be sure that the pager is C<less>.
8505 It checks for C<less> masquerading as C<more> and records the result in
8506 C<$fixed_less> so we don't have to go through doing the stats again.
8507
8508 =cut
8509
8510 use vars qw($fixed_less);
8511
8512 sub _calc_is_less {
8513     if ($pager =~ /\bless\b/)
8514     {
8515         return 1;
8516     }
8517     elsif ($pager =~ /\bmore\b/)
8518     {
8519         # Nope, set to more. See what's out there.
8520         my @st_more = stat('/usr/bin/more');
8521         my @st_less = stat('/usr/bin/less');
8522
8523         # is it really less, pretending to be more?
8524         return (
8525             @st_more
8526             && @st_less
8527             && $st_more[0] == $st_less[0]
8528             && $st_more[1] == $st_less[1]
8529         );
8530     }
8531     else {
8532         return;
8533     }
8534 }
8535
8536 sub fix_less {
8537
8538     # We already know if this is set.
8539     return if $fixed_less;
8540
8541     # changes environment!
8542     # 'r' added so we don't do (slow) stats again.
8543     $fixed_less = 1 if _calc_is_less();
8544
8545     return;
8546 } ## end sub fix_less
8547
8548 =head1 DIE AND WARN MANAGEMENT
8549
8550 =head2 C<diesignal>
8551
8552 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
8553 to debug a debugger problem.
8554
8555 It does its best to report the error that occurred, and then forces the
8556 program, debugger, and everything to die.
8557
8558 =cut
8559
8560 sub diesignal {
8561
8562     # No entry/exit messages.
8563     local $frame = 0;
8564
8565     # No return value prints.
8566     local $doret = -2;
8567
8568     # set the abort signal handling to the default (just terminate).
8569     $SIG{'ABRT'} = 'DEFAULT';
8570
8571     # If we enter the signal handler recursively, kill myself with an
8572     # abort signal (so we just terminate).
8573     kill 'ABRT', $$ if $panic++;
8574
8575     # If we can show detailed info, do so.
8576     if ( defined &Carp::longmess ) {
8577
8578         # Don't recursively enter the warn handler, since we're carping.
8579         local $SIG{__WARN__} = '';
8580
8581         # Skip two levels before reporting traceback: we're skipping
8582         # mydie and confess.
8583         local $Carp::CarpLevel = 2;    # mydie + confess
8584
8585         # Tell us all about it.
8586         _db_warn( Carp::longmess("Signal @_") );
8587     }
8588
8589     # No Carp. Tell us about the signal as best we can.
8590     else {
8591         local $\ = '';
8592         print $DB::OUT "Got signal @_\n";
8593     }
8594
8595     # Drop dead.
8596     kill 'ABRT', $$;
8597 } ## end sub diesignal
8598
8599 =head2 C<dbwarn>
8600
8601 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
8602 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
8603
8604 =cut
8605
8606 sub dbwarn {
8607
8608     # No entry/exit trace.
8609     local $frame = 0;
8610
8611     # No return value printing.
8612     local $doret = -2;
8613
8614     # Turn off warn and die handling to prevent recursive entries to this
8615     # routine.
8616     local $SIG{__WARN__} = '';
8617     local $SIG{__DIE__}  = '';
8618
8619     # Load Carp if we can. If $^S is false (current thing being compiled isn't
8620     # done yet), we may not be able to do a require.
8621     eval { require Carp }
8622       if defined $^S;    # If error/warning during compilation,
8623                          # require may be broken.
8624
8625     # Use the core warn() unless Carp loaded OK.
8626     CORE::warn( @_,
8627         "\nCannot print stack trace, load with -MCarp option to see stack" ),
8628       return
8629       unless defined &Carp::longmess;
8630
8631     # Save the current values of $single and $trace, and then turn them off.
8632     my ( $mysingle, $mytrace ) = ( $single, $trace );
8633     $single = 0;
8634     $trace  = 0;
8635
8636     # We can call Carp::longmess without its being "debugged" (which we
8637     # don't want - we just want to use it!). Capture this for later.
8638     my $mess = Carp::longmess(@_);
8639
8640     # Restore $single and $trace to their original values.
8641     ( $single, $trace ) = ( $mysingle, $mytrace );
8642
8643     # Use the debugger's own special way of printing warnings to print
8644     # the stack trace message.
8645     _db_warn($mess);
8646 } ## end sub dbwarn
8647
8648 =head2 C<dbdie>
8649
8650 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
8651 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
8652 single stepping and tracing during the call to C<Carp::longmess> to avoid
8653 debugging it - we just want to use it.
8654
8655 If C<dieLevel> is zero, we let the program being debugged handle the
8656 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
8657 the debugger takes over all exception handling, printing a backtrace and
8658 displaying the exception via its C<dbwarn()> routine.
8659
8660 =cut
8661
8662 sub dbdie {
8663     local $frame         = 0;
8664     local $doret         = -2;
8665     local $SIG{__DIE__}  = '';
8666     local $SIG{__WARN__} = '';
8667     if ( $dieLevel > 2 ) {
8668         local $SIG{__WARN__} = \&dbwarn;
8669         _db_warn(@_);    # Yell no matter what
8670         return;
8671     }
8672     if ( $dieLevel < 2 ) {
8673         die @_ if $^S;    # in eval propagate
8674     }
8675
8676     # The code used to check $^S to see if compilation of the current thing
8677     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
8678     eval { require Carp };
8679
8680     die( @_,
8681         "\nCannot print stack trace, load with -MCarp option to see stack" )
8682       unless defined &Carp::longmess;
8683
8684     # We do not want to debug this chunk (automatic disabling works
8685     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
8686     # get the stack trace from Carp::longmess (if possible), restore $signal
8687     # and $trace, and then die with the stack trace.
8688     my ( $mysingle, $mytrace ) = ( $single, $trace );
8689     $single = 0;
8690     $trace  = 0;
8691     my $mess = "@_";
8692     {
8693
8694         package Carp;    # Do not include us in the list
8695         eval { $mess = Carp::longmess(@_); };
8696     }
8697     ( $single, $trace ) = ( $mysingle, $mytrace );
8698     die $mess;
8699 } ## end sub dbdie
8700
8701 =head2 C<warnlevel()>
8702
8703 Set the C<$DB::warnLevel> variable that stores the value of the
8704 C<warnLevel> option. Calling C<warnLevel()> with a positive value
8705 results in the debugger taking over all warning handlers. Setting
8706 C<warnLevel> to zero leaves any warning handlers set up by the program
8707 being debugged in place.
8708
8709 =cut
8710
8711 sub warnLevel {
8712     if (@_) {
8713         my $prevwarn = $SIG{__WARN__} unless $warnLevel;
8714         $warnLevel = shift;
8715         if ($warnLevel) {
8716             $SIG{__WARN__} = \&DB::dbwarn;
8717         }
8718         elsif ($prevwarn) {
8719             $SIG{__WARN__} = $prevwarn;
8720         } else {
8721             undef $SIG{__WARN__};
8722         }
8723     } ## end if (@_)
8724     $warnLevel;
8725 } ## end sub warnLevel
8726
8727 =head2 C<dielevel>
8728
8729 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
8730 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
8731 zero lets you use your own C<die()> handler.
8732
8733 =cut
8734
8735 sub dieLevel {
8736     local $\ = '';
8737     if (@_) {
8738         my $prevdie = $SIG{__DIE__} unless $dieLevel;
8739         $dieLevel = shift;
8740         if ($dieLevel) {
8741
8742             # Always set it to dbdie() for non-zero values.
8743             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
8744
8745             # No longer exists, so don't try  to use it.
8746             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
8747
8748             # If we've finished initialization, mention that stack dumps
8749             # are enabled, If dieLevel is 1, we won't stack dump if we die
8750             # in an eval().
8751             print $OUT "Stack dump during die enabled",
8752               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
8753               if $I_m_init;
8754
8755             # XXX This is probably obsolete, given that diehard() is gone.
8756             print $OUT "Dump printed too.\n" if $dieLevel > 2;
8757         } ## end if ($dieLevel)
8758
8759         # Put the old one back if there was one.
8760         elsif ($prevdie) {
8761             $SIG{__DIE__} = $prevdie;
8762             print $OUT "Default die handler restored.\n";
8763         } else {
8764             undef $SIG{__DIE__};
8765             print $OUT "Die handler removed.\n";
8766         }
8767     } ## end if (@_)
8768     $dieLevel;
8769 } ## end sub dieLevel
8770
8771 =head2 C<signalLevel>
8772
8773 Number three in a series: set C<signalLevel> to zero to keep your own
8774 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
8775 takes over and handles them with C<DB::diesignal()>.
8776
8777 =cut
8778
8779 sub signalLevel {
8780     if (@_) {
8781         my $prevsegv = $SIG{SEGV} unless $signalLevel;
8782         my $prevbus  = $SIG{BUS}  unless $signalLevel;
8783         $signalLevel = shift;
8784         if ($signalLevel) {
8785             $SIG{SEGV} = \&DB::diesignal;
8786             $SIG{BUS}  = \&DB::diesignal;
8787         }
8788         else {
8789             $SIG{SEGV} = $prevsegv;
8790             $SIG{BUS}  = $prevbus;
8791         }
8792     } ## end if (@_)
8793     $signalLevel;
8794 } ## end sub signalLevel
8795
8796 =head1 SUBROUTINE DECODING SUPPORT
8797
8798 These subroutines are used during the C<x> and C<X> commands to try to
8799 produce as much information as possible about a code reference. They use
8800 L<Devel::Peek> to try to find the glob in which this code reference lives
8801 (if it does) - this allows us to actually code references which correspond
8802 to named subroutines (including those aliased via glob assignment).
8803
8804 =head2 C<CvGV_name()>
8805
8806 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
8807 via that routine. If this fails, return the reference again (when the
8808 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
8809
8810 =cut
8811
8812 sub CvGV_name {
8813     my $in   = shift;
8814     my $name = CvGV_name_or_bust($in);
8815     defined $name ? $name : $in;
8816 }
8817
8818 =head2 C<CvGV_name_or_bust> I<coderef>
8819
8820 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
8821 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
8822 find a glob for this ref.
8823
8824 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
8825
8826 =cut
8827
8828 use vars qw($skipCvGV);
8829
8830 sub CvGV_name_or_bust {
8831     my $in = shift;
8832     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
8833     return unless ref $in;
8834     $in = \&$in;            # Hard reference...
8835     eval { require Devel::Peek; 1 } or return;
8836     my $gv = Devel::Peek::CvGV($in) or return;
8837     *$gv{PACKAGE} . '::' . *$gv{NAME};
8838 } ## end sub CvGV_name_or_bust
8839
8840 =head2 C<find_sub>
8841
8842 A utility routine used in various places; finds the file where a subroutine
8843 was defined, and returns that filename and a line-number range.
8844
8845 Tries to use C<@sub> first; if it can't find it there, it tries building a
8846 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
8847 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
8848 this way, it brute-force searches C<%sub>, checking for identical references.
8849
8850 =cut
8851
8852 sub _find_sub_helper {
8853     my $subr = shift;
8854
8855     return unless defined &$subr;
8856     my $name = CvGV_name_or_bust($subr);
8857     my $data;
8858     $data = $sub{$name} if defined $name;
8859     return $data if defined $data;
8860
8861     # Old stupid way...
8862     $subr = \&$subr;    # Hard reference
8863     my $s;
8864     for ( keys %sub ) {
8865         $s = $_, last if $subr eq \&$_;
8866     }
8867     if ($s)
8868     {
8869         return $sub{$s};
8870     }
8871     else
8872     {
8873         return;
8874     }
8875
8876 }
8877
8878 sub find_sub {
8879     my $subr = shift;
8880     return ( $sub{$subr} || _find_sub_helper($subr) );
8881 } ## end sub find_sub
8882
8883 =head2 C<methods>
8884
8885 A subroutine that uses the utility function C<methods_via> to find all the
8886 methods in the class corresponding to the current reference and in
8887 C<UNIVERSAL>.
8888
8889 =cut
8890
8891 use vars qw(%seen);
8892
8893 sub methods {
8894
8895     # Figure out the class - either this is the class or it's a reference
8896     # to something blessed into that class.
8897     my $class = shift;
8898     $class = ref $class if ref $class;
8899
8900     local %seen;
8901
8902     # Show the methods that this class has.
8903     methods_via( $class, '', 1 );
8904
8905     # Show the methods that UNIVERSAL has.
8906     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
8907 } ## end sub methods
8908
8909 =head2 C<methods_via($class, $prefix, $crawl_upward)>
8910
8911 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
8912 all the parent class methods. C<$class> is the name of the next class to
8913 try; C<$prefix> is the message prefix, which gets built up as we go up the
8914 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
8915 higher in the C<@ISA> tree, 0 if we should stop.
8916
8917 =cut
8918
8919 sub methods_via {
8920
8921     # If we've processed this class already, just quit.
8922     my $class = shift;
8923     return if $seen{$class}++;
8924
8925     # This is a package that is contributing the methods we're about to print.
8926     my $prefix  = shift;
8927     my $prepend = $prefix ? "via $prefix: " : '';
8928     my @to_print;
8929
8930     # Extract from all the symbols in this class.
8931     my $class_ref = do { no strict "refs"; \%{$class . '::'} };
8932     while (my ($name, $glob) = each %$class_ref) {
8933         # references directly in the symbol table are Proxy Constant
8934         # Subroutines, and are by their very nature defined
8935         # Otherwise, check if the thing is a typeglob, and if it is, it decays
8936         # to a subroutine reference, which can be tested by defined.
8937         # $glob might also be the value -1  (from sub foo;)
8938         # or (say) '$$' (from sub foo ($$);)
8939         # \$glob will be SCALAR in both cases.
8940         if ((ref $glob || ($glob && ref \$glob eq 'GLOB' && defined &$glob))
8941             && !$seen{$name}++) {
8942             push @to_print, "$prepend$name\n";
8943         }
8944     }
8945
8946     {
8947         local $\ = '';
8948         local $, = '';
8949         print $DB::OUT $_ foreach sort @to_print;
8950     }
8951
8952     # If the $crawl_upward argument is false, just quit here.
8953     return unless shift;
8954
8955     # $crawl_upward true: keep going up the tree.
8956     # Find all the classes this one is a subclass of.
8957     my $class_ISA_ref = do { no strict "refs"; \@{"${class}::ISA"} };
8958     for my $name ( @$class_ISA_ref ) {
8959
8960         # Set up the new prefix.
8961         $prepend = $prefix ? $prefix . " -> $name" : $name;
8962
8963         # Crawl up the tree and keep trying to crawl up.
8964         methods_via( $name, $prepend, 1 );
8965     }
8966 } ## end sub methods_via
8967
8968 =head2 C<setman> - figure out which command to use to show documentation
8969
8970 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8971
8972 =cut
8973
8974 sub setman {
8975     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|NetWare)\z/s
8976       ? "man"         # O Happy Day!
8977       : "perldoc";    # Alas, poor unfortunates
8978 } ## end sub setman
8979
8980 =head2 C<runman> - run the appropriate command to show documentation
8981
8982 Accepts a man page name; runs the appropriate command to display it (set up
8983 during debugger initialization). Uses C<_db_system()> to avoid mucking up the
8984 program's STDIN and STDOUT.
8985
8986 =cut
8987
8988 sub runman {
8989     my $page = shift;
8990     unless ($page) {
8991         _db_system("$doccmd $doccmd");
8992         return;
8993     }
8994
8995     # this way user can override, like with $doccmd="man -Mwhatever"
8996     # or even just "man " to disable the path check.
8997     if ( $doccmd ne 'man' ) {
8998         _db_system("$doccmd $page");
8999         return;
9000     }
9001
9002     $page = 'perl' if lc($page) eq 'help';
9003
9004     require Config;
9005     my $man1dir = $Config::Config{man1direxp};
9006     my $man3dir = $Config::Config{man3direxp};
9007     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
9008     my $manpath = '';
9009     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
9010     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
9011     chop $manpath if $manpath;
9012
9013     # harmless if missing, I figure
9014     local $ENV{MANPATH} = $manpath if $manpath;
9015     my $nopathopt = $^O =~ /dunno what goes here/;
9016     if (
9017         CORE::system(
9018             $doccmd,
9019
9020             # I just *know* there are men without -M
9021             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
9022             split ' ', $page
9023         )
9024       )
9025     {
9026         unless ( $page =~ /^perl\w/ ) {
9027             # Previously the debugger contained a list which it slurped in,
9028             # listing the known "perl" manpages. However, it was out of date,
9029             # with errors both of omission and inclusion. This approach is
9030             # considerably less complex. The failure mode on a butchered
9031             # install is simply that the user has to run man or perldoc
9032             # "manually" with the full manpage name.
9033
9034             # There is a list of $^O values in installperl to determine whether
9035             # the directory is 'pods' or 'pod'. However, we can avoid tight
9036             # coupling to that by simply checking the "non-standard" 'pods'
9037             # first.
9038             my $pods = "$Config::Config{privlibexp}/pods";
9039             $pods = "$Config::Config{privlibexp}/pod"
9040                 unless -d $pods;
9041             if (-f "$pods/perl$page.pod") {
9042                 CORE::system( $doccmd,
9043                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
9044                     "perl$page" );
9045             }
9046         }
9047     } ## end if (CORE::system($doccmd...
9048 } ## end sub runman
9049
9050 #use Carp;                          # This did break, left for debugging
9051
9052 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
9053
9054 Because of the way the debugger interface to the Perl core is designed, any
9055 debugger package globals that C<DB::sub()> requires have to be defined before
9056 any subroutines can be called. These are defined in the second C<BEGIN> block.
9057
9058 This block sets things up so that (basically) the world is sane
9059 before the debugger starts executing. We set up various variables that the
9060 debugger has to have set up before the Perl core starts running:
9061
9062 =over 4
9063
9064 =item *
9065
9066 The debugger's own filehandles (copies of STD and STDOUT for now).
9067
9068 =item *
9069
9070 Characters for shell escapes, the recall command, and the history command.
9071
9072 =item *
9073
9074 The maximum recursion depth.
9075
9076 =item *
9077
9078 The size of a C<w> command's window.
9079
9080 =item *
9081
9082 The before-this-line context to be printed in a C<v> (view a window around this line) command.
9083
9084 =item *
9085
9086 The fact that we're not in a sub at all right now.
9087
9088 =item *
9089
9090 The default SIGINT handler for the debugger.
9091
9092 =item *
9093
9094 The appropriate value of the flag in C<$^D> that says the debugger is running
9095
9096 =item *
9097
9098 The current debugger recursion level
9099
9100 =item *
9101
9102 The list of postponed items and the C<$single> stack (XXX define this)
9103
9104 =item *
9105
9106 That we want no return values and no subroutine entry/exit trace.
9107
9108 =back
9109
9110 =cut
9111
9112 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
9113
9114 use vars qw($db_stop);
9115
9116 BEGIN {    # This does not compile, alas. (XXX eh?)
9117     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
9118     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
9119
9120     # Define characters used by command parsing.
9121     $sh       = '!';      # Shell escape (does not work)
9122     $rc       = ',';      # Recall command (does not work)
9123     @hist     = ('?');    # Show history (does not work)
9124     @truehist = ();       # Can be saved for replay (per session)
9125
9126     # This defines the point at which you get the 'deep recursion'
9127     # warning. It MUST be defined or the debugger will not load.
9128     $deep = 1000;
9129
9130     # Number of lines around the current one that are shown in the
9131     # 'w' command.
9132     $window = 10;
9133
9134     # How much before-the-current-line context the 'v' command should
9135     # use in calculating the start of the window it will display.
9136     $preview = 3;
9137
9138     # We're not in any sub yet, but we need this to be a defined value.
9139     $sub = '';
9140
9141     # Set up the debugger's interrupt handler. It simply sets a flag
9142     # ($signal) that DB::DB() will check before each command is executed.
9143     $SIG{INT} = \&DB::catch;
9144
9145     # The following lines supposedly, if uncommented, allow the debugger to
9146     # debug itself. Perhaps we can try that someday.
9147     # This may be enabled to debug debugger:
9148     #$warnLevel = 1 unless defined $warnLevel;
9149     #$dieLevel = 1 unless defined $dieLevel;
9150     #$signalLevel = 1 unless defined $signalLevel;
9151
9152     # This is the flag that says "a debugger is running, please call
9153     # DB::DB and DB::sub". We will turn it on forcibly before we try to
9154     # execute anything in the user's context, because we always want to
9155     # get control back.
9156     $db_stop = 0;          # Compiler warning ...
9157     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
9158
9159     # This variable records how many levels we're nested in debugging. Used
9160     # Used in the debugger prompt, and in determining whether it's all over or
9161     # not.
9162     $level = 0;            # Level of recursive debugging
9163
9164     # "Triggers bug (?) in perl if we postpone this until runtime."
9165     # XXX No details on this yet, or whether we should fix the bug instead
9166     # of work around it. Stay tuned.
9167     @stack = (0);
9168
9169     # Used to track the current stack depth using the auto-stacked-variable
9170     # trick.
9171     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
9172
9173     # Don't print return values on exiting a subroutine.
9174     $doret = -2;
9175
9176     # No extry/exit tracing.
9177     $frame = 0;
9178
9179 } ## end BEGIN
9180
9181 BEGIN { $^W = $ini_warn; }    # Switch warnings back
9182
9183 =head1 READLINE SUPPORT - COMPLETION FUNCTION
9184
9185 =head2 db_complete
9186
9187 C<readline> support - adds command completion to basic C<readline>.
9188
9189 Returns a list of possible completions to C<readline> when invoked. C<readline>
9190 will print the longest common substring following the text already entered.
9191
9192 If there is only a single possible completion, C<readline> will use it in full.
9193
9194 This code uses C<map> and C<grep> heavily to create lists of possible
9195 completion. Think LISP in this section.
9196
9197 =cut
9198
9199 sub db_complete {
9200
9201     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
9202     # $text is the text to be completed.
9203     # $line is the incoming line typed by the user.
9204     # $start is the start of the text to be completed in the incoming line.
9205     my ( $text, $line, $start ) = @_;
9206
9207     # Save the initial text.
9208     # The search pattern is current package, ::, extract the next qualifier
9209     # Prefix and pack are set to undef.
9210     my ( $itext, $search, $prefix, $pack ) =
9211       ( $text, "^\Q${package}::\E([^:]+)\$" );
9212
9213 =head3 C<b postpone|compile>
9214
9215 =over 4
9216
9217 =item *
9218
9219 Find all the subroutines that might match in this package
9220
9221 =item *
9222
9223 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
9224
9225 =item *
9226
9227 Include all the rest of the subs that are known
9228
9229 =item *
9230
9231 C<grep> out the ones that match the text we have so far
9232
9233 =item *
9234
9235 Return this as the list of possible completions
9236
9237 =back
9238
9239 =cut
9240
9241     return sort grep /^\Q$text/, ( keys %sub ),
9242       qw(postpone load compile),    # subroutines
9243       ( map { /$search/ ? ($1) : () } keys %sub )
9244       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
9245
9246 =head3 C<b load>
9247
9248 Get all the possible files from C<@INC> as it currently stands and
9249 select the ones that match the text so far.
9250
9251 =cut
9252
9253     return sort grep /^\Q$text/, values %INC    # files
9254       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
9255
9256 =head3  C<V> (list variable) and C<m> (list modules)
9257
9258 There are two entry points for these commands:
9259
9260 =head4 Unqualified package names
9261
9262 Get the top-level packages and grab everything that matches the text
9263 so far. For each match, recursively complete the partial packages to
9264 get all possible matching packages. Return this sorted list.
9265
9266 =cut
9267
9268     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
9269       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
9270       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
9271
9272 =head4 Qualified package names
9273
9274 Take a partially-qualified package and find all subpackages for it
9275 by getting all the subpackages for the package so far, matching all
9276 the subpackages against the text, and discarding all of them which
9277 start with 'main::'. Return this list.
9278
9279 =cut
9280
9281     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
9282       grep !/^main::/, grep /^\Q$text/,
9283       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () }
9284       do { no strict 'refs'; keys %{ $prefix . '::' } }
9285       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
9286       and $text =~ /^(.*[^:])::?(\w*)$/
9287       and $prefix = $1;
9288
9289 =head3 C<f> - switch files
9290
9291 Here, we want to get a fully-qualified filename for the C<f> command.
9292 Possibilities are:
9293
9294 =over 4
9295
9296 =item 1. The original source file itself
9297
9298 =item 2. A file from C<@INC>
9299
9300 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
9301
9302 =back
9303
9304 =cut
9305
9306     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
9307            # We might possibly want to switch to an eval (which has a "filename"
9308            # like '(eval 9)'), so we may need to clean up the completion text
9309            # before proceeding.
9310         $prefix = length($1) - length($text);
9311         $text   = $1;
9312
9313 =pod
9314
9315 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
9316 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
9317 out of C<%main::>, add the initial source file, and extract the ones that
9318 match the completion text so far.
9319
9320 =cut
9321
9322         return sort
9323           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
9324           $0;
9325     } ## end if ($line =~ /^\|*f\s+(.*)/)
9326
9327 =head3 Subroutine name completion
9328
9329 We look through all of the defined subs (the keys of C<%sub>) and
9330 return both all the possible matches to the subroutine name plus
9331 all the matches qualified to the current package.
9332
9333 =cut
9334
9335     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
9336         $text = substr $text, 1;
9337         $prefix = "&";
9338         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
9339           (
9340             map { /$search/ ? ($1) : () }
9341               keys %sub
9342           );
9343     } ## end if ((substr $text, 0, ...
9344
9345 =head3  Scalar, array, and hash completion: partially qualified package
9346
9347 Much like the above, except we have to do a little more cleanup:
9348
9349 =cut
9350
9351     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
9352
9353 =pod
9354
9355 =over 4
9356
9357 =item *
9358
9359 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
9360
9361 =cut
9362
9363         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
9364
9365 =pod
9366
9367 =item *
9368
9369 Figure out the prefix vs. what needs completing.
9370
9371 =cut
9372
9373         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
9374         $text   = $2;
9375
9376 =pod
9377
9378 =item *
9379
9380 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
9381
9382 =cut
9383
9384         my @out = do {
9385             no strict 'refs';
9386             map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
9387             keys %$pack;
9388         };
9389
9390 =pod
9391
9392 =item *
9393
9394 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
9395
9396 =cut
9397
9398         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9399             return db_complete( $out[0], $line, $start );
9400         }
9401
9402         # Return the list of possibles.
9403         return sort @out;
9404
9405     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
9406
9407 =pod
9408
9409 =back
9410
9411 =head3 Symbol completion: current package or package C<main>.
9412
9413 =cut
9414
9415     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
9416 =pod
9417
9418 =over 4
9419
9420 =item *
9421
9422 If it's C<main>, delete main to just get C<::> leading.
9423
9424 =cut
9425
9426         $pack = ( $package eq 'main' ? '' : $package ) . '::';
9427
9428 =pod
9429
9430 =item *
9431
9432 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
9433
9434 =cut
9435
9436         $prefix = substr $text, 0, 1;
9437         $text   = substr $text, 1;
9438
9439         my @out;
9440
9441 =pod
9442
9443 =item *
9444
9445 We look for the lexical scope above DB::DB and auto-complete lexical variables
9446 if PadWalker could be loaded.
9447
9448 =cut
9449
9450         if (not $text =~ /::/ and eval {
9451             local @INC = @INC;
9452             pop @INC if $INC[-1] eq '.';
9453             require PadWalker } ) {
9454             my $level = 1;
9455             while (1) {
9456                 my @info = caller($level);
9457                 $level++;
9458                 $level = -1, last
9459                   if not @info;
9460                 last if $info[3] eq 'DB::DB';
9461             }
9462             if ($level > 0) {
9463                 my $lexicals = PadWalker::peek_my($level);
9464                 push @out, grep /^\Q$prefix$text/, keys %$lexicals;
9465             }
9466         }
9467
9468 =pod
9469
9470 =item *
9471
9472 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
9473
9474 =cut
9475
9476         push @out, map "$prefix$_", grep /^\Q$text/,
9477           ( grep /^_?[a-zA-Z]/, do { no strict 'refs'; keys %$pack } ),
9478           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
9479
9480 =item *
9481
9482 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
9483
9484 =back
9485
9486 =cut
9487
9488         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9489             return db_complete( $out[0], $line, $start );
9490         }
9491
9492         # Return the list of possibles.
9493         return sort @out;
9494     } ## end if ($text =~ /^[\$@%]/)
9495
9496 =head3 Options
9497
9498 We use C<option_val()> to look up the current value of the option. If there's
9499 only a single value, we complete the command in such a way that it is a
9500 complete command for setting the option in question. If there are multiple
9501 possible values, we generate a command consisting of the option plus a trailing
9502 question mark, which, if executed, will list the current value of the option.
9503
9504 =cut
9505
9506     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
9507     {    # Options after space
9508            # We look for the text to be matched in the list of possible options,
9509            # and fetch the current value.
9510         my @out = grep /^\Q$text/, @options;
9511         my $val = option_val( $out[0], undef );
9512
9513         # Set up a 'query option's value' command.
9514         my $out = '? ';
9515         if ( not defined $val or $val =~ /[\n\r]/ ) {
9516
9517             # There's really nothing else we can do.
9518         }
9519
9520         # We have a value. Create a proper option-setting command.
9521         elsif ( $val =~ /\s/ ) {
9522
9523             # XXX This may be an extraneous variable.
9524             my $found;
9525
9526             # We'll want to quote the string (because of the embedded
9527             # whtespace), but we want to make sure we don't end up with
9528             # mismatched quote characters. We try several possibilities.
9529             foreach my $l ( split //, qq/\"\'\#\|/ ) {
9530
9531                 # If we didn't find this quote character in the value,
9532                 # quote it using this quote character.
9533                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
9534             }
9535         } ## end elsif ($val =~ /\s/)
9536
9537         # Don't need any quotes.
9538         else {
9539             $out = "=$val ";
9540         }
9541
9542         # If there were multiple possible values, return '? ', which
9543         # makes the command into a query command. If there was just one,
9544         # have readline append that.
9545         $rl_attribs->{completer_terminator_character} =
9546           ( @out == 1 ? $out : '? ' );
9547
9548         # Return list of possibilities.
9549         return sort @out;
9550     } ## end if ((substr $line, 0, ...
9551
9552 =head3 Filename completion
9553
9554 For entering filenames. We simply call C<readline>'s C<filename_list()>
9555 method with the completion text to get the possible completions.
9556
9557 =cut
9558
9559     return $term->filename_list($text);    # filenames
9560
9561 } ## end sub db_complete
9562
9563 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
9564
9565 Functions that possibly ought to be somewhere else.
9566
9567 =head2 end_report
9568
9569 Say we're done.
9570
9571 =cut
9572
9573 sub end_report {
9574     local $\ = '';
9575     print $OUT "Use 'q' to quit or 'R' to restart.  'h q' for details.\n";
9576 }
9577
9578 =head2 clean_ENV
9579
9580 If we have $ini_pids, save it in the environment; else remove it from the
9581 environment. Used by the C<R> (restart) command.
9582
9583 =cut
9584
9585 sub clean_ENV {
9586     if ( defined($ini_pids) ) {
9587         $ENV{PERLDB_PIDS} = $ini_pids;
9588     }
9589     else {
9590         delete( $ENV{PERLDB_PIDS} );
9591     }
9592 } ## end sub clean_ENV
9593
9594 # PERLDBf_... flag names from perl.h
9595 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
9596
9597 BEGIN {
9598     %DollarCaretP_flags = (
9599         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
9600         PERLDBf_LINE      => 0x02,     # Keep line #
9601         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
9602         PERLDBf_INTER     => 0x08,     # Preserve more data
9603         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
9604         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
9605         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
9606         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
9607         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
9608         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
9609         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
9610         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
9611     );
9612     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
9613     # doesn't need to set it. It's provided for the benefit of profilers and
9614     # other code analysers.
9615
9616     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
9617 }
9618
9619 sub parse_DollarCaretP_flags {
9620     my $flags = shift;
9621     $flags =~ s/^\s+//;
9622     $flags =~ s/\s+$//;
9623     my $acu = 0;
9624     foreach my $f ( split /\s*\|\s*/, $flags ) {
9625         my $value;
9626         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
9627             $value = hex $1;
9628         }
9629         elsif ( $f =~ /^(\d+)$/ ) {
9630             $value = int $1;
9631         }
9632         elsif ( $f =~ /^DEFAULT$/i ) {
9633             $value = $DollarCaretP_flags{PERLDB_ALL};
9634         }
9635         else {
9636             $f =~ /^(?:PERLDBf_)?(.*)$/i;
9637             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
9638             unless ( defined $value ) {
9639                 print $OUT (
9640                     "Unrecognized \$^P flag '$f'!\n",
9641                     "Acceptable flags are: "
9642                       . join( ', ', sort keys %DollarCaretP_flags ),
9643                     ", and hexadecimal and decimal numbers.\n"
9644                 );
9645                 return undef;
9646             }
9647         }
9648         $acu |= $value;
9649     }
9650     $acu;
9651 }
9652
9653 sub expand_DollarCaretP_flags {
9654     my $DollarCaretP = shift;
9655     my @bits         = (
9656         map {
9657             my $n = ( 1 << $_ );
9658             ( $DollarCaretP & $n )
9659               ? ( $DollarCaretP_flags_r{$n}
9660                   || sprintf( '0x%x', $n ) )
9661               : ()
9662           } 0 .. 31
9663     );
9664     return @bits ? join( '|', @bits ) : 0;
9665 }
9666
9667 =over 4
9668
9669 =item rerun
9670
9671 Rerun the current session to:
9672
9673     rerun        current position
9674
9675     rerun 4      command number 4
9676
9677     rerun -4     current command minus 4 (go back 4 steps)
9678
9679 Whether this always makes sense, in the current context is unknowable, and is
9680 in part left as a useful exercise for the reader.  This sub returns the
9681 appropriate arguments to rerun the current session.
9682
9683 =cut
9684
9685 sub rerun {
9686     my $i = shift;
9687     my @args;
9688     pop(@truehist);                      # strim
9689     unless (defined $truehist[$i]) {
9690         print "Unable to return to non-existent command: $i\n";
9691     } else {
9692         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
9693         my @temp = @truehist;            # store
9694         push(@DB::typeahead, @truehist); # saved
9695         @truehist = @hist = ();          # flush
9696         @args = restart();              # setup
9697         get_list("PERLDB_HIST");        # clean
9698         set_list("PERLDB_HIST", @temp); # reset
9699     }
9700     return @args;
9701 }
9702
9703 =item restart
9704
9705 Restarting the debugger is a complex operation that occurs in several phases.
9706 First, we try to reconstruct the command line that was used to invoke Perl
9707 and the debugger.
9708
9709 =cut
9710
9711 sub restart {
9712     # I may not be able to resurrect you, but here goes ...
9713     print $OUT
9714 "Warning: some settings and command-line options may be lost!\n";
9715     my ( @script, @flags, $cl );
9716
9717     # If warn was on before, turn it on again.
9718     push @flags, '-w' if $ini_warn;
9719
9720     # Rebuild the -I flags that were on the initial
9721     # command line.
9722     for (@ini_INC) {
9723         push @flags, '-I', $_;
9724     }
9725
9726     # Turn on taint if it was on before.
9727     push @flags, '-T' if ${^TAINT};
9728
9729     # Arrange for setting the old INC:
9730     # Save the current @init_INC in the environment.
9731     set_list( "PERLDB_INC", @ini_INC );
9732
9733     # If this was a perl one-liner, go to the "file"
9734     # corresponding to the one-liner read all the lines
9735     # out of it (except for the first one, which is going
9736     # to be added back on again when 'perl -d' runs: that's
9737     # the 'require perl5db.pl;' line), and add them back on
9738     # to the command line to be executed.
9739     if ( $0 eq '-e' ) {
9740         my $lines = *{$main::{'_<-e'}}{ARRAY};
9741         for ( 1 .. $#$lines ) {  # The first line is PERL5DB
9742             chomp( $cl = $lines->[$_] );
9743             push @script, '-e', $cl;
9744         }
9745     } ## end if ($0 eq '-e')
9746
9747     # Otherwise we just reuse the original name we had
9748     # before.
9749     else {
9750         @script = $0;
9751     }
9752
9753 =pod
9754
9755 After the command line  has been reconstructed, the next step is to save
9756 the debugger's status in environment variables. The C<DB::set_list> routine
9757 is used to save aggregate variables (both hashes and arrays); scalars are
9758 just popped into environment variables directly.
9759
9760 =cut
9761
9762     # If the terminal supported history, grab it and
9763     # save that in the environment.
9764     set_list( "PERLDB_HIST",
9765           $term->Features->{getHistory}
9766         ? $term->GetHistory
9767         : @hist );
9768
9769     # Find all the files that were visited during this
9770     # session (i.e., the debugger had magic hashes
9771     # corresponding to them) and stick them in the environment.
9772     my @had_breakpoints = keys %had_breakpoints;
9773     set_list( "PERLDB_VISITED", @had_breakpoints );
9774
9775     # Save the debugger options we chose.
9776     set_list( "PERLDB_OPT", %option );
9777     # set_list( "PERLDB_OPT", options2remember() );
9778
9779     # Save the break-on-loads.
9780     set_list( "PERLDB_ON_LOAD", %break_on_load );
9781
9782 =pod
9783
9784 The most complex part of this is the saving of all of the breakpoints. They
9785 can live in an awful lot of places, and we have to go through all of them,
9786 find the breakpoints, and then save them in the appropriate environment
9787 variable via C<DB::set_list>.
9788
9789 =cut
9790
9791     # Go through all the breakpoints and make sure they're
9792     # still valid.
9793     my @hard;
9794     for ( 0 .. $#had_breakpoints ) {
9795
9796         # We were in this file.
9797         my $file = $had_breakpoints[$_];
9798
9799         # Grab that file's magic line hash.
9800         *dbline = $main::{ '_<' . $file };
9801
9802         # Skip out if it doesn't exist, or if the breakpoint
9803         # is in a postponed file (we'll do postponed ones
9804         # later).
9805         next unless %dbline or $postponed_file{$file};
9806
9807         # In an eval. This is a little harder, so we'll
9808         # do more processing on that below.
9809         ( push @hard, $file ), next
9810           if $file =~ /^\(\w*eval/;
9811
9812         # XXX I have no idea what this is doing. Yet.
9813         my @add;
9814         @add = %{ $postponed_file{$file} }
9815           if $postponed_file{$file};
9816
9817         # Save the list of all the breakpoints for this file.
9818         set_list( "PERLDB_FILE_$_", %dbline, @add );
9819
9820         # Serialize the extra data %breakpoints_data hash.
9821         # That's a bug fix.
9822         set_list( "PERLDB_FILE_ENABLED_$_",
9823             map { _is_breakpoint_enabled($file, $_) ? 1 : 0 }
9824             sort { $a <=> $b } keys(%dbline)
9825         )
9826     } ## end for (0 .. $#had_breakpoints)
9827
9828     # The breakpoint was inside an eval. This is a little
9829     # more difficult. XXX and I don't understand it.
9830     foreach my $hard_file (@hard) {
9831         # Get over to the eval in question.
9832         *dbline = $main::{ '_<' . $hard_file };
9833         my $quoted = quotemeta $hard_file;
9834         my %subs;
9835         for my $sub ( keys %sub ) {
9836             if (my ($n1, $n2) = $sub{$sub} =~ /\A$quoted:(\d+)-(\d+)\z/) {
9837                 $subs{$sub} = [ $n1, $n2 ];
9838             }
9839         }
9840         unless (%subs) {
9841             print {$OUT}
9842             "No subroutines in $hard_file, ignoring breakpoints.\n";
9843             next;
9844         }
9845         LINES: foreach my $line ( keys %dbline ) {
9846
9847             # One breakpoint per sub only:
9848             my ( $offset, $found );
9849             SUBS: foreach my $sub ( keys %subs ) {
9850                 if (
9851                     $subs{$sub}->[1] >= $line    # Not after the subroutine
9852                     and (
9853                         not defined $offset    # Not caught
9854                             or $offset < 0
9855                     )
9856                 )
9857                 {                              # or badly caught
9858                     $found  = $sub;
9859                     $offset = $line - $subs{$sub}->[0];
9860                     if ($offset >= 0) {
9861                         $offset = "+$offset";
9862                         last SUBS;
9863                     }
9864                 } ## end if ($subs{$sub}->[1] >=...
9865             } ## end for $sub (keys %subs)
9866             if ( defined $offset ) {
9867                 $postponed{$found} =
9868                 "break $offset if $dbline{$line}";
9869             }
9870             else {
9871                 print {$OUT}
9872                 ("Breakpoint in ${hard_file}:$line ignored:"
9873                 . " after all the subroutines.\n");
9874             }
9875         } ## end for $line (keys %dbline)
9876     } ## end for (@hard)
9877
9878     # Save the other things that don't need to be
9879     # processed.
9880     set_list( "PERLDB_POSTPONE",  %postponed );
9881     set_list( "PERLDB_PRETYPE",   @$pretype );
9882     set_list( "PERLDB_PRE",       @$pre );
9883     set_list( "PERLDB_POST",      @$post );
9884     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9885
9886     # We are officially restarting.
9887     $ENV{PERLDB_RESTART} = 1;
9888
9889     # We are junking all child debuggers.
9890     delete $ENV{PERLDB_PIDS};    # Restore ini state
9891
9892     # Set this back to the initial pid.
9893     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9894
9895 =pod
9896
9897 After all the debugger status has been saved, we take the command we built up
9898 and then return it, so we can C<exec()> it. The debugger will spot the
9899 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9900 from the environment.
9901
9902 =cut
9903
9904     # And run Perl again. Add the "-d" flag, all the
9905     # flags we built up, the script (whether a one-liner
9906     # or a file), add on the -emacs flag for a slave editor,
9907     # and then the old arguments.
9908
9909     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9910
9911 };  # end restart
9912
9913 =back
9914
9915 =head1 END PROCESSING - THE C<END> BLOCK
9916
9917 Come here at the very end of processing. We want to go into a
9918 loop where we allow the user to enter commands and interact with the
9919 debugger, but we don't want anything else to execute.
9920
9921 First we set the C<$finished> variable, so that some commands that
9922 shouldn't be run after the end of program quit working.
9923
9924 We then figure out whether we're truly done (as in the user entered a C<q>
9925 command, or we finished execution while running nonstop). If we aren't,
9926 we set C<$single> to 1 (causing the debugger to get control again).
9927
9928 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9929 message and returns control to the debugger. Repeat.
9930
9931 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9932 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9933 break, run to completion.).
9934
9935 =cut
9936
9937 END {
9938     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9939     $fall_off_end = 1 unless $inhibit_exit;
9940
9941     # Do not stop in at_exit() and destructors on exit:
9942     if ($fall_off_end or $runnonstop) {
9943         save_hist();
9944     } else {
9945         $DB::single = 1;
9946         DB::fake::at_exit();
9947     }
9948 } ## end END
9949
9950 =head1 PRE-5.8 COMMANDS
9951
9952 Some of the commands changed function quite a bit in the 5.8 command
9953 realignment, so much so that the old code had to be replaced completely.
9954 Because we wanted to retain the option of being able to go back to the
9955 former command set, we moved the old code off to this section.
9956
9957 There's an awful lot of duplicated code here. We've duplicated the
9958 comments to keep things clear.
9959
9960 =head2 Null command
9961
9962 Does nothing. Used to I<turn off> commands.
9963
9964 =cut
9965
9966 sub cmd_pre580_null {
9967
9968     # do nothing...
9969 }
9970
9971 =head2 Old C<a> command.
9972
9973 This version added actions if you supplied them, and deleted them
9974 if you didn't.
9975
9976 =cut
9977
9978 sub cmd_pre580_a {
9979     my $xcmd = shift;
9980     my $cmd  = shift;
9981
9982     # Argument supplied. Add the action.
9983     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9984
9985         # If the line isn't there, use the current line.
9986         my $i = $1 || $line;
9987         my $j = $2;
9988
9989         # If there is an action ...
9990         if ( length $j ) {
9991
9992             # ... but the line isn't breakable, skip it.
9993             if ( $dbline[$i] == 0 ) {
9994                 print $OUT "Line $i may not have an action.\n";
9995             }
9996             else {
9997
9998                 # ... and the line is breakable:
9999                 # Mark that there's an action in this file.
10000                 $had_breakpoints{$filename} |= 2;
10001
10002                 # Delete any current action.
10003                 $dbline{$i} =~ s/\0[^\0]*//;
10004
10005                 # Add the new action, continuing the line as needed.
10006                 $dbline{$i} .= "\0" . action($j);
10007             }
10008         } ## end if (length $j)
10009
10010         # No action supplied.
10011         else {
10012
10013             # Delete the action.
10014             $dbline{$i} =~ s/\0[^\0]*//;
10015
10016             # Mark as having no break or action if nothing's left.
10017             delete $dbline{$i} if $dbline{$i} eq '';
10018         }
10019     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
10020 } ## end sub cmd_pre580_a
10021
10022 =head2 Old C<b> command
10023
10024 Add breakpoints.
10025
10026 =cut
10027
10028 sub cmd_pre580_b {
10029     my $xcmd   = shift;
10030     my $cmd    = shift;
10031     my $dbline = shift;
10032
10033     # Break on load.
10034     if ( $cmd =~ /^load\b\s*(.*)/ ) {
10035         my $file = $1;
10036         $file =~ s/\s+$//;
10037         cmd_b_load($file);
10038     }
10039
10040     # b compile|postpone <some sub> [<condition>]
10041     # The interpreter actually traps this one for us; we just put the
10042     # necessary condition in the %postponed hash.
10043     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
10044
10045         # Capture the condition if there is one. Make it true if none.
10046         my $cond = length $3 ? $3 : '1';
10047
10048         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
10049         # if it was 'compile'.
10050         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
10051
10052         # De-Perl4-ify the name - ' separators to ::.
10053         $subname =~ s/\'/::/g;
10054
10055         # Qualify it into the current package unless it's already qualified.
10056         $subname = "${package}::" . $subname
10057           unless $subname =~ /::/;
10058
10059         # Add main if it starts with ::.
10060         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
10061
10062         # Save the break type for this sub.
10063         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
10064     } ## end elsif ($cmd =~ ...
10065
10066     # b <sub name> [<condition>]
10067     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
10068         my $subname = $1;
10069         my $cond = length $2 ? $2 : '1';
10070         cmd_b_sub( $subname, $cond );
10071     }
10072     # b <line> [<condition>].
10073     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
10074         my $i = $1 || $dbline;
10075         my $cond = length $2 ? $2 : '1';
10076         cmd_b_line( $i, $cond );
10077     }
10078 } ## end sub cmd_pre580_b
10079
10080 =head2 Old C<D> command.
10081
10082 Delete all breakpoints unconditionally.
10083
10084 =cut
10085
10086 sub cmd_pre580_D {
10087     my $xcmd = shift;
10088     my $cmd  = shift;
10089     if ( $cmd =~ /^\s*$/ ) {
10090         print $OUT "Deleting all breakpoints...\n";
10091
10092         # %had_breakpoints lists every file that had at least one
10093         # breakpoint in it.
10094         my $file;
10095         for $file ( keys %had_breakpoints ) {
10096
10097             # Switch to the desired file temporarily.
10098             local *dbline = $main::{ '_<' . $file };
10099
10100             $max = $#dbline;
10101             my $was;
10102
10103             # For all lines in this file ...
10104             for my $i (1 .. $max) {
10105
10106                 # If there's a breakpoint or action on this line ...
10107                 if ( defined $dbline{$i} ) {
10108
10109                     # ... remove the breakpoint.
10110                     $dbline{$i} =~ s/^[^\0]+//;
10111                     if ( $dbline{$i} =~ s/^\0?$// ) {
10112
10113                         # Remove the entry altogether if no action is there.
10114                         delete $dbline{$i};
10115                     }
10116                 } ## end if (defined $dbline{$i...
10117             } ## end for my $i (1 .. $max)
10118
10119             # If, after we turn off the "there were breakpoints in this file"
10120             # bit, the entry in %had_breakpoints for this file is zero,
10121             # we should remove this file from the hash.
10122             if ( not $had_breakpoints{$file} &= ~1 ) {
10123                 delete $had_breakpoints{$file};
10124             }
10125         } ## end for $file (keys %had_breakpoints)
10126
10127         # Kill off all the other breakpoints that are waiting for files that
10128         # haven't been loaded yet.
10129         undef %postponed;
10130         undef %postponed_file;
10131         undef %break_on_load;
10132     } ## end if ($cmd =~ /^\s*$/)
10133 } ## end sub cmd_pre580_D
10134
10135 =head2 Old C<h> command
10136
10137 Print help. Defaults to printing the long-form help; the 5.8 version
10138 prints the summary by default.
10139
10140 =cut
10141
10142 sub cmd_pre580_h {
10143     my $xcmd = shift;
10144     my $cmd  = shift;
10145
10146     # Print the *right* help, long format.
10147     if ( $cmd =~ /^\s*$/ ) {
10148         print_help($pre580_help);
10149     }
10150
10151     # 'h h' - explicitly-requested summary.
10152     elsif ( $cmd =~ /^h\s*/ ) {
10153         print_help($pre580_summary);
10154     }
10155
10156     # Find and print a command's help.
10157     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
10158         my $asked  = $1;                   # for proper errmsg
10159         my $qasked = quotemeta($asked);    # for searching
10160                                            # XXX: finds CR but not <CR>
10161         if (
10162             $pre580_help =~ /^
10163                               <?           # Optional '<'
10164                               (?:[IB]<)    # Optional markup
10165                               $qasked      # The command name
10166                             /mx
10167           )
10168         {
10169
10170             while (
10171                 $pre580_help =~ /^
10172                                   (             # The command help:
10173                                    <?           # Optional '<'
10174                                    (?:[IB]<)    # Optional markup
10175                                    $qasked      # The command name
10176                                    ([\s\S]*?)   # Lines starting with tabs
10177                                    \n           # Final newline
10178                                   )
10179                                   (?!\s)/mgx
10180               )    # Line not starting with space
10181                    # (Next command's help)
10182             {
10183                 print_help($1);
10184             }
10185         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
10186
10187         # Help not found.
10188         else {
10189             print_help("B<$asked> is not a debugger command.\n");
10190         }
10191     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
10192 } ## end sub cmd_pre580_h
10193
10194 =head2 Old C<W> command
10195
10196 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
10197
10198 =cut
10199
10200 sub cmd_pre580_W {
10201     my $xcmd = shift;
10202     my $cmd  = shift;
10203
10204     # Delete all watch expressions.
10205     if ( $cmd =~ /^$/ ) {
10206
10207         # No watching is going on.
10208         $trace &= ~2;
10209
10210         # Kill all the watch expressions and values.
10211         @to_watch = @old_watch = ();
10212     }
10213
10214     # Add a watch expression.
10215     elsif ( $cmd =~ /^(.*)/s ) {
10216
10217         # add it to the list to be watched.
10218         push @to_watch, $1;
10219
10220         # Get the current value of the expression.
10221         # Doesn't handle expressions returning list values!
10222         $evalarg = $1;
10223         # The &-call is here to ascertain the mutability of @_.
10224         my ($val) = &DB::eval;
10225         $val = ( defined $val ) ? "'$val'" : 'undef';
10226
10227         # Save it.
10228         push @old_watch, $val;
10229
10230         # We're watching stuff.
10231         $trace |= 2;
10232
10233     } ## end elsif ($cmd =~ /^(.*)/s)
10234 } ## end sub cmd_pre580_W
10235
10236 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
10237
10238 The debugger used to have a bunch of nearly-identical code to handle
10239 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
10240 C<cmd_prepost> unify all this into one set of code to handle the
10241 appropriate actions.
10242
10243 =head2 C<cmd_pre590_prepost>
10244
10245 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
10246 do something destructive. In pre 5.8 debuggers, the default action was to
10247 delete all the actions.
10248
10249 =cut
10250
10251 sub cmd_pre590_prepost {
10252     my $cmd    = shift;
10253     my $line   = shift || '*';
10254     my $dbline = shift;
10255
10256     return cmd_prepost( $cmd, $line, $dbline );
10257 } ## end sub cmd_pre590_prepost
10258
10259 =head2 C<cmd_prepost>
10260
10261 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
10262 Since the lists of actions are all held in arrays that are pointed to by
10263 references anyway, all we have to do is pick the right array reference and
10264 then use generic code to all, delete, or list actions.
10265
10266 =cut
10267
10268 sub cmd_prepost {
10269     my $cmd = shift;
10270
10271     # No action supplied defaults to 'list'.
10272     my $line = shift || '?';
10273
10274     # Figure out what to put in the prompt.
10275     my $which = '';
10276
10277     # Make sure we have some array or another to address later.
10278     # This means that if for some reason the tests fail, we won't be
10279     # trying to stash actions or delete them from the wrong place.
10280     my $aref = [];
10281
10282     # < - Perl code to run before prompt.
10283     if ( $cmd =~ /^\</o ) {
10284         $which = 'pre-perl';
10285         $aref  = $pre;
10286     }
10287
10288     # > - Perl code to run after prompt.
10289     elsif ( $cmd =~ /^\>/o ) {
10290         $which = 'post-perl';
10291         $aref  = $post;
10292     }
10293
10294     # { - first check for properly-balanced braces.
10295     elsif ( $cmd =~ /^\{/o ) {
10296         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
10297             print $OUT
10298 "$cmd is now a debugger command\nuse ';$cmd' if you mean Perl code\n";
10299         }
10300
10301         # Properly balanced. Pre-prompt debugger actions.
10302         else {
10303             $which = 'pre-debugger';
10304             $aref  = $pretype;
10305         }
10306     } ## end elsif ( $cmd =~ /^\{/o )
10307
10308     # Did we find something that makes sense?
10309     unless ($which) {
10310         print $OUT "Confused by command: $cmd\n";
10311     }
10312
10313     # Yes.
10314     else {
10315
10316         # List actions.
10317         if ( $line =~ /^\s*\?\s*$/o ) {
10318             unless (@$aref) {
10319
10320                 # Nothing there. Complain.
10321                 print $OUT "No $which actions.\n";
10322             }
10323             else {
10324
10325                 # List the actions in the selected list.
10326                 print $OUT "$which commands:\n";
10327                 foreach my $action (@$aref) {
10328                     print $OUT "\t$cmd -- $action\n";
10329                 }
10330             } ## end else
10331         } ## end if ( $line =~ /^\s*\?\s*$/o)
10332
10333         # Might be a delete.
10334         else {
10335             if ( length($cmd) == 1 ) {
10336                 if ( $line =~ /^\s*\*\s*$/o ) {
10337
10338                     # It's a delete. Get rid of the old actions in the
10339                     # selected list..
10340                     @$aref = ();
10341                     print $OUT "All $cmd actions cleared.\n";
10342                 }
10343                 else {
10344
10345                     # Replace all the actions. (This is a <, >, or {).
10346                     @$aref = action($line);
10347                 }
10348             } ## end if ( length($cmd) == 1)
10349             elsif ( length($cmd) == 2 ) {
10350
10351                 # Add the action to the line. (This is a <<, >>, or {{).
10352                 push @$aref, action($line);
10353             }
10354             else {
10355
10356                 # <<<, >>>>, {{{{{{ ... something not a command.
10357                 print $OUT
10358                   "Confused by strange length of $which command($cmd)...\n";
10359             }
10360         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
10361     } ## end else
10362 } ## end sub cmd_prepost
10363
10364 =head1 C<DB::fake>
10365
10366 Contains the C<at_exit> routine that the debugger uses to issue the
10367 C<Debugged program terminated ...> message after the program completes. See
10368 the C<END> block documentation for more details.
10369
10370 =cut
10371
10372 package DB::fake;
10373
10374 sub at_exit {
10375     "Debugged program terminated.  Use 'q' to quit or 'R' to restart.";
10376 }
10377
10378 package DB;    # Do not trace this 1; below!
10379
10380 1;
10381
10382