lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<_<$filename>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34)> or C<(re_eval 19)>.
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
 514
 515 BEGIN {
 516     require feature;
 517     $^V =~ /^v(\d+\.\d+)/;
 518     feature->import(":$1");
 519 }
 520
 521 # Debugger for Perl 5.00x; perl5db.pl patch level:
 522 $VERSION = '1.34';
 523
 524 $header = "perl5db.pl version $VERSION";
 525
 526 =head1 DEBUGGER ROUTINES
 527
 528 =head2 C<DB::eval()>
 529
 530 This function replaces straight C<eval()> inside the debugger; it simplifies
 531 the process of evaluating code in the user's context.
 532
 533 The code to be evaluated is passed via the package global variable
 534 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 535
 536 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 537 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 538 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 539 user's current package, grabbed when C<DB::DB> got control.  This causes the
 540 proper context to be used when the eval is actually done.  Afterward, we
 541 restore C<$trace>, C<$single>, and C<$^D>.
 542
 543 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 544 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 545 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 546 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 547 considered sane by the debugger. If there was an C<eval()> error, we print
 548 it on the debugger's output. If C<$onetimedump> is defined, we call
 549 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 550 'methods'. Setting it to something else causes the debugger to do the eval
 551 but not print the result - handy if you want to do something else with it
 552 (the "watch expressions" code does this to get the value of the watch
 553 expression but not show it unless it matters).
 554
 555 In any case, we then return the list of output from C<eval> to the caller,
 556 and unwinding restores the former version of C<$@> in C<@saved> as well
 557 (the localization of C<$saved[0]> goes away at the end of this scope).
 558
 559 =head3 Parameters and variables influencing execution of DB::eval()
 560
 561 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 562 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 563 The variables listed below influence C<DB::eval()>'s execution directly.
 564
 565 =over 4
 566
 567 =item C<$evalarg> - the thing to actually be eval'ed
 568
 569 =item C<$trace> - Current state of execution tracing
 570
 571 =item C<$single> - Current state of single-stepping
 572
 573 =item C<$onetimeDump> - what is to be displayed after the evaluation
 574
 575 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 576
 577 =back
 578
 579 The following variables are altered by C<DB::eval()> during its execution. They
 580 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 581
 582 =over 4
 583
 584 =item C<@res> - used to capture output from actual C<eval>.
 585
 586 =item C<$otrace> - saved value of C<$trace>.
 587
 588 =item C<$osingle> - saved value of C<$single>.
 589
 590 =item C<$od> - saved value of C<$^D>.
 591
 592 =item C<$saved[0]> - saved value of C<$@>.
 593
 594 =item $\ - for output of C<$@> if there is an evaluation error.
 595
 596 =back
 597
 598 =head3 The problem of lexicals
 599
 600 The context of C<DB::eval()> presents us with some problems. Obviously,
 601 we want to be 'sandboxed' away from the debugger's internals when we do
 602 the eval, but we need some way to control how punctuation variables and
 603 debugger globals are used.
 604
 605 We can't use local, because the code inside C<DB::eval> can see localized
 606 variables; and we can't use C<my> either for the same reason. The code
 607 in this routine compromises and uses C<my>.
 608
 609 After this routine is over, we don't have user code executing in the debugger's
 610 context, so we can use C<my> freely.
 611
 612 =cut
 613
 614 ############################################## Begin lexical danger zone
 615
 616 # 'my' variables used here could leak into (that is, be visible in)
 617 # the context that the code being evaluated is executing in. This means that
 618 # the code could modify the debugger's variables.
 619 #
 620 # Fiddling with the debugger's context could be Bad. We insulate things as
 621 # much as we can.
 622
 623 sub eval {
 624
 625     # 'my' would make it visible from user code
 626     #    but so does local! --tchrist
 627     # Remember: this localizes @DB::res, not @main::res.
 628     local @res;
 629     {
 630
 631         # Try to keep the user code from messing  with us. Save these so that
 632         # even if the eval'ed code changes them, we can put them back again.
 633         # Needed because the user could refer directly to the debugger's
 634         # package globals (and any 'my' variables in this containing scope)
 635         # inside the eval(), and we want to try to stay safe.
 636         local $otrace  = $trace;
 637         local $osingle = $single;
 638         local $od      = $^D;
 639
 640         # Untaint the incoming eval() argument.
 641         { ($evalarg) = $evalarg =~ /(.*)/s; }
 642
 643         # $usercontext built in DB::DB near the comment
 644         # "set up the context for DB::eval ..."
 645         # Evaluate and save any results.
 646         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 647
 648         # Restore those old values.
 649         $trace  = $otrace;
 650         $single = $osingle;
 651         $^D     = $od;
 652     }
 653
 654     # Save the current value of $@, and preserve it in the debugger's copy
 655     # of the saved precious globals.
 656     my $at = $@;
 657
 658     # Since we're only saving $@, we only have to localize the array element
 659     # that it will be stored in.
 660     local $saved[0];    # Preserve the old value of $@
 661     eval { &DB::save };
 662
 663     # Now see whether we need to report an error back to the user.
 664     if ($at) {
 665         local $\ = '';
 666         print $OUT $at;
 667     }
 668
 669     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 670     # are package globals.
 671     elsif ($onetimeDump) {
 672         if ( $onetimeDump eq 'dump' ) {
 673             local $option{dumpDepth} = $onetimedumpDepth
 674               if defined $onetimedumpDepth;
 675             dumpit( $OUT, \@res );
 676         }
 677         elsif ( $onetimeDump eq 'methods' ) {
 678             methods( $res[0] );
 679         }
 680     } ## end elsif ($onetimeDump)
 681     @res;
 682 } ## end sub eval
 683
 684 ############################################## End lexical danger zone
 685
 686 # After this point it is safe to introduce lexicals.
 687 # The code being debugged will be executing in its own context, and
 688 # can't see the inside of the debugger.
 689 #
 690 # However, one should not overdo it: leave as much control from outside as
 691 # possible. If you make something a lexical, it's not going to be addressable
 692 # from outside the debugger even if you know its name.
 693
 694 # This file is automatically included if you do perl -d.
 695 # It's probably not useful to include this yourself.
 696 #
 697 # Before venturing further into these twisty passages, it is
 698 # wise to read the perldebguts man page or risk the ire of dragons.
 699 #
 700 # (It should be noted that perldebguts will tell you a lot about
 701 # the underlying mechanics of how the debugger interfaces into the
 702 # Perl interpreter, but not a lot about the debugger itself. The new
 703 # comments in this code try to address this problem.)
 704
 705 # Note that no subroutine call is possible until &DB::sub is defined
 706 # (for subroutines defined outside of the package DB). In fact the same is
 707 # true if $deep is not defined.
 708
 709 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 710
 711 # modified Perl debugger, to be run from Emacs in perldb-mode
 712 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 713 # Johan Vromans -- upgrade to 4.0 pl 10
 714 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 715
 716 # (We have made efforts to  clarify the comments in the change log
 717 # in other places; some of them may seem somewhat obscure as they
 718 # were originally written, and explaining them away from the code
 719 # in question seems conterproductive.. -JM)
 720
 721 ########################################################################
 722 # Changes: 0.94
 723 #   + A lot of things changed after 0.94. First of all, core now informs
 724 #     debugger about entry into XSUBs, overloaded operators, tied operations,
 725 #     BEGIN and END. Handy with 'O f=2'.
 726 #   + This can make debugger a little bit too verbose, please be patient
 727 #     and report your problems promptly.
 728 #   + Now the option frame has 3 values: 0,1,2. XXX Document!
 729 #   + Note that if DESTROY returns a reference to the object (or object),
 730 #     the deletion of data may be postponed until the next function call,
 731 #     due to the need to examine the return value.
 732 #
 733 # Changes: 0.95
 734 #   + 'v' command shows versions.
 735 #
 736 # Changes: 0.96
 737 #   + 'v' command shows version of readline.
 738 #     primitive completion works (dynamic variables, subs for 'b' and 'l',
 739 #     options). Can 'p %var'
 740 #   + Better help ('h <' now works). New commands <<, >>, {, {{.
 741 #     {dump|print}_trace() coded (to be able to do it from <<cmd).
 742 #   + 'c sub' documented.
 743 #   + At last enough magic combined to stop after the end of debuggee.
 744 #   + !! should work now (thanks to Emacs bracket matching an extra
 745 #     ']' in a regexp is caught).
 746 #   + 'L', 'D' and 'A' span files now (as documented).
 747 #   + Breakpoints in 'require'd code are possible (used in 'R').
 748 #   +  Some additional words on internal work of debugger.
 749 #   + 'b load filename' implemented.
 750 #   + 'b postpone subr' implemented.
 751 #   + now only 'q' exits debugger (overwritable on $inhibit_exit).
 752 #   + When restarting debugger breakpoints/actions persist.
 753 #   + Buglet: When restarting debugger only one breakpoint/action per
 754 #             autoloaded function persists.
 755 #
 756 # Changes: 0.97: NonStop will not stop in at_exit().
 757 #   + Option AutoTrace implemented.
 758 #   + Trace printed differently if frames are printed too.
 759 #   + new 'inhibitExit' option.
 760 #   + printing of a very long statement interruptible.
 761 # Changes: 0.98: New command 'm' for printing possible methods
 762 #   + 'l -' is a synonym for '-'.
 763 #   + Cosmetic bugs in printing stack trace.
 764 #   +  'frame' & 8 to print "expanded args" in stack trace.
 765 #   + Can list/break in imported subs.
 766 #   + new 'maxTraceLen' option.
 767 #   + frame & 4 and frame & 8 granted.
 768 #   + new command 'm'
 769 #   + nonstoppable lines do not have ':' near the line number.
 770 #   + 'b compile subname' implemented.
 771 #   + Will not use $` any more.
 772 #   + '-' behaves sane now.
 773 # Changes: 0.99: Completion for 'f', 'm'.
 774 #   +  'm' will remove duplicate names instead of duplicate functions.
 775 #   + 'b load' strips trailing whitespace.
 776 #     completion ignores leading '|'; takes into account current package
 777 #     when completing a subroutine name (same for 'l').
 778 # Changes: 1.07: Many fixed by tchrist 13-March-2000
 779 #   BUG FIXES:
 780 #   + Added bare minimal security checks on perldb rc files, plus
 781 #     comments on what else is needed.
 782 #   + Fixed the ornaments that made "|h" completely unusable.
 783 #     They are not used in print_help if they will hurt.  Strip pod
 784 #     if we're paging to less.
 785 #   + Fixed mis-formatting of help messages caused by ornaments
 786 #     to restore Larry's original formatting.
 787 #   + Fixed many other formatting errors.  The code is still suboptimal,
 788 #     and needs a lot of work at restructuring.  It's also misindented
 789 #     in many places.
 790 #   + Fixed bug where trying to look at an option like your pager
 791 #     shows "1".
 792 #   + Fixed some $? processing.  Note: if you use csh or tcsh, you will
 793 #     lose.  You should consider shell escapes not using their shell,
 794 #     or else not caring about detailed status.  This should really be
 795 #     unified into one place, too.
 796 #   + Fixed bug where invisible trailing whitespace on commands hoses you,
 797 #     tricking Perl into thinking you weren't calling a debugger command!
 798 #   + Fixed bug where leading whitespace on commands hoses you.  (One
 799 #     suggests a leading semicolon or any other irrelevant non-whitespace
 800 #     to indicate literal Perl code.)
 801 #   + Fixed bugs that ate warnings due to wrong selected handle.
 802 #   + Fixed a precedence bug on signal stuff.
 803 #   + Fixed some unseemly wording.
 804 #   + Fixed bug in help command trying to call perl method code.
 805 #   + Fixed to call dumpvar from exception handler.  SIGPIPE killed us.
 806 #   ENHANCEMENTS:
 807 #   + Added some comments.  This code is still nasty spaghetti.
 808 #   + Added message if you clear your pre/post command stacks which was
 809 #     very easy to do if you just typed a bare >, <, or {.  (A command
 810 #     without an argument should *never* be a destructive action; this
 811 #     API is fundamentally screwed up; likewise option setting, which
 812 #     is equally buggered.)
 813 #   + Added command stack dump on argument of "?" for >, <, or {.
 814 #   + Added a semi-built-in doc viewer command that calls man with the
 815 #     proper %Config::Config path (and thus gets caching, man -k, etc),
 816 #     or else perldoc on obstreperous platforms.
 817 #   + Added to and rearranged the help information.
 818 #   + Detected apparent misuse of { ... } to declare a block; this used
 819 #     to work but now is a command, and mysteriously gave no complaint.
 820 #
 821 # Changes: 1.08: Apr 25, 2001  Jon Eveland <jweveland@yahoo.com>
 822 #   BUG FIX:
 823 #   + This patch to perl5db.pl cleans up formatting issues on the help
 824 #     summary (h h) screen in the debugger.  Mostly columnar alignment
 825 #     issues, plus converted the printed text to use all spaces, since
 826 #     tabs don't seem to help much here.
 827 #
 828 # Changes: 1.09: May 19, 2001  Ilya Zakharevich <ilya@math.ohio-state.edu>
 829 #   Minor bugs corrected;
 830 #   + Support for auto-creation of new TTY window on startup, either
 831 #     unconditionally, or if started as a kid of another debugger session;
 832 #   + New 'O'ption CreateTTY
 833 #       I<CreateTTY>      bits control attempts to create a new TTY on events:
 834 #                         1: on fork()
 835 #                         2: debugger is started inside debugger
 836 #                         4: on startup
 837 #   + Code to auto-create a new TTY window on OS/2 (currently one
 838 #     extra window per session - need named pipes to have more...);
 839 #   + Simplified interface for custom createTTY functions (with a backward
 840 #     compatibility hack); now returns the TTY name to use; return of ''
 841 #     means that the function reset the I/O handles itself;
 842 #   + Better message on the semantic of custom createTTY function;
 843 #   + Convert the existing code to create a TTY into a custom createTTY
 844 #     function;
 845 #   + Consistent support for TTY names of the form "TTYin,TTYout";
 846 #   + Switch line-tracing output too to the created TTY window;
 847 #   + make 'b fork' DWIM with CORE::GLOBAL::fork;
 848 #   + High-level debugger API cmd_*():
 849 #      cmd_b_load($filenamepart)            # b load filenamepart
 850 #      cmd_b_line($lineno [, $cond])        # b lineno [cond]
 851 #      cmd_b_sub($sub [, $cond])            # b sub [cond]
 852 #      cmd_stop()                           # Control-C
 853 #      cmd_d($lineno)                       # d lineno (B)
 854 #      The cmd_*() API returns FALSE on failure; in this case it outputs
 855 #      the error message to the debugging output.
 856 #   + Low-level debugger API
 857 #      break_on_load($filename)             # b load filename
 858 #      @files = report_break_on_load()      # List files with load-breakpoints
 859 #      breakable_line_in_filename($name, $from [, $to])
 860 #                                           # First breakable line in the
 861 #                                           # range $from .. $to.  $to defaults
 862 #                                           # to $from, and may be less than
 863 #                                           # $to
 864 #      breakable_line($from [, $to])        # Same for the current file
 865 #      break_on_filename_line($name, $lineno [, $cond])
 866 #                                           # Set breakpoint,$cond defaults to
 867 #                                           # 1
 868 #      break_on_filename_line_range($name, $from, $to [, $cond])
 869 #                                           # As above, on the first
 870 #                                           # breakable line in range
 871 #      break_on_line($lineno [, $cond])     # As above, in the current file
 872 #      break_subroutine($sub [, $cond])     # break on the first breakable line
 873 #      ($name, $from, $to) = subroutine_filename_lines($sub)
 874 #                                           # The range of lines of the text
 875 #      The low-level API returns TRUE on success, and die()s on failure.
 876 #
 877 # Changes: 1.10: May 23, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 878 #   BUG FIXES:
 879 #   + Fixed warnings generated by "perl -dWe 42"
 880 #   + Corrected spelling errors
 881 #   + Squeezed Help (h) output into 80 columns
 882 #
 883 # Changes: 1.11: May 24, 2001  David Dyck <dcd@tc.fluke.com>
 884 #   + Made "x @INC" work like it used to
 885 #
 886 # Changes: 1.12: May 24, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 887 #   + Fixed warnings generated by "O" (Show debugger options)
 888 #   + Fixed warnings generated by "p 42" (Print expression)
 889 # Changes: 1.13: Jun 19, 2001 Scott.L.Miller@compaq.com
 890 #   + Added windowSize option
 891 # Changes: 1.14: Oct  9, 2001 multiple
 892 #   + Clean up after itself on VMS (Charles Lane in 12385)
 893 #   + Adding "@ file" syntax (Peter Scott in 12014)
 894 #   + Debug reloading selfloaded stuff (Ilya Zakharevich in 11457)
 895 #   + $^S and other debugger fixes (Ilya Zakharevich in 11120)
 896 #   + Forgot a my() declaration (Ilya Zakharevich in 11085)
 897 # Changes: 1.15: Nov  6, 2001 Michael G Schwern <schwern@pobox.com>
 898 #   + Updated 1.14 change log
 899 #   + Added *dbline explanatory comments
 900 #   + Mentioning perldebguts man page
 901 # Changes: 1.16: Feb 15, 2002 Mark-Jason Dominus <mjd@plover.com>
 902 #   + $onetimeDump improvements
 903 # Changes: 1.17: Feb 20, 2002 Richard Foley <richard.foley@rfi.net>
 904 #   Moved some code to cmd_[.]()'s for clarity and ease of handling,
 905 #   rationalised the following commands and added cmd_wrapper() to
 906 #   enable switching between old and frighteningly consistent new
 907 #   behaviours for diehards: 'o CommandSet=pre580' (sigh...)
 908 #     a(add),       A(del)            # action expr   (added del by line)
 909 #   + b(add),       B(del)            # break  [line] (was b,D)
 910 #   + w(add),       W(del)            # watch  expr   (was W,W)
 911 #                                     # added del by expr
 912 #   + h(summary), h h(long)           # help (hh)     (was h h,h)
 913 #   + m(methods),   M(modules)        # ...           (was m,v)
 914 #   + o(option)                       # lc            (was O)
 915 #   + v(view code), V(view Variables) # ...           (was w,V)
 916 # Changes: 1.18: Mar 17, 2002 Richard Foley <richard.foley@rfi.net>
 917 #   + fixed missing cmd_O bug
 918 # Changes: 1.19: Mar 29, 2002 Spider Boardman
 919 #   + Added missing local()s -- DB::DB is called recursively.
 920 # Changes: 1.20: Feb 17, 2003 Richard Foley <richard.foley@rfi.net>
 921 #   + pre'n'post commands no longer trashed with no args
 922 #   + watch val joined out of eval()
 923 # Changes: 1.21: Jun 04, 2003 Joe McMahon <mcmahon@ibiblio.org>
 924 #   + Added comments and reformatted source. No bug fixes/enhancements.
 925 #   + Includes cleanup by Robin Barker and Jarkko Hietaniemi.
 926 # Changes: 1.22  Jun 09, 2003 Alex Vandiver <alexmv@MIT.EDU>
 927 #   + Flush stdout/stderr before the debugger prompt is printed.
 928 # Changes: 1.23: Dec 21, 2003 Dominique Quatravaux
 929 #   + Fix a side-effect of bug #24674 in the perl debugger ("odd taint bug")
 930 # Changes: 1.24: Mar 03, 2004 Richard Foley <richard.foley@rfi.net>
 931 #   + Added command to save all debugger commands for sourcing later.
 932 #   + Added command to display parent inheritance tree of given class.
 933 #   + Fixed minor newline in history bug.
 934 # Changes: 1.25: Apr 17, 2004 Richard Foley <richard.foley@rfi.net>
 935 #   + Fixed option bug (setting invalid options + not recognising valid short forms)
 936 # Changes: 1.26: Apr 22, 2004 Richard Foley <richard.foley@rfi.net>
 937 #   + unfork the 5.8.x and 5.9.x debuggers.
 938 #   + whitespace and assertions call cleanup across versions
 939 #   + H * deletes (resets) history
 940 #   + i now handles Class + blessed objects
 941 # Changes: 1.27: May 09, 2004 Richard Foley <richard.foley@rfi.net>
 942 #   + updated pod page references - clunky.
 943 #   + removed windowid restriction for forking into an xterm.
 944 #   + more whitespace again.
 945 #   + wrapped restart and enabled rerun [-n] (go back n steps) command.
 946 # Changes: 1.28: Oct 12, 2004 Richard Foley <richard.foley@rfi.net>
 947 #   + Added threads support (inc. e and E commands)
 948 # Changes: 1.29: Nov 28, 2006 Bo Lindbergh <blgl@hagernas.com>
 949 #   + Added macosx_get_fork_TTY support
 950 # Changes: 1.30: Mar 06, 2007 Andreas Koenig <andk@cpan.org>
 951 #   + Added HistFile, HistSize
 952 # Changes: 1.31
 953 #   + Remove support for assertions and -A
 954 #   + stop NEXT::AUTOLOAD from emitting warnings under the debugger. RT #25053
 955 #   + "update for Mac OS X 10.5" [finding the tty device]
 956 #   + "What I needed to get the forked debugger to work" [on VMS]
 957 #   + [perl #57016] debugger: o warn=0 die=0 ignored
 958 #   + Note, but don't use, PERLDBf_SAVESRC
 959 #   + Fix #7013: lvalue subs not working inside debugger
 960 # Changes: 1.32: Jun 03, 2009 Jonathan Leto <jonathan@leto.net>
 961 #   + Fix bug where a key _< with undefined value was put into the symbol table
 962 #   +   when the $filename variable is not set
 963 # Changes: 1.33:
 964 #   + Debugger prints lines to the remote port when it forks and openes a new port (f633fd2)
 965 #   + The debugger now continues to use RemotePort when it's been configured to use it. (11653f7)
 966 #   + Stop using $ENV{LESS} for parameters not intended for less (d463cf2)
 967 #   + Configure has a path to less and perl5db.pl can use it (bf320d6)
 968 #   + Die with $@ instead of empty message (86755f4)
 969 #   + Remove extra/useless $@ check after eval { require PadWalker } (which is still checked) (dab8d6d)
 970 #   + Promote eval( "require ..." ) to eval { require ... } (4a49187)
 971 #   + Promote eval { require( ... )} || die to mere require( ... ) (999f23b)
 972 #   + Remove indirect object notation from debugger (bee4b46)
 973 #   + Document that @{$main::{'_<'.$filename}} lines are dualvar to (COP*). (7e17a74)
 974 #   + Remove MacOS classic support from the debugger. (2b894b7)
 975 ########################################################################
 976
 977 =head1 DEBUGGER INITIALIZATION
 978
 979 The debugger starts up in phases.
 980
 981 =head2 BASIC SETUP
 982
 983 First, it initializes the environment it wants to run in: turning off
 984 warnings during its own compilation, defining variables which it will need
 985 to avoid warnings later, setting itself up to not exit when the program
 986 terminates, and defaulting to printing return values for the C<r> command.
 987
 988 =cut
 989
 990 # Needed for the statement after exec():
 991 #
 992 # This BEGIN block is simply used to switch off warnings during debugger
 993 # compilation. Probably it would be better practice to fix the warnings,
 994 # but this is how it's done at the moment.
 995
 996 BEGIN {
 997     $ini_warn = $^W;
 998     $^W       = 0;
 999 }    # Switch compilation warnings off until another BEGIN.
