lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<_<$filename>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34).
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 use strict;
 514
 515 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
 516
 517 BEGIN {
 518     require feature;
 519     $^V =~ /^v(\d+\.\d+)/;
 520     feature->import(":$1");
 521 }
 522
 523 # Debugger for Perl 5.00x; perl5db.pl patch level:
 524 use vars qw($VERSION $header);
 525
 526 $VERSION = '1.39_04';
 527
 528 $header = "perl5db.pl version $VERSION";
 529
 530 =head1 DEBUGGER ROUTINES
 531
 532 =head2 C<DB::eval()>
 533
 534 This function replaces straight C<eval()> inside the debugger; it simplifies
 535 the process of evaluating code in the user's context.
 536
 537 The code to be evaluated is passed via the package global variable
 538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 539
 540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 543 user's current package, grabbed when C<DB::DB> got control.  This causes the
 544 proper context to be used when the eval is actually done.  Afterward, we
 545 restore C<$trace>, C<$single>, and C<$^D>.
 546
 547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 551 considered sane by the debugger. If there was an C<eval()> error, we print
 552 it on the debugger's output. If C<$onetimedump> is defined, we call
 553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 554 'methods'. Setting it to something else causes the debugger to do the eval
 555 but not print the result - handy if you want to do something else with it
 556 (the "watch expressions" code does this to get the value of the watch
 557 expression but not show it unless it matters).
 558
 559 In any case, we then return the list of output from C<eval> to the caller,
 560 and unwinding restores the former version of C<$@> in C<@saved> as well
 561 (the localization of C<$saved[0]> goes away at the end of this scope).
 562
 563 =head3 Parameters and variables influencing execution of DB::eval()
 564
 565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 567 The variables listed below influence C<DB::eval()>'s execution directly.
 568
 569 =over 4
 570
 571 =item C<$evalarg> - the thing to actually be eval'ed
 572
 573 =item C<$trace> - Current state of execution tracing
 574
 575 =item C<$single> - Current state of single-stepping
 576
 577 =item C<$onetimeDump> - what is to be displayed after the evaluation
 578
 579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 580
 581 =back
 582
 583 The following variables are altered by C<DB::eval()> during its execution. They
 584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 585
 586 =over 4
 587
 588 =item C<@res> - used to capture output from actual C<eval>.
 589
 590 =item C<$otrace> - saved value of C<$trace>.
 591
 592 =item C<$osingle> - saved value of C<$single>.
 593
 594 =item C<$od> - saved value of C<$^D>.
 595
 596 =item C<$saved[0]> - saved value of C<$@>.
 597
 598 =item $\ - for output of C<$@> if there is an evaluation error.
 599
 600 =back
 601
 602 =head3 The problem of lexicals
 603
 604 The context of C<DB::eval()> presents us with some problems. Obviously,
 605 we want to be 'sandboxed' away from the debugger's internals when we do
 606 the eval, but we need some way to control how punctuation variables and
 607 debugger globals are used.
 608
 609 We can't use local, because the code inside C<DB::eval> can see localized
 610 variables; and we can't use C<my> either for the same reason. The code
 611 in this routine compromises and uses C<my>.
 612
 613 After this routine is over, we don't have user code executing in the debugger's
 614 context, so we can use C<my> freely.
 615
 616 =cut
 617
 618 ############################################## Begin lexical danger zone
 619
 620 # 'my' variables used here could leak into (that is, be visible in)
 621 # the context that the code being evaluated is executing in. This means that
 622 # the code could modify the debugger's variables.
 623 #
 624 # Fiddling with the debugger's context could be Bad. We insulate things as
 625 # much as we can.
 626
 627 use vars qw(
 628     @args
 629     %break_on_load
 630     @cmdfhs
 631     $CommandSet
 632     $CreateTTY
 633     $DBGR
 634     @dbline
 635     $dbline
 636     %dbline
 637     $dieLevel
 638     $evalarg
 639     $filename
 640     $frame
 641     $hist
 642     $histfile
 643     $histsize
 644     $ImmediateStop
 645     $IN
 646     $inhibit_exit
 647     @ini_INC
 648     $ini_warn
 649     $line
 650     $maxtrace
 651     $od
 652     $onetimeDump
 653     $onetimedumpDepth
 654     %option
 655     @options
 656     $osingle
 657     $otrace
 658     $OUT
 659     $packname
 660     $pager
 661     $post
 662     %postponed
 663     $prc
 664     $pre
 665     $pretype
 666     $psh
 667     @RememberOnROptions
 668     $remoteport
 669     @res
 670     $rl
 671     @saved
 672     $signal
 673     $signalLevel
 674     $single
 675     $start
 676     $sub
 677     %sub
 678     $subname
 679     $term
 680     $trace
 681     $usercontext
 682     $warnLevel
 683     $window
 684 );
 685
 686 # Used to save @ARGV and extract any debugger-related flags.
 687 use vars qw(@ARGS);
 688
 689 # Used to prevent multiple entries to diesignal()
 690 # (if for instance diesignal() itself dies)
 691 use vars qw($panic);
 692
 693 # Used to prevent the debugger from running nonstop
 694 # after a restart
 695 use vars qw($second_time);
 696
 697 sub _calc_usercontext {
 698     my ($package) = @_;
 699
 700     # Cancel strict completely for the evaluated code, so the code
 701     # the user evaluates won't be affected by it. (Shlomi Fish)
 702     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
 703     . "package $package;";    # this won't let them modify, alas
 704 }
 705
 706 sub eval {
 707
 708     # 'my' would make it visible from user code
 709     #    but so does local! --tchrist
 710     # Remember: this localizes @DB::res, not @main::res.
 711     local @res;
 712     {
 713
 714         # Try to keep the user code from messing  with us. Save these so that
 715         # even if the eval'ed code changes them, we can put them back again.
 716         # Needed because the user could refer directly to the debugger's
 717         # package globals (and any 'my' variables in this containing scope)
 718         # inside the eval(), and we want to try to stay safe.
 719         local $otrace  = $trace;
 720         local $osingle = $single;
 721         local $od      = $^D;
 722
 723         # Untaint the incoming eval() argument.
 724         { ($evalarg) = $evalarg =~ /(.*)/s; }
 725
 726         # $usercontext built in DB::DB near the comment
 727         # "set up the context for DB::eval ..."
 728         # Evaluate and save any results.
 729         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 730
 731         # Restore those old values.
 732         $trace  = $otrace;
 733         $single = $osingle;
 734         $^D     = $od;
 735     }
 736
 737     # Save the current value of $@, and preserve it in the debugger's copy
 738     # of the saved precious globals.
 739     my $at = $@;
 740
 741     # Since we're only saving $@, we only have to localize the array element
 742     # that it will be stored in.
 743     local $saved[0];    # Preserve the old value of $@
 744     eval { &DB::save };
 745
 746     # Now see whether we need to report an error back to the user.
 747     if ($at) {
 748         local $\ = '';
 749         print $OUT $at;
 750     }
 751
 752     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 753     # are package globals.
 754     elsif ($onetimeDump) {
 755         if ( $onetimeDump eq 'dump' ) {
 756             local $option{dumpDepth} = $onetimedumpDepth
 757               if defined $onetimedumpDepth;
 758             dumpit( $OUT, \@res );
 759         }
 760         elsif ( $onetimeDump eq 'methods' ) {
 761             methods( $res[0] );
 762         }
 763     } ## end elsif ($onetimeDump)
 764     @res;
 765 } ## end sub eval
 766
 767 ############################################## End lexical danger zone
 768
 769 # After this point it is safe to introduce lexicals.
 770 # The code being debugged will be executing in its own context, and
 771 # can't see the inside of the debugger.
 772 #
 773 # However, one should not overdo it: leave as much control from outside as
 774 # possible. If you make something a lexical, it's not going to be addressable
 775 # from outside the debugger even if you know its name.
 776
 777 # This file is automatically included if you do perl -d.
 778 # It's probably not useful to include this yourself.
 779 #
 780 # Before venturing further into these twisty passages, it is
 781 # wise to read the perldebguts man page or risk the ire of dragons.
 782 #
 783 # (It should be noted that perldebguts will tell you a lot about
 784 # the underlying mechanics of how the debugger interfaces into the
 785 # Perl interpreter, but not a lot about the debugger itself. The new
 786 # comments in this code try to address this problem.)
 787
 788 # Note that no subroutine call is possible until &DB::sub is defined
 789 # (for subroutines defined outside of the package DB). In fact the same is
 790 # true if $deep is not defined.
 791
 792 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 793
 794 # modified Perl debugger, to be run from Emacs in perldb-mode
 795 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 796 # Johan Vromans -- upgrade to 4.0 pl 10
 797 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 798 ########################################################################
 799
 800 =head1 DEBUGGER INITIALIZATION
 801
 802 The debugger starts up in phases.
 803
 804 =head2 BASIC SETUP
 805
 806 First, it initializes the environment it wants to run in: turning off
 807 warnings during its own compilation, defining variables which it will need
 808 to avoid warnings later, setting itself up to not exit when the program
 809 terminates, and defaulting to printing return values for the C<r> command.
 810
 811 =cut
 812
 813 # Needed for the statement after exec():
 814 #
 815 # This BEGIN block is simply used to switch off warnings during debugger
 816 # compilation. Probably it would be better practice to fix the warnings,
 817 # but this is how it's done at the moment.
 818
 819 BEGIN {
 820     $ini_warn = $^W;
 821     $^W       = 0;
 822 }    # Switch compilation warnings off until another BEGIN.
 823
 824 local ($^W) = 0;    # Switch run-time warnings off during init.
 825
 826 =head2 THREADS SUPPORT
 827
 828 If we are running under a threaded Perl, we require threads and threads::shared
 829 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 830 threaded debugger control.  C<-dt> can also be used to set this.
 831
 832 Each new thread will be announced and the debugger prompt will always inform
 833 you of each new thread created.  It will also indicate the thread id in which
 834 we are currently running within the prompt like this:
 835
 836         [tid] DB<$i>
 837
 838 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 839 command prompt.  The prompt will show: C<[0]> when running under threads, but
 840 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 841
 842 While running under threads, when you set or delete a breakpoint (etc.), this
 843 will apply to all threads, not just the currently running one.  When you are
 844 in a currently executing thread, you will stay there until it completes.  With
 845 the current implementation it is not currently possible to hop from one thread
 846 to another.
 847
 848 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 849
 850 Note that threading support was built into the debugger as of Perl version
 851 C<5.8.6> and debugger version C<1.2.8>.
 852
 853 =cut
 854
 855 BEGIN {
 856   # ensure we can share our non-threaded variables or no-op
 857   if ($ENV{PERL5DB_THREADED}) {
 858         require threads;
 859         require threads::shared;
 860         import threads::shared qw(share);
 861         $DBGR;
 862         share(\$DBGR);
 863         lock($DBGR);
 864         print "Threads support enabled\n";
 865   } else {
 866         *lock  = sub(*) {};
 867         *share = sub(*) {};
 868   }
 869 }
 870
 871 # This would probably be better done with "use vars", but that wasn't around
 872 # when this code was originally written. (Neither was "use strict".) And on
 873 # the principle of not fiddling with something that was working, this was
 874 # left alone.
 875 warn(               # Do not ;-)
 876     # These variables control the execution of 'dumpvar.pl'.
 877     $dumpvar::hashDepth,
 878     $dumpvar::arrayDepth,
 879     $dumpvar::dumpDBFiles,
 880     $dumpvar::dumpPackages,
 881     $dumpvar::quoteHighBit,
 882     $dumpvar::printUndef,
 883     $dumpvar::globPrint,
 884     $dumpvar::usageOnly,
 885
 886     # used to control die() reporting in diesignal()
 887     $Carp::CarpLevel,
 888
 889
 890   )
 891   if 0;
 892
 893 # without threads, $filename is not defined until DB::DB is called
 894 foreach my $k (keys (%INC)) {
 895         &share(\$main::{'_<'.$filename}) if defined $filename;
 896 };
 897
 898 # Command-line + PERLLIB:
 899 # Save the contents of @INC before they are modified elsewhere.
 900 @ini_INC = @INC;
 901
 902 # This was an attempt to clear out the previous values of various
 903 # trapped errors. Apparently it didn't help. XXX More info needed!
 904 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 905
 906 # We set these variables to safe values. We don't want to blindly turn
 907 # off warnings, because other packages may still want them.
 908 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 909                                    # (local $^W cannot help - other packages!).
 910
 911 # Default to not exiting when program finishes; print the return
 912 # value when the 'r' command is used to return from a subroutine.
 913 $inhibit_exit = $option{PrintRet} = 1;
 914
 915 use vars qw($trace_to_depth);
 916
 917 # Default to 1 so the prompt will display the first line.
 918 $trace_to_depth = 1;
 919
 920 =head1 OPTION PROCESSING
 921
 922 The debugger's options are actually spread out over the debugger itself and
 923 C<dumpvar.pl>; some of these are variables to be set, while others are
 924 subs to be called with a value. To try to make this a little easier to
 925 manage, the debugger uses a few data structures to define what options
 926 are legal and how they are to be processed.
 927
 928 First, the C<@options> array defines the I<names> of all the options that
 929 are to be accepted.
 930
 931 =cut
 932
 933 @options = qw(
 934   CommandSet   HistFile      HistSize
 935   hashDepth    arrayDepth    dumpDepth
 936   DumpDBFiles  DumpPackages  DumpReused
 937   compactDump  veryCompact   quote
 938   HighBit      undefPrint    globPrint
 939   PrintRet     UsageOnly     frame
 940   AutoTrace    TTY           noTTY
 941   ReadLine     NonStop       LineInfo
 942   maxTraceLen  recallCommand ShellBang
 943   pager        tkRunning     ornaments
 944   signalLevel  warnLevel     dieLevel
 945   inhibit_exit ImmediateStop bareStringify
 946   CreateTTY    RemotePort    windowSize
 947   DollarCaretP
 948 );
 949
 950 @RememberOnROptions = qw(DollarCaretP);
 951
 952 =pod
 953
 954 Second, C<optionVars> lists the variables that each option uses to save its
 955 state.
 956
 957 =cut
 958
 959 use vars qw(%optionVars);
 960
 961 %optionVars = (
 962     hashDepth     => \$dumpvar::hashDepth,
 963     arrayDepth    => \$dumpvar::arrayDepth,
 964     CommandSet    => \$CommandSet,
 965     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 966     DumpPackages  => \$dumpvar::dumpPackages,
 967     DumpReused    => \$dumpvar::dumpReused,
 968     HighBit       => \$dumpvar::quoteHighBit,
 969     undefPrint    => \$dumpvar::printUndef,
 970     globPrint     => \$dumpvar::globPrint,
 971     UsageOnly     => \$dumpvar::usageOnly,
 972     CreateTTY     => \$CreateTTY,
 973     bareStringify => \$dumpvar::bareStringify,
 974     frame         => \$frame,
 975     AutoTrace     => \$trace,
 976     inhibit_exit  => \$inhibit_exit,
 977     maxTraceLen   => \$maxtrace,
 978     ImmediateStop => \$ImmediateStop,
 979     RemotePort    => \$remoteport,
 980     windowSize    => \$window,
 981     HistFile      => \$histfile,
 982     HistSize      => \$histsize,
 983 );
 984
 985 =pod
 986
 987 Third, C<%optionAction> defines the subroutine to be called to process each
 988 option.
 989
 990 =cut
 991
 992 use vars qw(%optionAction);
 993
 994 %optionAction = (
 995     compactDump   => \&dumpvar::compactDump,
 996     veryCompact   => \&dumpvar::veryCompact,
 997     quote         => \&dumpvar::quote,
 998     TTY           => \&TTY,
 999     noTTY         => \&noTTY,
1000     ReadLine      => \&ReadLine,
1001     NonStop       => \&NonStop,
1002     LineInfo      => \&LineInfo,
1003     recallCommand => \&recallCommand,
1004     ShellBang     => \&shellBang,
1005     pager         => \&pager,
1006     signalLevel   => \&signalLevel,
1007     warnLevel     => \&warnLevel,
1008     dieLevel      => \&dieLevel,
1009     tkRunning     => \&tkRunning,
1010     ornaments     => \&ornaments,
1011     RemotePort    => \&RemotePort,
1012     DollarCaretP  => \&DollarCaretP,
1013 );
1014
1015 =pod
1016
1017 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1018 option is used.
1019
1020 =cut
1021
1022 # Note that this list is not complete: several options not listed here
1023 # actually require that dumpvar.pl be loaded for them to work, but are
1024 # not in the table. A subsequent patch will correct this problem; for
1025 # the moment, we're just recommenting, and we are NOT going to change
1026 # function.
1027 use vars qw(%optionRequire);
1028
1029 %optionRequire = (
1030     compactDump => 'dumpvar.pl',
1031     veryCompact => 'dumpvar.pl',
1032     quote       => 'dumpvar.pl',
1033 );
1034
1035 =pod
1036
1037 There are a number of initialization-related variables which can be set
1038 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1039 variable. These are:
1040
1041 =over 4
1042
1043 =item C<$rl> - readline control XXX needs more explanation
1044
1045 =item C<$warnLevel> - whether or not debugger takes over warning handling
1046
1047 =item C<$dieLevel> - whether or not debugger takes over die handling
1048
1049 =item C<$signalLevel> - whether or not debugger takes over signal handling
1050
1051 =item C<$pre> - preprompt actions (array reference)
1052
1053 =item C<$post> - postprompt actions (array reference)
1054
1055 =item C<$pretype>
1056
1057 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1058
1059 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1060
1061 =back
1062
1063 =cut
1064
1065 # These guys may be defined in $ENV{PERL5DB} :
1066 $rl          = 1     unless defined $rl;
1067 $warnLevel   = 1     unless defined $warnLevel;
1068 $dieLevel    = 1     unless defined $dieLevel;
1069 $signalLevel = 1     unless defined $signalLevel;
1070 $pre         = []    unless defined $pre;
1071 $post        = []    unless defined $post;
1072 $pretype     = []    unless defined $pretype;
1073 $CreateTTY   = 3     unless defined $CreateTTY;
1074 $CommandSet  = '580' unless defined $CommandSet;
1075
1076 share($rl);
1077 share($warnLevel);
1078 share($dieLevel);
1079 share($signalLevel);
1080 share($pre);
1081 share($post);
1082 share($pretype);
1083 share($rl);
1084 share($CreateTTY);
1085 share($CommandSet);
1086
1087 =pod
1088
1089 The default C<die>, C<warn>, and C<signal> handlers are set up.
1090
1091 =cut
1092
1093 warnLevel($warnLevel);
1094 dieLevel($dieLevel);
1095 signalLevel($signalLevel);
1096
1097 =pod
1098
1099 The pager to be used is needed next. We try to get it from the
1100 environment first.  If it's not defined there, we try to find it in
1101 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1102 then call the C<pager()> function to save the pager name.
1103
1104 =cut
1105
1106 # This routine makes sure $pager is set up so that '|' can use it.
1107 pager(
1108
1109     # If PAGER is defined in the environment, use it.
1110     defined $ENV{PAGER}
1111     ? $ENV{PAGER}
1112
1113       # If not, see if Config.pm defines it.
1114     : eval { require Config }
1115       && defined $Config::Config{pager}
1116     ? $Config::Config{pager}
1117
1118       # If not, fall back to 'more'.
1119     : 'more'
1120   )
1121   unless defined $pager;
1122
1123 =pod
1124
1125 We set up the command to be used to access the man pages, the command
1126 recall character (C<!> unless otherwise defined) and the shell escape
1127 character (C<!> unless otherwise defined). Yes, these do conflict, and
1128 neither works in the debugger at the moment.
1129
1130 =cut
1131
1132 setman();
1133
1134 # Set up defaults for command recall and shell escape (note:
1135 # these currently don't work in linemode debugging).
1136 &recallCommand("!") unless defined $prc;
1137 &shellBang("!")     unless defined $psh;
1138
1139 =pod
1140
1141 We then set up the gigantic string containing the debugger help.
1142 We also set the limit on the number of arguments we'll display during a
1143 trace.
1144
1145 =cut
1146
1147 sethelp();
1148
1149 # If we didn't get a default for the length of eval/stack trace args,
1150 # set it here.
1151 $maxtrace = 400 unless defined $maxtrace;
1152
1153 =head2 SETTING UP THE DEBUGGER GREETING
1154
1155 The debugger I<greeting> helps to inform the user how many debuggers are
1156 running, and whether the current debugger is the primary or a child.
1157
1158 If we are the primary, we just hang onto our pid so we'll have it when
1159 or if we start a child debugger. If we are a child, we'll set things up
1160 so we'll have a unique greeting and so the parent will give us our own
1161 TTY later.
1162
1163 We save the current contents of the C<PERLDB_PIDS> environment variable
1164 because we mess around with it. We'll also need to hang onto it because
1165 we'll need it if we restart.
1166
1167 Child debuggers make a label out of the current PID structure recorded in
1168 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1169 yet so the parent will give them one later via C<resetterm()>.
1170
1171 =cut
1172
1173 # Save the current contents of the environment; we're about to
1174 # much with it. We'll need this if we have to restart.
1175 use vars qw($ini_pids);
1176 $ini_pids = $ENV{PERLDB_PIDS};
1177
1178 use vars qw ($pids $term_pid);
1179
1180 if ( defined $ENV{PERLDB_PIDS} ) {
1181
1182     # We're a child. Make us a label out of the current PID structure
1183     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1184     # a term yet so the parent will give us one later via resetterm().
1185
1186     my $env_pids = $ENV{PERLDB_PIDS};
1187     $pids = "[$env_pids]";
1188
1189     # Unless we are on OpenVMS, all programs under the DCL shell run under
1190     # the same PID.
1191
1192     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1193         $term_pid         = $$;
1194     }
1195     else {
1196         $ENV{PERLDB_PIDS} .= "->$$";
1197         $term_pid = -1;
1198     }
1199
1200 } ## end if (defined $ENV{PERLDB_PIDS...
1201 else {
1202
1203     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1204     # child debugger, and mark us as the parent, so we'll know to set up
1205     # more TTY's is we have to.
1206     $ENV{PERLDB_PIDS} = "$$";
1207     $pids             = "[pid=$$]";
1208     $term_pid         = $$;
1209 }
1210
1211 use vars qw($pidprompt);
1212 $pidprompt = '';
1213
1214 # Sets up $emacs as a synonym for $slave_editor.
1215 use vars qw($slave_editor);
1216 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1217
1218 =head2 READING THE RC FILE
1219
1220 The debugger will read a file of initialization options if supplied. If
1221 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1222
1223 =cut
1224
1225 # As noted, this test really doesn't check accurately that the debugger
1226 # is running at a terminal or not.
1227
1228 my $dev_tty = '/dev/tty';
1229    $dev_tty = 'TT:' if ($^O eq 'VMS');
1230 use vars qw($rcfile);
1231 if ( -e $dev_tty ) {                      # this is the wrong metric!
1232     $rcfile = ".perldb";
1233 }
1234 else {
1235     $rcfile = "perldb.ini";
1236 }
1237
1238 =pod
1239
1240 The debugger does a safety test of the file to be read. It must be owned
1241 either by the current user or root, and must only be writable by the owner.
1242
1243 =cut
1244
1245 # This wraps a safety test around "do" to read and evaluate the init file.
1246 #
1247 # This isn't really safe, because there's a race
1248 # between checking and opening.  The solution is to
1249 # open and fstat the handle, but then you have to read and
1250 # eval the contents.  But then the silly thing gets
1251 # your lexical scope, which is unfortunate at best.
1252 sub safe_do {
1253     my $file = shift;
1254
1255     # Just exactly what part of the word "CORE::" don't you understand?
1256     local $SIG{__WARN__};
1257     local $SIG{__DIE__};
1258
1259     unless ( is_safe_file($file) ) {
1260         CORE::warn <<EO_GRIPE;
1261 perldb: Must not source insecure rcfile $file.
1262         You or the superuser must be the owner, and it must not
1263         be writable by anyone but its owner.
1264 EO_GRIPE
1265         return;
1266     } ## end unless (is_safe_file($file...
1267
1268     do $file;
1269     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1270 } ## end sub safe_do
1271
1272 # This is the safety test itself.
1273 #
1274 # Verifies that owner is either real user or superuser and that no
1275 # one but owner may write to it.  This function is of limited use
1276 # when called on a path instead of upon a handle, because there are
1277 # no guarantees that filename (by dirent) whose file (by ino) is
1278 # eventually accessed is the same as the one tested.
1279 # Assumes that the file's existence is not in doubt.
1280 sub is_safe_file {
1281     my $path = shift;
1282     stat($path) || return;    # mysteriously vaporized
1283     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1284
1285     return 0 if $uid != 0 && $uid != $<;
1286     return 0 if $mode & 022;
1287     return 1;
1288 } ## end sub is_safe_file
1289
1290 # If the rcfile (whichever one we decided was the right one to read)
1291 # exists, we safely do it.
1292 if ( -f $rcfile ) {
1293     safe_do("./$rcfile");
1294 }
1295
1296 # If there isn't one here, try the user's home directory.
1297 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1298     safe_do("$ENV{HOME}/$rcfile");
1299 }
1300
1301 # Else try the login directory.
1302 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1303     safe_do("$ENV{LOGDIR}/$rcfile");
1304 }
1305
1306 # If the PERLDB_OPTS variable has options in it, parse those out next.
1307 if ( defined $ENV{PERLDB_OPTS} ) {
1308     parse_options( $ENV{PERLDB_OPTS} );
1309 }
1310
1311 =pod
1312
1313 The last thing we do during initialization is determine which subroutine is
1314 to be used to obtain a new terminal when a new debugger is started. Right now,
1315 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1316 (darwin).
1317
1318 =cut
1319
1320 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1321 # Works if you're running an xterm or xterm-like window, or you're on
1322 # OS/2, or on Mac OS X. This may need some expansion.
1323
1324 if (not defined &get_fork_TTY)       # only if no routine exists
1325 {
1326     if ( defined $remoteport ) {
1327                                                  # Expect an inetd-like server
1328         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1329     }
1330     elsif (defined $ENV{TERM}                    # If we know what kind
1331                                                  # of terminal this is,
1332         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1333         and defined $ENV{DISPLAY}                # and what display it's on,
1334       )
1335     {
1336         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1337     }
1338     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1339         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1340     }
1341     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1342             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1343             and $ENV{TERM_PROGRAM}
1344                 eq 'Apple_Terminal'              # Terminal.app
1345             )
1346     {
1347         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1348     }
1349 } ## end if (not defined &get_fork_TTY...
1350
1351 # untaint $^O, which may have been tainted by the last statement.
1352 # see bug [perl #24674]
1353 $^O =~ m/^(.*)\z/;
1354 $^O = $1;
1355
1356 # Here begin the unreadable code.  It needs fixing.
1357
1358 =head2 RESTART PROCESSING
1359
1360 This section handles the restart command. When the C<R> command is invoked, it
1361 tries to capture all of the state it can into environment variables, and
1362 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1363 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1364 the R command stuffed into the environment variables.
1365
1366   PERLDB_RESTART   - flag only, contains no restart data itself.
1367   PERLDB_HIST      - command history, if it's available
1368   PERLDB_ON_LOAD   - breakpoints set by the rc file
1369   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1370   PERLDB_VISITED   - files that had breakpoints
1371   PERLDB_FILE_...  - breakpoints for a file
1372   PERLDB_OPT       - active options
1373   PERLDB_INC       - the original @INC
1374   PERLDB_PRETYPE   - preprompt debugger actions
1375   PERLDB_PRE       - preprompt Perl code
1376   PERLDB_POST      - post-prompt Perl code
1377   PERLDB_TYPEAHEAD - typeahead captured by readline()
1378
1379 We chug through all these variables and plug the values saved in them
1380 back into the appropriate spots in the debugger.
1381
1382 =cut
1383
1384 use vars qw(@hist @truehist %postponed_file @typeahead);
1385
1386 if ( exists $ENV{PERLDB_RESTART} ) {
1387
1388     # We're restarting, so we don't need the flag that says to restart anymore.
1389     delete $ENV{PERLDB_RESTART};
1390
1391     # $restart = 1;
1392     @hist          = get_list('PERLDB_HIST');
1393     %break_on_load = get_list("PERLDB_ON_LOAD");
1394     %postponed     = get_list("PERLDB_POSTPONE");
1395
1396         share(@hist);
1397         share(@truehist);
1398         share(%break_on_load);
1399         share(%postponed);
1400
1401     # restore breakpoints/actions
1402     my @had_breakpoints = get_list("PERLDB_VISITED");
1403     for my $file_idx ( 0 .. $#had_breakpoints ) {
1404         my $filename = $had_breakpoints[$file_idx];
1405         my %pf = get_list("PERLDB_FILE_$file_idx");
1406         $postponed_file{ $filename } = \%pf if %pf;
1407         my @lines = sort {$a <=> $b} keys(%pf);
1408         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1409         for my $line_idx (0 .. $#lines) {
1410             _set_breakpoint_enabled_status(
1411                 $filename,
1412                 $lines[$line_idx],
1413                 ($enabled_statuses[$line_idx] ? 1 : ''),
1414             );
1415         }
1416     }
1417
1418     # restore options
1419     my %opt = get_list("PERLDB_OPT");
1420     my ( $opt, $val );
1421     while ( ( $opt, $val ) = each %opt ) {
1422         $val =~ s/[\\\']/\\$1/g;
1423         parse_options("$opt'$val'");
1424     }
1425
1426     # restore original @INC
1427     @INC     = get_list("PERLDB_INC");
1428     @ini_INC = @INC;
1429
1430     # return pre/postprompt actions and typeahead buffer
1431     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1432     $pre       = [ get_list("PERLDB_PRE") ];
1433     $post      = [ get_list("PERLDB_POST") ];
1434     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1435 } ## end if (exists $ENV{PERLDB_RESTART...
1436
1437 =head2 SETTING UP THE TERMINAL
1438
1439 Now, we'll decide how the debugger is going to interact with the user.
1440 If there's no TTY, we set the debugger to run non-stop; there's not going
1441 to be anyone there to enter commands.
1442
1443 =cut
1444
1445 use vars qw($notty $runnonstop $console $tty $LINEINFO);
1446 use vars qw($lineinfo $doccmd);
1447
1448 if ($notty) {
1449     $runnonstop = 1;
1450         share($runnonstop);
1451 }
1452
1453 =pod
1454
1455 If there is a TTY, we have to determine who it belongs to before we can
1456 proceed. If this is a slave editor or graphical debugger (denoted by
1457 the first command-line switch being '-emacs'), we shift this off and
1458 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1459
1460 =cut
1461
1462 else {
1463
1464     # Is Perl being run from a slave editor or graphical debugger?
1465     # If so, don't use readline, and set $slave_editor = 1.
1466     $slave_editor =
1467       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1468     $rl = 0, shift(@main::ARGV) if $slave_editor;
1469
1470     #require Term::ReadLine;
1471
1472 =pod
1473
1474 We then determine what the console should be on various systems:
1475
1476 =over 4
1477
1478 =item * Cygwin - We use C<stdin> instead of a separate device.
1479
1480 =cut
1481
1482     if ( $^O eq 'cygwin' ) {
1483
1484         # /dev/tty is binary. use stdin for textmode
1485         undef $console;
1486     }
1487
1488 =item * Unix - use C</dev/tty>.
1489
1490 =cut
1491
1492     elsif ( -e "/dev/tty" ) {
1493         $console = "/dev/tty";
1494     }
1495
1496 =item * Windows or MSDOS - use C<con>.
1497
1498 =cut
1499
1500     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1501         $console = "con";
1502     }
1503
1504 =item * VMS - use C<sys$command>.
1505
1506 =cut
1507
1508     else {
1509
1510         # everything else is ...
1511         $console = "sys\$command";
1512     }
1513
1514 =pod
1515
1516 =back
1517
1518 Several other systems don't use a specific console. We C<undef $console>
1519 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1520 with a slave editor, Epoc).
1521
1522 =cut
1523
1524     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1525
1526         # /dev/tty is binary. use stdin for textmode
1527         $console = undef;
1528     }
1529
1530     if ( $^O eq 'NetWare' ) {
1531
1532         # /dev/tty is binary. use stdin for textmode
1533         $console = undef;
1534     }
1535
1536     # In OS/2, we need to use STDIN to get textmode too, even though
1537     # it pretty much looks like Unix otherwise.
1538     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1539     {    # In OS/2
1540         $console = undef;
1541     }
1542
1543     # EPOC also falls into the 'got to use STDIN' camp.
1544     if ( $^O eq 'epoc' ) {
1545         $console = undef;
1546     }
1547
1548 =pod
1549
1550 If there is a TTY hanging around from a parent, we use that as the console.
1551
1552 =cut
1553
1554     $console = $tty if defined $tty;
1555
1556 =head2 SOCKET HANDLING
1557
1558 The debugger is capable of opening a socket and carrying out a debugging
1559 session over the socket.
1560
1561 If C<RemotePort> was defined in the options, the debugger assumes that it
1562 should try to start a debugging session on that port. It builds the socket
1563 and then tries to connect the input and output filehandles to it.
1564
1565 =cut
1566
1567     # Handle socket stuff.
1568
1569     if ( defined $remoteport ) {
1570
1571         # If RemotePort was defined in the options, connect input and output
1572         # to the socket.
1573         $IN = $OUT = connect_remoteport();
1574     } ## end if (defined $remoteport)
1575
1576 =pod
1577
1578 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1579 this is probably a situation where multiple debuggers are running (for example,
1580 a backticked command that starts up another debugger). We create a new IN and
1581 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1582 and if we can.
1583
1584 =cut
1585
1586     # Non-socket.
1587     else {
1588
1589         # Two debuggers running (probably a system or a backtick that invokes
1590         # the debugger itself under the running one). create a new IN and OUT
1591         # filehandle, and do the necessary mojo to create a new tty if we
1592         # know how, and we can.
1593         create_IN_OUT(4) if $CreateTTY & 4;
1594         if ($console) {
1595
1596             # If we have a console, check to see if there are separate ins and
1597             # outs to open. (They are assumed identical if not.)
1598
1599             my ( $i, $o ) = split /,/, $console;
1600             $o = $i unless defined $o;
1601
1602             # read/write on in, or just read, or read on STDIN.
1603             open( IN,      "+<$i" )
1604               || open( IN, "<$i" )
1605               || open( IN, "<&STDIN" );
1606
1607             # read/write/create/clobber out, or write/create/clobber out,
1608             # or merge with STDERR, or merge with STDOUT.
1609                  open( OUT, "+>$o" )
1610               || open( OUT, ">$o" )
1611               || open( OUT, ">&STDERR" )
1612               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1613
1614         } ## end if ($console)
1615         elsif ( not defined $console ) {
1616
1617             # No console. Open STDIN.
1618             open( IN, "<&STDIN" );
1619
1620             # merge with STDERR, or with STDOUT.
1621             open( OUT,      ">&STDERR" )
1622               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1623             $console = 'STDIN/OUT';
1624         } ## end elsif (not defined $console)
1625
1626         # Keep copies of the filehandles so that when the pager runs, it
1627         # can close standard input without clobbering ours.
1628         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1629     } ## end elsif (from if(defined $remoteport))
1630
1631     # Unbuffer DB::OUT. We need to see responses right away.
1632     my $previous = select($OUT);
1633     $| = 1;                                  # for DB::OUT
1634     select($previous);
1635
1636     # Line info goes to debugger output unless pointed elsewhere.
1637     # Pointing elsewhere makes it possible for slave editors to
1638     # keep track of file and position. We have both a filehandle
1639     # and a I/O description to keep track of.
1640     $LINEINFO = $OUT     unless defined $LINEINFO;
1641     $lineinfo = $console unless defined $lineinfo;
1642         # share($LINEINFO); # <- unable to share globs
1643         share($lineinfo);   #
1644
1645 =pod
1646
1647 To finish initialization, we show the debugger greeting,
1648 and then call the C<afterinit()> subroutine if there is one.
1649
1650 =cut
1651
1652     # Show the debugger greeting.
1653     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1654     unless ($runnonstop) {
1655         local $\ = '';
1656         local $, = '';
1657         if ( $term_pid eq '-1' ) {
1658             print $OUT "\nDaughter DB session started...\n";
1659         }
1660         else {
1661             print $OUT "\nLoading DB routines from $header\n";
1662             print $OUT (
1663                 "Editor support ",
1664                 $slave_editor ? "enabled" : "available", ".\n"
1665             );
1666             print $OUT
1667 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1668         } ## end else [ if ($term_pid eq '-1')
1669     } ## end unless ($runnonstop)
1670 } ## end else [ if ($notty)
1671
1672 # XXX This looks like a bug to me.
1673 # Why copy to @ARGS and then futz with @args?
1674 @ARGS = @ARGV;
1675 # for (@args) {
1676     # Make sure backslashes before single quotes are stripped out, and
1677     # keep args unless they are numeric (XXX why?)
1678     # s/\'/\\\'/g;                      # removed while not justified understandably
1679     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1680 # }
1681
1682 # If there was an afterinit() sub defined, call it. It will get
1683 # executed in our scope, so it can fiddle with debugger globals.
1684 if ( defined &afterinit ) {    # May be defined in $rcfile
1685     &afterinit();
1686 }
1687
1688 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1689 use vars qw($I_m_init);
1690
1691 $I_m_init = 1;
1692
1693 ############################################################ Subroutines
1694
1695 =head1 SUBROUTINES
1696
1697 =head2 DB
1698
1699 This gigantic subroutine is the heart of the debugger. Called before every
1700 statement, its job is to determine if a breakpoint has been reached, and
1701 stop if so; read commands from the user, parse them, and execute
1702 them, and then send execution off to the next statement.
1703
1704 Note that the order in which the commands are processed is very important;
1705 some commands earlier in the loop will actually alter the C<$cmd> variable
1706 to create other commands to be executed later. This is all highly I<optimized>
1707 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1708 see what's happening in any given command.
1709
1710 =cut
1711
1712 use vars qw(
1713     $action
1714     %alias
1715     $cmd
1716     $doret
1717     $fall_off_end
1718     $file
1719     $filename_ini
1720     $finished
1721     %had_breakpoints
1722     $incr
1723     $laststep
1724     $level
1725     $max
1726     @old_watch
1727     $package
1728     $rc
1729     $sh
1730     @stack
1731     $stack_depth
1732     @to_watch
1733     $try
1734     $end
1735 );
1736
1737 sub DB {
1738
1739     # lock the debugger and get the thread id for the prompt
1740         lock($DBGR);
1741         my $tid;
1742         my $position;
1743         my ($prefix, $after, $infix);
1744         my $pat;
1745
1746         if ($ENV{PERL5DB_THREADED}) {
1747                 $tid = eval { "[".threads->tid."]" };
1748         }
1749
1750     # Check for whether we should be running continuously or not.
1751     # _After_ the perl program is compiled, $single is set to 1:
1752     if ( $single and not $second_time++ ) {
1753
1754         # Options say run non-stop. Run until we get an interrupt.
1755         if ($runnonstop) {    # Disable until signal
1756                 # If there's any call stack in place, turn off single
1757                 # stepping into subs throughout the stack.
1758             for my $i (0 .. $stack_depth) {
1759                 $stack[ $i ] &= ~1;
1760             }
1761
1762             # And we are now no longer in single-step mode.
1763             $single = 0;
1764
1765             # If we simply returned at this point, we wouldn't get
1766             # the trace info. Fall on through.
1767             # return;
1768         } ## end if ($runnonstop)
1769
1770         elsif ($ImmediateStop) {
1771
1772             # We are supposed to stop here; XXX probably a break.
1773             $ImmediateStop = 0;    # We've processed it; turn it off
1774             $signal        = 1;    # Simulate an interrupt to force
1775                                    # us into the command loop
1776         }
1777     } ## end if ($single and not $second_time...
1778
1779     # If we're in single-step mode, or an interrupt (real or fake)
1780     # has occurred, turn off non-stop mode.
1781     $runnonstop = 0 if $single or $signal;
1782
1783     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1784     # The code being debugged may have altered them.
1785     &save;
1786
1787     # Since DB::DB gets called after every line, we can use caller() to
1788     # figure out where we last were executing. Sneaky, eh? This works because
1789     # caller is returning all the extra information when called from the
1790     # debugger.
1791     local ( $package, $filename, $line ) = caller;
1792     $filename_ini = $filename;
1793
1794     # set up the context for DB::eval, so it can properly execute
1795     # code on behalf of the user. We add the package in so that the
1796     # code is eval'ed in the proper package (not in the debugger!).
1797     local $usercontext = _calc_usercontext($package);
1798
1799     # Create an alias to the active file magical array to simplify
1800     # the code here.
1801     local (*dbline) = $main::{ '_<' . $filename };
1802
1803     # Last line in the program.
1804     $max = $#dbline;
1805
1806     # if we have something here, see if we should break.
1807     {
1808         # $stop is lexical and local to this block - $action on the other hand
1809         # is global.
1810         my $stop;
1811
1812         if ( $dbline{$line}
1813             && _is_breakpoint_enabled($filename, $line)
1814             && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1815         {
1816
1817             # Stop if the stop criterion says to just stop.
1818             if ( $stop eq '1' ) {
1819                 $signal |= 1;
1820             }
1821
1822             # It's a conditional stop; eval it in the user's context and
1823             # see if we should stop. If so, remove the one-time sigil.
1824             elsif ($stop) {
1825                 $evalarg = "\$DB::signal |= 1 if do {$stop}";
1826                 &eval;
1827                 # If the breakpoint is temporary, then delete its enabled status.
1828                 if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1829                     _cancel_breakpoint_temp_enabled_status($filename, $line);
1830                 }
1831             }
1832         } ## end if ($dbline{$line} && ...
1833     }
1834
1835     # Preserve the current stop-or-not, and see if any of the W
1836     # (watch expressions) has changed.
1837     my $was_signal = $signal;
1838
1839     # If we have any watch expressions ...
1840     if ( $trace & 2 ) {
1841         for my $n (0 .. $#to_watch) {
1842             $evalarg = $to_watch[$n];
1843             local $onetimeDump;    # Tell DB::eval() to not output results
1844
1845             # Fix context DB::eval() wants to return an array, but
1846             # we need a scalar here.
1847             my ($val) = join( "', '", &eval );
1848             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1849
1850             # Did it change?
1851             if ( $val ne $old_watch[$n] ) {
1852
1853                 # Yep! Show the difference, and fake an interrupt.
1854                 $signal = 1;
1855                 print $OUT <<EOP;
1856 Watchpoint $n:\t$to_watch[$n] changed:
1857     old value:\t$old_watch[$n]
1858     new value:\t$val
1859 EOP
1860                 $old_watch[$n] = $val;
1861             } ## end if ($val ne $old_watch...
1862         } ## end for my $n (0 ..
1863     } ## end if ($trace & 2)
1864
1865 =head2 C<watchfunction()>
1866
1867 C<watchfunction()> is a function that can be defined by the user; it is a
1868 function which will be run on each entry to C<DB::DB>; it gets the
1869 current package, filename, and line as its parameters.
1870
1871 The watchfunction can do anything it likes; it is executing in the
1872 debugger's context, so it has access to all of the debugger's internal
1873 data structures and functions.
1874
1875 C<watchfunction()> can control the debugger's actions. Any of the following
1876 will cause the debugger to return control to the user's program after
1877 C<watchfunction()> executes:
1878
1879 =over 4
1880
1881 =item *
1882
1883 Returning a false value from the C<watchfunction()> itself.
1884
1885 =item *
1886
1887 Altering C<$single> to a false value.
1888
1889 =item *
1890
1891 Altering C<$signal> to a false value.
1892
1893 =item *
1894
1895 Turning off the C<4> bit in C<$trace> (this also disables the
1896 check for C<watchfunction()>. This can be done with
1897
1898     $trace &= ~4;
1899
1900 =back
1901
1902 =cut
1903
1904     # If there's a user-defined DB::watchfunction, call it with the
1905     # current package, filename, and line. The function executes in
1906     # the DB:: package.
1907     if ( $trace & 4 ) {    # User-installed watch
1908         return
1909           if watchfunction( $package, $filename, $line )
1910           and not $single
1911           and not $was_signal
1912           and not( $trace & ~4 );
1913     } ## end if ($trace & 4)
1914
1915     # Pick up any alteration to $signal in the watchfunction, and
1916     # turn off the signal now.
1917     $was_signal = $signal;
1918     $signal     = 0;
1919
1920 =head2 GETTING READY TO EXECUTE COMMANDS
1921
1922 The debugger decides to take control if single-step mode is on, the
1923 C<t> command was entered, or the user generated a signal. If the program
1924 has fallen off the end, we set things up so that entering further commands
1925 won't cause trouble, and we say that the program is over.
1926
1927 =cut
1928
1929     # Make sure that we always print if asked for explicitly regardless
1930     # of $trace_to_depth .
1931     my $explicit_stop = ($single || $was_signal);
1932
1933     # Check to see if we should grab control ($single true,
1934     # trace set appropriately, or we got a signal).
1935     if ( $explicit_stop || ( $trace & 1 ) ) {
1936
1937         # Yes, grab control.
1938         if ($slave_editor) {
1939
1940             # Tell the editor to update its position.
1941             $position = "\032\032$filename:$line:0\n";
1942             print_lineinfo($position);
1943         }
1944
1945 =pod
1946
1947 Special check: if we're in package C<DB::fake>, we've gone through the
1948 C<END> block at least once. We set up everything so that we can continue
1949 to enter commands and have a valid context to be in.
1950
1951 =cut
1952
1953         elsif ( $package eq 'DB::fake' ) {
1954
1955             # Fallen off the end already.
1956             $term || &setterm;
1957             print_help(<<EOP);
1958 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
1959   use B<o> I<inhibit_exit> to avoid stopping after program termination,
1960   B<h q>, B<h R> or B<h o> to get additional info.
1961 EOP
1962
1963             # Set the DB::eval context appropriately.
1964             $package     = 'main';
1965             $usercontext = _calc_usercontext($package);
1966         } ## end elsif ($package eq 'DB::fake')
1967
1968 =pod
1969
1970 If the program hasn't finished executing, we scan forward to the
1971 next executable line, print that out, build the prompt from the file and line
1972 number information, and print that.
1973
1974 =cut
1975
1976         else {
1977
1978
1979             # Still somewhere in the midst of execution. Set up the
1980             #  debugger prompt.
1981             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
1982                                  # Perl 5 ones (sorry, we don't print Klingon
1983                                  #module names)
1984
1985             $prefix = $sub =~ /::/ ? "" : ($package . '::');
1986             $prefix .= "$sub($filename:";
1987             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
1988
1989             # Break up the prompt if it's really long.
1990             if ( length($prefix) > 30 ) {
1991                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
1992                 $prefix   = "";
1993                 $infix    = ":\t";
1994             }
1995             else {
1996                 $infix    = "):\t";
1997                 $position = "$prefix$line$infix$dbline[$line]$after";
1998             }
1999
2000             # Print current line info, indenting if necessary.
2001             if ($frame) {
2002                 print_lineinfo( ' ' x $stack_depth,
2003                     "$line:\t$dbline[$line]$after" );
2004             }
2005             else {
2006                 depth_print_lineinfo($explicit_stop, $position);
2007             }
2008
2009             # Scan forward, stopping at either the end or the next
2010             # unbreakable line.
2011             for ( my $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2012             {    #{ vi
2013
2014                 # Drop out on null statements, block closers, and comments.
2015                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2016
2017                 # Drop out if the user interrupted us.
2018                 last if $signal;
2019
2020                 # Append a newline if the line doesn't have one. Can happen
2021                 # in eval'ed text, for instance.
2022                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2023
2024                 # Next executable line.
2025                 my $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2026                 $position .= $incr_pos;
2027                 if ($frame) {
2028
2029                     # Print it indented if tracing is on.
2030                     print_lineinfo( ' ' x $stack_depth,
2031                         "$i:\t$dbline[$i]$after" );
2032                 }
2033                 else {
2034                     depth_print_lineinfo($explicit_stop, $incr_pos);
2035                 }
2036             } ## end for ($i = $line + 1 ; $i...
2037         } ## end else [ if ($slave_editor)
2038     } ## end if ($single || ($trace...
2039
2040 =pod
2041
2042 If there's an action to be executed for the line we stopped at, execute it.
2043 If there are any preprompt actions, execute those as well.
2044
2045 =cut
2046
2047     # If there's an action, do it now.
2048     $evalarg = $action, &eval if $action;
2049
2050     # Are we nested another level (e.g., did we evaluate a function
2051     # that had a breakpoint in it at the debugger prompt)?
2052     if ( $single || $was_signal ) {
2053
2054         # Yes, go down a level.
2055         local $level = $level + 1;
2056
2057         # Do any pre-prompt actions.
2058         foreach $evalarg (@$pre) {
2059             &eval;
2060         }
2061
2062         # Complain about too much recursion if we passed the limit.
2063         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2064           if $single & 4;
2065
2066         # The line we're currently on. Set $incr to -1 to stay here
2067         # until we get a command that tells us to advance.
2068         $start = $line;
2069         $incr  = -1;      # for backward motion.
2070
2071         # Tack preprompt debugger actions ahead of any actual input.
2072         @typeahead = ( @$pretype, @typeahead );
2073
2074 =head2 WHERE ARE WE?
2075
2076 XXX Relocate this section?
2077
2078 The debugger normally shows the line corresponding to the current line of
2079 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2080 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2081
2082 C<$incr> controls by how many lines the I<current> line should move forward
2083 after a command is executed. If set to -1, this indicates that the I<current>
2084 line shouldn't change.
2085
2086 C<$start> is the I<current> line. It is used for things like knowing where to
2087 move forwards or backwards from when doing an C<L> or C<-> command.
2088
2089 C<$max> tells the debugger where the last line of the current file is. It's
2090 used to terminate loops most often.
2091
2092 =head2 THE COMMAND LOOP
2093
2094 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2095 in two parts:
2096
2097 =over 4
2098
2099 =item *
2100
2101 The outer part of the loop, starting at the C<CMD> label. This loop
2102 reads a command and then executes it.
2103
2104 =item *
2105
2106 The inner part of the loop, starting at the C<PIPE> label. This part
2107 is wholly contained inside the C<CMD> block and only executes a command.
2108 Used to handle commands running inside a pager.
2109
2110 =back
2111
2112 So why have two labels to restart the loop? Because sometimes, it's easier to
2113 have a command I<generate> another command and then re-execute the loop to do
2114 the new command. This is faster, but perhaps a bit more convoluted.
2115
2116 =cut
2117
2118         # The big command dispatch loop. It keeps running until the
2119         # user yields up control again.
2120         #
2121         # If we have a terminal for input, and we get something back
2122         # from readline(), keep on processing.
2123         my $piped;
2124         my $selected;
2125
2126       CMD:
2127         while (
2128
2129             # We have a terminal, or can get one ...
2130             ( $term || &setterm ),
2131
2132             # ... and it belogs to this PID or we get one for this PID ...
2133             ( $term_pid == $$ or resetterm(1) ),
2134
2135             # ... and we got a line of command input ...
2136             defined(
2137                 $cmd = &readline(
2138                         "$pidprompt $tid DB"
2139                       . ( '<' x $level )
2140                       . ( $#hist + 1 )
2141                       . ( '>' x $level ) . " "
2142                 )
2143             )
2144           )
2145         {
2146
2147                         share($cmd);
2148             # ... try to execute the input as debugger commands.
2149
2150             # Don't stop running.
2151             $single = 0;
2152
2153             # No signal is active.
2154             $signal = 0;
2155
2156             # Handle continued commands (ending with \):
2157             $cmd =~ s/\\$/\n/ && do {
2158                 $cmd .= &readline("  cont: ");
2159                 redo CMD;
2160             };
2161
2162 =head4 The null command
2163
2164 A newline entered by itself means I<re-execute the last command>. We grab the
2165 command out of C<$laststep> (where it was recorded previously), and copy it
2166 back into C<$cmd> to be executed below. If there wasn't any previous command,
2167 we'll do nothing below (no command will match). If there was, we also save it
2168 in the command history and fall through to allow the command parsing to pick
2169 it up.
2170
2171 =cut
2172
2173             # Empty input means repeat the last command.
2174             $cmd =~ /^$/ && ( $cmd = $laststep );
2175             chomp($cmd);    # get rid of the annoying extra newline
2176             push( @hist, $cmd ) if length($cmd) > 1;
2177             push( @truehist, $cmd );
2178                         share(@hist);
2179                         share(@truehist);
2180
2181             # This is a restart point for commands that didn't arrive
2182             # via direct user input. It allows us to 'redo PIPE' to
2183             # re-execute command processing without reading a new command.
2184           PIPE: {
2185                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2186                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2187                 my ($i) = split( /\s+/, $cmd );
2188
2189 =head3 COMMAND ALIASES
2190
2191 The debugger can create aliases for commands (these are stored in the
2192 C<%alias> hash). Before a command is executed, the command loop looks it up
2193 in the alias hash and substitutes the contents of the alias for the command,
2194 completely replacing it.
2195
2196 =cut
2197
2198                 # See if there's an alias for the command, and set it up if so.
2199                 if ( $alias{$i} ) {
2200
2201                     # Squelch signal handling; we want to keep control here
2202                     # if something goes loco during the alias eval.
2203                     local $SIG{__DIE__};
2204                     local $SIG{__WARN__};
2205
2206                     # This is a command, so we eval it in the DEBUGGER's
2207                     # scope! Otherwise, we can't see the special debugger
2208                     # variables, or get to the debugger's subs. (Well, we
2209                     # _could_, but why make it even more complicated?)
2210                     eval "\$cmd =~ $alias{$i}";
2211                     if ($@) {
2212                         local $\ = '';
2213                         print $OUT "Couldn't evaluate '$i' alias: $@";
2214                         next CMD;
2215                     }
2216                 } ## end if ($alias{$i})
2217
2218 =head3 MAIN-LINE COMMANDS
2219
2220 All of these commands work up to and after the program being debugged has
2221 terminated.
2222
2223 =head4 C<q> - quit
2224
2225 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2226 try to execute further, cleaning any restart-related stuff out of the
2227 environment, and executing with the last value of C<$?>.
2228
2229 =cut
2230
2231                 $cmd =~ /^q$/ && do {
2232                     $fall_off_end = 1;
2233                     clean_ENV();
2234                     exit $?;
2235                 };
2236
2237 =head4 C<t> - trace [n]
2238
2239 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2240 If level is specified, set C<$trace_to_depth>.
2241
2242 =cut
2243
2244                 $cmd =~ /^t(?:\s+(\d+))?$/ && do {
2245                     my $levels = $1;
2246                     $trace ^= 1;
2247                     local $\ = '';
2248                     $trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
2249                     print $OUT "Trace = "
2250                       . ( ( $trace & 1 )
2251                       ? ( $levels ? "on (to level $trace_to_depth)" : "on" )
2252                       : "off" ) . "\n";
2253                     next CMD;
2254                 };
2255
2256 =head4 C<S> - list subroutines matching/not matching a pattern
2257
2258 Walks through C<%sub>, checking to see whether or not to print the name.
2259
2260 =cut
2261
2262                 $cmd =~ /^S(\s+(!)?(.+))?$/ && do {
2263
2264                     my $Srev     = defined $2;     # Reverse scan?
2265                     my $Spatt    = $3;             # The pattern (if any) to use.
2266                     my $Snocheck = !defined $1;    # No args - print all subs.
2267
2268                     # Need to make these sane here.
2269                     local $\ = '';
2270                     local $, = '';
2271
2272                     # Search through the debugger's magical hash of subs.
2273                     # If $nocheck is true, just print the sub name.
2274                     # Otherwise, check it against the pattern. We then use
2275                     # the XOR trick to reverse the condition as required.
2276                     foreach $subname ( sort( keys %sub ) ) {
2277                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2278                             print $OUT $subname, "\n";
2279                         }
2280                     }
2281                     next CMD;
2282                 };
2283
2284 =head4 C<X> - list variables in current package
2285
2286 Since the C<V> command actually processes this, just change this to the
2287 appropriate C<V> command and fall through.
2288
2289 =cut
2290
2291                 $cmd =~ s/^X\b/V $package/;
2292
2293 =head4 C<V> - list variables
2294
2295 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2296
2297 =cut
2298
2299                 # Bare V commands get the currently-being-debugged package
2300                 # added.
2301                 $cmd =~ /^V$/ && do {
2302                     $cmd = "V $package";
2303                 };
2304
2305                 # V - show variables in package.
2306                 $cmd =~ /^V\b\s*(\S+)\s*(.*)/ && do {
2307
2308                     # Save the currently selected filehandle and
2309                     # force output to debugger's filehandle (dumpvar
2310                     # just does "print" for output).
2311                     my $savout = select($OUT);
2312
2313                     # Grab package name and variables to dump.
2314                     $packname = $1;
2315                     my @vars     = split( ' ', $2 );
2316
2317                     # If main::dumpvar isn't here, get it.
2318                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2319                     if ( defined &main::dumpvar ) {
2320
2321                         # We got it. Turn off subroutine entry/exit messages
2322                         # for the moment, along with return values.
2323                         local $frame = 0;
2324                         local $doret = -2;
2325
2326                         # must detect sigpipe failures  - not catching
2327                         # then will cause the debugger to die.
2328                         eval {
2329                             &main::dumpvar(
2330                                 $packname,
2331                                 defined $option{dumpDepth}
2332                                 ? $option{dumpDepth}
2333                                 : -1,    # assume -1 unless specified
2334                                 @vars
2335                             );
2336                         };
2337
2338                         # The die doesn't need to include the $@, because
2339                         # it will automatically get propagated for us.
2340                         if ($@) {
2341                             die unless $@ =~ /dumpvar print failed/;
2342                         }
2343                     } ## end if (defined &main::dumpvar)
2344                     else {
2345
2346                         # Couldn't load dumpvar.
2347                         print $OUT "dumpvar.pl not available.\n";
2348                     }
2349
2350                     # Restore the output filehandle, and go round again.
2351                     select($savout);
2352                     next CMD;
2353                 };
2354
2355 =head4 C<x> - evaluate and print an expression
2356
2357 Hands the expression off to C<DB::eval>, setting it up to print the value
2358 via C<dumpvar.pl> instead of just printing it directly.
2359
2360 =cut
2361
2362                 $cmd =~ s/^x\b/ / && do {    # Remainder gets done by DB::eval()
2363                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2364
2365                     # handle special  "x 3 blah" syntax XXX propagate
2366                     # doc back to special variables.
2367                     if ( $cmd =~ s/^\s*(\d+)(?=\s)/ / ) {
2368                         $onetimedumpDepth = $1;
2369                     }
2370                 };
2371
2372 =head4 C<m> - print methods
2373
2374 Just uses C<DB::methods> to determine what methods are available.
2375
2376 =cut
2377
2378                 $cmd =~ s/^m\s+([\w:]+)\s*$/ / && do {
2379                     methods($1);
2380                     next CMD;
2381                 };
2382
2383                 # m expr - set up DB::eval to do the work
2384                 $cmd =~ s/^m\b/ / && do {    # Rest gets done by DB::eval()
2385                     $onetimeDump = 'methods';   #  method output gets used there
2386                 };
2387
2388 =head4 C<f> - switch files
2389
2390 =cut
2391
2392                 $cmd =~ /^f\b\s*(.*)/ && do {
2393                     $file = $1;
2394                     $file =~ s/\s+$//;
2395
2396                     # help for no arguments (old-style was return from sub).
2397                     if ( !$file ) {
2398                         print $OUT
2399                           "The old f command is now the r command.\n";    # hint
2400                         print $OUT "The new f command switches filenames.\n";
2401                         next CMD;
2402                     } ## end if (!$file)
2403
2404                     # if not in magic file list, try a close match.
2405                     if ( !defined $main::{ '_<' . $file } ) {
2406                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2407                             {
2408                                 $try = substr( $try, 2 );
2409                                 print $OUT "Choosing $try matching '$file':\n";
2410                                 $file = $try;
2411                             }
2412                         } ## end if (($try) = grep(m#^_<.*$file#...
2413                     } ## end if (!defined $main::{ ...
2414
2415                     # If not successfully switched now, we failed.
2416                     if ( !defined $main::{ '_<' . $file } ) {
2417                         print $OUT "No file matching '$file' is loaded.\n";
2418                         next CMD;
2419                     }
2420
2421                     # We switched, so switch the debugger internals around.
2422                     elsif ( $file ne $filename ) {
2423                         *dbline   = $main::{ '_<' . $file };
2424                         $max      = $#dbline;
2425                         $filename = $file;
2426                         $start    = 1;
2427                         $cmd      = "l";
2428                     } ## end elsif ($file ne $filename)
2429
2430                     # We didn't switch; say we didn't.
2431                     else {
2432                         print $OUT "Already in $file.\n";
2433                         next CMD;
2434                     }
2435                 };
2436
2437 =head4 C<.> - return to last-executed line.
2438
2439 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2440 and then we look up the line in the magical C<%dbline> hash.
2441
2442 =cut
2443
2444                 # . command.
2445                 $cmd =~ /^\.$/ && do {
2446                     $incr = -1;    # stay at current line
2447
2448                     # Reset everything to the old location.
2449                     $start    = $line;
2450                     $filename = $filename_ini;
2451                     *dbline   = $main::{ '_<' . $filename };
2452                     $max      = $#dbline;
2453
2454                     # Now where are we?
2455                     print_lineinfo($position);
2456                     next CMD;
2457                 };
2458
2459 =head4 C<-> - back one window
2460
2461 We change C<$start> to be one window back; if we go back past the first line,
2462 we set it to be the first line. We ser C<$incr> to put us back at the
2463 currently-executing line, and then put a C<l $start +> (list one window from
2464 C<$start>) in C<$cmd> to be executed later.
2465
2466 =cut
2467
2468                 # - - back a window.
2469                 $cmd =~ /^-$/ && do {
2470
2471                     # back up by a window; go to 1 if back too far.
2472                     $start -= $incr + $window + 1;
2473                     $start = 1 if $start <= 0;
2474                     $incr  = $window - 1;
2475
2476                     # Generate and execute a "l +" command (handled below).
2477                     $cmd = 'l ' . ($start) . '+';
2478                 };
2479
2480 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2481
2482 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2483 problems, most notably that the default case of several commands destroying
2484 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2485 retain the old commands for those who were used to using them or who preferred
2486 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2487 deal with them instead of processing them in-line.
2488
2489 =cut
2490
2491                 # All of these commands were remapped in perl 5.8.0;
2492                 # we send them off to the secondary dispatcher (see below).
2493                 $cmd =~ /^([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so && do {
2494                     &cmd_wrapper( $1, $2, $line );
2495                     next CMD;
2496                 };
2497
2498 =head4 C<y> - List lexicals in higher scope
2499
2500 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2501 above the current one and then displays then using C<dumpvar.pl>.
2502
2503 =cut
2504
2505                 $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/ && do {
2506
2507                     # See if we've got the necessary support.
2508                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2509                       or &warn(
2510                         $@ =~ /locate/
2511                         ? "PadWalker module not found - please install\n"
2512                         : $@
2513                       )
2514                       and next CMD;
2515
2516                     # Load up dumpvar if we don't have it. If we can, that is.
2517                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2518                     defined &main::dumpvar
2519                       or print $OUT "dumpvar.pl not available.\n"
2520                       and next CMD;
2521
2522                     # Got all the modules we need. Find them and print them.
2523                     my @vars = split( ' ', $2 || '' );
2524
2525                     # Find the pad.
2526                     my $h = eval { PadWalker::peek_my( ( $1 || 0 ) + 1 ) };
2527
2528                     # Oops. Can't find it.
2529                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2530
2531                     # Show the desired vars with dumplex().
2532                     my $savout = select($OUT);
2533
2534                     # Have dumplex dump the lexicals.
2535                     dumpvar::dumplex( $_, $h->{$_},
2536                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2537                         @vars )
2538                       for sort keys %$h;
2539                     select($savout);
2540                     next CMD;
2541                 };
2542
2543 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2544
2545 All of the commands below this point don't work after the program being
2546 debugged has ended. All of them check to see if the program has ended; this
2547 allows the commands to be relocated without worrying about a 'line of
2548 demarcation' above which commands can be entered anytime, and below which
2549 they can't.
2550
2551 =head4 C<n> - single step, but don't trace down into subs
2552
2553 Done by setting C<$single> to 2, which forces subs to execute straight through
2554 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2555 so a null command knows what to re-execute.
2556
2557 =cut
2558
2559                 # n - next
2560                 $cmd =~ /^n$/ && do {
2561                     end_report(), next CMD if $finished and $level <= 1;
2562
2563                     # Single step, but don't enter subs.
2564                     $single = 2;
2565
2566                     # Save for empty command (repeat last).
2567                     $laststep = $cmd;
2568                     last CMD;
2569                 };
2570
2571 =head4 C<s> - single-step, entering subs
2572
2573 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2574 subs. Also saves C<s> as C<$lastcmd>.
2575
2576 =cut
2577
2578                 # s - single step.
2579                 $cmd =~ /^s$/ && do {
2580
2581                     # Get out and restart the command loop if program
2582                     # has finished.
2583                     end_report(), next CMD if $finished and $level <= 1;
2584
2585                     # Single step should enter subs.
2586                     $single = 1;
2587
2588                     # Save for empty command (repeat last).
2589                     $laststep = $cmd;
2590                     last CMD;
2591                 };
2592
2593 =head4 C<c> - run continuously, setting an optional breakpoint
2594
2595 Most of the code for this command is taken up with locating the optional
2596 breakpoint, which is either a subroutine name or a line number. We set
2597 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2598 in this and all call levels above this one.
2599
2600 =cut
2601
2602                 # c - start continuous execution.
2603                 $cmd =~ /^c\b\s*([\w:]*)\s*$/ && do {
2604
2605                     # Hey, show's over. The debugged program finished
2606                     # executing already.
2607                     end_report(), next CMD if $finished and $level <= 1;
2608
2609                     # Capture the place to put a one-time break.
2610                     $subname = $i = $1;
2611
2612                     #  Probably not needed, since we finish an interactive
2613                     #  sub-session anyway...
2614                     # local $filename = $filename;
2615                     # local *dbline = *dbline; # XXX Would this work?!
2616                     #
2617                     # The above question wonders if localizing the alias
2618                     # to the magic array works or not. Since it's commented
2619                     # out, we'll just leave that to speculation for now.
2620
2621                     # If the "subname" isn't all digits, we'll assume it
2622                     # is a subroutine name, and try to find it.
2623                     if ( $subname =~ /\D/ ) {    # subroutine name
2624                             # Qualify it to the current package unless it's
2625                             # already qualified.
2626                         $subname = $package . "::" . $subname
2627                           unless $subname =~ /::/;
2628
2629                         # find_sub will return "file:line_number" corresponding
2630                         # to where the subroutine is defined; we call find_sub,
2631                         # break up the return value, and assign it in one
2632                         # operation.
2633                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2634
2635                         # Force the line number to be numeric.
2636                         $i += 0;
2637
2638                         # If we got a line number, we found the sub.
2639                         if ($i) {
2640
2641                             # Switch all the debugger's internals around so
2642                             # we're actually working with that file.
2643                             $filename = $file;
2644                             *dbline   = $main::{ '_<' . $filename };
2645
2646                             # Mark that there's a breakpoint in this file.
2647                             $had_breakpoints{$filename} |= 1;
2648
2649                             # Scan forward to the first executable line
2650                             # after the 'sub whatever' line.
2651                             $max = $#dbline;
2652                             ++$i while $dbline[$i] == 0 && $i < $max;
2653                         } ## end if ($i)
2654
2655                         # We didn't find a sub by that name.
2656                         else {
2657                             print $OUT "Subroutine $subname not found.\n";
2658                             next CMD;
2659                         }
2660                     } ## end if ($subname =~ /\D/)
2661
2662                     # At this point, either the subname was all digits (an
2663                     # absolute line-break request) or we've scanned through
2664                     # the code following the definition of the sub, looking
2665                     # for an executable, which we may or may not have found.
2666                     #
2667                     # If $i (which we set $subname from) is non-zero, we
2668                     # got a request to break at some line somewhere. On
2669                     # one hand, if there wasn't any real subroutine name
2670                     # involved, this will be a request to break in the current
2671                     # file at the specified line, so we have to check to make
2672                     # sure that the line specified really is breakable.
2673                     #
2674                     # On the other hand, if there was a subname supplied, the
2675                     # preceding block has moved us to the proper file and
2676                     # location within that file, and then scanned forward
2677                     # looking for the next executable line. We have to make
2678                     # sure that one was found.
2679                     #
2680                     # On the gripping hand, we can't do anything unless the
2681                     # current value of $i points to a valid breakable line.
2682                     # Check that.
2683                     if ($i) {
2684
2685                         # Breakable?
2686                         if ( $dbline[$i] == 0 ) {
2687                             print $OUT "Line $i not breakable.\n";
2688                             next CMD;
2689                         }
2690
2691                         # Yes. Set up the one-time-break sigil.
2692                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2693                         _enable_breakpoint_temp_enabled_status($filename, $i);
2694                     } ## end if ($i)
2695
2696                     # Turn off stack tracing from here up.
2697                     for my $i (0 .. $stack_depth) {
2698                         $stack[ $i ] &= ~1;
2699                     }
2700                     last CMD;
2701                 };
2702
2703 =head4 C<r> - return from a subroutine
2704
2705 For C<r> to work properly, the debugger has to stop execution again
2706 immediately after the return is executed. This is done by forcing
2707 single-stepping to be on in the call level above the current one. If
2708 we are printing return values when a C<r> is executed, set C<$doret>
2709 appropriately, and force us out of the command loop.
2710
2711 =cut
2712
2713                 # r - return from the current subroutine.
2714                 $cmd =~ /^r$/ && do {
2715
2716                     # Can't do anything if the program's over.
2717                     end_report(), next CMD if $finished and $level <= 1;
2718
2719                     # Turn on stack trace.
2720                     $stack[$stack_depth] |= 1;
2721
2722                     # Print return value unless the stack is empty.
2723                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2724                     last CMD;
2725                 };
2726
2727 =head4 C<T> - stack trace
2728
2729 Just calls C<DB::print_trace>.
2730
2731 =cut
2732
2733                 $cmd =~ /^T$/ && do {
2734                     print_trace( $OUT, 1 );    # skip DB
2735                     next CMD;
2736                 };
2737
2738 =head4 C<w> - List window around current line.
2739
2740 Just calls C<DB::cmd_w>.
2741
2742 =cut
2743
2744                 $cmd =~ /^w\b\s*(.*)/s && do { &cmd_w( 'w', $1 ); next CMD; };
2745
2746 =head4 C<W> - watch-expression processing.
2747
2748 Just calls C<DB::cmd_W>.
2749
2750 =cut
2751
2752                 $cmd =~ /^W\b\s*(.*)/s && do { &cmd_W( 'W', $1 ); next CMD; };
2753
2754 =head4 C</> - search forward for a string in the source
2755
2756 We take the argument and treat it as a pattern. If it turns out to be a
2757 bad one, we return the error we got from trying to C<eval> it and exit.
2758 If not, we create some code to do the search and C<eval> it so it can't
2759 mess us up.
2760
2761 =cut
2762
2763                 $cmd =~ /^\/(.*)$/ && do {
2764
2765                     # The pattern as a string.
2766                     use vars qw($inpat);
2767                     $inpat = $1;
2768
2769                     # Remove the final slash.
2770                     $inpat =~ s:([^\\])/$:$1:;
2771
2772                     # If the pattern isn't null ...
2773                     if ( $inpat ne "" ) {
2774
2775                         # Turn of warn and die procesing for a bit.
2776                         local $SIG{__DIE__};
2777                         local $SIG{__WARN__};
2778
2779                         # Create the pattern.
2780                         eval '$inpat =~ m' . "\a$inpat\a";
2781                         if ( $@ ne "" ) {
2782
2783                             # Oops. Bad pattern. No biscuit.
2784                             # Print the eval error and go back for more
2785                             # commands.
2786                             print $OUT "$@";
2787                             next CMD;
2788                         }
2789                         $pat = $inpat;
2790                     } ## end if ($inpat ne "")
2791
2792                     # Set up to stop on wrap-around.
2793                     $end = $start;
2794
2795                     # Don't move off the current line.
2796                     $incr = -1;
2797
2798                     # Done in eval so nothing breaks if the pattern
2799                     # does something weird.
2800                     eval '
2801                         for (;;) {
2802                             # Move ahead one line.
2803                             ++$start;
2804
2805                             # Wrap if we pass the last line.
2806                             $start = 1 if ($start > $max);
2807
2808                             # Stop if we have gotten back to this line again,
2809                             last if ($start == $end);
2810
2811                             # A hit! (Note, though, that we are doing
2812                             # case-insensitive matching. Maybe a qr//
2813                             # expression would be better, so the user could
2814                             # do case-sensitive matching if desired.
2815                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2816                                 if ($slave_editor) {
2817                                     # Handle proper escaping in the slave.
2818                                     print $OUT "\032\032$filename:$start:0\n";
2819                                 }
2820                                 else {
2821                                     # Just print the line normally.
2822                                     print $OUT "$start:\t",$dbline[$start],"\n";
2823                                 }
2824                                 # And quit since we found something.
2825                                 last;
2826                             }
2827                          } ';
2828
2829                     # If we wrapped, there never was a match.
2830                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2831                     next CMD;
2832                 };
2833
2834 =head4 C<?> - search backward for a string in the source
2835
2836 Same as for C</>, except the loop runs backwards.
2837
2838 =cut
2839
2840                 # ? - backward pattern search.
2841                 $cmd =~ /^\?(.*)$/ && do {
2842
2843                     # Get the pattern, remove trailing question mark.
2844                     my $inpat = $1;
2845                     $inpat =~ s:([^\\])\?$:$1:;
2846
2847                     # If we've got one ...
2848                     if ( $inpat ne "" ) {
2849
2850                         # Turn off die & warn handlers.
2851                         local $SIG{__DIE__};
2852                         local $SIG{__WARN__};
2853                         eval '$inpat =~ m' . "\a$inpat\a";
2854
2855                         if ( $@ ne "" ) {
2856
2857                             # Ouch. Not good. Print the error.
2858                             print $OUT $@;
2859                             next CMD;
2860                         }
2861                         $pat = $inpat;
2862                     } ## end if ($inpat ne "")
2863
2864                     # Where we are now is where to stop after wraparound.
2865                     $end = $start;
2866
2867                     # Don't move away from this line.
2868                     $incr = -1;
2869
2870                     # Search inside the eval to prevent pattern badness
2871                     # from killing us.
2872                     eval '
2873                         for (;;) {
2874                             # Back up a line.
2875                             --$start;
2876
2877                             # Wrap if we pass the first line.
2878
2879                             $start = $max if ($start <= 0);
2880
2881                             # Quit if we get back where we started,
2882                             last if ($start == $end);
2883
2884                             # Match?
2885                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2886                                 if ($slave_editor) {
2887                                     # Yep, follow slave editor requirements.
2888                                     print $OUT "\032\032$filename:$start:0\n";
2889                                 }
2890                                 else {
2891                                     # Yep, just print normally.
2892                                     print $OUT "$start:\t",$dbline[$start],"\n";
2893                                 }
2894
2895                                 # Found, so done.
2896                                 last;
2897                             }
2898                         } ';
2899
2900                     # Say we failed if the loop never found anything,
2901                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2902                     next CMD;
2903                 };
2904
2905 =head4 C<$rc> - Recall command
2906
2907 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2908 that the terminal supports history). It find the the command required, puts it
2909 into C<$cmd>, and redoes the loop to execute it.
2910
2911 =cut
2912
2913                 # $rc - recall command.
2914                 $cmd =~ /^$rc+\s*(-)?(\d+)?$/ && do {
2915
2916                     # No arguments, take one thing off history.
2917                     pop(@hist) if length($cmd) > 1;
2918
2919                     # Relative (- found)?
2920                     #  Y - index back from most recent (by 1 if bare minus)
2921                     #  N - go to that particular command slot or the last
2922                     #      thing if nothing following.
2923                     $i = $1 ? ( $#hist - ( $2 || 1 ) ) : ( $2 || $#hist );
2924
2925                     # Pick out the command desired.
2926                     $cmd = $hist[$i];
2927
2928                     # Print the command to be executed and restart the loop
2929                     # with that command in the buffer.
2930                     print $OUT $cmd, "\n";
2931                     redo CMD;
2932                 };
2933
2934 =head4 C<$sh$sh> - C<system()> command
2935
2936 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2937 C<STDOUT> from getting messed up.
2938
2939 =cut
2940
2941                 # $sh$sh - run a shell command (if it's all ASCII).
2942                 # Can't run shell commands with Unicode in the debugger, hmm.
2943                 $cmd =~ /^$sh$sh\s*([\x00-\xff]*)/ && do {
2944
2945                     # System it.
2946                     &system($1);
2947                     next CMD;
2948                 };
2949
2950 =head4 C<$rc I<pattern> $rc> - Search command history
2951
2952 Another command to manipulate C<@hist>: this one searches it with a pattern.
2953 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2954
2955 =cut
2956
2957                 # $rc pattern $rc - find a command in the history.
2958                 $cmd =~ /^$rc([^$rc].*)$/ && do {
2959
2960                     # Create the pattern to use.
2961                     $pat = "^$1";
2962
2963                     # Toss off last entry if length is >1 (and it always is).
2964                     pop(@hist) if length($cmd) > 1;
2965
2966                     # Look backward through the history.
2967                     for ( $i = $#hist ; $i ; --$i ) {
2968                         # Stop if we find it.
2969                         last if $hist[$i] =~ /$pat/;
2970                     }
2971
2972                     if ( !$i ) {
2973
2974                         # Never found it.
2975                         print $OUT "No such command!\n\n";
2976                         next CMD;
2977                     }
2978
2979                     # Found it. Put it in the buffer, print it, and process it.
2980                     $cmd = $hist[$i];
2981                     print $OUT $cmd, "\n";
2982                     redo CMD;
2983                 };
2984
2985 =head4 C<$sh> - Invoke a shell
2986
2987 Uses C<DB::system> to invoke a shell.
2988
2989 =cut
2990
2991                 # $sh - start a shell.
2992                 $cmd =~ /^$sh$/ && do {
2993
2994                     # Run the user's shell. If none defined, run Bourne.
2995                     # We resume execution when the shell terminates.
2996                     &system( $ENV{SHELL} || "/bin/sh" );
2997                     next CMD;
2998                 };
2999
3000 =head4 C<$sh I<command>> - Force execution of a command in a shell
3001
3002 Like the above, but the command is passed to the shell. Again, we use
3003 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3004
3005 =cut
3006
3007                 # $sh command - start a shell and run a command in it.
3008                 $cmd =~ /^$sh\s*([\x00-\xff]*)/ && do {
3009
3010                     # XXX: using csh or tcsh destroys sigint retvals!
3011                     #&system($1);  # use this instead
3012
3013                     # use the user's shell, or Bourne if none defined.
3014                     &system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3015                     next CMD;
3016                 };
3017
3018 =head4 C<H> - display commands in history
3019
3020 Prints the contents of C<@hist> (if any).
3021
3022 =cut
3023
3024                 $cmd =~ /^H\b\s*\*/ && do {
3025                     @hist = @truehist = ();
3026                     print $OUT "History cleansed\n";
3027                     next CMD;
3028                 };
3029
3030                 $cmd =~ /^H\b\s*(-(\d+))?/ && do {
3031
3032                     # Anything other than negative numbers is ignored by
3033                     # the (incorrect) pattern, so this test does nothing.
3034                     $end = $2 ? ( $#hist - $2 ) : 0;
3035
3036                     # Set to the minimum if less than zero.
3037                     $hist = 0 if $hist < 0;
3038
3039                     # Start at the end of the array.
3040                     # Stay in while we're still above the ending value.
3041                     # Tick back by one each time around the loop.
3042                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3043
3044                         # Print the command  unless it has no arguments.
3045                         print $OUT "$i: ", $hist[$i], "\n"
3046                           unless $hist[$i] =~ /^.?$/;
3047                     }
3048                     next CMD;
3049                 };
3050
3051 =head4 C<man, doc, perldoc> - look up documentation
3052
3053 Just calls C<runman()> to print the appropriate document.
3054
3055 =cut
3056
3057                 # man, perldoc, doc - show manual pages.
3058                 $cmd =~ /^(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?$/ && do {
3059                     runman($1);
3060                     next CMD;
3061                 };
3062
3063 =head4 C<p> - print
3064
3065 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3066 the bottom of the loop.
3067
3068 =cut
3069
3070                 # p - print (no args): print $_.
3071                 $cmd =~ s/^p$/print {\$DB::OUT} \$_/;
3072
3073                 # p - print the given expression.
3074                 $cmd =~ s/^p\b/print {\$DB::OUT} /;
3075
3076 =head4 C<=> - define command alias
3077
3078 Manipulates C<%alias> to add or list command aliases.
3079
3080 =cut
3081
3082                 # = - set up a command alias.
3083                 $cmd =~ s/^=\s*// && do {
3084                     my @keys;
3085                     if ( length $cmd == 0 ) {
3086
3087                         # No args, get current aliases.
3088                         @keys = sort keys %alias;
3089                     }
3090                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3091
3092                         # Creating a new alias. $k is alias name, $v is
3093                         # alias value.
3094
3095                         # can't use $_ or kill //g state
3096                         for my $x ( $k, $v ) {
3097
3098                             # Escape "alarm" characters.
3099                             $x =~ s/\a/\\a/g;
3100                         }
3101
3102                         # Substitute key for value, using alarm chars
3103                         # as separators (which is why we escaped them in
3104                         # the command).
3105                         $alias{$k} = "s\a$k\a$v\a";
3106
3107                         # Turn off standard warn and die behavior.
3108                         local $SIG{__DIE__};
3109                         local $SIG{__WARN__};
3110
3111                         # Is it valid Perl?
3112                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3113
3114                             # Nope. Bad alias. Say so and get out.
3115                             print $OUT "Can't alias $k to $v: $@\n";
3116                             delete $alias{$k};
3117                             next CMD;
3118                         }
3119
3120                         # We'll only list the new one.
3121                         @keys = ($k);
3122                     } ## end elsif (my ($k, $v) = ($cmd...
3123
3124                     # The argument is the alias to list.
3125                     else {
3126                         @keys = ($cmd);
3127                     }
3128
3129                     # List aliases.
3130                     for my $k (@keys) {
3131
3132                         # Messy metaquoting: Trim the substitution code off.
3133                         # We use control-G as the delimiter because it's not
3134                         # likely to appear in the alias.
3135                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3136
3137                             # Print the alias.
3138                             print $OUT "$k\t= $1\n";
3139                         }
3140                         elsif ( defined $alias{$k} ) {
3141
3142                             # Couldn't trim it off; just print the alias code.
3143                             print $OUT "$k\t$alias{$k}\n";
3144                         }
3145                         else {
3146
3147                             # No such, dude.
3148                             print "No alias for $k\n";
3149                         }
3150                     } ## end for my $k (@keys)
3151                     next CMD;
3152                 };
3153
3154 =head4 C<source> - read commands from a file.
3155
3156 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3157 pick it up.
3158
3159 =cut
3160
3161                 # source - read commands from a file (or pipe!) and execute.
3162                 $cmd =~ /^source\s+(.*\S)/ && do {
3163                     if ( open my $fh, $1 ) {
3164
3165                         # Opened OK; stick it in the list of file handles.
3166                         push @cmdfhs, $fh;
3167                     }
3168                     else {
3169
3170                         # Couldn't open it.
3171                         &warn("Can't execute '$1': $!\n");
3172                     }
3173                     next CMD;
3174                 };
3175
3176                 $cmd =~ /^(enable|disable)\s+(\S+)\s*$/ && do {
3177                     my ($cmd, $position) = ($1, $2);
3178
3179                     my ($fn, $line_num);
3180                     if ($position =~ m{\A\d+\z})
3181                     {
3182                         $fn = $filename;
3183                         $line_num = $position;
3184                     }
3185                     elsif ($position =~ m{\A(.*):(\d+)\z})
3186                     {
3187                         ($fn, $line_num) = ($1, $2);
3188                     }
3189                     else
3190                     {
3191                         &warn("Wrong spec for enable/disable argument.\n");
3192                     }
3193
3194                     if (defined($fn)) {
3195                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3196                             _set_breakpoint_enabled_status($fn, $line_num,
3197                                 ($cmd eq 'enable' ? 1 : '')
3198                             );
3199                         }
3200                         else {
3201                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3202                         }
3203                     }
3204
3205                     next CMD;
3206                 };
3207
3208 =head4 C<save> - send current history to a file
3209
3210 Takes the complete history, (not the shrunken version you see with C<H>),
3211 and saves it to the given filename, so it can be replayed using C<source>.
3212
3213 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3214
3215 =cut
3216
3217                 # save source - write commands to a file for later use
3218                 $cmd =~ /^save\s*(.*)$/ && do {
3219                     my $file = $1 || '.perl5dbrc';    # default?
3220                     if ( open my $fh, "> $file" ) {
3221
3222                        # chomp to remove extraneous newlines from source'd files
3223                         chomp( my @truelist =
3224                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3225                               @truehist );
3226                         print $fh join( "\n", @truelist );
3227                         print "commands saved in $file\n";
3228                     }
3229                     else {
3230                         &warn("Can't save debugger commands in '$1': $!\n");
3231                     }
3232                     next CMD;
3233                 };
3234
3235 =head4 C<R> - restart
3236
3237 Restart the debugger session.
3238
3239 =head4 C<rerun> - rerun the current session
3240
3241 Return to any given position in the B<true>-history list
3242
3243 =cut
3244
3245                 # R - restart execution.
3246                 # rerun - controlled restart execution.
3247                 $cmd =~ /^(R|rerun\s*(.*))$/ && do {
3248                     my @args = ($1 eq 'R' ? restart() : rerun($2));
3249
3250                     # Close all non-system fds for a clean restart.  A more
3251                     # correct method would be to close all fds that were not
3252                     # open when the process started, but this seems to be
3253                     # hard.  See "debugger 'R'estart and open database
3254                     # connections" on p5p.
3255
3256                     my $max_fd = 1024; # default if POSIX can't be loaded
3257                     if (eval { require POSIX }) {
3258                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3259                     }
3260
3261                     if (defined $max_fd) {
3262                         foreach ($^F+1 .. $max_fd-1) {
3263                             next unless open FD_TO_CLOSE, "<&=$_";
3264                             close(FD_TO_CLOSE);
3265                         }
3266                     }
3267
3268                     # And run Perl again.  We use exec() to keep the
3269                     # PID stable (and that way $ini_pids is still valid).
3270                     exec(@args) || print $OUT "exec failed: $!\n";
3271
3272                     last CMD;
3273                 };
3274
3275 =head4 C<|, ||> - pipe output through the pager.
3276
3277 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3278 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3279 pipe to the pager (restoring the output filehandles if this fails). If this
3280 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3281 set C<$signal>, sending us back into the debugger.
3282
3283 We then trim off the pipe symbols and C<redo> the command loop at the
3284 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3285 reading another.
3286
3287 =cut
3288
3289                 # || - run command in the pager, with output to DB::OUT.
3290                 $cmd =~ /^\|\|?\s*[^|]/ && do {
3291                     if ( $pager =~ /^\|/ ) {
3292
3293                         # Default pager is into a pipe. Redirect I/O.
3294                         open( SAVEOUT, ">&STDOUT" )
3295                           || &warn("Can't save STDOUT");
3296                         open( STDOUT, ">&OUT" )
3297                           || &warn("Can't redirect STDOUT");
3298                     } ## end if ($pager =~ /^\|/)
3299                     else {
3300
3301                         # Not into a pipe. STDOUT is safe.
3302                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3303                     }
3304
3305                     # Fix up environment to record we have less if so.
3306                     fix_less();
3307
3308                     unless ( $piped = open( OUT, $pager ) ) {
3309
3310                         # Couldn't open pipe to pager.
3311                         &warn("Can't pipe output to '$pager'");
3312                         if ( $pager =~ /^\|/ ) {
3313
3314                             # Redirect I/O back again.
3315                             open( OUT, ">&STDOUT" )    # XXX: lost message
3316                               || &warn("Can't restore DB::OUT");
3317                             open( STDOUT, ">&SAVEOUT" )
3318                               || &warn("Can't restore STDOUT");
3319                             close(SAVEOUT);
3320                         } ## end if ($pager =~ /^\|/)
3321                         else {
3322
3323                             # Redirect I/O. STDOUT already safe.
3324                             open( OUT, ">&STDOUT" )    # XXX: lost message
3325                               || &warn("Can't restore DB::OUT");
3326                         }
3327                         next CMD;
3328                     } ## end unless ($piped = open(OUT,...
3329
3330                     # Set up broken-pipe handler if necessary.
3331                     $SIG{PIPE} = \&DB::catch
3332                       if $pager =~ /^\|/
3333                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3334
3335                     # Save current filehandle, unbuffer out, and put it back.
3336                     $selected = select(OUT);
3337                     $|        = 1;
3338
3339                     # Don't put it back if pager was a pipe.
3340                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3341
3342                     # Trim off the pipe symbols and run the command now.
3343                     $cmd =~ s/^\|+\s*//;
3344                     redo PIPE;
3345                 };
3346
3347 =head3 END OF COMMAND PARSING
3348
3349 Anything left in C<$cmd> at this point is a Perl expression that we want to
3350 evaluate. We'll always evaluate in the user's context, and fully qualify
3351 any variables we might want to address in the C<DB> package.
3352
3353 =cut
3354
3355                 # t - turn trace on.
3356                 $cmd =~ s/^t\s+(\d+)?/\$DB::trace |= 1;\n/ && do {
3357                     $trace_to_depth = $1 ? $stack_depth||0 + $1 : 1E9;
3358                 };
3359
3360                 # s - single-step. Remember the last command was 's'.
3361                 $cmd =~ s/^s\s/\$DB::single = 1;\n/ && do { $laststep = 's' };
3362
3363                 # n - single-step, but not into subs. Remember last command
3364                 # was 'n'.
3365                 $cmd =~ s/^n\s/\$DB::single = 2;\n/ && do { $laststep = 'n' };
3366
3367             }    # PIPE:
3368
3369             # Make sure the flag that says "the debugger's running" is
3370             # still on, to make sure we get control again.
3371             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3372
3373             # Run *our* eval that executes in the caller's context.
3374             &eval;
3375
3376             # Turn off the one-time-dump stuff now.
3377             if ($onetimeDump) {
3378                 $onetimeDump      = undef;
3379                 $onetimedumpDepth = undef;
3380             }
3381             elsif ( $term_pid == $$ ) {
3382                 eval {          # May run under miniperl, when not available...
3383                     STDOUT->flush();
3384                     STDERR->flush();
3385                 };
3386
3387                 # XXX If this is the master pid, print a newline.
3388                 print $OUT "\n";
3389             }
3390         } ## end while (($term || &setterm...
3391
3392 =head3 POST-COMMAND PROCESSING
3393
3394 After each command, we check to see if the command output was piped anywhere.
3395 If so, we go through the necessary code to unhook the pipe and go back to
3396 our standard filehandles for input and output.
3397
3398 =cut
3399
3400         continue {    # CMD:
3401
3402             # At the end of every command:
3403             if ($piped) {
3404
3405                 # Unhook the pipe mechanism now.
3406                 if ( $pager =~ /^\|/ ) {
3407
3408                     # No error from the child.
3409                     $? = 0;
3410
3411                     # we cannot warn here: the handle is missing --tchrist
3412                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3413
3414                     # most of the $? crud was coping with broken cshisms
3415                     # $? is explicitly set to 0, so this never runs.
3416                     if ($?) {
3417                         print SAVEOUT "Pager '$pager' failed: ";
3418                         if ( $? == -1 ) {
3419                             print SAVEOUT "shell returned -1\n";
3420                         }
3421                         elsif ( $? >> 8 ) {
3422                             print SAVEOUT ( $? & 127 )
3423                               ? " (SIG#" . ( $? & 127 ) . ")"
3424                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3425                         }
3426                         else {
3427                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3428                         }
3429                     } ## end if ($?)
3430
3431                     # Reopen filehandle for our output (if we can) and
3432                     # restore STDOUT (if we can).
3433                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3434                     open( STDOUT, ">&SAVEOUT" )
3435                       || &warn("Can't restore STDOUT");
3436
3437                     # Turn off pipe exception handler if necessary.
3438                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3439
3440                     # Will stop ignoring SIGPIPE if done like nohup(1)
3441                     # does SIGINT but Perl doesn't give us a choice.
3442                 } ## end if ($pager =~ /^\|/)
3443                 else {
3444
3445                     # Non-piped "pager". Just restore STDOUT.
3446                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3447                 }
3448
3449                 # Close filehandle pager was using, restore the normal one
3450                 # if necessary,
3451                 close(SAVEOUT);
3452                 select($selected), $selected = "" unless $selected eq "";
3453
3454                 # No pipes now.
3455                 $piped = "";
3456             } ## end if ($piped)
3457         }    # CMD:
3458
3459 =head3 COMMAND LOOP TERMINATION
3460
3461 When commands have finished executing, we come here. If the user closed the
3462 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3463 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3464 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3465 The interpreter will then execute the next line and then return control to us
3466 again.
3467
3468 =cut
3469
3470         # No more commands? Quit.
3471         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3472
3473         # Evaluate post-prompt commands.
3474         foreach $evalarg (@$post) {
3475             &eval;
3476         }
3477     }    # if ($single || $signal)
3478
3479     # Put the user's globals back where you found them.
3480     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3481     ();
3482 } ## end sub DB
3483
3484 # The following code may be executed now:
3485 # BEGIN {warn 4}
3486
3487 =head2 sub
3488
3489 C<sub> is called whenever a subroutine call happens in the program being
3490 debugged. The variable C<$DB::sub> contains the name of the subroutine
3491 being called.
3492
3493 The core function of this subroutine is to actually call the sub in the proper
3494 context, capturing its output. This of course causes C<DB::DB> to get called
3495 again, repeating until the subroutine ends and returns control to C<DB::sub>
3496 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3497 return value, and returns its captured copy of the return value as its own
3498 return value. The value then feeds back into the program being debugged as if
3499 C<DB::sub> hadn't been there at all.
3500
3501 C<sub> does all the work of printing the subroutine entry and exit messages
3502 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3503 and also prints the return value if needed (for the C<r> command and if
3504 the 16 bit is set in C<$frame>).
3505
3506 It also tracks the subroutine call depth by saving the current setting of
3507 C<$single> in the C<@stack> package global; if this exceeds the value in
3508 C<$deep>, C<sub> automatically turns on printing of the current depth by
3509 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3510 of stop/don't stop on entry to subs set as it currently is set.
3511
3512 =head3 C<caller()> support
3513
3514 If C<caller()> is called from the package C<DB>, it provides some
3515 additional data, in the following order:
3516
3517 =over 4
3518
3519 =item * C<$package>
3520
3521 The package name the sub was in
3522
3523 =item * C<$filename>
3524
3525 The filename it was defined in
3526
3527 =item * C<$line>
3528
3529 The line number it was defined on
3530
3531 =item * C<$subroutine>
3532
3533 The subroutine name; C<(eval)> if an C<eval>().
3534
3535 =item * C<$hasargs>
3536
3537 1 if it has arguments, 0 if not
3538
3539 =item * C<$wantarray>
3540
3541 1 if array context, 0 if scalar context
3542
3543 =item * C<$evaltext>
3544
3545 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3546
3547 =item * C<$is_require>
3548
3549 frame was created by a C<use> or C<require> statement
3550
3551 =item * C<$hints>
3552
3553 pragma information; subject to change between versions
3554
3555 =item * C<$bitmask>
3556
3557 pragma information; subject to change between versions
3558
3559 =item * C<@DB::args>
3560
3561 arguments with which the subroutine was invoked
3562
3563 =back
3564
3565 =cut
3566
3567 use vars qw($deep);
3568
3569 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3570 # happy. -- Shlomi Fish
3571 sub DB::sub {
3572         # Do not use a regex in this subroutine -> results in corrupted memory
3573         # See: [perl #66110]
3574
3575         # lock ourselves under threads
3576         lock($DBGR);
3577
3578     # Whether or not the autoloader was running, a scalar to put the
3579     # sub's return value in (if needed), and an array to put the sub's
3580     # return value in (if needed).
3581     my ( $al, $ret, @ret ) = "";
3582         if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3583                 print "creating new thread\n";
3584         }
3585
3586     # If the last ten characters are '::AUTOLOAD', note we've traced
3587     # into AUTOLOAD for $sub.
3588     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3589         no strict 'refs';
3590         $al = " for $$sub" if defined $$sub;
3591     }
3592
3593     # We stack the stack pointer and then increment it to protect us
3594     # from a situation that might unwind a whole bunch of call frames
3595     # at once. Localizing the stack pointer means that it will automatically
3596     # unwind the same amount when multiple stack frames are unwound.
3597     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3598
3599     # Expand @stack.
3600     $#stack = $stack_depth;
3601
3602     # Save current single-step setting.
3603     $stack[-1] = $single;
3604
3605     # Turn off all flags except single-stepping.
3606     $single &= 1;
3607
3608     # If we've gotten really deeply recursed, turn on the flag that will
3609     # make us stop with the 'deep recursion' message.
3610     $single |= 4 if $stack_depth == $deep;
3611
3612     # If frame messages are on ...
3613     (
3614         $frame & 4    # Extended frame entry message
3615         ? (
3616             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3617
3618             # Why -1? But it works! :-(
3619             # Because print_trace will call add 1 to it and then call
3620             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3621             # in dump_trace.
3622             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3623           )
3624         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3625
3626           # standard frame entry message
3627       )
3628       if $frame;
3629
3630     # Determine the sub's return type, and capture appropriately.
3631     if (wantarray) {
3632
3633         # Called in array context. call sub and capture output.
3634         # DB::DB will recursively get control again if appropriate; we'll come
3635         # back here when the sub is finished.
3636         {
3637             no strict 'refs';
3638             @ret = &$sub;
3639         }
3640
3641         # Pop the single-step value back off the stack.
3642         $single |= $stack[ $stack_depth-- ];
3643
3644         # Check for exit trace messages...
3645         (
3646             $frame & 4    # Extended exit message
3647             ? (
3648                 print_lineinfo( ' ' x $stack_depth, "out " ),
3649                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3650               )
3651             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3652
3653               # Standard exit message
3654           )
3655           if $frame & 2;
3656
3657         # Print the return info if we need to.
3658         if ( $doret eq $stack_depth or $frame & 16 ) {
3659
3660             # Turn off output record separator.
3661             local $\ = '';
3662             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3663
3664             # Indent if we're printing because of $frame tracing.
3665             print $fh ' ' x $stack_depth if $frame & 16;
3666
3667             # Print the return value.
3668             print $fh "list context return from $sub:\n";
3669             dumpit( $fh, \@ret );
3670
3671             # And don't print it again.
3672             $doret = -2;
3673         } ## end if ($doret eq $stack_depth...
3674             # And we have to return the return value now.
3675         @ret;
3676     } ## end if (wantarray)
3677
3678     # Scalar context.
3679     else {
3680         if ( defined wantarray ) {
3681         no strict 'refs';
3682             # Save the value if it's wanted at all.
3683             $ret = &$sub;
3684         }
3685         else {
3686         no strict 'refs';
3687             # Void return, explicitly.
3688             &$sub;
3689             undef $ret;
3690         }
3691
3692         # Pop the single-step value off the stack.
3693         $single |= $stack[ $stack_depth-- ];
3694
3695         # If we're doing exit messages...
3696         (
3697             $frame & 4    # Extended messages
3698             ? (
3699                 print_lineinfo( ' ' x $stack_depth, "out " ),
3700                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3701               )
3702             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3703
3704               # Standard messages
3705           )
3706           if $frame & 2;
3707
3708         # If we are supposed to show the return value... same as before.
3709         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3710             local $\ = '';
3711             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3712             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3713             print $fh (
3714                 defined wantarray
3715                 ? "scalar context return from $sub: "
3716                 : "void context return from $sub\n"
3717             );
3718             dumpit( $fh, $ret ) if defined wantarray;
3719             $doret = -2;
3720         } ## end if ($doret eq $stack_depth...
3721
3722         # Return the appropriate scalar value.
3723         $ret;
3724     } ## end else [ if (wantarray)
3725 } ## end sub _sub
3726
3727 sub lsub : lvalue {
3728
3729     no strict 'refs';
3730
3731         # lock ourselves under threads
3732         lock($DBGR);
3733
3734     # Whether or not the autoloader was running, a scalar to put the
3735     # sub's return value in (if needed), and an array to put the sub's
3736     # return value in (if needed).
3737     my ( $al, $ret, @ret ) = "";
3738         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3739                 print "creating new thread\n";
3740         }
3741
3742     # If the last ten characters are C'::AUTOLOAD', note we've traced
3743     # into AUTOLOAD for $sub.
3744     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3745         $al = " for $$sub";
3746     }
3747
3748     # We stack the stack pointer and then increment it to protect us
3749     # from a situation that might unwind a whole bunch of call frames
3750     # at once. Localizing the stack pointer means that it will automatically
3751     # unwind the same amount when multiple stack frames are unwound.
3752     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3753
3754     # Expand @stack.
3755     $#stack = $stack_depth;
3756
3757     # Save current single-step setting.
3758     $stack[-1] = $single;
3759
3760     # Turn off all flags except single-stepping.
3761     $single &= 1;
3762
3763     # If we've gotten really deeply recursed, turn on the flag that will
3764     # make us stop with the 'deep recursion' message.
3765     $single |= 4 if $stack_depth == $deep;
3766
3767     # If frame messages are on ...
3768     (
3769         $frame & 4    # Extended frame entry message
3770         ? (
3771             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3772
3773             # Why -1? But it works! :-(
3774             # Because print_trace will call add 1 to it and then call
3775             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3776             # in dump_trace.
3777             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3778           )
3779         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3780
3781           # standard frame entry message
3782       )
3783       if $frame;
3784
3785     # Pop the single-step value back off the stack.
3786     $single |= $stack[ $stack_depth-- ];
3787
3788     # call the original lvalue sub.
3789     &$sub;
3790 }
3791
3792 # Abstracting common code from multiple places elsewhere:
3793 sub depth_print_lineinfo {
3794     my $always_print = shift;
3795
3796     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
3797 }
3798
3799 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3800
3801 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3802 Most of the changes were to systematize the command structure and to eliminate
3803 commands that threw away user input without checking.
3804
3805 The following sections describe the code added to make it easy to support
3806 multiple command sets with conflicting command names. This section is a start
3807 at unifying all command processing to make it simpler to develop commands.
3808
3809 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3810 number, and C<$dbline> (the current line) as arguments.
3811
3812 Support functions in this section which have multiple modes of failure C<die>
3813 on error; the rest simply return a false value.
3814
3815 The user-interface functions (all of the C<cmd_*> functions) just output
3816 error messages.
3817
3818 =head2 C<%set>
3819
3820 The C<%set> hash defines the mapping from command letter to subroutine
3821 name suffix.
3822
3823 C<%set> is a two-level hash, indexed by set name and then by command name.
3824 Note that trying to set the CommandSet to C<foobar> simply results in the
3825 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3826
3827 =cut
3828
3829 ### The API section
3830
3831 my %set = (    #
3832     'pre580' => {
3833         'a' => 'pre580_a',
3834         'A' => 'pre580_null',
3835         'b' => 'pre580_b',
3836         'B' => 'pre580_null',
3837         'd' => 'pre580_null',
3838         'D' => 'pre580_D',
3839         'h' => 'pre580_h',
3840         'M' => 'pre580_null',
3841         'O' => 'o',
3842         'o' => 'pre580_null',
3843         'v' => 'M',
3844         'w' => 'v',
3845         'W' => 'pre580_W',
3846     },
3847     'pre590' => {
3848         '<'  => 'pre590_prepost',
3849         '<<' => 'pre590_prepost',
3850         '>'  => 'pre590_prepost',
3851         '>>' => 'pre590_prepost',
3852         '{'  => 'pre590_prepost',
3853         '{{' => 'pre590_prepost',
3854     },
3855 );
3856
3857 my %breakpoints_data;
3858
3859 sub _has_breakpoint_data_ref {
3860     my ($filename, $line) = @_;
3861
3862     return (
3863         exists( $breakpoints_data{$filename} )
3864             and
3865         exists( $breakpoints_data{$filename}{$line} )
3866     );
3867 }
3868
3869 sub _get_breakpoint_data_ref {
3870     my ($filename, $line) = @_;
3871
3872     return ($breakpoints_data{$filename}{$line} ||= +{});
3873 }
3874
3875 sub _delete_breakpoint_data_ref {
3876     my ($filename, $line) = @_;
3877
3878     delete($breakpoints_data{$filename}{$line});
3879     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
3880         delete($breakpoints_data{$filename});
3881     }
3882
3883     return;
3884 }
3885
3886 sub _set_breakpoint_enabled_status {
3887     my ($filename, $line, $status) = @_;
3888
3889     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
3890         ($status ? 1 : '')
3891         ;
3892
3893     return;
3894 }
3895
3896 sub _enable_breakpoint_temp_enabled_status {
3897     my ($filename, $line) = @_;
3898
3899     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
3900
3901     return;
3902 }
3903
3904 sub _cancel_breakpoint_temp_enabled_status {
3905     my ($filename, $line) = @_;
3906
3907     my $ref = _get_breakpoint_data_ref($filename, $line);
3908
3909     delete ($ref->{'temp_enabled'});
3910
3911     if (! %$ref) {
3912         _delete_breakpoint_data_ref($filename, $line);
3913     }
3914
3915     return;
3916 }
3917
3918 sub _is_breakpoint_enabled {
3919     my ($filename, $line) = @_;
3920
3921     my $data_ref = _get_breakpoint_data_ref($filename, $line);
3922     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
3923 }
3924
3925 =head2 C<cmd_wrapper()> (API)
3926
3927 C<cmd_wrapper()> allows the debugger to switch command sets
3928 depending on the value of the C<CommandSet> option.
3929
3930 It tries to look up the command in the C<%set> package-level I<lexical>
3931 (which means external entities can't fiddle with it) and create the name of
3932 the sub to call based on the value found in the hash (if it's there). I<All>
3933 of the commands to be handled in a set have to be added to C<%set>; if they
3934 aren't found, the 5.8.0 equivalent is called (if there is one).
3935
3936 This code uses symbolic references.
3937
3938 =cut
3939
3940 sub cmd_wrapper {
3941     my $cmd      = shift;
3942     my $line     = shift;
3943     my $dblineno = shift;
3944
3945     # Assemble the command subroutine's name by looking up the
3946     # command set and command name in %set. If we can't find it,
3947     # default to the older version of the command.
3948     my $call = 'cmd_'
3949       . ( $set{$CommandSet}{$cmd}
3950           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3951
3952     # Call the command subroutine, call it by name.
3953     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
3954 } ## end sub cmd_wrapper
3955
3956 =head3 C<cmd_a> (command)
3957
3958 The C<a> command handles pre-execution actions. These are associated with a
3959 particular line, so they're stored in C<%dbline>. We default to the current
3960 line if none is specified.
3961
3962 =cut
3963
3964 sub cmd_a {
3965     my $cmd    = shift;
3966     my $line   = shift || '';    # [.|line] expr
3967     my $dbline = shift;
3968
3969     # If it's dot (here), or not all digits,  use the current line.
3970     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3971
3972     # Should be a line number followed by an expression.
3973     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3974         my ( $lineno, $expr ) = ( $1, $2 );
3975
3976         # If we have an expression ...
3977         if ( length $expr ) {
3978
3979             # ... but the line isn't breakable, complain.
3980             if ( $dbline[$lineno] == 0 ) {
3981                 print $OUT
3982                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
3983             }
3984             else {
3985
3986                 # It's executable. Record that the line has an action.
3987                 $had_breakpoints{$filename} |= 2;
3988
3989                 # Remove any action, temp breakpoint, etc.
3990                 $dbline{$lineno} =~ s/\0[^\0]*//;
3991
3992                 # Add the action to the line.
3993                 $dbline{$lineno} .= "\0" . action($expr);
3994
3995                 _set_breakpoint_enabled_status($filename, $lineno, 1);
3996             }
3997         } ## end if (length $expr)
3998     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
3999     else {
4000
4001         # Syntax wrong.
4002         print $OUT
4003           "Adding an action requires an optional lineno and an expression\n"
4004           ;    # hint
4005     }
4006 } ## end sub cmd_a
4007
4008 =head3 C<cmd_A> (command)
4009
4010 Delete actions. Similar to above, except the delete code is in a separate
4011 subroutine, C<delete_action>.
4012
4013 =cut
4014
4015 sub cmd_A {
4016     my $cmd    = shift;
4017     my $line   = shift || '';
4018     my $dbline = shift;
4019
4020     # Dot is this line.
4021     $line =~ s/^\./$dbline/;
4022
4023     # Call delete_action with a null param to delete them all.
4024     # The '1' forces the eval to be true. It'll be false only
4025     # if delete_action blows up for some reason, in which case
4026     # we print $@ and get out.
4027     if ( $line eq '*' ) {
4028         eval { &delete_action(); 1 } or print $OUT $@ and return;
4029     }
4030
4031     # There's a real line  number. Pass it to delete_action.
4032     # Error trapping is as above.
4033     elsif ( $line =~ /^(\S.*)/ ) {
4034         eval { &delete_action($1); 1 } or print $OUT $@ and return;
4035     }
4036
4037     # Swing and a miss. Bad syntax.
4038     else {
4039         print $OUT
4040           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4041     }
4042 } ## end sub cmd_A
4043
4044 =head3 C<delete_action> (API)
4045
4046 C<delete_action> accepts either a line number or C<undef>. If a line number
4047 is specified, we check for the line being executable (if it's not, it
4048 couldn't have had an  action). If it is, we just take the action off (this
4049 will get any kind of an action, including breakpoints).
4050
4051 =cut
4052
4053 sub delete_action {
4054     my $i = shift;
4055     if ( defined($i) ) {
4056
4057         # Can there be one?
4058         die "Line $i has no action .\n" if $dbline[$i] == 0;
4059
4060         # Nuke whatever's there.
4061         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4062         delete $dbline{$i} if $dbline{$i} eq '';
4063     }
4064     else {
4065         print $OUT "Deleting all actions...\n";
4066         for my $file ( keys %had_breakpoints ) {
4067             local *dbline = $main::{ '_<' . $file };
4068             $max = $#dbline;
4069             my $was;
4070             for $i (1 .. $max) {
4071                 if ( defined $dbline{$i} ) {
4072                     $dbline{$i} =~ s/\0[^\0]*//;
4073                     delete $dbline{$i} if $dbline{$i} eq '';
4074                 }
4075                 unless ( $had_breakpoints{$file} &= ~2 ) {
4076                     delete $had_breakpoints{$file};
4077                 }
4078             } ## end for ($i = 1 .. $max)
4079         } ## end for my $file (keys %had_breakpoints)
4080     } ## end else [ if (defined($i))
4081 } ## end sub delete_action
4082
4083 =head3 C<cmd_b> (command)
4084
4085 Set breakpoints. Since breakpoints can be set in so many places, in so many
4086 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4087 we try to parse the command type, and then shuttle it off to an appropriate
4088 subroutine to actually do the work of setting the breakpoint in the right
4089 place.
4090
4091 =cut
4092
4093 sub cmd_b {
4094     my $cmd    = shift;
4095     my $line   = shift;    # [.|line] [cond]
4096     my $dbline = shift;
4097
4098     # Make . the current line number if it's there..
4099     $line =~ s/^\.(\s|\z)/$dbline$1/;
4100
4101     # No line number, no condition. Simple break on current line.
4102     if ( $line =~ /^\s*$/ ) {
4103         &cmd_b_line( $dbline, 1 );
4104     }
4105
4106     # Break on load for a file.
4107     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4108         my $file = $1;
4109         $file =~ s/\s+$//;
4110         &cmd_b_load($file);
4111     }
4112
4113     # b compile|postpone <some sub> [<condition>]
4114     # The interpreter actually traps this one for us; we just put the
4115     # necessary condition in the %postponed hash.
4116     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4117
4118         # Capture the condition if there is one. Make it true if none.
4119         my $cond = length $3 ? $3 : '1';
4120
4121         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4122         # if it was 'compile'.
4123         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4124
4125         # De-Perl4-ify the name - ' separators to ::.
4126         $subname =~ s/\'/::/g;
4127
4128         # Qualify it into the current package unless it's already qualified.
4129         $subname = "${package}::" . $subname unless $subname =~ /::/;
4130
4131         # Add main if it starts with ::.
4132         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4133
4134         # Save the break type for this sub.
4135         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4136     } ## end elsif ($line =~ ...
4137     # b <filename>:<line> [<condition>]
4138     elsif ($line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4139         my ($filename, $line_num, $cond) = ($1, $2, $3);
4140         cmd_b_filename_line(
4141             $filename,
4142             $line_num,
4143             (length($cond) ? $cond : '1'),
4144         );
4145     }
4146     # b <sub name> [<condition>]
4147     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4148
4149         #
4150         $subname = $1;
4151         my $cond = length $2 ? $2 : '1';
4152         &cmd_b_sub( $subname, $cond );
4153     }
4154
4155     # b <line> [<condition>].
4156     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4157
4158         # Capture the line. If none, it's the current line.
4159         $line = $1 || $dbline;
4160
4161         # If there's no condition, make it '1'.
4162         my $cond = length $2 ? $2 : '1';
4163
4164         # Break on line.
4165         &cmd_b_line( $line, $cond );
4166     }
4167
4168     # Line didn't make sense.
4169     else {
4170         print "confused by line($line)?\n";
4171     }
4172 } ## end sub cmd_b
4173
4174 =head3 C<break_on_load> (API)
4175
4176 We want to break when this file is loaded. Mark this file in the
4177 C<%break_on_load> hash, and note that it has a breakpoint in
4178 C<%had_breakpoints>.
4179
4180 =cut
4181
4182 sub break_on_load {
4183     my $file = shift;
4184     $break_on_load{$file} = 1;
4185     $had_breakpoints{$file} |= 1;
4186 }
4187
4188 =head3 C<report_break_on_load> (API)
4189
4190 Gives us an array of filenames that are set to break on load. Note that
4191 only files with break-on-load are in here, so simply showing the keys
4192 suffices.
4193
4194 =cut
4195
4196 sub report_break_on_load {
4197     sort keys %break_on_load;
4198 }
4199
4200 =head3 C<cmd_b_load> (command)
4201
4202 We take the file passed in and try to find it in C<%INC> (which maps modules
4203 to files they came from). We mark those files for break-on-load via
4204 C<break_on_load> and then report that it was done.
4205
4206 =cut
4207
4208 sub cmd_b_load {
4209     my $file = shift;
4210     my @files;
4211
4212     # This is a block because that way we can use a redo inside it
4213     # even without there being any looping structure at all outside it.
4214     {
4215
4216         # Save short name and full path if found.
4217         push @files, $file;
4218         push @files, $::INC{$file} if $::INC{$file};
4219
4220         # Tack on .pm and do it again unless there was a '.' in the name
4221         # already.
4222         $file .= '.pm', redo unless $file =~ /\./;
4223     }
4224
4225     # Do the real work here.
4226     break_on_load($_) for @files;
4227
4228     # All the files that have break-on-load breakpoints.
4229     @files = report_break_on_load;
4230
4231     # Normalize for the purposes of our printing this.
4232     local $\ = '';
4233     local $" = ' ';
4234     print $OUT "Will stop on load of '@files'.\n";
4235 } ## end sub cmd_b_load
4236
4237 =head3 C<$filename_error> (API package global)
4238
4239 Several of the functions we need to implement in the API need to work both
4240 on the current file and on other files. We don't want to duplicate code, so
4241 C<$filename_error> is used to contain the name of the file that's being
4242 worked on (if it's not the current one).
4243
4244 We can now build functions in pairs: the basic function works on the current
4245 file, and uses C<$filename_error> as part of its error message. Since this is
4246 initialized to C<"">, no filename will appear when we are working on the
4247 current file.
4248
4249 The second function is a wrapper which does the following:
4250
4251 =over 4
4252
4253 =item *
4254
4255 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4256
4257 =item *
4258
4259 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4260
4261 =item *
4262
4263 Calls the first function.
4264
4265 The first function works on the I<current> file (i.e., the one we changed to),
4266 and prints C<$filename_error> in the error message (the name of the other file)
4267 if it needs to. When the functions return, C<*dbline> is restored to point
4268 to the actual current file (the one we're executing in) and
4269 C<$filename_error> is restored to C<"">. This restores everything to
4270 the way it was before the second function was called at all.
4271
4272 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4273 details.
4274
4275 =back
4276
4277 =cut
4278
4279 use vars qw($filename_error);
4280 $filename_error = '';
4281
4282 =head3 breakable_line(from, to) (API)
4283
4284 The subroutine decides whether or not a line in the current file is breakable.
4285 It walks through C<@dbline> within the range of lines specified, looking for
4286 the first line that is breakable.
4287
4288 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4289 first line I<after> C<$to> that's breakable, if there is one.
4290
4291 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4292 first line I<before> C<$to> that's breakable, if there is one.
4293
4294 =cut
4295
4296 sub breakable_line {
4297
4298     my ( $from, $to ) = @_;
4299
4300     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4301     my $i = $from;
4302
4303     # If there are at least 2 arguments, we're trying to search a range.
4304     if ( @_ >= 2 ) {
4305
4306         # $delta is positive for a forward search, negative for a backward one.
4307         my $delta = $from < $to ? +1 : -1;
4308
4309         # Keep us from running off the ends of the file.
4310         my $limit = $delta > 0 ? $#dbline : 1;
4311
4312         # Clever test. If you're a mathematician, it's obvious why this
4313         # test works. If not:
4314         # If $delta is positive (going forward), $limit will be $#dbline.
4315         #    If $to is less than $limit, ($limit - $to) will be positive, times
4316         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4317         #    as the stopping point.
4318         #
4319         #    If $to is greater than $limit, ($limit - $to) is negative,
4320         #    times $delta of 1 (positive), so the result is < 0 and we should
4321         #    use $limit ($#dbline) as the stopping point.
4322         #
4323         # If $delta is negative (going backward), $limit will be 1.
4324         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4325         #    (negative) so the result is > 0, and we use $to as the stopping
4326         #    point.
4327         #
4328         #    If $to is less than zero, ($limit - $to) will be positive,
4329         #    times $delta of -1 (negative), so the result is not > 0, and
4330         #    we use $limit (1) as the stopping point.
4331         #
4332         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4333         #    (negative), still giving zero; the result is not > 0, and
4334         #    we use $limit (1) as the stopping point.
4335         #
4336         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4337         #    (negative), giving a positive (>0) value, so we'll set $limit to
4338         #    $to.
4339
4340         $limit = $to if ( $limit - $to ) * $delta > 0;
4341
4342         # The real search loop.
4343         # $i starts at $from (the point we want to start searching from).
4344         # We move through @dbline in the appropriate direction (determined
4345         # by $delta: either -1 (back) or +1 (ahead).
4346         # We stay in as long as we haven't hit an executable line
4347         # ($dbline[$i] == 0 means not executable) and we haven't reached
4348         # the limit yet (test similar to the above).
4349         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4350
4351     } ## end if (@_ >= 2)
4352
4353     # If $i points to a line that is executable, return that.
4354     return $i unless $dbline[$i] == 0;
4355
4356     # Format the message and print it: no breakable lines in range.
4357     my ( $pl, $upto ) = ( '', '' );
4358     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4359
4360     # If there's a filename in filename_error, we'll see it.
4361     # If not, not.
4362     die "Line$pl $from$upto$filename_error not breakable\n";
4363 } ## end sub breakable_line
4364
4365 =head3 breakable_line_in_filename(file, from, to) (API)
4366
4367 Like C<breakable_line>, but look in another file.
4368
4369 =cut
4370
4371 sub breakable_line_in_filename {
4372
4373     # Capture the file name.
4374     my ($f) = shift;
4375
4376     # Swap the magic line array over there temporarily.
4377     local *dbline = $main::{ '_<' . $f };
4378
4379     # If there's an error, it's in this other file.
4380     local $filename_error = " of '$f'";
4381
4382     # Find the breakable line.
4383     breakable_line(@_);
4384
4385     # *dbline and $filename_error get restored when this block ends.
4386
4387 } ## end sub breakable_line_in_filename
4388
4389 =head3 break_on_line(lineno, [condition]) (API)
4390
4391 Adds a breakpoint with the specified condition (or 1 if no condition was
4392 specified) to the specified line. Dies if it can't.
4393
4394 =cut
4395
4396 sub break_on_line {
4397     my ( $i, $cond ) = @_;
4398
4399     # Always true if no condition supplied.
4400     $cond = 1 unless @_ >= 2;
4401
4402     my $inii  = $i;
4403     my $after = '';
4404     my $pl    = '';
4405
4406     # Woops, not a breakable line. $filename_error allows us to say
4407     # if it was in a different file.
4408     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4409
4410     # Mark this file as having breakpoints in it.
4411     $had_breakpoints{$filename} |= 1;
4412
4413     # If there is an action or condition here already ...
4414     if ( $dbline{$i} ) {
4415
4416         # ... swap this condition for the existing one.
4417         $dbline{$i} =~ s/^[^\0]*/$cond/;
4418     }
4419     else {
4420
4421         # Nothing here - just add the condition.
4422         $dbline{$i} = $cond;
4423
4424         _set_breakpoint_enabled_status($filename, $i, 1);
4425     }
4426 } ## end sub break_on_line
4427
4428 =head3 cmd_b_line(line, [condition]) (command)
4429
4430 Wrapper for C<break_on_line>. Prints the failure message if it
4431 doesn't work.
4432
4433 =cut
4434
4435 sub cmd_b_line {
4436     eval { break_on_line(@_); 1 } or do {
4437         local $\ = '';
4438         print $OUT $@ and return;
4439     };
4440 } ## end sub cmd_b_line
4441
4442 =head3 cmd_b_filename_line(line, [condition]) (command)
4443
4444 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4445 doesn't work.
4446
4447 =cut
4448
4449 sub cmd_b_filename_line {
4450     eval { break_on_filename_line(@_); 1 } or do {
4451         local $\ = '';
4452         print $OUT $@ and return;
4453     };
4454 }
4455
4456 =head3 break_on_filename_line(file, line, [condition]) (API)
4457
4458 Switches to the file specified and then calls C<break_on_line> to set
4459 the breakpoint.
4460
4461 =cut
4462
4463 sub break_on_filename_line {
4464     my ( $f, $i, $cond ) = @_;
4465
4466     # Always true if condition left off.
4467     $cond = 1 unless @_ >= 3;
4468
4469     # Switch the magical hash temporarily.
4470     local *dbline = $main::{ '_<' . $f };
4471
4472     # Localize the variables that break_on_line uses to make its message.
4473     local $filename_error = " of '$f'";
4474     local $filename       = $f;
4475
4476     # Add the breakpoint.
4477     break_on_line( $i, $cond );
4478 } ## end sub break_on_filename_line
4479
4480 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4481
4482 Switch to another file, search the range of lines specified for an
4483 executable one, and put a breakpoint on the first one you find.
4484
4485 =cut
4486
4487 sub break_on_filename_line_range {
4488     my ( $f, $from, $to, $cond ) = @_;
4489
4490     # Find a breakable line if there is one.
4491     my $i = breakable_line_in_filename( $f, $from, $to );
4492
4493     # Always true if missing.
4494     $cond = 1 unless @_ >= 3;
4495
4496     # Add the breakpoint.
4497     break_on_filename_line( $f, $i, $cond );
4498 } ## end sub break_on_filename_line_range
4499
4500 =head3 subroutine_filename_lines(subname, [condition]) (API)
4501
4502 Search for a subroutine within a given file. The condition is ignored.
4503 Uses C<find_sub> to locate the desired subroutine.
4504
4505 =cut
4506
4507 sub subroutine_filename_lines {
4508     my ( $subname, $cond ) = @_;
4509
4510     # Returned value from find_sub() is fullpathname:startline-endline.
4511     # The match creates the list (fullpathname, start, end). Falling off
4512     # the end of the subroutine returns this implicitly.
4513     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
4514 } ## end sub subroutine_filename_lines
4515
4516 =head3 break_subroutine(subname) (API)
4517
4518 Places a break on the first line possible in the specified subroutine. Uses
4519 C<subroutine_filename_lines> to find the subroutine, and
4520 C<break_on_filename_line_range> to place the break.
4521
4522 =cut
4523
4524 sub break_subroutine {
4525     my $subname = shift;
4526
4527     # Get filename, start, and end.
4528     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
4529       or die "Subroutine $subname not found.\n";
4530
4531
4532     # Null condition changes to '1' (always true).
4533     my $cond = @_ ? shift(@_) : 1;
4534
4535     # Put a break the first place possible in the range of lines
4536     # that make up this subroutine.
4537     break_on_filename_line_range( $file, $s, $e, $cond );
4538 } ## end sub break_subroutine
4539
4540 =head3 cmd_b_sub(subname, [condition]) (command)
4541
4542 We take the incoming subroutine name and fully-qualify it as best we can.
4543
4544 =over 4
4545
4546 =item 1. If it's already fully-qualified, leave it alone.
4547
4548 =item 2. Try putting it in the current package.
4549
4550 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
4551
4552 =item 4. If it starts with '::', put it in 'main::'.
4553
4554 =back
4555
4556 After all this cleanup, we call C<break_subroutine> to try to set the
4557 breakpoint.
4558
4559 =cut
4560
4561 sub cmd_b_sub {
4562     my ( $subname, $cond ) = @_;
4563
4564     # Add always-true condition if we have none.
4565     $cond = 1 unless @_ >= 2;
4566
4567     # If the subname isn't a code reference, qualify it so that
4568     # break_subroutine() will work right.
4569     unless ( ref $subname eq 'CODE' ) {
4570
4571         # Not Perl4.
4572         $subname =~ s/\'/::/g;
4573         my $s = $subname;
4574
4575         # Put it in this package unless it's already qualified.
4576         $subname = "${package}::" . $subname
4577           unless $subname =~ /::/;
4578
4579         # Requalify it into CORE::GLOBAL if qualifying it into this
4580         # package resulted in its not being defined, but only do so
4581         # if it really is in CORE::GLOBAL.
4582         $subname = "CORE::GLOBAL::$s"
4583           if not defined &$subname
4584           and $s !~ /::/
4585           and defined &{"CORE::GLOBAL::$s"};
4586
4587         # Put it in package 'main' if it has a leading ::.
4588         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4589
4590     } ## end unless (ref $subname eq 'CODE')
4591
4592     # Try to set the breakpoint.
4593     eval { break_subroutine( $subname, $cond ); 1 } or do {
4594         local $\ = '';
4595         print $OUT $@ and return;
4596       }
4597 } ## end sub cmd_b_sub
4598
4599 =head3 C<cmd_B> - delete breakpoint(s) (command)
4600
4601 The command mostly parses the command line and tries to turn the argument
4602 into a line spec. If it can't, it uses the current line. It then calls
4603 C<delete_breakpoint> to actually do the work.
4604
4605 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
4606 thereby deleting all the breakpoints.
4607
4608 =cut
4609
4610 sub cmd_B {
4611     my $cmd = shift;
4612
4613     # No line spec? Use dbline.
4614     # If there is one, use it if it's non-zero, or wipe it out if it is.
4615     my $line   = ( $_[0] =~ /^\./ ) ? $dbline : shift || '';
4616     my $dbline = shift;
4617
4618     # If the line was dot, make the line the current one.
4619     $line =~ s/^\./$dbline/;
4620
4621     # If it's * we're deleting all the breakpoints.
4622     if ( $line eq '*' ) {
4623         eval { &delete_breakpoint(); 1 } or print $OUT $@ and return;
4624     }
4625
4626     # If there is a line spec, delete the breakpoint on that line.
4627     elsif ( $line =~ /^(\S.*)/ ) {
4628         eval { &delete_breakpoint( $line || $dbline ); 1 } or do {
4629             local $\ = '';
4630             print $OUT $@ and return;
4631         };
4632     } ## end elsif ($line =~ /^(\S.*)/)
4633
4634     # No line spec.
4635     else {
4636         print $OUT
4637           "Deleting a breakpoint requires a line number, or '*' for all\n"
4638           ;    # hint
4639     }
4640 } ## end sub cmd_B
4641
4642 =head3 delete_breakpoint([line]) (API)
4643
4644 This actually does the work of deleting either a single breakpoint, or all
4645 of them.
4646
4647 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
4648 just drop out with a message saying so. If it is, we remove the condition
4649 part of the 'condition\0action' that says there's a breakpoint here. If,
4650 after we've done that, there's nothing left, we delete the corresponding
4651 line in C<%dbline> to signal that no action needs to be taken for this line.
4652
4653 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
4654 which lists all currently-loaded files which have breakpoints. We then look
4655 at each line in each of these files, temporarily switching the C<%dbline>
4656 and C<@dbline> structures to point to the files in question, and do what
4657 we did in the single line case: delete the condition in C<@dbline>, and
4658 delete the key in C<%dbline> if nothing's left.
4659
4660 We then wholesale delete C<%postponed>, C<%postponed_file>, and
4661 C<%break_on_load>, because these structures contain breakpoints for files
4662 and code that haven't been loaded yet. We can just kill these off because there
4663 are no magical debugger structures associated with them.
4664
4665 =cut
4666
4667 sub delete_breakpoint {
4668     my $i = shift;
4669
4670     my $fn = $filename;
4671
4672     # If we got a line, delete just that one.
4673     if ( defined($i) ) {
4674
4675         # Woops. This line wasn't breakable at all.
4676         die "Line $i not breakable.\n" if $dbline[$i] == 0;
4677
4678         # Kill the condition, but leave any action.
4679         $dbline{$i} =~ s/^[^\0]*//;
4680
4681         # Remove the entry entirely if there's no action left.
4682         if ($dbline{$i} eq '') {
4683             delete $dbline{$i};
4684             _delete_breakpoint_data_ref($fn, $i);
4685         }
4686     }
4687
4688     # No line; delete them all.
4689     else {
4690         print $OUT "Deleting all breakpoints...\n";
4691
4692         # %had_breakpoints lists every file that had at least one
4693         # breakpoint in it.
4694         for my $file ( keys %had_breakpoints ) {
4695
4696             # Switch to the desired file temporarily.
4697             local *dbline = $main::{ '_<' . $file };
4698
4699             $max = $#dbline;
4700             my $was;
4701
4702             # For all lines in this file ...
4703             for $i (1 .. $max) {
4704
4705                 # If there's a breakpoint or action on this line ...
4706                 if ( defined $dbline{$i} ) {
4707
4708                     # ... remove the breakpoint.
4709                     $dbline{$i} =~ s/^[^\0]+//;
4710                     if ( $dbline{$i} =~ s/^\0?$// ) {
4711
4712                         # Remove the entry altogether if no action is there.
4713                         delete $dbline{$i};
4714                         _delete_breakpoint_data_ref($file, $i);
4715                     }
4716                 } ## end if (defined $dbline{$i...
4717             } ## end for $i (1 .. $max)
4718
4719             # If, after we turn off the "there were breakpoints in this file"
4720             # bit, the entry in %had_breakpoints for this file is zero,
4721             # we should remove this file from the hash.
4722             if ( not $had_breakpoints{$file} &= ~1 ) {
4723                 delete $had_breakpoints{$file};
4724             }
4725         } ## end for my $file (keys %had_breakpoints)
4726
4727         # Kill off all the other breakpoints that are waiting for files that
4728         # haven't been loaded yet.
4729         undef %postponed;
4730         undef %postponed_file;
4731         undef %break_on_load;
4732     } ## end else [ if (defined($i))
4733 } ## end sub delete_breakpoint
4734
4735 =head3 cmd_stop (command)
4736
4737 This is meant to be part of the new command API, but it isn't called or used
4738 anywhere else in the debugger. XXX It is probably meant for use in development
4739 of new commands.
4740
4741 =cut
4742
4743 sub cmd_stop {    # As on ^C, but not signal-safy.
4744     $signal = 1;
4745 }
4746
4747 =head3 C<cmd_e> - threads
4748
4749 Display the current thread id:
4750
4751         e
4752
4753 This could be how (when implemented) to send commands to this thread id (e cmd)
4754 or that thread id (e tid cmd).
4755
4756 =cut
4757
4758 sub cmd_e {
4759     my $cmd  = shift;
4760     my $line = shift;
4761         unless (exists($INC{'threads.pm'})) {
4762                 print "threads not loaded($ENV{PERL5DB_THREADED})
4763                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4764         } else {
4765                 my $tid = threads->tid;
4766                 print "thread id: $tid\n";
4767         }
4768 } ## end sub cmd_e
4769
4770 =head3 C<cmd_E> - list of thread ids
4771
4772 Display the list of available thread ids:
4773
4774         E
4775
4776 This could be used (when implemented) to send commands to all threads (E cmd).
4777
4778 =cut
4779
4780 sub cmd_E {
4781     my $cmd  = shift;
4782     my $line = shift;
4783         unless (exists($INC{'threads.pm'})) {
4784                 print "threads not loaded($ENV{PERL5DB_THREADED})
4785                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4786         } else {
4787                 my $tid = threads->tid;
4788                 print "thread ids: ".join(', ',
4789                         map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
4790                 )."\n";
4791         }
4792 } ## end sub cmd_E
4793
4794 =head3 C<cmd_h> - help command (command)
4795
4796 Does the work of either
4797
4798 =over 4
4799
4800 =item *
4801
4802 Showing all the debugger help
4803
4804 =item *
4805
4806 Showing help for a specific command
4807
4808 =back
4809
4810 =cut
4811
4812 use vars qw($help);
4813 use vars qw($summary);
4814
4815 sub cmd_h {
4816     my $cmd = shift;
4817
4818     # If we have no operand, assume null.
4819     my $line = shift || '';
4820
4821     # 'h h'. Print the long-format help.
4822     if ( $line =~ /^h\s*/ ) {
4823         print_help($help);
4824     }
4825
4826     # 'h <something>'. Search for the command and print only its help.
4827     elsif ( $line =~ /^(\S.*)$/ ) {
4828
4829         # support long commands; otherwise bogus errors
4830         # happen when you ask for h on <CR> for example
4831         my $asked = $1;    # the command requested
4832                            # (for proper error message)
4833
4834         my $qasked = quotemeta($asked);    # for searching; we don't
4835                                            # want to use it as a pattern.
4836                                            # XXX: finds CR but not <CR>
4837
4838         # Search the help string for the command.
4839         if (
4840             $help =~ /^                    # Start of a line
4841                       <?                   # Optional '<'
4842                       (?:[IB]<)            # Optional markup
4843                       $qasked              # The requested command
4844                      /mx
4845           )
4846         {
4847
4848             # It's there; pull it out and print it.
4849             while (
4850                 $help =~ /^
4851                               (<?            # Optional '<'
4852                                  (?:[IB]<)   # Optional markup
4853                                  $qasked     # The command
4854                                  ([\s\S]*?)  # Description line(s)
4855                               \n)            # End of last description line
4856                               (?!\s)         # Next line not starting with
4857                                              # whitespace
4858                              /mgx
4859               )
4860             {
4861                 print_help($1);
4862             }
4863         }
4864
4865         # Not found; not a debugger command.
4866         else {
4867             print_help("B<$asked> is not a debugger command.\n");
4868         }
4869     } ## end elsif ($line =~ /^(\S.*)$/)
4870
4871     # 'h' - print the summary help.
4872     else {
4873         print_help($summary);
4874     }
4875 } ## end sub cmd_h
4876
4877 =head3 C<cmd_i> - inheritance display
4878
4879 Display the (nested) parentage of the module or object given.
4880
4881 =cut
4882
4883 sub cmd_i {
4884     my $cmd  = shift;
4885     my $line = shift;
4886     foreach my $isa ( split( /\s+/, $line ) ) {
4887         $evalarg = $isa;
4888         ($isa) = &eval;
4889         no strict 'refs';
4890         print join(
4891             ', ',
4892             map {
4893                 "$_"
4894                   . (
4895                     defined( ${"$_\::VERSION"} )
4896                     ? ' ' . ${"$_\::VERSION"}
4897                     : undef )
4898               } @{mro::get_linear_isa(ref($isa) || $isa)}
4899         );
4900         print "\n";
4901     }
4902 } ## end sub cmd_i
4903
4904 =head3 C<cmd_l> - list lines (command)
4905
4906 Most of the command is taken up with transforming all the different line
4907 specification syntaxes into 'start-stop'. After that is done, the command
4908 runs a loop over C<@dbline> for the specified range of lines. It handles
4909 the printing of each line and any markers (C<==E<gt>> for current line,
4910 C<b> for break on this line, C<a> for action on this line, C<:> for this
4911 line breakable).
4912
4913 We save the last line listed in the C<$start> global for further listing
4914 later.
4915
4916 =cut
4917
4918 sub cmd_l {
4919     my $current_line = $line;
4920     my $cmd  = shift;
4921     my $line = shift;
4922
4923     # If this is '-something', delete any spaces after the dash.
4924     $line =~ s/^-\s*$/-/;
4925
4926     # If the line is '$something', assume this is a scalar containing a
4927     # line number.
4928     if ( $line =~ /^(\$.*)/s ) {
4929
4930         # Set up for DB::eval() - evaluate in *user* context.
4931         $evalarg = $1;
4932         # $evalarg = $2;
4933         my ($s) = &eval;
4934
4935         # Ooops. Bad scalar.
4936         print( $OUT "Error: $@\n" ), next CMD if $@;
4937
4938         # Good scalar. If it's a reference, find what it points to.
4939         $s = CvGV_name($s);
4940         print( $OUT "Interpreted as: $1 $s\n" );
4941         $line = "$1 $s";
4942
4943         # Call self recursively to really do the command.
4944         &cmd_l( 'l', $s );
4945     } ## end if ($line =~ /^(\$.*)/s)
4946
4947     # l name. Try to find a sub by that name.
4948     elsif ( $line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s ) {
4949         my $s = $subname = $1;
4950
4951         # De-Perl4.
4952         $subname =~ s/\'/::/;
4953
4954         # Put it in this package unless it starts with ::.
4955         $subname = $package . "::" . $subname unless $subname =~ /::/;
4956
4957         # Put it in CORE::GLOBAL if t doesn't start with :: and
4958         # it doesn't live in this package and it lives in CORE::GLOBAL.
4959         $subname = "CORE::GLOBAL::$s"
4960           if not defined &$subname
4961           and $s !~ /::/
4962           and defined &{"CORE::GLOBAL::$s"};
4963
4964         # Put leading '::' names into 'main::'.
4965         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4966
4967         # Get name:start-stop from find_sub, and break this up at
4968         # colons.
4969         my @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
4970
4971         # Pull off start-stop.
4972         my $subrange = pop @pieces;
4973
4974         # If the name contained colons, the split broke it up.
4975         # Put it back together.
4976         $file = join( ':', @pieces );
4977
4978         # If we're not in that file, switch over to it.
4979         if ( $file ne $filename ) {
4980             print $OUT "Switching to file '$file'.\n"
4981               unless $slave_editor;
4982
4983             # Switch debugger's magic structures.
4984             *dbline   = $main::{ '_<' . $file };
4985             $max      = $#dbline;
4986             $filename = $file;
4987         } ## end if ($file ne $filename)
4988
4989         # Subrange is 'start-stop'. If this is less than a window full,
4990         # swap it to 'start+', which will list a window from the start point.
4991         if ($subrange) {
4992             if ( eval($subrange) < -$window ) {
4993                 $subrange =~ s/-.*/+/;
4994             }
4995
4996             # Call self recursively to list the range.
4997             $line = $subrange;
4998             &cmd_l( 'l', $subrange );
4999         } ## end if ($subrange)
5000
5001         # Couldn't find it.
5002         else {
5003             print $OUT "Subroutine $subname not found.\n";
5004         }
5005     } ## end elsif ($line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s)
5006
5007     # Bare 'l' command.
5008     elsif ( $line =~ /^\s*$/ ) {
5009
5010         # Compute new range to list.
5011         $incr = $window - 1;
5012         $line = $start . '-' . ( $start + $incr );
5013
5014         # Recurse to do it.
5015         &cmd_l( 'l', $line );
5016     }
5017
5018     # l [start]+number_of_lines
5019     elsif ( $line =~ /^(\d*)\+(\d*)$/ ) {
5020
5021         # Don't reset start for 'l +nnn'.
5022         $start = $1 if $1;
5023
5024         # Increment for list. Use window size if not specified.
5025         # (Allows 'l +' to work.)
5026         $incr = $2;
5027         $incr = $window - 1 unless $incr;
5028
5029         # Create a line range we'll understand, and recurse to do it.
5030         $line = $start . '-' . ( $start + $incr );
5031         &cmd_l( 'l', $line );
5032     } ## end elsif ($line =~ /^(\d*)\+(\d*)$/)
5033
5034     # l start-stop or l start,stop
5035     elsif ( $line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/ ) {
5036
5037         # Determine end point; use end of file if not specified.
5038         my $end = ( !defined $2 ) ? $max : ( $4 ? $4 : $2 );
5039
5040         # Go on to the end, and then stop.
5041         $end = $max if $end > $max;
5042
5043         # Determine start line.
5044         my $i    = $2;
5045         $i    = $line if $i eq '.';
5046         $i    = 1 if $i < 1;
5047         $incr = $end - $i;
5048
5049         # If we're running under a slave editor, force it to show the lines.
5050         if ($slave_editor) {
5051             print $OUT "\032\032$filename:$i:0\n";
5052             $i = $end;
5053         }
5054
5055         # We're doing it ourselves. We want to show the line and special
5056         # markers for:
5057         # - the current line in execution
5058         # - whether a line is breakable or not
5059         # - whether a line has a break or not
5060         # - whether a line has an action or not
5061         else {
5062             for ( ; $i <= $end ; $i++ ) {
5063
5064                 # Check for breakpoints and actions.
5065                 my ( $stop, $action );
5066                 ( $stop, $action ) = split( /\0/, $dbline{$i} )
5067                   if $dbline{$i};
5068
5069                 # ==> if this is the current line in execution,
5070                 # : if it's breakable.
5071                 my $arrow =
5072                   ( $i == $current_line and $filename eq $filename_ini )
5073                   ? '==>'
5074                   : ( $dbline[$i] + 0 ? ':' : ' ' );
5075
5076                 # Add break and action indicators.
5077                 $arrow .= 'b' if $stop;
5078                 $arrow .= 'a' if $action;
5079
5080                 # Print the line.
5081                 print $OUT "$i$arrow\t", $dbline[$i];
5082
5083                 # Move on to the next line. Drop out on an interrupt.
5084                 $i++, last if $signal;
5085             } ## end for (; $i <= $end ; $i++)
5086
5087             # Line the prompt up; print a newline if the last line listed
5088             # didn't have a newline.
5089             print $OUT "\n" unless $dbline[ $i - 1 ] =~ /\n$/;
5090         } ## end else [ if ($slave_editor)
5091
5092         # Save the point we last listed to in case another relative 'l'
5093         # command is desired. Don't let it run off the end.
5094         $start = $i;
5095         $start = $max if $start > $max;
5096     } ## end elsif ($line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/)
5097 } ## end sub cmd_l
5098
5099 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5100
5101 To list breakpoints, the command has to look determine where all of them are
5102 first. It starts a C<%had_breakpoints>, which tells us what all files have
5103 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5104 magic source and breakpoint data structures) to the file, and then look
5105 through C<%dbline> for lines with breakpoints and/or actions, listing them
5106 out. We look through C<%postponed> not-yet-compiled subroutines that have
5107 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5108 that have breakpoints.
5109
5110 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5111
5112 =cut
5113
5114 sub cmd_L {
5115     my $cmd = shift;
5116
5117     # If no argument, list everything. Pre-5.8.0 version always lists
5118     # everything
5119     my $arg = shift || 'abw';
5120     $arg = 'abw' unless $CommandSet eq '580';    # sigh...
5121
5122     # See what is wanted.
5123     my $action_wanted = ( $arg =~ /a/ ) ? 1 : 0;
5124     my $break_wanted  = ( $arg =~ /b/ ) ? 1 : 0;
5125     my $watch_wanted  = ( $arg =~ /w/ ) ? 1 : 0;
5126
5127     # Breaks and actions are found together, so we look in the same place
5128     # for both.
5129     if ( $break_wanted or $action_wanted ) {
5130
5131         # Look in all the files with breakpoints...
5132         for my $file ( keys %had_breakpoints ) {
5133
5134             # Temporary switch to this file.
5135             local *dbline = $main::{ '_<' . $file };
5136
5137             # Set up to look through the whole file.
5138             $max = $#dbline;
5139             my $was;    # Flag: did we print something
5140                         # in this file?
5141
5142             # For each line in the file ...
5143             for my $i (1 .. $max) {
5144
5145                 # We've got something on this line.
5146                 if ( defined $dbline{$i} ) {
5147
5148                     # Print the header if we haven't.
5149                     print $OUT "$file:\n" unless $was++;
5150
5151                     # Print the line.
5152                     print $OUT " $i:\t", $dbline[$i];
5153
5154                     # Pull out the condition and the action.
5155                     my ( $stop, $action ) = split( /\0/, $dbline{$i} );
5156
5157                     # Print the break if there is one and it's wanted.
5158                     print $OUT "   break if (", $stop, ")\n"
5159                       if $stop
5160                       and $break_wanted;
5161
5162                     # Print the action if there is one and it's wanted.
5163                     print $OUT "   action:  ", $action, "\n"
5164                       if $action
5165                       and $action_wanted;
5166
5167                     # Quit if the user hit interrupt.
5168                     last if $signal;
5169                 } ## end if (defined $dbline{$i...
5170             } ## end for my $i (1 .. $max)
5171         } ## end for my $file (keys %had_breakpoints)
5172     } ## end if ($break_wanted or $action_wanted)
5173
5174     # Look for breaks in not-yet-compiled subs:
5175     if ( %postponed and $break_wanted ) {
5176         print $OUT "Postponed breakpoints in subroutines:\n";
5177         my $subname;
5178         for $subname ( keys %postponed ) {
5179             print $OUT " $subname\t$postponed{$subname}\n";
5180             last if $signal;
5181         }
5182     } ## end if (%postponed and $break_wanted)
5183
5184     # Find files that have not-yet-loaded breaks:
5185     my @have = map {    # Combined keys
5186         keys %{ $postponed_file{$_} }
5187     } keys %postponed_file;
5188
5189     # If there are any, list them.
5190     if ( @have and ( $break_wanted or $action_wanted ) ) {
5191         print $OUT "Postponed breakpoints in files:\n";
5192         my ( $file, $line );
5193
5194         for $file ( keys %postponed_file ) {
5195             my $db = $postponed_file{$file};
5196             print $OUT " $file:\n";
5197             for $line ( sort { $a <=> $b } keys %$db ) {
5198                 print $OUT "  $line:\n";
5199                 my ( $stop, $action ) = split( /\0/, $$db{$line} );
5200                 print $OUT "    break if (", $stop, ")\n"
5201                   if $stop
5202                   and $break_wanted;
5203                 print $OUT "    action:  ", $action, "\n"
5204                   if $action
5205                   and $action_wanted;
5206                 last if $signal;
5207             } ## end for $line (sort { $a <=>...
5208             last if $signal;
5209         } ## end for $file (keys %postponed_file)
5210     } ## end if (@have and ($break_wanted...
5211     if ( %break_on_load and $break_wanted ) {
5212         print $OUT "Breakpoints on load:\n";
5213         my $file;
5214         for $file ( keys %break_on_load ) {
5215             print $OUT " $file\n";
5216             last if $signal;
5217         }
5218     } ## end if (%break_on_load and...
5219     if ($watch_wanted) {
5220         if ( $trace & 2 ) {
5221             print $OUT "Watch-expressions:\n" if @to_watch;
5222             for my $expr (@to_watch) {
5223                 print $OUT " $expr\n";
5224                 last if $signal;
5225             }
5226         } ## end if ($trace & 2)
5227     } ## end if ($watch_wanted)
5228 } ## end sub cmd_L
5229
5230 =head3 C<cmd_M> - list modules (command)
5231
5232 Just call C<list_modules>.
5233
5234 =cut
5235
5236 sub cmd_M {
5237     &list_modules();
5238 }
5239
5240 =head3 C<cmd_o> - options (command)
5241
5242 If this is just C<o> by itself, we list the current settings via
5243 C<dump_option>. If there's a nonblank value following it, we pass that on to
5244 C<parse_options> for processing.
5245
5246 =cut
5247
5248 sub cmd_o {
5249     my $cmd = shift;
5250     my $opt = shift || '';    # opt[=val]
5251
5252     # Nonblank. Try to parse and process.
5253     if ( $opt =~ /^(\S.*)/ ) {
5254         &parse_options($1);
5255     }
5256
5257     # Blank. List the current option settings.
5258     else {
5259         for (@options) {
5260             &dump_option($_);
5261         }
5262     }
5263 } ## end sub cmd_o
5264
5265 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5266
5267 Advises the user that the O command has been renamed.
5268
5269 =cut
5270
5271 sub cmd_O {
5272     print $OUT "The old O command is now the o command.\n";             # hint
5273     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5274     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5275 }
5276
5277 =head3 C<cmd_v> - view window (command)
5278
5279 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5280 move back a few lines to list the selected line in context. Uses C<cmd_l>
5281 to do the actual listing after figuring out the range of line to request.
5282
5283 =cut
5284
5285 use vars qw($preview);
5286
5287 sub cmd_v {
5288     my $cmd  = shift;
5289     my $line = shift;
5290
5291     # Extract the line to list around. (Astute readers will have noted that
5292     # this pattern will match whether or not a numeric line is specified,
5293     # which means that we'll always enter this loop (though a non-numeric
5294     # argument results in no action at all)).
5295     if ( $line =~ /^(\d*)$/ ) {
5296
5297         # Total number of lines to list (a windowful).
5298         $incr = $window - 1;
5299
5300         # Set the start to the argument given (if there was one).
5301         $start = $1 if $1;
5302
5303         # Back up by the context amount.
5304         $start -= $preview;
5305
5306         # Put together a linespec that cmd_l will like.
5307         $line = $start . '-' . ( $start + $incr );
5308
5309         # List the lines.
5310         &cmd_l( 'l', $line );
5311     } ## end if ($line =~ /^(\d*)$/)
5312 } ## end sub cmd_v
5313
5314 =head3 C<cmd_w> - add a watch expression (command)
5315
5316 The 5.8 version of this command adds a watch expression if one is specified;
5317 it does nothing if entered with no operands.
5318
5319 We extract the expression, save it, evaluate it in the user's context, and
5320 save the value. We'll re-evaluate it each time the debugger passes a line,
5321 and will stop (see the code at the top of the command loop) if the value
5322 of any of the expressions changes.
5323
5324 =cut
5325
5326 sub cmd_w {
5327     my $cmd = shift;
5328
5329     # Null expression if no arguments.
5330     my $expr = shift || '';
5331
5332     # If expression is not null ...
5333     if ( $expr =~ /^(\S.*)/ ) {
5334
5335         # ... save it.
5336         push @to_watch, $expr;
5337
5338         # Parameterize DB::eval and call it to get the expression's value
5339         # in the user's context. This version can handle expressions which
5340         # return a list value.
5341         $evalarg = $expr;
5342         my ($val) = join( ' ', &eval );
5343         $val = ( defined $val ) ? "'$val'" : 'undef';
5344
5345         # Save the current value of the expression.
5346         push @old_watch, $val;
5347
5348         # We are now watching expressions.
5349         $trace |= 2;
5350     } ## end if ($expr =~ /^(\S.*)/)
5351
5352     # You have to give one to get one.
5353     else {
5354         print $OUT "Adding a watch-expression requires an expression\n";  # hint
5355     }
5356 } ## end sub cmd_w
5357
5358 =head3 C<cmd_W> - delete watch expressions (command)
5359
5360 This command accepts either a watch expression to be removed from the list
5361 of watch expressions, or C<*> to delete them all.
5362
5363 If C<*> is specified, we simply empty the watch expression list and the
5364 watch expression value list. We also turn off the bit that says we've got
5365 watch expressions.
5366
5367 If an expression (or partial expression) is specified, we pattern-match
5368 through the expressions and remove the ones that match. We also discard
5369 the corresponding values. If no watch expressions are left, we turn off
5370 the I<watching expressions> bit.
5371
5372 =cut
5373
5374 sub cmd_W {
5375     my $cmd  = shift;
5376     my $expr = shift || '';
5377
5378     # Delete them all.
5379     if ( $expr eq '*' ) {
5380
5381         # Not watching now.
5382         $trace &= ~2;
5383
5384         print $OUT "Deleting all watch expressions ...\n";
5385
5386         # And all gone.
5387         @to_watch = @old_watch = ();
5388     }
5389
5390     # Delete one of them.
5391     elsif ( $expr =~ /^(\S.*)/ ) {
5392
5393         # Where we are in the list.
5394         my $i_cnt = 0;
5395
5396         # For each expression ...
5397         foreach (@to_watch) {
5398             my $val = $to_watch[$i_cnt];
5399
5400             # Does this one match the command argument?
5401             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
5402                                       # Yes. Turn it off, and its value too.
5403                 splice( @to_watch,  $i_cnt, 1 );
5404                 splice( @old_watch, $i_cnt, 1 );
5405             }
5406             $i_cnt++;
5407         } ## end foreach (@to_watch)
5408
5409         # We don't bother to turn watching off because
5410         #  a) we don't want to stop calling watchfunction() it it exists
5411         #  b) foreach over a null list doesn't do anything anyway
5412
5413     } ## end elsif ($expr =~ /^(\S.*)/)
5414
5415     # No command arguments entered.
5416     else {
5417         print $OUT
5418           "Deleting a watch-expression requires an expression, or '*' for all\n"
5419           ;    # hint
5420     }
5421 } ## end sub cmd_W
5422
5423 ### END of the API section
5424
5425 =head1 SUPPORT ROUTINES
5426
5427 These are general support routines that are used in a number of places
5428 throughout the debugger.
5429
5430 =head2 save
5431
5432 save() saves the user's versions of globals that would mess us up in C<@saved>,
5433 and installs the versions we like better.
5434
5435 =cut
5436
5437 sub save {
5438
5439     # Save eval failure, command failure, extended OS error, output field
5440     # separator, input record separator, output record separator and
5441     # the warning setting.
5442     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
5443
5444     $,  = "";      # output field separator is null string
5445     $/  = "\n";    # input record separator is newline
5446     $\  = "";      # output record separator is null string
5447     $^W = 0;       # warnings are off
5448 } ## end sub save
5449
5450 =head2 C<print_lineinfo> - show where we are now
5451
5452 print_lineinfo prints whatever it is that it is handed; it prints it to the
5453 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
5454 us to feed line information to a slave editor without messing up the
5455 debugger output.
5456
5457 =cut
5458
5459 sub print_lineinfo {
5460
5461     # Make the terminal sensible if we're not the primary debugger.
5462     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
5463     local $\ = '';
5464     local $, = '';
5465     print $LINEINFO @_;
5466 } ## end sub print_lineinfo
5467
5468 =head2 C<postponed_sub>
5469
5470 Handles setting postponed breakpoints in subroutines once they're compiled.
5471 For breakpoints, we use C<DB::find_sub> to locate the source file and line
5472 range for the subroutine, then mark the file as having a breakpoint,
5473 temporarily switch the C<*dbline> glob over to the source file, and then
5474 search the given range of lines to find a breakable line. If we find one,
5475 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
5476
5477 =cut
5478
5479 # The following takes its argument via $evalarg to preserve current @_
5480
5481 sub postponed_sub {
5482
5483     # Get the subroutine name.
5484     my $subname = shift;
5485
5486     # If this is a 'break +<n> if <condition>' ...
5487     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
5488
5489         # If there's no offset, use '+0'.
5490         my $offset = $1 || 0;
5491
5492         # find_sub's value is 'fullpath-filename:start-stop'. It's
5493         # possible that the filename might have colons in it too.
5494         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
5495         if ($i) {
5496
5497             # We got the start line. Add the offset '+<n>' from
5498             # $postponed{subname}.
5499             $i += $offset;
5500
5501             # Switch to the file this sub is in, temporarily.
5502             local *dbline = $main::{ '_<' . $file };
5503
5504             # No warnings, please.
5505             local $^W = 0;    # != 0 is magical below
5506
5507             # This file's got a breakpoint in it.
5508             $had_breakpoints{$file} |= 1;
5509
5510             # Last line in file.
5511             $max = $#dbline;
5512
5513             # Search forward until we hit a breakable line or get to
5514             # the end of the file.
5515             ++$i until $dbline[$i] != 0 or $i >= $max;
5516
5517             # Copy the breakpoint in and delete it from %postponed.
5518             $dbline{$i} = delete $postponed{$subname};
5519         } ## end if ($i)
5520
5521         # find_sub didn't find the sub.
5522         else {
5523             local $\ = '';
5524             print $OUT "Subroutine $subname not found.\n";
5525         }
5526         return;
5527     } ## end if ($postponed{$subname...
5528     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
5529
5530     #print $OUT "In postponed_sub for '$subname'.\n";
5531 } ## end sub postponed_sub
5532
5533 =head2 C<postponed>
5534
5535 Called after each required file is compiled, but before it is executed;
5536 also called if the name of a just-compiled subroutine is a key of
5537 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
5538 etc.) into the just-compiled code.
5539
5540 If this is a C<require>'d file, the incoming parameter is the glob
5541 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
5542
5543 If it's a subroutine, the incoming parameter is the subroutine name.
5544
5545 =cut
5546
5547 sub postponed {
5548
5549     # If there's a break, process it.
5550     if ($ImmediateStop) {
5551
5552         # Right, we've stopped. Turn it off.
5553         $ImmediateStop = 0;
5554
5555         # Enter the command loop when DB::DB gets called.
5556         $signal = 1;
5557     }
5558
5559     # If this is a subroutine, let postponed_sub() deal with it.
5560     return &postponed_sub unless ref \$_[0] eq 'GLOB';
5561
5562     # Not a subroutine. Deal with the file.
5563     local *dbline = shift;
5564     my $filename = $dbline;
5565     $filename =~ s/^_<//;
5566     local $\ = '';
5567     $signal = 1, print $OUT "'$filename' loaded...\n"
5568       if $break_on_load{$filename};
5569     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
5570
5571     # Do we have any breakpoints to put in this file?
5572     return unless $postponed_file{$filename};
5573
5574     # Yes. Mark this file as having breakpoints.
5575     $had_breakpoints{$filename} |= 1;
5576
5577     # "Cannot be done: insufficient magic" - we can't just put the
5578     # breakpoints saved in %postponed_file into %dbline by assigning
5579     # the whole hash; we have to do it one item at a time for the
5580     # breakpoints to be set properly.
5581     #%dbline = %{$postponed_file{$filename}};
5582
5583     # Set the breakpoints, one at a time.
5584     my $key;
5585
5586     for $key ( keys %{ $postponed_file{$filename} } ) {
5587
5588         # Stash the saved breakpoint into the current file's magic line array.
5589         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
5590     }
5591
5592     # This file's been compiled; discard the stored breakpoints.
5593     delete $postponed_file{$filename};
5594
5595 } ## end sub postponed
5596
5597 =head2 C<dumpit>
5598
5599 C<dumpit> is the debugger's wrapper around dumpvar.pl.
5600
5601 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
5602 a reference to a variable (the thing to be dumped) as its input.
5603
5604 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
5605 the currently-selected filehandle, thank you very much). The current
5606 values of the package globals C<$single> and C<$trace> are backed up in
5607 lexicals, and they are turned off (this keeps the debugger from trying
5608 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
5609 preserve its current value and it is set to zero to prevent entry/exit
5610 messages from printing, and C<$doret> is localized as well and set to -2 to
5611 prevent return values from being shown.
5612
5613 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
5614 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
5615 installed version in C<@INC>, yours will be used instead. Possible security
5616 problem?).
5617
5618 It then checks to see if the subroutine C<main::dumpValue> is now defined
5619 (it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
5620 localizes the globals necessary for things to be sane when C<main::dumpValue()>
5621 is called, and picks up the variable to be dumped from the parameter list.
5622
5623 It checks the package global C<%options> to see if there's a C<dumpDepth>
5624 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
5625 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
5626 structure: -1 means dump everything.
5627
5628 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
5629 warning.
5630
5631 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
5632 and we then return to the caller.
5633
5634 =cut
5635
5636 sub dumpit {
5637
5638     # Save the current output filehandle and switch to the one
5639     # passed in as the first parameter.
5640     my $savout = select(shift);
5641
5642     # Save current settings of $single and $trace, and then turn them off.
5643     my $osingle = $single;
5644     my $otrace  = $trace;
5645     $single = $trace = 0;
5646
5647     # XXX Okay, what do $frame and $doret do, again?
5648     local $frame = 0;
5649     local $doret = -2;
5650
5651     # Load dumpvar.pl unless we've already got the sub we need from it.
5652     unless ( defined &main::dumpValue ) {
5653         do 'dumpvar.pl' or die $@;
5654     }
5655
5656     # If the load succeeded (or we already had dumpvalue()), go ahead
5657     # and dump things.
5658     if ( defined &main::dumpValue ) {
5659         local $\ = '';
5660         local $, = '';
5661         local $" = ' ';
5662         my $v = shift;
5663         my $maxdepth = shift || $option{dumpDepth};
5664         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
5665         &main::dumpValue( $v, $maxdepth );
5666     } ## end if (defined &main::dumpValue)
5667
5668     # Oops, couldn't load dumpvar.pl.
5669     else {
5670         local $\ = '';
5671         print $OUT "dumpvar.pl not available.\n";
5672     }
5673
5674     # Reset $single and $trace to their old values.
5675     $single = $osingle;
5676     $trace  = $otrace;
5677
5678     # Restore the old filehandle.
5679     select($savout);
5680 } ## end sub dumpit
5681
5682 =head2 C<print_trace>
5683
5684 C<print_trace>'s job is to print a stack trace. It does this via the
5685 C<dump_trace> routine, which actually does all the ferreting-out of the
5686 stack trace data. C<print_trace> takes care of formatting it nicely and
5687 printing it to the proper filehandle.
5688
5689 Parameters:
5690
5691 =over 4
5692
5693 =item *
5694
5695 The filehandle to print to.
5696
5697 =item *
5698
5699 How many frames to skip before starting trace.
5700
5701 =item *
5702
5703 How many frames to print.
5704
5705 =item *
5706
5707 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
5708
5709 =back
5710
5711 The original comment below seems to be noting that the traceback may not be
5712 correct if this routine is called in a tied method.
5713
5714 =cut
5715
5716 # Tied method do not create a context, so may get wrong message:
5717
5718 sub print_trace {
5719     local $\ = '';
5720     my $fh = shift;
5721
5722     # If this is going to a slave editor, but we're not the primary
5723     # debugger, reset it first.
5724     resetterm(1)
5725       if $fh        eq $LINEINFO    # slave editor
5726       and $LINEINFO eq $OUT         # normal output
5727       and $term_pid != $$;          # not the primary
5728
5729     # Collect the actual trace information to be formatted.
5730     # This is an array of hashes of subroutine call info.
5731     my @sub = dump_trace( $_[0] + 1, $_[1] );
5732
5733     # Grab the "short report" flag from @_.
5734     my $short = $_[2];              # Print short report, next one for sub name
5735
5736     # Run through the traceback info, format it, and print it.
5737     my $s;
5738     for my $i (0 .. $#sub) {
5739
5740         # Drop out if the user has lost interest and hit control-C.
5741         last if $signal;
5742
5743         # Set the separator so arrys print nice.
5744         local $" = ', ';
5745
5746         # Grab and stringify the arguments if they are there.
5747         my $args =
5748           defined $sub[$i]{args}
5749           ? "(@{ $sub[$i]{args} })"
5750           : '';
5751
5752         # Shorten them up if $maxtrace says they're too long.
5753         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
5754           if length $args > $maxtrace;
5755
5756         # Get the file name.
5757         my $file = $sub[$i]{file};
5758
5759         # Put in a filename header if short is off.
5760         $file = $file eq '-e' ? $file : "file '$file'" unless $short;
5761
5762         # Get the actual sub's name, and shorten to $maxtrace's requirement.
5763         $s = $sub[$i]{sub};
5764         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
5765
5766         # Short report uses trimmed file and sub names.
5767         if ($short) {
5768             my $sub = @_ >= 4 ? $_[3] : $s;
5769             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
5770         } ## end if ($short)
5771
5772         # Non-short report includes full names.
5773         else {
5774             print $fh "$sub[$i]{context} = $s$args"
5775               . " called from $file"
5776               . " line $sub[$i]{line}\n";
5777         }
5778     } ## end for my $i (0 .. $#sub)
5779 } ## end sub print_trace
5780
5781 =head2 dump_trace(skip[,count])
5782
5783 Actually collect the traceback information available via C<caller()>. It does
5784 some filtering and cleanup of the data, but mostly it just collects it to
5785 make C<print_trace()>'s job easier.
5786
5787 C<skip> defines the number of stack frames to be skipped, working backwards
5788 from the most current. C<count> determines the total number of frames to
5789 be returned; all of them (well, the first 10^9) are returned if C<count>
5790 is omitted.
5791
5792 This routine returns a list of hashes, from most-recent to least-recent
5793 stack frame. Each has the following keys and values:
5794
5795 =over 4
5796
5797 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
5798
5799 =item * C<sub> - subroutine name, or C<eval> information
5800
5801 =item * C<args> - undef, or a reference to an array of arguments
5802
5803 =item * C<file> - the file in which this item was defined (if any)
5804
5805 =item * C<line> - the line on which it was defined
5806
5807 =back
5808
5809 =cut
5810
5811 sub dump_trace {
5812
5813     # How many levels to skip.
5814     my $skip = shift;
5815
5816     # How many levels to show. (1e9 is a cheap way of saying "all of them";
5817     # it's unlikely that we'll have more than a billion stack frames. If you
5818     # do, you've got an awfully big machine...)
5819     my $count = shift || 1e9;
5820
5821     # We increment skip because caller(1) is the first level *back* from
5822     # the current one.  Add $skip to the count of frames so we have a
5823     # simple stop criterion, counting from $skip to $count+$skip.
5824     $skip++;
5825     $count += $skip;
5826
5827     # These variables are used to capture output from caller();
5828     my ( $p, $file, $line, $sub, $h, $context );
5829
5830     my ( $e, $r, @a, @sub, $args );
5831
5832     # XXX Okay... why'd we do that?
5833     my $nothard = not $frame & 8;
5834     local $frame = 0;
5835
5836     # Do not want to trace this.
5837     my $otrace = $trace;
5838     $trace = 0;
5839
5840     # Start out at the skip count.
5841     # If we haven't reached the number of frames requested, and caller() is
5842     # still returning something, stay in the loop. (If we pass the requested
5843     # number of stack frames, or we run out - caller() returns nothing - we
5844     # quit.
5845     # Up the stack frame index to go back one more level each time.
5846     for (
5847         my $i = $skip ;
5848         $i < $count
5849         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
5850         $i++
5851     )
5852     {
5853
5854         # Go through the arguments and save them for later.
5855         @a = ();
5856         for my $arg (@args) {
5857             my $type;
5858             if ( not defined $arg ) {    # undefined parameter
5859                 push @a, "undef";
5860             }
5861
5862             elsif ( $nothard and tied $arg ) {    # tied parameter
5863                 push @a, "tied";
5864             }
5865             elsif ( $nothard and $type = ref $arg ) {    # reference
5866                 push @a, "ref($type)";
5867             }
5868             else {                                       # can be stringified
5869                 local $_ =
5870                   "$arg";    # Safe to stringify now - should not call f().
5871
5872                 # Backslash any single-quotes or backslashes.
5873                 s/([\'\\])/\\$1/g;
5874
5875                 # Single-quote it unless it's a number or a colon-separated
5876                 # name.
5877                 s/(.*)/'$1'/s
5878                   unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
5879
5880                 # Turn high-bit characters into meta-whatever.
5881                 s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
5882
5883                 # Turn control characters into ^-whatever.
5884                 s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
5885
5886                 push( @a, $_ );
5887             } ## end else [ if (not defined $arg)
5888         } ## end for $arg (@args)
5889
5890         # If context is true, this is array (@)context.
5891         # If context is false, this is scalar ($) context.
5892         # If neither, context isn't defined. (This is apparently a 'can't
5893         # happen' trap.)
5894         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
5895
5896         # if the sub has args ($h true), make an anonymous array of the
5897         # dumped args.
5898         $args = $h ? [@a] : undef;
5899
5900         # remove trailing newline-whitespace-semicolon-end of line sequence
5901         # from the eval text, if any.
5902         $e =~ s/\n\s*\;\s*\Z// if $e;
5903
5904         # Escape backslashed single-quotes again if necessary.
5905         $e =~ s/([\\\'])/\\$1/g if $e;
5906
5907         # if the require flag is true, the eval text is from a require.
5908         if ($r) {
5909             $sub = "require '$e'";
5910         }
5911
5912         # if it's false, the eval text is really from an eval.
5913         elsif ( defined $r ) {
5914             $sub = "eval '$e'";
5915         }
5916
5917         # If the sub is '(eval)', this is a block eval, meaning we don't
5918         # know what the eval'ed text actually was.
5919         elsif ( $sub eq '(eval)' ) {
5920             $sub = "eval {...}";
5921         }
5922
5923         # Stick the collected information into @sub as an anonymous hash.
5924         push(
5925             @sub,
5926             {
5927                 context => $context,
5928                 sub     => $sub,
5929                 args    => $args,
5930                 file    => $file,
5931                 line    => $line
5932             }
5933         );
5934
5935         # Stop processing frames if the user hit control-C.
5936         last if $signal;
5937     } ## end for ($i = $skip ; $i < ...
5938
5939     # Restore the trace value again.
5940     $trace = $otrace;
5941     @sub;
5942 } ## end sub dump_trace
5943
5944 =head2 C<action()>
5945
5946 C<action()> takes input provided as the argument to an add-action command,
5947 either pre- or post-, and makes sure it's a complete command. It doesn't do
5948 any fancy parsing; it just keeps reading input until it gets a string
5949 without a trailing backslash.
5950
5951 =cut
5952
5953 sub action {
5954     my $action = shift;
5955
5956     while ( $action =~ s/\\$// ) {
5957
5958         # We have a backslash on the end. Read more.
5959         $action .= &gets;
5960     } ## end while ($action =~ s/\\$//)
5961
5962     # Return the assembled action.
5963     $action;
5964 } ## end sub action
5965
5966 =head2 unbalanced
5967
5968 This routine mostly just packages up a regular expression to be used
5969 to check that the thing it's being matched against has properly-matched
5970 curly braces.
5971
5972 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
5973 speeds things up by only creating the qr//'ed expression once; if it's
5974 already defined, we don't try to define it again. A speed hack.
5975
5976 =cut
5977
5978 use vars qw($balanced_brace_re);
5979
5980 sub unbalanced {
5981
5982     # I hate using globals!
5983     $balanced_brace_re ||= qr{
5984         ^ \{
5985              (?:
5986                  (?> [^{}] + )              # Non-parens without backtracking
5987                 |
5988                  (??{ $balanced_brace_re }) # Group with matching parens
5989               ) *
5990           \} $
5991    }x;
5992     return $_[0] !~ m/$balanced_brace_re/;
5993 } ## end sub unbalanced
5994
5995 =head2 C<gets()>
5996
5997 C<gets()> is a primitive (very primitive) routine to read continuations.
5998 It was devised for reading continuations for actions.
5999 it just reads more input with C<readline()> and returns it.
6000
6001 =cut
6002
6003 sub gets {
6004     &readline("cont: ");
6005 }
6006
6007 =head2 C<DB::system()> - handle calls to<system()> without messing up the debugger
6008
6009 The C<system()> function assumes that it can just go ahead and use STDIN and
6010 STDOUT, but under the debugger, we want it to use the debugger's input and
6011 outout filehandles.
6012
6013 C<DB::system()> socks away the program's STDIN and STDOUT, and then substitutes
6014 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
6015 and then puts everything back again.
6016
6017 =cut
6018
6019 sub system {
6020
6021     # We save, change, then restore STDIN and STDOUT to avoid fork() since
6022     # some non-Unix systems can do system() but have problems with fork().
6023     open( SAVEIN,  "<&STDIN" )  || &warn("Can't save STDIN");
6024     open( SAVEOUT, ">&STDOUT" ) || &warn("Can't save STDOUT");
6025     open( STDIN,   "<&IN" )     || &warn("Can't redirect STDIN");
6026     open( STDOUT,  ">&OUT" )    || &warn("Can't redirect STDOUT");
6027
6028     # XXX: using csh or tcsh destroys sigint retvals!
6029     system(@_);
6030     open( STDIN,  "<&SAVEIN" )  || &warn("Can't restore STDIN");
6031     open( STDOUT, ">&SAVEOUT" ) || &warn("Can't restore STDOUT");
6032     close(SAVEIN);
6033     close(SAVEOUT);
6034
6035     # most of the $? crud was coping with broken cshisms
6036     if ( $? >> 8 ) {
6037         &warn( "(Command exited ", ( $? >> 8 ), ")\n" );
6038     }
6039     elsif ($?) {
6040         &warn(
6041             "(Command died of SIG#",
6042             ( $? & 127 ),
6043             ( ( $? & 128 ) ? " -- core dumped" : "" ),
6044             ")", "\n"
6045         );
6046     } ## end elsif ($?)
6047
6048     return $?;
6049
6050 } ## end sub system
6051
6052 =head1 TTY MANAGEMENT
6053
6054 The subs here do some of the terminal management for multiple debuggers.
6055
6056 =head2 setterm
6057
6058 Top-level function called when we want to set up a new terminal for use
6059 by the debugger.
6060
6061 If the C<noTTY> debugger option was set, we'll either use the terminal
6062 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6063 to find one. If we're a forked debugger, we call C<resetterm> to try to
6064 get a whole new terminal if we can.
6065
6066 In either case, we set up the terminal next. If the C<ReadLine> option was
6067 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6068 the appropriate attributes. We then
6069
6070 =cut
6071
6072 use vars qw($ornaments);
6073 use vars qw($rl_attribs);
6074
6075 sub setterm {
6076
6077     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6078     local $frame = 0;
6079     local $doret = -2;
6080     require Term::ReadLine;
6081
6082     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6083     if ($notty) {
6084         if ($tty) {
6085             my ( $i, $o ) = split $tty, /,/;
6086             $o = $i unless defined $o;
6087             open( IN,  "<$i" ) or die "Cannot open TTY '$i' for read: $!";
6088             open( OUT, ">$o" ) or die "Cannot open TTY '$o' for write: $!";
6089             $IN  = \*IN;
6090             $OUT = \*OUT;
6091             my $sel = select($OUT);
6092             $| = 1;
6093             select($sel);
6094         } ## end if ($tty)
6095
6096         # We don't have a TTY - try to find one via Term::Rendezvous.
6097         else {
6098             require Term::Rendezvous;
6099
6100             # See if we have anything to pass to Term::Rendezvous.
6101             # Use $HOME/.perldbtty$$ if not.
6102             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6103
6104             # Rendezvous and get the filehandles.
6105             my $term_rv = Term::Rendezvous->new( $rv );
6106             $IN  = $term_rv->IN;
6107             $OUT = $term_rv->OUT;
6108         } ## end else [ if ($tty)
6109     } ## end if ($notty)
6110
6111     # We're a daughter debugger. Try to fork off another TTY.
6112     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6113         resetterm(2);
6114     }
6115
6116     # If we shouldn't use Term::ReadLine, don't.
6117     if ( !$rl ) {
6118         $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6119     }
6120
6121     # We're using Term::ReadLine. Get all the attributes for this terminal.
6122     else {
6123         $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6124
6125         $rl_attribs = $term->Attribs;
6126         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6127           if defined $rl_attribs->{basic_word_break_characters}
6128           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6129         $rl_attribs->{special_prefixes} = '$@&%';
6130         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6131         $rl_attribs->{completion_function} = \&db_complete;
6132     } ## end else [ if (!$rl)
6133
6134     # Set up the LINEINFO filehandle.
6135     $LINEINFO = $OUT     unless defined $LINEINFO;
6136     $lineinfo = $console unless defined $lineinfo;
6137
6138     $term->MinLine(2);
6139
6140     &load_hist();
6141
6142     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6143         $term->SetHistory(@hist);
6144     }
6145
6146     # XXX Ornaments are turned on unconditionally, which is not
6147     # always a good thing.
6148     ornaments($ornaments) if defined $ornaments;
6149     $term_pid = $$;
6150 } ## end sub setterm
6151
6152 sub load_hist {
6153     $histfile //= option_val("HistFile", undef);
6154     return unless defined $histfile;
6155     open my $fh, "<", $histfile or return;
6156     local $/ = "\n";
6157     @hist = ();
6158     while (<$fh>) {
6159         chomp;
6160         push @hist, $_;
6161     }
6162     close $fh;
6163 }
6164
6165 sub save_hist {
6166     return unless defined $histfile;
6167     eval { require File::Path } or return;
6168     eval { require File::Basename } or return;
6169     File::Path::mkpath(File::Basename::dirname($histfile));
6170     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6171     $histsize //= option_val("HistSize",100);
6172     my @copy = grep { $_ ne '?' } @hist;
6173     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6174     for ($start .. $#copy) {
6175         print $fh "$copy[$_]\n";
6176     }
6177     close $fh or die "Could not write '$histfile': $!";
6178 }
6179
6180 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6181
6182 When the process being debugged forks, or the process invokes a command
6183 via C<system()> which starts a new debugger, we need to be able to get a new
6184 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6185 fight over the terminal, and you can never quite be sure who's going to get the
6186 input you're typing.
6187
6188 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6189 is tasked with doing all the necessary operating system mojo to get a new
6190 TTY (and probably another window) and to direct the new debugger to read and
6191 write there.
6192
6193 The debugger provides C<get_fork_TTY> functions which work for TCP
6194 socket servers, X11, OS/2, and Mac OS X. Other systems are not
6195 supported. You are encouraged to write C<get_fork_TTY> functions which
6196 work for I<your> platform and contribute them.
6197
6198 =head3 C<socket_get_fork_TTY>
6199
6200 =cut
6201
6202 sub connect_remoteport {
6203     require IO::Socket;
6204
6205     my $socket = IO::Socket::INET->new(
6206         Timeout  => '10',
6207         PeerAddr => $remoteport,
6208         Proto    => 'tcp',
6209     );
6210     if ( ! $socket ) {
6211         die "Unable to connect to remote host: $remoteport\n";
6212     }
6213     return $socket;
6214 }
6215
6216 sub socket_get_fork_TTY {
6217     $tty = $LINEINFO = $IN = $OUT = connect_remoteport();
6218
6219     # Do I need to worry about setting $term?
6220
6221     reset_IN_OUT( $IN, $OUT );
6222     return '';
6223 }
6224
6225 =head3 C<xterm_get_fork_TTY>
6226
6227 This function provides the C<get_fork_TTY> function for X11. If a
6228 program running under the debugger forks, a new <xterm> window is opened and
6229 the subsidiary debugger is directed there.
6230
6231 The C<open()> call is of particular note here. We have the new C<xterm>
6232 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6233 command (which prints the device name of the TTY we'll want to use for input
6234 and output to STDOUT, then C<sleep> for a very long time, routing this output
6235 to file number 3. This way we can simply read from the <XT> filehandle (which
6236 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6237
6238 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6239 properly set up.
6240
6241 =cut
6242
6243 sub xterm_get_fork_TTY {
6244     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6245     open XT,
6246 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6247  sleep 10000000' |];
6248
6249     # Get the output from 'tty' and clean it up a little.
6250     my $tty = <XT>;
6251     chomp $tty;
6252
6253     $pidprompt = '';    # Shown anyway in titlebar
6254
6255     # We need $term defined or we can not switch to the newly created xterm
6256     if ($tty ne '' && !defined $term) {
6257         require Term::ReadLine;
6258         if ( !$rl ) {
6259             $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6260         }
6261         else {
6262             $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6263         }
6264     }
6265     # There's our new TTY.
6266     return $tty;
6267 } ## end sub xterm_get_fork_TTY
6268
6269 =head3 C<os2_get_fork_TTY>
6270
6271 XXX It behooves an OS/2 expert to write the necessary documentation for this!
6272
6273 =cut
6274
6275 # This example function resets $IN, $OUT itself
6276 my $c_pipe = 0;
6277 sub os2_get_fork_TTY { # A simplification of the following (and works without):
6278     local $\  = '';
6279     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6280     my %opt = ( title => "Daughter Perl debugger $pids $name",
6281                 ($rl ? (read_by_key => 1) : ()) );
6282     require OS2::Process;
6283     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
6284       or return;
6285     $pidprompt = '';    # Shown anyway in titlebar
6286     reset_IN_OUT($in, $out);
6287     $tty = '*reset*';
6288     return '';          # Indicate that reset_IN_OUT is called
6289 } ## end sub os2_get_fork_TTY
6290
6291 =head3 C<macosx_get_fork_TTY>
6292
6293 The Mac OS X version uses AppleScript to tell Terminal.app to create
6294 a new window.
6295
6296 =cut
6297
6298 # Notes about Terminal.app's AppleScript support,
6299 # (aka things that might break in future OS versions).
6300 #
6301 # The "do script" command doesn't return a reference to the new window
6302 # it creates, but since it appears frontmost and windows are enumerated
6303 # front to back, we can use "first window" === "window 1".
6304 #
6305 # Since "do script" is implemented by supplying the argument (plus a
6306 # return character) as terminal input, there's a potential race condition
6307 # where the debugger could beat the shell to reading the command.
6308 # To prevent this, we wait for the screen to clear before proceeding.
6309 #
6310 # 10.3 and 10.4:
6311 # There's no direct accessor for the tty device name, so we fiddle
6312 # with the window title options until it says what we want.
6313 #
6314 # 10.5:
6315 # There _is_ a direct accessor for the tty device name, _and_ there's
6316 # a new possible component of the window title (the name of the settings
6317 # set).  A separate version is needed.
6318
6319 my @script_versions=
6320
6321     ([237, <<'__LEOPARD__'],
6322 tell application "Terminal"
6323     do script "clear;exec sleep 100000"
6324     tell first tab of first window
6325         copy tty to thetty
6326         set custom title to "forked perl debugger"
6327         set title displays custom title to true
6328         repeat while (length of first paragraph of (get contents)) > 0
6329             delay 0.1
6330         end repeat
6331     end tell
6332 end tell
6333 thetty
6334 __LEOPARD__
6335
6336      [100, <<'__JAGUAR_TIGER__'],
6337 tell application "Terminal"
6338     do script "clear;exec sleep 100000"
6339     tell first window
6340         set title displays shell path to false
6341         set title displays window size to false
6342         set title displays file name to false
6343         set title displays device name to true
6344         set title displays custom title to true
6345         set custom title to ""
6346         copy "/dev/" & name to thetty
6347         set custom title to "forked perl debugger"
6348         repeat while (length of first paragraph of (get contents)) > 0
6349             delay 0.1
6350         end repeat
6351     end tell
6352 end tell
6353 thetty
6354 __JAGUAR_TIGER__
6355
6356 );
6357
6358 sub macosx_get_fork_TTY
6359 {
6360     my($version,$script,$pipe,$tty);
6361
6362     return unless $version=$ENV{TERM_PROGRAM_VERSION};
6363     foreach my $entry (@script_versions) {
6364         if ($version>=$entry->[0]) {
6365             $script=$entry->[1];
6366             last;
6367         }
6368     }
6369     return unless defined($script);
6370     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
6371     $tty=readline($pipe);
6372     close($pipe);
6373     return unless defined($tty) && $tty =~ m(^/dev/);
6374     chomp $tty;
6375     return $tty;
6376 }
6377
6378 =head2 C<create_IN_OUT($flags)>
6379
6380 Create a new pair of filehandles, pointing to a new TTY. If impossible,
6381 try to diagnose why.
6382
6383 Flags are:
6384
6385 =over 4
6386
6387 =item * 1 - Don't know how to create a new TTY.
6388
6389 =item * 2 - Debugger has forked, but we can't get a new TTY.
6390
6391 =item * 4 - standard debugger startup is happening.
6392
6393 =back
6394
6395 =cut
6396
6397 use vars qw($fork_TTY);
6398
6399 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
6400
6401     # If we know how to get a new TTY, do it! $in will have
6402     # the TTY name if get_fork_TTY works.
6403     my $in = &get_fork_TTY if defined &get_fork_TTY;
6404
6405     # It used to be that
6406     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
6407
6408     if ( not defined $in ) {
6409         my $why = shift;
6410
6411         # We don't know how.
6412         print_help(<<EOP) if $why == 1;
6413 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
6414 EOP
6415
6416         # Forked debugger.
6417         print_help(<<EOP) if $why == 2;
6418 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
6419   This may be an asynchronous session, so the parent debugger may be active.
6420 EOP
6421
6422         # Note that both debuggers are fighting over the same input.
6423         print_help(<<EOP) if $why != 4;
6424   Since two debuggers fight for the same TTY, input is severely entangled.
6425
6426 EOP
6427         print_help(<<EOP);
6428   I know how to switch the output to a different window in xterms, OS/2
6429   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
6430   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
6431   B<DB::get_fork_TTY()> returning this.
6432
6433   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
6434   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
6435
6436 EOP
6437     } ## end if (not defined $in)
6438     elsif ( $in ne '' ) {
6439         TTY($in);
6440     }
6441     else {
6442         $console = '';    # Indicate no need to open-from-the-console
6443     }
6444     undef $fork_TTY;
6445 } ## end sub create_IN_OUT
6446
6447 =head2 C<resetterm>
6448
6449 Handles rejiggering the prompt when we've forked off a new debugger.
6450
6451 If the new debugger happened because of a C<system()> that invoked a
6452 program under the debugger, the arrow between the old pid and the new
6453 in the prompt has I<two> dashes instead of one.
6454
6455 We take the current list of pids and add this one to the end. If there
6456 isn't any list yet, we make one up out of the initial pid associated with
6457 the terminal and our new pid, sticking an arrow (either one-dashed or
6458 two dashed) in between them.
6459
6460 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
6461 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
6462 and try to do that.
6463
6464 =cut
6465
6466 sub resetterm {    # We forked, so we need a different TTY
6467
6468     # Needs to be passed to create_IN_OUT() as well.
6469     my $in = shift;
6470
6471     # resetterm(2): got in here because of a system() starting a debugger.
6472     # resetterm(1): just forked.
6473     my $systemed = $in > 1 ? '-' : '';
6474
6475     # If there's already a list of pids, add this to the end.
6476     if ($pids) {
6477         $pids =~ s/\]/$systemed->$$]/;
6478     }
6479
6480     # No pid list. Time to make one.
6481     else {
6482         $pids = "[$term_pid->$$]";
6483     }
6484
6485     # The prompt we're going to be using for this debugger.
6486     $pidprompt = $pids;
6487
6488     # We now 0wnz this terminal.
6489     $term_pid = $$;
6490
6491     # Just return if we're not supposed to try to create a new TTY.
6492     return unless $CreateTTY & $in;
6493
6494     # Try to create a new IN/OUT pair.
6495     create_IN_OUT($in);
6496 } ## end sub resetterm
6497
6498 =head2 C<readline>
6499
6500 First, we handle stuff in the typeahead buffer. If there is any, we shift off
6501 the next line, print a message saying we got it, add it to the terminal
6502 history (if possible), and return it.
6503
6504 If there's nothing in the typeahead buffer, check the command filehandle stack.
6505 If there are any filehandles there, read from the last one, and return the line
6506 if we got one. If not, we pop the filehandle off and close it, and try the
6507 next one up the stack.
6508
6509 If we've emptied the filehandle stack, we check to see if we've got a socket
6510 open, and we read that and return it if we do. If we don't, we just call the
6511 core C<readline()> and return its value.
6512
6513 =cut
6514
6515 sub readline {
6516
6517     # Localize to prevent it from being smashed in the program being debugged.
6518     local $.;
6519
6520     # Pull a line out of the typeahead if there's stuff there.
6521     if (@typeahead) {
6522
6523         # How many lines left.
6524         my $left = @typeahead;
6525
6526         # Get the next line.
6527         my $got = shift @typeahead;
6528
6529         # Print a message saying we got input from the typeahead.
6530         local $\ = '';
6531         print $OUT "auto(-$left)", shift, $got, "\n";
6532
6533         # Add it to the terminal history (if possible).
6534         $term->AddHistory($got)
6535           if length($got) > 1
6536           and defined $term->Features->{addHistory};
6537         return $got;
6538     } ## end if (@typeahead)
6539
6540     # We really need to read some input. Turn off entry/exit trace and
6541     # return value printing.
6542     local $frame = 0;
6543     local $doret = -2;
6544
6545     # If there are stacked filehandles to read from ...
6546     while (@cmdfhs) {
6547
6548         # Read from the last one in the stack.
6549         my $line = CORE::readline( $cmdfhs[-1] );
6550
6551         # If we got a line ...
6552         defined $line
6553           ? ( print $OUT ">> $line" and return $line )    # Echo and return
6554           : close pop @cmdfhs;                            # Pop and close
6555     } ## end while (@cmdfhs)
6556
6557     # Nothing on the filehandle stack. Socket?
6558     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
6559
6560         # Send anything we have to send.
6561         $OUT->write( join( '', @_ ) );
6562
6563         # Receive anything there is to receive.
6564         my $stuff = '';
6565         my $buf;
6566         do {
6567             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
6568                                             # XXX Don't know. You tell me.
6569         } while length $buf and ($stuff .= $buf) !~ /\n/;
6570
6571         # What we got.
6572         $stuff;
6573     } ## end if (ref $OUT and UNIVERSAL::isa...
6574
6575     # No socket. Just read from the terminal.
6576     else {
6577         $term->readline(@_);
6578     }
6579 } ## end sub readline
6580
6581 =head1 OPTIONS SUPPORT ROUTINES
6582
6583 These routines handle listing and setting option values.
6584
6585 =head2 C<dump_option> - list the current value of an option setting
6586
6587 This routine uses C<option_val> to look up the value for an option.
6588 It cleans up escaped single-quotes and then displays the option and
6589 its value.
6590
6591 =cut
6592
6593 sub dump_option {
6594     my ( $opt, $val ) = @_;
6595     $val = option_val( $opt, 'N/A' );
6596     $val =~ s/([\\\'])/\\$1/g;
6597     printf $OUT "%20s = '%s'\n", $opt, $val;
6598 } ## end sub dump_option
6599
6600 sub options2remember {
6601     foreach my $k (@RememberOnROptions) {
6602         $option{$k} = option_val( $k, 'N/A' );
6603     }
6604     return %option;
6605 }
6606
6607 =head2 C<option_val> - find the current value of an option
6608
6609 This can't just be a simple hash lookup because of the indirect way that
6610 the option values are stored. Some are retrieved by calling a subroutine,
6611 some are just variables.
6612
6613 You must supply a default value to be used in case the option isn't set.
6614
6615 =cut
6616
6617 sub option_val {
6618     my ( $opt, $default ) = @_;
6619     my $val;
6620
6621     # Does this option exist, and is it a variable?
6622     # If so, retrieve the value via the value in %optionVars.
6623     if (    defined $optionVars{$opt}
6624         and defined ${ $optionVars{$opt} } )
6625     {
6626         $val = ${ $optionVars{$opt} };
6627     }
6628
6629     # Does this option exist, and it's a subroutine?
6630     # If so, call the subroutine via the ref in %optionAction
6631     # and capture the value.
6632     elsif ( defined $optionAction{$opt}
6633         and defined &{ $optionAction{$opt} } )
6634     {
6635         $val = &{ $optionAction{$opt} }();
6636     }
6637
6638     # If there's an action or variable for the supplied option,
6639     # but no value was set, use the default.
6640     elsif (defined $optionAction{$opt} and not defined $option{$opt}
6641         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
6642     {
6643         $val = $default;
6644     }
6645
6646     # Otherwise, do the simple hash lookup.
6647     else {
6648         $val = $option{$opt};
6649     }
6650
6651     # If the value isn't defined, use the default.
6652     # Then return whatever the value is.
6653     $val = $default unless defined $val;
6654     $val;
6655 } ## end sub option_val
6656
6657 =head2 C<parse_options>
6658
6659 Handles the parsing and execution of option setting/displaying commands.
6660
6661 An option entered by itself is assumed to be I<set me to 1> (the default value)
6662 if the option is a boolean one. If not, the user is prompted to enter a valid
6663 value or to query the current value (via C<option? >).
6664
6665 If C<option=value> is entered, we try to extract a quoted string from the
6666 value (if it is quoted). If it's not, we just use the whole value as-is.
6667
6668 We load any modules required to service this option, and then we set it: if
6669 it just gets stuck in a variable, we do that; if there's a subroutine to
6670 handle setting the option, we call that.
6671
6672 Finally, if we're running in interactive mode, we display the effect of the
6673 user's command back to the terminal, skipping this if we're setting things
6674 during initialization.
6675
6676 =cut
6677
6678 sub parse_options {
6679     local ($_) = @_;
6680     local $\ = '';
6681
6682     my $option;
6683
6684     # These options need a value. Don't allow them to be clobbered by accident.
6685     my %opt_needs_val = map { ( $_ => 1 ) } qw{
6686       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
6687       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
6688     };
6689
6690     while (length) {
6691         my $val_defaulted;
6692
6693         # Clean off excess leading whitespace.
6694         s/^\s+// && next;
6695
6696         # Options are always all word characters, followed by a non-word
6697         # separator.
6698         s/^(\w+)(\W?)// or print( $OUT "Invalid option '$_'\n" ), last;
6699         my ( $opt, $sep ) = ( $1, $2 );
6700
6701         # Make sure that such an option exists.
6702         my $matches = grep( /^\Q$opt/ && ( $option = $_ ), @options )
6703           || grep( /^\Q$opt/i && ( $option = $_ ), @options );
6704
6705         print( $OUT "Unknown option '$opt'\n" ), next unless $matches;
6706         print( $OUT "Ambiguous option '$opt'\n" ), next if $matches > 1;
6707         my $val;
6708
6709         # '?' as separator means query, but must have whitespace after it.
6710         if ( "?" eq $sep ) {
6711             print( $OUT "Option query '$opt?' followed by non-space '$_'\n" ),
6712               last
6713               if /^\S/;
6714
6715             #&dump_option($opt);
6716         } ## end if ("?" eq $sep)
6717
6718         # Separator is whitespace (or just a carriage return).
6719         # They're going for a default, which we assume is 1.
6720         elsif ( $sep !~ /\S/ ) {
6721             $val_defaulted = 1;
6722             $val           = "1";   #  this is an evil default; make 'em set it!
6723         }
6724
6725         # Separator is =. Trying to set a value.
6726         elsif ( $sep eq "=" ) {
6727
6728             # If quoted, extract a quoted string.
6729             if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
6730                 my $quote = $1;
6731                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
6732             }
6733
6734             # Not quoted. Use the whole thing. Warn about 'option='.
6735             else {
6736                 s/^(\S*)//;
6737                 $val = $1;
6738                 print OUT qq(Option better cleared using $opt=""\n)
6739                   unless length $val;
6740             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
6741
6742         } ## end elsif ($sep eq "=")
6743
6744         # "Quoted" with [], <>, or {}.
6745         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
6746             my ($end) =
6747               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
6748             s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
6749               or print( $OUT "Unclosed option value '$opt$sep$_'\n" ), last;
6750             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
6751         } ## end else [ if ("?" eq $sep)
6752
6753         # Exclude non-booleans from getting set to 1 by default.
6754         if ( $opt_needs_val{$option} && $val_defaulted ) {
6755             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
6756             print $OUT
6757 "Option '$opt' is non-boolean.  Use '$cmd $option=VAL' to set, '$cmd $option?' to query\n";
6758             next;
6759         } ## end if ($opt_needs_val{$option...
6760
6761         # Save the option value.
6762         $option{$option} = $val if defined $val;
6763
6764         # Load any module that this option requires.
6765         eval qq{
6766                 local \$frame = 0;
6767                 local \$doret = -2;
6768                 require '$optionRequire{$option}';
6769                 1;
6770                } || die $@   # XXX: shouldn't happen
6771           if defined $optionRequire{$option}
6772           && defined $val;
6773
6774         # Set it.
6775         # Stick it in the proper variable if it goes in a variable.
6776         ${ $optionVars{$option} } = $val
6777           if defined $optionVars{$option}
6778           && defined $val;
6779
6780         # Call the appropriate sub if it gets set via sub.
6781         &{ $optionAction{$option} }($val)
6782           if defined $optionAction{$option}
6783           && defined &{ $optionAction{$option} }
6784           && defined $val;
6785
6786         # Not initialization - echo the value we set it to.
6787         dump_option($option) unless $OUT eq \*STDERR;
6788     } ## end while (length)
6789 } ## end sub parse_options
6790
6791 =head1 RESTART SUPPORT
6792
6793 These routines are used to store (and restore) lists of items in environment
6794 variables during a restart.
6795
6796 =head2 set_list
6797
6798 Set_list packages up items to be stored in a set of environment variables
6799 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
6800 the values). Values outside the standard ASCII charset are stored by encoding
6801 then as hexadecimal values.
6802
6803 =cut
6804
6805 sub set_list {
6806     my ( $stem, @list ) = @_;
6807     my $val;
6808
6809     # VAR_n: how many we have. Scalar assignment gets the number of items.
6810     $ENV{"${stem}_n"} = @list;
6811
6812     # Grab each item in the list, escape the backslashes, encode the non-ASCII
6813     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
6814     for my $i ( 0 .. $#list ) {
6815         $val = $list[$i];
6816         $val =~ s/\\/\\\\/g;
6817         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
6818         $ENV{"${stem}_$i"} = $val;
6819     } ## end for $i (0 .. $#list)
6820 } ## end sub set_list
6821
6822 =head2 get_list
6823
6824 Reverse the set_list operation: grab VAR_n to see how many we should be getting
6825 back, and then pull VAR_0, VAR_1. etc. back out.
6826
6827 =cut
6828
6829 sub get_list {
6830     my $stem = shift;
6831     my @list;
6832     my $n = delete $ENV{"${stem}_n"};
6833     my $val;
6834     for my $i ( 0 .. $n - 1 ) {
6835         $val = delete $ENV{"${stem}_$i"};
6836         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
6837         push @list, $val;
6838     }
6839     @list;
6840 } ## end sub get_list
6841
6842 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
6843
6844 =head2 catch()
6845
6846 The C<catch()> subroutine is the essence of fast and low-impact. We simply
6847 set an already-existing global scalar variable to a constant value. This
6848 avoids allocating any memory possibly in the middle of something that will
6849 get all confused if we do, particularly under I<unsafe signals>.
6850
6851 =cut
6852
6853 sub catch {
6854     $signal = 1;
6855     return;    # Put nothing on the stack - malloc/free land!
6856 }
6857
6858 =head2 C<warn()>
6859
6860 C<warn> emits a warning, by joining together its arguments and printing
6861 them, with couple of fillips.
6862
6863 If the composited message I<doesn't> end with a newline, we automatically
6864 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
6865 to be set to the filehandle to be used to output warnings; it makes no
6866 assumptions about what filehandles are available.
6867
6868 =cut
6869
6870 sub warn {
6871     my ($msg) = join( "", @_ );
6872     $msg .= ": $!\n" unless $msg =~ /\n$/;
6873     local $\ = '';
6874     print $OUT $msg;
6875 } ## end sub warn
6876
6877 =head1 INITIALIZATION TTY SUPPORT
6878
6879 =head2 C<reset_IN_OUT>
6880
6881 This routine handles restoring the debugger's input and output filehandles
6882 after we've tried and failed to move them elsewhere.  In addition, it assigns
6883 the debugger's output filehandle to $LINEINFO if it was already open there.
6884
6885 =cut
6886
6887 sub reset_IN_OUT {
6888     my $switch_li = $LINEINFO eq $OUT;
6889
6890     # If there's a term and it's able to get a new tty, try to get one.
6891     if ( $term and $term->Features->{newTTY} ) {
6892         ( $IN, $OUT ) = ( shift, shift );
6893         $term->newTTY( $IN, $OUT );
6894     }
6895
6896     # This term can't get a new tty now. Better luck later.
6897     elsif ($term) {
6898         &warn("Too late to set IN/OUT filehandles, enabled on next 'R'!\n");
6899     }
6900
6901     # Set the filehndles up as they were.
6902     else {
6903         ( $IN, $OUT ) = ( shift, shift );
6904     }
6905
6906     # Unbuffer the output filehandle.
6907     my $o = select $OUT;
6908     $| = 1;
6909     select $o;
6910
6911     # Point LINEINFO to the same output filehandle if it was there before.
6912     $LINEINFO = $OUT if $switch_li;
6913 } ## end sub reset_IN_OUT
6914
6915 =head1 OPTION SUPPORT ROUTINES
6916
6917 The following routines are used to process some of the more complicated
6918 debugger options.
6919
6920 =head2 C<TTY>
6921
6922 Sets the input and output filehandles to the specified files or pipes.
6923 If the terminal supports switching, we go ahead and do it. If not, and
6924 there's already a terminal in place, we save the information to take effect
6925 on restart.
6926
6927 If there's no terminal yet (for instance, during debugger initialization),
6928 we go ahead and set C<$console> and C<$tty> to the file indicated.
6929
6930 =cut
6931
6932 sub TTY {
6933
6934     if ( @_ and $term and $term->Features->{newTTY} ) {
6935
6936         # This terminal supports switching to a new TTY.
6937         # Can be a list of two files, or on string containing both names,
6938         # comma-separated.
6939         # XXX Should this perhaps be an assignment from @_?
6940         my ( $in, $out ) = shift;
6941         if ( $in =~ /,/ ) {
6942
6943             # Split list apart if supplied.
6944             ( $in, $out ) = split /,/, $in, 2;
6945         }
6946         else {
6947
6948             # Use the same file for both input and output.
6949             $out = $in;
6950         }
6951
6952         # Open file onto the debugger's filehandles, if you can.
6953         open IN,  $in     or die "cannot open '$in' for read: $!";
6954         open OUT, ">$out" or die "cannot open '$out' for write: $!";
6955
6956         # Swap to the new filehandles.
6957         reset_IN_OUT( \*IN, \*OUT );
6958
6959         # Save the setting for later.
6960         return $tty = $in;
6961     } ## end if (@_ and $term and $term...
6962
6963     # Terminal doesn't support new TTY, or doesn't support readline.
6964     # Can't do it now, try restarting.
6965     &warn("Too late to set TTY, enabled on next 'R'!\n") if $term and @_;
6966
6967     # Useful if done through PERLDB_OPTS:
6968     $console = $tty = shift if @_;
6969
6970     # Return whatever the TTY is.
6971     $tty or $console;
6972 } ## end sub TTY
6973
6974 =head2 C<noTTY>
6975
6976 Sets the C<$notty> global, controlling whether or not the debugger tries to
6977 get a terminal to read from. If called after a terminal is already in place,
6978 we save the value to use it if we're restarted.
6979
6980 =cut
6981
6982 sub noTTY {
6983     if ($term) {
6984         &warn("Too late to set noTTY, enabled on next 'R'!\n") if @_;
6985     }
6986     $notty = shift if @_;
6987     $notty;
6988 } ## end sub noTTY
6989
6990 =head2 C<ReadLine>
6991
6992 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
6993 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
6994 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
6995 the value in case a restart is done so we can change it then.
6996
6997 =cut
6998
6999 sub ReadLine {
7000     if ($term) {
7001         &warn("Too late to set ReadLine, enabled on next 'R'!\n") if @_;
7002     }
7003     $rl = shift if @_;
7004     $rl;
7005 } ## end sub ReadLine
7006
7007 =head2 C<RemotePort>
7008
7009 Sets the port that the debugger will try to connect to when starting up.
7010 If the terminal's already been set up, we can't do it, but we remember the
7011 setting in case the user does a restart.
7012
7013 =cut
7014
7015 sub RemotePort {
7016     if ($term) {
7017         &warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
7018     }
7019     $remoteport = shift if @_;
7020     $remoteport;
7021 } ## end sub RemotePort
7022
7023 =head2 C<tkRunning>
7024
7025 Checks with the terminal to see if C<Tk> is running, and returns true or
7026 false. Returns false if the current terminal doesn't support C<readline>.
7027
7028 =cut
7029
7030 sub tkRunning {
7031     if ( ${ $term->Features }{tkRunning} ) {
7032         return $term->tkRunning(@_);
7033     }
7034     else {
7035         local $\ = '';
7036         print $OUT "tkRunning not supported by current ReadLine package.\n";
7037         0;
7038     }
7039 } ## end sub tkRunning
7040
7041 =head2 C<NonStop>
7042
7043 Sets nonstop mode. If a terminal's already been set up, it's too late; the
7044 debugger remembers the setting in case you restart, though.
7045
7046 =cut
7047
7048 sub NonStop {
7049     if ($term) {
7050         &warn("Too late to set up NonStop mode, enabled on next 'R'!\n")
7051           if @_;
7052     }
7053     $runnonstop = shift if @_;
7054     $runnonstop;
7055 } ## end sub NonStop
7056
7057 sub DollarCaretP {
7058     if ($term) {
7059         &warn("Some flag changes could not take effect until next 'R'!\n")
7060           if @_;
7061     }
7062     $^P = parse_DollarCaretP_flags(shift) if @_;
7063     expand_DollarCaretP_flags($^P);
7064 }
7065
7066 =head2 C<pager>
7067
7068 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
7069 there already.
7070
7071 =cut
7072
7073 sub pager {
7074     if (@_) {
7075         $pager = shift;
7076         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
7077     }
7078     $pager;
7079 } ## end sub pager
7080
7081 =head2 C<shellBang>
7082
7083 Sets the shell escape command, and generates a printable copy to be used
7084 in the help.
7085
7086 =cut
7087
7088 sub shellBang {
7089
7090     # If we got an argument, meta-quote it, and add '\b' if it
7091     # ends in a word character.
7092     if (@_) {
7093         $sh = quotemeta shift;
7094         $sh .= "\\b" if $sh =~ /\w$/;
7095     }
7096
7097     # Generate the printable version for the help:
7098     $psh = $sh;    # copy it
7099     $psh =~ s/\\b$//;        # Take off trailing \b if any
7100     $psh =~ s/\\(.)/$1/g;    # De-escape
7101     $psh;                    # return the printable version
7102 } ## end sub shellBang
7103
7104 =head2 C<ornaments>
7105
7106 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7107 was passed as the argument. (This means you can't override the terminal's
7108 ornaments.)
7109
7110 =cut
7111
7112 sub ornaments {
7113     if ( defined $term ) {
7114
7115         # We don't want to show warning backtraces, but we do want die() ones.
7116         local ( $warnLevel, $dieLevel ) = ( 0, 1 );
7117
7118         # No ornaments if the terminal doesn't support them.
7119         return '' unless $term->Features->{ornaments};
7120         eval { $term->ornaments(@_) } || '';
7121     }
7122
7123     # Use what was passed in if we can't determine it ourselves.
7124     else {
7125         $ornaments = shift;
7126     }
7127 } ## end sub ornaments
7128
7129 =head2 C<recallCommand>
7130
7131 Sets the recall command, and builds a printable version which will appear in
7132 the help text.
7133
7134 =cut
7135
7136 sub recallCommand {
7137
7138     # If there is input, metaquote it. Add '\b' if it ends with a word
7139     # character.
7140     if (@_) {
7141         $rc = quotemeta shift;
7142         $rc .= "\\b" if $rc =~ /\w$/;
7143     }
7144
7145     # Build it into a printable version.
7146     $prc = $rc;    # Copy it
7147     $prc =~ s/\\b$//;        # Remove trailing \b
7148     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7149     $prc;                    # Return the printable version
7150 } ## end sub recallCommand
7151
7152 =head2 C<LineInfo> - where the line number information goes
7153
7154 Called with no arguments, returns the file or pipe that line info should go to.
7155
7156 Called with an argument (a file or a pipe), it opens that onto the
7157 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7158 file or pipe again to the caller.
7159
7160 =cut
7161
7162 sub LineInfo {
7163     return $lineinfo unless @_;
7164     $lineinfo = shift;
7165
7166     #  If this is a valid "thing to be opened for output", tack a
7167     # '>' onto the front.
7168     my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7169
7170     # If this is a pipe, the stream points to a slave editor.
7171     $slave_editor = ( $stream =~ /^\|/ );
7172
7173     # Open it up and unbuffer it.
7174     open( LINEINFO, "$stream" ) || &warn("Cannot open '$stream' for write");
7175     $LINEINFO = \*LINEINFO;
7176     my $save = select($LINEINFO);
7177     $| = 1;
7178     select($save);
7179
7180     # Hand the file or pipe back again.
7181     $lineinfo;
7182 } ## end sub LineInfo
7183
7184 =head1 COMMAND SUPPORT ROUTINES
7185
7186 These subroutines provide functionality for various commands.
7187
7188 =head2 C<list_modules>
7189
7190 For the C<M> command: list modules loaded and their versions.
7191 Essentially just runs through the keys in %INC, picks each package's
7192 C<$VERSION> variable, gets the file name, and formats the information
7193 for output.
7194
7195 =cut
7196
7197 sub list_modules {    # versions
7198     my %version;
7199     my $file;
7200
7201     # keys are the "as-loaded" name, values are the fully-qualified path
7202     # to the file itself.
7203     for ( keys %INC ) {
7204         $file = $_;                                # get the module name
7205         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
7206         s,/,::,g;                                  # change '/' to '::'
7207         s/^perl5db$/DB/;                           # Special case: debugger
7208                                                    # moves to package DB
7209         s/^Term::ReadLine::readline$/readline/;    # simplify readline
7210
7211         # If the package has a $VERSION package global (as all good packages
7212         # should!) decode it and save as partial message.
7213         my $pkg_version = do { no strict 'refs'; ${ $_ . '::VERSION' } };
7214         if ( defined $pkg_version ) {
7215             $version{$file} = "$pkg_version from ";
7216         }
7217
7218         # Finish up the message with the file the package came from.
7219         $version{$file} .= $INC{$file};
7220     } ## end for (keys %INC)
7221
7222     # Hey, dumpit() formats a hash nicely, so why not use it?
7223     dumpit( $OUT, \%version );
7224 } ## end sub list_modules
7225
7226 =head2 C<sethelp()>
7227
7228 Sets up the monster string used to format and print the help.
7229
7230 =head3 HELP MESSAGE FORMAT
7231
7232 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
7233 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
7234 easy to parse and portable, but which still allows the help to be a little
7235 nicer than just plain text.
7236
7237 Essentially, you define the command name (usually marked up with C<< B<> >>
7238 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
7239 newline. The descriptive text can also be marked up in the same way. If you
7240 need to continue the descriptive text to another line, start that line with
7241 just tabs and then enter the marked-up text.
7242
7243 If you are modifying the help text, I<be careful>. The help-string parser is
7244 not very sophisticated, and if you don't follow these rules it will mangle the
7245 help beyond hope until you fix the string.
7246
7247 =cut
7248
7249 use vars qw($pre580_help);
7250 use vars qw($pre580_summary);
7251
7252 sub sethelp {
7253
7254     # XXX: make sure there are tabs between the command and explanation,
7255     #      or print_help will screw up your formatting if you have
7256     #      eeevil ornaments enabled.  This is an insane mess.
7257
7258     $help = "
7259 Help is currently only available for the new 5.8 command set.
7260 No help is available for the old command set.
7261 We assume you know what you're doing if you switch to it.
7262
7263 B<T>        Stack trace.
7264 B<s> [I<expr>]    Single step [in I<expr>].
7265 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7266 <B<CR>>        Repeat last B<n> or B<s> command.
7267 B<r>        Return from current subroutine.
7268 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7269         at the specified position.
7270 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7271 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7272 B<l> I<line>        List single I<line>.
7273 B<l> I<subname>    List first window of lines from subroutine.
7274 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7275 B<l>        List next window of lines.
7276 B<->        List previous window of lines.
7277 B<v> [I<line>]    View window around I<line>.
7278 B<.>        Return to the executed line.
7279 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7280         I<filename> may be either the full name of the file, or a regular
7281         expression matching the full file name:
7282         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7283         Evals (with saved bodies) are considered to be filenames:
7284         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7285         (in the order of execution).
7286 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7287 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7288 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
7289 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7290 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth).
7291 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
7292 B<b>        Sets breakpoint on current line)
7293 B<b> [I<line>] [I<condition>]
7294         Set breakpoint; I<line> defaults to the current execution line;
7295         I<condition> breaks if it evaluates to true, defaults to '1'.
7296 B<b> I<subname> [I<condition>]
7297         Set breakpoint at first line of subroutine.
7298 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7299 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7300 B<b> B<postpone> I<subname> [I<condition>]
7301         Set breakpoint at first line of subroutine after
7302         it is compiled.
7303 B<b> B<compile> I<subname>
7304         Stop after the subroutine is compiled.
7305 B<B> [I<line>]    Delete the breakpoint for I<line>.
7306 B<B> I<*>             Delete all breakpoints.
7307 B<a> [I<line>] I<command>
7308         Set an action to be done before the I<line> is executed;
7309         I<line> defaults to the current execution line.
7310         Sequence is: check for breakpoint/watchpoint, print line
7311         if necessary, do action, prompt user if necessary,
7312         execute line.
7313 B<a>        Does nothing
7314 B<A> [I<line>]    Delete the action for I<line>.
7315 B<A> I<*>             Delete all actions.
7316 B<w> I<expr>        Add a global watch-expression.
7317 B<w>             Does nothing
7318 B<W> I<expr>        Delete a global watch-expression.
7319 B<W> I<*>             Delete all watch-expressions.
7320 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7321         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7322 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7323 B<x> I<expr>        Evals expression in list context, dumps the result.
7324 B<m> I<expr>        Evals expression in list context, prints methods callable
7325         on the first element of the result.
7326 B<m> I<class>        Prints methods callable via the given class.
7327 B<M>        Show versions of loaded modules.
7328 B<i> I<class>       Prints nested parents of given class.
7329 B<e>         Display current thread id.
7330 B<E>         Display all thread ids the current one will be identified: <n>.
7331 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7332
7333 B<<> ?            List Perl commands to run before each prompt.
7334 B<<> I<expr>        Define Perl command to run before each prompt.
7335 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7336 B<< *>                Delete the list of perl commands to run before each prompt.
7337 B<>> ?            List Perl commands to run after each prompt.
7338 B<>> I<expr>        Define Perl command to run after each prompt.
7339 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7340 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
7341 B<{> I<db_command>    Define debugger command to run before each prompt.
7342 B<{> ?            List debugger commands to run before each prompt.
7343 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7344 B<{ *>             Delete the list of debugger commands to run before each prompt.
7345 B<$prc> I<number>    Redo a previous command (default previous command).
7346 B<$prc> I<-number>    Redo number'th-to-last command.
7347 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7348         See 'B<O> I<recallCommand>' too.
7349 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7350       . (
7351         $rc eq $sh
7352         ? ""
7353         : "
7354 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7355       ) . "
7356         See 'B<O> I<shellBang>' too.
7357 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
7358 B<save> I<file>       Save current debugger session (actual history) to I<file>.
7359 B<rerun>           Rerun session to current position.
7360 B<rerun> I<n>         Rerun session to numbered command.
7361 B<rerun> I<-n>        Rerun session to number'th-to-last command.
7362 B<H> I<-number>    Display last number commands (default all).
7363 B<H> I<*>          Delete complete history.
7364 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7365 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7366 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarily select()ed as well.
7367 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7368 I<command>        Execute as a perl statement in current package.
7369 B<R>        Pure-man-restart of debugger, some of debugger state
7370         and command-line options may be lost.
7371         Currently the following settings are preserved:
7372         history, breakpoints and actions, debugger B<O>ptions
7373         and the following command-line options: I<-w>, I<-I>, I<-e>.
7374
7375 B<o> [I<opt>] ...    Set boolean option to true
7376 B<o> [I<opt>B<?>]    Query options
7377 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7378         Set options.  Use quotes if spaces in value.
7379     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7380     I<pager>            program for output of \"|cmd\";
7381     I<tkRunning>            run Tk while prompting (with ReadLine);
7382     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7383     I<inhibit_exit>        Allows stepping off the end of the script.
7384     I<ImmediateStop>        Debugger should stop as early as possible.
7385     I<RemotePort>            Remote hostname:port for remote debugging
7386   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7387     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7388     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7389     I<globPrint>             whether to print contents of globs;
7390     I<DumpDBFiles>         dump arrays holding debugged files;
7391     I<DumpPackages>         dump symbol tables of packages;
7392     I<DumpReused>             dump contents of \"reused\" addresses;
7393     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7394     I<bareStringify>         Do not print the overload-stringified value;
7395   Other options include:
7396     I<PrintRet>        affects printing of return value after B<r> command,
7397     I<frame>        affects printing messages on subroutine entry/exit.
7398     I<AutoTrace>    affects printing messages on possible breaking points.
7399     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7400     I<ornaments>     affects screen appearance of the command line.
7401     I<CreateTTY>     bits control attempts to create a new TTY on events:
7402             1: on fork()    2: debugger is started inside debugger
7403             4: on startup
7404     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7405     You can put additional initialization options I<TTY>, I<noTTY>,
7406     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7407     B<R> after you set them).
7408
7409 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7410 B<h>        Summary of debugger commands.
7411 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7412 B<h h>        Long help for debugger commands
7413 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7414         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7415         Set B<\$DB::doccmd> to change viewer.
7416
7417 Type '|h h' for a paged display if this was too hard to read.
7418
7419 ";    # Fix balance of vi % matching: }}}}
7420
7421     #  note: tabs in the following section are not-so-helpful
7422     $summary = <<"END_SUM";
7423 I<List/search source lines:>               I<Control script execution:>
7424   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7425   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7426   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
7427   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7428   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7429   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
7430 I<Debugger controls:>                        B<L>           List break/watch/actions
7431   B<o> [...]     Set debugger options        B<t> [I<n>] [I<expr>] Toggle trace [max depth] ][trace expr]
7432   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7433   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
7434   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7435   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
7436   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
7437   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
7438   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7439   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7440 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7441   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7442   B<p> I<expr>         Print expression (uses script's current package).
7443   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7444   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7445   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
7446   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7447   B<e>     Display thread id     B<E> Display all thread ids.
7448 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7449 END_SUM
7450
7451     # ')}}; # Fix balance of vi % matching
7452
7453     # and this is really numb...
7454     $pre580_help = "
7455 B<T>        Stack trace.
7456 B<s> [I<expr>]    Single step [in I<expr>].
7457 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7458 B<CR>>        Repeat last B<n> or B<s> command.
7459 B<r>        Return from current subroutine.
7460 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7461         at the specified position.
7462 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7463 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7464 B<l> I<line>        List single I<line>.
7465 B<l> I<subname>    List first window of lines from subroutine.
7466 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7467 B<l>        List next window of lines.
7468 B<->        List previous window of lines.
7469 B<w> [I<line>]    List window around I<line>.
7470 B<.>        Return to the executed line.
7471 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7472         I<filename> may be either the full name of the file, or a regular
7473         expression matching the full file name:
7474         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7475         Evals (with saved bodies) are considered to be filenames:
7476         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7477         (in the order of execution).
7478 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7479 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7480 B<L>        List all breakpoints and actions.
7481 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7482 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth) .
7483 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
7484 B<b> [I<line>] [I<condition>]
7485         Set breakpoint; I<line> defaults to the current execution line;
7486         I<condition> breaks if it evaluates to true, defaults to '1'.
7487 B<b> I<subname> [I<condition>]
7488         Set breakpoint at first line of subroutine.
7489 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7490 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7491 B<b> B<postpone> I<subname> [I<condition>]
7492         Set breakpoint at first line of subroutine after
7493         it is compiled.
7494 B<b> B<compile> I<subname>
7495         Stop after the subroutine is compiled.
7496 B<d> [I<line>]    Delete the breakpoint for I<line>.
7497 B<D>        Delete all breakpoints.
7498 B<a> [I<line>] I<command>
7499         Set an action to be done before the I<line> is executed;
7500         I<line> defaults to the current execution line.
7501         Sequence is: check for breakpoint/watchpoint, print line
7502         if necessary, do action, prompt user if necessary,
7503         execute line.
7504 B<a> [I<line>]    Delete the action for I<line>.
7505 B<A>        Delete all actions.
7506 B<W> I<expr>        Add a global watch-expression.
7507 B<W>        Delete all watch-expressions.
7508 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7509         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7510 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7511 B<x> I<expr>        Evals expression in list context, dumps the result.
7512 B<m> I<expr>        Evals expression in list context, prints methods callable
7513         on the first element of the result.
7514 B<m> I<class>        Prints methods callable via the given class.
7515
7516 B<<> ?            List Perl commands to run before each prompt.
7517 B<<> I<expr>        Define Perl command to run before each prompt.
7518 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7519 B<>> ?            List Perl commands to run after each prompt.
7520 B<>> I<expr>        Define Perl command to run after each prompt.
7521 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7522 B<{> I<db_command>    Define debugger command to run before each prompt.
7523 B<{> ?            List debugger commands to run before each prompt.
7524 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7525 B<$prc> I<number>    Redo a previous command (default previous command).
7526 B<$prc> I<-number>    Redo number'th-to-last command.
7527 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7528         See 'B<O> I<recallCommand>' too.
7529 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7530       . (
7531         $rc eq $sh
7532         ? ""
7533         : "
7534 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7535       ) . "
7536         See 'B<O> I<shellBang>' too.
7537 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
7538 B<H> I<-number>    Display last number commands (default all).
7539 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7540 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7541 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7542 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7543 I<command>        Execute as a perl statement in current package.
7544 B<v>        Show versions of loaded modules.
7545 B<R>        Pure-man-restart of debugger, some of debugger state
7546         and command-line options may be lost.
7547         Currently the following settings are preserved:
7548         history, breakpoints and actions, debugger B<O>ptions
7549         and the following command-line options: I<-w>, I<-I>, I<-e>.
7550
7551 B<O> [I<opt>] ...    Set boolean option to true
7552 B<O> [I<opt>B<?>]    Query options
7553 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7554         Set options.  Use quotes if spaces in value.
7555     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7556     I<pager>            program for output of \"|cmd\";
7557     I<tkRunning>            run Tk while prompting (with ReadLine);
7558     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7559     I<inhibit_exit>        Allows stepping off the end of the script.
7560     I<ImmediateStop>        Debugger should stop as early as possible.
7561     I<RemotePort>            Remote hostname:port for remote debugging
7562   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7563     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7564     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7565     I<globPrint>             whether to print contents of globs;
7566     I<DumpDBFiles>         dump arrays holding debugged files;
7567     I<DumpPackages>         dump symbol tables of packages;
7568     I<DumpReused>             dump contents of \"reused\" addresses;
7569     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7570     I<bareStringify>         Do not print the overload-stringified value;
7571   Other options include:
7572     I<PrintRet>        affects printing of return value after B<r> command,
7573     I<frame>        affects printing messages on subroutine entry/exit.
7574     I<AutoTrace>    affects printing messages on possible breaking points.
7575     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7576     I<ornaments>     affects screen appearance of the command line.
7577     I<CreateTTY>     bits control attempts to create a new TTY on events:
7578             1: on fork()    2: debugger is started inside debugger
7579             4: on startup
7580     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7581     You can put additional initialization options I<TTY>, I<noTTY>,
7582     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7583     B<R> after you set them).
7584
7585 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7586 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7587 B<h h>        Summary of debugger commands.
7588 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7589         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7590         Set B<\$DB::doccmd> to change viewer.
7591
7592 Type '|h' for a paged display if this was too hard to read.
7593
7594 ";    # Fix balance of vi % matching: }}}}
7595
7596     #  note: tabs in the following section are not-so-helpful
7597     $pre580_summary = <<"END_SUM";
7598 I<List/search source lines:>               I<Control script execution:>
7599   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7600   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7601   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
7602   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7603   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7604   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
7605 I<Debugger controls:>                        B<L>           List break/watch/actions
7606   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7607   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7608   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
7609   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7610   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
7611   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
7612   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7613   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7614 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7615   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7616   B<p> I<expr>         Print expression (uses script's current package).
7617   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7618   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7619   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
7620   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7621 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7622 END_SUM
7623
7624     # ')}}; # Fix balance of vi % matching
7625
7626 } ## end sub sethelp
7627
7628 =head2 C<print_help()>
7629
7630 Most of what C<print_help> does is just text formatting. It finds the
7631 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
7632 terminal control characters to simulate them (courtesy of
7633 C<Term::ReadLine::TermCap>).
7634
7635 =cut
7636
7637 sub print_help {
7638     local $_ = shift;
7639
7640     # Restore proper alignment destroyed by eeevil I<> and B<>
7641     # ornaments: A pox on both their houses!
7642     #
7643     # A help command will have everything up to and including
7644     # the first tab sequence padded into a field 16 (or if indented 20)
7645     # wide.  If it's wider than that, an extra space will be added.
7646     s{
7647         ^                       # only matters at start of line
7648           ( \040{4} | \t )*     # some subcommands are indented
7649           ( < ?                 # so <CR> works
7650             [BI] < [^\t\n] + )  # find an eeevil ornament
7651           ( \t+ )               # original separation, discarded
7652           ( .* )                # this will now start (no earlier) than
7653                                 # column 16
7654     } {
7655         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
7656         my $clean = $command;
7657         $clean =~ s/[BI]<([^>]*)>/$1/g;
7658
7659         # replace with this whole string:
7660         ($leadwhite ? " " x 4 : "")
7661       . $command
7662       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
7663       . $text;
7664
7665     }mgex;
7666
7667     s{                          # handle bold ornaments
7668        B < ( [^>] + | > ) >
7669     } {
7670           $Term::ReadLine::TermCap::rl_term_set[2]
7671         . $1
7672         . $Term::ReadLine::TermCap::rl_term_set[3]
7673     }gex;
7674
7675     s{                         # handle italic ornaments
7676        I < ( [^>] + | > ) >
7677     } {
7678           $Term::ReadLine::TermCap::rl_term_set[0]
7679         . $1
7680         . $Term::ReadLine::TermCap::rl_term_set[1]
7681     }gex;
7682
7683     local $\ = '';
7684     print $OUT $_;
7685 } ## end sub print_help
7686
7687 =head2 C<fix_less>
7688
7689 This routine does a lot of gyrations to be sure that the pager is C<less>.
7690 It checks for C<less> masquerading as C<more> and records the result in
7691 C<$fixed_less> so we don't have to go through doing the stats again.
7692
7693 =cut
7694
7695 use vars qw($fixed_less);
7696
7697 sub fix_less {
7698
7699     # We already know if this is set.
7700     return if $fixed_less;
7701
7702     # Pager is less for sure.
7703     my $is_less = $pager =~ /\bless\b/;
7704     if ( $pager =~ /\bmore\b/ ) {
7705
7706         # Nope, set to more. See what's out there.
7707         my @st_more = stat('/usr/bin/more');
7708         my @st_less = stat('/usr/bin/less');
7709
7710         # is it really less, pretending to be more?
7711              $is_less = @st_more
7712           && @st_less
7713           && $st_more[0] == $st_less[0]
7714           && $st_more[1] == $st_less[1];
7715     } ## end if ($pager =~ /\bmore\b/)
7716
7717     # changes environment!
7718     # 'r' added so we don't do (slow) stats again.
7719     $fixed_less = 1 if $is_less;
7720 } ## end sub fix_less
7721
7722 =head1 DIE AND WARN MANAGEMENT
7723
7724 =head2 C<diesignal>
7725
7726 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
7727 to debug a debugger problem.
7728
7729 It does its best to report the error that occurred, and then forces the
7730 program, debugger, and everything to die.
7731
7732 =cut
7733
7734 sub diesignal {
7735
7736     # No entry/exit messages.
7737     local $frame = 0;
7738
7739     # No return value prints.
7740     local $doret = -2;
7741
7742     # set the abort signal handling to the default (just terminate).
7743     $SIG{'ABRT'} = 'DEFAULT';
7744
7745     # If we enter the signal handler recursively, kill myself with an
7746     # abort signal (so we just terminate).
7747     kill 'ABRT', $$ if $panic++;
7748
7749     # If we can show detailed info, do so.
7750     if ( defined &Carp::longmess ) {
7751
7752         # Don't recursively enter the warn handler, since we're carping.
7753         local $SIG{__WARN__} = '';
7754
7755         # Skip two levels before reporting traceback: we're skipping
7756         # mydie and confess.
7757         local $Carp::CarpLevel = 2;    # mydie + confess
7758
7759         # Tell us all about it.
7760         &warn( Carp::longmess("Signal @_") );
7761     }
7762
7763     # No Carp. Tell us about the signal as best we can.
7764     else {
7765         local $\ = '';
7766         print $DB::OUT "Got signal @_\n";
7767     }
7768
7769     # Drop dead.
7770     kill 'ABRT', $$;
7771 } ## end sub diesignal
7772
7773 =head2 C<dbwarn>
7774
7775 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
7776 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
7777
7778 =cut
7779
7780 sub dbwarn {
7781
7782     # No entry/exit trace.
7783     local $frame = 0;
7784
7785     # No return value printing.
7786     local $doret = -2;
7787
7788     # Turn off warn and die handling to prevent recursive entries to this
7789     # routine.
7790     local $SIG{__WARN__} = '';
7791     local $SIG{__DIE__}  = '';
7792
7793     # Load Carp if we can. If $^S is false (current thing being compiled isn't
7794     # done yet), we may not be able to do a require.
7795     eval { require Carp }
7796       if defined $^S;    # If error/warning during compilation,
7797                          # require may be broken.
7798
7799     # Use the core warn() unless Carp loaded OK.
7800     CORE::warn( @_,
7801         "\nCannot print stack trace, load with -MCarp option to see stack" ),
7802       return
7803       unless defined &Carp::longmess;
7804
7805     # Save the current values of $single and $trace, and then turn them off.
7806     my ( $mysingle, $mytrace ) = ( $single, $trace );
7807     $single = 0;
7808     $trace  = 0;
7809
7810     # We can call Carp::longmess without its being "debugged" (which we
7811     # don't want - we just want to use it!). Capture this for later.
7812     my $mess = Carp::longmess(@_);
7813
7814     # Restore $single and $trace to their original values.
7815     ( $single, $trace ) = ( $mysingle, $mytrace );
7816
7817     # Use the debugger's own special way of printing warnings to print
7818     # the stack trace message.
7819     &warn($mess);
7820 } ## end sub dbwarn
7821
7822 =head2 C<dbdie>
7823
7824 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
7825 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
7826 single stepping and tracing during the call to C<Carp::longmess> to avoid
7827 debugging it - we just want to use it.
7828
7829 If C<dieLevel> is zero, we let the program being debugged handle the
7830 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
7831 the debugger takes over all exception handling, printing a backtrace and
7832 displaying the exception via its C<dbwarn()> routine.
7833
7834 =cut
7835
7836 sub dbdie {
7837     local $frame         = 0;
7838     local $doret         = -2;
7839     local $SIG{__DIE__}  = '';
7840     local $SIG{__WARN__} = '';
7841     my $i      = 0;
7842     my $ineval = 0;
7843     my $sub;
7844     if ( $dieLevel > 2 ) {
7845         local $SIG{__WARN__} = \&dbwarn;
7846         &warn(@_);    # Yell no matter what
7847         return;
7848     }
7849     if ( $dieLevel < 2 ) {
7850         die @_ if $^S;    # in eval propagate
7851     }
7852
7853     # The code used to check $^S to see if compilation of the current thing
7854     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
7855     eval { require Carp };
7856
7857     die( @_,
7858         "\nCannot print stack trace, load with -MCarp option to see stack" )
7859       unless defined &Carp::longmess;
7860
7861     # We do not want to debug this chunk (automatic disabling works
7862     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
7863     # get the stack trace from Carp::longmess (if possible), restore $signal
7864     # and $trace, and then die with the stack trace.
7865     my ( $mysingle, $mytrace ) = ( $single, $trace );
7866     $single = 0;
7867     $trace  = 0;
7868     my $mess = "@_";
7869     {
7870
7871         package Carp;    # Do not include us in the list
7872         eval { $mess = Carp::longmess(@_); };
7873     }
7874     ( $single, $trace ) = ( $mysingle, $mytrace );
7875     die $mess;
7876 } ## end sub dbdie
7877
7878 =head2 C<warnlevel()>
7879
7880 Set the C<$DB::warnLevel> variable that stores the value of the
7881 C<warnLevel> option. Calling C<warnLevel()> with a positive value
7882 results in the debugger taking over all warning handlers. Setting
7883 C<warnLevel> to zero leaves any warning handlers set up by the program
7884 being debugged in place.
7885
7886 =cut
7887
7888 sub warnLevel {
7889     if (@_) {
7890         my $prevwarn = $SIG{__WARN__} unless $warnLevel;
7891         $warnLevel = shift;
7892         if ($warnLevel) {
7893             $SIG{__WARN__} = \&DB::dbwarn;
7894         }
7895         elsif ($prevwarn) {
7896             $SIG{__WARN__} = $prevwarn;
7897         } else {
7898             undef $SIG{__WARN__};
7899         }
7900     } ## end if (@_)
7901     $warnLevel;
7902 } ## end sub warnLevel
7903
7904 =head2 C<dielevel>
7905
7906 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
7907 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
7908 zero lets you use your own C<die()> handler.
7909
7910 =cut
7911
7912 sub dieLevel {
7913     local $\ = '';
7914     if (@_) {
7915         my $prevdie = $SIG{__DIE__} unless $dieLevel;
7916         $dieLevel = shift;
7917         if ($dieLevel) {
7918
7919             # Always set it to dbdie() for non-zero values.
7920             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
7921
7922             # No longer exists, so don't try  to use it.
7923             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
7924
7925             # If we've finished initialization, mention that stack dumps
7926             # are enabled, If dieLevel is 1, we won't stack dump if we die
7927             # in an eval().
7928             print $OUT "Stack dump during die enabled",
7929               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
7930               if $I_m_init;
7931
7932             # XXX This is probably obsolete, given that diehard() is gone.
7933             print $OUT "Dump printed too.\n" if $dieLevel > 2;
7934         } ## end if ($dieLevel)
7935
7936         # Put the old one back if there was one.
7937         elsif ($prevdie) {
7938             $SIG{__DIE__} = $prevdie;
7939             print $OUT "Default die handler restored.\n";
7940         } else {
7941             undef $SIG{__DIE__};
7942             print $OUT "Die handler removed.\n";
7943         }
7944     } ## end if (@_)
7945     $dieLevel;
7946 } ## end sub dieLevel
7947
7948 =head2 C<signalLevel>
7949
7950 Number three in a series: set C<signalLevel> to zero to keep your own
7951 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
7952 takes over and handles them with C<DB::diesignal()>.
7953
7954 =cut
7955
7956 sub signalLevel {
7957     if (@_) {
7958         my $prevsegv = $SIG{SEGV} unless $signalLevel;
7959         my $prevbus  = $SIG{BUS}  unless $signalLevel;
7960         $signalLevel = shift;
7961         if ($signalLevel) {
7962             $SIG{SEGV} = \&DB::diesignal;
7963             $SIG{BUS}  = \&DB::diesignal;
7964         }
7965         else {
7966             $SIG{SEGV} = $prevsegv;
7967             $SIG{BUS}  = $prevbus;
7968         }
7969     } ## end if (@_)
7970     $signalLevel;
7971 } ## end sub signalLevel
7972
7973 =head1 SUBROUTINE DECODING SUPPORT
7974
7975 These subroutines are used during the C<x> and C<X> commands to try to
7976 produce as much information as possible about a code reference. They use
7977 L<Devel::Peek> to try to find the glob in which this code reference lives
7978 (if it does) - this allows us to actually code references which correspond
7979 to named subroutines (including those aliased via glob assignment).
7980
7981 =head2 C<CvGV_name()>
7982
7983 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
7984 via that routine. If this fails, return the reference again (when the
7985 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
7986
7987 =cut
7988
7989 sub CvGV_name {
7990     my $in   = shift;
7991     my $name = CvGV_name_or_bust($in);
7992     defined $name ? $name : $in;
7993 }
7994
7995 =head2 C<CvGV_name_or_bust> I<coderef>
7996
7997 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
7998 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
7999 find a glob for this ref.
8000
8001 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
8002
8003 =cut
8004
8005 use vars qw($skipCvGV);
8006
8007 sub CvGV_name_or_bust {
8008     my $in = shift;
8009     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
8010     return unless ref $in;
8011     $in = \&$in;            # Hard reference...
8012     eval { require Devel::Peek; 1 } or return;
8013     my $gv = Devel::Peek::CvGV($in) or return;
8014     *$gv{PACKAGE} . '::' . *$gv{NAME};
8015 } ## end sub CvGV_name_or_bust
8016
8017 =head2 C<find_sub>
8018
8019 A utility routine used in various places; finds the file where a subroutine
8020 was defined, and returns that filename and a line-number range.
8021
8022 Tries to use C<@sub> first; if it can't find it there, it tries building a
8023 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
8024 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
8025 this way, it brute-force searches C<%sub>, checking for identical references.
8026
8027 =cut
8028
8029 sub find_sub {
8030     my $subr = shift;
8031     $sub{$subr} or do {
8032         return unless defined &$subr;
8033         my $name = CvGV_name_or_bust($subr);
8034         my $data;
8035         $data = $sub{$name} if defined $name;
8036         return $data if defined $data;
8037
8038         # Old stupid way...
8039         $subr = \&$subr;    # Hard reference
8040         my $s;
8041         for ( keys %sub ) {
8042             $s = $_, last if $subr eq \&$_;
8043         }
8044         $sub{$s} if $s;
8045       } ## end do
8046 } ## end sub find_sub
8047
8048 =head2 C<methods>
8049
8050 A subroutine that uses the utility function C<methods_via> to find all the
8051 methods in the class corresponding to the current reference and in
8052 C<UNIVERSAL>.
8053
8054 =cut
8055
8056 use vars qw(%seen);
8057
8058 sub methods {
8059
8060     # Figure out the class - either this is the class or it's a reference
8061     # to something blessed into that class.
8062     my $class = shift;
8063     $class = ref $class if ref $class;
8064
8065     local %seen;
8066
8067     # Show the methods that this class has.
8068     methods_via( $class, '', 1 );
8069
8070     # Show the methods that UNIVERSAL has.
8071     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
8072 } ## end sub methods
8073
8074 =head2 C<methods_via($class, $prefix, $crawl_upward)>
8075
8076 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
8077 all the parent class methods. C<$class> is the name of the next class to
8078 try; C<$prefix> is the message prefix, which gets built up as we go up the
8079 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
8080 higher in the C<@ISA> tree, 0 if we should stop.
8081
8082 =cut
8083
8084 sub methods_via {
8085
8086     # If we've processed this class already, just quit.
8087     my $class = shift;
8088     return if $seen{$class}++;
8089
8090     # This is a package that is contributing the methods we're about to print.
8091     my $prefix  = shift;
8092     my $prepend = $prefix ? "via $prefix: " : '';
8093     my @to_print;
8094
8095     # Extract from all the symbols in this class.
8096     my $class_ref = do { no strict "refs"; \%{$class . '::'} };
8097     while (my ($name, $glob) = each %$class_ref) {
8098         # references directly in the symbol table are Proxy Constant
8099         # Subroutines, and are by their very nature defined
8100         # Otherwise, check if the thing is a typeglob, and if it is, it decays
8101         # to a subroutine reference, which can be tested by defined.
8102         # $glob might also be the value -1  (from sub foo;)
8103         # or (say) '$$' (from sub foo ($$);)
8104         # \$glob will be SCALAR in both cases.
8105         if ((ref $glob || ($glob && ref \$glob eq 'GLOB' && defined &$glob))
8106             && !$seen{$name}++) {
8107             push @to_print, "$prepend$name\n";
8108         }
8109     }
8110
8111     {
8112         local $\ = '';
8113         local $, = '';
8114         print $DB::OUT $_ foreach sort @to_print;
8115     }
8116
8117     # If the $crawl_upward argument is false, just quit here.
8118     return unless shift;
8119
8120     # $crawl_upward true: keep going up the tree.
8121     # Find all the classes this one is a subclass of.
8122     my $class_ISA_ref = do { no strict "refs"; \@{"${class}::ISA"} };
8123     for my $name ( @$class_ISA_ref ) {
8124
8125         # Set up the new prefix.
8126         $prepend = $prefix ? $prefix . " -> $name" : $name;
8127
8128         # Crawl up the tree and keep trying to crawl up.
8129         methods_via( $name, $prepend, 1 );
8130     }
8131 } ## end sub methods_via
8132
8133 =head2 C<setman> - figure out which command to use to show documentation
8134
8135 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8136
8137 =cut
8138
8139 sub setman {
8140     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|NetWare)\z/s
8141       ? "man"         # O Happy Day!
8142       : "perldoc";    # Alas, poor unfortunates
8143 } ## end sub setman
8144
8145 =head2 C<runman> - run the appropriate command to show documentation
8146
8147 Accepts a man page name; runs the appropriate command to display it (set up
8148 during debugger initialization). Uses C<DB::system> to avoid mucking up the
8149 program's STDIN and STDOUT.
8150
8151 =cut
8152
8153 sub runman {
8154     my $page = shift;
8155     unless ($page) {
8156         &system("$doccmd $doccmd");
8157         return;
8158     }
8159
8160     # this way user can override, like with $doccmd="man -Mwhatever"
8161     # or even just "man " to disable the path check.
8162     unless ( $doccmd eq 'man' ) {
8163         &system("$doccmd $page");
8164         return;
8165     }
8166
8167     $page = 'perl' if lc($page) eq 'help';
8168
8169     require Config;
8170     my $man1dir = $Config::Config{'man1dir'};
8171     my $man3dir = $Config::Config{'man3dir'};
8172     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
8173     my $manpath = '';
8174     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
8175     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
8176     chop $manpath if $manpath;
8177
8178     # harmless if missing, I figure
8179     my $oldpath = $ENV{MANPATH};
8180     $ENV{MANPATH} = $manpath if $manpath;
8181     my $nopathopt = $^O =~ /dunno what goes here/;
8182     if (
8183         CORE::system(
8184             $doccmd,
8185
8186             # I just *know* there are men without -M
8187             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8188             split ' ', $page
8189         )
8190       )
8191     {
8192         unless ( $page =~ /^perl\w/ ) {
8193 # do it this way because its easier to slurp in to keep up to date - clunky though.
8194 my @pods = qw(
8195     5004delta
8196     5005delta
8197     561delta
8198     56delta
8199     570delta
8200     571delta
8201     572delta
8202     573delta
8203     58delta
8204     581delta
8205     582delta
8206     583delta
8207     584delta
8208     590delta
8209     591delta
8210     592delta
8211     aix
8212     amiga
8213     apio
8214     api
8215     artistic
8216     beos
8217     book
8218     boot
8219     bot
8220     bs2000
8221     call
8222     ce
8223     cheat
8224     clib
8225     cn
8226     compile
8227     cygwin
8228     data
8229     dbmfilter
8230     debguts
8231     debtut
8232     debug
8233     delta
8234     dgux
8235     diag
8236     doc
8237     dos
8238     dsc
8239     ebcdic
8240     embed
8241     epoc
8242     faq1
8243     faq2
8244     faq3
8245     faq4
8246     faq5
8247     faq6
8248     faq7
8249     faq8
8250     faq9
8251     faq
8252     filter
8253     fork
8254     form
8255     freebsd
8256     func
8257     gpl
8258     guts
8259     hack
8260     hist
8261     hpux
8262     hurd
8263     intern
8264     intro
8265     iol
8266     ipc
8267     irix
8268     jp
8269     ko
8270     lexwarn
8271     locale
8272     lol
8273     macos
8274     macosx
8275     modinstall
8276     modlib
8277     mod
8278     modstyle
8279     netware
8280     newmod
8281     number
8282     obj
8283     opentut
8284     op
8285     os2
8286     os390
8287     os400
8288     packtut
8289     plan9
8290     pod
8291     podspec
8292     port
8293     qnx
8294     ref
8295     reftut
8296     re
8297     requick
8298     reref
8299     retut
8300     run
8301     sec
8302     solaris
8303     style
8304     sub
8305     syn
8306     thrtut
8307     tie
8308     toc
8309     todo
8310     tooc
8311     toot
8312     trap
8313     tru64
8314     tw
8315     unicode
8316     uniintro
8317     util
8318     uts
8319     var
8320     vms
8321     vos
8322     win32
8323     xs
8324     xstut
8325 );
8326             if (grep { $page eq $_ } @pods) {
8327                 $page =~ s/^/perl/;
8328                 CORE::system( $doccmd,
8329                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8330                     $page );
8331             } ## end if (grep { $page eq $_...
8332         } ## end unless ($page =~ /^perl\w/)
8333     } ## end if (CORE::system($doccmd...
8334     if ( defined $oldpath ) {
8335         $ENV{MANPATH} = $manpath;
8336     }
8337     else {
8338         delete $ENV{MANPATH};
8339     }
8340 } ## end sub runman
8341
8342 #use Carp;                          # This did break, left for debugging
8343
8344 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
8345
8346 Because of the way the debugger interface to the Perl core is designed, any
8347 debugger package globals that C<DB::sub()> requires have to be defined before
8348 any subroutines can be called. These are defined in the second C<BEGIN> block.
8349
8350 This block sets things up so that (basically) the world is sane
8351 before the debugger starts executing. We set up various variables that the
8352 debugger has to have set up before the Perl core starts running:
8353
8354 =over 4
8355
8356 =item *
8357
8358 The debugger's own filehandles (copies of STD and STDOUT for now).
8359
8360 =item *
8361
8362 Characters for shell escapes, the recall command, and the history command.
8363
8364 =item *
8365
8366 The maximum recursion depth.
8367
8368 =item *
8369
8370 The size of a C<w> command's window.
8371
8372 =item *
8373
8374 The before-this-line context to be printed in a C<v> (view a window around this line) command.
8375
8376 =item *
8377
8378 The fact that we're not in a sub at all right now.
8379
8380 =item *
8381
8382 The default SIGINT handler for the debugger.
8383
8384 =item *
8385
8386 The appropriate value of the flag in C<$^D> that says the debugger is running
8387
8388 =item *
8389
8390 The current debugger recursion level
8391
8392 =item *
8393
8394 The list of postponed items and the C<$single> stack (XXX define this)
8395
8396 =item *
8397
8398 That we want no return values and no subroutine entry/exit trace.
8399
8400 =back
8401
8402 =cut
8403
8404 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
8405
8406 use vars qw($db_stop);
8407
8408 BEGIN {    # This does not compile, alas. (XXX eh?)
8409     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
8410     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
8411
8412     # Define characters used by command parsing.
8413     $sh       = '!';      # Shell escape (does not work)
8414     $rc       = ',';      # Recall command (does not work)
8415     @hist     = ('?');    # Show history (does not work)
8416     @truehist = ();       # Can be saved for replay (per session)
8417
8418     # This defines the point at which you get the 'deep recursion'
8419     # warning. It MUST be defined or the debugger will not load.
8420     $deep = 100;
8421
8422     # Number of lines around the current one that are shown in the
8423     # 'w' command.
8424     $window = 10;
8425
8426     # How much before-the-current-line context the 'v' command should
8427     # use in calculating the start of the window it will display.
8428     $preview = 3;
8429
8430     # We're not in any sub yet, but we need this to be a defined value.
8431     $sub = '';
8432
8433     # Set up the debugger's interrupt handler. It simply sets a flag
8434     # ($signal) that DB::DB() will check before each command is executed.
8435     $SIG{INT} = \&DB::catch;
8436
8437     # The following lines supposedly, if uncommented, allow the debugger to
8438     # debug itself. Perhaps we can try that someday.
8439     # This may be enabled to debug debugger:
8440     #$warnLevel = 1 unless defined $warnLevel;
8441     #$dieLevel = 1 unless defined $dieLevel;
8442     #$signalLevel = 1 unless defined $signalLevel;
8443
8444     # This is the flag that says "a debugger is running, please call
8445     # DB::DB and DB::sub". We will turn it on forcibly before we try to
8446     # execute anything in the user's context, because we always want to
8447     # get control back.
8448     $db_stop = 0;          # Compiler warning ...
8449     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
8450
8451     # This variable records how many levels we're nested in debugging. Used
8452     # Used in the debugger prompt, and in determining whether it's all over or
8453     # not.
8454     $level = 0;            # Level of recursive debugging
8455
8456     # "Triggers bug (?) in perl if we postpone this until runtime."
8457     # XXX No details on this yet, or whether we should fix the bug instead
8458     # of work around it. Stay tuned.
8459     @stack = (0);
8460
8461     # Used to track the current stack depth using the auto-stacked-variable
8462     # trick.
8463     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
8464
8465     # Don't print return values on exiting a subroutine.
8466     $doret = -2;
8467
8468     # No extry/exit tracing.
8469     $frame = 0;
8470
8471 } ## end BEGIN
8472
8473 BEGIN { $^W = $ini_warn; }    # Switch warnings back
8474
8475 =head1 READLINE SUPPORT - COMPLETION FUNCTION
8476
8477 =head2 db_complete
8478
8479 C<readline> support - adds command completion to basic C<readline>.
8480
8481 Returns a list of possible completions to C<readline> when invoked. C<readline>
8482 will print the longest common substring following the text already entered.
8483
8484 If there is only a single possible completion, C<readline> will use it in full.
8485
8486 This code uses C<map> and C<grep> heavily to create lists of possible
8487 completion. Think LISP in this section.
8488
8489 =cut
8490
8491 sub db_complete {
8492
8493     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
8494     # $text is the text to be completed.
8495     # $line is the incoming line typed by the user.
8496     # $start is the start of the text to be completed in the incoming line.
8497     my ( $text, $line, $start ) = @_;
8498
8499     # Save the initial text.
8500     # The search pattern is current package, ::, extract the next qualifier
8501     # Prefix and pack are set to undef.
8502     my ( $itext, $search, $prefix, $pack ) =
8503       ( $text, "^\Q${package}::\E([^:]+)\$" );
8504
8505 =head3 C<b postpone|compile>
8506
8507 =over 4
8508
8509 =item *
8510
8511 Find all the subroutines that might match in this package
8512
8513 =item *
8514
8515 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
8516
8517 =item *
8518
8519 Include all the rest of the subs that are known
8520
8521 =item *
8522
8523 C<grep> out the ones that match the text we have so far
8524
8525 =item *
8526
8527 Return this as the list of possible completions
8528
8529 =back
8530
8531 =cut
8532
8533     return sort grep /^\Q$text/, ( keys %sub ),
8534       qw(postpone load compile),    # subroutines
8535       ( map { /$search/ ? ($1) : () } keys %sub )
8536       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
8537
8538 =head3 C<b load>
8539
8540 Get all the possible files from C<@INC> as it currently stands and
8541 select the ones that match the text so far.
8542
8543 =cut
8544
8545     return sort grep /^\Q$text/, values %INC    # files
8546       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
8547
8548 =head3  C<V> (list variable) and C<m> (list modules)
8549
8550 There are two entry points for these commands:
8551
8552 =head4 Unqualified package names
8553
8554 Get the top-level packages and grab everything that matches the text
8555 so far. For each match, recursively complete the partial packages to
8556 get all possible matching packages. Return this sorted list.
8557
8558 =cut
8559
8560     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8561       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
8562       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
8563
8564 =head4 Qualified package names
8565
8566 Take a partially-qualified package and find all subpackages for it
8567 by getting all the subpackages for the package so far, matching all
8568 the subpackages against the text, and discarding all of them which
8569 start with 'main::'. Return this list.
8570
8571 =cut
8572
8573     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8574       grep !/^main::/, grep /^\Q$text/,
8575       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () }
8576       do { no strict 'refs'; keys %{ $prefix . '::' } }
8577       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
8578       and $text =~ /^(.*[^:])::?(\w*)$/
8579       and $prefix = $1;
8580
8581 =head3 C<f> - switch files
8582
8583 Here, we want to get a fully-qualified filename for the C<f> command.
8584 Possibilities are:
8585
8586 =over 4
8587
8588 =item 1. The original source file itself
8589
8590 =item 2. A file from C<@INC>
8591
8592 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
8593
8594 =back
8595
8596 =cut
8597
8598     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
8599            # We might possibly want to switch to an eval (which has a "filename"
8600            # like '(eval 9)'), so we may need to clean up the completion text
8601            # before proceeding.
8602         $prefix = length($1) - length($text);
8603         $text   = $1;
8604
8605 =pod
8606
8607 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
8608 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
8609 out of C<%main::>, add the initial source file, and extract the ones that
8610 match the completion text so far.
8611
8612 =cut
8613
8614         return sort
8615           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
8616           $0;
8617     } ## end if ($line =~ /^\|*f\s+(.*)/)
8618
8619 =head3 Subroutine name completion
8620
8621 We look through all of the defined subs (the keys of C<%sub>) and
8622 return both all the possible matches to the subroutine name plus
8623 all the matches qualified to the current package.
8624
8625 =cut
8626
8627     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
8628         $text = substr $text, 1;
8629         $prefix = "&";
8630         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
8631           (
8632             map { /$search/ ? ($1) : () }
8633               keys %sub
8634           );
8635     } ## end if ((substr $text, 0, ...
8636
8637 =head3  Scalar, array, and hash completion: partially qualified package
8638
8639 Much like the above, except we have to do a little more cleanup:
8640
8641 =cut
8642
8643     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
8644
8645 =pod
8646
8647 =over 4
8648
8649 =item *
8650
8651 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
8652
8653 =cut
8654
8655         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
8656
8657 =pod
8658
8659 =item *
8660
8661 Figure out the prefix vs. what needs completing.
8662
8663 =cut
8664
8665         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
8666         $text   = $2;
8667
8668 =pod
8669
8670 =item *
8671
8672 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
8673
8674 =cut
8675
8676         my @out = do {
8677             no strict 'refs';
8678             map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
8679             keys %$pack;
8680         };
8681
8682 =pod
8683
8684 =item *
8685
8686 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
8687
8688 =cut
8689
8690         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8691             return db_complete( $out[0], $line, $start );
8692         }
8693
8694         # Return the list of possibles.
8695         return sort @out;
8696
8697     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
8698
8699 =pod
8700
8701 =back
8702
8703 =head3 Symbol completion: current package or package C<main>.
8704
8705 =cut
8706
8707     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
8708 =pod
8709
8710 =over 4
8711
8712 =item *
8713
8714 If it's C<main>, delete main to just get C<::> leading.
8715
8716 =cut
8717
8718         $pack = ( $package eq 'main' ? '' : $package ) . '::';
8719
8720 =pod
8721
8722 =item *
8723
8724 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
8725
8726 =cut
8727
8728         $prefix = substr $text, 0, 1;
8729         $text   = substr $text, 1;
8730
8731         my @out;
8732
8733 =pod
8734
8735 =item *
8736
8737 We look for the lexical scope above DB::DB and auto-complete lexical variables
8738 if PadWalker could be loaded.
8739
8740 =cut
8741
8742         if (not $text =~ /::/ and eval { require PadWalker } ) {
8743             my $level = 1;
8744             while (1) {
8745                 my @info = caller($level);
8746                 $level++;
8747                 $level = -1, last
8748                   if not @info;
8749                 last if $info[3] eq 'DB::DB';
8750             }
8751             if ($level > 0) {
8752                 my $lexicals = PadWalker::peek_my($level);
8753                 push @out, grep /^\Q$prefix$text/, keys %$lexicals;
8754             }
8755         }
8756
8757 =pod
8758
8759 =item *
8760
8761 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
8762
8763 =cut
8764
8765         push @out, map "$prefix$_", grep /^\Q$text/,
8766           ( grep /^_?[a-zA-Z]/, keys %$pack ),
8767           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
8768
8769 =item *
8770
8771 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
8772
8773 =back
8774
8775 =cut
8776
8777         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8778             return db_complete( $out[0], $line, $start );
8779         }
8780
8781         # Return the list of possibles.
8782         return sort @out;
8783     } ## end if ($text =~ /^[\$@%]/)
8784
8785 =head3 Options
8786
8787 We use C<option_val()> to look up the current value of the option. If there's
8788 only a single value, we complete the command in such a way that it is a
8789 complete command for setting the option in question. If there are multiple
8790 possible values, we generate a command consisting of the option plus a trailing
8791 question mark, which, if executed, will list the current value of the option.
8792
8793 =cut
8794
8795     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
8796     {    # Options after space
8797            # We look for the text to be matched in the list of possible options,
8798            # and fetch the current value.
8799         my @out = grep /^\Q$text/, @options;
8800         my $val = option_val( $out[0], undef );
8801
8802         # Set up a 'query option's value' command.
8803         my $out = '? ';
8804         if ( not defined $val or $val =~ /[\n\r]/ ) {
8805
8806             # There's really nothing else we can do.
8807         }
8808
8809         # We have a value. Create a proper option-setting command.
8810         elsif ( $val =~ /\s/ ) {
8811
8812             # XXX This may be an extraneous variable.
8813             my $found;
8814
8815             # We'll want to quote the string (because of the embedded
8816             # whtespace), but we want to make sure we don't end up with
8817             # mismatched quote characters. We try several possibilities.
8818             foreach my $l ( split //, qq/\"\'\#\|/ ) {
8819
8820                 # If we didn't find this quote character in the value,
8821                 # quote it using this quote character.
8822                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
8823             }
8824         } ## end elsif ($val =~ /\s/)
8825
8826         # Don't need any quotes.
8827         else {
8828             $out = "=$val ";
8829         }
8830
8831         # If there were multiple possible values, return '? ', which
8832         # makes the command into a query command. If there was just one,
8833         # have readline append that.
8834         $rl_attribs->{completer_terminator_character} =
8835           ( @out == 1 ? $out : '? ' );
8836
8837         # Return list of possibilities.
8838         return sort @out;
8839     } ## end if ((substr $line, 0, ...
8840
8841 =head3 Filename completion
8842
8843 For entering filenames. We simply call C<readline>'s C<filename_list()>
8844 method with the completion text to get the possible completions.
8845
8846 =cut
8847
8848     return $term->filename_list($text);    # filenames
8849
8850 } ## end sub db_complete
8851
8852 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
8853
8854 Functions that possibly ought to be somewhere else.
8855
8856 =head2 end_report
8857
8858 Say we're done.
8859
8860 =cut
8861
8862 sub end_report {
8863     local $\ = '';
8864     print $OUT "Use 'q' to quit or 'R' to restart.  'h q' for details.\n";
8865 }
8866
8867 =head2 clean_ENV
8868
8869 If we have $ini_pids, save it in the environment; else remove it from the
8870 environment. Used by the C<R> (restart) command.
8871
8872 =cut
8873
8874 sub clean_ENV {
8875     if ( defined($ini_pids) ) {
8876         $ENV{PERLDB_PIDS} = $ini_pids;
8877     }
8878     else {
8879         delete( $ENV{PERLDB_PIDS} );
8880     }
8881 } ## end sub clean_ENV
8882
8883 # PERLDBf_... flag names from perl.h
8884 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
8885
8886 BEGIN {
8887     %DollarCaretP_flags = (
8888         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
8889         PERLDBf_LINE      => 0x02,     # Keep line #
8890         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
8891         PERLDBf_INTER     => 0x08,     # Preserve more data
8892         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
8893         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
8894         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
8895         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
8896         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
8897         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
8898         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
8899         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
8900     );
8901     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
8902     # doesn't need to set it. It's provided for the benefit of profilers and
8903     # other code analysers.
8904
8905     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
8906 }
8907
8908 sub parse_DollarCaretP_flags {
8909     my $flags = shift;
8910     $flags =~ s/^\s+//;
8911     $flags =~ s/\s+$//;
8912     my $acu = 0;
8913     foreach my $f ( split /\s*\|\s*/, $flags ) {
8914         my $value;
8915         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
8916             $value = hex $1;
8917         }
8918         elsif ( $f =~ /^(\d+)$/ ) {
8919             $value = int $1;
8920         }
8921         elsif ( $f =~ /^DEFAULT$/i ) {
8922             $value = $DollarCaretP_flags{PERLDB_ALL};
8923         }
8924         else {
8925             $f =~ /^(?:PERLDBf_)?(.*)$/i;
8926             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
8927             unless ( defined $value ) {
8928                 print $OUT (
8929                     "Unrecognized \$^P flag '$f'!\n",
8930                     "Acceptable flags are: "
8931                       . join( ', ', sort keys %DollarCaretP_flags ),
8932                     ", and hexadecimal and decimal numbers.\n"
8933                 );
8934                 return undef;
8935             }
8936         }
8937         $acu |= $value;
8938     }
8939     $acu;
8940 }
8941
8942 sub expand_DollarCaretP_flags {
8943     my $DollarCaretP = shift;
8944     my @bits         = (
8945         map {
8946             my $n = ( 1 << $_ );
8947             ( $DollarCaretP & $n )
8948               ? ( $DollarCaretP_flags_r{$n}
8949                   || sprintf( '0x%x', $n ) )
8950               : ()
8951           } 0 .. 31
8952     );
8953     return @bits ? join( '|', @bits ) : 0;
8954 }
8955
8956 =over 4
8957
8958 =item rerun
8959
8960 Rerun the current session to:
8961
8962     rerun        current position
8963
8964     rerun 4      command number 4
8965
8966     rerun -4     current command minus 4 (go back 4 steps)
8967
8968 Whether this always makes sense, in the current context is unknowable, and is
8969 in part left as a useful exercise for the reader.  This sub returns the
8970 appropriate arguments to rerun the current session.
8971
8972 =cut
8973
8974 sub rerun {
8975     my $i = shift;
8976     my @args;
8977     pop(@truehist);                      # strim
8978     unless (defined $truehist[$i]) {
8979         print "Unable to return to non-existent command: $i\n";
8980     } else {
8981         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
8982         my @temp = @truehist;            # store
8983         push(@DB::typeahead, @truehist); # saved
8984         @truehist = @hist = ();          # flush
8985         @args = &restart();              # setup
8986         &get_list("PERLDB_HIST");        # clean
8987         &set_list("PERLDB_HIST", @temp); # reset
8988     }
8989     return @args;
8990 }
8991
8992 =item restart
8993
8994 Restarting the debugger is a complex operation that occurs in several phases.
8995 First, we try to reconstruct the command line that was used to invoke Perl
8996 and the debugger.
8997
8998 =cut
8999
9000 sub restart {
9001     # I may not be able to resurrect you, but here goes ...
9002     print $OUT
9003 "Warning: some settings and command-line options may be lost!\n";
9004     my ( @script, @flags, $cl );
9005
9006     # If warn was on before, turn it on again.
9007     push @flags, '-w' if $ini_warn;
9008
9009     # Rebuild the -I flags that were on the initial
9010     # command line.
9011     for (@ini_INC) {
9012         push @flags, '-I', $_;
9013     }
9014
9015     # Turn on taint if it was on before.
9016     push @flags, '-T' if ${^TAINT};
9017
9018     # Arrange for setting the old INC:
9019     # Save the current @init_INC in the environment.
9020     set_list( "PERLDB_INC", @ini_INC );
9021
9022     # If this was a perl one-liner, go to the "file"
9023     # corresponding to the one-liner read all the lines
9024     # out of it (except for the first one, which is going
9025     # to be added back on again when 'perl -d' runs: that's
9026     # the 'require perl5db.pl;' line), and add them back on
9027     # to the command line to be executed.
9028     if ( $0 eq '-e' ) {
9029         my $lines = *{$main::{'_<-e'}}{ARRAY};
9030         for ( 1 .. $#$lines ) {  # The first line is PERL5DB
9031             chomp( $cl = $lines->[$_] );
9032             push @script, '-e', $cl;
9033         }
9034     } ## end if ($0 eq '-e')
9035
9036     # Otherwise we just reuse the original name we had
9037     # before.
9038     else {
9039         @script = $0;
9040     }
9041
9042 =pod
9043
9044 After the command line  has been reconstructed, the next step is to save
9045 the debugger's status in environment variables. The C<DB::set_list> routine
9046 is used to save aggregate variables (both hashes and arrays); scalars are
9047 just popped into environment variables directly.
9048
9049 =cut
9050
9051     # If the terminal supported history, grab it and
9052     # save that in the environment.
9053     set_list( "PERLDB_HIST",
9054           $term->Features->{getHistory}
9055         ? $term->GetHistory
9056         : @hist );
9057
9058     # Find all the files that were visited during this
9059     # session (i.e., the debugger had magic hashes
9060     # corresponding to them) and stick them in the environment.
9061     my @had_breakpoints = keys %had_breakpoints;
9062     set_list( "PERLDB_VISITED", @had_breakpoints );
9063
9064     # Save the debugger options we chose.
9065     set_list( "PERLDB_OPT", %option );
9066     # set_list( "PERLDB_OPT", options2remember() );
9067
9068     # Save the break-on-loads.
9069     set_list( "PERLDB_ON_LOAD", %break_on_load );
9070
9071 =pod
9072
9073 The most complex part of this is the saving of all of the breakpoints. They
9074 can live in an awful lot of places, and we have to go through all of them,
9075 find the breakpoints, and then save them in the appropriate environment
9076 variable via C<DB::set_list>.
9077
9078 =cut
9079
9080     # Go through all the breakpoints and make sure they're
9081     # still valid.
9082     my @hard;
9083     for ( 0 .. $#had_breakpoints ) {
9084
9085         # We were in this file.
9086         my $file = $had_breakpoints[$_];
9087
9088         # Grab that file's magic line hash.
9089         *dbline = $main::{ '_<' . $file };
9090
9091         # Skip out if it doesn't exist, or if the breakpoint
9092         # is in a postponed file (we'll do postponed ones
9093         # later).
9094         next unless %dbline or $postponed_file{$file};
9095
9096         # In an eval. This is a little harder, so we'll
9097         # do more processing on that below.
9098         ( push @hard, $file ), next
9099           if $file =~ /^\(\w*eval/;
9100
9101         # XXX I have no idea what this is doing. Yet.
9102         my @add;
9103         @add = %{ $postponed_file{$file} }
9104           if $postponed_file{$file};
9105
9106         # Save the list of all the breakpoints for this file.
9107         set_list( "PERLDB_FILE_$_", %dbline, @add );
9108
9109         # Serialize the extra data %breakpoints_data hash.
9110         # That's a bug fix.
9111         set_list( "PERLDB_FILE_ENABLED_$_",
9112             map { _is_breakpoint_enabled($file, $_) ? 1 : 0 }
9113             sort { $a <=> $b } keys(%dbline)
9114         )
9115     } ## end for (0 .. $#had_breakpoints)
9116
9117     # The breakpoint was inside an eval. This is a little
9118     # more difficult. XXX and I don't understand it.
9119     for (@hard) {
9120         # Get over to the eval in question.
9121         *dbline = $main::{ '_<' . $_ };
9122         my ( $quoted, $sub, %subs, $line ) = quotemeta $_;
9123         for $sub ( keys %sub ) {
9124             next unless $sub{$sub} =~ /^$quoted:(\d+)-(\d+)$/;
9125             $subs{$sub} = [ $1, $2 ];
9126         }
9127         unless (%subs) {
9128             print $OUT
9129               "No subroutines in $_, ignoring breakpoints.\n";
9130             next;
9131         }
9132       LINES: for $line ( keys %dbline ) {
9133
9134             # One breakpoint per sub only:
9135             my ( $offset, $sub, $found );
9136           SUBS: for $sub ( keys %subs ) {
9137                 if (
9138                     $subs{$sub}->[1] >=
9139                     $line    # Not after the subroutine
9140                     and (
9141                         not defined $offset    # Not caught
9142                         or $offset < 0
9143                     )
9144                   )
9145                 {                              # or badly caught
9146                     $found  = $sub;
9147                     $offset = $line - $subs{$sub}->[0];
9148                     $offset = "+$offset", last SUBS
9149                       if $offset >= 0;
9150                 } ## end if ($subs{$sub}->[1] >=...
9151             } ## end for $sub (keys %subs)
9152             if ( defined $offset ) {
9153                 $postponed{$found} =
9154                   "break $offset if $dbline{$line}";
9155             }
9156             else {
9157                 print $OUT
9158 "Breakpoint in $_:$line ignored: after all the subroutines.\n";
9159             }
9160         } ## end for $line (keys %dbline)
9161     } ## end for (@hard)
9162
9163     # Save the other things that don't need to be
9164     # processed.
9165     set_list( "PERLDB_POSTPONE",  %postponed );
9166     set_list( "PERLDB_PRETYPE",   @$pretype );
9167     set_list( "PERLDB_PRE",       @$pre );
9168     set_list( "PERLDB_POST",      @$post );
9169     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9170
9171     # We are officially restarting.
9172     $ENV{PERLDB_RESTART} = 1;
9173
9174     # We are junking all child debuggers.
9175     delete $ENV{PERLDB_PIDS};    # Restore ini state
9176
9177     # Set this back to the initial pid.
9178     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9179
9180 =pod
9181
9182 After all the debugger status has been saved, we take the command we built up
9183 and then return it, so we can C<exec()> it. The debugger will spot the
9184 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9185 from the environment.
9186
9187 =cut
9188
9189     # And run Perl again. Add the "-d" flag, all the
9190     # flags we built up, the script (whether a one-liner
9191     # or a file), add on the -emacs flag for a slave editor,
9192     # and then the old arguments.
9193
9194     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9195
9196 };  # end restart
9197
9198 =back
9199
9200 =head1 END PROCESSING - THE C<END> BLOCK
9201
9202 Come here at the very end of processing. We want to go into a
9203 loop where we allow the user to enter commands and interact with the
9204 debugger, but we don't want anything else to execute.
9205
9206 First we set the C<$finished> variable, so that some commands that
9207 shouldn't be run after the end of program quit working.
9208
9209 We then figure out whether we're truly done (as in the user entered a C<q>
9210 command, or we finished execution while running nonstop). If we aren't,
9211 we set C<$single> to 1 (causing the debugger to get control again).
9212
9213 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9214 message and returns control to the debugger. Repeat.
9215
9216 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9217 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9218 break, run to completion.).
9219
9220 =cut
9221
9222 END {
9223     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9224     $fall_off_end = 1 unless $inhibit_exit;
9225
9226     # Do not stop in at_exit() and destructors on exit:
9227     if ($fall_off_end or $runnonstop) {
9228         &save_hist();
9229     } else {
9230         $DB::single = 1;
9231         DB::fake::at_exit();
9232     }
9233 } ## end END
9234
9235 =head1 PRE-5.8 COMMANDS
9236
9237 Some of the commands changed function quite a bit in the 5.8 command
9238 realignment, so much so that the old code had to be replaced completely.
9239 Because we wanted to retain the option of being able to go back to the
9240 former command set, we moved the old code off to this section.
9241
9242 There's an awful lot of duplicated code here. We've duplicated the
9243 comments to keep things clear.
9244
9245 =head2 Null command
9246
9247 Does nothing. Used to I<turn off> commands.
9248
9249 =cut
9250
9251 sub cmd_pre580_null {
9252
9253     # do nothing...
9254 }
9255
9256 =head2 Old C<a> command.
9257
9258 This version added actions if you supplied them, and deleted them
9259 if you didn't.
9260
9261 =cut
9262
9263 sub cmd_pre580_a {
9264     my $xcmd = shift;
9265     my $cmd  = shift;
9266
9267     # Argument supplied. Add the action.
9268     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9269
9270         # If the line isn't there, use the current line.
9271         my $i = $1 || $line;
9272         my $j = $2;
9273
9274         # If there is an action ...
9275         if ( length $j ) {
9276
9277             # ... but the line isn't breakable, skip it.
9278             if ( $dbline[$i] == 0 ) {
9279                 print $OUT "Line $i may not have an action.\n";
9280             }
9281             else {
9282
9283                 # ... and the line is breakable:
9284                 # Mark that there's an action in this file.
9285                 $had_breakpoints{$filename} |= 2;
9286
9287                 # Delete any current action.
9288                 $dbline{$i} =~ s/\0[^\0]*//;
9289
9290                 # Add the new action, continuing the line as needed.
9291                 $dbline{$i} .= "\0" . action($j);
9292             }
9293         } ## end if (length $j)
9294
9295         # No action supplied.
9296         else {
9297
9298             # Delete the action.
9299             $dbline{$i} =~ s/\0[^\0]*//;
9300
9301             # Mark as having no break or action if nothing's left.
9302             delete $dbline{$i} if $dbline{$i} eq '';
9303         }
9304     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
9305 } ## end sub cmd_pre580_a
9306
9307 =head2 Old C<b> command
9308
9309 Add breakpoints.
9310
9311 =cut
9312
9313 sub cmd_pre580_b {
9314     my $xcmd   = shift;
9315     my $cmd    = shift;
9316     my $dbline = shift;
9317
9318     # Break on load.
9319     if ( $cmd =~ /^load\b\s*(.*)/ ) {
9320         my $file = $1;
9321         $file =~ s/\s+$//;
9322         &cmd_b_load($file);
9323     }
9324
9325     # b compile|postpone <some sub> [<condition>]
9326     # The interpreter actually traps this one for us; we just put the
9327     # necessary condition in the %postponed hash.
9328     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
9329
9330         # Capture the condition if there is one. Make it true if none.
9331         my $cond = length $3 ? $3 : '1';
9332
9333         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
9334         # if it was 'compile'.
9335         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
9336
9337         # De-Perl4-ify the name - ' separators to ::.
9338         $subname =~ s/\'/::/g;
9339
9340         # Qualify it into the current package unless it's already qualified.
9341         $subname = "${package}::" . $subname
9342           unless $subname =~ /::/;
9343
9344         # Add main if it starts with ::.
9345         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
9346
9347         # Save the break type for this sub.
9348         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
9349     } ## end elsif ($cmd =~ ...
9350
9351     # b <sub name> [<condition>]
9352     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
9353         my $subname = $1;
9354         my $cond = length $2 ? $2 : '1';
9355         &cmd_b_sub( $subname, $cond );
9356     }
9357     # b <line> [<condition>].
9358     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9359         my $i = $1 || $dbline;
9360         my $cond = length $2 ? $2 : '1';
9361         &cmd_b_line( $i, $cond );
9362     }
9363 } ## end sub cmd_pre580_b
9364
9365 =head2 Old C<D> command.
9366
9367 Delete all breakpoints unconditionally.
9368
9369 =cut
9370
9371 sub cmd_pre580_D {
9372     my $xcmd = shift;
9373     my $cmd  = shift;
9374     if ( $cmd =~ /^\s*$/ ) {
9375         print $OUT "Deleting all breakpoints...\n";
9376
9377         # %had_breakpoints lists every file that had at least one
9378         # breakpoint in it.
9379         my $file;
9380         for $file ( keys %had_breakpoints ) {
9381
9382             # Switch to the desired file temporarily.
9383             local *dbline = $main::{ '_<' . $file };
9384
9385             $max = $#dbline;
9386             my $was;
9387
9388             # For all lines in this file ...
9389             for my $i (1 .. $max) {
9390
9391                 # If there's a breakpoint or action on this line ...
9392                 if ( defined $dbline{$i} ) {
9393
9394                     # ... remove the breakpoint.
9395                     $dbline{$i} =~ s/^[^\0]+//;
9396                     if ( $dbline{$i} =~ s/^\0?$// ) {
9397
9398                         # Remove the entry altogether if no action is there.
9399                         delete $dbline{$i};
9400                     }
9401                 } ## end if (defined $dbline{$i...
9402             } ## end for my $i (1 .. $max)
9403
9404             # If, after we turn off the "there were breakpoints in this file"
9405             # bit, the entry in %had_breakpoints for this file is zero,
9406             # we should remove this file from the hash.
9407             if ( not $had_breakpoints{$file} &= ~1 ) {
9408                 delete $had_breakpoints{$file};
9409             }
9410         } ## end for $file (keys %had_breakpoints)
9411
9412         # Kill off all the other breakpoints that are waiting for files that
9413         # haven't been loaded yet.
9414         undef %postponed;
9415         undef %postponed_file;
9416         undef %break_on_load;
9417     } ## end if ($cmd =~ /^\s*$/)
9418 } ## end sub cmd_pre580_D
9419
9420 =head2 Old C<h> command
9421
9422 Print help. Defaults to printing the long-form help; the 5.8 version
9423 prints the summary by default.
9424
9425 =cut
9426
9427 sub cmd_pre580_h {
9428     my $xcmd = shift;
9429     my $cmd  = shift;
9430
9431     # Print the *right* help, long format.
9432     if ( $cmd =~ /^\s*$/ ) {
9433         print_help($pre580_help);
9434     }
9435
9436     # 'h h' - explicitly-requested summary.
9437     elsif ( $cmd =~ /^h\s*/ ) {
9438         print_help($pre580_summary);
9439     }
9440
9441     # Find and print a command's help.
9442     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
9443         my $asked  = $1;                   # for proper errmsg
9444         my $qasked = quotemeta($asked);    # for searching
9445                                            # XXX: finds CR but not <CR>
9446         if (
9447             $pre580_help =~ /^
9448                               <?           # Optional '<'
9449                               (?:[IB]<)    # Optional markup
9450                               $qasked      # The command name
9451                             /mx
9452           )
9453         {
9454
9455             while (
9456                 $pre580_help =~ /^
9457                                   (             # The command help:
9458                                    <?           # Optional '<'
9459                                    (?:[IB]<)    # Optional markup
9460                                    $qasked      # The command name
9461                                    ([\s\S]*?)   # Lines starting with tabs
9462                                    \n           # Final newline
9463                                   )
9464                                   (?!\s)/mgx
9465               )    # Line not starting with space
9466                    # (Next command's help)
9467             {
9468                 print_help($1);
9469             }
9470         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
9471
9472         # Help not found.
9473         else {
9474             print_help("B<$asked> is not a debugger command.\n");
9475         }
9476     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
9477 } ## end sub cmd_pre580_h
9478
9479 =head2 Old C<W> command
9480
9481 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
9482
9483 =cut
9484
9485 sub cmd_pre580_W {
9486     my $xcmd = shift;
9487     my $cmd  = shift;
9488
9489     # Delete all watch expressions.
9490     if ( $cmd =~ /^$/ ) {
9491
9492         # No watching is going on.
9493         $trace &= ~2;
9494
9495         # Kill all the watch expressions and values.
9496         @to_watch = @old_watch = ();
9497     }
9498
9499     # Add a watch expression.
9500     elsif ( $cmd =~ /^(.*)/s ) {
9501
9502         # add it to the list to be watched.
9503         push @to_watch, $1;
9504
9505         # Get the current value of the expression.
9506         # Doesn't handle expressions returning list values!
9507         $evalarg = $1;
9508         my ($val) = &eval;
9509         $val = ( defined $val ) ? "'$val'" : 'undef';
9510
9511         # Save it.
9512         push @old_watch, $val;
9513
9514         # We're watching stuff.
9515         $trace |= 2;
9516
9517     } ## end elsif ($cmd =~ /^(.*)/s)
9518 } ## end sub cmd_pre580_W
9519
9520 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
9521
9522 The debugger used to have a bunch of nearly-identical code to handle
9523 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
9524 C<cmd_prepost> unify all this into one set of code to handle the
9525 appropriate actions.
9526
9527 =head2 C<cmd_pre590_prepost>
9528
9529 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
9530 do something destructive. In pre 5.8 debuggers, the default action was to
9531 delete all the actions.
9532
9533 =cut
9534
9535 sub cmd_pre590_prepost {
9536     my $cmd    = shift;
9537     my $line   = shift || '*';
9538     my $dbline = shift;
9539
9540     return &cmd_prepost( $cmd, $line, $dbline );
9541 } ## end sub cmd_pre590_prepost
9542
9543 =head2 C<cmd_prepost>
9544
9545 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
9546 Since the lists of actions are all held in arrays that are pointed to by
9547 references anyway, all we have to do is pick the right array reference and
9548 then use generic code to all, delete, or list actions.
9549
9550 =cut
9551
9552 sub cmd_prepost {
9553     my $cmd = shift;
9554
9555     # No action supplied defaults to 'list'.
9556     my $line = shift || '?';
9557
9558     # Figure out what to put in the prompt.
9559     my $which = '';
9560
9561     # Make sure we have some array or another to address later.
9562     # This means that if ssome reason the tests fail, we won't be
9563     # trying to stash actions or delete them from the wrong place.
9564     my $aref = [];
9565
9566     # < - Perl code to run before prompt.
9567     if ( $cmd =~ /^\</o ) {
9568         $which = 'pre-perl';
9569         $aref  = $pre;
9570     }
9571
9572     # > - Perl code to run after prompt.
9573     elsif ( $cmd =~ /^\>/o ) {
9574         $which = 'post-perl';
9575         $aref  = $post;
9576     }
9577
9578     # { - first check for properly-balanced braces.
9579     elsif ( $cmd =~ /^\{/o ) {
9580         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
9581             print $OUT
9582 "$cmd is now a debugger command\nuse ';$cmd' if you mean Perl code\n";
9583         }
9584
9585         # Properly balanced. Pre-prompt debugger actions.
9586         else {
9587             $which = 'pre-debugger';
9588             $aref  = $pretype;
9589         }
9590     } ## end elsif ( $cmd =~ /^\{/o )
9591
9592     # Did we find something that makes sense?
9593     unless ($which) {
9594         print $OUT "Confused by command: $cmd\n";
9595     }
9596
9597     # Yes.
9598     else {
9599
9600         # List actions.
9601         if ( $line =~ /^\s*\?\s*$/o ) {
9602             unless (@$aref) {
9603
9604                 # Nothing there. Complain.
9605                 print $OUT "No $which actions.\n";
9606             }
9607             else {
9608
9609                 # List the actions in the selected list.
9610                 print $OUT "$which commands:\n";
9611                 foreach my $action (@$aref) {
9612                     print $OUT "\t$cmd -- $action\n";
9613                 }
9614             } ## end else
9615         } ## end if ( $line =~ /^\s*\?\s*$/o)
9616
9617         # Might be a delete.
9618         else {
9619             if ( length($cmd) == 1 ) {
9620                 if ( $line =~ /^\s*\*\s*$/o ) {
9621
9622                     # It's a delete. Get rid of the old actions in the
9623                     # selected list..
9624                     @$aref = ();
9625                     print $OUT "All $cmd actions cleared.\n";
9626                 }
9627                 else {
9628
9629                     # Replace all the actions. (This is a <, >, or {).
9630                     @$aref = action($line);
9631                 }
9632             } ## end if ( length($cmd) == 1)
9633             elsif ( length($cmd) == 2 ) {
9634
9635                 # Add the action to the line. (This is a <<, >>, or {{).
9636                 push @$aref, action($line);
9637             }
9638             else {
9639
9640                 # <<<, >>>>, {{{{{{ ... something not a command.
9641                 print $OUT
9642                   "Confused by strange length of $which command($cmd)...\n";
9643             }
9644         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
9645     } ## end else
9646 } ## end sub cmd_prepost
9647
9648 =head1 C<DB::fake>
9649
9650 Contains the C<at_exit> routine that the debugger uses to issue the
9651 C<Debugged program terminated ...> message after the program completes. See
9652 the C<END> block documentation for more details.
9653
9654 =cut
9655
9656 package DB::fake;
9657
9658 sub at_exit {
9659     "Debugged program terminated.  Use 'q' to quit or 'R' to restart.";
9660 }
9661
9662 package DB;    # Do not trace this 1; below!
9663
9664 1;
9665
9666