lib/utf8_heavy.pl

   1 package utf8;
   2 use strict;
   3 use warnings;
   4
   5 sub DEBUG () { 0 }
   6
   7 sub DESTROY {}
   8
   9 my %Cache;
  10
  11 sub croak { require Carp; Carp::croak(@_) }
  12
  13 ##
  14 ## "SWASH" == "SWATCH HASH". A "swatch" is a swatch of the Unicode landscape.
  15 ## It's a data structure that encodes a set of Unicode characters.
  16 ##
  17
  18 {
  19     # If a floating point number is within this distance from the value of a
  20     # fraction, it is considered to be that fraction, even if many more digits
  21     # are specified that don't exactly match.
  22     my $min_floating_slop;
  23
  24     # To guard against this program calling something that in turn ends up
  25     # calling this program with the same inputs, and hence infinitely
  26     # recursing, we keep a stack of the properties that are currently in
  27     # progress, pushed upon entry, popped upon return.
  28     my @recursed;
  29
  30     sub SWASHNEW {
  31         my ($class, $type, $list, $minbits, $none) = @_;
  32         local $^D = 0 if $^D;
  33
  34         $class = "" unless defined $class;
  35         print STDERR __LINE__, ": class=$class, type=$type, list=",
  36                                 (defined $list) ? $list : ':undef:',
  37                                 ", minbits=$minbits, none=$none\n" if DEBUG;
  38
  39         ##
  40         ## Get the list of codepoints for the type.
  41         ## Called from swash_init (see utf8.c) or SWASHNEW itself.
  42         ##
  43         ## Callers of swash_init:
  44         ##     op.c:pmtrans             -- for tr/// and y///
  45         ##     regexec.c:regclass_swash -- for /[]/, \p, and \P
  46         ##     utf8.c:is_utf8_common    -- for common Unicode properties
  47         ##     utf8.c:to_utf8_case      -- for lc, uc, ucfirst, etc. and //i
  48         ##
  49         ## Given a $type, our goal is to fill $list with the set of codepoint
  50         ## ranges. If $type is false, $list passed is used.
  51         ##
  52         ## $minbits:
  53         ##     For binary properties, $minbits must be 1.
  54         ##     For character mappings (case and transliteration), $minbits must
  55         ##     be a number except 1.
  56         ##
  57         ## $list (or that filled according to $type):
  58         ##     Refer to perlunicode.pod, "User-Defined Character Properties."
  59         ##
  60         ##     For binary properties, only characters with the property value
  61         ##     of True should be listed. The 3rd column, if any, will be ignored
  62         ##
  63         ## $none is undocumented, so I'm (khw) trying to do some documentation
  64         ## of it now.  It appears to be if there is a mapping in an input file
  65         ## that maps to 'XXXX', then that is replaced by $none+1, expressed in
  66         ## hexadecimal.  It is used somehow in tr///.
  67         ##
  68         ## To make the parsing of $type clear, this code takes the a rather
  69         ## unorthodox approach of last'ing out of the block once we have the
  70         ## info we need. Were this to be a subroutine, the 'last' would just
  71         ## be a 'return'.
  72         ##
  73         #   If a problem is found $type is returned;
  74         #   Upon success, a new (or cached) blessed object is returned with
  75         #   keys TYPE, BITS, EXTRAS, LIST, and NONE with values having the
  76         #   same meanings as the input parameters.
  77         #   SPECIALS contains a reference to any special-treatment hash in the
  78         #   INVERT_IT is non-zero if the result should be inverted before use
  79         my $file; ## file to load data from, and also part of the %Cache key.
  80         my $ListSorted = 0;
  81
  82         # Change this to get a different set of Unicode tables
  83         my $unicore_dir = 'unicore';
  84         my $invert_it = 0;
  85
  86         if ($type)
  87         {
  88
  89             # Verify that this isn't a recursive call for this property.
  90             # Can't use croak, as it may try to recurse here itself.
  91             my $class_type = $class . "::$type";
  92             if (grep { $_ eq $class_type } @recursed) {
  93                 CORE::die "panic: Infinite recursion in SWASHNEW for '$type'\n";
  94             }
  95             push @recursed, $class_type;
  96
  97             $type =~ s/^\s+//;
  98             $type =~ s/\s+$//;
  99
 100             # regcomp.c surrounds the property name with '__" and '_i' if this
 101             # is to be caseless matching.
 102             my $caseless = $type =~ s/^__(.*)_i$/$1/;
 103
 104             print STDERR __LINE__, ": type=$type, caseless=$caseless\n" if DEBUG;
 105
 106         GETFILE:
 107             {
 108                 ##
 109                 ## It could be a user-defined property.  Look in current
 110                 ## package if no package given
 111                 ##
 112
 113                 my $caller1 = $type =~ s/(.+)::// ? $1 : caller(1);
 114
 115                 if (defined $caller1 && $type =~ /^I[ns]\w+$/) {
 116                     my $prop = "${caller1}::$type";
 117                     if (exists &{$prop}) {
 118                         # stolen from Scalar::Util::PP::tainted()
 119                         my $tainted;
 120                         {
 121                             local($@, $SIG{__DIE__}, $SIG{__WARN__});
 122                             local $^W = 0;
 123                             no warnings;
 124                             eval { kill 0 * $prop };
 125                             $tainted = 1 if $@ =~ /^Insecure/;
 126                         }
 127                         die "Insecure user-defined property \\p{$prop}\n"
 128                             if $tainted;
 129                         no strict 'refs';
 130                         $list = &{$prop}($caseless);
 131                         last GETFILE;
 132                     }
 133                 }
 134
 135                 # During Perl's compilation, this routine may be called before
 136                 # the tables are constructed.  If so, we have a chicken/egg
 137                 # problem.  If we die, the tables never get constructed, so
 138                 # keep going, but return an empty table so only what the code
 139                 # has compiled in internally (currently ASCII/Latin1 range
 140                 # matching) will work.
 141                 BEGIN {
 142                     # Poor man's constant, to avoid a run-time check.
 143                     $utf8::{miniperl}
 144                         = \! defined &DynaLoader::boot_DynaLoader;
 145                 }
 146                 if (miniperl) {
 147                     eval "require '$unicore_dir/Heavy.pl'";
 148                     last GETFILE if $@;
 149                 }
 150                 else {
 151                     require "$unicore_dir/Heavy.pl";
 152                 }
 153                 BEGIN { delete $utf8::{miniperl} }
 154
 155                 # All property names are matched caselessly
 156                 my $property_and_table = CORE::lc $type;
 157                 print STDERR __LINE__, ": $property_and_table\n" if DEBUG;
 158
 159                 # See if is of the compound form 'property=value', where the
 160                 # value indicates the table we should use.
 161                 my ($property, $table, @remainder) =
 162                                     split /\s*[:=]\s*/, $property_and_table, -1;
 163                 if (@remainder) {
 164                     pop @recursed if @recursed;
 165                     return $type;
 166                 }
 167
 168                 my $prefix;
 169                 if (! defined $table) {
 170
 171                     # Here, is the single form.  The property becomes empty, and
 172                     # the whole value is the table.
 173                     $table = $property;
 174                     $prefix = $property = "";
 175                 } else {
 176                     print STDERR __LINE__, ": $property\n" if DEBUG;
 177
 178                     # Here it is the compound property=table form.  The property
 179                     # name is always loosely matched, which means remove any of
 180                     # these:
 181                     $property =~ s/[_\s-]//g;
 182
 183                     # And convert to canonical form.  Quit if not valid.
 184                     $property = $utf8::loose_property_name_of{$property};
 185                     if (! defined $property) {
 186                         pop @recursed if @recursed;
 187                         return $type;
 188                     }
 189
 190                     $prefix = "$property=";
 191
 192                     # If the rhs looks like it is a number...
 193                     print STDERR __LINE__, ": table=$table\n" if DEBUG;
 194                     if ($table =~ qr{ ^ [ \s 0-9 _  + / . -]+ $ }x) {
 195                         print STDERR __LINE__, ": table=$table\n" if DEBUG;
 196
 197                         # Don't allow leading nor trailing slashes
 198                         if ($table =~ / ^ \/ | \/ $ /x) {
 199                             pop @recursed if @recursed;
 200                             return $type;
 201                         }
 202
 203                         # Split on slash, in case it is a rational, like \p{1/5}
 204                         my @parts = split qr{ \s* / \s* }x, $table, -1;
 205                         print __LINE__, ": $type\n" if @parts > 2 && DEBUG;
 206
 207                         # Can have maximum of one slash
 208                         if (@parts > 2) {
 209                             pop @recursed if @recursed;
 210                             return $type;
 211                         }
 212
 213                         foreach my $part (@parts) {
 214                             print __LINE__, ": part=$part\n" if DEBUG;
 215
 216                             $part =~ s/^\+\s*//;    # Remove leading plus
 217                             $part =~ s/^-\s*/-/;    # Remove blanks after unary
 218                                                     # minus
 219
 220                             # Remove underscores between digits.
 221                             $part =~ s/( ?<= [0-9] ) _ (?= [0-9] ) //xg;
 222
 223                             # No leading zeros (but don't make a single '0'
 224                             # into a null string)
 225                             $part =~ s/ ^ ( -? ) 0+ /$1/x;
 226                             $part .= '0' if $part eq '-' || $part eq "";
 227
 228                             # No trailing zeros after a decimal point
 229                             $part =~ s/ ( \. .*? ) 0+ $ /$1/x;
 230
 231                             # Begin with a 0 if a leading decimal point
 232                             $part =~ s/ ^ ( -? ) \. /${1}0./x;
 233
 234                             # Ensure not a trailing decimal point: turn into an
 235                             # integer
 236                             $part =~ s/ \. $ //x;
 237
 238                             print STDERR __LINE__, ": part=$part\n" if DEBUG;
 239                             #return $type if $part eq "";
 240
 241                             # Result better look like a number.  (This test is
 242                             # needed because, for example could have a plus in
 243                             # the middle.)
 244                             if ($part !~ / ^ -? [0-9]+ ( \. [0-9]+)? $ /x) {
 245                                 pop @recursed if @recursed;
 246                                 return $type;
 247                             }
 248                         }
 249
 250                         #  If a rational...
 251                         if (@parts == 2) {
 252
 253                             # If denominator is negative, get rid of it, and ...
 254                             if ($parts[1] =~ s/^-//) {
 255
 256                                 # If numerator is also negative, convert the
 257                                 # whole thing to positive, or move the minus to
 258                                 # the numerator
 259                                 if ($parts[0] !~ s/^-//) {
 260                                     $parts[0] = '-' . $parts[0];
 261                                 }
 262                             }
 263                             $table = join '/', @parts;
 264                         }
 265                         elsif ($property ne 'nv' || $parts[0] !~ /\./) {
 266
 267                             # Here is not numeric value, or doesn't have a
 268                             # decimal point.  No further manipulation is
 269                             # necessary.  (Note the hard-coded property name.
 270                             # This could fail if other properties eventually
 271                             # had fractions as well; perhaps the cjk ones
 272                             # could evolve to do that.  This hard-coding could
 273                             # be fixed by mktables generating a list of
 274                             # properties that could have fractions.)
 275                             $table = $parts[0];
 276                         } else {
 277
 278                             # Here is a floating point numeric_value.  Try to
 279                             # convert to rational.  First see if is in the list
 280                             # of known ones.
 281                             if (exists $utf8::nv_floating_to_rational{$parts[0]}) {
 282                                 $table = $utf8::nv_floating_to_rational{$parts[0]};
 283                             } else {
 284
 285                                 # Here not in the list.  See if is close
 286                                 # enough to something in the list.  First
 287                                 # determine what 'close enough' means.  It has
 288                                 # to be as tight as what mktables says is the
 289                                 # maximum slop, and as tight as how many
 290                                 # digits we were passed.  That is, if the user
 291                                 # said .667, .6667, .66667, etc.  we match as
 292                                 # many digits as they passed until get to
 293                                 # where it doesn't matter any more due to the
 294                                 # machine's precision.  If they said .6666668,
 295                                 # we fail.
 296                                 (my $fraction = $parts[0]) =~ s/^.*\.//;
 297                                 my $epsilon = 10 ** - (length($fraction));
 298                                 if ($epsilon > $utf8::max_floating_slop) {
 299                                     $epsilon = $utf8::max_floating_slop;
 300                                 }
 301
 302                                 # But it can't be tighter than the minimum
 303                                 # precision for this machine.  If haven't
 304                                 # already calculated that minimum, do so now.
 305                                 if (! defined $min_floating_slop) {
 306
 307                                     # Keep going down an order of magnitude
 308                                     # until find that adding this quantity to
 309                                     # 1 remains 1; but put an upper limit on
 310                                     # this so in case this algorithm doesn't
 311                                     # work properly on some platform, that we
 312                                     # won't loop forever.
 313                                     my $count = 0;
 314                                     $min_floating_slop = 1;
 315                                     while (1+ $min_floating_slop != 1
 316                                            && $count++ < 50)
 317                                     {
 318                                         my $next = $min_floating_slop / 10;
 319                                         last if $next == 0; # If underflows,
 320                                                             # use previous one
 321                                         $min_floating_slop = $next;
 322                                         print STDERR __LINE__, ": min_float_slop=$min_floating_slop\n" if DEBUG;
 323                                     }
 324
 325                                     # Back off a couple orders of magnitude,
 326                                     # just to be safe.
 327                                     $min_floating_slop *= 100;
 328                                 }
 329
 330                                 if ($epsilon < $min_floating_slop) {
 331                                     $epsilon = $min_floating_slop;
 332                                 }
 333                                 print STDERR __LINE__, ": fraction=.$fraction; epsilon=$epsilon\n" if DEBUG;
 334
 335                                 undef $table;
 336
 337                                 # And for each possible rational in the table,
 338                                 # see if it is within epsilon of the input.
 339                                 foreach my $official
 340                                         (keys %utf8::nv_floating_to_rational)
 341                                 {
 342                                     print STDERR __LINE__, ": epsilon=$epsilon, official=$official, diff=", abs($parts[0] - $official), "\n" if DEBUG;
 343                                     if (abs($parts[0] - $official) < $epsilon) {
 344                                       $table =
 345                                       $utf8::nv_floating_to_rational{$official};
 346                                         last;
 347                                     }
 348                                 }
 349
 350                                 # Quit if didn't find one.
 351                                 if (! defined $table) {
 352                                     pop @recursed if @recursed;
 353                                     return $type;
 354                                 }
 355                             }
 356                         }
 357                         print STDERR __LINE__, ": $property=$table\n" if DEBUG;
 358                     }
 359                 }
 360
 361                 # Combine lhs (if any) and rhs to get something that matches
 362                 # the syntax of the lookups.
 363                 $property_and_table = "$prefix$table";
 364                 print STDERR __LINE__, ": $property_and_table\n" if DEBUG;
 365
 366                 # First try stricter matching.
 367                 $file = $utf8::stricter_to_file_of{$property_and_table};
 368
 369                 # If didn't find it, try again with looser matching by editing
 370                 # out the applicable characters on the rhs and looking up
 371                 # again.
 372                 if (! defined $file) {
 373                     $table =~ s/ [_\s-] //xg;
 374                     $property_and_table = "$prefix$table";
 375                     print STDERR __LINE__, ": $property_and_table\n" if DEBUG;
 376                     $file = $utf8::loose_to_file_of{$property_and_table};
 377                 }
 378
 379                 # Add the constant and go fetch it in.
 380                 if (defined $file) {
 381
 382                     # A beginning ! means to invert
 383                     $invert_it = $file =~ s/^!//;
 384
 385                     if ($utf8::why_deprecated{$file}) {
 386                         warnings::warnif('deprecated', "Use of '$type' in \\p{} or \\P{} is deprecated because: $utf8::why_deprecated{$file};");
 387                     }
 388
 389                     if ($caseless
 390                         && exists $utf8::caseless_equivalent{$property_and_table})
 391                     {
 392                         $file = $utf8::caseless_equivalent{$property_and_table};
 393                     }
 394                     $file= "$unicore_dir/lib/$file.pl";
 395                     last GETFILE;
 396                 }
 397                 print STDERR __LINE__, ": didn't find $property_and_table\n" if DEBUG;
 398
 399                 ##
 400                 ## See if it's a user-level "To".
 401                 ##
 402
 403                 my $caller0 = caller(0);
 404
 405                 if (defined $caller0 && $type =~ /^To(?:\w+)$/) {
 406                     my $map = $caller0 . "::" . $type;
 407
 408                     if (exists &{$map}) {
 409                         no strict 'refs';
 410
 411                         $list = &{$map};
 412                         warnings::warnif('deprecated', "User-defined case-mapping '$type' is deprecated");
 413                         last GETFILE;
 414                     }
 415                 }
 416
 417                 ##
 418                 ## Last attempt -- see if it's a standard "To" name
 419                 ## (e.g. "ToLower")  ToTitle is used by ucfirst().
 420                 ## The user-level way to access ToDigit() and ToFold()
 421                 ## is to use Unicode::UCD.
 422                 ##
 423                 if ($type =~ /^To(Digit|Fold|Lower|Title|Upper)$/) {
 424
 425                     # Fail if wanting a binary property, as these aren't.
 426                     if ($minbits == 1) {
 427                         pop @recursed if @recursed;
 428                         return $type;
 429                     }
 430                     $file = "$unicore_dir/To/$1.pl";
 431                     ## would like to test to see if $file actually exists....
 432                     last GETFILE;
 433                 }
 434
 435                 ##
 436                 ## If we reach this line, it's because we couldn't figure
 437                 ## out what to do with $type. Ouch.
 438                 ##
 439
 440                 pop @recursed if @recursed;
 441                 return $type;
 442             }
 443
 444             if (defined $file) {
 445                 print STDERR __LINE__, ": found it (file='$file')\n" if DEBUG;
 446
 447                 ##
 448                 ## If we reach here, it was due to a 'last GETFILE' above
 449                 ## (exception: user-defined properties and mappings), so we
 450                 ## have a filename, so now we load it if we haven't already.
 451                 ## If we have, return the cached results. The cache key is the
 452                 ## class and file to load.
 453                 ##
 454                 my $found = $Cache{$class, $file};
 455                 if ($found and ref($found) eq $class) {
 456                     print STDERR __LINE__, ": Returning cached '$file' for \\p{$type}; invert_it=$invert_it\n" if DEBUG;
 457                     pop @recursed if @recursed;
 458                     $found->{'INVERT_IT'} = $invert_it;
 459                     return $found;
 460                 }
 461
 462                 local $@;
 463                 local $!;
 464                 $list = do $file; die $@ if $@;
 465             }
 466
 467             $ListSorted = 1; ## we know that these lists are sorted
 468         }
 469
 470         my $extras;
 471         my $bits = $minbits;
 472
 473         if ($list) {
 474             my $taint = substr($list,0,0); # maintain taint
 475             my @tmp = split(/^/m, $list);
 476             my %seen;
 477             no warnings;
 478             $extras = join '', $taint, grep /^[^0-9a-fA-F]/, @tmp;
 479             $list = join '', $taint,
 480                 map  { $_->[1] }
 481                 sort { $a->[0] <=> $b->[0] }
 482                 map  { /^([0-9a-fA-F]+)/; [ CORE::hex($1), $_ ] }
 483                 grep { /^([0-9a-fA-F]+)/ and not $seen{$1}++ } @tmp; # XXX doesn't do ranges right
 484         }
 485
 486         if ($none) {
 487             my $hextra = sprintf "%04x", $none + 1;
 488             $list =~ s/\tXXXX$/\t$hextra/mg;
 489         }
 490
 491         if ($minbits != 1 && $minbits < 32) { # not binary property
 492             my $top = 0;
 493             while ($list =~ /^([0-9a-fA-F]+)(?:[\t]([0-9a-fA-F]+)?)(?:[ \t]([0-9a-fA-F]+))?/mg) {
 494                 my $min = CORE::hex $1;
 495                 my $max = defined $2 ? CORE::hex $2 : $min;
 496                 my $val = defined $3 ? CORE::hex $3 : 0;
 497                 $val += $max - $min if defined $3;
 498                 $top = $val if $val > $top;
 499             }
 500             my $topbits =
 501                 $top > 0xffff ? 32 :
 502                 $top > 0xff ? 16 : 8;
 503             $bits = $topbits if $bits < $topbits;
 504         }
 505
 506         my @extras;
 507         if ($extras) {
 508             for my $x ($extras) {
 509                 my $taint = substr($x,0,0); # maintain taint
 510                 pos $x = 0;
 511                 while ($x =~ /^([^0-9a-fA-F\n])(.*)/mg) {
 512                     my $char = "$1$taint";
 513                     my $name = "$2$taint";
 514                     print STDERR __LINE__, ": char [$char] => name [$name]\n"
 515                         if DEBUG;
 516                     if ($char =~ /[-+!&]/) {
 517                         my ($c,$t) = split(/::/, $name, 2);     # bogus use of ::, really
 518                         my $subobj;
 519                         if ($c eq 'utf8') {
 520                             $subobj = utf8->SWASHNEW($t, "", $minbits, 0);
 521                         }
 522                         elsif (exists &$name) {
 523                             $subobj = utf8->SWASHNEW($name, "", $minbits, 0);
 524                         }
 525                         elsif ($c =~ /^([0-9a-fA-F]+)/) {
 526                             $subobj = utf8->SWASHNEW("", $c, $minbits, 0);
 527                         }
 528                         if (! ref $subobj) {
 529                             pop @recursed if @recursed && $type;
 530                             return $subobj;
 531                         }
 532                         push @extras, $name => $subobj;
 533                         $bits = $subobj->{BITS} if $bits < $subobj->{BITS};
 534                     }
 535                 }
 536             }
 537         }
 538
 539         if (DEBUG) {
 540             print STDERR __LINE__, ": CLASS = $class, TYPE => $type, BITS => $bits, NONE => $none, INVERT_IT => $invert_it";
 541             print STDERR "\nLIST =>\n$list" if defined $list;
 542             print STDERR "\nEXTRAS =>\n$extras" if defined $extras;
 543             print STDERR "\n";
 544         }
 545
 546         my $SWASH = bless {
 547             TYPE => $type,
 548             BITS => $bits,
 549             EXTRAS => $extras,
 550             LIST => $list,
 551             NONE => $none,
 552             @extras,
 553         } => $class;
 554
 555         if ($file) {
 556             $Cache{$class, $file} = $SWASH;
 557             if ($type
 558                 && exists $utf8::SwashInfo{$type}
 559                 && exists $utf8::SwashInfo{$type}{'specials_name'})
 560             {
 561                 my $specials_name = $utf8::SwashInfo{$type}{'specials_name'};
 562                 no strict "refs";
 563                 print STDERR "\nspecials_name => $SWASH->{'SPECIALS'}\n" if DEBUG;
 564                 $SWASH->{'SPECIALS'} = \%$specials_name;
 565             }
 566             $SWASH->{'INVERT_IT'} = $invert_it;
 567         }
 568
 569         pop @recursed if @recursed && $type;
 570
 571         return $SWASH;
 572     }
 573 }
 574
 575 # Now SWASHGET is recasted into a C function S_swash_get (see utf8.c).
 576
 577 1;