ext/Encode/Encode.pm

   1 package Encode;
   2 use strict;
   3
   4 our $VERSION = '0.02';
   5
   6 require DynaLoader;
   7 require Exporter;
   8
   9 our @ISA = qw(Exporter DynaLoader);
  10
  11 # Public, encouraged API is exported by default
  12 our @EXPORT = qw (
  13   encode
  14   decode
  15   encode_utf8
  16   decode_utf8
  17   find_encoding
  18   encodings
  19 );
  20
  21 our @EXPORT_OK =
  22     qw(
  23        define_encoding
  24        define_alias
  25        from_to
  26        is_utf8
  27        is_8bit
  28        is_16bit
  29        utf8_upgrade
  30        utf8_downgrade
  31        _utf8_on
  32        _utf8_off
  33       );
  34
  35 bootstrap Encode ();
  36
  37 # Documentation moved after __END__ for speed - NI-S
  38
  39 use Carp;
  40
  41 # Make a %encoding package variable to allow a certain amount of cheating
  42 our %encoding;
  43 my @alias;  # ordered matching list
  44 my %alias;  # cached known aliases
  45
  46                      # 0  1  2  3  4  5   6   7   8   9  10
  47 our @latin2iso_num = ( 0, 1, 2, 3, 4, 9, 10, 13, 14, 15, 16 );
  48
  49 our %winlatin2cp   = (
  50                       'Latin1'     => 1252,
  51                       'Latin2'     => 1250,
  52                       'Cyrillic'   => 1251,
  53                       'Baltic'     => 1257,
  54                       'Greek'      => 1253,
  55                       'Turkish'    => 1254,
  56                       'Hebrew'     => 1255,
  57                       'Arabic'     => 1256,
  58                       'Baltic'     => 1257,
  59                       'Vietnamese' => 1258,
  60                      );
  61
  62 sub encodings
  63 {
  64  my ($class) = @_;
  65  return keys %encoding;
  66 }
  67
  68 sub findAlias
  69 {
  70  my $class = shift;
  71  local $_ = shift;
  72  unless (exists $alias{$_})
  73   {
  74    for (my $i=0; $i < @alias; $i += 2)
  75     {
  76      my $alias = $alias[$i];
  77      my $val   = $alias[$i+1];
  78      my $new;
  79      if (ref($alias) eq 'Regexp' && $_ =~ $alias)
  80       {
  81        $new = eval $val;
  82       }
  83      elsif (ref($alias) eq 'CODE')
  84       {
  85        $new = &{$alias}($val)
  86       }
  87      elsif (lc($_) eq lc($alias))
  88       {
  89        $new = $val;
  90       }
  91      if (defined($new))
  92       {
  93        next if $new eq $_; # avoid (direct) recursion on bugs
  94        my $enc = (ref($new)) ? $new : find_encoding($new);
  95        if ($enc)
  96         {
  97          $alias{$_} = $enc;
  98          last;
  99         }
 100       }
 101     }
 102   }
 103  return $alias{$_};
 104 }
 105
 106 sub define_alias
 107 {
 108  while (@_)
 109   {
 110    my ($alias,$name) = splice(@_,0,2);
 111    push(@alias, $alias => $name);
 112   }
 113 }
 114
 115 # Allow variants of iso-8859-1 etc.
 116 define_alias( qr/^iso[-_]?(\d+)[-_](\d+)$/i => '"iso-$1-$2"' );
 117
 118 # At least HP-UX has these.
 119 define_alias( qr/^iso8859(\d+)$/i => '"iso-8859-$1"' );
 120
 121 # More HP stuff.
 122 define_alias( qr/^(?:hp-)?(arabic|greek|hebrew|kana|roman|thai|turkish)8$/i => '"${1}8"' );
 123
 124 # This is a font issue, not an encoding issue.
 125 # (The currency symbol of the Latin 1 upper half
 126 #  has been redefined as the euro symbol.)
 127 define_alias( qr/^(.+)\@euro$/i => '"$1"' );
 128
 129 # Allow latin-1 style names as well
 130 define_alias( qr/^(?:iso[-_]?)?latin[-_]?(\d+)$/i => '"iso-8859-$latin2iso_num[$1]"' );
 131
 132 # Allow winlatin1 style names as well
 133 define_alias( qr/^win(latin[12]|cyrillic|baltic|greek|turkish|hebrew|arabic|baltic|vietnamese)$/i => '"cp$winlatin2cp{\u$1}"' );
 134
 135 # Common names for non-latin prefered MIME names
 136 define_alias( 'ascii'    => 'US-ascii',
 137               'cyrillic' => 'iso-8859-5',
 138               'arabic'   => 'iso-8859-6',
 139               'greek'    => 'iso-8859-7',
 140               'hebrew'   => 'iso-8859-8',
 141               'thai'     => 'iso-8859-11',
 142               'tis620'   => 'iso-8859-11',
 143             );
 144
 145 # At least AIX has IBM-NNN (surprisingly...) instead of cpNNN.
 146 define_alias( qr/^ibm[-_]?(\d\d\d\d?)$/i => '"cp$1"');
 147
 148 # Standardize on the dashed versions.
 149 define_alias( qr/^utf8$/i  => 'utf-8' );
 150 define_alias( qr/^koi8r$/i => 'koi8-r' );
 151 define_alias( qr/^koi8u$/i => 'koi8-u' );
 152
 153 # TODO: HP-UX '8' encodings arabic8 greek8 hebrew8 kana8 thai8 turkish8
 154 # TODO: HP-UX '15' encodings japanese15 korean15 roi15
 155 # TODO: Cyrillic encoding ISO-IR-111 (useful?)
 156 # TODO: Chinese encodings GB18030 GBK Big5-HSKCS EUC-TW
 157 # TODO: Armenian encoding ARMSCII-8
 158 # TODO: Hebrew encoding ISO-8859-8-1
 159 # TODO: Thai encoding TCVN
 160 # TODO: Korean encoding Johab
 161 # TODO: Vietnamese encodings VISCII VPS
 162 # TODO: Japanese encoding JIS (not the same as SJIS)
 163 # TODO: Mac Asian+African encodings: Arabic Armenian Bengali Burmese
 164 #       ChineseSimp ChineseTrad Devanagari Ethiopic ExtArabic
 165 #       Farsi Georgian Gujarati Gurmukhi Hebrew Japanese
 166 #       Kannada Khmer Korean Laotian Malayalam Mongolian
 167 #       Oriya Sinhalese Symbol Tamil Telugu Tibetan Vietnamese
 168 # TODO: what is the Japanese 'UJIS' encoding seen in some Linuxes?
 169
 170 # Map white space and _ to '-'
 171 define_alias( qr/^(\S+)[\s_]+(.*)$/i => '"$1-$2"' );
 172
 173 sub define_encoding
 174 {
 175  my $obj  = shift;
 176  my $name = shift;
 177  $encoding{$name} = $obj;
 178  my $lc = lc($name);
 179  define_alias($lc => $obj) unless $lc eq $name;
 180  while (@_)
 181   {
 182    my $alias = shift;
 183    define_alias($alias,$obj);
 184   }
 185  return $obj;
 186 }
 187
 188 sub getEncoding
 189 {
 190  my ($class,$name) = @_;
 191  my $enc;
 192  if (ref($name) && $name->can('new_sequence'))
 193   {
 194    return $name;
 195   }
 196  if (exists $encoding{$name})
 197   {
 198    return $encoding{$name};
 199   }
 200  else
 201   {
 202    return $class->findAlias($name);
 203   }
 204 }
 205
 206 sub find_encoding
 207 {
 208  my ($name) = @_;
 209  return __PACKAGE__->getEncoding($name);
 210 }
 211
 212 sub encode
 213 {
 214  my ($name,$string,$check) = @_;
 215  my $enc = find_encoding($name);
 216  croak("Unknown encoding '$name'") unless defined $enc;
 217  my $octets = $enc->encode($string,$check);
 218  return undef if ($check && length($string));
 219  return $octets;
 220 }
 221
 222 sub decode
 223 {
 224  my ($name,$octets,$check) = @_;
 225  my $enc = find_encoding($name);
 226  croak("Unknown encoding '$name'") unless defined $enc;
 227  my $string = $enc->decode($octets,$check);
 228  $_[1] = $octets if $check;
 229  return $string;
 230 }
 231
 232 sub from_to
 233 {
 234  my ($string,$from,$to,$check) = @_;
 235  my $f = find_encoding($from);
 236  croak("Unknown encoding '$from'") unless defined $f;
 237  my $t = find_encoding($to);
 238  croak("Unknown encoding '$to'") unless defined $t;
 239  my $uni = $f->decode($string,$check);
 240  return undef if ($check && length($string));
 241  $string = $t->encode($uni,$check);
 242  return undef if ($check && length($uni));
 243  return length($_[0] = $string);
 244 }
 245
 246 sub encode_utf8
 247 {
 248  my ($str) = @_;
 249  utf8::encode($str);
 250  return $str;
 251 }
 252
 253 sub decode_utf8
 254 {
 255  my ($str) = @_;
 256  return undef unless utf8::decode($str);
 257  return $str;
 258 }
 259
 260 package Encode::Encoding;
 261 # Base class for classes which implement encodings
 262
 263 sub Define
 264 {
 265  my $obj = shift;
 266  my $canonical = shift;
 267  $obj = bless { Name => $canonical },$obj unless ref $obj;
 268  # warn "$canonical => $obj\n";
 269  Encode::define_encoding($obj, $canonical, @_);
 270 }
 271
 272 sub name { shift->{'Name'} }
 273
 274 # Temporary legacy methods
 275 sub toUnicode    { shift->decode(@_) }
 276 sub fromUnicode  { shift->encode(@_) }
 277
 278 sub new_sequence { return $_[0] }
 279
 280 package Encode::XS;
 281 use base 'Encode::Encoding';
 282
 283 package Encode::Internal;
 284 use base 'Encode::Encoding';
 285
 286 # Dummy package that provides the encode interface but leaves data
 287 # as UTF-X encoded. It is here so that from_to() works.
 288
 289 __PACKAGE__->Define('Internal');
 290
 291 Encode::define_alias( 'Unicode' => 'Internal' ) if ord('A') == 65;
 292
 293 sub decode
 294 {
 295  my ($obj,$str,$chk) = @_;
 296  utf8::upgrade($str);
 297  $_[1] = '' if $chk;
 298  return $str;
 299 }
 300
 301 *encode = \&decode;
 302
 303 package Encoding::Unicode;
 304 use base 'Encode::Encoding';
 305
 306 __PACKAGE__->Define('Unicode') unless ord('A') == 65;
 307
 308 sub decode
 309 {
 310  my ($obj,$str,$chk) = @_;
 311  my $res = '';
 312  for (my $i = 0; $i < length($str); $i++)
 313   {
 314    $res .= chr(utf8::unicode_to_native(ord(substr($str,$i,1))));
 315   }
 316  $_[1] = '' if $chk;
 317  return $res;
 318 }
 319
 320 sub encode
 321 {
 322  my ($obj,$str,$chk) = @_;
 323  my $res = '';
 324  for (my $i = 0; $i < length($str); $i++)
 325   {
 326    $res .= chr(utf8::native_to_unicode(ord(substr($str,$i,1))));
 327   }
 328  $_[1] = '' if $chk;
 329  return $res;
 330 }
 331
 332
 333 package Encode::utf8;
 334 use base 'Encode::Encoding';
 335 # package to allow long-hand
 336 #   $octets = encode( utf8 => $string );
 337 #
 338
 339 __PACKAGE__->Define(qw(UTF-8 utf8));
 340
 341 sub decode
 342 {
 343  my ($obj,$octets,$chk) = @_;
 344  my $str = Encode::decode_utf8($octets);
 345  if (defined $str)
 346   {
 347    $_[1] = '' if $chk;
 348    return $str;
 349   }
 350  return undef;
 351 }
 352
 353 sub encode
 354 {
 355  my ($obj,$string,$chk) = @_;
 356  my $octets = Encode::encode_utf8($string);
 357  $_[1] = '' if $chk;
 358  return $octets;
 359 }
 360
 361 package Encode::iso10646_1;
 362 use base 'Encode::Encoding';
 363 # Encoding is 16-bit network order Unicode (no surogates)
 364 # Used for X font encodings
 365
 366 __PACKAGE__->Define(qw(UCS-2 iso-10646-1));
 367
 368 sub decode
 369 {
 370  my ($obj,$str,$chk) = @_;
 371  my $uni   = '';
 372  while (length($str))
 373   {
 374    my $code = unpack('n',substr($str,0,2,'')) & 0xffff;
 375    $uni .= chr($code);
 376   }
 377  $_[1] = $str if $chk;
 378  utf8::upgrade($uni);
 379  return $uni;
 380 }
 381
 382 sub encode
 383 {
 384  my ($obj,$uni,$chk) = @_;
 385  my $str   = '';
 386  while (length($uni))
 387   {
 388    my $ch = substr($uni,0,1,'');
 389    my $x  = ord($ch);
 390    unless ($x < 32768)
 391     {
 392      last if ($chk);
 393      $x = 0;
 394     }
 395    $str .= pack('n',$x);
 396   }
 397  $_[1] = $uni if $chk;
 398  return $str;
 399 }
 400
 401 package Encode::ucs_2le;
 402 use base 'Encode::Encoding';
 403
 404 __PACKAGE__->Define(qw(UCS-2le UCS-2LE ucs-2le));
 405
 406 sub decode
 407 {
 408  my ($obj,$str,$chk) = @_;
 409  my $uni   = '';
 410  while (length($str))
 411  {
 412   my $code = unpack('v',substr($str,0,2,'')) & 0xffff;
 413   $uni .= chr($code);
 414  }
 415  $_[1] = $str if $chk;
 416  utf8::upgrade($uni);
 417  return $uni;
 418 }
 419
 420 sub encode
 421 {
 422  my ($obj,$uni,$chk) = @_;
 423  my $str   = '';
 424  while (length($uni))
 425  {
 426   my $ch = substr($uni,0,1,'');
 427   my $x  = ord($ch);
 428   unless ($x < 32768)
 429   {
 430    last if ($chk);
 431    $x = 0;
 432   }
 433   $str .= pack('v',$x);
 434  }
 435  $_[1] = $uni if $chk;
 436  return $str;
 437 }
 438
 439 # switch back to Encode package in case we ever add AutoLoader
 440 package Encode;
 441
 442 1;
 443
 444 __END__
 445
 446 =head1 NAME
 447
 448 Encode - character encodings
 449
 450 =head1 SYNOPSIS
 451
 452     use Encode;
 453
 454 =head1 DESCRIPTION
 455
 456 The C<Encode> module provides the interfaces between Perl's strings
 457 and the rest of the system.  Perl strings are sequences of B<characters>.
 458
 459 The repertoire of characters that Perl can represent is at least that
 460 defined by the Unicode Consortium. On most platforms the ordinal
 461 values of the characters (as returned by C<ord(ch)>) is the "Unicode
 462 codepoint" for the character (the exceptions are those platforms where
 463 the legacy encoding is some variant of EBCDIC rather than a super-set
 464 of ASCII - see L<perlebcdic>).
 465
 466 Traditionaly computer data has been moved around in 8-bit chunks
 467 often called "bytes". These chunks are also known as "octets" in
 468 networking standards. Perl is widely used to manipulate data of
 469 many types - not only strings of characters representing human or
 470 computer languages but also "binary" data being the machines representation
 471 of numbers, pixels in an image - or just about anything.
 472
 473 When Perl is processing "binary data" the programmer wants Perl to process
 474 "sequences of bytes". This is not a problem for Perl - as a byte has 256
 475 possible values it easily fits in Perl's much larger "logical character".
 476
 477 =head2 TERMINOLOGY
 478
 479 =over 4
 480
 481 =item *
 482
 483 I<character>: a character in the range 0..(2**32-1) (or more).
 484 (What Perl's strings are made of.)
 485
 486 =item *
 487
 488 I<byte>: a character in the range 0..255
 489 (A special case of a Perl character.)
 490
 491 =item *
 492
 493 I<octet>: 8 bits of data, with ordinal values 0..255
 494 (Term for bytes passed to or from a non-Perl context, e.g. disk file.)
 495
 496 =back
 497
 498 The marker [INTERNAL] marks Internal Implementation Details, in
 499 general meant only for those who think they know what they are doing,
 500 and such details may change in future releases.
 501
 502 =head1 ENCODINGS
 503
 504 =head2 Characteristics of an Encoding
 505
 506 An encoding has a "repertoire" of characters that it can represent,
 507 and for each representable character there is at least one sequence of
 508 octets that represents it.
 509
 510 =head2 Types of Encodings
 511
 512 Encodings can be divided into the following types:
 513
 514 =over 4
 515
 516 =item * Fixed length 8-bit (or less) encodings.
 517
 518 Each character is a single octet so may have a repertoire of up to
 519 256 characters. ASCII and iso-8859-* are typical examples.
 520
 521 =item * Fixed length 16-bit encodings
 522
 523 Each character is two octets so may have a repertoire of up to
 524 65 536 characters.  Unicode's UCS-2 is an example.  Also used for
 525 encodings for East Asian languages.
 526
 527 =item * Fixed length 32-bit encodings.
 528
 529 Not really very "encoded" encodings. The Unicode code points
 530 are just represented as 4-octet integers. None the less because
 531 different architectures use different representations of integers
 532 (so called "endian") there at least two disctinct encodings.
 533
 534 =item * Multi-byte encodings
 535
 536 The number of octets needed to represent a character varies.
 537 UTF-8 is a particularly complex but regular case of a multi-byte
 538 encoding. Several East Asian countries use a multi-byte encoding
 539 where 1-octet is used to cover western roman characters and Asian
 540 characters get 2-octets.
 541 (UTF-16 is strictly a multi-byte encoding taking either 2 or 4 octets
 542 to represent a Unicode code point.)
 543
 544 =item * "Escape" encodings.
 545
 546 These encodings embed "escape sequences" into the octet sequence
 547 which describe how the following octets are to be interpreted.
 548 The iso-2022-* family is typical. Following the escape sequence
 549 octets are encoded by an "embedded" encoding (which will be one
 550 of the above types) until another escape sequence switches to
 551 a different "embedded" encoding.
 552
 553 These schemes are very flexible and can handle mixed languages but are
 554 very complex to process (and have state).  No escape encodings are
 555 implemented for Perl yet.
 556
 557 =back
 558
 559 =head2 Specifying Encodings
 560
 561 Encodings can be specified to the API described below in two ways:
 562
 563 =over 4
 564
 565 =item 1. By name
 566
 567 Encoding names are strings with characters taken from a restricted
 568 repertoire.  See L</"Encoding Names">.
 569
 570 =item 2. As an object
 571
 572 Encoding objects are returned by C<find_encoding($name)>.
 573
 574 =back
 575
 576 =head2 Encoding Names
 577
 578 Encoding names are case insensitive. White space in names is ignored.
 579 In addition an encoding may have aliases. Each encoding has one
 580 "canonical" name.  The "canonical" name is chosen from the names of
 581 the encoding by picking the first in the following sequence:
 582
 583 =over 4
 584
 585 =item * The MIME name as defined in IETF RFC-XXXX.
 586
 587 =item * The name in the IANA registry.
 588
 589 =item * The name used by the the organization that defined it.
 590
 591 =back
 592
 593 Because of all the alias issues, and because in the general case
 594 encodings have state C<Encode> uses the encoding object internally
 595 once an operation is in progress.
 596
 597 =head1 PERL ENCODING API
 598
 599 =head2 Generic Encoding Interface
 600
 601 =over 4
 602
 603 =item *
 604
 605         $bytes  = encode(ENCODING, $string[, CHECK])
 606
 607 Encodes string from Perl's internal form into I<ENCODING> and returns
 608 a sequence of octets.  For CHECK see L</"Handling Malformed Data">.
 609
 610 =item *
 611
 612         $string = decode(ENCODING, $bytes[, CHECK])
 613
 614 Decode sequence of octets assumed to be in I<ENCODING> into Perl's
 615 internal form and returns the resulting string.  For CHECK see
 616 L</"Handling Malformed Data">.
 617
 618 =item *
 619
 620         from_to($string, FROM_ENCODING, TO_ENCODING[, CHECK])
 621
 622 Convert B<in-place> the data between two encodings.  How did the data
 623 in $string originally get to be in FROM_ENCODING?  Either using
 624 encode() or through PerlIO: See L</"Encoding and IO">.  For CHECK
 625 see L</"Handling Malformed Data">.
 626
 627 For example to convert ISO 8859-1 data to UTF-8:
 628
 629         from_to($data, "iso-8859-1", "utf-8");
 630
 631 and to convert it back:
 632
 633         from_to($data, "utf-8", "iso-8859-1");
 634
 635 Note that because the conversion happens in place, the data to be
 636 converted cannot be a string constant, it must be a scalar variable.
 637
 638 =back
 639
 640 =head2 Handling Malformed Data
 641
 642 If CHECK is not set, C<undef> is returned.  If the data is supposed to
 643 be UTF-8, an optional lexical warning (category utf8) is given.  If
 644 CHECK is true but not a code reference, dies.
 645
 646 It would desirable to have a way to indicate that transform should use
 647 the encodings "replacement character" - no such mechanism is defined yet.
 648
 649 It is also planned to allow I<CHECK> to be a code reference.
 650
 651 This is not yet implemented as there are design issues with what its
 652 arguments should be and how it returns its results.
 653
 654 =over 4
 655
 656 =item Scheme 1
 657
 658 Passed remaining fragment of string being processed.
 659 Modifies it in place to remove bytes/characters it can understand
 660 and returns a string used to represent them.
 661 e.g.
 662
 663  sub fixup {
 664    my $ch = substr($_[0],0,1,'');
 665    return sprintf("\x{%02X}",ord($ch);
 666  }
 667
 668 This scheme is close to how underlying C code for Encode works, but gives
 669 the fixup routine very little context.
 670
 671 =item Scheme 2
 672
 673 Passed original string, and an index into it of the problem area, and
 674 output string so far.  Appends what it will to output string and
 675 returns new index into original string.  For example:
 676
 677  sub fixup {
 678    # my ($s,$i,$d) = @_;
 679    my $ch = substr($_[0],$_[1],1);
 680    $_[2] .= sprintf("\x{%02X}",ord($ch);
 681    return $_[1]+1;
 682  }
 683
 684 This scheme gives maximal control to the fixup routine but is more
 685 complicated to code, and may need internals of Encode to be tweaked to
 686 keep original string intact.
 687
 688 =item Other Schemes
 689
 690 Hybrids of above.
 691
 692 Multiple return values rather than in-place modifications.
 693
 694 Index into the string could be pos($str) allowing s/\G...//.
 695
 696 =back
 697
 698 =head2 UTF-8 / utf8
 699
 700 The Unicode consortium defines the UTF-8 standard as a way of encoding
 701 the entire Unicode repertiore as sequences of octets.  This encoding is
 702 expected to become very widespread. Perl can use this form internaly
 703 to represent strings, so conversions to and from this form are
 704 particularly efficient (as octets in memory do not have to change,
 705 just the meta-data that tells Perl how to treat them).
 706
 707 =over 4
 708
 709 =item *
 710
 711         $bytes = encode_utf8($string);
 712
 713 The characters that comprise string are encoded in Perl's superset of UTF-8
 714 and the resulting octets returned as a sequence of bytes. All possible
 715 characters have a UTF-8 representation so this function cannot fail.
 716
 717 =item *
 718
 719         $string = decode_utf8($bytes [,CHECK]);
 720
 721 The sequence of octets represented by $bytes is decoded from UTF-8
 722 into a sequence of logical characters. Not all sequences of octets
 723 form valid UTF-8 encodings, so it is possible for this call to fail.
 724 For CHECK see L</"Handling Malformed Data">.
 725
 726 =back
 727
 728 =head2 Other Encodings of Unicode
 729
 730 UTF-16 is similar to UCS-2, 16 bit or 2-byte chunks.  UCS-2 can only
 731 represent 0..0xFFFF, while UTF-16 has a I<surrogate pair> scheme which
 732 allows it to cover the whole Unicode range.
 733
 734 Surrogates are code points set aside to encode the 0x01000..0x10FFFF
 735 range of Unicode code points in pairs of 16-bit units.  The I<high
 736 surrogates> are the range 0xD800..0xDBFF, and the I<low surrogates>
 737 are the range 0xDC00..0xDFFFF.  The surrogate encoding is
 738
 739         $hi = ($uni - 0x10000) / 0x400 + 0xD800;
 740         $lo = ($uni - 0x10000) % 0x400 + 0xDC00;
 741
 742 and the decoding is
 743
 744         $uni = 0x10000 + ($hi - 0xD8000) * 0x400 + ($lo - 0xDC00);
 745
 746 Encode implements big-endian UCS-2 aliased to "iso-10646-1" as that
 747 happens to be the name used by that representation when used with X11
 748 fonts.
 749
 750 UTF-32 or UCS-4 is 32-bit or 4-byte chunks.  Perl's logical characters
 751 can be considered as being in this form without encoding. An encoding
 752 to transfer strings in this form (e.g. to write them to a file) would
 753 need to
 754
 755      pack('L*', unpack('U*', $string));  # native
 756   or
 757      pack('V*', unpack('U*', $string));  # little-endian
 758   or
 759      pack('N*', unpack('U*', $string));  # big-endian
 760
 761 depending on the endianness required.
 762
 763 No UTF-32 encodings are implemented yet.
 764
 765 Both UCS-2 and UCS-4 style encodings can have "byte order marks" by
 766 representing the code point 0xFFFE as the very first thing in a file.
 767
 768 =head2 Listing available encodings
 769
 770   use Encode qw(encodings);
 771   @list = encodings();
 772
 773 Returns a list of the canonical names of the available encodings.
 774
 775 =head2 Defining Aliases
 776
 777   use Encode qw(define_alias);
 778   define_alias( newName => ENCODING);
 779
 780 Allows newName to be used as am alias for ENCODING. ENCODING may be
 781 either the name of an encoding or and encoding object (as above).
 782
 783 Currently I<newName> can be specified in the following ways:
 784
 785 =over 4
 786
 787 =item As a simple string.
 788
 789 =item As a qr// compiled regular expression, e.g.:
 790
 791   define_alias( qr/^iso8859-(\d+)$/i => '"iso-8859-$1"' );
 792
 793 In this case if I<ENCODING> is not a reference it is C<eval>-ed to
 794 allow C<$1> etc. to be subsituted.  The example is one way to names as
 795 used in X11 font names to alias the MIME names for the iso-8859-*
 796 family.
 797
 798 =item As a code reference, e.g.:
 799
 800   define_alias( sub { return /^iso8859-(\d+)$/i ? "iso-8859-$1" : undef } , '');
 801
 802 In this case C<$_> will be set to the name that is being looked up and
 803 I<ENCODING> is passed to the sub as its first argument.  The example
 804 is another way to names as used in X11 font names to alias the MIME
 805 names for the iso-8859-* family.
 806
 807 =back
 808
 809 =head2 Defining Encodings
 810
 811     use Encode qw(define_alias);
 812     define_encoding( $object, 'canonicalName' [,alias...]);
 813
 814 Causes I<canonicalName> to be associated with I<$object>.  The object
 815 should provide the interface described in L</"IMPLEMENTATION CLASSES">
 816 below.  If more than two arguments are provided then additional
 817 arguments are taken as aliases for I<$object> as for C<define_alias>.
 818
 819 =head1 Encoding and IO
 820
 821 It is very common to want to do encoding transformations when
 822 reading or writing files, network connections, pipes etc.
 823 If Perl is configured to use the new 'perlio' IO system then
 824 C<Encode> provides a "layer" (See L<perliol>) which can transform
 825 data as it is read or written.
 826
 827 Here is how the blind poet would modernise the encoding:
 828
 829     use Encode;
 830     open(my $iliad,'<:encoding(iso-8859-7)','iliad.greek');
 831     open(my $utf8,'>:utf8','iliad.utf8');
 832     my @epic = <$iliad>;
 833     print $utf8 @epic;
 834     close($utf8);
 835     close($illiad);
 836
 837 In addition the new IO system can also be configured to read/write
 838 UTF-8 encoded characters (as noted above this is efficient):
 839
 840     open(my $fh,'>:utf8','anything');
 841     print $fh "Any \x{0021} string \N{SMILEY FACE}\n";
 842
 843 Either of the above forms of "layer" specifications can be made the default
 844 for a lexical scope with the C<use open ...> pragma. See L<open>.
 845
 846 Once a handle is open is layers can be altered using C<binmode>.
 847
 848 Without any such configuration, or if Perl itself is built using
 849 system's own IO, then write operations assume that file handle accepts
 850 only I<bytes> and will C<die> if a character larger than 255 is
 851 written to the handle. When reading, each octet from the handle
 852 becomes a byte-in-a-character. Note that this default is the same
 853 behaviour as bytes-only languages (including Perl before v5.6) would
 854 have, and is sufficient to handle native 8-bit encodings
 855 e.g. iso-8859-1, EBCDIC etc. and any legacy mechanisms for handling
 856 other encodings and binary data.
 857
 858 In other cases it is the programs responsibility to transform
 859 characters into bytes using the API above before doing writes, and to
 860 transform the bytes read from a handle into characters before doing
 861 "character operations" (e.g. C<lc>, C</\W+/>, ...).
 862
 863 You can also use PerlIO to convert larger amounts of data you don't
 864 want to bring into memory.  For example to convert between ISO 8859-1
 865 (Latin 1) and UTF-8 (or UTF-EBCDIC in EBCDIC machines):
 866
 867     open(F, "<:encoding(iso-8859-1)", "data.txt") or die $!;
 868     open(G, ">:utf8",                 "data.utf") or die $!;
 869     while (<F>) { print G }
 870
 871     # Could also do "print G <F>" but that would pull
 872     # the whole file into memory just to write it out again.
 873
 874 More examples:
 875
 876     open(my $f, "<:encoding(cp1252)")
 877     open(my $g, ">:encoding(iso-8859-2)")
 878     open(my $h, ">:encoding(latin9)")       # iso-8859-15
 879
 880 See L<PerlIO> for more information.
 881
 882 See also L<encoding> for how to change the default encoding of the
 883 data in your script.
 884
 885 =head1 Encoding How to ...
 886
 887 To do:
 888
 889 =over 4
 890
 891 =item * IO with mixed content (faking iso-2020-*)
 892
 893 =item * MIME's Content-Length:
 894
 895 =item * UTF-8 strings in binary data.
 896
 897 =item * Perl/Encode wrappers on non-Unicode XS modules.
 898
 899 =back
 900
 901 =head1 Messing with Perl's Internals
 902
 903 The following API uses parts of Perl's internals in the current
 904 implementation.  As such they are efficient, but may change.
 905
 906 =over 4
 907
 908 =item * is_utf8(STRING [, CHECK])
 909
 910 [INTERNAL] Test whether the UTF-8 flag is turned on in the STRING.
 911 If CHECK is true, also checks the data in STRING for being well-formed
 912 UTF-8.  Returns true if successful, false otherwise.
 913
 914 =item * valid_utf8(STRING)
 915
 916 [INTERNAL] Test whether STRING is in a consistent state.  Will return
 917 true if string is held as bytes, or is well-formed UTF-8 and has the
 918 UTF-8 flag on.  Main reason for this routine is to allow Perl's
 919 testsuite to check that operations have left strings in a consistent
 920 state.
 921
 922 =item *
 923
 924         _utf8_on(STRING)
 925
 926 [INTERNAL] Turn on the UTF-8 flag in STRING.  The data in STRING is
 927 B<not> checked for being well-formed UTF-8.  Do not use unless you
 928 B<know> that the STRING is well-formed UTF-8.  Returns the previous
 929 state of the UTF-8 flag (so please don't test the return value as
 930 I<not> success or failure), or C<undef> if STRING is not a string.
 931
 932 =item *
 933
 934         _utf8_off(STRING)
 935
 936 [INTERNAL] Turn off the UTF-8 flag in STRING.  Do not use frivolously.
 937 Returns the previous state of the UTF-8 flag (so please don't test the
 938 return value as I<not> success or failure), or C<undef> if STRING is
 939 not a string.
 940
 941 =back
 942
 943 =head1 IMPLEMENTATION CLASSES
 944
 945 As mentioned above encodings are (in the current implementation at least)
 946 defined by objects. The mapping of encoding name to object is via the
 947 C<%encodings> hash.
 948
 949 The values of the hash can currently be either strings or objects.
 950 The string form may go away in the future. The string form occurs
 951 when C<encodings()> has scanned C<@INC> for loadable encodings but has
 952 not actually loaded the encoding in question. This is because the
 953 current "loading" process is all Perl and a bit slow.
 954
 955 Once an encoding is loaded then value of the hash is object which
 956 implements the encoding. The object should provide the following
 957 interface:
 958
 959 =over 4
 960
 961 =item -E<gt>name
 962
 963 Should return the string representing the canonical name of the encoding.
 964
 965 =item -E<gt>new_sequence
 966
 967 This is a placeholder for encodings with state. It should return an
 968 object which implements this interface, all current implementations
 969 return the original object.
 970
 971 =item -E<gt>encode($string,$check)
 972
 973 Should return the octet sequence representing I<$string>. If I<$check>
 974 is true it should modify I<$string> in place to remove the converted
 975 part (i.e.  the whole string unless there is an error).  If an error
 976 occurs it should return the octet sequence for the fragment of string
 977 that has been converted, and modify $string in-place to remove the
 978 converted part leaving it starting with the problem fragment.
 979
 980 If check is is false then C<encode> should make a "best effort" to
 981 convert the string - for example by using a replacement character.
 982
 983 =item -E<gt>decode($octets,$check)
 984
 985 Should return the string that I<$octets> represents. If I<$check> is
 986 true it should modify I<$octets> in place to remove the converted part
 987 (i.e.  the whole sequence unless there is an error).  If an error
 988 occurs it should return the fragment of string that has been
 989 converted, and modify $octets in-place to remove the converted part
 990 leaving it starting with the problem fragment.
 991
 992 If check is is false then C<decode> should make a "best effort" to
 993 convert the string - for example by using Unicode's "\x{FFFD}" as a
 994 replacement character.
 995
 996 =back
 997
 998 It should be noted that the check behaviour is different from the
 999 outer public API. The logic is that the "unchecked" case is useful
1000 when encoding is part of a stream which may be reporting errors
1001 (e.g. STDERR).  In such cases it is desirable to get everything
1002 through somehow without causing additional errors which obscure the
1003 original one. Also the encoding is best placed to know what the
1004 correct replacement character is, so if that is the desired behaviour
1005 then letting low level code do it is the most efficient.
1006
1007 In contrast if check is true, the scheme above allows the encoding to
1008 do as much as it can and tell layer above how much that was. What is
1009 lacking at present is a mechanism to report what went wrong. The most
1010 likely interface will be an additional method call to the object, or
1011 perhaps (to avoid forcing per-stream objects on otherwise stateless
1012 encodings) and additional parameter.
1013
1014 It is also highly desirable that encoding classes inherit from
1015 C<Encode::Encoding> as a base class. This allows that class to define
1016 additional behaviour for all encoding objects. For example built in
1017 Unicode, UCS-2 and UTF-8 classes use :
1018
1019   package Encode::MyEncoding;
1020   use base qw(Encode::Encoding);
1021
1022   __PACKAGE__->Define(qw(myCanonical myAlias));
1023
1024 To create an object with bless {Name => ...},$class, and call
1025 define_encoding.  They inherit their C<name> method from
1026 C<Encode::Encoding>.
1027
1028 =head2 Compiled Encodings
1029
1030 F<Encode.xs> provides a class C<Encode::XS> which provides the
1031 interface described above. It calls a generic octet-sequence to
1032 octet-sequence "engine" that is driven by tables (defined in
1033 F<encengine.c>). The same engine is used for both encode and
1034 decode. C<Encode:XS>'s C<encode> forces Perl's characters to their
1035 UTF-8 form and then treats them as just another multibyte
1036 encoding. C<Encode:XS>'s C<decode> transforms the sequence and then
1037 turns the UTF-8-ness flag as that is the form that the tables are
1038 defined to produce. For details of the engine see the comments in
1039 F<encengine.c>.
1040
1041 The tables are produced by the Perl script F<compile> (the name needs
1042 to change so we can eventually install it somewhere). F<compile> can
1043 currently read two formats:
1044
1045 =over 4
1046
1047 =item *.enc
1048
1049 This is a coined format used by Tcl. It is documented in
1050 Encode/EncodeFormat.pod.
1051
1052 =item *.ucm
1053
1054 This is the semi-standard format used by IBM's ICU package.
1055
1056 =back
1057
1058 F<compile> can write the following forms:
1059
1060 =over 4
1061
1062 =item *.ucm
1063
1064 See above - the F<Encode/*.ucm> files provided with the distribution have
1065 been created from the original Tcl .enc files using this approach.
1066
1067 =item *.c
1068
1069 Produces tables as C data structures - this is used to build in encodings
1070 into F<Encode.so>/F<Encode.dll>.
1071
1072 =item *.xs
1073
1074 In theory this allows encodings to be stand-alone loadable Perl
1075 extensions.  The process has not yet been tested. The plan is to use
1076 this approach for large East Asian encodings.
1077
1078 =back
1079
1080 The set of encodings built-in to F<Encode.so>/F<Encode.dll> is
1081 determined by F<Makefile.PL>.  The current set is as follows:
1082
1083 =over 4
1084
1085 =item ascii and iso-8859-*
1086
1087 That is all the common 8-bit "western" encodings.
1088
1089 =item IBM-1047 and two other variants of EBCDIC.
1090
1091 These are the same variants that are supported by EBCDIC Perl as
1092 "native" encodings.  They are included to prove "reversibility" of
1093 some constructs in EBCDIC Perl.
1094
1095 =item symbol and dingbats as used by Tk on X11.
1096
1097 (The reason Encode got started was to support Perl/Tk.)
1098
1099 =back
1100
1101 That set is rather ad hoc and has been driven by the needs of the
1102 tests rather than the needs of typical applications. It is likely
1103 to be rationalized.
1104
1105 =head1 SEE ALSO
1106
1107 L<perlunicode>, L<perlebcdic>, L<perlfunc/open>, L<PerlIO>, L<encoding>
1108
1109 =cut
1110