ext/Encode/lib/Encode/KR/2022_KR.pm

   1 package Encode::KR::2022_KR;
   2 use Encode::KR;
   3 use base 'Encode::Encoding';
   4
   5 use strict;
   6
   7 our $VERSION = do { my @r = (q$Revision: 1.2 $ =~ /\d+/g); sprintf "%d."."%02d" x $#r, @r };
   8
   9
  10 my $canon = 'iso-2022-kr';
  11 my $obj = bless {name => $canon}, __PACKAGE__;
  12 $obj->Define($canon);
  13
  14 sub name { return $_[0]->{name}; }
  15
  16 sub needs_lines { 1 }
  17
  18 sub decode
  19 {
  20     my ($obj,$str,$chk) = @_;
  21     my $res = $str;
  22     iso_euc(\$res);
  23     return Encode::decode('euc-kr', $res, $chk);
  24 }
  25
  26 sub encode
  27 {
  28     my ($obj,$str,$chk) = @_;
  29     my $res = Encode::encode('euc-kr', $str, $chk);
  30     euc_iso(\$res);
  31     return $res;
  32 }
  33
  34 use Encode::CJKConstants qw(:all);
  35
  36 # ISO<->EUC
  37
  38 sub iso_euc{
  39     my $r_str = shift;
  40     $$r_str =~ s/$RE{'2022_KR'}//gox;  # remove the designator
  41     $$r_str =~ s{                    # replace chars. in GL
  42      \x0e                            # between SO(\x0e) and SI(\x0f)
  43      ([^\x0f]*)                      # with chars. in GR
  44      \x0f
  45         }
  46     {
  47                         my $out= $1;
  48       $out =~ tr/\x21-\x7e/\xa1-\xfe/;
  49       $out;
  50     }geox;
  51     $$r_str;
  52 }
  53
  54 sub euc_iso{
  55     my $r_str = shift;
  56     substr($$r_str,0,0)=$ESC{'2022_KR'};  # put the designator at the beg.
  57     $$r_str =~ s{                     # move KS X 1001 chars. in GR to GL
  58         ($RE{EUC_C}+)                       # and enclose them with SO and SI
  59         }{
  60             my $str = $1;
  61             $str =~ tr/\xA1-\xFE/\x21-\x7E/;
  62             "\x0e" . $str . "\x0f";
  63         }geox;
  64     $$r_str;
  65 }
  66
  67 1;
  68 __END__
  69
  70 =head1 NAME
  71
  72 Encode::KR::2022_KR -- internally used by Encode::KR
  73
  74 =cut