Porting/corelist.pl

   1 #!perl
   2 # Generates info for Module::CoreList from this perl tree
   3 # run this from the root of a perl tree
   4 #
   5 # Data is on STDOUT.
   6 #
   7 # With an optional arg specifying the root of a CPAN mirror, outputs the
   8 # %upstream and %bug_tracker hashes too.
   9
  10 use autodie;
  11 use strict;
  12 use warnings;
  13 use File::Find;
  14 use ExtUtils::MM_Unix;
  15 use version;
  16 use lib "Porting";
  17 use Maintainers qw(%Modules files_to_modules);
  18 use File::Spec;
  19 use Parse::CPAN::Meta;
  20 use IPC::Cmd 'can_run';
  21 use HTTP::Tiny;
  22 use IO::Uncompress::Gunzip;
  23
  24 my $corelist_file = './dist/Module-CoreList/lib/Module/CoreList.pm';
  25 my $utils_file = './dist/Module-CoreList/lib/Module/CoreList/Utils.pm';
  26
  27 my %lines;
  28 my %module_to_file;
  29 my %modlist;
  30
  31 die "usage: $0 [ cpan-mirror/ ] [ 5.x.y] \n" unless @ARGV <= 2;
  32 my $cpan         = shift;
  33 my $raw_version  = shift || $];
  34 my $perl_version = version->parse("$raw_version");
  35 my $perl_vnum    = $perl_version->numify;
  36 my $perl_vstring = $perl_version->normal; # how do we get version.pm to not give us leading v?
  37 $perl_vstring =~ s/^v//;
  38
  39 if ( !-f 'MANIFEST' ) {
  40     die "Must be run from the root of a clean perl tree\n";
  41 }
  42
  43 open( my $corelist_fh, '<', $corelist_file );
  44 my $corelist = join( '', <$corelist_fh> );
  45 close $corelist_fh;
  46
  47 unless (
  48     $corelist =~ /^%released \s* = \s* \(
  49         .*?
  50         $perl_vnum \s* => \s* .*?
  51         \);/ismx
  52     )
  53 {
  54     warn "Adding $perl_vnum to the list of released perl versions. Please consider adding a release date.\n";
  55     $corelist =~ s/^(%released \s* = \s* .*?) ( \) )
  56                 /$1  $perl_vnum => '????-??-??',\n  $2/ismx;
  57 }
  58
  59 if ($cpan) {
  60     my $modlistfile = File::Spec->catfile( $cpan, 'modules', '02packages.details.txt' );
  61     my $content;
  62
  63     my $fh;
  64     if ( -e $modlistfile ) {
  65         warn "Reading the module list from $modlistfile";
  66         open $fh, '<', $modlistfile;
  67     } elsif ( -e $modlistfile . ".gz" ) {
  68         my $zcat = can_run('gzcat') || can_run('zcat') or die "Can't find gzcat or zcat";
  69         warn "Reading the module list from $modlistfile.gz";
  70         open $fh, '-|', "$zcat $modlistfile.gz";
  71     } else {
  72         warn "About to fetch 02packages from ftp.funet.fi. This may take a few minutes\n";
  73         my $gzipped_content = fetch_url('http://ftp.funet.fi/pub/CPAN/modules/02packages.details.txt.gz');
  74         unless ($gzipped_content) {
  75             die "Unable to read 02packages.details.txt from either your CPAN mirror or ftp.funet.fi";
  76         }
  77         IO::Uncompress::Gunzip::gunzip(\$gzipped_content, \$content, Transparent => 0)
  78             or die "Can't gunzip content: $IO::Uncompress::Gunzip::GunzipError";
  79     }
  80
  81     if ( $fh and !$content ) {
  82         local $/ = "\n";
  83         $content = join( '', <$fh> );
  84     }
  85
  86     die "Incompatible modlist format"
  87         unless $content =~ /^Columns: +package name, version, path/m;
  88
  89     # Converting the file to a hash is about 5 times faster than a regexp flat
  90     # lookup.
  91     for ( split( qr/\n/, $content ) ) {
  92         next unless /^([A-Za-z_:0-9]+) +[-0-9.undefHASHVERSIONvsetwhenloadingbogus]+ +(\S+)/;
  93         $modlist{$1} = $2;
  94     }
  95 }
  96
  97 find(
  98     sub {
  99         /(\.pm|_pm\.PL)$/ or return;
 100         /PPPort\.pm$/ and return;
 101         my $module = $File::Find::name;
 102         $module =~ /\b(demo|t|private|corpus)\b/ and return;    # demo or test modules
 103         my $version = MM->parse_version($_);
 104         defined $version or $version = 'undef';
 105         $version =~ /\d/ and $version = "'$version'";
 106
 107         # some heuristics to figure out the module name from the file name
 108         $module =~ s{^(lib|cpan|dist|ext|os2/OS2)/}{}
 109                         and $1 ne 'lib'
 110             and (
 111             $module =~ s{\b(\w+)/\1\b}{$1},
 112             $module =~ s{^B/O}{O},
 113             $module =~ s{^Devel-PPPort}{Devel},
 114             $module =~ s{^libnet/}{},
 115             $module =~ s{^PathTools/}{},
 116             $module =~ s{REXX/DLL}{DLL},
 117             $module =~ s{^Encode/encoding}{encoding},
 118             $module =~ s{^IPC-SysV/}{IPC/},
 119             $module =~ s{^MIME-Base64/QuotedPrint}{MIME/QuotedPrint},
 120             $module =~ s{^(?:DynaLoader|Errno|Opcode|XSLoader)/}{},
 121             $module =~ s{^Sys-Syslog/win32}{Sys-Syslog},
 122             $module =~ s{^Time-Piece/Seconds}{Time/Seconds},
 123             );
 124                 $module =~ s{^lib/}{}g;
 125         $module =~ s{/}{::}g;
 126         $module =~ s{-}{::}g;
 127                 $module =~ s{^.*::lib::}{}; # turns Foo/lib/Foo.pm into Foo.pm
 128         $module =~ s/(\.pm|_pm\.PL)$//;
 129         $lines{$module}          = $version;
 130         $module_to_file{$module} = $File::Find::name;
 131     },
 132     'os2/OS2',
 133     'lib',
 134     'ext',
 135         'cpan',
 136         'dist'
 137 );
 138
 139 -e 'configpm' and $lines{Config} = "$]";
 140
 141 if ( open my $ucdv, "<", "lib/unicore/version" ) {
 142     chomp( my $ucd = <$ucdv> );
 143     $lines{Unicode} = "'$ucd'";
 144     close $ucdv;
 145 }
 146
 147 my $delta_data = make_corelist_delta(
 148   $perl_vnum,
 149   \%lines,
 150   \%Module::CoreList::version
 151 );
 152
 153 my $versions_in_release = "    " . $perl_vnum . " => {\n";
 154 $versions_in_release .= "        delta_from => $delta_data->{delta_from},\n";
 155 $versions_in_release .= "        changed => {\n";
 156 foreach my $key (sort keys $delta_data->{changed}->%*) {
 157   $versions_in_release .= sprintf "            %-24s=> %s,\n", "'$key'",
 158       defined $delta_data->{changed}{$key} ? "'"
 159         . $delta_data->{changed}{$key} . "'" : "undef";
 160 }
 161 $versions_in_release .= "        },\n";
 162 $versions_in_release .= "        removed => {\n";
 163 for my $key (sort keys %{ $delta_data->{removed} || {} }) {
 164   $versions_in_release .= sprintf "            %-24s=> %s,\n", "'$key'", 1;
 165 }
 166 $versions_in_release .= "        }\n";
 167 $versions_in_release .= "    },\n";
 168
 169 $corelist =~ s/^(%delta\s*=\s*.*?)^\s*$perl_vnum\s*=>\s*{.*?},\s*(^\);)$/$1$2/ism;
 170 $corelist =~ s/^(%delta\s*=\s*.*?)(^\);)$/$1$versions_in_release$2/ism;
 171
 172 exit unless %modlist;
 173
 174 # We have to go through this two stage lookup, given how Maintainers.pl keys its
 175 # data by "Module", which is really a dist.
 176 my $file_to_M = files_to_modules( values %module_to_file );
 177
 178 sub slurp_utf8($) {
 179     open my $fh, "<:utf8", "$_[0]"
 180         or die "can't open $_[0] for reading: $!";
 181     return do { local $/; <$fh> };
 182 }
 183
 184 sub parse_cpan_meta($) {
 185     return Parse::CPAN::Meta->${
 186         $_[0] =~ /\A\x7b/ ? \"load_json_string" : \"load_yaml_string"
 187     }($_[0]);
 188 }
 189
 190 my %module_to_upstream;
 191 my %module_to_dist;
 192 my %dist_to_meta_YAML;
 193 my %module_to_deprecated;
 194 while ( my ( $module, $file ) = each %module_to_file ) {
 195     my $M = $file_to_M->{$file};
 196     next unless $M;
 197     next if $Modules{$M}{MAINTAINER} && $Modules{$M}{MAINTAINER} eq 'P5P';
 198     $module_to_upstream{$module} = $Modules{$M}{UPSTREAM};
 199     $module_to_deprecated{$module} = 1 if $Modules{$M}{DEPRECATED};
 200     next
 201         if defined $module_to_upstream{$module}
 202             && $module_to_upstream{$module} eq 'blead';
 203     my $dist = $modlist{$module};
 204     unless ($dist) {
 205         warn "Can't find a distribution for $module\n";
 206         next;
 207     }
 208     $module_to_dist{$module} = $dist;
 209
 210     next if exists $dist_to_meta_YAML{$dist};
 211
 212     $dist_to_meta_YAML{$dist} = undef;
 213
 214     # Like it or lump it, this has to be Unix format.
 215     my $meta_YAML_path = "authors/id/$dist";
 216     $meta_YAML_path =~ s/(?:tar\.gz|tar\.bz2|zip|tgz)$/meta/
 217         or die "ERROR: bad meta YAML path: '$meta_YAML_path'";
 218     my $meta_YAML_url = 'http://ftp.funet.fi/pub/CPAN/' . $meta_YAML_path;
 219
 220     if ( -e "$cpan/$meta_YAML_path" ) {
 221         $dist_to_meta_YAML{$dist} = parse_cpan_meta(slurp_utf8( $cpan . "/" . $meta_YAML_path ));
 222     } elsif ( my $content = fetch_url($meta_YAML_url) ) {
 223         unless ($content) {
 224             warn "Failed to fetch $meta_YAML_url\n";
 225             next;
 226         }
 227         eval { $dist_to_meta_YAML{$dist} = parse_cpan_meta($content); };
 228         if ( my $err = $@ ) {
 229             warn "$meta_YAML_path: ".$err;
 230             next;
 231         }
 232     } else {
 233         warn "$meta_YAML_path does not exist for $module\n";
 234
 235         # I tried code to open the tarballs with Archive::Tar to find and
 236         # extract META.yml, but only Text-Tabs+Wrap-2006.1117.tar.gz had one,
 237         # so it's not worth including.
 238         next;
 239     }
 240 }
 241
 242 my $upstream_stanza = "%upstream = (\n";
 243 foreach my $module ( sort keys %module_to_upstream ) {
 244     my $upstream = defined $module_to_upstream{$module} ? "'$module_to_upstream{$module}'" : 'undef';
 245     $upstream_stanza .= sprintf "    %-24s=> %s,\n", "'$module'", $upstream;
 246 }
 247 $upstream_stanza .= ");";
 248
 249 $corelist =~ s/^%upstream .*? ;$/$upstream_stanza/ismx;
 250
 251 # Deprecation generation
 252 {
 253   my $delta_data = make_corelist_delta(
 254     $perl_vnum,
 255     \%module_to_deprecated,
 256     do { no warnings 'once'; \%Module::CoreList::deprecated },
 257   );
 258
 259   my $deprecated_stanza = "    " . $perl_vnum . " => {\n";
 260   $deprecated_stanza .= "        delta_from => $delta_data->{delta_from},\n";
 261   $deprecated_stanza .= "        changed => {\n";
 262   foreach my $key (sort keys $delta_data->{changed}->%*) {
 263     $deprecated_stanza .= sprintf "            %-24s=> %s,\n", "'$key'",
 264         defined $delta_data->{changed}{$key} ? "'"
 265           . $delta_data->{changed}{$key} . "'" : "undef";
 266   }
 267   $deprecated_stanza .= "        },\n";
 268   $deprecated_stanza .= "        removed => {\n";
 269   for my $key (sort keys %{ $delta_data->{removed} || {} }) {
 270     $deprecated_stanza .= sprintf "           %-24s=> %s,\n", "'$key'", 1;
 271   }
 272   $deprecated_stanza .= "        }\n";
 273   $deprecated_stanza .= "    },\n";
 274
 275   $corelist =~ s/^(%deprecated\s*=\s*.*?)^\s*$perl_vnum\s*=>\s*{.*?},\s*(^\);)$/$1$2/ism;
 276   $corelist =~ s/^(%deprecated\s*=\s*.*?)(^\);)$/$1$deprecated_stanza$2/xism;
 277 }
 278
 279 my $tracker = "%bug_tracker = (\n";
 280 foreach my $module ( sort keys %module_to_upstream ) {
 281     my $upstream = defined $module_to_upstream{$module};
 282     next
 283         if defined $upstream and $upstream eq 'blead';
 284
 285     my $bug_tracker;
 286
 287     my $dist = $module_to_dist{$module};
 288     $bug_tracker = $dist_to_meta_YAML{$dist}->{resources}{bugtracker}
 289         if $dist;
 290     $bug_tracker = $bug_tracker->{web} if ref($bug_tracker) eq "HASH";
 291
 292     $bug_tracker = defined $bug_tracker ? quote($bug_tracker) : 'undef';
 293     next if $bug_tracker eq "'https://github.com/Perl/perl5/issues'";
 294         next if $bug_tracker eq "'http://rt.perl.org/perlbug/'";
 295         next if $bug_tracker eq "'https://rt.perl.org/perlbug/'";
 296     $tracker .= sprintf "    %-24s=> %s,\n", "'$module'", $bug_tracker;
 297 }
 298 $tracker .= ");";
 299
 300 $corelist =~ s/^%bug_tracker .*? ;/$tracker/eismx;
 301
 302 write_corelist($corelist,$corelist_file);
 303
 304 open( my $utils_fh, '<', $utils_file );
 305 my $utils = join( '', <$utils_fh> );
 306 close $utils_fh;
 307
 308 my %utils = map { ( $_ => 1 ) } parse_utils_lst();
 309
 310 my $delta_utils = make_coreutils_delta($perl_vnum, \%utils);
 311
 312 my $utilities_in_release = "    " . $perl_vnum . " => {\n";
 313 $utilities_in_release .= "        delta_from => $delta_utils->{delta_from},\n";
 314 $utilities_in_release .= "        changed => {\n";
 315 foreach my $key (sort keys $delta_utils->{changed}->%*) {
 316   $utilities_in_release .= sprintf "            %-24s=> %s,\n", "'$key'",
 317       defined $delta_utils->{changed}{$key} ? "'"
 318         . $delta_utils->{changed}{$key} . "'" : "undef";
 319 }
 320 $utilities_in_release .= "        },\n";
 321 $utilities_in_release .= "        removed => {\n";
 322 for my $key (sort keys %{ $delta_utils->{removed} || {} }) {
 323   $utilities_in_release .= sprintf "            %-24s=> %s,\n", "'$key'", 1;
 324 }
 325 $utilities_in_release .= "        }\n";
 326 $utilities_in_release .= "    },\n";
 327
 328 $utils =~ s/^(my %delta\s*=\s*.*?)^\s*$perl_vnum\s*=>\s*{.*?},\s*(^\);)$/$1$2/ism;
 329 $utils =~ s/^(my %delta\s*=\s*.*?)(^\);)$/$1$utilities_in_release$2/ism;
 330
 331 write_corelist($utils,$utils_file);
 332
 333 warn "All done. Please check over the following files carefully before committing.\nThanks!\n";
 334 warn "$corelist_file\n$utils_file\n";
 335
 336 sub write_corelist {
 337     my $content = shift;
 338     my $filename = shift;
 339     open (my $clfh, ">", $filename);
 340     binmode $clfh;
 341     print $clfh $content;
 342     close($clfh);
 343 }
 344
 345 sub fetch_url {
 346     my $url = shift;
 347     my $http = HTTP::Tiny->new;
 348     my $response = $http->get($url);
 349     if ($response->{success}) {
 350         return $response->{content};
 351     } else {
 352         warn "Error fetching $url: $response->{status} $response->{reason}\n";
 353         return;
 354     }
 355 }
 356
 357 sub make_corelist_delta {
 358   my($version, $lines, $existing) = @_;
 359   # Trust core perl, if someone does use a weird version number the worst that
 360   # can happen is an extra delta entry for a module.
 361   my %versions = map { $_ => eval $lines->{$_} } keys %$lines;
 362
 363   # Ensure we have the corelist data loaded from this perl checkout, not the system one.
 364   require $corelist_file;
 365
 366   my %deltas;
 367   # Search for the release with the least amount of changes (this avoids having
 368   # to ask for where this perl was branched from).
 369   for my $previous (reverse sort { $a <=> $b } keys %$existing) {
 370     # Shouldn't happen, but ensure we don't load weird data...
 371     next if $previous > $version || $previous == $version;
 372     my $delta = $deltas{$previous} = {};
 373     ($delta->{changed}, $delta->{removed}) = calculate_delta(
 374       $existing->{$previous}, \%versions);
 375   }
 376
 377   my $smallest = (sort {
 378       ((keys($deltas{$a}->{changed}->%*) + keys($deltas{$a}->{removed}->%*)) <=>
 379        (keys($deltas{$b}->{changed}->%*) + keys($deltas{$b}->{removed}->%*))) ||
 380       $b <=> $a
 381     } keys %deltas)[0];
 382
 383   return {
 384     delta_from => $smallest,
 385     changed => $deltas{$smallest}{changed},
 386     removed => $deltas{$smallest}{removed},
 387   }
 388 }
 389
 390 sub make_coreutils_delta {
 391   my($version, $lines) = @_;
 392   # Trust core perl, if someone does use a weird version number the worst that
 393   # can happen is an extra delta entry for a module.
 394   my %utilities = map { $_ => eval $lines->{$_} } keys %$lines;
 395
 396   # Ensure we have the corelist data loaded from this perl checkout, not the system one.
 397   require $utils_file;
 398
 399   my %deltas;
 400   # Search for the release with the least amount of changes (this avoids having
 401   # to ask for where this perl was branched from).
 402   for my $previous (reverse sort { $a <=> $b } keys %Module::CoreList::Utils::utilities) {
 403     # Shouldn't happen, but ensure we don't load weird data...
 404     next if $previous > $version || $previous == $version;
 405
 406     my $delta = $deltas{$previous} = {};
 407     ($delta->{changed}, $delta->{removed}) = calculate_delta(
 408       $Module::CoreList::Utils::utilities{$previous}, \%utilities);
 409   }
 410
 411   my $smallest = (sort {
 412       ((keys($deltas{$a}->{changed}->%*) + keys($deltas{$a}->{removed}->%*)) <=>
 413        (keys($deltas{$b}->{changed}->%*) + keys($deltas{$b}->{removed}->%*))) ||
 414       $b <=> $a
 415     } keys %deltas)[0];
 416
 417   return {
 418     delta_from => $smallest,
 419     changed => $deltas{$smallest}{changed},
 420     removed => $deltas{$smallest}{removed},
 421   }
 422 }
 423
 424 # Calculate (changed, removed) modules between two versions.
 425 sub calculate_delta {
 426   my($from, $to) = @_;
 427   my(%changed, %removed);
 428
 429   for my $package(keys %$from) {
 430     if(not exists $to->{$package}) {
 431       $removed{$package} = 1;
 432     }
 433   }
 434
 435   for my $package(keys %$to) {
 436     if(!exists $from->{$package}
 437         || (defined $from->{$package} && !defined $to->{$package})
 438         || (!defined $from->{$package} && defined $to->{$package})
 439         || (defined $from->{$package} && defined $to->{$package}
 440             && $from->{$package} ne $to->{$package})) {
 441       $changed{$package} = $to->{$package};
 442     }
 443   }
 444
 445   return \%changed, \%removed;
 446 }
 447
 448 sub quote {
 449     my ($str) = @_;
 450     # There's gotta be something already doing this properly that we could just
 451     # reuse, but I can't quite thing of where to look for it, so I'm gonna do
 452     # the simplest possible thing that'll allow me to release 5.17.7.  --rafl
 453     $str =~ s/'/\\'/g;
 454     "'${str}'";
 455 }
 456
 457 sub parse_utils_lst {
 458   require File::Spec::Unix;
 459   my @scripts;
 460   open my $fh, '<', 'utils.lst' or die "$!\n";
 461   while (<$fh>) {
 462     chomp;
 463     my ($file,$extra) = split m!#!;
 464     $file =~ s!\s+!!g;
 465     push @scripts, $file;
 466     $extra =~ s!\s+!!g if $extra;
 467     if ( $extra and my ($link) = $extra =~ m!^link=(.+?)$! ) {
 468       push @scripts, $link;
 469     }
 470   }
 471   return map { +( File::Spec::Unix->splitpath( $_ ) )[-1] } @scripts;
 472 }