Porting/corelist.pl

   1 #!perl
   2 # Generates info for Module::CoreList from this perl tree
   3 # run this from the root of a perl tree
   4 #
   5 # Data is on STDOUT.
   6 #
   7 # With an optional arg specifying the root of a CPAN mirror, outputs the
   8 # %upstream and %bug_tracker hashes too.
   9
  10 use strict;
  11 use warnings;
  12 use File::Find;
  13 use ExtUtils::MM_Unix;
  14 use version;
  15 use lib "Porting";
  16 use Maintainers qw(%Modules files_to_modules);
  17 use File::Spec;
  18 use Parse::CPAN::Meta;
  19 use IPC::Cmd 'can_run';
  20
  21 my $corelist_file = 'dist/Module-CoreList/lib/Module/CoreList.pm';
  22
  23 my %lines;
  24 my %module_to_file;
  25 my %modlist;
  26
  27 die "usage: $0 [ cpan-mirror/ ] [ 5.x.y] \n" unless @ARGV <= 2;
  28 my $cpan         = shift;
  29 my $raw_version  = shift || $];
  30 my $perl_version = version->parse("$raw_version");
  31 my $perl_vnum    = $perl_version->numify;
  32 my $perl_vstring = $perl_version->normal; # how do we get version.pm to not give us leading v?
  33 $perl_vstring =~ s/^v//;
  34
  35 if ( !-f 'MANIFEST' ) {
  36     die "Must be run from the root of a clean perl tree\n";
  37 }
  38
  39 open( my $corelist_fh, '<', $corelist_file ) || die "Could not open $corelist_file: $!";
  40 my $corelist = join( '', <$corelist_fh> );
  41
  42 if ($cpan) {
  43     my $modlistfile = File::Spec->catfile( $cpan, 'modules', '02packages.details.txt' );
  44     my $content;
  45
  46     my $fh;
  47     if ( -e $modlistfile ) {
  48         warn "Reading the module list from $modlistfile";
  49         open $fh, '<', $modlistfile or die "Couldn't open $modlistfile: $!";
  50     } elsif ( -e $modlistfile . ".gz" ) {
  51         my $zcat = can_run('gzcat') || can_run('zcat') or die "Can't find gzcat or zcat";
  52         warn "Reading the module list from $modlistfile.gz";
  53         open $fh, '-|', "$zcat $modlistfile.gz" or die "Couldn't zcat $modlistfile.gz: $!";
  54     } else {
  55         warn "About to fetch 02packages from ftp.funet.fi. This may take a few minutes\n";
  56         $content = fetch_url('http://ftp.funet.fi/pub/CPAN/modules/02packages.details.txt');
  57         unless ($content) {
  58             die "Unable to read 02packages.details.txt from either your CPAN mirror or ftp.funet.fi";
  59         }
  60     }
  61
  62     if ( $fh and !$content ) {
  63         local $/ = "\n";
  64         $content = join( '', <$fh> );
  65     }
  66
  67     die "Incompatible modlist format"
  68         unless $content =~ /^Columns: +package name, version, path/m;
  69
  70     # Converting the file to a hash is about 5 times faster than a regexp flat
  71     # lookup.
  72     for ( split( qr/\n/, $content ) ) {
  73         next unless /^([A-Za-z_:0-9]+) +[-0-9.undefHASHVERSIONvsetwhenloadingbogus]+ +(\S+)/;
  74         $modlist{$1} = $2;
  75     }
  76 }
  77
  78 find(
  79     sub {
  80         /(\.pm|_pm\.PL)$/ or return;
  81         /PPPort\.pm$/ and return;
  82         my $module = $File::Find::name;
  83         $module =~ /\b(demo|t|private)\b/ and return;    # demo or test modules
  84         my $version = MM->parse_version($_);
  85         defined $version or $version = 'undef';
  86         $version =~ /\d/ and $version = "'$version'";
  87
  88         # some heuristics to figure out the module name from the file name
  89         $module =~ s{^(lib|cpan|dist|(?:symbian/)?ext)/}{}
  90                         and $1 ne 'lib'
  91             and (
  92             $module =~ s{\b(\w+)/\1\b}{$1},
  93             $module =~ s{^B/O}{O},
  94             $module =~ s{^Devel-PPPort}{Devel},
  95             $module =~ s{^libnet/}{},
  96             $module =~ s{^Encode/encoding}{encoding},
  97             $module =~ s{^IPC-SysV/}{IPC/},
  98             $module =~ s{^MIME-Base64/QuotedPrint}{MIME/QuotedPrint},
  99             $module =~ s{^(?:DynaLoader|Errno|Opcode)/}{},
 100             );
 101         $module =~ s{^vms/ext}{VMS};
 102                 $module =~ s{^lib/}{}g;
 103         $module =~ s{/}{::}g;
 104         $module =~ s{-}{::}g;
 105                 $module =~ s{^.*::lib::}{}; # turns Foo/lib/Foo.pm into Foo.pm
 106         $module =~ s/(\.pm|_pm\.PL)$//;
 107         $lines{$module}          = $version;
 108         $module_to_file{$module} = $File::Find::name;
 109     },
 110     'vms/ext',
 111     'symbian/ext',
 112     'lib',
 113     'ext',
 114         'cpan',
 115         'dist'
 116 );
 117
 118 -e 'configpm' and $lines{Config} = 'undef';
 119
 120 if ( open my $ucdv, "<", "lib/unicore/version" ) {
 121     chomp( my $ucd = <$ucdv> );
 122     $lines{Unicode} = "'$ucd'";
 123     close $ucdv;
 124 }
 125
 126 my $versions_in_release = "    " . $perl_vnum . " => {\n";
 127 foreach my $key ( sort keys %lines ) {
 128     $versions_in_release .= sprintf "\t%-24s=> %s,\n", "'$key'", $lines{$key};
 129 }
 130 $versions_in_release .= "    },\n";
 131
 132 $corelist =~ s/^(%version\s*=\s*.*?)(^\);)$/$1$versions_in_release$2/xism;
 133
 134 exit unless %modlist;
 135
 136 # We have to go through this two stage lookup, given how Maintainers.pl keys its
 137 # data by "Module", which is really a dist.
 138 my $file_to_M = files_to_modules( values %module_to_file );
 139
 140 my %module_to_upstream;
 141 my %module_to_dist;
 142 my %dist_to_meta_YAML;
 143 my %module_to_deprecated;
 144 while ( my ( $module, $file ) = each %module_to_file ) {
 145     my $M = $file_to_M->{$file};
 146     next unless $M;
 147     next if $Modules{$M}{MAINTAINER} eq 'p5p';
 148     $module_to_upstream{$module} = $Modules{$M}{UPSTREAM};
 149     $module_to_deprecated{$module} = 1 if $Modules{$M}{DEPRECATED};
 150     next
 151         if defined $module_to_upstream{$module}
 152             && $module_to_upstream{$module} =~ /^(?:blead|first-come)$/;
 153     my $dist = $modlist{$module};
 154     unless ($dist) {
 155         warn "Can't find a distribution for $module\n";
 156         next;
 157     }
 158     $module_to_dist{$module} = $dist;
 159
 160     next if exists $dist_to_meta_YAML{$dist};
 161
 162     $dist_to_meta_YAML{$dist} = undef;
 163
 164     # Like it or lump it, this has to be Unix format.
 165     my $meta_YAML_path = "authors/id/$dist";
 166     $meta_YAML_path =~ s/(?:tar\.gz|tar\.bz2|zip)$/meta/ or die "$meta_YAML_path";
 167     my $meta_YAML_url = 'http://ftp.funet.fi/pub/CPAN/' . $meta_YAML_path;
 168
 169     if ( -e "$cpan/$meta_YAML_path" ) {
 170         $dist_to_meta_YAML{$dist} = Parse::CPAN::Meta::LoadFile( $cpan . "/" . $meta_YAML_path );
 171     } elsif ( my $content = fetch_url($meta_YAML_url) ) {
 172         unless ($content) {
 173             warn "Failed to fetch $meta_YAML_url\n";
 174             next;
 175         }
 176         eval { $dist_to_meta_YAML{$dist} = Parse::CPAN::Meta::Load($content); };
 177         if ( my $err = $@ ) {
 178             warn "$meta_YAML_path: ".$err;
 179             next;
 180         }
 181     } else {
 182         warn "$meta_YAML_path does not exist for $module\n";
 183
 184         # I tried code to open the tarballs with Archive::Tar to find and
 185         # extract META.yml, but only Text-Tabs+Wrap-2006.1117.tar.gz had one,
 186         # so it's not worth including.
 187         next;
 188     }
 189 }
 190
 191 my $upstream_stanza = "%upstream = (\n";
 192 foreach my $module ( sort keys %module_to_upstream ) {
 193     my $upstream = defined $module_to_upstream{$module} ? "'$module_to_upstream{$module}'" : 'undef';
 194     $upstream_stanza .= sprintf "    %-24s=> %s,\n", "'$module'", $upstream;
 195 }
 196 $upstream_stanza .= ");";
 197
 198 $corelist =~ s/^%upstream .*? ;$/$upstream_stanza/ismx;
 199
 200 # Deprecation generation
 201 my $deprecated_stanza = "    " . $perl_vnum . " => {\n";
 202 foreach my $module ( sort keys %module_to_deprecated ) {
 203     my $deprecated = defined $module_to_deprecated{$module} ? "'$module_to_deprecated{$module}'" : 'undef';
 204     $deprecated_stanza .= sprintf "\t%-24s=> %s,\n", "'$module'", $deprecated;
 205 }
 206 $deprecated_stanza .= "    },\n";
 207 $corelist =~ s/^(%deprecated\s*=\s*.*?)(^\);)$/$1$deprecated_stanza$2/xism;
 208
 209 my $tracker = "%bug_tracker = (\n";
 210 foreach my $module ( sort keys %module_to_upstream ) {
 211     my $upstream = defined $module_to_upstream{$module};
 212     next
 213         if defined $upstream
 214             and $upstream eq 'blead' || $upstream eq 'first-come';
 215
 216     my $bug_tracker;
 217
 218     my $dist = $module_to_dist{$module};
 219     $bug_tracker = $dist_to_meta_YAML{$dist}->{resources}{bugtracker}
 220         if $dist;
 221
 222     $bug_tracker = defined $bug_tracker ? "'$bug_tracker'" : 'undef';
 223         next if $bug_tracker eq "'http://rt.perl.org/perlbug/'";
 224     $tracker .= sprintf "    %-24s=> %s,\n", "'$module'", $bug_tracker;
 225 }
 226 $tracker .= ");";
 227
 228 $corelist =~ s/^%bug_tracker .*? ;/$tracker/eismx;
 229
 230 unless ( $corelist =~ /and $perl_vstring releases of perl/ ) {
 231     warn "Adding $perl_vstring to the list of perl versions covered by Module::CoreList\n";
 232     $corelist =~ s/(currently covers (?:.*?))\s*and (.*?) releases of perl/$1, $2 and $perl_vstring releases of perl/ism;
 233 }
 234
 235 unless (
 236     $corelist =~ /^%released \s* = \s* \(
 237         .*?
 238         $perl_vnum => .*?
 239         \);/ismx
 240     )
 241 {
 242     warn "Adding $perl_vnum to the list of released perl versions. Please consider adding a release date.\n";
 243     $corelist =~ s/^(%released \s* = \s* .*?) ( \) )
 244                 /$1  $perl_vnum => '????-??-??',\n  $2/ismx;
 245 }
 246
 247 write_corelist($corelist);
 248
 249 warn "All done. Please check over $corelist_file carefully before committing. Thanks!\n";
 250
 251
 252 sub write_corelist {
 253     my $content = shift;
 254     open (my $clfh, ">", $corelist_file) || die "Failed to open $corelist_file for writing: $!";
 255     print $clfh $content || die "Failed to write the new CoreList.pm: $!";
 256     close($clfh);
 257 }
 258
 259 sub fetch_url {
 260     my $url = shift;
 261     eval { require LWP::Simple };
 262     if ( LWP::Simple->can('get') ) {
 263         return LWP::Simple::get($url);
 264     } elsif (`which curl`) {
 265         return `curl -s $url`;
 266     } elsif (`which wget`) {
 267         return `wget -q -O - $url`;
 268     }
 269 }