1000
1001 local ($^W) = 0;    # Switch run-time warnings off during init.
1002
1003 =head2 THREADS SUPPORT
1004
1005 If we are running under a threaded Perl, we require threads and threads::shared
1006 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
1007 threaded debugger control.  C<-dt> can also be used to set this.
1008
1009 Each new thread will be announced and the debugger prompt will always inform
1010 you of each new thread created.  It will also indicate the thread id in which
1011 we are currently running within the prompt like this:
1012
1013         [tid] DB<$i>
1014
1015 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
1016 command prompt.  The prompt will show: C<[0]> when running under threads, but
1017 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
1018
1019 While running under threads, when you set or delete a breakpoint (etc.), this
1020 will apply to all threads, not just the currently running one.  When you are
1021 in a currently executing thread, you will stay there until it completes.  With
1022 the current implementation it is not currently possible to hop from one thread
1023 to another.
1024
1025 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
1026
1027 Note that threading support was built into the debugger as of Perl version
1028 C<5.8.6> and debugger version C<1.2.8>.
1029
1030 =cut
1031
1032 BEGIN {
1033   # ensure we can share our non-threaded variables or no-op
1034   if ($ENV{PERL5DB_THREADED}) {
1035         require threads;
1036         require threads::shared;
1037         import threads::shared qw(share);
1038         $DBGR;
1039         share(\$DBGR);
1040         lock($DBGR);
1041         print "Threads support enabled\n";
1042   } else {
1043         *lock  = sub(*) {};
1044         *share = sub(*) {};
1045   }
1046 }
1047
1048 # This would probably be better done with "use vars", but that wasn't around
1049 # when this code was originally written. (Neither was "use strict".) And on
1050 # the principle of not fiddling with something that was working, this was
1051 # left alone.
1052 warn(               # Do not ;-)
1053     # These variables control the execution of 'dumpvar.pl'.
1054     $dumpvar::hashDepth,
1055     $dumpvar::arrayDepth,
1056     $dumpvar::dumpDBFiles,
1057     $dumpvar::dumpPackages,
1058     $dumpvar::quoteHighBit,
1059     $dumpvar::printUndef,
1060     $dumpvar::globPrint,
1061     $dumpvar::usageOnly,
1062
1063     # used to save @ARGV and extract any debugger-related flags.
1064     @ARGS,
1065
1066     # used to control die() reporting in diesignal()
1067     $Carp::CarpLevel,
1068
1069     # used to prevent multiple entries to diesignal()
1070     # (if for instance diesignal() itself dies)
1071     $panic,
1072
1073     # used to prevent the debugger from running nonstop
1074     # after a restart
1075     $second_time,
1076   )
1077   if 0;
1078
1079 # without threads, $filename is not defined until DB::DB is called
1080 foreach my $k (keys (%INC)) {
1081         &share(\$main::{'_<'.$filename}) if defined $filename;
1082 };
1083
1084 # Command-line + PERLLIB:
1085 # Save the contents of @INC before they are modified elsewhere.
1086 @ini_INC = @INC;
1087
1088 # This was an attempt to clear out the previous values of various
1089 # trapped errors. Apparently it didn't help. XXX More info needed!
1090 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
1091
1092 # We set these variables to safe values. We don't want to blindly turn
1093 # off warnings, because other packages may still want them.
1094 $trace = $signal = $single = 0;    # Uninitialized warning suppression
1095                                    # (local $^W cannot help - other packages!).
1096
1097 # Default to not exiting when program finishes; print the return
1098 # value when the 'r' command is used to return from a subroutine.
1099 $inhibit_exit = $option{PrintRet} = 1;
1100
1101 =head1 OPTION PROCESSING
1102
1103 The debugger's options are actually spread out over the debugger itself and
1104 C<dumpvar.pl>; some of these are variables to be set, while others are
1105 subs to be called with a value. To try to make this a little easier to
1106 manage, the debugger uses a few data structures to define what options
1107 are legal and how they are to be processed.
1108
1109 First, the C<@options> array defines the I<names> of all the options that
1110 are to be accepted.
1111
1112 =cut
1113
1114 @options = qw(
1115   CommandSet   HistFile      HistSize
1116   hashDepth    arrayDepth    dumpDepth
1117   DumpDBFiles  DumpPackages  DumpReused
1118   compactDump  veryCompact   quote
1119   HighBit      undefPrint    globPrint
1120   PrintRet     UsageOnly     frame
1121   AutoTrace    TTY           noTTY
1122   ReadLine     NonStop       LineInfo
1123   maxTraceLen  recallCommand ShellBang
1124   pager        tkRunning     ornaments
1125   signalLevel  warnLevel     dieLevel
1126   inhibit_exit ImmediateStop bareStringify
1127   CreateTTY    RemotePort    windowSize
1128   DollarCaretP
1129 );
1130
1131 @RememberOnROptions = qw(DollarCaretP);
1132
1133 =pod
1134
1135 Second, C<optionVars> lists the variables that each option uses to save its
1136 state.
1137
1138 =cut
1139
1140 %optionVars = (
1141     hashDepth     => \$dumpvar::hashDepth,
1142     arrayDepth    => \$dumpvar::arrayDepth,
1143     CommandSet    => \$CommandSet,
1144     DumpDBFiles   => \$dumpvar::dumpDBFiles,
1145     DumpPackages  => \$dumpvar::dumpPackages,
1146     DumpReused    => \$dumpvar::dumpReused,
1147     HighBit       => \$dumpvar::quoteHighBit,
1148     undefPrint    => \$dumpvar::printUndef,
1149     globPrint     => \$dumpvar::globPrint,
1150     UsageOnly     => \$dumpvar::usageOnly,
1151     CreateTTY     => \$CreateTTY,
1152     bareStringify => \$dumpvar::bareStringify,
1153     frame         => \$frame,
1154     AutoTrace     => \$trace,
1155     inhibit_exit  => \$inhibit_exit,
1156     maxTraceLen   => \$maxtrace,
1157     ImmediateStop => \$ImmediateStop,
1158     RemotePort    => \$remoteport,
1159     windowSize    => \$window,
1160     HistFile      => \$histfile,
1161     HistSize      => \$histsize,
1162 );
1163
1164 =pod
1165
1166 Third, C<%optionAction> defines the subroutine to be called to process each
1167 option.
1168
1169 =cut
1170
1171 %optionAction = (
1172     compactDump   => \&dumpvar::compactDump,
1173     veryCompact   => \&dumpvar::veryCompact,
1174     quote         => \&dumpvar::quote,
1175     TTY           => \&TTY,
1176     noTTY         => \&noTTY,
1177     ReadLine      => \&ReadLine,
1178     NonStop       => \&NonStop,
1179     LineInfo      => \&LineInfo,
1180     recallCommand => \&recallCommand,
1181     ShellBang     => \&shellBang,
1182     pager         => \&pager,
1183     signalLevel   => \&signalLevel,
1184     warnLevel     => \&warnLevel,
1185     dieLevel      => \&dieLevel,
1186     tkRunning     => \&tkRunning,
1187     ornaments     => \&ornaments,
1188     RemotePort    => \&RemotePort,
1189     DollarCaretP  => \&DollarCaretP,
1190 );
1191
1192 =pod
1193
1194 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1195 option is used.
1196
1197 =cut
1198
1199 # Note that this list is not complete: several options not listed here
1200 # actually require that dumpvar.pl be loaded for them to work, but are
1201 # not in the table. A subsequent patch will correct this problem; for
1202 # the moment, we're just recommenting, and we are NOT going to change
1203 # function.
1204 %optionRequire = (
1205     compactDump => 'dumpvar.pl',
1206     veryCompact => 'dumpvar.pl',
1207     quote       => 'dumpvar.pl',
1208 );
1209
1210 =pod
1211
1212 There are a number of initialization-related variables which can be set
1213 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1214 variable. These are:
1215
1216 =over 4
1217
1218 =item C<$rl> - readline control XXX needs more explanation
1219
1220 =item C<$warnLevel> - whether or not debugger takes over warning handling
1221
1222 =item C<$dieLevel> - whether or not debugger takes over die handling
1223
1224 =item C<$signalLevel> - whether or not debugger takes over signal handling
1225
1226 =item C<$pre> - preprompt actions (array reference)
1227
1228 =item C<$post> - postprompt actions (array reference)
1229
1230 =item C<$pretype>
1231
1232 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1233
1234 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1235
1236 =back
1237
1238 =cut
1239
1240 # These guys may be defined in $ENV{PERL5DB} :
1241 $rl          = 1     unless defined $rl;
1242 $warnLevel   = 1     unless defined $warnLevel;
1243 $dieLevel    = 1     unless defined $dieLevel;
1244 $signalLevel = 1     unless defined $signalLevel;
1245 $pre         = []    unless defined $pre;
1246 $post        = []    unless defined $post;
1247 $pretype     = []    unless defined $pretype;
1248 $CreateTTY   = 3     unless defined $CreateTTY;
1249 $CommandSet  = '580' unless defined $CommandSet;
1250
1251 share($rl);
1252 share($warnLevel);
1253 share($dieLevel);
1254 share($signalLevel);
1255 share($pre);
1256 share($post);
1257 share($pretype);
1258 share($rl);
1259 share($CreateTTY);
1260 share($CommandSet);
1261
1262 =pod
1263
1264 The default C<die>, C<warn>, and C<signal> handlers are set up.
1265
1266 =cut
1267
1268 warnLevel($warnLevel);
1269 dieLevel($dieLevel);
1270 signalLevel($signalLevel);
1271
1272 =pod
1273
1274 The pager to be used is needed next. We try to get it from the
1275 environment first.  If it's not defined there, we try to find it in
1276 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1277 then call the C<pager()> function to save the pager name.
1278
1279 =cut
1280
1281 # This routine makes sure $pager is set up so that '|' can use it.
1282 pager(
1283
1284     # If PAGER is defined in the environment, use it.
1285     defined $ENV{PAGER}
1286     ? $ENV{PAGER}
1287
1288       # If not, see if Config.pm defines it.
1289     : eval { require Config }
1290       && defined $Config::Config{pager}
1291     ? $Config::Config{pager}
1292
1293       # If not, fall back to 'more'.
1294     : 'more'
1295   )
1296   unless defined $pager;
1297
1298 =pod
1299
1300 We set up the command to be used to access the man pages, the command
1301 recall character (C<!> unless otherwise defined) and the shell escape
1302 character (C<!> unless otherwise defined). Yes, these do conflict, and
1303 neither works in the debugger at the moment.
1304
1305 =cut
1306
1307 setman();
1308
1309 # Set up defaults for command recall and shell escape (note:
1310 # these currently don't work in linemode debugging).
1311 &recallCommand("!") unless defined $prc;
1312 &shellBang("!")     unless defined $psh;
1313
1314 =pod
1315
1316 We then set up the gigantic string containing the debugger help.
1317 We also set the limit on the number of arguments we'll display during a
1318 trace.
1319
1320 =cut
1321
1322 sethelp();
1323
1324 # If we didn't get a default for the length of eval/stack trace args,
1325 # set it here.
1326 $maxtrace = 400 unless defined $maxtrace;
1327
1328 =head2 SETTING UP THE DEBUGGER GREETING
1329
1330 The debugger I<greeting> helps to inform the user how many debuggers are
1331 running, and whether the current debugger is the primary or a child.
1332
1333 If we are the primary, we just hang onto our pid so we'll have it when
1334 or if we start a child debugger. If we are a child, we'll set things up
1335 so we'll have a unique greeting and so the parent will give us our own
1336 TTY later.
1337
1338 We save the current contents of the C<PERLDB_PIDS> environment variable
1339 because we mess around with it. We'll also need to hang onto it because
1340 we'll need it if we restart.
1341
1342 Child debuggers make a label out of the current PID structure recorded in
1343 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1344 yet so the parent will give them one later via C<resetterm()>.
1345
1346 =cut
1347
1348 # Save the current contents of the environment; we're about to
1349 # much with it. We'll need this if we have to restart.
1350 $ini_pids = $ENV{PERLDB_PIDS};
1351
1352 if ( defined $ENV{PERLDB_PIDS} ) {
1353
1354     # We're a child. Make us a label out of the current PID structure
1355     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1356     # a term yet so the parent will give us one later via resetterm().
1357
1358     my $env_pids = $ENV{PERLDB_PIDS};
1359     $pids = "[$env_pids]";
1360
1361     # Unless we are on OpenVMS, all programs under the DCL shell run under
1362     # the same PID.
1363
1364     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1365         $term_pid         = $$;
1366     }
1367     else {
1368         $ENV{PERLDB_PIDS} .= "->$$";
1369         $term_pid = -1;
1370     }
1371
1372 } ## end if (defined $ENV{PERLDB_PIDS...
1373 else {
1374
1375     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1376     # child debugger, and mark us as the parent, so we'll know to set up
1377     # more TTY's is we have to.
1378     $ENV{PERLDB_PIDS} = "$$";
1379     $pids             = "[pid=$$]";
1380     $term_pid         = $$;
1381 }
1382
1383 $pidprompt = '';
1384
1385 # Sets up $emacs as a synonym for $slave_editor.
1386 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1387
1388 =head2 READING THE RC FILE
1389
1390 The debugger will read a file of initialization options if supplied. If
1391 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1392
1393 =cut
1394
1395 # As noted, this test really doesn't check accurately that the debugger
1396 # is running at a terminal or not.
1397
1398 my $dev_tty = '/dev/tty';
1399    $dev_tty = 'TT:' if ($^O eq 'VMS');
1400 if ( -e $dev_tty ) {                      # this is the wrong metric!
1401     $rcfile = ".perldb";
1402 }
1403 else {
1404     $rcfile = "perldb.ini";
1405 }
1406
1407 =pod
1408
1409 The debugger does a safety test of the file to be read. It must be owned
1410 either by the current user or root, and must only be writable by the owner.
1411
1412 =cut
1413
1414 # This wraps a safety test around "do" to read and evaluate the init file.
1415 #
1416 # This isn't really safe, because there's a race
1417 # between checking and opening.  The solution is to
1418 # open and fstat the handle, but then you have to read and
1419 # eval the contents.  But then the silly thing gets
1420 # your lexical scope, which is unfortunate at best.
1421 sub safe_do {
1422     my $file = shift;
1423
1424     # Just exactly what part of the word "CORE::" don't you understand?
1425     local $SIG{__WARN__};
1426     local $SIG{__DIE__};
1427
1428     unless ( is_safe_file($file) ) {
1429         CORE::warn <<EO_GRIPE;
1430 perldb: Must not source insecure rcfile $file.
1431         You or the superuser must be the owner, and it must not
1432         be writable by anyone but its owner.
1433 EO_GRIPE
1434         return;
1435     } ## end unless (is_safe_file($file...
1436
1437     do $file;
1438     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1439 } ## end sub safe_do
1440
1441 # This is the safety test itself.
1442 #
1443 # Verifies that owner is either real user or superuser and that no
1444 # one but owner may write to it.  This function is of limited use
1445 # when called on a path instead of upon a handle, because there are
1446 # no guarantees that filename (by dirent) whose file (by ino) is
1447 # eventually accessed is the same as the one tested.
1448 # Assumes that the file's existence is not in doubt.
1449 sub is_safe_file {
1450     my $path = shift;
1451     stat($path) || return;    # mysteriously vaporized
1452     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1453
1454     return 0 if $uid != 0 && $uid != $<;
1455     return 0 if $mode & 022;
1456     return 1;
1457 } ## end sub is_safe_file
1458
1459 # If the rcfile (whichever one we decided was the right one to read)
1460 # exists, we safely do it.
1461 if ( -f $rcfile ) {
1462     safe_do("./$rcfile");
1463 }
1464
1465 # If there isn't one here, try the user's home directory.
1466 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1467     safe_do("$ENV{HOME}/$rcfile");
1468 }
1469
1470 # Else try the login directory.
1471 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1472     safe_do("$ENV{LOGDIR}/$rcfile");
1473 }
1474
1475 # If the PERLDB_OPTS variable has options in it, parse those out next.
1476 if ( defined $ENV{PERLDB_OPTS} ) {
1477     parse_options( $ENV{PERLDB_OPTS} );
1478 }
1479
1480 =pod
1481
1482 The last thing we do during initialization is determine which subroutine is
1483 to be used to obtain a new terminal when a new debugger is started. Right now,
1484 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1485 (darwin).
1486
1487 =cut
1488
1489 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1490 # Works if you're running an xterm or xterm-like window, or you're on
1491 # OS/2, or on Mac OS X. This may need some expansion.
1492
1493 if (not defined &get_fork_TTY)       # only if no routine exists
1494 {
1495     if ( defined $remoteport ) {
1496                                                  # Expect an inetd-like server
1497         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1498     }
1499     elsif (defined $ENV{TERM}                    # If we know what kind
1500                                                  # of terminal this is,
1501         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1502         and defined $ENV{DISPLAY}                # and what display it's on,
1503       )
1504     {
1505         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1506     }
1507     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1508         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1509     }
1510     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1511             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1512             and $ENV{TERM_PROGRAM}
1513                 eq 'Apple_Terminal'              # Terminal.app
1514             )
1515     {
1516         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1517     }
1518 } ## end if (not defined &get_fork_TTY...
1519
1520 # untaint $^O, which may have been tainted by the last statement.
1521 # see bug [perl #24674]
1522 $^O =~ m/^(.*)\z/;
1523 $^O = $1;
1524
1525 # Here begin the unreadable code.  It needs fixing.
1526
1527 =head2 RESTART PROCESSING
1528
1529 This section handles the restart command. When the C<R> command is invoked, it
1530 tries to capture all of the state it can into environment variables, and
1531 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1532 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1533 the R command stuffed into the environment variables.
1534
1535   PERLDB_RESTART   - flag only, contains no restart data itself.
1536   PERLDB_HIST      - command history, if it's available
1537   PERLDB_ON_LOAD   - breakpoints set by the rc file
1538   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1539   PERLDB_VISITED   - files that had breakpoints
1540   PERLDB_FILE_...  - breakpoints for a file
1541   PERLDB_OPT       - active options
1542   PERLDB_INC       - the original @INC
1543   PERLDB_PRETYPE   - preprompt debugger actions
1544   PERLDB_PRE       - preprompt Perl code
1545   PERLDB_POST      - post-prompt Perl code
1546   PERLDB_TYPEAHEAD - typeahead captured by readline()
1547
1548 We chug through all these variables and plug the values saved in them
1549 back into the appropriate spots in the debugger.
1550
1551 =cut
1552
1553 if ( exists $ENV{PERLDB_RESTART} ) {
1554
1555     # We're restarting, so we don't need the flag that says to restart anymore.
1556     delete $ENV{PERLDB_RESTART};
1557
1558     # $restart = 1;
1559     @hist          = get_list('PERLDB_HIST');
1560     %break_on_load = get_list("PERLDB_ON_LOAD");
1561     %postponed     = get_list("PERLDB_POSTPONE");
1562
1563         share(@hist);
1564         share(@truehist);
1565         share(%break_on_load);
1566         share(%postponed);
1567
1568     # restore breakpoints/actions
1569     my @had_breakpoints = get_list("PERLDB_VISITED");
1570     for ( 0 .. $#had_breakpoints ) {
1571         my %pf = get_list("PERLDB_FILE_$_");
1572         $postponed_file{ $had_breakpoints[$_] } = \%pf if %pf;
1573     }
1574
1575     # restore options
1576     my %opt = get_list("PERLDB_OPT");
1577     my ( $opt, $val );
1578     while ( ( $opt, $val ) = each %opt ) {
1579         $val =~ s/[\\\']/\\$1/g;
1580         parse_options("$opt'$val'");
1581     }
1582
1583     # restore original @INC
1584     @INC     = get_list("PERLDB_INC");
1585     @ini_INC = @INC;
1586
1587     # return pre/postprompt actions and typeahead buffer
1588     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1589     $pre       = [ get_list("PERLDB_PRE") ];
1590     $post      = [ get_list("PERLDB_POST") ];
1591     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1592 } ## end if (exists $ENV{PERLDB_RESTART...
1593
1594 =head2 SETTING UP THE TERMINAL
1595
1596 Now, we'll decide how the debugger is going to interact with the user.
1597 If there's no TTY, we set the debugger to run non-stop; there's not going
1598 to be anyone there to enter commands.
1599
1600 =cut
1601
1602 if ($notty) {
1603     $runnonstop = 1;
1604         share($runnonstop);
1605 }
1606
1607 =pod
1608
1609 If there is a TTY, we have to determine who it belongs to before we can
1610 proceed. If this is a slave editor or graphical debugger (denoted by
1611 the first command-line switch being '-emacs'), we shift this off and
1612 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1613
1614 =cut
1615
1616 else {
1617
1618     # Is Perl being run from a slave editor or graphical debugger?
1619     # If so, don't use readline, and set $slave_editor = 1.
1620     $slave_editor =
1621       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1622     $rl = 0, shift(@main::ARGV) if $slave_editor;
1623
1624     #require Term::ReadLine;
1625
1626 =pod
1627
1628 We then determine what the console should be on various systems:
1629
1630 =over 4
1631
1632 =item * Cygwin - We use C<stdin> instead of a separate device.
1633
1634 =cut
1635
1636     if ( $^O eq 'cygwin' ) {
1637
1638         # /dev/tty is binary. use stdin for textmode
1639         undef $console;
1640     }
1641
1642 =item * Unix - use C</dev/tty>.
1643
1644 =cut
1645
1646     elsif ( -e "/dev/tty" ) {
1647         $console = "/dev/tty";
1648     }
1649
1650 =item * Windows or MSDOS - use C<con>.
1651
1652 =cut
1653
1654     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1655         $console = "con";
1656     }
1657
1658 =item * VMS - use C<sys$command>.
1659
1660 =cut
1661
1662     else {
1663
1664         # everything else is ...
1665         $console = "sys\$command";
1666     }
1667
1668 =pod
1669
1670 =back
1671
1672 Several other systems don't use a specific console. We C<undef $console>
1673 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1674 with a slave editor, Epoc).
1675
1676 =cut
1677
1678     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1679
1680         # /dev/tty is binary. use stdin for textmode
1681         $console = undef;
1682     }
1683
1684     if ( $^O eq 'NetWare' ) {
1685
1686         # /dev/tty is binary. use stdin for textmode
1687         $console = undef;
1688     }
1689
1690     # In OS/2, we need to use STDIN to get textmode too, even though
1691     # it pretty much looks like Unix otherwise.
1692     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1693     {    # In OS/2
1694         $console = undef;
1695     }
1696
1697     # EPOC also falls into the 'got to use STDIN' camp.
1698     if ( $^O eq 'epoc' ) {
1699         $console = undef;
1700     }
1701
1702 =pod
1703
1704 If there is a TTY hanging around from a parent, we use that as the console.
1705
1706 =cut
1707
1708     $console = $tty if defined $tty;
1709
1710 =head2 SOCKET HANDLING
1711
1712 The debugger is capable of opening a socket and carrying out a debugging
1713 session over the socket.
1714
1715 If C<RemotePort> was defined in the options, the debugger assumes that it
1716 should try to start a debugging session on that port. It builds the socket
1717 and then tries to connect the input and output filehandles to it.
1718
1719 =cut
1720
1721     # Handle socket stuff.
1722
1723     if ( defined $remoteport ) {
1724
1725         # If RemotePort was defined in the options, connect input and output
1726         # to the socket.
1727         $IN = $OUT = connect_remoteport();
1728     } ## end if (defined $remoteport)
1729
1730 =pod
1731
1732 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1733 this is probably a situation where multiple debuggers are running (for example,
1734 a backticked command that starts up another debugger). We create a new IN and
1735 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1736 and if we can.
1737
1738 =cut
1739
1740     # Non-socket.
1741     else {
1742
1743         # Two debuggers running (probably a system or a backtick that invokes
1744         # the debugger itself under the running one). create a new IN and OUT
1745         # filehandle, and do the necessary mojo to create a new tty if we
1746         # know how, and we can.
1747         create_IN_OUT(4) if $CreateTTY & 4;
1748         if ($console) {
1749
1750             # If we have a console, check to see if there are separate ins and
1751             # outs to open. (They are assumed identical if not.)
1752
1753             my ( $i, $o ) = split /,/, $console;
1754             $o = $i unless defined $o;
1755
1756             # read/write on in, or just read, or read on STDIN.
1757             open( IN,      "+<$i" )
1758               || open( IN, "<$i" )
1759               || open( IN, "<&STDIN" );
1760
1761             # read/write/create/clobber out, or write/create/clobber out,
1762             # or merge with STDERR, or merge with STDOUT.
1763                  open( OUT, "+>$o" )
1764               || open( OUT, ">$o" )
1765               || open( OUT, ">&STDERR" )
1766               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1767
1768         } ## end if ($console)
1769         elsif ( not defined $console ) {
1770
1771             # No console. Open STDIN.
1772             open( IN, "<&STDIN" );
1773
1774             # merge with STDERR, or with STDOUT.
1775             open( OUT,      ">&STDERR" )
1776               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1777             $console = 'STDIN/OUT';
1778         } ## end elsif (not defined $console)
1779
1780         # Keep copies of the filehandles so that when the pager runs, it
1781         # can close standard input without clobbering ours.
1782         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1783     } ## end elsif (from if(defined $remoteport))
1784
1785     # Unbuffer DB::OUT. We need to see responses right away.
1786     my $previous = select($OUT);
1787     $| = 1;                                  # for DB::OUT
1788     select($previous);
1789
1790     # Line info goes to debugger output unless pointed elsewhere.
1791     # Pointing elsewhere makes it possible for slave editors to
1792     # keep track of file and position. We have both a filehandle
1793     # and a I/O description to keep track of.
1794     $LINEINFO = $OUT     unless defined $LINEINFO;
1795     $lineinfo = $console unless defined $lineinfo;
1796         # share($LINEINFO); # <- unable to share globs
1797         share($lineinfo);   #
1798
1799 =pod
1800
1801 To finish initialization, we show the debugger greeting,
1802 and then call the C<afterinit()> subroutine if there is one.
1803
1804 =cut
1805
1806     # Show the debugger greeting.
1807     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1808     unless ($runnonstop) {
1809         local $\ = '';
1810         local $, = '';
1811         if ( $term_pid eq '-1' ) {
1812             print $OUT "\nDaughter DB session started...\n";
1813         }
1814         else {
1815             print $OUT "\nLoading DB routines from $header\n";
1816             print $OUT (
1817                 "Editor support ",
1818                 $slave_editor ? "enabled" : "available", ".\n"
1819             );
1820             print $OUT
1821 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1822         } ## end else [ if ($term_pid eq '-1')
1823     } ## end unless ($runnonstop)
1824 } ## end else [ if ($notty)
1825
1826 # XXX This looks like a bug to me.
1827 # Why copy to @ARGS and then futz with @args?
1828 @ARGS = @ARGV;
1829 for (@args) {
1830     # Make sure backslashes before single quotes are stripped out, and
1831     # keep args unless they are numeric (XXX why?)
1832     # s/\'/\\\'/g;                      # removed while not justified understandably
1833     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1834 }
1835
1836 # If there was an afterinit() sub defined, call it. It will get
1837 # executed in our scope, so it can fiddle with debugger globals.
1838 if ( defined &afterinit ) {    # May be defined in $rcfile
1839     &afterinit();
1840 }
1841
1842 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1843 $I_m_init = 1;
1844
1845 ############################################################ Subroutines
1846
1847 =head1 SUBROUTINES
1848
1849 =head2 DB
1850
1851 This gigantic subroutine is the heart of the debugger. Called before every
1852 statement, its job is to determine if a breakpoint has been reached, and
1853 stop if so; read commands from the user, parse them, and execute
1854 them, and then send execution off to the next statement.
1855
1856 Note that the order in which the commands are processed is very important;
1857 some commands earlier in the loop will actually alter the C<$cmd> variable
1858 to create other commands to be executed later. This is all highly I<optimized>
1859 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1860 see what's happening in any given command.
1861
1862 =cut
1863
1864 sub DB {
1865
1866     # lock the debugger and get the thread id for the prompt
1867         lock($DBGR);
1868         my $tid;
1869         if ($ENV{PERL5DB_THREADED}) {
1870                 $tid = eval { "[".threads->tid."]" };
1871         }
1872
1873     # Check for whether we should be running continuously or not.
1874     # _After_ the perl program is compiled, $single is set to 1:
1875     if ( $single and not $second_time++ ) {
1876
1877         # Options say run non-stop. Run until we get an interrupt.
1878         if ($runnonstop) {    # Disable until signal
1879                 # If there's any call stack in place, turn off single
1880                 # stepping into subs throughout the stack.
1881             for ( $i = 0 ; $i <= $stack_depth ; ) {
1882                 $stack[ $i++ ] &= ~1;
1883             }
1884
1885             # And we are now no longer in single-step mode.
1886             $single = 0;
1887
1888             # If we simply returned at this point, we wouldn't get
1889             # the trace info. Fall on through.
1890             # return;
1891         } ## end if ($runnonstop)
1892
1893         elsif ($ImmediateStop) {
1894
1895             # We are supposed to stop here; XXX probably a break.
1896             $ImmediateStop = 0;    # We've processed it; turn it off
1897             $signal        = 1;    # Simulate an interrupt to force
1898                                    # us into the command loop
1899         }
1900     } ## end if ($single and not $second_time...
1901
1902     # If we're in single-step mode, or an interrupt (real or fake)
1903     # has occurred, turn off non-stop mode.
1904     $runnonstop = 0 if $single or $signal;
1905
1906     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1907     # The code being debugged may have altered them.
1908     &save;
1909
1910     # Since DB::DB gets called after every line, we can use caller() to
1911     # figure out where we last were executing. Sneaky, eh? This works because
1912     # caller is returning all the extra information when called from the
1913     # debugger.
1914     local ( $package, $filename, $line ) = caller;
1915     local $filename_ini = $filename;
1916
1917     # set up the context for DB::eval, so it can properly execute
1918     # code on behalf of the user. We add the package in so that the
1919     # code is eval'ed in the proper package (not in the debugger!).
1920     local $usercontext =
1921       '($@, $!, $^E, $,, $/, $\, $^W) = @saved;' . "package $package;";
1922
1923     # Create an alias to the active file magical array to simplify
1924     # the code here.
1925     local (*dbline) = $main::{ '_<' . $filename };
1926
1927     # Last line in the program.
1928     local $max = $#dbline;
1929
1930     # if we have something here, see if we should break.
1931     if ( $dbline{$line}
1932         && _is_breakpoint_enabled($filename, $line)
1933         && ( ( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1934     {
1935
1936         # Stop if the stop criterion says to just stop.
1937         if ( $stop eq '1' ) {
1938             $signal |= 1;
1939         }
1940
1941         # It's a conditional stop; eval it in the user's context and
1942         # see if we should stop. If so, remove the one-time sigil.
1943         elsif ($stop) {
1944             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1945             &eval;
1946             $dbline{$line} =~ s/;9($|\0)/$1/;
1947         }
1948     } ## end if ($dbline{$line} && ...
1949
1950     # Preserve the current stop-or-not, and see if any of the W
1951     # (watch expressions) has changed.
1952     my $was_signal = $signal;
1953
1954     # If we have any watch expressions ...
1955     if ( $trace & 2 ) {
1956         for ( my $n = 0 ; $n <= $#to_watch ; $n++ ) {
1957             $evalarg = $to_watch[$n];
1958             local $onetimeDump;    # Tell DB::eval() to not output results
1959
1960             # Fix context DB::eval() wants to return an array, but
1961             # we need a scalar here.
1962             my ($val) = join( "', '", &eval );
1963             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1964
1965             # Did it change?
1966             if ( $val ne $old_watch[$n] ) {
1967
1968                 # Yep! Show the difference, and fake an interrupt.
1969                 $signal = 1;
1970                 print $OUT <<EOP;
1971 Watchpoint $n:\t$to_watch[$n] changed:
1972     old value:\t$old_watch[$n]
1973     new value:\t$val
1974 EOP
1975                 $old_watch[$n] = $val;
1976             } ## end if ($val ne $old_watch...
1977         } ## end for (my $n = 0 ; $n <= ...
1978     } ## end if ($trace & 2)
1979
1980 =head2 C<watchfunction()>
1981
1982 C<watchfunction()> is a function that can be defined by the user; it is a
1983 function which will be run on each entry to C<DB::DB>; it gets the
1984 current package, filename, and line as its parameters.
1985
1986 The watchfunction can do anything it likes; it is executing in the
1987 debugger's context, so it has access to all of the debugger's internal
1988 data structures and functions.
1989
1990 C<watchfunction()> can control the debugger's actions. Any of the following
1991 will cause the debugger to return control to the user's program after
1992 C<watchfunction()> executes:
1993
1994 =over 4
1995
1996 =item *
1997
1998 Returning a false value from the C<watchfunction()> itself.
1999
2000 =item *
2001
2002 Altering C<$single> to a false value.
2003
2004 =item *
2005
2006 Altering C<$signal> to a false value.
2007
2008 =item *
2009
2010 Turning off the C<4> bit in C<$trace> (this also disables the
2011 check for C<watchfunction()>. This can be done with
2012
2013     $trace &= ~4;
2014
2015 =back
2016
2017 =cut
2018
2019     # If there's a user-defined DB::watchfunction, call it with the
2020     # current package, filename, and line. The function executes in
2021     # the DB:: package.
2022     if ( $trace & 4 ) {    # User-installed watch
2023         return
2024           if watchfunction( $package, $filename, $line )
2025           and not $single
2026           and not $was_signal
2027           and not( $trace & ~4 );
2028     } ## end if ($trace & 4)
2029
2030     # Pick up any alteration to $signal in the watchfunction, and
2031     # turn off the signal now.
2032     $was_signal = $signal;
2033     $signal     = 0;
2034
2035 =head2 GETTING READY TO EXECUTE COMMANDS
2036
2037 The debugger decides to take control if single-step mode is on, the
2038 C<t> command was entered, or the user generated a signal. If the program
2039 has fallen off the end, we set things up so that entering further commands
2040 won't cause trouble, and we say that the program is over.
2041
2042 =cut
2043
2044     # Check to see if we should grab control ($single true,
2045     # trace set appropriately, or we got a signal).
2046     if ( $single || ( $trace & 1 ) || $was_signal ) {
2047
2048         # Yes, grab control.
2049         if ($slave_editor) {
2050
2051             # Tell the editor to update its position.
2052             $position = "\032\032$filename:$line:0\n";
2053             print_lineinfo($position);
2054         }
2055
2056 =pod
2057
2058 Special check: if we're in package C<DB::fake>, we've gone through the
2059 C<END> block at least once. We set up everything so that we can continue
2060 to enter commands and have a valid context to be in.
2061
2062 =cut
2063
2064         elsif ( $package eq 'DB::fake' ) {
2065
2066             # Fallen off the end already.
2067             $term || &setterm;
2068             print_help(<<EOP);
2069 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
2070   use B<o> I<inhibit_exit> to avoid stopping after program termination,
2071   B<h q>, B<h R> or B<h o> to get additional info.
2072 EOP
2073
2074             # Set the DB::eval context appropriately.
2075             $package     = 'main';
2076             $usercontext =
2077                 '($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
2078               . "package $package;";    # this won't let them modify, alas
2079         } ## end elsif ($package eq 'DB::fake')
2080
2081 =pod
2082
2083 If the program hasn't finished executing, we scan forward to the
2084 next executable line, print that out, build the prompt from the file and line
2085 number information, and print that.
2086
2087 =cut
2088
2089         else {
2090
2091             # Still somewhere in the midst of execution. Set up the
2092             #  debugger prompt.
2093             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
2094                                  # Perl 5 ones (sorry, we don't print Klingon
2095                                  #module names)
2096
2097             $prefix = $sub =~ /::/ ? "" : "${'package'}::";
2098             $prefix .= "$sub($filename:";
2099             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
2100
2101             # Break up the prompt if it's really long.
2102             if ( length($prefix) > 30 ) {
2103                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
2104                 $prefix   = "";
2105                 $infix    = ":\t";
2106             }
2107             else {
2108                 $infix    = "):\t";
2109                 $position = "$prefix$line$infix$dbline[$line]$after";
2110             }
2111
2112             # Print current line info, indenting if necessary.
2113             if ($frame) {
2114                 print_lineinfo( ' ' x $stack_depth,
2115                     "$line:\t$dbline[$line]$after" );
2116             }
2117             else {
2118                 depth_print_lineinfo($position);
2119             }
2120
2121             # Scan forward, stopping at either the end or the next
2122             # unbreakable line.
2123             for ( $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2124             {    #{ vi
2125
2126                 # Drop out on null statements, block closers, and comments.
2127                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2128
2129                 # Drop out if the user interrupted us.
2130                 last if $signal;
2131
2132                 # Append a newline if the line doesn't have one. Can happen
2133                 # in eval'ed text, for instance.
2134                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2135
2136                 # Next executable line.
2137                 $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2138                 $position .= $incr_pos;
2139                 if ($frame) {
2140
2141                     # Print it indented if tracing is on.
2142                     print_lineinfo( ' ' x $stack_depth,
2143                         "$i:\t$dbline[$i]$after" );
2144                 }
2145                 else {
2146                     depth_print_lineinfo($incr_pos);
2147                 }
2148             } ## end for ($i = $line + 1 ; $i...
2149         } ## end else [ if ($slave_editor)
2150     } ## end if ($single || ($trace...
2151
2152 =pod
2153
2154 If there's an action to be executed for the line we stopped at, execute it.
2155 If there are any preprompt actions, execute those as well.
2156
2157 =cut
2158
2159     # If there's an action, do it now.
2160     $evalarg = $action, &eval if $action;
2161
2162     # Are we nested another level (e.g., did we evaluate a function
2163     # that had a breakpoint in it at the debugger prompt)?
2164     if ( $single || $was_signal ) {
2165
2166         # Yes, go down a level.
2167         local $level = $level + 1;
2168
2169         # Do any pre-prompt actions.
2170         foreach $evalarg (@$pre) {
2171             &eval;
2172         }
2173
2174         # Complain about too much recursion if we passed the limit.
2175         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2176           if $single & 4;
2177
2178         # The line we're currently on. Set $incr to -1 to stay here
2179         # until we get a command that tells us to advance.
2180         $start = $line;
2181         $incr  = -1;      # for backward motion.
2182
2183         # Tack preprompt debugger actions ahead of any actual input.
2184         @typeahead = ( @$pretype, @typeahead );
2185
2186 =head2 WHERE ARE WE?
2187
2188 XXX Relocate this section?
2189
2190 The debugger normally shows the line corresponding to the current line of
2191 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2192 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2193
2194 C<$incr> controls by how many lines the I<current> line should move forward
2195 after a command is executed. If set to -1, this indicates that the I<current>
2196 line shouldn't change.
2197
2198 C<$start> is the I<current> line. It is used for things like knowing where to
2199 move forwards or backwards from when doing an C<L> or C<-> command.
2200
2201 C<$max> tells the debugger where the last line of the current file is. It's
2202 used to terminate loops most often.
2203
2204 =head2 THE COMMAND LOOP
2205
2206 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2207 in two parts:
2208
2209 =over 4
2210
2211 =item *
2212
2213 The outer part of the loop, starting at the C<CMD> label. This loop
2214 reads a command and then executes it.
2215
2216 =item *
2217
2218 The inner part of the loop, starting at the C<PIPE> label. This part
2219 is wholly contained inside the C<CMD> block and only executes a command.
2220 Used to handle commands running inside a pager.
2221
2222 =back
2223
2224 So why have two labels to restart the loop? Because sometimes, it's easier to
2225 have a command I<generate> another command and then re-execute the loop to do
2226 the new command. This is faster, but perhaps a bit more convoluted.
2227
2228 =cut
2229
2230         # The big command dispatch loop. It keeps running until the
2231         # user yields up control again.
2232         #
2233         # If we have a terminal for input, and we get something back
2234         # from readline(), keep on processing.
2235       CMD:
2236         while (
2237
2238             # We have a terminal, or can get one ...
2239             ( $term || &setterm ),
2240
2241             # ... and it belogs to this PID or we get one for this PID ...
2242             ( $term_pid == $$ or resetterm(1) ),
2243
2244             # ... and we got a line of command input ...
2245             defined(
2246                 $cmd = &readline(
2247                         "$pidprompt $tid DB"
2248                       . ( '<' x $level )
2249                       . ( $#hist + 1 )
2250                       . ( '>' x $level ) . " "
2251                 )
2252             )
2253           )
2254         {
2255
2256                         share($cmd);
2257             # ... try to execute the input as debugger commands.
2258
2259             # Don't stop running.
2260             $single = 0;
2261
2262             # No signal is active.
2263             $signal = 0;
2264
2265             # Handle continued commands (ending with \):
2266             $cmd =~ s/\\$/\n/ && do {
2267                 $cmd .= &readline("  cont: ");
2268                 redo CMD;
2269             };
2270
2271 =head4 The null command
2272
2273 A newline entered by itself means I<re-execute the last command>. We grab the
2274 command out of C<$laststep> (where it was recorded previously), and copy it
2275 back into C<$cmd> to be executed below. If there wasn't any previous command,
2276 we'll do nothing below (no command will match). If there was, we also save it
2277 in the command history and fall through to allow the command parsing to pick
2278 it up.
2279
2280 =cut
2281
2282             # Empty input means repeat the last command.
2283             $cmd =~ /^$/ && ( $cmd = $laststep );
2284             chomp($cmd);    # get rid of the annoying extra newline
2285             push( @hist, $cmd ) if length($cmd) > 1;
2286             push( @truehist, $cmd );
2287                         share(@hist);
2288                         share(@truehist);
2289
2290             # This is a restart point for commands that didn't arrive
2291             # via direct user input. It allows us to 'redo PIPE' to
2292             # re-execute command processing without reading a new command.
2293           PIPE: {
2294                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2295                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2296                 ($i) = split( /\s+/, $cmd );
2297
2298 =head3 COMMAND ALIASES
2299
2300 The debugger can create aliases for commands (these are stored in the
2301 C<%alias> hash). Before a command is executed, the command loop looks it up
2302 in the alias hash and substitutes the contents of the alias for the command,
2303 completely replacing it.
2304
2305 =cut
2306
2307                 # See if there's an alias for the command, and set it up if so.
2308                 if ( $alias{$i} ) {
2309
2310                     # Squelch signal handling; we want to keep control here
2311                     # if something goes loco during the alias eval.
2312                     local $SIG{__DIE__};
2313                     local $SIG{__WARN__};
2314
2315                     # This is a command, so we eval it in the DEBUGGER's
2316                     # scope! Otherwise, we can't see the special debugger
2317                     # variables, or get to the debugger's subs. (Well, we
2318                     # _could_, but why make it even more complicated?)
2319                     eval "\$cmd =~ $alias{$i}";
2320                     if ($@) {
2321                         local $\ = '';
2322                         print $OUT "Couldn't evaluate '$i' alias: $@";
2323                         next CMD;
2324                     }
2325                 } ## end if ($alias{$i})
2326
2327 =head3 MAIN-LINE COMMANDS
2328
2329 All of these commands work up to and after the program being debugged has
2330 terminated.
2331
2332 =head4 C<q> - quit
2333
2334 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2335 try to execute further, cleaning any restart-related stuff out of the
2336 environment, and executing with the last value of C<$?>.
2337
2338 =cut
2339
2340                 $cmd =~ /^q$/ && do {
2341                     $fall_off_end = 1;
2342                     clean_ENV();
2343                     exit $?;
2344                 };
2345
2346 =head4 C<t> - trace [n]
2347
2348 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2349 If level is specified, set C<$trace_to_depth>.
2350
2351 =cut
2352
2353                 $cmd =~ /^t(?:\s+(\d+))?$/ && do {
2354                     my $levels = $1;
2355                     $trace ^= 1;
2356                     local $\ = '';
2357                     $trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
2358                     print $OUT "Trace = "
2359                       . ( ( $trace & 1 )
2360                       ? ( $levels ? "on (to level $trace_to_depth)" : "on" )
2361                       : "off" ) . "\n";
2362                     next CMD;
2363                 };
2364
2365 =head4 C<S> - list subroutines matching/not matching a pattern
2366
2367 Walks through C<%sub>, checking to see whether or not to print the name.
2368
2369 =cut
2370
2371                 $cmd =~ /^S(\s+(!)?(.+))?$/ && do {
2372
2373                     $Srev     = defined $2;     # Reverse scan?
2374                     $Spatt    = $3;             # The pattern (if any) to use.
2375                     $Snocheck = !defined $1;    # No args - print all subs.
2376
2377                     # Need to make these sane here.
2378                     local $\ = '';
2379                     local $, = '';
2380
2381                     # Search through the debugger's magical hash of subs.
2382                     # If $nocheck is true, just print the sub name.
2383                     # Otherwise, check it against the pattern. We then use
2384                     # the XOR trick to reverse the condition as required.
2385                     foreach $subname ( sort( keys %sub ) ) {
2386                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2387                             print $OUT $subname, "\n";
2388                         }
2389                     }
2390                     next CMD;
2391                 };
2392
2393 =head4 C<X> - list variables in current package
2394
2395 Since the C<V> command actually processes this, just change this to the
2396 appropriate C<V> command and fall through.
2397
2398 =cut
2399
2400                 $cmd =~ s/^X\b/V $package/;
2401
2402 =head4 C<V> - list variables
2403
2404 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2405
2406 =cut
2407
2408                 # Bare V commands get the currently-being-debugged package
2409                 # added.
2410                 $cmd =~ /^V$/ && do {
2411                     $cmd = "V $package";
2412                 };
2413
2414                 # V - show variables in package.
2415                 $cmd =~ /^V\b\s*(\S+)\s*(.*)/ && do {
2416
2417                     # Save the currently selected filehandle and
2418                     # force output to debugger's filehandle (dumpvar
2419                     # just does "print" for output).
2420                     local ($savout) = select($OUT);
2421
2422                     # Grab package name and variables to dump.
2423                     $packname = $1;
2424                     @vars     = split( ' ', $2 );
2425
2426                     # If main::dumpvar isn't here, get it.
2427                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2428                     if ( defined &main::dumpvar ) {
2429
2430                         # We got it. Turn off subroutine entry/exit messages
2431                         # for the moment, along with return values.
2432                         local $frame = 0;
2433                         local $doret = -2;
2434
2435                         # must detect sigpipe failures  - not catching
2436                         # then will cause the debugger to die.
2437                         eval {
2438                             &main::dumpvar(
2439                                 $packname,
2440                                 defined $option{dumpDepth}
2441                                 ? $option{dumpDepth}
2442                                 : -1,    # assume -1 unless specified
2443                                 @vars
2444                             );
2445                         };
2446
2447                         # The die doesn't need to include the $@, because
2448                         # it will automatically get propagated for us.
2449                         if ($@) {
2450                             die unless $@ =~ /dumpvar print failed/;
2451                         }
2452                     } ## end if (defined &main::dumpvar)
2453                     else {
2454
2455                         # Couldn't load dumpvar.
2456                         print $OUT "dumpvar.pl not available.\n";
2457                     }
2458
2459                     # Restore the output filehandle, and go round again.
2460                     select($savout);
2461                     next CMD;
2462                 };
2463
2464 =head4 C<x> - evaluate and print an expression
2465
2466 Hands the expression off to C<DB::eval>, setting it up to print the value
2467 via C<dumpvar.pl> instead of just printing it directly.
2468
2469 =cut
2470
2471                 $cmd =~ s/^x\b/ / && do {    # Remainder gets done by DB::eval()
2472                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2473
2474                     # handle special  "x 3 blah" syntax XXX propagate
2475                     # doc back to special variables.
2476                     if ( $cmd =~ s/^\s*(\d+)(?=\s)/ / ) {
2477                         $onetimedumpDepth = $1;
2478                     }
2479                 };
2480
2481 =head4 C<m> - print methods
2482
2483 Just uses C<DB::methods> to determine what methods are available.
2484
2485 =cut
2486
2487                 $cmd =~ s/^m\s+([\w:]+)\s*$/ / && do {
2488                     methods($1);
2489                     next CMD;
2490                 };
2491
2492                 # m expr - set up DB::eval to do the work
2493                 $cmd =~ s/^m\b/ / && do {    # Rest gets done by DB::eval()
2494                     $onetimeDump = 'methods';   #  method output gets used there
2495                 };
2496
2497 =head4 C<f> - switch files
2498
2499 =cut
2500
2501                 $cmd =~ /^f\b\s*(.*)/ && do {
2502                     $file = $1;
2503                     $file =~ s/\s+$//;
2504
2505                     # help for no arguments (old-style was return from sub).
2506                     if ( !$file ) {
2507                         print $OUT
2508                           "The old f command is now the r command.\n";    # hint
2509                         print $OUT "The new f command switches filenames.\n";
2510                         next CMD;
2511                     } ## end if (!$file)
2512
2513                     # if not in magic file list, try a close match.
2514                     if ( !defined $main::{ '_<' . $file } ) {
2515                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2516                             {
2517                                 $try = substr( $try, 2 );
2518                                 print $OUT "Choosing $try matching '$file':\n";
2519                                 $file = $try;
2520                             }
2521                         } ## end if (($try) = grep(m#^_<.*$file#...
2522                     } ## end if (!defined $main::{ ...
2523
2524                     # If not successfully switched now, we failed.
2525                     if ( !defined $main::{ '_<' . $file } ) {
2526                         print $OUT "No file matching '$file' is loaded.\n";
2527                         next CMD;
2528                     }
2529
2530                     # We switched, so switch the debugger internals around.
2531                     elsif ( $file ne $filename ) {
2532                         *dbline   = $main::{ '_<' . $file };
2533                         $max      = $#dbline;
2534                         $filename = $file;
2535                         $start    = 1;
2536                         $cmd      = "l";
2537                     } ## end elsif ($file ne $filename)
2538
2539                     # We didn't switch; say we didn't.
2540                     else {
2541                         print $OUT "Already in $file.\n";
2542                         next CMD;
2543                     }
2544                 };
2545
2546 =head4 C<.> - return to last-executed line.
2547
2548 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2549 and then we look up the line in the magical C<%dbline> hash.
2550
2551 =cut
2552
2553                 # . command.
2554                 $cmd =~ /^\.$/ && do {
2555                     $incr = -1;    # stay at current line
2556
2557                     # Reset everything to the old location.
2558                     $start    = $line;
2559                     $filename = $filename_ini;
2560                     *dbline   = $main::{ '_<' . $filename };
2561                     $max      = $#dbline;
2562
2563                     # Now where are we?
2564                     print_lineinfo($position);
2565                     next CMD;
2566                 };
2567
2568 =head4 C<-> - back one window
2569
2570 We change C<$start> to be one window back; if we go back past the first line,
2571 we set it to be the first line. We ser C<$incr> to put us back at the
2572 currently-executing line, and then put a C<l $start +> (list one window from
2573 C<$start>) in C<$cmd> to be executed later.
2574
2575 =cut
2576
2577                 # - - back a window.
2578                 $cmd =~ /^-$/ && do {
2579
2580                     # back up by a window; go to 1 if back too far.
2581                     $start -= $incr + $window + 1;
2582                     $start = 1 if $start <= 0;
2583                     $incr  = $window - 1;
2584
2585                     # Generate and execute a "l +" command (handled below).
2586                     $cmd = 'l ' . ($start) . '+';
2587                 };
2588
2589 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2590
2591 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2592 problems, most notably that the default case of several commands destroying
2593 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2594 retain the old commands for those who were used to using them or who preferred
2595 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2596 deal with them instead of processing them in-line.
2597
2598 =cut
2599
2600                 # All of these commands were remapped in perl 5.8.0;
2601                 # we send them off to the secondary dispatcher (see below).
2602                 $cmd =~ /^([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so && do {
2603                     &cmd_wrapper( $1, $2, $line );
2604                     next CMD;
2605                 };
2606
2607 =head4 C<y> - List lexicals in higher scope
2608
2609 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2610 above the current one and then displays then using C<dumpvar.pl>.
2611
2612 =cut
2613
2614                 $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/ && do {
2615
2616                     # See if we've got the necessary support.
2617                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2618                       or &warn(
2619                         $@ =~ /locate/
2620                         ? "PadWalker module not found - please install\n"
2621                         : $@
2622                       )
2623                       and next CMD;
2624
2625                     # Load up dumpvar if we don't have it. If we can, that is.
2626                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2627                     defined &main::dumpvar
2628                       or print $OUT "dumpvar.pl not available.\n"
2629                       and next CMD;
2630
2631                     # Got all the modules we need. Find them and print them.
2632                     my @vars = split( ' ', $2 || '' );
2633
2634                     # Find the pad.
2635                     my $h = eval { PadWalker::peek_my( ( $1 || 0 ) + 1 ) };
2636
2637                     # Oops. Can't find it.
2638                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2639
2640                     # Show the desired vars with dumplex().
2641                     my $savout = select($OUT);
2642
2643                     # Have dumplex dump the lexicals.
2644                     dumpvar::dumplex( $_, $h->{$_},
2645                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2646                         @vars )
2647                       for sort keys %$h;
2648                     select($savout);
2649                     next CMD;
2650                 };
2651
2652 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2653
2654 All of the commands below this point don't work after the program being
2655 debugged has ended. All of them check to see if the program has ended; this
2656 allows the commands to be relocated without worrying about a 'line of
2657 demarcation' above which commands can be entered anytime, and below which
2658 they can't.
2659
2660 =head4 C<n> - single step, but don't trace down into subs
2661
2662 Done by setting C<$single> to 2, which forces subs to execute straight through
2663 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2664 so a null command knows what to re-execute.
2665
2666 =cut
2667
2668                 # n - next
2669                 $cmd =~ /^n$/ && do {
2670                     end_report(), next CMD if $finished and $level <= 1;
2671
2672                     # Single step, but don't enter subs.
2673                     $single = 2;
2674
2675                     # Save for empty command (repeat last).
2676                     $laststep = $cmd;
2677                     last CMD;
2678                 };
2679
2680 =head4 C<s> - single-step, entering subs
2681
2682 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2683 subs. Also saves C<s> as C<$lastcmd>.
2684
2685 =cut
2686
2687                 # s - single step.
2688                 $cmd =~ /^s$/ && do {
2689
2690                     # Get out and restart the command loop if program
2691                     # has finished.
2692                     end_report(), next CMD if $finished and $level <= 1;
2693
2694                     # Single step should enter subs.
2695                     $single = 1;
2696
2697                     # Save for empty command (repeat last).
2698                     $laststep = $cmd;
2699                     last CMD;
2700                 };
2701
2702 =head4 C<c> - run continuously, setting an optional breakpoint
2703
2704 Most of the code for this command is taken up with locating the optional
2705 breakpoint, which is either a subroutine name or a line number. We set
2706 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2707 in this and all call levels above this one.
2708
2709 =cut
2710
2711                 # c - start continuous execution.
2712                 $cmd =~ /^c\b\s*([\w:]*)\s*$/ && do {
2713
2714                     # Hey, show's over. The debugged program finished
2715                     # executing already.
2716                     end_report(), next CMD if $finished and $level <= 1;
2717
2718                     # Capture the place to put a one-time break.
2719                     $subname = $i = $1;
2720
2721                     #  Probably not needed, since we finish an interactive
2722                     #  sub-session anyway...
2723                     # local $filename = $filename;
2724                     # local *dbline = *dbline; # XXX Would this work?!
2725                     #
2726                     # The above question wonders if localizing the alias
2727                     # to the magic array works or not. Since it's commented
2728                     # out, we'll just leave that to speculation for now.
2729
2730                     # If the "subname" isn't all digits, we'll assume it
2731                     # is a subroutine name, and try to find it.
2732                     if ( $subname =~ /\D/ ) {    # subroutine name
2733                             # Qualify it to the current package unless it's
2734                             # already qualified.
2735                         $subname = $package . "::" . $subname
2736                           unless $subname =~ /::/;
2737
2738                         # find_sub will return "file:line_number" corresponding
2739                         # to where the subroutine is defined; we call find_sub,
2740                         # break up the return value, and assign it in one
2741                         # operation.
2742                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2743
2744                         # Force the line number to be numeric.
2745                         $i += 0;
2746
2747                         # If we got a line number, we found the sub.
2748                         if ($i) {
2749
2750                             # Switch all the debugger's internals around so
2751                             # we're actually working with that file.
2752                             $filename = $file;
2753                             *dbline   = $main::{ '_<' . $filename };
2754
2755                             # Mark that there's a breakpoint in this file.
2756                             $had_breakpoints{$filename} |= 1;
2757
2758                             # Scan forward to the first executable line
2759                             # after the 'sub whatever' line.
2760                             $max = $#dbline;
2761                             ++$i while $dbline[$i] == 0 && $i < $max;
2762                         } ## end if ($i)
2763
2764                         # We didn't find a sub by that name.
2765                         else {
2766                             print $OUT "Subroutine $subname not found.\n";
2767                             next CMD;
2768                         }
2769                     } ## end if ($subname =~ /\D/)
2770
2771                     # At this point, either the subname was all digits (an
2772                     # absolute line-break request) or we've scanned through
2773                     # the code following the definition of the sub, looking
2774                     # for an executable, which we may or may not have found.
2775                     #
2776                     # If $i (which we set $subname from) is non-zero, we
2777                     # got a request to break at some line somewhere. On
2778                     # one hand, if there wasn't any real subroutine name
2779                     # involved, this will be a request to break in the current
2780                     # file at the specified line, so we have to check to make
2781                     # sure that the line specified really is breakable.
2782                     #
2783                     # On the other hand, if there was a subname supplied, the
2784                     # preceding block has moved us to the proper file and
2785                     # location within that file, and then scanned forward
2786                     # looking for the next executable line. We have to make
2787                     # sure that one was found.
2788                     #
2789                     # On the gripping hand, we can't do anything unless the
2790                     # current value of $i points to a valid breakable line.
2791                     # Check that.
2792                     if ($i) {
2793
2794                         # Breakable?
2795                         if ( $dbline[$i] == 0 ) {
2796                             print $OUT "Line $i not breakable.\n";
2797                             next CMD;
2798                         }
2799
2800                         # Yes. Set up the one-time-break sigil.
2801                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2802                     } ## end if ($i)
2803
2804                     # Turn off stack tracing from here up.
2805                     for ( $i = 0 ; $i <= $stack_depth ; ) {
2806                         $stack[ $i++ ] &= ~1;
2807                     }
2808                     last CMD;
2809                 };
2810
2811 =head4 C<r> - return from a subroutine
2812
2813 For C<r> to work properly, the debugger has to stop execution again
2814 immediately after the return is executed. This is done by forcing
2815 single-stepping to be on in the call level above the current one. If
2816 we are printing return values when a C<r> is executed, set C<$doret>
2817 appropriately, and force us out of the command loop.
2818
2819 =cut
2820
2821                 # r - return from the current subroutine.
2822                 $cmd =~ /^r$/ && do {
2823
2824                     # Can't do anything if the program's over.
2825                     end_report(), next CMD if $finished and $level <= 1;
2826
2827                     # Turn on stack trace.
2828                     $stack[$stack_depth] |= 1;
2829
2830                     # Print return value unless the stack is empty.
2831                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2832                     last CMD;
2833                 };
2834
2835 =head4 C<T> - stack trace
2836
2837 Just calls C<DB::print_trace>.
2838
2839 =cut
2840
2841                 $cmd =~ /^T$/ && do {
2842                     print_trace( $OUT, 1 );    # skip DB
2843                     next CMD;
2844                 };
2845
2846 =head4 C<w> - List window around current line.
2847
2848 Just calls C<DB::cmd_w>.
2849
2850 =cut
2851
2852                 $cmd =~ /^w\b\s*(.*)/s && do { &cmd_w( 'w', $1 ); next CMD; };
2853
2854 =head4 C<W> - watch-expression processing.
2855
2856 Just calls C<DB::cmd_W>.
2857
2858 =cut
2859
2860                 $cmd =~ /^W\b\s*(.*)/s && do { &cmd_W( 'W', $1 ); next CMD; };
2861
2862 =head4 C</> - search forward for a string in the source
2863
2864 We take the argument and treat it as a pattern. If it turns out to be a
2865 bad one, we return the error we got from trying to C<eval> it and exit.
2866 If not, we create some code to do the search and C<eval> it so it can't
2867 mess us up.
2868
2869 =cut
2870
2871                 $cmd =~ /^\/(.*)$/ && do {
2872
2873                     # The pattern as a string.
2874                     $inpat = $1;
2875
2876                     # Remove the final slash.
2877                     $inpat =~ s:([^\\])/$:$1:;
2878
2879                     # If the pattern isn't null ...
2880                     if ( $inpat ne "" ) {
2881
2882                         # Turn of warn and die procesing for a bit.
2883                         local $SIG{__DIE__};
2884                         local $SIG{__WARN__};
2885
2886                         # Create the pattern.
2887                         eval '$inpat =~ m' . "\a$inpat\a";
2888                         if ( $@ ne "" ) {
2889
2890                             # Oops. Bad pattern. No biscuit.
2891                             # Print the eval error and go back for more
2892                             # commands.
2893                             print $OUT "$@";
2894                             next CMD;
2895                         }
2896                         $pat = $inpat;
2897                     } ## end if ($inpat ne "")
2898
2899                     # Set up to stop on wrap-around.
2900                     $end = $start;
2901
2902                     # Don't move off the current line.
2903                     $incr = -1;
2904
2905                     # Done in eval so nothing breaks if the pattern
2906                     # does something weird.
2907                     eval '
2908                         for (;;) {
2909                             # Move ahead one line.
2910                             ++$start;
2911
2912                             # Wrap if we pass the last line.
2913                             $start = 1 if ($start > $max);
2914
2915                             # Stop if we have gotten back to this line again,
2916                             last if ($start == $end);
2917
2918                             # A hit! (Note, though, that we are doing
2919                             # case-insensitive matching. Maybe a qr//
2920                             # expression would be better, so the user could
2921                             # do case-sensitive matching if desired.
2922                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2923                                 if ($slave_editor) {
2924                                     # Handle proper escaping in the slave.
2925                                     print $OUT "\032\032$filename:$start:0\n";
2926                                 }
2927                                 else {
2928                                     # Just print the line normally.
2929                                     print $OUT "$start:\t",$dbline[$start],"\n";
2930                                 }
2931                                 # And quit since we found something.
2932                                 last;
2933                             }
2934                          } ';
2935
2936                     # If we wrapped, there never was a match.
2937                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2938                     next CMD;
2939                 };
2940
2941 =head4 C<?> - search backward for a string in the source
2942
2943 Same as for C</>, except the loop runs backwards.
2944
2945 =cut
2946
2947                 # ? - backward pattern search.
2948                 $cmd =~ /^\?(.*)$/ && do {
2949
2950                     # Get the pattern, remove trailing question mark.
2951                     $inpat = $1;
2952                     $inpat =~ s:([^\\])\?$:$1:;
2953
2954                     # If we've got one ...
2955                     if ( $inpat ne "" ) {
2956
2957                         # Turn off die & warn handlers.
2958                         local $SIG{__DIE__};
2959                         local $SIG{__WARN__};
2960                         eval '$inpat =~ m' . "\a$inpat\a";
2961
2962                         if ( $@ ne "" ) {
2963
2964                             # Ouch. Not good. Print the error.
2965                             print $OUT $@;
2966                             next CMD;
2967                         }
2968                         $pat = $inpat;
2969                     } ## end if ($inpat ne "")
2970
2971                     # Where we are now is where to stop after wraparound.
2972                     $end = $start;
2973
2974                     # Don't move away from this line.
2975                     $incr = -1;
2976
2977                     # Search inside the eval to prevent pattern badness
2978                     # from killing us.
2979                     eval '
2980                         for (;;) {
2981                             # Back up a line.
2982                             --$start;
2983
2984                             # Wrap if we pass the first line.
2985
2986                             $start = $max if ($start <= 0);
2987
2988                             # Quit if we get back where we started,
2989                             last if ($start == $end);
2990
2991                             # Match?
2992                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2993                                 if ($slave_editor) {
2994                                     # Yep, follow slave editor requirements.
2995                                     print $OUT "\032\032$filename:$start:0\n";
2996                                 }
2997                                 else {
2998                                     # Yep, just print normally.
2999                                     print $OUT "$start:\t",$dbline[$start],"\n";
3000                                 }
3001
3002                                 # Found, so done.
3003                                 last;
3004                             }
3005                         } ';
3006
3007                     # Say we failed if the loop never found anything,
3008                     print $OUT "?$pat?: not found\n" if ( $start == $end );
3009                     next CMD;
3010                 };
3011
3012 =head4 C<$rc> - Recall command
3013
3014 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
3015 that the terminal supports history). It find the the command required, puts it
3016 into C<$cmd>, and redoes the loop to execute it.
3017
3018 =cut
3019
3020                 # $rc - recall command.
3021                 $cmd =~ /^$rc+\s*(-)?(\d+)?$/ && do {
3022
3023                     # No arguments, take one thing off history.
3024                     pop(@hist) if length($cmd) > 1;
3025
3026                     # Relative (- found)?
3027                     #  Y - index back from most recent (by 1 if bare minus)
3028                     #  N - go to that particular command slot or the last
3029                     #      thing if nothing following.
3030                     $i = $1 ? ( $#hist - ( $2 || 1 ) ) : ( $2 || $#hist );
3031
3032                     # Pick out the command desired.
3033                     $cmd = $hist[$i];
3034
3035                     # Print the command to be executed and restart the loop
3036                     # with that command in the buffer.
3037                     print $OUT $cmd, "\n";
3038                     redo CMD;
3039                 };
3040
3041 =head4 C<$sh$sh> - C<system()> command
3042
3043 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
3044 C<STDOUT> from getting messed up.
3045
3046 =cut
3047
3048                 # $sh$sh - run a shell command (if it's all ASCII).
3049                 # Can't run shell commands with Unicode in the debugger, hmm.
3050                 $cmd =~ /^$sh$sh\s*([\x00-\xff]*)/ && do {
3051
3052                     # System it.
3053                     &system($1);
3054                     next CMD;
3055                 };
3056
3057 =head4 C<$rc I<pattern> $rc> - Search command history
3058
3059 Another command to manipulate C<@hist>: this one searches it with a pattern.
3060 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
3061
3062 =cut
3063
3064                 # $rc pattern $rc - find a command in the history.
3065                 $cmd =~ /^$rc([^$rc].*)$/ && do {
3066
3067                     # Create the pattern to use.
3068                     $pat = "^$1";
3069
3070                     # Toss off last entry if length is >1 (and it always is).
3071                     pop(@hist) if length($cmd) > 1;
3072
3073                     # Look backward through the history.
3074                     for ( $i = $#hist ; $i ; --$i ) {
3075
3076                         # Stop if we find it.
3077                         last if $hist[$i] =~ /$pat/;
3078                     }
3079
3080                     if ( !$i ) {
3081
3082                         # Never found it.
3083                         print $OUT "No such command!\n\n";
3084                         next CMD;
3085                     }
3086
3087                     # Found it. Put it in the buffer, print it, and process it.
3088                     $cmd = $hist[$i];
3089                     print $OUT $cmd, "\n";
3090                     redo CMD;
3091                 };
3092
3093 =head4 C<$sh> - Invoke a shell
3094
3095 Uses C<DB::system> to invoke a shell.
3096
3097 =cut
3098
3099                 # $sh - start a shell.
3100                 $cmd =~ /^$sh$/ && do {
3101
3102                     # Run the user's shell. If none defined, run Bourne.
3103                     # We resume execution when the shell terminates.
3104                     &system( $ENV{SHELL} || "/bin/sh" );
3105                     next CMD;
3106                 };
3107
3108 =head4 C<$sh I<command>> - Force execution of a command in a shell
3109
3110 Like the above, but the command is passed to the shell. Again, we use
3111 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3112
3113 =cut
3114
3115                 # $sh command - start a shell and run a command in it.
3116                 $cmd =~ /^$sh\s*([\x00-\xff]*)/ && do {
3117
3118                     # XXX: using csh or tcsh destroys sigint retvals!
3119                     #&system($1);  # use this instead
3120
3121                     # use the user's shell, or Bourne if none defined.
3122                     &system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3123                     next CMD;
3124                 };
3125
3126 =head4 C<H> - display commands in history
3127
3128 Prints the contents of C<@hist> (if any).
3129
3130 =cut
3131
3132                 $cmd =~ /^H\b\s*\*/ && do {
3133                     @hist = @truehist = ();
3134                     print $OUT "History cleansed\n";
3135                     next CMD;
3136                 };
3137
3138                 $cmd =~ /^H\b\s*(-(\d+))?/ && do {
3139
3140                     # Anything other than negative numbers is ignored by
3141                     # the (incorrect) pattern, so this test does nothing.
3142                     $end = $2 ? ( $#hist - $2 ) : 0;
3143
3144                     # Set to the minimum if less than zero.
3145                     $hist = 0 if $hist < 0;
3146
3147                     # Start at the end of the array.
3148                     # Stay in while we're still above the ending value.
3149                     # Tick back by one each time around the loop.
3150                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3151
3152                         # Print the command  unless it has no arguments.
3153                         print $OUT "$i: ", $hist[$i], "\n"
3154                           unless $hist[$i] =~ /^.?$/;
3155                     }
3156                     next CMD;
3157                 };
3158
3159 =head4 C<man, doc, perldoc> - look up documentation
3160
3161 Just calls C<runman()> to print the appropriate document.
3162
3163 =cut
3164
3165                 # man, perldoc, doc - show manual pages.
3166                 $cmd =~ /^(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?$/ && do {
3167                     runman($1);
3168                     next CMD;
3169                 };
3170
3171 =head4 C<p> - print
3172
3173 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3174 the bottom of the loop.
3175
3176 =cut
3177
3178                 # p - print (no args): print $_.
3179                 $cmd =~ s/^p$/print {\$DB::OUT} \$_/;
3180
3181                 # p - print the given expression.
3182                 $cmd =~ s/^p\b/print {\$DB::OUT} /;
3183
3184 =head4 C<=> - define command alias
3185
3186 Manipulates C<%alias> to add or list command aliases.
3187
3188 =cut
3189
3190                 # = - set up a command alias.
3191                 $cmd =~ s/^=\s*// && do {
3192                     my @keys;
3193                     if ( length $cmd == 0 ) {
3194
3195                         # No args, get current aliases.
3196                         @keys = sort keys %alias;
3197                     }
3198                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3199
3200                         # Creating a new alias. $k is alias name, $v is
3201                         # alias value.
3202
3203                         # can't use $_ or kill //g state
3204                         for my $x ( $k, $v ) {
3205
3206                             # Escape "alarm" characters.
3207                             $x =~ s/\a/\\a/g;
3208                         }
3209
3210                         # Substitute key for value, using alarm chars
3211                         # as separators (which is why we escaped them in
3212                         # the command).
3213                         $alias{$k} = "s\a$k\a$v\a";
3214
3215                         # Turn off standard warn and die behavior.
3216                         local $SIG{__DIE__};
3217                         local $SIG{__WARN__};
3218
3219                         # Is it valid Perl?
3220                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3221
3222                             # Nope. Bad alias. Say so and get out.
3223                             print $OUT "Can't alias $k to $v: $@\n";
3224                             delete $alias{$k};
3225                             next CMD;
3226                         }
3227
3228                         # We'll only list the new one.
3229                         @keys = ($k);
3230                     } ## end elsif (my ($k, $v) = ($cmd...
3231
3232                     # The argument is the alias to list.
3233                     else {
3234                         @keys = ($cmd);
3235                     }
3236
3237                     # List aliases.
3238                     for my $k (@keys) {
3239
3240                         # Messy metaquoting: Trim the substitution code off.
3241                         # We use control-G as the delimiter because it's not
3242                         # likely to appear in the alias.
3243                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3244
3245                             # Print the alias.
3246                             print $OUT "$k\t= $1\n";
3247                         }
3248                         elsif ( defined $alias{$k} ) {
3249
3250                             # Couldn't trim it off; just print the alias code.
3251                             print $OUT "$k\t$alias{$k}\n";
3252                         }
3253                         else {
3254
3255                             # No such, dude.
3256                             print "No alias for $k\n";
3257                         }
3258                     } ## end for my $k (@keys)
3259                     next CMD;
3260                 };
3261
3262 =head4 C<source> - read commands from a file.
3263
3264 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3265 pick it up.
3266
3267 =cut
3268
3269                 # source - read commands from a file (or pipe!) and execute.
3270                 $cmd =~ /^source\s+(.*\S)/ && do {
3271                     if ( open my $fh, $1 ) {
3272
3273                         # Opened OK; stick it in the list of file handles.
3274                         push @cmdfhs, $fh;
3275                     }
3276                     else {
3277
3278                         # Couldn't open it.
3279                         &warn("Can't execute '$1': $!\n");
3280                     }
3281                     next CMD;
3282                 };
3283
3284                 $cmd =~ /^(enable|disable)\s+(\S+)\s*$/ && do {
3285                     my ($cmd, $position) = ($1, $2);
3286
3287                     my ($fn, $line_num);
3288                     if ($position =~ m{\A\d+\z})
3289                     {
3290                         $fn = $filename;
3291                         $line_num = $position;
3292                     }
3293                     elsif ($position =~ m{\A(.*):(\d+)\z})
3294                     {
3295                         ($fn, $line_num) = ($1, $2);
3296                     }
3297                     else
3298                     {
3299                         &warn("Wrong spec for enable/disable argument.\n");
3300                     }
3301
3302                     if (defined($fn)) {
3303                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3304                             _set_breakpoint_enabled_status($fn, $line_num,
3305                                 ($cmd eq 'enable' ? 1 : '')
3306                             );
3307                         }
3308                         else {
3309                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3310                         }
3311                     }
3312
3313                     next CMD;
3314                 };
3315
3316 =head4 C<save> - send current history to a file
3317
3318 Takes the complete history, (not the shrunken version you see with C<H>),
3319 and saves it to the given filename, so it can be replayed using C<source>.
3320
3321 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3322
3323 =cut
3324
3325                 # save source - write commands to a file for later use
3326                 $cmd =~ /^save\s*(.*)$/ && do {
3327                     my $file = $1 || '.perl5dbrc';    # default?
3328                     if ( open my $fh, "> $file" ) {
3329
3330                        # chomp to remove extraneous newlines from source'd files
3331                         chomp( my @truelist =
3332                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3333                               @truehist );
3334                         print $fh join( "\n", @truelist );
3335                         print "commands saved in $file\n";
3336                     }
3337                     else {
3338                         &warn("Can't save debugger commands in '$1': $!\n");
3339                     }
3340                     next CMD;
3341                 };
3342
3343 =head4 C<R> - restart
3344
3345 Restart the debugger session.
3346
3347 =head4 C<rerun> - rerun the current session
3348
3349 Return to any given position in the B<true>-history list
3350
3351 =cut
3352
3353                 # R - restart execution.
3354                 # rerun - controlled restart execution.
3355                 $cmd =~ /^(R|rerun\s*(.*))$/ && do {
3356                     my @args = ($1 eq 'R' ? restart() : rerun($2));
3357
3358                     # Close all non-system fds for a clean restart.  A more
3359                     # correct method would be to close all fds that were not
3360                     # open when the process started, but this seems to be
3361                     # hard.  See "debugger 'R'estart and open database
3362                     # connections" on p5p.
3363
3364                     my $max_fd = 1024; # default if POSIX can't be loaded
3365                     if (eval { require POSIX }) {
3366                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3367                     }
3368
3369                     if (defined $max_fd) {
3370                         foreach ($^F+1 .. $max_fd-1) {
3371                             next unless open FD_TO_CLOSE, "<&=$_";
3372                             close(FD_TO_CLOSE);
3373                         }
3374                     }
3375
3376                     # And run Perl again.  We use exec() to keep the
3377                     # PID stable (and that way $ini_pids is still valid).
3378                     exec(@args) || print $OUT "exec failed: $!\n";
3379
3380                     last CMD;
3381                 };
3382
3383 =head4 C<|, ||> - pipe output through the pager.
3384
3385 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3386 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3387 pipe to the pager (restoring the output filehandles if this fails). If this
3388 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3389 set C<$signal>, sending us back into the debugger.
3390
3391 We then trim off the pipe symbols and C<redo> the command loop at the
3392 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3393 reading another.
3394
3395 =cut
3396
3397                 # || - run command in the pager, with output to DB::OUT.
3398                 $cmd =~ /^\|\|?\s*[^|]/ && do {
3399                     if ( $pager =~ /^\|/ ) {
3400
3401                         # Default pager is into a pipe. Redirect I/O.
3402                         open( SAVEOUT, ">&STDOUT" )
3403                           || &warn("Can't save STDOUT");
3404                         open( STDOUT, ">&OUT" )
3405                           || &warn("Can't redirect STDOUT");
3406                     } ## end if ($pager =~ /^\|/)
3407                     else {
3408
3409                         # Not into a pipe. STDOUT is safe.
3410                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3411                     }
3412
3413                     # Fix up environment to record we have less if so.
3414                     fix_less();
3415
3416                     unless ( $piped = open( OUT, $pager ) ) {
3417
3418                         # Couldn't open pipe to pager.
3419                         &warn("Can't pipe output to '$pager'");
3420                         if ( $pager =~ /^\|/ ) {
3421
3422                             # Redirect I/O back again.
3423                             open( OUT, ">&STDOUT" )    # XXX: lost message
3424                               || &warn("Can't restore DB::OUT");
3425                             open( STDOUT, ">&SAVEOUT" )
3426                               || &warn("Can't restore STDOUT");
3427                             close(SAVEOUT);
3428                         } ## end if ($pager =~ /^\|/)
3429                         else {
3430
3431                             # Redirect I/O. STDOUT already safe.
3432                             open( OUT, ">&STDOUT" )    # XXX: lost message
3433                               || &warn("Can't restore DB::OUT");
3434                         }
3435                         next CMD;
3436                     } ## end unless ($piped = open(OUT,...
3437
3438                     # Set up broken-pipe handler if necessary.
3439                     $SIG{PIPE} = \&DB::catch
3440                       if $pager =~ /^\|/
3441                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3442
3443                     # Save current filehandle, unbuffer out, and put it back.
3444                     $selected = select(OUT);
3445                     $|        = 1;
3446
3447                     # Don't put it back if pager was a pipe.
3448                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3449
3450                     # Trim off the pipe symbols and run the command now.
3451                     $cmd =~ s/^\|+\s*//;
3452                     redo PIPE;
3453                 };
3454
3455 =head3 END OF COMMAND PARSING
3456
3457 Anything left in C<$cmd> at this point is a Perl expression that we want to
3458 evaluate. We'll always evaluate in the user's context, and fully qualify
3459 any variables we might want to address in the C<DB> package.
3460
3461 =cut
3462
3463                 # t - turn trace on.
3464                 $cmd =~ s/^t\s+(\d+)?/\$DB::trace |= 1;\n/ && do {
3465                     $trace_to_depth = $1 ? $stack_depth||0 + $1 : 1E9;
3466                 };
3467
3468                 # s - single-step. Remember the last command was 's'.
3469                 $cmd =~ s/^s\s/\$DB::single = 1;\n/ && do { $laststep = 's' };
3470
3471                 # n - single-step, but not into subs. Remember last command
3472                 # was 'n'.
3473                 $cmd =~ s/^n\s/\$DB::single = 2;\n/ && do { $laststep = 'n' };
3474
3475             }    # PIPE:
3476
3477             # Make sure the flag that says "the debugger's running" is
3478             # still on, to make sure we get control again.
3479             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3480
3481             # Run *our* eval that executes in the caller's context.
3482             &eval;
3483
3484             # Turn off the one-time-dump stuff now.
3485             if ($onetimeDump) {
3486                 $onetimeDump      = undef;
3487                 $onetimedumpDepth = undef;
3488             }
3489             elsif ( $term_pid == $$ ) {
3490                 eval {          # May run under miniperl, when not available...
3491                     STDOUT->flush();
3492                     STDERR->flush();
3493                 };
3494
3495                 # XXX If this is the master pid, print a newline.
3496                 print $OUT "\n";
3497             }
3498         } ## end while (($term || &setterm...
3499
3500 =head3 POST-COMMAND PROCESSING
3501
3502 After each command, we check to see if the command output was piped anywhere.
3503 If so, we go through the necessary code to unhook the pipe and go back to
3504 our standard filehandles for input and output.
3505
3506 =cut
3507
3508         continue {    # CMD:
3509
3510             # At the end of every command:
3511             if ($piped) {
3512
3513                 # Unhook the pipe mechanism now.
3514                 if ( $pager =~ /^\|/ ) {
3515
3516                     # No error from the child.
3517                     $? = 0;
3518
3519                     # we cannot warn here: the handle is missing --tchrist
3520                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3521
3522                     # most of the $? crud was coping with broken cshisms
3523                     # $? is explicitly set to 0, so this never runs.
3524                     if ($?) {
3525                         print SAVEOUT "Pager '$pager' failed: ";
3526                         if ( $? == -1 ) {
3527                             print SAVEOUT "shell returned -1\n";
3528                         }
3529                         elsif ( $? >> 8 ) {
3530                             print SAVEOUT ( $? & 127 )
3531                               ? " (SIG#" . ( $? & 127 ) . ")"
3532                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3533                         }
3534                         else {
3535                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3536                         }
3537                     } ## end if ($?)
3538
3539                     # Reopen filehandle for our output (if we can) and
3540                     # restore STDOUT (if we can).
3541                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3542                     open( STDOUT, ">&SAVEOUT" )
3543                       || &warn("Can't restore STDOUT");
3544
3545                     # Turn off pipe exception handler if necessary.
3546                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3547
3548                     # Will stop ignoring SIGPIPE if done like nohup(1)
3549                     # does SIGINT but Perl doesn't give us a choice.
3550                 } ## end if ($pager =~ /^\|/)
3551                 else {
3552
3553                     # Non-piped "pager". Just restore STDOUT.
3554                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3555                 }
3556
3557                 # Close filehandle pager was using, restore the normal one
3558                 # if necessary,
3559                 close(SAVEOUT);
3560                 select($selected), $selected = "" unless $selected eq "";
3561
3562                 # No pipes now.
3563                 $piped = "";
3564             } ## end if ($piped)
3565         }    # CMD:
3566
3567 =head3 COMMAND LOOP TERMINATION
3568
3569 When commands have finished executing, we come here. If the user closed the
3570 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3571 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3572 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3573 The interpreter will then execute the next line and then return control to us
3574 again.
3575
3576 =cut
3577
3578         # No more commands? Quit.
3579         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3580
3581         # Evaluate post-prompt commands.
3582         foreach $evalarg (@$post) {
3583             &eval;
3584         }
3585     }    # if ($single || $signal)
3586
3587     # Put the user's globals back where you found them.
3588     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3589     ();
3590 } ## end sub DB
3591
3592 # The following code may be executed now:
3593 # BEGIN {warn 4}
3594
3595 =head2 sub
3596
3597 C<sub> is called whenever a subroutine call happens in the program being
3598 debugged. The variable C<$DB::sub> contains the name of the subroutine
3599 being called.
3600
3601 The core function of this subroutine is to actually call the sub in the proper
3602 context, capturing its output. This of course causes C<DB::DB> to get called
3603 again, repeating until the subroutine ends and returns control to C<DB::sub>
3604 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3605 return value, and returns its captured copy of the return value as its own
3606 return value. The value then feeds back into the program being debugged as if
3607 C<DB::sub> hadn't been there at all.
3608
3609 C<sub> does all the work of printing the subroutine entry and exit messages
3610 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3611 and also prints the return value if needed (for the C<r> command and if
3612 the 16 bit is set in C<$frame>).
3613
3614 It also tracks the subroutine call depth by saving the current setting of
3615 C<$single> in the C<@stack> package global; if this exceeds the value in
3616 C<$deep>, C<sub> automatically turns on printing of the current depth by
3617 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3618 of stop/don't stop on entry to subs set as it currently is set.
3619
3620 =head3 C<caller()> support
3621
3622 If C<caller()> is called from the package C<DB>, it provides some
3623 additional data, in the following order:
3624
3625 =over 4
3626
3627 =item * C<$package>
3628
3629 The package name the sub was in
3630
3631 =item * C<$filename>
3632
3633 The filename it was defined in
3634
3635 =item * C<$line>
3636
3637 The line number it was defined on
3638
3639 =item * C<$subroutine>
3640
3641 The subroutine name; C<(eval)> if an C<eval>().
3642
3643 =item * C<$hasargs>
3644
3645 1 if it has arguments, 0 if not
3646
3647 =item * C<$wantarray>
3648
3649 1 if array context, 0 if scalar context
3650
3651 =item * C<$evaltext>
3652
3653 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3654
3655 =item * C<$is_require>
3656
3657 frame was created by a C<use> or C<require> statement
3658
3659 =item * C<$hints>
3660
3661 pragma information; subject to change between versions
3662
3663 =item * C<$bitmask>
3664
3665 pragma information; subject to change between versions
3666
3667 =item * C<@DB::args>
3668
3669 arguments with which the subroutine was invoked
3670
3671 =back
3672
3673 =cut
3674
3675 sub sub {
3676         # Do not use a regex in this subroutine -> results in corrupted memory
3677         # See: [perl #66110]
3678
3679         # lock ourselves under threads
3680         lock($DBGR);
3681
3682     # Whether or not the autoloader was running, a scalar to put the
3683     # sub's return value in (if needed), and an array to put the sub's
3684     # return value in (if needed).
3685     my ( $al, $ret, @ret ) = "";
3686         if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3687                 print "creating new thread\n";
3688         }
3689
3690     # If the last ten characters are '::AUTOLOAD', note we've traced
3691     # into AUTOLOAD for $sub.
3692     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3693         $al = " for $$sub" if defined $$sub;
3694     }
3695
3696     # We stack the stack pointer and then increment it to protect us
3697     # from a situation that might unwind a whole bunch of call frames
3698     # at once. Localizing the stack pointer means that it will automatically
3699     # unwind the same amount when multiple stack frames are unwound.
3700     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3701
3702     # Expand @stack.
3703     $#stack = $stack_depth;
3704
3705     # Save current single-step setting.
3706     $stack[-1] = $single;
3707
3708     # Turn off all flags except single-stepping.
3709     $single &= 1;
3710
3711     # If we've gotten really deeply recursed, turn on the flag that will
3712     # make us stop with the 'deep recursion' message.
3713     $single |= 4 if $stack_depth == $deep;
3714
3715     # If frame messages are on ...
3716     (
3717         $frame & 4    # Extended frame entry message
3718         ? (
3719             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3720
3721             # Why -1? But it works! :-(
3722             # Because print_trace will call add 1 to it and then call
3723             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3724             # in dump_trace.
3725             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3726           )
3727         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3728
3729           # standard frame entry message
3730       )
3731       if $frame;
3732
3733     # Determine the sub's return type, and capture appropriately.
3734     if (wantarray) {
3735
3736         # Called in array context. call sub and capture output.
3737         # DB::DB will recursively get control again if appropriate; we'll come
3738         # back here when the sub is finished.
3739         @ret = &$sub;
3740
3741         # Pop the single-step value back off the stack.
3742         $single |= $stack[ $stack_depth-- ];
3743
3744         # Check for exit trace messages...
3745         (
3746             $frame & 4    # Extended exit message
3747             ? (
3748                 print_lineinfo( ' ' x $stack_depth, "out " ),
3749                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3750               )
3751             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3752
3753               # Standard exit message
3754           )
3755           if $frame & 2;
3756
3757         # Print the return info if we need to.
3758         if ( $doret eq $stack_depth or $frame & 16 ) {
3759
3760             # Turn off output record separator.
3761             local $\ = '';
3762             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3763
3764             # Indent if we're printing because of $frame tracing.
3765             print $fh ' ' x $stack_depth if $frame & 16;
3766
3767             # Print the return value.
3768             print $fh "list context return from $sub:\n";
3769             dumpit( $fh, \@ret );
3770
3771             # And don't print it again.
3772             $doret = -2;
3773         } ## end if ($doret eq $stack_depth...
3774             # And we have to return the return value now.
3775         @ret;
3776     } ## end if (wantarray)
3777
3778     # Scalar context.
3779     else {
3780         if ( defined wantarray ) {
3781
3782             # Save the value if it's wanted at all.
3783             $ret = &$sub;
3784         }
3785         else {
3786
3787             # Void return, explicitly.
3788             &$sub;
3789             undef $ret;
3790         }
3791
3792         # Pop the single-step value off the stack.
3793         $single |= $stack[ $stack_depth-- ];
3794
3795         # If we're doing exit messages...
3796         (
3797             $frame & 4    # Extended messages
3798             ? (
3799                 print_lineinfo( ' ' x $stack_depth, "out " ),
3800                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3801               )
3802             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3803
3804               # Standard messages
3805           )
3806           if $frame & 2;
3807
3808         # If we are supposed to show the return value... same as before.
3809         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3810             local $\ = '';
3811             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3812             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3813             print $fh (
3814                 defined wantarray
3815                 ? "scalar context return from $sub: "
3816                 : "void context return from $sub\n"
3817             );
3818             dumpit( $fh, $ret ) if defined wantarray;
3819             $doret = -2;
3820         } ## end if ($doret eq $stack_depth...
3821
3822         # Return the appropriate scalar value.
3823         $ret;
3824     } ## end else [ if (wantarray)
3825 } ## end sub sub
3826
3827 sub lsub : lvalue {
3828
3829         # lock ourselves under threads
3830         lock($DBGR);
3831
3832     # Whether or not the autoloader was running, a scalar to put the
3833     # sub's return value in (if needed), and an array to put the sub's
3834     # return value in (if needed).
3835     my ( $al, $ret, @ret ) = "";
3836         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3837                 print "creating new thread\n";
3838         }
3839
3840     # If the last ten characters are C'::AUTOLOAD', note we've traced
3841     # into AUTOLOAD for $sub.
3842     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3843         $al = " for $$sub";
3844     }
3845
3846     # We stack the stack pointer and then increment it to protect us
3847     # from a situation that might unwind a whole bunch of call frames
3848     # at once. Localizing the stack pointer means that it will automatically
3849     # unwind the same amount when multiple stack frames are unwound.
3850     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3851
3852     # Expand @stack.
3853     $#stack = $stack_depth;
3854
3855     # Save current single-step setting.
3856     $stack[-1] = $single;
3857
3858     # Turn off all flags except single-stepping.
3859     $single &= 1;
3860
3861     # If we've gotten really deeply recursed, turn on the flag that will
3862     # make us stop with the 'deep recursion' message.
3863     $single |= 4 if $stack_depth == $deep;
3864
3865     # If frame messages are on ...
3866     (
3867         $frame & 4    # Extended frame entry message
3868         ? (
3869             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3870
3871             # Why -1? But it works! :-(
3872             # Because print_trace will call add 1 to it and then call
3873             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3874             # in dump_trace.
3875             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3876           )
3877         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3878
3879           # standard frame entry message
3880       )
3881       if $frame;
3882
3883     # Pop the single-step value back off the stack.
3884     $single |= $stack[ $stack_depth-- ];
3885
3886     # call the original lvalue sub.
3887     &$sub;
3888 }
3889
3890 # Abstracting common code from multiple places elsewhere:
3891 sub depth_print_lineinfo {
3892     print_lineinfo( @_ ) if $stack_depth < $trace_to_depth;
3893 }
3894
3895 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3896
3897 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3898 Most of the changes were to systematize the command structure and to eliminate
3899 commands that threw away user input without checking.
3900
3901 The following sections describe the code added to make it easy to support
3902 multiple command sets with conflicting command names. This section is a start
3903 at unifying all command processing to make it simpler to develop commands.
3904
3905 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3906 number, and C<$dbline> (the current line) as arguments.
3907
3908 Support functions in this section which have multiple modes of failure C<die>
3909 on error; the rest simply return a false value.
3910
3911 The user-interface functions (all of the C<cmd_*> functions) just output
3912 error messages.
3913
3914 =head2 C<%set>
3915
3916 The C<%set> hash defines the mapping from command letter to subroutine
3917 name suffix.
3918
3919 C<%set> is a two-level hash, indexed by set name and then by command name.
3920 Note that trying to set the CommandSet to C<foobar> simply results in the
3921 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3922
3923 =cut
3924
3925 ### The API section
3926
3927 my %set = (    #
3928     'pre580' => {
3929         'a' => 'pre580_a',
3930         'A' => 'pre580_null',
3931         'b' => 'pre580_b',
3932         'B' => 'pre580_null',
3933         'd' => 'pre580_null',
3934         'D' => 'pre580_D',
3935         'h' => 'pre580_h',
3936         'M' => 'pre580_null',
3937         'O' => 'o',
3938         'o' => 'pre580_null',
3939         'v' => 'M',
3940         'w' => 'v',
3941         'W' => 'pre580_W',
3942     },
3943     'pre590' => {
3944         '<'  => 'pre590_prepost',
3945         '<<' => 'pre590_prepost',
3946         '>'  => 'pre590_prepost',
3947         '>>' => 'pre590_prepost',
3948         '{'  => 'pre590_prepost',
3949         '{{' => 'pre590_prepost',
3950     },
3951 );
3952
3953 my %breakpoints_data;
3954
3955 sub _has_breakpoint_data_ref {
3956     my ($filename, $line) = @_;
3957
3958     return (
3959         exists( $breakpoints_data{$filename} )
3960             and
3961         exists( $breakpoints_data{$filename}{$line} )
3962     );
3963 }
3964
3965 sub _get_breakpoint_data_ref {
3966     my ($filename, $line) = @_;
3967
3968     return ($breakpoints_data{$filename}{$line} ||= +{});
3969 }
3970
3971 sub _delete_breakpoint_data_ref {
3972     my ($filename, $line) = @_;
3973
3974     delete($breakpoints_data{$filename}{$line});
3975     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
3976         delete($breakpoints_data{$filename});
3977     }
3978
3979     return;
3980 }
3981
3982 sub _set_breakpoint_enabled_status {
3983     my ($filename, $line, $status) = @_;
3984
3985     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
3986         ($status ? 1 : '')
3987         ;
3988
3989     return;
3990 }
3991
3992 sub _is_breakpoint_enabled {
3993     my ($filename, $line) = @_;
3994
3995     return _get_breakpoint_data_ref($filename, $line)->{'enabled'};
3996 }
3997
3998 =head2 C<cmd_wrapper()> (API)
3999
4000 C<cmd_wrapper()> allows the debugger to switch command sets
4001 depending on the value of the C<CommandSet> option.
4002
4003 It tries to look up the command in the C<%set> package-level I<lexical>
4004 (which means external entities can't fiddle with it) and create the name of
4005 the sub to call based on the value found in the hash (if it's there). I<All>
4006 of the commands to be handled in a set have to be added to C<%set>; if they
4007 aren't found, the 5.8.0 equivalent is called (if there is one).
4008
4009 This code uses symbolic references.
4010
4011 =cut
4012
4013 sub cmd_wrapper {
4014     my $cmd      = shift;
4015     my $line     = shift;
4016     my $dblineno = shift;
4017
4018     # Assemble the command subroutine's name by looking up the
4019     # command set and command name in %set. If we can't find it,
4020     # default to the older version of the command.
4021     my $call = 'cmd_'
4022       . ( $set{$CommandSet}{$cmd}
4023           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
4024
4025     # Call the command subroutine, call it by name.
4026     return &$call( $cmd, $line, $dblineno );
4027 } ## end sub cmd_wrapper
4028
4029 =head3 C<cmd_a> (command)
4030
4031 The C<a> command handles pre-execution actions. These are associated with a
4032 particular line, so they're stored in C<%dbline>. We default to the current
4033 line if none is specified.
4034
4035 =cut
4036
4037 sub cmd_a {
4038     my $cmd    = shift;
4039     my $line   = shift || '';    # [.|line] expr
4040     my $dbline = shift;
4041
4042     # If it's dot (here), or not all digits,  use the current line.
4043     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
4044
4045     # Should be a line number followed by an expression.
4046     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4047         my ( $lineno, $expr ) = ( $1, $2 );
4048
4049         # If we have an expression ...
4050         if ( length $expr ) {
4051
4052             # ... but the line isn't breakable, complain.
4053             if ( $dbline[$lineno] == 0 ) {
4054                 print $OUT
4055                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4056             }
4057             else {
4058
4059                 # It's executable. Record that the line has an action.
4060                 $had_breakpoints{$filename} |= 2;
4061
4062                 # Remove any action, temp breakpoint, etc.
4063                 $dbline{$lineno} =~ s/\0[^\0]*//;
4064
4065                 # Add the action to the line.
4066                 $dbline{$lineno} .= "\0" . action($expr);
4067             }
4068         } ## end if (length $expr)
4069     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4070     else {
4071
4072         # Syntax wrong.
4073         print $OUT
4074           "Adding an action requires an optional lineno and an expression\n"
4075           ;    # hint
4076     }
4077 } ## end sub cmd_a
4078
4079 =head3 C<cmd_A> (command)
4080
4081 Delete actions. Similar to above, except the delete code is in a separate
4082 subroutine, C<delete_action>.
4083
4084 =cut
4085
4086 sub cmd_A {
4087     my $cmd    = shift;
4088     my $line   = shift || '';
4089     my $dbline = shift;
4090
4091     # Dot is this line.
4092     $line =~ s/^\./$dbline/;
4093
4094     # Call delete_action with a null param to delete them all.
4095     # The '1' forces the eval to be true. It'll be false only
4096     # if delete_action blows up for some reason, in which case
4097     # we print $@ and get out.
4098     if ( $line eq '*' ) {
4099         eval { &delete_action(); 1 } or print $OUT $@ and return;
4100     }
4101
4102     # There's a real line  number. Pass it to delete_action.
4103     # Error trapping is as above.
4104     elsif ( $line =~ /^(\S.*)/ ) {
4105         eval { &delete_action($1); 1 } or print $OUT $@ and return;
4106     }
4107
4108     # Swing and a miss. Bad syntax.
4109     else {
4110         print $OUT
4111           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4112     }
4113 } ## end sub cmd_A
4114
4115 =head3 C<delete_action> (API)
4116
4117 C<delete_action> accepts either a line number or C<undef>. If a line number
4118 is specified, we check for the line being executable (if it's not, it
4119 couldn't have had an  action). If it is, we just take the action off (this
4120 will get any kind of an action, including breakpoints).
4121
4122 =cut
4123
4124 sub delete_action {
4125     my $i = shift;
4126     if ( defined($i) ) {
4127
4128         # Can there be one?
4129         die "Line $i has no action .\n" if $dbline[$i] == 0;
4130
4131         # Nuke whatever's there.
4132         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4133         delete $dbline{$i} if $dbline{$i} eq '';
4134     }
4135     else {
4136         print $OUT "Deleting all actions...\n";
4137         for my $file ( keys %had_breakpoints ) {
4138             local *dbline = $main::{ '_<' . $file };
4139             my $max = $#dbline;
4140             my $was;
4141             for ( $i = 1 ; $i <= $max ; $i++ ) {
4142                 if ( defined $dbline{$i} ) {
4143                     $dbline{$i} =~ s/\0[^\0]*//;
4144                     delete $dbline{$i} if $dbline{$i} eq '';
4145                 }
4146                 unless ( $had_breakpoints{$file} &= ~2 ) {
4147                     delete $had_breakpoints{$file};
4148                 }
4149             } ## end for ($i = 1 ; $i <= $max...
4150         } ## end for my $file (keys %had_breakpoints)
4151     } ## end else [ if (defined($i))
4152 } ## end sub delete_action
4153
4154 =head3 C<cmd_b> (command)
4155
4156 Set breakpoints. Since breakpoints can be set in so many places, in so many
4157 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4158 we try to parse the command type, and then shuttle it off to an appropriate
4159 subroutine to actually do the work of setting the breakpoint in the right
4160 place.
4161
4162 =cut
4163
4164 sub cmd_b {
4165     my $cmd    = shift;
4166     my $line   = shift;    # [.|line] [cond]
4167     my $dbline = shift;
4168
4169     # Make . the current line number if it's there..
4170     $line =~ s/^\.\b/$dbline/;
4171
4172     # No line number, no condition. Simple break on current line.
4173     if ( $line =~ /^\s*$/ ) {
4174         &cmd_b_line( $dbline, 1 );
4175     }
4176
4177     # Break on load for a file.
4178     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4179         my $file = $1;
4180         $file =~ s/\s+$//;
4181         &cmd_b_load($file);
4182     }
4183
4184     # b compile|postpone <some sub> [<condition>]
4185     # The interpreter actually traps this one for us; we just put the
4186     # necessary condition in the %postponed hash.
4187     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4188
4189         # Capture the condition if there is one. Make it true if none.
4190         my $cond = length $3 ? $3 : '1';
4191
4192         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4193         # if it was 'compile'.
4194         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4195
4196         # De-Perl4-ify the name - ' separators to ::.
4197         $subname =~ s/\'/::/g;
4198
4199         # Qualify it into the current package unless it's already qualified.
4200         $subname = "${'package'}::" . $subname unless $subname =~ /::/;
4201
4202         # Add main if it starts with ::.
4203         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4204
4205         # Save the break type for this sub.
4206         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4207     } ## end elsif ($line =~ ...
4208     # b <filename>:<line> [<condition>]
4209     elsif ($line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4210         my ($filename, $line_num, $cond) = ($1, $2, $3);
4211         cmd_b_filename_line(
4212             $filename,
4213             $line_num,
4214             (length($cond) ? $cond : '1'),
4215         );
4216     }
4217     # b <sub name> [<condition>]
4218     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4219
4220         #
4221         $subname = $1;
4222         $cond = length $2 ? $2 : '1';
4223         &cmd_b_sub( $subname, $cond );
4224     }
4225
4226     # b <line> [<condition>].
4227     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4228
4229         # Capture the line. If none, it's the current line.
4230         $line = $1 || $dbline;
4231
4232         # If there's no condition, make it '1'.
4233         $cond = length $2 ? $2 : '1';
4234
4235         # Break on line.
4236         &cmd_b_line( $line, $cond );
4237     }
4238
4239     # Line didn't make sense.
4240     else {
4241         print "confused by line($line)?\n";
4242     }
4243 } ## end sub cmd_b
4244
4245 =head3 C<break_on_load> (API)
4246
4247 We want to break when this file is loaded. Mark this file in the
4248 C<%break_on_load> hash, and note that it has a breakpoint in
4249 C<%had_breakpoints>.
4250
4251 =cut
4252
4253 sub break_on_load {
4254     my $file = shift;
4255     $break_on_load{$file} = 1;
4256     $had_breakpoints{$file} |= 1;
4257 }
4258
4259 =head3 C<report_break_on_load> (API)
4260
4261 Gives us an array of filenames that are set to break on load. Note that
4262 only files with break-on-load are in here, so simply showing the keys
4263 suffices.
4264
4265 =cut
4266
4267 sub report_break_on_load {
4268     sort keys %break_on_load;
4269 }
4270
4271 =head3 C<cmd_b_load> (command)
4272
4273 We take the file passed in and try to find it in C<%INC> (which maps modules
4274 to files they came from). We mark those files for break-on-load via
4275 C<break_on_load> and then report that it was done.
4276
4277 =cut
4278
4279 sub cmd_b_load {
4280     my $file = shift;
4281     my @files;
4282
4283     # This is a block because that way we can use a redo inside it
4284     # even without there being any looping structure at all outside it.
4285     {
4286
4287         # Save short name and full path if found.
4288         push @files, $file;
4289         push @files, $::INC{$file} if $::INC{$file};
4290
4291         # Tack on .pm and do it again unless there was a '.' in the name
4292         # already.
4293         $file .= '.pm', redo unless $file =~ /\./;
4294     }
4295
4296     # Do the real work here.
4297     break_on_load($_) for @files;
4298
4299     # All the files that have break-on-load breakpoints.
4300     @files = report_break_on_load;
4301
4302     # Normalize for the purposes of our printing this.
4303     local $\ = '';
4304     local $" = ' ';
4305     print $OUT "Will stop on load of '@files'.\n";
4306 } ## end sub cmd_b_load
4307
4308 =head3 C<$filename_error> (API package global)
4309
4310 Several of the functions we need to implement in the API need to work both
4311 on the current file and on other files. We don't want to duplicate code, so
4312 C<$filename_error> is used to contain the name of the file that's being
4313 worked on (if it's not the current one).
4314
4315 We can now build functions in pairs: the basic function works on the current
4316 file, and uses C<$filename_error> as part of its error message. Since this is
4317 initialized to C<"">, no filename will appear when we are working on the
4318 current file.
4319
4320 The second function is a wrapper which does the following:
4321
4322 =over 4
4323
4324 =item *
4325
4326 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4327
4328 =item *
4329
4330 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4331
4332 =item *
4333
4334 Calls the first function.
4335
4336 The first function works on the I<current> file (i.e., the one we changed to),
4337 and prints C<$filename_error> in the error message (the name of the other file)
4338 if it needs to. When the functions return, C<*dbline> is restored to point
4339 to the actual current file (the one we're executing in) and
4340 C<$filename_error> is restored to C<"">. This restores everything to
4341 the way it was before the second function was called at all.
4342
4343 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4344 details.
4345
4346 =back
4347
4348 =cut
4349
4350 $filename_error = '';
4351
4352 =head3 breakable_line(from, to) (API)
4353
4354 The subroutine decides whether or not a line in the current file is breakable.
4355 It walks through C<@dbline> within the range of lines specified, looking for
4356 the first line that is breakable.
4357
4358 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4359 first line I<after> C<$to> that's breakable, if there is one.
4360
4361 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4362 first line I<before> C<$to> that's breakable, if there is one.
4363
4364 =cut
4365
4366 sub breakable_line {
4367
4368     my ( $from, $to ) = @_;
4369
4370     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4371     my $i = $from;
4372
4373     # If there are at least 2 arguments, we're trying to search a range.
4374     if ( @_ >= 2 ) {
4375
4376         # $delta is positive for a forward search, negative for a backward one.
4377         my $delta = $from < $to ? +1 : -1;
4378
4379         # Keep us from running off the ends of the file.
4380         my $limit = $delta > 0 ? $#dbline : 1;
4381
4382         # Clever test. If you're a mathematician, it's obvious why this
4383         # test works. If not:
4384         # If $delta is positive (going forward), $limit will be $#dbline.
4385         #    If $to is less than $limit, ($limit - $to) will be positive, times
4386         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4387         #    as the stopping point.
4388         #
4389         #    If $to is greater than $limit, ($limit - $to) is negative,
4390         #    times $delta of 1 (positive), so the result is < 0 and we should
4391         #    use $limit ($#dbline) as the stopping point.
4392         #
4393         # If $delta is negative (going backward), $limit will be 1.
4394         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4395         #    (negative) so the result is > 0, and we use $to as the stopping
4396         #    point.
4397         #
4398         #    If $to is less than zero, ($limit - $to) will be positive,
4399         #    times $delta of -1 (negative), so the result is not > 0, and
4400         #    we use $limit (1) as the stopping point.
4401         #
4402         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4403         #    (negative), still giving zero; the result is not > 0, and
4404         #    we use $limit (1) as the stopping point.
4405         #
4406         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4407         #    (negative), giving a positive (>0) value, so we'll set $limit to
4408         #    $to.
4409
4410         $limit = $to if ( $limit - $to ) * $delta > 0;
4411
4412         # The real search loop.
4413         # $i starts at $from (the point we want to start searching from).
4414         # We move through @dbline in the appropriate direction (determined
4415         # by $delta: either -1 (back) or +1 (ahead).
4416         # We stay in as long as we haven't hit an executable line
4417         # ($dbline[$i] == 0 means not executable) and we haven't reached
4418         # the limit yet (test similar to the above).
4419         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4420
4421     } ## end if (@_ >= 2)
4422
4423     # If $i points to a line that is executable, return that.
4424     return $i unless $dbline[$i] == 0;
4425
4426     # Format the message and print it: no breakable lines in range.
4427     my ( $pl, $upto ) = ( '', '' );
4428     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4429
4430     # If there's a filename in filename_error, we'll see it.
4431     # If not, not.
4432     die "Line$pl $from$upto$filename_error not breakable\n";
4433 } ## end sub breakable_line
4434
4435 =head3 breakable_line_in_filename(file, from, to) (API)
4436
4437 Like C<breakable_line>, but look in another file.
4438
4439 =cut
4440
4441 sub breakable_line_in_filename {
4442
4443     # Capture the file name.
4444     my ($f) = shift;
4445
4446     # Swap the magic line array over there temporarily.
4447     local *dbline = $main::{ '_<' . $f };
4448
4449     # If there's an error, it's in this other file.
4450     local $filename_error = " of '$f'";
4451
4452     # Find the breakable line.
4453     breakable_line(@_);
4454
4455     # *dbline and $filename_error get restored when this block ends.
4456
4457 } ## end sub breakable_line_in_filename
4458
4459 =head3 break_on_line(lineno, [condition]) (API)
4460
4461 Adds a breakpoint with the specified condition (or 1 if no condition was
4462 specified) to the specified line. Dies if it can't.
4463
4464 =cut
4465
4466 sub break_on_line {
4467     my ( $i, $cond ) = @_;
4468
4469     # Always true if no condition supplied.
4470     $cond = 1 unless @_ >= 2;
4471
4472     my $inii  = $i;
4473     my $after = '';
4474     my $pl    = '';
4475
4476     # Woops, not a breakable line. $filename_error allows us to say
4477     # if it was in a different file.
4478     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4479
4480     # Mark this file as having breakpoints in it.
4481     $had_breakpoints{$filename} |= 1;
4482
4483     # If there is an action or condition here already ...
4484     if ( $dbline{$i} ) {
4485
4486         # ... swap this condition for the existing one.
4487         $dbline{$i} =~ s/^[^\0]*/$cond/;
4488     }
4489     else {
4490
4491         # Nothing here - just add the condition.
4492         $dbline{$i} = $cond;
4493
4494         _set_breakpoint_enabled_status($filename, $i, 1);
4495     }
4496 } ## end sub break_on_line
4497
4498 =head3 cmd_b_line(line, [condition]) (command)
4499
4500 Wrapper for C<break_on_line>. Prints the failure message if it
4501 doesn't work.
4502
4503 =cut
4504
4505 sub cmd_b_line {
4506     eval { break_on_line(@_); 1 } or do {
4507         local $\ = '';
4508         print $OUT $@ and return;
4509     };
4510 } ## end sub cmd_b_line
4511
4512 =head3 cmd_b_filename_line(line, [condition]) (command)
4513
4514 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4515 doesn't work.
4516
4517 =cut
4518
4519 sub cmd_b_filename_line {
4520     eval { break_on_filename_line(@_); 1 } or do {
4521         local $\ = '';
4522         print $OUT $@ and return;
4523     };
4524 }
4525
4526 =head3 break_on_filename_line(file, line, [condition]) (API)
4527
4528 Switches to the file specified and then calls C<break_on_line> to set
4529 the breakpoint.
4530
4531 =cut
4532
4533 sub break_on_filename_line {
4534     my ( $f, $i, $cond ) = @_;
4535
4536     # Always true if condition left off.
4537     $cond = 1 unless @_ >= 3;
4538
4539     # Switch the magical hash temporarily.
4540     local *dbline = $main::{ '_<' . $f };
4541
4542     # Localize the variables that break_on_line uses to make its message.
4543     local $filename_error = " of '$f'";
4544     local $filename       = $f;
4545
4546     # Add the breakpoint.
4547     break_on_line( $i, $cond );
4548 } ## end sub break_on_filename_line
4549
4550 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4551
4552 Switch to another file, search the range of lines specified for an
4553 executable one, and put a breakpoint on the first one you find.
4554
4555 =cut
4556
4557 sub break_on_filename_line_range {
4558     my ( $f, $from, $to, $cond ) = @_;
4559
4560     # Find a breakable line if there is one.
4561     my $i = breakable_line_in_filename( $f, $from, $to );
4562
4563     # Always true if missing.
4564     $cond = 1 unless @_ >= 3;
4565
4566     # Add the breakpoint.
4567     break_on_filename_line( $f, $i, $cond );
4568 } ## end sub break_on_filename_line_range
4569
4570 =head3 subroutine_filename_lines(subname, [condition]) (API)
4571
4572 Search for a subroutine within a given file. The condition is ignored.
4573 Uses C<find_sub> to locate the desired subroutine.
4574
4575 =cut
4576
4577 sub subroutine_filename_lines {
4578     my ( $subname, $cond ) = @_;
4579
4580     # Returned value from find_sub() is fullpathname:startline-endline.
4581     # The match creates the list (fullpathname, start, end). Falling off
4582     # the end of the subroutine returns this implicitly.
4583     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
4584 } ## end sub subroutine_filename_lines
4585
4586 =head3 break_subroutine(subname) (API)
4587
4588 Places a break on the first line possible in the specified subroutine. Uses
4589 C<subroutine_filename_lines> to find the subroutine, and
4590 C<break_on_filename_line_range> to place the break.
4591
4592 =cut
4593
4594 sub break_subroutine {
4595     my $subname = shift;
4596
4597     # Get filename, start, and end.
4598     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
4599       or die "Subroutine $subname not found.\n";
4600
4601     # Null condition changes to '1' (always true).
4602     $cond = 1 unless @_ >= 2;
4603
4604     # Put a break the first place possible in the range of lines
4605     # that make up this subroutine.
4606     break_on_filename_line_range( $file, $s, $e, @_ );
4607 } ## end sub break_subroutine
4608
4609 =head3 cmd_b_sub(subname, [condition]) (command)
4610
4611 We take the incoming subroutine name and fully-qualify it as best we can.
4612
4613 =over 4
4614
4615 =item 1. If it's already fully-qualified, leave it alone.
4616
4617 =item 2. Try putting it in the current package.
4618
4619 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
4620
4621 =item 4. If it starts with '::', put it in 'main::'.
4622
4623 =back
4624
4625 After all this cleanup, we call C<break_subroutine> to try to set the
4626 breakpoint.
4627
4628 =cut
4629
4630 sub cmd_b_sub {
4631     my ( $subname, $cond ) = @_;
4632
4633     # Add always-true condition if we have none.
4634     $cond = 1 unless @_ >= 2;
4635
4636     # If the subname isn't a code reference, qualify it so that
4637     # break_subroutine() will work right.
4638     unless ( ref $subname eq 'CODE' ) {
4639
4640         # Not Perl4.
4641         $subname =~ s/\'/::/g;
4642         my $s = $subname;
4643
4644         # Put it in this package unless it's already qualified.
4645         $subname = "${'package'}::" . $subname
4646           unless $subname =~ /::/;
4647
4648         # Requalify it into CORE::GLOBAL if qualifying it into this
4649         # package resulted in its not being defined, but only do so
4650         # if it really is in CORE::GLOBAL.
4651         $subname = "CORE::GLOBAL::$s"
4652           if not defined &$subname
4653           and $s !~ /::/
4654           and defined &{"CORE::GLOBAL::$s"};
4655
4656         # Put it in package 'main' if it has a leading ::.
4657         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4658
4659     } ## end unless (ref $subname eq 'CODE')
4660
4661     # Try to set the breakpoint.
4662     eval { break_subroutine( $subname, $cond ); 1 } or do {
4663         local $\ = '';
4664         print $OUT $@ and return;
4665       }
4666 } ## end sub cmd_b_sub
4667
4668 =head3 C<cmd_B> - delete breakpoint(s) (command)
4669
4670 The command mostly parses the command line and tries to turn the argument
4671 into a line spec. If it can't, it uses the current line. It then calls
4672 C<delete_breakpoint> to actually do the work.
4673
4674 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
4675 thereby deleting all the breakpoints.
4676
4677 =cut
4678
4679 sub cmd_B {
4680     my $cmd = shift;
4681
4682     # No line spec? Use dbline.
4683     # If there is one, use it if it's non-zero, or wipe it out if it is.
4684     my $line   = ( $_[0] =~ /^\./ ) ? $dbline : shift || '';
4685     my $dbline = shift;
4686
4687     # If the line was dot, make the line the current one.
4688     $line =~ s/^\./$dbline/;
4689
4690     # If it's * we're deleting all the breakpoints.
4691     if ( $line eq '*' ) {
4692         eval { &delete_breakpoint(); 1 } or print $OUT $@ and return;
4693     }
4694
4695     # If there is a line spec, delete the breakpoint on that line.
4696     elsif ( $line =~ /^(\S.*)/ ) {
4697         eval { &delete_breakpoint( $line || $dbline ); 1 } or do {
4698             local $\ = '';
4699             print $OUT $@ and return;
4700         };
4701     } ## end elsif ($line =~ /^(\S.*)/)
4702
4703     # No line spec.
4704     else {
4705         print $OUT
4706           "Deleting a breakpoint requires a line number, or '*' for all\n"
4707           ;    # hint
4708     }
4709 } ## end sub cmd_B
4710
4711 =head3 delete_breakpoint([line]) (API)
4712
4713 This actually does the work of deleting either a single breakpoint, or all
4714 of them.
4715
4716 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
4717 just drop out with a message saying so. If it is, we remove the condition
4718 part of the 'condition\0action' that says there's a breakpoint here. If,
4719 after we've done that, there's nothing left, we delete the corresponding
4720 line in C<%dbline> to signal that no action needs to be taken for this line.
4721
4722 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
4723 which lists all currently-loaded files which have breakpoints. We then look
4724 at each line in each of these files, temporarily switching the C<%dbline>
4725 and C<@dbline> structures to point to the files in question, and do what
4726 we did in the single line case: delete the condition in C<@dbline>, and
4727 delete the key in C<%dbline> if nothing's left.
4728
4729 We then wholesale delete C<%postponed>, C<%postponed_file>, and
4730 C<%break_on_load>, because these structures contain breakpoints for files
4731 and code that haven't been loaded yet. We can just kill these off because there
4732 are no magical debugger structures associated with them.
4733
4734 =cut
4735
4736 sub delete_breakpoint {
4737     my $i = shift;
4738
4739     my $fn = $filename;
4740
4741     # If we got a line, delete just that one.
4742     if ( defined($i) ) {
4743
4744         # Woops. This line wasn't breakable at all.
4745         die "Line $i not breakable.\n" if $dbline[$i] == 0;
4746
4747         # Kill the condition, but leave any action.
4748         $dbline{$i} =~ s/^[^\0]*//;
4749
4750         # Remove the entry entirely if there's no action left.
4751         if ($dbline{$i} eq '') {
4752             delete $dbline{$i};
4753             _delete_breakpoint_data_ref($fn, $i);
4754         }
4755     }
4756
4757     # No line; delete them all.
4758     else {
4759         print $OUT "Deleting all breakpoints...\n";
4760
4761         # %had_breakpoints lists every file that had at least one
4762         # breakpoint in it.
4763         for my $file ( keys %had_breakpoints ) {
4764
4765             # Switch to the desired file temporarily.
4766             local *dbline = $main::{ '_<' . $file };
4767
4768             my $max = $#dbline;
4769             my $was;
4770
4771             # For all lines in this file ...
4772             for ( $i = 1 ; $i <= $max ; $i++ ) {
4773
4774                 # If there's a breakpoint or action on this line ...
4775                 if ( defined $dbline{$i} ) {
4776
4777                     # ... remove the breakpoint.
4778                     $dbline{$i} =~ s/^[^\0]+//;
4779                     if ( $dbline{$i} =~ s/^\0?$// ) {
4780
4781                         # Remove the entry altogether if no action is there.
4782                         delete $dbline{$i};
4783                         _delete_breakpoint_data_ref($file, $i);
4784                     }
4785                 } ## end if (defined $dbline{$i...
4786             } ## end for ($i = 1 ; $i <= $max...
4787
4788             # If, after we turn off the "there were breakpoints in this file"
4789             # bit, the entry in %had_breakpoints for this file is zero,
4790             # we should remove this file from the hash.
4791             if ( not $had_breakpoints{$file} &= ~1 ) {
4792                 delete $had_breakpoints{$file};
4793             }
4794         } ## end for my $file (keys %had_breakpoints)
4795
4796         # Kill off all the other breakpoints that are waiting for files that
4797         # haven't been loaded yet.
4798         undef %postponed;
4799         undef %postponed_file;
4800         undef %break_on_load;
4801     } ## end else [ if (defined($i))
4802 } ## end sub delete_breakpoint
4803
4804 =head3 cmd_stop (command)
4805
4806 This is meant to be part of the new command API, but it isn't called or used
4807 anywhere else in the debugger. XXX It is probably meant for use in development
4808 of new commands.
4809
4810 =cut
4811
4812 sub cmd_stop {    # As on ^C, but not signal-safy.
4813     $signal = 1;
4814 }
4815
4816 =head3 C<cmd_e> - threads
4817
4818 Display the current thread id:
4819
4820         e
4821
4822 This could be how (when implemented) to send commands to this thread id (e cmd)
4823 or that thread id (e tid cmd).
4824
4825 =cut
4826
4827 sub cmd_e {
4828     my $cmd  = shift;
4829     my $line = shift;
4830         unless (exists($INC{'threads.pm'})) {
4831                 print "threads not loaded($ENV{PERL5DB_THREADED})
4832                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4833         } else {
4834                 my $tid = threads->tid;
4835                 print "thread id: $tid\n";
4836         }
4837 } ## end sub cmd_e
4838
4839 =head3 C<cmd_E> - list of thread ids
4840
4841 Display the list of available thread ids:
4842
4843         E
4844
4845 This could be used (when implemented) to send commands to all threads (E cmd).
4846
4847 =cut
4848
4849 sub cmd_E {
4850     my $cmd  = shift;
4851     my $line = shift;
4852         unless (exists($INC{'threads.pm'})) {
4853                 print "threads not loaded($ENV{PERL5DB_THREADED})
4854                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4855         } else {
4856                 my $tid = threads->tid;
4857                 print "thread ids: ".join(', ',
4858                         map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
4859                 )."\n";
4860         }
4861 } ## end sub cmd_E
4862
4863 =head3 C<cmd_h> - help command (command)
4864
4865 Does the work of either
4866
4867 =over 4
4868
4869 =item *
4870
4871 Showing all the debugger help
4872
4873 =item *
4874
4875 Showing help for a specific command
4876
4877 =back
4878
4879 =cut
4880
4881 sub cmd_h {
4882     my $cmd = shift;
4883
4884     # If we have no operand, assume null.
4885     my $line = shift || '';
4886
4887     # 'h h'. Print the long-format help.
4888     if ( $line =~ /^h\s*/ ) {
4889         print_help($help);
4890     }
4891
4892     # 'h <something>'. Search for the command and print only its help.
4893     elsif ( $line =~ /^(\S.*)$/ ) {
4894
4895         # support long commands; otherwise bogus errors
4896         # happen when you ask for h on <CR> for example
4897         my $asked = $1;    # the command requested
4898                            # (for proper error message)
4899
4900         my $qasked = quotemeta($asked);    # for searching; we don't
4901                                            # want to use it as a pattern.
4902                                            # XXX: finds CR but not <CR>
4903
4904         # Search the help string for the command.
4905         if (
4906             $help =~ /^                    # Start of a line
4907                       <?                   # Optional '<'
4908                       (?:[IB]<)            # Optional markup
4909                       $qasked              # The requested command
4910                      /mx
4911           )
4912         {
4913
4914             # It's there; pull it out and print it.
4915             while (
4916                 $help =~ /^
4917                               (<?            # Optional '<'
4918                                  (?:[IB]<)   # Optional markup
4919                                  $qasked     # The command
4920                                  ([\s\S]*?)  # Description line(s)
4921                               \n)            # End of last description line
4922                               (?!\s)         # Next line not starting with
4923                                              # whitespace
4924                              /mgx
4925               )
4926             {
4927                 print_help($1);
4928             }
4929         }
4930
4931         # Not found; not a debugger command.
4932         else {
4933             print_help("B<$asked> is not a debugger command.\n");
4934         }
4935     } ## end elsif ($line =~ /^(\S.*)$/)
4936
4937     # 'h' - print the summary help.
4938     else {
4939         print_help($summary);
4940     }
4941 } ## end sub cmd_h
4942
4943 =head3 C<cmd_i> - inheritance display
4944
4945 Display the (nested) parentage of the module or object given.
4946
4947 =cut
4948
4949 sub cmd_i {
4950     my $cmd  = shift;
4951     my $line = shift;
4952     foreach my $isa ( split( /\s+/, $line ) ) {
4953         $evalarg = $isa;
4954         ($isa) = &eval;
4955         no strict 'refs';
4956         print join(
4957             ', ',
4958             map {
4959                 "$_"
4960                   . (
4961                     defined( ${"$_\::VERSION"} )
4962                     ? ' ' . ${"$_\::VERSION"}
4963                     : undef )
4964               } @{mro::get_linear_isa(ref($isa) || $isa)}
4965         );
4966         print "\n";
4967     }
4968 } ## end sub cmd_i
4969
4970 =head3 C<cmd_l> - list lines (command)
4971
4972 Most of the command is taken up with transforming all the different line
4973 specification syntaxes into 'start-stop'. After that is done, the command
4974 runs a loop over C<@dbline> for the specified range of lines. It handles
4975 the printing of each line and any markers (C<==E<gt>> for current line,
4976 C<b> for break on this line, C<a> for action on this line, C<:> for this
4977 line breakable).
4978
4979 We save the last line listed in the C<$start> global for further listing
4980 later.
4981
4982 =cut
4983
4984 sub cmd_l {
4985     my $current_line = $line;
4986     my $cmd  = shift;
4987     my $line = shift;
4988
4989     # If this is '-something', delete any spaces after the dash.
4990     $line =~ s/^-\s*$/-/;
4991
4992     # If the line is '$something', assume this is a scalar containing a
4993     # line number.
4994     if ( $line =~ /^(\$.*)/s ) {
4995
4996         # Set up for DB::eval() - evaluate in *user* context.
4997         $evalarg = $1;
4998         # $evalarg = $2;
4999         my ($s) = &eval;
5000
5001         # Ooops. Bad scalar.
5002         print( $OUT "Error: $@\n" ), next CMD if $@;
5003
5004         # Good scalar. If it's a reference, find what it points to.
5005         $s = CvGV_name($s);
5006         print( $OUT "Interpreted as: $1 $s\n" );
5007         $line = "$1 $s";
5008
5009         # Call self recursively to really do the command.
5010         &cmd_l( 'l', $s );
5011     } ## end if ($line =~ /^(\$.*)/s)
5012
5013     # l name. Try to find a sub by that name.
5014     elsif ( $line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s ) {
5015         my $s = $subname = $1;
5016
5017         # De-Perl4.
5018         $subname =~ s/\'/::/;
5019
5020         # Put it in this package unless it starts with ::.
5021         $subname = $package . "::" . $subname unless $subname =~ /::/;
5022
5023         # Put it in CORE::GLOBAL if t doesn't start with :: and
5024         # it doesn't live in this package and it lives in CORE::GLOBAL.
5025         $subname = "CORE::GLOBAL::$s"
5026           if not defined &$subname
5027           and $s !~ /::/
5028           and defined &{"CORE::GLOBAL::$s"};
5029
5030         # Put leading '::' names into 'main::'.
5031         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
5032
5033         # Get name:start-stop from find_sub, and break this up at
5034         # colons.
5035         @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
5036
5037         # Pull off start-stop.
5038         $subrange = pop @pieces;
5039
5040         # If the name contained colons, the split broke it up.
5041         # Put it back together.
5042         $file = join( ':', @pieces );
5043
5044         # If we're not in that file, switch over to it.
5045         if ( $file ne $filename ) {
5046             print $OUT "Switching to file '$file'.\n"
5047               unless $slave_editor;
5048
5049             # Switch debugger's magic structures.
5050             *dbline   = $main::{ '_<' . $file };
5051             $max      = $#dbline;
5052             $filename = $file;
5053         } ## end if ($file ne $filename)
5054
5055         # Subrange is 'start-stop'. If this is less than a window full,
5056         # swap it to 'start+', which will list a window from the start point.
5057         if ($subrange) {
5058             if ( eval($subrange) < -$window ) {
5059                 $subrange =~ s/-.*/+/;
5060             }
5061
5062             # Call self recursively to list the range.
5063             $line = $subrange;
5064             &cmd_l( 'l', $subrange );
5065         } ## end if ($subrange)
5066
5067         # Couldn't find it.
5068         else {
5069             print $OUT "Subroutine $subname not found.\n";
5070         }
5071     } ## end elsif ($line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s)
5072
5073     # Bare 'l' command.
5074     elsif ( $line =~ /^\s*$/ ) {
5075
5076         # Compute new range to list.
5077         $incr = $window - 1;
5078         $line = $start . '-' . ( $start + $incr );
5079
5080         # Recurse to do it.
5081         &cmd_l( 'l', $line );
5082     }
5083
5084     # l [start]+number_of_lines
5085     elsif ( $line =~ /^(\d*)\+(\d*)$/ ) {
5086
5087         # Don't reset start for 'l +nnn'.
5088         $start = $1 if $1;
5089
5090         # Increment for list. Use window size if not specified.
5091         # (Allows 'l +' to work.)
5092         $incr = $2;
5093         $incr = $window - 1 unless $incr;
5094
5095         # Create a line range we'll understand, and recurse to do it.
5096         $line = $start . '-' . ( $start + $incr );
5097         &cmd_l( 'l', $line );
5098     } ## end elsif ($line =~ /^(\d*)\+(\d*)$/)
5099
5100     # l start-stop or l start,stop
5101     elsif ( $line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/ ) {
5102
5103         # Determine end point; use end of file if not specified.
5104         $end = ( !defined $2 ) ? $max : ( $4 ? $4 : $2 );
5105
5106         # Go on to the end, and then stop.
5107         $end = $max if $end > $max;
5108
5109         # Determine start line.
5110         $i    = $2;
5111         $i    = $line if $i eq '.';
5112         $i    = 1 if $i < 1;
5113         $incr = $end - $i;
5114
5115         # If we're running under a slave editor, force it to show the lines.
5116         if ($slave_editor) {
5117             print $OUT "\032\032$filename:$i:0\n";
5118             $i = $end;
5119         }
5120
5121         # We're doing it ourselves. We want to show the line and special
5122         # markers for:
5123         # - the current line in execution
5124         # - whether a line is breakable or not
5125         # - whether a line has a break or not
5126         # - whether a line has an action or not
5127         else {
5128             for ( ; $i <= $end ; $i++ ) {
5129
5130                 # Check for breakpoints and actions.
5131                 my ( $stop, $action );
5132                 ( $stop, $action ) = split( /\0/, $dbline{$i} )
5133                   if $dbline{$i};
5134
5135                 # ==> if this is the current line in execution,
5136                 # : if it's breakable.
5137                 $arrow =
5138                   ( $i == $current_line and $filename eq $filename_ini )
5139                   ? '==>'
5140                   : ( $dbline[$i] + 0 ? ':' : ' ' );
5141
5142                 # Add break and action indicators.
5143                 $arrow .= 'b' if $stop;
5144                 $arrow .= 'a' if $action;
5145
5146                 # Print the line.
5147                 print $OUT "$i$arrow\t", $dbline[$i];
5148
5149                 # Move on to the next line. Drop out on an interrupt.
5150                 $i++, last if $signal;
5151             } ## end for (; $i <= $end ; $i++)
5152
5153             # Line the prompt up; print a newline if the last line listed
5154             # didn't have a newline.
5155             print $OUT "\n" unless $dbline[ $i - 1 ] =~ /\n$/;
5156         } ## end else [ if ($slave_editor)
5157
5158         # Save the point we last listed to in case another relative 'l'
5159         # command is desired. Don't let it run off the end.
5160         $start = $i;
5161         $start = $max if $start > $max;
5162     } ## end elsif ($line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/)
5163 } ## end sub cmd_l
5164
5165 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5166
5167 To list breakpoints, the command has to look determine where all of them are
5168 first. It starts a C<%had_breakpoints>, which tells us what all files have
5169 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5170 magic source and breakpoint data structures) to the file, and then look
5171 through C<%dbline> for lines with breakpoints and/or actions, listing them
5172 out. We look through C<%postponed> not-yet-compiled subroutines that have
5173 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5174 that have breakpoints.
5175
5176 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5177
5178 =cut
5179
5180 sub cmd_L {
5181     my $cmd = shift;
5182
5183     # If no argument, list everything. Pre-5.8.0 version always lists
5184     # everything
5185     my $arg = shift || 'abw';
5186     $arg = 'abw' unless $CommandSet eq '580';    # sigh...
5187
5188     # See what is wanted.
5189     my $action_wanted = ( $arg =~ /a/ ) ? 1 : 0;
5190     my $break_wanted  = ( $arg =~ /b/ ) ? 1 : 0;
5191     my $watch_wanted  = ( $arg =~ /w/ ) ? 1 : 0;
5192
5193     # Breaks and actions are found together, so we look in the same place
5194     # for both.
5195     if ( $break_wanted or $action_wanted ) {
5196
5197         # Look in all the files with breakpoints...
5198         for my $file ( keys %had_breakpoints ) {
5199
5200             # Temporary switch to this file.
5201             local *dbline = $main::{ '_<' . $file };
5202
5203             # Set up to look through the whole file.
5204             my $max = $#dbline;
5205             my $was;    # Flag: did we print something
5206                         # in this file?
5207
5208             # For each line in the file ...
5209             for ( $i = 1 ; $i <= $max ; $i++ ) {
5210
5211                 # We've got something on this line.
5212                 if ( defined $dbline{$i} ) {
5213
5214                     # Print the header if we haven't.
5215                     print $OUT "$file:\n" unless $was++;
5216
5217                     # Print the line.
5218                     print $OUT " $i:\t", $dbline[$i];
5219
5220                     # Pull out the condition and the action.
5221                     ( $stop, $action ) = split( /\0/, $dbline{$i} );
5222
5223                     # Print the break if there is one and it's wanted.
5224                     print $OUT "   break if (", $stop, ")\n"
5225                       if $stop
5226                       and $break_wanted;
5227
5228                     # Print the action if there is one and it's wanted.
5229                     print $OUT "   action:  ", $action, "\n"
5230                       if $action
5231                       and $action_wanted;
5232
5233                     # Quit if the user hit interrupt.
5234                     last if $signal;
5235                 } ## end if (defined $dbline{$i...
5236             } ## end for ($i = 1 ; $i <= $max...
5237         } ## end for my $file (keys %had_breakpoints)
5238     } ## end if ($break_wanted or $action_wanted)
5239
5240     # Look for breaks in not-yet-compiled subs:
5241     if ( %postponed and $break_wanted ) {
5242         print $OUT "Postponed breakpoints in subroutines:\n";
5243         my $subname;
5244         for $subname ( keys %postponed ) {
5245             print $OUT " $subname\t$postponed{$subname}\n";
5246             last if $signal;
5247         }
5248     } ## end if (%postponed and $break_wanted)
5249
5250     # Find files that have not-yet-loaded breaks:
5251     my @have = map {    # Combined keys
5252         keys %{ $postponed_file{$_} }
5253     } keys %postponed_file;
5254
5255     # If there are any, list them.
5256     if ( @have and ( $break_wanted or $action_wanted ) ) {
5257         print $OUT "Postponed breakpoints in files:\n";
5258         my ( $file, $line );
5259
5260         for $file ( keys %postponed_file ) {
5261             my $db = $postponed_file{$file};
5262             print $OUT " $file:\n";
5263             for $line ( sort { $a <=> $b } keys %$db ) {
5264                 print $OUT "  $line:\n";
5265                 my ( $stop, $action ) = split( /\0/, $$db{$line} );
5266                 print $OUT "    break if (", $stop, ")\n"
5267                   if $stop
5268                   and $break_wanted;
5269                 print $OUT "    action:  ", $action, "\n"
5270                   if $action
5271                   and $action_wanted;
5272                 last if $signal;
5273             } ## end for $line (sort { $a <=>...
5274             last if $signal;
5275         } ## end for $file (keys %postponed_file)
5276     } ## end if (@have and ($break_wanted...
5277     if ( %break_on_load and $break_wanted ) {
5278         print $OUT "Breakpoints on load:\n";
5279         my $file;
5280         for $file ( keys %break_on_load ) {
5281             print $OUT " $file\n";
5282             last if $signal;
5283         }
5284     } ## end if (%break_on_load and...
5285     if ($watch_wanted) {
5286         if ( $trace & 2 ) {
5287             print $OUT "Watch-expressions:\n" if @to_watch;
5288             for my $expr (@to_watch) {
5289                 print $OUT " $expr\n";
5290                 last if $signal;
5291             }
5292         } ## end if ($trace & 2)
5293     } ## end if ($watch_wanted)
5294 } ## end sub cmd_L
5295
5296 =head3 C<cmd_M> - list modules (command)
5297
5298 Just call C<list_modules>.
5299
5300 =cut
5301
5302 sub cmd_M {
5303     &list_modules();
5304 }
5305
5306 =head3 C<cmd_o> - options (command)
5307
5308 If this is just C<o> by itself, we list the current settings via
5309 C<dump_option>. If there's a nonblank value following it, we pass that on to
5310 C<parse_options> for processing.
5311
5312 =cut
5313
5314 sub cmd_o {
5315     my $cmd = shift;
5316     my $opt = shift || '';    # opt[=val]
5317
5318     # Nonblank. Try to parse and process.
5319     if ( $opt =~ /^(\S.*)/ ) {
5320         &parse_options($1);
5321     }
5322
5323     # Blank. List the current option settings.
5324     else {
5325         for (@options) {
5326             &dump_option($_);
5327         }
5328     }
5329 } ## end sub cmd_o
5330
5331 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5332
5333 Advises the user that the O command has been renamed.
5334
5335 =cut
5336
5337 sub cmd_O {
5338     print $OUT "The old O command is now the o command.\n";             # hint
5339     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5340     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5341 }
5342
5343 =head3 C<cmd_v> - view window (command)
5344
5345 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5346 move back a few lines to list the selected line in context. Uses C<cmd_l>
5347 to do the actual listing after figuring out the range of line to request.
5348
5349 =cut
5350
5351 sub cmd_v {
5352     my $cmd  = shift;
5353     my $line = shift;
5354
5355     # Extract the line to list around. (Astute readers will have noted that
5356     # this pattern will match whether or not a numeric line is specified,
5357     # which means that we'll always enter this loop (though a non-numeric
5358     # argument results in no action at all)).
5359     if ( $line =~ /^(\d*)$/ ) {
5360
5361         # Total number of lines to list (a windowful).
5362         $incr = $window - 1;
5363
5364         # Set the start to the argument given (if there was one).
5365         $start = $1 if $1;
5366
5367         # Back up by the context amount.
5368         $start -= $preview;
5369
5370         # Put together a linespec that cmd_l will like.
5371         $line = $start . '-' . ( $start + $incr );
5372
5373         # List the lines.
5374         &cmd_l( 'l', $line );
5375     } ## end if ($line =~ /^(\d*)$/)
5376 } ## end sub cmd_v
5377
5378 =head3 C<cmd_w> - add a watch expression (command)
5379
5380 The 5.8 version of this command adds a watch expression if one is specified;
5381 it does nothing if entered with no operands.
5382
5383 We extract the expression, save it, evaluate it in the user's context, and
5384 save the value. We'll re-evaluate it each time the debugger passes a line,
5385 and will stop (see the code at the top of the command loop) if the value
5386 of any of the expressions changes.
5387
5388 =cut
5389
5390 sub cmd_w {
5391     my $cmd = shift;
5392
5393     # Null expression if no arguments.
5394     my $expr = shift || '';
5395
5396     # If expression is not null ...
5397     if ( $expr =~ /^(\S.*)/ ) {
5398
5399         # ... save it.
5400         push @to_watch, $expr;
5401
5402         # Parameterize DB::eval and call it to get the expression's value
5403         # in the user's context. This version can handle expressions which
5404         # return a list value.
5405         $evalarg = $expr;
5406         my ($val) = join( ' ', &eval );
5407         $val = ( defined $val ) ? "'$val'" : 'undef';
5408
5409         # Save the current value of the expression.
5410         push @old_watch, $val;
5411
5412         # We are now watching expressions.
5413         $trace |= 2;
5414     } ## end if ($expr =~ /^(\S.*)/)
5415
5416     # You have to give one to get one.
5417     else {
5418         print $OUT "Adding a watch-expression requires an expression\n";  # hint
5419     }
5420 } ## end sub cmd_w
5421
5422 =head3 C<cmd_W> - delete watch expressions (command)
5423
5424 This command accepts either a watch expression to be removed from the list
5425 of watch expressions, or C<*> to delete them all.
5426
5427 If C<*> is specified, we simply empty the watch expression list and the
5428 watch expression value list. We also turn off the bit that says we've got
5429 watch expressions.
5430
5431 If an expression (or partial expression) is specified, we pattern-match
5432 through the expressions and remove the ones that match. We also discard
5433 the corresponding values. If no watch expressions are left, we turn off
5434 the I<watching expressions> bit.
5435
5436 =cut
5437
5438 sub cmd_W {
5439     my $cmd  = shift;
5440     my $expr = shift || '';
5441
5442     # Delete them all.
5443     if ( $expr eq '*' ) {
5444
5445         # Not watching now.
5446         $trace &= ~2;
5447
5448         print $OUT "Deleting all watch expressions ...\n";
5449
5450         # And all gone.
5451         @to_watch = @old_watch = ();
5452     }
5453
5454     # Delete one of them.
5455     elsif ( $expr =~ /^(\S.*)/ ) {
5456
5457         # Where we are in the list.
5458         my $i_cnt = 0;
5459
5460         # For each expression ...
5461         foreach (@to_watch) {
5462             my $val = $to_watch[$i_cnt];
5463
5464             # Does this one match the command argument?
5465             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
5466                                       # Yes. Turn it off, and its value too.
5467                 splice( @to_watch,  $i_cnt, 1 );
5468                 splice( @old_watch, $i_cnt, 1 );
5469             }
5470             $i_cnt++;
5471         } ## end foreach (@to_watch)
5472
5473         # We don't bother to turn watching off because
5474         #  a) we don't want to stop calling watchfunction() it it exists
5475         #  b) foreach over a null list doesn't do anything anyway
5476
5477     } ## end elsif ($expr =~ /^(\S.*)/)
5478
5479     # No command arguments entered.
5480     else {
5481         print $OUT
5482           "Deleting a watch-expression requires an expression, or '*' for all\n"
5483           ;    # hint
5484     }
5485 } ## end sub cmd_W
5486
5487 ### END of the API section
5488
5489 =head1 SUPPORT ROUTINES
5490
5491 These are general support routines that are used in a number of places
5492 throughout the debugger.
5493
5494 =head2 save
5495
5496 save() saves the user's versions of globals that would mess us up in C<@saved>,
5497 and installs the versions we like better.
5498
5499 =cut
5500
5501 sub save {
5502
5503     # Save eval failure, command failure, extended OS error, output field
5504     # separator, input record separator, output record separator and
5505     # the warning setting.
5506     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
5507
5508     $,  = "";      # output field separator is null string
5509     $/  = "\n";    # input record separator is newline
5510     $\  = "";      # output record separator is null string
5511     $^W = 0;       # warnings are off
5512 } ## end sub save
5513
5514 =head2 C<print_lineinfo> - show where we are now
5515
5516 print_lineinfo prints whatever it is that it is handed; it prints it to the
5517 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
5518 us to feed line information to a slave editor without messing up the
5519 debugger output.
5520
5521 =cut
5522
5523 sub print_lineinfo {
5524
5525     # Make the terminal sensible if we're not the primary debugger.
5526     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
5527     local $\ = '';
5528     local $, = '';
5529     print $LINEINFO @_;
5530 } ## end sub print_lineinfo
5531
5532 =head2 C<postponed_sub>
5533
5534 Handles setting postponed breakpoints in subroutines once they're compiled.
5535 For breakpoints, we use C<DB::find_sub> to locate the source file and line
5536 range for the subroutine, then mark the file as having a breakpoint,
5537 temporarily switch the C<*dbline> glob over to the source file, and then
5538 search the given range of lines to find a breakable line. If we find one,
5539 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
5540
5541 =cut
5542
5543 # The following takes its argument via $evalarg to preserve current @_
5544
5545 sub postponed_sub {
5546
5547     # Get the subroutine name.
5548     my $subname = shift;
5549
5550     # If this is a 'break +<n> if <condition>' ...
5551     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
5552
5553         # If there's no offset, use '+0'.
5554         my $offset = $1 || 0;
5555
5556         # find_sub's value is 'fullpath-filename:start-stop'. It's
5557         # possible that the filename might have colons in it too.
5558         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
5559         if ($i) {
5560
5561             # We got the start line. Add the offset '+<n>' from
5562             # $postponed{subname}.
5563             $i += $offset;
5564
5565             # Switch to the file this sub is in, temporarily.
5566             local *dbline = $main::{ '_<' . $file };
5567
5568             # No warnings, please.
5569             local $^W = 0;    # != 0 is magical below
5570
5571             # This file's got a breakpoint in it.
5572             $had_breakpoints{$file} |= 1;
5573
5574             # Last line in file.
5575             my $max = $#dbline;
5576
5577             # Search forward until we hit a breakable line or get to
5578             # the end of the file.
5579             ++$i until $dbline[$i] != 0 or $i >= $max;
5580
5581             # Copy the breakpoint in and delete it from %postponed.
5582             $dbline{$i} = delete $postponed{$subname};
5583         } ## end if ($i)
5584
5585         # find_sub didn't find the sub.
5586         else {
5587             local $\ = '';
5588             print $OUT "Subroutine $subname not found.\n";
5589         }
5590         return;
5591     } ## end if ($postponed{$subname...
5592     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
5593
5594     #print $OUT "In postponed_sub for '$subname'.\n";
5595 } ## end sub postponed_sub
5596
5597 =head2 C<postponed>
5598
5599 Called after each required file is compiled, but before it is executed;
5600 also called if the name of a just-compiled subroutine is a key of
5601 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
5602 etc.) into the just-compiled code.
5603
5604 If this is a C<require>'d file, the incoming parameter is the glob
5605 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
5606
5607 If it's a subroutine, the incoming parameter is the subroutine name.
5608
5609 =cut
5610
5611 sub postponed {
5612
5613     # If there's a break, process it.
5614     if ($ImmediateStop) {
5615
5616         # Right, we've stopped. Turn it off.
5617         $ImmediateStop = 0;
5618
5619         # Enter the command loop when DB::DB gets called.
5620         $signal = 1;
5621     }
5622
5623     # If this is a subroutine, let postponed_sub() deal with it.
5624     return &postponed_sub unless ref \$_[0] eq 'GLOB';
5625
5626     # Not a subroutine. Deal with the file.
5627     local *dbline = shift;
5628     my $filename = $dbline;
5629     $filename =~ s/^_<//;
5630     local $\ = '';
5631     $signal = 1, print $OUT "'$filename' loaded...\n"
5632       if $break_on_load{$filename};
5633     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
5634
5635     # Do we have any breakpoints to put in this file?
5636     return unless $postponed_file{$filename};
5637
5638     # Yes. Mark this file as having breakpoints.
5639     $had_breakpoints{$filename} |= 1;
5640
5641     # "Cannot be done: insufficient magic" - we can't just put the
5642     # breakpoints saved in %postponed_file into %dbline by assigning
5643     # the whole hash; we have to do it one item at a time for the
5644     # breakpoints to be set properly.
5645     #%dbline = %{$postponed_file{$filename}};
5646
5647     # Set the breakpoints, one at a time.
5648     my $key;
5649
5650     for $key ( keys %{ $postponed_file{$filename} } ) {
5651
5652         # Stash the saved breakpoint into the current file's magic line array.
5653         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
5654     }
5655
5656     # This file's been compiled; discard the stored breakpoints.
5657     delete $postponed_file{$filename};
5658
5659 } ## end sub postponed
5660
5661 =head2 C<dumpit>
5662
5663 C<dumpit> is the debugger's wrapper around dumpvar.pl.
5664
5665 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
5666 a reference to a variable (the thing to be dumped) as its input.
5667
5668 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
5669 the currently-selected filehandle, thank you very much). The current
5670 values of the package globals C<$single> and C<$trace> are backed up in
5671 lexicals, and they are turned off (this keeps the debugger from trying
5672 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
5673 preserve its current value and it is set to zero to prevent entry/exit
5674 messages from printing, and C<$doret> is localized as well and set to -2 to
5675 prevent return values from being shown.
5676
5677 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
5678 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
5679 installed version in C<@INC>, yours will be used instead. Possible security
5680 problem?).
5681
5682 It then checks to see if the subroutine C<main::dumpValue> is now defined
5683 (it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
5684 localizes the globals necessary for things to be sane when C<main::dumpValue()>
5685 is called, and picks up the variable to be dumped from the parameter list.
5686
5687 It checks the package global C<%options> to see if there's a C<dumpDepth>
5688 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
5689 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
5690 structure: -1 means dump everything.
5691
5692 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
5693 warning.
5694
5695 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
5696 and we then return to the caller.
5697
5698 =cut
5699
5700 sub dumpit {
5701
5702     # Save the current output filehandle and switch to the one
5703     # passed in as the first parameter.
5704     local ($savout) = select(shift);
5705
5706     # Save current settings of $single and $trace, and then turn them off.
5707     my $osingle = $single;
5708     my $otrace  = $trace;
5709     $single = $trace = 0;
5710
5711     # XXX Okay, what do $frame and $doret do, again?
5712     local $frame = 0;
5713     local $doret = -2;
5714
5715     # Load dumpvar.pl unless we've already got the sub we need from it.
5716     unless ( defined &main::dumpValue ) {
5717         do 'dumpvar.pl' or die $@;
5718     }
5719
5720     # If the load succeeded (or we already had dumpvalue()), go ahead
5721     # and dump things.
5722     if ( defined &main::dumpValue ) {
5723         local $\ = '';
5724         local $, = '';
5725         local $" = ' ';
5726         my $v = shift;
5727         my $maxdepth = shift || $option{dumpDepth};
5728         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
5729         &main::dumpValue( $v, $maxdepth );
5730     } ## end if (defined &main::dumpValue)
5731
5732     # Oops, couldn't load dumpvar.pl.
5733     else {
5734         local $\ = '';
5735         print $OUT "dumpvar.pl not available.\n";
5736     }
5737
5738     # Reset $single and $trace to their old values.
5739     $single = $osingle;
5740     $trace  = $otrace;
5741
5742     # Restore the old filehandle.
5743     select($savout);
5744 } ## end sub dumpit
5745
5746 =head2 C<print_trace>
5747
5748 C<print_trace>'s job is to print a stack trace. It does this via the
5749 C<dump_trace> routine, which actually does all the ferreting-out of the
5750 stack trace data. C<print_trace> takes care of formatting it nicely and
5751 printing it to the proper filehandle.
5752
5753 Parameters:
5754
5755 =over 4
5756
5757 =item *
5758
5759 The filehandle to print to.
5760
5761 =item *
5762
5763 How many frames to skip before starting trace.
5764
5765 =item *
5766
5767 How many frames to print.
5768
5769 =item *
5770
5771 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
5772
5773 =back
5774
5775 The original comment below seems to be noting that the traceback may not be
5776 correct if this routine is called in a tied method.
5777
5778 =cut
5779
5780 # Tied method do not create a context, so may get wrong message:
5781
5782 sub print_trace {
5783     local $\ = '';
5784     my $fh = shift;
5785
5786     # If this is going to a slave editor, but we're not the primary
5787     # debugger, reset it first.
5788     resetterm(1)
5789       if $fh        eq $LINEINFO    # slave editor
5790       and $LINEINFO eq $OUT         # normal output
5791       and $term_pid != $$;          # not the primary
5792
5793     # Collect the actual trace information to be formatted.
5794     # This is an array of hashes of subroutine call info.
5795     my @sub = dump_trace( $_[0] + 1, $_[1] );
5796
5797     # Grab the "short report" flag from @_.
5798     my $short = $_[2];              # Print short report, next one for sub name
5799
5800     # Run through the traceback info, format it, and print it.
5801     my $s;
5802     for ( $i = 0 ; $i <= $#sub ; $i++ ) {
5803
5804         # Drop out if the user has lost interest and hit control-C.
5805         last if $signal;
5806
5807         # Set the separator so arrys print nice.
5808         local $" = ', ';
5809
5810         # Grab and stringify the arguments if they are there.
5811         my $args =
5812           defined $sub[$i]{args}
5813           ? "(@{ $sub[$i]{args} })"
5814           : '';
5815
5816         # Shorten them up if $maxtrace says they're too long.
5817         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
5818           if length $args > $maxtrace;
5819
5820         # Get the file name.
5821         my $file = $sub[$i]{file};
5822
5823         # Put in a filename header if short is off.
5824         $file = $file eq '-e' ? $file : "file '$file'" unless $short;
5825
5826         # Get the actual sub's name, and shorten to $maxtrace's requirement.
5827         $s = $sub[$i]{sub};
5828         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
5829
5830         # Short report uses trimmed file and sub names.
5831         if ($short) {
5832             my $sub = @_ >= 4 ? $_[3] : $s;
5833             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
5834         } ## end if ($short)
5835
5836         # Non-short report includes full names.
5837         else {
5838             print $fh "$sub[$i]{context} = $s$args"
5839               . " called from $file"
5840               . " line $sub[$i]{line}\n";
5841         }
5842     } ## end for ($i = 0 ; $i <= $#sub...
5843 } ## end sub print_trace
5844
5845 =head2 dump_trace(skip[,count])
5846
5847 Actually collect the traceback information available via C<caller()>. It does
5848 some filtering and cleanup of the data, but mostly it just collects it to
5849 make C<print_trace()>'s job easier.
5850
5851 C<skip> defines the number of stack frames to be skipped, working backwards
5852 from the most current. C<count> determines the total number of frames to
5853 be returned; all of them (well, the first 10^9) are returned if C<count>
5854 is omitted.
5855
5856 This routine returns a list of hashes, from most-recent to least-recent
5857 stack frame. Each has the following keys and values:
5858
5859 =over 4
5860
5861 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
5862
5863 =item * C<sub> - subroutine name, or C<eval> information
5864
5865 =item * C<args> - undef, or a reference to an array of arguments
5866
5867 =item * C<file> - the file in which this item was defined (if any)
5868
5869 =item * C<line> - the line on which it was defined
5870
5871 =back
5872
5873 =cut
5874
5875 sub dump_trace {
5876
5877     # How many levels to skip.
5878     my $skip = shift;
5879
5880     # How many levels to show. (1e9 is a cheap way of saying "all of them";
5881     # it's unlikely that we'll have more than a billion stack frames. If you
5882     # do, you've got an awfully big machine...)
5883     my $count = shift || 1e9;
5884
5885     # We increment skip because caller(1) is the first level *back* from
5886     # the current one.  Add $skip to the count of frames so we have a
5887     # simple stop criterion, counting from $skip to $count+$skip.
5888     $skip++;
5889     $count += $skip;
5890
5891     # These variables are used to capture output from caller();
5892     my ( $p, $file, $line, $sub, $h, $context );
5893
5894     my ( $e, $r, @a, @sub, $args );
5895
5896     # XXX Okay... why'd we do that?
5897     my $nothard = not $frame & 8;
5898     local $frame = 0;
5899
5900     # Do not want to trace this.
5901     my $otrace = $trace;
5902     $trace = 0;
5903
5904     # Start out at the skip count.
5905     # If we haven't reached the number of frames requested, and caller() is
5906     # still returning something, stay in the loop. (If we pass the requested
5907     # number of stack frames, or we run out - caller() returns nothing - we
5908     # quit.
5909     # Up the stack frame index to go back one more level each time.
5910     for (
5911         $i = $skip ;
5912         $i < $count
5913         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
5914         $i++
5915       )
5916     {
5917
5918         # Go through the arguments and save them for later.
5919         @a = ();
5920         for $arg (@args) {
5921             my $type;
5922             if ( not defined $arg ) {    # undefined parameter
5923                 push @a, "undef";
5924             }
5925
5926             elsif ( $nothard and tied $arg ) {    # tied parameter
5927                 push @a, "tied";
5928             }
5929             elsif ( $nothard and $type = ref $arg ) {    # reference
5930                 push @a, "ref($type)";
5931             }
5932             else {                                       # can be stringified
5933                 local $_ =
5934                   "$arg";    # Safe to stringify now - should not call f().
5935
5936                 # Backslash any single-quotes or backslashes.
5937                 s/([\'\\])/\\$1/g;
5938
5939                 # Single-quote it unless it's a number or a colon-separated
5940                 # name.
5941                 s/(.*)/'$1'/s
5942                   unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
5943
5944                 # Turn high-bit characters into meta-whatever.
5945                 s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
5946
5947                 # Turn control characters into ^-whatever.
5948                 s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
5949
5950                 push( @a, $_ );
5951             } ## end else [ if (not defined $arg)
5952         } ## end for $arg (@args)
5953
5954         # If context is true, this is array (@)context.
5955         # If context is false, this is scalar ($) context.
5956         # If neither, context isn't defined. (This is apparently a 'can't
5957         # happen' trap.)
5958         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
5959
5960         # if the sub has args ($h true), make an anonymous array of the
5961         # dumped args.
5962         $args = $h ? [@a] : undef;
5963
5964         # remove trailing newline-whitespace-semicolon-end of line sequence
5965         # from the eval text, if any.
5966         $e =~ s/\n\s*\;\s*\Z// if $e;
5967
5968         # Escape backslashed single-quotes again if necessary.
5969         $e =~ s/([\\\'])/\\$1/g if $e;
5970
5971         # if the require flag is true, the eval text is from a require.
5972         if ($r) {
5973             $sub = "require '$e'";
5974         }
5975
5976         # if it's false, the eval text is really from an eval.
5977         elsif ( defined $r ) {
5978             $sub = "eval '$e'";
5979         }
5980
5981         # If the sub is '(eval)', this is a block eval, meaning we don't
5982         # know what the eval'ed text actually was.
5983         elsif ( $sub eq '(eval)' ) {
5984             $sub = "eval {...}";
5985         }
5986
5987         # Stick the collected information into @sub as an anonymous hash.
5988         push(
5989             @sub,
5990             {
5991                 context => $context,
5992                 sub     => $sub,
5993                 args    => $args,
5994                 file    => $file,
5995                 line    => $line
5996             }
5997         );
5998
5999         # Stop processing frames if the user hit control-C.
6000         last if $signal;
6001     } ## end for ($i = $skip ; $i < ...
6002
6003     # Restore the trace value again.
6004     $trace = $otrace;
6005     @sub;
6006 } ## end sub dump_trace
6007
6008 =head2 C<action()>
6009
6010 C<action()> takes input provided as the argument to an add-action command,
6011 either pre- or post-, and makes sure it's a complete command. It doesn't do
6012 any fancy parsing; it just keeps reading input until it gets a string
6013 without a trailing backslash.
6014
6015 =cut
6016
6017 sub action {
6018     my $action = shift;
6019
6020     while ( $action =~ s/\\$// ) {
6021
6022         # We have a backslash on the end. Read more.
6023         $action .= &gets;
6024     } ## end while ($action =~ s/\\$//)
6025
6026     # Return the assembled action.
6027     $action;
6028 } ## end sub action
6029
6030 =head2 unbalanced
6031
6032 This routine mostly just packages up a regular expression to be used
6033 to check that the thing it's being matched against has properly-matched
6034 curly braces.
6035
6036 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
6037 speeds things up by only creating the qr//'ed expression once; if it's
6038 already defined, we don't try to define it again. A speed hack.
6039
6040 =cut
6041
6042 sub unbalanced {
6043
6044     # I hate using globals!
6045     $balanced_brace_re ||= qr{
6046         ^ \{
6047              (?:
6048                  (?> [^{}] + )              # Non-parens without backtracking
6049                 |
6050                  (??{ $balanced_brace_re }) # Group with matching parens
6051               ) *
6052           \} $
6053    }x;
6054     return $_[0] !~ m/$balanced_brace_re/;
6055 } ## end sub unbalanced
6056
6057 =head2 C<gets()>
6058
6059 C<gets()> is a primitive (very primitive) routine to read continuations.
6060 It was devised for reading continuations for actions.
6061 it just reads more input with C<readline()> and returns it.
6062
6063 =cut
6064
6065 sub gets {
6066     &readline("cont: ");
6067 }
6068
6069 =head2 C<DB::system()> - handle calls to<system()> without messing up the debugger
6070
6071 The C<system()> function assumes that it can just go ahead and use STDIN and
6072 STDOUT, but under the debugger, we want it to use the debugger's input and
6073 outout filehandles.
6074
6075 C<DB::system()> socks away the program's STDIN and STDOUT, and then substitutes
6076 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
6077 and then puts everything back again.
6078
6079 =cut
6080
6081 sub system {
6082
6083     # We save, change, then restore STDIN and STDOUT to avoid fork() since
6084     # some non-Unix systems can do system() but have problems with fork().
6085     open( SAVEIN,  "<&STDIN" )  || &warn("Can't save STDIN");
6086     open( SAVEOUT, ">&STDOUT" ) || &warn("Can't save STDOUT");
6087     open( STDIN,   "<&IN" )     || &warn("Can't redirect STDIN");
6088     open( STDOUT,  ">&OUT" )    || &warn("Can't redirect STDOUT");
6089
6090     # XXX: using csh or tcsh destroys sigint retvals!
6091     system(@_);
6092     open( STDIN,  "<&SAVEIN" )  || &warn("Can't restore STDIN");
6093     open( STDOUT, ">&SAVEOUT" ) || &warn("Can't restore STDOUT");
6094     close(SAVEIN);
6095     close(SAVEOUT);
6096
6097     # most of the $? crud was coping with broken cshisms
6098     if ( $? >> 8 ) {
6099         &warn( "(Command exited ", ( $? >> 8 ), ")\n" );
6100     }
6101     elsif ($?) {
6102         &warn(
6103             "(Command died of SIG#",
6104             ( $? & 127 ),
6105             ( ( $? & 128 ) ? " -- core dumped" : "" ),
6106             ")", "\n"
6107         );
6108     } ## end elsif ($?)
6109
6110     return $?;
6111
6112 } ## end sub system
6113
6114 =head1 TTY MANAGEMENT
6115
6116 The subs here do some of the terminal management for multiple debuggers.
6117
6118 =head2 setterm
6119
6120 Top-level function called when we want to set up a new terminal for use
6121 by the debugger.
6122
6123 If the C<noTTY> debugger option was set, we'll either use the terminal
6124 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6125 to find one. If we're a forked debugger, we call C<resetterm> to try to
6126 get a whole new terminal if we can.
6127
6128 In either case, we set up the terminal next. If the C<ReadLine> option was
6129 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6130 the appropriate attributes. We then
6131
6132 =cut
6133
6134 sub setterm {
6135
6136     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6137     local $frame = 0;
6138     local $doret = -2;
6139     require Term::ReadLine;
6140
6141     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6142     if ($notty) {
6143         if ($tty) {
6144             my ( $i, $o ) = split $tty, /,/;
6145             $o = $i unless defined $o;
6146             open( IN,  "<$i" ) or die "Cannot open TTY '$i' for read: $!";
6147             open( OUT, ">$o" ) or die "Cannot open TTY '$o' for write: $!";
6148             $IN  = \*IN;
6149             $OUT = \*OUT;
6150             my $sel = select($OUT);
6151             $| = 1;
6152             select($sel);
6153         } ## end if ($tty)
6154
6155         # We don't have a TTY - try to find one via Term::Rendezvous.
6156         else {
6157             require Term::Rendezvous;
6158
6159             # See if we have anything to pass to Term::Rendezvous.
6160             # Use $HOME/.perldbtty$$ if not.
6161             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6162
6163             # Rendezvous and get the filehandles.
6164             my $term_rv = Term::Rendezvous->new( $rv );
6165             $IN  = $term_rv->IN;
6166             $OUT = $term_rv->OUT;
6167         } ## end else [ if ($tty)
6168     } ## end if ($notty)
6169
6170     # We're a daughter debugger. Try to fork off another TTY.
6171     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6172         resetterm(2);
6173     }
6174
6175     # If we shouldn't use Term::ReadLine, don't.
6176     if ( !$rl ) {
6177         $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6178     }
6179
6180     # We're using Term::ReadLine. Get all the attributes for this terminal.
6181     else {
6182         $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6183
6184         $rl_attribs = $term->Attribs;
6185         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6186           if defined $rl_attribs->{basic_word_break_characters}
6187           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6188         $rl_attribs->{special_prefixes} = '$@&%';
6189         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6190         $rl_attribs->{completion_function} = \&db_complete;
6191     } ## end else [ if (!$rl)
6192
6193     # Set up the LINEINFO filehandle.
6194     $LINEINFO = $OUT     unless defined $LINEINFO;
6195     $lineinfo = $console unless defined $lineinfo;
6196
6197     $term->MinLine(2);
6198
6199     &load_hist();
6200
6201     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6202         $term->SetHistory(@hist);
6203     }
6204
6205     # XXX Ornaments are turned on unconditionally, which is not
6206     # always a good thing.
6207     ornaments($ornaments) if defined $ornaments;
6208     $term_pid = $$;
6209 } ## end sub setterm
6210
6211 sub load_hist {
6212     $histfile //= option_val("HistFile", undef);
6213     return unless defined $histfile;
6214     open my $fh, "<", $histfile or return;
6215     local $/ = "\n";
6216     @hist = ();
6217     while (<$fh>) {
6218         chomp;
6219         push @hist, $_;
6220     }
6221     close $fh;
6222 }
6223
6224 sub save_hist {
6225     return unless defined $histfile;
6226     eval { require File::Path } or return;
6227     eval { require File::Basename } or return;
6228     File::Path::mkpath(File::Basename::dirname($histfile));
6229     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6230     $histsize //= option_val("HistSize",100);
6231     my @copy = grep { $_ ne '?' } @hist;
6232     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6233     for ($start .. $#copy) {
6234         print $fh "$copy[$_]\n";
6235     }
6236     close $fh or die "Could not write '$histfile': $!";
6237 }
6238
6239 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6240
6241 When the process being debugged forks, or the process invokes a command
6242 via C<system()> which starts a new debugger, we need to be able to get a new
6243 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6244 fight over the terminal, and you can never quite be sure who's going to get the
6245 input you're typing.
6246
6247 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6248 is tasked with doing all the necessary operating system mojo to get a new
6249 TTY (and probably another window) and to direct the new debugger to read and
6250 write there.
6251
6252 The debugger provides C<get_fork_TTY> functions which work for TCP
6253 socket servers, X11, OS/2, and Mac OS X. Other systems are not
6254 supported. You are encouraged to write C<get_fork_TTY> functions which
6255 work for I<your> platform and contribute them.
6256
6257 =head3 C<socket_get_fork_TTY>
6258
6259 =cut
6260
6261 sub connect_remoteport {
6262     require IO::Socket;
6263
6264     my $socket = IO::Socket::INET->new(
6265         Timeout  => '10',
6266         PeerAddr => $remoteport,
6267         Proto    => 'tcp',
6268     );
6269     if ( ! $socket ) {
6270         die "Unable to connect to remote host: $remoteport\n";
6271     }
6272     return $socket;
6273 }
6274
6275 sub socket_get_fork_TTY {
6276     $tty = $LINEINFO = $IN = $OUT = connect_remoteport();
6277
6278     # Do I need to worry about setting $term?
6279
6280     reset_IN_OUT( $IN, $OUT );
6281     return '';
6282 }
6283
6284 =head3 C<xterm_get_fork_TTY>
6285
6286 This function provides the C<get_fork_TTY> function for X11. If a
6287 program running under the debugger forks, a new <xterm> window is opened and
6288 the subsidiary debugger is directed there.
6289
6290 The C<open()> call is of particular note here. We have the new C<xterm>
6291 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6292 command (which prints the device name of the TTY we'll want to use for input
6293 and output to STDOUT, then C<sleep> for a very long time, routing this output
6294 to file number 3. This way we can simply read from the <XT> filehandle (which
6295 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6296
6297 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6298 properly set up.
6299
6300 =cut
6301
6302 sub xterm_get_fork_TTY {
6303     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6304     open XT,
6305 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6306  sleep 10000000' |];
6307
6308     # Get the output from 'tty' and clean it up a little.
6309     my $tty = <XT>;
6310     chomp $tty;
6311
6312     $pidprompt = '';    # Shown anyway in titlebar
6313
6314     # We need $term defined or we can not switch to the newly created xterm
6315     if ($tty ne '' && !defined $term) {
6316         require Term::ReadLine;
6317         if ( !$rl ) {
6318             $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6319         }
6320         else {
6321             $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6322         }
6323     }
6324     # There's our new TTY.
6325     return $tty;
6326 } ## end sub xterm_get_fork_TTY
6327
6328 =head3 C<os2_get_fork_TTY>
6329
6330 XXX It behooves an OS/2 expert to write the necessary documentation for this!
6331
6332 =cut
6333
6334 # This example function resets $IN, $OUT itself
6335 my $c_pipe = 0;
6336 sub os2_get_fork_TTY { # A simplification of the following (and works without):
6337     local $\  = '';
6338     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6339     my %opt = ( title => "Daughter Perl debugger $pids $name",
6340                 ($rl ? (read_by_key => 1) : ()) );
6341     require OS2::Process;
6342     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
6343       or return;
6344     $pidprompt = '';    # Shown anyway in titlebar
6345     reset_IN_OUT($in, $out);
6346     $tty = '*reset*';
6347     return '';          # Indicate that reset_IN_OUT is called
6348 } ## end sub os2_get_fork_TTY
6349
6350 =head3 C<macosx_get_fork_TTY>
6351
6352 The Mac OS X version uses AppleScript to tell Terminal.app to create
6353 a new window.
6354
6355 =cut
6356
6357 # Notes about Terminal.app's AppleScript support,
6358 # (aka things that might break in future OS versions).
6359 #
6360 # The "do script" command doesn't return a reference to the new window
6361 # it creates, but since it appears frontmost and windows are enumerated
6362 # front to back, we can use "first window" === "window 1".
6363 #
6364 # Since "do script" is implemented by supplying the argument (plus a
6365 # return character) as terminal input, there's a potential race condition
6366 # where the debugger could beat the shell to reading the command.
6367 # To prevent this, we wait for the screen to clear before proceeding.
6368 #
6369 # 10.3 and 10.4:
6370 # There's no direct accessor for the tty device name, so we fiddle
6371 # with the window title options until it says what we want.
6372 #
6373 # 10.5:
6374 # There _is_ a direct accessor for the tty device name, _and_ there's
6375 # a new possible component of the window title (the name of the settings
6376 # set).  A separate version is needed.
6377
6378 my @script_versions=
6379
6380     ([237, <<'__LEOPARD__'],
6381 tell application "Terminal"
6382     do script "clear;exec sleep 100000"
6383     tell first tab of first window
6384         copy tty to thetty
6385         set custom title to "forked perl debugger"
6386         set title displays custom title to true
6387         repeat while (length of first paragraph of (get contents)) > 0
6388             delay 0.1
6389         end repeat
6390     end tell
6391 end tell
6392 thetty
6393 __LEOPARD__
6394
6395      [100, <<'__JAGUAR_TIGER__'],
6396 tell application "Terminal"
6397     do script "clear;exec sleep 100000"
6398     tell first window
6399         set title displays shell path to false
6400         set title displays window size to false
6401         set title displays file name to false
6402         set title displays device name to true
6403         set title displays custom title to true
6404         set custom title to ""
6405         copy "/dev/" & name to thetty
6406         set custom title to "forked perl debugger"
6407         repeat while (length of first paragraph of (get contents)) > 0
6408             delay 0.1
6409         end repeat
6410     end tell
6411 end tell
6412 thetty
6413 __JAGUAR_TIGER__
6414
6415 );
6416
6417 sub macosx_get_fork_TTY
6418 {
6419     my($version,$script,$pipe,$tty);
6420
6421     return unless $version=$ENV{TERM_PROGRAM_VERSION};
6422     foreach my $entry (@script_versions) {
6423         if ($version>=$entry->[0]) {
6424             $script=$entry->[1];
6425             last;
6426         }
6427     }
6428     return unless defined($script);
6429     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
6430     $tty=readline($pipe);
6431     close($pipe);
6432     return unless defined($tty) && $tty =~ m(^/dev/);
6433     chomp $tty;
6434     return $tty;
6435 }
6436
6437 =head2 C<create_IN_OUT($flags)>
6438
6439 Create a new pair of filehandles, pointing to a new TTY. If impossible,
6440 try to diagnose why.
6441
6442 Flags are:
6443
6444 =over 4
6445
6446 =item * 1 - Don't know how to create a new TTY.
6447
6448 =item * 2 - Debugger has forked, but we can't get a new TTY.
6449
6450 =item * 4 - standard debugger startup is happening.
6451
6452 =back
6453
6454 =cut
6455
6456 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
6457
6458     # If we know how to get a new TTY, do it! $in will have
6459     # the TTY name if get_fork_TTY works.
6460     my $in = &get_fork_TTY if defined &get_fork_TTY;
6461
6462     # It used to be that
6463     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
6464
6465     if ( not defined $in ) {
6466         my $why = shift;
6467
6468         # We don't know how.
6469         print_help(<<EOP) if $why == 1;
6470 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
6471 EOP
6472
6473         # Forked debugger.
6474         print_help(<<EOP) if $why == 2;
6475 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
6476   This may be an asynchronous session, so the parent debugger may be active.
6477 EOP
6478
6479         # Note that both debuggers are fighting over the same input.
6480         print_help(<<EOP) if $why != 4;
6481   Since two debuggers fight for the same TTY, input is severely entangled.
6482
6483 EOP
6484         print_help(<<EOP);
6485   I know how to switch the output to a different window in xterms, OS/2
6486   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
6487   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
6488   B<DB::get_fork_TTY()> returning this.
6489
6490   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
6491   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
6492
6493 EOP
6494     } ## end if (not defined $in)
6495     elsif ( $in ne '' ) {
6496         TTY($in);
6497     }
6498     else {
6499         $console = '';    # Indicate no need to open-from-the-console
6500     }
6501     undef $fork_TTY;
6502 } ## end sub create_IN_OUT
6503
6504 =head2 C<resetterm>
6505
6506 Handles rejiggering the prompt when we've forked off a new debugger.
6507
6508 If the new debugger happened because of a C<system()> that invoked a
6509 program under the debugger, the arrow between the old pid and the new
6510 in the prompt has I<two> dashes instead of one.
6511
6512 We take the current list of pids and add this one to the end. If there
6513 isn't any list yet, we make one up out of the initial pid associated with
6514 the terminal and our new pid, sticking an arrow (either one-dashed or
6515 two dashed) in between them.
6516
6517 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
6518 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
6519 and try to do that.
6520
6521 =cut
6522
6523 sub resetterm {    # We forked, so we need a different TTY
6524
6525     # Needs to be passed to create_IN_OUT() as well.
6526     my $in = shift;
6527
6528     # resetterm(2): got in here because of a system() starting a debugger.
6529     # resetterm(1): just forked.
6530     my $systemed = $in > 1 ? '-' : '';
6531
6532     # If there's already a list of pids, add this to the end.
6533     if ($pids) {
6534         $pids =~ s/\]/$systemed->$$]/;
6535     }
6536
6537     # No pid list. Time to make one.
6538     else {
6539         $pids = "[$term_pid->$$]";
6540     }
6541
6542     # The prompt we're going to be using for this debugger.
6543     $pidprompt = $pids;
6544
6545     # We now 0wnz this terminal.
6546     $term_pid = $$;
6547
6548     # Just return if we're not supposed to try to create a new TTY.
6549     return unless $CreateTTY & $in;
6550
6551     # Try to create a new IN/OUT pair.
6552     create_IN_OUT($in);
6553 } ## end sub resetterm
6554
6555 =head2 C<readline>
6556
6557 First, we handle stuff in the typeahead buffer. If there is any, we shift off
6558 the next line, print a message saying we got it, add it to the terminal
6559 history (if possible), and return it.
6560
6561 If there's nothing in the typeahead buffer, check the command filehandle stack.
6562 If there are any filehandles there, read from the last one, and return the line
6563 if we got one. If not, we pop the filehandle off and close it, and try the
6564 next one up the stack.
6565
6566 If we've emptied the filehandle stack, we check to see if we've got a socket
6567 open, and we read that and return it if we do. If we don't, we just call the
6568 core C<readline()> and return its value.
6569
6570 =cut
6571
6572 sub readline {
6573
6574     # Localize to prevent it from being smashed in the program being debugged.
6575     local $.;
6576
6577     # Pull a line out of the typeahead if there's stuff there.
6578     if (@typeahead) {
6579
6580         # How many lines left.
6581         my $left = @typeahead;
6582
6583         # Get the next line.
6584         my $got = shift @typeahead;
6585
6586         # Print a message saying we got input from the typeahead.
6587         local $\ = '';
6588         print $OUT "auto(-$left)", shift, $got, "\n";
6589
6590         # Add it to the terminal history (if possible).
6591         $term->AddHistory($got)
6592           if length($got) > 1
6593           and defined $term->Features->{addHistory};
6594         return $got;
6595     } ## end if (@typeahead)
6596
6597     # We really need to read some input. Turn off entry/exit trace and
6598     # return value printing.
6599     local $frame = 0;
6600     local $doret = -2;
6601
6602     # If there are stacked filehandles to read from ...
6603     while (@cmdfhs) {
6604
6605         # Read from the last one in the stack.
6606         my $line = CORE::readline( $cmdfhs[-1] );
6607
6608         # If we got a line ...
6609         defined $line
6610           ? ( print $OUT ">> $line" and return $line )    # Echo and return
6611           : close pop @cmdfhs;                            # Pop and close
6612     } ## end while (@cmdfhs)
6613
6614     # Nothing on the filehandle stack. Socket?
6615     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
6616
6617         # Send anything we have to send.
6618         $OUT->write( join( '', @_ ) );
6619
6620         # Receive anything there is to receive.
6621         $stuff;
6622         my $stuff = '';
6623         my $buf;
6624         do {
6625             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
6626                                             # XXX Don't know. You tell me.
6627         } while length $buf and ($stuff .= $buf) !~ /\n/;
6628
6629         # What we got.
6630         $stuff;
6631     } ## end if (ref $OUT and UNIVERSAL::isa...
6632
6633     # No socket. Just read from the terminal.
6634     else {
6635         $term->readline(@_);
6636     }
6637 } ## end sub readline
6638
6639 =head1 OPTIONS SUPPORT ROUTINES
6640
6641 These routines handle listing and setting option values.
6642
6643 =head2 C<dump_option> - list the current value of an option setting
6644
6645 This routine uses C<option_val> to look up the value for an option.
6646 It cleans up escaped single-quotes and then displays the option and
6647 its value.
6648
6649 =cut
6650
6651 sub dump_option {
6652     my ( $opt, $val ) = @_;
6653     $val = option_val( $opt, 'N/A' );
6654     $val =~ s/([\\\'])/\\$1/g;
6655     printf $OUT "%20s = '%s'\n", $opt, $val;
6656 } ## end sub dump_option
6657
6658 sub options2remember {
6659     foreach my $k (@RememberOnROptions) {
6660         $option{$k} = option_val( $k, 'N/A' );
6661     }
6662     return %option;
6663 }
6664
6665 =head2 C<option_val> - find the current value of an option
6666
6667 This can't just be a simple hash lookup because of the indirect way that
6668 the option values are stored. Some are retrieved by calling a subroutine,
6669 some are just variables.
6670
6671 You must supply a default value to be used in case the option isn't set.
6672
6673 =cut
6674
6675 sub option_val {
6676     my ( $opt, $default ) = @_;
6677     my $val;
6678
6679     # Does this option exist, and is it a variable?
6680     # If so, retrieve the value via the value in %optionVars.
6681     if (    defined $optionVars{$opt}
6682         and defined ${ $optionVars{$opt} } )
6683     {
6684         $val = ${ $optionVars{$opt} };
6685     }
6686
6687     # Does this option exist, and it's a subroutine?
6688     # If so, call the subroutine via the ref in %optionAction
6689     # and capture the value.
6690     elsif ( defined $optionAction{$opt}
6691         and defined &{ $optionAction{$opt} } )
6692     {
6693         $val = &{ $optionAction{$opt} }();
6694     }
6695
6696     # If there's an action or variable for the supplied option,
6697     # but no value was set, use the default.
6698     elsif (defined $optionAction{$opt} and not defined $option{$opt}
6699         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
6700     {
6701         $val = $default;
6702     }
6703
6704     # Otherwise, do the simple hash lookup.
6705     else {
6706         $val = $option{$opt};
6707     }
6708
6709     # If the value isn't defined, use the default.
6710     # Then return whatever the value is.
6711     $val = $default unless defined $val;
6712     $val;
6713 } ## end sub option_val
6714
6715 =head2 C<parse_options>
6716
6717 Handles the parsing and execution of option setting/displaying commands.
6718
6719 An option entered by itself is assumed to be I<set me to 1> (the default value)
6720 if the option is a boolean one. If not, the user is prompted to enter a valid
6721 value or to query the current value (via C<option? >).
6722
6723 If C<option=value> is entered, we try to extract a quoted string from the
6724 value (if it is quoted). If it's not, we just use the whole value as-is.
6725
6726 We load any modules required to service this option, and then we set it: if
6727 it just gets stuck in a variable, we do that; if there's a subroutine to
6728 handle setting the option, we call that.
6729
6730 Finally, if we're running in interactive mode, we display the effect of the
6731 user's command back to the terminal, skipping this if we're setting things
6732 during initialization.
6733
6734 =cut
6735
6736 sub parse_options {
6737     local ($_) = @_;
6738     local $\ = '';
6739
6740     # These options need a value. Don't allow them to be clobbered by accident.
6741     my %opt_needs_val = map { ( $_ => 1 ) } qw{
6742       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
6743       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
6744     };
6745
6746     while (length) {
6747         my $val_defaulted;
6748
6749         # Clean off excess leading whitespace.
6750         s/^\s+// && next;
6751
6752         # Options are always all word characters, followed by a non-word
6753         # separator.
6754         s/^(\w+)(\W?)// or print( $OUT "Invalid option '$_'\n" ), last;
6755         my ( $opt, $sep ) = ( $1, $2 );
6756
6757         # Make sure that such an option exists.
6758         my $matches = grep( /^\Q$opt/ && ( $option = $_ ), @options )
6759           || grep( /^\Q$opt/i && ( $option = $_ ), @options );
6760
6761         print( $OUT "Unknown option '$opt'\n" ), next unless $matches;
6762         print( $OUT "Ambiguous option '$opt'\n" ), next if $matches > 1;
6763         my $val;
6764
6765         # '?' as separator means query, but must have whitespace after it.
6766         if ( "?" eq $sep ) {
6767             print( $OUT "Option query '$opt?' followed by non-space '$_'\n" ),
6768               last
6769               if /^\S/;
6770
6771             #&dump_option($opt);
6772         } ## end if ("?" eq $sep)
6773
6774         # Separator is whitespace (or just a carriage return).
6775         # They're going for a default, which we assume is 1.
6776         elsif ( $sep !~ /\S/ ) {
6777             $val_defaulted = 1;
6778             $val           = "1";   #  this is an evil default; make 'em set it!
6779         }
6780
6781         # Separator is =. Trying to set a value.
6782         elsif ( $sep eq "=" ) {
6783
6784             # If quoted, extract a quoted string.
6785             if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
6786                 my $quote = $1;
6787                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
6788             }
6789
6790             # Not quoted. Use the whole thing. Warn about 'option='.
6791             else {
6792                 s/^(\S*)//;
6793                 $val = $1;
6794                 print OUT qq(Option better cleared using $opt=""\n)
6795                   unless length $val;
6796             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
6797
6798         } ## end elsif ($sep eq "=")
6799
6800         # "Quoted" with [], <>, or {}.
6801         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
6802             my ($end) =
6803               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
6804             s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
6805               or print( $OUT "Unclosed option value '$opt$sep$_'\n" ), last;
6806             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
6807         } ## end else [ if ("?" eq $sep)
6808
6809         # Exclude non-booleans from getting set to 1 by default.
6810         if ( $opt_needs_val{$option} && $val_defaulted ) {
6811             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
6812             print $OUT
6813 "Option '$opt' is non-boolean.  Use '$cmd $option=VAL' to set, '$cmd $option?' to query\n";
6814             next;
6815         } ## end if ($opt_needs_val{$option...
6816
6817         # Save the option value.
6818         $option{$option} = $val if defined $val;
6819
6820         # Load any module that this option requires.
6821         eval qq{
6822                 local \$frame = 0;
6823                 local \$doret = -2;
6824                 require '$optionRequire{$option}';
6825                 1;
6826                } || die $@   # XXX: shouldn't happen
6827           if defined $optionRequire{$option}
6828           && defined $val;
6829
6830         # Set it.
6831         # Stick it in the proper variable if it goes in a variable.
6832         ${ $optionVars{$option} } = $val
6833           if defined $optionVars{$option}
6834           && defined $val;
6835
6836         # Call the appropriate sub if it gets set via sub.
6837         &{ $optionAction{$option} }($val)
6838           if defined $optionAction{$option}
6839           && defined &{ $optionAction{$option} }
6840           && defined $val;
6841
6842         # Not initialization - echo the value we set it to.
6843         dump_option($option) unless $OUT eq \*STDERR;
6844     } ## end while (length)
6845 } ## end sub parse_options
6846
6847 =head1 RESTART SUPPORT
6848
6849 These routines are used to store (and restore) lists of items in environment
6850 variables during a restart.
6851
6852 =head2 set_list
6853
6854 Set_list packages up items to be stored in a set of environment variables
6855 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
6856 the values). Values outside the standard ASCII charset are stored by encoding
6857 then as hexadecimal values.
6858
6859 =cut
6860
6861 sub set_list {
6862     my ( $stem, @list ) = @_;
6863     my $val;
6864
6865     # VAR_n: how many we have. Scalar assignment gets the number of items.
6866     $ENV{"${stem}_n"} = @list;
6867
6868     # Grab each item in the list, escape the backslashes, encode the non-ASCII
6869     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
6870     for $i ( 0 .. $#list ) {
6871         $val = $list[$i];
6872         $val =~ s/\\/\\\\/g;
6873         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
6874         $ENV{"${stem}_$i"} = $val;
6875     } ## end for $i (0 .. $#list)
6876 } ## end sub set_list
6877
6878 =head2 get_list
6879
6880 Reverse the set_list operation: grab VAR_n to see how many we should be getting
6881 back, and then pull VAR_0, VAR_1. etc. back out.
6882
6883 =cut
6884
6885 sub get_list {
6886     my $stem = shift;
6887     my @list;
6888     my $n = delete $ENV{"${stem}_n"};
6889     my $val;
6890     for $i ( 0 .. $n - 1 ) {
6891         $val = delete $ENV{"${stem}_$i"};
6892         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
6893         push @list, $val;
6894     }
6895     @list;
6896 } ## end sub get_list
6897
6898 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
6899
6900 =head2 catch()
6901
6902 The C<catch()> subroutine is the essence of fast and low-impact. We simply
6903 set an already-existing global scalar variable to a constant value. This
6904 avoids allocating any memory possibly in the middle of something that will
6905 get all confused if we do, particularly under I<unsafe signals>.
6906
6907 =cut
6908
6909 sub catch {
6910     $signal = 1;
6911     return;    # Put nothing on the stack - malloc/free land!
6912 }
6913
6914 =head2 C<warn()>
6915
6916 C<warn> emits a warning, by joining together its arguments and printing
6917 them, with couple of fillips.
6918
6919 If the composited message I<doesn't> end with a newline, we automatically
6920 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
6921 to be set to the filehandle to be used to output warnings; it makes no
6922 assumptions about what filehandles are available.
6923
6924 =cut
6925
6926 sub warn {
6927     my ($msg) = join( "", @_ );
6928     $msg .= ": $!\n" unless $msg =~ /\n$/;
6929     local $\ = '';
6930     print $OUT $msg;
6931 } ## end sub warn
6932
6933 =head1 INITIALIZATION TTY SUPPORT
6934
6935 =head2 C<reset_IN_OUT>
6936
6937 This routine handles restoring the debugger's input and output filehandles
6938 after we've tried and failed to move them elsewhere.  In addition, it assigns
6939 the debugger's output filehandle to $LINEINFO if it was already open there.
6940
6941 =cut
6942
6943 sub reset_IN_OUT {
6944     my $switch_li = $LINEINFO eq $OUT;
6945
6946     # If there's a term and it's able to get a new tty, try to get one.
6947     if ( $term and $term->Features->{newTTY} ) {
6948         ( $IN, $OUT ) = ( shift, shift );
6949         $term->newTTY( $IN, $OUT );
6950     }
6951
6952     # This term can't get a new tty now. Better luck later.
6953     elsif ($term) {
6954         &warn("Too late to set IN/OUT filehandles, enabled on next 'R'!\n");
6955     }
6956
6957     # Set the filehndles up as they were.
6958     else {
6959         ( $IN, $OUT ) = ( shift, shift );
6960     }
6961
6962     # Unbuffer the output filehandle.
6963     my $o = select $OUT;
6964     $| = 1;
6965     select $o;
6966
6967     # Point LINEINFO to the same output filehandle if it was there before.
6968     $LINEINFO = $OUT if $switch_li;
6969 } ## end sub reset_IN_OUT
6970
6971 =head1 OPTION SUPPORT ROUTINES
6972
6973 The following routines are used to process some of the more complicated
6974 debugger options.
6975
6976 =head2 C<TTY>
6977
6978 Sets the input and output filehandles to the specified files or pipes.
6979 If the terminal supports switching, we go ahead and do it. If not, and
6980 there's already a terminal in place, we save the information to take effect
6981 on restart.
6982
6983 If there's no terminal yet (for instance, during debugger initialization),
6984 we go ahead and set C<$console> and C<$tty> to the file indicated.
6985
6986 =cut
6987
6988 sub TTY {
6989
6990     if ( @_ and $term and $term->Features->{newTTY} ) {
6991
6992         # This terminal supports switching to a new TTY.
6993         # Can be a list of two files, or on string containing both names,
6994         # comma-separated.
6995         # XXX Should this perhaps be an assignment from @_?
6996         my ( $in, $out ) = shift;
6997         if ( $in =~ /,/ ) {
6998
6999             # Split list apart if supplied.
7000             ( $in, $out ) = split /,/, $in, 2;
7001         }
7002         else {
7003
7004             # Use the same file for both input and output.
7005             $out = $in;
7006         }
7007
7008         # Open file onto the debugger's filehandles, if you can.
7009         open IN,  $in     or die "cannot open '$in' for read: $!";
7010         open OUT, ">$out" or die "cannot open '$out' for write: $!";
7011
7012         # Swap to the new filehandles.
7013         reset_IN_OUT( \*IN, \*OUT );
7014
7015         # Save the setting for later.
7016         return $tty = $in;
7017     } ## end if (@_ and $term and $term...
7018
7019     # Terminal doesn't support new TTY, or doesn't support readline.
7020     # Can't do it now, try restarting.
7021     &warn("Too late to set TTY, enabled on next 'R'!\n") if $term and @_;
7022
7023     # Useful if done through PERLDB_OPTS:
7024     $console = $tty = shift if @_;
7025
7026     # Return whatever the TTY is.
7027     $tty or $console;
7028 } ## end sub TTY
7029
7030 =head2 C<noTTY>
7031
7032 Sets the C<$notty> global, controlling whether or not the debugger tries to
7033 get a terminal to read from. If called after a terminal is already in place,
7034 we save the value to use it if we're restarted.
7035
7036 =cut
7037
7038 sub noTTY {
7039     if ($term) {
7040         &warn("Too late to set noTTY, enabled on next 'R'!\n") if @_;
7041     }
7042     $notty = shift if @_;
7043     $notty;
7044 } ## end sub noTTY
7045
7046 =head2 C<ReadLine>
7047
7048 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
7049 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
7050 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
7051 the value in case a restart is done so we can change it then.
7052
7053 =cut
7054
7055 sub ReadLine {
7056     if ($term) {
7057         &warn("Too late to set ReadLine, enabled on next 'R'!\n") if @_;
7058     }
7059     $rl = shift if @_;
7060     $rl;
7061 } ## end sub ReadLine
7062
7063 =head2 C<RemotePort>
7064
7065 Sets the port that the debugger will try to connect to when starting up.
7066 If the terminal's already been set up, we can't do it, but we remember the
7067 setting in case the user does a restart.
7068
7069 =cut
7070
7071 sub RemotePort {
7072     if ($term) {
7073         &warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
7074     }
7075     $remoteport = shift if @_;
7076     $remoteport;
7077 } ## end sub RemotePort
7078
7079 =head2 C<tkRunning>
7080
7081 Checks with the terminal to see if C<Tk> is running, and returns true or
7082 false. Returns false if the current terminal doesn't support C<readline>.
7083
7084 =cut
7085
7086 sub tkRunning {
7087     if ( ${ $term->Features }{tkRunning} ) {
7088         return $term->tkRunning(@_);
7089     }
7090     else {
7091         local $\ = '';
7092         print $OUT "tkRunning not supported by current ReadLine package.\n";
7093         0;
7094     }
7095 } ## end sub tkRunning
7096
7097 =head2 C<NonStop>
7098
7099 Sets nonstop mode. If a terminal's already been set up, it's too late; the
7100 debugger remembers the setting in case you restart, though.
7101
7102 =cut
7103
7104 sub NonStop {
7105     if ($term) {
7106         &warn("Too late to set up NonStop mode, enabled on next 'R'!\n")
7107           if @_;
7108     }
7109     $runnonstop = shift if @_;
7110     $runnonstop;
7111 } ## end sub NonStop
7112
7113 sub DollarCaretP {
7114     if ($term) {
7115         &warn("Some flag changes could not take effect until next 'R'!\n")
7116           if @_;
7117     }
7118     $^P = parse_DollarCaretP_flags(shift) if @_;
7119     expand_DollarCaretP_flags($^P);
7120 }
7121
7122 =head2 C<pager>
7123
7124 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
7125 there already.
7126
7127 =cut
7128
7129 sub pager {
7130     if (@_) {
7131         $pager = shift;
7132         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
7133     }
7134     $pager;
7135 } ## end sub pager
7136
7137 =head2 C<shellBang>
7138
7139 Sets the shell escape command, and generates a printable copy to be used
7140 in the help.
7141
7142 =cut
7143
7144 sub shellBang {
7145
7146     # If we got an argument, meta-quote it, and add '\b' if it
7147     # ends in a word character.
7148     if (@_) {
7149         $sh = quotemeta shift;
7150         $sh .= "\\b" if $sh =~ /\w$/;
7151     }
7152
7153     # Generate the printable version for the help:
7154     $psh = $sh;    # copy it
7155     $psh =~ s/\\b$//;        # Take off trailing \b if any
7156     $psh =~ s/\\(.)/$1/g;    # De-escape
7157     $psh;                    # return the printable version
7158 } ## end sub shellBang
7159
7160 =head2 C<ornaments>
7161
7162 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7163 was passed as the argument. (This means you can't override the terminal's
7164 ornaments.)
7165
7166 =cut
7167
7168 sub ornaments {
7169     if ( defined $term ) {
7170
7171         # We don't want to show warning backtraces, but we do want die() ones.
7172         local ( $warnLevel, $dieLevel ) = ( 0, 1 );
7173
7174         # No ornaments if the terminal doesn't support them.
7175         return '' unless $term->Features->{ornaments};
7176         eval { $term->ornaments(@_) } || '';
7177     }
7178
7179     # Use what was passed in if we can't determine it ourselves.
7180     else {
7181         $ornaments = shift;
7182     }
7183 } ## end sub ornaments
7184
7185 =head2 C<recallCommand>
7186
7187 Sets the recall command, and builds a printable version which will appear in
7188 the help text.
7189
7190 =cut
7191
7192 sub recallCommand {
7193
7194     # If there is input, metaquote it. Add '\b' if it ends with a word
7195     # character.
7196     if (@_) {
7197         $rc = quotemeta shift;
7198         $rc .= "\\b" if $rc =~ /\w$/;
7199     }
7200
7201     # Build it into a printable version.
7202     $prc = $rc;    # Copy it
7203     $prc =~ s/\\b$//;        # Remove trailing \b
7204     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7205     $prc;                    # Return the printable version
7206 } ## end sub recallCommand
7207
7208 =head2 C<LineInfo> - where the line number information goes
7209
7210 Called with no arguments, returns the file or pipe that line info should go to.
7211
7212 Called with an argument (a file or a pipe), it opens that onto the
7213 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7214 file or pipe again to the caller.
7215
7216 =cut
7217
7218 sub LineInfo {
7219     return $lineinfo unless @_;
7220     $lineinfo = shift;
7221
7222     #  If this is a valid "thing to be opened for output", tack a
7223     # '>' onto the front.
7224     my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7225
7226     # If this is a pipe, the stream points to a slave editor.
7227     $slave_editor = ( $stream =~ /^\|/ );
7228
7229     # Open it up and unbuffer it.
7230     open( LINEINFO, "$stream" ) || &warn("Cannot open '$stream' for write");
7231     $LINEINFO = \*LINEINFO;
7232     my $save = select($LINEINFO);
7233     $| = 1;
7234     select($save);
7235
7236     # Hand the file or pipe back again.
7237     $lineinfo;
7238 } ## end sub LineInfo
7239
7240 =head1 COMMAND SUPPORT ROUTINES
7241
7242 These subroutines provide functionality for various commands.
7243
7244 =head2 C<list_modules>
7245
7246 For the C<M> command: list modules loaded and their versions.
7247 Essentially just runs through the keys in %INC, picks each package's
7248 C<$VERSION> variable, gets the file name, and formats the information
7249 for output.
7250
7251 =cut
7252
7253 sub list_modules {    # versions
7254     my %version;
7255     my $file;
7256
7257     # keys are the "as-loaded" name, values are the fully-qualified path
7258     # to the file itself.
7259     for ( keys %INC ) {
7260         $file = $_;                                # get the module name
7261         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
7262         s,/,::,g;                                  # change '/' to '::'
7263         s/^perl5db$/DB/;                           # Special case: debugger
7264                                                    # moves to package DB
7265         s/^Term::ReadLine::readline$/readline/;    # simplify readline
7266
7267         # If the package has a $VERSION package global (as all good packages
7268         # should!) decode it and save as partial message.
7269         if ( defined ${ $_ . '::VERSION' } ) {
7270             $version{$file} = "${ $_ . '::VERSION' } from ";
7271         }
7272
7273         # Finish up the message with the file the package came from.
7274         $version{$file} .= $INC{$file};
7275     } ## end for (keys %INC)
7276
7277     # Hey, dumpit() formats a hash nicely, so why not use it?
7278     dumpit( $OUT, \%version );
7279 } ## end sub list_modules
7280
7281 =head2 C<sethelp()>
7282
7283 Sets up the monster string used to format and print the help.
7284
7285 =head3 HELP MESSAGE FORMAT
7286
7287 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
7288 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
7289 easy to parse and portable, but which still allows the help to be a little
7290 nicer than just plain text.
7291
7292 Essentially, you define the command name (usually marked up with C<< B<> >>
7293 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
7294 newline. The descriptive text can also be marked up in the same way. If you
7295 need to continue the descriptive text to another line, start that line with
7296 just tabs and then enter the marked-up text.
7297
7298 If you are modifying the help text, I<be careful>. The help-string parser is
7299 not very sophisticated, and if you don't follow these rules it will mangle the
7300 help beyond hope until you fix the string.
7301
7302 =cut
7303
7304 sub sethelp {
7305
7306     # XXX: make sure there are tabs between the command and explanation,
7307     #      or print_help will screw up your formatting if you have
7308     #      eeevil ornaments enabled.  This is an insane mess.
7309
7310     $help = "
7311 Help is currently only available for the new 5.8 command set.
7312 No help is available for the old command set.
7313 We assume you know what you're doing if you switch to it.
7314
7315 B<T>        Stack trace.
7316 B<s> [I<expr>]    Single step [in I<expr>].
7317 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7318 <B<CR>>        Repeat last B<n> or B<s> command.
7319 B<r>        Return from current subroutine.
7320 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7321         at the specified position.
7322 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7323 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7324 B<l> I<line>        List single I<line>.
7325 B<l> I<subname>    List first window of lines from subroutine.
7326 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7327 B<l>        List next window of lines.
7328 B<->        List previous window of lines.
7329 B<v> [I<line>]    View window around I<line>.
7330 B<.>        Return to the executed line.
7331 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7332         I<filename> may be either the full name of the file, or a regular
7333         expression matching the full file name:
7334         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7335         Evals (with saved bodies) are considered to be filenames:
7336         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7337         (in the order of execution).
7338 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7339 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7340 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
7341 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7342 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth).
7343 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
7344 B<b>        Sets breakpoint on current line)
7345 B<b> [I<line>] [I<condition>]
7346         Set breakpoint; I<line> defaults to the current execution line;
7347         I<condition> breaks if it evaluates to true, defaults to '1'.
7348 B<b> I<subname> [I<condition>]
7349         Set breakpoint at first line of subroutine.
7350 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7351 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7352 B<b> B<postpone> I<subname> [I<condition>]
7353         Set breakpoint at first line of subroutine after
7354         it is compiled.
7355 B<b> B<compile> I<subname>
7356         Stop after the subroutine is compiled.
7357 B<B> [I<line>]    Delete the breakpoint for I<line>.
7358 B<B> I<*>             Delete all breakpoints.
7359 B<a> [I<line>] I<command>
7360         Set an action to be done before the I<line> is executed;
7361         I<line> defaults to the current execution line.
7362         Sequence is: check for breakpoint/watchpoint, print line
7363         if necessary, do action, prompt user if necessary,
7364         execute line.
7365 B<a>        Does nothing
7366 B<A> [I<line>]    Delete the action for I<line>.
7367 B<A> I<*>             Delete all actions.
7368 B<w> I<expr>        Add a global watch-expression.
7369 B<w>             Does nothing
7370 B<W> I<expr>        Delete a global watch-expression.
7371 B<W> I<*>             Delete all watch-expressions.
7372 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7373         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7374 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7375 B<x> I<expr>        Evals expression in list context, dumps the result.
7376 B<m> I<expr>        Evals expression in list context, prints methods callable
7377         on the first element of the result.
7378 B<m> I<class>        Prints methods callable via the given class.
7379 B<M>        Show versions of loaded modules.
7380 B<i> I<class>       Prints nested parents of given class.
7381 B<e>         Display current thread id.
7382 B<E>         Display all thread ids the current one will be identified: <n>.
7383 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7384
7385 B<<> ?            List Perl commands to run before each prompt.
7386 B<<> I<expr>        Define Perl command to run before each prompt.
7387 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7388 B<< *>                Delete the list of perl commands to run before each prompt.
7389 B<>> ?            List Perl commands to run after each prompt.
7390 B<>> I<expr>        Define Perl command to run after each prompt.
7391 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7392 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
7393 B<{> I<db_command>    Define debugger command to run before each prompt.
7394 B<{> ?            List debugger commands to run before each prompt.
7395 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7396 B<{ *>             Delete the list of debugger commands to run before each prompt.
7397 B<$prc> I<number>    Redo a previous command (default previous command).
7398 B<$prc> I<-number>    Redo number'th-to-last command.
7399 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7400         See 'B<O> I<recallCommand>' too.
7401 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7402       . (
7403         $rc eq $sh
7404         ? ""
7405         : "
7406 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7407       ) . "
7408         See 'B<O> I<shellBang>' too.
7409 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
7410 B<save> I<file>       Save current debugger session (actual history) to I<file>.
7411 B<rerun>           Rerun session to current position.
7412 B<rerun> I<n>         Rerun session to numbered command.
7413 B<rerun> I<-n>        Rerun session to number'th-to-last command.
7414 B<H> I<-number>    Display last number commands (default all).
7415 B<H> I<*>          Delete complete history.
7416 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7417 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7418 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarily select()ed as well.
7419 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7420 I<command>        Execute as a perl statement in current package.
7421 B<R>        Pure-man-restart of debugger, some of debugger state
7422         and command-line options may be lost.
7423         Currently the following settings are preserved:
7424         history, breakpoints and actions, debugger B<O>ptions
7425         and the following command-line options: I<-w>, I<-I>, I<-e>.
7426
7427 B<o> [I<opt>] ...    Set boolean option to true
7428 B<o> [I<opt>B<?>]    Query options
7429 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7430         Set options.  Use quotes if spaces in value.
7431     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7432     I<pager>            program for output of \"|cmd\";
7433     I<tkRunning>            run Tk while prompting (with ReadLine);
7434     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7435     I<inhibit_exit>        Allows stepping off the end of the script.
7436     I<ImmediateStop>        Debugger should stop as early as possible.
7437     I<RemotePort>            Remote hostname:port for remote debugging
7438   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7439     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7440     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7441     I<globPrint>             whether to print contents of globs;
7442     I<DumpDBFiles>         dump arrays holding debugged files;
7443     I<DumpPackages>         dump symbol tables of packages;
7444     I<DumpReused>             dump contents of \"reused\" addresses;
7445     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7446     I<bareStringify>         Do not print the overload-stringified value;
7447   Other options include:
7448     I<PrintRet>        affects printing of return value after B<r> command,
7449     I<frame>        affects printing messages on subroutine entry/exit.
7450     I<AutoTrace>    affects printing messages on possible breaking points.
7451     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7452     I<ornaments>     affects screen appearance of the command line.
7453     I<CreateTTY>     bits control attempts to create a new TTY on events:
7454             1: on fork()    2: debugger is started inside debugger
7455             4: on startup
7456     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7457     You can put additional initialization options I<TTY>, I<noTTY>,
7458     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7459     B<R> after you set them).
7460
7461 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7462 B<h>        Summary of debugger commands.
7463 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7464 B<h h>        Long help for debugger commands
7465 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7466         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7467         Set B<\$DB::doccmd> to change viewer.
7468
7469 Type '|h h' for a paged display if this was too hard to read.
7470
7471 ";    # Fix balance of vi % matching: }}}}
7472
7473     #  note: tabs in the following section are not-so-helpful
7474     $summary = <<"END_SUM";
7475 I<List/search source lines:>               I<Control script execution:>
7476   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7477   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7478   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
7479   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7480   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7481   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
7482 I<Debugger controls:>                        B<L>           List break/watch/actions
7483   B<o> [...]     Set debugger options        B<t> [I<n>] [I<expr>] Toggle trace [max depth] ][trace expr]
7484   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7485   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
7486   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7487   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
7488   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
7489   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
7490   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7491   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7492 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7493   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7494   B<p> I<expr>         Print expression (uses script's current package).
7495   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7496   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7497   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
7498   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7499   B<e>     Display thread id     B<E> Display all thread ids.
7500 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7501 END_SUM
7502
7503     # ')}}; # Fix balance of vi % matching
7504
7505     # and this is really numb...
7506     $pre580_help = "
7507 B<T>        Stack trace.
7508 B<s> [I<expr>]    Single step [in I<expr>].
7509 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7510 B<CR>>        Repeat last B<n> or B<s> command.
7511 B<r>        Return from current subroutine.
7512 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7513         at the specified position.
7514 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7515 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7516 B<l> I<line>        List single I<line>.
7517 B<l> I<subname>    List first window of lines from subroutine.
7518 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7519 B<l>        List next window of lines.
7520 B<->        List previous window of lines.
7521 B<w> [I<line>]    List window around I<line>.
7522 B<.>        Return to the executed line.
7523 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7524         I<filename> may be either the full name of the file, or a regular
7525         expression matching the full file name:
7526         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7527         Evals (with saved bodies) are considered to be filenames:
7528         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7529         (in the order of execution).
7530 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7531 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7532 B<L>        List all breakpoints and actions.
7533 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7534 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth) .
7535 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
7536 B<b> [I<line>] [I<condition>]
7537         Set breakpoint; I<line> defaults to the current execution line;
7538         I<condition> breaks if it evaluates to true, defaults to '1'.
7539 B<b> I<subname> [I<condition>]
7540         Set breakpoint at first line of subroutine.
7541 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7542 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7543 B<b> B<postpone> I<subname> [I<condition>]
7544         Set breakpoint at first line of subroutine after
7545         it is compiled.
7546 B<b> B<compile> I<subname>
7547         Stop after the subroutine is compiled.
7548 B<d> [I<line>]    Delete the breakpoint for I<line>.
7549 B<D>        Delete all breakpoints.
7550 B<a> [I<line>] I<command>
7551         Set an action to be done before the I<line> is executed;
7552         I<line> defaults to the current execution line.
7553         Sequence is: check for breakpoint/watchpoint, print line
7554         if necessary, do action, prompt user if necessary,
7555         execute line.
7556 B<a> [I<line>]    Delete the action for I<line>.
7557 B<A>        Delete all actions.
7558 B<W> I<expr>        Add a global watch-expression.
7559 B<W>        Delete all watch-expressions.
7560 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7561         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7562 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7563 B<x> I<expr>        Evals expression in list context, dumps the result.
7564 B<m> I<expr>        Evals expression in list context, prints methods callable
7565         on the first element of the result.
7566 B<m> I<class>        Prints methods callable via the given class.
7567
7568 B<<> ?            List Perl commands to run before each prompt.
7569 B<<> I<expr>        Define Perl command to run before each prompt.
7570 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7571 B<>> ?            List Perl commands to run after each prompt.
7572 B<>> I<expr>        Define Perl command to run after each prompt.
7573 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7574 B<{> I<db_command>    Define debugger command to run before each prompt.
7575 B<{> ?            List debugger commands to run before each prompt.
7576 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7577 B<$prc> I<number>    Redo a previous command (default previous command).
7578 B<$prc> I<-number>    Redo number'th-to-last command.
7579 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7580         See 'B<O> I<recallCommand>' too.
7581 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7582       . (
7583         $rc eq $sh
7584         ? ""
7585         : "
7586 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7587       ) . "
7588         See 'B<O> I<shellBang>' too.
7589 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
7590 B<H> I<-number>    Display last number commands (default all).
7591 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7592 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7593 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7594 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7595 I<command>        Execute as a perl statement in current package.
7596 B<v>        Show versions of loaded modules.
7597 B<R>        Pure-man-restart of debugger, some of debugger state
7598         and command-line options may be lost.
7599         Currently the following settings are preserved:
7600         history, breakpoints and actions, debugger B<O>ptions
7601         and the following command-line options: I<-w>, I<-I>, I<-e>.
7602
7603 B<O> [I<opt>] ...    Set boolean option to true
7604 B<O> [I<opt>B<?>]    Query options
7605 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7606         Set options.  Use quotes if spaces in value.
7607     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7608     I<pager>            program for output of \"|cmd\";
7609     I<tkRunning>            run Tk while prompting (with ReadLine);
7610     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7611     I<inhibit_exit>        Allows stepping off the end of the script.
7612     I<ImmediateStop>        Debugger should stop as early as possible.
7613     I<RemotePort>            Remote hostname:port for remote debugging
7614   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7615     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7616     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7617     I<globPrint>             whether to print contents of globs;
7618     I<DumpDBFiles>         dump arrays holding debugged files;
7619     I<DumpPackages>         dump symbol tables of packages;
7620     I<DumpReused>             dump contents of \"reused\" addresses;
7621     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7622     I<bareStringify>         Do not print the overload-stringified value;
7623   Other options include:
7624     I<PrintRet>        affects printing of return value after B<r> command,
7625     I<frame>        affects printing messages on subroutine entry/exit.
7626     I<AutoTrace>    affects printing messages on possible breaking points.
7627     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7628     I<ornaments>     affects screen appearance of the command line.
7629     I<CreateTTY>     bits control attempts to create a new TTY on events:
7630             1: on fork()    2: debugger is started inside debugger
7631             4: on startup
7632     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7633     You can put additional initialization options I<TTY>, I<noTTY>,
7634     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7635     B<R> after you set them).
7636
7637 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7638 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7639 B<h h>        Summary of debugger commands.
7640 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7641         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7642         Set B<\$DB::doccmd> to change viewer.
7643
7644 Type '|h' for a paged display if this was too hard to read.
7645
7646 ";    # Fix balance of vi % matching: }}}}
7647
7648     #  note: tabs in the following section are not-so-helpful
7649     $pre580_summary = <<"END_SUM";
7650 I<List/search source lines:>               I<Control script execution:>
7651   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7652   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7653   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
7654   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7655   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7656   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
7657 I<Debugger controls:>                        B<L>           List break/watch/actions
7658   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7659   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7660   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
7661   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7662   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
7663   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
7664   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7665   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7666 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7667   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7668   B<p> I<expr>         Print expression (uses script's current package).
7669   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7670   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7671   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
7672   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7673 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7674 END_SUM
7675
7676     # ')}}; # Fix balance of vi % matching
7677
7678 } ## end sub sethelp
7679
7680 =head2 C<print_help()>
7681
7682 Most of what C<print_help> does is just text formatting. It finds the
7683 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
7684 terminal control characters to simulate them (courtesy of
7685 C<Term::ReadLine::TermCap>).
7686
7687 =cut
7688
7689 sub print_help {
7690     local $_ = shift;
7691
7692     # Restore proper alignment destroyed by eeevil I<> and B<>
7693     # ornaments: A pox on both their houses!
7694     #
7695     # A help command will have everything up to and including
7696     # the first tab sequence padded into a field 16 (or if indented 20)
7697     # wide.  If it's wider than that, an extra space will be added.
7698     s{
7699         ^                       # only matters at start of line
7700           ( \040{4} | \t )*     # some subcommands are indented
7701           ( < ?                 # so <CR> works
7702             [BI] < [^\t\n] + )  # find an eeevil ornament
7703           ( \t+ )               # original separation, discarded
7704           ( .* )                # this will now start (no earlier) than
7705                                 # column 16
7706     } {
7707         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
7708         my $clean = $command;
7709         $clean =~ s/[BI]<([^>]*)>/$1/g;
7710
7711         # replace with this whole string:
7712         ($leadwhite ? " " x 4 : "")
7713       . $command
7714       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
7715       . $text;
7716
7717     }mgex;
7718
7719     s{                          # handle bold ornaments
7720        B < ( [^>] + | > ) >
7721     } {
7722           $Term::ReadLine::TermCap::rl_term_set[2]
7723         . $1
7724         . $Term::ReadLine::TermCap::rl_term_set[3]
7725     }gex;
7726
7727     s{                         # handle italic ornaments
7728        I < ( [^>] + | > ) >
7729     } {
7730           $Term::ReadLine::TermCap::rl_term_set[0]
7731         . $1
7732         . $Term::ReadLine::TermCap::rl_term_set[1]
7733     }gex;
7734
7735     local $\ = '';
7736     print $OUT $_;
7737 } ## end sub print_help
7738
7739 =head2 C<fix_less>
7740
7741 This routine does a lot of gyrations to be sure that the pager is C<less>.
7742 It checks for C<less> masquerading as C<more> and records the result in
7743 C<$fixed_less> so we don't have to go through doing the stats again.
7744
7745 =cut
7746
7747 sub fix_less {
7748
7749     # We already know if this is set.
7750     return if $fixed_less;
7751
7752     # Pager is less for sure.
7753     my $is_less = $pager =~ /\bless\b/;
7754     if ( $pager =~ /\bmore\b/ ) {
7755
7756         # Nope, set to more. See what's out there.
7757         my @st_more = stat('/usr/bin/more');
7758         my @st_less = stat('/usr/bin/less');
7759
7760         # is it really less, pretending to be more?
7761              $is_less = @st_more
7762           && @st_less
7763           && $st_more[0] == $st_less[0]
7764           && $st_more[1] == $st_less[1];
7765     } ## end if ($pager =~ /\bmore\b/)
7766
7767     # changes environment!
7768     # 'r' added so we don't do (slow) stats again.
7769     $fixed_less = 1 if $is_less;
7770 } ## end sub fix_less
7771
7772 =head1 DIE AND WARN MANAGEMENT
7773
7774 =head2 C<diesignal>
7775
7776 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
7777 to debug a debugger problem.
7778
7779 It does its best to report the error that occurred, and then forces the
7780 program, debugger, and everything to die.
7781
7782 =cut
7783
7784 sub diesignal {
7785
7786     # No entry/exit messages.
7787     local $frame = 0;
7788
7789     # No return value prints.
7790     local $doret = -2;
7791
7792     # set the abort signal handling to the default (just terminate).
7793     $SIG{'ABRT'} = 'DEFAULT';
7794
7795     # If we enter the signal handler recursively, kill myself with an
7796     # abort signal (so we just terminate).
7797     kill 'ABRT', $$ if $panic++;
7798
7799     # If we can show detailed info, do so.
7800     if ( defined &Carp::longmess ) {
7801
7802         # Don't recursively enter the warn handler, since we're carping.
7803         local $SIG{__WARN__} = '';
7804
7805         # Skip two levels before reporting traceback: we're skipping
7806         # mydie and confess.
7807         local $Carp::CarpLevel = 2;    # mydie + confess
7808
7809         # Tell us all about it.
7810         &warn( Carp::longmess("Signal @_") );
7811     }
7812
7813     # No Carp. Tell us about the signal as best we can.
7814     else {
7815         local $\ = '';
7816         print $DB::OUT "Got signal @_\n";
7817     }
7818
7819     # Drop dead.
7820     kill 'ABRT', $$;
7821 } ## end sub diesignal
7822
7823 =head2 C<dbwarn>
7824
7825 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
7826 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
7827
7828 =cut
7829
7830 sub dbwarn {
7831
7832     # No entry/exit trace.
7833     local $frame = 0;
7834
7835     # No return value printing.
7836     local $doret = -2;
7837
7838     # Turn off warn and die handling to prevent recursive entries to this
7839     # routine.
7840     local $SIG{__WARN__} = '';
7841     local $SIG{__DIE__}  = '';
7842
7843     # Load Carp if we can. If $^S is false (current thing being compiled isn't
7844     # done yet), we may not be able to do a require.
7845     eval { require Carp }
7846       if defined $^S;    # If error/warning during compilation,
7847                          # require may be broken.
7848
7849     # Use the core warn() unless Carp loaded OK.
7850     CORE::warn( @_,
7851         "\nCannot print stack trace, load with -MCarp option to see stack" ),
7852       return
7853       unless defined &Carp::longmess;
7854
7855     # Save the current values of $single and $trace, and then turn them off.
7856     my ( $mysingle, $mytrace ) = ( $single, $trace );
7857     $single = 0;
7858     $trace  = 0;
7859
7860     # We can call Carp::longmess without its being "debugged" (which we
7861     # don't want - we just want to use it!). Capture this for later.
7862     my $mess = Carp::longmess(@_);
7863
7864     # Restore $single and $trace to their original values.
7865     ( $single, $trace ) = ( $mysingle, $mytrace );
7866
7867     # Use the debugger's own special way of printing warnings to print
7868     # the stack trace message.
7869     &warn($mess);
7870 } ## end sub dbwarn
7871
7872 =head2 C<dbdie>
7873
7874 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
7875 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
7876 single stepping and tracing during the call to C<Carp::longmess> to avoid
7877 debugging it - we just want to use it.
7878
7879 If C<dieLevel> is zero, we let the program being debugged handle the
7880 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
7881 the debugger takes over all exception handling, printing a backtrace and
7882 displaying the exception via its C<dbwarn()> routine.
7883
7884 =cut
7885
7886 sub dbdie {
7887     local $frame         = 0;
7888     local $doret         = -2;
7889     local $SIG{__DIE__}  = '';
7890     local $SIG{__WARN__} = '';
7891     my $i      = 0;
7892     my $ineval = 0;
7893     my $sub;
7894     if ( $dieLevel > 2 ) {
7895         local $SIG{__WARN__} = \&dbwarn;
7896         &warn(@_);    # Yell no matter what
7897         return;
7898     }
7899     if ( $dieLevel < 2 ) {
7900         die @_ if $^S;    # in eval propagate
7901     }
7902
7903     # The code used to check $^S to see if compilation of the current thing
7904     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
7905     eval { require Carp };
7906
7907     die( @_,
7908         "\nCannot print stack trace, load with -MCarp option to see stack" )
7909       unless defined &Carp::longmess;
7910
7911     # We do not want to debug this chunk (automatic disabling works
7912     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
7913     # get the stack trace from Carp::longmess (if possible), restore $signal
7914     # and $trace, and then die with the stack trace.
7915     my ( $mysingle, $mytrace ) = ( $single, $trace );
7916     $single = 0;
7917     $trace  = 0;
7918     my $mess = "@_";
7919     {
7920
7921         package Carp;    # Do not include us in the list
7922         eval { $mess = Carp::longmess(@_); };
7923     }
7924     ( $single, $trace ) = ( $mysingle, $mytrace );
7925     die $mess;
7926 } ## end sub dbdie
7927
7928 =head2 C<warnlevel()>
7929
7930 Set the C<$DB::warnLevel> variable that stores the value of the
7931 C<warnLevel> option. Calling C<warnLevel()> with a positive value
7932 results in the debugger taking over all warning handlers. Setting
7933 C<warnLevel> to zero leaves any warning handlers set up by the program
7934 being debugged in place.
7935
7936 =cut
7937
7938 sub warnLevel {
7939     if (@_) {
7940         $prevwarn = $SIG{__WARN__} unless $warnLevel;
7941         $warnLevel = shift;
7942         if ($warnLevel) {
7943             $SIG{__WARN__} = \&DB::dbwarn;
7944         }
7945         elsif ($prevwarn) {
7946             $SIG{__WARN__} = $prevwarn;
7947         } else {
7948             undef $SIG{__WARN__};
7949         }
7950     } ## end if (@_)
7951     $warnLevel;
7952 } ## end sub warnLevel
7953
7954 =head2 C<dielevel>
7955
7956 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
7957 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
7958 zero lets you use your own C<die()> handler.
7959
7960 =cut
7961
7962 sub dieLevel {
7963     local $\ = '';
7964     if (@_) {
7965         $prevdie = $SIG{__DIE__} unless $dieLevel;
7966         $dieLevel = shift;
7967         if ($dieLevel) {
7968
7969             # Always set it to dbdie() for non-zero values.
7970             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
7971
7972             # No longer exists, so don't try  to use it.
7973             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
7974
7975             # If we've finished initialization, mention that stack dumps
7976             # are enabled, If dieLevel is 1, we won't stack dump if we die
7977             # in an eval().
7978             print $OUT "Stack dump during die enabled",
7979               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
7980               if $I_m_init;
7981
7982             # XXX This is probably obsolete, given that diehard() is gone.
7983             print $OUT "Dump printed too.\n" if $dieLevel > 2;
7984         } ## end if ($dieLevel)
7985
7986         # Put the old one back if there was one.
7987         elsif ($prevdie) {
7988             $SIG{__DIE__} = $prevdie;
7989             print $OUT "Default die handler restored.\n";
7990         } else {
7991             undef $SIG{__DIE__};
7992             print $OUT "Die handler removed.\n";
7993         }
7994     } ## end if (@_)
7995     $dieLevel;
7996 } ## end sub dieLevel
7997
7998 =head2 C<signalLevel>
7999
8000 Number three in a series: set C<signalLevel> to zero to keep your own
8001 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
8002 takes over and handles them with C<DB::diesignal()>.
8003
8004 =cut
8005
8006 sub signalLevel {
8007     if (@_) {
8008         $prevsegv = $SIG{SEGV} unless $signalLevel;
8009         $prevbus  = $SIG{BUS}  unless $signalLevel;
8010         $signalLevel = shift;
8011         if ($signalLevel) {
8012             $SIG{SEGV} = \&DB::diesignal;
8013             $SIG{BUS}  = \&DB::diesignal;
8014         }
8015         else {
8016             $SIG{SEGV} = $prevsegv;
8017             $SIG{BUS}  = $prevbus;
8018         }
8019     } ## end if (@_)
8020     $signalLevel;
8021 } ## end sub signalLevel
8022
8023 =head1 SUBROUTINE DECODING SUPPORT
8024
8025 These subroutines are used during the C<x> and C<X> commands to try to
8026 produce as much information as possible about a code reference. They use
8027 L<Devel::Peek> to try to find the glob in which this code reference lives
8028 (if it does) - this allows us to actually code references which correspond
8029 to named subroutines (including those aliased via glob assignment).
8030
8031 =head2 C<CvGV_name()>
8032
8033 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
8034 via that routine. If this fails, return the reference again (when the
8035 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
8036
8037 =cut
8038
8039 sub CvGV_name {
8040     my $in   = shift;
8041     my $name = CvGV_name_or_bust($in);
8042     defined $name ? $name : $in;
8043 }
8044
8045 =head2 C<CvGV_name_or_bust> I<coderef>
8046
8047 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
8048 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
8049 find a glob for this ref.
8050
8051 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
8052
8053 =cut
8054
8055 sub CvGV_name_or_bust {
8056     my $in = shift;
8057     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
8058     return unless ref $in;
8059     $in = \&$in;            # Hard reference...
8060     eval { require Devel::Peek; 1 } or return;
8061     my $gv = Devel::Peek::CvGV($in) or return;
8062     *$gv{PACKAGE} . '::' . *$gv{NAME};
8063 } ## end sub CvGV_name_or_bust
8064
8065 =head2 C<find_sub>
8066
8067 A utility routine used in various places; finds the file where a subroutine
8068 was defined, and returns that filename and a line-number range.
8069
8070 Tries to use C<@sub> first; if it can't find it there, it tries building a
8071 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
8072 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
8073 this way, it brute-force searches C<%sub>, checking for identical references.
8074
8075 =cut
8076
8077 sub find_sub {
8078     my $subr = shift;
8079     $sub{$subr} or do {
8080         return unless defined &$subr;
8081         my $name = CvGV_name_or_bust($subr);
8082         my $data;
8083         $data = $sub{$name} if defined $name;
8084         return $data if defined $data;
8085
8086         # Old stupid way...
8087         $subr = \&$subr;    # Hard reference
8088         my $s;
8089         for ( keys %sub ) {
8090             $s = $_, last if $subr eq \&$_;
8091         }
8092         $sub{$s} if $s;
8093       } ## end do
8094 } ## end sub find_sub
8095
8096 =head2 C<methods>
8097
8098 A subroutine that uses the utility function C<methods_via> to find all the
8099 methods in the class corresponding to the current reference and in
8100 C<UNIVERSAL>.
8101
8102 =cut
8103
8104 sub methods {
8105
8106     # Figure out the class - either this is the class or it's a reference
8107     # to something blessed into that class.
8108     my $class = shift;
8109     $class = ref $class if ref $class;
8110
8111     local %seen;
8112
8113     # Show the methods that this class has.
8114     methods_via( $class, '', 1 );
8115
8116     # Show the methods that UNIVERSAL has.
8117     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
8118 } ## end sub methods
8119
8120 =head2 C<methods_via($class, $prefix, $crawl_upward)>
8121
8122 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
8123 all the parent class methods. C<$class> is the name of the next class to
8124 try; C<$prefix> is the message prefix, which gets built up as we go up the
8125 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
8126 higher in the C<@ISA> tree, 0 if we should stop.
8127
8128 =cut
8129
8130 sub methods_via {
8131
8132     # If we've processed this class already, just quit.
8133     my $class = shift;
8134     return if $seen{$class}++;
8135
8136     # This is a package that is contributing the methods we're about to print.
8137     my $prefix  = shift;
8138     my $prepend = $prefix ? "via $prefix: " : '';
8139     my @to_print;
8140
8141     # Extract from all the symbols in this class.
8142     while (my ($name, $glob) = each %{"${class}::"}) {
8143         # references directly in the symbol table are Proxy Constant
8144         # Subroutines, and are by their very nature defined
8145         # Otherwise, check if the thing is a typeglob, and if it is, it decays
8146         # to a subroutine reference, which can be tested by defined.
8147         # $glob might also be the value -1  (from sub foo;)
8148         # or (say) '$$' (from sub foo ($$);)
8149         # \$glob will be SCALAR in both cases.
8150         if ((ref $glob || ($glob && ref \$glob eq 'GLOB' && defined &$glob))
8151             && !$seen{$name}++) {
8152             push @to_print, "$prepend$name\n";
8153         }
8154     }
8155
8156     {
8157         local $\ = '';
8158         local $, = '';
8159         print $DB::OUT $_ foreach sort @to_print;
8160     }
8161
8162     # If the $crawl_upward argument is false, just quit here.
8163     return unless shift;
8164
8165     # $crawl_upward true: keep going up the tree.
8166     # Find all the classes this one is a subclass of.
8167     for $name ( @{"${class}::ISA"} ) {
8168
8169         # Set up the new prefix.
8170         $prepend = $prefix ? $prefix . " -> $name" : $name;
8171
8172         # Crawl up the tree and keep trying to crawl up.
8173         methods_via( $name, $prepend, 1 );
8174     }
8175 } ## end sub methods_via
8176
8177 =head2 C<setman> - figure out which command to use to show documentation
8178
8179 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8180
8181 =cut
8182
8183 sub setman {
8184     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|NetWare)\z/s
8185       ? "man"         # O Happy Day!
8186       : "perldoc";    # Alas, poor unfortunates
8187 } ## end sub setman
8188
8189 =head2 C<runman> - run the appropriate command to show documentation
8190
8191 Accepts a man page name; runs the appropriate command to display it (set up
8192 during debugger initialization). Uses C<DB::system> to avoid mucking up the
8193 program's STDIN and STDOUT.
8194
8195 =cut
8196
8197 sub runman {
8198     my $page = shift;
8199     unless ($page) {
8200         &system("$doccmd $doccmd");
8201         return;
8202     }
8203
8204     # this way user can override, like with $doccmd="man -Mwhatever"
8205     # or even just "man " to disable the path check.
8206     unless ( $doccmd eq 'man' ) {
8207         &system("$doccmd $page");
8208         return;
8209     }
8210
8211     $page = 'perl' if lc($page) eq 'help';
8212
8213     require Config;
8214     my $man1dir = $Config::Config{'man1dir'};
8215     my $man3dir = $Config::Config{'man3dir'};
8216     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
8217     my $manpath = '';
8218     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
8219     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
8220     chop $manpath if $manpath;
8221
8222     # harmless if missing, I figure
8223     my $oldpath = $ENV{MANPATH};
8224     $ENV{MANPATH} = $manpath if $manpath;
8225     my $nopathopt = $^O =~ /dunno what goes here/;
8226     if (
8227         CORE::system(
8228             $doccmd,
8229
8230             # I just *know* there are men without -M
8231             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8232             split ' ', $page
8233         )
8234       )
8235     {
8236         unless ( $page =~ /^perl\w/ ) {
8237 # do it this way because its easier to slurp in to keep up to date - clunky though.
8238 my @pods = qw(
8239     5004delta
8240     5005delta
8241     561delta
8242     56delta
8243     570delta
8244     571delta
8245     572delta
8246     573delta
8247     58delta
8248     581delta
8249     582delta
8250     583delta
8251     584delta
8252     590delta
8253     591delta
8254     592delta
8255     aix
8256     amiga
8257     apio
8258     api
8259     artistic
8260     beos
8261     book
8262     boot
8263     bot
8264     bs2000
8265     call
8266     ce
8267     cheat
8268     clib
8269     cn
8270     compile
8271     cygwin
8272     data
8273     dbmfilter
8274     debguts
8275     debtut
8276     debug
8277     delta
8278     dgux
8279     diag
8280     doc
8281     dos
8282     dsc
8283     ebcdic
8284     embed
8285     epoc
8286     faq1
8287     faq2
8288     faq3
8289     faq4
8290     faq5
8291     faq6
8292     faq7
8293     faq8
8294     faq9
8295     faq
8296     filter
8297     fork
8298     form
8299     freebsd
8300     func
8301     gpl
8302     guts
8303     hack
8304     hist
8305     hpux
8306     hurd
8307     intern
8308     intro
8309     iol
8310     ipc
8311     irix
8312     jp
8313     ko
8314     lexwarn
8315     locale
8316     lol
8317     macos
8318     macosx
8319     modinstall
8320     modlib
8321     mod
8322     modstyle
8323     mpeix
8324     netware
8325     newmod
8326     number
8327     obj
8328     opentut
8329     op
8330     os2
8331     os390
8332     os400
8333     packtut
8334     plan9
8335     pod
8336     podspec
8337     port
8338     qnx
8339     ref
8340     reftut
8341     re
8342     requick
8343     reref
8344     retut
8345     run
8346     sec
8347     solaris
8348     style
8349     sub
8350     syn
8351     thrtut
8352     tie
8353     toc
8354     todo
8355     tooc
8356     toot
8357     trap
8358     tru64
8359     tw
8360     unicode
8361     uniintro
8362     util
8363     uts
8364     var
8365     vmesa
8366     vms
8367     vos
8368     win32
8369     xs
8370     xstut
8371 );
8372             if (grep { $page eq $_ } @pods) {
8373                 $page =~ s/^/perl/;
8374                 CORE::system( $doccmd,
8375                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8376                     $page );
8377             } ## end if (grep { $page eq $_...
8378         } ## end unless ($page =~ /^perl\w/)
8379     } ## end if (CORE::system($doccmd...
8380     if ( defined $oldpath ) {
8381         $ENV{MANPATH} = $manpath;
8382     }
8383     else {
8384         delete $ENV{MANPATH};
8385     }
8386 } ## end sub runman
8387
8388 #use Carp;                          # This did break, left for debugging
8389
8390 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
8391
8392 Because of the way the debugger interface to the Perl core is designed, any
8393 debugger package globals that C<DB::sub()> requires have to be defined before
8394 any subroutines can be called. These are defined in the second C<BEGIN> block.
8395
8396 This block sets things up so that (basically) the world is sane
8397 before the debugger starts executing. We set up various variables that the
8398 debugger has to have set up before the Perl core starts running:
8399
8400 =over 4
8401
8402 =item *
8403
8404 The debugger's own filehandles (copies of STD and STDOUT for now).
8405
8406 =item *
8407
8408 Characters for shell escapes, the recall command, and the history command.
8409
8410 =item *
8411
8412 The maximum recursion depth.
8413
8414 =item *
8415
8416 The size of a C<w> command's window.
8417
8418 =item *
8419
8420 The before-this-line context to be printed in a C<v> (view a window around this line) command.
8421
8422 =item *
8423
8424 The fact that we're not in a sub at all right now.
8425
8426 =item *
8427
8428 The default SIGINT handler for the debugger.
8429
8430 =item *
8431
8432 The appropriate value of the flag in C<$^D> that says the debugger is running
8433
8434 =item *
8435
8436 The current debugger recursion level
8437
8438 =item *
8439
8440 The list of postponed items and the C<$single> stack (XXX define this)
8441
8442 =item *
8443
8444 That we want no return values and no subroutine entry/exit trace.
8445
8446 =back
8447
8448 =cut
8449
8450 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
8451
8452 BEGIN {    # This does not compile, alas. (XXX eh?)
8453     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
8454     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
8455
8456     # Define characters used by command parsing.
8457     $sh       = '!';      # Shell escape (does not work)
8458     $rc       = ',';      # Recall command (does not work)
8459     @hist     = ('?');    # Show history (does not work)
8460     @truehist = ();       # Can be saved for replay (per session)
8461
8462     # This defines the point at which you get the 'deep recursion'
8463     # warning. It MUST be defined or the debugger will not load.
8464     $deep = 100;
8465
8466     # Number of lines around the current one that are shown in the
8467     # 'w' command.
8468     $window = 10;
8469
8470     # How much before-the-current-line context the 'v' command should
8471     # use in calculating the start of the window it will display.
8472     $preview = 3;
8473
8474     # We're not in any sub yet, but we need this to be a defined value.
8475     $sub = '';
8476
8477     # Set up the debugger's interrupt handler. It simply sets a flag
8478     # ($signal) that DB::DB() will check before each command is executed.
8479     $SIG{INT} = \&DB::catch;
8480
8481     # The following lines supposedly, if uncommented, allow the debugger to
8482     # debug itself. Perhaps we can try that someday.
8483     # This may be enabled to debug debugger:
8484     #$warnLevel = 1 unless defined $warnLevel;
8485     #$dieLevel = 1 unless defined $dieLevel;
8486     #$signalLevel = 1 unless defined $signalLevel;
8487
8488     # This is the flag that says "a debugger is running, please call
8489     # DB::DB and DB::sub". We will turn it on forcibly before we try to
8490     # execute anything in the user's context, because we always want to
8491     # get control back.
8492     $db_stop = 0;          # Compiler warning ...
8493     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
8494
8495     # This variable records how many levels we're nested in debugging. Used
8496     # Used in the debugger prompt, and in determining whether it's all over or
8497     # not.
8498     $level = 0;            # Level of recursive debugging
8499
8500     # "Triggers bug (?) in perl if we postpone this until runtime."
8501     # XXX No details on this yet, or whether we should fix the bug instead
8502     # of work around it. Stay tuned.
8503     @postponed = @stack = (0);
8504
8505     # Used to track the current stack depth using the auto-stacked-variable
8506     # trick.
8507     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
8508
8509     # Don't print return values on exiting a subroutine.
8510     $doret = -2;
8511
8512     # No extry/exit tracing.
8513     $frame = 0;
8514
8515 } ## end BEGIN
8516
8517 BEGIN { $^W = $ini_warn; }    # Switch warnings back
8518
8519 =head1 READLINE SUPPORT - COMPLETION FUNCTION
8520
8521 =head2 db_complete
8522
8523 C<readline> support - adds command completion to basic C<readline>.
8524
8525 Returns a list of possible completions to C<readline> when invoked. C<readline>
8526 will print the longest common substring following the text already entered.
8527
8528 If there is only a single possible completion, C<readline> will use it in full.
8529
8530 This code uses C<map> and C<grep> heavily to create lists of possible
8531 completion. Think LISP in this section.
8532
8533 =cut
8534
8535 sub db_complete {
8536
8537     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
8538     # $text is the text to be completed.
8539     # $line is the incoming line typed by the user.
8540     # $start is the start of the text to be completed in the incoming line.
8541     my ( $text, $line, $start ) = @_;
8542
8543     # Save the initial text.
8544     # The search pattern is current package, ::, extract the next qualifier
8545     # Prefix and pack are set to undef.
8546     my ( $itext, $search, $prefix, $pack ) =
8547       ( $text, "^\Q${'package'}::\E([^:]+)\$" );
8548
8549 =head3 C<b postpone|compile>
8550
8551 =over 4
8552
8553 =item *
8554
8555 Find all the subroutines that might match in this package
8556
8557 =item *
8558
8559 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
8560
8561 =item *
8562
8563 Include all the rest of the subs that are known
8564
8565 =item *
8566
8567 C<grep> out the ones that match the text we have so far
8568
8569 =item *
8570
8571 Return this as the list of possible completions
8572
8573 =back
8574
8575 =cut
8576
8577     return sort grep /^\Q$text/, ( keys %sub ),
8578       qw(postpone load compile),    # subroutines
8579       ( map { /$search/ ? ($1) : () } keys %sub )
8580       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
8581
8582 =head3 C<b load>
8583
8584 Get all the possible files from C<@INC> as it currently stands and
8585 select the ones that match the text so far.
8586
8587 =cut
8588
8589     return sort grep /^\Q$text/, values %INC    # files
8590       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
8591
8592 =head3  C<V> (list variable) and C<m> (list modules)
8593
8594 There are two entry points for these commands:
8595
8596 =head4 Unqualified package names
8597
8598 Get the top-level packages and grab everything that matches the text
8599 so far. For each match, recursively complete the partial packages to
8600 get all possible matching packages. Return this sorted list.
8601
8602 =cut
8603
8604     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8605       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
8606       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
8607
8608 =head4 Qualified package names
8609
8610 Take a partially-qualified package and find all subpackages for it
8611 by getting all the subpackages for the package so far, matching all
8612 the subpackages against the text, and discarding all of them which
8613 start with 'main::'. Return this list.
8614
8615 =cut
8616
8617     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8618       grep !/^main::/, grep /^\Q$text/,
8619       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () } keys %{ $prefix . '::' }
8620       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
8621       and $text =~ /^(.*[^:])::?(\w*)$/
8622       and $prefix = $1;
8623
8624 =head3 C<f> - switch files
8625
8626 Here, we want to get a fully-qualified filename for the C<f> command.
8627 Possibilities are:
8628
8629 =over 4
8630
8631 =item 1. The original source file itself
8632
8633 =item 2. A file from C<@INC>
8634
8635 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
8636
8637 =back
8638
8639 =cut
8640
8641     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
8642            # We might possibly want to switch to an eval (which has a "filename"
8643            # like '(eval 9)'), so we may need to clean up the completion text
8644            # before proceeding.
8645         $prefix = length($1) - length($text);
8646         $text   = $1;
8647
8648 =pod
8649
8650 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
8651 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
8652 out of C<%main::>, add the initial source file, and extract the ones that
8653 match the completion text so far.
8654
8655 =cut
8656
8657         return sort
8658           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
8659           $0;
8660     } ## end if ($line =~ /^\|*f\s+(.*)/)
8661
8662 =head3 Subroutine name completion
8663
8664 We look through all of the defined subs (the keys of C<%sub>) and
8665 return both all the possible matches to the subroutine name plus
8666 all the matches qualified to the current package.
8667
8668 =cut
8669
8670     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
8671         $text = substr $text, 1;
8672         $prefix = "&";
8673         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
8674           (
8675             map { /$search/ ? ($1) : () }
8676               keys %sub
8677           );
8678     } ## end if ((substr $text, 0, ...
8679
8680 =head3  Scalar, array, and hash completion: partially qualified package
8681
8682 Much like the above, except we have to do a little more cleanup:
8683
8684 =cut
8685
8686     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
8687
8688 =pod
8689
8690 =over 4
8691
8692 =item *
8693
8694 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
8695
8696 =cut
8697
8698         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
8699
8700 =pod
8701
8702 =item *
8703
8704 Figure out the prefix vs. what needs completing.
8705
8706 =cut
8707
8708         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
8709         $text   = $2;
8710
8711 =pod
8712
8713 =item *
8714
8715 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
8716
8717 =cut
8718
8719         my @out = map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
8720           keys %$pack;
8721
8722 =pod
8723
8724 =item *
8725
8726 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
8727
8728 =cut
8729
8730         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8731             return db_complete( $out[0], $line, $start );
8732         }
8733
8734         # Return the list of possibles.
8735         return sort @out;
8736
8737     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
8738
8739 =pod
8740
8741 =back
8742
8743 =head3 Symbol completion: current package or package C<main>.
8744
8745 =cut
8746
8747     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
8748 =pod
8749
8750 =over 4
8751
8752 =item *
8753
8754 If it's C<main>, delete main to just get C<::> leading.
8755
8756 =cut
8757
8758         $pack = ( $package eq 'main' ? '' : $package ) . '::';
8759
8760 =pod
8761
8762 =item *
8763
8764 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
8765
8766 =cut
8767
8768         $prefix = substr $text, 0, 1;
8769         $text   = substr $text, 1;
8770
8771         my @out;
8772
8773 =pod
8774
8775 =item *
8776
8777 We look for the lexical scope above DB::DB and auto-complete lexical variables
8778 if PadWalker could be loaded.
8779
8780 =cut
8781
8782         if (not $text =~ /::/ and eval { require PadWalker } ) {
8783             my $level = 1;
8784             while (1) {
8785                 my @info = caller($level);
8786                 $level++;
8787                 $level = -1, last
8788                   if not @info;
8789                 last if $info[3] eq 'DB::DB';
8790             }
8791             if ($level > 0) {
8792                 my $lexicals = PadWalker::peek_my($level);
8793                 push @out, grep /^\Q$prefix$text/, keys %$lexicals;
8794             }
8795         }
8796
8797 =pod
8798
8799 =item *
8800
8801 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
8802
8803 =cut
8804
8805         push @out, map "$prefix$_", grep /^\Q$text/,
8806           ( grep /^_?[a-zA-Z]/, keys %$pack ),
8807           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
8808
8809 =item *
8810
8811 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
8812
8813 =back
8814
8815 =cut
8816
8817         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8818             return db_complete( $out[0], $line, $start );
8819         }
8820
8821         # Return the list of possibles.
8822         return sort @out;
8823     } ## end if ($text =~ /^[\$@%]/)
8824
8825 =head3 Options
8826
8827 We use C<option_val()> to look up the current value of the option. If there's
8828 only a single value, we complete the command in such a way that it is a
8829 complete command for setting the option in question. If there are multiple
8830 possible values, we generate a command consisting of the option plus a trailing
8831 question mark, which, if executed, will list the current value of the option.
8832
8833 =cut
8834
8835     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
8836     {    # Options after space
8837            # We look for the text to be matched in the list of possible options,
8838            # and fetch the current value.
8839         my @out = grep /^\Q$text/, @options;
8840         my $val = option_val( $out[0], undef );
8841
8842         # Set up a 'query option's value' command.
8843         my $out = '? ';
8844         if ( not defined $val or $val =~ /[\n\r]/ ) {
8845
8846             # There's really nothing else we can do.
8847         }
8848
8849         # We have a value. Create a proper option-setting command.
8850         elsif ( $val =~ /\s/ ) {
8851
8852             # XXX This may be an extraneous variable.
8853             my $found;
8854
8855             # We'll want to quote the string (because of the embedded
8856             # whtespace), but we want to make sure we don't end up with
8857             # mismatched quote characters. We try several possibilities.
8858             foreach $l ( split //, qq/\"\'\#\|/ ) {
8859
8860                 # If we didn't find this quote character in the value,
8861                 # quote it using this quote character.
8862                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
8863             }
8864         } ## end elsif ($val =~ /\s/)
8865
8866         # Don't need any quotes.
8867         else {
8868             $out = "=$val ";
8869         }
8870
8871         # If there were multiple possible values, return '? ', which
8872         # makes the command into a query command. If there was just one,
8873         # have readline append that.
8874         $rl_attribs->{completer_terminator_character} =
8875           ( @out == 1 ? $out : '? ' );
8876
8877         # Return list of possibilities.
8878         return sort @out;
8879     } ## end if ((substr $line, 0, ...
8880
8881 =head3 Filename completion
8882
8883 For entering filenames. We simply call C<readline>'s C<filename_list()>
8884 method with the completion text to get the possible completions.
8885
8886 =cut
8887
8888     return $term->filename_list($text);    # filenames
8889
8890 } ## end sub db_complete
8891
8892 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
8893
8894 Functions that possibly ought to be somewhere else.
8895
8896 =head2 end_report
8897
8898 Say we're done.
8899
8900 =cut
8901
8902 sub end_report {
8903     local $\ = '';
8904     print $OUT "Use 'q' to quit or 'R' to restart.  'h q' for details.\n";
8905 }
8906
8907 =head2 clean_ENV
8908
8909 If we have $ini_pids, save it in the environment; else remove it from the
8910 environment. Used by the C<R> (restart) command.
8911
8912 =cut
8913
8914 sub clean_ENV {
8915     if ( defined($ini_pids) ) {
8916         $ENV{PERLDB_PIDS} = $ini_pids;
8917     }
8918     else {
8919         delete( $ENV{PERLDB_PIDS} );
8920     }
8921 } ## end sub clean_ENV
8922
8923 # PERLDBf_... flag names from perl.h
8924 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
8925
8926 BEGIN {
8927     %DollarCaretP_flags = (
8928         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
8929         PERLDBf_LINE      => 0x02,     # Keep line #
8930         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
8931         PERLDBf_INTER     => 0x08,     # Preserve more data
8932         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
8933         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
8934         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
8935         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
8936         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
8937         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
8938         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
8939         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
8940     );
8941     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
8942     # doesn't need to set it. It's provided for the benefit of profilers and
8943     # other code analysers.
8944
8945     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
8946 }
8947
8948 sub parse_DollarCaretP_flags {
8949     my $flags = shift;
8950     $flags =~ s/^\s+//;
8951     $flags =~ s/\s+$//;
8952     my $acu = 0;
8953     foreach my $f ( split /\s*\|\s*/, $flags ) {
8954         my $value;
8955         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
8956             $value = hex $1;
8957         }
8958         elsif ( $f =~ /^(\d+)$/ ) {
8959             $value = int $1;
8960         }
8961         elsif ( $f =~ /^DEFAULT$/i ) {
8962             $value = $DollarCaretP_flags{PERLDB_ALL};
8963         }
8964         else {
8965             $f =~ /^(?:PERLDBf_)?(.*)$/i;
8966             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
8967             unless ( defined $value ) {
8968                 print $OUT (
8969                     "Unrecognized \$^P flag '$f'!\n",
8970                     "Acceptable flags are: "
8971                       . join( ', ', sort keys %DollarCaretP_flags ),
8972                     ", and hexadecimal and decimal numbers.\n"
8973                 );
8974                 return undef;
8975             }
8976         }
8977         $acu |= $value;
8978     }
8979     $acu;
8980 }
8981
8982 sub expand_DollarCaretP_flags {
8983     my $DollarCaretP = shift;
8984     my @bits         = (
8985         map {
8986             my $n = ( 1 << $_ );
8987             ( $DollarCaretP & $n )
8988               ? ( $DollarCaretP_flags_r{$n}
8989                   || sprintf( '0x%x', $n ) )
8990               : ()
8991           } 0 .. 31
8992     );
8993     return @bits ? join( '|', @bits ) : 0;
8994 }
8995
8996 =over 4
8997
8998 =item rerun
8999
9000 Rerun the current session to:
9001
9002     rerun        current position
9003
9004     rerun 4      command number 4
9005
9006     rerun -4     current command minus 4 (go back 4 steps)
9007
9008 Whether this always makes sense, in the current context is unknowable, and is
9009 in part left as a useful exercise for the reader.  This sub returns the
9010 appropriate arguments to rerun the current session.
9011
9012 =cut
9013
9014 sub rerun {
9015     my $i = shift;
9016     my @args;
9017     pop(@truehist);                      # strim
9018     unless (defined $truehist[$i]) {
9019         print "Unable to return to non-existent command: $i\n";
9020     } else {
9021         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
9022         my @temp = @truehist;            # store
9023         push(@DB::typeahead, @truehist); # saved
9024         @truehist = @hist = ();          # flush
9025         @args = &restart();              # setup
9026         &get_list("PERLDB_HIST");        # clean
9027         &set_list("PERLDB_HIST", @temp); # reset
9028     }
9029     return @args;
9030 }
9031
9032 =item restart
9033
9034 Restarting the debugger is a complex operation that occurs in several phases.
9035 First, we try to reconstruct the command line that was used to invoke Perl
9036 and the debugger.
9037
9038 =cut
9039
9040 sub restart {
9041     # I may not be able to resurrect you, but here goes ...
9042     print $OUT
9043 "Warning: some settings and command-line options may be lost!\n";
9044     my ( @script, @flags, $cl );
9045
9046     # If warn was on before, turn it on again.
9047     push @flags, '-w' if $ini_warn;
9048
9049     # Rebuild the -I flags that were on the initial
9050     # command line.
9051     for (@ini_INC) {
9052         push @flags, '-I', $_;
9053     }
9054
9055     # Turn on taint if it was on before.
9056     push @flags, '-T' if ${^TAINT};
9057
9058     # Arrange for setting the old INC:
9059     # Save the current @init_INC in the environment.
9060     set_list( "PERLDB_INC", @ini_INC );
9061
9062     # If this was a perl one-liner, go to the "file"
9063     # corresponding to the one-liner read all the lines
9064     # out of it (except for the first one, which is going
9065     # to be added back on again when 'perl -d' runs: that's
9066     # the 'require perl5db.pl;' line), and add them back on
9067     # to the command line to be executed.
9068     if ( $0 eq '-e' ) {
9069         for ( 1 .. $#{'::_<-e'} ) {  # The first line is PERL5DB
9070             chomp( $cl = ${'::_<-e'}[$_] );
9071             push @script, '-e', $cl;
9072         }
9073     } ## end if ($0 eq '-e')
9074
9075     # Otherwise we just reuse the original name we had
9076     # before.
9077     else {
9078         @script = $0;
9079     }
9080
9081 =pod
9082
9083 After the command line  has been reconstructed, the next step is to save
9084 the debugger's status in environment variables. The C<DB::set_list> routine
9085 is used to save aggregate variables (both hashes and arrays); scalars are
9086 just popped into environment variables directly.
9087
9088 =cut
9089
9090     # If the terminal supported history, grab it and
9091     # save that in the environment.
9092     set_list( "PERLDB_HIST",
9093           $term->Features->{getHistory}
9094         ? $term->GetHistory
9095         : @hist );
9096
9097     # Find all the files that were visited during this
9098     # session (i.e., the debugger had magic hashes
9099     # corresponding to them) and stick them in the environment.
9100     my @had_breakpoints = keys %had_breakpoints;
9101     set_list( "PERLDB_VISITED", @had_breakpoints );
9102
9103     # Save the debugger options we chose.
9104     set_list( "PERLDB_OPT", %option );
9105     # set_list( "PERLDB_OPT", options2remember() );
9106
9107     # Save the break-on-loads.
9108     set_list( "PERLDB_ON_LOAD", %break_on_load );
9109
9110 =pod
9111
9112 The most complex part of this is the saving of all of the breakpoints. They
9113 can live in an awful lot of places, and we have to go through all of them,
9114 find the breakpoints, and then save them in the appropriate environment
9115 variable via C<DB::set_list>.
9116
9117 =cut
9118
9119     # Go through all the breakpoints and make sure they're
9120     # still valid.
9121     my @hard;
9122     for ( 0 .. $#had_breakpoints ) {
9123
9124         # We were in this file.
9125         my $file = $had_breakpoints[$_];
9126
9127         # Grab that file's magic line hash.
9128         *dbline = $main::{ '_<' . $file };
9129
9130         # Skip out if it doesn't exist, or if the breakpoint
9131         # is in a postponed file (we'll do postponed ones
9132         # later).
9133         next unless %dbline or $postponed_file{$file};
9134
9135         # In an eval. This is a little harder, so we'll
9136         # do more processing on that below.
9137         ( push @hard, $file ), next
9138           if $file =~ /^\(\w*eval/;
9139
9140         # XXX I have no idea what this is doing. Yet.
9141         my @add;
9142         @add = %{ $postponed_file{$file} }
9143           if $postponed_file{$file};
9144
9145         # Save the list of all the breakpoints for this file.
9146         set_list( "PERLDB_FILE_$_", %dbline, @add );
9147     } ## end for (0 .. $#had_breakpoints)
9148
9149     # The breakpoint was inside an eval. This is a little
9150     # more difficult. XXX and I don't understand it.
9151     for (@hard) {
9152         # Get over to the eval in question.
9153         *dbline = $main::{ '_<' . $_ };
9154         my ( $quoted, $sub, %subs, $line ) = quotemeta $_;
9155         for $sub ( keys %sub ) {
9156             next unless $sub{$sub} =~ /^$quoted:(\d+)-(\d+)$/;
9157             $subs{$sub} = [ $1, $2 ];
9158         }
9159         unless (%subs) {
9160             print $OUT
9161               "No subroutines in $_, ignoring breakpoints.\n";
9162             next;
9163         }
9164       LINES: for $line ( keys %dbline ) {
9165
9166             # One breakpoint per sub only:
9167             my ( $offset, $sub, $found );
9168           SUBS: for $sub ( keys %subs ) {
9169                 if (
9170                     $subs{$sub}->[1] >=
9171                     $line    # Not after the subroutine
9172                     and (
9173                         not defined $offset    # Not caught
9174                         or $offset < 0
9175                     )
9176                   )
9177                 {                              # or badly caught
9178                     $found  = $sub;
9179                     $offset = $line - $subs{$sub}->[0];
9180                     $offset = "+$offset", last SUBS
9181                       if $offset >= 0;
9182                 } ## end if ($subs{$sub}->[1] >=...
9183             } ## end for $sub (keys %subs)
9184             if ( defined $offset ) {
9185                 $postponed{$found} =
9186                   "break $offset if $dbline{$line}";
9187             }
9188             else {
9189                 print $OUT
9190 "Breakpoint in $_:$line ignored: after all the subroutines.\n";
9191             }
9192         } ## end for $line (keys %dbline)
9193     } ## end for (@hard)
9194
9195     # Save the other things that don't need to be
9196     # processed.
9197     set_list( "PERLDB_POSTPONE",  %postponed );
9198     set_list( "PERLDB_PRETYPE",   @$pretype );
9199     set_list( "PERLDB_PRE",       @$pre );
9200     set_list( "PERLDB_POST",      @$post );
9201     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9202
9203     # We are officially restarting.
9204     $ENV{PERLDB_RESTART} = 1;
9205
9206     # We are junking all child debuggers.
9207     delete $ENV{PERLDB_PIDS};    # Restore ini state
9208
9209     # Set this back to the initial pid.
9210     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9211
9212 =pod
9213
9214 After all the debugger status has been saved, we take the command we built up
9215 and then return it, so we can C<exec()> it. The debugger will spot the
9216 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9217 from the environment.
9218
9219 =cut
9220
9221     # And run Perl again. Add the "-d" flag, all the
9222     # flags we built up, the script (whether a one-liner
9223     # or a file), add on the -emacs flag for a slave editor,
9224     # and then the old arguments.
9225
9226     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9227
9228 };  # end restart
9229
9230 =back
9231
9232 =head1 END PROCESSING - THE C<END> BLOCK
9233
9234 Come here at the very end of processing. We want to go into a
9235 loop where we allow the user to enter commands and interact with the
9236 debugger, but we don't want anything else to execute.
9237
9238 First we set the C<$finished> variable, so that some commands that
9239 shouldn't be run after the end of program quit working.
9240
9241 We then figure out whether we're truly done (as in the user entered a C<q>
9242 command, or we finished execution while running nonstop). If we aren't,
9243 we set C<$single> to 1 (causing the debugger to get control again).
9244
9245 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9246 message and returns control to the debugger. Repeat.
9247
9248 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9249 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9250 break, run to completion.).
9251
9252 =cut
9253
9254 END {
9255     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9256     $fall_off_end = 1 unless $inhibit_exit;
9257
9258     # Do not stop in at_exit() and destructors on exit:
9259     if ($fall_off_end or $runnonstop) {
9260         &save_hist();
9261     } else {
9262         $DB::single = 1;
9263         DB::fake::at_exit();
9264     }
9265 } ## end END
9266
9267 =head1 PRE-5.8 COMMANDS
9268
9269 Some of the commands changed function quite a bit in the 5.8 command
9270 realignment, so much so that the old code had to be replaced completely.
9271 Because we wanted to retain the option of being able to go back to the
9272 former command set, we moved the old code off to this section.
9273
9274 There's an awful lot of duplicated code here. We've duplicated the
9275 comments to keep things clear.
9276
9277 =head2 Null command
9278
9279 Does nothing. Used to I<turn off> commands.
9280
9281 =cut
9282
9283 sub cmd_pre580_null {
9284
9285     # do nothing...
9286 }
9287
9288 =head2 Old C<a> command.
9289
9290 This version added actions if you supplied them, and deleted them
9291 if you didn't.
9292
9293 =cut
9294
9295 sub cmd_pre580_a {
9296     my $xcmd = shift;
9297     my $cmd  = shift;
9298
9299     # Argument supplied. Add the action.
9300     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9301
9302         # If the line isn't there, use the current line.
9303         $i = $1 || $line;
9304         $j = $2;
9305
9306         # If there is an action ...
9307         if ( length $j ) {
9308
9309             # ... but the line isn't breakable, skip it.
9310             if ( $dbline[$i] == 0 ) {
9311                 print $OUT "Line $i may not have an action.\n";
9312             }
9313             else {
9314
9315                 # ... and the line is breakable:
9316                 # Mark that there's an action in this file.
9317                 $had_breakpoints{$filename} |= 2;
9318
9319                 # Delete any current action.
9320                 $dbline{$i} =~ s/\0[^\0]*//;
9321
9322                 # Add the new action, continuing the line as needed.
9323                 $dbline{$i} .= "\0" . action($j);
9324             }
9325         } ## end if (length $j)
9326
9327         # No action supplied.
9328         else {
9329
9330             # Delete the action.
9331             $dbline{$i} =~ s/\0[^\0]*//;
9332
9333             # Mark as having no break or action if nothing's left.
9334             delete $dbline{$i} if $dbline{$i} eq '';
9335         }
9336     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
9337 } ## end sub cmd_pre580_a
9338
9339 =head2 Old C<b> command
9340
9341 Add breakpoints.
9342
9343 =cut
9344
9345 sub cmd_pre580_b {
9346     my $xcmd   = shift;
9347     my $cmd    = shift;
9348     my $dbline = shift;
9349
9350     # Break on load.
9351     if ( $cmd =~ /^load\b\s*(.*)/ ) {
9352         my $file = $1;
9353         $file =~ s/\s+$//;
9354         &cmd_b_load($file);
9355     }
9356
9357     # b compile|postpone <some sub> [<condition>]
9358     # The interpreter actually traps this one for us; we just put the
9359     # necessary condition in the %postponed hash.
9360     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
9361
9362         # Capture the condition if there is one. Make it true if none.
9363         my $cond = length $3 ? $3 : '1';
9364
9365         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
9366         # if it was 'compile'.
9367         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
9368
9369         # De-Perl4-ify the name - ' separators to ::.
9370         $subname =~ s/\'/::/g;
9371
9372         # Qualify it into the current package unless it's already qualified.
9373         $subname = "${'package'}::" . $subname
9374           unless $subname =~ /::/;
9375
9376         # Add main if it starts with ::.
9377         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
9378
9379         # Save the break type for this sub.
9380         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
9381     } ## end elsif ($cmd =~ ...
9382
9383     # b <sub name> [<condition>]
9384     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
9385         my $subname = $1;
9386         my $cond = length $2 ? $2 : '1';
9387         &cmd_b_sub( $subname, $cond );
9388     }
9389     # b <line> [<condition>].
9390     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9391         my $i = $1 || $dbline;
9392         my $cond = length $2 ? $2 : '1';
9393         &cmd_b_line( $i, $cond );
9394     }
9395 } ## end sub cmd_pre580_b
9396
9397 =head2 Old C<D> command.
9398
9399 Delete all breakpoints unconditionally.
9400
9401 =cut
9402
9403 sub cmd_pre580_D {
9404     my $xcmd = shift;
9405     my $cmd  = shift;
9406     if ( $cmd =~ /^\s*$/ ) {
9407         print $OUT "Deleting all breakpoints...\n";
9408
9409         # %had_breakpoints lists every file that had at least one
9410         # breakpoint in it.
9411         my $file;
9412         for $file ( keys %had_breakpoints ) {
9413
9414             # Switch to the desired file temporarily.
9415             local *dbline = $main::{ '_<' . $file };
9416
9417             my $max = $#dbline;
9418             my $was;
9419
9420             # For all lines in this file ...
9421             for ( $i = 1 ; $i <= $max ; $i++ ) {
9422
9423                 # If there's a breakpoint or action on this line ...
9424                 if ( defined $dbline{$i} ) {
9425
9426                     # ... remove the breakpoint.
9427                     $dbline{$i} =~ s/^[^\0]+//;
9428                     if ( $dbline{$i} =~ s/^\0?$// ) {
9429
9430                         # Remove the entry altogether if no action is there.
9431                         delete $dbline{$i};
9432                     }
9433                 } ## end if (defined $dbline{$i...
9434             } ## end for ($i = 1 ; $i <= $max...
9435
9436             # If, after we turn off the "there were breakpoints in this file"
9437             # bit, the entry in %had_breakpoints for this file is zero,
9438             # we should remove this file from the hash.
9439             if ( not $had_breakpoints{$file} &= ~1 ) {
9440                 delete $had_breakpoints{$file};
9441             }
9442         } ## end for $file (keys %had_breakpoints)
9443
9444         # Kill off all the other breakpoints that are waiting for files that
9445         # haven't been loaded yet.
9446         undef %postponed;
9447         undef %postponed_file;
9448         undef %break_on_load;
9449     } ## end if ($cmd =~ /^\s*$/)
9450 } ## end sub cmd_pre580_D
9451
9452 =head2 Old C<h> command
9453
9454 Print help. Defaults to printing the long-form help; the 5.8 version
9455 prints the summary by default.
9456
9457 =cut
9458
9459 sub cmd_pre580_h {
9460     my $xcmd = shift;
9461     my $cmd  = shift;
9462
9463     # Print the *right* help, long format.
9464     if ( $cmd =~ /^\s*$/ ) {
9465         print_help($pre580_help);
9466     }
9467
9468     # 'h h' - explicitly-requested summary.
9469     elsif ( $cmd =~ /^h\s*/ ) {
9470         print_help($pre580_summary);
9471     }
9472
9473     # Find and print a command's help.
9474     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
9475         my $asked  = $1;                   # for proper errmsg
9476         my $qasked = quotemeta($asked);    # for searching
9477                                            # XXX: finds CR but not <CR>
9478         if (
9479             $pre580_help =~ /^
9480                               <?           # Optional '<'
9481                               (?:[IB]<)    # Optional markup
9482                               $qasked      # The command name
9483                             /mx
9484           )
9485         {
9486
9487             while (
9488                 $pre580_help =~ /^
9489                                   (             # The command help:
9490                                    <?           # Optional '<'
9491                                    (?:[IB]<)    # Optional markup
9492                                    $qasked      # The command name
9493                                    ([\s\S]*?)   # Lines starting with tabs
9494                                    \n           # Final newline
9495                                   )
9496                                   (?!\s)/mgx
9497               )    # Line not starting with space
9498                    # (Next command's help)
9499             {
9500                 print_help($1);
9501             }
9502         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
9503
9504         # Help not found.
9505         else {
9506             print_help("B<$asked> is not a debugger command.\n");
9507         }
9508     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
9509 } ## end sub cmd_pre580_h
9510
9511 =head2 Old C<W> command
9512
9513 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
9514
9515 =cut
9516
9517 sub cmd_pre580_W {
9518     my $xcmd = shift;
9519     my $cmd  = shift;
9520
9521     # Delete all watch expressions.
9522     if ( $cmd =~ /^$/ ) {
9523
9524         # No watching is going on.
9525         $trace &= ~2;
9526
9527         # Kill all the watch expressions and values.
9528         @to_watch = @old_watch = ();
9529     }
9530
9531     # Add a watch expression.
9532     elsif ( $cmd =~ /^(.*)/s ) {
9533
9534         # add it to the list to be watched.
9535         push @to_watch, $1;
9536
9537         # Get the current value of the expression.
9538         # Doesn't handle expressions returning list values!
9539         $evalarg = $1;
9540         my ($val) = &eval;
9541         $val = ( defined $val ) ? "'$val'" : 'undef';
9542
9543         # Save it.
9544         push @old_watch, $val;
9545
9546         # We're watching stuff.
9547         $trace |= 2;
9548
9549     } ## end elsif ($cmd =~ /^(.*)/s)
9550 } ## end sub cmd_pre580_W
9551
9552 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
9553
9554 The debugger used to have a bunch of nearly-identical code to handle
9555 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
9556 C<cmd_prepost> unify all this into one set of code to handle the
9557 appropriate actions.
9558
9559 =head2 C<cmd_pre590_prepost>
9560
9561 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
9562 do something destructive. In pre 5.8 debuggers, the default action was to
9563 delete all the actions.
9564
9565 =cut
9566
9567 sub cmd_pre590_prepost {
9568     my $cmd    = shift;
9569     my $line   = shift || '*';
9570     my $dbline = shift;
9571
9572     return &cmd_prepost( $cmd, $line, $dbline );
9573 } ## end sub cmd_pre590_prepost
9574
9575 =head2 C<cmd_prepost>
9576
9577 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
9578 Since the lists of actions are all held in arrays that are pointed to by
9579 references anyway, all we have to do is pick the right array reference and
9580 then use generic code to all, delete, or list actions.
9581
9582 =cut
9583
9584 sub cmd_prepost {
9585     my $cmd = shift;
9586
9587     # No action supplied defaults to 'list'.
9588     my $line = shift || '?';
9589
9590     # Figure out what to put in the prompt.
9591     my $which = '';
9592
9593     # Make sure we have some array or another to address later.
9594     # This means that if ssome reason the tests fail, we won't be
9595     # trying to stash actions or delete them from the wrong place.
9596     my $aref = [];
9597
9598     # < - Perl code to run before prompt.
9599     if ( $cmd =~ /^\</o ) {
9600         $which = 'pre-perl';
9601         $aref  = $pre;
9602     }
9603
9604     # > - Perl code to run after prompt.
9605     elsif ( $cmd =~ /^\>/o ) {
9606         $which = 'post-perl';
9607         $aref  = $post;
9608     }
9609
9610     # { - first check for properly-balanced braces.
9611     elsif ( $cmd =~ /^\{/o ) {
9612         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
9613             print $OUT
9614 "$cmd is now a debugger command\nuse ';$cmd' if you mean Perl code\n";
9615         }
9616
9617         # Properly balanced. Pre-prompt debugger actions.
9618         else {
9619             $which = 'pre-debugger';
9620             $aref  = $pretype;
9621         }
9622     } ## end elsif ( $cmd =~ /^\{/o )
9623
9624     # Did we find something that makes sense?
9625     unless ($which) {
9626         print $OUT "Confused by command: $cmd\n";
9627     }
9628
9629     # Yes.
9630     else {
9631
9632         # List actions.
9633         if ( $line =~ /^\s*\?\s*$/o ) {
9634             unless (@$aref) {
9635
9636                 # Nothing there. Complain.
9637                 print $OUT "No $which actions.\n";
9638             }
9639             else {
9640
9641                 # List the actions in the selected list.
9642                 print $OUT "$which commands:\n";
9643                 foreach my $action (@$aref) {
9644                     print $OUT "\t$cmd -- $action\n";
9645                 }
9646             } ## end else
9647         } ## end if ( $line =~ /^\s*\?\s*$/o)
9648
9649         # Might be a delete.
9650         else {
9651             if ( length($cmd) == 1 ) {
9652                 if ( $line =~ /^\s*\*\s*$/o ) {
9653
9654                     # It's a delete. Get rid of the old actions in the
9655                     # selected list..
9656                     @$aref = ();
9657                     print $OUT "All $cmd actions cleared.\n";
9658                 }
9659                 else {
9660
9661                     # Replace all the actions. (This is a <, >, or {).
9662                     @$aref = action($line);
9663                 }
9664             } ## end if ( length($cmd) == 1)
9665             elsif ( length($cmd) == 2 ) {
9666
9667                 # Add the action to the line. (This is a <<, >>, or {{).
9668                 push @$aref, action($line);
9669             }
9670             else {
9671
9672                 # <<<, >>>>, {{{{{{ ... something not a command.
9673                 print $OUT
9674                   "Confused by strange length of $which command($cmd)...\n";
9675             }
9676         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
9677     } ## end else
9678 } ## end sub cmd_prepost
9679
9680 =head1 C<DB::fake>
9681
9682 Contains the C<at_exit> routine that the debugger uses to issue the
9683 C<Debugged program terminated ...> message after the program completes. See
9684 the C<END> block documentation for more details.
9685
9686 =cut
9687
9688 package DB::fake;
9689
9690 sub at_exit {
9691     "Debugged program terminated.  Use 'q' to quit or 'R' to restart.";
9692 }
9693
9694 package DB;    # Do not trace this 1; below!
9695
9696 1;
9697
9698