t/op/stat.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require './test.pl';        # for which_perl() etc
   7 }
   8
   9 use Config;
  10 use File::Spec;
  11
  12 plan tests => 73;
  13
  14 my $Perl = which_perl();
  15
  16 $Is_Amiga   = $^O eq 'amigaos';
  17 $Is_Cygwin  = $^O eq 'cygwin';
  18 $Is_Dos     = $^O eq 'dos';
  19 $Is_MPE     = $^O eq 'mpeix';
  20 $Is_MSWin32 = $^O eq 'MSWin32';
  21 $Is_NetWare = $^O eq 'NetWare';
  22 $Is_OS2     = $^O eq 'os2';
  23 $Is_Solaris = $^O eq 'solaris';
  24 $Is_VMS     = $^O eq 'VMS';
  25
  26 $Is_Dosish  = $Is_Dos || $Is_OS2 || $Is_MSWin32 || $Is_NetWare || $Is_Cygwin;
  27
  28 my($DEV, $INO, $MODE, $NLINK, $UID, $GID, $RDEV, $SIZE,
  29    $ATIME, $MTIME, $CTIME, $BLKSIZE, $BLOCKS) = (0..12);
  30
  31 my $Curdir = File::Spec->curdir;
  32
  33
  34 my $tmpfile = 'Op_stat.tmp';
  35 my $tmpfile_link = $tmpfile.'2';
  36
  37
  38 unlink $tmpfile;
  39 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  40 close FOO;
  41
  42 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  43
  44 my($nlink, $mtime, $ctime) = (stat(FOO))[$NLINK, $MTIME, $CTIME];
  45 SKIP: {
  46     skip "No link count", 1 if $Is_VMS;
  47
  48     is($nlink, 1, 'nlink on regular file');
  49 }
  50
  51 SKIP: {
  52   skip "mtime and ctime not reliable", 2
  53     if $Is_MSWin32 or $Is_NetWare or $Is_Cygwin or $Is_Dos;
  54
  55   ok( $mtime,           'mtime' );
  56   is( $mtime, $ctime,   'mtime == ctime' );
  57 }
  58
  59
  60 # Cygwin seems to have a 3 second granularity on its timestamps.
  61 my $funky_FAT_timestamps = $Is_Cygwin;
  62 sleep 3 if $funky_FAT_timestamps;
  63
  64 print FOO "Now is the time for all good men to come to.\n";
  65 close(FOO);
  66
  67 sleep 2 unless $funky_FAT_timestamps;
  68
  69
  70 SKIP: {
  71     unlink $tmpfile_link;
  72     my $lnk_result = eval { link $tmpfile, $tmpfile_link };
  73     skip "link() unimplemented", 6 if $@ =~ /unimplemented/;
  74
  75     is( $@, '',         'link() implemented' );
  76     ok( $lnk_result,    'linked tmp testfile' );
  77     ok( chmod(0644, $tmpfile),             'chmoded tmp testfile' );
  78
  79     my($nlink, $mtime, $ctime) = (stat($tmpfile))[$NLINK, $MTIME, $CTIME];
  80
  81     SKIP: {
  82         skip "No link count", 1 if $Config{dont_use_nlink};
  83         skip "Cygwin9X fakes hard links by copying", 1
  84           if $Config{myuname} =~ /^cygwin_(?:9\d|me)\b/i;
  85
  86         is($nlink, 2,     'Link count on hard linked file' );
  87     }
  88
  89     SKIP: {
  90         my $cwd = File::Spec->rel2abs($Curdir);
  91         skip "Solaris tmpfs has different mtime/ctime link semantics", 2
  92                                      if $Is_Solaris and $cwd =~ m#^/tmp# and
  93                                         $mtime && $mtime == $ctime;
  94         skip "AFS has different mtime/ctime link semantics", 2
  95                                      if $cwd =~ m#$Config{'afsroot'}/#;
  96         skip "AmigaOS has different mtime/ctime link semantics", 2
  97                                      if $Is_Amiga;
  98         # Win32 could pass $mtime test but as FAT and NTFS have
  99         # no ctime concept $ctime is ALWAYS == $mtime
 100         # expect netware to be the same ...
 101         skip "No ctime concept on this OS", 2
 102                                      if $Is_MSWin32;
 103         if( !ok($mtime, 'hard link mtime') ||
 104             !isnt($mtime, $ctime, 'hard link ctime != mtime') ) {
 105             print <<DIAG;
 106 # Check if you are on a tmpfs of some sort.  Building in /tmp sometimes
 107 # has this problem.  Also building on the ClearCase VOBS filesystem may
 108 # cause this failure.
 109 # Darwins UFS doesn't have a ctime concept, and thus is
 110 # expected to fail this test.
 111 DIAG
 112         }
 113     }
 114
 115 }
 116
 117 # truncate and touch $tmpfile.
 118 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 119 close F;
 120
 121 ok(-z $tmpfile,     '-z on empty file');
 122 ok(! -s $tmpfile,   '   and -s');
 123
 124 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 125 print F "hi\n";
 126 close F;
 127
 128 ok(! -z $tmpfile,   '-z on non-empty file');
 129 ok(-s $tmpfile,     '   and -s');
 130
 131
 132 # Strip all access rights from the file.
 133 ok( chmod(0000, $tmpfile),     'chmod 0000' );
 134
 135 SKIP: {
 136     skip "-r, -w and -x have different meanings on VMS", 3 if $Is_VMS;
 137
 138     SKIP: {
 139         # Going to try to switch away from root.  Might not work.
 140         my $olduid = $>;
 141         eval { $> = 1; };
 142         skip "Can't test -r or -w meaningfully if you're superuser", 2
 143           if $> == 0;
 144
 145         SKIP: {
 146             skip "Can't test -r meaningfully?", 1 if $Is_Dos || $Is_Cygwin;
 147             ok(!-r $tmpfile,    "   -r");
 148         }
 149
 150         ok(!-w $tmpfile,    "   -w");
 151
 152         # switch uid back (may not be implemented)
 153         eval { $> = $olduid; };
 154     }
 155
 156     ok(! -x $tmpfile,   '   -x');
 157 }
 158
 159
 160
 161
 162 # in ms windows, $tmpfile inherits owner uid from directory
 163 # not sure about os/2, but chown is harmless anyway
 164 eval { chown $>,$tmpfile; 1 } or print "# $@" ;
 165
 166 ok(chmod(0700,$tmpfile),    'chmod 0700');
 167 ok(-r $tmpfile,     '   -r');
 168 ok(-w $tmpfile,     '   -w');
 169
 170 SKIP: {
 171     skip "-x simply determins if a file ends in an executable suffix", 1
 172       if $Is_Dosish;
 173
 174     ok(-x $tmpfile,     '   -x');
 175 }
 176
 177 ok(  -f $tmpfile,   '   -f');
 178 ok(! -d $tmpfile,   '   !-d');
 179
 180 # Is this portable?
 181 ok(  -d $Curdir,          '-d cwd' );
 182 ok(! -f $Curdir,          '!-f cwd' );
 183
 184
 185 SKIP: {
 186     unlink($tmpfile_link);
 187     my $symlink_rslt = eval { symlink $tmpfile, $tmpfile_link };
 188     skip "symlink not implemented", 3 if $@ =~ /unimplemented/;
 189
 190     is( $@, '',     'symlink() implemented' );
 191     ok( $symlink_rslt,      'symlink() ok' );
 192     ok(-l $tmpfile_link,    '-l');
 193 }
 194
 195 ok(-o $tmpfile,     '-o');
 196
 197 ok(-e $tmpfile,     '-e');
 198
 199 unlink($tmpfile_link);
 200 ok(! -e $tmpfile_link,  '   -e on unlinked file');
 201
 202 SKIP: {
 203     skip "No character, socket or block special files", 3
 204       if $Is_MSWin32 || $Is_NetWare || $Is_Dos;
 205     skip "/dev isn't available to test against", 3
 206       unless -d '/dev' && -r '/dev' && -x '/dev';
 207
 208     my $LS  = $Config{d_readlink} ? "ls -lL" : "ls -l";
 209     my $CMD = "$LS /dev 2>/dev/null";
 210     my $DEV = qx($CMD);
 211
 212     skip "$CMD failed", 3 if $DEV eq '';
 213
 214     my @DEV = do { my $dev; opendir($dev, "/dev") ? readdir($dev) : () };
 215
 216     skip "opendir failed: $!", 3 if @DEV == 0;
 217
 218     # /dev/stdout might be either character special or a named pipe,
 219     # or a symlink, or a socket, depending on which OS and how are
 220     # you running the test, so let's censor that one away.
 221     # Similar remarks hold for stderr.
 222     $DEV =~ s{^[cpls].+?\sstdout$}{}m;
 223     @DEV =  grep { $_ ne 'stdout' } @DEV;
 224     $DEV =~ s{^[cpls].+?\sstderr$}{}m;
 225     @DEV =  grep { $_ ne 'stderr' } @DEV;
 226
 227     # /dev/printer is also naughty: in IRIX it shows up as
 228     # Srwx-----, not srwx------.
 229     $DEV =~ s{^.+?\sprinter$}{}m;
 230     @DEV =  grep { $_ ne 'printer' } @DEV;
 231
 232     # If running as root, we will see .files in the ls result,
 233     # and readdir() will see them always.  Potential for conflict,
 234     # so let's weed them out.
 235     $DEV =~ s{^.+?\s\..+?$}{}m;
 236     @DEV =  grep { ! m{^\..+$} } @DEV;
 237
 238     my $try = sub {
 239         my @c1 = eval qq[\$DEV =~ /^$_[0].*/mg];
 240         my @c2 = eval qq[grep { $_[1] "/dev/\$_" } \@DEV];
 241         my $c1 = scalar @c1;
 242         my $c2 = scalar @c2;
 243         is($c1, $c2, "ls and $_[1] agreeing on /dev ($c1 $c2)");
 244     };
 245
 246     $try->('b', '-b');
 247     $try->('c', '-c');
 248     $try->('s', '-S');
 249 }
 250
 251 ok(! -b $Curdir,    '!-b cwd');
 252 ok(! -c $Curdir,    '!-c cwd');
 253 ok(! -S $Curdir,    '!-S cwd');
 254
 255 SKIP: {
 256     my($cnt, $uid);
 257     $cnt = $uid = 0;
 258
 259     # Find a set of directories that's very likely to have setuid files
 260     # but not likely to be *all* setuid files.
 261     my @bin = grep {-d && -r && -x} qw(/sbin /usr/sbin /bin /usr/bin);
 262     skip "Can't find a setuid file to test with", 3 unless @bin;
 263
 264     for my $bin (@bin) {
 265         opendir BIN, $bin or die "Can't opendir $bin: $!";
 266         while (defined($_ = readdir BIN)) {
 267             $_ = "$bin/$_";
 268             $cnt++;
 269             $uid++ if -u;
 270             last if $uid && $uid < $cnt;
 271         }
 272     }
 273     closedir BIN;
 274
 275     skip "No setuid programs", 3 if $uid == 0;
 276
 277     isnt($cnt, 0,    'found some programs');
 278     isnt($uid, 0,    '  found some setuid programs');
 279     ok($uid < $cnt,  "    they're not all setuid");
 280 }
 281
 282
 283 # To assist in automated testing when a controlling terminal (/dev/tty)
 284 # may not be available (at, cron  rsh etc), the PERL_SKIP_TTY_TEST env var
 285 # can be set to skip the tests that need a tty.
 286 SKIP: {
 287     skip "These tests require a TTY", 4 if $ENV{PERL_SKIP_TTY_TEST};
 288
 289     my $TTY = $^O eq 'rhapsody' ? "/dev/ttyp0" : "/dev/tty";
 290
 291     SKIP: {
 292         skip "Test uses unixisms", 2 if $Is_MSWin32 || $Is_NetWare;
 293         skip "No TTY to test -t with", 2 unless -e $TTY;
 294
 295         open(TTY, $TTY) ||
 296           warn "Can't open $TTY--run t/TEST outside of make.\n";
 297         ok(-t TTY,  '-t');
 298         ok(-c TTY,  'tty is -c');
 299         close(TTY);
 300     }
 301     ok(! -t TTY,    '!-t on closed TTY filehandle');
 302
 303     {
 304         local $TODO = 'STDIN not a tty when output is to pipe' if $Is_VMS;
 305         ok(-t,          '-t on STDIN');
 306     }
 307 }
 308
 309 my $Null = File::Spec->devnull;
 310 SKIP: {
 311     skip "No null device to test with", 1 unless -e $Null;
 312     skip "We know Win32 thinks '$Null' is a TTY", 1 if $Is_MSWin32;
 313
 314     open(NULL, $Null) or DIE("Can't open $Null: $!");
 315     ok(! -t NULL,   'null device is not a TTY');
 316     close(NULL);
 317 }
 318
 319
 320 # These aren't strictly "stat" calls, but so what?
 321
 322 ok(-T 'op/stat.t',      '-T');
 323 ok(! -B 'op/stat.t',    '!-B');
 324
 325 ok(-B $Perl,      '-B');
 326 ok(! -T $Perl,    '!-T');
 327
 328 open(FOO,'op/stat.t');
 329 SKIP: {
 330     eval { -T FOO; };
 331     skip "-T/B on filehandle not implemented", 15 if $@ =~ /not implemented/;
 332
 333     is( $@, '',     '-T on filehandle causes no errors' );
 334
 335     ok(-T FOO,      '   -T');
 336     ok(! -B FOO,    '   !-B');
 337
 338     $_ = <FOO>;
 339     like($_, qr/perl/, 'after readline');
 340     ok(-T FOO,      '   still -T');
 341     ok(! -B FOO,    '   still -B');
 342     close(FOO);
 343
 344     open(FOO,'op/stat.t');
 345     $_ = <FOO>;
 346     like($_, qr/perl/,      'reopened and after readline');
 347     ok(-T FOO,      '   still -T');
 348     ok(! -B FOO,    '   still !-B');
 349
 350     ok(seek(FOO,0,0),   'after seek');
 351     ok(-T FOO,          '   still -T');
 352     ok(! -B FOO,        '   still !-B');
 353
 354     # It's documented this way in perlfunc *shrug*
 355     () = <FOO>;
 356     ok(eof FOO,         'at EOF');
 357     ok(-T FOO,          '   still -T');
 358     ok(-B FOO,          '   now -B');
 359 }
 360 close(FOO);
 361
 362
 363 SKIP: {
 364     skip "No null device to test with", 2 unless -e $Null;
 365
 366     ok(-T $Null,  'null device is -T');
 367     ok(-B $Null,  '    and -B');
 368 }
 369
 370
 371 # and now, a few parsing tests:
 372 $_ = $tmpfile;
 373 ok(-f,      'bare -f   uses $_');
 374 ok(-f(),    '     -f() "');
 375
 376 unlink $tmpfile or print "# unlink failed: $!\n";
 377
 378 # bug id 20011101.069
 379 my @r = \stat(".");
 380 is(scalar @r, 13,   'stat returns full 13 elements');
 381
 382 SKIP: {
 383     skip "No lstat", 4 unless $Config{d_lstat};
 384
 385     stat $0;
 386     eval { lstat _ };
 387     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 388         'lstat _ croaks after stat' );
 389     eval { -l _ };
 390     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 391         '-l _ croaks after stat' );
 392
 393     # bug id 20020124.004
 394     # If we have d_lstat, we should have symlink()
 395     my $linkname = 'dolzero';
 396     symlink $0, $linkname or die "# Can't symlink $0: $!";
 397     lstat $linkname;
 398     -T _;
 399     eval { lstat _ };
 400     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 401         'lstat croaks after -T _' );
 402     eval { -l _ };
 403     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 404         '-l _ croaks after -T _' );
 405     unlink $linkname or print "# unlink $linkname failed: $!\n";
 406 }