lib/ExtUtils/t/parse_version.t

   1 #!/usr/bin/perl -w
   2
   3 BEGIN {
   4     if( $ENV{PERL_CORE} ) {
   5         chdir 't';
   6         @INC = '../lib';
   7     }
   8     else {
   9         unshift @INC, 't/lib';
  10     }
  11 }
  12 chdir 't';
  13
  14 use Test::More;
  15 use ExtUtils::MakeMaker;
  16
  17 my $Has_Version = eval 'require version; "version"->import; 1';
  18
  19 my %versions = (q[$VERSION = '1.00']            => '1.00',
  20                 q[*VERSION = \'1.01']           => '1.01',
  21                 q[($VERSION) = q$Revision: 32208 $ =~ /(\d+)/g;] => 32208,
  22                 q[$FOO::VERSION = '1.10';]      => '1.10',
  23                 q[*FOO::VERSION = \'1.11';]     => '1.11',
  24                 '$VERSION = 0.02'               => 0.02,
  25                 '$VERSION = 0.0'                => 0.0,
  26                 '$VERSION = -1.0'               => -1.0,
  27                 '$VERSION = undef'              => 'undef',
  28                 '$wibble  = 1.0'                => 'undef',
  29                 q[my $VERSION = '1.01']         => 'undef',
  30                 q[local $VERISON = '1.02']      => 'undef',
  31                 q[local $FOO::VERSION = '1.30'] => 'undef',
  32                 q[if( $Foo::VERSION >= 3.00 ) {]=> 'undef',
  33                 q[our $VERSION = '1.23';]       => '1.23',
  34
  35                 '$Something::VERSION == 1.0'    => 'undef',
  36                 '$Something::VERSION <= 1.0'    => 'undef',
  37                 '$Something::VERSION >= 1.0'    => 'undef',
  38                 '$Something::VERSION != 1.0'    => 'undef',
  39
  40                 qq[\$Something::VERSION == 1.0\n\$VERSION = 2.3\n]                     => '2.3',
  41                 qq[\$Something::VERSION == 1.0\n\$VERSION = 2.3\n\$VERSION = 4.5\n]    => '2.3',
  42
  43                 '$VERSION = sprintf("%d.%03d", q$Revision: 3.74 $ =~ /(\d+)\.(\d+)/);' => '3.074',
  44                 '$VERSION = substr(q$Revision: 2.8 $, 10) + 2 . "";'                   => '4.8',
  45                );
  46
  47 if( $Has_Version ) {
  48     $versions{q[use version; $VERSION = qv("1.2.3");]} = qv("1.2.3");
  49     $versions{q[$VERSION = qv("1.2.3")]}               = qv("1.2.3");
  50 }
  51
  52 plan tests => (2 * keys %versions) + 4;
  53
  54 while( my($code, $expect) = each %versions ) {
  55     is( parse_version_string($code), $expect, $code );
  56 }
  57
  58
  59 sub parse_version_string {
  60     my $code = shift;
  61
  62     open(FILE, ">VERSION.tmp") || die $!;
  63     print FILE "$code\n";
  64     close FILE;
  65
  66     $_ = 'foo';
  67     my $version = MM->parse_version('VERSION.tmp');
  68     is( $_, 'foo', '$_ not leaked by parse_version' );
  69
  70     unlink "VERSION.tmp";
  71
  72     return $version;
  73 }
  74
  75
  76 # This is a specific test to see if a version subroutine in the $VERSION
  77 # declaration confuses later calls to the version class.
  78 # [rt.cpan.org 30747]
  79 SKIP: {
  80     skip "need version.pm", 4 unless $Has_Version;
  81     is parse_version_string(q[ $VERSION = '1.00'; sub version { $VERSION } ]),
  82        '1.00';
  83     is parse_version_string(q[ use version; $VERSION = version->new("1.2.3") ]),
  84        qv("1.2.3");
  85 }