3 perlmod - Perl modules (packages and symbol tables)
8 X<package> X<namespace> X<variable, global> X<global variable> X<global>
10 Perl provides a mechanism for alternative namespaces to protect
11 packages from stomping on each other's variables. In fact, there's
12 really no such thing as a global variable in Perl. The package
13 statement declares the compilation unit as being in the given
14 namespace. The scope of the package declaration is from the
15 declaration itself through the end of the enclosing block, C<eval>,
16 or file, whichever comes first (the same scope as the my() and
17 local() operators). Unqualified dynamic identifiers will be in
18 this namespace, except for those few identifiers that if unqualified,
19 default to the main package instead of the current one as described
20 below. A package statement affects only dynamic variables--including
21 those you've used local() on--but I<not> lexical variables created
22 with my(). Typically it would be the first declaration in a file
23 included by the C<do>, C<require>, or C<use> operators. You can
24 switch into a package in more than one place; it merely influences
25 which symbol table is used by the compiler for the rest of that
26 block. You can refer to variables and filehandles in other packages
27 by prefixing the identifier with the package name and a double
28 colon: C<$Package::Variable>. If the package name is null, the
29 C<main> package is assumed. That is, C<$::sail> is equivalent to
32 The old package delimiter was a single quote, but double colon is now the
33 preferred delimiter, in part because it's more readable to humans, and
34 in part because it's more readable to B<emacs> macros. It also makes C++
35 programmers feel like they know what's going on--as opposed to using the
36 single quote as separator, which was there to make Ada programmers feel
37 like they knew what was going on. Because the old-fashioned syntax is still
38 supported for backwards compatibility, if you try to use a string like
39 C<"This is $owner's house">, you'll be accessing C<$owner::s>; that is,
40 the $s variable in package C<owner>, which is probably not what you meant.
41 Use braces to disambiguate, as in C<"This is ${owner}'s house">.
44 Packages may themselves contain package separators, as in
45 C<$OUTER::INNER::var>. This implies nothing about the order of
46 name lookups, however. There are no relative packages: all symbols
47 are either local to the current package, or must be fully qualified
48 from the outer package name down. For instance, there is nowhere
49 within package C<OUTER> that C<$INNER::var> refers to
50 C<$OUTER::INNER::var>. C<INNER> refers to a totally
51 separate global package.
53 Only identifiers starting with letters (or underscore) are stored
54 in a package's symbol table. All other symbols are kept in package
55 C<main>, including all punctuation variables, like $_. In addition,
56 when unqualified, the identifiers STDIN, STDOUT, STDERR, ARGV,
57 ARGVOUT, ENV, INC, and SIG are forced to be in package C<main>,
58 even when used for other purposes than their built-in ones. If you
59 have a package called C<m>, C<s>, or C<y>, then you can't use the
60 qualified form of an identifier because it would be instead interpreted
61 as a pattern match, a substitution, or a transliteration.
62 X<variable, punctuation>
64 Variables beginning with underscore used to be forced into package
65 main, but we decided it was more useful for package writers to be able
66 to use leading underscore to indicate private variables and method names.
67 However, variables and functions named with a single C<_>, such as
68 $_ and C<sub _>, are still forced into the package C<main>. See also
69 L<perlvar/"Technical Note on the Syntax of Variable Names">.
71 C<eval>ed strings are compiled in the package in which the eval() was
72 compiled. (Assignments to C<$SIG{}>, however, assume the signal
73 handler specified is in the C<main> package. Qualify the signal handler
74 name if you wish to have a signal handler in a package.) For an
75 example, examine F<perldb.pl> in the Perl library. It initially switches
76 to the C<DB> package so that the debugger doesn't interfere with variables
77 in the program you are trying to debug. At various points, however, it
78 temporarily switches back to the C<main> package to evaluate various
79 expressions in the context of the C<main> package (or wherever you came
80 from). See L<perldebug>.
82 The special symbol C<__PACKAGE__> contains the current package, but cannot
83 (easily) be used to construct variable names.
85 See L<perlsub> for other scoping issues related to my() and local(),
86 and L<perlref> regarding closures.
89 X<symbol table> X<stash> X<%::> X<%main::> X<typeglob> X<glob> X<alias>
91 The symbol table for a package happens to be stored in the hash of that
92 name with two colons appended. The main symbol table's name is thus
93 C<%main::>, or C<%::> for short. Likewise the symbol table for the nested
94 package mentioned earlier is named C<%OUTER::INNER::>.
96 The value in each entry of the hash is what you are referring to when you
97 use the C<*name> typeglob notation.
99 local *main::foo = *main::bar;
101 You can use this to print out all the variables in a package, for
102 instance. The standard but antiquated F<dumpvar.pl> library and
103 the CPAN module Devel::Symdump make use of this.
105 Assignment to a typeglob performs an aliasing operation, i.e.,
109 causes variables, subroutines, formats, and file and directory handles
110 accessible via the identifier C<richard> also to be accessible via the
111 identifier C<dick>. If you want to alias only a particular variable or
112 subroutine, assign a reference instead:
116 Which makes $richard and $dick the same variable, but leaves
117 @richard and @dick as separate arrays. Tricky, eh?
119 There is one subtle difference between the following statements:
124 C<*foo = *bar> makes the typeglobs themselves synonymous while
125 C<*foo = \$bar> makes the SCALAR portions of two distinct typeglobs
126 refer to the same scalar value. This means that the following code:
129 *foo = \$bar; # Make $foo an alias for $bar
132 local $bar = 2; # Restrict changes to block
133 print $foo; # Prints '1'!
136 Would print '1', because C<$foo> holds a reference to the I<original>
137 C<$bar>. The one that was stuffed away by C<local()> and which will be
138 restored when the block ends. Because variables are accessed through the
139 typeglob, you can use C<*foo = *bar> to create an alias which can be
140 localized. (But be aware that this means you can't have a separate
141 C<@foo> and C<@bar>, etc.)
143 What makes all of this important is that the Exporter module uses glob
144 aliasing as the import/export mechanism. Whether or not you can properly
145 localize a variable that has been exported from a module depends on how
148 @EXPORT = qw($FOO); # Usual form, can't be localized
149 @EXPORT = qw(*FOO); # Can be localized
151 You can work around the first case by using the fully qualified name
152 (C<$Package::FOO>) where you need a local value, or by overriding it
153 by saying C<*FOO = *Package::FOO> in your script.
155 The C<*x = \$y> mechanism may be used to pass and return cheap references
156 into or from subroutines if you don't want to copy the whole
157 thing. It only works when assigning to dynamic variables, not
160 %some_hash = (); # can't be my()
161 *some_hash = fn( \%another_hash );
163 local *hashsym = shift;
164 # now use %hashsym normally, and you
165 # will affect the caller's %another_hash
166 my %nhash = (); # do what you want
170 On return, the reference will overwrite the hash slot in the
171 symbol table specified by the *some_hash typeglob. This
172 is a somewhat tricky way of passing around references cheaply
173 when you don't want to have to remember to dereference variables
176 Another use of symbol tables is for making "constant" scalars.
177 X<constant> X<scalar, constant>
179 *PI = \3.14159265358979;
181 Now you cannot alter C<$PI>, which is probably a good thing all in all.
182 This isn't the same as a constant subroutine, which is subject to
183 optimization at compile-time. A constant subroutine is one prototyped
184 to take no arguments and to return a constant expression. See
185 L<perlsub> for details on these. The C<use constant> pragma is a
186 convenient shorthand for these.
188 You can say C<*foo{PACKAGE}> and C<*foo{NAME}> to find out what name and
189 package the *foo symbol table entry comes from. This may be useful
190 in a subroutine that gets passed typeglobs as arguments:
192 sub identify_typeglob {
194 print 'You gave me ', *{$glob}{PACKAGE}, '::', *{$glob}{NAME}, "\n";
196 identify_typeglob *foo;
197 identify_typeglob *bar::baz;
201 You gave me main::foo
204 The C<*foo{THING}> notation can also be used to obtain references to the
205 individual elements of *foo. See L<perlref>.
207 Subroutine definitions (and declarations, for that matter) need
208 not necessarily be situated in the package whose symbol table they
209 occupy. You can define a subroutine outside its package by
210 explicitly qualifying the name of the subroutine:
213 sub Some_package::foo { ... } # &foo defined in Some_package
215 This is just a shorthand for a typeglob assignment at compile time:
217 BEGIN { *Some_package::foo = sub { ... } }
219 and is I<not> the same as writing:
222 package Some_package;
226 In the first two versions, the body of the subroutine is
227 lexically in the main package, I<not> in Some_package. So
232 $Some_package::name = "fred";
233 $main::name = "barney";
235 sub Some_package::foo {
236 print "in ", __PACKAGE__, ": \$name is '$name'\n";
243 in main: $name is 'barney'
247 in Some_package: $name is 'fred'
249 This also has implications for the use of the SUPER:: qualifier
252 =head2 BEGIN, UNITCHECK, CHECK, INIT and END
253 X<BEGIN> X<UNITCHECK> X<CHECK> X<INIT> X<END>
255 Five specially named code blocks are executed at the beginning and at
256 the end of a running Perl program. These are the C<BEGIN>,
257 C<UNITCHECK>, C<CHECK>, C<INIT>, and C<END> blocks.
259 These code blocks can be prefixed with C<sub> to give the appearance of a
260 subroutine (although this is not considered good style). One should note
261 that these code blocks don't really exist as named subroutines (despite
262 their appearance). The thing that gives this away is the fact that you can
263 have B<more than one> of these code blocks in a program, and they will get
264 B<all> executed at the appropriate moment. So you can't execute any of
265 these code blocks by name.
267 A C<BEGIN> code block is executed as soon as possible, that is, the moment
268 it is completely defined, even before the rest of the containing file (or
269 string) is parsed. You may have multiple C<BEGIN> blocks within a file (or
270 eval'ed string); they will execute in order of definition. Because a C<BEGIN>
271 code block executes immediately, it can pull in definitions of subroutines
272 and such from other files in time to be visible to the rest of the compile
273 and run time. Once a C<BEGIN> has run, it is immediately undefined and any
274 code it used is returned to Perl's memory pool.
276 An C<END> code block is executed as late as possible, that is, after
277 perl has finished running the program and just before the interpreter
278 is being exited, even if it is exiting as a result of a die() function.
279 (But not if it's morphing into another program via C<exec>, or
280 being blown out of the water by a signal--you have to trap that yourself
281 (if you can).) You may have multiple C<END> blocks within a file--they
282 will execute in reverse order of definition; that is: last in, first
283 out (LIFO). C<END> blocks are not executed when you run perl with the
284 C<-c> switch, or if compilation fails.
286 Note that C<END> code blocks are B<not> executed at the end of a string
287 C<eval()>: if any C<END> code blocks are created in a string C<eval()>,
288 they will be executed just as any other C<END> code block of that package
289 in LIFO order just before the interpreter is being exited.
291 Inside an C<END> code block, C<$?> contains the value that the program is
292 going to pass to C<exit()>. You can modify C<$?> to change the exit
293 value of the program. Beware of changing C<$?> by accident (e.g. by
294 running something via C<system>).
297 Inside of a C<END> block, the value of C<${^GLOBAL_PHASE}> will be
300 C<UNITCHECK>, C<CHECK> and C<INIT> code blocks are useful to catch the
301 transition between the compilation phase and the execution phase of
304 C<UNITCHECK> blocks are run just after the unit which defined them has
305 been compiled. The main program file and each module it loads are
306 compilation units, as are string C<eval>s, code compiled using the
307 C<(?{ })> construct in a regex, calls to C<do FILE>, C<require FILE>,
308 and code after the C<-e> switch on the command line.
310 C<BEGIN> and C<UNITCHECK> blocks are not directly related to the phase of
311 the interpreter. They can be created and executed during any phase.
313 C<CHECK> code blocks are run just after the B<initial> Perl compile phase ends
314 and before the run time begins, in LIFO order. C<CHECK> code blocks are used
315 in the Perl compiler suite to save the compiled state of the program.
317 Inside of a C<CHECK> block, the value of C<${^GLOBAL_PHASE}> will be
320 C<INIT> blocks are run just before the Perl runtime begins execution, in
321 "first in, first out" (FIFO) order.
323 Inside of an C<INIT> block, the value of C<${^GLOBAL_PHASE}> will be C<"INIT">.
325 The C<CHECK> and C<INIT> blocks in code compiled by C<require>, string C<do>,
326 or string C<eval> will not be executed if they occur after the end of the
327 main compilation phase; that can be a problem in mod_perl and other persistent
328 environments which use those functions to load code at runtime.
330 When you use the B<-n> and B<-p> switches to Perl, C<BEGIN> and
331 C<END> work just as they do in B<awk>, as a degenerate case.
332 Both C<BEGIN> and C<CHECK> blocks are run when you use the B<-c>
333 switch for a compile-only syntax check, although your main code
336 The B<begincheck> program makes it all clear, eventually:
342 print "10. Ordinary code runs at runtime.\n";
344 END { print "16. So this is the end of the tale.\n" }
345 INIT { print " 7. INIT blocks run FIFO just before runtime.\n" }
347 print " 4. And therefore before any CHECK blocks.\n"
349 CHECK { print " 6. So this is the sixth line.\n" }
351 print "11. It runs in order, of course.\n";
353 BEGIN { print " 1. BEGIN blocks run FIFO during compilation.\n" }
354 END { print "15. Read perlmod for the rest of the story.\n" }
355 CHECK { print " 5. CHECK blocks run LIFO after all compilation.\n" }
356 INIT { print " 8. Run this again, using Perl's -c switch.\n" }
358 print "12. This is anti-obfuscated code.\n";
360 END { print "14. END blocks run LIFO at quitting time.\n" }
361 BEGIN { print " 2. So this line comes out second.\n" }
363 print " 3. UNITCHECK blocks run LIFO after each file is compiled.\n"
365 INIT { print " 9. You'll see the difference right away.\n" }
367 print "13. It merely _looks_ like it should be confusing.\n";
374 There is no special class syntax in Perl, but a package may act
375 as a class if it provides subroutines to act as methods. Such a
376 package may also derive some of its methods from another class (package)
377 by listing the other package name(s) in its global @ISA array (which
378 must be a package global, not a lexical).
380 For more on this, see L<perltoot> and L<perlobj>.
385 A module is just a set of related functions in a library file, i.e.,
386 a Perl package with the same name as the file. It is specifically
387 designed to be reusable by other modules or programs. It may do this
388 by providing a mechanism for exporting some of its symbols into the
389 symbol table of any package using it, or it may function as a class
390 definition and make its semantics available implicitly through
391 method calls on the class and its objects, without explicitly
392 exporting anything. Or it can do a little of both.
394 For example, to start a traditional, non-OO module called Some::Module,
395 create a file called F<Some/Module.pm> and start with this template:
397 package Some::Module; # assumes Some/Module.pm
404 our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
406 # set the version for version checking
408 # if using RCS/CVS, this may be preferred
409 $VERSION = sprintf "%d.%03d", q$Revision: 1.1 $ =~ /(\d+)/g;
412 @EXPORT = qw(&func1 &func2 &func4);
413 %EXPORT_TAGS = ( ); # eg: TAG => [ qw!name1 name2! ],
415 # your exported package globals go here,
416 # as well as any optionally exported functions
417 @EXPORT_OK = qw($Var1 %Hashit &func3);
421 # exported package globals go here
425 # non-exported package globals go here
429 # initialize package globals, first exported ones
433 # then the others (which are still accessible as $Some::Module::stuff)
437 # all file-scoped lexicals must be created before
438 # the functions below that use them.
440 # file-private lexicals go here
442 my %secret_hash = ();
444 # here's a file-private function as a closure,
445 # callable as &$priv_func; it cannot be prototyped.
446 my $priv_func = sub {
450 # make all your functions, whether exported or not;
451 # remember to put something interesting in the {} stubs
452 sub func1 {} # no prototype
453 sub func2() {} # proto'd void
454 sub func3($$) {} # proto'd to 2 scalars
456 # this one isn't exported, but could be called!
457 sub func4(\%) {} # proto'd to 1 hash ref
459 END { } # module clean-up code here (global destructor)
461 ## YOUR CODE GOES HERE
463 1; # don't forget to return a true value from the file
465 Then go on to declare and use your variables in functions without
466 any qualifications. See L<Exporter> and the L<perlmodlib> for
467 details on mechanics and style issues in module creation.
469 Perl modules are included into your program by saying
477 This is exactly equivalent to
479 BEGIN { require Module; import Module; }
483 BEGIN { require Module; import Module LIST; }
489 is exactly equivalent to
491 BEGIN { require Module; }
493 All Perl module files have the extension F<.pm>. The C<use> operator
494 assumes this so you don't have to spell out "F<Module.pm>" in quotes.
495 This also helps to differentiate new modules from old F<.pl> and
496 F<.ph> files. Module names are also capitalized unless they're
497 functioning as pragmas; pragmas are in effect compiler directives,
498 and are sometimes called "pragmatic modules" (or even "pragmata"
499 if you're a classicist).
504 require "SomeModule.pm";
506 differ from each other in two ways. In the first case, any double
507 colons in the module name, such as C<Some::Module>, are translated
508 into your system's directory separator, usually "/". The second
509 case does not, and would have to be specified literally. The other
510 difference is that seeing the first C<require> clues in the compiler
511 that uses of indirect object notation involving "SomeModule", as
512 in C<$ob = purge SomeModule>, are method calls, not function calls.
513 (Yes, this really can make a difference.)
515 Because the C<use> statement implies a C<BEGIN> block, the importing
516 of semantics happens as soon as the C<use> statement is compiled,
517 before the rest of the file is compiled. This is how it is able
518 to function as a pragma mechanism, and also how modules are able to
519 declare subroutines that are then visible as list or unary operators for
520 the rest of the current file. This will not work if you use C<require>
521 instead of C<use>. With C<require> you can get into this problem:
523 require Cwd; # make Cwd:: accessible
524 $here = Cwd::getcwd();
526 use Cwd; # import names from Cwd::
529 require Cwd; # make Cwd:: accessible
530 $here = getcwd(); # oops! no main::getcwd()
532 In general, C<use Module ()> is recommended over C<require Module>,
533 because it determines module availability at compile time, not in the
534 middle of your program's execution. An exception would be if two modules
535 each tried to C<use> each other, and each also called a function from
536 that other module. In that case, it's easy to use C<require> instead.
538 Perl packages may be nested inside other package names, so we can have
539 package names containing C<::>. But if we used that package name
540 directly as a filename it would make for unwieldy or impossible
541 filenames on some systems. Therefore, if a module's name is, say,
542 C<Text::Soundex>, then its definition is actually found in the library
543 file F<Text/Soundex.pm>.
545 Perl modules always have a F<.pm> file, but there may also be
546 dynamically linked executables (often ending in F<.so>) or autoloaded
547 subroutine definitions (often ending in F<.al>) associated with the
548 module. If so, these will be entirely transparent to the user of
549 the module. It is the responsibility of the F<.pm> file to load
550 (or arrange to autoload) any additional functionality. For example,
551 although the POSIX module happens to do both dynamic loading and
552 autoloading, the user can say just C<use POSIX> to get it all.
554 =head2 Making your module threadsafe
555 X<threadsafe> X<thread safe>
556 X<module, threadsafe> X<module, thread safe>
557 X<CLONE> X<CLONE_SKIP> X<thread> X<threads> X<ithread>
559 Since 5.6.0, Perl has had support for a new type of threads called
560 interpreter threads (ithreads). These threads can be used explicitly
563 Ithreads work by cloning the data tree so that no data is shared
564 between different threads. These threads can be used by using the C<threads>
565 module or by doing fork() on win32 (fake fork() support). When a
566 thread is cloned all Perl data is cloned, however non-Perl data cannot
567 be cloned automatically. Perl after 5.7.2 has support for the C<CLONE>
568 special subroutine. In C<CLONE> you can do whatever
570 like for example handle the cloning of non-Perl data, if necessary.
571 C<CLONE> will be called once as a class method for every package that has it
572 defined (or inherits it). It will be called in the context of the new thread,
573 so all modifications are made in the new area. Currently CLONE is called with
574 no parameters other than the invocand package name, but code should not assume
575 that this will remain unchanged, as it is likely that in future extra parameters
576 will be passed in to give more information about the state of cloning.
578 If you want to CLONE all objects you will need to keep track of them per
579 package. This is simply done using a hash and Scalar::Util::weaken().
581 Perl after 5.8.7 has support for the C<CLONE_SKIP> special subroutine.
582 Like C<CLONE>, C<CLONE_SKIP> is called once per package; however, it is
583 called just before cloning starts, and in the context of the parent
584 thread. If it returns a true value, then no objects of that class will
585 be cloned; or rather, they will be copied as unblessed, undef values.
586 For example: if in the parent there are two references to a single blessed
587 hash, then in the child there will be two references to a single undefined
588 scalar value instead.
589 This provides a simple mechanism for making a module threadsafe; just add
590 C<sub CLONE_SKIP { 1 }> at the top of the class, and C<DESTROY()> will
591 now only be called once per object. Of course, if the child thread needs
592 to make use of the objects, then a more sophisticated approach is
595 Like C<CLONE>, C<CLONE_SKIP> is currently called with no parameters other
596 than the invocand package name, although that may change. Similarly, to
597 allow for future expansion, the return value should be a single C<0> or
602 See L<perlmodlib> for general style issues related to building Perl
603 modules and classes, as well as descriptions of the standard library
604 and CPAN, L<Exporter> for how Perl's standard import/export mechanism
605 works, L<perltoot> and L<perltooc> for an in-depth tutorial on
606 creating classes, L<perlobj> for a hard-core reference document on
607 objects, L<perlsub> for an explanation of functions and scoping,
608 and L<perlxstut> and L<perlguts> for more information on writing