lib/ExtUtils.t

   1 #!./perl -w
   2
   3 print "1..27\n";
   4
   5 BEGIN {
   6     chdir 't' if -d 't';
   7     @INC = '../lib';
   8 }
   9
  10 use warnings;
  11 use strict;
  12 use ExtUtils::MakeMaker;
  13 use ExtUtils::Constant qw (constant_types C_constant XS_constant autoload);
  14 use Config;
  15 use File::Spec::Functions;
  16 use File::Spec;
  17 # Because were are going to be changing directory before running Makefile.PL
  18 my $perl = File::Spec->rel2abs( $^X );
  19 # ExtUtils::Constant::C_constant uses $^X inside a comment, and we want to
  20 # compare output to ensure that it is the same. We were probably run as ./perl
  21 # whereas we will run the child with the full path in $perl. So make $^X for
  22 # us the same as our child will see.
  23 $^X = $perl;
  24
  25 print "# perl=$perl\n";
  26 my $runperl = "$perl -x \"-I../../lib\"";
  27
  28 $| = 1;
  29
  30 my $dir = "ext-$$";
  31 my @files;
  32
  33 print "# $dir being created...\n";
  34 mkdir $dir, 0777 or die "mkdir: $!\n";
  35
  36 my $output = "output";
  37
  38 END {
  39     use File::Path;
  40     print "# $dir being removed...\n";
  41     rmtree($dir);
  42 }
  43
  44 my $package = "ExtTest";
  45
  46 # Test the code that generates 1 and 2 letter name comparisons.
  47 my %compass = (
  48 N => 0, NE => 45, E => 90, SE => 135, S => 180, SW => 225, W => 270, NW => 315
  49 );
  50
  51 my $parent_rfc1149 =
  52   'A Standard for the Transmission of IP Datagrams on Avian Carriers';
  53
  54 my @names = ("FIVE", {name=>"OK6", type=>"PV",},
  55              {name=>"OK7", type=>"PVN",
  56               value=>['"not ok 7\\n\\0ok 7\\n"', 15]},
  57              {name => "FARTHING", type=>"NV"},
  58              {name => "NOT_ZERO", type=>"UV", value=>"~(UV)0"},
  59              {name => "OPEN", type=>"PV", value=>'"/*"', macro=>1},
  60              {name => "CLOSE", type=>"PV", value=>'"*/"',
  61               macro=>["#if 1\n", "#endif\n"]},
  62              {name => "ANSWER", default=>["UV", 42]}, "NOTDEF",
  63              {name => "Yes", type=>"YES"},
  64              {name => "No", type=>"NO"},
  65              {name => "Undef", type=>"UNDEF"},
  66 # OK. It wasn't really designed to allow the creation of dual valued constants.
  67 # It was more for INADDR_ANY INADDR_BROADCAST INADDR_LOOPBACK INADDR_NONE
  68              {name=>"RFC1149", type=>"SV", value=>"sv_2mortal(temp_sv)",
  69               pre=>"SV *temp_sv = newSVpv(RFC1149, 0); "
  70                    . "(void) SvUPGRADE(temp_sv,SVt_PVIV); SvIOK_on(temp_sv); "
  71                    . "SvIVX(temp_sv) = 1149;"},
  72 );
  73
  74 push @names, $_ foreach keys %compass;
  75
  76 my @names_only = map {(ref $_) ? $_->{name} : $_} @names;
  77
  78 my $types = {};
  79 my $constant_types = constant_types(); # macro defs
  80 my $C_constant = join "\n",
  81   C_constant ($package, undef, "IV", $types, undef, undef, @names);
  82 my $XS_constant = XS_constant ($package, $types); # XS for ExtTest::constant
  83
  84 ################ Header
  85 my $header = catfile($dir, "test.h");
  86 push @files, "test.h";
  87 open FH, ">$header" or die "open >$header: $!\n";
  88 print FH <<"EOT";
  89 #define FIVE 5
  90 #define OK6 "ok 6\\n"
  91 #define OK7 1
  92 #define FARTHING 0.25
  93 #define NOT_ZERO 1
  94 #define Yes 0
  95 #define No 1
  96 #define Undef 1
  97 #define RFC1149 "$parent_rfc1149"
  98 #undef NOTDEF
  99
 100 EOT
 101
 102 while (my ($point, $bearing) = each %compass) {
 103   print FH "#define $point $bearing\n"
 104 }
 105 close FH or die "close $header: $!\n";
 106
 107 ################ XS
 108 my $xs = catfile($dir, "$package.xs");
 109 push @files, "$package.xs";
 110 open FH, ">$xs" or die "open >$xs: $!\n";
 111
 112 print FH <<'EOT';
 113 #include "EXTERN.h"
 114 #include "perl.h"
 115 #include "XSUB.h"
 116 EOT
 117
 118 print FH "#include \"test.h\"\n\n";
 119 print FH $constant_types;
 120 print FH $C_constant, "\n";
 121 print FH "MODULE = $package             PACKAGE = $package\n";
 122 print FH "PROTOTYPES: ENABLE\n";
 123 print FH $XS_constant;
 124 close FH or die "close $xs: $!\n";
 125
 126 ################ PM
 127 my $pm = catfile($dir, "$package.pm");
 128 push @files, "$package.pm";
 129 open FH, ">$pm" or die "open >$pm: $!\n";
 130 print FH "package $package;\n";
 131 print FH "use $];\n";
 132
 133 print FH <<'EOT';
 134
 135 use strict;
 136 use warnings;
 137 use Carp;
 138
 139 require Exporter;
 140 require DynaLoader;
 141 use vars qw ($VERSION @ISA @EXPORT_OK);
 142
 143 $VERSION = '0.01';
 144 @ISA = qw(Exporter DynaLoader);
 145 @EXPORT_OK = qw(
 146 EOT
 147
 148 print FH "\t$_\n" foreach (@names_only);
 149 print FH ");\n";
 150 print FH autoload ($package, $]);
 151 print FH "bootstrap $package \$VERSION;\n1;\n__END__\n";
 152 close FH or die "close $pm: $!\n";
 153
 154 ################ test.pl
 155 my $testpl = catfile($dir, "test.pl");
 156 push @files, "test.pl";
 157 open FH, ">$testpl" or die "open >$testpl: $!\n";
 158
 159 print FH "use strict;\n";
 160 print FH "use $package qw(@names_only);\n";
 161 print FH <<"EOT";
 162
 163 print "1..1\n";
 164 if (open OUTPUT, ">$output") {
 165   print "ok 1\n";
 166   select OUTPUT;
 167 } else {
 168   print "not ok 1 # Failed to open '$output': $!\n";
 169   exit 1;
 170 }
 171 EOT
 172
 173 print FH << 'EOT';
 174
 175 # What follows goes to the temporary file.
 176 # IV
 177 my $five = FIVE;
 178 if ($five == 5) {
 179   print "ok 5\n";
 180 } else {
 181   print "not ok 5 # $five\n";
 182 }
 183
 184 # PV
 185 print OK6;
 186
 187 # PVN containing embedded \0s
 188 $_ = OK7;
 189 s/.*\0//s;
 190 print;
 191
 192 # NV
 193 my $farthing = FARTHING;
 194 if ($farthing == 0.25) {
 195   print "ok 8\n";
 196 } else {
 197   print "not ok 8 # $farthing\n";
 198 }
 199
 200 # UV
 201 my $not_zero = NOT_ZERO;
 202 if ($not_zero > 0 && $not_zero == ~0) {
 203   print "ok 9\n";
 204 } else {
 205   print "not ok 9 # \$not_zero=$not_zero ~0=" . (~0) . "\n";
 206 }
 207
 208 # Value includes a "*/" in an attempt to bust out of a C comment.
 209 # Also tests custom cpp #if clauses
 210 my $close = CLOSE;
 211 if ($close eq '*/') {
 212   print "ok 10\n";
 213 } else {
 214   print "not ok 10 # \$close='$close'\n";
 215 }
 216
 217 # Default values if macro not defined.
 218 my $answer = ANSWER;
 219 if ($answer == 42) {
 220   print "ok 11\n";
 221 } else {
 222   print "not ok 11 # What do you get if you multiply six by nine? '$answer'\n";
 223 }
 224
 225 # not defined macro
 226 my $notdef = eval { NOTDEF; };
 227 if (defined $notdef) {
 228   print "not ok 12 # \$notdef='$notdef'\n";
 229 } elsif ($@ !~ /Your vendor has not defined ExtTest macro NOTDEF/) {
 230   print "not ok 12 # \$@='$@'\n";
 231 } else {
 232   print "ok 12\n";
 233 }
 234
 235 # not a macro
 236 my $notthere = eval { &ExtTest::NOTTHERE; };
 237 if (defined $notthere) {
 238   print "not ok 13 # \$notthere='$notthere'\n";
 239 } elsif ($@ !~ /NOTTHERE is not a valid ExtTest macro/) {
 240   chomp $@;
 241   print "not ok 13 # \$@='$@'\n";
 242 } else {
 243   print "ok 13\n";
 244 }
 245
 246 # Truth
 247 my $yes = Yes;
 248 if ($yes) {
 249   print "ok 14\n";
 250 } else {
 251   print "not ok 14 # $yes='\$yes'\n";
 252 }
 253
 254 # Falsehood
 255 my $no = No;
 256 if (defined $no and !$no) {
 257   print "ok 15\n";
 258 } else {
 259   print "not ok 15 # \$no=" . defined ($no) ? "'$no'\n" : "undef\n";
 260 }
 261
 262 # Undef
 263 my $undef = Undef;
 264 unless (defined $undef) {
 265   print "ok 16\n";
 266 } else {
 267   print "not ok 16 # \$undef='$undef'\n";
 268 }
 269
 270
 271 # invalid macro (chosen to look like a mix up between No and SW)
 272 $notdef = eval { &ExtTest::So };
 273 if (defined $notdef) {
 274   print "not ok 17 # \$notdef='$notdef'\n";
 275 } elsif ($@ !~ /^So is not a valid ExtTest macro/) {
 276   print "not ok 17 # \$@='$@'\n";
 277 } else {
 278   print "ok 17\n";
 279 }
 280
 281 # invalid defined macro
 282 $notdef = eval { &ExtTest::EW };
 283 if (defined $notdef) {
 284   print "not ok 18 # \$notdef='$notdef'\n";
 285 } elsif ($@ !~ /^EW is not a valid ExtTest macro/) {
 286   print "not ok 18 # \$@='$@'\n";
 287 } else {
 288   print "ok 18\n";
 289 }
 290
 291 my %compass = (
 292 EOT
 293
 294 while (my ($point, $bearing) = each %compass) {
 295   print FH "$point => $bearing, "
 296 }
 297
 298 print FH <<'EOT';
 299
 300 );
 301
 302 my $fail;
 303 while (my ($point, $bearing) = each %compass) {
 304   my $val = eval $point;
 305   if ($@) {
 306     print "# $point: \$@='$@'\n";
 307     $fail = 1;
 308   } elsif (!defined $bearing) {
 309     print "# $point: \$val=undef\n";
 310     $fail = 1;
 311   } elsif ($val != $bearing) {
 312     print "# $point: \$val=$val, not $bearing\n";
 313     $fail = 1;
 314   }
 315 }
 316 if ($fail) {
 317   print "not ok 19\n";
 318 } else {
 319   print "ok 19\n";
 320 }
 321
 322 EOT
 323
 324 print FH <<"EOT";
 325 my \$rfc1149 = RFC1149;
 326 if (\$rfc1149 ne "$parent_rfc1149") {
 327   print "not ok 20 # '\$rfc1149' ne '$parent_rfc1149'\n";
 328 } else {
 329   print "ok 20\n";
 330 }
 331
 332 if (\$rfc1149 != 1149) {
 333   printf "not ok 21 # %d != 1149\n", \$rfc1149;
 334 } else {
 335   print "ok 21\n";
 336 }
 337
 338 EOT
 339
 340 print FH <<'EOT';
 341 # test macro=>1
 342 my $open = OPEN;
 343 if ($open eq '/*') {
 344   print "ok 22\n";
 345 } else {
 346   print "not ok 22 # \$open='$open'\n";
 347 }
 348 EOT
 349 close FH or die "close $testpl: $!\n";
 350
 351 ################ Makefile.PL
 352 # We really need a Makefile.PL because make test for a no dynamic linking perl
 353 # will run Makefile.PL again as part of the "make perl" target.
 354 my $makefilePL = catfile($dir, "Makefile.PL");
 355 push @files, "Makefile.PL";
 356 open FH, ">$makefilePL" or die "open >$makefilePL: $!\n";
 357 print FH <<"EOT";
 358 #!$perl -w
 359 use ExtUtils::MakeMaker;
 360 WriteMakefile(
 361               'NAME'            => "$package",
 362               'VERSION_FROM'    => "$package.pm", # finds \$VERSION
 363               (\$] >= 5.005 ?
 364                (#ABSTRACT_FROM => "$package.pm", # XXX add this
 365                 AUTHOR     => "$0") : ())
 366              );
 367 EOT
 368
 369 close FH or die "close $makefilePL: $!\n";
 370
 371 chdir $dir or die $!; push @INC,  '../../lib';
 372 END {chdir ".." or warn $!};
 373
 374 my @perlout = `$runperl Makefile.PL PERL_CORE=1`;
 375 if ($?) {
 376   print "not ok 1 # $runperl Makefile.PL failed: $?\n";
 377   print "# $_" foreach @perlout;
 378   exit($?);
 379 } else {
 380   print "ok 1\n";
 381 }
 382
 383
 384 my $makefile = ($^O eq 'VMS' ? 'descrip' : 'Makefile');
 385 my $makefile_ext = ($^O eq 'VMS' ? '.mms' : '');
 386 if (-f "$makefile$makefile_ext") {
 387   print "ok 2\n";
 388 } else {
 389   print "not ok 2\n";
 390 }
 391 my $makefile_rename = ($^O eq 'VMS' ? '.mms' : '.old');
 392 push @files, "$makefile$makefile_rename"; # Renamed by make clean
 393
 394 my $make = $Config{make};
 395
 396 $make = $ENV{MAKE} if exists $ENV{MAKE};
 397
 398 if ($^O eq 'MSWin32' && $make eq 'nmake') { $make .= " -nologo"; }
 399
 400 my @makeout;
 401
 402 print "# make = '$make'\n";
 403 @makeout = `$make`;
 404 if ($?) {
 405   print "not ok 3 # $make failed: $?\n";
 406   print "# $_" foreach @makeout;
 407   exit($?);
 408 } else {
 409   print "ok 3\n";
 410 }
 411
 412 if ($Config{usedl}) {
 413   print "ok 4\n";
 414 } else {
 415   my $makeperl = "$make perl";
 416   print "# make = '$makeperl'\n";
 417   @makeout = `$makeperl`;
 418   if ($?) {
 419     print "not ok 4 # $makeperl failed: $?\n";
 420   print "# $_" foreach @makeout;
 421     exit($?);
 422   } else {
 423     print "ok 4\n";
 424   }
 425 }
 426
 427 push @files, $output;
 428
 429 my $maketest = "$make test";
 430 print "# make = '$maketest'\n";
 431
 432 @makeout = `$maketest`;
 433
 434 if (open OUTPUT, "<$output") {
 435   print while <OUTPUT>;
 436   close OUTPUT or print "# Close $output failed: $!\n";
 437 } else {
 438   # Harness will report missing test results at this point.
 439   print "# Open <$output failed: $!\n";
 440 }
 441
 442 my $test = 23;
 443
 444 if ($?) {
 445   print "not ok $test # $maketest failed: $?\n";
 446   print "# $_" foreach @makeout;
 447 } else {
 448   print "ok $test\n";
 449 }
 450 $test++;
 451
 452 my $regen = `$runperl $package.xs`;
 453 if ($?) {
 454   print "not ok $test # $runperl $package.xs failed: $?\n";
 455 } else {
 456   print "ok $test\n";
 457 }
 458 $test++;
 459
 460 my $expect = $constant_types . $C_constant .
 461   "\n#### XS Section:\n" . $XS_constant;
 462
 463 if ($expect eq $regen) {
 464   print "ok $test\n";
 465 } else {
 466   print "not ok $test\n";
 467   # open FOO, ">expect"; print FOO $expect;
 468   # open FOO, ">regen"; print FOO $regen; close FOO;
 469 }
 470 $test++;
 471
 472 my $makeclean = "$make clean";
 473 print "# make = '$makeclean'\n";
 474 @makeout = `$makeclean`;
 475 if ($?) {
 476   print "not ok $test # $make failed: $?\n";
 477   print "# $_" foreach @makeout;
 478 } else {
 479   print "ok $test\n";
 480 }
 481 $test++;
 482
 483 foreach (@files) {
 484   unlink $_ or warn "unlink $_: $!";
 485 }
 486
 487 my $fail;
 488 opendir DIR, "." or die "opendir '.': $!";
 489 while (defined (my $entry = readdir DIR)) {
 490   next if $entry =~ /^\.\.?$/;
 491   print "# Extra file '$entry'\n";
 492   $fail = 1;
 493 }
 494 closedir DIR or warn "closedir '.': $!";
 495 if ($fail) {
 496   print "not ok $test\n";
 497 } else {
 498   print "ok $test\n";
 499 }