lib/Class/Struct.pm

   1 package Class::Struct;
   2
   3 ## See POD after __END__
   4
   5 use 5.006_001;
   6
   7 use strict;
   8 use warnings::register;
   9 our(@ISA, @EXPORT, $VERSION);
  10
  11 use Carp;
  12
  13 require Exporter;
  14 @ISA = qw(Exporter);
  15 @EXPORT = qw(struct);
  16
  17 $VERSION = '0.65';
  18
  19 my $print = 0;
  20 sub printem {
  21     if (@_) { $print = shift }
  22     else    { $print++ }
  23 }
  24
  25 {
  26     package Class::Struct::Tie_ISA;
  27
  28     sub TIEARRAY {
  29         my $class = shift;
  30         return bless [], $class;
  31     }
  32
  33     sub STORE {
  34         my ($self, $index, $value) = @_;
  35         Class::Struct::_subclass_error();
  36     }
  37
  38     sub FETCH {
  39         my ($self, $index) = @_;
  40         $self->[$index];
  41     }
  42
  43     sub FETCHSIZE {
  44         my $self = shift;
  45         return scalar(@$self);
  46     }
  47
  48     sub DESTROY { }
  49 }
  50
  51 sub import {
  52     my $self = shift;
  53
  54     if ( @_ == 0 ) {
  55       $self->export_to_level( 1, $self, @EXPORT );
  56     } elsif ( @_ == 1 ) {
  57         # This is admittedly a little bit silly:
  58         # do we ever export anything else than 'struct'...?
  59       $self->export_to_level( 1, $self, @_ );
  60     } else {
  61       goto &struct;
  62     }
  63 }
  64
  65 sub struct {
  66
  67     # Determine parameter list structure, one of:
  68     #   struct( class => [ element-list ])
  69     #   struct( class => { element-list })
  70     #   struct( element-list )
  71     # Latter form assumes current package name as struct name.
  72
  73     my ($class, @decls);
  74     my $base_type = ref $_[1];
  75     if ( $base_type eq 'HASH' ) {
  76         $class = shift;
  77         @decls = %{shift()};
  78         _usage_error() if @_;
  79     }
  80     elsif ( $base_type eq 'ARRAY' ) {
  81         $class = shift;
  82         @decls = @{shift()};
  83         _usage_error() if @_;
  84     }
  85     else {
  86         $base_type = 'ARRAY';
  87         $class = (caller())[0];
  88         @decls = @_;
  89     }
  90
  91     _usage_error() if @decls % 2 == 1;
  92
  93     # Ensure we are not, and will not be, a subclass.
  94
  95     my $isa = do {
  96         no strict 'refs';
  97         \@{$class . '::ISA'};
  98     };
  99     _subclass_error() if @$isa;
 100     tie @$isa, 'Class::Struct::Tie_ISA';
 101
 102     # Create constructor.
 103
 104     croak "function 'new' already defined in package $class"
 105         if do { no strict 'refs'; defined &{$class . "::new"} };
 106
 107     my @methods = ();
 108     my %refs = ();
 109     my %arrays = ();
 110     my %hashes = ();
 111     my %classes = ();
 112     my $got_class = 0;
 113     my $out = '';
 114
 115     $out = "{\n  package $class;\n  use Carp;\n  sub new {\n";
 116     $out .= "    my (\$class, \%init) = \@_;\n";
 117     $out .= "    \$class = __PACKAGE__ unless \@_;\n";
 118
 119     my $cnt = 0;
 120     my $idx = 0;
 121     my( $cmt, $name, $type, $elem );
 122
 123     if( $base_type eq 'HASH' ){
 124         $out .= "    my(\$r) = {};\n";
 125         $cmt = '';
 126     }
 127     elsif( $base_type eq 'ARRAY' ){
 128         $out .= "    my(\$r) = [];\n";
 129     }
 130
 131     $out .= " bless \$r, \$class;\n\n";
 132
 133     while( $idx < @decls ){
 134         $name = $decls[$idx];
 135         $type = $decls[$idx+1];
 136         push( @methods, $name );
 137         if( $base_type eq 'HASH' ){
 138             $elem = "{'${class}::$name'}";
 139         }
 140         elsif( $base_type eq 'ARRAY' ){
 141             $elem = "[$cnt]";
 142             ++$cnt;
 143             $cmt = " # $name";
 144         }
 145         if( $type =~ /^\*(.)/ ){
 146             $refs{$name}++;
 147             $type = $1;
 148         }
 149         my $init = "defined(\$init{'$name'}) ? \$init{'$name'} :";
 150         if( $type eq '@' ){
 151             $out .= "    croak 'Initializer for $name must be array reference'\n";
 152             $out .= "        if defined(\$init{'$name'}) && ref(\$init{'$name'}) ne 'ARRAY';\n";
 153             $out .= "    \$r->$name( $init [] );$cmt\n";
 154             $arrays{$name}++;
 155         }
 156         elsif( $type eq '%' ){
 157             $out .= "    croak 'Initializer for $name must be hash reference'\n";
 158             $out .= "        if defined(\$init{'$name'}) && ref(\$init{'$name'}) ne 'HASH';\n";
 159             $out .= "    \$r->$name( $init {} );$cmt\n";
 160             $hashes{$name}++;
 161         }
 162         elsif ( $type eq '$') {
 163             $out .= "    \$r->$name( $init undef );$cmt\n";
 164         }
 165         elsif( $type =~ /^\w+(?:::\w+)*$/ ){
 166             $out .= "    if (defined(\$init{'$name'})) {\n";
 167            $out .= "       if (ref \$init{'$name'} eq 'HASH')\n";
 168             $out .= "            { \$r->$name( $type->new(\%{\$init{'$name'}}) ) } $cmt\n";
 169            $out .= "       elsif (UNIVERSAL::isa(\$init{'$name'}, '$type'))\n";
 170             $out .= "            { \$r->$name( \$init{'$name'} ) } $cmt\n";
 171             $out .= "       else { croak 'Initializer for $name must be hash or $type reference' }\n";
 172             $out .= "    }\n";
 173             $classes{$name} = $type;
 174             $got_class = 1;
 175         }
 176         else{
 177             croak "'$type' is not a valid struct element type";
 178         }
 179         $idx += 2;
 180     }
 181
 182     $out .= "\n \$r;\n}\n";
 183
 184     # Create accessor methods.
 185
 186     my( $pre, $pst, $sel );
 187     $cnt = 0;
 188     foreach $name (@methods){
 189         if ( do { no strict 'refs'; defined &{$class . "::$name"} } ) {
 190             warnings::warnif("function '$name' already defined, overrides struct accessor method");
 191         }
 192         else {
 193             $pre = $pst = $cmt = $sel = '';
 194             if( defined $refs{$name} ){
 195                 $pre = "\\(";
 196                 $pst = ")";
 197                 $cmt = " # returns ref";
 198             }
 199             $out .= "  sub $name {$cmt\n    my \$r = shift;\n";
 200             if( $base_type eq 'ARRAY' ){
 201                 $elem = "[$cnt]";
 202                 ++$cnt;
 203             }
 204             elsif( $base_type eq 'HASH' ){
 205                 $elem = "{'${class}::$name'}";
 206             }
 207             if( defined $arrays{$name} ){
 208                 $out .= "    my \$i;\n";
 209                 $out .= "    \@_ ? (\$i = shift) : return \$r->$elem;\n";
 210                 $out .= "    if (ref(\$i) eq 'ARRAY' && !\@_) { \$r->$elem = \$i; return \$r }\n";
 211                 $sel = "->[\$i]";
 212             }
 213             elsif( defined $hashes{$name} ){
 214                 $out .= "    my \$i;\n";
 215                 $out .= "    \@_ ? (\$i = shift) : return \$r->$elem;\n";
 216                 $out .= "    if (ref(\$i) eq 'HASH' && !\@_) { \$r->$elem = \$i; return \$r }\n";
 217                 $sel = "->{\$i}";
 218             }
 219             elsif( defined $classes{$name} ){
 220                 $out .= "    croak '$name argument is wrong class' if \@_ && ! UNIVERSAL::isa(\$_[0], '$classes{$name}');\n";
 221             }
 222             $out .= "    croak 'Too many args to $name' if \@_ > 1;\n";
 223             $out .= "    \@_ ? ($pre\$r->$elem$sel = shift$pst) : $pre\$r->$elem$sel$pst;\n";
 224             $out .= "  }\n";
 225         }
 226     }
 227     $out .= "}\n1;\n";
 228
 229     print $out if $print;
 230     my $result = eval $out;
 231     carp $@ if $@;
 232 }
 233
 234 sub _usage_error {
 235     confess "struct usage error";
 236 }
 237
 238 sub _subclass_error {
 239     croak 'struct class cannot be a subclass (@ISA not allowed)';
 240 }
 241
 242 1; # for require
 243
 244
 245 __END__
 246
 247 =head1 NAME
 248
 249 Class::Struct - declare struct-like datatypes as Perl classes
 250
 251 =head1 SYNOPSIS
 252
 253     use Class::Struct;
 254             # declare struct, based on array:
 255     struct( CLASS_NAME => [ ELEMENT_NAME => ELEMENT_TYPE, ... ]);
 256             # declare struct, based on hash:
 257     struct( CLASS_NAME => { ELEMENT_NAME => ELEMENT_TYPE, ... });
 258
 259     package CLASS_NAME;
 260     use Class::Struct;
 261             # declare struct, based on array, implicit class name:
 262     struct( ELEMENT_NAME => ELEMENT_TYPE, ... );
 263
 264     # Declare struct at compile time
 265     use Class::Struct CLASS_NAME => [ELEMENT_NAME => ELEMENT_TYPE, ...];
 266     use Class::Struct CLASS_NAME => {ELEMENT_NAME => ELEMENT_TYPE, ...};
 267
 268     # declare struct at compile time, based on array, implicit
 269     # class name:
 270     package CLASS_NAME;
 271     use Class::Struct ELEMENT_NAME => ELEMENT_TYPE, ... ;
 272
 273     package Myobj;
 274     use Class::Struct;
 275             # declare struct with four types of elements:
 276     struct( s => '$', a => '@', h => '%', c => 'My_Other_Class' );
 277
 278     $obj = new Myobj;               # constructor
 279
 280                                     # scalar type accessor:
 281     $element_value = $obj->s;           # element value
 282     $obj->s('new value');               # assign to element
 283
 284                                     # array type accessor:
 285     $ary_ref = $obj->a;                 # reference to whole array
 286     $ary_element_value = $obj->a(2);    # array element value
 287     $obj->a(2, 'new value');            # assign to array element
 288
 289                                     # hash type accessor:
 290     $hash_ref = $obj->h;                # reference to whole hash
 291     $hash_element_value = $obj->h('x'); # hash element value
 292     $obj->h('x', 'new value');          # assign to hash element
 293
 294                                     # class type accessor:
 295     $element_value = $obj->c;           # object reference
 296     $obj->c->method(...);               # call method of object
 297     $obj->c(new My_Other_Class);        # assign a new object
 298
 299 =head1 DESCRIPTION
 300
 301 C<Class::Struct> exports a single function, C<struct>.
 302 Given a list of element names and types, and optionally
 303 a class name, C<struct> creates a Perl 5 class that implements
 304 a "struct-like" data structure.
 305
 306 The new class is given a constructor method, C<new>, for creating
 307 struct objects.
 308
 309 Each element in the struct data has an accessor method, which is
 310 used to assign to the element and to fetch its value.  The
 311 default accessor can be overridden by declaring a C<sub> of the
 312 same name in the package.  (See Example 2.)
 313
 314 Each element's type can be scalar, array, hash, or class.
 315
 316 =head2 The C<struct()> function
 317
 318 The C<struct> function has three forms of parameter-list.
 319
 320     struct( CLASS_NAME => [ ELEMENT_LIST ]);
 321     struct( CLASS_NAME => { ELEMENT_LIST });
 322     struct( ELEMENT_LIST );
 323
 324 The first and second forms explicitly identify the name of the
 325 class being created.  The third form assumes the current package
 326 name as the class name.
 327
 328 An object of a class created by the first and third forms is
 329 based on an array, whereas an object of a class created by the
 330 second form is based on a hash. The array-based forms will be
 331 somewhat faster and smaller; the hash-based forms are more
 332 flexible.
 333
 334 The class created by C<struct> must not be a subclass of another
 335 class other than C<UNIVERSAL>.
 336
 337 It can, however, be used as a superclass for other classes. To facilitate
 338 this, the generated constructor method uses a two-argument blessing.
 339 Furthermore, if the class is hash-based, the key of each element is
 340 prefixed with the class name (see I<Perl Cookbook>, Recipe 13.12).
 341
 342 A function named C<new> must not be explicitly defined in a class
 343 created by C<struct>.
 344
 345 The I<ELEMENT_LIST> has the form
 346
 347     NAME => TYPE, ...
 348
 349 Each name-type pair declares one element of the struct. Each
 350 element name will be defined as an accessor method unless a
 351 method by that name is explicitly defined; in the latter case, a
 352 warning is issued if the warning flag (B<-w>) is set.
 353
 354 =head2 Class Creation at Compile Time
 355
 356 C<Class::Struct> can create your class at compile time.  The main reason
 357 for doing this is obvious, so your class acts like every other class in
 358 Perl.  Creating your class at compile time will make the order of events
 359 similar to using any other class ( or Perl module ).
 360
 361 There is no significant speed gain between compile time and run time
 362 class creation, there is just a new, more standard order of events.
 363
 364 =head2 Element Types and Accessor Methods
 365
 366 The four element types -- scalar, array, hash, and class -- are
 367 represented by strings -- C<'$'>, C<'@'>, C<'%'>, and a class name --
 368 optionally preceded by a C<'*'>.
 369
 370 The accessor method provided by C<struct> for an element depends
 371 on the declared type of the element.
 372
 373 =over 4
 374
 375 =item Scalar (C<'$'> or C<'*$'>)
 376
 377 The element is a scalar, and by default is initialized to C<undef>
 378 (but see L<Initializing with new>).
 379
 380 The accessor's argument, if any, is assigned to the element.
 381
 382 If the element type is C<'$'>, the value of the element (after
 383 assignment) is returned. If the element type is C<'*$'>, a reference
 384 to the element is returned.
 385
 386 =item Array (C<'@'> or C<'*@'>)
 387
 388 The element is an array, initialized by default to C<()>.
 389
 390 With no argument, the accessor returns a reference to the
 391 element's whole array (whether or not the element was
 392 specified as C<'@'> or C<'*@'>).
 393
 394 With one or two arguments, the first argument is an index
 395 specifying one element of the array; the second argument, if
 396 present, is assigned to the array element.  If the element type
 397 is C<'@'>, the accessor returns the array element value.  If the
 398 element type is C<'*@'>, a reference to the array element is
 399 returned.
 400
 401 As a special case, when the accessor is called with an array reference
 402 as the sole argument, this causes an assignment of the whole array element.
 403 The object reference is returned.
 404
 405 =item Hash (C<'%'> or C<'*%'>)
 406
 407 The element is a hash, initialized by default to C<()>.
 408
 409 With no argument, the accessor returns a reference to the
 410 element's whole hash (whether or not the element was
 411 specified as C<'%'> or C<'*%'>).
 412
 413 With one or two arguments, the first argument is a key specifying
 414 one element of the hash; the second argument, if present, is
 415 assigned to the hash element.  If the element type is C<'%'>, the
 416 accessor returns the hash element value.  If the element type is
 417 C<'*%'>, a reference to the hash element is returned.
 418
 419 As a special case, when the accessor is called with a hash reference
 420 as the sole argument, this causes an assignment of the whole hash element.
 421 The object reference is returned.
 422
 423 =item Class (C<'Class_Name'> or C<'*Class_Name'>)
 424
 425 The element's value must be a reference blessed to the named
 426 class or to one of its subclasses. The element is not initialized
 427 by default.
 428
 429 The accessor's argument, if any, is assigned to the element. The
 430 accessor will C<croak> if this is not an appropriate object
 431 reference.
 432
 433 If the element type does not start with a C<'*'>, the accessor
 434 returns the element value (after assignment). If the element type
 435 starts with a C<'*'>, a reference to the element itself is returned.
 436
 437 =back
 438
 439 =head2 Initializing with C<new>
 440
 441 C<struct> always creates a constructor called C<new>. That constructor
 442 may take a list of initializers for the various elements of the new
 443 struct.
 444
 445 Each initializer is a pair of values: I<element name>C< =E<gt> >I<value>.
 446 The initializer value for a scalar element is just a scalar value. The
 447 initializer for an array element is an array reference. The initializer
 448 for a hash is a hash reference.
 449
 450 The initializer for a class element is an object of the corresponding class,
 451 or of one of it's subclasses, or a reference to a hash containing named
 452 arguments to be passed to the element's constructor.
 453
 454 See Example 3 below for an example of initialization.
 455
 456 =head1 EXAMPLES
 457
 458 =over 4
 459
 460 =item Example 1
 461
 462 Giving a struct element a class type that is also a struct is how
 463 structs are nested.  Here, C<Timeval> represents a time (seconds and
 464 microseconds), and C<Rusage> has two elements, each of which is of
 465 type C<Timeval>.
 466
 467     use Class::Struct;
 468
 469     struct( Rusage => {
 470         ru_utime => 'Timeval',  # user time used
 471         ru_stime => 'Timeval',  # system time used
 472     });
 473
 474     struct( Timeval => [
 475         tv_secs  => '$',        # seconds
 476         tv_usecs => '$',        # microseconds
 477     ]);
 478
 479     # create an object:
 480     my $t = Rusage->new(ru_utime=>Timeval->new(),
 481         ru_stime=>Timeval->new());
 482
 483     # $t->ru_utime and $t->ru_stime are objects of type Timeval.
 484     # set $t->ru_utime to 100.0 sec and $t->ru_stime to 5.0 sec.
 485     $t->ru_utime->tv_secs(100);
 486     $t->ru_utime->tv_usecs(0);
 487     $t->ru_stime->tv_secs(5);
 488     $t->ru_stime->tv_usecs(0);
 489
 490 =item Example 2
 491
 492 An accessor function can be redefined in order to provide
 493 additional checking of values, etc.  Here, we want the C<count>
 494 element always to be nonnegative, so we redefine the C<count>
 495 accessor accordingly.
 496
 497     package MyObj;
 498     use Class::Struct;
 499
 500     # declare the struct
 501     struct ( 'MyObj', { count => '$', stuff => '%' } );
 502
 503     # override the default accessor method for 'count'
 504     sub count {
 505         my $self = shift;
 506         if ( @_ ) {
 507             die 'count must be nonnegative' if $_[0] < 0;
 508             $self->{'MyObj::count'} = shift;
 509             warn "Too many args to count" if @_;
 510         }
 511         return $self->{'MyObj::count'};
 512     }
 513
 514     package main;
 515     $x = new MyObj;
 516     print "\$x->count(5) = ", $x->count(5), "\n";
 517                             # prints '$x->count(5) = 5'
 518
 519     print "\$x->count = ", $x->count, "\n";
 520                             # prints '$x->count = 5'
 521
 522     print "\$x->count(-5) = ", $x->count(-5), "\n";
 523                             # dies due to negative argument!
 524
 525 =item Example 3
 526
 527 The constructor of a generated class can be passed a list
 528 of I<element>=>I<value> pairs, with which to initialize the struct.
 529 If no initializer is specified for a particular element, its default
 530 initialization is performed instead. Initializers for non-existent
 531 elements are silently ignored.
 532
 533 Note that the initializer for a nested class may be specified as
 534 an object of that class, or as a reference to a hash of initializers
 535 that are passed on to the nested struct's constructor.
 536
 537     use Class::Struct;
 538
 539     struct Breed =>
 540     {
 541         name  => '$',
 542         cross => '$',
 543     };
 544
 545     struct Cat =>
 546     [
 547         name     => '$',
 548         kittens  => '@',
 549         markings => '%',
 550         breed    => 'Breed',
 551     ];
 552
 553
 554     my $cat = Cat->new( name => 'Socks',
 555                kittens  => ['Monica', 'Kenneth'],
 556                markings => { socks=>1, blaze=>"white" },
 557                breed    => Breed->new(name=>'short-hair', cross=>1),
 558           or:  breed    => {name=>'short-hair', cross=>1},
 559                       );
 560
 561     print "Once a cat called ", $cat->name, "\n";
 562     print "(which was a ", $cat->breed->name, ")\n";
 563     print "had 2 kittens: ", join(' and ', @{$cat->kittens}), "\n";
 564
 565 =back
 566
 567 =head1 Author and Modification History
 568
 569 Modified by Damian Conway, 2001-09-10, v0.62.
 570
 571    Modified implicit construction of nested objects.
 572    Now will also take an object ref instead of requiring a hash ref.
 573    Also default initializes nested object attributes to undef, rather
 574    than calling object constructor without args
 575    Original over-helpfulness was fraught with problems:
 576        * the class's constructor might not be called 'new'
 577        * the class might not have a hash-like-arguments constructor
 578        * the class might not have a no-argument constructor
 579        * "recursive" data structures didn't work well:
 580                  package Person;
 581                  struct { mother => 'Person', father => 'Person'};
 582
 583
 584 Modified by Casey West, 2000-11-08, v0.59.
 585
 586     Added the ability for compile time class creation.
 587
 588 Modified by Damian Conway, 1999-03-05, v0.58.
 589
 590     Added handling of hash-like arg list to class ctor.
 591
 592     Changed to two-argument blessing in ctor to support
 593     derivation from created classes.
 594
 595     Added classname prefixes to keys in hash-based classes
 596     (refer to "Perl Cookbook", Recipe 13.12 for rationale).
 597
 598     Corrected behaviour of accessors for '*@' and '*%' struct
 599     elements.  Package now implements documented behaviour when
 600     returning a reference to an entire hash or array element.
 601     Previously these were returned as a reference to a reference
 602     to the element.
 603
 604 Renamed to C<Class::Struct> and modified by Jim Miner, 1997-04-02.
 605
 606     members() function removed.
 607     Documentation corrected and extended.
 608     Use of struct() in a subclass prohibited.
 609     User definition of accessor allowed.
 610     Treatment of '*' in element types corrected.
 611     Treatment of classes as element types corrected.
 612     Class name to struct() made optional.
 613     Diagnostic checks added.
 614
 615 Originally C<Class::Template> by Dean Roehrich.
 616
 617     # Template.pm   --- struct/member template builder
 618     #   12mar95
 619     #   Dean Roehrich
 620     #
 621     # changes/bugs fixed since 28nov94 version:
 622     #  - podified
 623     # changes/bugs fixed since 21nov94 version:
 624     #  - Fixed examples.
 625     # changes/bugs fixed since 02sep94 version:
 626     #  - Moved to Class::Template.
 627     # changes/bugs fixed since 20feb94 version:
 628     #  - Updated to be a more proper module.
 629     #  - Added "use strict".
 630     #  - Bug in build_methods, was using @var when @$var needed.
 631     #  - Now using my() rather than local().
 632     #
 633     # Uses perl5 classes to create nested data types.
 634     # This is offered as one implementation of Tom Christiansen's
 635     # "structs.pl" idea.
 636
 637 =cut