pod/perlfaq5.pod

   1 =head1 NAME
   2
   3 perlfaq5 - Files and Formats ($Revision: 8075 $)
   4
   5 =head1 DESCRIPTION
   6
   7 This section deals with I/O and the "f" issues: filehandles, flushing,
   8 formats, and footers.
   9
  10 =head2 How do I flush/unbuffer an output filehandle?  Why must I do this?
  11 X<flush> X<buffer> X<unbuffer> X<autoflush>
  12
  13 Perl does not support truly unbuffered output (except
  14 insofar as you can C<syswrite(OUT, $char, 1)>), although it
  15 does support is "command buffering", in which a physical
  16 write is performed after every output command.
  17
  18 The C standard I/O library (stdio) normally buffers
  19 characters sent to devices so that there isn't a system call
  20 for each byte. In most stdio implementations, the type of
  21 output buffering and the size of the buffer varies according
  22 to the type of device. Perl's print() and write() functions
  23 normally buffer output, while syswrite() bypasses buffering
  24 all together.
  25
  26 If you want your output to be sent immediately when you
  27 execute print() or write() (for instance, for some network
  28 protocols), you must set the handle's autoflush flag. This
  29 flag is the Perl variable $| and when it is set to a true
  30 value, Perl will flush the handle's buffer after each
  31 print() or write(). Setting $| affects buffering only for
  32 the currently selected default file handle. You choose this
  33 handle with the one argument select() call (see
  34 L<perlvar/$E<verbar>> and L<perlfunc/select>).
  35
  36 Use select() to choose the desired handle, then set its
  37 per-filehandle variables.
  38
  39         $old_fh = select(OUTPUT_HANDLE);
  40         $| = 1;
  41         select($old_fh);
  42
  43 Some modules offer object-oriented access to handles and their
  44 variables, although they may be overkill if this is the only
  45 thing you do with them.  You can use IO::Handle:
  46
  47         use IO::Handle;
  48         open(DEV, ">/dev/printer");   # but is this?
  49         DEV->autoflush(1);
  50
  51 or IO::Socket:
  52
  53         use IO::Socket;           # this one is kinda a pipe?
  54         my $sock = IO::Socket::INET->new( 'www.example.com:80' );
  55
  56         $sock->autoflush();
  57
  58 =head2 How do I change, delete, or insert a line in a file, or append to the beginning of a file?
  59 X<file, editing>
  60
  61 (contributed by brian d foy)
  62
  63 The basic idea of inserting, changing, or deleting a line from a text
  64 file involves reading and printing the file to the point you want to
  65 make the change, making the change, then reading and printing the rest
  66 of the file. Perl doesn't provide random access to lines (especially
  67 since the record input separator, C<$/>, is mutable), although modules
  68 such as C<Tie::File> can fake it.
  69
  70 A Perl program to do these tasks takes the basic form of opening a
  71 file, printing its lines, then closing the file:
  72
  73         open my $in,  '<',  $file      or die "Can't read old file: $!";
  74         open my $out, '>', "$file.new" or die "Can't write new file: $!";
  75
  76         while( <$in> )
  77                 {
  78                 print $out $_;
  79                 }
  80
  81    close $out;
  82
  83 Within that basic form, add the parts that you need to insert, change,
  84 or delete lines.
  85
  86 To prepend lines to the beginning, print those lines before you enter
  87 the loop that prints the existing lines.
  88
  89         open my $in,  '<',  $file      or die "Can't read old file: $!";
  90         open my $out, '>', "$file.new" or die "Can't write new file: $!";
  91
  92         print "# Add this line to the top\n"; # <--- HERE'S THE MAGIC
  93
  94         while( <$in> )
  95                 {
  96                 print $out $_;
  97                 }
  98
  99    close $out;
 100
 101 To change existing lines, insert the code to modify the lines inside
 102 the C<while> loop. In this case, the code finds all lowercased
 103 versions of "perl" and uppercases them. The happens for every line, so
 104 be sure that you're supposed to do that on every line!
 105
 106         open my $in,  '<',  $file      or die "Can't read old file: $!";
 107         open my $out, '>', "$file.new" or die "Can't write new file: $!";
 108
 109         print "# Add this line to the top\n";
 110
 111         while( <$in> )
 112                 {
 113                 s/\b(perl)\b/Perl/g;
 114                 print $out $_;
 115                 }
 116
 117    close $out;
 118
 119 To change only a particular line, the input line number, C<$.>, is
 120 useful. Use C<next> to skip all lines up to line 5, make a change and
 121 print the result, then stop further processing with C<last>.
 122
 123         while( <$in> )
 124                 {
 125                 next unless $. == 5;
 126                 s/\b(perl)\b/Perl/g;
 127                 print $out $_;
 128                 last;
 129                 }
 130
 131 To skip lines, use the looping controls. The C<next> in this example
 132 skips comment lines, and the C<last> stops all processing once it
 133 encounters either C<__END__> or C<__DATA__>.
 134
 135         while( <$in> )
 136                 {
 137                 next if /^\s+#/;             # skip comment lines
 138                 last if /^__(END|DATA)__$/;  # stop at end of code marker
 139                 print $out $_;
 140                 }
 141
 142 Do the same sort of thing to delete a particular line by using C<next>
 143 to skip the lines you don't want to show up in the output. This
 144 example skips every fifth line:
 145
 146         while( <$in> )
 147                 {
 148                 next unless $. % 5;
 149                 print $out $_;
 150                 }
 151
 152 If, for some odd reason, you really want to see the whole file at once
 153 rather than processing line by line, you can slurp it in (as long as
 154 you can fit the whole thing in memory!):
 155
 156         open my $in,  '<',  $file      or die "Can't read old file: $!"
 157         open my $out, '>', "$file.new" or die "Can't write new file: $!";
 158
 159         my @lines = do { local $/; <$in> }; # slurp!
 160
 161                 # do your magic here
 162
 163         print $out @lines;
 164
 165 Modules such as C<File::Slurp> and C<Tie::File> can help with that
 166 too. If you can, however, avoid reading the entire file at once. Perl
 167 won't give that memory back to the operating system until the process
 168 finishes.
 169
 170 You can also use Perl one-liners to modify a file in-place. The
 171 following changes all 'Fred' to 'Barney' in F<inFile.txt>, overwriting
 172 the file with the new contents. With the C<-p> switch, Perl wraps a
 173 C<while> loop around the code you specify with C<-e>, and C<-i> turns
 174 on in-place editing. The current line is in C<$_>. With C<-p>, Perl
 175 automatically prints the value of C<$_> at the end of the loop. See
 176 L<perlrun> for more details.
 177
 178         perl -pi -e 's/Fred/Barney/' inFile.txt
 179
 180 To make a backup of C<inFile.txt>, give C<-i> a file extension to add:
 181
 182         perl -pi.bak -e 's/Fred/Barney/' inFile.txt
 183
 184 To change only the fifth line, you can add a test checking C<$.>, the
 185 input line number, then only perform the operation when the test
 186 passes:
 187
 188         perl -pi -e 's/Fred/Barney/ if $. == 5' inFile.txt
 189
 190 To add lines before a certain line, you can add a line (or lines!)
 191 before Perl prints C<$_>:
 192
 193         perl -pi -e 'print "Put before third line\n" if $. == 3' inFile.txt
 194
 195 You can even add a line to the beginning of a file, since the current
 196 line prints at the end of the loop:
 197
 198         perl -pi -e 'print "Put before first line\n" if $. == 1' inFile.txt
 199
 200 To insert a line after one already in the file, use the C<-n> switch.
 201 It's just like C<-p> except that it doesn't print C<$_> at the end of
 202 the loop, so you have to do that yourself. In this case, print C<$_>
 203 first, then print the line that you want to add.
 204
 205         perl -ni -e 'print; print "Put after fifth line\n" if $. == 5' inFile.txt
 206
 207 To delete lines, only print the ones that you want.
 208
 209         perl -ni -e 'print unless /d/' inFile.txt
 210
 211                 ... or ...
 212
 213         perl -pi -e 'next unless /d/' inFile.txt
 214
 215 =head2 How do I count the number of lines in a file?
 216 X<file, counting lines> X<lines> X<line>
 217
 218 One fairly efficient way is to count newlines in the file. The
 219 following program uses a feature of tr///, as documented in L<perlop>.
 220 If your text file doesn't end with a newline, then it's not really a
 221 proper text file, so this may report one fewer line than you expect.
 222
 223         $lines = 0;
 224         open(FILE, $filename) or die "Can't open `$filename': $!";
 225         while (sysread FILE, $buffer, 4096) {
 226                 $lines += ($buffer =~ tr/\n//);
 227                 }
 228         close FILE;
 229
 230 This assumes no funny games with newline translations.
 231
 232 =head2 How can I use Perl's C<-i> option from within a program?
 233 X<-i> X<in-place>
 234
 235 C<-i> sets the value of Perl's C<$^I> variable, which in turn affects
 236 the behavior of C<< <> >>; see L<perlrun> for more details.  By
 237 modifying the appropriate variables directly, you can get the same
 238 behavior within a larger program.  For example:
 239
 240         # ...
 241         {
 242         local($^I, @ARGV) = ('.orig', glob("*.c"));
 243         while (<>) {
 244                 if ($. == 1) {
 245                         print "This line should appear at the top of each file\n";
 246                 }
 247                 s/\b(p)earl\b/${1}erl/i;        # Correct typos, preserving case
 248                 print;
 249                 close ARGV if eof;              # Reset $.
 250                 }
 251         }
 252         # $^I and @ARGV return to their old values here
 253
 254 This block modifies all the C<.c> files in the current directory,
 255 leaving a backup of the original data from each file in a new
 256 C<.c.orig> file.
 257
 258 =head2 How can I copy a file?
 259 X<copy> X<file, copy>
 260
 261 (contributed by brian d foy)
 262
 263 Use the File::Copy module. It comes with Perl and can do a
 264 true copy across file systems, and it does its magic in
 265 a portable fashion.
 266
 267         use File::Copy;
 268
 269         copy( $original, $new_copy ) or die "Copy failed: $!";
 270
 271 If you can't use File::Copy, you'll have to do the work yourself:
 272 open the original file, open the destination file, then print
 273 to the destination file as you read the original.
 274
 275 =head2 How do I make a temporary file name?
 276 X<file, temporary>
 277
 278 If you don't need to know the name of the file, you can use C<open()>
 279 with C<undef> in place of the file name.  The C<open()> function
 280 creates an anonymous temporary file.
 281
 282         open my $tmp, '+>', undef or die $!;
 283
 284 Otherwise, you can use the File::Temp module.
 285
 286         use File::Temp qw/ tempfile tempdir /;
 287
 288         $dir = tempdir( CLEANUP => 1 );
 289         ($fh, $filename) = tempfile( DIR => $dir );
 290
 291         # or if you don't need to know the filename
 292
 293         $fh = tempfile( DIR => $dir );
 294
 295 The File::Temp has been a standard module since Perl 5.6.1.  If you
 296 don't have a modern enough Perl installed, use the C<new_tmpfile>
 297 class method from the IO::File module to get a filehandle opened for
 298 reading and writing.  Use it if you don't need to know the file's name:
 299
 300         use IO::File;
 301         $fh = IO::File->new_tmpfile()
 302         or die "Unable to make new temporary file: $!";
 303
 304 If you're committed to creating a temporary file by hand, use the
 305 process ID and/or the current time-value.  If you need to have many
 306 temporary files in one process, use a counter:
 307
 308         BEGIN {
 309         use Fcntl;
 310         my $temp_dir = -d '/tmp' ? '/tmp' : $ENV{TMPDIR} || $ENV{TEMP};
 311         my $base_name = sprintf("%s/%d-%d-0000", $temp_dir, $$, time());
 312
 313         sub temp_file {
 314                 local *FH;
 315                 my $count = 0;
 316                 until (defined(fileno(FH)) || $count++ > 100) {
 317                 $base_name =~ s/-(\d+)$/"-" . (1 + $1)/e;
 318                 # O_EXCL is required for security reasons.
 319                 sysopen(FH, $base_name, O_WRONLY|O_EXCL|O_CREAT);
 320                 }
 321
 322         if (defined(fileno(FH))
 323                 return (*FH, $base_name);
 324             }
 325         else {
 326                 return ();
 327             }
 328         }
 329         }
 330
 331 =head2 How can I manipulate fixed-record-length files?
 332 X<fixed-length> X<file, fixed-length records>
 333
 334 The most efficient way is using L<pack()|perlfunc/"pack"> and
 335 L<unpack()|perlfunc/"unpack">.  This is faster than using
 336 L<substr()|perlfunc/"substr"> when taking many, many strings.  It is
 337 slower for just a few.
 338
 339 Here is a sample chunk of code to break up and put back together again
 340 some fixed-format input lines, in this case from the output of a normal,
 341 Berkeley-style ps:
 342
 343         # sample input line:
 344         #   15158 p5  T      0:00 perl /home/tchrist/scripts/now-what
 345         my $PS_T = 'A6 A4 A7 A5 A*';
 346         open my $ps, '-|', 'ps';
 347         print scalar <$ps>;
 348         my @fields = qw( pid tt stat time command );
 349         while (<$ps>) {
 350                 my %process;
 351                 @process{@fields} = unpack($PS_T, $_);
 352         for my $field ( @fields ) {
 353                 print "$field: <$process{$field}>\n";
 354         }
 355         print 'line=', pack($PS_T, @process{@fields} ), "\n";
 356         }
 357
 358 We've used a hash slice in order to easily handle the fields of each row.
 359 Storing the keys in an array means it's easy to operate on them as a
 360 group or loop over them with for. It also avoids polluting the program
 361 with global variables and using symbolic references.
 362
 363 =head2 How can I make a filehandle local to a subroutine?  How do I pass filehandles between subroutines?  How do I make an array of filehandles?
 364 X<filehandle, local> X<filehandle, passing> X<filehandle, reference>
 365
 366 As of perl5.6, open() autovivifies file and directory handles
 367 as references if you pass it an uninitialized scalar variable.
 368 You can then pass these references just like any other scalar,
 369 and use them in the place of named handles.
 370
 371         open my    $fh, $file_name;
 372
 373         open local $fh, $file_name;
 374
 375         print $fh "Hello World!\n";
 376
 377         process_file( $fh );
 378
 379 If you like, you can store these filehandles in an array or a hash.
 380 If you access them directly, they aren't simple scalars and you
 381 need to give C<print> a little help by placing the filehandle
 382 reference in braces. Perl can only figure it out on its own when
 383 the filehandle reference is a simple scalar.
 384
 385         my @fhs = ( $fh1, $fh2, $fh3 );
 386
 387         for( $i = 0; $i <= $#fhs; $i++ ) {
 388                 print {$fhs[$i]} "just another Perl answer, \n";
 389                 }
 390
 391 Before perl5.6, you had to deal with various typeglob idioms
 392 which you may see in older code.
 393
 394         open FILE, "> $filename";
 395         process_typeglob(   *FILE );
 396         process_reference( \*FILE );
 397
 398         sub process_typeglob  { local *FH = shift; print FH  "Typeglob!" }
 399         sub process_reference { local $fh = shift; print $fh "Reference!" }
 400
 401 If you want to create many anonymous handles, you should
 402 check out the Symbol or IO::Handle modules.
 403
 404 =head2 How can I use a filehandle indirectly?
 405 X<filehandle, indirect>
 406
 407 An indirect filehandle is using something other than a symbol
 408 in a place that a filehandle is expected.  Here are ways
 409 to get indirect filehandles:
 410
 411         $fh =   SOME_FH;       # bareword is strict-subs hostile
 412         $fh =  "SOME_FH";      # strict-refs hostile; same package only
 413         $fh =  *SOME_FH;       # typeglob
 414         $fh = \*SOME_FH;       # ref to typeglob (bless-able)
 415         $fh =  *SOME_FH{IO};   # blessed IO::Handle from *SOME_FH typeglob
 416
 417 Or, you can use the C<new> method from one of the IO::* modules to
 418 create an anonymous filehandle, store that in a scalar variable,
 419 and use it as though it were a normal filehandle.
 420
 421         use IO::Handle;                     # 5.004 or higher
 422         $fh = IO::Handle->new();
 423
 424 Then use any of those as you would a normal filehandle.  Anywhere that
 425 Perl is expecting a filehandle, an indirect filehandle may be used
 426 instead. An indirect filehandle is just a scalar variable that contains
 427 a filehandle.  Functions like C<print>, C<open>, C<seek>, or
 428 the C<< <FH> >> diamond operator will accept either a named filehandle
 429 or a scalar variable containing one:
 430
 431         ($ifh, $ofh, $efh) = (*STDIN, *STDOUT, *STDERR);
 432         print $ofh "Type it: ";
 433         $got = <$ifh>
 434         print $efh "What was that: $got";
 435
 436 If you're passing a filehandle to a function, you can write
 437 the function in two ways:
 438
 439         sub accept_fh {
 440                 my $fh = shift;
 441                 print $fh "Sending to indirect filehandle\n";
 442         }
 443
 444 Or it can localize a typeglob and use the filehandle directly:
 445
 446         sub accept_fh {
 447                 local *FH = shift;
 448                 print  FH "Sending to localized filehandle\n";
 449         }
 450
 451 Both styles work with either objects or typeglobs of real filehandles.
 452 (They might also work with strings under some circumstances, but this
 453 is risky.)
 454
 455         accept_fh(*STDOUT);
 456         accept_fh($handle);
 457
 458 In the examples above, we assigned the filehandle to a scalar variable
 459 before using it.  That is because only simple scalar variables, not
 460 expressions or subscripts of hashes or arrays, can be used with
 461 built-ins like C<print>, C<printf>, or the diamond operator.  Using
 462 something other than a simple scalar variable as a filehandle is
 463 illegal and won't even compile:
 464
 465         @fd = (*STDIN, *STDOUT, *STDERR);
 466         print $fd[1] "Type it: ";                           # WRONG
 467         $got = <$fd[0]>                                     # WRONG
 468         print $fd[2] "What was that: $got";                 # WRONG
 469
 470 With C<print> and C<printf>, you get around this by using a block and
 471 an expression where you would place the filehandle:
 472
 473         print  { $fd[1] } "funny stuff\n";
 474         printf { $fd[1] } "Pity the poor %x.\n", 3_735_928_559;
 475         # Pity the poor deadbeef.
 476
 477 That block is a proper block like any other, so you can put more
 478 complicated code there.  This sends the message out to one of two places:
 479
 480         $ok = -x "/bin/cat";
 481         print { $ok ? $fd[1] : $fd[2] } "cat stat $ok\n";
 482         print { $fd[ 1+ ($ok || 0) ]  } "cat stat $ok\n";
 483
 484 This approach of treating C<print> and C<printf> like object methods
 485 calls doesn't work for the diamond operator.  That's because it's a
 486 real operator, not just a function with a comma-less argument.  Assuming
 487 you've been storing typeglobs in your structure as we did above, you
 488 can use the built-in function named C<readline> to read a record just
 489 as C<< <> >> does.  Given the initialization shown above for @fd, this
 490 would work, but only because readline() requires a typeglob.  It doesn't
 491 work with objects or strings, which might be a bug we haven't fixed yet.
 492
 493         $got = readline($fd[0]);
 494
 495 Let it be noted that the flakiness of indirect filehandles is not
 496 related to whether they're strings, typeglobs, objects, or anything else.
 497 It's the syntax of the fundamental operators.  Playing the object
 498 game doesn't help you at all here.
 499
 500 =head2 How can I set up a footer format to be used with write()?
 501 X<footer>
 502
 503 There's no builtin way to do this, but L<perlform> has a couple of
 504 techniques to make it possible for the intrepid hacker.
 505
 506 =head2 How can I write() into a string?
 507 X<write, into a string>
 508
 509 See L<perlform/"Accessing Formatting Internals"> for an swrite() function.
 510
 511 =head2 How can I output my numbers with commas added?
 512 X<number, commify>
 513
 514 (contributed by brian d foy and Benjamin Goldberg)
 515
 516 You can use L<Number::Format> to separate places in a number.
 517 It handles locale information for those of you who want to insert
 518 full stops instead (or anything else that they want to use,
 519 really).
 520
 521 This subroutine will add commas to your number:
 522
 523         sub commify {
 524                 local $_  = shift;
 525                 1 while s/^([-+]?\d+)(\d{3})/$1,$2/;
 526                 return $_;
 527                 }
 528
 529 This regex from Benjamin Goldberg will add commas to numbers:
 530
 531         s/(^[-+]?\d+?(?=(?>(?:\d{3})+)(?!\d))|\G\d{3}(?=\d))/$1,/g;
 532
 533 It is easier to see with comments:
 534
 535         s/(
 536                 ^[-+]?             # beginning of number.
 537                 \d+?               # first digits before first comma
 538                 (?=                # followed by, (but not included in the match) :
 539                         (?>(?:\d{3})+) # some positive multiple of three digits.
 540                         (?!\d)         # an *exact* multiple, not x * 3 + 1 or whatever.
 541                 )
 542                 |                  # or:
 543                 \G\d{3}            # after the last group, get three digits
 544                 (?=\d)             # but they have to have more digits after them.
 545         )/$1,/xg;
 546
 547 =head2 How can I translate tildes (~) in a filename?
 548 X<tilde> X<tilde expansion>
 549
 550 Use the <> (glob()) operator, documented in L<perlfunc>.  Older
 551 versions of Perl require that you have a shell installed that groks
 552 tildes.  Recent perl versions have this feature built in. The
 553 File::KGlob module (available from CPAN) gives more portable glob
 554 functionality.
 555
 556 Within Perl, you may use this directly:
 557
 558         $filename =~ s{
 559           ^ ~             # find a leading tilde
 560           (               # save this in $1
 561               [^/]        # a non-slash character
 562                     *     # repeated 0 or more times (0 means me)
 563           )
 564         }{
 565           $1
 566               ? (getpwnam($1))[7]
 567               : ( $ENV{HOME} || $ENV{LOGDIR} )
 568         }ex;
 569
 570 =head2 How come when I open a file read-write it wipes it out?
 571 X<clobber> X<read-write> X<clobbering> X<truncate> X<truncating>
 572
 573 Because you're using something like this, which truncates the file and
 574 I<then> gives you read-write access:
 575
 576         open(FH, "+> /path/name");              # WRONG (almost always)
 577
 578 Whoops.  You should instead use this, which will fail if the file
 579 doesn't exist.
 580
 581         open(FH, "+< /path/name");      # open for update
 582
 583 Using ">" always clobbers or creates.  Using "<" never does
 584 either.  The "+" doesn't change this.
 585
 586 Here are examples of many kinds of file opens.  Those using sysopen()
 587 all assume
 588
 589         use Fcntl;
 590
 591 To open file for reading:
 592
 593         open(FH, "< $path")                                 || die $!;
 594         sysopen(FH, $path, O_RDONLY)                        || die $!;
 595
 596 To open file for writing, create new file if needed or else truncate old file:
 597
 598         open(FH, "> $path") || die $!;
 599         sysopen(FH, $path, O_WRONLY|O_TRUNC|O_CREAT)        || die $!;
 600         sysopen(FH, $path, O_WRONLY|O_TRUNC|O_CREAT, 0666)  || die $!;
 601
 602 To open file for writing, create new file, file must not exist:
 603
 604         sysopen(FH, $path, O_WRONLY|O_EXCL|O_CREAT)         || die $!;
 605         sysopen(FH, $path, O_WRONLY|O_EXCL|O_CREAT, 0666)   || die $!;
 606
 607 To open file for appending, create if necessary:
 608
 609         open(FH, ">> $path") || die $!;
 610         sysopen(FH, $path, O_WRONLY|O_APPEND|O_CREAT)       || die $!;
 611         sysopen(FH, $path, O_WRONLY|O_APPEND|O_CREAT, 0666) || die $!;
 612
 613 To open file for appending, file must exist:
 614
 615         sysopen(FH, $path, O_WRONLY|O_APPEND)               || die $!;
 616
 617 To open file for update, file must exist:
 618
 619         open(FH, "+< $path")                                || die $!;
 620         sysopen(FH, $path, O_RDWR)                          || die $!;
 621
 622 To open file for update, create file if necessary:
 623
 624         sysopen(FH, $path, O_RDWR|O_CREAT)                  || die $!;
 625         sysopen(FH, $path, O_RDWR|O_CREAT, 0666)            || die $!;
 626
 627 To open file for update, file must not exist:
 628
 629         sysopen(FH, $path, O_RDWR|O_EXCL|O_CREAT)           || die $!;
 630         sysopen(FH, $path, O_RDWR|O_EXCL|O_CREAT, 0666)     || die $!;
 631
 632 To open a file without blocking, creating if necessary:
 633
 634         sysopen(FH, "/foo/somefile", O_WRONLY|O_NDELAY|O_CREAT)
 635             or die "can't open /foo/somefile: $!":
 636
 637 Be warned that neither creation nor deletion of files is guaranteed to
 638 be an atomic operation over NFS.  That is, two processes might both
 639 successfully create or unlink the same file!  Therefore O_EXCL
 640 isn't as exclusive as you might wish.
 641
 642 See also the new L<perlopentut> if you have it (new for 5.6).
 643
 644 =head2 Why do I sometimes get an "Argument list too long" when I use E<lt>*E<gt>?
 645 X<argument list too long>
 646
 647 The C<< <> >> operator performs a globbing operation (see above).
 648 In Perl versions earlier than v5.6.0, the internal glob() operator forks
 649 csh(1) to do the actual glob expansion, but
 650 csh can't handle more than 127 items and so gives the error message
 651 C<Argument list too long>.  People who installed tcsh as csh won't
 652 have this problem, but their users may be surprised by it.
 653
 654 To get around this, either upgrade to Perl v5.6.0 or later, do the glob
 655 yourself with readdir() and patterns, or use a module like File::KGlob,
 656 one that doesn't use the shell to do globbing.
 657
 658 =head2 Is there a leak/bug in glob()?
 659 X<glob>
 660
 661 Due to the current implementation on some operating systems, when you
 662 use the glob() function or its angle-bracket alias in a scalar
 663 context, you may cause a memory leak and/or unpredictable behavior.  It's
 664 best therefore to use glob() only in list context.
 665
 666 =head2 How can I open a file with a leading ">" or trailing blanks?
 667 X<filename, special characters>
 668
 669 (contributed by Brian McCauley)
 670
 671 The special two argument form of Perl's open() function ignores
 672 trailing blanks in filenames and infers the mode from certain leading
 673 characters (or a trailing "|"). In older versions of Perl this was the
 674 only version of open() and so it is prevalent in old code and books.
 675
 676 Unless you have a particular reason to use the two argument form you
 677 should use the three argument form of open() which does not treat any
 678 charcters in the filename as special.
 679
 680         open FILE, "<", "  file  ";  # filename is "   file   "
 681         open FILE, ">", ">file";     # filename is ">file"
 682
 683 =head2 How can I reliably rename a file?
 684 X<rename> X<mv> X<move> X<file, rename> X<ren>
 685
 686 If your operating system supports a proper mv(1) utility or its
 687 functional equivalent, this works:
 688
 689         rename($old, $new) or system("mv", $old, $new);
 690
 691 It may be more portable to use the File::Copy module instead.
 692 You just copy to the new file to the new name (checking return
 693 values), then delete the old one.  This isn't really the same
 694 semantically as a rename(), which preserves meta-information like
 695 permissions, timestamps, inode info, etc.
 696
 697 Newer versions of File::Copy export a move() function.
 698
 699 =head2 How can I lock a file?
 700 X<lock> X<file, lock> X<flock>
 701
 702 Perl's builtin flock() function (see L<perlfunc> for details) will call
 703 flock(2) if that exists, fcntl(2) if it doesn't (on perl version 5.004 and
 704 later), and lockf(3) if neither of the two previous system calls exists.
 705 On some systems, it may even use a different form of native locking.
 706 Here are some gotchas with Perl's flock():
 707
 708 =over 4
 709
 710 =item 1
 711
 712 Produces a fatal error if none of the three system calls (or their
 713 close equivalent) exists.
 714
 715 =item 2
 716
 717 lockf(3) does not provide shared locking, and requires that the
 718 filehandle be open for writing (or appending, or read/writing).
 719
 720 =item 3
 721
 722 Some versions of flock() can't lock files over a network (e.g. on NFS file
 723 systems), so you'd need to force the use of fcntl(2) when you build Perl.
 724 But even this is dubious at best.  See the flock entry of L<perlfunc>
 725 and the F<INSTALL> file in the source distribution for information on
 726 building Perl to do this.
 727
 728 Two potentially non-obvious but traditional flock semantics are that
 729 it waits indefinitely until the lock is granted, and that its locks are
 730 I<merely advisory>.  Such discretionary locks are more flexible, but
 731 offer fewer guarantees.  This means that files locked with flock() may
 732 be modified by programs that do not also use flock().  Cars that stop
 733 for red lights get on well with each other, but not with cars that don't
 734 stop for red lights.  See the perlport manpage, your port's specific
 735 documentation, or your system-specific local manpages for details.  It's
 736 best to assume traditional behavior if you're writing portable programs.
 737 (If you're not, you should as always feel perfectly free to write
 738 for your own system's idiosyncrasies (sometimes called "features").
 739 Slavish adherence to portability concerns shouldn't get in the way of
 740 your getting your job done.)
 741
 742 For more information on file locking, see also
 743 L<perlopentut/"File Locking"> if you have it (new for 5.6).
 744
 745 =back
 746
 747 =head2 Why can't I just open(FH, "E<gt>file.lock")?
 748 X<lock, lockfile race condition>
 749
 750 A common bit of code B<NOT TO USE> is this:
 751
 752         sleep(3) while -e "file.lock";  # PLEASE DO NOT USE
 753         open(LCK, "> file.lock");               # THIS BROKEN CODE
 754
 755 This is a classic race condition: you take two steps to do something
 756 which must be done in one.  That's why computer hardware provides an
 757 atomic test-and-set instruction.   In theory, this "ought" to work:
 758
 759         sysopen(FH, "file.lock", O_WRONLY|O_EXCL|O_CREAT)
 760                 or die "can't open  file.lock: $!";
 761
 762 except that lamentably, file creation (and deletion) is not atomic
 763 over NFS, so this won't work (at least, not every time) over the net.
 764 Various schemes involving link() have been suggested, but
 765 these tend to involve busy-wait, which is also subdesirable.
 766
 767 =head2 I still don't get locking.  I just want to increment the number in the file.  How can I do this?
 768 X<counter> X<file, counter>
 769
 770 Didn't anyone ever tell you web-page hit counters were useless?
 771 They don't count number of hits, they're a waste of time, and they serve
 772 only to stroke the writer's vanity.  It's better to pick a random number;
 773 they're more realistic.
 774
 775 Anyway, this is what you can do if you can't help yourself.
 776
 777         use Fcntl qw(:DEFAULT :flock);
 778         sysopen(FH, "numfile", O_RDWR|O_CREAT)   or die "can't open numfile: $!";
 779         flock(FH, LOCK_EX)                               or die "can't flock numfile: $!";
 780         $num = <FH> || 0;
 781         seek(FH, 0, 0)                           or die "can't rewind numfile: $!";
 782         truncate(FH, 0)                                  or die "can't truncate numfile: $!";
 783         (print FH $num+1, "\n")                  or die "can't write numfile: $!";
 784         close FH                                         or die "can't close numfile: $!";
 785
 786 Here's a much better web-page hit counter:
 787
 788         $hits = int( (time() - 850_000_000) / rand(1_000) );
 789
 790 If the count doesn't impress your friends, then the code might.  :-)
 791
 792 =head2 All I want to do is append a small amount of text to the end of a file.  Do I still have to use locking?
 793 X<append> X<file, append>
 794
 795 If you are on a system that correctly implements flock() and you use the
 796 example appending code from "perldoc -f flock" everything will be OK
 797 even if the OS you are on doesn't implement append mode correctly (if
 798 such a system exists.) So if you are happy to restrict yourself to OSs
 799 that implement flock() (and that's not really much of a restriction)
 800 then that is what you should do.
 801
 802 If you know you are only going to use a system that does correctly
 803 implement appending (i.e. not Win32) then you can omit the seek() from
 804 the code in the previous answer.
 805
 806 If you know you are only writing code to run on an OS and filesystem that
 807 does implement append mode correctly (a local filesystem on a modern
 808 Unix for example), and you keep the file in block-buffered mode and you
 809 write less than one buffer-full of output between each manual flushing
 810 of the buffer then each bufferload is almost guaranteed to be written to
 811 the end of the file in one chunk without getting intermingled with
 812 anyone else's output. You can also use the syswrite() function which is
 813 simply a wrapper around your systems write(2) system call.
 814
 815 There is still a small theoretical chance that a signal will interrupt
 816 the system level write() operation before completion.  There is also a
 817 possibility that some STDIO implementations may call multiple system
 818 level write()s even if the buffer was empty to start.  There may be some
 819 systems where this probability is reduced to zero.
 820
 821 =head2 How do I randomly update a binary file?
 822 X<file, binary patch>
 823
 824 If you're just trying to patch a binary, in many cases something as
 825 simple as this works:
 826
 827         perl -i -pe 's{window manager}{window mangler}g' /usr/bin/emacs
 828
 829 However, if you have fixed sized records, then you might do something more
 830 like this:
 831
 832         $RECSIZE = 220; # size of record, in bytes
 833         $recno   = 37;  # which record to update
 834         open(FH, "+<somewhere") || die "can't update somewhere: $!";
 835         seek(FH, $recno * $RECSIZE, 0);
 836         read(FH, $record, $RECSIZE) == $RECSIZE || die "can't read record $recno: $!";
 837         # munge the record
 838         seek(FH, -$RECSIZE, 1);
 839         print FH $record;
 840         close FH;
 841
 842 Locking and error checking are left as an exercise for the reader.
 843 Don't forget them or you'll be quite sorry.
 844
 845 =head2 How do I get a file's timestamp in perl?
 846 X<timestamp> X<file, timestamp>
 847
 848 If you want to retrieve the time at which the file was last
 849 read, written, or had its meta-data (owner, etc) changed,
 850 you use the B<-A>, B<-M>, or B<-C> file test operations as
 851 documented in L<perlfunc>.  These retrieve the age of the
 852 file (measured against the start-time of your program) in
 853 days as a floating point number. Some platforms may not have
 854 all of these times.  See L<perlport> for details. To
 855 retrieve the "raw" time in seconds since the epoch, you
 856 would call the stat function, then use localtime(),
 857 gmtime(), or POSIX::strftime() to convert this into
 858 human-readable form.
 859
 860 Here's an example:
 861
 862         $write_secs = (stat($file))[9];
 863         printf "file %s updated at %s\n", $file,
 864         scalar localtime($write_secs);
 865
 866 If you prefer something more legible, use the File::stat module
 867 (part of the standard distribution in version 5.004 and later):
 868
 869         # error checking left as an exercise for reader.
 870         use File::stat;
 871         use Time::localtime;
 872         $date_string = ctime(stat($file)->mtime);
 873         print "file $file updated at $date_string\n";
 874
 875 The POSIX::strftime() approach has the benefit of being,
 876 in theory, independent of the current locale.  See L<perllocale>
 877 for details.
 878
 879 =head2 How do I set a file's timestamp in perl?
 880 X<timestamp> X<file, timestamp>
 881
 882 You use the utime() function documented in L<perlfunc/utime>.
 883 By way of example, here's a little program that copies the
 884 read and write times from its first argument to all the rest
 885 of them.
 886
 887         if (@ARGV < 2) {
 888                 die "usage: cptimes timestamp_file other_files ...\n";
 889                 }
 890         $timestamp = shift;
 891         ($atime, $mtime) = (stat($timestamp))[8,9];
 892         utime $atime, $mtime, @ARGV;
 893
 894 Error checking is, as usual, left as an exercise for the reader.
 895
 896 The perldoc for utime also has an example that has the same
 897 effect as touch(1) on files that I<already exist>.
 898
 899 Certain file systems have a limited ability to store the times
 900 on a file at the expected level of precision.  For example, the
 901 FAT and HPFS filesystem are unable to create dates on files with
 902 a finer granularity than two seconds.  This is a limitation of
 903 the filesystems, not of utime().
 904
 905 =head2 How do I print to more than one file at once?
 906 X<print, to multiple files>
 907
 908 To connect one filehandle to several output filehandles,
 909 you can use the IO::Tee or Tie::FileHandle::Multiplex modules.
 910
 911 If you only have to do this once, you can print individually
 912 to each filehandle.
 913
 914         for $fh (FH1, FH2, FH3) { print $fh "whatever\n" }
 915
 916 =head2 How can I read in an entire file all at once?
 917 X<slurp> X<file, slurping>
 918
 919 You can use the File::Slurp module to do it in one step.
 920
 921         use File::Slurp;
 922
 923         $all_of_it = read_file($filename); # entire file in scalar
 924         @all_lines = read_file($filename); # one line perl element
 925
 926 The customary Perl approach for processing all the lines in a file is to
 927 do so one line at a time:
 928
 929         open (INPUT, $file)     || die "can't open $file: $!";
 930         while (<INPUT>) {
 931                 chomp;
 932                 # do something with $_
 933                 }
 934         close(INPUT)            || die "can't close $file: $!";
 935
 936 This is tremendously more efficient than reading the entire file into
 937 memory as an array of lines and then processing it one element at a time,
 938 which is often--if not almost always--the wrong approach.  Whenever
 939 you see someone do this:
 940
 941         @lines = <INPUT>;
 942
 943 you should think long and hard about why you need everything loaded at
 944 once.  It's just not a scalable solution.  You might also find it more
 945 fun to use the standard Tie::File module, or the DB_File module's
 946 $DB_RECNO bindings, which allow you to tie an array to a file so that
 947 accessing an element the array actually accesses the corresponding
 948 line in the file.
 949
 950 You can read the entire filehandle contents into a scalar.
 951
 952         {
 953         local(*INPUT, $/);
 954         open (INPUT, $file)     || die "can't open $file: $!";
 955         $var = <INPUT>;
 956         }
 957
 958 That temporarily undefs your record separator, and will automatically
 959 close the file at block exit.  If the file is already open, just use this:
 960
 961         $var = do { local $/; <INPUT> };
 962
 963 For ordinary files you can also use the read function.
 964
 965         read( INPUT, $var, -s INPUT );
 966
 967 The third argument tests the byte size of the data on the INPUT filehandle
 968 and reads that many bytes into the buffer $var.
 969
 970 =head2 How can I read in a file by paragraphs?
 971 X<file, reading by paragraphs>
 972
 973 Use the C<$/> variable (see L<perlvar> for details).  You can either
 974 set it to C<""> to eliminate empty paragraphs (C<"abc\n\n\n\ndef">,
 975 for instance, gets treated as two paragraphs and not three), or
 976 C<"\n\n"> to accept empty paragraphs.
 977
 978 Note that a blank line must have no blanks in it.  Thus
 979 S<C<"fred\n \nstuff\n\n">> is one paragraph, but C<"fred\n\nstuff\n\n"> is two.
 980
 981 =head2 How can I read a single character from a file?  From the keyboard?
 982 X<getc> X<file, reading one character at a time>
 983
 984 You can use the builtin C<getc()> function for most filehandles, but
 985 it won't (easily) work on a terminal device.  For STDIN, either use
 986 the Term::ReadKey module from CPAN or use the sample code in
 987 L<perlfunc/getc>.
 988
 989 If your system supports the portable operating system programming
 990 interface (POSIX), you can use the following code, which you'll note
 991 turns off echo processing as well.
 992
 993         #!/usr/bin/perl -w
 994         use strict;
 995         $| = 1;
 996         for (1..4) {
 997                 my $got;
 998                 print "gimme: ";
 999                 $got = getone();
1000                 print "--> $got\n";
1001                 }
1002     exit;
1003
1004         BEGIN {
1005         use POSIX qw(:termios_h);
1006
1007         my ($term, $oterm, $echo, $noecho, $fd_stdin);
1008
1009         $fd_stdin = fileno(STDIN);
1010
1011         $term     = POSIX::Termios->new();
1012         $term->getattr($fd_stdin);
1013         $oterm     = $term->getlflag();
1014
1015         $echo     = ECHO | ECHOK | ICANON;
1016         $noecho   = $oterm & ~$echo;
1017
1018         sub cbreak {
1019                 $term->setlflag($noecho);
1020                 $term->setcc(VTIME, 1);
1021                 $term->setattr($fd_stdin, TCSANOW);
1022                 }
1023
1024         sub cooked {
1025                 $term->setlflag($oterm);
1026                 $term->setcc(VTIME, 0);
1027                 $term->setattr($fd_stdin, TCSANOW);
1028                 }
1029
1030         sub getone {
1031                 my $key = '';
1032                 cbreak();
1033                 sysread(STDIN, $key, 1);
1034                 cooked();
1035                 return $key;
1036                 }
1037
1038         }
1039
1040         END { cooked() }
1041
1042 The Term::ReadKey module from CPAN may be easier to use.  Recent versions
1043 include also support for non-portable systems as well.
1044
1045         use Term::ReadKey;
1046         open(TTY, "</dev/tty");
1047         print "Gimme a char: ";
1048         ReadMode "raw";
1049         $key = ReadKey 0, *TTY;
1050         ReadMode "normal";
1051         printf "\nYou said %s, char number %03d\n",
1052                 $key, ord $key;
1053
1054 =head2 How can I tell whether there's a character waiting on a filehandle?
1055
1056 The very first thing you should do is look into getting the Term::ReadKey
1057 extension from CPAN.  As we mentioned earlier, it now even has limited
1058 support for non-portable (read: not open systems, closed, proprietary,
1059 not POSIX, not Unix, etc) systems.
1060
1061 You should also check out the Frequently Asked Questions list in
1062 comp.unix.* for things like this: the answer is essentially the same.
1063 It's very system dependent.  Here's one solution that works on BSD
1064 systems:
1065
1066         sub key_ready {
1067                 my($rin, $nfd);
1068                 vec($rin, fileno(STDIN), 1) = 1;
1069                 return $nfd = select($rin,undef,undef,0);
1070                 }
1071
1072 If you want to find out how many characters are waiting, there's
1073 also the FIONREAD ioctl call to be looked at.  The I<h2ph> tool that
1074 comes with Perl tries to convert C include files to Perl code, which
1075 can be C<require>d.  FIONREAD ends up defined as a function in the
1076 I<sys/ioctl.ph> file:
1077
1078         require 'sys/ioctl.ph';
1079
1080         $size = pack("L", 0);
1081         ioctl(FH, FIONREAD(), $size)    or die "Couldn't call ioctl: $!\n";
1082         $size = unpack("L", $size);
1083
1084 If I<h2ph> wasn't installed or doesn't work for you, you can
1085 I<grep> the include files by hand:
1086
1087         % grep FIONREAD /usr/include/*/*
1088         /usr/include/asm/ioctls.h:#define FIONREAD      0x541B
1089
1090 Or write a small C program using the editor of champions:
1091
1092         % cat > fionread.c
1093         #include <sys/ioctl.h>
1094         main() {
1095             printf("%#08x\n", FIONREAD);
1096         }
1097         ^D
1098         % cc -o fionread fionread.c
1099         % ./fionread
1100         0x4004667f
1101
1102 And then hard code it, leaving porting as an exercise to your successor.
1103
1104         $FIONREAD = 0x4004667f;         # XXX: opsys dependent
1105
1106         $size = pack("L", 0);
1107         ioctl(FH, $FIONREAD, $size)     or die "Couldn't call ioctl: $!\n";
1108         $size = unpack("L", $size);
1109
1110 FIONREAD requires a filehandle connected to a stream, meaning that sockets,
1111 pipes, and tty devices work, but I<not> files.
1112
1113 =head2 How do I do a C<tail -f> in perl?
1114 X<tail> X<IO::Handle> X<File::Tail> X<clearerr>
1115
1116 First try
1117
1118         seek(GWFILE, 0, 1);
1119
1120 The statement C<seek(GWFILE, 0, 1)> doesn't change the current position,
1121 but it does clear the end-of-file condition on the handle, so that the
1122 next C<< <GWFILE> >> makes Perl try again to read something.
1123
1124 If that doesn't work (it relies on features of your stdio implementation),
1125 then you need something more like this:
1126
1127         for (;;) {
1128           for ($curpos = tell(GWFILE); <GWFILE>; $curpos = tell(GWFILE)) {
1129             # search for some stuff and put it into files
1130           }
1131           # sleep for a while
1132           seek(GWFILE, $curpos, 0);  # seek to where we had been
1133         }
1134
1135 If this still doesn't work, look into the C<clearerr> method
1136 from C<IO::Handle>, which resets the error and end-of-file states
1137 on the handle.
1138
1139 There's also a C<File::Tail> module from CPAN.
1140
1141 =head2 How do I dup() a filehandle in Perl?
1142 X<dup>
1143
1144 If you check L<perlfunc/open>, you'll see that several of the ways
1145 to call open() should do the trick.  For example:
1146
1147         open(LOG, ">>/foo/logfile");
1148         open(STDERR, ">&LOG");
1149
1150 Or even with a literal numeric descriptor:
1151
1152    $fd = $ENV{MHCONTEXTFD};
1153    open(MHCONTEXT, "<&=$fd");   # like fdopen(3S)
1154
1155 Note that "<&STDIN" makes a copy, but "<&=STDIN" make
1156 an alias.  That means if you close an aliased handle, all
1157 aliases become inaccessible.  This is not true with
1158 a copied one.
1159
1160 Error checking, as always, has been left as an exercise for the reader.
1161
1162 =head2 How do I close a file descriptor by number?
1163 X<file, closing file descriptors>
1164
1165 This should rarely be necessary, as the Perl close() function is to be
1166 used for things that Perl opened itself, even if it was a dup of a
1167 numeric descriptor as with MHCONTEXT above.  But if you really have
1168 to, you may be able to do this:
1169
1170         require 'sys/syscall.ph';
1171         $rc = syscall(&SYS_close, $fd + 0);  # must force numeric
1172         die "can't sysclose $fd: $!" unless $rc == -1;
1173
1174 Or, just use the fdopen(3S) feature of open():
1175
1176         {
1177         local *F;
1178         open F, "<&=$fd" or die "Cannot reopen fd=$fd: $!";
1179         close F;
1180         }
1181
1182 =head2 Why can't I use "C:\temp\foo" in DOS paths?  Why doesn't `C:\temp\foo.exe` work?
1183 X<filename, DOS issues>
1184
1185 Whoops!  You just put a tab and a formfeed into that filename!
1186 Remember that within double quoted strings ("like\this"), the
1187 backslash is an escape character.  The full list of these is in
1188 L<perlop/Quote and Quote-like Operators>.  Unsurprisingly, you don't
1189 have a file called "c:(tab)emp(formfeed)oo" or
1190 "c:(tab)emp(formfeed)oo.exe" on your legacy DOS filesystem.
1191
1192 Either single-quote your strings, or (preferably) use forward slashes.
1193 Since all DOS and Windows versions since something like MS-DOS 2.0 or so
1194 have treated C</> and C<\> the same in a path, you might as well use the
1195 one that doesn't clash with Perl--or the POSIX shell, ANSI C and C++,
1196 awk, Tcl, Java, or Python, just to mention a few.  POSIX paths
1197 are more portable, too.
1198
1199 =head2 Why doesn't glob("*.*") get all the files?
1200 X<glob>
1201
1202 Because even on non-Unix ports, Perl's glob function follows standard
1203 Unix globbing semantics.  You'll need C<glob("*")> to get all (non-hidden)
1204 files.  This makes glob() portable even to legacy systems.  Your
1205 port may include proprietary globbing functions as well.  Check its
1206 documentation for details.
1207
1208 =head2 Why does Perl let me delete read-only files?  Why does C<-i> clobber protected files?  Isn't this a bug in Perl?
1209
1210 This is elaborately and painstakingly described in the
1211 F<file-dir-perms> article in the "Far More Than You Ever Wanted To
1212 Know" collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz .
1213
1214 The executive summary: learn how your filesystem works.  The
1215 permissions on a file say what can happen to the data in that file.
1216 The permissions on a directory say what can happen to the list of
1217 files in that directory.  If you delete a file, you're removing its
1218 name from the directory (so the operation depends on the permissions
1219 of the directory, not of the file).  If you try to write to the file,
1220 the permissions of the file govern whether you're allowed to.
1221
1222 =head2 How do I select a random line from a file?
1223 X<file, selecting a random line>
1224
1225 Here's an algorithm from the Camel Book:
1226
1227         srand;
1228         rand($.) < 1 && ($line = $_) while <>;
1229
1230 This has a significant advantage in space over reading the whole file
1231 in.  You can find a proof of this method in I<The Art of Computer
1232 Programming>, Volume 2, Section 3.4.2, by Donald E. Knuth.
1233
1234 You can use the File::Random module which provides a function
1235 for that algorithm:
1236
1237         use File::Random qw/random_line/;
1238         my $line = random_line($filename);
1239
1240 Another way is to use the Tie::File module, which treats the entire
1241 file as an array.  Simply access a random array element.
1242
1243 =head2 Why do I get weird spaces when I print an array of lines?
1244
1245 Saying
1246
1247         print "@lines\n";
1248
1249 joins together the elements of C<@lines> with a space between them.
1250 If C<@lines> were C<("little", "fluffy", "clouds")> then the above
1251 statement would print
1252
1253         little fluffy clouds
1254
1255 but if each element of C<@lines> was a line of text, ending a newline
1256 character C<("little\n", "fluffy\n", "clouds\n")> then it would print:
1257
1258         little
1259          fluffy
1260          clouds
1261
1262 If your array contains lines, just print them:
1263
1264         print @lines;
1265
1266 =head1 REVISION
1267
1268 Revision: $Revision: 8075 $
1269
1270 Date: $Date: 2006-11-15 02:26:49 +0100 (mer, 15 nov 2006) $
1271
1272 See L<perlfaq> for source control details and availability.
1273
1274 =head1 AUTHOR AND COPYRIGHT
1275
1276 Copyright (c) 1997-2006 Tom Christiansen, Nathan Torkington, and
1277 other authors as noted. All rights reserved.
1278
1279 This documentation is free; you can redistribute it and/or modify it
1280 under the same terms as Perl itself.
1281
1282 Irrespective of its distribution, all code examples here are in the public
1283 domain.  You are permitted and encouraged to use this code and any
1284 derivatives thereof in your own programs for fun or for profit as you
1285 see fit.  A simple comment in the code giving credit to the FAQ would
1286 be courteous but is not required.