3 perlreftut - Mark's very short tutorial about references
7 One of the most important new features in Perl 5 was the capability to
8 manage complicated data structures like multidimensional arrays and
9 nested hashes. To enable these, Perl 5 introduced a feature called
10 I<references>, and using references is the key to managing complicated,
11 structured data in Perl. Unfortunately, there's a lot of funny syntax
12 to learn, and the main manual page can be hard to follow. The manual
13 is quite complete, and sometimes people find that a problem, because
14 it can be hard to tell what is important and what isn't.
16 Fortunately, you only need to know 10% of what's in the main page to get
17 90% of the benefit. This page will show you that 10%.
19 =head1 Who Needs Complicated Data Structures?
21 One problem that comes up all the time is needing a hash whose values are
22 lists. Perl has hashes, of course, but the values have to be scalars;
25 Why would you want a hash of lists? Let's take a simple example: You
26 have a file of city and country names, like this:
35 and you want to produce an output like this, with each country mentioned
36 once, and then an alphabetical list of the cities in that country:
39 Germany: Berlin, Frankfurt.
40 USA: Chicago, New York, Washington.
42 The natural way to do this is to have a hash whose keys are country
43 names. Associated with each country name key is a list of the cities in
44 that country. Each time you read a line of input, split it into a country
45 and a city, look up the list of cities already known to be in that
46 country, and append the new city to the list. When you're done reading
47 the input, iterate over the hash as usual, sorting each list of cities
48 before you print it out.
50 If hash values couldn't be lists, you lose. You'd probably have to
51 combine all the cities into a single string somehow, and then when
52 time came to write the output, you'd have to break the string into a
53 list, sort the list, and turn it back into a string. This is messy
54 and error-prone. And it's frustrating, because Perl already has
55 perfectly good lists that would solve the problem if only you could
60 By the time Perl 5 rolled around, we were already stuck with this
61 design: Hash values must be scalars. The solution to this is
64 A reference is a scalar value that I<refers to> an entire array or an
65 entire hash (or to just about anything else). Names are one kind of
66 reference that you're already familiar with. Each human being is a
67 messy, inconvenient collection of cells. But to refer to a particular
68 human, for instance the first computer programmer, it isn't necessary to
69 describe each of their cells; all you need is the easy, convenient
70 scalar string "Ada Lovelace".
72 References in Perl are like names for arrays and hashes. They're
73 Perl's private, internal names, so you can be sure they're
74 unambiguous. Unlike a human name, a reference only refers to one
75 thing, and you always know what it refers to. If you have a reference
76 to an array, you can recover the entire array from it. If you have a
77 reference to a hash, you can recover the entire hash. But the
78 reference is still an easy, compact scalar value.
80 You can't have a hash whose values are arrays; hash values can only be
81 scalars. We're stuck with that. But a single reference can refer to
82 an entire array, and references are scalars, so you can have a hash of
83 references to arrays, and it'll act a lot like a hash of arrays, and
84 it'll be just as useful as a hash of arrays.
86 We'll come back to this city-country problem later, after we've seen
87 some syntax for managing references.
92 There are just two ways to make a reference, and just two ways to use
95 =head2 Making References
99 If you put a C<\> in front of a variable, you get a
100 reference to that variable.
102 $aref = \@array; # $aref now holds a reference to @array
103 $href = \%hash; # $href now holds a reference to %hash
104 $sref = \$scalar; # $sref now holds a reference to $scalar
106 Once the reference is stored in a variable like $aref or $href, you
107 can copy it or store it just the same as any other scalar value:
109 $xy = $aref; # $xy now holds a reference to @array
110 $p[3] = $href; # $p[3] now holds a reference to %hash
111 $z = $p[3]; # $z now holds a reference to %hash
114 These examples show how to make references to variables with names.
115 Sometimes you want to make an array or a hash that doesn't have a
116 name. This is analogous to the way you like to be able to use the
117 string C<"\n"> or the number 80 without having to store it in a named
120 =head3 B<Make Rule 2>
122 C<[ ITEMS ]> makes a new, anonymous array, and returns a reference to
123 that array. C<{ ITEMS }> makes a new, anonymous hash, and returns a
124 reference to that hash.
126 $aref = [ 1, "foo", undef, 13 ];
127 # $aref now holds a reference to an array
129 $href = { APR => 4, AUG => 8 };
130 # $href now holds a reference to a hash
133 The references you get from rule 2 are the same kind of
134 references that you get from rule 1:
139 # Does the same as this:
144 The first line is an abbreviation for the following two lines, except
145 that it doesn't create the superfluous array variable C<@array>.
147 If you write just C<[]>, you get a new, empty anonymous array.
148 If you write just C<{}>, you get a new, empty anonymous hash.
151 =head2 Using References
153 What can you do with a reference once you have it? It's a scalar
154 value, and we've seen that you can store it as a scalar and get it back
155 again just like any scalar. There are just two more ways to use it:
159 You can always use an array reference, in curly braces, in place of
160 the name of an array. For example, C<@{$aref}> instead of C<@array>.
162 Here are some examples of that:
168 reverse @a reverse @{$aref} Reverse the array
169 $a[3] ${$aref}[3] An element of the array
170 $a[3] = 17; ${$aref}[3] = 17 Assigning an element
173 On each line are two expressions that do the same thing. The
174 left-hand versions operate on the array C<@a>. The right-hand
175 versions operate on the array that is referred to by C<$aref>. Once
176 they find the array they're operating on, both versions do the same
177 things to the arrays.
179 Using a hash reference is I<exactly> the same:
182 keys %h keys %{$href} Get the keys from the hash
183 $h{'red'} ${$href}{'red'} An element of the hash
184 $h{'red'} = 17 ${$href}{'red'} = 17 Assigning an element
186 Whatever you want to do with a reference, B<Use Rule 1> tells you how
187 to do it. You just write the Perl code that you would have written
188 for doing the same thing to a regular array or hash, and then replace
189 the array or hash name with C<{$reference}>. "How do I loop over an
190 array when all I have is a reference?" Well, to loop over an array, you
193 for my $element (@array) {
197 so replace the array name, C<@array>, with the reference:
199 for my $element (@{$aref}) {
203 "How do I print out the contents of a hash when all I have is a
204 reference?" First write the code for printing out a hash:
206 for my $key (keys %hash) {
207 print "$key => $hash{$key}\n";
210 And then replace the hash name with the reference:
212 for my $key (keys %{$href}) {
213 print "$key => ${$href}{$key}\n";
218 L<B<Use Rule 1>|/B<Use Rule 1>> is all you really need, because it tells
219 you how to do absolutely everything you ever need to do with references.
220 But the most common thing to do with an array or a hash is to extract a
221 single element, and the L<B<Use Rule 1>|/B<Use Rule 1>> notation is
222 cumbersome. So there is an abbreviation.
224 C<${$aref}[3]> is too hard to read, so you can write C<< $aref->[3] >>
227 C<${$href}{red}> is too hard to read, so you can write
228 C<< $href->{red} >> instead.
230 If C<$aref> holds a reference to an array, then C<< $aref->[3] >> is
231 the fourth element of the array. Don't confuse this with C<$aref[3]>,
232 which is the fourth element of a totally different array, one
233 deceptively named C<@aref>. C<$aref> and C<@aref> are unrelated the
234 same way that C<$item> and C<@item> are.
236 Similarly, C<< $href->{'red'} >> is part of the hash referred to by
237 the scalar variable C<$href>, perhaps even one with no name.
238 C<$href{'red'}> is part of the deceptively named C<%href> hash. It's
239 easy to forget to leave out the C<< -> >>, and if you do, you'll get
240 bizarre results when your program gets array and hash elements out of
241 totally unexpected hashes and arrays that weren't the ones you wanted
247 Let's see a quick example of how all this is useful.
249 First, remember that C<[1, 2, 3]> makes an anonymous array containing
250 C<(1, 2, 3)>, and gives you a reference to that array.
259 C<@a> is an array with three elements, and each one is a reference to
262 C<$a[1]> is one of these references. It refers to an array, the array
263 containing C<(4, 5, 6)>, and because it is a reference to an array,
264 L<B<Use Rule 2>|/B<Use Rule 2>> says that we can write C<< $a[1]->[2] >>
265 to get the third element from that array. C<< $a[1]->[2] >> is the 6.
266 Similarly, C<< $a[0]->[1] >> is the 2. What we have here is like a
267 two-dimensional array; you can write C<< $a[ROW]->[COLUMN] >> to get or
268 set the element in any row and any column of the array.
270 The notation still looks a little cumbersome, so there's one more
275 In between two B<subscripts>, the arrow is optional.
277 Instead of C<< $a[1]->[2] >>, we can write C<$a[1][2]>; it means the
278 same thing. Instead of C<< $a[0]->[1] = 23 >>, we can write
279 C<$a[0][1] = 23>; it means the same thing.
281 Now it really looks like two-dimensional arrays!
283 You can see why the arrows are important. Without them, we would have
284 had to write C<${$a[1]}[2]> instead of C<$a[1][2]>. For
285 three-dimensional arrays, they let us write C<$x[2][3][5]> instead of
286 the unreadable C<${${$x[2]}[3]}[5]>.
290 Here's the answer to the problem I posed earlier, of reformatting a
291 file of city and country names.
297 4 my ($city, $country) = split /, /;
298 5 $table{$country} = [] unless exists $table{$country};
299 6 push @{$table{$country}}, $city;
302 8 for my $country (sort keys %table) {
303 9 print "$country: ";
304 10 my @cities = @{$table{$country}};
305 11 print join ', ', sort @cities;
310 The program has two pieces: Lines 2-7 read the input and build a data
311 structure, and lines 8-13 analyze the data and print out the report.
312 We're going to have a hash, C<%table>, whose keys are country names,
313 and whose values are references to arrays of city names. The data
314 structure will look like this:
319 | | | +-----------+--------+
320 |Germany| *---->| Frankfurt | Berlin |
321 | | | +-----------+--------+
324 |Finland| *---->| Helsinki |
327 | | | +---------+------------+----------+
328 | USA | *---->| Chicago | Washington | New York |
329 | | | +---------+------------+----------+
332 We'll look at output first. Supposing we already have this structure,
333 how do we print it out?
335 8 for my $country (sort keys %table) {
336 9 print "$country: ";
337 10 my @cities = @{$table{$country}};
338 11 print join ', ', sort @cities;
342 C<%table> is an ordinary hash, and we get a list of keys from it, sort
343 the keys, and loop over the keys as usual. The only use of references
344 is in line 10. C<$table{$country}> looks up the key C<$country> in the
345 hash and gets the value, which is a reference to an array of cities in
346 that country. L<B<Use Rule 1>|/B<Use Rule 1>> says that we can recover
347 the array by saying C<@{$table{$country}}>. Line 10 is just like
351 except that the name C<array> has been replaced by the reference
352 C<{$table{$country}}>. The C<@> tells Perl to get the entire array.
353 Having gotten the list of cities, we sort it, join it, and print it
356 Lines 2-7 are responsible for building the structure in the first
357 place. Here they are again:
361 4 my ($city, $country) = split /, /;
362 5 $table{$country} = [] unless exists $table{$country};
363 6 push @{$table{$country}}, $city;
366 Lines 2-4 acquire a city and country name. Line 5 looks to see if the
367 country is already present as a key in the hash. If it's not, the
368 program uses the C<[]> notation (L<B<Make Rule 2>|/B<Make Rule 2>>) to
369 manufacture a new, empty anonymous array of cities, and installs a
370 reference to it into the hash under the appropriate key.
372 Line 6 installs the city name into the appropriate array.
373 C<$table{$country}> now holds a reference to the array of cities seen
374 in that country so far. Line 6 is exactly like
378 except that the name C<array> has been replaced by the reference
379 C<{$table{$country}}>. The L<C<push>|perlfunc/push ARRAY,LIST> adds a
380 city name to the end of the referred-to array.
382 There's one fine point I skipped. Line 5 is unnecessary, and we can
387 4 my ($city, $country) = split /, /;
388 5 #### $table{$country} = [] unless exists $table{$country};
389 6 push @{$table{$country}}, $city;
392 If there's already an entry in C<%table> for the current C<$country>,
393 then nothing is different. Line 6 will locate the value in
394 C<$table{$country}>, which is a reference to an array, and push C<$city>
395 into the array. But what does it do when C<$country> holds a key, say
396 C<Greece>, that is not yet in C<%table>?
398 This is Perl, so it does the exact right thing. It sees that you want
399 to push C<Athens> onto an array that doesn't exist, so it helpfully
400 makes a new, empty, anonymous array for you, installs it into
401 C<%table>, and then pushes C<Athens> onto it. This is called
402 I<autovivification>--bringing things to life automatically. Perl saw
403 that the key wasn't in the hash, so it created a new hash entry
404 automatically. Perl saw that you wanted to use the hash value as an
405 array, so it created a new empty array and installed a reference to it
406 in the hash automatically. And as usual, Perl made the array one
407 element longer to hold the new city name.
411 I promised to give you 90% of the benefit with 10% of the details, and
412 that means I left out 90% of the details. Now that you have an
413 overview of the important parts, it should be easier to read the
414 L<perlref> manual page, which discusses 100% of the details.
416 Some of the highlights of L<perlref>:
422 You can make references to anything, including scalars, functions, and
427 In L<B<Use Rule 1>|/B<Use Rule 1>>, you can omit the curly brackets
428 whenever the thing inside them is an atomic scalar variable like
429 C<$aref>. For example, C<@$aref> is the same as C<@{$aref}>, and
430 C<$$aref[1]> is the same as C<${$aref}[1]>. If you're just starting
431 out, you may want to adopt the habit of always including the curly
436 This doesn't copy the underlying array:
440 You get two references to the same array. If you modify
441 C<< $aref1->[23] >> and then look at
442 C<< $aref2->[23] >> you'll see the change.
444 To copy the array, use
446 $aref2 = [@{$aref1}];
448 This uses C<[...]> notation to create a new anonymous array, and
449 C<$aref2> is assigned a reference to the new array. The new array is
450 initialized with the contents of the array referred to by C<$aref1>.
452 Similarly, to copy an anonymous hash, you can use
454 $href2 = {%{$href1}};
458 To see if a variable contains a reference, use the
459 L<C<ref>|perlfunc/ref EXPR> function. It returns true if its argument
460 is a reference. Actually it's a little better than that: It returns
461 C<HASH> for hash references and C<ARRAY> for array references.
465 If you try to use a reference like a string, you get strings like
467 ARRAY(0x80f5dec) or HASH(0x826afc0)
469 If you ever see a string that looks like this, you'll know you
470 printed out a reference by mistake.
472 A side effect of this representation is that you can use
473 L<C<eq>|perlop/Equality Operators> to see if two references refer to the
474 same thing. (But you should usually use
475 L<C<==>|perlop/Equality Operators> instead because it's much faster.)
479 You can use a string as if it were a reference. If you use the string
480 C<"foo"> as an array reference, it's taken to be a reference to the
481 array C<@foo>. This is called a I<symbolic reference>. The declaration
482 L<C<use strict 'refs'>|strict> disables this feature, which can cause
483 all sorts of trouble if you use it by accident.
487 You might prefer to go on to L<perllol> instead of L<perlref>; it
488 discusses lists of lists and multidimensional arrays in detail. After
489 that, you should move on to L<perldsc>; it's a Data Structure Cookbook
490 that shows recipes for using and printing out arrays of hashes, hashes
491 of arrays, and other kinds of data.
495 Everyone needs compound data structures, and in Perl the way you get
496 them is with references. There are four important rules for managing
497 references: Two for making references and two for using them. Once
498 you know these rules you can do most of the important things you need
499 to do with references.
503 Author: Mark Jason Dominus, Plover Systems (C<mjd-perl-ref+@plover.com>)
505 This article originally appeared in I<The Perl Journal>
506 ( L<http://www.tpj.com/> ) volume 3, #2. Reprinted with permission.
508 The original title was I<Understand References Today>.
510 =head2 Distribution Conditions
512 Copyright 1998 The Perl Journal.
514 This documentation is free; you can redistribute it and/or modify it
515 under the same terms as Perl itself.
517 Irrespective of its distribution, all code examples in these files are
518 hereby placed into the public domain. You are permitted and
519 encouraged to use this code in your own programs for fun or for profit
520 as you see fit. A simple comment in the code giving credit would be
521 courteous but is not required.