lib/overload.pm

   1 package overload;
   2
   3 our $VERSION = '1.04';
   4
   5 sub nil {}
   6
   7 sub OVERLOAD {
   8   $package = shift;
   9   my %arg = @_;
  10   my ($sub, $fb);
  11   $ {$package . "::OVERLOAD"}{dummy}++; # Register with magic by touching.
  12   *{$package . "::()"} = \&nil; # Make it findable via fetchmethod.
  13   for (keys %arg) {
  14     if ($_ eq 'fallback') {
  15       $fb = $arg{$_};
  16     } else {
  17       $sub = $arg{$_};
  18       if (not ref $sub and $sub !~ /::/) {
  19         $ {$package . "::(" . $_} = $sub;
  20         $sub = \&nil;
  21       }
  22       #print STDERR "Setting `$ {'package'}::\cO$_' to \\&`$sub'.\n";
  23       *{$package . "::(" . $_} = \&{ $sub };
  24     }
  25   }
  26   ${$package . "::()"} = $fb; # Make it findable too (fallback only).
  27 }
  28
  29 sub import {
  30   $package = (caller())[0];
  31   # *{$package . "::OVERLOAD"} = \&OVERLOAD;
  32   shift;
  33   $package->overload::OVERLOAD(@_);
  34 }
  35
  36 sub unimport {
  37   $package = (caller())[0];
  38   ${$package . "::OVERLOAD"}{dummy}++; # Upgrade the table
  39   shift;
  40   for (@_) {
  41     if ($_ eq 'fallback') {
  42       undef $ {$package . "::()"};
  43     } else {
  44       delete $ {$package . "::"}{"(" . $_};
  45     }
  46   }
  47 }
  48
  49 sub Overloaded {
  50   my $package = shift;
  51   $package = ref $package if ref $package;
  52   $package->can('()');
  53 }
  54
  55 sub ov_method {
  56   my $globref = shift;
  57   return undef unless $globref;
  58   my $sub = \&{*$globref};
  59   return $sub if $sub ne \&nil;
  60   return shift->can($ {*$globref});
  61 }
  62
  63 sub OverloadedStringify {
  64   my $package = shift;
  65   $package = ref $package if ref $package;
  66   #$package->can('(""')
  67   ov_method mycan($package, '(""'), $package
  68     or ov_method mycan($package, '(0+'), $package
  69     or ov_method mycan($package, '(bool'), $package
  70     or ov_method mycan($package, '(nomethod'), $package;
  71 }
  72
  73 sub Method {
  74   my $package = shift;
  75   $package = ref $package if ref $package;
  76   #my $meth = $package->can('(' . shift);
  77   ov_method mycan($package, '(' . shift), $package;
  78   #return $meth if $meth ne \&nil;
  79   #return $ {*{$meth}};
  80 }
  81
  82 sub AddrRef {
  83   my $package = ref $_[0];
  84   return "$_[0]" unless $package;
  85
  86         require Scalar::Util;
  87         my $class = Scalar::Util::blessed($_[0]);
  88         my $class_prefix = defined($class) ? "$class=" : "";
  89         my $type = Scalar::Util::reftype($_[0]);
  90         my $addr = Scalar::Util::refaddr($_[0]);
  91         return sprintf("$class_prefix$type(0x%x)", $addr);
  92 }
  93
  94 *StrVal = *AddrRef;
  95
  96 sub mycan {                             # Real can would leave stubs.
  97   my ($package, $meth) = @_;
  98   return \*{$package . "::$meth"} if defined &{$package . "::$meth"};
  99   my $p;
 100   foreach $p (@{$package . "::ISA"}) {
 101     my $out = mycan($p, $meth);
 102     return $out if $out;
 103   }
 104   return undef;
 105 }
 106
 107 %constants = (
 108               'integer'   =>  0x1000, # HINT_NEW_INTEGER
 109               'float'     =>  0x2000, # HINT_NEW_FLOAT
 110               'binary'    =>  0x4000, # HINT_NEW_BINARY
 111               'q'         =>  0x8000, # HINT_NEW_STRING
 112               'qr'        => 0x10000, # HINT_NEW_RE
 113              );
 114
 115 %ops = ( with_assign      => "+ - * / % ** << >> x .",
 116          assign           => "+= -= *= /= %= **= <<= >>= x= .=",
 117          num_comparison   => "< <= >  >= == !=",
 118          '3way_comparison'=> "<=> cmp",
 119          str_comparison   => "lt le gt ge eq ne",
 120          binary           => "& | ^",
 121          unary            => "neg ! ~",
 122          mutators         => '++ --',
 123          func             => "atan2 cos sin exp abs log sqrt int",
 124          conversion       => 'bool "" 0+',
 125          iterators        => '<>',
 126          dereferencing    => '${} @{} %{} &{} *{}',
 127          special          => 'nomethod fallback =');
 128
 129 use warnings::register;
 130 sub constant {
 131   # Arguments: what, sub
 132   while (@_) {
 133     if (@_ == 1) {
 134         warnings::warnif ("Odd number of arguments for overload::constant");
 135         last;
 136     }
 137     elsif (!exists $constants {$_ [0]}) {
 138         warnings::warnif ("`$_[0]' is not an overloadable type");
 139     }
 140     elsif (!ref $_ [1] || "$_[1]" !~ /CODE\(0x[\da-f]+\)$/) {
 141         # Can't use C<ref $_[1] eq "CODE"> above as code references can be
 142         # blessed, and C<ref> would return the package the ref is blessed into.
 143         if (warnings::enabled) {
 144             $_ [1] = "undef" unless defined $_ [1];
 145             warnings::warn ("`$_[1]' is not a code reference");
 146         }
 147     }
 148     else {
 149         $^H{$_[0]} = $_[1];
 150         $^H |= $constants{$_[0]};
 151     }
 152     shift, shift;
 153   }
 154 }
 155
 156 sub remove_constant {
 157   # Arguments: what, sub
 158   while (@_) {
 159     delete $^H{$_[0]};
 160     $^H &= ~ $constants{$_[0]};
 161     shift, shift;
 162   }
 163 }
 164
 165 1;
 166
 167 __END__
 168
 169 =head1 NAME
 170
 171 overload - Package for overloading Perl operations
 172
 173 =head1 SYNOPSIS
 174
 175     package SomeThing;
 176
 177     use overload
 178         '+' => \&myadd,
 179         '-' => \&mysub;
 180         # etc
 181     ...
 182
 183     package main;
 184     $a = new SomeThing 57;
 185     $b=5+$a;
 186     ...
 187     if (overload::Overloaded $b) {...}
 188     ...
 189     $strval = overload::StrVal $b;
 190
 191 =head1 DESCRIPTION
 192
 193 =head2 Declaration of overloaded functions
 194
 195 The compilation directive
 196
 197     package Number;
 198     use overload
 199         "+" => \&add,
 200         "*=" => "muas";
 201
 202 declares function Number::add() for addition, and method muas() in
 203 the "class" C<Number> (or one of its base classes)
 204 for the assignment form C<*=> of multiplication.
 205
 206 Arguments of this directive come in (key, value) pairs.  Legal values
 207 are values legal inside a C<&{ ... }> call, so the name of a
 208 subroutine, a reference to a subroutine, or an anonymous subroutine
 209 will all work.  Note that values specified as strings are
 210 interpreted as methods, not subroutines.  Legal keys are listed below.
 211
 212 The subroutine C<add> will be called to execute C<$a+$b> if $a
 213 is a reference to an object blessed into the package C<Number>, or if $a is
 214 not an object from a package with defined mathemagic addition, but $b is a
 215 reference to a C<Number>.  It can also be called in other situations, like
 216 C<$a+=7>, or C<$a++>.  See L<MAGIC AUTOGENERATION>.  (Mathemagical
 217 methods refer to methods triggered by an overloaded mathematical
 218 operator.)
 219
 220 Since overloading respects inheritance via the @ISA hierarchy, the
 221 above declaration would also trigger overloading of C<+> and C<*=> in
 222 all the packages which inherit from C<Number>.
 223
 224 =head2 Calling Conventions for Binary Operations
 225
 226 The functions specified in the C<use overload ...> directive are called
 227 with three (in one particular case with four, see L<Last Resort>)
 228 arguments.  If the corresponding operation is binary, then the first
 229 two arguments are the two arguments of the operation.  However, due to
 230 general object calling conventions, the first argument should always be
 231 an object in the package, so in the situation of C<7+$a>, the
 232 order of the arguments is interchanged.  It probably does not matter
 233 when implementing the addition method, but whether the arguments
 234 are reversed is vital to the subtraction method.  The method can
 235 query this information by examining the third argument, which can take
 236 three different values:
 237
 238 =over 7
 239
 240 =item FALSE
 241
 242 the order of arguments is as in the current operation.
 243
 244 =item TRUE
 245
 246 the arguments are reversed.
 247
 248 =item C<undef>
 249
 250 the current operation is an assignment variant (as in
 251 C<$a+=7>), but the usual function is called instead.  This additional
 252 information can be used to generate some optimizations.  Compare
 253 L<Calling Conventions for Mutators>.
 254
 255 =back
 256
 257 =head2 Calling Conventions for Unary Operations
 258
 259 Unary operation are considered binary operations with the second
 260 argument being C<undef>.  Thus the functions that overloads C<{"++"}>
 261 is called with arguments C<($a,undef,'')> when $a++ is executed.
 262
 263 =head2 Calling Conventions for Mutators
 264
 265 Two types of mutators have different calling conventions:
 266
 267 =over
 268
 269 =item C<++> and C<-->
 270
 271 The routines which implement these operators are expected to actually
 272 I<mutate> their arguments.  So, assuming that $obj is a reference to a
 273 number,
 274
 275   sub incr { my $n = $ {$_[0]}; ++$n; $_[0] = bless \$n}
 276
 277 is an appropriate implementation of overloaded C<++>.  Note that
 278
 279   sub incr { ++$ {$_[0]} ; shift }
 280
 281 is OK if used with preincrement and with postincrement. (In the case
 282 of postincrement a copying will be performed, see L<Copy Constructor>.)
 283
 284 =item C<x=> and other assignment versions
 285
 286 There is nothing special about these methods.  They may change the
 287 value of their arguments, and may leave it as is.  The result is going
 288 to be assigned to the value in the left-hand-side if different from
 289 this value.
 290
 291 This allows for the same method to be used as overloaded C<+=> and
 292 C<+>.  Note that this is I<allowed>, but not recommended, since by the
 293 semantic of L<"Fallback"> Perl will call the method for C<+> anyway,
 294 if C<+=> is not overloaded.
 295
 296 =back
 297
 298 B<Warning.>  Due to the presence of assignment versions of operations,
 299 routines which may be called in assignment context may create
 300 self-referential structures.  Currently Perl will not free self-referential
 301 structures until cycles are C<explicitly> broken.  You may get problems
 302 when traversing your structures too.
 303
 304 Say,
 305
 306   use overload '+' => sub { bless [ \$_[0], \$_[1] ] };
 307
 308 is asking for trouble, since for code C<$obj += $foo> the subroutine
 309 is called as C<$obj = add($obj, $foo, undef)>, or C<$obj = [\$obj,
 310 \$foo]>.  If using such a subroutine is an important optimization, one
 311 can overload C<+=> explicitly by a non-"optimized" version, or switch
 312 to non-optimized version if C<not defined $_[2]> (see
 313 L<Calling Conventions for Binary Operations>).
 314
 315 Even if no I<explicit> assignment-variants of operators are present in
 316 the script, they may be generated by the optimizer.  Say, C<",$obj,"> or
 317 C<',' . $obj . ','> may be both optimized to
 318
 319   my $tmp = ',' . $obj;    $tmp .= ',';
 320
 321 =head2 Overloadable Operations
 322
 323 The following symbols can be specified in C<use overload> directive:
 324
 325 =over 5
 326
 327 =item * I<Arithmetic operations>
 328
 329     "+", "+=", "-", "-=", "*", "*=", "/", "/=", "%", "%=",
 330     "**", "**=", "<<", "<<=", ">>", ">>=", "x", "x=", ".", ".=",
 331
 332 For these operations a substituted non-assignment variant can be called if
 333 the assignment variant is not available.  Methods for operations C<+>,
 334 C<->, C<+=>, and C<-=> can be called to automatically generate
 335 increment and decrement methods.  The operation C<-> can be used to
 336 autogenerate missing methods for unary minus or C<abs>.
 337
 338 See L<"MAGIC AUTOGENERATION">, L<"Calling Conventions for Mutators"> and
 339 L<"Calling Conventions for Binary Operations">) for details of these
 340 substitutions.
 341
 342 =item * I<Comparison operations>
 343
 344     "<",  "<=", ">",  ">=", "==", "!=", "<=>",
 345     "lt", "le", "gt", "ge", "eq", "ne", "cmp",
 346
 347 If the corresponding "spaceship" variant is available, it can be
 348 used to substitute for the missing operation.  During C<sort>ing
 349 arrays, C<cmp> is used to compare values subject to C<use overload>.
 350
 351 =item * I<Bit operations>
 352
 353     "&", "^", "|", "neg", "!", "~",
 354
 355 C<neg> stands for unary minus.  If the method for C<neg> is not
 356 specified, it can be autogenerated using the method for
 357 subtraction. If the method for C<!> is not specified, it can be
 358 autogenerated using the methods for C<bool>, or C<"">, or C<0+>.
 359
 360 =item * I<Increment and decrement>
 361
 362     "++", "--",
 363
 364 If undefined, addition and subtraction methods can be
 365 used instead.  These operations are called both in prefix and
 366 postfix form.
 367
 368 =item * I<Transcendental functions>
 369
 370     "atan2", "cos", "sin", "exp", "abs", "log", "sqrt", "int"
 371
 372 If C<abs> is unavailable, it can be autogenerated using methods
 373 for "E<lt>" or "E<lt>=E<gt>" combined with either unary minus or subtraction.
 374
 375 Note that traditionally the Perl function L<int> rounds to 0, thus for
 376 floating-point-like types one should follow the same semantic.  If
 377 C<int> is unavailable, it can be autogenerated using the overloading of
 378 C<0+>.
 379
 380 =item * I<Boolean, string and numeric conversion>
 381
 382     'bool', '""', '0+',
 383
 384 If one or two of these operations are not overloaded, the remaining ones can
 385 be used instead.  C<bool> is used in the flow control operators
 386 (like C<while>) and for the ternary C<?:> operation.  These functions can
 387 return any arbitrary Perl value.  If the corresponding operation for this value
 388 is overloaded too, that operation will be called again with this value.
 389
 390 As a special case if the overload returns the object itself then it will
 391 be used directly. An overloaded conversion returning the object is
 392 probably a bug, because you're likely to get something that looks like
 393 C<YourPackage=HASH(0x8172b34)>.
 394
 395 =item * I<Iteration>
 396
 397     "<>"
 398
 399 If not overloaded, the argument will be converted to a filehandle or
 400 glob (which may require a stringification).  The same overloading
 401 happens both for the I<read-filehandle> syntax C<E<lt>$varE<gt>> and
 402 I<globbing> syntax C<E<lt>${var}E<gt>>.
 403
 404 B<BUGS> Even in list context, the iterator is currently called only
 405 once and with scalar context.
 406
 407 =item * I<Dereferencing>
 408
 409     '${}', '@{}', '%{}', '&{}', '*{}'.
 410
 411 If not overloaded, the argument will be dereferenced I<as is>, thus
 412 should be of correct type.  These functions should return a reference
 413 of correct type, or another object with overloaded dereferencing.
 414
 415 As a special case if the overload returns the object itself then it
 416 will be used directly (provided it is the correct type).
 417
 418 The dereference operators must be specified explicitly they will not be passed to
 419 "nomethod".
 420
 421 =item * I<Special>
 422
 423     "nomethod", "fallback", "=", "~~",
 424
 425 see L<SPECIAL SYMBOLS FOR C<use overload>>.
 426
 427 =back
 428
 429 See L<"Fallback"> for an explanation of when a missing method can be
 430 autogenerated.
 431
 432 A computer-readable form of the above table is available in the hash
 433 %overload::ops, with values being space-separated lists of names:
 434
 435  with_assign      => '+ - * / % ** << >> x .',
 436  assign           => '+= -= *= /= %= **= <<= >>= x= .=',
 437  num_comparison   => '< <= > >= == !=',
 438  '3way_comparison'=> '<=> cmp',
 439  str_comparison   => 'lt le gt ge eq ne',
 440  binary           => '& | ^',
 441  unary            => 'neg ! ~',
 442  mutators         => '++ --',
 443  func             => 'atan2 cos sin exp abs log sqrt',
 444  conversion       => 'bool "" 0+',
 445  iterators        => '<>',
 446  dereferencing    => '${} @{} %{} &{} *{}',
 447  special          => 'nomethod fallback ='
 448
 449 =head2 Inheritance and overloading
 450
 451 Inheritance interacts with overloading in two ways.
 452
 453 =over
 454
 455 =item Strings as values of C<use overload> directive
 456
 457 If C<value> in
 458
 459   use overload key => value;
 460
 461 is a string, it is interpreted as a method name.
 462
 463 =item Overloading of an operation is inherited by derived classes
 464
 465 Any class derived from an overloaded class is also overloaded.  The
 466 set of overloaded methods is the union of overloaded methods of all
 467 the ancestors. If some method is overloaded in several ancestor, then
 468 which description will be used is decided by the usual inheritance
 469 rules:
 470
 471 If C<A> inherits from C<B> and C<C> (in this order), C<B> overloads
 472 C<+> with C<\&D::plus_sub>, and C<C> overloads C<+> by C<"plus_meth">,
 473 then the subroutine C<D::plus_sub> will be called to implement
 474 operation C<+> for an object in package C<A>.
 475
 476 =back
 477
 478 Note that since the value of the C<fallback> key is not a subroutine,
 479 its inheritance is not governed by the above rules.  In the current
 480 implementation, the value of C<fallback> in the first overloaded
 481 ancestor is used, but this is accidental and subject to change.
 482
 483 =head1 SPECIAL SYMBOLS FOR C<use overload>
 484
 485 Three keys are recognized by Perl that are not covered by the above
 486 description.
 487
 488 =head2 Last Resort
 489
 490 C<"nomethod"> should be followed by a reference to a function of four
 491 parameters.  If defined, it is called when the overloading mechanism
 492 cannot find a method for some operation.  The first three arguments of
 493 this function coincide with the arguments for the corresponding method if
 494 it were found, the fourth argument is the symbol
 495 corresponding to the missing method.  If several methods are tried,
 496 the last one is used.  Say, C<1-$a> can be equivalent to
 497
 498         &nomethodMethod($a,1,1,"-")
 499
 500 if the pair C<"nomethod" =E<gt> "nomethodMethod"> was specified in the
 501 C<use overload> directive.
 502
 503 The C<"nomethod"> mechanism is I<not> used for the dereference operators
 504 ( ${} @{} %{} &{} *{} ).
 505
 506
 507 If some operation cannot be resolved, and there is no function
 508 assigned to C<"nomethod">, then an exception will be raised via die()--
 509 unless C<"fallback"> was specified as a key in C<use overload> directive.
 510
 511
 512 =head2 Fallback
 513
 514 The key C<"fallback"> governs what to do if a method for a particular
 515 operation is not found.  Three different cases are possible depending on
 516 the value of C<"fallback">:
 517
 518 =over 16
 519
 520 =item * C<undef>
 521
 522 Perl tries to use a
 523 substituted method (see L<MAGIC AUTOGENERATION>).  If this fails, it
 524 then tries to calls C<"nomethod"> value; if missing, an exception
 525 will be raised.
 526
 527 =item * TRUE
 528
 529 The same as for the C<undef> value, but no exception is raised.  Instead,
 530 it silently reverts to what it would have done were there no C<use overload>
 531 present.
 532
 533 =item * defined, but FALSE
 534
 535 No autogeneration is tried.  Perl tries to call
 536 C<"nomethod"> value, and if this is missing, raises an exception.
 537
 538 =back
 539
 540 B<Note.> C<"fallback"> inheritance via @ISA is not carved in stone
 541 yet, see L<"Inheritance and overloading">.
 542
 543 =head2 Smart Match
 544
 545 The key C<"~~"> allows you to override the smart matching used by
 546 the switch construct. See L<feature>.
 547
 548 =head2 Copy Constructor
 549
 550 The value for C<"="> is a reference to a function with three
 551 arguments, i.e., it looks like the other values in C<use
 552 overload>. However, it does not overload the Perl assignment
 553 operator. This would go against Camel hair.
 554
 555 This operation is called in the situations when a mutator is applied
 556 to a reference that shares its object with some other reference, such
 557 as
 558
 559         $a=$b;
 560         ++$a;
 561
 562 To make this change $a and not change $b, a copy of C<$$a> is made,
 563 and $a is assigned a reference to this new object.  This operation is
 564 done during execution of the C<++$a>, and not during the assignment,
 565 (so before the increment C<$$a> coincides with C<$$b>).  This is only
 566 done if C<++> is expressed via a method for C<'++'> or C<'+='> (or
 567 C<nomethod>).  Note that if this operation is expressed via C<'+'>
 568 a nonmutator, i.e., as in
 569
 570         $a=$b;
 571         $a=$a+1;
 572
 573 then C<$a> does not reference a new copy of C<$$a>, since $$a does not
 574 appear as lvalue when the above code is executed.
 575
 576 If the copy constructor is required during the execution of some mutator,
 577 but a method for C<'='> was not specified, it can be autogenerated as a
 578 string copy if the object is a plain scalar.
 579
 580 =over 5
 581
 582 =item B<Example>
 583
 584 The actually executed code for
 585
 586         $a=$b;
 587         Something else which does not modify $a or $b....
 588         ++$a;
 589
 590 may be
 591
 592         $a=$b;
 593         Something else which does not modify $a or $b....
 594         $a = $a->clone(undef,"");
 595         $a->incr(undef,"");
 596
 597 if $b was mathemagical, and C<'++'> was overloaded with C<\&incr>,
 598 C<'='> was overloaded with C<\&clone>.
 599
 600 =back
 601
 602 Same behaviour is triggered by C<$b = $a++>, which is consider a synonym for
 603 C<$b = $a; ++$a>.
 604
 605 =head1 MAGIC AUTOGENERATION
 606
 607 If a method for an operation is not found, and the value for  C<"fallback"> is
 608 TRUE or undefined, Perl tries to autogenerate a substitute method for
 609 the missing operation based on the defined operations.  Autogenerated method
 610 substitutions are possible for the following operations:
 611
 612 =over 16
 613
 614 =item I<Assignment forms of arithmetic operations>
 615
 616 C<$a+=$b> can use the method for C<"+"> if the method for C<"+=">
 617 is not defined.
 618
 619 =item I<Conversion operations>
 620
 621 String, numeric, and boolean conversion are calculated in terms of one
 622 another if not all of them are defined.
 623
 624 =item I<Increment and decrement>
 625
 626 The C<++$a> operation can be expressed in terms of C<$a+=1> or C<$a+1>,
 627 and C<$a--> in terms of C<$a-=1> and C<$a-1>.
 628
 629 =item C<abs($a)>
 630
 631 can be expressed in terms of C<$aE<lt>0> and C<-$a> (or C<0-$a>).
 632
 633 =item I<Unary minus>
 634
 635 can be expressed in terms of subtraction.
 636
 637 =item I<Negation>
 638
 639 C<!> and C<not> can be expressed in terms of boolean conversion, or
 640 string or numerical conversion.
 641
 642 =item I<Concatenation>
 643
 644 can be expressed in terms of string conversion.
 645
 646 =item I<Comparison operations>
 647
 648 can be expressed in terms of its "spaceship" counterpart: either
 649 C<E<lt>=E<gt>> or C<cmp>:
 650
 651     <, >, <=, >=, ==, !=        in terms of <=>
 652     lt, gt, le, ge, eq, ne      in terms of cmp
 653
 654 =item I<Iterator>
 655
 656     <>                          in terms of builtin operations
 657
 658 =item I<Dereferencing>
 659
 660     ${} @{} %{} &{} *{}         in terms of builtin operations
 661
 662 =item I<Copy operator>
 663
 664 can be expressed in terms of an assignment to the dereferenced value, if this
 665 value is a scalar and not a reference.
 666
 667 =back
 668
 669 =head1 Minimal set of overloaded operations
 670
 671 Since some operations can be automatically generated from others, there is
 672 a minimal set of operations that need to be overloaded in order to have
 673 the complete set of overloaded operations at one's disposal.
 674 Of course, the autogenerated operations may not do exactly what the user
 675 expects. See L<MAGIC AUTOGENERATION> above. The minimal set is:
 676
 677     + - * / % ** << >> x
 678     <=> cmp
 679     & | ^ ~
 680     atan2 cos sin exp log sqrt int
 681
 682 Additionally, you need to define at least one of string, boolean or
 683 numeric conversions because any one can be used to emulate the others.
 684 The string conversion can also be used to emulate concatenation.
 685
 686 =head1 Losing overloading
 687
 688 The restriction for the comparison operation is that even if, for example,
 689 `C<cmp>' should return a blessed reference, the autogenerated `C<lt>'
 690 function will produce only a standard logical value based on the
 691 numerical value of the result of `C<cmp>'.  In particular, a working
 692 numeric conversion is needed in this case (possibly expressed in terms of
 693 other conversions).
 694
 695 Similarly, C<.=>  and C<x=> operators lose their mathemagical properties
 696 if the string conversion substitution is applied.
 697
 698 When you chop() a mathemagical object it is promoted to a string and its
 699 mathemagical properties are lost.  The same can happen with other
 700 operations as well.
 701
 702 =head1 Run-time Overloading
 703
 704 Since all C<use> directives are executed at compile-time, the only way to
 705 change overloading during run-time is to
 706
 707     eval 'use overload "+" => \&addmethod';
 708
 709 You can also use
 710
 711     eval 'no overload "+", "--", "<="';
 712
 713 though the use of these constructs during run-time is questionable.
 714
 715 =head1 Public functions
 716
 717 Package C<overload.pm> provides the following public functions:
 718
 719 =over 5
 720
 721 =item overload::StrVal(arg)
 722
 723 Gives string value of C<arg> as in absence of stringify overloading. If you
 724 are using this to get the address of a reference (useful for checking if two
 725 references point to the same thing) then you may be better off using
 726 C<Scalar::Util::refaddr()>, which is faster.
 727
 728 =item overload::Overloaded(arg)
 729
 730 Returns true if C<arg> is subject to overloading of some operations.
 731
 732 =item overload::Method(obj,op)
 733
 734 Returns C<undef> or a reference to the method that implements C<op>.
 735
 736 =back
 737
 738 =head1 Overloading constants
 739
 740 For some applications, the Perl parser mangles constants too much.
 741 It is possible to hook into this process via C<overload::constant()>
 742 and C<overload::remove_constant()> functions.
 743
 744 These functions take a hash as an argument.  The recognized keys of this hash
 745 are:
 746
 747 =over 8
 748
 749 =item integer
 750
 751 to overload integer constants,
 752
 753 =item float
 754
 755 to overload floating point constants,
 756
 757 =item binary
 758
 759 to overload octal and hexadecimal constants,
 760
 761 =item q
 762
 763 to overload C<q>-quoted strings, constant pieces of C<qq>- and C<qx>-quoted
 764 strings and here-documents,
 765
 766 =item qr
 767
 768 to overload constant pieces of regular expressions.
 769
 770 =back
 771
 772 The corresponding values are references to functions which take three arguments:
 773 the first one is the I<initial> string form of the constant, the second one
 774 is how Perl interprets this constant, the third one is how the constant is used.
 775 Note that the initial string form does not
 776 contain string delimiters, and has backslashes in backslash-delimiter
 777 combinations stripped (thus the value of delimiter is not relevant for
 778 processing of this string).  The return value of this function is how this
 779 constant is going to be interpreted by Perl.  The third argument is undefined
 780 unless for overloaded C<q>- and C<qr>- constants, it is C<q> in single-quote
 781 context (comes from strings, regular expressions, and single-quote HERE
 782 documents), it is C<tr> for arguments of C<tr>/C<y> operators,
 783 it is C<s> for right-hand side of C<s>-operator, and it is C<qq> otherwise.
 784
 785 Since an expression C<"ab$cd,,"> is just a shortcut for C<'ab' . $cd . ',,'>,
 786 it is expected that overloaded constant strings are equipped with reasonable
 787 overloaded catenation operator, otherwise absurd results will result.
 788 Similarly, negative numbers are considered as negations of positive constants.
 789
 790 Note that it is probably meaningless to call the functions overload::constant()
 791 and overload::remove_constant() from anywhere but import() and unimport() methods.
 792 From these methods they may be called as
 793
 794         sub import {
 795           shift;
 796           return unless @_;
 797           die "unknown import: @_" unless @_ == 1 and $_[0] eq ':constant';
 798           overload::constant integer => sub {Math::BigInt->new(shift)};
 799         }
 800
 801 =head1 IMPLEMENTATION
 802
 803 What follows is subject to change RSN.
 804
 805 The table of methods for all operations is cached in magic for the
 806 symbol table hash for the package.  The cache is invalidated during
 807 processing of C<use overload>, C<no overload>, new function
 808 definitions, and changes in @ISA. However, this invalidation remains
 809 unprocessed until the next C<bless>ing into the package. Hence if you
 810 want to change overloading structure dynamically, you'll need an
 811 additional (fake) C<bless>ing to update the table.
 812
 813 (Every SVish thing has a magic queue, and magic is an entry in that
 814 queue.  This is how a single variable may participate in multiple
 815 forms of magic simultaneously.  For instance, environment variables
 816 regularly have two forms at once: their %ENV magic and their taint
 817 magic. However, the magic which implements overloading is applied to
 818 the stashes, which are rarely used directly, thus should not slow down
 819 Perl.)
 820
 821 If an object belongs to a package using overload, it carries a special
 822 flag.  Thus the only speed penalty during arithmetic operations without
 823 overloading is the checking of this flag.
 824
 825 In fact, if C<use overload> is not present, there is almost no overhead
 826 for overloadable operations, so most programs should not suffer
 827 measurable performance penalties.  A considerable effort was made to
 828 minimize the overhead when overload is used in some package, but the
 829 arguments in question do not belong to packages using overload.  When
 830 in doubt, test your speed with C<use overload> and without it.  So far
 831 there have been no reports of substantial speed degradation if Perl is
 832 compiled with optimization turned on.
 833
 834 There is no size penalty for data if overload is not used. The only
 835 size penalty if overload is used in some package is that I<all> the
 836 packages acquire a magic during the next C<bless>ing into the
 837 package. This magic is three-words-long for packages without
 838 overloading, and carries the cache table if the package is overloaded.
 839
 840 Copying (C<$a=$b>) is shallow; however, a one-level-deep copying is
 841 carried out before any operation that can imply an assignment to the
 842 object $a (or $b) refers to, like C<$a++>.  You can override this
 843 behavior by defining your own copy constructor (see L<"Copy Constructor">).
 844
 845 It is expected that arguments to methods that are not explicitly supposed
 846 to be changed are constant (but this is not enforced).
 847
 848 =head1 Metaphor clash
 849
 850 One may wonder why the semantic of overloaded C<=> is so counter intuitive.
 851 If it I<looks> counter intuitive to you, you are subject to a metaphor
 852 clash.
 853
 854 Here is a Perl object metaphor:
 855
 856 I<  object is a reference to blessed data>
 857
 858 and an arithmetic metaphor:
 859
 860 I<  object is a thing by itself>.
 861
 862 The I<main> problem of overloading C<=> is the fact that these metaphors
 863 imply different actions on the assignment C<$a = $b> if $a and $b are
 864 objects.  Perl-think implies that $a becomes a reference to whatever
 865 $b was referencing.  Arithmetic-think implies that the value of "object"
 866 $a is changed to become the value of the object $b, preserving the fact
 867 that $a and $b are separate entities.
 868
 869 The difference is not relevant in the absence of mutators.  After
 870 a Perl-way assignment an operation which mutates the data referenced by $a
 871 would change the data referenced by $b too.  Effectively, after
 872 C<$a = $b> values of $a and $b become I<indistinguishable>.
 873
 874 On the other hand, anyone who has used algebraic notation knows the
 875 expressive power of the arithmetic metaphor.  Overloading works hard
 876 to enable this metaphor while preserving the Perlian way as far as
 877 possible.  Since it is not possible to freely mix two contradicting
 878 metaphors, overloading allows the arithmetic way to write things I<as
 879 far as all the mutators are called via overloaded access only>.  The
 880 way it is done is described in L<Copy Constructor>.
 881
 882 If some mutator methods are directly applied to the overloaded values,
 883 one may need to I<explicitly unlink> other values which references the
 884 same value:
 885
 886     $a = new Data 23;
 887     ...
 888     $b = $a;            # $b is "linked" to $a
 889     ...
 890     $a = $a->clone;     # Unlink $b from $a
 891     $a->increment_by(4);
 892
 893 Note that overloaded access makes this transparent:
 894
 895     $a = new Data 23;
 896     $b = $a;            # $b is "linked" to $a
 897     $a += 4;            # would unlink $b automagically
 898
 899 However, it would not make
 900
 901     $a = new Data 23;
 902     $a = 4;             # Now $a is a plain 4, not 'Data'
 903
 904 preserve "objectness" of $a.  But Perl I<has> a way to make assignments
 905 to an object do whatever you want.  It is just not the overload, but
 906 tie()ing interface (see L<perlfunc/tie>).  Adding a FETCH() method
 907 which returns the object itself, and STORE() method which changes the
 908 value of the object, one can reproduce the arithmetic metaphor in its
 909 completeness, at least for variables which were tie()d from the start.
 910
 911 (Note that a workaround for a bug may be needed, see L<"BUGS">.)
 912
 913 =head1 Cookbook
 914
 915 Please add examples to what follows!
 916
 917 =head2 Two-face scalars
 918
 919 Put this in F<two_face.pm> in your Perl library directory:
 920
 921   package two_face;             # Scalars with separate string and
 922                                 # numeric values.
 923   sub new { my $p = shift; bless [@_], $p }
 924   use overload '""' => \&str, '0+' => \&num, fallback => 1;
 925   sub num {shift->[1]}
 926   sub str {shift->[0]}
 927
 928 Use it as follows:
 929
 930   require two_face;
 931   my $seven = new two_face ("vii", 7);
 932   printf "seven=$seven, seven=%d, eight=%d\n", $seven, $seven+1;
 933   print "seven contains `i'\n" if $seven =~ /i/;
 934
 935 (The second line creates a scalar which has both a string value, and a
 936 numeric value.)  This prints:
 937
 938   seven=vii, seven=7, eight=8
 939   seven contains `i'
 940
 941 =head2 Two-face references
 942
 943 Suppose you want to create an object which is accessible as both an
 944 array reference and a hash reference.
 945
 946   package two_refs;
 947   use overload '%{}' => \&gethash, '@{}' => sub { $ {shift()} };
 948   sub new {
 949     my $p = shift;
 950     bless \ [@_], $p;
 951   }
 952   sub gethash {
 953     my %h;
 954     my $self = shift;
 955     tie %h, ref $self, $self;
 956     \%h;
 957   }
 958
 959   sub TIEHASH { my $p = shift; bless \ shift, $p }
 960   my %fields;
 961   my $i = 0;
 962   $fields{$_} = $i++ foreach qw{zero one two three};
 963   sub STORE {
 964     my $self = ${shift()};
 965     my $key = $fields{shift()};
 966     defined $key or die "Out of band access";
 967     $$self->[$key] = shift;
 968   }
 969   sub FETCH {
 970     my $self = ${shift()};
 971     my $key = $fields{shift()};
 972     defined $key or die "Out of band access";
 973     $$self->[$key];
 974   }
 975
 976 Now one can access an object using both the array and hash syntax:
 977
 978   my $bar = new two_refs 3,4,5,6;
 979   $bar->[2] = 11;
 980   $bar->{two} == 11 or die 'bad hash fetch';
 981
 982 Note several important features of this example.  First of all, the
 983 I<actual> type of $bar is a scalar reference, and we do not overload
 984 the scalar dereference.  Thus we can get the I<actual> non-overloaded
 985 contents of $bar by just using C<$$bar> (what we do in functions which
 986 overload dereference).  Similarly, the object returned by the
 987 TIEHASH() method is a scalar reference.
 988
 989 Second, we create a new tied hash each time the hash syntax is used.
 990 This allows us not to worry about a possibility of a reference loop,
 991 which would lead to a memory leak.
 992
 993 Both these problems can be cured.  Say, if we want to overload hash
 994 dereference on a reference to an object which is I<implemented> as a
 995 hash itself, the only problem one has to circumvent is how to access
 996 this I<actual> hash (as opposed to the I<virtual> hash exhibited by the
 997 overloaded dereference operator).  Here is one possible fetching routine:
 998
 999   sub access_hash {
1000     my ($self, $key) = (shift, shift);
1001     my $class = ref $self;
1002     bless $self, 'overload::dummy'; # Disable overloading of %{}
1003     my $out = $self->{$key};
1004     bless $self, $class;        # Restore overloading
1005     $out;
1006   }
1007
1008 To remove creation of the tied hash on each access, one may an extra
1009 level of indirection which allows a non-circular structure of references:
1010
1011   package two_refs1;
1012   use overload '%{}' => sub { ${shift()}->[1] },
1013                '@{}' => sub { ${shift()}->[0] };
1014   sub new {
1015     my $p = shift;
1016     my $a = [@_];
1017     my %h;
1018     tie %h, $p, $a;
1019     bless \ [$a, \%h], $p;
1020   }
1021   sub gethash {
1022     my %h;
1023     my $self = shift;
1024     tie %h, ref $self, $self;
1025     \%h;
1026   }
1027
1028   sub TIEHASH { my $p = shift; bless \ shift, $p }
1029   my %fields;
1030   my $i = 0;
1031   $fields{$_} = $i++ foreach qw{zero one two three};
1032   sub STORE {
1033     my $a = ${shift()};
1034     my $key = $fields{shift()};
1035     defined $key or die "Out of band access";
1036     $a->[$key] = shift;
1037   }
1038   sub FETCH {
1039     my $a = ${shift()};
1040     my $key = $fields{shift()};
1041     defined $key or die "Out of band access";
1042     $a->[$key];
1043   }
1044
1045 Now if $baz is overloaded like this, then C<$baz> is a reference to a
1046 reference to the intermediate array, which keeps a reference to an
1047 actual array, and the access hash.  The tie()ing object for the access
1048 hash is a reference to a reference to the actual array, so
1049
1050 =over
1051
1052 =item *
1053
1054 There are no loops of references.
1055
1056 =item *
1057
1058 Both "objects" which are blessed into the class C<two_refs1> are
1059 references to a reference to an array, thus references to a I<scalar>.
1060 Thus the accessor expression C<$$foo-E<gt>[$ind]> involves no
1061 overloaded operations.
1062
1063 =back
1064
1065 =head2 Symbolic calculator
1066
1067 Put this in F<symbolic.pm> in your Perl library directory:
1068
1069   package symbolic;             # Primitive symbolic calculator
1070   use overload nomethod => \&wrap;
1071
1072   sub new { shift; bless ['n', @_] }
1073   sub wrap {
1074     my ($obj, $other, $inv, $meth) = @_;
1075     ($obj, $other) = ($other, $obj) if $inv;
1076     bless [$meth, $obj, $other];
1077   }
1078
1079 This module is very unusual as overloaded modules go: it does not
1080 provide any usual overloaded operators, instead it provides the L<Last
1081 Resort> operator C<nomethod>.  In this example the corresponding
1082 subroutine returns an object which encapsulates operations done over
1083 the objects: C<new symbolic 3> contains C<['n', 3]>, C<2 + new
1084 symbolic 3> contains C<['+', 2, ['n', 3]]>.
1085
1086 Here is an example of the script which "calculates" the side of
1087 circumscribed octagon using the above package:
1088
1089   require symbolic;
1090   my $iter = 1;                 # 2**($iter+2) = 8
1091   my $side = new symbolic 1;
1092   my $cnt = $iter;
1093
1094   while ($cnt--) {
1095     $side = (sqrt(1 + $side**2) - 1)/$side;
1096   }
1097   print "OK\n";
1098
1099 The value of $side is
1100
1101   ['/', ['-', ['sqrt', ['+', 1, ['**', ['n', 1], 2]],
1102                        undef], 1], ['n', 1]]
1103
1104 Note that while we obtained this value using a nice little script,
1105 there is no simple way to I<use> this value.  In fact this value may
1106 be inspected in debugger (see L<perldebug>), but only if
1107 C<bareStringify> B<O>ption is set, and not via C<p> command.
1108
1109 If one attempts to print this value, then the overloaded operator
1110 C<""> will be called, which will call C<nomethod> operator.  The
1111 result of this operator will be stringified again, but this result is
1112 again of type C<symbolic>, which will lead to an infinite loop.
1113
1114 Add a pretty-printer method to the module F<symbolic.pm>:
1115
1116   sub pretty {
1117     my ($meth, $a, $b) = @{+shift};
1118     $a = 'u' unless defined $a;
1119     $b = 'u' unless defined $b;
1120     $a = $a->pretty if ref $a;
1121     $b = $b->pretty if ref $b;
1122     "[$meth $a $b]";
1123   }
1124
1125 Now one can finish the script by
1126
1127   print "side = ", $side->pretty, "\n";
1128
1129 The method C<pretty> is doing object-to-string conversion, so it
1130 is natural to overload the operator C<""> using this method.  However,
1131 inside such a method it is not necessary to pretty-print the
1132 I<components> $a and $b of an object.  In the above subroutine
1133 C<"[$meth $a $b]"> is a catenation of some strings and components $a
1134 and $b.  If these components use overloading, the catenation operator
1135 will look for an overloaded operator C<.>; if not present, it will
1136 look for an overloaded operator C<"">.  Thus it is enough to use
1137
1138   use overload nomethod => \&wrap, '""' => \&str;
1139   sub str {
1140     my ($meth, $a, $b) = @{+shift};
1141     $a = 'u' unless defined $a;
1142     $b = 'u' unless defined $b;
1143     "[$meth $a $b]";
1144   }
1145
1146 Now one can change the last line of the script to
1147
1148   print "side = $side\n";
1149
1150 which outputs
1151
1152   side = [/ [- [sqrt [+ 1 [** [n 1 u] 2]] u] 1] [n 1 u]]
1153
1154 and one can inspect the value in debugger using all the possible
1155 methods.
1156
1157 Something is still amiss: consider the loop variable $cnt of the
1158 script.  It was a number, not an object.  We cannot make this value of
1159 type C<symbolic>, since then the loop will not terminate.
1160
1161 Indeed, to terminate the cycle, the $cnt should become false.
1162 However, the operator C<bool> for checking falsity is overloaded (this
1163 time via overloaded C<"">), and returns a long string, thus any object
1164 of type C<symbolic> is true.  To overcome this, we need a way to
1165 compare an object to 0.  In fact, it is easier to write a numeric
1166 conversion routine.
1167
1168 Here is the text of F<symbolic.pm> with such a routine added (and
1169 slightly modified str()):
1170
1171   package symbolic;             # Primitive symbolic calculator
1172   use overload
1173     nomethod => \&wrap, '""' => \&str, '0+' => \&num;
1174
1175   sub new { shift; bless ['n', @_] }
1176   sub wrap {
1177     my ($obj, $other, $inv, $meth) = @_;
1178     ($obj, $other) = ($other, $obj) if $inv;
1179     bless [$meth, $obj, $other];
1180   }
1181   sub str {
1182     my ($meth, $a, $b) = @{+shift};
1183     $a = 'u' unless defined $a;
1184     if (defined $b) {
1185       "[$meth $a $b]";
1186     } else {
1187       "[$meth $a]";
1188     }
1189   }
1190   my %subr = ( n => sub {$_[0]},
1191                sqrt => sub {sqrt $_[0]},
1192                '-' => sub {shift() - shift()},
1193                '+' => sub {shift() + shift()},
1194                '/' => sub {shift() / shift()},
1195                '*' => sub {shift() * shift()},
1196                '**' => sub {shift() ** shift()},
1197              );
1198   sub num {
1199     my ($meth, $a, $b) = @{+shift};
1200     my $subr = $subr{$meth}
1201       or die "Do not know how to ($meth) in symbolic";
1202     $a = $a->num if ref $a eq __PACKAGE__;
1203     $b = $b->num if ref $b eq __PACKAGE__;
1204     $subr->($a,$b);
1205   }
1206
1207 All the work of numeric conversion is done in %subr and num().  Of
1208 course, %subr is not complete, it contains only operators used in the
1209 example below.  Here is the extra-credit question: why do we need an
1210 explicit recursion in num()?  (Answer is at the end of this section.)
1211
1212 Use this module like this:
1213
1214   require symbolic;
1215   my $iter = new symbolic 2;    # 16-gon
1216   my $side = new symbolic 1;
1217   my $cnt = $iter;
1218
1219   while ($cnt) {
1220     $cnt = $cnt - 1;            # Mutator `--' not implemented
1221     $side = (sqrt(1 + $side**2) - 1)/$side;
1222   }
1223   printf "%s=%f\n", $side, $side;
1224   printf "pi=%f\n", $side*(2**($iter+2));
1225
1226 It prints (without so many line breaks)
1227
1228   [/ [- [sqrt [+ 1 [** [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1]
1229                           [n 1]] 2]]] 1]
1230      [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1] [n 1]]]=0.198912
1231   pi=3.182598
1232
1233 The above module is very primitive.  It does not implement
1234 mutator methods (C<++>, C<-=> and so on), does not do deep copying
1235 (not required without mutators!), and implements only those arithmetic
1236 operations which are used in the example.
1237
1238 To implement most arithmetic operations is easy; one should just use
1239 the tables of operations, and change the code which fills %subr to
1240
1241   my %subr = ( 'n' => sub {$_[0]} );
1242   foreach my $op (split " ", $overload::ops{with_assign}) {
1243     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1244   }
1245   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1246   foreach my $op (split " ", "@overload::ops{ @bins }") {
1247     $subr{$op} = eval "sub {shift() $op shift()}";
1248   }
1249   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1250     print "defining `$op'\n";
1251     $subr{$op} = eval "sub {$op shift()}";
1252   }
1253
1254 Due to L<Calling Conventions for Mutators>, we do not need anything
1255 special to make C<+=> and friends work, except filling C<+=> entry of
1256 %subr, and defining a copy constructor (needed since Perl has no
1257 way to know that the implementation of C<'+='> does not mutate
1258 the argument, compare L<Copy Constructor>).
1259
1260 To implement a copy constructor, add C<< '=' => \&cpy >> to C<use overload>
1261 line, and code (this code assumes that mutators change things one level
1262 deep only, so recursive copying is not needed):
1263
1264   sub cpy {
1265     my $self = shift;
1266     bless [@$self], ref $self;
1267   }
1268
1269 To make C<++> and C<--> work, we need to implement actual mutators,
1270 either directly, or in C<nomethod>.  We continue to do things inside
1271 C<nomethod>, thus add
1272
1273     if ($meth eq '++' or $meth eq '--') {
1274       @$obj = ($meth, (bless [@$obj]), 1); # Avoid circular reference
1275       return $obj;
1276     }
1277
1278 after the first line of wrap().  This is not a most effective
1279 implementation, one may consider
1280
1281   sub inc { $_[0] = bless ['++', shift, 1]; }
1282
1283 instead.
1284
1285 As a final remark, note that one can fill %subr by
1286
1287   my %subr = ( 'n' => sub {$_[0]} );
1288   foreach my $op (split " ", $overload::ops{with_assign}) {
1289     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1290   }
1291   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1292   foreach my $op (split " ", "@overload::ops{ @bins }") {
1293     $subr{$op} = eval "sub {shift() $op shift()}";
1294   }
1295   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1296     $subr{$op} = eval "sub {$op shift()}";
1297   }
1298   $subr{'++'} = $subr{'+'};
1299   $subr{'--'} = $subr{'-'};
1300
1301 This finishes implementation of a primitive symbolic calculator in
1302 50 lines of Perl code.  Since the numeric values of subexpressions
1303 are not cached, the calculator is very slow.
1304
1305 Here is the answer for the exercise: In the case of str(), we need no
1306 explicit recursion since the overloaded C<.>-operator will fall back
1307 to an existing overloaded operator C<"">.  Overloaded arithmetic
1308 operators I<do not> fall back to numeric conversion if C<fallback> is
1309 not explicitly requested.  Thus without an explicit recursion num()
1310 would convert C<['+', $a, $b]> to C<$a + $b>, which would just rebuild
1311 the argument of num().
1312
1313 If you wonder why defaults for conversion are different for str() and
1314 num(), note how easy it was to write the symbolic calculator.  This
1315 simplicity is due to an appropriate choice of defaults.  One extra
1316 note: due to the explicit recursion num() is more fragile than sym():
1317 we need to explicitly check for the type of $a and $b.  If components
1318 $a and $b happen to be of some related type, this may lead to problems.
1319
1320 =head2 I<Really> symbolic calculator
1321
1322 One may wonder why we call the above calculator symbolic.  The reason
1323 is that the actual calculation of the value of expression is postponed
1324 until the value is I<used>.
1325
1326 To see it in action, add a method
1327
1328   sub STORE {
1329     my $obj = shift;
1330     $#$obj = 1;
1331     @$obj->[0,1] = ('=', shift);
1332   }
1333
1334 to the package C<symbolic>.  After this change one can do
1335
1336   my $a = new symbolic 3;
1337   my $b = new symbolic 4;
1338   my $c = sqrt($a**2 + $b**2);
1339
1340 and the numeric value of $c becomes 5.  However, after calling
1341
1342   $a->STORE(12);  $b->STORE(5);
1343
1344 the numeric value of $c becomes 13.  There is no doubt now that the module
1345 symbolic provides a I<symbolic> calculator indeed.
1346
1347 To hide the rough edges under the hood, provide a tie()d interface to the
1348 package C<symbolic> (compare with L<Metaphor clash>).  Add methods
1349
1350   sub TIESCALAR { my $pack = shift; $pack->new(@_) }
1351   sub FETCH { shift }
1352   sub nop {  }          # Around a bug
1353
1354 (the bug is described in L<"BUGS">).  One can use this new interface as
1355
1356   tie $a, 'symbolic', 3;
1357   tie $b, 'symbolic', 4;
1358   $a->nop;  $b->nop;    # Around a bug
1359
1360   my $c = sqrt($a**2 + $b**2);
1361
1362 Now numeric value of $c is 5.  After C<$a = 12; $b = 5> the numeric value
1363 of $c becomes 13.  To insulate the user of the module add a method
1364
1365   sub vars { my $p = shift; tie($_, $p), $_->nop foreach @_; }
1366
1367 Now
1368
1369   my ($a, $b);
1370   symbolic->vars($a, $b);
1371   my $c = sqrt($a**2 + $b**2);
1372
1373   $a = 3; $b = 4;
1374   printf "c5  %s=%f\n", $c, $c;
1375
1376   $a = 12; $b = 5;
1377   printf "c13  %s=%f\n", $c, $c;
1378
1379 shows that the numeric value of $c follows changes to the values of $a
1380 and $b.
1381
1382 =head1 AUTHOR
1383
1384 Ilya Zakharevich E<lt>F<ilya@math.mps.ohio-state.edu>E<gt>.
1385
1386 =head1 DIAGNOSTICS
1387
1388 When Perl is run with the B<-Do> switch or its equivalent, overloading
1389 induces diagnostic messages.
1390
1391 Using the C<m> command of Perl debugger (see L<perldebug>) one can
1392 deduce which operations are overloaded (and which ancestor triggers
1393 this overloading). Say, if C<eq> is overloaded, then the method C<(eq>
1394 is shown by debugger. The method C<()> corresponds to the C<fallback>
1395 key (in fact a presence of this method shows that this package has
1396 overloading enabled, and it is what is used by the C<Overloaded>
1397 function of module C<overload>).
1398
1399 The module might issue the following warnings:
1400
1401 =over 4
1402
1403 =item Odd number of arguments for overload::constant
1404
1405 (W) The call to overload::constant contained an odd number of arguments.
1406 The arguments should come in pairs.
1407
1408 =item `%s' is not an overloadable type
1409
1410 (W) You tried to overload a constant type the overload package is unaware of.
1411
1412 =item `%s' is not a code reference
1413
1414 (W) The second (fourth, sixth, ...) argument of overload::constant needs
1415 to be a code reference. Either an anonymous subroutine, or a reference
1416 to a subroutine.
1417
1418 =back
1419
1420 =head1 BUGS
1421
1422 Because it is used for overloading, the per-package hash %OVERLOAD now
1423 has a special meaning in Perl. The symbol table is filled with names
1424 looking like line-noise.
1425
1426 For the purpose of inheritance every overloaded package behaves as if
1427 C<fallback> is present (possibly undefined). This may create
1428 interesting effects if some package is not overloaded, but inherits
1429 from two overloaded packages.
1430
1431 Relation between overloading and tie()ing is broken.  Overloading is
1432 triggered or not basing on the I<previous> class of tie()d value.
1433
1434 This happens because the presence of overloading is checked too early,
1435 before any tie()d access is attempted.  If the FETCH()ed class of the
1436 tie()d value does not change, a simple workaround is to access the value
1437 immediately after tie()ing, so that after this call the I<previous> class
1438 coincides with the current one.
1439
1440 B<Needed:> a way to fix this without a speed penalty.
1441
1442 Barewords are not covered by overloaded string constants.
1443
1444 This document is confusing.  There are grammos and misleading language
1445 used in places.  It would seem a total rewrite is needed.
1446
1447 =cut
1448