lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline> via glob
 177 assignment) contains the text from C<$filename>, with each element
 178 corresponding to a single line of C<$filename>.
 179
 180 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 181 assignment) contains breakpoints and actions.  The keys are line numbers;
 182 you can set individual values, but not the whole hash. The Perl interpreter
 183 uses this hash to determine where breakpoints have been set. Any true value is
 184 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 185 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 186
 187 The scalar C<${"_<$filename"}> simply contains the string C<_<$filename>.
 188 This is also the case for evaluated strings that contain subroutines, or
 189 which are currently being executed.  The $filename for C<eval>ed strings looks
 190 like C<(eval 34)> or C<(re_eval 19)>.
 191
 192 =head1 DEBUGGER STARTUP
 193
 194 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 195 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 196 of options. In addition, this file may define a subroutine C<&afterinit>
 197 that will be executed (in the debugger's context) after the debugger has
 198 initialized itself.
 199
 200 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 201 contents as the argument of a C<o> command in the debugger.
 202
 203 =head2 STARTUP-ONLY OPTIONS
 204
 205 The following options can only be specified at startup.
 206 To set them in your rcfile, add a call to
 207 C<&parse_options("optionName=new_value")>.
 208
 209 =over 4
 210
 211 =item * TTY
 212
 213 the TTY to use for debugging i/o.
 214
 215 =item * noTTY
 216
 217 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 218 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 219 Term::Rendezvous.  Current variant is to have the name of TTY in this
 220 file.
 221
 222 =item * ReadLine
 223
 224 if false, a dummy ReadLine is used, so you can debug
 225 ReadLine applications.
 226
 227 =item * NonStop
 228
 229 if true, no i/o is performed until interrupt.
 230
 231 =item * LineInfo
 232
 233 file or pipe to print line number info to.  If it is a
 234 pipe, a short "emacs like" message is used.
 235
 236 =item * RemotePort
 237
 238 host:port to connect to on remote host for remote debugging.
 239
 240 =item * HistFile
 241
 242 file to store session history to. There is no default and so no
 243 history file is written unless this variable is explicitly set.
 244
 245 =item * HistSize
 246
 247 number of commands to store to the file specified in C<HistFile>.
 248 Default is 100.
 249
 250 =back
 251
 252 =head3 SAMPLE RCFILE
 253
 254  &parse_options("NonStop=1 LineInfo=db.out");
 255   sub afterinit { $trace = 1; }
 256
 257 The script will run without human intervention, putting trace
 258 information into C<db.out>.  (If you interrupt it, you had better
 259 reset C<LineInfo> to something I<interactive>!)
 260
 261 =head1 INTERNALS DESCRIPTION
 262
 263 =head2 DEBUGGER INTERFACE VARIABLES
 264
 265 Perl supplies the values for C<%sub>.  It effectively inserts
 266 a C<&DB::DB();> in front of each place that can have a
 267 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 268 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 269 {require 'perl5db.pl'}> before the first line.
 270
 271 After each C<require>d file is compiled, but before it is executed, a
 272 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 273 is the expanded name of the C<require>d file (as found via C<%INC>).
 274
 275 =head3 IMPORTANT INTERNAL VARIABLES
 276
 277 =head4 C<$CreateTTY>
 278
 279 Used to control when the debugger will attempt to acquire another TTY to be
 280 used for input.
 281
 282 =over
 283
 284 =item * 1 -  on C<fork()>
 285
 286 =item * 2 - debugger is started inside debugger
 287
 288 =item * 4 -  on startup
 289
 290 =back
 291
 292 =head4 C<$doret>
 293
 294 The value -2 indicates that no return value should be printed.
 295 Any other positive value causes C<DB::sub> to print return values.
 296
 297 =head4 C<$evalarg>
 298
 299 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 300 contents of C<@_> when C<DB::eval> is called.
 301
 302 =head4 C<$frame>
 303
 304 Determines what messages (if any) will get printed when a subroutine (or eval)
 305 is entered or exited.
 306
 307 =over 4
 308
 309 =item * 0 -  No enter/exit messages
 310
 311 =item * 1 - Print I<entering> messages on subroutine entry
 312
 313 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 314
 315 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 316
 317 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 318
 319 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 320
 321 =back
 322
 323 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 324 The debugger internally juggles the value of C<$frame> during execution to
 325 protect external modules that the debugger uses from getting traced.
 326
 327 =head4 C<$level>
 328
 329 Tracks current debugger nesting level. Used to figure out how many
 330 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 331 outputs a prompt. Also used to help determine if the program has finished
 332 during command parsing.
 333
 334 =head4 C<$onetimeDump>
 335
 336 Controls what (if anything) C<DB::eval()> will print after evaluating an
 337 expression.
 338
 339 =over 4
 340
 341 =item * C<undef> - don't print anything
 342
 343 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 344
 345 =item * C<methods> - print the methods callable on the first item returned
 346
 347 =back
 348
 349 =head4 C<$onetimeDumpDepth>
 350
 351 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 352 dumping a structure. Numeric. If C<undef>, print all levels.
 353
 354 =head4 C<$signal>
 355
 356 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 357 which is called before every statement, checks this and puts the user into
 358 command mode if it finds C<$signal> set to a true value.
 359
 360 =head4 C<$single>
 361
 362 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 363 each subroutine; popped again at the end of each subroutine.
 364
 365 =over 4
 366
 367 =item * 0 - run continuously.
 368
 369 =item * 1 - single-step, go into subs. The C<s> command.
 370
 371 =item * 2 - single-step, don't go into subs. The C<n> command.
 372
 373 =item * 4 - print current sub depth (turned on to force this when C<too much
 374 recursion> occurs.
 375
 376 =back
 377
 378 =head4 C<$trace>
 379
 380 Controls the output of trace information.
 381
 382 =over 4
 383
 384 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 385
 386 =item * 2 - watch expressions are active
 387
 388 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 389
 390 =back
 391
 392 =head4 C<$slave_editor>
 393
 394 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 395
 396 =head4 C<@cmdfhs>
 397
 398 Stack of filehandles that C<DB::readline()> will read commands from.
 399 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 400
 401 =head4 C<@dbline>
 402
 403 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 404 supplied by the Perl interpreter to the debugger. Contains the source.
 405
 406 =head4 C<@old_watch>
 407
 408 Previous values of watch expressions. First set when the expression is
 409 entered; reset whenever the watch expression changes.
 410
 411 =head4 C<@saved>
 412
 413 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 414 so that the debugger can substitute safe values while it's running, and
 415 restore them when it returns control.
 416
 417 =head4 C<@stack>
 418
 419 Saves the current value of C<$single> on entry to a subroutine.
 420 Manipulated by the C<c> command to turn off tracing in all subs above the
 421 current one.
 422
 423 =head4 C<@to_watch>
 424
 425 The 'watch' expressions: to be evaluated before each line is executed.
 426
 427 =head4 C<@typeahead>
 428
 429 The typeahead buffer, used by C<DB::readline>.
 430
 431 =head4 C<%alias>
 432
 433 Command aliases. Stored as character strings to be substituted for a command
 434 entered.
 435
 436 =head4 C<%break_on_load>
 437
 438 Keys are file names, values are 1 (break when this file is loaded) or undef
 439 (don't break when it is loaded).
 440
 441 =head4 C<%dbline>
 442
 443 Keys are line numbers, values are C<condition\0action>. If used in numeric
 444 context, values are 0 if not breakable, 1 if breakable, no matter what is
 445 in the actual hash entry.
 446
 447 =head4 C<%had_breakpoints>
 448
 449 Keys are file names; values are bitfields:
 450
 451 =over 4
 452
 453 =item * 1 - file has a breakpoint in it.
 454
 455 =item * 2 - file has an action in it.
 456
 457 =back
 458
 459 A zero or undefined value means this file has neither.
 460
 461 =head4 C<%option>
 462
 463 Stores the debugger options. These are character string values.
 464
 465 =head4 C<%postponed>
 466
 467 Saves breakpoints for code that hasn't been compiled yet.
 468 Keys are subroutine names, values are:
 469
 470 =over 4
 471
 472 =item * C<compile> - break when this sub is compiled
 473
 474 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 475
 476 =back
 477
 478 =head4 C<%postponed_file>
 479
 480 This hash keeps track of breakpoints that need to be set for files that have
 481 not yet been compiled. Keys are filenames; values are references to hashes.
 482 Each of these hashes is keyed by line number, and its values are breakpoint
 483 definitions (C<condition\0action>).
 484
 485 =head1 DEBUGGER INITIALIZATION
 486
 487 The debugger's initialization actually jumps all over the place inside this
 488 package. This is because there are several BEGIN blocks (which of course
 489 execute immediately) spread through the code. Why is that?
 490
 491 The debugger needs to be able to change some things and set some things up
 492 before the debugger code is compiled; most notably, the C<$deep> variable that
 493 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 494 debugger has to turn off warnings while the debugger code is compiled, but then
 495 restore them to their original setting before the program being debugged begins
 496 executing.
 497
 498 The first C<BEGIN> block simply turns off warnings by saving the current
 499 setting of C<$^W> and then setting it to zero. The second one initializes
 500 the debugger variables that are needed before the debugger begins executing.
 501 The third one puts C<$^X> back to its former value.
 502
 503 We'll detail the second C<BEGIN> block later; just remember that if you need
 504 to initialize something before the debugger starts really executing, that's
 505 where it has to go.
 506
 507 =cut
 508
 509 package DB;
 510
 511 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
 512
 513 # Debugger for Perl 5.00x; perl5db.pl patch level:
 514 $VERSION = 1.30;
 515
 516 $header = "perl5db.pl version $VERSION";
 517
 518 =head1 DEBUGGER ROUTINES
 519
 520 =head2 C<DB::eval()>
 521
 522 This function replaces straight C<eval()> inside the debugger; it simplifies
 523 the process of evaluating code in the user's context.
 524
 525 The code to be evaluated is passed via the package global variable
 526 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 527
 528 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 529 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 530 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 531 user's current package, grabbed when C<DB::DB> got control.  This causes the
 532 proper context to be used when the eval is actually done.  Afterward, we
 533 restore C<$trace>, C<$single>, and C<$^D>.
 534
 535 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 536 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 537 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 538 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 539 considered sane by the debugger. If there was an C<eval()> error, we print
 540 it on the debugger's output. If C<$onetimedump> is defined, we call
 541 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 542 'methods'. Setting it to something else causes the debugger to do the eval
 543 but not print the result - handy if you want to do something else with it
 544 (the "watch expressions" code does this to get the value of the watch
 545 expression but not show it unless it matters).
 546
 547 In any case, we then return the list of output from C<eval> to the caller,
 548 and unwinding restores the former version of C<$@> in C<@saved> as well
 549 (the localization of C<$saved[0]> goes away at the end of this scope).
 550
 551 =head3 Parameters and variables influencing execution of DB::eval()
 552
 553 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 554 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 555 The variables listed below influence C<DB::eval()>'s execution directly.
 556
 557 =over 4
 558
 559 =item C<$evalarg> - the thing to actually be eval'ed
 560
 561 =item C<$trace> - Current state of execution tracing
 562
 563 =item C<$single> - Current state of single-stepping
 564
 565 =item C<$onetimeDump> - what is to be displayed after the evaluation
 566
 567 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 568
 569 =back
 570
 571 The following variables are altered by C<DB::eval()> during its execution. They
 572 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 573
 574 =over 4
 575
 576 =item C<@res> - used to capture output from actual C<eval>.
 577
 578 =item C<$otrace> - saved value of C<$trace>.
 579
 580 =item C<$osingle> - saved value of C<$single>.
 581
 582 =item C<$od> - saved value of C<$^D>.
 583
 584 =item C<$saved[0]> - saved value of C<$@>.
 585
 586 =item $\ - for output of C<$@> if there is an evaluation error.
 587
 588 =back
 589
 590 =head3 The problem of lexicals
 591
 592 The context of C<DB::eval()> presents us with some problems. Obviously,
 593 we want to be 'sandboxed' away from the debugger's internals when we do
 594 the eval, but we need some way to control how punctuation variables and
 595 debugger globals are used.
 596
 597 We can't use local, because the code inside C<DB::eval> can see localized
 598 variables; and we can't use C<my> either for the same reason. The code
 599 in this routine compromises and uses C<my>.
 600
 601 After this routine is over, we don't have user code executing in the debugger's
 602 context, so we can use C<my> freely.
 603
 604 =cut
 605
 606 ############################################## Begin lexical danger zone
 607
 608 # 'my' variables used here could leak into (that is, be visible in)
 609 # the context that the code being evaluated is executing in. This means that
 610 # the code could modify the debugger's variables.
 611 #
 612 # Fiddling with the debugger's context could be Bad. We insulate things as
 613 # much as we can.
 614
 615 sub eval {
 616
 617     # 'my' would make it visible from user code
 618     #    but so does local! --tchrist
 619     # Remember: this localizes @DB::res, not @main::res.
 620     local @res;
 621     {
 622
 623         # Try to keep the user code from messing  with us. Save these so that
 624         # even if the eval'ed code changes them, we can put them back again.
 625         # Needed because the user could refer directly to the debugger's
 626         # package globals (and any 'my' variables in this containing scope)
 627         # inside the eval(), and we want to try to stay safe.
 628         local $otrace  = $trace;
 629         local $osingle = $single;
 630         local $od      = $^D;
 631
 632         # Untaint the incoming eval() argument.
 633         { ($evalarg) = $evalarg =~ /(.*)/s; }
 634
 635         # $usercontext built in DB::DB near the comment
 636         # "set up the context for DB::eval ..."
 637         # Evaluate and save any results.
 638         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 639
 640         # Restore those old values.
 641         $trace  = $otrace;
 642         $single = $osingle;
 643         $^D     = $od;
 644     }
 645
 646     # Save the current value of $@, and preserve it in the debugger's copy
 647     # of the saved precious globals.
 648     my $at = $@;
 649
 650     # Since we're only saving $@, we only have to localize the array element
 651     # that it will be stored in.
 652     local $saved[0];    # Preserve the old value of $@
 653     eval { &DB::save };
 654
 655     # Now see whether we need to report an error back to the user.
 656     if ($at) {
 657         local $\ = '';
 658         print $OUT $at;
 659     }
 660
 661     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 662     # are package globals.
 663     elsif ($onetimeDump) {
 664         if ( $onetimeDump eq 'dump' ) {
 665             local $option{dumpDepth} = $onetimedumpDepth
 666               if defined $onetimedumpDepth;
 667             dumpit( $OUT, \@res );
 668         }
 669         elsif ( $onetimeDump eq 'methods' ) {
 670             methods( $res[0] );
 671         }
 672     } ## end elsif ($onetimeDump)
 673     @res;
 674 } ## end sub eval
 675
 676 ############################################## End lexical danger zone
 677
 678 # After this point it is safe to introduce lexicals.
 679 # The code being debugged will be executing in its own context, and
 680 # can't see the inside of the debugger.
 681 #
 682 # However, one should not overdo it: leave as much control from outside as
 683 # possible. If you make something a lexical, it's not going to be addressable
 684 # from outside the debugger even if you know its name.
 685
 686 # This file is automatically included if you do perl -d.
 687 # It's probably not useful to include this yourself.
 688 #
 689 # Before venturing further into these twisty passages, it is
 690 # wise to read the perldebguts man page or risk the ire of dragons.
 691 #
 692 # (It should be noted that perldebguts will tell you a lot about
 693 # the underlying mechanics of how the debugger interfaces into the
 694 # Perl interpreter, but not a lot about the debugger itself. The new
 695 # comments in this code try to address this problem.)
 696
 697 # Note that no subroutine call is possible until &DB::sub is defined
 698 # (for subroutines defined outside of the package DB). In fact the same is
 699 # true if $deep is not defined.
 700
 701 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 702
 703 # modified Perl debugger, to be run from Emacs in perldb-mode
 704 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 705 # Johan Vromans -- upgrade to 4.0 pl 10
 706 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 707
 708 # (We have made efforts to  clarify the comments in the change log
 709 # in other places; some of them may seem somewhat obscure as they
 710 # were originally written, and explaining them away from the code
 711 # in question seems conterproductive.. -JM)
 712
 713 ########################################################################
 714 # Changes: 0.94
 715 #   + A lot of things changed after 0.94. First of all, core now informs
 716 #     debugger about entry into XSUBs, overloaded operators, tied operations,
 717 #     BEGIN and END. Handy with `O f=2'.
 718 #   + This can make debugger a little bit too verbose, please be patient
 719 #     and report your problems promptly.
 720 #   + Now the option frame has 3 values: 0,1,2. XXX Document!
 721 #   + Note that if DESTROY returns a reference to the object (or object),
 722 #     the deletion of data may be postponed until the next function call,
 723 #     due to the need to examine the return value.
 724 #
 725 # Changes: 0.95
 726 #   + `v' command shows versions.
 727 #
 728 # Changes: 0.96
 729 #   + `v' command shows version of readline.
 730 #     primitive completion works (dynamic variables, subs for `b' and `l',
 731 #     options). Can `p %var'
 732 #   + Better help (`h <' now works). New commands <<, >>, {, {{.
 733 #     {dump|print}_trace() coded (to be able to do it from <<cmd).
 734 #   + `c sub' documented.
 735 #   + At last enough magic combined to stop after the end of debuggee.
 736 #   + !! should work now (thanks to Emacs bracket matching an extra
 737 #     `]' in a regexp is caught).
 738 #   + `L', `D' and `A' span files now (as documented).
 739 #   + Breakpoints in `require'd code are possible (used in `R').
 740 #   +  Some additional words on internal work of debugger.
 741 #   + `b load filename' implemented.
 742 #   + `b postpone subr' implemented.
 743 #   + now only `q' exits debugger (overwritable on $inhibit_exit).
 744 #   + When restarting debugger breakpoints/actions persist.
 745 #   + Buglet: When restarting debugger only one breakpoint/action per
 746 #             autoloaded function persists.
 747 #
 748 # Changes: 0.97: NonStop will not stop in at_exit().
 749 #   + Option AutoTrace implemented.
 750 #   + Trace printed differently if frames are printed too.
 751 #   + new `inhibitExit' option.
 752 #   + printing of a very long statement interruptible.
 753 # Changes: 0.98: New command `m' for printing possible methods
 754 #   + 'l -' is a synonym for `-'.
 755 #   + Cosmetic bugs in printing stack trace.
 756 #   +  `frame' & 8 to print "expanded args" in stack trace.
 757 #   + Can list/break in imported subs.
 758 #   + new `maxTraceLen' option.
 759 #   + frame & 4 and frame & 8 granted.
 760 #   + new command `m'
 761 #   + nonstoppable lines do not have `:' near the line number.
 762 #   + `b compile subname' implemented.
 763 #   + Will not use $` any more.
 764 #   + `-' behaves sane now.
 765 # Changes: 0.99: Completion for `f', `m'.
 766 #   +  `m' will remove duplicate names instead of duplicate functions.
 767 #   + `b load' strips trailing whitespace.
 768 #     completion ignores leading `|'; takes into account current package
 769 #     when completing a subroutine name (same for `l').
 770 # Changes: 1.07: Many fixed by tchrist 13-March-2000
 771 #   BUG FIXES:
 772 #   + Added bare minimal security checks on perldb rc files, plus
 773 #     comments on what else is needed.
 774 #   + Fixed the ornaments that made "|h" completely unusable.
 775 #     They are not used in print_help if they will hurt.  Strip pod
 776 #     if we're paging to less.
 777 #   + Fixed mis-formatting of help messages caused by ornaments
 778 #     to restore Larry's original formatting.
 779 #   + Fixed many other formatting errors.  The code is still suboptimal,
 780 #     and needs a lot of work at restructuring.  It's also misindented
 781 #     in many places.
 782 #   + Fixed bug where trying to look at an option like your pager
 783 #     shows "1".
 784 #   + Fixed some $? processing.  Note: if you use csh or tcsh, you will
 785 #     lose.  You should consider shell escapes not using their shell,
 786 #     or else not caring about detailed status.  This should really be
 787 #     unified into one place, too.
 788 #   + Fixed bug where invisible trailing whitespace on commands hoses you,
 789 #     tricking Perl into thinking you weren't calling a debugger command!
 790 #   + Fixed bug where leading whitespace on commands hoses you.  (One
 791 #     suggests a leading semicolon or any other irrelevant non-whitespace
 792 #     to indicate literal Perl code.)
 793 #   + Fixed bugs that ate warnings due to wrong selected handle.
 794 #   + Fixed a precedence bug on signal stuff.
 795 #   + Fixed some unseemly wording.
 796 #   + Fixed bug in help command trying to call perl method code.
 797 #   + Fixed to call dumpvar from exception handler.  SIGPIPE killed us.
 798 #   ENHANCEMENTS:
 799 #   + Added some comments.  This code is still nasty spaghetti.
 800 #   + Added message if you clear your pre/post command stacks which was
 801 #     very easy to do if you just typed a bare >, <, or {.  (A command
 802 #     without an argument should *never* be a destructive action; this
 803 #     API is fundamentally screwed up; likewise option setting, which
 804 #     is equally buggered.)
 805 #   + Added command stack dump on argument of "?" for >, <, or {.
 806 #   + Added a semi-built-in doc viewer command that calls man with the
 807 #     proper %Config::Config path (and thus gets caching, man -k, etc),
 808 #     or else perldoc on obstreperous platforms.
 809 #   + Added to and rearranged the help information.
 810 #   + Detected apparent misuse of { ... } to declare a block; this used
 811 #     to work but now is a command, and mysteriously gave no complaint.
 812 #
 813 # Changes: 1.08: Apr 25, 2001  Jon Eveland <jweveland@yahoo.com>
 814 #   BUG FIX:
 815 #   + This patch to perl5db.pl cleans up formatting issues on the help
 816 #     summary (h h) screen in the debugger.  Mostly columnar alignment
 817 #     issues, plus converted the printed text to use all spaces, since
 818 #     tabs don't seem to help much here.
 819 #
 820 # Changes: 1.09: May 19, 2001  Ilya Zakharevich <ilya@math.ohio-state.edu>
 821 #   Minor bugs corrected;
 822 #   + Support for auto-creation of new TTY window on startup, either
 823 #     unconditionally, or if started as a kid of another debugger session;
 824 #   + New `O'ption CreateTTY
 825 #       I<CreateTTY>      bits control attempts to create a new TTY on events:
 826 #                         1: on fork()
 827 #                         2: debugger is started inside debugger
 828 #                         4: on startup
 829 #   + Code to auto-create a new TTY window on OS/2 (currently one
 830 #     extra window per session - need named pipes to have more...);
 831 #   + Simplified interface for custom createTTY functions (with a backward
 832 #     compatibility hack); now returns the TTY name to use; return of ''
 833 #     means that the function reset the I/O handles itself;
 834 #   + Better message on the semantic of custom createTTY function;
 835 #   + Convert the existing code to create a TTY into a custom createTTY
 836 #     function;
 837 #   + Consistent support for TTY names of the form "TTYin,TTYout";
 838 #   + Switch line-tracing output too to the created TTY window;
 839 #   + make `b fork' DWIM with CORE::GLOBAL::fork;
 840 #   + High-level debugger API cmd_*():
 841 #      cmd_b_load($filenamepart)            # b load filenamepart
 842 #      cmd_b_line($lineno [, $cond])        # b lineno [cond]
 843 #      cmd_b_sub($sub [, $cond])            # b sub [cond]
 844 #      cmd_stop()                           # Control-C
 845 #      cmd_d($lineno)                       # d lineno (B)
 846 #      The cmd_*() API returns FALSE on failure; in this case it outputs
 847 #      the error message to the debugging output.
 848 #   + Low-level debugger API
 849 #      break_on_load($filename)             # b load filename
 850 #      @files = report_break_on_load()      # List files with load-breakpoints
 851 #      breakable_line_in_filename($name, $from [, $to])
 852 #                                           # First breakable line in the
 853 #                                           # range $from .. $to.  $to defaults
 854 #                                           # to $from, and may be less than
 855 #                                           # $to
 856 #      breakable_line($from [, $to])        # Same for the current file
 857 #      break_on_filename_line($name, $lineno [, $cond])
 858 #                                           # Set breakpoint,$cond defaults to
 859 #                                           # 1
 860 #      break_on_filename_line_range($name, $from, $to [, $cond])
 861 #                                           # As above, on the first
 862 #                                           # breakable line in range
 863 #      break_on_line($lineno [, $cond])     # As above, in the current file
 864 #      break_subroutine($sub [, $cond])     # break on the first breakable line
 865 #      ($name, $from, $to) = subroutine_filename_lines($sub)
 866 #                                           # The range of lines of the text
 867 #      The low-level API returns TRUE on success, and die()s on failure.
 868 #
 869 # Changes: 1.10: May 23, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 870 #   BUG FIXES:
 871 #   + Fixed warnings generated by "perl -dWe 42"
 872 #   + Corrected spelling errors
 873 #   + Squeezed Help (h) output into 80 columns
 874 #
 875 # Changes: 1.11: May 24, 2001  David Dyck <dcd@tc.fluke.com>
 876 #   + Made "x @INC" work like it used to
 877 #
 878 # Changes: 1.12: May 24, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 879 #   + Fixed warnings generated by "O" (Show debugger options)
 880 #   + Fixed warnings generated by "p 42" (Print expression)
 881 # Changes: 1.13: Jun 19, 2001 Scott.L.Miller@compaq.com
 882 #   + Added windowSize option
 883 # Changes: 1.14: Oct  9, 2001 multiple
 884 #   + Clean up after itself on VMS (Charles Lane in 12385)
 885 #   + Adding "@ file" syntax (Peter Scott in 12014)
 886 #   + Debug reloading selfloaded stuff (Ilya Zakharevich in 11457)
 887 #   + $^S and other debugger fixes (Ilya Zakharevich in 11120)
 888 #   + Forgot a my() declaration (Ilya Zakharevich in 11085)
 889 # Changes: 1.15: Nov  6, 2001 Michael G Schwern <schwern@pobox.com>
 890 #   + Updated 1.14 change log
 891 #   + Added *dbline explainatory comments
 892 #   + Mentioning perldebguts man page
 893 # Changes: 1.16: Feb 15, 2002 Mark-Jason Dominus <mjd@plover.com>
 894 #   + $onetimeDump improvements
 895 # Changes: 1.17: Feb 20, 2002 Richard Foley <richard.foley@rfi.net>
 896 #   Moved some code to cmd_[.]()'s for clarity and ease of handling,
 897 #   rationalised the following commands and added cmd_wrapper() to
 898 #   enable switching between old and frighteningly consistent new
 899 #   behaviours for diehards: 'o CommandSet=pre580' (sigh...)
 900 #     a(add),       A(del)            # action expr   (added del by line)
 901 #   + b(add),       B(del)            # break  [line] (was b,D)
 902 #   + w(add),       W(del)            # watch  expr   (was W,W)
 903 #                                     # added del by expr
 904 #   + h(summary), h h(long)           # help (hh)     (was h h,h)
 905 #   + m(methods),   M(modules)        # ...           (was m,v)
 906 #   + o(option)                       # lc            (was O)
 907 #   + v(view code), V(view Variables) # ...           (was w,V)
 908 # Changes: 1.18: Mar 17, 2002 Richard Foley <richard.foley@rfi.net>
 909 #   + fixed missing cmd_O bug
 910 # Changes: 1.19: Mar 29, 2002 Spider Boardman
 911 #   + Added missing local()s -- DB::DB is called recursively.
 912 # Changes: 1.20: Feb 17, 2003 Richard Foley <richard.foley@rfi.net>
 913 #   + pre'n'post commands no longer trashed with no args
 914 #   + watch val joined out of eval()
 915 # Changes: 1.21: Jun 04, 2003 Joe McMahon <mcmahon@ibiblio.org>
 916 #   + Added comments and reformatted source. No bug fixes/enhancements.
 917 #   + Includes cleanup by Robin Barker and Jarkko Hietaniemi.
 918 # Changes: 1.22  Jun 09, 2003 Alex Vandiver <alexmv@MIT.EDU>
 919 #   + Flush stdout/stderr before the debugger prompt is printed.
 920 # Changes: 1.23: Dec 21, 2003 Dominique Quatravaux
 921 #   + Fix a side-effect of bug #24674 in the perl debugger ("odd taint bug")
 922 # Changes: 1.24: Mar 03, 2004 Richard Foley <richard.foley@rfi.net>
 923 #   + Added command to save all debugger commands for sourcing later.
 924 #   + Added command to display parent inheritance tree of given class.
 925 #   + Fixed minor newline in history bug.
 926 # Changes: 1.25: Apr 17, 2004 Richard Foley <richard.foley@rfi.net>
 927 #   + Fixed option bug (setting invalid options + not recognising valid short forms)
 928 # Changes: 1.26: Apr 22, 2004 Richard Foley <richard.foley@rfi.net>
 929 #   + unfork the 5.8.x and 5.9.x debuggers.
 930 #   + whitespace and assertions call cleanup across versions
 931 #   + H * deletes (resets) history
 932 #   + i now handles Class + blessed objects
 933 # Changes: 1.27: May 09, 2004 Richard Foley <richard.foley@rfi.net>
 934 #   + updated pod page references - clunky.
 935 #   + removed windowid restriction for forking into an xterm.
 936 #   + more whitespace again.
 937 #   + wrapped restart and enabled rerun [-n] (go back n steps) command.
 938 # Changes: 1.28: Oct 12, 2004 Richard Foley <richard.foley@rfi.net>
 939 #   + Added threads support (inc. e and E commands)
 940 # Changes: 1.29: Nov 28, 2006 Bo Lindbergh <blgl@hagernas.com>
 941 #   + Added macosx_get_fork_TTY support
 942 # Changes: 1.30: Mar 06, 2007 Andreas Koenig <andk@cpan.org>
 943 #   + Added HistFile, HistSize
 944 ########################################################################
 945
 946 =head1 DEBUGGER INITIALIZATION
 947
 948 The debugger starts up in phases.
 949
 950 =head2 BASIC SETUP
 951
 952 First, it initializes the environment it wants to run in: turning off
 953 warnings during its own compilation, defining variables which it will need
 954 to avoid warnings later, setting itself up to not exit when the program
 955 terminates, and defaulting to printing return values for the C<r> command.
 956
 957 =cut
 958
 959 # Needed for the statement after exec():
 960 #
 961 # This BEGIN block is simply used to switch off warnings during debugger
 962 # compiliation. Probably it would be better practice to fix the warnings,
 963 # but this is how it's done at the moment.
 964
 965 BEGIN {
 966     $ini_warn = $^W;
 967     $^W       = 0;
 968 }    # Switch compilation warnings off until another BEGIN.
 969
 970 local ($^W) = 0;    # Switch run-time warnings off during init.
 971
 972 =head2 THREADS SUPPORT
 973
 974 If we are running under a threaded Perl, we require threads and threads::shared
 975 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 976 threaded debugger control.  C<-dt> can also be used to set this.
 977
 978 Each new thread will be announced and the debugger prompt will always inform
 979 you of each new thread created.  It will also indicate the thread id in which
 980 we are currently running within the prompt like this:
 981
 982         [tid] DB<$i>
 983
 984 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 985 command prompt.  The prompt will show: C<[0]> when running under threads, but
 986 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 987
 988 While running under threads, when you set or delete a breakpoint (etc.), this
 989 will apply to all threads, not just the currently running one.  When you are
 990 in a currently executing thread, you will stay there until it completes.  With
 991 the current implementation it is not currently possible to hop from one thread
 992 to another.
 993
 994 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 995
 996 Note that threading support was built into the debugger as of Perl version
 997 C<5.8.6> and debugger version C<1.2.8>.
 998
 999 =cut
1000
1001 BEGIN {
1002   # ensure we can share our non-threaded variables or no-op
1003   if ($ENV{PERL5DB_THREADED}) {
1004         require threads;
1005         require threads::shared;
1006         import threads::shared qw(share);
1007         $DBGR;
1008         share(\$DBGR);
1009         lock($DBGR);
1010         print "Threads support enabled\n";
1011   } else {
1012         *lock  = sub(*) {};
1013         *share = sub(*) {};
1014   }
1015 }
1016
1017 # This would probably be better done with "use vars", but that wasn't around
1018 # when this code was originally written. (Neither was "use strict".) And on
1019 # the principle of not fiddling with something that was working, this was
1020 # left alone.
1021 warn(               # Do not ;-)
1022     # These variables control the execution of 'dumpvar.pl'.
1023     $dumpvar::hashDepth,
1024     $dumpvar::arrayDepth,
1025     $dumpvar::dumpDBFiles,
1026     $dumpvar::dumpPackages,
1027     $dumpvar::quoteHighBit,
1028     $dumpvar::printUndef,
1029     $dumpvar::globPrint,
1030     $dumpvar::usageOnly,
1031
1032     # used to save @ARGV and extract any debugger-related flags.
1033     @ARGS,
1034
1035     # used to control die() reporting in diesignal()
1036     $Carp::CarpLevel,
1037
1038     # used to prevent multiple entries to diesignal()
1039     # (if for instance diesignal() itself dies)
1040     $panic,
1041
1042     # used to prevent the debugger from running nonstop
1043     # after a restart
1044     $second_time,
1045   )
1046   if 0;
1047
1048 foreach my $k (keys (%INC)) {
1049         &share(\$main::{'_<'.$filename});
1050 };
1051
1052 # Command-line + PERLLIB:
1053 # Save the contents of @INC before they are modified elsewhere.
1054 @ini_INC = @INC;
1055
1056 # This was an attempt to clear out the previous values of various
1057 # trapped errors. Apparently it didn't help. XXX More info needed!
1058 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
1059
1060 # We set these variables to safe values. We don't want to blindly turn
1061 # off warnings, because other packages may still want them.
1062 $trace = $signal = $single = 0;    # Uninitialized warning suppression
1063                                    # (local $^W cannot help - other packages!).
1064
1065 # Default to not exiting when program finishes; print the return
1066 # value when the 'r' command is used to return from a subroutine.
1067 $inhibit_exit = $option{PrintRet} = 1;
1068
1069 =head1 OPTION PROCESSING
1070
1071 The debugger's options are actually spread out over the debugger itself and
1072 C<dumpvar.pl>; some of these are variables to be set, while others are
1073 subs to be called with a value. To try to make this a little easier to
1074 manage, the debugger uses a few data structures to define what options
1075 are legal and how they are to be processed.
1076
1077 First, the C<@options> array defines the I<names> of all the options that
1078 are to be accepted.
1079
1080 =cut
1081
1082 @options = qw(
1083   CommandSet   HistFile      HistSize
1084   hashDepth    arrayDepth    dumpDepth
1085   DumpDBFiles  DumpPackages  DumpReused
1086   compactDump  veryCompact   quote
1087   HighBit      undefPrint    globPrint
1088   PrintRet     UsageOnly     frame
1089   AutoTrace    TTY           noTTY
1090   ReadLine     NonStop       LineInfo
1091   maxTraceLen  recallCommand ShellBang
1092   pager        tkRunning     ornaments
1093   signalLevel  warnLevel     dieLevel
1094   inhibit_exit ImmediateStop bareStringify
1095   CreateTTY    RemotePort    windowSize
1096   DollarCaretP
1097 );
1098
1099 @RememberOnROptions = qw(DollarCaretP);
1100
1101 =pod
1102
1103 Second, C<optionVars> lists the variables that each option uses to save its
1104 state.
1105
1106 =cut
1107
1108 %optionVars = (
1109     hashDepth     => \$dumpvar::hashDepth,
1110     arrayDepth    => \$dumpvar::arrayDepth,
1111     CommandSet    => \$CommandSet,
1112     DumpDBFiles   => \$dumpvar::dumpDBFiles,
1113     DumpPackages  => \$dumpvar::dumpPackages,
1114     DumpReused    => \$dumpvar::dumpReused,
1115     HighBit       => \$dumpvar::quoteHighBit,
1116     undefPrint    => \$dumpvar::printUndef,
1117     globPrint     => \$dumpvar::globPrint,
1118     UsageOnly     => \$dumpvar::usageOnly,
1119     CreateTTY     => \$CreateTTY,
1120     bareStringify => \$dumpvar::bareStringify,
1121     frame         => \$frame,
1122     AutoTrace     => \$trace,
1123     inhibit_exit  => \$inhibit_exit,
1124     maxTraceLen   => \$maxtrace,
1125     ImmediateStop => \$ImmediateStop,
1126     RemotePort    => \$remoteport,
1127     windowSize    => \$window,
1128     HistFile      => \$histfile,
1129     HistSize      => \$histsize,
1130 );
1131
1132 =pod
1133
1134 Third, C<%optionAction> defines the subroutine to be called to process each
1135 option.
1136
1137 =cut
1138
1139 %optionAction = (
1140     compactDump   => \&dumpvar::compactDump,
1141     veryCompact   => \&dumpvar::veryCompact,
1142     quote         => \&dumpvar::quote,
1143     TTY           => \&TTY,
1144     noTTY         => \&noTTY,
1145     ReadLine      => \&ReadLine,
1146     NonStop       => \&NonStop,
1147     LineInfo      => \&LineInfo,
1148     recallCommand => \&recallCommand,
1149     ShellBang     => \&shellBang,
1150     pager         => \&pager,
1151     signalLevel   => \&signalLevel,
1152     warnLevel     => \&warnLevel,
1153     dieLevel      => \&dieLevel,
1154     tkRunning     => \&tkRunning,
1155     ornaments     => \&ornaments,
1156     RemotePort    => \&RemotePort,
1157     DollarCaretP  => \&DollarCaretP,
1158 );
1159
1160 =pod
1161
1162 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1163 option is used.
1164
1165 =cut
1166
1167 # Note that this list is not complete: several options not listed here
1168 # actually require that dumpvar.pl be loaded for them to work, but are
1169 # not in the table. A subsequent patch will correct this problem; for
1170 # the moment, we're just recommenting, and we are NOT going to change
1171 # function.
1172 %optionRequire = (
1173     compactDump => 'dumpvar.pl',
1174     veryCompact => 'dumpvar.pl',
1175     quote       => 'dumpvar.pl',
1176 );
1177
1178 =pod
1179
1180 There are a number of initialization-related variables which can be set
1181 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1182 variable. These are:
1183
1184 =over 4
1185
1186 =item C<$rl> - readline control XXX needs more explanation
1187
1188 =item C<$warnLevel> - whether or not debugger takes over warning handling
1189
1190 =item C<$dieLevel> - whether or not debugger takes over die handling
1191
1192 =item C<$signalLevel> - whether or not debugger takes over signal handling
1193
1194 =item C<$pre> - preprompt actions (array reference)
1195
1196 =item C<$post> - postprompt actions (array reference)
1197
1198 =item C<$pretype>
1199
1200 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1201
1202 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1203
1204 =back
1205
1206 =cut
1207
1208 # These guys may be defined in $ENV{PERL5DB} :
1209 $rl          = 1     unless defined $rl;
1210 $warnLevel   = 1     unless defined $warnLevel;
1211 $dieLevel    = 1     unless defined $dieLevel;
1212 $signalLevel = 1     unless defined $signalLevel;
1213 $pre         = []    unless defined $pre;
1214 $post        = []    unless defined $post;
1215 $pretype     = []    unless defined $pretype;
1216 $CreateTTY   = 3     unless defined $CreateTTY;
1217 $CommandSet  = '580' unless defined $CommandSet;
1218
1219 share($rl);
1220 share($warnLevel);
1221 share($dieLevel);
1222 share($signalLevel);
1223 share($pre);
1224 share($post);
1225 share($pretype);
1226 share($rl);
1227 share($CreateTTY);
1228 share($CommandSet);
1229
1230 =pod
1231
1232 The default C<die>, C<warn>, and C<signal> handlers are set up.
1233
1234 =cut
1235
1236 warnLevel($warnLevel);
1237 dieLevel($dieLevel);
1238 signalLevel($signalLevel);
1239
1240 =pod
1241
1242 The pager to be used is needed next. We try to get it from the
1243 environment first.  If it's not defined there, we try to find it in
1244 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1245 then call the C<pager()> function to save the pager name.
1246
1247 =cut
1248
1249 # This routine makes sure $pager is set up so that '|' can use it.
1250 pager(
1251
1252     # If PAGER is defined in the environment, use it.
1253     defined $ENV{PAGER}
1254     ? $ENV{PAGER}
1255
1256       # If not, see if Config.pm defines it.
1257     : eval { require Config }
1258       && defined $Config::Config{pager}
1259     ? $Config::Config{pager}
1260
1261       # If not, fall back to 'more'.
1262     : 'more'
1263   )
1264   unless defined $pager;
1265
1266 =pod
1267
1268 We set up the command to be used to access the man pages, the command
1269 recall character (C<!> unless otherwise defined) and the shell escape
1270 character (C<!> unless otherwise defined). Yes, these do conflict, and
1271 neither works in the debugger at the moment.
1272
1273 =cut
1274
1275 setman();
1276
1277 # Set up defaults for command recall and shell escape (note:
1278 # these currently don't work in linemode debugging).
1279 &recallCommand("!") unless defined $prc;
1280 &shellBang("!")     unless defined $psh;
1281
1282 =pod
1283
1284 We then set up the gigantic string containing the debugger help.
1285 We also set the limit on the number of arguments we'll display during a
1286 trace.
1287
1288 =cut
1289
1290 sethelp();
1291
1292 # If we didn't get a default for the length of eval/stack trace args,
1293 # set it here.
1294 $maxtrace = 400 unless defined $maxtrace;
1295
1296 =head2 SETTING UP THE DEBUGGER GREETING
1297
1298 The debugger I<greeting> helps to inform the user how many debuggers are
1299 running, and whether the current debugger is the primary or a child.
1300
1301 If we are the primary, we just hang onto our pid so we'll have it when
1302 or if we start a child debugger. If we are a child, we'll set things up
1303 so we'll have a unique greeting and so the parent will give us our own
1304 TTY later.
1305
1306 We save the current contents of the C<PERLDB_PIDS> environment variable
1307 because we mess around with it. We'll also need to hang onto it because
1308 we'll need it if we restart.
1309
1310 Child debuggers make a label out of the current PID structure recorded in
1311 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1312 yet so the parent will give them one later via C<resetterm()>.
1313
1314 =cut
1315
1316 # Save the current contents of the environment; we're about to
1317 # much with it. We'll need this if we have to restart.
1318 $ini_pids = $ENV{PERLDB_PIDS};
1319
1320 if ( defined $ENV{PERLDB_PIDS} ) {
1321
1322     # We're a child. Make us a label out of the current PID structure
1323     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1324     # a term yet so the parent will give us one later via resetterm().
1325
1326     my $env_pids = $ENV{PERLDB_PIDS};
1327     $pids = "[$env_pids]";
1328
1329     # Unless we are on OpenVMS, all programs under the DCL shell run under
1330     # the same PID.
1331
1332     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1333         $term_pid         = $$;
1334     }
1335     else {
1336         $ENV{PERLDB_PIDS} .= "->$$";
1337         $term_pid = -1;
1338     }
1339
1340 } ## end if (defined $ENV{PERLDB_PIDS...
1341 else {
1342
1343     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1344     # child debugger, and mark us as the parent, so we'll know to set up
1345     # more TTY's is we have to.
1346     $ENV{PERLDB_PIDS} = "$$";
1347     $pids             = "[pid=$$]";
1348     $term_pid         = $$;
1349 }
1350
1351 $pidprompt = '';
1352
1353 # Sets up $emacs as a synonym for $slave_editor.
1354 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1355
1356 =head2 READING THE RC FILE
1357
1358 The debugger will read a file of initialization options if supplied. If
1359 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1360
1361 =cut
1362
1363 # As noted, this test really doesn't check accurately that the debugger
1364 # is running at a terminal or not.
1365
1366 my $dev_tty = '/dev/tty';
1367    $dev_tty = 'TT:' if ($^O eq 'VMS');
1368 if ( -e $dev_tty ) {                      # this is the wrong metric!
1369     $rcfile = ".perldb";
1370 }
1371 else {
1372     $rcfile = "perldb.ini";
1373 }
1374
1375 =pod
1376
1377 The debugger does a safety test of the file to be read. It must be owned
1378 either by the current user or root, and must only be writable by the owner.
1379
1380 =cut
1381
1382 # This wraps a safety test around "do" to read and evaluate the init file.
1383 #
1384 # This isn't really safe, because there's a race
1385 # between checking and opening.  The solution is to
1386 # open and fstat the handle, but then you have to read and
1387 # eval the contents.  But then the silly thing gets
1388 # your lexical scope, which is unfortunate at best.
1389 sub safe_do {
1390     my $file = shift;
1391
1392     # Just exactly what part of the word "CORE::" don't you understand?
1393     local $SIG{__WARN__};
1394     local $SIG{__DIE__};
1395
1396     unless ( is_safe_file($file) ) {
1397         CORE::warn <<EO_GRIPE;
1398 perldb: Must not source insecure rcfile $file.
1399         You or the superuser must be the owner, and it must not
1400         be writable by anyone but its owner.
1401 EO_GRIPE
1402         return;
1403     } ## end unless (is_safe_file($file...
1404
1405     do $file;
1406     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1407 } ## end sub safe_do
1408
1409 # This is the safety test itself.
1410 #
1411 # Verifies that owner is either real user or superuser and that no
1412 # one but owner may write to it.  This function is of limited use
1413 # when called on a path instead of upon a handle, because there are
1414 # no guarantees that filename (by dirent) whose file (by ino) is
1415 # eventually accessed is the same as the one tested.
1416 # Assumes that the file's existence is not in doubt.
1417 sub is_safe_file {
1418     my $path = shift;
1419     stat($path) || return;    # mysteriously vaporized
1420     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1421
1422     return 0 if $uid != 0 && $uid != $<;
1423     return 0 if $mode & 022;
1424     return 1;
1425 } ## end sub is_safe_file
1426
1427 # If the rcfile (whichever one we decided was the right one to read)
1428 # exists, we safely do it.
1429 if ( -f $rcfile ) {
1430     safe_do("./$rcfile");
1431 }
1432
1433 # If there isn't one here, try the user's home directory.
1434 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1435     safe_do("$ENV{HOME}/$rcfile");
1436 }
1437
1438 # Else try the login directory.
1439 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1440     safe_do("$ENV{LOGDIR}/$rcfile");
1441 }
1442
1443 # If the PERLDB_OPTS variable has options in it, parse those out next.
1444 if ( defined $ENV{PERLDB_OPTS} ) {
1445     parse_options( $ENV{PERLDB_OPTS} );
1446 }
1447
1448 =pod
1449
1450 The last thing we do during initialization is determine which subroutine is
1451 to be used to obtain a new terminal when a new debugger is started. Right now,
1452 the debugger only handles X Windows, OS/2, and Mac OS X (darwin).
1453
1454 =cut
1455
1456 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1457 # Works if you're running an xterm or xterm-like window, or you're on
1458 # OS/2, or on Mac OS X. This may need some expansion.
1459
1460 if (not defined &get_fork_TTY)       # only if no routine exists
1461 {
1462     if (defined $ENV{TERM}                       # If we know what kind
1463                                                  # of terminal this is,
1464         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1465         and defined $ENV{DISPLAY}                # and what display it's on,
1466       )
1467     {
1468         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1469     }
1470     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1471         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1472     }
1473     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1474             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1475             and $ENV{TERM_PROGRAM}
1476                 eq 'Apple_Terminal'              # Terminal.app
1477             )
1478     {
1479         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1480     }
1481 } ## end if (not defined &get_fork_TTY...
1482
1483 # untaint $^O, which may have been tainted by the last statement.
1484 # see bug [perl #24674]
1485 $^O =~ m/^(.*)\z/;
1486 $^O = $1;
1487
1488 # Here begin the unreadable code.  It needs fixing.
1489
1490 =head2 RESTART PROCESSING
1491
1492 This section handles the restart command. When the C<R> command is invoked, it
1493 tries to capture all of the state it can into environment variables, and
1494 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1495 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1496 the R command stuffed into the environment variables.
1497
1498   PERLDB_RESTART   - flag only, contains no restart data itself.
1499   PERLDB_HIST      - command history, if it's available
1500   PERLDB_ON_LOAD   - breakpoints set by the rc file
1501   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1502   PERLDB_VISITED   - files that had breakpoints
1503   PERLDB_FILE_...  - breakpoints for a file
1504   PERLDB_OPT       - active options
1505   PERLDB_INC       - the original @INC
1506   PERLDB_PRETYPE   - preprompt debugger actions
1507   PERLDB_PRE       - preprompt Perl code
1508   PERLDB_POST      - post-prompt Perl code
1509   PERLDB_TYPEAHEAD - typeahead captured by readline()
1510
1511 We chug through all these variables and plug the values saved in them
1512 back into the appropriate spots in the debugger.
1513
1514 =cut
1515
1516 if ( exists $ENV{PERLDB_RESTART} ) {
1517
1518     # We're restarting, so we don't need the flag that says to restart anymore.
1519     delete $ENV{PERLDB_RESTART};
1520
1521     # $restart = 1;
1522     @hist          = get_list('PERLDB_HIST');
1523     %break_on_load = get_list("PERLDB_ON_LOAD");
1524     %postponed     = get_list("PERLDB_POSTPONE");
1525
1526         share(@hist);
1527         share(@truehist);
1528         share(%break_on_load);
1529         share(%postponed);
1530
1531     # restore breakpoints/actions
1532     my @had_breakpoints = get_list("PERLDB_VISITED");
1533     for ( 0 .. $#had_breakpoints ) {
1534         my %pf = get_list("PERLDB_FILE_$_");
1535         $postponed_file{ $had_breakpoints[$_] } = \%pf if %pf;
1536     }
1537
1538     # restore options
1539     my %opt = get_list("PERLDB_OPT");
1540     my ( $opt, $val );
1541     while ( ( $opt, $val ) = each %opt ) {
1542         $val =~ s/[\\\']/\\$1/g;
1543         parse_options("$opt'$val'");
1544     }
1545
1546     # restore original @INC
1547     @INC     = get_list("PERLDB_INC");
1548     @ini_INC = @INC;
1549
1550     # return pre/postprompt actions and typeahead buffer
1551     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1552     $pre       = [ get_list("PERLDB_PRE") ];
1553     $post      = [ get_list("PERLDB_POST") ];
1554     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1555 } ## end if (exists $ENV{PERLDB_RESTART...
1556
1557 =head2 SETTING UP THE TERMINAL
1558
1559 Now, we'll decide how the debugger is going to interact with the user.
1560 If there's no TTY, we set the debugger to run non-stop; there's not going
1561 to be anyone there to enter commands.
1562
1563 =cut
1564
1565 if ($notty) {
1566     $runnonstop = 1;
1567         share($runnonstop);
1568 }
1569
1570 =pod
1571
1572 If there is a TTY, we have to determine who it belongs to before we can
1573 proceed. If this is a slave editor or graphical debugger (denoted by
1574 the first command-line switch being '-emacs'), we shift this off and
1575 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1576
1577 =cut
1578
1579 else {
1580
1581     # Is Perl being run from a slave editor or graphical debugger?
1582     # If so, don't use readline, and set $slave_editor = 1.
1583     $slave_editor =
1584       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1585     $rl = 0, shift(@main::ARGV) if $slave_editor;
1586
1587     #require Term::ReadLine;
1588
1589 =pod
1590
1591 We then determine what the console should be on various systems:
1592
1593 =over 4
1594
1595 =item * Cygwin - We use C<stdin> instead of a separate device.
1596
1597 =cut
1598
1599     if ( $^O eq 'cygwin' ) {
1600
1601         # /dev/tty is binary. use stdin for textmode
1602         undef $console;
1603     }
1604
1605 =item * Unix - use C</dev/tty>.
1606
1607 =cut
1608
1609     elsif ( -e "/dev/tty" ) {
1610         $console = "/dev/tty";
1611     }
1612
1613 =item * Windows or MSDOS - use C<con>.
1614
1615 =cut
1616
1617     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1618         $console = "con";
1619     }
1620
1621 =item * MacOS - use C<Dev:Console:Perl Debug> if this is the MPW version; C<Dev:
1622 Console> if not.
1623
1624 Note that Mac OS X returns C<darwin>, not C<MacOS>. Also note that the debugger doesn't do anything special for C<darwin>. Maybe it should.
1625
1626 =cut
1627
1628     elsif ( $^O eq 'MacOS' ) {
1629         if ( $MacPerl::Version !~ /MPW/ ) {
1630             $console =
1631               "Dev:Console:Perl Debug";    # Separate window for application
1632         }
1633         else {
1634             $console = "Dev:Console";
1635         }
1636     } ## end elsif ($^O eq 'MacOS')
1637
1638 =item * VMS - use C<sys$command>.
1639
1640 =cut
1641
1642     else {
1643
1644         # everything else is ...
1645         $console = "sys\$command";
1646     }
1647
1648 =pod
1649
1650 =back
1651
1652 Several other systems don't use a specific console. We C<undef $console>
1653 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1654 with a slave editor, Epoc).
1655
1656 =cut
1657
1658     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1659
1660         # /dev/tty is binary. use stdin for textmode
1661         $console = undef;
1662     }
1663
1664     if ( $^O eq 'NetWare' ) {
1665
1666         # /dev/tty is binary. use stdin for textmode
1667         $console = undef;
1668     }
1669
1670     # In OS/2, we need to use STDIN to get textmode too, even though
1671     # it pretty much looks like Unix otherwise.
1672     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1673     {    # In OS/2
1674         $console = undef;
1675     }
1676
1677     # EPOC also falls into the 'got to use STDIN' camp.
1678     if ( $^O eq 'epoc' ) {
1679         $console = undef;
1680     }
1681
1682 =pod
1683
1684 If there is a TTY hanging around from a parent, we use that as the console.
1685
1686 =cut
1687
1688     $console = $tty if defined $tty;
1689
1690 =head2 SOCKET HANDLING
1691
1692 The debugger is capable of opening a socket and carrying out a debugging
1693 session over the socket.
1694
1695 If C<RemotePort> was defined in the options, the debugger assumes that it
1696 should try to start a debugging session on that port. It builds the socket
1697 and then tries to connect the input and output filehandles to it.
1698
1699 =cut
1700
1701     # Handle socket stuff.
1702
1703     if ( defined $remoteport ) {
1704
1705         # If RemotePort was defined in the options, connect input and output
1706         # to the socket.
1707         require IO::Socket;
1708         $OUT = new IO::Socket::INET(
1709             Timeout  => '10',
1710             PeerAddr => $remoteport,
1711             Proto    => 'tcp',
1712         );
1713         if ( !$OUT ) { die "Unable to connect to remote host: $remoteport\n"; }
1714         $IN = $OUT;
1715     } ## end if (defined $remoteport)
1716
1717 =pod
1718
1719 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1720 this is probably a situation where multiple debuggers are running (for example,
1721 a backticked command that starts up another debugger). We create a new IN and
1722 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1723 and if we can.
1724
1725 =cut
1726
1727     # Non-socket.
1728     else {
1729
1730         # Two debuggers running (probably a system or a backtick that invokes
1731         # the debugger itself under the running one). create a new IN and OUT
1732         # filehandle, and do the necessary mojo to create a new tty if we
1733         # know how, and we can.
1734         create_IN_OUT(4) if $CreateTTY & 4;
1735         if ($console) {
1736
1737             # If we have a console, check to see if there are separate ins and
1738             # outs to open. (They are assumed identical if not.)
1739
1740             my ( $i, $o ) = split /,/, $console;
1741             $o = $i unless defined $o;
1742
1743             # read/write on in, or just read, or read on STDIN.
1744             open( IN,      "+<$i" )
1745               || open( IN, "<$i" )
1746               || open( IN, "<&STDIN" );
1747
1748             # read/write/create/clobber out, or write/create/clobber out,
1749             # or merge with STDERR, or merge with STDOUT.
1750                  open( OUT, "+>$o" )
1751               || open( OUT, ">$o" )
1752               || open( OUT, ">&STDERR" )
1753               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1754
1755         } ## end if ($console)
1756         elsif ( not defined $console ) {
1757
1758             # No console. Open STDIN.
1759             open( IN, "<&STDIN" );
1760
1761             # merge with STDERR, or with STDOUT.
1762             open( OUT,      ">&STDERR" )
1763               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1764             $console = 'STDIN/OUT';
1765         } ## end elsif (not defined $console)
1766
1767         # Keep copies of the filehandles so that when the pager runs, it
1768         # can close standard input without clobbering ours.
1769         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1770     } ## end elsif (from if(defined $remoteport))
1771
1772     # Unbuffer DB::OUT. We need to see responses right away.
1773     my $previous = select($OUT);
1774     $| = 1;                                  # for DB::OUT
1775     select($previous);
1776
1777     # Line info goes to debugger output unless pointed elsewhere.
1778     # Pointing elsewhere makes it possible for slave editors to
1779     # keep track of file and position. We have both a filehandle
1780     # and a I/O description to keep track of.
1781     $LINEINFO = $OUT     unless defined $LINEINFO;
1782     $lineinfo = $console unless defined $lineinfo;
1783         # share($LINEINFO); # <- unable to share globs
1784         share($lineinfo);   #
1785
1786 =pod
1787
1788 To finish initialization, we show the debugger greeting,
1789 and then call the C<afterinit()> subroutine if there is one.
1790
1791 =cut
1792
1793     # Show the debugger greeting.
1794     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1795     unless ($runnonstop) {
1796         local $\ = '';
1797         local $, = '';
1798         if ( $term_pid eq '-1' ) {
1799             print $OUT "\nDaughter DB session started...\n";
1800         }
1801         else {
1802             print $OUT "\nLoading DB routines from $header\n";
1803             print $OUT (
1804                 "Editor support ",
1805                 $slave_editor ? "enabled" : "available", ".\n"
1806             );
1807             print $OUT
1808 "\nEnter h or `h h' for help, or `$doccmd perldebug' for more help.\n\n";
1809         } ## end else [ if ($term_pid eq '-1')
1810     } ## end unless ($runnonstop)
1811 } ## end else [ if ($notty)
1812
1813 # XXX This looks like a bug to me.
1814 # Why copy to @ARGS and then futz with @args?
1815 @ARGS = @ARGV;
1816 for (@args) {
1817     # Make sure backslashes before single quotes are stripped out, and
1818     # keep args unless they are numeric (XXX why?)
1819     # s/\'/\\\'/g;                      # removed while not justified understandably
1820     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1821 }
1822
1823 # If there was an afterinit() sub defined, call it. It will get
1824 # executed in our scope, so it can fiddle with debugger globals.
1825 if ( defined &afterinit ) {    # May be defined in $rcfile
1826     &afterinit();
1827 }
1828
1829 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1830 $I_m_init = 1;
1831
1832 ############################################################ Subroutines
1833
1834 =head1 SUBROUTINES
1835
1836 =head2 DB
1837
1838 This gigantic subroutine is the heart of the debugger. Called before every
1839 statement, its job is to determine if a breakpoint has been reached, and
1840 stop if so; read commands from the user, parse them, and execute
1841 them, and hen send execution off to the next statement.
1842
1843 Note that the order in which the commands are processed is very important;
1844 some commands earlier in the loop will actually alter the C<$cmd> variable
1845 to create other commands to be executed later. This is all highly I<optimized>
1846 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1847 see what's happening in any given command.
1848
1849 =cut
1850
1851 sub DB {
1852
1853     # lock the debugger and get the thread id for the prompt
1854         lock($DBGR);
1855         my $tid;
1856         if ($ENV{PERL5DB_THREADED}) {
1857                 $tid = eval { "[".threads->tid."]" };
1858         }
1859
1860     # Check for whether we should be running continuously or not.
1861     # _After_ the perl program is compiled, $single is set to 1:
1862     if ( $single and not $second_time++ ) {
1863
1864         # Options say run non-stop. Run until we get an interrupt.
1865         if ($runnonstop) {    # Disable until signal
1866                 # If there's any call stack in place, turn off single
1867                 # stepping into subs throughout the stack.
1868             for ( $i = 0 ; $i <= $stack_depth ; ) {
1869                 $stack[ $i++ ] &= ~1;
1870             }
1871
1872             # And we are now no longer in single-step mode.
1873             $single = 0;
1874
1875             # If we simply returned at this point, we wouldn't get
1876             # the trace info. Fall on through.
1877             # return;
1878         } ## end if ($runnonstop)
1879
1880         elsif ($ImmediateStop) {
1881
1882             # We are supposed to stop here; XXX probably a break.
1883             $ImmediateStop = 0;    # We've processed it; turn it off
1884             $signal        = 1;    # Simulate an interrupt to force
1885                                    # us into the command loop
1886         }
1887     } ## end if ($single and not $second_time...
1888
1889     # If we're in single-step mode, or an interrupt (real or fake)
1890     # has occurred, turn off non-stop mode.
1891     $runnonstop = 0 if $single or $signal;
1892
1893     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1894     # The code being debugged may have altered them.
1895     &save;
1896
1897     # Since DB::DB gets called after every line, we can use caller() to
1898     # figure out where we last were executing. Sneaky, eh? This works because
1899     # caller is returning all the extra information when called from the
1900     # debugger.
1901     local ( $package, $filename, $line ) = caller;
1902     local $filename_ini = $filename;
1903
1904     # set up the context for DB::eval, so it can properly execute
1905     # code on behalf of the user. We add the package in so that the
1906     # code is eval'ed in the proper package (not in the debugger!).
1907     local $usercontext =
1908       '($@, $!, $^E, $,, $/, $\, $^W) = @saved;' . "package $package;";
1909
1910     # Create an alias to the active file magical array to simplify
1911     # the code here.
1912     local (*dbline) = $main::{ '_<' . $filename };
1913
1914     # we need to check for pseudofiles on Mac OS (these are files
1915     # not attached to a filename, but instead stored in Dev:Pseudo)
1916     if ( $^O eq 'MacOS' && $#dbline < 0 ) {
1917         $filename_ini = $filename = 'Dev:Pseudo';
1918         *dbline = $main::{ '_<' . $filename };
1919     }
1920
1921     # Last line in the program.
1922     local $max = $#dbline;
1923
1924     # if we have something here, see if we should break.
1925     if ( $dbline{$line}
1926         && ( ( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1927     {
1928
1929         # Stop if the stop criterion says to just stop.
1930         if ( $stop eq '1' ) {
1931             $signal |= 1;
1932         }
1933
1934         # It's a conditional stop; eval it in the user's context and
1935         # see if we should stop. If so, remove the one-time sigil.
1936         elsif ($stop) {
1937             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1938             &eval;
1939             $dbline{$line} =~ s/;9($|\0)/$1/;
1940         }
1941     } ## end if ($dbline{$line} && ...
1942
1943     # Preserve the current stop-or-not, and see if any of the W
1944     # (watch expressions) has changed.
1945     my $was_signal = $signal;
1946
1947     # If we have any watch expressions ...
1948     if ( $trace & 2 ) {
1949         for ( my $n = 0 ; $n <= $#to_watch ; $n++ ) {
1950             $evalarg = $to_watch[$n];
1951             local $onetimeDump;    # Tell DB::eval() to not output results
1952
1953             # Fix context DB::eval() wants to return an array, but
1954             # we need a scalar here.
1955             my ($val) = join( "', '", &eval );
1956             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1957
1958             # Did it change?
1959             if ( $val ne $old_watch[$n] ) {
1960
1961                 # Yep! Show the difference, and fake an interrupt.
1962                 $signal = 1;
1963                 print $OUT <<EOP;
1964 Watchpoint $n:\t$to_watch[$n] changed:
1965     old value:\t$old_watch[$n]
1966     new value:\t$val
1967 EOP
1968                 $old_watch[$n] = $val;
1969             } ## end if ($val ne $old_watch...
1970         } ## end for (my $n = 0 ; $n <= ...
1971     } ## end if ($trace & 2)
1972
1973 =head2 C<watchfunction()>
1974
1975 C<watchfunction()> is a function that can be defined by the user; it is a
1976 function which will be run on each entry to C<DB::DB>; it gets the
1977 current package, filename, and line as its parameters.
1978
1979 The watchfunction can do anything it likes; it is executing in the
1980 debugger's context, so it has access to all of the debugger's internal
1981 data structures and functions.
1982
1983 C<watchfunction()> can control the debugger's actions. Any of the following
1984 will cause the debugger to return control to the user's program after
1985 C<watchfunction()> executes:
1986
1987 =over 4
1988
1989 =item *
1990
1991 Returning a false value from the C<watchfunction()> itself.
1992
1993 =item *
1994
1995 Altering C<$single> to a false value.
1996
1997 =item *
1998
1999 Altering C<$signal> to a false value.
2000
2001 =item *
2002
2003 Turning off the C<4> bit in C<$trace> (this also disables the
2004 check for C<watchfunction()>. This can be done with
2005
2006     $trace &= ~4;
2007
2008 =back
2009
2010 =cut
2011
2012     # If there's a user-defined DB::watchfunction, call it with the
2013     # current package, filename, and line. The function executes in
2014     # the DB:: package.
2015     if ( $trace & 4 ) {    # User-installed watch
2016         return
2017           if watchfunction( $package, $filename, $line )
2018           and not $single
2019           and not $was_signal
2020           and not( $trace & ~4 );
2021     } ## end if ($trace & 4)
2022
2023     # Pick up any alteration to $signal in the watchfunction, and
2024     # turn off the signal now.
2025     $was_signal = $signal;
2026     $signal     = 0;
2027
2028 =head2 GETTING READY TO EXECUTE COMMANDS
2029
2030 The debugger decides to take control if single-step mode is on, the
2031 C<t> command was entered, or the user generated a signal. If the program
2032 has fallen off the end, we set things up so that entering further commands
2033 won't cause trouble, and we say that the program is over.
2034
2035 =cut
2036
2037     # Check to see if we should grab control ($single true,
2038     # trace set appropriately, or we got a signal).
2039     if ( $single || ( $trace & 1 ) || $was_signal ) {
2040
2041         # Yes, grab control.
2042         if ($slave_editor) {
2043
2044             # Tell the editor to update its position.
2045             $position = "\032\032$filename:$line:0\n";
2046             print_lineinfo($position);
2047         }
2048
2049 =pod
2050
2051 Special check: if we're in package C<DB::fake>, we've gone through the
2052 C<END> block at least once. We set up everything so that we can continue
2053 to enter commands and have a valid context to be in.
2054
2055 =cut
2056
2057         elsif ( $package eq 'DB::fake' ) {
2058
2059             # Fallen off the end already.
2060             $term || &setterm;
2061             print_help(<<EOP);
2062 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
2063   use B<o> I<inhibit_exit> to avoid stopping after program termination,
2064   B<h q>, B<h R> or B<h o> to get additional info.
2065 EOP
2066
2067             # Set the DB::eval context appropriately.
2068             $package     = 'main';
2069             $usercontext =
2070                 '($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
2071               . "package $package;";    # this won't let them modify, alas
2072         } ## end elsif ($package eq 'DB::fake')
2073
2074 =pod
2075
2076 If the program hasn't finished executing, we scan forward to the
2077 next executable line, print that out, build the prompt from the file and line
2078 number information, and print that.
2079
2080 =cut
2081
2082         else {
2083
2084             # Still somewhere in the midst of execution. Set up the
2085             #  debugger prompt.
2086             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
2087                                  # Perl 5 ones (sorry, we don't print Klingon
2088                                  #module names)
2089
2090             $prefix = $sub =~ /::/ ? "" : "${'package'}::";
2091             $prefix .= "$sub($filename:";
2092             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
2093
2094             # Break up the prompt if it's really long.
2095             if ( length($prefix) > 30 ) {
2096                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
2097                 $prefix   = "";
2098                 $infix    = ":\t";
2099             }
2100             else {
2101                 $infix    = "):\t";
2102                 $position = "$prefix$line$infix$dbline[$line]$after";
2103             }
2104
2105             # Print current line info, indenting if necessary.
2106             if ($frame) {
2107                 print_lineinfo( ' ' x $stack_depth,
2108                     "$line:\t$dbline[$line]$after" );
2109             }
2110             else {
2111                 print_lineinfo($position);
2112             }
2113
2114             # Scan forward, stopping at either the end or the next
2115             # unbreakable line.
2116             for ( $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2117             {    #{ vi
2118
2119                 # Drop out on null statements, block closers, and comments.
2120                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2121
2122                 # Drop out if the user interrupted us.
2123                 last if $signal;
2124
2125                 # Append a newline if the line doesn't have one. Can happen
2126                 # in eval'ed text, for instance.
2127                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2128
2129                 # Next executable line.
2130                 $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2131                 $position .= $incr_pos;
2132                 if ($frame) {
2133
2134                     # Print it indented if tracing is on.
2135                     print_lineinfo( ' ' x $stack_depth,
2136                         "$i:\t$dbline[$i]$after" );
2137                 }
2138                 else {
2139                     print_lineinfo($incr_pos);
2140                 }
2141             } ## end for ($i = $line + 1 ; $i...
2142         } ## end else [ if ($slave_editor)
2143     } ## end if ($single || ($trace...
2144
2145 =pod
2146
2147 If there's an action to be executed for the line we stopped at, execute it.
2148 If there are any preprompt actions, execute those as well.
2149
2150 =cut
2151
2152     # If there's an action, do it now.
2153     $evalarg = $action, &eval if $action;
2154
2155     # Are we nested another level (e.g., did we evaluate a function
2156     # that had a breakpoint in it at the debugger prompt)?
2157     if ( $single || $was_signal ) {
2158
2159         # Yes, go down a level.
2160         local $level = $level + 1;
2161
2162         # Do any pre-prompt actions.
2163         foreach $evalarg (@$pre) {
2164             &eval;
2165         }
2166
2167         # Complain about too much recursion if we passed the limit.
2168         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2169           if $single & 4;
2170
2171         # The line we're currently on. Set $incr to -1 to stay here
2172         # until we get a command that tells us to advance.
2173         $start = $line;
2174         $incr  = -1;      # for backward motion.
2175
2176         # Tack preprompt debugger actions ahead of any actual input.
2177         @typeahead = ( @$pretype, @typeahead );
2178
2179 =head2 WHERE ARE WE?
2180
2181 XXX Relocate this section?
2182
2183 The debugger normally shows the line corresponding to the current line of
2184 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2185 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2186
2187 C<$incr> controls by how many lines the I<current> line should move forward
2188 after a command is executed. If set to -1, this indicates that the I<current>
2189 line shouldn't change.
2190
2191 C<$start> is the I<current> line. It is used for things like knowing where to
2192 move forwards or backwards from when doing an C<L> or C<-> command.
2193
2194 C<$max> tells the debugger where the last line of the current file is. It's
2195 used to terminate loops most often.
2196
2197 =head2 THE COMMAND LOOP
2198
2199 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2200 in two parts:
2201
2202 =over 4
2203
2204 =item *
2205
2206 The outer part of the loop, starting at the C<CMD> label. This loop
2207 reads a command and then executes it.
2208
2209 =item *
2210
2211 The inner part of the loop, starting at the C<PIPE> label. This part
2212 is wholly contained inside the C<CMD> block and only executes a command.
2213 Used to handle commands running inside a pager.
2214
2215 =back
2216
2217 So why have two labels to restart the loop? Because sometimes, it's easier to
2218 have a command I<generate> another command and then re-execute the loop to do
2219 the new command. This is faster, but perhaps a bit more convoluted.
2220
2221 =cut
2222
2223         # The big command dispatch loop. It keeps running until the
2224         # user yields up control again.
2225         #
2226         # If we have a terminal for input, and we get something back
2227         # from readline(), keep on processing.
2228       CMD:
2229         while (
2230
2231             # We have a terminal, or can get one ...
2232             ( $term || &setterm ),
2233
2234             # ... and it belogs to this PID or we get one for this PID ...
2235             ( $term_pid == $$ or resetterm(1) ),
2236
2237             # ... and we got a line of command input ...
2238             defined(
2239                 $cmd = &readline(
2240                         "$pidprompt $tid DB"
2241                       . ( '<' x $level )
2242                       . ( $#hist + 1 )
2243                       . ( '>' x $level ) . " "
2244                 )
2245             )
2246           )
2247         {
2248
2249                         share($cmd);
2250             # ... try to execute the input as debugger commands.
2251
2252             # Don't stop running.
2253             $single = 0;
2254
2255             # No signal is active.
2256             $signal = 0;
2257
2258             # Handle continued commands (ending with \):
2259             $cmd =~ s/\\$/\n/ && do {
2260                 $cmd .= &readline("  cont: ");
2261                 redo CMD;
2262             };
2263
2264 =head4 The null command
2265
2266 A newline entered by itself means I<re-execute the last command>. We grab the
2267 command out of C<$laststep> (where it was recorded previously), and copy it
2268 back into C<$cmd> to be executed below. If there wasn't any previous command,
2269 we'll do nothing below (no command will match). If there was, we also save it
2270 in the command history and fall through to allow the command parsing to pick
2271 it up.
2272
2273 =cut
2274
2275             # Empty input means repeat the last command.
2276             $cmd =~ /^$/ && ( $cmd = $laststep );
2277             chomp($cmd);    # get rid of the annoying extra newline
2278             push( @hist, $cmd ) if length($cmd) > 1;
2279             push( @truehist, $cmd );
2280                         share(@hist);
2281                         share(@truehist);
2282
2283             # This is a restart point for commands that didn't arrive
2284             # via direct user input. It allows us to 'redo PIPE' to
2285             # re-execute command processing without reading a new command.
2286           PIPE: {
2287                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2288                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2289                 ($i) = split( /\s+/, $cmd );
2290
2291 =head3 COMMAND ALIASES
2292
2293 The debugger can create aliases for commands (these are stored in the
2294 C<%alias> hash). Before a command is executed, the command loop looks it up
2295 in the alias hash and substitutes the contents of the alias for the command,
2296 completely replacing it.
2297
2298 =cut
2299
2300                 # See if there's an alias for the command, and set it up if so.
2301                 if ( $alias{$i} ) {
2302
2303                     # Squelch signal handling; we want to keep control here
2304                     # if something goes loco during the alias eval.
2305                     local $SIG{__DIE__};
2306                     local $SIG{__WARN__};
2307
2308                     # This is a command, so we eval it in the DEBUGGER's
2309                     # scope! Otherwise, we can't see the special debugger
2310                     # variables, or get to the debugger's subs. (Well, we
2311                     # _could_, but why make it even more complicated?)
2312                     eval "\$cmd =~ $alias{$i}";
2313                     if ($@) {
2314                         local $\ = '';
2315                         print $OUT "Couldn't evaluate `$i' alias: $@";
2316                         next CMD;
2317                     }
2318                 } ## end if ($alias{$i})
2319
2320 =head3 MAIN-LINE COMMANDS
2321
2322 All of these commands work up to and after the program being debugged has
2323 terminated.
2324
2325 =head4 C<q> - quit
2326
2327 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2328 try to execute further, cleaning any restart-related stuff out of the
2329 environment, and executing with the last value of C<$?>.
2330
2331 =cut
2332
2333                 $cmd =~ /^q$/ && do {
2334                     $fall_off_end = 1;
2335                     clean_ENV();
2336                     exit $?;
2337                 };
2338
2339 =head4 C<t> - trace
2340
2341 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2342
2343 =cut
2344
2345                 $cmd =~ /^t$/ && do {
2346                     $trace ^= 1;
2347                     local $\ = '';
2348                     print $OUT "Trace = "
2349                       . ( ( $trace & 1 ) ? "on" : "off" ) . "\n";
2350                     next CMD;
2351                 };
2352
2353 =head4 C<S> - list subroutines matching/not matching a pattern
2354
2355 Walks through C<%sub>, checking to see whether or not to print the name.
2356
2357 =cut
2358
2359                 $cmd =~ /^S(\s+(!)?(.+))?$/ && do {
2360
2361                     $Srev     = defined $2;     # Reverse scan?
2362                     $Spatt    = $3;             # The pattern (if any) to use.
2363                     $Snocheck = !defined $1;    # No args - print all subs.
2364
2365                     # Need to make these sane here.
2366                     local $\ = '';
2367                     local $, = '';
2368
2369                     # Search through the debugger's magical hash of subs.
2370                     # If $nocheck is true, just print the sub name.
2371                     # Otherwise, check it against the pattern. We then use
2372                     # the XOR trick to reverse the condition as required.
2373                     foreach $subname ( sort( keys %sub ) ) {
2374                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2375                             print $OUT $subname, "\n";
2376                         }
2377                     }
2378                     next CMD;
2379                 };
2380
2381 =head4 C<X> - list variables in current package
2382
2383 Since the C<V> command actually processes this, just change this to the
2384 appropriate C<V> command and fall through.
2385
2386 =cut
2387
2388                 $cmd =~ s/^X\b/V $package/;
2389
2390 =head4 C<V> - list variables
2391
2392 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2393
2394 =cut
2395
2396                 # Bare V commands get the currently-being-debugged package
2397                 # added.
2398                 $cmd =~ /^V$/ && do {
2399                     $cmd = "V $package";
2400                 };
2401
2402                 # V - show variables in package.
2403                 $cmd =~ /^V\b\s*(\S+)\s*(.*)/ && do {
2404
2405                     # Save the currently selected filehandle and
2406                     # force output to debugger's filehandle (dumpvar
2407                     # just does "print" for output).
2408                     local ($savout) = select($OUT);
2409
2410                     # Grab package name and variables to dump.
2411                     $packname = $1;
2412                     @vars     = split( ' ', $2 );
2413
2414                     # If main::dumpvar isn't here, get it.
2415                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2416                     if ( defined &main::dumpvar ) {
2417
2418                         # We got it. Turn off subroutine entry/exit messages
2419                         # for the moment, along with return values.
2420                         local $frame = 0;
2421                         local $doret = -2;
2422
2423                         # must detect sigpipe failures  - not catching
2424                         # then will cause the debugger to die.
2425                         eval {
2426                             &main::dumpvar(
2427                                 $packname,
2428                                 defined $option{dumpDepth}
2429                                 ? $option{dumpDepth}
2430                                 : -1,    # assume -1 unless specified
2431                                 @vars
2432                             );
2433                         };
2434
2435                         # The die doesn't need to include the $@, because
2436                         # it will automatically get propagated for us.
2437                         if ($@) {
2438                             die unless $@ =~ /dumpvar print failed/;
2439                         }
2440                     } ## end if (defined &main::dumpvar)
2441                     else {
2442
2443                         # Couldn't load dumpvar.
2444                         print $OUT "dumpvar.pl not available.\n";
2445                     }
2446
2447                     # Restore the output filehandle, and go round again.
2448                     select($savout);
2449                     next CMD;
2450                 };
2451
2452 =head4 C<x> - evaluate and print an expression
2453
2454 Hands the expression off to C<DB::eval>, setting it up to print the value
2455 via C<dumpvar.pl> instead of just printing it directly.
2456
2457 =cut
2458
2459                 $cmd =~ s/^x\b/ / && do {    # Remainder gets done by DB::eval()
2460                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2461
2462                     # handle special  "x 3 blah" syntax XXX propagate
2463                     # doc back to special variables.
2464                     if ( $cmd =~ s/^\s*(\d+)(?=\s)/ / ) {
2465                         $onetimedumpDepth = $1;
2466                     }
2467                 };
2468
2469 =head4 C<m> - print methods
2470
2471 Just uses C<DB::methods> to determine what methods are available.
2472
2473 =cut
2474
2475                 $cmd =~ s/^m\s+([\w:]+)\s*$/ / && do {
2476                     methods($1);
2477                     next CMD;
2478                 };
2479
2480                 # m expr - set up DB::eval to do the work
2481                 $cmd =~ s/^m\b/ / && do {    # Rest gets done by DB::eval()
2482                     $onetimeDump = 'methods';   #  method output gets used there
2483                 };
2484
2485 =head4 C<f> - switch files
2486
2487 =cut
2488
2489                 $cmd =~ /^f\b\s*(.*)/ && do {
2490                     $file = $1;
2491                     $file =~ s/\s+$//;
2492
2493                     # help for no arguments (old-style was return from sub).
2494                     if ( !$file ) {
2495                         print $OUT
2496                           "The old f command is now the r command.\n";    # hint
2497                         print $OUT "The new f command switches filenames.\n";
2498                         next CMD;
2499                     } ## end if (!$file)
2500
2501                     # if not in magic file list, try a close match.
2502                     if ( !defined $main::{ '_<' . $file } ) {
2503                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2504                             {
2505                                 $try = substr( $try, 2 );
2506                                 print $OUT "Choosing $try matching `$file':\n";
2507                                 $file = $try;
2508                             }
2509                         } ## end if (($try) = grep(m#^_<.*$file#...
2510                     } ## end if (!defined $main::{ ...
2511
2512                     # If not successfully switched now, we failed.
2513                     if ( !defined $main::{ '_<' . $file } ) {
2514                         print $OUT "No file matching `$file' is loaded.\n";
2515                         next CMD;
2516                     }
2517
2518                     # We switched, so switch the debugger internals around.
2519                     elsif ( $file ne $filename ) {
2520                         *dbline   = $main::{ '_<' . $file };
2521                         $max      = $#dbline;
2522                         $filename = $file;
2523                         $start    = 1;
2524                         $cmd      = "l";
2525                     } ## end elsif ($file ne $filename)
2526
2527                     # We didn't switch; say we didn't.
2528                     else {
2529                         print $OUT "Already in $file.\n";
2530                         next CMD;
2531                     }
2532                 };
2533
2534 =head4 C<.> - return to last-executed line.
2535
2536 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2537 and then we look up the line in the magical C<%dbline> hash.
2538
2539 =cut
2540
2541                 # . command.
2542                 $cmd =~ /^\.$/ && do {
2543                     $incr = -1;    # stay at current line
2544
2545                     # Reset everything to the old location.
2546                     $start    = $line;
2547                     $filename = $filename_ini;
2548                     *dbline   = $main::{ '_<' . $filename };
2549                     $max      = $#dbline;
2550
2551                     # Now where are we?
2552                     print_lineinfo($position);
2553                     next CMD;
2554                 };
2555
2556 =head4 C<-> - back one window
2557
2558 We change C<$start> to be one window back; if we go back past the first line,
2559 we set it to be the first line. We ser C<$incr> to put us back at the
2560 currently-executing line, and then put a C<l $start +> (list one window from
2561 C<$start>) in C<$cmd> to be executed later.
2562
2563 =cut
2564
2565                 # - - back a window.
2566                 $cmd =~ /^-$/ && do {
2567
2568                     # back up by a window; go to 1 if back too far.
2569                     $start -= $incr + $window + 1;
2570                     $start = 1 if $start <= 0;
2571                     $incr  = $window - 1;
2572
2573                     # Generate and execute a "l +" command (handled below).
2574                     $cmd = 'l ' . ($start) . '+';
2575                 };
2576
2577 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2578
2579 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2580 problems, most notably that the default case of several commands destroying
2581 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2582 retain the old commands for those who were used to using them or who preferred
2583 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2584 deal with them instead of processing them in-line.
2585
2586 =cut
2587
2588                 # All of these commands were remapped in perl 5.8.0;
2589                 # we send them off to the secondary dispatcher (see below).
2590                 $cmd =~ /^([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so && do {
2591                     &cmd_wrapper( $1, $2, $line );
2592                     next CMD;
2593                 };
2594
2595 =head4 C<y> - List lexicals in higher scope
2596
2597 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2598 above the current one and then displays then using C<dumpvar.pl>.
2599
2600 =cut
2601
2602                 $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/ && do {
2603
2604                     # See if we've got the necessary support.
2605                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2606                       or &warn(
2607                         $@ =~ /locate/
2608                         ? "PadWalker module not found - please install\n"
2609                         : $@
2610                       )
2611                       and next CMD;
2612
2613                     # Load up dumpvar if we don't have it. If we can, that is.
2614                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2615                     defined &main::dumpvar
2616                       or print $OUT "dumpvar.pl not available.\n"
2617                       and next CMD;
2618
2619                     # Got all the modules we need. Find them and print them.
2620                     my @vars = split( ' ', $2 || '' );
2621
2622                     # Find the pad.
2623                     my $h = eval { PadWalker::peek_my( ( $1 || 0 ) + 1 ) };
2624
2625                     # Oops. Can't find it.
2626                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2627
2628                     # Show the desired vars with dumplex().
2629                     my $savout = select($OUT);
2630
2631                     # Have dumplex dump the lexicals.
2632                     dumpvar::dumplex( $_, $h->{$_},
2633                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2634                         @vars )
2635                       for sort keys %$h;
2636                     select($savout);
2637                     next CMD;
2638                 };
2639
2640 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2641
2642 All of the commands below this point don't work after the program being
2643 debugged has ended. All of them check to see if the program has ended; this
2644 allows the commands to be relocated without worrying about a 'line of
2645 demarcation' above which commands can be entered anytime, and below which
2646 they can't.
2647
2648 =head4 C<n> - single step, but don't trace down into subs
2649
2650 Done by setting C<$single> to 2, which forces subs to execute straight through
2651 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2652 so a null command knows what to re-execute.
2653
2654 =cut
2655
2656                 # n - next
2657                 $cmd =~ /^n$/ && do {
2658                     end_report(), next CMD if $finished and $level <= 1;
2659
2660                     # Single step, but don't enter subs.
2661                     $single = 2;
2662
2663                     # Save for empty command (repeat last).
2664                     $laststep = $cmd;
2665                     last CMD;
2666                 };
2667
2668 =head4 C<s> - single-step, entering subs
2669
2670 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2671 subs. Also saves C<s> as C<$lastcmd>.
2672
2673 =cut
2674
2675                 # s - single step.
2676                 $cmd =~ /^s$/ && do {
2677
2678                     # Get out and restart the command loop if program
2679                     # has finished.
2680                     end_report(), next CMD if $finished and $level <= 1;
2681
2682                     # Single step should enter subs.
2683                     $single = 1;
2684
2685                     # Save for empty command (repeat last).
2686                     $laststep = $cmd;
2687                     last CMD;
2688                 };
2689
2690 =head4 C<c> - run continuously, setting an optional breakpoint
2691
2692 Most of the code for this command is taken up with locating the optional
2693 breakpoint, which is either a subroutine name or a line number. We set
2694 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2695 in this and all call levels above this one.
2696
2697 =cut
2698
2699                 # c - start continuous execution.
2700                 $cmd =~ /^c\b\s*([\w:]*)\s*$/ && do {
2701
2702                     # Hey, show's over. The debugged program finished
2703                     # executing already.
2704                     end_report(), next CMD if $finished and $level <= 1;
2705
2706                     # Capture the place to put a one-time break.
2707                     $subname = $i = $1;
2708
2709                     #  Probably not needed, since we finish an interactive
2710                     #  sub-session anyway...
2711                     # local $filename = $filename;
2712                     # local *dbline = *dbline; # XXX Would this work?!
2713                     #
2714                     # The above question wonders if localizing the alias
2715                     # to the magic array works or not. Since it's commented
2716                     # out, we'll just leave that to speculation for now.
2717
2718                     # If the "subname" isn't all digits, we'll assume it
2719                     # is a subroutine name, and try to find it.
2720                     if ( $subname =~ /\D/ ) {    # subroutine name
2721                             # Qualify it to the current package unless it's
2722                             # already qualified.
2723                         $subname = $package . "::" . $subname
2724                           unless $subname =~ /::/;
2725
2726                         # find_sub will return "file:line_number" corresponding
2727                         # to where the subroutine is defined; we call find_sub,
2728                         # break up the return value, and assign it in one
2729                         # operation.
2730                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2731
2732                         # Force the line number to be numeric.
2733                         $i += 0;
2734
2735                         # If we got a line number, we found the sub.
2736                         if ($i) {
2737
2738                             # Switch all the debugger's internals around so
2739                             # we're actually working with that file.
2740                             $filename = $file;
2741                             *dbline   = $main::{ '_<' . $filename };
2742
2743                             # Mark that there's a breakpoint in this file.
2744                             $had_breakpoints{$filename} |= 1;
2745
2746                             # Scan forward to the first executable line
2747                             # after the 'sub whatever' line.
2748                             $max = $#dbline;
2749                             ++$i while $dbline[$i] == 0 && $i < $max;
2750                         } ## end if ($i)
2751
2752                         # We didn't find a sub by that name.
2753                         else {
2754                             print $OUT "Subroutine $subname not found.\n";
2755                             next CMD;
2756                         }
2757                     } ## end if ($subname =~ /\D/)
2758
2759                     # At this point, either the subname was all digits (an
2760                     # absolute line-break request) or we've scanned through
2761                     # the code following the definition of the sub, looking
2762                     # for an executable, which we may or may not have found.
2763                     #
2764                     # If $i (which we set $subname from) is non-zero, we
2765                     # got a request to break at some line somewhere. On
2766                     # one hand, if there wasn't any real subroutine name
2767                     # involved, this will be a request to break in the current
2768                     # file at the specified line, so we have to check to make
2769                     # sure that the line specified really is breakable.
2770                     #
2771                     # On the other hand, if there was a subname supplied, the
2772                     # preceding block has moved us to the proper file and
2773                     # location within that file, and then scanned forward
2774                     # looking for the next executable line. We have to make
2775                     # sure that one was found.
2776                     #
2777                     # On the gripping hand, we can't do anything unless the
2778                     # current value of $i points to a valid breakable line.
2779                     # Check that.
2780                     if ($i) {
2781
2782                         # Breakable?
2783                         if ( $dbline[$i] == 0 ) {
2784                             print $OUT "Line $i not breakable.\n";
2785                             next CMD;
2786                         }
2787
2788                         # Yes. Set up the one-time-break sigil.
2789                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2790                     } ## end if ($i)
2791
2792                     # Turn off stack tracing from here up.
2793                     for ( $i = 0 ; $i <= $stack_depth ; ) {
2794                         $stack[ $i++ ] &= ~1;
2795                     }
2796                     last CMD;
2797                 };
2798
2799 =head4 C<r> - return from a subroutine
2800
2801 For C<r> to work properly, the debugger has to stop execution again
2802 immediately after the return is executed. This is done by forcing
2803 single-stepping to be on in the call level above the current one. If
2804 we are printing return values when a C<r> is executed, set C<$doret>
2805 appropriately, and force us out of the command loop.
2806
2807 =cut
2808
2809                 # r - return from the current subroutine.
2810                 $cmd =~ /^r$/ && do {
2811
2812                     # Can't do anythign if the program's over.
2813                     end_report(), next CMD if $finished and $level <= 1;
2814
2815                     # Turn on stack trace.
2816                     $stack[$stack_depth] |= 1;
2817
2818                     # Print return value unless the stack is empty.
2819                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2820                     last CMD;
2821                 };
2822
2823 =head4 C<T> - stack trace
2824
2825 Just calls C<DB::print_trace>.
2826
2827 =cut
2828
2829                 $cmd =~ /^T$/ && do {
2830                     print_trace( $OUT, 1 );    # skip DB
2831                     next CMD;
2832                 };
2833
2834 =head4 C<w> - List window around current line.
2835
2836 Just calls C<DB::cmd_w>.
2837
2838 =cut
2839
2840                 $cmd =~ /^w\b\s*(.*)/s && do { &cmd_w( 'w', $1 ); next CMD; };
2841
2842 =head4 C<W> - watch-expression processing.
2843
2844 Just calls C<DB::cmd_W>.
2845
2846 =cut
2847
2848                 $cmd =~ /^W\b\s*(.*)/s && do { &cmd_W( 'W', $1 ); next CMD; };
2849
2850 =head4 C</> - search forward for a string in the source
2851
2852 We take the argument and treat it as a pattern. If it turns out to be a
2853 bad one, we return the error we got from trying to C<eval> it and exit.
2854 If not, we create some code to do the search and C<eval> it so it can't
2855 mess us up.
2856
2857 =cut
2858
2859                 $cmd =~ /^\/(.*)$/ && do {
2860
2861                     # The pattern as a string.
2862                     $inpat = $1;
2863
2864                     # Remove the final slash.
2865                     $inpat =~ s:([^\\])/$:$1:;
2866
2867                     # If the pattern isn't null ...
2868                     if ( $inpat ne "" ) {
2869
2870                         # Turn of warn and die procesing for a bit.
2871                         local $SIG{__DIE__};
2872                         local $SIG{__WARN__};
2873
2874                         # Create the pattern.
2875                         eval '$inpat =~ m' . "\a$inpat\a";
2876                         if ( $@ ne "" ) {
2877
2878                             # Oops. Bad pattern. No biscuit.
2879                             # Print the eval error and go back for more
2880                             # commands.
2881                             print $OUT "$@";
2882                             next CMD;
2883                         }
2884                         $pat = $inpat;
2885                     } ## end if ($inpat ne "")
2886
2887                     # Set up to stop on wrap-around.
2888                     $end = $start;
2889
2890                     # Don't move off the current line.
2891                     $incr = -1;
2892
2893                     # Done in eval so nothing breaks if the pattern
2894                     # does something weird.
2895                     eval '
2896                         for (;;) {
2897                             # Move ahead one line.
2898                             ++$start;
2899
2900                             # Wrap if we pass the last line.
2901                             $start = 1 if ($start > $max);
2902
2903                             # Stop if we have gotten back to this line again,
2904                             last if ($start == $end);
2905
2906                             # A hit! (Note, though, that we are doing
2907                             # case-insensitive matching. Maybe a qr//
2908                             # expression would be better, so the user could
2909                             # do case-sensitive matching if desired.
2910                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2911                                 if ($slave_editor) {
2912                                     # Handle proper escaping in the slave.
2913                                     print $OUT "\032\032$filename:$start:0\n";
2914                                 }
2915                                 else {
2916                                     # Just print the line normally.
2917                                     print $OUT "$start:\t",$dbline[$start],"\n";
2918                                 }
2919                                 # And quit since we found something.
2920                                 last;
2921                             }
2922                          } ';
2923
2924                     # If we wrapped, there never was a match.
2925                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2926                     next CMD;
2927                 };
2928
2929 =head4 C<?> - search backward for a string in the source
2930
2931 Same as for C</>, except the loop runs backwards.
2932
2933 =cut
2934
2935                 # ? - backward pattern search.
2936                 $cmd =~ /^\?(.*)$/ && do {
2937
2938                     # Get the pattern, remove trailing question mark.
2939                     $inpat = $1;
2940                     $inpat =~ s:([^\\])\?$:$1:;
2941
2942                     # If we've got one ...
2943                     if ( $inpat ne "" ) {
2944
2945                         # Turn off die & warn handlers.
2946                         local $SIG{__DIE__};
2947                         local $SIG{__WARN__};
2948                         eval '$inpat =~ m' . "\a$inpat\a";
2949
2950                         if ( $@ ne "" ) {
2951
2952                             # Ouch. Not good. Print the error.
2953                             print $OUT $@;
2954                             next CMD;
2955                         }
2956                         $pat = $inpat;
2957                     } ## end if ($inpat ne "")
2958
2959                     # Where we are now is where to stop after wraparound.
2960                     $end = $start;
2961
2962                     # Don't move away from this line.
2963                     $incr = -1;
2964
2965                     # Search inside the eval to prevent pattern badness
2966                     # from killing us.
2967                     eval '
2968                         for (;;) {
2969                             # Back up a line.
2970                             --$start;
2971
2972                             # Wrap if we pass the first line.
2973
2974                             $start = $max if ($start <= 0);
2975
2976                             # Quit if we get back where we started,
2977                             last if ($start == $end);
2978
2979                             # Match?
2980                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2981                                 if ($slave_editor) {
2982                                     # Yep, follow slave editor requirements.
2983                                     print $OUT "\032\032$filename:$start:0\n";
2984                                 }
2985                                 else {
2986                                     # Yep, just print normally.
2987                                     print $OUT "$start:\t",$dbline[$start],"\n";
2988                                 }
2989
2990                                 # Found, so done.
2991                                 last;
2992                             }
2993                         } ';
2994
2995                     # Say we failed if the loop never found anything,
2996                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2997                     next CMD;
2998                 };
2999
3000 =head4 C<$rc> - Recall command
3001
3002 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
3003 that the terminal supports history). It find the the command required, puts it
3004 into C<$cmd>, and redoes the loop to execute it.
3005
3006 =cut
3007
3008                 # $rc - recall command.
3009                 $cmd =~ /^$rc+\s*(-)?(\d+)?$/ && do {
3010
3011                     # No arguments, take one thing off history.
3012                     pop(@hist) if length($cmd) > 1;
3013
3014                     # Relative (- found)?
3015                     #  Y - index back from most recent (by 1 if bare minus)
3016                     #  N - go to that particular command slot or the last
3017                     #      thing if nothing following.
3018                     $i = $1 ? ( $#hist - ( $2 || 1 ) ) : ( $2 || $#hist );
3019
3020                     # Pick out the command desired.
3021                     $cmd = $hist[$i];
3022
3023                     # Print the command to be executed and restart the loop
3024                     # with that command in the buffer.
3025                     print $OUT $cmd, "\n";
3026                     redo CMD;
3027                 };
3028
3029 =head4 C<$sh$sh> - C<system()> command
3030
3031 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
3032 C<STDOUT> from getting messed up.
3033
3034 =cut
3035
3036                 # $sh$sh - run a shell command (if it's all ASCII).
3037                 # Can't run shell commands with Unicode in the debugger, hmm.
3038                 $cmd =~ /^$sh$sh\s*([\x00-\xff]*)/ && do {
3039
3040                     # System it.
3041                     &system($1);
3042                     next CMD;
3043                 };
3044
3045 =head4 C<$rc I<pattern> $rc> - Search command history
3046
3047 Another command to manipulate C<@hist>: this one searches it with a pattern.
3048 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
3049
3050 =cut
3051
3052                 # $rc pattern $rc - find a command in the history.
3053                 $cmd =~ /^$rc([^$rc].*)$/ && do {
3054
3055                     # Create the pattern to use.
3056                     $pat = "^$1";
3057
3058                     # Toss off last entry if length is >1 (and it always is).
3059                     pop(@hist) if length($cmd) > 1;
3060
3061                     # Look backward through the history.
3062                     for ( $i = $#hist ; $i ; --$i ) {
3063
3064                         # Stop if we find it.
3065                         last if $hist[$i] =~ /$pat/;
3066                     }
3067
3068                     if ( !$i ) {
3069
3070                         # Never found it.
3071                         print $OUT "No such command!\n\n";
3072                         next CMD;
3073                     }
3074
3075                     # Found it. Put it in the buffer, print it, and process it.
3076                     $cmd = $hist[$i];
3077                     print $OUT $cmd, "\n";
3078                     redo CMD;
3079                 };
3080
3081 =head4 C<$sh> - Invoke a shell
3082
3083 Uses C<DB::system> to invoke a shell.
3084
3085 =cut
3086
3087                 # $sh - start a shell.
3088                 $cmd =~ /^$sh$/ && do {
3089
3090                     # Run the user's shell. If none defined, run Bourne.
3091                     # We resume execution when the shell terminates.
3092                     &system( $ENV{SHELL} || "/bin/sh" );
3093                     next CMD;
3094                 };
3095
3096 =head4 C<$sh I<command>> - Force execution of a command in a shell
3097
3098 Like the above, but the command is passed to the shell. Again, we use
3099 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3100
3101 =cut
3102
3103                 # $sh command - start a shell and run a command in it.
3104                 $cmd =~ /^$sh\s*([\x00-\xff]*)/ && do {
3105
3106                     # XXX: using csh or tcsh destroys sigint retvals!
3107                     #&system($1);  # use this instead
3108
3109                     # use the user's shell, or Bourne if none defined.
3110                     &system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3111                     next CMD;
3112                 };
3113
3114 =head4 C<H> - display commands in history
3115
3116 Prints the contents of C<@hist> (if any).
3117
3118 =cut
3119
3120                 $cmd =~ /^H\b\s*\*/ && do {
3121                     @hist = @truehist = ();
3122                     print $OUT "History cleansed\n";
3123                     next CMD;
3124                 };
3125
3126                 $cmd =~ /^H\b\s*(-(\d+))?/ && do {
3127
3128                     # Anything other than negative numbers is ignored by
3129                     # the (incorrect) pattern, so this test does nothing.
3130                     $end = $2 ? ( $#hist - $2 ) : 0;
3131
3132                     # Set to the minimum if less than zero.
3133                     $hist = 0 if $hist < 0;
3134
3135                     # Start at the end of the array.
3136                     # Stay in while we're still above the ending value.
3137                     # Tick back by one each time around the loop.
3138                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3139
3140                         # Print the command  unless it has no arguments.
3141                         print $OUT "$i: ", $hist[$i], "\n"
3142                           unless $hist[$i] =~ /^.?$/;
3143                     }
3144                     next CMD;
3145                 };
3146
3147 =head4 C<man, doc, perldoc> - look up documentation
3148
3149 Just calls C<runman()> to print the appropriate document.
3150
3151 =cut
3152
3153                 # man, perldoc, doc - show manual pages.
3154                 $cmd =~ /^(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?$/ && do {
3155                     runman($1);
3156                     next CMD;
3157                 };
3158
3159 =head4 C<p> - print
3160
3161 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3162 the bottom of the loop.
3163
3164 =cut
3165
3166                 # p - print (no args): print $_.
3167                 $cmd =~ s/^p$/print {\$DB::OUT} \$_/;
3168
3169                 # p - print the given expression.
3170                 $cmd =~ s/^p\b/print {\$DB::OUT} /;
3171
3172 =head4 C<=> - define command alias
3173
3174 Manipulates C<%alias> to add or list command aliases.
3175
3176 =cut
3177
3178                 # = - set up a command alias.
3179                 $cmd =~ s/^=\s*// && do {
3180                     my @keys;
3181                     if ( length $cmd == 0 ) {
3182
3183                         # No args, get current aliases.
3184                         @keys = sort keys %alias;
3185                     }
3186                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3187
3188                         # Creating a new alias. $k is alias name, $v is
3189                         # alias value.
3190
3191                         # can't use $_ or kill //g state
3192                         for my $x ( $k, $v ) {
3193
3194                             # Escape "alarm" characters.
3195                             $x =~ s/\a/\\a/g;
3196                         }
3197
3198                         # Substitute key for value, using alarm chars
3199                         # as separators (which is why we escaped them in
3200                         # the command).
3201                         $alias{$k} = "s\a$k\a$v\a";
3202
3203                         # Turn off standard warn and die behavior.
3204                         local $SIG{__DIE__};
3205                         local $SIG{__WARN__};
3206
3207                         # Is it valid Perl?
3208                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3209
3210                             # Nope. Bad alias. Say so and get out.
3211                             print $OUT "Can't alias $k to $v: $@\n";
3212                             delete $alias{$k};
3213                             next CMD;
3214                         }
3215
3216                         # We'll only list the new one.
3217                         @keys = ($k);
3218                     } ## end elsif (my ($k, $v) = ($cmd...
3219
3220                     # The argument is the alias to list.
3221                     else {
3222                         @keys = ($cmd);
3223                     }
3224
3225                     # List aliases.
3226                     for my $k (@keys) {
3227
3228                         # Messy metaquoting: Trim the substiution code off.
3229                         # We use control-G as the delimiter because it's not
3230                         # likely to appear in the alias.
3231                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3232
3233                             # Print the alias.
3234                             print $OUT "$k\t= $1\n";
3235                         }
3236                         elsif ( defined $alias{$k} ) {
3237
3238                             # Couldn't trim it off; just print the alias code.
3239                             print $OUT "$k\t$alias{$k}\n";
3240                         }
3241                         else {
3242
3243                             # No such, dude.
3244                             print "No alias for $k\n";
3245                         }
3246                     } ## end for my $k (@keys)
3247                     next CMD;
3248                 };
3249
3250 =head4 C<source> - read commands from a file.
3251
3252 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3253 pick it up.
3254
3255 =cut
3256
3257                 # source - read commands from a file (or pipe!) and execute.
3258                 $cmd =~ /^source\s+(.*\S)/ && do {
3259                     if ( open my $fh, $1 ) {
3260
3261                         # Opened OK; stick it in the list of file handles.
3262                         push @cmdfhs, $fh;
3263                     }
3264                     else {
3265
3266                         # Couldn't open it.
3267                         &warn("Can't execute `$1': $!\n");
3268                     }
3269                     next CMD;
3270                 };
3271
3272 =head4 C<save> - send current history to a file
3273
3274 Takes the complete history, (not the shrunken version you see with C<H>),
3275 and saves it to the given filename, so it can be replayed using C<source>.
3276
3277 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3278
3279 =cut
3280
3281                 # save source - write commands to a file for later use
3282                 $cmd =~ /^save\s*(.*)$/ && do {
3283                     my $file = $1 || '.perl5dbrc';    # default?
3284                     if ( open my $fh, "> $file" ) {
3285
3286                        # chomp to remove extraneous newlines from source'd files
3287                         chomp( my @truelist =
3288                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3289                               @truehist );
3290                         print $fh join( "\n", @truelist );
3291                         print "commands saved in $file\n";
3292                     }
3293                     else {
3294                         &warn("Can't save debugger commands in '$1': $!\n");
3295                     }
3296                     next CMD;
3297                 };
3298
3299 =head4 C<R> - restart
3300
3301 Restart the debugger session.
3302
3303 =head4 C<rerun> - rerun the current session
3304
3305 Return to any given position in the B<true>-history list
3306
3307 =cut
3308
3309                 # R - restart execution.
3310                 # rerun - controlled restart execution.
3311                 $cmd =~ /^(R|rerun\s*(.*))$/ && do {
3312                     my @args = ($1 eq 'R' ? restart() : rerun($2));
3313
3314                     # Close all non-system fds for a clean restart.  A more
3315                     # correct method would be to close all fds that were not
3316                     # open when the process started, but this seems to be
3317                     # hard.  See "debugger 'R'estart and open database
3318                     # connections" on p5p.
3319
3320                     my $max_fd = 1024; # default if POSIX can't be loaded
3321                     if (eval { require POSIX }) {
3322                         $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX());
3323                     }
3324
3325                     if (defined $max_fd) {
3326                         foreach ($^F+1 .. $max_fd-1) {
3327                             next unless open FD_TO_CLOSE, "<&=$_";
3328                             close(FD_TO_CLOSE);
3329                         }
3330                     }
3331
3332                     # And run Perl again.  We use exec() to keep the
3333                     # PID stable (and that way $ini_pids is still valid).
3334                     exec(@args) || print $OUT "exec failed: $!\n";
3335
3336                     last CMD;
3337                 };
3338
3339 =head4 C<|, ||> - pipe output through the pager.
3340
3341 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3342 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3343 pipe to the pager (restoring the output filehandles if this fails). If this
3344 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3345 set C<$signal>, sending us back into the debugger.
3346
3347 We then trim off the pipe symbols and C<redo> the command loop at the
3348 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3349 reading another.
3350
3351 =cut
3352
3353                 # || - run command in the pager, with output to DB::OUT.
3354                 $cmd =~ /^\|\|?\s*[^|]/ && do {
3355                     if ( $pager =~ /^\|/ ) {
3356
3357                         # Default pager is into a pipe. Redirect I/O.
3358                         open( SAVEOUT, ">&STDOUT" )
3359                           || &warn("Can't save STDOUT");
3360                         open( STDOUT, ">&OUT" )
3361                           || &warn("Can't redirect STDOUT");
3362                     } ## end if ($pager =~ /^\|/)
3363                     else {
3364
3365                         # Not into a pipe. STDOUT is safe.
3366                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3367                     }
3368
3369                     # Fix up environment to record we have less if so.
3370                     fix_less();
3371
3372                     unless ( $piped = open( OUT, $pager ) ) {
3373
3374                         # Couldn't open pipe to pager.
3375                         &warn("Can't pipe output to `$pager'");
3376                         if ( $pager =~ /^\|/ ) {
3377
3378                             # Redirect I/O back again.
3379                             open( OUT, ">&STDOUT" )    # XXX: lost message
3380                               || &warn("Can't restore DB::OUT");
3381                             open( STDOUT, ">&SAVEOUT" )
3382                               || &warn("Can't restore STDOUT");
3383                             close(SAVEOUT);
3384                         } ## end if ($pager =~ /^\|/)
3385                         else {
3386
3387                             # Redirect I/O. STDOUT already safe.
3388                             open( OUT, ">&STDOUT" )    # XXX: lost message
3389                               || &warn("Can't restore DB::OUT");
3390                         }
3391                         next CMD;
3392                     } ## end unless ($piped = open(OUT,...
3393
3394                     # Set up broken-pipe handler if necessary.
3395                     $SIG{PIPE} = \&DB::catch
3396                       if $pager =~ /^\|/
3397                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3398
3399                     # Save current filehandle, unbuffer out, and put it back.
3400                     $selected = select(OUT);
3401                     $|        = 1;
3402
3403                     # Don't put it back if pager was a pipe.
3404                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3405
3406                     # Trim off the pipe symbols and run the command now.
3407                     $cmd =~ s/^\|+\s*//;
3408                     redo PIPE;
3409                 };
3410
3411 =head3 END OF COMMAND PARSING
3412
3413 Anything left in C<$cmd> at this point is a Perl expression that we want to
3414 evaluate. We'll always evaluate in the user's context, and fully qualify
3415 any variables we might want to address in the C<DB> package.
3416
3417 =cut
3418
3419                 # t - turn trace on.
3420                 $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3421
3422                 # s - single-step. Remember the last command was 's'.
3423                 $cmd =~ s/^s\s/\$DB::single = 1;\n/ && do { $laststep = 's' };
3424
3425                 # n - single-step, but not into subs. Remember last command
3426                 # was 'n'.
3427                 $cmd =~ s/^n\s/\$DB::single = 2;\n/ && do { $laststep = 'n' };
3428
3429             }    # PIPE:
3430
3431             # Make sure the flag that says "the debugger's running" is
3432             # still on, to make sure we get control again.
3433             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3434
3435             # Run *our* eval that executes in the caller's context.
3436             &eval;
3437
3438             # Turn off the one-time-dump stuff now.
3439             if ($onetimeDump) {
3440                 $onetimeDump      = undef;
3441                 $onetimedumpDepth = undef;
3442             }
3443             elsif ( $term_pid == $$ ) {
3444                 eval {          # May run under miniperl, when not available...
3445                     STDOUT->flush();
3446                     STDERR->flush();
3447                 };
3448
3449                 # XXX If this is the master pid, print a newline.
3450                 print $OUT "\n";
3451             }
3452         } ## end while (($term || &setterm...
3453
3454 =head3 POST-COMMAND PROCESSING
3455
3456 After each command, we check to see if the command output was piped anywhere.
3457 If so, we go through the necessary code to unhook the pipe and go back to
3458 our standard filehandles for input and output.
3459
3460 =cut
3461
3462         continue {    # CMD:
3463
3464             # At the end of every command:
3465             if ($piped) {
3466
3467                 # Unhook the pipe mechanism now.
3468                 if ( $pager =~ /^\|/ ) {
3469
3470                     # No error from the child.
3471                     $? = 0;
3472
3473                     # we cannot warn here: the handle is missing --tchrist
3474                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3475
3476                     # most of the $? crud was coping with broken cshisms
3477                     # $? is explicitly set to 0, so this never runs.
3478                     if ($?) {
3479                         print SAVEOUT "Pager `$pager' failed: ";
3480                         if ( $? == -1 ) {
3481                             print SAVEOUT "shell returned -1\n";
3482                         }
3483                         elsif ( $? >> 8 ) {
3484                             print SAVEOUT ( $? & 127 )
3485                               ? " (SIG#" . ( $? & 127 ) . ")"
3486                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3487                         }
3488                         else {
3489                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3490                         }
3491                     } ## end if ($?)
3492
3493                     # Reopen filehandle for our output (if we can) and
3494                     # restore STDOUT (if we can).
3495                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3496                     open( STDOUT, ">&SAVEOUT" )
3497                       || &warn("Can't restore STDOUT");
3498
3499                     # Turn off pipe exception handler if necessary.
3500                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3501
3502                     # Will stop ignoring SIGPIPE if done like nohup(1)
3503                     # does SIGINT but Perl doesn't give us a choice.
3504                 } ## end if ($pager =~ /^\|/)
3505                 else {
3506
3507                     # Non-piped "pager". Just restore STDOUT.
3508                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3509                 }
3510
3511                 # Close filehandle pager was using, restore the normal one
3512                 # if necessary,
3513                 close(SAVEOUT);
3514                 select($selected), $selected = "" unless $selected eq "";
3515
3516                 # No pipes now.
3517                 $piped = "";
3518             } ## end if ($piped)
3519         }    # CMD:
3520
3521 =head3 COMMAND LOOP TERMINATION
3522
3523 When commands have finished executing, we come here. If the user closed the
3524 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3525 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3526 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3527 The interpreter will then execute the next line and then return control to us
3528 again.
3529
3530 =cut
3531
3532         # No more commands? Quit.
3533         $fall_off_end = 1 unless defined $cmd;    # Emulate `q' on EOF
3534
3535         # Evaluate post-prompt commands.
3536         foreach $evalarg (@$post) {
3537             &eval;
3538         }
3539     }    # if ($single || $signal)
3540
3541     # Put the user's globals back where you found them.
3542     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3543     ();
3544 } ## end sub DB
3545
3546 # The following code may be executed now:
3547 # BEGIN {warn 4}
3548
3549 =head2 sub
3550
3551 C<sub> is called whenever a subroutine call happens in the program being
3552 debugged. The variable C<$DB::sub> contains the name of the subroutine
3553 being called.
3554
3555 The core function of this subroutine is to actually call the sub in the proper
3556 context, capturing its output. This of course causes C<DB::DB> to get called
3557 again, repeating until the subroutine ends and returns control to C<DB::sub>
3558 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3559 return value, and returns its captured copy of the return value as its own
3560 return value. The value then feeds back into the program being debugged as if
3561 C<DB::sub> hadn't been there at all.
3562
3563 C<sub> does all the work of printing the subroutine entry and exit messages
3564 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3565 and also prints the return value if needed (for the C<r> command and if
3566 the 16 bit is set in C<$frame>).
3567
3568 It also tracks the subroutine call depth by saving the current setting of
3569 C<$single> in the C<@stack> package global; if this exceeds the value in
3570 C<$deep>, C<sub> automatically turns on printing of the current depth by
3571 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3572 of stop/don't stop on entry to subs set as it currently is set.
3573
3574 =head3 C<caller()> support
3575
3576 If C<caller()> is called from the package C<DB>, it provides some
3577 additional data, in the following order:
3578
3579 =over 4
3580
3581 =item * C<$package>
3582
3583 The package name the sub was in
3584
3585 =item * C<$filename>
3586
3587 The filename it was defined in
3588
3589 =item * C<$line>
3590
3591 The line number it was defined on
3592
3593 =item * C<$subroutine>
3594
3595 The subroutine name; C<(eval)> if an C<eval>().
3596
3597 =item * C<$hasargs>
3598
3599 1 if it has arguments, 0 if not
3600
3601 =item * C<$wantarray>
3602
3603 1 if array context, 0 if scalar context
3604
3605 =item * C<$evaltext>
3606
3607 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3608
3609 =item * C<$is_require>
3610
3611 frame was created by a C<use> or C<require> statement
3612
3613 =item * C<$hints>
3614
3615 pragma information; subject to change between versions
3616
3617 =item * C<$bitmask>
3618
3619 pragma information; subject to change between versions
3620
3621 =item * C<@DB::args>
3622
3623 arguments with which the subroutine was invoked
3624
3625 =back
3626
3627 =cut
3628
3629 sub sub {
3630
3631         # lock ourselves under threads
3632         lock($DBGR);
3633
3634     # Whether or not the autoloader was running, a scalar to put the
3635     # sub's return value in (if needed), and an array to put the sub's
3636     # return value in (if needed).
3637     my ( $al, $ret, @ret ) = "";
3638         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3639                 print "creating new thread\n";
3640         }
3641
3642     # If the last ten characters are '::AUTOLOAD', note we've traced
3643     # into AUTOLOAD for $sub.
3644     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3645         $al = " for $$sub" if defined $$sub;
3646     }
3647
3648     # We stack the stack pointer and then increment it to protect us
3649     # from a situation that might unwind a whole bunch of call frames
3650     # at once. Localizing the stack pointer means that it will automatically
3651     # unwind the same amount when multiple stack frames are unwound.
3652     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3653
3654     # Expand @stack.
3655     $#stack = $stack_depth;
3656
3657     # Save current single-step setting.
3658     $stack[-1] = $single;
3659
3660     # Turn off all flags except single-stepping.
3661     $single &= 1;
3662
3663     # If we've gotten really deeply recursed, turn on the flag that will
3664     # make us stop with the 'deep recursion' message.
3665     $single |= 4 if $stack_depth == $deep;
3666
3667     # If frame messages are on ...
3668     (
3669         $frame & 4    # Extended frame entry message
3670         ? (
3671             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3672
3673             # Why -1? But it works! :-(
3674             # Because print_trace will call add 1 to it and then call
3675             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3676             # in dump_trace.
3677             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3678           )
3679         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3680
3681           # standard frame entry message
3682       )
3683       if $frame;
3684
3685     # Determine the sub's return type,and capture approppriately.
3686     if (wantarray) {
3687
3688         # Called in array context. call sub and capture output.
3689         # DB::DB will recursively get control again if appropriate; we'll come
3690         # back here when the sub is finished.
3691         @ret = &$sub;
3692
3693         # Pop the single-step value back off the stack.
3694         $single |= $stack[ $stack_depth-- ];
3695
3696         # Check for exit trace messages...
3697         (
3698             $frame & 4    # Extended exit message
3699             ? (
3700                 print_lineinfo( ' ' x $stack_depth, "out " ),
3701                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3702               )
3703             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3704
3705               # Standard exit message
3706           )
3707           if $frame & 2;
3708
3709         # Print the return info if we need to.
3710         if ( $doret eq $stack_depth or $frame & 16 ) {
3711
3712             # Turn off output record separator.
3713             local $\ = '';
3714             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3715
3716             # Indent if we're printing because of $frame tracing.
3717             print $fh ' ' x $stack_depth if $frame & 16;
3718
3719             # Print the return value.
3720             print $fh "list context return from $sub:\n";
3721             dumpit( $fh, \@ret );
3722
3723             # And don't print it again.
3724             $doret = -2;
3725         } ## end if ($doret eq $stack_depth...
3726             # And we have to return the return value now.
3727         @ret;
3728     } ## end if (wantarray)
3729
3730     # Scalar context.
3731     else {
3732         if ( defined wantarray ) {
3733
3734             # Save the value if it's wanted at all.
3735             $ret = &$sub;
3736         }
3737         else {
3738
3739             # Void return, explicitly.
3740             &$sub;
3741             undef $ret;
3742         }
3743
3744         # Pop the single-step value off the stack.
3745         $single |= $stack[ $stack_depth-- ];
3746
3747         # If we're doing exit messages...
3748         (
3749             $frame & 4    # Extended messsages
3750             ? (
3751                 print_lineinfo( ' ' x $stack_depth, "out " ),
3752                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3753               )
3754             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3755
3756               # Standard messages
3757           )
3758           if $frame & 2;
3759
3760         # If we are supposed to show the return value... same as before.
3761         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3762             local $\ = '';
3763             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3764             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3765             print $fh (
3766                 defined wantarray
3767                 ? "scalar context return from $sub: "
3768                 : "void context return from $sub\n"
3769             );
3770             dumpit( $fh, $ret ) if defined wantarray;
3771             $doret = -2;
3772         } ## end if ($doret eq $stack_depth...
3773
3774         # Return the appropriate scalar value.
3775         $ret;
3776     } ## end else [ if (wantarray)
3777 } ## end sub sub
3778
3779 sub lsub : lvalue {
3780
3781         # lock ourselves under threads
3782         lock($DBGR);
3783
3784     # Whether or not the autoloader was running, a scalar to put the
3785     # sub's return value in (if needed), and an array to put the sub's
3786     # return value in (if needed).
3787     my ( $al, $ret, @ret ) = "";
3788         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3789                 print "creating new thread\n";
3790         }
3791
3792     # If the last ten characters are C'::AUTOLOAD', note we've traced
3793     # into AUTOLOAD for $sub.
3794     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3795         $al = " for $$sub";
3796     }
3797
3798     # We stack the stack pointer and then increment it to protect us
3799     # from a situation that might unwind a whole bunch of call frames
3800     # at once. Localizing the stack pointer means that it will automatically
3801     # unwind the same amount when multiple stack frames are unwound.
3802     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3803
3804     # Expand @stack.
3805     $#stack = $stack_depth;
3806
3807     # Save current single-step setting.
3808     $stack[-1] = $single;
3809
3810     # Turn off all flags except single-stepping.
3811     $single &= 1;
3812
3813     # If we've gotten really deeply recursed, turn on the flag that will
3814     # make us stop with the 'deep recursion' message.
3815     $single |= 4 if $stack_depth == $deep;
3816
3817     # If frame messages are on ...
3818     (
3819         $frame & 4    # Extended frame entry message
3820         ? (
3821             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3822
3823             # Why -1? But it works! :-(
3824             # Because print_trace will call add 1 to it and then call
3825             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3826             # in dump_trace.
3827             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3828           )
3829         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3830
3831           # standard frame entry message
3832       )
3833       if $frame;
3834
3835     # Pop the single-step value back off the stack.
3836     $single |= $stack[ $stack_depth-- ];
3837
3838     # call the original lvalue sub.
3839     &$sub;
3840 }
3841
3842 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3843
3844 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3845 Most of the changes were to systematize the command structure and to eliminate
3846 commands that threw away user input without checking.
3847
3848 The following sections describe the code added to make it easy to support
3849 multiple command sets with conflicting command names. This section is a start
3850 at unifying all command processing to make it simpler to develop commands.
3851
3852 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3853 number, and C<$dbline> (the current line) as arguments.
3854
3855 Support functions in this section which have multiple modes of failure C<die>
3856 on error; the rest simply return a false value.
3857
3858 The user-interface functions (all of the C<cmd_*> functions) just output
3859 error messages.
3860
3861 =head2 C<%set>
3862
3863 The C<%set> hash defines the mapping from command letter to subroutine
3864 name suffix.
3865
3866 C<%set> is a two-level hash, indexed by set name and then by command name.
3867 Note that trying to set the CommandSet to C<foobar> simply results in the
3868 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3869
3870 =cut
3871
3872 ### The API section
3873
3874 my %set = (    #
3875     'pre580' => {
3876         'a' => 'pre580_a',
3877         'A' => 'pre580_null',
3878         'b' => 'pre580_b',
3879         'B' => 'pre580_null',
3880         'd' => 'pre580_null',
3881         'D' => 'pre580_D',
3882         'h' => 'pre580_h',
3883         'M' => 'pre580_null',
3884         'O' => 'o',
3885         'o' => 'pre580_null',
3886         'v' => 'M',
3887         'w' => 'v',
3888         'W' => 'pre580_W',
3889     },
3890     'pre590' => {
3891         '<'  => 'pre590_prepost',
3892         '<<' => 'pre590_prepost',
3893         '>'  => 'pre590_prepost',
3894         '>>' => 'pre590_prepost',
3895         '{'  => 'pre590_prepost',
3896         '{{' => 'pre590_prepost',
3897     },
3898 );
3899
3900 =head2 C<cmd_wrapper()> (API)
3901
3902 C<cmd_wrapper()> allows the debugger to switch command sets
3903 depending on the value of the C<CommandSet> option.
3904
3905 It tries to look up the command in the C<%set> package-level I<lexical>
3906 (which means external entities can't fiddle with it) and create the name of
3907 the sub to call based on the value found in the hash (if it's there). I<All>
3908 of the commands to be handled in a set have to be added to C<%set>; if they
3909 aren't found, the 5.8.0 equivalent is called (if there is one).
3910
3911 This code uses symbolic references.
3912
3913 =cut
3914
3915 sub cmd_wrapper {
3916     my $cmd      = shift;
3917     my $line     = shift;
3918     my $dblineno = shift;
3919
3920     # Assemble the command subroutine's name by looking up the
3921     # command set and command name in %set. If we can't find it,
3922     # default to the older version of the command.
3923     my $call = 'cmd_'
3924       . ( $set{$CommandSet}{$cmd}
3925           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3926
3927     # Call the command subroutine, call it by name.
3928     return &$call( $cmd, $line, $dblineno );
3929 } ## end sub cmd_wrapper
3930
3931 =head3 C<cmd_a> (command)
3932
3933 The C<a> command handles pre-execution actions. These are associated with a
3934 particular line, so they're stored in C<%dbline>. We default to the current
3935 line if none is specified.
3936
3937 =cut
3938
3939 sub cmd_a {
3940     my $cmd    = shift;
3941     my $line   = shift || '';    # [.|line] expr
3942     my $dbline = shift;
3943
3944     # If it's dot (here), or not all digits,  use the current line.
3945     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3946
3947     # Should be a line number followed by an expression.
3948     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3949         my ( $lineno, $expr ) = ( $1, $2 );
3950
3951         # If we have an expression ...
3952         if ( length $expr ) {
3953
3954             # ... but the line isn't breakable, complain.
3955             if ( $dbline[$lineno] == 0 ) {
3956                 print $OUT
3957                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
3958             }
3959             else {
3960
3961                 # It's executable. Record that the line has an action.
3962                 $had_breakpoints{$filename} |= 2;
3963
3964                 # Remove any action, temp breakpoint, etc.
3965                 $dbline{$lineno} =~ s/\0[^\0]*//;
3966
3967                 # Add the action to the line.
3968                 $dbline{$lineno} .= "\0" . action($expr);
3969             }
3970         } ## end if (length $expr)
3971     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
3972     else {
3973
3974         # Syntax wrong.
3975         print $OUT
3976           "Adding an action requires an optional lineno and an expression\n"
3977           ;    # hint
3978     }
3979 } ## end sub cmd_a
3980
3981 =head3 C<cmd_A> (command)
3982
3983 Delete actions. Similar to above, except the delete code is in a separate
3984 subroutine, C<delete_action>.
3985
3986 =cut
3987
3988 sub cmd_A {
3989     my $cmd    = shift;
3990     my $line   = shift || '';
3991     my $dbline = shift;
3992
3993     # Dot is this line.
3994     $line =~ s/^\./$dbline/;
3995
3996     # Call delete_action with a null param to delete them all.
3997     # The '1' forces the eval to be true. It'll be false only
3998     # if delete_action blows up for some reason, in which case
3999     # we print $@ and get out.
4000     if ( $line eq '*' ) {
4001         eval { &delete_action(); 1 } or print $OUT $@ and return;
4002     }
4003
4004     # There's a real line  number. Pass it to delete_action.
4005     # Error trapping is as above.
4006     elsif ( $line =~ /^(\S.*)/ ) {
4007         eval { &delete_action($1); 1 } or print $OUT $@ and return;
4008     }
4009
4010     # Swing and a miss. Bad syntax.
4011     else {
4012         print $OUT
4013           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4014     }
4015 } ## end sub cmd_A
4016
4017 =head3 C<delete_action> (API)
4018
4019 C<delete_action> accepts either a line number or C<undef>. If a line number
4020 is specified, we check for the line being executable (if it's not, it
4021 couldn't have had an  action). If it is, we just take the action off (this
4022 will get any kind of an action, including breakpoints).
4023
4024 =cut
4025
4026 sub delete_action {
4027     my $i = shift;
4028     if ( defined($i) ) {
4029
4030         # Can there be one?
4031         die "Line $i has no action .\n" if $dbline[$i] == 0;
4032
4033         # Nuke whatever's there.
4034         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4035         delete $dbline{$i} if $dbline{$i} eq '';
4036     }
4037     else {
4038         print $OUT "Deleting all actions...\n";
4039         for my $file ( keys %had_breakpoints ) {
4040             local *dbline = $main::{ '_<' . $file };
4041             my $max = $#dbline;
4042             my $was;
4043             for ( $i = 1 ; $i <= $max ; $i++ ) {
4044                 if ( defined $dbline{$i} ) {
4045                     $dbline{$i} =~ s/\0[^\0]*//;
4046                     delete $dbline{$i} if $dbline{$i} eq '';
4047                 }
4048                 unless ( $had_breakpoints{$file} &= ~2 ) {
4049                     delete $had_breakpoints{$file};
4050                 }
4051             } ## end for ($i = 1 ; $i <= $max...
4052         } ## end for my $file (keys %had_breakpoints)
4053     } ## end else [ if (defined($i))
4054 } ## end sub delete_action
4055
4056 =head3 C<cmd_b> (command)
4057
4058 Set breakpoints. Since breakpoints can be set in so many places, in so many
4059 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4060 we try to parse the command type, and then shuttle it off to an appropriate
4061 subroutine to actually do the work of setting the breakpoint in the right
4062 place.
4063
4064 =cut
4065
4066 sub cmd_b {
4067     my $cmd    = shift;
4068     my $line   = shift;    # [.|line] [cond]
4069     my $dbline = shift;
4070
4071     # Make . the current line number if it's there..
4072     $line =~ s/^\./$dbline/;
4073
4074     # No line number, no condition. Simple break on current line.
4075     if ( $line =~ /^\s*$/ ) {
4076         &cmd_b_line( $dbline, 1 );
4077     }
4078
4079     # Break on load for a file.
4080     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4081         my $file = $1;
4082         $file =~ s/\s+$//;
4083         &cmd_b_load($file);
4084     }
4085
4086     # b compile|postpone <some sub> [<condition>]
4087     # The interpreter actually traps this one for us; we just put the
4088     # necessary condition in the %postponed hash.
4089     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4090
4091         # Capture the condition if there is one. Make it true if none.
4092         my $cond = length $3 ? $3 : '1';
4093
4094         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4095         # if it was 'compile'.
4096         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4097
4098         # De-Perl4-ify the name - ' separators to ::.
4099         $subname =~ s/\'/::/g;
4100
4101         # Qualify it into the current package unless it's already qualified.
4102         $subname = "${'package'}::" . $subname unless $subname =~ /::/;
4103
4104         # Add main if it starts with ::.
4105         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4106
4107         # Save the break type for this sub.
4108         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4109     } ## end elsif ($line =~ ...
4110
4111     # b <sub name> [<condition>]
4112     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4113
4114         #
4115         $subname = $1;
4116         $cond = length $2 ? $2 : '1';
4117         &cmd_b_sub( $subname, $cond );
4118     }
4119
4120     # b <line> [<condition>].
4121     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4122
4123         # Capture the line. If none, it's the current line.
4124         $line = $1 || $dbline;
4125
4126         # If there's no condition, make it '1'.
4127         $cond = length $2 ? $2 : '1';
4128
4129         # Break on line.
4130         &cmd_b_line( $line, $cond );
4131     }
4132
4133     # Line didn't make sense.
4134     else {
4135         print "confused by line($line)?\n";
4136     }
4137 } ## end sub cmd_b
4138
4139 =head3 C<break_on_load> (API)
4140
4141 We want to break when this file is loaded. Mark this file in the
4142 C<%break_on_load> hash, and note that it has a breakpoint in
4143 C<%had_breakpoints>.
4144
4145 =cut
4146
4147 sub break_on_load {
4148     my $file = shift;
4149     $break_on_load{$file} = 1;
4150     $had_breakpoints{$file} |= 1;
4151 }
4152
4153 =head3 C<report_break_on_load> (API)
4154
4155 Gives us an array of filenames that are set to break on load. Note that
4156 only files with break-on-load are in here, so simply showing the keys
4157 suffices.
4158
4159 =cut
4160
4161 sub report_break_on_load {
4162     sort keys %break_on_load;
4163 }
4164
4165 =head3 C<cmd_b_load> (command)
4166
4167 We take the file passed in and try to find it in C<%INC> (which maps modules
4168 to files they came from). We mark those files for break-on-load via
4169 C<break_on_load> and then report that it was done.
4170
4171 =cut
4172
4173 sub cmd_b_load {
4174     my $file = shift;
4175     my @files;
4176
4177     # This is a block because that way we can use a redo inside it
4178     # even without there being any looping structure at all outside it.
4179     {
4180
4181         # Save short name and full path if found.
4182         push @files, $file;
4183         push @files, $::INC{$file} if $::INC{$file};
4184
4185         # Tack on .pm and do it again unless there was a '.' in the name
4186         # already.
4187         $file .= '.pm', redo unless $file =~ /\./;
4188     }
4189
4190     # Do the real work here.
4191     break_on_load($_) for @files;
4192
4193     # All the files that have break-on-load breakpoints.
4194     @files = report_break_on_load;
4195
4196     # Normalize for the purposes of our printing this.
4197     local $\ = '';
4198     local $" = ' ';
4199     print $OUT "Will stop on load of `@files'.\n";
4200 } ## end sub cmd_b_load
4201
4202 =head3 C<$filename_error> (API package global)
4203
4204 Several of the functions we need to implement in the API need to work both
4205 on the current file and on other files. We don't want to duplicate code, so
4206 C<$filename_error> is used to contain the name of the file that's being
4207 worked on (if it's not the current one).
4208
4209 We can now build functions in pairs: the basic function works on the current
4210 file, and uses C<$filename_error> as part of its error message. Since this is
4211 initialized to C<"">, no filename will appear when we are working on the
4212 current file.
4213
4214 The second function is a wrapper which does the following:
4215
4216 =over 4
4217
4218 =item *
4219
4220 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4221
4222 =item *
4223
4224 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4225
4226 =item *
4227
4228 Calls the first function.
4229
4230 The first function works on the I<current> file (i.e., the one we changed to),
4231 and prints C<$filename_error> in the error message (the name of the other file)
4232 if it needs to. When the functions return, C<*dbline> is restored to point
4233 to the actual current file (the one we're executing in) and
4234 C<$filename_error> is restored to C<"">. This restores everything to
4235 the way it was before the second function was called at all.
4236
4237 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4238 details.
4239
4240 =back
4241
4242 =cut
4243
4244 $filename_error = '';
4245
4246 =head3 breakable_line(from, to) (API)
4247
4248 The subroutine decides whether or not a line in the current file is breakable.
4249 It walks through C<@dbline> within the range of lines specified, looking for
4250 the first line that is breakable.
4251
4252 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4253 first line I<after> C<$to> that's breakable, if there is one.
4254
4255 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4256 first line I<before> C<$to> that's breakable, if there is one.
4257
4258 =cut
4259
4260 sub breakable_line {
4261
4262     my ( $from, $to ) = @_;
4263
4264     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4265     my $i = $from;
4266
4267     # If there are at least 2 arguments, we're trying to search a range.
4268     if ( @_ >= 2 ) {
4269
4270         # $delta is positive for a forward search, negative for a backward one.
4271         my $delta = $from < $to ? +1 : -1;
4272
4273         # Keep us from running off the ends of the file.
4274         my $limit = $delta > 0 ? $#dbline : 1;
4275
4276         # Clever test. If you're a mathematician, it's obvious why this
4277         # test works. If not:
4278         # If $delta is positive (going forward), $limit will be $#dbline.
4279         #    If $to is less than $limit, ($limit - $to) will be positive, times
4280         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4281         #    as the stopping point.
4282         #
4283         #    If $to is greater than $limit, ($limit - $to) is negative,
4284         #    times $delta of 1 (positive), so the result is < 0 and we should
4285         #    use $limit ($#dbline) as the stopping point.
4286         #
4287         # If $delta is negative (going backward), $limit will be 1.
4288         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4289         #    (negative) so the result is > 0, and we use $to as the stopping
4290         #    point.
4291         #
4292         #    If $to is less than zero, ($limit - $to) will be positive,
4293         #    times $delta of -1 (negative), so the result is not > 0, and
4294         #    we use $limit (1) as the stopping point.
4295         #
4296         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4297         #    (negative), still giving zero; the result is not > 0, and
4298         #    we use $limit (1) as the stopping point.
4299         #
4300         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4301         #    (negative), giving a positive (>0) value, so we'll set $limit to
4302         #    $to.
4303
4304         $limit = $to if ( $limit - $to ) * $delta > 0;
4305
4306         # The real search loop.
4307         # $i starts at $from (the point we want to start searching from).
4308         # We move through @dbline in the appropriate direction (determined
4309         # by $delta: either -1 (back) or +1 (ahead).
4310         # We stay in as long as we haven't hit an executable line
4311         # ($dbline[$i] == 0 means not executable) and we haven't reached
4312         # the limit yet (test similar to the above).
4313         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4314
4315     } ## end if (@_ >= 2)
4316
4317     # If $i points to a line that is executable, return that.
4318     return $i unless $dbline[$i] == 0;
4319
4320     # Format the message and print it: no breakable lines in range.
4321     my ( $pl, $upto ) = ( '', '' );
4322     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4323
4324     # If there's a filename in filename_error, we'll see it.
4325     # If not, not.
4326     die "Line$pl $from$upto$filename_error not breakable\n";
4327 } ## end sub breakable_line
4328
4329 =head3 breakable_line_in_filename(file, from, to) (API)
4330
4331 Like C<breakable_line>, but look in another file.
4332
4333 =cut
4334
4335 sub breakable_line_in_filename {
4336
4337     # Capture the file name.
4338     my ($f) = shift;
4339
4340     # Swap the magic line array over there temporarily.
4341     local *dbline = $main::{ '_<' . $f };
4342
4343     # If there's an error, it's in this other file.
4344     local $filename_error = " of `$f'";
4345
4346     # Find the breakable line.
4347     breakable_line(@_);
4348
4349     # *dbline and $filename_error get restored when this block ends.
4350
4351 } ## end sub breakable_line_in_filename
4352
4353 =head3 break_on_line(lineno, [condition]) (API)
4354
4355 Adds a breakpoint with the specified condition (or 1 if no condition was
4356 specified) to the specified line. Dies if it can't.
4357
4358 =cut
4359
4360 sub break_on_line {
4361     my ( $i, $cond ) = @_;
4362
4363     # Always true if no condition supplied.
4364     $cond = 1 unless @_ >= 2;
4365
4366     my $inii  = $i;
4367     my $after = '';
4368     my $pl    = '';
4369
4370     # Woops, not a breakable line. $filename_error allows us to say
4371     # if it was in a different file.
4372     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4373
4374     # Mark this file as having breakpoints in it.
4375     $had_breakpoints{$filename} |= 1;
4376
4377     # If there is an action or condition here already ...
4378     if ( $dbline{$i} ) {
4379
4380         # ... swap this condition for the existing one.
4381         $dbline{$i} =~ s/^[^\0]*/$cond/;
4382     }
4383     else {
4384
4385         # Nothing here - just add the condition.
4386         $dbline{$i} = $cond;
4387     }
4388 } ## end sub break_on_line
4389
4390 =head3 cmd_b_line(line, [condition]) (command)
4391
4392 Wrapper for C<break_on_line>. Prints the failure message if it
4393 doesn't work.
4394
4395 =cut
4396
4397 sub cmd_b_line {
4398     eval { break_on_line(@_); 1 } or do {
4399         local $\ = '';
4400         print $OUT $@ and return;
4401     };
4402 } ## end sub cmd_b_line
4403
4404 =head3 break_on_filename_line(file, line, [condition]) (API)
4405
4406 Switches to the file specified and then calls C<break_on_line> to set
4407 the breakpoint.
4408
4409 =cut
4410
4411 sub break_on_filename_line {
4412     my ( $f, $i, $cond ) = @_;
4413
4414     # Always true if condition left off.
4415     $cond = 1 unless @_ >= 3;
4416
4417     # Switch the magical hash temporarily.
4418     local *dbline = $main::{ '_<' . $f };
4419
4420     # Localize the variables that break_on_line uses to make its message.
4421     local $filename_error = " of `$f'";
4422     local $filename       = $f;
4423
4424     # Add the breakpoint.
4425     break_on_line( $i, $cond );
4426 } ## end sub break_on_filename_line
4427
4428 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4429
4430 Switch to another file, search the range of lines specified for an
4431 executable one, and put a breakpoint on the first one you find.
4432
4433 =cut
4434
4435 sub break_on_filename_line_range {
4436     my ( $f, $from, $to, $cond ) = @_;
4437
4438     # Find a breakable line if there is one.
4439     my $i = breakable_line_in_filename( $f, $from, $to );
4440
4441     # Always true if missing.
4442     $cond = 1 unless @_ >= 3;
4443
4444     # Add the breakpoint.
4445     break_on_filename_line( $f, $i, $cond );
4446 } ## end sub break_on_filename_line_range
4447
4448 =head3 subroutine_filename_lines(subname, [condition]) (API)
4449
4450 Search for a subroutine within a given file. The condition is ignored.
4451 Uses C<find_sub> to locate the desired subroutine.
4452
4453 =cut
4454
4455 sub subroutine_filename_lines {
4456     my ( $subname, $cond ) = @_;
4457
4458     # Returned value from find_sub() is fullpathname:startline-endline.
4459     # The match creates the list (fullpathname, start, end). Falling off
4460     # the end of the subroutine returns this implicitly.
4461     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
4462 } ## end sub subroutine_filename_lines
4463
4464 =head3 break_subroutine(subname) (API)
4465
4466 Places a break on the first line possible in the specified subroutine. Uses
4467 C<subroutine_filename_lines> to find the subroutine, and
4468 C<break_on_filename_line_range> to place the break.
4469
4470 =cut
4471
4472 sub break_subroutine {
4473     my $subname = shift;
4474
4475     # Get filename, start, and end.
4476     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
4477       or die "Subroutine $subname not found.\n";
4478
4479     # Null condition changes to '1' (always true).
4480     $cond = 1 unless @_ >= 2;
4481
4482     # Put a break the first place possible in the range of lines
4483     # that make up this subroutine.
4484     break_on_filename_line_range( $file, $s, $e, @_ );
4485 } ## end sub break_subroutine
4486
4487 =head3 cmd_b_sub(subname, [condition]) (command)
4488
4489 We take the incoming subroutine name and fully-qualify it as best we can.
4490
4491 =over 4
4492
4493 =item 1. If it's already fully-qualified, leave it alone.
4494
4495 =item 2. Try putting it in the current package.
4496
4497 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
4498
4499 =item 4. If it starts with '::', put it in 'main::'.
4500
4501 =back
4502
4503 After all this cleanup, we call C<break_subroutine> to try to set the
4504 breakpoint.
4505
4506 =cut
4507
4508 sub cmd_b_sub {
4509     my ( $subname, $cond ) = @_;
4510
4511     # Add always-true condition if we have none.
4512     $cond = 1 unless @_ >= 2;
4513
4514     # If the subname isn't a code reference, qualify it so that
4515     # break_subroutine() will work right.
4516     unless ( ref $subname eq 'CODE' ) {
4517
4518         # Not Perl4.
4519         $subname =~ s/\'/::/g;
4520         my $s = $subname;
4521
4522         # Put it in this package unless it's already qualified.
4523         $subname = "${'package'}::" . $subname
4524           unless $subname =~ /::/;
4525
4526         # Requalify it into CORE::GLOBAL if qualifying it into this
4527         # package resulted in its not being defined, but only do so
4528         # if it really is in CORE::GLOBAL.
4529         $subname = "CORE::GLOBAL::$s"
4530           if not defined &$subname
4531           and $s !~ /::/
4532           and defined &{"CORE::GLOBAL::$s"};
4533
4534         # Put it in package 'main' if it has a leading ::.
4535         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4536
4537     } ## end unless (ref $subname eq 'CODE')
4538
4539     # Try to set the breakpoint.
4540     eval { break_subroutine( $subname, $cond ); 1 } or do {
4541         local $\ = '';
4542         print $OUT $@ and return;
4543       }
4544 } ## end sub cmd_b_sub
4545
4546 =head3 C<cmd_B> - delete breakpoint(s) (command)
4547
4548 The command mostly parses the command line and tries to turn the argument
4549 into a line spec. If it can't, it uses the current line. It then calls
4550 C<delete_breakpoint> to actually do the work.
4551
4552 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
4553 thereby deleting all the breakpoints.
4554
4555 =cut
4556
4557 sub cmd_B {
4558     my $cmd = shift;
4559
4560     # No line spec? Use dbline.
4561     # If there is one, use it if it's non-zero, or wipe it out if it is.
4562     my $line   = ( $_[0] =~ /^\./ ) ? $dbline : shift || '';
4563     my $dbline = shift;
4564
4565     # If the line was dot, make the line the current one.
4566     $line =~ s/^\./$dbline/;
4567
4568     # If it's * we're deleting all the breakpoints.
4569     if ( $line eq '*' ) {
4570         eval { &delete_breakpoint(); 1 } or print $OUT $@ and return;
4571     }
4572
4573     # If there is a line spec, delete the breakpoint on that line.
4574     elsif ( $line =~ /^(\S.*)/ ) {
4575         eval { &delete_breakpoint( $line || $dbline ); 1 } or do {
4576             local $\ = '';
4577             print $OUT $@ and return;
4578         };
4579     } ## end elsif ($line =~ /^(\S.*)/)
4580
4581     # No line spec.
4582     else {
4583         print $OUT
4584           "Deleting a breakpoint requires a line number, or '*' for all\n"
4585           ;    # hint
4586     }
4587 } ## end sub cmd_B
4588
4589 =head3 delete_breakpoint([line]) (API)
4590
4591 This actually does the work of deleting either a single breakpoint, or all
4592 of them.
4593
4594 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
4595 just drop out with a message saying so. If it is, we remove the condition
4596 part of the 'condition\0action' that says there's a breakpoint here. If,
4597 after we've done that, there's nothing left, we delete the corresponding
4598 line in C<%dbline> to signal that no action needs to be taken for this line.
4599
4600 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
4601 which lists all currently-loaded files which have breakpoints. We then look
4602 at each line in each of these files, temporarily switching the C<%dbline>
4603 and C<@dbline> structures to point to the files in question, and do what
4604 we did in the single line case: delete the condition in C<@dbline>, and
4605 delete the key in C<%dbline> if nothing's left.
4606
4607 We then wholesale delete C<%postponed>, C<%postponed_file>, and
4608 C<%break_on_load>, because these structures contain breakpoints for files
4609 and code that haven't been loaded yet. We can just kill these off because there
4610 are no magical debugger structures associated with them.
4611
4612 =cut
4613
4614 sub delete_breakpoint {
4615     my $i = shift;
4616
4617     # If we got a line, delete just that one.
4618     if ( defined($i) ) {
4619
4620         # Woops. This line wasn't breakable at all.
4621         die "Line $i not breakable.\n" if $dbline[$i] == 0;
4622
4623         # Kill the condition, but leave any action.
4624         $dbline{$i} =~ s/^[^\0]*//;
4625
4626         # Remove the entry entirely if there's no action left.
4627         delete $dbline{$i} if $dbline{$i} eq '';
4628     }
4629
4630     # No line; delete them all.
4631     else {
4632         print $OUT "Deleting all breakpoints...\n";
4633
4634         # %had_breakpoints lists every file that had at least one
4635         # breakpoint in it.
4636         for my $file ( keys %had_breakpoints ) {
4637
4638             # Switch to the desired file temporarily.
4639             local *dbline = $main::{ '_<' . $file };
4640
4641             my $max = $#dbline;
4642             my $was;
4643
4644             # For all lines in this file ...
4645             for ( $i = 1 ; $i <= $max ; $i++ ) {
4646
4647                 # If there's a breakpoint or action on this line ...
4648                 if ( defined $dbline{$i} ) {
4649
4650                     # ... remove the breakpoint.
4651                     $dbline{$i} =~ s/^[^\0]+//;
4652                     if ( $dbline{$i} =~ s/^\0?$// ) {
4653
4654                         # Remove the entry altogether if no action is there.
4655                         delete $dbline{$i};
4656                     }
4657                 } ## end if (defined $dbline{$i...
4658             } ## end for ($i = 1 ; $i <= $max...
4659
4660             # If, after we turn off the "there were breakpoints in this file"
4661             # bit, the entry in %had_breakpoints for this file is zero,
4662             # we should remove this file from the hash.
4663             if ( not $had_breakpoints{$file} &= ~1 ) {
4664                 delete $had_breakpoints{$file};
4665             }
4666         } ## end for my $file (keys %had_breakpoints)
4667
4668         # Kill off all the other breakpoints that are waiting for files that
4669         # haven't been loaded yet.
4670         undef %postponed;
4671         undef %postponed_file;
4672         undef %break_on_load;
4673     } ## end else [ if (defined($i))
4674 } ## end sub delete_breakpoint
4675
4676 =head3 cmd_stop (command)
4677
4678 This is meant to be part of the new command API, but it isn't called or used
4679 anywhere else in the debugger. XXX It is probably meant for use in development
4680 of new commands.
4681
4682 =cut
4683
4684 sub cmd_stop {    # As on ^C, but not signal-safy.
4685     $signal = 1;
4686 }
4687
4688 =head3 C<cmd_e> - threads
4689
4690 Display the current thread id:
4691
4692         e
4693
4694 This could be how (when implemented) to send commands to this thread id (e cmd)
4695 or that thread id (e tid cmd).
4696
4697 =cut
4698
4699 sub cmd_e {
4700     my $cmd  = shift;
4701     my $line = shift;
4702         unless (exists($INC{'threads.pm'})) {
4703                 print "threads not loaded($ENV{PERL5DB_THREADED})
4704                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4705         } else {
4706                 my $tid = threads->tid;
4707                 print "thread id: $tid\n";
4708         }
4709 } ## end sub cmd_e
4710
4711 =head3 C<cmd_E> - list of thread ids
4712
4713 Display the list of available thread ids:
4714
4715         E
4716
4717 This could be used (when implemented) to send commands to all threads (E cmd).
4718
4719 =cut
4720
4721 sub cmd_E {
4722     my $cmd  = shift;
4723     my $line = shift;
4724         unless (exists($INC{'threads.pm'})) {
4725                 print "threads not loaded($ENV{PERL5DB_THREADED})
4726                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4727         } else {
4728                 my $tid = threads->tid;
4729                 print "thread ids: ".join(', ',
4730                         map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
4731                 )."\n";
4732         }
4733 } ## end sub cmd_E
4734
4735 =head3 C<cmd_h> - help command (command)
4736
4737 Does the work of either
4738
4739 =over 4
4740
4741 =item *
4742
4743 Showing all the debugger help
4744
4745 =item *
4746
4747 Showing help for a specific command
4748
4749 =back
4750
4751 =cut
4752
4753 sub cmd_h {
4754     my $cmd = shift;
4755
4756     # If we have no operand, assume null.
4757     my $line = shift || '';
4758
4759     # 'h h'. Print the long-format help.
4760     if ( $line =~ /^h\s*/ ) {
4761         print_help($help);
4762     }
4763
4764     # 'h <something>'. Search for the command and print only its help.
4765     elsif ( $line =~ /^(\S.*)$/ ) {
4766
4767         # support long commands; otherwise bogus errors
4768         # happen when you ask for h on <CR> for example
4769         my $asked = $1;    # the command requested
4770                            # (for proper error message)
4771
4772         my $qasked = quotemeta($asked);    # for searching; we don't
4773                                            # want to use it as a pattern.
4774                                            # XXX: finds CR but not <CR>
4775
4776         # Search the help string for the command.
4777         if (
4778             $help =~ /^                    # Start of a line
4779                       <?                   # Optional '<'
4780                       (?:[IB]<)            # Optional markup
4781                       $qasked              # The requested command
4782                      /mx
4783           )
4784         {
4785
4786             # It's there; pull it out and print it.
4787             while (
4788                 $help =~ /^
4789                               (<?            # Optional '<'
4790                                  (?:[IB]<)   # Optional markup
4791                                  $qasked     # The command
4792                                  ([\s\S]*?)  # Description line(s)
4793                               \n)            # End of last description line
4794                               (?!\s)         # Next line not starting with
4795                                              # whitespace
4796                              /mgx
4797               )
4798             {
4799                 print_help($1);
4800             }
4801         }
4802
4803         # Not found; not a debugger command.
4804         else {
4805             print_help("B<$asked> is not a debugger command.\n");
4806         }
4807     } ## end elsif ($line =~ /^(\S.*)$/)
4808
4809     # 'h' - print the summary help.
4810     else {
4811         print_help($summary);
4812     }
4813 } ## end sub cmd_h
4814
4815 =head3 C<cmd_i> - inheritance display
4816
4817 Display the (nested) parentage of the module or object given.
4818
4819 =cut
4820
4821 sub cmd_i {
4822     my $cmd  = shift;
4823     my $line = shift;
4824     eval { require Class::ISA };
4825     if ($@) {
4826         &warn( $@ =~ /locate/
4827             ? "Class::ISA module not found - please install\n"
4828             : $@ );
4829     }
4830     else {
4831       ISA:
4832         foreach my $isa ( split( /\s+/, $line ) ) {
4833             $evalarg = $isa;
4834             ($isa) = &eval;
4835             no strict 'refs';
4836             print join(
4837                 ', ',
4838                 map {    # snaffled unceremoniously from Class::ISA
4839                     "$_"
4840                       . (
4841                         defined( ${"$_\::VERSION"} )
4842                         ? ' ' . ${"$_\::VERSION"}
4843                         : undef )
4844                   } Class::ISA::self_and_super_path(ref($isa) || $isa)
4845             );
4846             print "\n";
4847         }
4848     }
4849 } ## end sub cmd_i
4850
4851 =head3 C<cmd_l> - list lines (command)
4852
4853 Most of the command is taken up with transforming all the different line
4854 specification syntaxes into 'start-stop'. After that is done, the command
4855 runs a loop over C<@dbline> for the specified range of lines. It handles
4856 the printing of each line and any markers (C<==E<gt>> for current line,
4857 C<b> for break on this line, C<a> for action on this line, C<:> for this
4858 line breakable).
4859
4860 We save the last line listed in the C<$start> global for further listing
4861 later.
4862
4863 =cut
4864
4865 sub cmd_l {
4866     my $current_line = $line;
4867     my $cmd  = shift;
4868     my $line = shift;
4869
4870     # If this is '-something', delete any spaces after the dash.
4871     $line =~ s/^-\s*$/-/;
4872
4873     # If the line is '$something', assume this is a scalar containing a
4874     # line number.
4875     if ( $line =~ /^(\$.*)/s ) {
4876
4877         # Set up for DB::eval() - evaluate in *user* context.
4878         $evalarg = $1;
4879         # $evalarg = $2;
4880         my ($s) = &eval;
4881
4882         # Ooops. Bad scalar.
4883         print( $OUT "Error: $@\n" ), next CMD if $@;
4884
4885         # Good scalar. If it's a reference, find what it points to.
4886         $s = CvGV_name($s);
4887         print( $OUT "Interpreted as: $1 $s\n" );
4888         $line = "$1 $s";
4889
4890         # Call self recursively to really do the command.
4891         &cmd_l( 'l', $s );
4892     } ## end if ($line =~ /^(\$.*)/s)
4893
4894     # l name. Try to find a sub by that name.
4895     elsif ( $line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s ) {
4896         my $s = $subname = $1;
4897
4898         # De-Perl4.
4899         $subname =~ s/\'/::/;
4900
4901         # Put it in this package unless it starts with ::.
4902         $subname = $package . "::" . $subname unless $subname =~ /::/;
4903
4904         # Put it in CORE::GLOBAL if t doesn't start with :: and
4905         # it doesn't live in this package and it lives in CORE::GLOBAL.
4906         $subname = "CORE::GLOBAL::$s"
4907           if not defined &$subname
4908           and $s !~ /::/
4909           and defined &{"CORE::GLOBAL::$s"};
4910
4911         # Put leading '::' names into 'main::'.
4912         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4913
4914         # Get name:start-stop from find_sub, and break this up at
4915         # colons.
4916         @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
4917
4918         # Pull off start-stop.
4919         $subrange = pop @pieces;
4920
4921         # If the name contained colons, the split broke it up.
4922         # Put it back together.
4923         $file = join( ':', @pieces );
4924
4925         # If we're not in that file, switch over to it.
4926         if ( $file ne $filename ) {
4927             print $OUT "Switching to file '$file'.\n"
4928               unless $slave_editor;
4929
4930             # Switch debugger's magic structures.
4931             *dbline   = $main::{ '_<' . $file };
4932             $max      = $#dbline;
4933             $filename = $file;
4934         } ## end if ($file ne $filename)
4935
4936         # Subrange is 'start-stop'. If this is less than a window full,
4937         # swap it to 'start+', which will list a window from the start point.
4938         if ($subrange) {
4939             if ( eval($subrange) < -$window ) {
4940                 $subrange =~ s/-.*/+/;
4941             }
4942
4943             # Call self recursively to list the range.
4944             $line = $subrange;
4945             &cmd_l( 'l', $subrange );
4946         } ## end if ($subrange)
4947
4948         # Couldn't find it.
4949         else {
4950             print $OUT "Subroutine $subname not found.\n";
4951         }
4952     } ## end elsif ($line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s)
4953
4954     # Bare 'l' command.
4955     elsif ( $line =~ /^\s*$/ ) {
4956
4957         # Compute new range to list.
4958         $incr = $window - 1;
4959         $line = $start . '-' . ( $start + $incr );
4960
4961         # Recurse to do it.
4962         &cmd_l( 'l', $line );
4963     }
4964
4965     # l [start]+number_of_lines
4966     elsif ( $line =~ /^(\d*)\+(\d*)$/ ) {
4967
4968         # Don't reset start for 'l +nnn'.
4969         $start = $1 if $1;
4970
4971         # Increment for list. Use window size if not specified.
4972         # (Allows 'l +' to work.)
4973         $incr = $2;
4974         $incr = $window - 1 unless $incr;
4975
4976         # Create a line range we'll understand, and recurse to do it.
4977         $line = $start . '-' . ( $start + $incr );
4978         &cmd_l( 'l', $line );
4979     } ## end elsif ($line =~ /^(\d*)\+(\d*)$/)
4980
4981     # l start-stop or l start,stop
4982     elsif ( $line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/ ) {
4983
4984         # Determine end point; use end of file if not specified.
4985         $end = ( !defined $2 ) ? $max : ( $4 ? $4 : $2 );
4986
4987         # Go on to the end, and then stop.
4988         $end = $max if $end > $max;
4989
4990         # Determine start line.
4991         $i    = $2;
4992         $i    = $line if $i eq '.';
4993         $i    = 1 if $i < 1;
4994         $incr = $end - $i;
4995
4996         # If we're running under a slave editor, force it to show the lines.
4997         if ($slave_editor) {
4998             print $OUT "\032\032$filename:$i:0\n";
4999             $i = $end;
5000         }
5001
5002         # We're doing it ourselves. We want to show the line and special
5003         # markers for:
5004         # - the current line in execution
5005         # - whether a line is breakable or not
5006         # - whether a line has a break or not
5007         # - whether a line has an action or not
5008         else {
5009             for ( ; $i <= $end ; $i++ ) {
5010
5011                 # Check for breakpoints and actions.
5012                 my ( $stop, $action );
5013                 ( $stop, $action ) = split( /\0/, $dbline{$i} )
5014                   if $dbline{$i};
5015
5016                 # ==> if this is the current line in execution,
5017                 # : if it's breakable.
5018                 $arrow =
5019                   ( $i == $current_line and $filename eq $filename_ini )
5020                   ? '==>'
5021                   : ( $dbline[$i] + 0 ? ':' : ' ' );
5022
5023                 # Add break and action indicators.
5024                 $arrow .= 'b' if $stop;
5025                 $arrow .= 'a' if $action;
5026
5027                 # Print the line.
5028                 print $OUT "$i$arrow\t", $dbline[$i];
5029
5030                 # Move on to the next line. Drop out on an interrupt.
5031                 $i++, last if $signal;
5032             } ## end for (; $i <= $end ; $i++)
5033
5034             # Line the prompt up; print a newline if the last line listed
5035             # didn't have a newline.
5036             print $OUT "\n" unless $dbline[ $i - 1 ] =~ /\n$/;
5037         } ## end else [ if ($slave_editor)
5038
5039         # Save the point we last listed to in case another relative 'l'
5040         # command is desired. Don't let it run off the end.
5041         $start = $i;
5042         $start = $max if $start > $max;
5043     } ## end elsif ($line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/)
5044 } ## end sub cmd_l
5045
5046 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5047
5048 To list breakpoints, the command has to look determine where all of them are
5049 first. It starts a C<%had_breakpoints>, which tells us what all files have
5050 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5051 magic source and breakpoint data structures) to the file, and then look
5052 through C<%dbline> for lines with breakpoints and/or actions, listing them
5053 out. We look through C<%postponed> not-yet-compiled subroutines that have
5054 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5055 that have breakpoints.
5056
5057 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5058
5059 =cut
5060
5061 sub cmd_L {
5062     my $cmd = shift;
5063
5064     # If no argument, list everything. Pre-5.8.0 version always lists
5065     # everything
5066     my $arg = shift || 'abw';
5067     $arg = 'abw' unless $CommandSet eq '580';    # sigh...
5068
5069     # See what is wanted.
5070     my $action_wanted = ( $arg =~ /a/ ) ? 1 : 0;
5071     my $break_wanted  = ( $arg =~ /b/ ) ? 1 : 0;
5072     my $watch_wanted  = ( $arg =~ /w/ ) ? 1 : 0;
5073
5074     # Breaks and actions are found together, so we look in the same place
5075     # for both.
5076     if ( $break_wanted or $action_wanted ) {
5077
5078         # Look in all the files with breakpoints...
5079         for my $file ( keys %had_breakpoints ) {
5080
5081             # Temporary switch to this file.
5082             local *dbline = $main::{ '_<' . $file };
5083
5084             # Set up to look through the whole file.
5085             my $max = $#dbline;
5086             my $was;    # Flag: did we print something
5087                         # in this file?
5088
5089             # For each line in the file ...
5090             for ( $i = 1 ; $i <= $max ; $i++ ) {
5091
5092                 # We've got something on this line.
5093                 if ( defined $dbline{$i} ) {
5094
5095                     # Print the header if we haven't.
5096                     print $OUT "$file:\n" unless $was++;
5097
5098                     # Print the line.
5099                     print $OUT " $i:\t", $dbline[$i];
5100
5101                     # Pull out the condition and the action.
5102                     ( $stop, $action ) = split( /\0/, $dbline{$i} );
5103
5104                     # Print the break if there is one and it's wanted.
5105                     print $OUT "   break if (", $stop, ")\n"
5106                       if $stop
5107                       and $break_wanted;
5108
5109                     # Print the action if there is one and it's wanted.
5110                     print $OUT "   action:  ", $action, "\n"
5111                       if $action
5112                       and $action_wanted;
5113
5114                     # Quit if the user hit interrupt.
5115                     last if $signal;
5116                 } ## end if (defined $dbline{$i...
5117             } ## end for ($i = 1 ; $i <= $max...
5118         } ## end for my $file (keys %had_breakpoints)
5119     } ## end if ($break_wanted or $action_wanted)
5120
5121     # Look for breaks in not-yet-compiled subs:
5122     if ( %postponed and $break_wanted ) {
5123         print $OUT "Postponed breakpoints in subroutines:\n";
5124         my $subname;
5125         for $subname ( keys %postponed ) {
5126             print $OUT " $subname\t$postponed{$subname}\n";
5127             last if $signal;
5128         }
5129     } ## end if (%postponed and $break_wanted)
5130
5131     # Find files that have not-yet-loaded breaks:
5132     my @have = map {    # Combined keys
5133         keys %{ $postponed_file{$_} }
5134     } keys %postponed_file;
5135
5136     # If there are any, list them.
5137     if ( @have and ( $break_wanted or $action_wanted ) ) {
5138         print $OUT "Postponed breakpoints in files:\n";
5139         my ( $file, $line );
5140
5141         for $file ( keys %postponed_file ) {
5142             my $db = $postponed_file{$file};
5143             print $OUT " $file:\n";
5144             for $line ( sort { $a <=> $b } keys %$db ) {
5145                 print $OUT "  $line:\n";
5146                 my ( $stop, $action ) = split( /\0/, $$db{$line} );
5147                 print $OUT "    break if (", $stop, ")\n"
5148                   if $stop
5149                   and $break_wanted;
5150                 print $OUT "    action:  ", $action, "\n"
5151                   if $action
5152                   and $action_wanted;
5153                 last if $signal;
5154             } ## end for $line (sort { $a <=>...
5155             last if $signal;
5156         } ## end for $file (keys %postponed_file)
5157     } ## end if (@have and ($break_wanted...
5158     if ( %break_on_load and $break_wanted ) {
5159         print $OUT "Breakpoints on load:\n";
5160         my $file;
5161         for $file ( keys %break_on_load ) {
5162             print $OUT " $file\n";
5163             last if $signal;
5164         }
5165     } ## end if (%break_on_load and...
5166     if ($watch_wanted) {
5167         if ( $trace & 2 ) {
5168             print $OUT "Watch-expressions:\n" if @to_watch;
5169             for my $expr (@to_watch) {
5170                 print $OUT " $expr\n";
5171                 last if $signal;
5172             }
5173         } ## end if ($trace & 2)
5174     } ## end if ($watch_wanted)
5175 } ## end sub cmd_L
5176
5177 =head3 C<cmd_M> - list modules (command)
5178
5179 Just call C<list_modules>.
5180
5181 =cut
5182
5183 sub cmd_M {
5184     &list_modules();
5185 }
5186
5187 =head3 C<cmd_o> - options (command)
5188
5189 If this is just C<o> by itself, we list the current settings via
5190 C<dump_option>. If there's a nonblank value following it, we pass that on to
5191 C<parse_options> for processing.
5192
5193 =cut
5194
5195 sub cmd_o {
5196     my $cmd = shift;
5197     my $opt = shift || '';    # opt[=val]
5198
5199     # Nonblank. Try to parse and process.
5200     if ( $opt =~ /^(\S.*)/ ) {
5201         &parse_options($1);
5202     }
5203
5204     # Blank. List the current option settings.
5205     else {
5206         for (@options) {
5207             &dump_option($_);
5208         }
5209     }
5210 } ## end sub cmd_o
5211
5212 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5213
5214 Advises the user that the O command has been renamed.
5215
5216 =cut
5217
5218 sub cmd_O {
5219     print $OUT "The old O command is now the o command.\n";             # hint
5220     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5221     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5222 }
5223
5224 =head3 C<cmd_v> - view window (command)
5225
5226 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5227 move back a few lines to list the selected line in context. Uses C<cmd_l>
5228 to do the actual listing after figuring out the range of line to request.
5229
5230 =cut
5231
5232 sub cmd_v {
5233     my $cmd  = shift;
5234     my $line = shift;
5235
5236     # Extract the line to list around. (Astute readers will have noted that
5237     # this pattern will match whether or not a numeric line is specified,
5238     # which means that we'll always enter this loop (though a non-numeric
5239     # argument results in no action at all)).
5240     if ( $line =~ /^(\d*)$/ ) {
5241
5242         # Total number of lines to list (a windowful).
5243         $incr = $window - 1;
5244
5245         # Set the start to the argument given (if there was one).
5246         $start = $1 if $1;
5247
5248         # Back up by the context amount.
5249         $start -= $preview;
5250
5251         # Put together a linespec that cmd_l will like.
5252         $line = $start . '-' . ( $start + $incr );
5253
5254         # List the lines.
5255         &cmd_l( 'l', $line );
5256     } ## end if ($line =~ /^(\d*)$/)
5257 } ## end sub cmd_v
5258
5259 =head3 C<cmd_w> - add a watch expression (command)
5260
5261 The 5.8 version of this command adds a watch expression if one is specified;
5262 it does nothing if entered with no operands.
5263
5264 We extract the expression, save it, evaluate it in the user's context, and
5265 save the value. We'll re-evaluate it each time the debugger passes a line,
5266 and will stop (see the code at the top of the command loop) if the value
5267 of any of the expressions changes.
5268
5269 =cut
5270
5271 sub cmd_w {
5272     my $cmd = shift;
5273
5274     # Null expression if no arguments.
5275     my $expr = shift || '';
5276
5277     # If expression is not null ...
5278     if ( $expr =~ /^(\S.*)/ ) {
5279
5280         # ... save it.
5281         push @to_watch, $expr;
5282
5283         # Parameterize DB::eval and call it to get the expression's value
5284         # in the user's context. This version can handle expressions which
5285         # return a list value.
5286         $evalarg = $expr;
5287         my ($val) = join( ' ', &eval );
5288         $val = ( defined $val ) ? "'$val'" : 'undef';
5289
5290         # Save the current value of the expression.
5291         push @old_watch, $val;
5292
5293         # We are now watching expressions.
5294         $trace |= 2;
5295     } ## end if ($expr =~ /^(\S.*)/)
5296
5297     # You have to give one to get one.
5298     else {
5299         print $OUT "Adding a watch-expression requires an expression\n";  # hint
5300     }
5301 } ## end sub cmd_w
5302
5303 =head3 C<cmd_W> - delete watch expressions (command)
5304
5305 This command accepts either a watch expression to be removed from the list
5306 of watch expressions, or C<*> to delete them all.
5307
5308 If C<*> is specified, we simply empty the watch expression list and the
5309 watch expression value list. We also turn off the bit that says we've got
5310 watch expressions.
5311
5312 If an expression (or partial expression) is specified, we pattern-match
5313 through the expressions and remove the ones that match. We also discard
5314 the corresponding values. If no watch expressions are left, we turn off
5315 the I<watching expressions> bit.
5316
5317 =cut
5318
5319 sub cmd_W {
5320     my $cmd  = shift;
5321     my $expr = shift || '';
5322
5323     # Delete them all.
5324     if ( $expr eq '*' ) {
5325
5326         # Not watching now.
5327         $trace &= ~2;
5328
5329         print $OUT "Deleting all watch expressions ...\n";
5330
5331         # And all gone.
5332         @to_watch = @old_watch = ();
5333     }
5334
5335     # Delete one of them.
5336     elsif ( $expr =~ /^(\S.*)/ ) {
5337
5338         # Where we are in the list.
5339         my $i_cnt = 0;
5340
5341         # For each expression ...
5342         foreach (@to_watch) {
5343             my $val = $to_watch[$i_cnt];
5344
5345             # Does this one match the command argument?
5346             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
5347                                       # Yes. Turn it off, and its value too.
5348                 splice( @to_watch,  $i_cnt, 1 );
5349                 splice( @old_watch, $i_cnt, 1 );
5350             }
5351             $i_cnt++;
5352         } ## end foreach (@to_watch)
5353
5354         # We don't bother to turn watching off because
5355         #  a) we don't want to stop calling watchfunction() it it exists
5356         #  b) foreach over a null list doesn't do anything anyway
5357
5358     } ## end elsif ($expr =~ /^(\S.*)/)
5359
5360     # No command arguments entered.
5361     else {
5362         print $OUT
5363           "Deleting a watch-expression requires an expression, or '*' for all\n"
5364           ;    # hint
5365     }
5366 } ## end sub cmd_W
5367
5368 ### END of the API section
5369
5370 =head1 SUPPORT ROUTINES
5371
5372 These are general support routines that are used in a number of places
5373 throughout the debugger.
5374
5375 =head2 save
5376
5377 save() saves the user's versions of globals that would mess us up in C<@saved>,
5378 and installs the versions we like better.
5379
5380 =cut
5381
5382 sub save {
5383
5384     # Save eval failure, command failure, extended OS error, output field
5385     # separator, input record separator, output record separator and
5386     # the warning setting.
5387     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
5388
5389     $,  = "";      # output field separator is null string
5390     $/  = "\n";    # input record separator is newline
5391     $\  = "";      # output record separator is null string
5392     $^W = 0;       # warnings are off
5393 } ## end sub save
5394
5395 =head2 C<print_lineinfo> - show where we are now
5396
5397 print_lineinfo prints whatever it is that it is handed; it prints it to the
5398 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
5399 us to feed line information to a slave editor without messing up the
5400 debugger output.
5401
5402 =cut
5403
5404 sub print_lineinfo {
5405
5406     # Make the terminal sensible if we're not the primary debugger.
5407     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
5408     local $\ = '';
5409     local $, = '';
5410     print $LINEINFO @_;
5411 } ## end sub print_lineinfo
5412
5413 =head2 C<postponed_sub>
5414
5415 Handles setting postponed breakpoints in subroutines once they're compiled.
5416 For breakpoints, we use C<DB::find_sub> to locate the source file and line
5417 range for the subroutine, then mark the file as having a breakpoint,
5418 temporarily switch the C<*dbline> glob over to the source file, and then
5419 search the given range of lines to find a breakable line. If we find one,
5420 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
5421
5422 =cut
5423
5424 # The following takes its argument via $evalarg to preserve current @_
5425
5426 sub postponed_sub {
5427
5428     # Get the subroutine name.
5429     my $subname = shift;
5430
5431     # If this is a 'break +<n> if <condition>' ...
5432     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
5433
5434         # If there's no offset, use '+0'.
5435         my $offset = $1 || 0;
5436
5437         # find_sub's value is 'fullpath-filename:start-stop'. It's
5438         # possible that the filename might have colons in it too.
5439         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
5440         if ($i) {
5441
5442             # We got the start line. Add the offset '+<n>' from
5443             # $postponed{subname}.
5444             $i += $offset;
5445
5446             # Switch to the file this sub is in, temporarily.
5447             local *dbline = $main::{ '_<' . $file };
5448
5449             # No warnings, please.
5450             local $^W = 0;    # != 0 is magical below
5451
5452             # This file's got a breakpoint in it.
5453             $had_breakpoints{$file} |= 1;
5454
5455             # Last line in file.
5456             my $max = $#dbline;
5457
5458             # Search forward until we hit a breakable line or get to
5459             # the end of the file.
5460             ++$i until $dbline[$i] != 0 or $i >= $max;
5461
5462             # Copy the breakpoint in and delete it from %postponed.
5463             $dbline{$i} = delete $postponed{$subname};
5464         } ## end if ($i)
5465
5466         # find_sub didn't find the sub.
5467         else {
5468             local $\ = '';
5469             print $OUT "Subroutine $subname not found.\n";
5470         }
5471         return;
5472     } ## end if ($postponed{$subname...
5473     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
5474
5475     #print $OUT "In postponed_sub for `$subname'.\n";
5476 } ## end sub postponed_sub
5477
5478 =head2 C<postponed>
5479
5480 Called after each required file is compiled, but before it is executed;
5481 also called if the name of a just-compiled subroutine is a key of
5482 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
5483 etc.) into the just-compiled code.
5484
5485 If this is a C<require>'d file, the incoming parameter is the glob
5486 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
5487
5488 If it's a subroutine, the incoming parameter is the subroutine name.
5489
5490 =cut
5491
5492 sub postponed {
5493
5494     # If there's a break, process it.
5495     if ($ImmediateStop) {
5496
5497         # Right, we've stopped. Turn it off.
5498         $ImmediateStop = 0;
5499
5500         # Enter the command loop when DB::DB gets called.
5501         $signal = 1;
5502     }
5503
5504     # If this is a subroutine, let postponed_sub() deal with it.
5505     return &postponed_sub unless ref \$_[0] eq 'GLOB';
5506
5507     # Not a subroutine. Deal with the file.
5508     local *dbline = shift;
5509     my $filename = $dbline;
5510     $filename =~ s/^_<//;
5511     local $\ = '';
5512     $signal = 1, print $OUT "'$filename' loaded...\n"
5513       if $break_on_load{$filename};
5514     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
5515
5516     # Do we have any breakpoints to put in this file?
5517     return unless $postponed_file{$filename};
5518
5519     # Yes. Mark this file as having breakpoints.
5520     $had_breakpoints{$filename} |= 1;
5521
5522     # "Cannot be done: unsufficient magic" - we can't just put the
5523     # breakpoints saved in %postponed_file into %dbline by assigning
5524     # the whole hash; we have to do it one item at a time for the
5525     # breakpoints to be set properly.
5526     #%dbline = %{$postponed_file{$filename}};
5527
5528     # Set the breakpoints, one at a time.
5529     my $key;
5530
5531     for $key ( keys %{ $postponed_file{$filename} } ) {
5532
5533         # Stash the saved breakpoint into the current file's magic line array.
5534         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
5535     }
5536
5537     # This file's been compiled; discard the stored breakpoints.
5538     delete $postponed_file{$filename};
5539
5540 } ## end sub postponed
5541
5542 =head2 C<dumpit>
5543
5544 C<dumpit> is the debugger's wrapper around dumpvar.pl.
5545
5546 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
5547 a reference to a variable (the thing to be dumped) as its input.
5548
5549 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
5550 the currently-selected filehandle, thank you very much). The current
5551 values of the package globals C<$single> and C<$trace> are backed up in
5552 lexicals, and they are turned off (this keeps the debugger from trying
5553 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
5554 preserve its current value and it is set to zero to prevent entry/exit
5555 messages from printing, and C<$doret> is localized as well and set to -2 to
5556 prevent return values from being shown.
5557
5558 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
5559 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
5560 installed version in C<@INC>, yours will be used instead. Possible security
5561 problem?).
5562
5563 It then checks to see if the subroutine C<main::dumpValue> is now defined
5564 (it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
5565 localizes the globals necessary for things to be sane when C<main::dumpValue()>
5566 is called, and picks up the variable to be dumped from the parameter list.
5567
5568 It checks the package global C<%options> to see if there's a C<dumpDepth>
5569 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
5570 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
5571 structure: -1 means dump everything.
5572
5573 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
5574 warning.
5575
5576 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
5577 and we then return to the caller.
5578
5579 =cut
5580
5581 sub dumpit {
5582
5583     # Save the current output filehandle and switch to the one
5584     # passed in as the first parameter.
5585     local ($savout) = select(shift);
5586
5587     # Save current settings of $single and $trace, and then turn them off.
5588     my $osingle = $single;
5589     my $otrace  = $trace;
5590     $single = $trace = 0;
5591
5592     # XXX Okay, what do $frame and $doret do, again?
5593     local $frame = 0;
5594     local $doret = -2;
5595
5596     # Load dumpvar.pl unless we've already got the sub we need from it.
5597     unless ( defined &main::dumpValue ) {
5598         do 'dumpvar.pl' or die $@;
5599     }
5600
5601     # If the load succeeded (or we already had dumpvalue()), go ahead
5602     # and dump things.
5603     if ( defined &main::dumpValue ) {
5604         local $\ = '';
5605         local $, = '';
5606         local $" = ' ';
5607         my $v = shift;
5608         my $maxdepth = shift || $option{dumpDepth};
5609         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
5610         &main::dumpValue( $v, $maxdepth );
5611     } ## end if (defined &main::dumpValue)
5612
5613     # Oops, couldn't load dumpvar.pl.
5614     else {
5615         local $\ = '';
5616         print $OUT "dumpvar.pl not available.\n";
5617     }
5618
5619     # Reset $single and $trace to their old values.
5620     $single = $osingle;
5621     $trace  = $otrace;
5622
5623     # Restore the old filehandle.
5624     select($savout);
5625 } ## end sub dumpit
5626
5627 =head2 C<print_trace>
5628
5629 C<print_trace>'s job is to print a stack trace. It does this via the
5630 C<dump_trace> routine, which actually does all the ferreting-out of the
5631 stack trace data. C<print_trace> takes care of formatting it nicely and
5632 printing it to the proper filehandle.
5633
5634 Parameters:
5635
5636 =over 4
5637
5638 =item *
5639
5640 The filehandle to print to.
5641
5642 =item *
5643
5644 How many frames to skip before starting trace.
5645
5646 =item *
5647
5648 How many frames to print.
5649
5650 =item *
5651
5652 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
5653
5654 =back
5655
5656 The original comment below seems to be noting that the traceback may not be
5657 correct if this routine is called in a tied method.
5658
5659 =cut
5660
5661 # Tied method do not create a context, so may get wrong message:
5662
5663 sub print_trace {
5664     local $\ = '';
5665     my $fh = shift;
5666
5667     # If this is going to a slave editor, but we're not the primary
5668     # debugger, reset it first.
5669     resetterm(1)
5670       if $fh        eq $LINEINFO    # slave editor
5671       and $LINEINFO eq $OUT         # normal output
5672       and $term_pid != $$;          # not the primary
5673
5674     # Collect the actual trace information to be formatted.
5675     # This is an array of hashes of subroutine call info.
5676     my @sub = dump_trace( $_[0] + 1, $_[1] );
5677
5678     # Grab the "short report" flag from @_.
5679     my $short = $_[2];              # Print short report, next one for sub name
5680
5681     # Run through the traceback info, format it, and print it.
5682     my $s;
5683     for ( $i = 0 ; $i <= $#sub ; $i++ ) {
5684
5685         # Drop out if the user has lost interest and hit control-C.
5686         last if $signal;
5687
5688         # Set the separator so arrys print nice.
5689         local $" = ', ';
5690
5691         # Grab and stringify the arguments if they are there.
5692         my $args =
5693           defined $sub[$i]{args}
5694           ? "(@{ $sub[$i]{args} })"
5695           : '';
5696
5697         # Shorten them up if $maxtrace says they're too long.
5698         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
5699           if length $args > $maxtrace;
5700
5701         # Get the file name.
5702         my $file = $sub[$i]{file};
5703
5704         # Put in a filename header if short is off.
5705         $file = $file eq '-e' ? $file : "file `$file'" unless $short;
5706
5707         # Get the actual sub's name, and shorten to $maxtrace's requirement.
5708         $s = $sub[$i]{sub};
5709         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
5710
5711         # Short report uses trimmed file and sub names.
5712         if ($short) {
5713             my $sub = @_ >= 4 ? $_[3] : $s;
5714             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
5715         } ## end if ($short)
5716
5717         # Non-short report includes full names.
5718         else {
5719             print $fh "$sub[$i]{context} = $s$args"
5720               . " called from $file"
5721               . " line $sub[$i]{line}\n";
5722         }
5723     } ## end for ($i = 0 ; $i <= $#sub...
5724 } ## end sub print_trace
5725
5726 =head2 dump_trace(skip[,count])
5727
5728 Actually collect the traceback information available via C<caller()>. It does
5729 some filtering and cleanup of the data, but mostly it just collects it to
5730 make C<print_trace()>'s job easier.
5731
5732 C<skip> defines the number of stack frames to be skipped, working backwards
5733 from the most current. C<count> determines the total number of frames to
5734 be returned; all of them (well, the first 10^9) are returned if C<count>
5735 is omitted.
5736
5737 This routine returns a list of hashes, from most-recent to least-recent
5738 stack frame. Each has the following keys and values:
5739
5740 =over 4
5741
5742 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
5743
5744 =item * C<sub> - subroutine name, or C<eval> information
5745
5746 =item * C<args> - undef, or a reference to an array of arguments
5747
5748 =item * C<file> - the file in which this item was defined (if any)
5749
5750 =item * C<line> - the line on which it was defined
5751
5752 =back
5753
5754 =cut
5755
5756 sub dump_trace {
5757
5758     # How many levels to skip.
5759     my $skip = shift;
5760
5761     # How many levels to show. (1e9 is a cheap way of saying "all of them";
5762     # it's unlikely that we'll have more than a billion stack frames. If you
5763     # do, you've got an awfully big machine...)
5764     my $count = shift || 1e9;
5765
5766     # We increment skip because caller(1) is the first level *back* from
5767     # the current one.  Add $skip to the count of frames so we have a
5768     # simple stop criterion, counting from $skip to $count+$skip.
5769     $skip++;
5770     $count += $skip;
5771
5772     # These variables are used to capture output from caller();
5773     my ( $p, $file, $line, $sub, $h, $context );
5774
5775     my ( $e, $r, @a, @sub, $args );
5776
5777     # XXX Okay... why'd we do that?
5778     my $nothard = not $frame & 8;
5779     local $frame = 0;
5780
5781     # Do not want to trace this.
5782     my $otrace = $trace;
5783     $trace = 0;
5784
5785     # Start out at the skip count.
5786     # If we haven't reached the number of frames requested, and caller() is
5787     # still returning something, stay in the loop. (If we pass the requested
5788     # number of stack frames, or we run out - caller() returns nothing - we
5789     # quit.
5790     # Up the stack frame index to go back one more level each time.
5791     for (
5792         $i = $skip ;
5793         $i < $count
5794         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
5795         $i++
5796       )
5797     {
5798
5799         # Go through the arguments and save them for later.
5800         @a = ();
5801         for $arg (@args) {
5802             my $type;
5803             if ( not defined $arg ) {    # undefined parameter
5804                 push @a, "undef";
5805             }
5806
5807             elsif ( $nothard and tied $arg ) {    # tied parameter
5808                 push @a, "tied";
5809             }
5810             elsif ( $nothard and $type = ref $arg ) {    # reference
5811                 push @a, "ref($type)";
5812             }
5813             else {                                       # can be stringified
5814                 local $_ =
5815                   "$arg";    # Safe to stringify now - should not call f().
5816
5817                 # Backslash any single-quotes or backslashes.
5818                 s/([\'\\])/\\$1/g;
5819
5820                 # Single-quote it unless it's a number or a colon-separated
5821                 # name.
5822                 s/(.*)/'$1'/s
5823                   unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
5824
5825                 # Turn high-bit characters into meta-whatever.
5826                 s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
5827
5828                 # Turn control characters into ^-whatever.
5829                 s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
5830
5831                 push( @a, $_ );
5832             } ## end else [ if (not defined $arg)
5833         } ## end for $arg (@args)
5834
5835         # If context is true, this is array (@)context.
5836         # If context is false, this is scalar ($) context.
5837         # If neither, context isn't defined. (This is apparently a 'can't
5838         # happen' trap.)
5839         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
5840
5841         # if the sub has args ($h true), make an anonymous array of the
5842         # dumped args.
5843         $args = $h ? [@a] : undef;
5844
5845         # remove trailing newline-whitespace-semicolon-end of line sequence
5846         # from the eval text, if any.
5847         $e =~ s/\n\s*\;\s*\Z// if $e;
5848
5849         # Escape backslashed single-quotes again if necessary.
5850         $e =~ s/([\\\'])/\\$1/g if $e;
5851
5852         # if the require flag is true, the eval text is from a require.
5853         if ($r) {
5854             $sub = "require '$e'";
5855         }
5856
5857         # if it's false, the eval text is really from an eval.
5858         elsif ( defined $r ) {
5859             $sub = "eval '$e'";
5860         }
5861
5862         # If the sub is '(eval)', this is a block eval, meaning we don't
5863         # know what the eval'ed text actually was.
5864         elsif ( $sub eq '(eval)' ) {
5865             $sub = "eval {...}";
5866         }
5867
5868         # Stick the collected information into @sub as an anonymous hash.
5869         push(
5870             @sub,
5871             {
5872                 context => $context,
5873                 sub     => $sub,
5874                 args    => $args,
5875                 file    => $file,
5876                 line    => $line
5877             }
5878         );
5879
5880         # Stop processing frames if the user hit control-C.
5881         last if $signal;
5882     } ## end for ($i = $skip ; $i < ...
5883
5884     # Restore the trace value again.
5885     $trace = $otrace;
5886     @sub;
5887 } ## end sub dump_trace
5888
5889 =head2 C<action()>
5890
5891 C<action()> takes input provided as the argument to an add-action command,
5892 either pre- or post-, and makes sure it's a complete command. It doesn't do
5893 any fancy parsing; it just keeps reading input until it gets a string
5894 without a trailing backslash.
5895
5896 =cut
5897
5898 sub action {
5899     my $action = shift;
5900
5901     while ( $action =~ s/\\$// ) {
5902
5903         # We have a backslash on the end. Read more.
5904         $action .= &gets;
5905     } ## end while ($action =~ s/\\$//)
5906
5907     # Return the assembled action.
5908     $action;
5909 } ## end sub action
5910
5911 =head2 unbalanced
5912
5913 This routine mostly just packages up a regular expression to be used
5914 to check that the thing it's being matched against has properly-matched
5915 curly braces.
5916
5917 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
5918 speeds things up by only creating the qr//'ed expression once; if it's
5919 already defined, we don't try to define it again. A speed hack.
5920
5921 =cut
5922
5923 sub unbalanced {
5924
5925     # I hate using globals!
5926     $balanced_brace_re ||= qr{
5927         ^ \{
5928              (?:
5929                  (?> [^{}] + )              # Non-parens without backtracking
5930                 |
5931                  (??{ $balanced_brace_re }) # Group with matching parens
5932               ) *
5933           \} $
5934    }x;
5935     return $_[0] !~ m/$balanced_brace_re/;
5936 } ## end sub unbalanced
5937
5938 =head2 C<gets()>
5939
5940 C<gets()> is a primitive (very primitive) routine to read continuations.
5941 It was devised for reading continuations for actions.
5942 it just reads more input with C<readline()> and returns it.
5943
5944 =cut
5945
5946 sub gets {
5947     &readline("cont: ");
5948 }
5949
5950 =head2 C<DB::system()> - handle calls to<system()> without messing up the debugger
5951
5952 The C<system()> function assumes that it can just go ahead and use STDIN and
5953 STDOUT, but under the debugger, we want it to use the debugger's input and
5954 outout filehandles.
5955
5956 C<DB::system()> socks away the program's STDIN and STDOUT, and then substitutes
5957 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
5958 and then puts everything back again.
5959
5960 =cut
5961
5962 sub system {
5963
5964     # We save, change, then restore STDIN and STDOUT to avoid fork() since
5965     # some non-Unix systems can do system() but have problems with fork().
5966     open( SAVEIN,  "<&STDIN" )  || &warn("Can't save STDIN");
5967     open( SAVEOUT, ">&STDOUT" ) || &warn("Can't save STDOUT");
5968     open( STDIN,   "<&IN" )     || &warn("Can't redirect STDIN");
5969     open( STDOUT,  ">&OUT" )    || &warn("Can't redirect STDOUT");
5970
5971     # XXX: using csh or tcsh destroys sigint retvals!
5972     system(@_);
5973     open( STDIN,  "<&SAVEIN" )  || &warn("Can't restore STDIN");
5974     open( STDOUT, ">&SAVEOUT" ) || &warn("Can't restore STDOUT");
5975     close(SAVEIN);
5976     close(SAVEOUT);
5977
5978     # most of the $? crud was coping with broken cshisms
5979     if ( $? >> 8 ) {
5980         &warn( "(Command exited ", ( $? >> 8 ), ")\n" );
5981     }
5982     elsif ($?) {
5983         &warn(
5984             "(Command died of SIG#",
5985             ( $? & 127 ),
5986             ( ( $? & 128 ) ? " -- core dumped" : "" ),
5987             ")", "\n"
5988         );
5989     } ## end elsif ($?)
5990
5991     return $?;
5992
5993 } ## end sub system
5994
5995 =head1 TTY MANAGEMENT
5996
5997 The subs here do some of the terminal management for multiple debuggers.
5998
5999 =head2 setterm
6000
6001 Top-level function called when we want to set up a new terminal for use
6002 by the debugger.
6003
6004 If the C<noTTY> debugger option was set, we'll either use the terminal
6005 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6006 to find one. If we're a forked debugger, we call C<resetterm> to try to
6007 get a whole new terminal if we can.
6008
6009 In either case, we set up the terminal next. If the C<ReadLine> option was
6010 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6011 the appropriate attributes. We then
6012
6013 =cut
6014
6015 sub setterm {
6016
6017     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6018     local $frame = 0;
6019     local $doret = -2;
6020     eval { require Term::ReadLine } or die $@;
6021
6022     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6023     if ($notty) {
6024         if ($tty) {
6025             my ( $i, $o ) = split $tty, /,/;
6026             $o = $i unless defined $o;
6027             open( IN,  "<$i" ) or die "Cannot open TTY `$i' for read: $!";
6028             open( OUT, ">$o" ) or die "Cannot open TTY `$o' for write: $!";
6029             $IN  = \*IN;
6030             $OUT = \*OUT;
6031             my $sel = select($OUT);
6032             $| = 1;
6033             select($sel);
6034         } ## end if ($tty)
6035
6036         # We don't have a TTY - try to find one via Term::Rendezvous.
6037         else {
6038             eval "require Term::Rendezvous;" or die;
6039
6040             # See if we have anything to pass to Term::Rendezvous.
6041             # Use $HOME/.perldbtty$$ if not.
6042             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6043
6044             # Rendezvous and get the filehandles.
6045             my $term_rv = new Term::Rendezvous $rv;
6046             $IN  = $term_rv->IN;
6047             $OUT = $term_rv->OUT;
6048         } ## end else [ if ($tty)
6049     } ## end if ($notty)
6050
6051     # We're a daughter debugger. Try to fork off another TTY.
6052     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6053         resetterm(2);
6054     }
6055
6056     # If we shouldn't use Term::ReadLine, don't.
6057     if ( !$rl ) {
6058         $term = new Term::ReadLine::Stub 'perldb', $IN, $OUT;
6059     }
6060
6061     # We're using Term::ReadLine. Get all the attributes for this terminal.
6062     else {
6063         $term = new Term::ReadLine 'perldb', $IN, $OUT;
6064
6065         $rl_attribs = $term->Attribs;
6066         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6067           if defined $rl_attribs->{basic_word_break_characters}
6068           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6069         $rl_attribs->{special_prefixes} = '$@&%';
6070         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6071         $rl_attribs->{completion_function} = \&db_complete;
6072     } ## end else [ if (!$rl)
6073
6074     # Set up the LINEINFO filehandle.
6075     $LINEINFO = $OUT     unless defined $LINEINFO;
6076     $lineinfo = $console unless defined $lineinfo;
6077
6078     $term->MinLine(2);
6079
6080     &load_hist();
6081
6082     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6083         $term->SetHistory(@hist);
6084     }
6085
6086     # XXX Ornaments are turned on unconditionally, which is not
6087     # always a good thing.
6088     ornaments($ornaments) if defined $ornaments;
6089     $term_pid = $$;
6090 } ## end sub setterm
6091
6092 sub load_hist {
6093     $histfile //= option_val("HistFile", undef);
6094     return unless defined $histfile;
6095     open my $fh, "<", $histfile or return;
6096     local $/ = "\n";
6097     @hist = ();
6098     while (<$fh>) {
6099         chomp;
6100         push @hist, $_;
6101     }
6102     close $fh;
6103 }
6104
6105 sub save_hist {
6106     return unless defined $histfile;
6107     eval { require File::Path } or return;
6108     eval { require File::Basename } or return;
6109     File::Path::mkpath(File::Basename::dirname($histfile));
6110     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6111     $histsize //= option_val("HistSize",100);
6112     my @copy = grep { $_ ne '?' } @hist;
6113     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6114     for ($start .. $#copy) {
6115         print $fh "$copy[$_]\n";
6116     }
6117     close $fh or die "Could not write '$histfile': $!";
6118 }
6119
6120 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6121
6122 When the process being debugged forks, or the process invokes a command
6123 via C<system()> which starts a new debugger, we need to be able to get a new
6124 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6125 fight over the terminal, and you can never quite be sure who's going to get the
6126 input you're typing.
6127
6128 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6129 is tasked with doing all the necessary operating system mojo to get a new
6130 TTY (and probably another window) and to direct the new debugger to read and
6131 write there.
6132
6133 The debugger provides C<get_fork_TTY> functions which work for X Windows,
6134 OS/2, and Mac OS X. Other systems are not supported. You are encouraged
6135 to write C<get_fork_TTY> functions which work for I<your> platform
6136 and contribute them.
6137
6138 =head3 C<xterm_get_fork_TTY>
6139
6140 This function provides the C<get_fork_TTY> function for X windows. If a
6141 program running under the debugger forks, a new <xterm> window is opened and
6142 the subsidiary debugger is directed there.
6143
6144 The C<open()> call is of particular note here. We have the new C<xterm>
6145 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6146 command (which prints the device name of the TTY we'll want to use for input
6147 and output to STDOUT, then C<sleep> for a very long time, routing this output
6148 to file number 3. This way we can simply read from the <XT> filehandle (which
6149 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6150
6151 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6152 properly set up.
6153
6154 =cut
6155
6156 sub xterm_get_fork_TTY {
6157     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6158     open XT,
6159 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6160  sleep 10000000' |];
6161
6162     # Get the output from 'tty' and clean it up a little.
6163     my $tty = <XT>;
6164     chomp $tty;
6165
6166     $pidprompt = '';    # Shown anyway in titlebar
6167
6168     # We need $term defined or we can not switch to the newly created xterm
6169     if ($tty ne '' && !defined $term) {
6170         eval { require Term::ReadLine } or die $@;
6171         if ( !$rl ) {
6172             $term = new Term::ReadLine::Stub 'perldb', $IN, $OUT;
6173         }
6174         else {
6175             $term = new Term::ReadLine 'perldb', $IN, $OUT;
6176         }
6177     }
6178     # There's our new TTY.
6179     return $tty;
6180 } ## end sub xterm_get_fork_TTY
6181
6182 =head3 C<os2_get_fork_TTY>
6183
6184 XXX It behooves an OS/2 expert to write the necessary documentation for this!
6185
6186 =cut
6187
6188 # This example function resets $IN, $OUT itself
6189 my $c_pipe = 0;
6190 sub os2_get_fork_TTY { # A simplification of the following (and works without):
6191     local $\  = '';
6192     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6193     my %opt = ( title => "Daughter Perl debugger $pids $name",
6194                 ($rl ? (read_by_key => 1) : ()) );
6195     require OS2::Process;
6196     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
6197       or return;
6198     $pidprompt = '';    # Shown anyway in titlebar
6199     reset_IN_OUT($in, $out);
6200     $tty = '*reset*';
6201     return '';          # Indicate that reset_IN_OUT is called
6202 } ## end sub os2_get_fork_TTY
6203
6204 =head3 C<macosx_get_fork_TTY>
6205
6206 The Mac OS X version uses AppleScript to tell Terminal.app to create
6207 a new window.
6208
6209 =cut
6210
6211 # Notes about Terminal.app's AppleScript support,
6212 # (aka things that might break in future OS versions).
6213 #
6214 # The "do script" command doesn't return a reference to the new window
6215 # it creates, but since it appears frontmost and windows are enumerated
6216 # front to back, we can use "first window" === "window 1".
6217 #
6218 # Since "do script" is implemented by supplying the argument (plus a
6219 # return character) as terminal input, there's a potential race condition
6220 # where the debugger could beat the shell to reading the command.
6221 # To prevent this, we wait for the screen to clear before proceeding.
6222 #
6223 # 10.3 and 10.4:
6224 # There's no direct accessor for the tty device name, so we fiddle
6225 # with the window title options until it says what we want.
6226 #
6227 # 10.5:
6228 # There _is_ a direct accessor for the tty device name, _and_ there's
6229 # a new possible component of the window title (the name of the settings
6230 # set).  A separate version is needed.
6231
6232 my @script_versions=
6233
6234     ([237, <<'__LEOPARD__'],
6235 tell application "Terminal"
6236     do script "clear;exec sleep 100000"
6237     tell first tab of first window
6238         copy tty to thetty
6239         set custom title to "forked perl debugger"
6240         set title displays custom title to true
6241         repeat while (length of first paragraph of (get contents)) > 0
6242             delay 0.1
6243         end repeat
6244     end tell
6245 end tell
6246 thetty
6247 __LEOPARD__
6248
6249      [100, <<'__JAGUAR_TIGER__'],
6250 tell application "Terminal"
6251     do script "clear;exec sleep 100000"
6252     tell first window
6253         set title displays shell path to false
6254         set title displays window size to false
6255         set title displays file name to false
6256         set title displays device name to true
6257         set title displays custom title to true
6258         set custom title to ""
6259         copy "/dev/" & name to thetty
6260         set custom title to "forked perl debugger"
6261         repeat while (length of first paragraph of (get contents)) > 0
6262             delay 0.1
6263         end repeat
6264     end tell
6265 end tell
6266 thetty
6267 __JAGUAR_TIGER__
6268
6269 );
6270
6271 sub macosx_get_fork_TTY
6272 {
6273     my($version,$script,$pipe,$tty);
6274
6275     return unless $version=$ENV{TERM_PROGRAM_VERSION};
6276     foreach my $entry (@script_versions) {
6277         if ($version>=$entry->[0]) {
6278             $script=$entry->[1];
6279             last;
6280         }
6281     }
6282     return unless defined($script);
6283     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
6284     $tty=readline($pipe);
6285     close($pipe);
6286     return unless defined($tty) && $tty =~ m(^/dev/);
6287     chomp $tty;
6288     return $tty;
6289 }
6290
6291 =head2 C<create_IN_OUT($flags)>
6292
6293 Create a new pair of filehandles, pointing to a new TTY. If impossible,
6294 try to diagnose why.
6295
6296 Flags are:
6297
6298 =over 4
6299
6300 =item * 1 - Don't know how to create a new TTY.
6301
6302 =item * 2 - Debugger has forked, but we can't get a new TTY.
6303
6304 =item * 4 - standard debugger startup is happening.
6305
6306 =back
6307
6308 =cut
6309
6310 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
6311
6312     # If we know how to get a new TTY, do it! $in will have
6313     # the TTY name if get_fork_TTY works.
6314     my $in = &get_fork_TTY if defined &get_fork_TTY;
6315
6316     # It used to be that
6317     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
6318
6319     if ( not defined $in ) {
6320         my $why = shift;
6321
6322         # We don't know how.
6323         print_help(<<EOP) if $why == 1;
6324 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
6325 EOP
6326
6327         # Forked debugger.
6328         print_help(<<EOP) if $why == 2;
6329 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
6330   This may be an asynchronous session, so the parent debugger may be active.
6331 EOP
6332
6333         # Note that both debuggers are fighting over the same input.
6334         print_help(<<EOP) if $why != 4;
6335   Since two debuggers fight for the same TTY, input is severely entangled.
6336
6337 EOP
6338         print_help(<<EOP);
6339   I know how to switch the output to a different window in xterms, OS/2
6340   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
6341   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
6342   B<DB::get_fork_TTY()> returning this.
6343
6344   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
6345   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
6346
6347 EOP
6348     } ## end if (not defined $in)
6349     elsif ( $in ne '' ) {
6350         TTY($in);
6351     }
6352     else {
6353         $console = '';    # Indicate no need to open-from-the-console
6354     }
6355     undef $fork_TTY;
6356 } ## end sub create_IN_OUT
6357
6358 =head2 C<resetterm>
6359
6360 Handles rejiggering the prompt when we've forked off a new debugger.
6361
6362 If the new debugger happened because of a C<system()> that invoked a
6363 program under the debugger, the arrow between the old pid and the new
6364 in the prompt has I<two> dashes instead of one.
6365
6366 We take the current list of pids and add this one to the end. If there
6367 isn't any list yet, we make one up out of the initial pid associated with
6368 the terminal and our new pid, sticking an arrow (either one-dashed or
6369 two dashed) in between them.
6370
6371 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
6372 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
6373 and try to do that.
6374
6375 =cut
6376
6377 sub resetterm {    # We forked, so we need a different TTY
6378
6379     # Needs to be passed to create_IN_OUT() as well.
6380     my $in = shift;
6381
6382     # resetterm(2): got in here because of a system() starting a debugger.
6383     # resetterm(1): just forked.
6384     my $systemed = $in > 1 ? '-' : '';
6385
6386     # If there's already a list of pids, add this to the end.
6387     if ($pids) {
6388         $pids =~ s/\]/$systemed->$$]/;
6389     }
6390
6391     # No pid list. Time to make one.
6392     else {
6393         $pids = "[$term_pid->$$]";
6394     }
6395
6396     # The prompt we're going to be using for this debugger.
6397     $pidprompt = $pids;
6398
6399     # We now 0wnz this terminal.
6400     $term_pid = $$;
6401
6402     # Just return if we're not supposed to try to create a new TTY.
6403     return unless $CreateTTY & $in;
6404
6405     # Try to create a new IN/OUT pair.
6406     create_IN_OUT($in);
6407 } ## end sub resetterm
6408
6409 =head2 C<readline>
6410
6411 First, we handle stuff in the typeahead buffer. If there is any, we shift off
6412 the next line, print a message saying we got it, add it to the terminal
6413 history (if possible), and return it.
6414
6415 If there's nothing in the typeahead buffer, check the command filehandle stack.
6416 If there are any filehandles there, read from the last one, and return the line
6417 if we got one. If not, we pop the filehandle off and close it, and try the
6418 next one up the stack.
6419
6420 If we've emptied the filehandle stack, we check to see if we've got a socket
6421 open, and we read that and return it if we do. If we don't, we just call the
6422 core C<readline()> and return its value.
6423
6424 =cut
6425
6426 sub readline {
6427
6428     # Localize to prevent it from being smashed in the program being debugged.
6429     local $.;
6430
6431     # Pull a line out of the typeahead if there's stuff there.
6432     if (@typeahead) {
6433
6434         # How many lines left.
6435         my $left = @typeahead;
6436
6437         # Get the next line.
6438         my $got = shift @typeahead;
6439
6440         # Print a message saying we got input from the typeahead.
6441         local $\ = '';
6442         print $OUT "auto(-$left)", shift, $got, "\n";
6443
6444         # Add it to the terminal history (if possible).
6445         $term->AddHistory($got)
6446           if length($got) > 1
6447           and defined $term->Features->{addHistory};
6448         return $got;
6449     } ## end if (@typeahead)
6450
6451     # We really need to read some input. Turn off entry/exit trace and
6452     # return value printing.
6453     local $frame = 0;
6454     local $doret = -2;
6455
6456     # If there are stacked filehandles to read from ...
6457     while (@cmdfhs) {
6458
6459         # Read from the last one in the stack.
6460         my $line = CORE::readline( $cmdfhs[-1] );
6461
6462         # If we got a line ...
6463         defined $line
6464           ? ( print $OUT ">> $line" and return $line )    # Echo and return
6465           : close pop @cmdfhs;                            # Pop and close
6466     } ## end while (@cmdfhs)
6467
6468     # Nothing on the filehandle stack. Socket?
6469     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
6470
6471         # Send anyting we have to send.
6472         $OUT->write( join( '', @_ ) );
6473
6474         # Receive anything there is to receive.
6475         $stuff;
6476         my $stuff = '';
6477         my $buf;
6478         do {
6479             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
6480                                             # XXX Don't know. You tell me.
6481         } while length $buf and ($stuff .= $buf) !~ /\n/;
6482
6483         # What we got.
6484         $stuff;
6485     } ## end if (ref $OUT and UNIVERSAL::isa...
6486
6487     # No socket. Just read from the terminal.
6488     else {
6489         $term->readline(@_);
6490     }
6491 } ## end sub readline
6492
6493 =head1 OPTIONS SUPPORT ROUTINES
6494
6495 These routines handle listing and setting option values.
6496
6497 =head2 C<dump_option> - list the current value of an option setting
6498
6499 This routine uses C<option_val> to look up the value for an option.
6500 It cleans up escaped single-quotes and then displays the option and
6501 its value.
6502
6503 =cut
6504
6505 sub dump_option {
6506     my ( $opt, $val ) = @_;
6507     $val = option_val( $opt, 'N/A' );
6508     $val =~ s/([\\\'])/\\$1/g;
6509     printf $OUT "%20s = '%s'\n", $opt, $val;
6510 } ## end sub dump_option
6511
6512 sub options2remember {
6513     foreach my $k (@RememberOnROptions) {
6514         $option{$k} = option_val( $k, 'N/A' );
6515     }
6516     return %option;
6517 }
6518
6519 =head2 C<option_val> - find the current value of an option
6520
6521 This can't just be a simple hash lookup because of the indirect way that
6522 the option values are stored. Some are retrieved by calling a subroutine,
6523 some are just variables.
6524
6525 You must supply a default value to be used in case the option isn't set.
6526
6527 =cut
6528
6529 sub option_val {
6530     my ( $opt, $default ) = @_;
6531     my $val;
6532
6533     # Does this option exist, and is it a variable?
6534     # If so, retrieve the value via the value in %optionVars.
6535     if (    defined $optionVars{$opt}
6536         and defined ${ $optionVars{$opt} } )
6537     {
6538         $val = ${ $optionVars{$opt} };
6539     }
6540
6541     # Does this option exist, and it's a subroutine?
6542     # If so, call the subroutine via the ref in %optionAction
6543     # and capture the value.
6544     elsif ( defined $optionAction{$opt}
6545         and defined &{ $optionAction{$opt} } )
6546     {
6547         $val = &{ $optionAction{$opt} }();
6548     }
6549
6550     # If there's an action or variable for the supplied option,
6551     # but no value was set, use the default.
6552     elsif (defined $optionAction{$opt} and not defined $option{$opt}
6553         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
6554     {
6555         $val = $default;
6556     }
6557
6558     # Otherwise, do the simple hash lookup.
6559     else {
6560         $val = $option{$opt};
6561     }
6562
6563     # If the value isn't defined, use the default.
6564     # Then return whatever the value is.
6565     $val = $default unless defined $val;
6566     $val;
6567 } ## end sub option_val
6568
6569 =head2 C<parse_options>
6570
6571 Handles the parsing and execution of option setting/displaying commands.
6572
6573 An option entered by itself is assumed to be I<set me to 1> (the default value)
6574 if the option is a boolean one. If not, the user is prompted to enter a valid
6575 value or to query the current value (via C<option? >).
6576
6577 If C<option=value> is entered, we try to extract a quoted string from the
6578 value (if it is quoted). If it's not, we just use the whole value as-is.
6579
6580 We load any modules required to service this option, and then we set it: if
6581 it just gets stuck in a variable, we do that; if there's a subroutine to
6582 handle setting the option, we call that.
6583
6584 Finally, if we're running in interactive mode, we display the effect of the
6585 user's command back to the terminal, skipping this if we're setting things
6586 during initialization.
6587
6588 =cut
6589
6590 sub parse_options {
6591     local ($_) = @_;
6592     local $\ = '';
6593
6594     # These options need a value. Don't allow them to be clobbered by accident.
6595     my %opt_needs_val = map { ( $_ => 1 ) } qw{
6596       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
6597       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
6598     };
6599
6600     while (length) {
6601         my $val_defaulted;
6602
6603         # Clean off excess leading whitespace.
6604         s/^\s+// && next;
6605
6606         # Options are always all word characters, followed by a non-word
6607         # separator.
6608         s/^(\w+)(\W?)// or print( $OUT "Invalid option `$_'\n" ), last;
6609         my ( $opt, $sep ) = ( $1, $2 );
6610
6611         # Make sure that such an option exists.
6612         my $matches = grep( /^\Q$opt/ && ( $option = $_ ), @options )
6613           || grep( /^\Q$opt/i && ( $option = $_ ), @options );
6614
6615         print( $OUT "Unknown option `$opt'\n" ), next unless $matches;
6616         print( $OUT "Ambiguous option `$opt'\n" ), next if $matches > 1;
6617         my $val;
6618
6619         # '?' as separator means query, but must have whitespace after it.
6620         if ( "?" eq $sep ) {
6621             print( $OUT "Option query `$opt?' followed by non-space `$_'\n" ),
6622               last
6623               if /^\S/;
6624
6625             #&dump_option($opt);
6626         } ## end if ("?" eq $sep)
6627
6628         # Separator is whitespace (or just a carriage return).
6629         # They're going for a default, which we assume is 1.
6630         elsif ( $sep !~ /\S/ ) {
6631             $val_defaulted = 1;
6632             $val           = "1";   #  this is an evil default; make 'em set it!
6633         }
6634
6635         # Separator is =. Trying to set a value.
6636         elsif ( $sep eq "=" ) {
6637
6638             # If quoted, extract a quoted string.
6639             if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
6640                 my $quote = $1;
6641                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
6642             }
6643
6644             # Not quoted. Use the whole thing. Warn about 'option='.
6645             else {
6646                 s/^(\S*)//;
6647                 $val = $1;
6648                 print OUT qq(Option better cleared using $opt=""\n)
6649                   unless length $val;
6650             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
6651
6652         } ## end elsif ($sep eq "=")
6653
6654         # "Quoted" with [], <>, or {}.
6655         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
6656             my ($end) =
6657               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
6658             s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
6659               or print( $OUT "Unclosed option value `$opt$sep$_'\n" ), last;
6660             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
6661         } ## end else [ if ("?" eq $sep)
6662
6663         # Exclude non-booleans from getting set to 1 by default.
6664         if ( $opt_needs_val{$option} && $val_defaulted ) {
6665             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
6666             print $OUT
6667 "Option `$opt' is non-boolean.  Use `$cmd $option=VAL' to set, `$cmd $option?' to query\n";
6668             next;
6669         } ## end if ($opt_needs_val{$option...
6670
6671         # Save the option value.
6672         $option{$option} = $val if defined $val;
6673
6674         # Load any module that this option requires.
6675         eval qq{
6676                 local \$frame = 0;
6677                 local \$doret = -2;
6678                 require '$optionRequire{$option}';
6679                 1;
6680                } || die    # XXX: shouldn't happen
6681           if defined $optionRequire{$option}
6682           && defined $val;
6683
6684         # Set it.
6685         # Stick it in the proper variable if it goes in a variable.
6686         ${ $optionVars{$option} } = $val
6687           if defined $optionVars{$option}
6688           && defined $val;
6689
6690         # Call the appropriate sub if it gets set via sub.
6691         &{ $optionAction{$option} }($val)
6692           if defined $optionAction{$option}
6693           && defined &{ $optionAction{$option} }
6694           && defined $val;
6695
6696         # Not initialization - echo the value we set it to.
6697         dump_option($option) unless $OUT eq \*STDERR;
6698     } ## end while (length)
6699 } ## end sub parse_options
6700
6701 =head1 RESTART SUPPORT
6702
6703 These routines are used to store (and restore) lists of items in environment
6704 variables during a restart.
6705
6706 =head2 set_list
6707
6708 Set_list packages up items to be stored in a set of environment variables
6709 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
6710 the values). Values outside the standard ASCII charset are stored by encoding
6711 then as hexadecimal values.
6712
6713 =cut
6714
6715 sub set_list {
6716     my ( $stem, @list ) = @_;
6717     my $val;
6718
6719     # VAR_n: how many we have. Scalar assignment gets the number of items.
6720     $ENV{"${stem}_n"} = @list;
6721
6722     # Grab each item in the list, escape the backslashes, encode the non-ASCII
6723     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
6724     for $i ( 0 .. $#list ) {
6725         $val = $list[$i];
6726         $val =~ s/\\/\\\\/g;
6727         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
6728         $ENV{"${stem}_$i"} = $val;
6729     } ## end for $i (0 .. $#list)
6730 } ## end sub set_list
6731
6732 =head2 get_list
6733
6734 Reverse the set_list operation: grab VAR_n to see how many we should be getting
6735 back, and then pull VAR_0, VAR_1. etc. back out.
6736
6737 =cut
6738
6739 sub get_list {
6740     my $stem = shift;
6741     my @list;
6742     my $n = delete $ENV{"${stem}_n"};
6743     my $val;
6744     for $i ( 0 .. $n - 1 ) {
6745         $val = delete $ENV{"${stem}_$i"};
6746         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
6747         push @list, $val;
6748     }
6749     @list;
6750 } ## end sub get_list
6751
6752 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
6753
6754 =head2 catch()
6755
6756 The C<catch()> subroutine is the essence of fast and low-impact. We simply
6757 set an already-existing global scalar variable to a constant value. This
6758 avoids allocating any memory possibly in the middle of something that will
6759 get all confused if we do, particularly under I<unsafe signals>.
6760
6761 =cut
6762
6763 sub catch {
6764     $signal = 1;
6765     return;    # Put nothing on the stack - malloc/free land!
6766 }
6767
6768 =head2 C<warn()>
6769
6770 C<warn> emits a warning, by joining together its arguments and printing
6771 them, with couple of fillips.
6772
6773 If the composited message I<doesn't> end with a newline, we automatically
6774 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
6775 to be set to the filehandle to be used to output warnings; it makes no
6776 assumptions about what filehandles are available.
6777
6778 =cut
6779
6780 sub warn {
6781     my ($msg) = join( "", @_ );
6782     $msg .= ": $!\n" unless $msg =~ /\n$/;
6783     local $\ = '';
6784     print $OUT $msg;
6785 } ## end sub warn
6786
6787 =head1 INITIALIZATION TTY SUPPORT
6788
6789 =head2 C<reset_IN_OUT>
6790
6791 This routine handles restoring the debugger's input and output filehandles
6792 after we've tried and failed to move them elsewhere.  In addition, it assigns
6793 the debugger's output filehandle to $LINEINFO if it was already open there.
6794
6795 =cut
6796
6797 sub reset_IN_OUT {
6798     my $switch_li = $LINEINFO eq $OUT;
6799
6800     # If there's a term and it's able to get a new tty, try to get one.
6801     if ( $term and $term->Features->{newTTY} ) {
6802         ( $IN, $OUT ) = ( shift, shift );
6803         $term->newTTY( $IN, $OUT );
6804     }
6805
6806     # This term can't get a new tty now. Better luck later.
6807     elsif ($term) {
6808         &warn("Too late to set IN/OUT filehandles, enabled on next `R'!\n");
6809     }
6810
6811     # Set the filehndles up as they were.
6812     else {
6813         ( $IN, $OUT ) = ( shift, shift );
6814     }
6815
6816     # Unbuffer the output filehandle.
6817     my $o = select $OUT;
6818     $| = 1;
6819     select $o;
6820
6821     # Point LINEINFO to the same output filehandle if it was there before.
6822     $LINEINFO = $OUT if $switch_li;
6823 } ## end sub reset_IN_OUT
6824
6825 =head1 OPTION SUPPORT ROUTINES
6826
6827 The following routines are used to process some of the more complicated
6828 debugger options.
6829
6830 =head2 C<TTY>
6831
6832 Sets the input and output filehandles to the specified files or pipes.
6833 If the terminal supports switching, we go ahead and do it. If not, and
6834 there's already a terminal in place, we save the information to take effect
6835 on restart.
6836
6837 If there's no terminal yet (for instance, during debugger initialization),
6838 we go ahead and set C<$console> and C<$tty> to the file indicated.
6839
6840 =cut
6841
6842 sub TTY {
6843
6844     if ( @_ and $term and $term->Features->{newTTY} ) {
6845
6846         # This terminal supports switching to a new TTY.
6847         # Can be a list of two files, or on string containing both names,
6848         # comma-separated.
6849         # XXX Should this perhaps be an assignment from @_?
6850         my ( $in, $out ) = shift;
6851         if ( $in =~ /,/ ) {
6852
6853             # Split list apart if supplied.
6854             ( $in, $out ) = split /,/, $in, 2;
6855         }
6856         else {
6857
6858             # Use the same file for both input and output.
6859             $out = $in;
6860         }
6861
6862         # Open file onto the debugger's filehandles, if you can.
6863         open IN,  $in     or die "cannot open `$in' for read: $!";
6864         open OUT, ">$out" or die "cannot open `$out' for write: $!";
6865
6866         # Swap to the new filehandles.
6867         reset_IN_OUT( \*IN, \*OUT );
6868
6869         # Save the setting for later.
6870         return $tty = $in;
6871     } ## end if (@_ and $term and $term...
6872
6873     # Terminal doesn't support new TTY, or doesn't support readline.
6874     # Can't do it now, try restarting.
6875     &warn("Too late to set TTY, enabled on next `R'!\n") if $term and @_;
6876
6877     # Useful if done through PERLDB_OPTS:
6878     $console = $tty = shift if @_;
6879
6880     # Return whatever the TTY is.
6881     $tty or $console;
6882 } ## end sub TTY
6883
6884 =head2 C<noTTY>
6885
6886 Sets the C<$notty> global, controlling whether or not the debugger tries to
6887 get a terminal to read from. If called after a terminal is already in place,
6888 we save the value to use it if we're restarted.
6889
6890 =cut
6891
6892 sub noTTY {
6893     if ($term) {
6894         &warn("Too late to set noTTY, enabled on next `R'!\n") if @_;
6895     }
6896     $notty = shift if @_;
6897     $notty;
6898 } ## end sub noTTY
6899
6900 =head2 C<ReadLine>
6901
6902 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
6903 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
6904 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
6905 the value in case a restart is done so we can change it then.
6906
6907 =cut
6908
6909 sub ReadLine {
6910     if ($term) {
6911         &warn("Too late to set ReadLine, enabled on next `R'!\n") if @_;
6912     }
6913     $rl = shift if @_;
6914     $rl;
6915 } ## end sub ReadLine
6916
6917 =head2 C<RemotePort>
6918
6919 Sets the port that the debugger will try to connect to when starting up.
6920 If the terminal's already been set up, we can't do it, but we remember the
6921 setting in case the user does a restart.
6922
6923 =cut
6924
6925 sub RemotePort {
6926     if ($term) {
6927         &warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
6928     }
6929     $remoteport = shift if @_;
6930     $remoteport;
6931 } ## end sub RemotePort
6932
6933 =head2 C<tkRunning>
6934
6935 Checks with the terminal to see if C<Tk> is running, and returns true or
6936 false. Returns false if the current terminal doesn't support C<readline>.
6937
6938 =cut
6939
6940 sub tkRunning {
6941     if ( ${ $term->Features }{tkRunning} ) {
6942         return $term->tkRunning(@_);
6943     }
6944     else {
6945         local $\ = '';
6946         print $OUT "tkRunning not supported by current ReadLine package.\n";
6947         0;
6948     }
6949 } ## end sub tkRunning
6950
6951 =head2 C<NonStop>
6952
6953 Sets nonstop mode. If a terminal's already been set up, it's too late; the
6954 debugger remembers the setting in case you restart, though.
6955
6956 =cut
6957
6958 sub NonStop {
6959     if ($term) {
6960         &warn("Too late to set up NonStop mode, enabled on next `R'!\n")
6961           if @_;
6962     }
6963     $runnonstop = shift if @_;
6964     $runnonstop;
6965 } ## end sub NonStop
6966
6967 sub DollarCaretP {
6968     if ($term) {
6969         &warn("Some flag changes could not take effect until next 'R'!\n")
6970           if @_;
6971     }
6972     $^P = parse_DollarCaretP_flags(shift) if @_;
6973     expand_DollarCaretP_flags($^P);
6974 }
6975
6976 =head2 C<pager>
6977
6978 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
6979 there already.
6980
6981 =cut
6982
6983 sub pager {
6984     if (@_) {
6985         $pager = shift;
6986         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
6987     }
6988     $pager;
6989 } ## end sub pager
6990
6991 =head2 C<shellBang>
6992
6993 Sets the shell escape command, and generates a printable copy to be used
6994 in the help.
6995
6996 =cut
6997
6998 sub shellBang {
6999
7000     # If we got an argument, meta-quote it, and add '\b' if it
7001     # ends in a word character.
7002     if (@_) {
7003         $sh = quotemeta shift;
7004         $sh .= "\\b" if $sh =~ /\w$/;
7005     }
7006
7007     # Generate the printable version for the help:
7008     $psh = $sh;    # copy it
7009     $psh =~ s/\\b$//;        # Take off trailing \b if any
7010     $psh =~ s/\\(.)/$1/g;    # De-escape
7011     $psh;                    # return the printable version
7012 } ## end sub shellBang
7013
7014 =head2 C<ornaments>
7015
7016 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7017 was passed as the argument. (This means you can't override the terminal's
7018 ornaments.)
7019
7020 =cut
7021
7022 sub ornaments {
7023     if ( defined $term ) {
7024
7025         # We don't want to show warning backtraces, but we do want die() ones.
7026         local ( $warnLevel, $dieLevel ) = ( 0, 1 );
7027
7028         # No ornaments if the terminal doesn't support them.
7029         return '' unless $term->Features->{ornaments};
7030         eval { $term->ornaments(@_) } || '';
7031     }
7032
7033     # Use what was passed in if we can't determine it ourselves.
7034     else {
7035         $ornaments = shift;
7036     }
7037 } ## end sub ornaments
7038
7039 =head2 C<recallCommand>
7040
7041 Sets the recall command, and builds a printable version which will appear in
7042 the help text.
7043
7044 =cut
7045
7046 sub recallCommand {
7047
7048     # If there is input, metaquote it. Add '\b' if it ends with a word
7049     # character.
7050     if (@_) {
7051         $rc = quotemeta shift;
7052         $rc .= "\\b" if $rc =~ /\w$/;
7053     }
7054
7055     # Build it into a printable version.
7056     $prc = $rc;    # Copy it
7057     $prc =~ s/\\b$//;        # Remove trailing \b
7058     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7059     $prc;                    # Return the printable version
7060 } ## end sub recallCommand
7061
7062 =head2 C<LineInfo> - where the line number information goes
7063
7064 Called with no arguments, returns the file or pipe that line info should go to.
7065
7066 Called with an argument (a file or a pipe), it opens that onto the
7067 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7068 file or pipe again to the caller.
7069
7070 =cut
7071
7072 sub LineInfo {
7073     return $lineinfo unless @_;
7074     $lineinfo = shift;
7075
7076     #  If this is a valid "thing to be opened for output", tack a
7077     # '>' onto the front.
7078     my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7079
7080     # If this is a pipe, the stream points to a slave editor.
7081     $slave_editor = ( $stream =~ /^\|/ );
7082
7083     # Open it up and unbuffer it.
7084     open( LINEINFO, "$stream" ) || &warn("Cannot open `$stream' for write");
7085     $LINEINFO = \*LINEINFO;
7086     my $save = select($LINEINFO);
7087     $| = 1;
7088     select($save);
7089
7090     # Hand the file or pipe back again.
7091     $lineinfo;
7092 } ## end sub LineInfo
7093
7094 =head1 COMMAND SUPPORT ROUTINES
7095
7096 These subroutines provide functionality for various commands.
7097
7098 =head2 C<list_modules>
7099
7100 For the C<M> command: list modules loaded and their versions.
7101 Essentially just runs through the keys in %INC, picks each package's
7102 C<$VERSION> variable, gets the file name, and formats the information
7103 for output.
7104
7105 =cut
7106
7107 sub list_modules {    # versions
7108     my %version;
7109     my $file;
7110
7111     # keys are the "as-loaded" name, values are the fully-qualified path
7112     # to the file itself.
7113     for ( keys %INC ) {
7114         $file = $_;                                # get the module name
7115         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
7116         s,/,::,g;                                  # change '/' to '::'
7117         s/^perl5db$/DB/;                           # Special case: debugger
7118                                                    # moves to package DB
7119         s/^Term::ReadLine::readline$/readline/;    # simplify readline
7120
7121         # If the package has a $VERSION package global (as all good packages
7122         # should!) decode it and save as partial message.
7123         if ( defined ${ $_ . '::VERSION' } ) {
7124             $version{$file} = "${ $_ . '::VERSION' } from ";
7125         }
7126
7127         # Finish up the message with the file the package came from.
7128         $version{$file} .= $INC{$file};
7129     } ## end for (keys %INC)
7130
7131     # Hey, dumpit() formats a hash nicely, so why not use it?
7132     dumpit( $OUT, \%version );
7133 } ## end sub list_modules
7134
7135 =head2 C<sethelp()>
7136
7137 Sets up the monster string used to format and print the help.
7138
7139 =head3 HELP MESSAGE FORMAT
7140
7141 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
7142 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
7143 easy to parse and portable, but which still allows the help to be a little
7144 nicer than just plain text.
7145
7146 Essentially, you define the command name (usually marked up with C<< B<> >>
7147 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
7148 newline. The descriptive text can also be marked up in the same way. If you
7149 need to continue the descriptive text to another line, start that line with
7150 just tabs and then enter the marked-up text.
7151
7152 If you are modifying the help text, I<be careful>. The help-string parser is
7153 not very sophisticated, and if you don't follow these rules it will mangle the
7154 help beyond hope until you fix the string.
7155
7156 =cut
7157
7158 sub sethelp {
7159
7160     # XXX: make sure there are tabs between the command and explanation,
7161     #      or print_help will screw up your formatting if you have
7162     #      eeevil ornaments enabled.  This is an insane mess.
7163
7164     $help = "
7165 Help is currently only available for the new 5.8 command set.
7166 No help is available for the old command set.
7167 We assume you know what you're doing if you switch to it.
7168
7169 B<T>        Stack trace.
7170 B<s> [I<expr>]    Single step [in I<expr>].
7171 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7172 <B<CR>>        Repeat last B<n> or B<s> command.
7173 B<r>        Return from current subroutine.
7174 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7175         at the specified position.
7176 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7177 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7178 B<l> I<line>        List single I<line>.
7179 B<l> I<subname>    List first window of lines from subroutine.
7180 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7181 B<l>        List next window of lines.
7182 B<->        List previous window of lines.
7183 B<v> [I<line>]    View window around I<line>.
7184 B<.>        Return to the executed line.
7185 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7186         I<filename> may be either the full name of the file, or a regular
7187         expression matching the full file name:
7188         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7189         Evals (with saved bodies) are considered to be filenames:
7190         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7191         (in the order of execution).
7192 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7193 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7194 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
7195 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7196 B<t>        Toggle trace mode.
7197 B<t> I<expr>        Trace through execution of I<expr>.
7198 B<b>        Sets breakpoint on current line)
7199 B<b> [I<line>] [I<condition>]
7200         Set breakpoint; I<line> defaults to the current execution line;
7201         I<condition> breaks if it evaluates to true, defaults to '1'.
7202 B<b> I<subname> [I<condition>]
7203         Set breakpoint at first line of subroutine.
7204 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7205 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7206 B<b> B<postpone> I<subname> [I<condition>]
7207         Set breakpoint at first line of subroutine after
7208         it is compiled.
7209 B<b> B<compile> I<subname>
7210         Stop after the subroutine is compiled.
7211 B<B> [I<line>]    Delete the breakpoint for I<line>.
7212 B<B> I<*>             Delete all breakpoints.
7213 B<a> [I<line>] I<command>
7214         Set an action to be done before the I<line> is executed;
7215         I<line> defaults to the current execution line.
7216         Sequence is: check for breakpoint/watchpoint, print line
7217         if necessary, do action, prompt user if necessary,
7218         execute line.
7219 B<a>        Does nothing
7220 B<A> [I<line>]    Delete the action for I<line>.
7221 B<A> I<*>             Delete all actions.
7222 B<w> I<expr>        Add a global watch-expression.
7223 B<w>             Does nothing
7224 B<W> I<expr>        Delete a global watch-expression.
7225 B<W> I<*>             Delete all watch-expressions.
7226 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7227         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7228 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7229 B<x> I<expr>        Evals expression in list context, dumps the result.
7230 B<m> I<expr>        Evals expression in list context, prints methods callable
7231         on the first element of the result.
7232 B<m> I<class>        Prints methods callable via the given class.
7233 B<M>        Show versions of loaded modules.
7234 B<i> I<class>       Prints nested parents of given class.
7235 B<e>         Display current thread id.
7236 B<E>         Display all thread ids the current one will be identified: <n>.
7237 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7238
7239 B<<> ?            List Perl commands to run before each prompt.
7240 B<<> I<expr>        Define Perl command to run before each prompt.
7241 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7242 B<< *>                Delete the list of perl commands to run before each prompt.
7243 B<>> ?            List Perl commands to run after each prompt.
7244 B<>> I<expr>        Define Perl command to run after each prompt.
7245 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7246 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
7247 B<{> I<db_command>    Define debugger command to run before each prompt.
7248 B<{> ?            List debugger commands to run before each prompt.
7249 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7250 B<{ *>             Delete the list of debugger commands to run before each prompt.
7251 B<$prc> I<number>    Redo a previous command (default previous command).
7252 B<$prc> I<-number>    Redo number'th-to-last command.
7253 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7254         See 'B<O> I<recallCommand>' too.
7255 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7256       . (
7257         $rc eq $sh
7258         ? ""
7259         : "
7260 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7261       ) . "
7262         See 'B<O> I<shellBang>' too.
7263 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
7264 B<save> I<file>       Save current debugger session (actual history) to I<file>.
7265 B<rerun>           Rerun session to current position.
7266 B<rerun> I<n>         Rerun session to numbered command.
7267 B<rerun> I<-n>        Rerun session to number'th-to-last command.
7268 B<H> I<-number>    Display last number commands (default all).
7269 B<H> I<*>          Delete complete history.
7270 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7271 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7272 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7273 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7274 I<command>        Execute as a perl statement in current package.
7275 B<R>        Pure-man-restart of debugger, some of debugger state
7276         and command-line options may be lost.
7277         Currently the following settings are preserved:
7278         history, breakpoints and actions, debugger B<O>ptions
7279         and the following command-line options: I<-w>, I<-I>, I<-e>.
7280
7281 B<o> [I<opt>] ...    Set boolean option to true
7282 B<o> [I<opt>B<?>]    Query options
7283 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7284         Set options.  Use quotes if spaces in value.
7285     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7286     I<pager>            program for output of \"|cmd\";
7287     I<tkRunning>            run Tk while prompting (with ReadLine);
7288     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7289     I<inhibit_exit>        Allows stepping off the end of the script.
7290     I<ImmediateStop>        Debugger should stop as early as possible.
7291     I<RemotePort>            Remote hostname:port for remote debugging
7292   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7293     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7294     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7295     I<globPrint>             whether to print contents of globs;
7296     I<DumpDBFiles>         dump arrays holding debugged files;
7297     I<DumpPackages>         dump symbol tables of packages;
7298     I<DumpReused>             dump contents of \"reused\" addresses;
7299     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7300     I<bareStringify>         Do not print the overload-stringified value;
7301   Other options include:
7302     I<PrintRet>        affects printing of return value after B<r> command,
7303     I<frame>        affects printing messages on subroutine entry/exit.
7304     I<AutoTrace>    affects printing messages on possible breaking points.
7305     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7306     I<ornaments>     affects screen appearance of the command line.
7307     I<CreateTTY>     bits control attempts to create a new TTY on events:
7308             1: on fork()    2: debugger is started inside debugger
7309             4: on startup
7310     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7311     You can put additional initialization options I<TTY>, I<noTTY>,
7312     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7313     `B<R>' after you set them).
7314
7315 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7316 B<h>        Summary of debugger commands.
7317 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7318 B<h h>        Long help for debugger commands
7319 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7320         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7321         Set B<\$DB::doccmd> to change viewer.
7322
7323 Type `|h h' for a paged display if this was too hard to read.
7324
7325 ";    # Fix balance of vi % matching: }}}}
7326
7327     #  note: tabs in the following section are not-so-helpful
7328     $summary = <<"END_SUM";
7329 I<List/search source lines:>               I<Control script execution:>
7330   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7331   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7332   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
7333   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7334   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7335   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
7336 I<Debugger controls:>                        B<L>           List break/watch/actions
7337   B<o> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7338   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7339   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
7340   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7341   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
7342   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
7343   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
7344   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7345   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7346 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7347   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7348   B<p> I<expr>         Print expression (uses script's current package).
7349   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7350   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7351   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
7352   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7353   B<e>     Display thread id     B<E> Display all thread ids.
7354 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7355 END_SUM
7356
7357     # ')}}; # Fix balance of vi % matching
7358
7359     # and this is really numb...
7360     $pre580_help = "
7361 B<T>        Stack trace.
7362 B<s> [I<expr>]    Single step [in I<expr>].
7363 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7364 B<CR>>        Repeat last B<n> or B<s> command.
7365 B<r>        Return from current subroutine.
7366 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7367         at the specified position.
7368 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7369 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7370 B<l> I<line>        List single I<line>.
7371 B<l> I<subname>    List first window of lines from subroutine.
7372 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7373 B<l>        List next window of lines.
7374 B<->        List previous window of lines.
7375 B<w> [I<line>]    List window around I<line>.
7376 B<.>        Return to the executed line.
7377 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7378         I<filename> may be either the full name of the file, or a regular
7379         expression matching the full file name:
7380         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7381         Evals (with saved bodies) are considered to be filenames:
7382         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7383         (in the order of execution).
7384 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7385 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7386 B<L>        List all breakpoints and actions.
7387 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7388 B<t>        Toggle trace mode.
7389 B<t> I<expr>        Trace through execution of I<expr>.
7390 B<b> [I<line>] [I<condition>]
7391         Set breakpoint; I<line> defaults to the current execution line;
7392         I<condition> breaks if it evaluates to true, defaults to '1'.
7393 B<b> I<subname> [I<condition>]
7394         Set breakpoint at first line of subroutine.
7395 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7396 B<b> B<load> I<filename> Set breakpoint on `require'ing the given file.
7397 B<b> B<postpone> I<subname> [I<condition>]
7398         Set breakpoint at first line of subroutine after
7399         it is compiled.
7400 B<b> B<compile> I<subname>
7401         Stop after the subroutine is compiled.
7402 B<d> [I<line>]    Delete the breakpoint for I<line>.
7403 B<D>        Delete all breakpoints.
7404 B<a> [I<line>] I<command>
7405         Set an action to be done before the I<line> is executed;
7406         I<line> defaults to the current execution line.
7407         Sequence is: check for breakpoint/watchpoint, print line
7408         if necessary, do action, prompt user if necessary,
7409         execute line.
7410 B<a> [I<line>]    Delete the action for I<line>.
7411 B<A>        Delete all actions.
7412 B<W> I<expr>        Add a global watch-expression.
7413 B<W>        Delete all watch-expressions.
7414 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7415         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7416 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7417 B<x> I<expr>        Evals expression in list context, dumps the result.
7418 B<m> I<expr>        Evals expression in list context, prints methods callable
7419         on the first element of the result.
7420 B<m> I<class>        Prints methods callable via the given class.
7421
7422 B<<> ?            List Perl commands to run before each prompt.
7423 B<<> I<expr>        Define Perl command to run before each prompt.
7424 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7425 B<>> ?            List Perl commands to run after each prompt.
7426 B<>> I<expr>        Define Perl command to run after each prompt.
7427 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7428 B<{> I<db_command>    Define debugger command to run before each prompt.
7429 B<{> ?            List debugger commands to run before each prompt.
7430 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7431 B<$prc> I<number>    Redo a previous command (default previous command).
7432 B<$prc> I<-number>    Redo number'th-to-last command.
7433 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7434         See 'B<O> I<recallCommand>' too.
7435 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7436       . (
7437         $rc eq $sh
7438         ? ""
7439         : "
7440 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7441       ) . "
7442         See 'B<O> I<shellBang>' too.
7443 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
7444 B<H> I<-number>    Display last number commands (default all).
7445 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7446 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7447 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7448 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7449 I<command>        Execute as a perl statement in current package.
7450 B<v>        Show versions of loaded modules.
7451 B<R>        Pure-man-restart of debugger, some of debugger state
7452         and command-line options may be lost.
7453         Currently the following settings are preserved:
7454         history, breakpoints and actions, debugger B<O>ptions
7455         and the following command-line options: I<-w>, I<-I>, I<-e>.
7456
7457 B<O> [I<opt>] ...    Set boolean option to true
7458 B<O> [I<opt>B<?>]    Query options
7459 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7460         Set options.  Use quotes if spaces in value.
7461     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7462     I<pager>            program for output of \"|cmd\";
7463     I<tkRunning>            run Tk while prompting (with ReadLine);
7464     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7465     I<inhibit_exit>        Allows stepping off the end of the script.
7466     I<ImmediateStop>        Debugger should stop as early as possible.
7467     I<RemotePort>            Remote hostname:port for remote debugging
7468   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7469     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7470     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7471     I<globPrint>             whether to print contents of globs;
7472     I<DumpDBFiles>         dump arrays holding debugged files;
7473     I<DumpPackages>         dump symbol tables of packages;
7474     I<DumpReused>             dump contents of \"reused\" addresses;
7475     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7476     I<bareStringify>         Do not print the overload-stringified value;
7477   Other options include:
7478     I<PrintRet>        affects printing of return value after B<r> command,
7479     I<frame>        affects printing messages on subroutine entry/exit.
7480     I<AutoTrace>    affects printing messages on possible breaking points.
7481     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7482     I<ornaments>     affects screen appearance of the command line.
7483     I<CreateTTY>     bits control attempts to create a new TTY on events:
7484             1: on fork()    2: debugger is started inside debugger
7485             4: on startup
7486     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7487     You can put additional initialization options I<TTY>, I<noTTY>,
7488     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7489     `B<R>' after you set them).
7490
7491 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7492 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7493 B<h h>        Summary of debugger commands.
7494 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7495         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7496         Set B<\$DB::doccmd> to change viewer.
7497
7498 Type `|h' for a paged display if this was too hard to read.
7499
7500 ";    # Fix balance of vi % matching: }}}}
7501
7502     #  note: tabs in the following section are not-so-helpful
7503     $pre580_summary = <<"END_SUM";
7504 I<List/search source lines:>               I<Control script execution:>
7505   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7506   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7507   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
7508   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7509   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7510   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
7511 I<Debugger controls:>                        B<L>           List break/watch/actions
7512   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7513   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7514   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
7515   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7516   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
7517   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
7518   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7519   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7520 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7521   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7522   B<p> I<expr>         Print expression (uses script's current package).
7523   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7524   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7525   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
7526   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7527 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7528 END_SUM
7529
7530     # ')}}; # Fix balance of vi % matching
7531
7532 } ## end sub sethelp
7533
7534 =head2 C<print_help()>
7535
7536 Most of what C<print_help> does is just text formatting. It finds the
7537 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
7538 terminal control characters to simulate them (courtesy of
7539 C<Term::ReadLine::TermCap>).
7540
7541 =cut
7542
7543 sub print_help {
7544     local $_ = shift;
7545
7546     # Restore proper alignment destroyed by eeevil I<> and B<>
7547     # ornaments: A pox on both their houses!
7548     #
7549     # A help command will have everything up to and including
7550     # the first tab sequence padded into a field 16 (or if indented 20)
7551     # wide.  If it's wider than that, an extra space will be added.
7552     s{
7553         ^                       # only matters at start of line
7554           ( \040{4} | \t )*     # some subcommands are indented
7555           ( < ?                 # so <CR> works
7556             [BI] < [^\t\n] + )  # find an eeevil ornament
7557           ( \t+ )               # original separation, discarded
7558           ( .* )                # this will now start (no earlier) than
7559                                 # column 16
7560     } {
7561         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
7562         my $clean = $command;
7563         $clean =~ s/[BI]<([^>]*)>/$1/g;
7564
7565         # replace with this whole string:
7566         ($leadwhite ? " " x 4 : "")
7567       . $command
7568       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
7569       . $text;
7570
7571     }mgex;
7572
7573     s{                          # handle bold ornaments
7574        B < ( [^>] + | > ) >
7575     } {
7576           $Term::ReadLine::TermCap::rl_term_set[2]
7577         . $1
7578         . $Term::ReadLine::TermCap::rl_term_set[3]
7579     }gex;
7580
7581     s{                         # handle italic ornaments
7582        I < ( [^>] + | > ) >
7583     } {
7584           $Term::ReadLine::TermCap::rl_term_set[0]
7585         . $1
7586         . $Term::ReadLine::TermCap::rl_term_set[1]
7587     }gex;
7588
7589     local $\ = '';
7590     print $OUT $_;
7591 } ## end sub print_help
7592
7593 =head2 C<fix_less>
7594
7595 This routine does a lot of gyrations to be sure that the pager is C<less>.
7596 It checks for C<less> masquerading as C<more> and records the result in
7597 C<$ENV{LESS}> so we don't have to go through doing the stats again.
7598
7599 =cut
7600
7601 sub fix_less {
7602
7603     # We already know if this is set.
7604     return if defined $ENV{LESS} && $ENV{LESS} =~ /r/;
7605
7606     # Pager is less for sure.
7607     my $is_less = $pager =~ /\bless\b/;
7608     if ( $pager =~ /\bmore\b/ ) {
7609
7610         # Nope, set to more. See what's out there.
7611         my @st_more = stat('/usr/bin/more');
7612         my @st_less = stat('/usr/bin/less');
7613
7614         # is it really less, pretending to be more?
7615              $is_less = @st_more
7616           && @st_less
7617           && $st_more[0] == $st_less[0]
7618           && $st_more[1] == $st_less[1];
7619     } ## end if ($pager =~ /\bmore\b/)
7620
7621     # changes environment!
7622     # 'r' added so we don't do (slow) stats again.
7623     $ENV{LESS} .= 'r' if $is_less;
7624 } ## end sub fix_less
7625
7626 =head1 DIE AND WARN MANAGEMENT
7627
7628 =head2 C<diesignal>
7629
7630 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
7631 to debug a debugger problem.
7632
7633 It does its best to report the error that occurred, and then forces the
7634 program, debugger, and everything to die.
7635
7636 =cut
7637
7638 sub diesignal {
7639
7640     # No entry/exit messages.
7641     local $frame = 0;
7642
7643     # No return value prints.
7644     local $doret = -2;
7645
7646     # set the abort signal handling to the default (just terminate).
7647     $SIG{'ABRT'} = 'DEFAULT';
7648
7649     # If we enter the signal handler recursively, kill myself with an
7650     # abort signal (so we just terminate).
7651     kill 'ABRT', $$ if $panic++;
7652
7653     # If we can show detailed info, do so.
7654     if ( defined &Carp::longmess ) {
7655
7656         # Don't recursively enter the warn handler, since we're carping.
7657         local $SIG{__WARN__} = '';
7658
7659         # Skip two levels before reporting traceback: we're skipping
7660         # mydie and confess.
7661         local $Carp::CarpLevel = 2;    # mydie + confess
7662
7663         # Tell us all about it.
7664         &warn( Carp::longmess("Signal @_") );
7665     }
7666
7667     # No Carp. Tell us about the signal as best we can.
7668     else {
7669         local $\ = '';
7670         print $DB::OUT "Got signal @_\n";
7671     }
7672
7673     # Drop dead.
7674     kill 'ABRT', $$;
7675 } ## end sub diesignal
7676
7677 =head2 C<dbwarn>
7678
7679 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
7680 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
7681
7682 =cut
7683
7684 sub dbwarn {
7685
7686     # No entry/exit trace.
7687     local $frame = 0;
7688
7689     # No return value printing.
7690     local $doret = -2;
7691
7692     # Turn off warn and die handling to prevent recursive entries to this
7693     # routine.
7694     local $SIG{__WARN__} = '';
7695     local $SIG{__DIE__}  = '';
7696
7697     # Load Carp if we can. If $^S is false (current thing being compiled isn't
7698     # done yet), we may not be able to do a require.
7699     eval { require Carp }
7700       if defined $^S;    # If error/warning during compilation,
7701                          # require may be broken.
7702
7703     # Use the core warn() unless Carp loaded OK.
7704     CORE::warn( @_,
7705         "\nCannot print stack trace, load with -MCarp option to see stack" ),
7706       return
7707       unless defined &Carp::longmess;
7708
7709     # Save the current values of $single and $trace, and then turn them off.
7710     my ( $mysingle, $mytrace ) = ( $single, $trace );
7711     $single = 0;
7712     $trace  = 0;
7713
7714     # We can call Carp::longmess without its being "debugged" (which we
7715     # don't want - we just want to use it!). Capture this for later.
7716     my $mess = Carp::longmess(@_);
7717
7718     # Restore $single and $trace to their original values.
7719     ( $single, $trace ) = ( $mysingle, $mytrace );
7720
7721     # Use the debugger's own special way of printing warnings to print
7722     # the stack trace message.
7723     &warn($mess);
7724 } ## end sub dbwarn
7725
7726 =head2 C<dbdie>
7727
7728 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
7729 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
7730 single stepping and tracing during the call to C<Carp::longmess> to avoid
7731 debugging it - we just want to use it.
7732
7733 If C<dieLevel> is zero, we let the program being debugged handle the
7734 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
7735 the debugger takes over all exception handling, printing a backtrace and
7736 displaying the exception via its C<dbwarn()> routine.
7737
7738 =cut
7739
7740 sub dbdie {
7741     local $frame         = 0;
7742     local $doret         = -2;
7743     local $SIG{__DIE__}  = '';
7744     local $SIG{__WARN__} = '';
7745     my $i      = 0;
7746     my $ineval = 0;
7747     my $sub;
7748     if ( $dieLevel > 2 ) {
7749         local $SIG{__WARN__} = \&dbwarn;
7750         &warn(@_);    # Yell no matter what
7751         return;
7752     }
7753     if ( $dieLevel < 2 ) {
7754         die @_ if $^S;    # in eval propagate
7755     }
7756
7757     # The code used to check $^S to see if compiliation of the current thing
7758     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
7759     eval { require Carp };
7760
7761     die( @_,
7762         "\nCannot print stack trace, load with -MCarp option to see stack" )
7763       unless defined &Carp::longmess;
7764
7765     # We do not want to debug this chunk (automatic disabling works
7766     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
7767     # get the stack trace from Carp::longmess (if possible), restore $signal
7768     # and $trace, and then die with the stack trace.
7769     my ( $mysingle, $mytrace ) = ( $single, $trace );
7770     $single = 0;
7771     $trace  = 0;
7772     my $mess = "@_";
7773     {
7774
7775         package Carp;    # Do not include us in the list
7776         eval { $mess = Carp::longmess(@_); };
7777     }
7778     ( $single, $trace ) = ( $mysingle, $mytrace );
7779     die $mess;
7780 } ## end sub dbdie
7781
7782 =head2 C<warnlevel()>
7783
7784 Set the C<$DB::warnLevel> variable that stores the value of the
7785 C<warnLevel> option. Calling C<warnLevel()> with a positive value
7786 results in the debugger taking over all warning handlers. Setting
7787 C<warnLevel> to zero leaves any warning handlers set up by the program
7788 being debugged in place.
7789
7790 =cut
7791
7792 sub warnLevel {
7793     if (@_) {
7794         $prevwarn = $SIG{__WARN__} unless $warnLevel;
7795         $warnLevel = shift;
7796         if ($warnLevel) {
7797             $SIG{__WARN__} = \&DB::dbwarn;
7798         }
7799         elsif ($prevwarn) {
7800             $SIG{__WARN__} = $prevwarn;
7801         } else {
7802             undef $SIG{__WARN__};
7803         }
7804     } ## end if (@_)
7805     $warnLevel;
7806 } ## end sub warnLevel
7807
7808 =head2 C<dielevel>
7809
7810 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
7811 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
7812 zero lets you use your own C<die()> handler.
7813
7814 =cut
7815
7816 sub dieLevel {
7817     local $\ = '';
7818     if (@_) {
7819         $prevdie = $SIG{__DIE__} unless $dieLevel;
7820         $dieLevel = shift;
7821         if ($dieLevel) {
7822
7823             # Always set it to dbdie() for non-zero values.
7824             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
7825
7826             # No longer exists, so don't try  to use it.
7827             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
7828
7829             # If we've finished initialization, mention that stack dumps
7830             # are enabled, If dieLevel is 1, we won't stack dump if we die
7831             # in an eval().
7832             print $OUT "Stack dump during die enabled",
7833               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
7834               if $I_m_init;
7835
7836             # XXX This is probably obsolete, given that diehard() is gone.
7837             print $OUT "Dump printed too.\n" if $dieLevel > 2;
7838         } ## end if ($dieLevel)
7839
7840         # Put the old one back if there was one.
7841         elsif ($prevdie) {
7842             $SIG{__DIE__} = $prevdie;
7843             print $OUT "Default die handler restored.\n";
7844         } else {
7845             undef $SIG{__DIE__};
7846             print $OUT "Die handler removed.\n";
7847         }
7848     } ## end if (@_)
7849     $dieLevel;
7850 } ## end sub dieLevel
7851
7852 =head2 C<signalLevel>
7853
7854 Number three in a series: set C<signalLevel> to zero to keep your own
7855 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
7856 takes over and handles them with C<DB::diesignal()>.
7857
7858 =cut
7859
7860 sub signalLevel {
7861     if (@_) {
7862         $prevsegv = $SIG{SEGV} unless $signalLevel;
7863         $prevbus  = $SIG{BUS}  unless $signalLevel;
7864         $signalLevel = shift;
7865         if ($signalLevel) {
7866             $SIG{SEGV} = \&DB::diesignal;
7867             $SIG{BUS}  = \&DB::diesignal;
7868         }
7869         else {
7870             $SIG{SEGV} = $prevsegv;
7871             $SIG{BUS}  = $prevbus;
7872         }
7873     } ## end if (@_)
7874     $signalLevel;
7875 } ## end sub signalLevel
7876
7877 =head1 SUBROUTINE DECODING SUPPORT
7878
7879 These subroutines are used during the C<x> and C<X> commands to try to
7880 produce as much information as possible about a code reference. They use
7881 L<Devel::Peek> to try to find the glob in which this code reference lives
7882 (if it does) - this allows us to actually code references which correspond
7883 to named subroutines (including those aliased via glob assignment).
7884
7885 =head2 C<CvGV_name()>
7886
7887 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
7888 via that routine. If this fails, return the reference again (when the
7889 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
7890
7891 =cut
7892
7893 sub CvGV_name {
7894     my $in   = shift;
7895     my $name = CvGV_name_or_bust($in);
7896     defined $name ? $name : $in;
7897 }
7898
7899 =head2 C<CvGV_name_or_bust> I<coderef>
7900
7901 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
7902 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
7903 find a glob for this ref.
7904
7905 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
7906
7907 =cut
7908
7909 sub CvGV_name_or_bust {
7910     my $in = shift;
7911     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
7912     return unless ref $in;
7913     $in = \&$in;            # Hard reference...
7914     eval { require Devel::Peek; 1 } or return;
7915     my $gv = Devel::Peek::CvGV($in) or return;
7916     *$gv{PACKAGE} . '::' . *$gv{NAME};
7917 } ## end sub CvGV_name_or_bust
7918
7919 =head2 C<find_sub>
7920
7921 A utility routine used in various places; finds the file where a subroutine
7922 was defined, and returns that filename and a line-number range.
7923
7924 Tries to use C<@sub> first; if it can't find it there, it tries building a
7925 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
7926 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
7927 this way, it brute-force searches C<%sub>, checking for identical references.
7928
7929 =cut
7930
7931 sub find_sub {
7932     my $subr = shift;
7933     $sub{$subr} or do {
7934         return unless defined &$subr;
7935         my $name = CvGV_name_or_bust($subr);
7936         my $data;
7937         $data = $sub{$name} if defined $name;
7938         return $data if defined $data;
7939
7940         # Old stupid way...
7941         $subr = \&$subr;    # Hard reference
7942         my $s;
7943         for ( keys %sub ) {
7944             $s = $_, last if $subr eq \&$_;
7945         }
7946         $sub{$s} if $s;
7947       } ## end do
7948 } ## end sub find_sub
7949
7950 =head2 C<methods>
7951
7952 A subroutine that uses the utility function C<methods_via> to find all the
7953 methods in the class corresponding to the current reference and in
7954 C<UNIVERSAL>.
7955
7956 =cut
7957
7958 sub methods {
7959
7960     # Figure out the class - either this is the class or it's a reference
7961     # to something blessed into that class.
7962     my $class = shift;
7963     $class = ref $class if ref $class;
7964
7965     local %seen;
7966
7967     # Show the methods that this class has.
7968     methods_via( $class, '', 1 );
7969
7970     # Show the methods that UNIVERSAL has.
7971     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
7972 } ## end sub methods
7973
7974 =head2 C<methods_via($class, $prefix, $crawl_upward)>
7975
7976 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
7977 all the parent class methods. C<$class> is the name of the next class to
7978 try; C<$prefix> is the message prefix, which gets built up as we go up the
7979 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
7980 higher in the C<@ISA> tree, 0 if we should stop.
7981
7982 =cut
7983
7984 sub methods_via {
7985
7986     # If we've processed this class already, just quit.
7987     my $class = shift;
7988     return if $seen{$class}++;
7989
7990     # This is a package that is contributing the methods we're about to print.
7991     my $prefix  = shift;
7992     my $prepend = $prefix ? "via $prefix: " : '';
7993
7994     my $name;
7995     for $name (
7996
7997         # Keep if this is a defined subroutine in this class.
7998         grep { defined &{ ${"${class}::"}{$_} } }
7999
8000         # Extract from all the symbols in this class.
8001         sort keys %{"${class}::"}
8002       )
8003     {
8004
8005         # If we printed this already, skip it.
8006         next if $seen{$name}++;
8007
8008         # Print the new method name.
8009         local $\ = '';
8010         local $, = '';
8011         print $DB::OUT "$prepend$name\n";
8012     } ## end for $name (grep { defined...
8013
8014     # If the $crawl_upward argument is false, just quit here.
8015     return unless shift;
8016
8017     # $crawl_upward true: keep going up the tree.
8018     # Find all the classes this one is a subclass of.
8019     for $name ( @{"${class}::ISA"} ) {
8020
8021         # Set up the new prefix.
8022         $prepend = $prefix ? $prefix . " -> $name" : $name;
8023
8024         # Crawl up the tree and keep trying to crawl up.
8025         methods_via( $name, $prepend, 1 );
8026     }
8027 } ## end sub methods_via
8028
8029 =head2 C<setman> - figure out which command to use to show documentation
8030
8031 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8032
8033 =cut
8034
8035 sub setman {
8036     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|MacOS|NetWare)\z/s
8037       ? "man"         # O Happy Day!
8038       : "perldoc";    # Alas, poor unfortunates
8039 } ## end sub setman
8040
8041 =head2 C<runman> - run the appropriate command to show documentation
8042
8043 Accepts a man page name; runs the appropriate command to display it (set up
8044 during debugger initialization). Uses C<DB::system> to avoid mucking up the
8045 program's STDIN and STDOUT.
8046
8047 =cut
8048
8049 sub runman {
8050     my $page = shift;
8051     unless ($page) {
8052         &system("$doccmd $doccmd");
8053         return;
8054     }
8055
8056     # this way user can override, like with $doccmd="man -Mwhatever"
8057     # or even just "man " to disable the path check.
8058     unless ( $doccmd eq 'man' ) {
8059         &system("$doccmd $page");
8060         return;
8061     }
8062
8063     $page = 'perl' if lc($page) eq 'help';
8064
8065     require Config;
8066     my $man1dir = $Config::Config{'man1dir'};
8067     my $man3dir = $Config::Config{'man3dir'};
8068     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
8069     my $manpath = '';
8070     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
8071     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
8072     chop $manpath if $manpath;
8073
8074     # harmless if missing, I figure
8075     my $oldpath = $ENV{MANPATH};
8076     $ENV{MANPATH} = $manpath if $manpath;
8077     my $nopathopt = $^O =~ /dunno what goes here/;
8078     if (
8079         CORE::system(
8080             $doccmd,
8081
8082             # I just *know* there are men without -M
8083             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8084             split ' ', $page
8085         )
8086       )
8087     {
8088         unless ( $page =~ /^perl\w/ ) {
8089 # do it this way because its easier to slurp in to keep up to date - clunky though.
8090 my @pods = qw(
8091     5004delta
8092     5005delta
8093     561delta
8094     56delta
8095     570delta
8096     571delta
8097     572delta
8098     573delta
8099     58delta
8100     581delta
8101     582delta
8102     583delta
8103     584delta
8104     590delta
8105     591delta
8106     592delta
8107     aix
8108     amiga
8109     apio
8110     api
8111     apollo
8112     artistic
8113     beos
8114     book
8115     boot
8116     bot
8117     bs2000
8118     call
8119     ce
8120     cheat
8121     clib
8122     cn
8123     compile
8124     cygwin
8125     data
8126     dbmfilter
8127     debguts
8128     debtut
8129     debug
8130     delta
8131     dgux
8132     diag
8133     doc
8134     dos
8135     dsc
8136     ebcdic
8137     embed
8138     epoc
8139     faq1
8140     faq2
8141     faq3
8142     faq4
8143     faq5
8144     faq6
8145     faq7
8146     faq8
8147     faq9
8148     faq
8149     filter
8150     fork
8151     form
8152     freebsd
8153     func
8154     gpl
8155     guts
8156     hack
8157     hist
8158     hpux
8159     hurd
8160     intern
8161     intro
8162     iol
8163     ipc
8164     irix
8165     jp
8166     ko
8167     lexwarn
8168     locale
8169     lol
8170     machten
8171     macos
8172     macosx
8173     mint
8174     modinstall
8175     modlib
8176     mod
8177     modstyle
8178     mpeix
8179     netware
8180     newmod
8181     number
8182     obj
8183     opentut
8184     op
8185     os2
8186     os390
8187     os400
8188     othrtut
8189     packtut
8190     plan9
8191     pod
8192     podspec
8193     port
8194     qnx
8195     ref
8196     reftut
8197     re
8198     requick
8199     reref
8200     retut
8201     run
8202     sec
8203     solaris
8204     style
8205     sub
8206     syn
8207     thrtut
8208     tie
8209     toc
8210     todo
8211     tooc
8212     toot
8213     trap
8214     tru64
8215     tw
8216     unicode
8217     uniintro
8218     util
8219     uts
8220     var
8221     vmesa
8222     vms
8223     vos
8224     win32
8225     xs
8226     xstut
8227 );
8228             if (grep { $page eq $_ } @pods) {
8229                 $page =~ s/^/perl/;
8230                 CORE::system( $doccmd,
8231                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8232                     $page );
8233             } ## end if (grep { $page eq $_...
8234         } ## end unless ($page =~ /^perl\w/)
8235     } ## end if (CORE::system($doccmd...
8236     if ( defined $oldpath ) {
8237         $ENV{MANPATH} = $manpath;
8238     }
8239     else {
8240         delete $ENV{MANPATH};
8241     }
8242 } ## end sub runman
8243
8244 #use Carp;                          # This did break, left for debugging
8245
8246 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
8247
8248 Because of the way the debugger interface to the Perl core is designed, any
8249 debugger package globals that C<DB::sub()> requires have to be defined before
8250 any subroutines can be called. These are defined in the second C<BEGIN> block.
8251
8252 This block sets things up so that (basically) the world is sane
8253 before the debugger starts executing. We set up various variables that the
8254 debugger has to have set up before the Perl core starts running:
8255
8256 =over 4
8257
8258 =item *
8259
8260 The debugger's own filehandles (copies of STD and STDOUT for now).
8261
8262 =item *
8263
8264 Characters for shell escapes, the recall command, and the history command.
8265
8266 =item *
8267
8268 The maximum recursion depth.
8269
8270 =item *
8271
8272 The size of a C<w> command's window.
8273
8274 =item *
8275
8276 The before-this-line context to be printed in a C<v> (view a window around this line) command.
8277
8278 =item *
8279
8280 The fact that we're not in a sub at all right now.
8281
8282 =item *
8283
8284 The default SIGINT handler for the debugger.
8285
8286 =item *
8287
8288 The appropriate value of the flag in C<$^D> that says the debugger is running
8289
8290 =item *
8291
8292 The current debugger recursion level
8293
8294 =item *
8295
8296 The list of postponed items and the C<$single> stack (XXX define this)
8297
8298 =item *
8299
8300 That we want no return values and no subroutine entry/exit trace.
8301
8302 =back
8303
8304 =cut
8305
8306 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
8307
8308 BEGIN {    # This does not compile, alas. (XXX eh?)
8309     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
8310     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
8311
8312     # Define characters used by command parsing.
8313     $sh       = '!';      # Shell escape (does not work)
8314     $rc       = ',';      # Recall command (does not work)
8315     @hist     = ('?');    # Show history (does not work)
8316     @truehist = ();       # Can be saved for replay (per session)
8317
8318     # This defines the point at which you get the 'deep recursion'
8319     # warning. It MUST be defined or the debugger will not load.
8320     $deep = 100;
8321
8322     # Number of lines around the current one that are shown in the
8323     # 'w' command.
8324     $window = 10;
8325
8326     # How much before-the-current-line context the 'v' command should
8327     # use in calculating the start of the window it will display.
8328     $preview = 3;
8329
8330     # We're not in any sub yet, but we need this to be a defined value.
8331     $sub = '';
8332
8333     # Set up the debugger's interrupt handler. It simply sets a flag
8334     # ($signal) that DB::DB() will check before each command is executed.
8335     $SIG{INT} = \&DB::catch;
8336
8337     # The following lines supposedly, if uncommented, allow the debugger to
8338     # debug itself. Perhaps we can try that someday.
8339     # This may be enabled to debug debugger:
8340     #$warnLevel = 1 unless defined $warnLevel;
8341     #$dieLevel = 1 unless defined $dieLevel;
8342     #$signalLevel = 1 unless defined $signalLevel;
8343
8344     # This is the flag that says "a debugger is running, please call
8345     # DB::DB and DB::sub". We will turn it on forcibly before we try to
8346     # execute anything in the user's context, because we always want to
8347     # get control back.
8348     $db_stop = 0;          # Compiler warning ...
8349     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
8350
8351     # This variable records how many levels we're nested in debugging. Used
8352     # Used in the debugger prompt, and in determining whether it's all over or
8353     # not.
8354     $level = 0;            # Level of recursive debugging
8355
8356     # "Triggers bug (?) in perl if we postpone this until runtime."
8357     # XXX No details on this yet, or whether we should fix the bug instead
8358     # of work around it. Stay tuned.
8359     @postponed = @stack = (0);
8360
8361     # Used to track the current stack depth using the auto-stacked-variable
8362     # trick.
8363     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
8364
8365     # Don't print return values on exiting a subroutine.
8366     $doret = -2;
8367
8368     # No extry/exit tracing.
8369     $frame = 0;
8370
8371 } ## end BEGIN
8372
8373 BEGIN { $^W = $ini_warn; }    # Switch warnings back
8374
8375 =head1 READLINE SUPPORT - COMPLETION FUNCTION
8376
8377 =head2 db_complete
8378
8379 C<readline> support - adds command completion to basic C<readline>.
8380
8381 Returns a list of possible completions to C<readline> when invoked. C<readline>
8382 will print the longest common substring following the text already entered.
8383
8384 If there is only a single possible completion, C<readline> will use it in full.
8385
8386 This code uses C<map> and C<grep> heavily to create lists of possible
8387 completion. Think LISP in this section.
8388
8389 =cut
8390
8391 sub db_complete {
8392
8393     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
8394     # $text is the text to be completed.
8395     # $line is the incoming line typed by the user.
8396     # $start is the start of the text to be completed in the incoming line.
8397     my ( $text, $line, $start ) = @_;
8398
8399     # Save the initial text.
8400     # The search pattern is current package, ::, extract the next qualifier
8401     # Prefix and pack are set to undef.
8402     my ( $itext, $search, $prefix, $pack ) =
8403       ( $text, "^\Q${'package'}::\E([^:]+)\$" );
8404
8405 =head3 C<b postpone|compile>
8406
8407 =over 4
8408
8409 =item *
8410
8411 Find all the subroutines that might match in this package
8412
8413 =item *
8414
8415 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
8416
8417 =item *
8418
8419 Include all the rest of the subs that are known
8420
8421 =item *
8422
8423 C<grep> out the ones that match the text we have so far
8424
8425 =item *
8426
8427 Return this as the list of possible completions
8428
8429 =back
8430
8431 =cut
8432
8433     return sort grep /^\Q$text/, ( keys %sub ),
8434       qw(postpone load compile),    # subroutines
8435       ( map { /$search/ ? ($1) : () } keys %sub )
8436       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
8437
8438 =head3 C<b load>
8439
8440 Get all the possible files from C<@INC> as it currently stands and
8441 select the ones that match the text so far.
8442
8443 =cut
8444
8445     return sort grep /^\Q$text/, values %INC    # files
8446       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
8447
8448 =head3  C<V> (list variable) and C<m> (list modules)
8449
8450 There are two entry points for these commands:
8451
8452 =head4 Unqualified package names
8453
8454 Get the top-level packages and grab everything that matches the text
8455 so far. For each match, recursively complete the partial packages to
8456 get all possible matching packages. Return this sorted list.
8457
8458 =cut
8459
8460     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8461       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
8462       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
8463
8464 =head4 Qualified package names
8465
8466 Take a partially-qualified package and find all subpackages for it
8467 by getting all the subpackages for the package so far, matching all
8468 the subpackages against the text, and discarding all of them which
8469 start with 'main::'. Return this list.
8470
8471 =cut
8472
8473     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8474       grep !/^main::/, grep /^\Q$text/,
8475       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () } keys %{ $prefix . '::' }
8476       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
8477       and $text =~ /^(.*[^:])::?(\w*)$/
8478       and $prefix = $1;
8479
8480 =head3 C<f> - switch files
8481
8482 Here, we want to get a fully-qualified filename for the C<f> command.
8483 Possibilities are:
8484
8485 =over 4
8486
8487 =item 1. The original source file itself
8488
8489 =item 2. A file from C<@INC>
8490
8491 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
8492
8493 =back
8494
8495 =cut
8496
8497     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
8498            # We might possibly want to switch to an eval (which has a "filename"
8499            # like '(eval 9)'), so we may need to clean up the completion text
8500            # before proceeding.
8501         $prefix = length($1) - length($text);
8502         $text   = $1;
8503
8504 =pod
8505
8506 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
8507 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
8508 out of C<%main::>, add the initial source file, and extract the ones that
8509 match the completion text so far.
8510
8511 =cut
8512
8513         return sort
8514           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
8515           $0;
8516     } ## end if ($line =~ /^\|*f\s+(.*)/)
8517
8518 =head3 Subroutine name completion
8519
8520 We look through all of the defined subs (the keys of C<%sub>) and
8521 return both all the possible matches to the subroutine name plus
8522 all the matches qualified to the current package.
8523
8524 =cut
8525
8526     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
8527         $text = substr $text, 1;
8528         $prefix = "&";
8529         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
8530           (
8531             map { /$search/ ? ($1) : () }
8532               keys %sub
8533           );
8534     } ## end if ((substr $text, 0, ...
8535
8536 =head3  Scalar, array, and hash completion: partially qualified package
8537
8538 Much like the above, except we have to do a little more cleanup:
8539
8540 =cut
8541
8542     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
8543
8544 =pod
8545
8546 =over 4
8547
8548 =item *
8549
8550 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
8551
8552 =cut
8553
8554         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
8555
8556 =pod
8557
8558 =item *
8559
8560 Figure out the prefix vs. what needs completing.
8561
8562 =cut
8563
8564         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
8565         $text   = $2;
8566
8567 =pod
8568
8569 =item *
8570
8571 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
8572
8573 =cut
8574
8575         my @out = map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
8576           keys %$pack;
8577
8578 =pod
8579
8580 =item *
8581
8582 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
8583
8584 =cut
8585
8586         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8587             return db_complete( $out[0], $line, $start );
8588         }
8589
8590         # Return the list of possibles.
8591         return sort @out;
8592
8593     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
8594
8595 =pod
8596
8597 =back
8598
8599 =head3 Symbol completion: current package or package C<main>.
8600
8601 =cut
8602
8603     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
8604
8605 =pod
8606
8607 =over 4
8608
8609 =item *
8610
8611 If it's C<main>, delete main to just get C<::> leading.
8612
8613 =cut
8614
8615         $pack = ( $package eq 'main' ? '' : $package ) . '::';
8616
8617 =pod
8618
8619 =item *
8620
8621 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
8622
8623 =cut
8624
8625         $prefix = substr $text, 0, 1;
8626         $text   = substr $text, 1;
8627
8628 =pod
8629
8630 =item *
8631
8632 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
8633
8634 =cut
8635
8636         my @out = map "$prefix$_", grep /^\Q$text/,
8637           ( grep /^_?[a-zA-Z]/, keys %$pack ),
8638           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
8639
8640 =item *
8641
8642 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
8643
8644 =back
8645
8646 =cut
8647
8648         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8649             return db_complete( $out[0], $line, $start );
8650         }
8651
8652         # Return the list of possibles.
8653         return sort @out;
8654     } ## end if ($text =~ /^[\$@%]/)
8655
8656 =head3 Options
8657
8658 We use C<option_val()> to look up the current value of the option. If there's
8659 only a single value, we complete the command in such a way that it is a
8660 complete command for setting the option in question. If there are multiple
8661 possible values, we generate a command consisting of the option plus a trailing
8662 question mark, which, if executed, will list the current value of the option.
8663
8664 =cut
8665
8666     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
8667     {    # Options after space
8668            # We look for the text to be matched in the list of possible options,
8669            # and fetch the current value.
8670         my @out = grep /^\Q$text/, @options;
8671         my $val = option_val( $out[0], undef );
8672
8673         # Set up a 'query option's value' command.
8674         my $out = '? ';
8675         if ( not defined $val or $val =~ /[\n\r]/ ) {
8676
8677             # There's really nothing else we can do.
8678         }
8679
8680         # We have a value. Create a proper option-setting command.
8681         elsif ( $val =~ /\s/ ) {
8682
8683             # XXX This may be an extraneous variable.
8684             my $found;
8685
8686             # We'll want to quote the string (because of the embedded
8687             # whtespace), but we want to make sure we don't end up with
8688             # mismatched quote characters. We try several possibilities.
8689             foreach $l ( split //, qq/\"\'\#\|/ ) {
8690
8691                 # If we didn't find this quote character in the value,
8692                 # quote it using this quote character.
8693                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
8694             }
8695         } ## end elsif ($val =~ /\s/)
8696
8697         # Don't need any quotes.
8698         else {
8699             $out = "=$val ";
8700         }
8701
8702         # If there were multiple possible values, return '? ', which
8703         # makes the command into a query command. If there was just one,
8704         # have readline append that.
8705         $rl_attribs->{completer_terminator_character} =
8706           ( @out == 1 ? $out : '? ' );
8707
8708         # Return list of possibilities.
8709         return sort @out;
8710     } ## end if ((substr $line, 0, ...
8711
8712 =head3 Filename completion
8713
8714 For entering filenames. We simply call C<readline>'s C<filename_list()>
8715 method with the completion text to get the possible completions.
8716
8717 =cut
8718
8719     return $term->filename_list($text);    # filenames
8720
8721 } ## end sub db_complete
8722
8723 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
8724
8725 Functions that possibly ought to be somewhere else.
8726
8727 =head2 end_report
8728
8729 Say we're done.
8730
8731 =cut
8732
8733 sub end_report {
8734     local $\ = '';
8735     print $OUT "Use `q' to quit or `R' to restart.  `h q' for details.\n";
8736 }
8737
8738 =head2 clean_ENV
8739
8740 If we have $ini_pids, save it in the environment; else remove it from the
8741 environment. Used by the C<R> (restart) command.
8742
8743 =cut
8744
8745 sub clean_ENV {
8746     if ( defined($ini_pids) ) {
8747         $ENV{PERLDB_PIDS} = $ini_pids;
8748     }
8749     else {
8750         delete( $ENV{PERLDB_PIDS} );
8751     }
8752 } ## end sub clean_ENV
8753
8754 # PERLDBf_... flag names from perl.h
8755 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
8756
8757 BEGIN {
8758     %DollarCaretP_flags = (
8759         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
8760         PERLDBf_LINE      => 0x02,     # Keep line #
8761         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
8762         PERLDBf_INTER     => 0x08,     # Preserve more data
8763         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
8764         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
8765         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
8766         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
8767         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
8768         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
8769         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
8770         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
8771     );
8772     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
8773     # doesn't need to set it. It's provided for the benefit of profilers and
8774     # other code analysers.
8775
8776     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
8777 }
8778
8779 sub parse_DollarCaretP_flags {
8780     my $flags = shift;
8781     $flags =~ s/^\s+//;
8782     $flags =~ s/\s+$//;
8783     my $acu = 0;
8784     foreach my $f ( split /\s*\|\s*/, $flags ) {
8785         my $value;
8786         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
8787             $value = hex $1;
8788         }
8789         elsif ( $f =~ /^(\d+)$/ ) {
8790             $value = int $1;
8791         }
8792         elsif ( $f =~ /^DEFAULT$/i ) {
8793             $value = $DollarCaretP_flags{PERLDB_ALL};
8794         }
8795         else {
8796             $f =~ /^(?:PERLDBf_)?(.*)$/i;
8797             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
8798             unless ( defined $value ) {
8799                 print $OUT (
8800                     "Unrecognized \$^P flag '$f'!\n",
8801                     "Acceptable flags are: "
8802                       . join( ', ', sort keys %DollarCaretP_flags ),
8803                     ", and hexadecimal and decimal numbers.\n"
8804                 );
8805                 return undef;
8806             }
8807         }
8808         $acu |= $value;
8809     }
8810     $acu;
8811 }
8812
8813 sub expand_DollarCaretP_flags {
8814     my $DollarCaretP = shift;
8815     my @bits         = (
8816         map {
8817             my $n = ( 1 << $_ );
8818             ( $DollarCaretP & $n )
8819               ? ( $DollarCaretP_flags_r{$n}
8820                   || sprintf( '0x%x', $n ) )
8821               : ()
8822           } 0 .. 31
8823     );
8824     return @bits ? join( '|', @bits ) : 0;
8825 }
8826
8827 =over 4
8828
8829 =item rerun
8830
8831 Rerun the current session to:
8832
8833     rerun        current position
8834
8835     rerun 4      command number 4
8836
8837     rerun -4     current command minus 4 (go back 4 steps)
8838
8839 Whether this always makes sense, in the current context is unknowable, and is
8840 in part left as a useful exersize for the reader.  This sub returns the
8841 appropriate arguments to rerun the current session.
8842
8843 =cut
8844
8845 sub rerun {
8846     my $i = shift;
8847     my @args;
8848     pop(@truehist);                      # strim
8849     unless (defined $truehist[$i]) {
8850         print "Unable to return to non-existent command: $i\n";
8851     } else {
8852         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
8853         my @temp = @truehist;            # store
8854         push(@DB::typeahead, @truehist); # saved
8855         @truehist = @hist = ();          # flush
8856         @args = &restart();              # setup
8857         &get_list("PERLDB_HIST");        # clean
8858         &set_list("PERLDB_HIST", @temp); # reset
8859     }
8860     return @args;
8861 }
8862
8863 =item restart
8864
8865 Restarting the debugger is a complex operation that occurs in several phases.
8866 First, we try to reconstruct the command line that was used to invoke Perl
8867 and the debugger.
8868
8869 =cut
8870
8871 sub restart {
8872     # I may not be able to resurrect you, but here goes ...
8873     print $OUT
8874 "Warning: some settings and command-line options may be lost!\n";
8875     my ( @script, @flags, $cl );
8876
8877     # If warn was on before, turn it on again.
8878     push @flags, '-w' if $ini_warn;
8879
8880     # Rebuild the -I flags that were on the initial
8881     # command line.
8882     for (@ini_INC) {
8883         push @flags, '-I', $_;
8884     }
8885
8886     # Turn on taint if it was on before.
8887     push @flags, '-T' if ${^TAINT};
8888
8889     # Arrange for setting the old INC:
8890     # Save the current @init_INC in the environment.
8891     set_list( "PERLDB_INC", @ini_INC );
8892
8893     # If this was a perl one-liner, go to the "file"
8894     # corresponding to the one-liner read all the lines
8895     # out of it (except for the first one, which is going
8896     # to be added back on again when 'perl -d' runs: that's
8897     # the 'require perl5db.pl;' line), and add them back on
8898     # to the command line to be executed.
8899     if ( $0 eq '-e' ) {
8900         for ( 1 .. $#{'::_<-e'} ) {  # The first line is PERL5DB
8901             chomp( $cl = ${'::_<-e'}[$_] );
8902             push @script, '-e', $cl;
8903         }
8904     } ## end if ($0 eq '-e')
8905
8906     # Otherwise we just reuse the original name we had
8907     # before.
8908     else {
8909         @script = $0;
8910     }
8911
8912 =pod
8913
8914 After the command line  has been reconstructed, the next step is to save
8915 the debugger's status in environment variables. The C<DB::set_list> routine
8916 is used to save aggregate variables (both hashes and arrays); scalars are
8917 just popped into environment variables directly.
8918
8919 =cut
8920
8921     # If the terminal supported history, grab it and
8922     # save that in the environment.
8923     set_list( "PERLDB_HIST",
8924           $term->Features->{getHistory}
8925         ? $term->GetHistory
8926         : @hist );
8927
8928     # Find all the files that were visited during this
8929     # session (i.e., the debugger had magic hashes
8930     # corresponding to them) and stick them in the environment.
8931     my @had_breakpoints = keys %had_breakpoints;
8932     set_list( "PERLDB_VISITED", @had_breakpoints );
8933
8934     # Save the debugger options we chose.
8935     set_list( "PERLDB_OPT", %option );
8936     # set_list( "PERLDB_OPT", options2remember() );
8937
8938     # Save the break-on-loads.
8939     set_list( "PERLDB_ON_LOAD", %break_on_load );
8940
8941 =pod
8942
8943 The most complex part of this is the saving of all of the breakpoints. They
8944 can live in an awful lot of places, and we have to go through all of them,
8945 find the breakpoints, and then save them in the appropriate environment
8946 variable via C<DB::set_list>.
8947
8948 =cut
8949
8950     # Go through all the breakpoints and make sure they're
8951     # still valid.
8952     my @hard;
8953     for ( 0 .. $#had_breakpoints ) {
8954
8955         # We were in this file.
8956         my $file = $had_breakpoints[$_];
8957
8958         # Grab that file's magic line hash.
8959         *dbline = $main::{ '_<' . $file };
8960
8961         # Skip out if it doesn't exist, or if the breakpoint
8962         # is in a postponed file (we'll do postponed ones
8963         # later).
8964         next unless %dbline or $postponed_file{$file};
8965
8966         # In an eval. This is a little harder, so we'll
8967         # do more processing on that below.
8968         ( push @hard, $file ), next
8969           if $file =~ /^\(\w*eval/;
8970
8971         # XXX I have no idea what this is doing. Yet.
8972         my @add;
8973         @add = %{ $postponed_file{$file} }
8974           if $postponed_file{$file};
8975
8976         # Save the list of all the breakpoints for this file.
8977         set_list( "PERLDB_FILE_$_", %dbline, @add );
8978     } ## end for (0 .. $#had_breakpoints)
8979
8980     # The breakpoint was inside an eval. This is a little
8981     # more difficult. XXX and I don't understand it.
8982     for (@hard) {
8983         # Get over to the eval in question.
8984         *dbline = $main::{ '_<' . $_ };
8985         my ( $quoted, $sub, %subs, $line ) = quotemeta $_;
8986         for $sub ( keys %sub ) {
8987             next unless $sub{$sub} =~ /^$quoted:(\d+)-(\d+)$/;
8988             $subs{$sub} = [ $1, $2 ];
8989         }
8990         unless (%subs) {
8991             print $OUT
8992               "No subroutines in $_, ignoring breakpoints.\n";
8993             next;
8994         }
8995       LINES: for $line ( keys %dbline ) {
8996
8997             # One breakpoint per sub only:
8998             my ( $offset, $sub, $found );
8999           SUBS: for $sub ( keys %subs ) {
9000                 if (
9001                     $subs{$sub}->[1] >=
9002                     $line    # Not after the subroutine
9003                     and (
9004                         not defined $offset    # Not caught
9005                         or $offset < 0
9006                     )
9007                   )
9008                 {                              # or badly caught
9009                     $found  = $sub;
9010                     $offset = $line - $subs{$sub}->[0];
9011                     $offset = "+$offset", last SUBS
9012                       if $offset >= 0;
9013                 } ## end if ($subs{$sub}->[1] >=...
9014             } ## end for $sub (keys %subs)
9015             if ( defined $offset ) {
9016                 $postponed{$found} =
9017                   "break $offset if $dbline{$line}";
9018             }
9019             else {
9020                 print $OUT
9021 "Breakpoint in $_:$line ignored: after all the subroutines.\n";
9022             }
9023         } ## end for $line (keys %dbline)
9024     } ## end for (@hard)
9025
9026     # Save the other things that don't need to be
9027     # processed.
9028     set_list( "PERLDB_POSTPONE",  %postponed );
9029     set_list( "PERLDB_PRETYPE",   @$pretype );
9030     set_list( "PERLDB_PRE",       @$pre );
9031     set_list( "PERLDB_POST",      @$post );
9032     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9033
9034     # We are oficially restarting.
9035     $ENV{PERLDB_RESTART} = 1;
9036
9037     # We are junking all child debuggers.
9038     delete $ENV{PERLDB_PIDS};    # Restore ini state
9039
9040     # Set this back to the initial pid.
9041     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9042
9043 =pod
9044
9045 After all the debugger status has been saved, we take the command we built up
9046 and then return it, so we can C<exec()> it. The debugger will spot the
9047 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9048 from the environment.
9049
9050 =cut
9051
9052     # And run Perl again. Add the "-d" flag, all the
9053     # flags we built up, the script (whether a one-liner
9054     # or a file), add on the -emacs flag for a slave editor,
9055     # and then the old arguments.
9056
9057     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9058
9059 };  # end restart
9060
9061 =back
9062
9063 =head1 END PROCESSING - THE C<END> BLOCK
9064
9065 Come here at the very end of processing. We want to go into a
9066 loop where we allow the user to enter commands and interact with the
9067 debugger, but we don't want anything else to execute.
9068
9069 First we set the C<$finished> variable, so that some commands that
9070 shouldn't be run after the end of program quit working.
9071
9072 We then figure out whether we're truly done (as in the user entered a C<q>
9073 command, or we finished execution while running nonstop). If we aren't,
9074 we set C<$single> to 1 (causing the debugger to get control again).
9075
9076 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9077 message and returns control to the debugger. Repeat.
9078
9079 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9080 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9081 break, run to completion.).
9082
9083 =cut
9084
9085 END {
9086     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9087     $fall_off_end = 1 unless $inhibit_exit;
9088
9089     # Do not stop in at_exit() and destructors on exit:
9090     if ($fall_off_end or $runnonstop) {
9091         &save_hist();
9092     } else {
9093         $DB::single = 1;
9094         DB::fake::at_exit();
9095     }
9096 } ## end END
9097
9098 =head1 PRE-5.8 COMMANDS
9099
9100 Some of the commands changed function quite a bit in the 5.8 command
9101 realignment, so much so that the old code had to be replaced completely.
9102 Because we wanted to retain the option of being able to go back to the
9103 former command set, we moved the old code off to this section.
9104
9105 There's an awful lot of duplicated code here. We've duplicated the
9106 comments to keep things clear.
9107
9108 =head2 Null command
9109
9110 Does nothing. Used to I<turn off> commands.
9111
9112 =cut
9113
9114 sub cmd_pre580_null {
9115
9116     # do nothing...
9117 }
9118
9119 =head2 Old C<a> command.
9120
9121 This version added actions if you supplied them, and deleted them
9122 if you didn't.
9123
9124 =cut
9125
9126 sub cmd_pre580_a {
9127     my $xcmd = shift;
9128     my $cmd  = shift;
9129
9130     # Argument supplied. Add the action.
9131     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9132
9133         # If the line isn't there, use the current line.
9134         $i = $1 || $line;
9135         $j = $2;
9136
9137         # If there is an action ...
9138         if ( length $j ) {
9139
9140             # ... but the line isn't breakable, skip it.
9141             if ( $dbline[$i] == 0 ) {
9142                 print $OUT "Line $i may not have an action.\n";
9143             }
9144             else {
9145
9146                 # ... and the line is breakable:
9147                 # Mark that there's an action in this file.
9148                 $had_breakpoints{$filename} |= 2;
9149
9150                 # Delete any current action.
9151                 $dbline{$i} =~ s/\0[^\0]*//;
9152
9153                 # Add the new action, continuing the line as needed.
9154                 $dbline{$i} .= "\0" . action($j);
9155             }
9156         } ## end if (length $j)
9157
9158         # No action supplied.
9159         else {
9160
9161             # Delete the action.
9162             $dbline{$i} =~ s/\0[^\0]*//;
9163
9164             # Mark as having no break or action if nothing's left.
9165             delete $dbline{$i} if $dbline{$i} eq '';
9166         }
9167     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
9168 } ## end sub cmd_pre580_a
9169
9170 =head2 Old C<b> command
9171
9172 Add breakpoints.
9173
9174 =cut
9175
9176 sub cmd_pre580_b {
9177     my $xcmd   = shift;
9178     my $cmd    = shift;
9179     my $dbline = shift;
9180
9181     # Break on load.
9182     if ( $cmd =~ /^load\b\s*(.*)/ ) {
9183         my $file = $1;
9184         $file =~ s/\s+$//;
9185         &cmd_b_load($file);
9186     }
9187
9188     # b compile|postpone <some sub> [<condition>]
9189     # The interpreter actually traps this one for us; we just put the
9190     # necessary condition in the %postponed hash.
9191     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
9192
9193         # Capture the condition if there is one. Make it true if none.
9194         my $cond = length $3 ? $3 : '1';
9195
9196         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
9197         # if it was 'compile'.
9198         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
9199
9200         # De-Perl4-ify the name - ' separators to ::.
9201         $subname =~ s/\'/::/g;
9202
9203         # Qualify it into the current package unless it's already qualified.
9204         $subname = "${'package'}::" . $subname
9205           unless $subname =~ /::/;
9206
9207         # Add main if it starts with ::.
9208         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
9209
9210         # Save the break type for this sub.
9211         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
9212     } ## end elsif ($cmd =~ ...
9213
9214     # b <sub name> [<condition>]
9215     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
9216         my $subname = $1;
9217         my $cond = length $2 ? $2 : '1';
9218         &cmd_b_sub( $subname, $cond );
9219     }
9220
9221     # b <line> [<condition>].
9222     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9223         my $i = $1 || $dbline;
9224         my $cond = length $2 ? $2 : '1';
9225         &cmd_b_line( $i, $cond );
9226     }
9227 } ## end sub cmd_pre580_b
9228
9229 =head2 Old C<D> command.
9230
9231 Delete all breakpoints unconditionally.
9232
9233 =cut
9234
9235 sub cmd_pre580_D {
9236     my $xcmd = shift;
9237     my $cmd  = shift;
9238     if ( $cmd =~ /^\s*$/ ) {
9239         print $OUT "Deleting all breakpoints...\n";
9240
9241         # %had_breakpoints lists every file that had at least one
9242         # breakpoint in it.
9243         my $file;
9244         for $file ( keys %had_breakpoints ) {
9245
9246             # Switch to the desired file temporarily.
9247             local *dbline = $main::{ '_<' . $file };
9248
9249             my $max = $#dbline;
9250             my $was;
9251
9252             # For all lines in this file ...
9253             for ( $i = 1 ; $i <= $max ; $i++ ) {
9254
9255                 # If there's a breakpoint or action on this line ...
9256                 if ( defined $dbline{$i} ) {
9257
9258                     # ... remove the breakpoint.
9259                     $dbline{$i} =~ s/^[^\0]+//;
9260                     if ( $dbline{$i} =~ s/^\0?$// ) {
9261
9262                         # Remove the entry altogether if no action is there.
9263                         delete $dbline{$i};
9264                     }
9265                 } ## end if (defined $dbline{$i...
9266             } ## end for ($i = 1 ; $i <= $max...
9267
9268             # If, after we turn off the "there were breakpoints in this file"
9269             # bit, the entry in %had_breakpoints for this file is zero,
9270             # we should remove this file from the hash.
9271             if ( not $had_breakpoints{$file} &= ~1 ) {
9272                 delete $had_breakpoints{$file};
9273             }
9274         } ## end for $file (keys %had_breakpoints)
9275
9276         # Kill off all the other breakpoints that are waiting for files that
9277         # haven't been loaded yet.
9278         undef %postponed;
9279         undef %postponed_file;
9280         undef %break_on_load;
9281     } ## end if ($cmd =~ /^\s*$/)
9282 } ## end sub cmd_pre580_D
9283
9284 =head2 Old C<h> command
9285
9286 Print help. Defaults to printing the long-form help; the 5.8 version
9287 prints the summary by default.
9288
9289 =cut
9290
9291 sub cmd_pre580_h {
9292     my $xcmd = shift;
9293     my $cmd  = shift;
9294
9295     # Print the *right* help, long format.
9296     if ( $cmd =~ /^\s*$/ ) {
9297         print_help($pre580_help);
9298     }
9299
9300     # 'h h' - explicitly-requested summary.
9301     elsif ( $cmd =~ /^h\s*/ ) {
9302         print_help($pre580_summary);
9303     }
9304
9305     # Find and print a command's help.
9306     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
9307         my $asked  = $1;                   # for proper errmsg
9308         my $qasked = quotemeta($asked);    # for searching
9309                                            # XXX: finds CR but not <CR>
9310         if (
9311             $pre580_help =~ /^
9312                               <?           # Optional '<'
9313                               (?:[IB]<)    # Optional markup
9314                               $qasked      # The command name
9315                             /mx
9316           )
9317         {
9318
9319             while (
9320                 $pre580_help =~ /^
9321                                   (             # The command help:
9322                                    <?           # Optional '<'
9323                                    (?:[IB]<)    # Optional markup
9324                                    $qasked      # The command name
9325                                    ([\s\S]*?)   # Lines starting with tabs
9326                                    \n           # Final newline
9327                                   )
9328                                   (?!\s)/mgx
9329               )    # Line not starting with space
9330                    # (Next command's help)
9331             {
9332                 print_help($1);
9333             }
9334         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
9335
9336         # Help not found.
9337         else {
9338             print_help("B<$asked> is not a debugger command.\n");
9339         }
9340     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
9341 } ## end sub cmd_pre580_h
9342
9343 =head2 Old C<W> command
9344
9345 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
9346
9347 =cut
9348
9349 sub cmd_pre580_W {
9350     my $xcmd = shift;
9351     my $cmd  = shift;
9352
9353     # Delete all watch expressions.
9354     if ( $cmd =~ /^$/ ) {
9355
9356         # No watching is going on.
9357         $trace &= ~2;
9358
9359         # Kill all the watch expressions and values.
9360         @to_watch = @old_watch = ();
9361     }
9362
9363     # Add a watch expression.
9364     elsif ( $cmd =~ /^(.*)/s ) {
9365
9366         # add it to the list to be watched.
9367         push @to_watch, $1;
9368
9369         # Get the current value of the expression.
9370         # Doesn't handle expressions returning list values!
9371         $evalarg = $1;
9372         my ($val) = &eval;
9373         $val = ( defined $val ) ? "'$val'" : 'undef';
9374
9375         # Save it.
9376         push @old_watch, $val;
9377
9378         # We're watching stuff.
9379         $trace |= 2;
9380
9381     } ## end elsif ($cmd =~ /^(.*)/s)
9382 } ## end sub cmd_pre580_W
9383
9384 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
9385
9386 The debugger used to have a bunch of nearly-identical code to handle
9387 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
9388 C<cmd_prepost> unify all this into one set of code to handle the
9389 appropriate actions.
9390
9391 =head2 C<cmd_pre590_prepost>
9392
9393 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
9394 do something destructive. In pre 5.8 debuggers, the default action was to
9395 delete all the actions.
9396
9397 =cut
9398
9399 sub cmd_pre590_prepost {
9400     my $cmd    = shift;
9401     my $line   = shift || '*';
9402     my $dbline = shift;
9403
9404     return &cmd_prepost( $cmd, $line, $dbline );
9405 } ## end sub cmd_pre590_prepost
9406
9407 =head2 C<cmd_prepost>
9408
9409 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
9410 Since the lists of actions are all held in arrays that are pointed to by
9411 references anyway, all we have to do is pick the right array reference and
9412 then use generic code to all, delete, or list actions.
9413
9414 =cut
9415
9416 sub cmd_prepost {
9417     my $cmd = shift;
9418
9419     # No action supplied defaults to 'list'.
9420     my $line = shift || '?';
9421
9422     # Figure out what to put in the prompt.
9423     my $which = '';
9424
9425     # Make sure we have some array or another to address later.
9426     # This means that if ssome reason the tests fail, we won't be
9427     # trying to stash actions or delete them from the wrong place.
9428     my $aref = [];
9429
9430     # < - Perl code to run before prompt.
9431     if ( $cmd =~ /^\</o ) {
9432         $which = 'pre-perl';
9433         $aref  = $pre;
9434     }
9435
9436     # > - Perl code to run after prompt.
9437     elsif ( $cmd =~ /^\>/o ) {
9438         $which = 'post-perl';
9439         $aref  = $post;
9440     }
9441
9442     # { - first check for properly-balanced braces.
9443     elsif ( $cmd =~ /^\{/o ) {
9444         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
9445             print $OUT
9446 "$cmd is now a debugger command\nuse `;$cmd' if you mean Perl code\n";
9447         }
9448
9449         # Properly balanced. Pre-prompt debugger actions.
9450         else {
9451             $which = 'pre-debugger';
9452             $aref  = $pretype;
9453         }
9454     } ## end elsif ( $cmd =~ /^\{/o )
9455
9456     # Did we find something that makes sense?
9457     unless ($which) {
9458         print $OUT "Confused by command: $cmd\n";
9459     }
9460
9461     # Yes.
9462     else {
9463
9464         # List actions.
9465         if ( $line =~ /^\s*\?\s*$/o ) {
9466             unless (@$aref) {
9467
9468                 # Nothing there. Complain.
9469                 print $OUT "No $which actions.\n";
9470             }
9471             else {
9472
9473                 # List the actions in the selected list.
9474                 print $OUT "$which commands:\n";
9475                 foreach my $action (@$aref) {
9476                     print $OUT "\t$cmd -- $action\n";
9477                 }
9478             } ## end else
9479         } ## end if ( $line =~ /^\s*\?\s*$/o)
9480
9481         # Might be a delete.
9482         else {
9483             if ( length($cmd) == 1 ) {
9484                 if ( $line =~ /^\s*\*\s*$/o ) {
9485
9486                     # It's a delete. Get rid of the old actions in the
9487                     # selected list..
9488                     @$aref = ();
9489                     print $OUT "All $cmd actions cleared.\n";
9490                 }
9491                 else {
9492
9493                     # Replace all the actions. (This is a <, >, or {).
9494                     @$aref = action($line);
9495                 }
9496             } ## end if ( length($cmd) == 1)
9497             elsif ( length($cmd) == 2 ) {
9498
9499                 # Add the action to the line. (This is a <<, >>, or {{).
9500                 push @$aref, action($line);
9501             }
9502             else {
9503
9504                 # <<<, >>>>, {{{{{{ ... something not a command.
9505                 print $OUT
9506                   "Confused by strange length of $which command($cmd)...\n";
9507             }
9508         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
9509     } ## end else
9510 } ## end sub cmd_prepost
9511
9512 =head1 C<DB::fake>
9513
9514 Contains the C<at_exit> routine that the debugger uses to issue the
9515 C<Debugged program terminated ...> message after the program completes. See
9516 the C<END> block documentation for more details.
9517
9518 =cut
9519
9520 package DB::fake;
9521
9522 sub at_exit {
9523     "Debugged program terminated.  Use `q' to quit or `R' to restart.";
9524 }
9525
9526 package DB;    # Do not trace this 1; below!
9527
9528 1;
9529
9530