installperl

   1 #!./perl
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '../lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8 }
   9
  10 BEGIN {
  11     use Config;
  12     if ($Config{userelocatableinc}) {
  13         # This might be a considered a hack. Need to get information about the
  14         # configuration from Config.pm *before* Config.pm expands any .../
  15         # prefixes.
  16         #
  17         # So we set $^X to pretend that we're the already installed perl, so
  18         # Config.pm doesits ... expansion off that location.
  19
  20         my $location = $Config{initialinstalllocation};
  21         die <<'OS' unless defined $location;
  22 $Config{initialinstalllocation} is not defined - can't install a relocatable
  23 perl without this.
  24 OS
  25         $^X = "$location/perl";
  26         # And then remove all trace of ever having loaded Config.pm, so that
  27         # it will reload with the revised $^X
  28         undef %Config::;
  29         delete $INC{"Config.pm"};
  30         delete $INC{"Config_heavy.pl"};
  31         # You never saw us. We weren't here.
  32     }
  33 }
  34
  35 use strict;
  36 my ($Is_VMS, $Is_W32, $Is_OS2, $Is_Cygwin, $Is_Darwin,
  37     $nonono, $dostrip, $versiononly, $silent, $verbose, $force,
  38     $otherperls, $archname, $Is_NetWare, $nwinstall, $nopods);
  39 use vars qw /$depth/;
  40
  41 BEGIN {
  42     $Is_VMS = $^O eq 'VMS';
  43     $Is_W32 = $^O eq 'MSWin32';
  44     $Is_OS2 = $^O eq 'os2';
  45     $Is_Cygwin = $^O eq 'cygwin';
  46     $Is_Darwin = $^O eq 'darwin';
  47     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  48 }
  49
  50 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  51
  52 use File::Find;
  53 use File::Compare;
  54 use File::Copy ();
  55 use File::Path ();
  56 use ExtUtils::Packlist;
  57 use Config;
  58 use subs qw(unlink link chmod);
  59
  60 if ($Config{d_umask}) {
  61     umask(022); # umasks like 077 aren't that useful for installations
  62 }
  63
  64 $Is_NetWare = $Config{osname} eq 'NetWare';
  65 if ($Is_NetWare) {
  66     $Is_W32 = 0;
  67     $scr_ext = '.pl';
  68 }
  69
  70 # override the ones in the rest of the script
  71 sub mkpath {
  72     File::Path::mkpath(@_) unless $nonono;
  73 }
  74
  75 my $mainperldir = "/usr/bin";
  76 my $exe_ext = $Config{exe_ext};
  77
  78 # Allow ``make install PERLNAME=something_besides_perl'':
  79 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  80
  81 # This is the base used for versioned names, like "perl5.6.0".
  82 # It's separate because a common use of $PERLNAME is to install
  83 # perl as "perl5", if that's used as base for versioned files you
  84 # get "perl55.6.0".
  85 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  86                     ? $ENV{PERLNAME_VERBASE}
  87                     : $perl;
  88 my $dbg = '';
  89 my $ndbg = '';
  90 if ( $Is_VMS ) {
  91     if ( defined $Config{usevmsdebug} ) {
  92         if ( $Config{usevmsdebug} eq 'define' ) {
  93             $dbg = 'dbg';
  94             $ndbg = 'ndbg';
  95         }
  96     }
  97 }
  98
  99 $otherperls = 1;
 100 my $destdir = '';
 101 while (@ARGV) {
 102     $nonono = 1 if $ARGV[0] eq '-n';
 103     $dostrip = 1 if $ARGV[0] eq '-s';
 104     $versiononly = 1 if $ARGV[0] eq '-v';
 105     $versiononly = 0 if $ARGV[0] eq '+v';
 106     $silent = 1 if $ARGV[0] eq '-S';
 107     $otherperls = 0 if $ARGV[0] eq '-o';
 108     $force = 1 if $ARGV[0] eq '-f';
 109     $verbose = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
 110     $archname = 1 if $ARGV[0] eq '-A';
 111     $nwinstall = 1 if $ARGV[0] eq '-netware';
 112     $nopods = 1 if $ARGV[0] eq '-p';
 113     $destdir = $1 if $ARGV[0] =~ /^-?-destdir=(.*)$/;
 114     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
 115         print <<"EOT";
 116 Usage $0: [switches]
 117   -n        Don't actually run any commands; just print them.
 118   -s        Run strip on installed binaries.
 119   -v        Only install perl as a binary with the version number in the name.
 120             (Override whatever config.sh says)
 121   +v        Install perl as "perl" and as a binary with the version number in
 122             the name.  (Override whatever config.sh says)
 123   -S        Silent mode.
 124   -f        Force installation (don't check if same version is there)
 125   -o        Skip checking for other copies of perl in your PATH.
 126   -V        Verbose mode.
 127   -A        Also install perl with the architecture's name in the perl binary's
 128             name.
 129   -p        Don't install the pod files. [This will break use diagnostics;]
 130   -netware  Install correctly on a Netware server.
 131   -destdir  Prefix installation directories by this string.
 132 EOT
 133         exit;
 134     }
 135     shift;
 136 }
 137
 138 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
 139 my (@scripts, @tolink);
 140 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
 141 while (<SCRIPTS>) {
 142     next if /^#/;
 143     s/\s*#\s*pod\s*=.*//; # install script regardless of pod location
 144     next if /a2p/; # a2p is binary, to be installed separately
 145     chomp;
 146     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
 147         push @scripts, $1;
 148         push @tolink, [$1, $2];
 149     } else {
 150         push @scripts, $_;
 151     }
 152 }
 153 close SCRIPTS;
 154
 155 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
 156
 157 my @pods = $nopods ? () : (<pod/*.pod>, 'x2p/a2p.pod');
 158
 159 # Specify here any .pm files that are actually architecture-dependent.
 160 # (Those included with XS extensions under ext/ are automatically
 161 # added later.)
 162 # Now that the default privlib has the full perl version number included,
 163 # we no longer have to play the trick of sticking version-specific .pm
 164 # files under the archlib directory.
 165 my %archpms = (
 166     Config => 1,
 167     lib => 1,
 168     Cwd => 1,
 169 );
 170
 171 if ($^O eq 'dos') {
 172     push(@scripts,'djgpp/fixpmain');
 173     $archpms{config} = $archpms{filehand} = 1;
 174 }
 175
 176 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
 177     push(@scripts, map("$_.exe", @scripts));
 178 }
 179
 180 find(sub {
 181     if ("$File::Find::dir/$_" =~ m{^ext\b(.*)/([^/]+)\.pm$}) {
 182         my($path, $modname) = ($1,$2);
 183
 184         # strip trailing component first
 185         $path =~ s{/[^/]*$}{};
 186
 187         # strip optional "/lib";
 188         $path =~ s{/lib\b}{};
 189
 190         # strip any leading /
 191         $path =~ s{^/}{};
 192
 193         # reconstitute canonical module name
 194         $modname = "$path/$modname" if length $path;
 195
 196         # remember it
 197         $archpms{$modname} = 1;
 198     }
 199 }, 'ext');
 200
 201 # print "[$_]\n" for sort keys %archpms;
 202
 203 my $ver = $Config{version};
 204 my $release = substr($],0,3);   # Not used currently.
 205 my $patchlevel = substr($],3,2);
 206 die "Patchlevel of perl ($patchlevel)",
 207     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 208         if $patchlevel != $Config{'PERL_VERSION'};
 209
 210 # Fetch some frequently-used items from %Config
 211 my $installbin = "$destdir$Config{installbin}";
 212 my $installscript = "$destdir$Config{installscript}";
 213 my $installprivlib = "$destdir$Config{installprivlib}";
 214 my $installarchlib = "$destdir$Config{installarchlib}";
 215 my $installsitelib = "$destdir$Config{installsitelib}";
 216 my $installsitearch = "$destdir$Config{installsitearch}";
 217 my $installman1dir = "$destdir$Config{installman1dir}";
 218 my $man1ext = $Config{man1ext};
 219 my $libperl = $Config{libperl};
 220 # Shared library and dynamic loading suffixes.
 221 my $so = $Config{so};
 222 my $dlext = $Config{dlext};
 223 my $dlsrc = $Config{dlsrc};
 224 if ($^O eq 'os390') {
 225     my $pwd;
 226     chomp($pwd=`pwd`);
 227     my $archlibexp = $Config{archlibexp};
 228     my $usedl = $Config{usedl};
 229     if ($usedl eq 'define') {
 230         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
 231     }
 232 }
 233
 234 if ($nwinstall) {
 235     # This is required only if we are installing on a NetWare server
 236     $installscript = $Config{installnwscripts};
 237     $installprivlib = $Config{installnwlib};
 238     $installarchlib = $Config{installnwlib};
 239     $installsitelib = $Config{installnwlib};
 240 }
 241
 242 my $d_dosuid = $Config{d_dosuid};
 243 my $binexp = $Config{binexp};
 244
 245 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 246     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 247               \$installarchlib, \$installsitelib, \$installsitearch,
 248               \$installman1dir ) {
 249         $$_ = unixify($$_);  $$_ =~ s:/$::;
 250     }
 251 }
 252
 253 # Do some quick sanity checks.
 254
 255 if (!$nonono && $d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 256
 257    $installbin          || die "No installbin directory in config.sh\n";
 258 -d $installbin          || mkpath($installbin, $verbose, 0777);
 259 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 260 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 261         unless $installbin =~ m#^/afs/# || $nonono;
 262
 263 if (!$Is_NetWare) {
 264 if (!$Is_VMS) {
 265 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 266 }
 267 else {
 268 -x $ndbg . 'perl' . $exe_ext    || die "${ndbg}perl$exe_ext isn't executable!\n";
 269     if ($dbg) {
 270         -x $dbg . 'perl' . $exe_ext     || die "${dbg}perl$exe_ext isn't executable!\n";
 271     }
 272 }
 273 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 274
 275 -f 't/rantests'         || $Is_W32
 276                         || warn "WARNING: You've never run 'make test' or",
 277                                 " some tests failed! (Installing anyway.)\n";
 278 } #if (!$Is_NetWare)
 279
 280 # This will be used to store the packlist
 281 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 282
 283 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
 284     my $perldll;
 285
 286     if ($Is_Cygwin) {
 287         $perldll = $libperl;
 288         my $v_e_r_s = $ver; $v_e_r_s =~ tr/./_/;
 289         $perldll =~ s/(\..*)?$/$v_e_r_s.$dlext/;
 290         $perldll =~ s/^lib/cyg/;
 291         if ($Config{useshrplib} eq 'true') {
 292             # install ld2 and perlld as well
 293             foreach ('ld2', 'perlld') {
 294                 safe_unlink("$installbin/$_");
 295                 copy("$_", "$installbin/$_");
 296                 chmod(0755, "$installbin/$_");
 297                 $packlist->{"$installbin/$_"} = { type => 'file' };
 298             };
 299             open (LD2, ">$installbin/ld2");
 300             print LD2 <<SHELL;
 301 #!/bin/sh
 302 #
 303 # ld wrapper, passes all args to perlld;
 304 #
 305 for trythis in $installbin/perl
 306 do
 307   if [ -x \$trythis ]
 308   then
 309     \$trythis $installbin/perlld "\$\@"
 310     exit \$?
 311   fi
 312 done
 313 # hard luck!
 314 echo I see no perl executable around there
 315 echo perl is required to build dynamic libraries
 316 echo look if the path to perl in /bin/ld2 is correct
 317 exit 1
 318 SHELL
 319             close LD2;
 320             chmod(0755, "$installbin/ld2");
 321         };
 322     } else {
 323         $perldll = 'perl58.' . $dlext;
 324     }
 325
 326     if ($dlsrc ne "dl_none.xs") {
 327         -f $perldll || die "No perl DLL built\n";
 328     }
 329
 330     # Install the DLL
 331     safe_unlink("$installbin/$perldll");
 332     copy("$perldll", "$installbin/$perldll");
 333     chmod(0755, "$installbin/$perldll");
 334     $packlist->{"$installbin/$perldll"} = { type => 'file' };
 335 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
 336
 337 # First we install the version-numbered executables.
 338
 339 if ($Is_VMS) {
 340     safe_unlink("$installbin/perl_setup.com");
 341     copy("perl_setup.com", "$installbin/perl_setup.com");
 342     chmod(0755, "$installbin/perl_setup.com");
 343     safe_unlink("$installbin/$dbg$perl$exe_ext");
 344     copy("$dbg$perl$exe_ext", "$installbin/$dbg$perl$exe_ext");
 345     chmod(0755, "$installbin/$dbg$perl$exe_ext");
 346     safe_unlink("$installbin/$dbg${perl}shr$exe_ext");
 347     copy("$dbg${perl}shr$exe_ext", "$installbin/$dbg${perl}shr$exe_ext");
 348     chmod(0755, "$installbin/$dbg${perl}shr$exe_ext");
 349     if ($ndbg) {
 350         safe_unlink("$installbin/$ndbg$perl$exe_ext");
 351         copy("$ndbg$perl$exe_ext", "$installbin/$ndbg$perl$exe_ext");
 352         chmod(0755, "$installbin/$ndbg$perl$exe_ext");
 353         safe_unlink("$installbin/${dbg}a2p$exe_ext");
 354         copy("x2p/${dbg}a2p$exe_ext", "$installbin/${dbg}a2p$exe_ext");
 355         chmod(0755, "$installbin/${dbg}a2p$exe_ext");
 356     }
 357 }
 358 elsif ($^O eq 'mpeix') {
 359     # MPE lacks hard links and requires that executables with special
 360     # capabilities reside in the MPE namespace.
 361     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 362     # Install the primary executable into the MPE namespace as perlpath.
 363     copy("perl$exe_ext", $Config{perlpath});
 364     chmod(0755, $Config{perlpath});
 365     # Create a backup copy with the version number.
 366     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 367 }
 368 elsif ($^O ne 'dos') {
 369     if (!$Is_NetWare) {
 370         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 371         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 372         strip("$installbin/$perl_verbase$ver$exe_ext");
 373         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 374     }
 375     else {
 376         # If installing onto a NetWare server
 377         if ($nwinstall) {
 378             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
 379             mkpath($Config{installnwsystem}, 1, 0777);
 380             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
 381             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
 382             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
 383             copy("x2p\\a2p.nlm", $Config{installnwsystem});
 384             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
 385             mkpath($Config{installnwlcgi}, 1, 0777);
 386             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
 387         }
 388     } #if (!$Is_NetWare)
 389 }
 390 else {
 391     safe_unlink("$installbin/$perl.exe");
 392     copy("perl.exe", "$installbin/$perl.exe");
 393 }
 394
 395 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
 396 if ($d_dosuid) {
 397     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
 398     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
 399 }
 400
 401 # Install library files.
 402
 403 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 404
 405 mkpath($installprivlib, $verbose, 0777);
 406 mkpath($installarchlib, $verbose, 0777);
 407 mkpath($installsitelib, $verbose, 0777) if ($installsitelib);
 408 mkpath($installsitearch, $verbose, 0777) if ($installsitearch);
 409
 410 if (chdir "lib") {
 411     $do_installarchlib = ! samepath($installarchlib, '.');
 412     $do_installprivlib = ! samepath($installprivlib, '.');
 413     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$ver/);
 414
 415     if ($do_installarchlib || $do_installprivlib) {
 416         find(\&installlib, '.');
 417     }
 418     chdir ".." || die "Can't cd back to source directory: $!\n";
 419 }
 420 else {
 421     warn "Can't cd to lib to install lib files: $!\n";
 422 }
 423
 424 # Install header files and libraries.
 425 mkpath("$installarchlib/CORE", $verbose, 0777);
 426 my @corefiles;
 427 if ($Is_VMS) {  # We did core file selection during build
 428     my $coredir = "lib/$Config{archname}/$ver/CORE";
 429     $coredir =~ tr/./_/;
 430     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 431 }
 432 else {
 433     # [als] hard-coded 'libperl' name... not good!
 434     @corefiles = <*.h *.inc libperl*.* perl*$Config{lib_ext}>;
 435
 436     # AIX needs perl.exp installed as well.
 437     push(@corefiles,'perl.exp') if $^O eq 'aix';
 438     if ($^O eq 'mpeix') {
 439         # MPE needs mpeixish.h installed as well.
 440         mkpath("$installarchlib/CORE/mpeix", $verbose, 0777);
 441         push(@corefiles,'mpeix/mpeixish.h');
 442     }
 443     # If they have built sperl.o...
 444     push(@corefiles,'sperl.o') if -f 'sperl.o';
 445 }
 446 foreach my $file (@corefiles) {
 447     # HP-UX (at least) needs to maintain execute permissions
 448     # on dynamically-loadable libraries. So we do it for all.
 449     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 450         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 451             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
 452             chmod(0555, "$installarchlib/CORE/$file");
 453         } else {
 454             chmod(0444, "$installarchlib/CORE/$file");
 455         }
 456     }
 457 }
 458
 459 # Switch in the 5.005-threads versions of he threadsafe queue and semaphore
 460 # modules if so needed.
 461 if ($Config{use5005threads}) {
 462     for my $m (qw(Queue Semaphore)) {
 463         my $t = "$installprivlib/Thread/$m.pm";
 464         unlink $t;
 465         copy("ext/Thread/$m.pmx", $t);
 466         chmod(0444, $t);
 467     }
 468 }
 469
 470 # Install main perl executables
 471 # Make links to ordinary names if installbin directory isn't current directory.
 472
 473 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
 474     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 475     if ($^O eq 'mpeix') {
 476         # MPE doesn't support hard links, so use a symlink.
 477         # We don't want another cloned copy.
 478         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 479     } elsif ($^O eq 'vos') {
 480         # VOS doesn't support hard links, so use a symlink.
 481         symlink("$installbin/$perl_verbase$ver$exe_ext",
 482                 "$installbin/$perl$exe_ext");
 483     } else {
 484         link("$installbin/$perl_verbase$ver$exe_ext",
 485                 "$installbin/$perl$exe_ext");
 486     }
 487     link("$installbin/$perl_verbase$ver$exe_ext",
 488             "$installbin/suid$perl$exe_ext")
 489       if $d_dosuid;
 490 }
 491
 492 # For development purposes it can be very useful to have multiple perls
 493 # build for different "architectures" (eg threading or not) simultaneously.
 494 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 495     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
 496     safe_unlink("$installbin/$archperl");
 497     if ($^O eq 'mpeix') {
 498         # MPE doesn't support hard links, so use a symlink.
 499         # We don't want another cloned copy.
 500         symlink($Config{perlpath}, "$installbin/$archperl");
 501     } elsif ($^O eq 'vos') {
 502         # VOS doesn't support hard links, so use a symlink.
 503         symlink("$installbin/$perl_verbase$ver$exe_ext",
 504                 "$installbin/$archperl");
 505     } else {
 506         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
 507     }
 508 }
 509
 510 # Offer to install perl in a "standard" location
 511
 512 my $mainperl_is_instperl = 0;
 513
 514 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 515     !$versiononly && !$nonono && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
 516         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 517     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 518     my($instperl)       = "$installbin/$perl$exe_ext";
 519     my($expinstperl)    = "$binexp/$perl$exe_ext";
 520
 521     # First make sure $usrbinperl is not already the same as the perl we
 522     # just installed.
 523     if (-x $usrbinperl) {
 524         # Try to be clever about mainperl being a symbolic link
 525         # to binexp/perl if binexp and installbin are different.
 526         $mainperl_is_instperl =
 527             samepath($usrbinperl, $instperl) ||
 528             samepath($usrbinperl, $expinstperl) ||
 529              (($binexp ne $installbin) &&
 530               (-l $usrbinperl) &&
 531               ((readlink $usrbinperl) eq $expinstperl));
 532     }
 533     if (! $mainperl_is_instperl) {
 534         unlink($usrbinperl);
 535         ( $Config{'d_link'} eq 'define' &&
 536           eval { CORE::link $instperl, $usrbinperl } )  ||
 537         eval { symlink $expinstperl, $usrbinperl }      ||
 538         copy($instperl, $usrbinperl);
 539
 540         $mainperl_is_instperl = 1;
 541     }
 542 }
 543
 544 # Make links to ordinary names if installbin directory isn't current directory.
 545 if (!$Is_NetWare && $dbg eq '') {
 546     if (! samepath($installbin, 'x2p')) {
 547         my $base = 'a2p';
 548         $base .= $ver if $versiononly;
 549         safe_unlink("$installbin/$base$exe_ext");
 550         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
 551         strip("$installbin/$base$exe_ext");
 552         chmod(0755, "$installbin/$base$exe_ext");
 553     }
 554 }
 555
 556 # cppstdin is just a script, but it is architecture-dependent, so
 557 # it can't safely be shared.  Place it in $installbin.
 558 # Note that Configure doesn't build cppstin if it isn't needed, so
 559 # we skip this if cppstdin doesn't exist.
 560 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 561     safe_unlink("$installbin/cppstdin");
 562     copy("cppstdin", "$installbin/cppstdin");
 563     chmod(0755, "$installbin/cppstdin");
 564 }
 565
 566 sub script_alias {
 567     my ($installscript, $orig, $alias, $scr_ext) = @_;
 568
 569     safe_unlink("$installscript/$alias$scr_ext");
 570     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 571         copy("$installscript/$orig$scr_ext",
 572              "$installscript/$alias$scr_ext");
 573     } elsif ($^O eq 'vos') {
 574         symlink("$installscript/$orig$scr_ext",
 575                 "$installscript/$alias$scr_ext");
 576     } else {
 577         link("$installscript/$orig$scr_ext",
 578              "$installscript/$alias$scr_ext");
 579     }
 580 }
 581
 582 # Install scripts.
 583 mkpath($installscript, $verbose, 0777);
 584 if ($versiononly) {
 585     for (@scripts) {
 586         (my $base = $_) =~ s#.*/##;
 587         $base .= $ver;
 588         copy($_,    "$installscript/$base");
 589         chmod(0755, "$installscript/$base");
 590     }
 591
 592     for (@tolink) {
 593         my ($from, $to) = map { "$_$ver" } @$_;
 594         (my $frbase = $from) =~ s#.*/##;
 595         (my $tobase = $to) =~ s#.*/##;
 596         script_alias($installscript, $frbase, $tobase, $scr_ext);
 597     }
 598 } else {
 599     for (@scripts) {
 600         (my $base = $_) =~ s#.*/##;
 601         copy($_, "$installscript/$base");
 602         chmod(0755, "$installscript/$base");
 603     }
 604
 605     for (@tolink) {
 606         my ($from, $to) = @$_;
 607         (my $frbase = $from) =~ s#.*/##;
 608         (my $tobase = $to) =~ s#.*/##;
 609         script_alias($installscript, $frbase, $tobase, $scr_ext);
 610     }
 611 }
 612
 613 # Install pod pages.  Where? I guess in $installprivlib/pod
 614 # ($installprivlib/pods for cygwin).
 615
 616 my $pod = ($Is_Cygwin || $Is_Darwin || $Is_VMS) ? 'pods' : 'pod';
 617 if ( !$versiononly || ($installprivlib =~ m/\Q$ver/)) {
 618     mkpath("${installprivlib}/$pod", $verbose, 0777);
 619
 620     # If Perl 5.003's perldiag.pod is there, rename it.
 621     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
 622         read POD, $_, 4000;
 623         close POD;
 624         # Some of Perl 5.003's diagnostic messages ended with periods.
 625         if (/^=.*\.$/m) {
 626             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
 627                                "${installprivlib}/$pod/perldiag-5.003.pod");
 628             print "  rename $from $to";
 629             rename($from, $to)
 630                 or warn "Couldn't rename $from to $to: $!\n"
 631                 unless $nonono;
 632         }
 633     }
 634
 635     for (@pods) {
 636         # $_ is a name like  pod/perl.pod
 637         (my $base = $_) =~ s#.*/##;
 638         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 639     }
 640
 641 }
 642
 643 # Check to make sure there aren't other perls around in installer's
 644 # path.  This is probably UNIX-specific.  Check all absolute directories
 645 # in the path except for where public executables are supposed to live.
 646 # Also skip $mainperl if the user opted to have it be a link to the
 647 # installed perl.
 648
 649 if (!$versiononly && $otherperls) {
 650     my ($path, @path);
 651     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
 652     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 653     @path = split(/$dirsep/, $path);
 654     if ($Is_VMS) {
 655         my $i = 0;
 656         while (exists $ENV{'DCL$PATH' . $i}) {
 657             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 658             push(@path,$dir);
 659         }
 660     }
 661     my @otherperls;
 662     my %otherperls;
 663     for (@path) {
 664         next unless m,^/,;
 665         # Use &samepath here because some systems have other dirs linked
 666         # to $mainperldir (like SunOS)
 667         next if samepath($_, $binexp);
 668         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 669         my $otherperl = "$_/$perl$exe_ext";
 670         next if $otherperls{$otherperl}++;
 671         push(@otherperls, $otherperl)
 672             if (-x $otherperl && ! -d $otherperl);
 673     }
 674     if (@otherperls) {
 675         warn "\nWarning: $perl appears in your path in the following " .
 676             "locations beyond where\nwe just installed it:\n";
 677         for (@otherperls) {
 678             warn "    ", $_, "\n";
 679         }
 680         warn "\n";
 681     }
 682
 683 }
 684
 685 $packlist->write() unless $nonono;
 686 print "  Installation complete\n" if $verbose;
 687
 688 exit 0;
 689
 690 ###############################################################################
 691
 692 sub yn {
 693     my($prompt) = @_;
 694     my($answer);
 695     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 696     print STDERR $prompt;
 697     chop($answer = <STDIN>);
 698     $answer = $default if $answer =~ m/^\s*$/;
 699     ($answer =~ m/^[yY]/);
 700 }
 701
 702 sub unlink {
 703     my(@names) = @_;
 704     my($cnt) = 0;
 705
 706     return scalar(@names) if $Is_VMS;
 707
 708     foreach my $name (@names) {
 709         next unless -e $name;
 710         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin || $Is_NetWare);
 711         print "  unlink $name\n" if $verbose;
 712         ( CORE::unlink($name) and ++$cnt
 713           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 714     }
 715     return $cnt;
 716 }
 717
 718 sub safe_unlink {
 719     return if $nonono or $Is_VMS;
 720     my @names = @_;
 721     foreach my $name (@names) {
 722         next unless -e $name;
 723         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
 724         print "  unlink $name\n" if $verbose;
 725         next if CORE::unlink($name);
 726         warn "Couldn't unlink $name: $!\n";
 727         if ($! =~ /busy/i) {
 728             print "  mv $name $name.old\n" if $verbose;
 729             safe_rename($name, "$name.old")
 730                 or warn "Couldn't rename $name: $!\n";
 731         }
 732     }
 733 }
 734
 735 sub safe_rename {
 736     my($from,$to) = @_;
 737     if (-f $to and not unlink($to)) {
 738         my($i);
 739         for ($i = 1; $i < 50; $i++) {
 740             last if rename($to, "$to.$i");
 741         }
 742         warn("Cannot rename to `$to.$i': $!"), return 0
 743            if $i >= 50; # Give up!
 744     }
 745     link($from,$to) || return 0;
 746     unlink($from);
 747 }
 748
 749 sub link {
 750     my($from,$to) = @_;
 751     my($success) = 0;
 752
 753     my $xfrom = $from;
 754     $xfrom =~ s/^\Q$destdir\E// if $destdir;
 755     my $xto = $to;
 756     $xto =~ s/^\Q$destdir\E// if $destdir;
 757     print $verbose ? "  ln $xfrom $xto\n" : "  $xto\n" unless $silent;
 758     eval {
 759         CORE::link($from, $to)
 760             ? $success++
 761             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 762               ? die "AFS"  # okay inside eval {}
 763               : die "Couldn't link $from to $to: $!\n"
 764           unless $nonono;
 765         $packlist->{$xto} = { from => $xfrom, type => 'link' };
 766     };
 767     if ($@) {
 768         warn "Replacing link() with File::Copy::copy(): $@";
 769         print $verbose ? "  cp $from $xto\n" : "  $xto\n" unless $silent;
 770         print "  creating new version of $xto\n"
 771                  if $Is_VMS and -e $to and !$silent;
 772         unless ($nonono or File::Copy::copy($from, $to) and ++$success) {
 773             # Might have been that F::C::c can't overwrite the target
 774             warn "Couldn't copy $from to $to: $!\n"
 775                 unless -f $to and (chmod(0666, $to), unlink $to)
 776                         and File::Copy::copy($from, $to) and ++$success;
 777         }
 778         $packlist->{$xto} = { type => 'file' };
 779     }
 780     $success;
 781 }
 782
 783 sub chmod {
 784     my($mode,$name) = @_;
 785
 786     return if ($^O eq 'dos');
 787     printf "  chmod %o %s\n", $mode, $name if $verbose;
 788     CORE::chmod($mode,$name)
 789         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 790       unless $nonono;
 791 }
 792
 793 sub copy {
 794     my($from,$to) = @_;
 795
 796     my $xto = $to;
 797     $xto =~ s/^\Q$destdir\E// if $destdir;
 798     print $verbose ? "  cp $from $xto\n" : "  $xto\n" unless $silent;
 799     print "  creating new version of $xto\n" if $Is_VMS and -e $to and !$silent;
 800     unless ($nonono or File::Copy::copy($from, $to)) {
 801         # Might have been that F::C::c can't overwrite the target
 802         warn "Couldn't copy $from to $to: $!\n"
 803             unless -f $to and (chmod(0666, $to), unlink $to)
 804                    and File::Copy::copy($from, $to);
 805     }
 806     $packlist->{$xto} = { type => 'file' };
 807 }
 808
 809 sub samepath {
 810     my($p1, $p2) = @_;
 811
 812     return (lc($p1) eq lc($p2)) if ($Is_W32 || $Is_NetWare);
 813
 814     if ($p1 ne $p2) {
 815         my($dev1, $ino1, $dev2, $ino2);
 816         ($dev1, $ino1) = stat($p1);
 817         ($dev2, $ino2) = stat($p2);
 818         ($dev1 == $dev2 && $ino1 == $ino2);
 819     }
 820     else {
 821         1;
 822     }
 823 }
 824
 825 sub installlib {
 826     my $dir = $File::Find::dir;
 827     $dir =~ s#^\.(?![^/])/?##;
 828     local($depth) = $dir ? "lib/$dir" : "lib";
 829
 830     my $name = $_;
 831
 832     # Ignore version control directories.
 833     if ($name =~ /^(?:CVS|RCS|SCCS|\.svn)\z/ and -d $name) {
 834         $File::Find::prune = 1;
 835         return;
 836     }
 837
 838     # ignore patch backups, RCS files, emacs backup & temp files and the
 839     # .exists files, .PL files, and test files.
 840     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.plc$|\.t$|^test\.pl$} ||
 841               $dir  =~ m{/t(?:/|$)};
 842
 843     # XXX xsubpp back out of the list. prove now integrated. Out of order, so
 844     # p4 will conflict on the next update to the following lines:
 845
 846     # ignore the cpan script in lib/CPAN/bin, the instmodsh and xsubpp
 847     # scripts in lib/ExtUtils, and the prove script in lib/Test/Harness
 848     # (they're installed later with other utils)
 849     return if $name =~ /^(?:cpan|instmodsh|prove)\z/;
 850
 851     # ignore the Makefiles
 852     return if $name =~ /^makefile$/i;
 853     # ignore the test extensions
 854     return if $dir =~ m{ext/XS/(?:APItest|Typemap)/};
 855     # ignore the demo files
 856     return if $dir =~ /\bdemos?\b/;
 857
 858     # ignore READMEs, MANIFESTs, INSTALL docs, META.ymls and change logs.
 859     # Changes.e2x and README.e2x are needed by enc2xs.
 860     return if $name =~ m{^(?:README(?:\.\w+)?|MANIFEST|META\.yml|INSTALL)$} && $name ne 'README.e2x';
 861     return if $name =~ m{^(?:TODO|BUGS|CREDITS)$}i;
 862     return if $name =~ m{^change(?:s|log)(?:\.libnet)?$}i;
 863
 864     $name = "$dir/$name" if $dir ne '';
 865
 866     my $installlib = $installprivlib;
 867     if ($dir =~ /^auto/ ||
 868           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 869           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare)) ||
 870           $name eq 'Config_heavy.pl'
 871        ) {
 872         $installlib = $installarchlib;
 873         return unless $do_installarchlib;
 874     } else {
 875         return unless $do_installprivlib;
 876     }
 877
 878     if (-f $_) {
 879         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
 880             $installlib = $installprivlib;
 881             #We're installing *.al and *.ix files into $installprivlib,
 882             #but we have to delete old *.al and *.ix files from the 5.000
 883             #distribution:
 884             #This might not work because $archname might have changed.
 885             unlink("$installarchlib/$name");
 886         }
 887         my $xname = "$installlib/$name";
 888         $xname =~ s/^\Q$destdir\E// if $destdir;
 889         $packlist->{$xname} = { type => 'file' };
 890         if ($force || compare($_, "$installlib/$name") || $nonono) {
 891             unlink("$installlib/$name");
 892             mkpath("$installlib/$dir", $verbose, 0777);
 893             # HP-UX (at least) needs to maintain execute permissions
 894             # on dynamically-loaded libraries.
 895             if ($Is_NetWare && !$nwinstall) {
 896                 # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
 897                 # if copied will give problems when building new extensions.
 898                 # Has to be copied if we are installing on a NetWare server and hence
 899                 # the check !$nwinstall
 900                 if (!(/\.(?:nlp|nlm|bs)$/)) {
 901                     copy_if_diff($_, "$installlib/$name")
 902                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 903                                   "$installlib/$name");
 904                 }
 905            } else {
 906                 if (copy_if_diff($_, "$installlib/$name")) {
 907                     if ($name =~ /\.(so|$dlext)$/o) {
 908                         strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
 909                         chmod(0555, "$installlib/$name");
 910                     } else {
 911                         strip("-S", "$installlib/$name")
 912                             if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
 913                         chmod(0444, "$installlib/$name");
 914                     }
 915                 }
 916             } #if ($Is_NetWare)
 917         }
 918     }
 919 }
 920
 921 # Copy $from to $to, only if $from is different than $to.
 922 # Also preserve modification times for .a libraries.
 923 # On some systems, if you do
 924 #   ranlib libperl.a
 925 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 926 # and then try to link against the installed libperl.a, you might
 927 # get an error message to the effect that the symbol table is older
 928 # than the library.
 929 # Return true if copying occurred.
 930
 931 sub copy_if_diff {
 932     my($from,$to)=@_;
 933     return 1 if (($^O eq 'VMS') && (-d $from));
 934     my $xto = $to;
 935     $xto =~ s/^\Q$destdir\E// if $destdir;
 936     my $perlpodbadsymlink;
 937     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
 938         -l $from &&
 939         ! -e $from) {
 940         # Some Linux implementations have problems traversing over
 941         # multiple symlinks (when going over NFS?) and fail to read
 942         # the symlink target.  Combine this with the fact that some
 943         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
 944         # and you end up with those pods not getting installed.
 945         $perlpodbadsymlink = 1;
 946     }
 947     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
 948     $packlist->{$xto} = { type => 'file' };
 949     if ($force || compare($from, $to) || $nonono) {
 950         safe_unlink($to);   # In case we don't have write permissions.
 951         if ($nonono) {
 952             $from = $depth . "/" . $from if $depth;
 953         }
 954         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
 955             $from = "README.$1";
 956         }
 957         copy($from, $to);
 958         # Restore timestamps if it's a .a library or for OS/2.
 959         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
 960             my ($atime, $mtime) = (stat $from)[8,9];
 961             utime $atime, $mtime, $to;
 962         }
 963         1;
 964     }
 965 }
 966
 967 sub strip
 968 {
 969     my(@args) = @_;
 970
 971     return unless $dostrip;
 972
 973     my @opts;
 974     while (@args && $args[0] =~ /^(-\w+)$/) {
 975         push @opts, shift @args;
 976     }
 977
 978     foreach my $file (@args) {
 979         if (-f $file) {
 980             if ($verbose) {
 981                 print "  strip " . join(' ', @opts);
 982                 print " " if (@opts);
 983                 print "$file\n";
 984             }
 985             system("strip", @opts, $file);
 986         } else {
 987             print "# file '$file' skipped\n" if $verbose;
 988         }
 989     }
 990 }