lib/ExtUtils.t

   1 #!./perl -w
   2
   3 print "1..27\n";
   4
   5 BEGIN {
   6     chdir 't' if -d 't';
   7     @INC = '../lib';
   8 }
   9
  10 use warnings;
  11 use strict;
  12 use ExtUtils::MakeMaker;
  13 use ExtUtils::Constant qw (constant_types C_constant XS_constant autoload);
  14 use Config;
  15 use File::Spec::Functions;
  16 use File::Spec;
  17 # Because were are going to be changing directory before running Makefile.PL
  18 my $perl = File::Spec->rel2abs( $^X );
  19 # ExtUtils::Constant::C_constant uses $^X inside a comment, and we want to
  20 # compare output to ensure that it is the same. We were probably run as ./perl
  21 # whereas we will run the child with the full path in $perl. So make $^X for
  22 # us the same as our child will see.
  23 $^X = $perl;
  24
  25 print "# perl=$perl\n";
  26 my $runperl = "$perl -x \"-I../../lib\"";
  27
  28 $| = 1;
  29
  30 my $dir = "ext-$$";
  31 my @files;
  32
  33 print "# $dir being created...\n";
  34 mkdir $dir, 0777 or die "mkdir: $!\n";
  35
  36
  37 END {
  38     use File::Path;
  39     print "# $dir being removed...\n";
  40     rmtree($dir);
  41 }
  42
  43 my $package = "ExtTest";
  44
  45 # Test the code that generates 1 and 2 letter name comparisons.
  46 my %compass = (
  47 N => 0, NE => 45, E => 90, SE => 135, S => 180, SW => 225, W => 270, NW => 315
  48 );
  49
  50 my $parent_rfc1149 =
  51   'A Standard for the Transmission of IP Datagrams on Avian Carriers';
  52
  53 my @names = ("FIVE", {name=>"OK6", type=>"PV",},
  54              {name=>"OK7", type=>"PVN",
  55               value=>['"not ok 7\\n\\0ok 7\\n"', 15]},
  56              {name => "FARTHING", type=>"NV"},
  57              {name => "NOT_ZERO", type=>"UV", value=>"~(UV)0"},
  58              {name => "OPEN", type=>"PV", value=>'"/*"', macro=>1},
  59              {name => "CLOSE", type=>"PV", value=>'"*/"',
  60               macro=>["#if 1\n", "#endif\n"]},
  61              {name => "ANSWER", default=>["UV", 42]}, "NOTDEF",
  62              {name => "Yes", type=>"YES"},
  63              {name => "No", type=>"NO"},
  64              {name => "Undef", type=>"UNDEF"},
  65 # OK. It wasn't really designed to allow the creation of dual valued constants.
  66 # It was more for INADDR_ANY INADDR_BROADCAST INADDR_LOOPBACK INADDR_NONE
  67              {name=>"RFC1149", type=>"SV", value=>"sv_2mortal(temp_sv)",
  68               pre=>"SV *temp_sv = newSVpv(RFC1149, 0); "
  69                    . "(void) SvUPGRADE(temp_sv,SVt_PVIV); SvIOK_on(temp_sv); "
  70                    . "SvIVX(temp_sv) = 1149;"},
  71 );
  72
  73 push @names, $_ foreach keys %compass;
  74
  75 my @names_only = map {(ref $_) ? $_->{name} : $_} @names;
  76
  77 my $types = {};
  78 my $constant_types = constant_types(); # macro defs
  79 my $C_constant = join "\n",
  80   C_constant ($package, undef, "IV", $types, undef, undef, @names);
  81 my $XS_constant = XS_constant ($package, $types); # XS for ExtTest::constant
  82
  83 ################ Header
  84 my $header = catfile($dir, "test.h");
  85 push @files, "test.h";
  86 open FH, ">$header" or die "open >$header: $!\n";
  87 print FH <<"EOT";
  88 #define FIVE 5
  89 #define OK6 "ok 6\\n"
  90 #define OK7 1
  91 #define FARTHING 0.25
  92 #define NOT_ZERO 1
  93 #define Yes 0
  94 #define No 1
  95 #define Undef 1
  96 #define RFC1149 "$parent_rfc1149"
  97 #undef NOTDEF
  98
  99 EOT
 100
 101 while (my ($point, $bearing) = each %compass) {
 102   print FH "#define $point $bearing\n"
 103 }
 104 close FH or die "close $header: $!\n";
 105
 106 ################ XS
 107 my $xs = catfile($dir, "$package.xs");
 108 push @files, "$package.xs";
 109 open FH, ">$xs" or die "open >$xs: $!\n";
 110
 111 print FH <<'EOT';
 112 #include "EXTERN.h"
 113 #include "perl.h"
 114 #include "XSUB.h"
 115 EOT
 116
 117 print FH "#include \"test.h\"\n\n";
 118 print FH $constant_types;
 119 print FH $C_constant, "\n";
 120 print FH "MODULE = $package             PACKAGE = $package\n";
 121 print FH "PROTOTYPES: ENABLE\n";
 122 print FH $XS_constant;
 123 close FH or die "close $xs: $!\n";
 124
 125 ################ PM
 126 my $pm = catfile($dir, "$package.pm");
 127 push @files, "$package.pm";
 128 open FH, ">$pm" or die "open >$pm: $!\n";
 129 print FH "package $package;\n";
 130 print FH "use $];\n";
 131
 132 print FH <<'EOT';
 133
 134 use strict;
 135 use warnings;
 136 use Carp;
 137
 138 require Exporter;
 139 require DynaLoader;
 140 use vars qw ($VERSION @ISA @EXPORT_OK);
 141
 142 $VERSION = '0.01';
 143 @ISA = qw(Exporter DynaLoader);
 144 @EXPORT_OK = qw(
 145 EOT
 146
 147 print FH "\t$_\n" foreach (@names_only);
 148 print FH ");\n";
 149 print FH autoload ($package, $]);
 150 print FH "bootstrap $package \$VERSION;\n1;\n__END__\n";
 151 close FH or die "close $pm: $!\n";
 152
 153 ################ test.pl
 154 my $testpl = catfile($dir, "test.pl");
 155 push @files, "test.pl";
 156 open FH, ">$testpl" or die "open >$testpl: $!\n";
 157
 158 print FH "use strict;\n";
 159 print FH "use $package qw(@names_only);\n";
 160 print FH <<'EOT';
 161
 162 # IV
 163 my $five = FIVE;
 164 if ($five == 5) {
 165   print "ok 5\n";
 166 } else {
 167   print "not ok 5 # $five\n";
 168 }
 169
 170 # PV
 171 print OK6;
 172
 173 # PVN containing embedded \0s
 174 $_ = OK7;
 175 s/.*\0//s;
 176 print;
 177
 178 # NV
 179 my $farthing = FARTHING;
 180 if ($farthing == 0.25) {
 181   print "ok 8\n";
 182 } else {
 183   print "not ok 8 # $farthing\n";
 184 }
 185
 186 # UV
 187 my $not_zero = NOT_ZERO;
 188 if ($not_zero > 0 && $not_zero == ~0) {
 189   print "ok 9\n";
 190 } else {
 191   print "not ok 9 # \$not_zero=$not_zero ~0=" . (~0) . "\n";
 192 }
 193
 194 # Value includes a "*/" in an attempt to bust out of a C comment.
 195 # Also tests custom cpp #if clauses
 196 my $close = CLOSE;
 197 if ($close eq '*/') {
 198   print "ok 10\n";
 199 } else {
 200   print "not ok 10 # \$close='$close'\n";
 201 }
 202
 203 # Default values if macro not defined.
 204 my $answer = ANSWER;
 205 if ($answer == 42) {
 206   print "ok 11\n";
 207 } else {
 208   print "not ok 11 # What do you get if you multiply six by nine? '$answer'\n";
 209 }
 210
 211 # not defined macro
 212 my $notdef = eval { NOTDEF; };
 213 if (defined $notdef) {
 214   print "not ok 12 # \$notdef='$notdef'\n";
 215 } elsif ($@ !~ /Your vendor has not defined ExtTest macro NOTDEF/) {
 216   print "not ok 12 # \$@='$@'\n";
 217 } else {
 218   print "ok 12\n";
 219 }
 220
 221 # not a macro
 222 my $notthere = eval { &ExtTest::NOTTHERE; };
 223 if (defined $notthere) {
 224   print "not ok 13 # \$notthere='$notthere'\n";
 225 } elsif ($@ !~ /NOTTHERE is not a valid ExtTest macro/) {
 226   chomp $@;
 227   print "not ok 13 # \$@='$@'\n";
 228 } else {
 229   print "ok 13\n";
 230 }
 231
 232 # Truth
 233 my $yes = Yes;
 234 if ($yes) {
 235   print "ok 14\n";
 236 } else {
 237   print "not ok 14 # $yes='\$yes'\n";
 238 }
 239
 240 # Falsehood
 241 my $no = No;
 242 if (defined $no and !$no) {
 243   print "ok 15\n";
 244 } else {
 245   print "not ok 15 # \$no=" . defined ($no) ? "'$no'\n" : "undef\n";
 246 }
 247
 248 # Undef
 249 my $undef = Undef;
 250 unless (defined $undef) {
 251   print "ok 16\n";
 252 } else {
 253   print "not ok 16 # \$undef='$undef'\n";
 254 }
 255
 256
 257 # invalid macro (chosen to look like a mix up between No and SW)
 258 $notdef = eval { &ExtTest::So };
 259 if (defined $notdef) {
 260   print "not ok 17 # \$notdef='$notdef'\n";
 261 } elsif ($@ !~ /^So is not a valid ExtTest macro/) {
 262   print "not ok 17 # \$@='$@'\n";
 263 } else {
 264   print "ok 17\n";
 265 }
 266
 267 # invalid defined macro
 268 $notdef = eval { &ExtTest::EW };
 269 if (defined $notdef) {
 270   print "not ok 18 # \$notdef='$notdef'\n";
 271 } elsif ($@ !~ /^EW is not a valid ExtTest macro/) {
 272   print "not ok 18 # \$@='$@'\n";
 273 } else {
 274   print "ok 18\n";
 275 }
 276
 277 my %compass = (
 278 EOT
 279
 280 while (my ($point, $bearing) = each %compass) {
 281   print FH "$point => $bearing, "
 282 }
 283
 284 print FH <<'EOT';
 285
 286 );
 287
 288 my $fail;
 289 while (my ($point, $bearing) = each %compass) {
 290   my $val = eval $point;
 291   if ($@) {
 292     print "# $point: \$@='$@'\n";
 293     $fail = 1;
 294   } elsif (!defined $bearing) {
 295     print "# $point: \$val=undef\n";
 296     $fail = 1;
 297   } elsif ($val != $bearing) {
 298     print "# $point: \$val=$val, not $bearing\n";
 299     $fail = 1;
 300   }
 301 }
 302 if ($fail) {
 303   print "not ok 19\n";
 304 } else {
 305   print "ok 19\n";
 306 }
 307
 308 EOT
 309
 310 print FH <<"EOT";
 311 my \$rfc1149 = RFC1149;
 312 if (\$rfc1149 ne "$parent_rfc1149") {
 313   print "not ok 20 # '\$rfc1149' ne '$parent_rfc1149'\n";
 314 } else {
 315   print "ok 20\n";
 316 }
 317
 318 if (\$rfc1149 != 1149) {
 319   printf "not ok 21 # %d != 1149\n", \$rfc1149;
 320 } else {
 321   print "ok 21\n";
 322 }
 323
 324 EOT
 325
 326 print FH <<'EOT';
 327 # test macro=>1
 328 my $open = OPEN;
 329 if ($open eq '/*') {
 330   print "ok 22\n";
 331 } else {
 332   print "not ok 22 # \$open='$open'\n";
 333 }
 334 EOT
 335 close FH or die "close $testpl: $!\n";
 336
 337 ################ Makefile.PL
 338 # We really need a Makefile.PL because make test for a no dynamic linking perl
 339 # will run Makefile.PL again as part of the "make perl" target.
 340 my $makefilePL = catfile($dir, "Makefile.PL");
 341 push @files, "Makefile.PL";
 342 open FH, ">$makefilePL" or die "open >$makefilePL: $!\n";
 343 print FH <<"EOT";
 344 #!$perl -w
 345 use ExtUtils::MakeMaker;
 346 WriteMakefile(
 347               'NAME'            => "$package",
 348               'VERSION_FROM'    => "$package.pm", # finds \$VERSION
 349               (\$] >= 5.005 ?
 350                (#ABSTRACT_FROM => "$package.pm", # XXX add this
 351                 AUTHOR     => "$0") : ())
 352              );
 353 EOT
 354
 355 close FH or die "close $makefilePL: $!\n";
 356
 357 chdir $dir or die $!; push @INC,  '../../lib';
 358 END {chdir ".." or warn $!};
 359
 360 my @perlout = `$runperl Makefile.PL`;
 361 if ($?) {
 362   print "not ok 1 # $runperl Makefile.PL failed: $?\n";
 363   print "# $_" foreach @perlout;
 364   exit($?);
 365 } else {
 366   print "ok 1\n";
 367 }
 368
 369
 370 my $makefile = ($^O eq 'VMS' ? 'descrip' : 'Makefile');
 371 my $makefile_ext = ($^O eq 'VMS' ? '.mms' : '');
 372 if (-f "$makefile$makefile_ext") {
 373   print "ok 2\n";
 374 } else {
 375   print "not ok 2\n";
 376 }
 377 my $makefile_rename = ($^O eq 'VMS' ? '.mms' : '.old');
 378 push @files, "$makefile$makefile_rename"; # Renamed by make clean
 379
 380 my $make = $Config{make};
 381
 382 $make = $ENV{MAKE} if exists $ENV{MAKE};
 383
 384 if ($^O eq 'MSWin32' && $make =~ /\bnmake\b/) { $make .= " -nologo"; }
 385
 386 my $makeout;
 387
 388 print "# make = '$make'\n";
 389 $makeout = `$make`;
 390 if ($?) {
 391   print "not ok 3 # $make failed: $?\n";
 392   exit($?);
 393 } else {
 394   print "ok 3\n";
 395 }
 396
 397 if ($Config{usedl}) {
 398   print "ok 4\n";
 399 } else {
 400   push @files, "perl$Config{exe_ext}";
 401   my $makeperl = "$make perl";
 402   print "# make = '$makeperl'\n";
 403   $makeout = `$makeperl`;
 404   if ($?) {
 405     print "not ok 4 # $makeperl failed: $?\n";
 406     exit($?);
 407   } else {
 408     print "ok 4\n";
 409   }
 410 }
 411
 412 my $test = 23;
 413 my $maketest = "$make test";
 414 print "# make = '$maketest'\n";
 415 $makeout = `$maketest`;
 416
 417 # echo of running the test script
 418 $makeout =~ s/^\s*PERL_DL_NONLAZY=.+?\n//m;
 419 $makeout =~ s/^MCR.+test.pl\n//mig if $^O eq 'VMS';
 420
 421 # GNU make babblings
 422 $makeout =~ s/^\w*?make.+?(?:entering|leaving) directory.+?\n//mig;
 423
 424 # Hopefully gets most make's babblings
 425 # make -f Makefile.aperl perl
 426 $makeout =~ s/^\w*?make.+\sperl[^A-Za-z0-9]*\n//mig;
 427 # make[1]: `perl' is up to date.
 428 $makeout =~ s/^\w*?make.+perl.+?is up to date.*?\n//mig;
 429
 430 print $makeout;
 431
 432 if ($?) {
 433   print "not ok $test # $maketest failed: $?\n";
 434 } else {
 435   print "ok $test\n";
 436 }
 437 $test++;
 438
 439 my $regen = `$runperl $package.xs`;
 440 if ($?) {
 441   print "not ok $test # $runperl $package.xs failed: $?\n";
 442 } else {
 443   print "ok $test\n";
 444 }
 445 $test++;
 446
 447 my $expect = $constant_types . $C_constant .
 448   "\n#### XS Section:\n" . $XS_constant;
 449
 450 if ($expect eq $regen) {
 451   print "ok $test\n";
 452 } else {
 453   print "not ok $test\n";
 454   # open FOO, ">expect"; print FOO $expect;
 455   # open FOO, ">regen"; print FOO $regen; close FOO;
 456 }
 457 $test++;
 458
 459 my $makeclean = "$make clean";
 460 print "# make = '$makeclean'\n";
 461 $makeout = `$makeclean`;
 462 if ($?) {
 463   print "not ok $test # $make failed: $?\n";
 464 } else {
 465   print "ok $test\n";
 466 }
 467 $test++;
 468
 469 foreach (@files) {
 470   unlink $_ or warn "unlink $_: $!";
 471 }
 472
 473 my $fail;
 474 opendir DIR, "." or die "opendir '.': $!";
 475 while (defined (my $entry = readdir DIR)) {
 476   next if $entry =~ /^\.\.?$/;
 477   print "# Extra file '$entry'\n";
 478   $fail = 1;
 479 }
 480 closedir DIR or warn "closedir '.': $!";
 481 if ($fail) {
 482   print "not ok $test\n";
 483 } else {
 484   print "ok $test\n";
 485 }