3 perldata - Perl data types
8 X<variable, name> X<variable name> X<data type> X<type>
10 Perl has three built-in data types: scalars, arrays of scalars, and
11 associative arrays of scalars, known as "hashes". A scalar is a
12 single string (of any size, limited only by the available memory),
13 number, or a reference to something (which will be discussed
14 in L<perlref>). Normal arrays are ordered lists of scalars indexed
15 by number, starting with 0. Hashes are unordered collections of scalar
16 values indexed by their associated string key.
18 Values are usually referred to by name, or through a named reference.
19 The first character of the name tells you to what sort of data
20 structure it refers. The rest of the name tells you the particular
21 value to which it refers. Usually this name is a single I<identifier>,
22 that is, a string beginning with a letter or underscore, and
23 containing letters, underscores, and digits. In some cases, it may
24 be a chain of identifiers, separated by C<::> (or by the slightly
25 archaic C<'>); all but the last are interpreted as names of packages,
26 to locate the namespace in which to look up the final identifier
27 (see L<perlmod/Packages> for details). It's possible to substitute
28 for a simple identifier, an expression that produces a reference
29 to the value at runtime. This is described in more detail below
33 Perl also has its own built-in variables whose names don't follow
34 these rules. They have strange names so they don't accidentally
35 collide with one of your normal variables. Strings that match
36 parenthesized parts of a regular expression are saved under names
37 containing only digits after the C<$> (see L<perlop> and L<perlre>).
38 In addition, several special variables that provide windows into
39 the inner working of Perl have names containing punctuation characters
40 and control characters. These are documented in L<perlvar>.
43 Scalar values are always named with '$', even when referring to a
44 scalar that is part of an array or a hash. The '$' symbol works
45 semantically like the English word "the" in that it indicates a
46 single value is expected.
49 $days # the simple scalar value "days"
50 $days[28] # the 29th element of array @days
51 $days{'Feb'} # the 'Feb' value from hash %days
52 $#days # the last index of array @days
54 Entire arrays (and slices of arrays and hashes) are denoted by '@',
55 which works much as the word "these" or "those" does in English,
56 in that it indicates multiple values are expected.
59 @days # ($days[0], $days[1],... $days[n])
60 @days[3,4,5] # same as ($days[3],$days[4],$days[5])
61 @days{'a','c'} # same as ($days{'a'},$days{'c'})
63 Entire hashes are denoted by '%':
66 %days # (key1, val1, key2, val2 ...)
68 In addition, subroutines are named with an initial '&', though this
69 is optional when unambiguous, just as the word "do" is often redundant
70 in English. Symbol table entries can be named with an initial '*',
71 but you don't really care about that yet (if ever :-).
73 Every variable type has its own namespace, as do several
74 non-variable identifiers. This means that you can, without fear
75 of conflict, use the same name for a scalar variable, an array, or
76 a hash--or, for that matter, for a filehandle, a directory handle, a
77 subroutine name, a format name, or a label. This means that $foo
78 and @foo are two different variables. It also means that C<$foo[1]>
79 is a part of @foo, not a part of $foo. This may seem a bit weird,
80 but that's okay, because it is weird.
83 Because variable references always start with '$', '@', or '%', the
84 "reserved" words aren't in fact reserved with respect to variable
85 names. They I<are> reserved with respect to labels and filehandles,
86 however, which don't have an initial special character. You can't
87 have a filehandle named "log", for instance. Hint: you could say
88 C<open(LOG,'logfile')> rather than C<open(log,'logfile')>. Using
89 uppercase filehandles also improves readability and protects you
90 from conflict with future reserved words. Case I<is> significant--"FOO",
91 "Foo", and "foo" are all different names. Names that start with a
92 letter or underscore may also contain digits and underscores.
93 X<identifier, case sensitivity>
96 It is possible to replace such an alphanumeric name with an expression
97 that returns a reference to the appropriate type. For a description
98 of this, see L<perlref>.
100 Names that start with a digit may contain only more digits. Names
101 that do not start with a letter, underscore, digit or a caret (i.e.
102 a control character) are limited to one character, e.g., C<$%> or
103 C<$$>. (Most of these one character names have a predefined
104 significance to Perl. For instance, C<$$> is the current process
108 X<context> X<scalar context> X<list context>
110 The interpretation of operations and values in Perl sometimes depends
111 on the requirements of the context around the operation or value.
112 There are two major contexts: list and scalar. Certain operations
113 return list values in contexts wanting a list, and scalar values
114 otherwise. If this is true of an operation it will be mentioned in
115 the documentation for that operation. In other words, Perl overloads
116 certain operations based on whether the expected return value is
117 singular or plural. Some words in English work this way, like "fish"
120 In a reciprocal fashion, an operation provides either a scalar or a
121 list context to each of its arguments. For example, if you say
125 the integer operation provides scalar context for the <>
126 operator, which responds by reading one line from STDIN and passing it
127 back to the integer operation, which will then find the integer value
128 of that line and return that. If, on the other hand, you say
132 then the sort operation provides list context for <>, which
133 will proceed to read every line available up to the end of file, and
134 pass that list of lines back to the sort routine, which will then
135 sort those lines and return them as a list to whatever the context
138 Assignment is a little bit special in that it uses its left argument
139 to determine the context for the right argument. Assignment to a
140 scalar evaluates the right-hand side in scalar context, while
141 assignment to an array or hash evaluates the righthand side in list
142 context. Assignment to a list (or slice, which is just a list
143 anyway) also evaluates the right-hand side in list context.
145 When you use the C<use warnings> pragma or Perl's B<-w> command-line
146 option, you may see warnings
147 about useless uses of constants or functions in "void context".
148 Void context just means the value has been discarded, such as a
149 statement containing only C<"fred";> or C<getpwuid(0);>. It still
150 counts as scalar context for functions that care whether or not
151 they're being called in list context.
153 User-defined subroutines may choose to care whether they are being
154 called in a void, scalar, or list context. Most subroutines do not
155 need to bother, though. That's because both scalars and lists are
156 automatically interpolated into lists. See L<perlfunc/wantarray>
157 for how you would dynamically discern your function's calling
161 X<scalar> X<number> X<string> X<reference>
163 All data in Perl is a scalar, an array of scalars, or a hash of
164 scalars. A scalar may contain one single value in any of three
165 different flavors: a number, a string, or a reference. In general,
166 conversion from one form to another is transparent. Although a
167 scalar may not directly hold multiple values, it may contain a
168 reference to an array or hash which in turn contains multiple values.
170 Scalars aren't necessarily one thing or another. There's no place
171 to declare a scalar variable to be of type "string", type "number",
172 type "reference", or anything else. Because of the automatic
173 conversion of scalars, operations that return scalars don't need
174 to care (and in fact, cannot care) whether their caller is looking
175 for a string, a number, or a reference. Perl is a contextually
176 polymorphic language whose scalars can be strings, numbers, or
177 references (which includes objects). Although strings and numbers
178 are considered pretty much the same thing for nearly all purposes,
179 references are strongly-typed, uncastable pointers with builtin
180 reference-counting and destructor invocation.
182 A scalar value is interpreted as FALSE in the Boolean sense
183 if it is undefined, the null string or the number 0 (or its
184 string equivalent, "0"), and TRUE if it is anything else. The
185 Boolean context is just a special kind of scalar context where no
186 conversion to a string or a number is ever performed.
187 X<boolean> X<bool> X<true> X<false> X<truth>
189 There are actually two varieties of null strings (sometimes referred
190 to as "empty" strings), a defined one and an undefined one. The
191 defined version is just a string of length zero, such as C<"">.
192 The undefined version is the value that indicates that there is
193 no real value for something, such as when there was an error, or
194 at end of file, or when you refer to an uninitialized variable or
195 element of an array or hash. Although in early versions of Perl,
196 an undefined scalar could become defined when first used in a
197 place expecting a defined value, this no longer happens except for
198 rare cases of autovivification as explained in L<perlref>. You can
199 use the defined() operator to determine whether a scalar value is
200 defined (this has no meaning on arrays or hashes), and the undef()
201 operator to produce an undefined value.
202 X<defined> X<undefined> X<undef> X<null> X<string, null>
204 To find out whether a given string is a valid non-zero number, it's
205 sometimes enough to test it against both numeric 0 and also lexical
206 "0" (although this will cause noises if warnings are on). That's
207 because strings that aren't numbers count as 0, just as they do in B<awk>:
209 if ($str == 0 && $str ne "0") {
210 warn "That doesn't look like a number";
213 That method may be best because otherwise you won't treat IEEE
214 notations like C<NaN> or C<Infinity> properly. At other times, you
215 might prefer to determine whether string data can be used numerically
216 by calling the POSIX::strtod() function or by inspecting your string
217 with a regular expression (as documented in L<perlre>).
219 warn "has nondigits" if /\D/;
220 warn "not a natural number" unless /^\d+$/; # rejects -3
221 warn "not an integer" unless /^-?\d+$/; # rejects +3
222 warn "not an integer" unless /^[+-]?\d+$/;
223 warn "not a decimal number" unless /^-?\d+\.?\d*$/; # rejects .2
224 warn "not a decimal number" unless /^-?(?:\d+(?:\.\d*)?|\.\d+)$/;
226 unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/;
228 The length of an array is a scalar value. You may find the length
229 of array @days by evaluating C<$#days>, as in B<csh>. However, this
230 isn't the length of the array; it's the subscript of the last element,
231 which is a different value since there is ordinarily a 0th element.
232 Assigning to C<$#days> actually changes the length of the array.
233 Shortening an array this way destroys intervening values. Lengthening
234 an array that was previously shortened does not recover values
235 that were in those elements. (It used to do so in Perl 4, but we
236 had to break this to make sure destructors were called when expected.)
237 X<$#> X<array, length>
239 You can also gain some minuscule measure of efficiency by pre-extending
240 an array that is going to get big. You can also extend an array
241 by assigning to an element that is off the end of the array. You
242 can truncate an array down to nothing by assigning the null list
243 () to it. The following are equivalent:
248 If you evaluate an array in scalar context, it returns the length
249 of the array. (Note that this is not true of lists, which return
250 the last value, like the C comma operator, nor of built-in functions,
251 which return whatever they feel like returning.) The following is
255 scalar(@whatever) == $#whatever + 1;
257 Some programmers choose to use an explicit conversion so as to
258 leave nothing to doubt:
260 $element_count = scalar(@whatever);
262 If you evaluate a hash in scalar context, it returns false if the
263 hash is empty. If there are any key/value pairs, it returns true;
264 more precisely, the value returned is a string consisting of the
265 number of used buckets and the number of allocated buckets, separated
266 by a slash. This is pretty much useful only to find out whether
267 Perl's internal hashing algorithm is performing poorly on your data
268 set. For example, you stick 10,000 things in a hash, but evaluating
269 %HASH in scalar context reveals C<"1/16">, which means only one out
270 of sixteen buckets has been touched, and presumably contains all
271 10,000 of your items. This isn't supposed to happen. If a tied hash
272 is evaluated in scalar context, the C<SCALAR> method is called (with a
273 fallback to C<FIRSTKEY>).
274 X<hash, scalar context> X<hash, bucket> X<bucket>
276 You can preallocate space for a hash by assigning to the keys() function.
277 This rounds up the allocated buckets to the next power of two:
279 keys(%users) = 1000; # allocate 1024 buckets
281 =head2 Scalar value constructors
282 X<scalar, literal> X<scalar, constant>
284 Numeric literals are specified in any of the following floating point or
289 .23E-10 # a very small number
290 3.14_15_92 # a very important number
291 4_294_967_296 # underscore for legibility
293 0xdead_beef # more hex
294 0377 # octal (only numbers, begins with 0)
297 You are allowed to use underscores (underbars) in numeric literals
298 between digits for legibility (but not multiple underscores in a row:
299 C<23__500> is not legal; C<23_500> is).
300 You could, for example, group binary
301 digits by threes (as for a Unix-style mode argument such as 0b110_100_100)
302 or by fours (to represent nibbles, as in 0b1010_0110) or in other groups.
305 String literals are usually delimited by either single or double
306 quotes. They work much like quotes in the standard Unix shells:
307 double-quoted string literals are subject to backslash and variable
308 substitution; single-quoted strings are not (except for C<\'> and
309 C<\\>). The usual C-style backslash rules apply for making
310 characters such as newline, tab, etc., as well as some more exotic
311 forms. See L<perlop/"Quote and Quote-like Operators"> for a list.
314 Hexadecimal, octal, or binary, representations in string literals
315 (e.g. '0xff') are not automatically converted to their integer
316 representation. The hex() and oct() functions make these conversions
317 for you. See L<perlfunc/hex> and L<perlfunc/oct> for more details.
319 You can also embed newlines directly in your strings, i.e., they can end
320 on a different line than they begin. This is nice, but if you forget
321 your trailing quote, the error will not be reported until Perl finds
322 another line containing the quote character, which may be much further
323 on in the script. Variable substitution inside strings is limited to
324 scalar variables, arrays, and array or hash slices. (In other words,
325 names beginning with $ or @, followed by an optional bracketed
326 expression as a subscript.) The following code segment prints out "The
330 $Price = '$100'; # not interpolated
331 print "The price is $Price.\n"; # interpolated
333 There is no double interpolation in Perl, so the C<$100> is left as is.
335 By default floating point numbers substituted inside strings use the
336 dot (".") as the decimal separator. If C<use locale> is in effect,
337 and POSIX::setlocale() has been called, the character used for the
338 decimal separator is affected by the LC_NUMERIC locale.
339 See L<perllocale> and L<POSIX>.
341 As in some shells, you can enclose the variable name in braces to
342 disambiguate it from following alphanumerics (and underscores).
344 this when interpolating a variable into a string to separate the
345 variable name from a following double-colon or an apostrophe, since
346 these would be otherwise treated as a package separator:
350 print PASSWD "${who}::0:0:Superuser:/:/bin/perl\n";
351 print "We use ${who}speak when ${who}'s here.\n";
353 Without the braces, Perl would have looked for a $whospeak, a
354 C<$who::0>, and a C<$who's> variable. The last two would be the
355 $0 and the $s variables in the (presumably) non-existent package
358 In fact, an identifier within such curlies is forced to be a string,
359 as is any simple identifier within a hash subscript. Neither need
360 quoting. Our earlier example, C<$days{'Feb'}> can be written as
361 C<$days{Feb}> and the quotes will be assumed automatically. But
362 anything more complicated in the subscript will be interpreted as an
363 expression. This means for example that C<$version{2.0}++> is
364 equivalent to C<$version{2}++>, not to C<$version{'2.0'}++>.
366 =head3 Version Strings
367 X<version string> X<vstring> X<v-string>
369 A literal of the form C<v1.20.300.4000> is parsed as a string composed
370 of characters with the specified ordinals. This form, known as
371 v-strings, provides an alternative, more readable way to construct
372 strings, rather than use the somewhat less readable interpolation form
373 C<"\x{1}\x{14}\x{12c}\x{fa0}">. This is useful for representing
374 Unicode strings, and for comparing version "numbers" using the string
375 comparison operators, C<cmp>, C<gt>, C<lt> etc. If there are two or
376 more dots in the literal, the leading C<v> may be omitted.
378 print v9786; # prints SMILEY, "\x{263a}"
379 print v102.111.111; # prints "foo"
380 print 102.111.111; # same
382 Such literals are accepted by both C<require> and C<use> for
383 doing a version check. Note that using the v-strings for IPv4
384 addresses is not portable unless you also use the
385 inet_aton()/inet_ntoa() routines of the Socket package.
387 Note that since Perl 5.8.1 the single-number v-strings (like C<v65>)
388 are not v-strings before the C<< => >> operator (which is usually used
389 to separate a hash key from a hash value); instead they are interpreted
390 as literal strings ('v65'). They were v-strings from Perl 5.6.0 to
391 Perl 5.8.0, but that caused more confusion and breakage than good.
392 Multi-number v-strings like C<v65.66> and C<65.66.67> continue to
395 =head3 Special Literals
396 X<special literal> X<__END__> X<__DATA__> X<END> X<DATA>
397 X<end> X<data> X<^D> X<^Z>
399 The special literals __FILE__, __LINE__, and __PACKAGE__
400 represent the current filename, line number, and package name at that
401 point in your program. They may be used only as separate tokens; they
402 will not be interpolated into strings. If there is no current package
403 (due to an empty C<package;> directive), __PACKAGE__ is the undefined
404 value. (But the empty C<package;> is no longer supported, as of version
406 X<__FILE__> X<__LINE__> X<__PACKAGE__> X<line> X<file> X<package>
408 The two control characters ^D and ^Z, and the tokens __END__ and __DATA__
409 may be used to indicate the logical end of the script before the actual
410 end of file. Any following text is ignored.
412 Text after __DATA__ may be read via the filehandle C<PACKNAME::DATA>,
413 where C<PACKNAME> is the package that was current when the __DATA__
414 token was encountered. The filehandle is left open pointing to the
415 line after __DATA__. It is the program's responsibility to
416 C<close DATA> when it is done reading from it. For compatibility with
417 older scripts written before __DATA__ was introduced, __END__ behaves
418 like __DATA__ in the top level script (but not in files loaded with
419 C<require> or C<do>) and leaves the remaining contents of the
420 file accessible via C<main::DATA>.
422 See L<SelfLoader> for more description of __DATA__, and
423 an example of its use. Note that you cannot read from the DATA
424 filehandle in a BEGIN block: the BEGIN block is executed as soon
425 as it is seen (during compilation), at which point the corresponding
426 __DATA__ (or __END__) token has not yet been seen.
431 A word that has no other interpretation in the grammar will
432 be treated as if it were a quoted string. These are known as
433 "barewords". As with filehandles and labels, a bareword that consists
434 entirely of lowercase letters risks conflict with future reserved
435 words, and if you use the C<use warnings> pragma or the B<-w> switch,
436 Perl will warn you about any such words. Perl limits barewords (like
437 identifiers) to about 250 characters. Future versions of Perl are likely
438 to eliminate these arbitrary limitations.
440 Some people may wish to outlaw barewords entirely. If you
445 then any bareword that would NOT be interpreted as a subroutine call
446 produces a compile-time error instead. The restriction lasts to the
447 end of the enclosing block. An inner block may countermand this
448 by saying C<no strict 'subs'>.
450 =head3 Array Interpolation
451 X<array, interpolation> X<interpolation, array> X<$">
453 Arrays and slices are interpolated into double-quoted strings
454 by joining the elements with the delimiter specified in the C<$">
455 variable (C<$LIST_SEPARATOR> if "use English;" is specified),
456 space by default. The following are equivalent:
458 $temp = join($", @ARGV);
463 Within search patterns (which also undergo double-quotish substitution)
464 there is an unfortunate ambiguity: Is C</$foo[bar]/> to be interpreted as
465 C</${foo}[bar]/> (where C<[bar]> is a character class for the regular
466 expression) or as C</${foo[bar]}/> (where C<[bar]> is the subscript to array
467 @foo)? If @foo doesn't otherwise exist, then it's obviously a
468 character class. If @foo exists, Perl takes a good guess about C<[bar]>,
469 and is almost always right. If it does guess wrong, or if you're just
470 plain paranoid, you can force the correct interpretation with curly
473 If you're looking for the information on how to use here-documents,
474 which used to be here, that's been moved to
475 L<perlop/Quote and Quote-like Operators>.
477 =head2 List value constructors
480 List values are denoted by separating individual values by commas
481 (and enclosing the list in parentheses where precedence requires it):
485 In a context not requiring a list value, the value of what appears
486 to be a list literal is simply the value of the final element, as
487 with the C comma operator. For example,
489 @foo = ('cc', '-E', $bar);
491 assigns the entire list value to array @foo, but
493 $foo = ('cc', '-E', $bar);
495 assigns the value of variable $bar to the scalar variable $foo.
496 Note that the value of an actual array in scalar context is the
497 length of the array; the following assigns the value 3 to $foo:
499 @foo = ('cc', '-E', $bar);
500 $foo = @foo; # $foo gets 3
502 You may have an optional comma before the closing parenthesis of a
503 list literal, so that you can say:
511 To use a here-document to assign an array, one line per element,
512 you might use an approach like this:
514 @sauces = <<End_Lines =~ m/(\S.*\S)/g;
522 LISTs do automatic interpolation of sublists. That is, when a LIST is
523 evaluated, each element of the list is evaluated in list context, and
524 the resulting list value is interpolated into LIST just as if each
525 individual element were a member of LIST. Thus arrays and hashes lose their
526 identity in a LIST--the list
528 (@foo,@bar,&SomeSub,%glarch)
530 contains all the elements of @foo followed by all the elements of @bar,
531 followed by all the elements returned by the subroutine named SomeSub
532 called in list context, followed by the key/value pairs of %glarch.
533 To make a list reference that does I<NOT> interpolate, see L<perlref>.
535 The null list is represented by (). Interpolating it in a list
536 has no effect. Thus ((),(),()) is equivalent to (). Similarly,
537 interpolating an array with no elements is the same as if no
538 array had been interpolated at that point.
540 This interpolation combines with the facts that the opening
541 and closing parentheses are optional (except when necessary for
542 precedence) and lists may end with an optional comma to mean that
543 multiple commas within lists are legal syntax. The list C<1,,3> is a
544 concatenation of two lists, C<1,> and C<3>, the first of which ends
545 with that optional comma. C<1,,3> is C<(1,),(3)> is C<1,3> (And
546 similarly for C<1,,,3> is C<(1,),(,),3> is C<1,3> and so on.) Not that
547 we'd advise you to use this obfuscation.
549 A list value may also be subscripted like a normal array. You must
550 put the list in parentheses to avoid ambiguity. For example:
552 # Stat returns list value.
553 $time = (stat($file))[8];
556 $time = stat($file)[8]; # OOPS, FORGOT PARENTHESES
559 $hexdigit = ('a','b','c','d','e','f')[$digit-10];
561 # A "reverse comma operator".
562 return (pop(@foo),pop(@foo))[0];
564 Lists may be assigned to only when each element of the list
565 is itself legal to assign to:
567 ($a, $b, $c) = (1, 2, 3);
569 ($map{'red'}, $map{'blue'}, $map{'green'}) = (0x00f, 0x0f0, 0xf00);
571 An exception to this is that you may assign to C<undef> in a list.
572 This is useful for throwing away some of the return values of a
575 ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
577 List assignment in scalar context returns the number of elements
578 produced by the expression on the right side of the assignment:
580 $x = (($foo,$bar) = (3,2,1)); # set $x to 3, not 2
581 $x = (($foo,$bar) = f()); # set $x to f()'s return count
583 This is handy when you want to do a list assignment in a Boolean
584 context, because most list functions return a null list when finished,
585 which when assigned produces a 0, which is interpreted as FALSE.
587 It's also the source of a useful idiom for executing a function or
588 performing an operation in list context and then counting the number of
589 return values, by assigning to an empty list and then using that
590 assignment in scalar context. For example, this code:
592 $count = () = $string =~ /\d+/g;
594 will place into $count the number of digit groups found in $string.
595 This happens because the pattern match is in list context (since it
596 is being assigned to the empty list), and will therefore return a list
597 of all matching parts of the string. The list assignment in scalar
598 context will translate that into the number of elements (here, the
599 number of times the pattern matched) and assign that to $count. Note
602 $count = $string =~ /\d+/g;
604 would not have worked, since a pattern match in scalar context will
605 only return true or false, rather than a count of matches.
607 The final element of a list assignment may be an array or a hash:
609 ($a, $b, @rest) = split;
610 my($a, $b, %rest) = @_;
612 You can actually put an array or hash anywhere in the list, but the first one
613 in the list will soak up all the values, and anything after it will become
614 undefined. This may be useful in a my() or local().
616 A hash can be initialized using a literal list holding pairs of
617 items to be interpreted as a key and a value:
619 # same as map assignment above
620 %map = ('red',0x00f,'blue',0x0f0,'green',0xf00);
622 While literal lists and named arrays are often interchangeable, that's
623 not the case for hashes. Just because you can subscript a list value like
624 a normal array does not mean that you can subscript a list value as a
625 hash. Likewise, hashes included as parts of other lists (including
626 parameters lists and return lists from functions) always flatten out into
627 key/value pairs. That's why it's good to use references sometimes.
629 It is often more readable to use the C<< => >> operator between key/value
630 pairs. The C<< => >> operator is mostly just a more visually distinctive
631 synonym for a comma, but it also arranges for its left-hand operand to be
632 interpreted as a string if it's a bareword that would be a legal simple
633 identifier. C<< => >> doesn't quote compound identifiers, that contain
634 double colons. This makes it nice for initializing hashes:
642 or for initializing hash references to be used as records:
645 witch => 'Mable the Merciless',
646 cat => 'Fluffy the Ferocious',
647 date => '10/31/1776',
650 or for using call-by-named-parameter to complicated functions:
652 $field = $query->radio_group(
653 name => 'group_name',
654 values => ['eenie','meenie','minie'],
660 Note that just because a hash is initialized in that order doesn't
661 mean that it comes out in that order. See L<perlfunc/sort> for examples
662 of how to arrange for an output ordering.
666 An array can be accessed one scalar at a
667 time by specifying a dollar sign (C<$>), then the
668 name of the array (without the leading C<@>), then the subscript inside
669 square brackets. For example:
671 @myarray = (5, 50, 500, 5000);
672 print "The Third Element is", $myarray[2], "\n";
674 The array indices start with 0. A negative subscript retrieves its
675 value from the end. In our example, C<$myarray[-1]> would have been
676 5000, and C<$myarray[-2]> would have been 500.
678 Hash subscripts are similar, only instead of square brackets curly brackets
679 are used. For example:
684 "Einstein" => "Albert",
685 "Darwin" => "Charles",
686 "Feynman" => "Richard",
689 print "Darwin's First Name is ", $scientists{"Darwin"}, "\n";
691 You can also subscript a list to get a single element from it:
693 $dir = (getpwnam("daemon"))[7];
695 =head2 Multi-dimensional array emulation
697 Multidimensional arrays may be emulated by subscripting a hash with a
698 list. The elements of the list are joined with the subscript separator
705 $foo{join($;, $a, $b, $c)}
707 The default subscript separator is "\034", the same as SUBSEP in B<awk>.
710 X<slice> X<array, slice> X<hash, slice>
712 A slice accesses several elements of a list, an array, or a hash
713 simultaneously using a list of subscripts. It's more convenient
714 than writing out the individual elements as a list of separate
717 ($him, $her) = @folks[0,-1]; # array slice
718 @them = @folks[0 .. 3]; # array slice
719 ($who, $home) = @ENV{"USER", "HOME"}; # hash slice
720 ($uid, $dir) = (getpwnam("daemon"))[2,7]; # list slice
722 Since you can assign to a list of variables, you can also assign to
723 an array or hash slice.
725 @days[3..5] = qw/Wed Thu Fri/;
726 @colors{'red','blue','green'}
727 = (0xff0000, 0x0000ff, 0x00ff00);
728 @folks[0, -1] = @folks[-1, 0];
730 The previous assignments are exactly equivalent to
732 ($days[3], $days[4], $days[5]) = qw/Wed Thu Fri/;
733 ($colors{'red'}, $colors{'blue'}, $colors{'green'})
734 = (0xff0000, 0x0000ff, 0x00ff00);
735 ($folks[0], $folks[-1]) = ($folks[-1], $folks[0]);
737 Since changing a slice changes the original array or hash that it's
738 slicing, a C<foreach> construct will alter some--or even all--of the
739 values of the array or hash.
741 foreach (@array[ 4 .. 10 ]) { s/peter/paul/ }
743 foreach (@hash{qw[key1 key2]}) {
744 s/^\s+//; # trim leading whitespace
745 s/\s+$//; # trim trailing whitespace
746 s/(\w+)/\u\L$1/g; # "titlecase" words
749 A slice of an empty list is still an empty list. Thus:
751 @a = ()[1,0]; # @a has no elements
752 @b = (@a)[0,1]; # @b has no elements
753 @c = (0,1)[2,3]; # @c has no elements
757 @a = (1)[1,0]; # @a has two elements
758 @b = (1,undef)[1,0,2]; # @b has three elements
760 This makes it easy to write loops that terminate when a null list
763 while ( ($home, $user) = (getpwent)[7,0]) {
764 printf "%-8s %s\n", $user, $home;
767 As noted earlier in this document, the scalar sense of list assignment
768 is the number of elements on the right-hand side of the assignment.
769 The null list contains no elements, so when the password file is
770 exhausted, the result is 0, not 2.
772 Slices in scalar context return the last item of the slice.
774 @a = qw/first second third/;
775 %h = (first => 'A', second => 'B');
776 $t = @a[0, 1]; # $t is now 'second'
777 $u = @h{'first', 'second'}; # $u is now 'B'
779 If you're confused about why you use an '@' there on a hash slice
780 instead of a '%', think of it like this. The type of bracket (square
781 or curly) governs whether it's an array or a hash being looked at.
782 On the other hand, the leading symbol ('$' or '@') on the array or
783 hash indicates whether you are getting back a singular value (a
784 scalar) or a plural one (a list).
786 =head2 Typeglobs and Filehandles
787 X<typeglob> X<filehandle> X<*>
789 Perl uses an internal type called a I<typeglob> to hold an entire
790 symbol table entry. The type prefix of a typeglob is a C<*>, because
791 it represents all types. This used to be the preferred way to
792 pass arrays and hashes by reference into a function, but now that
793 we have real references, this is seldom needed.
795 The main use of typeglobs in modern Perl is create symbol table aliases.
800 makes $this an alias for $that, @this an alias for @that, %this an alias
801 for %that, &this an alias for &that, etc. Much safer is to use a reference.
804 local *Here::blue = \$There::green;
806 temporarily makes $Here::blue an alias for $There::green, but doesn't
807 make @Here::blue an alias for @There::green, or %Here::blue an alias for
808 %There::green, etc. See L<perlmod/"Symbol Tables"> for more examples
809 of this. Strange though this may seem, this is the basis for the whole
810 module import/export system.
812 Another use for typeglobs is to pass filehandles into a function or
813 to create new filehandles. If you need to use a typeglob to save away
814 a filehandle, do it this way:
818 or perhaps as a real reference, like this:
822 See L<perlsub> for examples of using these as indirect filehandles
825 Typeglobs are also a way to create a local filehandle using the local()
826 operator. These last until their block is exited, but may be passed back.
832 open (FH, $path) or return undef;
835 $fh = newopen('/etc/passwd');
837 Now that we have the C<*foo{THING}> notation, typeglobs aren't used as much
838 for filehandle manipulations, although they're still needed to pass brand
839 new file and directory handles into or out of functions. That's because
840 C<*HANDLE{IO}> only works if HANDLE has already been used as a handle.
841 In other words, C<*FH> must be used to create new symbol table entries;
842 C<*foo{THING}> cannot. When in doubt, use C<*FH>.
844 All functions that are capable of creating filehandles (open(),
845 opendir(), pipe(), socketpair(), sysopen(), socket(), and accept())
846 automatically create an anonymous filehandle if the handle passed to
847 them is an uninitialized scalar variable. This allows the constructs
848 such as C<open(my $fh, ...)> and C<open(local $fh,...)> to be used to
849 create filehandles that will conveniently be closed automatically when
850 the scope ends, provided there are no other references to them. This
851 largely eliminates the need for typeglobs when opening filehandles
852 that must be passed around, as in the following example:
856 or die "Can't open '@_': $!";
861 my $f = myopen("</etc/motd");
863 # $f implicitly closed here
866 Note that if an initialized scalar variable is used instead the
867 result is different: C<my $fh='zzz'; open($fh, ...)> is equivalent
868 to C<open( *{'zzz'}, ...)>.
869 C<use strict 'refs'> forbids such practice.
871 Another way to create anonymous filehandles is with the Symbol
872 module or with the IO::Handle module and its ilk. These modules
873 have the advantage of not hiding different types of the same name
874 during the local(). See the bottom of L<perlfunc/open> for an
879 See L<perlvar> for a description of Perl's built-in variables and
880 a discussion of legal variable names. See L<perlref>, L<perlsub>,
881 and L<perlmod/"Symbol Tables"> for more discussion on typeglobs and
882 the C<*foo{THING}> syntax.