regen/mk_PL_charclass.pl

   1 #!perl -w
   2 use v5.15.8;
   3 use strict;
   4 use warnings;
   5 require 'regen/regen_lib.pl';
   6 require 'regen/charset_translations.pl';
   7
   8 # This program outputs l1_charclass_tab.h, which defines the guts of the
   9 # PL_charclass table.  Each line is a bit map of properties that the Unicode
  10 # code point at the corresponding position in the table array has.  The first
  11 # line corresponds to code point U+0000, NULL, the last line to U+00FF.  For
  12 # an application to see if the code point "i" has a particular property, it
  13 # just does
  14 #    'PL_charclass[i] & BIT'
  15 # The bit names are of the form '_CC_property_suffix', where 'CC' stands for
  16 # character class, and 'property' is the corresponding property, and 'suffix'
  17 # is one of '_A' to mean the property is true only if the corresponding code
  18 # point is ASCII, and '_L1' means that the range includes any Latin1
  19 # character (ISO-8859-1 including the C0 and C1 controls).  A property without
  20 # these suffixes does not have different forms for both ranges.
  21
  22 # This program need be run only when adding new properties to it, or upon a
  23 # new Unicode release, to make sure things haven't been changed by it.
  24
  25 my @properties = qw(
  26     NONLATIN1_SIMPLE_FOLD
  27     NONLATIN1_FOLD
  28     ALPHANUMERIC
  29     ALPHA
  30     ASCII
  31     BLANK
  32     CASED
  33     CHARNAME_CONT
  34     CNTRL
  35     DIGIT
  36     GRAPH
  37     IDFIRST
  38     LOWER
  39     NON_FINAL_FOLD
  40     PRINT
  41     PSXSPC
  42     PUNCT
  43     QUOTEMETA
  44     SPACE
  45     UPPER
  46     WORDCHAR
  47     XDIGIT
  48     VERTSPACE
  49     IS_IN_SOME_FOLD
  50     BACKSLASH_FOO_LBRACE_IS_META
  51 );
  52
  53 # Read in the case fold mappings.
  54 my %folded_closure;
  55 my @hex_non_final_folds;
  56 my @non_latin1_simple_folds;
  57 my @folds;
  58 use Unicode::UCD;
  59
  60 BEGIN { # Have to do this at compile time because using user-defined \p{property}
  61
  62     # Use the Unicode data file if we are on an ASCII platform (which its data
  63     # is for), and it is in the modern format (starting in Unicode 3.1.0) and
  64     # it is available.  This avoids being affected by potential bugs
  65     # introduced by other layers of Perl
  66     my $file="lib/unicore/CaseFolding.txt";
  67
  68     if (ord('A') == 65
  69         && pack("C*", split /\./, Unicode::UCD::UnicodeVersion()) ge v3.1.0
  70         && open my $fh, "<", $file)
  71     {
  72         @folds = <$fh>;
  73     }
  74     else {
  75         my ($invlist_ref, $invmap_ref, undef, $default)
  76                                     = Unicode::UCD::prop_invmap('Case_Folding');
  77         for my $i (0 .. @$invlist_ref - 1 - 1) {
  78             next if $invmap_ref->[$i] == $default;
  79             my $adjust = -1;
  80             for my $j ($invlist_ref->[$i] .. $invlist_ref->[$i+1] -1) {
  81                 $adjust++;
  82
  83                 # Single-code point maps go to a 'C' type
  84                 if (! ref $invmap_ref->[$i]) {
  85                     push @folds, sprintf("%04X; C; %04X\n",
  86                                         $j,
  87                                         $invmap_ref->[$i] + $adjust);
  88                 }
  89                 else {  # Multi-code point maps go to 'F'.  prop_invmap()
  90                         # guarantees that no adjustment is needed for these,
  91                         # as the range will contain just one element
  92                     push @folds, sprintf("%04X; F; %s\n",
  93                                         $j,
  94                                         join " ", map { sprintf "%04X", $_ }
  95                                                         @{$invmap_ref->[$i]});
  96                 }
  97             }
  98         }
  99     }
 100
 101     for (@folds) {
 102         chomp;
 103
 104         # Lines look like (without the initial '#'
 105         #0130; F; 0069 0307; # LATIN CAPITAL LETTER I WITH DOT ABOVE
 106         # Get rid of comments, ignore blank or comment-only lines
 107         my $line = $_ =~ s/ (?: \s* \# .* )? $ //rx;
 108         next unless length $line;
 109         my ($hex_from, $fold_type, @folded) = split /[\s;]+/, $line;
 110
 111         my $from = hex $hex_from;
 112
 113         # Perl only deals with S, C, and F folds
 114         next if $fold_type ne 'C' and $fold_type ne 'F' and $fold_type ne 'S';
 115
 116         # Get each code point in the range that participates in this line's fold.
 117         # The hash has keys of each code point in the range, and values of what it
 118         # folds to and what folds to it
 119         for my $i (0 .. @folded - 1) {
 120             my $hex_fold = $folded[$i];
 121             my $fold = hex $hex_fold;
 122             push @{$folded_closure{$fold}}, $from if $fold < 256;
 123             push @{$folded_closure{$from}}, $fold if $from < 256;
 124
 125             if (($fold_type eq 'C' || $fold_type eq 'S')
 126                 && ($fold < 256 != $from < 256))
 127             {
 128                 # Fold is simple (hence can't be a non-final fold, so the 'if'
 129                 # above is mutualy exclusive from the 'if below) and crosses
 130                 # 255/256 boundary.  We keep track of the Latin1 code points
 131                 # in such folds.
 132                 push @non_latin1_simple_folds, ($fold < 256)
 133                                                 ? $fold
 134                                                 : $from;
 135             }
 136             elsif ($i < @folded-1
 137                    && $fold < 256
 138                    && ! grep { $_ eq $hex_fold } @hex_non_final_folds)
 139             {
 140                 push @hex_non_final_folds, $hex_fold;
 141
 142                 # Also add the upper case, which in the latin1 range folds to
 143                 # $fold
 144                 push @hex_non_final_folds, sprintf "%04X", ord uc chr $fold;
 145             }
 146         }
 147     }
 148
 149     # Now having read all the lines, combine them into the full closure of each
 150     # code point in the range by adding lists together that share a common
 151     # element
 152     foreach my $folded (keys %folded_closure) {
 153         foreach my $from (grep { $_ < 256 } @{$folded_closure{$folded}}) {
 154             push @{$folded_closure{$from}}, @{$folded_closure{$folded}};
 155         }
 156     }
 157
 158     # We have the single-character folds that cross the 255/256, like KELVIN
 159     # SIGN => 'k', but we need the closure, so add like 'K' to it
 160     foreach my $folded (@non_latin1_simple_folds) {
 161         foreach my $fold (@{$folded_closure{$folded}}) {
 162             if ($fold < 256 && ! grep { $fold == $_ } @non_latin1_simple_folds) {
 163                 push @non_latin1_simple_folds, $fold;
 164             }
 165         }
 166     }
 167 }
 168
 169 sub Is_Non_Latin1_Fold {
 170     my @return;
 171
 172     foreach my $folded (keys %folded_closure) {
 173         push @return, sprintf("%X", $folded), if grep { $_ > 255 }
 174                                                      @{$folded_closure{$folded}};
 175     }
 176     return join("\n", @return) . "\n";
 177 }
 178
 179 sub Is_Non_Latin1_Simple_Fold { # Latin1 code points that are folded to by
 180                                 # non-Latin1 code points as single character
 181                                 # folds
 182     return join("\n", map { sprintf "%X", $_ } @non_latin1_simple_folds) . "\n";
 183 }
 184
 185 sub Is_Non_Final_Fold {
 186     return join("\n", @hex_non_final_folds) . "\n";
 187 }
 188
 189 my @bits;   # Bit map for each code point
 190
 191 # For each character, calculate which properties it matches.
 192 for my $ord (0..255) {
 193     my $char = chr($ord);
 194     utf8::upgrade($char);   # Important to use Unicode rules!
 195
 196     # Look at all the properties we care about here.
 197     for my $property (@properties) {
 198         my $name = $property;
 199
 200         # Remove the suffix to get the actual property name.
 201         # Currently the suffixes are '_L1', '_A', and none.
 202         # If is a latin1 version, no further checking is needed.
 203         if (! ($name =~ s/_L1$//)) {
 204
 205             # Here, isn't an _L1.  If its _A, it's automatically false for
 206             # non-ascii.  The only current ones (besides ASCII) without a
 207             # suffix are valid over the whole range.
 208             next if $name =~ s/_A$// && $char !~ /\p{ASCII}/;
 209         }
 210         my $re;
 211         if ($name eq 'PUNCT') {;
 212
 213             # Sadly, this is inconsistent: \pP and \pS for the ascii range,
 214             # just \pP outside it.
 215             $re = qr/\p{Punct}|[^\P{Symbol}\P{ASCII}]/;
 216         } elsif ($name eq 'CHARNAME_CONT') {;
 217             $re = qr/\p{_Perl_Charname_Continue}/,
 218         } elsif ($name eq 'SPACE') {;
 219             $re = qr/\p{XPerlSpace}/;
 220         } elsif ($name eq 'IDFIRST') {
 221             $re = qr/[_\p{Alpha}]/;
 222         } elsif ($name eq 'PSXSPC') {
 223             $re = qr/[\v\p{Space}]/;
 224         } elsif ($name eq 'WORDCHAR') {
 225             $re = qr/\p{XPosixWord}/;
 226         } elsif ($name eq 'ALPHANUMERIC') {
 227             # Like \w, but no underscore
 228             $re = qr/\p{Alnum}/;
 229         } elsif ($name eq 'QUOTEMETA') {
 230             $re = qr/\p{_Perl_Quotemeta}/;
 231         } elsif ($name eq 'NONLATIN1_FOLD') {
 232             $re = qr/\p{Is_Non_Latin1_Fold}/;
 233         } elsif ($name eq 'NONLATIN1_SIMPLE_FOLD') {
 234             $re = qr/\p{Is_Non_Latin1_Simple_Fold}/;
 235         } elsif ($name eq 'NON_FINAL_FOLD') {
 236             $re = qr/\p{Is_Non_Final_Fold}/;
 237         } elsif ($name eq 'IS_IN_SOME_FOLD') {
 238             $re = qr/\p{_Perl_Any_Folds}/;
 239         } elsif ($name eq 'BACKSLASH_FOO_LBRACE_IS_META') {
 240
 241             # This is true for FOO where FOO is the varying character in:
 242             # \a{, \b{, \c{, ...
 243             # and the sequence has non-literal meaning to Perl; so it is true
 244             # for 'x' because \x{ is special, but not 'a' because \a{ isn't.
 245             $re = qr/[gkNopPx]/;
 246         } else {    # The remainder have the same name and values as Unicode
 247             $re = eval "qr/\\p{$name}/";
 248             use Carp;
 249             carp $@ if ! defined $re;
 250         }
 251         #print "$ord, $name $property, $re\n";
 252         if ($char =~ $re) {  # Add this property if matches
 253             $bits[$ord] .= '|' if $bits[$ord];
 254             $bits[$ord] .= "(1U<<_CC_$property)";
 255         }
 256     }
 257     #print __LINE__, " $ord $char $bits[$ord]\n";
 258 }
 259
 260 my $out_fh = open_new('l1_char_class_tab.h', '>',
 261                       {style => '*', by => $0,
 262                       from => "property definitions"});
 263
 264 print $out_fh <<END;
 265 /* For code points whose position is not the same as Unicode,  both are shown
 266  * in the comment*/
 267 END
 268
 269 # Output the table using fairly short names for each char.
 270 foreach my $charset (get_supported_code_pages()) {
 271     my @a2n = get_a2n($charset);
 272     my @out;
 273
 274     print $out_fh "\n" . get_conditional_compile_line_start($charset);
 275     for my $ord (0..255) {
 276         my $name;
 277         my $char = chr $ord;
 278         if ($char =~ /\p{PosixGraph}/) {
 279             my $quote = $char eq "'" ? '"' : "'";
 280             $name = $quote . chr($ord) . $quote;
 281         }
 282         elsif ($char =~ /\p{XPosixGraph}/) {
 283             use charnames();
 284             $name = charnames::viacode($ord);
 285             $name =~ s/LATIN CAPITAL LETTER //
 286                     or $name =~ s/LATIN SMALL LETTER (.*)/\L$1/
 287                     or $name =~ s/ SIGN\b//
 288                     or $name =~ s/EXCLAMATION MARK/'!'/
 289                     or $name =~ s/QUESTION MARK/'?'/
 290                     or $name =~ s/QUOTATION MARK/QUOTE/
 291                     or $name =~ s/ INDICATOR//;
 292             $name =~ s/\bWITH\b/\L$&/;
 293             $name =~ s/\bONE\b/1/;
 294             $name =~ s/\b(TWO|HALF)\b/2/;
 295             $name =~ s/\bTHREE\b/3/;
 296             $name =~ s/\b QUARTER S? \b/4/x;
 297             $name =~ s/VULGAR FRACTION (.) (.)/$1\/$2/;
 298             $name =~ s/\bTILDE\b/'~'/i
 299                     or $name =~ s/\bCIRCUMFLEX\b/'^'/i
 300                     or $name =~ s/\bSTROKE\b/'\/'/i
 301                     or $name =~ s/ ABOVE\b//i;
 302         }
 303         else {
 304             use Unicode::UCD qw(prop_invmap);
 305             my ($list_ref, $map_ref, $format) = prop_invmap("Name_Alias");
 306             if ($format !~ /^s/) {
 307                 use Carp;
 308                 carp "Unexpected format '$format' for 'Name_Alias";
 309                 last;
 310             }
 311             my $which = Unicode::UCD::search_invlist($list_ref, $ord);
 312             if (! defined $which) {
 313                 use Carp;
 314                 carp "No name found for code pont $ord";
 315             }
 316             else {
 317                 my $map = $map_ref->[$which];
 318                 if (! ref $map) {
 319                     $name = $map;
 320                 }
 321                 else {
 322                     # Just pick the first abbreviation if more than one
 323                     my @names = grep { $_ =~ /abbreviation/ } @$map;
 324                     $name = $names[0];
 325                 }
 326                 $name =~ s/:.*//;
 327             }
 328         }
 329         my $index = $a2n[$ord];
 330         $out[$index] = ($ord == $index)
 331                     ? sprintf "/* U+%02X %s */ %s,\n", $ord, $name, $bits[$ord]
 332                     : sprintf "/* 0x%02X U+%02X %s */ %s,\n", $index, $ord, $name, $bits[$ord];
 333     }
 334     print $out_fh join "", @out;
 335     print $out_fh "\n" . get_conditional_compile_line_end();
 336 }
 337
 338 read_only_bottom_close_and_rename($out_fh)