lib/overload.pm

   1 package overload;
   2
   3 our $VERSION = '1.00';
   4
   5 $overload::hint_bits = 0x20000; # HINT_LOCALIZE_HH
   6
   7 sub nil {}
   8
   9 sub OVERLOAD {
  10   $package = shift;
  11   my %arg = @_;
  12   my ($sub, $fb);
  13   $ {$package . "::OVERLOAD"}{dummy}++; # Register with magic by touching.
  14   *{$package . "::()"} = \&nil; # Make it findable via fetchmethod.
  15   for (keys %arg) {
  16     if ($_ eq 'fallback') {
  17       $fb = $arg{$_};
  18     } else {
  19       $sub = $arg{$_};
  20       if (not ref $sub and $sub !~ /::/) {
  21         $ {$package . "::(" . $_} = $sub;
  22         $sub = \&nil;
  23       }
  24       #print STDERR "Setting `$ {'package'}::\cO$_' to \\&`$sub'.\n";
  25       *{$package . "::(" . $_} = \&{ $sub };
  26     }
  27   }
  28   ${$package . "::()"} = $fb; # Make it findable too (fallback only).
  29 }
  30
  31 sub import {
  32   $package = (caller())[0];
  33   # *{$package . "::OVERLOAD"} = \&OVERLOAD;
  34   shift;
  35   $package->overload::OVERLOAD(@_);
  36 }
  37
  38 sub unimport {
  39   $package = (caller())[0];
  40   ${$package . "::OVERLOAD"}{dummy}++; # Upgrade the table
  41   shift;
  42   for (@_) {
  43     if ($_ eq 'fallback') {
  44       undef $ {$package . "::()"};
  45     } else {
  46       delete $ {$package . "::"}{"(" . $_};
  47     }
  48   }
  49 }
  50
  51 sub Overloaded {
  52   my $package = shift;
  53   $package = ref $package if ref $package;
  54   $package->can('()');
  55 }
  56
  57 sub ov_method {
  58   my $globref = shift;
  59   return undef unless $globref;
  60   my $sub = \&{*$globref};
  61   return $sub if $sub ne \&nil;
  62   return shift->can($ {*$globref});
  63 }
  64
  65 sub OverloadedStringify {
  66   my $package = shift;
  67   $package = ref $package if ref $package;
  68   #$package->can('(""')
  69   ov_method mycan($package, '(""'), $package
  70     or ov_method mycan($package, '(0+'), $package
  71     or ov_method mycan($package, '(bool'), $package
  72     or ov_method mycan($package, '(nomethod'), $package;
  73 }
  74
  75 sub Method {
  76   my $package = shift;
  77   $package = ref $package if ref $package;
  78   #my $meth = $package->can('(' . shift);
  79   ov_method mycan($package, '(' . shift), $package;
  80   #return $meth if $meth ne \&nil;
  81   #return $ {*{$meth}};
  82 }
  83
  84 sub AddrRef {
  85   my $package = ref $_[0];
  86   return "$_[0]" unless $package;
  87   bless $_[0], overload::Fake;  # Non-overloaded package
  88   my $str = "$_[0]";
  89   bless $_[0], $package;        # Back
  90   $package . substr $str, index $str, '=';
  91 }
  92
  93 sub StrVal {
  94   (ref $_[0] && OverloadedStringify($_[0]) or ref($_[0]) eq 'Regexp') ?
  95     (AddrRef(shift)) :
  96     "$_[0]";
  97 }
  98
  99 sub mycan {                             # Real can would leave stubs.
 100   my ($package, $meth) = @_;
 101   return \*{$package . "::$meth"} if defined &{$package . "::$meth"};
 102   my $p;
 103   foreach $p (@{$package . "::ISA"}) {
 104     my $out = mycan($p, $meth);
 105     return $out if $out;
 106   }
 107   return undef;
 108 }
 109
 110 %constants = (
 111               'integer'   =>  0x1000, # HINT_NEW_INTEGER
 112               'float'     =>  0x2000, # HINT_NEW_FLOAT
 113               'binary'    =>  0x4000, # HINT_NEW_BINARY
 114               'q'         =>  0x8000, # HINT_NEW_STRING
 115               'qr'        => 0x10000, # HINT_NEW_RE
 116              );
 117
 118 %ops = ( with_assign      => "+ - * / % ** << >> x .",
 119          assign           => "+= -= *= /= %= **= <<= >>= x= .=",
 120          num_comparison   => "< <= >  >= == !=",
 121          '3way_comparison'=> "<=> cmp",
 122          str_comparison   => "lt le gt ge eq ne",
 123          binary           => "& | ^",
 124          unary            => "neg ! ~",
 125          mutators         => '++ --',
 126          func             => "atan2 cos sin exp abs log sqrt int",
 127          conversion       => 'bool "" 0+',
 128          iterators        => '<>',
 129          dereferencing    => '${} @{} %{} &{} *{}',
 130          special          => 'nomethod fallback =');
 131
 132 use warnings::register;
 133 sub constant {
 134   # Arguments: what, sub
 135   while (@_) {
 136     if (@_ == 1) {
 137         warnings::warnif ("Odd number of arguments for overload::constant");
 138         last;
 139     }
 140     elsif (!exists $constants {$_ [0]}) {
 141         warnings::warnif ("`$_[0]' is not an overloadable type");
 142     }
 143     elsif (!ref $_ [1] || "$_[1]" !~ /CODE\(0x[\da-f]+\)$/) {
 144         # Can't use C<ref $_[1] eq "CODE"> above as code references can be
 145         # blessed, and C<ref> would return the package the ref is blessed into.
 146         if (warnings::enabled) {
 147             $_ [1] = "undef" unless defined $_ [1];
 148             warnings::warn ("`$_[1]' is not a code reference");
 149         }
 150     }
 151     else {
 152         $^H{$_[0]} = $_[1];
 153         $^H |= $constants{$_[0]} | $overload::hint_bits;
 154     }
 155     shift, shift;
 156   }
 157 }
 158
 159 sub remove_constant {
 160   # Arguments: what, sub
 161   while (@_) {
 162     delete $^H{$_[0]};
 163     $^H &= ~ $constants{$_[0]};
 164     shift, shift;
 165   }
 166 }
 167
 168 1;
 169
 170 __END__
 171
 172 =head1 NAME
 173
 174 overload - Package for overloading perl operations
 175
 176 =head1 SYNOPSIS
 177
 178     package SomeThing;
 179
 180     use overload
 181         '+' => \&myadd,
 182         '-' => \&mysub;
 183         # etc
 184     ...
 185
 186     package main;
 187     $a = new SomeThing 57;
 188     $b=5+$a;
 189     ...
 190     if (overload::Overloaded $b) {...}
 191     ...
 192     $strval = overload::StrVal $b;
 193
 194 =head1 DESCRIPTION
 195
 196 =head2 Declaration of overloaded functions
 197
 198 The compilation directive
 199
 200     package Number;
 201     use overload
 202         "+" => \&add,
 203         "*=" => "muas";
 204
 205 declares function Number::add() for addition, and method muas() in
 206 the "class" C<Number> (or one of its base classes)
 207 for the assignment form C<*=> of multiplication.
 208
 209 Arguments of this directive come in (key, value) pairs.  Legal values
 210 are values legal inside a C<&{ ... }> call, so the name of a
 211 subroutine, a reference to a subroutine, or an anonymous subroutine
 212 will all work.  Note that values specified as strings are
 213 interpreted as methods, not subroutines.  Legal keys are listed below.
 214
 215 The subroutine C<add> will be called to execute C<$a+$b> if $a
 216 is a reference to an object blessed into the package C<Number>, or if $a is
 217 not an object from a package with defined mathemagic addition, but $b is a
 218 reference to a C<Number>.  It can also be called in other situations, like
 219 C<$a+=7>, or C<$a++>.  See L<MAGIC AUTOGENERATION>.  (Mathemagical
 220 methods refer to methods triggered by an overloaded mathematical
 221 operator.)
 222
 223 Since overloading respects inheritance via the @ISA hierarchy, the
 224 above declaration would also trigger overloading of C<+> and C<*=> in
 225 all the packages which inherit from C<Number>.
 226
 227 =head2 Calling Conventions for Binary Operations
 228
 229 The functions specified in the C<use overload ...> directive are called
 230 with three (in one particular case with four, see L<Last Resort>)
 231 arguments.  If the corresponding operation is binary, then the first
 232 two arguments are the two arguments of the operation.  However, due to
 233 general object calling conventions, the first argument should always be
 234 an object in the package, so in the situation of C<7+$a>, the
 235 order of the arguments is interchanged.  It probably does not matter
 236 when implementing the addition method, but whether the arguments
 237 are reversed is vital to the subtraction method.  The method can
 238 query this information by examining the third argument, which can take
 239 three different values:
 240
 241 =over 7
 242
 243 =item FALSE
 244
 245 the order of arguments is as in the current operation.
 246
 247 =item TRUE
 248
 249 the arguments are reversed.
 250
 251 =item C<undef>
 252
 253 the current operation is an assignment variant (as in
 254 C<$a+=7>), but the usual function is called instead.  This additional
 255 information can be used to generate some optimizations.  Compare
 256 L<Calling Conventions for Mutators>.
 257
 258 =back
 259
 260 =head2 Calling Conventions for Unary Operations
 261
 262 Unary operation are considered binary operations with the second
 263 argument being C<undef>.  Thus the functions that overloads C<{"++"}>
 264 is called with arguments C<($a,undef,'')> when $a++ is executed.
 265
 266 =head2 Calling Conventions for Mutators
 267
 268 Two types of mutators have different calling conventions:
 269
 270 =over
 271
 272 =item C<++> and C<-->
 273
 274 The routines which implement these operators are expected to actually
 275 I<mutate> their arguments.  So, assuming that $obj is a reference to a
 276 number,
 277
 278   sub incr { my $n = $ {$_[0]}; ++$n; $_[0] = bless \$n}
 279
 280 is an appropriate implementation of overloaded C<++>.  Note that
 281
 282   sub incr { ++$ {$_[0]} ; shift }
 283
 284 is OK if used with preincrement and with postincrement. (In the case
 285 of postincrement a copying will be performed, see L<Copy Constructor>.)
 286
 287 =item C<x=> and other assignment versions
 288
 289 There is nothing special about these methods.  They may change the
 290 value of their arguments, and may leave it as is.  The result is going
 291 to be assigned to the value in the left-hand-side if different from
 292 this value.
 293
 294 This allows for the same method to be used as overloaded C<+=> and
 295 C<+>.  Note that this is I<allowed>, but not recommended, since by the
 296 semantic of L<"Fallback"> Perl will call the method for C<+> anyway,
 297 if C<+=> is not overloaded.
 298
 299 =back
 300
 301 B<Warning.>  Due to the presence of assignment versions of operations,
 302 routines which may be called in assignment context may create
 303 self-referential structures.  Currently Perl will not free self-referential
 304 structures until cycles are C<explicitly> broken.  You may get problems
 305 when traversing your structures too.
 306
 307 Say,
 308
 309   use overload '+' => sub { bless [ \$_[0], \$_[1] ] };
 310
 311 is asking for trouble, since for code C<$obj += $foo> the subroutine
 312 is called as C<$obj = add($obj, $foo, undef)>, or C<$obj = [\$obj,
 313 \$foo]>.  If using such a subroutine is an important optimization, one
 314 can overload C<+=> explicitly by a non-"optimized" version, or switch
 315 to non-optimized version if C<not defined $_[2]> (see
 316 L<Calling Conventions for Binary Operations>).
 317
 318 Even if no I<explicit> assignment-variants of operators are present in
 319 the script, they may be generated by the optimizer.  Say, C<",$obj,"> or
 320 C<',' . $obj . ','> may be both optimized to
 321
 322   my $tmp = ',' . $obj;    $tmp .= ',';
 323
 324 =head2 Overloadable Operations
 325
 326 The following symbols can be specified in C<use overload> directive:
 327
 328 =over 5
 329
 330 =item * I<Arithmetic operations>
 331
 332     "+", "+=", "-", "-=", "*", "*=", "/", "/=", "%", "%=",
 333     "**", "**=", "<<", "<<=", ">>", ">>=", "x", "x=", ".", ".=",
 334
 335 For these operations a substituted non-assignment variant can be called if
 336 the assignment variant is not available.  Methods for operations C<+>,
 337 C<->, C<+=>, and C<-=> can be called to automatically generate
 338 increment and decrement methods.  The operation C<-> can be used to
 339 autogenerate missing methods for unary minus or C<abs>.
 340
 341 See L<"MAGIC AUTOGENERATION">, L<"Calling Conventions for Mutators"> and
 342 L<"Calling Conventions for Binary Operations">) for details of these
 343 substitutions.
 344
 345 =item * I<Comparison operations>
 346
 347     "<",  "<=", ">",  ">=", "==", "!=", "<=>",
 348     "lt", "le", "gt", "ge", "eq", "ne", "cmp",
 349
 350 If the corresponding "spaceship" variant is available, it can be
 351 used to substitute for the missing operation.  During C<sort>ing
 352 arrays, C<cmp> is used to compare values subject to C<use overload>.
 353
 354 =item * I<Bit operations>
 355
 356     "&", "^", "|", "neg", "!", "~",
 357
 358 C<neg> stands for unary minus.  If the method for C<neg> is not
 359 specified, it can be autogenerated using the method for
 360 subtraction. If the method for C<!> is not specified, it can be
 361 autogenerated using the methods for C<bool>, or C<"">, or C<0+>.
 362
 363 =item * I<Increment and decrement>
 364
 365     "++", "--",
 366
 367 If undefined, addition and subtraction methods can be
 368 used instead.  These operations are called both in prefix and
 369 postfix form.
 370
 371 =item * I<Transcendental functions>
 372
 373     "atan2", "cos", "sin", "exp", "abs", "log", "sqrt", "int"
 374
 375 If C<abs> is unavailable, it can be autogenerated using methods
 376 for "E<lt>" or "E<lt>=E<gt>" combined with either unary minus or subtraction.
 377
 378 Note that traditionally the Perl function L<int> rounds to 0, thus for
 379 floating-point-like types one should follow the same semantic.  If
 380 C<int> is unavailable, it can be autogenerated using the overloading of
 381 C<0+>.
 382
 383 =item * I<Boolean, string and numeric conversion>
 384
 385     'bool', '""', '0+',
 386
 387 If one or two of these operations are not overloaded, the remaining ones can
 388 be used instead.  C<bool> is used in the flow control operators
 389 (like C<while>) and for the ternary C<?:> operation.  These functions can
 390 return any arbitrary Perl value.  If the corresponding operation for this value
 391 is overloaded too, that operation will be called again with this value.
 392
 393 As a special case if the overload returns the object itself then it will
 394 be used directly. An overloaded conversion returning the object is
 395 probably a bug, because you're likely to get something that looks like
 396 C<YourPackage=HASH(0x8172b34)>.
 397
 398 =item * I<Iteration>
 399
 400     "<>"
 401
 402 If not overloaded, the argument will be converted to a filehandle or
 403 glob (which may require a stringification).  The same overloading
 404 happens both for the I<read-filehandle> syntax C<E<lt>$varE<gt>> and
 405 I<globbing> syntax C<E<lt>${var}E<gt>>.
 406
 407 B<BUGS> Even in list context, the iterator is currently called only
 408 once and with scalar context.
 409
 410 =item * I<Dereferencing>
 411
 412     '${}', '@{}', '%{}', '&{}', '*{}'.
 413
 414 If not overloaded, the argument will be dereferenced I<as is>, thus
 415 should be of correct type.  These functions should return a reference
 416 of correct type, or another object with overloaded dereferencing.
 417
 418 As a special case if the overload returns the object itself then it
 419 will be used directly (provided it is the correct type).
 420
 421 The dereference operators must be specified explicitly they will not be passed to
 422 "nomethod".
 423
 424 =item * I<Special>
 425
 426     "nomethod", "fallback", "=",
 427
 428 see L<SPECIAL SYMBOLS FOR C<use overload>>.
 429
 430 =back
 431
 432 See L<"Fallback"> for an explanation of when a missing method can be
 433 autogenerated.
 434
 435 A computer-readable form of the above table is available in the hash
 436 %overload::ops, with values being space-separated lists of names:
 437
 438  with_assign      => '+ - * / % ** << >> x .',
 439  assign           => '+= -= *= /= %= **= <<= >>= x= .=',
 440  num_comparison   => '< <= > >= == !=',
 441  '3way_comparison'=> '<=> cmp',
 442  str_comparison   => 'lt le gt ge eq ne',
 443  binary           => '& | ^',
 444  unary            => 'neg ! ~',
 445  mutators         => '++ --',
 446  func             => 'atan2 cos sin exp abs log sqrt',
 447  conversion       => 'bool "" 0+',
 448  iterators        => '<>',
 449  dereferencing    => '${} @{} %{} &{} *{}',
 450  special          => 'nomethod fallback ='
 451
 452 =head2 Inheritance and overloading
 453
 454 Inheritance interacts with overloading in two ways.
 455
 456 =over
 457
 458 =item Strings as values of C<use overload> directive
 459
 460 If C<value> in
 461
 462   use overload key => value;
 463
 464 is a string, it is interpreted as a method name.
 465
 466 =item Overloading of an operation is inherited by derived classes
 467
 468 Any class derived from an overloaded class is also overloaded.  The
 469 set of overloaded methods is the union of overloaded methods of all
 470 the ancestors. If some method is overloaded in several ancestor, then
 471 which description will be used is decided by the usual inheritance
 472 rules:
 473
 474 If C<A> inherits from C<B> and C<C> (in this order), C<B> overloads
 475 C<+> with C<\&D::plus_sub>, and C<C> overloads C<+> by C<"plus_meth">,
 476 then the subroutine C<D::plus_sub> will be called to implement
 477 operation C<+> for an object in package C<A>.
 478
 479 =back
 480
 481 Note that since the value of the C<fallback> key is not a subroutine,
 482 its inheritance is not governed by the above rules.  In the current
 483 implementation, the value of C<fallback> in the first overloaded
 484 ancestor is used, but this is accidental and subject to change.
 485
 486 =head1 SPECIAL SYMBOLS FOR C<use overload>
 487
 488 Three keys are recognized by Perl that are not covered by the above
 489 description.
 490
 491 =head2 Last Resort
 492
 493 C<"nomethod"> should be followed by a reference to a function of four
 494 parameters.  If defined, it is called when the overloading mechanism
 495 cannot find a method for some operation.  The first three arguments of
 496 this function coincide with the arguments for the corresponding method if
 497 it were found, the fourth argument is the symbol
 498 corresponding to the missing method.  If several methods are tried,
 499 the last one is used.  Say, C<1-$a> can be equivalent to
 500
 501         &nomethodMethod($a,1,1,"-")
 502
 503 if the pair C<"nomethod" =E<gt> "nomethodMethod"> was specified in the
 504 C<use overload> directive.
 505
 506 The C<"nomethod"> mechanism is I<not> used for the dereference operators
 507 ( ${} @{} %{} &{} *{} ).
 508
 509
 510 If some operation cannot be resolved, and there is no function
 511 assigned to C<"nomethod">, then an exception will be raised via die()--
 512 unless C<"fallback"> was specified as a key in C<use overload> directive.
 513
 514
 515 =head2 Fallback
 516
 517 The key C<"fallback"> governs what to do if a method for a particular
 518 operation is not found.  Three different cases are possible depending on
 519 the value of C<"fallback">:
 520
 521 =over 16
 522
 523 =item * C<undef>
 524
 525 Perl tries to use a
 526 substituted method (see L<MAGIC AUTOGENERATION>).  If this fails, it
 527 then tries to calls C<"nomethod"> value; if missing, an exception
 528 will be raised.
 529
 530 =item * TRUE
 531
 532 The same as for the C<undef> value, but no exception is raised.  Instead,
 533 it silently reverts to what it would have done were there no C<use overload>
 534 present.
 535
 536 =item * defined, but FALSE
 537
 538 No autogeneration is tried.  Perl tries to call
 539 C<"nomethod"> value, and if this is missing, raises an exception.
 540
 541 =back
 542
 543 B<Note.> C<"fallback"> inheritance via @ISA is not carved in stone
 544 yet, see L<"Inheritance and overloading">.
 545
 546 =head2 Copy Constructor
 547
 548 The value for C<"="> is a reference to a function with three
 549 arguments, i.e., it looks like the other values in C<use
 550 overload>. However, it does not overload the Perl assignment
 551 operator. This would go against Camel hair.
 552
 553 This operation is called in the situations when a mutator is applied
 554 to a reference that shares its object with some other reference, such
 555 as
 556
 557         $a=$b;
 558         ++$a;
 559
 560 To make this change $a and not change $b, a copy of C<$$a> is made,
 561 and $a is assigned a reference to this new object.  This operation is
 562 done during execution of the C<++$a>, and not during the assignment,
 563 (so before the increment C<$$a> coincides with C<$$b>).  This is only
 564 done if C<++> is expressed via a method for C<'++'> or C<'+='> (or
 565 C<nomethod>).  Note that if this operation is expressed via C<'+'>
 566 a nonmutator, i.e., as in
 567
 568         $a=$b;
 569         $a=$a+1;
 570
 571 then C<$a> does not reference a new copy of C<$$a>, since $$a does not
 572 appear as lvalue when the above code is executed.
 573
 574 If the copy constructor is required during the execution of some mutator,
 575 but a method for C<'='> was not specified, it can be autogenerated as a
 576 string copy if the object is a plain scalar.
 577
 578 =over 5
 579
 580 =item B<Example>
 581
 582 The actually executed code for
 583
 584         $a=$b;
 585         Something else which does not modify $a or $b....
 586         ++$a;
 587
 588 may be
 589
 590         $a=$b;
 591         Something else which does not modify $a or $b....
 592         $a = $a->clone(undef,"");
 593         $a->incr(undef,"");
 594
 595 if $b was mathemagical, and C<'++'> was overloaded with C<\&incr>,
 596 C<'='> was overloaded with C<\&clone>.
 597
 598 =back
 599
 600 Same behaviour is triggered by C<$b = $a++>, which is consider a synonym for
 601 C<$b = $a; ++$a>.
 602
 603 =head1 MAGIC AUTOGENERATION
 604
 605 If a method for an operation is not found, and the value for  C<"fallback"> is
 606 TRUE or undefined, Perl tries to autogenerate a substitute method for
 607 the missing operation based on the defined operations.  Autogenerated method
 608 substitutions are possible for the following operations:
 609
 610 =over 16
 611
 612 =item I<Assignment forms of arithmetic operations>
 613
 614 C<$a+=$b> can use the method for C<"+"> if the method for C<"+=">
 615 is not defined.
 616
 617 =item I<Conversion operations>
 618
 619 String, numeric, and boolean conversion are calculated in terms of one
 620 another if not all of them are defined.
 621
 622 =item I<Increment and decrement>
 623
 624 The C<++$a> operation can be expressed in terms of C<$a+=1> or C<$a+1>,
 625 and C<$a--> in terms of C<$a-=1> and C<$a-1>.
 626
 627 =item C<abs($a)>
 628
 629 can be expressed in terms of C<$aE<lt>0> and C<-$a> (or C<0-$a>).
 630
 631 =item I<Unary minus>
 632
 633 can be expressed in terms of subtraction.
 634
 635 =item I<Negation>
 636
 637 C<!> and C<not> can be expressed in terms of boolean conversion, or
 638 string or numerical conversion.
 639
 640 =item I<Concatenation>
 641
 642 can be expressed in terms of string conversion.
 643
 644 =item I<Comparison operations>
 645
 646 can be expressed in terms of its "spaceship" counterpart: either
 647 C<E<lt>=E<gt>> or C<cmp>:
 648
 649     <, >, <=, >=, ==, !=        in terms of <=>
 650     lt, gt, le, ge, eq, ne      in terms of cmp
 651
 652 =item I<Iterator>
 653
 654     <>                          in terms of builtin operations
 655
 656 =item I<Dereferencing>
 657
 658     ${} @{} %{} &{} *{}         in terms of builtin operations
 659
 660 =item I<Copy operator>
 661
 662 can be expressed in terms of an assignment to the dereferenced value, if this
 663 value is a scalar and not a reference.
 664
 665 =back
 666
 667 =head1 Losing overloading
 668
 669 The restriction for the comparison operation is that even if, for example,
 670 `C<cmp>' should return a blessed reference, the autogenerated `C<lt>'
 671 function will produce only a standard logical value based on the
 672 numerical value of the result of `C<cmp>'.  In particular, a working
 673 numeric conversion is needed in this case (possibly expressed in terms of
 674 other conversions).
 675
 676 Similarly, C<.=>  and C<x=> operators lose their mathemagical properties
 677 if the string conversion substitution is applied.
 678
 679 When you chop() a mathemagical object it is promoted to a string and its
 680 mathemagical properties are lost.  The same can happen with other
 681 operations as well.
 682
 683 =head1 Run-time Overloading
 684
 685 Since all C<use> directives are executed at compile-time, the only way to
 686 change overloading during run-time is to
 687
 688     eval 'use overload "+" => \&addmethod';
 689
 690 You can also use
 691
 692     eval 'no overload "+", "--", "<="';
 693
 694 though the use of these constructs during run-time is questionable.
 695
 696 =head1 Public functions
 697
 698 Package C<overload.pm> provides the following public functions:
 699
 700 =over 5
 701
 702 =item overload::StrVal(arg)
 703
 704 Gives string value of C<arg> as in absence of stringify overloading.
 705
 706 =item overload::Overloaded(arg)
 707
 708 Returns true if C<arg> is subject to overloading of some operations.
 709
 710 =item overload::Method(obj,op)
 711
 712 Returns C<undef> or a reference to the method that implements C<op>.
 713
 714 =back
 715
 716 =head1 Overloading constants
 717
 718 For some application Perl parser mangles constants too much.  It is possible
 719 to hook into this process via overload::constant() and overload::remove_constant()
 720 functions.
 721
 722 These functions take a hash as an argument.  The recognized keys of this hash
 723 are
 724
 725 =over 8
 726
 727 =item integer
 728
 729 to overload integer constants,
 730
 731 =item float
 732
 733 to overload floating point constants,
 734
 735 =item binary
 736
 737 to overload octal and hexadecimal constants,
 738
 739 =item q
 740
 741 to overload C<q>-quoted strings, constant pieces of C<qq>- and C<qx>-quoted
 742 strings and here-documents,
 743
 744 =item qr
 745
 746 to overload constant pieces of regular expressions.
 747
 748 =back
 749
 750 The corresponding values are references to functions which take three arguments:
 751 the first one is the I<initial> string form of the constant, the second one
 752 is how Perl interprets this constant, the third one is how the constant is used.
 753 Note that the initial string form does not
 754 contain string delimiters, and has backslashes in backslash-delimiter
 755 combinations stripped (thus the value of delimiter is not relevant for
 756 processing of this string).  The return value of this function is how this
 757 constant is going to be interpreted by Perl.  The third argument is undefined
 758 unless for overloaded C<q>- and C<qr>- constants, it is C<q> in single-quote
 759 context (comes from strings, regular expressions, and single-quote HERE
 760 documents), it is C<tr> for arguments of C<tr>/C<y> operators,
 761 it is C<s> for right-hand side of C<s>-operator, and it is C<qq> otherwise.
 762
 763 Since an expression C<"ab$cd,,"> is just a shortcut for C<'ab' . $cd . ',,'>,
 764 it is expected that overloaded constant strings are equipped with reasonable
 765 overloaded catenation operator, otherwise absurd results will result.
 766 Similarly, negative numbers are considered as negations of positive constants.
 767
 768 Note that it is probably meaningless to call the functions overload::constant()
 769 and overload::remove_constant() from anywhere but import() and unimport() methods.
 770 From these methods they may be called as
 771
 772         sub import {
 773           shift;
 774           return unless @_;
 775           die "unknown import: @_" unless @_ == 1 and $_[0] eq ':constant';
 776           overload::constant integer => sub {Math::BigInt->new(shift)};
 777         }
 778
 779 B<BUGS> Currently overloaded-ness of constants does not propagate
 780 into C<eval '...'>.
 781
 782 =head1 IMPLEMENTATION
 783
 784 What follows is subject to change RSN.
 785
 786 The table of methods for all operations is cached in magic for the
 787 symbol table hash for the package.  The cache is invalidated during
 788 processing of C<use overload>, C<no overload>, new function
 789 definitions, and changes in @ISA. However, this invalidation remains
 790 unprocessed until the next C<bless>ing into the package. Hence if you
 791 want to change overloading structure dynamically, you'll need an
 792 additional (fake) C<bless>ing to update the table.
 793
 794 (Every SVish thing has a magic queue, and magic is an entry in that
 795 queue.  This is how a single variable may participate in multiple
 796 forms of magic simultaneously.  For instance, environment variables
 797 regularly have two forms at once: their %ENV magic and their taint
 798 magic. However, the magic which implements overloading is applied to
 799 the stashes, which are rarely used directly, thus should not slow down
 800 Perl.)
 801
 802 If an object belongs to a package using overload, it carries a special
 803 flag.  Thus the only speed penalty during arithmetic operations without
 804 overloading is the checking of this flag.
 805
 806 In fact, if C<use overload> is not present, there is almost no overhead
 807 for overloadable operations, so most programs should not suffer
 808 measurable performance penalties.  A considerable effort was made to
 809 minimize the overhead when overload is used in some package, but the
 810 arguments in question do not belong to packages using overload.  When
 811 in doubt, test your speed with C<use overload> and without it.  So far
 812 there have been no reports of substantial speed degradation if Perl is
 813 compiled with optimization turned on.
 814
 815 There is no size penalty for data if overload is not used. The only
 816 size penalty if overload is used in some package is that I<all> the
 817 packages acquire a magic during the next C<bless>ing into the
 818 package. This magic is three-words-long for packages without
 819 overloading, and carries the cache table if the package is overloaded.
 820
 821 Copying (C<$a=$b>) is shallow; however, a one-level-deep copying is
 822 carried out before any operation that can imply an assignment to the
 823 object $a (or $b) refers to, like C<$a++>.  You can override this
 824 behavior by defining your own copy constructor (see L<"Copy Constructor">).
 825
 826 It is expected that arguments to methods that are not explicitly supposed
 827 to be changed are constant (but this is not enforced).
 828
 829 =head1 Metaphor clash
 830
 831 One may wonder why the semantic of overloaded C<=> is so counter intuitive.
 832 If it I<looks> counter intuitive to you, you are subject to a metaphor
 833 clash.
 834
 835 Here is a Perl object metaphor:
 836
 837 I<  object is a reference to blessed data>
 838
 839 and an arithmetic metaphor:
 840
 841 I<  object is a thing by itself>.
 842
 843 The I<main> problem of overloading C<=> is the fact that these metaphors
 844 imply different actions on the assignment C<$a = $b> if $a and $b are
 845 objects.  Perl-think implies that $a becomes a reference to whatever
 846 $b was referencing.  Arithmetic-think implies that the value of "object"
 847 $a is changed to become the value of the object $b, preserving the fact
 848 that $a and $b are separate entities.
 849
 850 The difference is not relevant in the absence of mutators.  After
 851 a Perl-way assignment an operation which mutates the data referenced by $a
 852 would change the data referenced by $b too.  Effectively, after
 853 C<$a = $b> values of $a and $b become I<indistinguishable>.
 854
 855 On the other hand, anyone who has used algebraic notation knows the
 856 expressive power of the arithmetic metaphor.  Overloading works hard
 857 to enable this metaphor while preserving the Perlian way as far as
 858 possible.  Since it is not possible to freely mix two contradicting
 859 metaphors, overloading allows the arithmetic way to write things I<as
 860 far as all the mutators are called via overloaded access only>.  The
 861 way it is done is described in L<Copy Constructor>.
 862
 863 If some mutator methods are directly applied to the overloaded values,
 864 one may need to I<explicitly unlink> other values which references the
 865 same value:
 866
 867     $a = new Data 23;
 868     ...
 869     $b = $a;            # $b is "linked" to $a
 870     ...
 871     $a = $a->clone;     # Unlink $b from $a
 872     $a->increment_by(4);
 873
 874 Note that overloaded access makes this transparent:
 875
 876     $a = new Data 23;
 877     $b = $a;            # $b is "linked" to $a
 878     $a += 4;            # would unlink $b automagically
 879
 880 However, it would not make
 881
 882     $a = new Data 23;
 883     $a = 4;             # Now $a is a plain 4, not 'Data'
 884
 885 preserve "objectness" of $a.  But Perl I<has> a way to make assignments
 886 to an object do whatever you want.  It is just not the overload, but
 887 tie()ing interface (see L<perlfunc/tie>).  Adding a FETCH() method
 888 which returns the object itself, and STORE() method which changes the
 889 value of the object, one can reproduce the arithmetic metaphor in its
 890 completeness, at least for variables which were tie()d from the start.
 891
 892 (Note that a workaround for a bug may be needed, see L<"BUGS">.)
 893
 894 =head1 Cookbook
 895
 896 Please add examples to what follows!
 897
 898 =head2 Two-face scalars
 899
 900 Put this in F<two_face.pm> in your Perl library directory:
 901
 902   package two_face;             # Scalars with separate string and
 903                                 # numeric values.
 904   sub new { my $p = shift; bless [@_], $p }
 905   use overload '""' => \&str, '0+' => \&num, fallback => 1;
 906   sub num {shift->[1]}
 907   sub str {shift->[0]}
 908
 909 Use it as follows:
 910
 911   require two_face;
 912   my $seven = new two_face ("vii", 7);
 913   printf "seven=$seven, seven=%d, eight=%d\n", $seven, $seven+1;
 914   print "seven contains `i'\n" if $seven =~ /i/;
 915
 916 (The second line creates a scalar which has both a string value, and a
 917 numeric value.)  This prints:
 918
 919   seven=vii, seven=7, eight=8
 920   seven contains `i'
 921
 922 =head2 Two-face references
 923
 924 Suppose you want to create an object which is accessible as both an
 925 array reference and a hash reference.
 926
 927   package two_refs;
 928   use overload '%{}' => \&gethash, '@{}' => sub { $ {shift()} };
 929   sub new {
 930     my $p = shift;
 931     bless \ [@_], $p;
 932   }
 933   sub gethash {
 934     my %h;
 935     my $self = shift;
 936     tie %h, ref $self, $self;
 937     \%h;
 938   }
 939
 940   sub TIEHASH { my $p = shift; bless \ shift, $p }
 941   my %fields;
 942   my $i = 0;
 943   $fields{$_} = $i++ foreach qw{zero one two three};
 944   sub STORE {
 945     my $self = ${shift()};
 946     my $key = $fields{shift()};
 947     defined $key or die "Out of band access";
 948     $$self->[$key] = shift;
 949   }
 950   sub FETCH {
 951     my $self = ${shift()};
 952     my $key = $fields{shift()};
 953     defined $key or die "Out of band access";
 954     $$self->[$key];
 955   }
 956
 957 Now one can access an object using both the array and hash syntax:
 958
 959   my $bar = new two_refs 3,4,5,6;
 960   $bar->[2] = 11;
 961   $bar->{two} == 11 or die 'bad hash fetch';
 962
 963 Note several important features of this example.  First of all, the
 964 I<actual> type of $bar is a scalar reference, and we do not overload
 965 the scalar dereference.  Thus we can get the I<actual> non-overloaded
 966 contents of $bar by just using C<$$bar> (what we do in functions which
 967 overload dereference).  Similarly, the object returned by the
 968 TIEHASH() method is a scalar reference.
 969
 970 Second, we create a new tied hash each time the hash syntax is used.
 971 This allows us not to worry about a possibility of a reference loop,
 972 which would lead to a memory leak.
 973
 974 Both these problems can be cured.  Say, if we want to overload hash
 975 dereference on a reference to an object which is I<implemented> as a
 976 hash itself, the only problem one has to circumvent is how to access
 977 this I<actual> hash (as opposed to the I<virtual> hash exhibited by the
 978 overloaded dereference operator).  Here is one possible fetching routine:
 979
 980   sub access_hash {
 981     my ($self, $key) = (shift, shift);
 982     my $class = ref $self;
 983     bless $self, 'overload::dummy'; # Disable overloading of %{}
 984     my $out = $self->{$key};
 985     bless $self, $class;        # Restore overloading
 986     $out;
 987   }
 988
 989 To remove creation of the tied hash on each access, one may an extra
 990 level of indirection which allows a non-circular structure of references:
 991
 992   package two_refs1;
 993   use overload '%{}' => sub { ${shift()}->[1] },
 994                '@{}' => sub { ${shift()}->[0] };
 995   sub new {
 996     my $p = shift;
 997     my $a = [@_];
 998     my %h;
 999     tie %h, $p, $a;
1000     bless \ [$a, \%h], $p;
1001   }
1002   sub gethash {
1003     my %h;
1004     my $self = shift;
1005     tie %h, ref $self, $self;
1006     \%h;
1007   }
1008
1009   sub TIEHASH { my $p = shift; bless \ shift, $p }
1010   my %fields;
1011   my $i = 0;
1012   $fields{$_} = $i++ foreach qw{zero one two three};
1013   sub STORE {
1014     my $a = ${shift()};
1015     my $key = $fields{shift()};
1016     defined $key or die "Out of band access";
1017     $a->[$key] = shift;
1018   }
1019   sub FETCH {
1020     my $a = ${shift()};
1021     my $key = $fields{shift()};
1022     defined $key or die "Out of band access";
1023     $a->[$key];
1024   }
1025
1026 Now if $baz is overloaded like this, then C<$baz> is a reference to a
1027 reference to the intermediate array, which keeps a reference to an
1028 actual array, and the access hash.  The tie()ing object for the access
1029 hash is a reference to a reference to the actual array, so
1030
1031 =over
1032
1033 =item *
1034
1035 There are no loops of references.
1036
1037 =item *
1038
1039 Both "objects" which are blessed into the class C<two_refs1> are
1040 references to a reference to an array, thus references to a I<scalar>.
1041 Thus the accessor expression C<$$foo-E<gt>[$ind]> involves no
1042 overloaded operations.
1043
1044 =back
1045
1046 =head2 Symbolic calculator
1047
1048 Put this in F<symbolic.pm> in your Perl library directory:
1049
1050   package symbolic;             # Primitive symbolic calculator
1051   use overload nomethod => \&wrap;
1052
1053   sub new { shift; bless ['n', @_] }
1054   sub wrap {
1055     my ($obj, $other, $inv, $meth) = @_;
1056     ($obj, $other) = ($other, $obj) if $inv;
1057     bless [$meth, $obj, $other];
1058   }
1059
1060 This module is very unusual as overloaded modules go: it does not
1061 provide any usual overloaded operators, instead it provides the L<Last
1062 Resort> operator C<nomethod>.  In this example the corresponding
1063 subroutine returns an object which encapsulates operations done over
1064 the objects: C<new symbolic 3> contains C<['n', 3]>, C<2 + new
1065 symbolic 3> contains C<['+', 2, ['n', 3]]>.
1066
1067 Here is an example of the script which "calculates" the side of
1068 circumscribed octagon using the above package:
1069
1070   require symbolic;
1071   my $iter = 1;                 # 2**($iter+2) = 8
1072   my $side = new symbolic 1;
1073   my $cnt = $iter;
1074
1075   while ($cnt--) {
1076     $side = (sqrt(1 + $side**2) - 1)/$side;
1077   }
1078   print "OK\n";
1079
1080 The value of $side is
1081
1082   ['/', ['-', ['sqrt', ['+', 1, ['**', ['n', 1], 2]],
1083                        undef], 1], ['n', 1]]
1084
1085 Note that while we obtained this value using a nice little script,
1086 there is no simple way to I<use> this value.  In fact this value may
1087 be inspected in debugger (see L<perldebug>), but ony if
1088 C<bareStringify> B<O>ption is set, and not via C<p> command.
1089
1090 If one attempts to print this value, then the overloaded operator
1091 C<""> will be called, which will call C<nomethod> operator.  The
1092 result of this operator will be stringified again, but this result is
1093 again of type C<symbolic>, which will lead to an infinite loop.
1094
1095 Add a pretty-printer method to the module F<symbolic.pm>:
1096
1097   sub pretty {
1098     my ($meth, $a, $b) = @{+shift};
1099     $a = 'u' unless defined $a;
1100     $b = 'u' unless defined $b;
1101     $a = $a->pretty if ref $a;
1102     $b = $b->pretty if ref $b;
1103     "[$meth $a $b]";
1104   }
1105
1106 Now one can finish the script by
1107
1108   print "side = ", $side->pretty, "\n";
1109
1110 The method C<pretty> is doing object-to-string conversion, so it
1111 is natural to overload the operator C<""> using this method.  However,
1112 inside such a method it is not necessary to pretty-print the
1113 I<components> $a and $b of an object.  In the above subroutine
1114 C<"[$meth $a $b]"> is a catenation of some strings and components $a
1115 and $b.  If these components use overloading, the catenation operator
1116 will look for an overloaded operator C<.>; if not present, it will
1117 look for an overloaded operator C<"">.  Thus it is enough to use
1118
1119   use overload nomethod => \&wrap, '""' => \&str;
1120   sub str {
1121     my ($meth, $a, $b) = @{+shift};
1122     $a = 'u' unless defined $a;
1123     $b = 'u' unless defined $b;
1124     "[$meth $a $b]";
1125   }
1126
1127 Now one can change the last line of the script to
1128
1129   print "side = $side\n";
1130
1131 which outputs
1132
1133   side = [/ [- [sqrt [+ 1 [** [n 1 u] 2]] u] 1] [n 1 u]]
1134
1135 and one can inspect the value in debugger using all the possible
1136 methods.
1137
1138 Something is still amiss: consider the loop variable $cnt of the
1139 script.  It was a number, not an object.  We cannot make this value of
1140 type C<symbolic>, since then the loop will not terminate.
1141
1142 Indeed, to terminate the cycle, the $cnt should become false.
1143 However, the operator C<bool> for checking falsity is overloaded (this
1144 time via overloaded C<"">), and returns a long string, thus any object
1145 of type C<symbolic> is true.  To overcome this, we need a way to
1146 compare an object to 0.  In fact, it is easier to write a numeric
1147 conversion routine.
1148
1149 Here is the text of F<symbolic.pm> with such a routine added (and
1150 slightly modified str()):
1151
1152   package symbolic;             # Primitive symbolic calculator
1153   use overload
1154     nomethod => \&wrap, '""' => \&str, '0+' => \&num;
1155
1156   sub new { shift; bless ['n', @_] }
1157   sub wrap {
1158     my ($obj, $other, $inv, $meth) = @_;
1159     ($obj, $other) = ($other, $obj) if $inv;
1160     bless [$meth, $obj, $other];
1161   }
1162   sub str {
1163     my ($meth, $a, $b) = @{+shift};
1164     $a = 'u' unless defined $a;
1165     if (defined $b) {
1166       "[$meth $a $b]";
1167     } else {
1168       "[$meth $a]";
1169     }
1170   }
1171   my %subr = ( n => sub {$_[0]},
1172                sqrt => sub {sqrt $_[0]},
1173                '-' => sub {shift() - shift()},
1174                '+' => sub {shift() + shift()},
1175                '/' => sub {shift() / shift()},
1176                '*' => sub {shift() * shift()},
1177                '**' => sub {shift() ** shift()},
1178              );
1179   sub num {
1180     my ($meth, $a, $b) = @{+shift};
1181     my $subr = $subr{$meth}
1182       or die "Do not know how to ($meth) in symbolic";
1183     $a = $a->num if ref $a eq __PACKAGE__;
1184     $b = $b->num if ref $b eq __PACKAGE__;
1185     $subr->($a,$b);
1186   }
1187
1188 All the work of numeric conversion is done in %subr and num().  Of
1189 course, %subr is not complete, it contains only operators used in the
1190 example below.  Here is the extra-credit question: why do we need an
1191 explicit recursion in num()?  (Answer is at the end of this section.)
1192
1193 Use this module like this:
1194
1195   require symbolic;
1196   my $iter = new symbolic 2;    # 16-gon
1197   my $side = new symbolic 1;
1198   my $cnt = $iter;
1199
1200   while ($cnt) {
1201     $cnt = $cnt - 1;            # Mutator `--' not implemented
1202     $side = (sqrt(1 + $side**2) - 1)/$side;
1203   }
1204   printf "%s=%f\n", $side, $side;
1205   printf "pi=%f\n", $side*(2**($iter+2));
1206
1207 It prints (without so many line breaks)
1208
1209   [/ [- [sqrt [+ 1 [** [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1]
1210                           [n 1]] 2]]] 1]
1211      [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1] [n 1]]]=0.198912
1212   pi=3.182598
1213
1214 The above module is very primitive.  It does not implement
1215 mutator methods (C<++>, C<-=> and so on), does not do deep copying
1216 (not required without mutators!), and implements only those arithmetic
1217 operations which are used in the example.
1218
1219 To implement most arithmetic operations is easy; one should just use
1220 the tables of operations, and change the code which fills %subr to
1221
1222   my %subr = ( 'n' => sub {$_[0]} );
1223   foreach my $op (split " ", $overload::ops{with_assign}) {
1224     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1225   }
1226   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1227   foreach my $op (split " ", "@overload::ops{ @bins }") {
1228     $subr{$op} = eval "sub {shift() $op shift()}";
1229   }
1230   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1231     print "defining `$op'\n";
1232     $subr{$op} = eval "sub {$op shift()}";
1233   }
1234
1235 Due to L<Calling Conventions for Mutators>, we do not need anything
1236 special to make C<+=> and friends work, except filling C<+=> entry of
1237 %subr, and defining a copy constructor (needed since Perl has no
1238 way to know that the implementation of C<'+='> does not mutate
1239 the argument, compare L<Copy Constructor>).
1240
1241 To implement a copy constructor, add C<< '=' => \&cpy >> to C<use overload>
1242 line, and code (this code assumes that mutators change things one level
1243 deep only, so recursive copying is not needed):
1244
1245   sub cpy {
1246     my $self = shift;
1247     bless [@$self], ref $self;
1248   }
1249
1250 To make C<++> and C<--> work, we need to implement actual mutators,
1251 either directly, or in C<nomethod>.  We continue to do things inside
1252 C<nomethod>, thus add
1253
1254     if ($meth eq '++' or $meth eq '--') {
1255       @$obj = ($meth, (bless [@$obj]), 1); # Avoid circular reference
1256       return $obj;
1257     }
1258
1259 after the first line of wrap().  This is not a most effective
1260 implementation, one may consider
1261
1262   sub inc { $_[0] = bless ['++', shift, 1]; }
1263
1264 instead.
1265
1266 As a final remark, note that one can fill %subr by
1267
1268   my %subr = ( 'n' => sub {$_[0]} );
1269   foreach my $op (split " ", $overload::ops{with_assign}) {
1270     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1271   }
1272   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1273   foreach my $op (split " ", "@overload::ops{ @bins }") {
1274     $subr{$op} = eval "sub {shift() $op shift()}";
1275   }
1276   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1277     $subr{$op} = eval "sub {$op shift()}";
1278   }
1279   $subr{'++'} = $subr{'+'};
1280   $subr{'--'} = $subr{'-'};
1281
1282 This finishes implementation of a primitive symbolic calculator in
1283 50 lines of Perl code.  Since the numeric values of subexpressions
1284 are not cached, the calculator is very slow.
1285
1286 Here is the answer for the exercise: In the case of str(), we need no
1287 explicit recursion since the overloaded C<.>-operator will fall back
1288 to an existing overloaded operator C<"">.  Overloaded arithmetic
1289 operators I<do not> fall back to numeric conversion if C<fallback> is
1290 not explicitly requested.  Thus without an explicit recursion num()
1291 would convert C<['+', $a, $b]> to C<$a + $b>, which would just rebuild
1292 the argument of num().
1293
1294 If you wonder why defaults for conversion are different for str() and
1295 num(), note how easy it was to write the symbolic calculator.  This
1296 simplicity is due to an appropriate choice of defaults.  One extra
1297 note: due to the explicit recursion num() is more fragile than sym():
1298 we need to explicitly check for the type of $a and $b.  If components
1299 $a and $b happen to be of some related type, this may lead to problems.
1300
1301 =head2 I<Really> symbolic calculator
1302
1303 One may wonder why we call the above calculator symbolic.  The reason
1304 is that the actual calculation of the value of expression is postponed
1305 until the value is I<used>.
1306
1307 To see it in action, add a method
1308
1309   sub STORE {
1310     my $obj = shift;
1311     $#$obj = 1;
1312     @$obj->[0,1] = ('=', shift);
1313   }
1314
1315 to the package C<symbolic>.  After this change one can do
1316
1317   my $a = new symbolic 3;
1318   my $b = new symbolic 4;
1319   my $c = sqrt($a**2 + $b**2);
1320
1321 and the numeric value of $c becomes 5.  However, after calling
1322
1323   $a->STORE(12);  $b->STORE(5);
1324
1325 the numeric value of $c becomes 13.  There is no doubt now that the module
1326 symbolic provides a I<symbolic> calculator indeed.
1327
1328 To hide the rough edges under the hood, provide a tie()d interface to the
1329 package C<symbolic> (compare with L<Metaphor clash>).  Add methods
1330
1331   sub TIESCALAR { my $pack = shift; $pack->new(@_) }
1332   sub FETCH { shift }
1333   sub nop {  }          # Around a bug
1334
1335 (the bug is described in L<"BUGS">).  One can use this new interface as
1336
1337   tie $a, 'symbolic', 3;
1338   tie $b, 'symbolic', 4;
1339   $a->nop;  $b->nop;    # Around a bug
1340
1341   my $c = sqrt($a**2 + $b**2);
1342
1343 Now numeric value of $c is 5.  After C<$a = 12; $b = 5> the numeric value
1344 of $c becomes 13.  To insulate the user of the module add a method
1345
1346   sub vars { my $p = shift; tie($_, $p), $_->nop foreach @_; }
1347
1348 Now
1349
1350   my ($a, $b);
1351   symbolic->vars($a, $b);
1352   my $c = sqrt($a**2 + $b**2);
1353
1354   $a = 3; $b = 4;
1355   printf "c5  %s=%f\n", $c, $c;
1356
1357   $a = 12; $b = 5;
1358   printf "c13  %s=%f\n", $c, $c;
1359
1360 shows that the numeric value of $c follows changes to the values of $a
1361 and $b.
1362
1363 =head1 AUTHOR
1364
1365 Ilya Zakharevich E<lt>F<ilya@math.mps.ohio-state.edu>E<gt>.
1366
1367 =head1 DIAGNOSTICS
1368
1369 When Perl is run with the B<-Do> switch or its equivalent, overloading
1370 induces diagnostic messages.
1371
1372 Using the C<m> command of Perl debugger (see L<perldebug>) one can
1373 deduce which operations are overloaded (and which ancestor triggers
1374 this overloading). Say, if C<eq> is overloaded, then the method C<(eq>
1375 is shown by debugger. The method C<()> corresponds to the C<fallback>
1376 key (in fact a presence of this method shows that this package has
1377 overloading enabled, and it is what is used by the C<Overloaded>
1378 function of module C<overload>).
1379
1380 The module might issue the following warnings:
1381
1382 =over 4
1383
1384 =item Odd number of arguments for overload::constant
1385
1386 (W) The call to overload::constant contained an odd number of arguments.
1387 The arguments should come in pairs.
1388
1389 =item `%s' is not an overloadable type
1390
1391 (W) You tried to overload a constant type the overload package is unaware of.
1392
1393 =item `%s' is not a code reference
1394
1395 (W) The second (fourth, sixth, ...) argument of overload::constant needs
1396 to be a code reference. Either an anonymous subroutine, or a reference
1397 to a subroutine.
1398
1399 =back
1400
1401 =head1 BUGS
1402
1403 Because it is used for overloading, the per-package hash %OVERLOAD now
1404 has a special meaning in Perl. The symbol table is filled with names
1405 looking like line-noise.
1406
1407 For the purpose of inheritance every overloaded package behaves as if
1408 C<fallback> is present (possibly undefined). This may create
1409 interesting effects if some package is not overloaded, but inherits
1410 from two overloaded packages.
1411
1412 Relation between overloading and tie()ing is broken.  Overloading is
1413 triggered or not basing on the I<previous> class of tie()d value.
1414
1415 This happens because the presence of overloading is checked too early,
1416 before any tie()d access is attempted.  If the FETCH()ed class of the
1417 tie()d value does not change, a simple workaround is to access the value
1418 immediately after tie()ing, so that after this call the I<previous> class
1419 coincides with the current one.
1420
1421 B<Needed:> a way to fix this without a speed penalty.
1422
1423 Barewords are not covered by overloaded string constants.
1424
1425 This document is confusing.  There are grammos and misleading language
1426 used in places.  It would seem a total rewrite is needed.
1427
1428 =cut
1429