lib/constant.pm

   1 package constant;
   2
   3 use strict;
   4 use 5.006_00;
   5 use warnings::register;
   6
   7 our($VERSION, %declared);
   8 $VERSION = '1.07';
   9
  10 #=======================================================================
  11
  12 # Some names are evil choices.
  13 my %keywords = map +($_, 1), qw{ BEGIN INIT CHECK END DESTROY AUTOLOAD };
  14
  15 my %forced_into_main = map +($_, 1),
  16     qw{ STDIN STDOUT STDERR ARGV ARGVOUT ENV INC SIG };
  17
  18 my %forbidden = (%keywords, %forced_into_main);
  19
  20 #=======================================================================
  21 # import() - import symbols into user's namespace
  22 #
  23 # What we actually do is define a function in the caller's namespace
  24 # which returns the value. The function we create will normally
  25 # be inlined as a constant, thereby avoiding further sub calling
  26 # overhead.
  27 #=======================================================================
  28 sub import {
  29     my $class = shift;
  30     return unless @_;                   # Ignore 'use constant;'
  31     my $constants;
  32     my $multiple  = ref $_[0];
  33     my $pkg = caller;
  34     my $symtab;
  35
  36     if ($] > 5.009002) {
  37         no strict 'refs';
  38         $symtab = \%{$pkg . '::'};
  39     };
  40
  41     if ( $multiple ) {
  42         if (ref $_[0] ne 'HASH') {
  43             require Carp;
  44             Carp::croak("Invalid reference type '".ref(shift)."' not 'HASH'");
  45         }
  46         $constants = shift;
  47     } else {
  48         $constants->{+shift} = undef;
  49     }
  50
  51     foreach my $name ( keys %$constants ) {
  52         unless (defined $name) {
  53             require Carp;
  54             Carp::croak("Can't use undef as constant name");
  55         }
  56
  57         # Normal constant name
  58         if ($name =~ /^_?[^\W_0-9]\w*\z/ and !$forbidden{$name}) {
  59             # Everything is okay
  60
  61         # Name forced into main, but we're not in main. Fatal.
  62         } elsif ($forced_into_main{$name} and $pkg ne 'main') {
  63             require Carp;
  64             Carp::croak("Constant name '$name' is forced into main::");
  65
  66         # Starts with double underscore. Fatal.
  67         } elsif ($name =~ /^__/) {
  68             require Carp;
  69             Carp::croak("Constant name '$name' begins with '__'");
  70
  71         # Maybe the name is tolerable
  72         } elsif ($name =~ /^[A-Za-z_]\w*\z/) {
  73             # Then we'll warn only if you've asked for warnings
  74             if (warnings::enabled()) {
  75                 if ($keywords{$name}) {
  76                     warnings::warn("Constant name '$name' is a Perl keyword");
  77                 } elsif ($forced_into_main{$name}) {
  78                     warnings::warn("Constant name '$name' is " .
  79                         "forced into package main::");
  80                 }
  81             }
  82
  83         # Looks like a boolean
  84         # use constant FRED == fred;
  85         } elsif ($name =~ /^[01]?\z/) {
  86             require Carp;
  87             if (@_) {
  88                 Carp::croak("Constant name '$name' is invalid");
  89             } else {
  90                 Carp::croak("Constant name looks like boolean value");
  91             }
  92
  93         } else {
  94            # Must have bad characters
  95             require Carp;
  96             Carp::croak("Constant name '$name' has invalid characters");
  97         }
  98
  99         {
 100             no strict 'refs';
 101             my $full_name = "${pkg}::$name";
 102             $declared{$full_name}++;
 103             if ($multiple || @_ == 1) {
 104                 my $scalar = $multiple ? $constants->{$name} : $_[0];
 105                 if ($symtab && !exists $symtab->{$name}) {
 106                     # No typeglob yet, so we can use a reference as space-
 107                     # efficient proxy for a constant subroutine
 108                     # The check in Perl_ck_rvconst knows that inlinable
 109                     # constants from cv_const_sv are read only. So we have to:
 110                     Internals::SvREADONLY($scalar, 1);
 111                     $symtab->{$name} = \$scalar;
 112                     Internals::inc_sub_generation;
 113                 } else {
 114                     if(!exists $symtab->{$name}) {
 115                         print STDERR "$name $scalar\n";
 116                     }
 117                     *$full_name = sub () { $scalar };
 118                 }
 119             } elsif (@_) {
 120                 my @list = @_;
 121                 *$full_name = sub () { @list };
 122             } else {
 123                 *$full_name = sub () { };
 124             }
 125         }
 126     }
 127 }
 128
 129 1;
 130
 131 __END__
 132
 133 =head1 NAME
 134
 135 constant - Perl pragma to declare constants
 136
 137 =head1 SYNOPSIS
 138
 139     use constant PI    => 4 * atan2(1, 1);
 140     use constant DEBUG => 0;
 141
 142     print "Pi equals ", PI, "...\n" if DEBUG;
 143
 144     use constant {
 145         SEC   => 0,
 146         MIN   => 1,
 147         HOUR  => 2,
 148         MDAY  => 3,
 149         MON   => 4,
 150         YEAR  => 5,
 151         WDAY  => 6,
 152         YDAY  => 7,
 153         ISDST => 8,
 154     };
 155
 156     use constant WEEKDAYS => qw(
 157         Sunday Monday Tuesday Wednesday Thursday Friday Saturday
 158     );
 159
 160     print "Today is ", (WEEKDAYS)[ (localtime)[WDAY] ], ".\n";
 161
 162 =head1 DESCRIPTION
 163
 164 This will declare a symbol to be a constant with the given value.
 165
 166 When you declare a constant such as C<PI> using the method shown
 167 above, each machine your script runs upon can have as many digits
 168 of accuracy as it can use. Also, your program will be easier to
 169 read, more likely to be maintained (and maintained correctly), and
 170 far less likely to send a space probe to the wrong planet because
 171 nobody noticed the one equation in which you wrote C<3.14195>.
 172
 173 When a constant is used in an expression, perl replaces it with its
 174 value at compile time, and may then optimize the expression further.
 175 In particular, any code in an C<if (CONSTANT)> block will be optimized
 176 away if the constant is false.
 177
 178 =head1 NOTES
 179
 180 As with all C<use> directives, defining a constant happens at
 181 compile time. Thus, it's probably not correct to put a constant
 182 declaration inside of a conditional statement (like C<if ($foo)
 183 { use constant ... }>).
 184
 185 Constants defined using this module cannot be interpolated into
 186 strings like variables.  However, concatenation works just fine:
 187
 188     print "Pi equals PI...\n";        # WRONG: does not expand "PI"
 189     print "Pi equals ".PI."...\n";    # right
 190
 191 Even though a reference may be declared as a constant, the reference may
 192 point to data which may be changed, as this code shows.
 193
 194     use constant ARRAY => [ 1,2,3,4 ];
 195     print ARRAY->[1];
 196     ARRAY->[1] = " be changed";
 197     print ARRAY->[1];
 198
 199 Dereferencing constant references incorrectly (such as using an array
 200 subscript on a constant hash reference, or vice versa) will be trapped at
 201 compile time.
 202
 203 Constants belong to the package they are defined in.  To refer to a
 204 constant defined in another package, specify the full package name, as
 205 in C<Some::Package::CONSTANT>.  Constants may be exported by modules,
 206 and may also be called as either class or instance methods, that is,
 207 as C<< Some::Package->CONSTANT >> or as C<< $obj->CONSTANT >> where
 208 C<$obj> is an instance of C<Some::Package>.  Subclasses may define
 209 their own constants to override those in their base class.
 210
 211 The use of all caps for constant names is merely a convention,
 212 although it is recommended in order to make constants stand out
 213 and to help avoid collisions with other barewords, keywords, and
 214 subroutine names. Constant names must begin with a letter or
 215 underscore. Names beginning with a double underscore are reserved. Some
 216 poor choices for names will generate warnings, if warnings are enabled at
 217 compile time.
 218
 219 =head2 List constants
 220
 221 Constants may be lists of more (or less) than one value.  A constant
 222 with no values evaluates to C<undef> in scalar context.  Note that
 223 constants with more than one value do I<not> return their last value in
 224 scalar context as one might expect.  They currently return the number
 225 of values, but B<this may change in the future>.  Do not use constants
 226 with multiple values in scalar context.
 227
 228 B<NOTE:> This implies that the expression defining the value of a
 229 constant is evaluated in list context.  This may produce surprises:
 230
 231     use constant TIMESTAMP => localtime;                # WRONG!
 232     use constant TIMESTAMP => scalar localtime;         # right
 233
 234 The first line above defines C<TIMESTAMP> as a 9-element list, as
 235 returned by localtime() in list context.  To set it to the string
 236 returned by localtime() in scalar context, an explicit C<scalar>
 237 keyword is required.
 238
 239 List constants are lists, not arrays.  To index or slice them, they
 240 must be placed in parentheses.
 241
 242     my @workdays = WEEKDAYS[1 .. 5];            # WRONG!
 243     my @workdays = (WEEKDAYS)[1 .. 5];          # right
 244
 245 =head2 Defining multiple constants at once
 246
 247 Instead of writing multiple C<use constant> statements, you may define
 248 multiple constants in a single statement by giving, instead of the
 249 constant name, a reference to a hash where the keys are the names of
 250 the constants to be defined.  Obviously, all constants defined using
 251 this method must have a single value.
 252
 253     use constant {
 254         FOO => "A single value",
 255         BAR => "This", "won't", "work!",        # Error!
 256     };
 257
 258 This is a fundamental limitation of the way hashes are constructed in
 259 Perl.  The error messages produced when this happens will often be
 260 quite cryptic -- in the worst case there may be none at all, and
 261 you'll only later find that something is broken.
 262
 263 When defining multiple constants, you cannot use the values of other
 264 constants defined in the same declaration.  This is because the
 265 calling package doesn't know about any constant within that group
 266 until I<after> the C<use> statement is finished.
 267
 268     use constant {
 269         BITMASK => 0xAFBAEBA8,
 270         NEGMASK => ~BITMASK,                    # Error!
 271     };
 272
 273 =head2 Magic constants
 274
 275 Magical values and references can be made into constants at compile
 276 time, allowing for way cool stuff like this.  (These error numbers
 277 aren't totally portable, alas.)
 278
 279     use constant E2BIG => ($! = 7);
 280     print   E2BIG, "\n";        # something like "Arg list too long"
 281     print 0+E2BIG, "\n";        # "7"
 282
 283 You can't produce a tied constant by giving a tied scalar as the
 284 value.  References to tied variables, however, can be used as
 285 constants without any problems.
 286
 287 =head1 TECHNICAL NOTES
 288
 289 In the current implementation, scalar constants are actually
 290 inlinable subroutines. As of version 5.004 of Perl, the appropriate
 291 scalar constant is inserted directly in place of some subroutine
 292 calls, thereby saving the overhead of a subroutine call. See
 293 L<perlsub/"Constant Functions"> for details about how and when this
 294 happens.
 295
 296 In the rare case in which you need to discover at run time whether a
 297 particular constant has been declared via this module, you may use
 298 this function to examine the hash C<%constant::declared>. If the given
 299 constant name does not include a package name, the current package is
 300 used.
 301
 302     sub declared ($) {
 303         use constant 1.01;              # don't omit this!
 304         my $name = shift;
 305         $name =~ s/^::/main::/;
 306         my $pkg = caller;
 307         my $full_name = $name =~ /::/ ? $name : "${pkg}::$name";
 308         $constant::declared{$full_name};
 309     }
 310
 311 =head1 BUGS
 312
 313 In the current version of Perl, list constants are not inlined
 314 and some symbols may be redefined without generating a warning.
 315
 316 It is not possible to have a subroutine or a keyword with the same
 317 name as a constant in the same package. This is probably a Good Thing.
 318
 319 A constant with a name in the list C<STDIN STDOUT STDERR ARGV ARGVOUT
 320 ENV INC SIG> is not allowed anywhere but in package C<main::>, for
 321 technical reasons.
 322
 323 Unlike constants in some languages, these cannot be overridden
 324 on the command line or via environment variables.
 325
 326 You can get into trouble if you use constants in a context which
 327 automatically quotes barewords (as is true for any subroutine call).
 328 For example, you can't say C<$hash{CONSTANT}> because C<CONSTANT> will
 329 be interpreted as a string.  Use C<$hash{CONSTANT()}> or
 330 C<$hash{+CONSTANT}> to prevent the bareword quoting mechanism from
 331 kicking in.  Similarly, since the C<< => >> operator quotes a bareword
 332 immediately to its left, you have to say C<< CONSTANT() => 'value' >>
 333 (or simply use a comma in place of the big arrow) instead of
 334 C<< CONSTANT => 'value' >>.
 335
 336 =head1 AUTHOR
 337
 338 Tom Phoenix, E<lt>F<rootbeer@redcat.com>E<gt>, with help from
 339 many other folks.
 340
 341 Multiple constant declarations at once added by Casey West,
 342 E<lt>F<casey@geeknest.com>E<gt>.
 343
 344 Documentation mostly rewritten by Ilmari Karonen,
 345 E<lt>F<perl@itz.pp.sci.fi>E<gt>.
 346
 347 =head1 COPYRIGHT
 348
 349 Copyright (C) 1997, 1999 Tom Phoenix
 350
 351 This module is free software; you can redistribute it or modify it
 352 under the same terms as Perl itself.
 353
 354 =cut