pod/perlfaq5.pod

   1 =head1 NAME
   2
   3 perlfaq5 - Files and Formats
   4
   5 =head1 DESCRIPTION
   6
   7 This section deals with I/O and the "f" issues: filehandles, flushing,
   8 formats, and footers.
   9
  10 =head2 How do I flush/unbuffer an output filehandle?  Why must I do this?
  11 X<flush> X<buffer> X<unbuffer> X<autoflush>
  12
  13 (contributed by brian d foy)
  14
  15 You might like to read Mark Jason Dominus's "Suffering From Buffering"
  16 at http://perl.plover.com/FAQs/Buffering.html .
  17
  18 Perl normally buffers output so it doesn't make a system call for every
  19 bit of output. By saving up output, it makes fewer expensive system calls.
  20 For instance, in this little bit of code, you want to print a dot to the
  21 screen for every line you process to watch the progress of your program.
  22 Instead of seeing a dot for every line, Perl buffers the output and you
  23 have a long wait before you see a row of 50 dots all at once:
  24
  25         # long wait, then row of dots all at once
  26         while( <> ) {
  27                 print ".";
  28                 print "\n" unless ++$count % 50;
  29
  30                 #... expensive line processing operations
  31                 }
  32
  33 To get around this, you have to unbuffer the output filehandle, in this
  34 case, C<STDOUT>. You can set the special variable C<$|> to a true value
  35 (mnemonic: making your filehandles "piping hot"):
  36
  37         $|++;
  38
  39         # dot shown immediately
  40         while( <> ) {
  41                 print ".";
  42                 print "\n" unless ++$count % 50;
  43
  44                 #... expensive line processing operations
  45                 }
  46
  47 The C<$|> is one of the per-filehandle special variables, so each
  48 filehandle has its own copy of its value. If you want to merge
  49 standard output and standard error for instance, you have to unbuffer
  50 each (although STDERR might be unbuffered by default):
  51
  52         {
  53         my $previous_default = select(STDOUT);  # save previous default
  54         $|++;                                   # autoflush STDOUT
  55         select(STDERR);
  56         $|++;                                   # autoflush STDERR, to be sure
  57         select($previous_default);              # restore previous default
  58         }
  59
  60         # now should alternate . and +
  61         while( 1 )
  62                 {
  63                 sleep 1;
  64                 print STDOUT ".";
  65                 print STDERR "+";
  66                 print STDOUT "\n" unless ++$count % 25;
  67                 }
  68
  69 Besides the C<$|> special variable, you can use C<binmode> to give
  70 your filehandle a C<:unix> layer, which is unbuffered:
  71
  72         binmode( STDOUT, ":unix" );
  73
  74         while( 1 ) {
  75                 sleep 1;
  76                 print ".";
  77                 print "\n" unless ++$count % 50;
  78                 }
  79
  80 For more information on output layers, see the entries for C<binmode>
  81 and C<open> in L<perlfunc>, and the C<PerlIO> module documentation.
  82
  83 If you are using C<IO::Handle> or one of its subclasses, you can
  84 call the C<autoflush> method to change the settings of the
  85 filehandle:
  86
  87         use IO::Handle;
  88         open my( $io_fh ), ">", "output.txt";
  89         $io_fh->autoflush(1);
  90
  91 The C<IO::Handle> objects also have a C<flush> method. You can flush
  92 the buffer any time you want without auto-buffering
  93
  94         $io_fh->flush;
  95
  96 =head2 How do I change, delete, or insert a line in a file, or append to the beginning of a file?
  97 X<file, editing>
  98
  99 (contributed by brian d foy)
 100
 101 The basic idea of inserting, changing, or deleting a line from a text
 102 file involves reading and printing the file to the point you want to
 103 make the change, making the change, then reading and printing the rest
 104 of the file. Perl doesn't provide random access to lines (especially
 105 since the record input separator, C<$/>, is mutable), although modules
 106 such as C<Tie::File> can fake it.
 107
 108 A Perl program to do these tasks takes the basic form of opening a
 109 file, printing its lines, then closing the file:
 110
 111         open my $in,  '<',  $file      or die "Can't read old file: $!";
 112         open my $out, '>', "$file.new" or die "Can't write new file: $!";
 113
 114         while( <$in> )
 115                 {
 116                 print $out $_;
 117                 }
 118
 119    close $out;
 120
 121 Within that basic form, add the parts that you need to insert, change,
 122 or delete lines.
 123
 124 To prepend lines to the beginning, print those lines before you enter
 125 the loop that prints the existing lines.
 126
 127         open my $in,  '<',  $file      or die "Can't read old file: $!";
 128         open my $out, '>', "$file.new" or die "Can't write new file: $!";
 129
 130         print $out "# Add this line to the top\n"; # <--- HERE'S THE MAGIC
 131
 132         while( <$in> )
 133                 {
 134                 print $out $_;
 135                 }
 136
 137    close $out;
 138
 139 To change existing lines, insert the code to modify the lines inside
 140 the C<while> loop. In this case, the code finds all lowercased
 141 versions of "perl" and uppercases them. The happens for every line, so
 142 be sure that you're supposed to do that on every line!
 143
 144         open my $in,  '<',  $file      or die "Can't read old file: $!";
 145         open my $out, '>', "$file.new" or die "Can't write new file: $!";
 146
 147         print $out "# Add this line to the top\n";
 148
 149         while( <$in> )
 150                 {
 151                 s/\b(perl)\b/Perl/g;
 152                 print $out $_;
 153                 }
 154
 155    close $out;
 156
 157 To change only a particular line, the input line number, C<$.>, is
 158 useful. First read and print the lines up to the one you  want to
 159 change. Next, read the single line you want to change, change it, and
 160 print it. After that, read the rest of the lines and print those:
 161
 162         while( <$in> )   # print the lines before the change
 163                 {
 164                 print $out $_;
 165                 last if $. == 4; # line number before change
 166                 }
 167
 168         my $line = <$in>;
 169         $line =~ s/\b(perl)\b/Perl/g;
 170         print $out $line;
 171
 172         while( <$in> )   # print the rest of the lines
 173                 {
 174                 print $out $_;
 175                 }
 176
 177 To skip lines, use the looping controls. The C<next> in this example
 178 skips comment lines, and the C<last> stops all processing once it
 179 encounters either C<__END__> or C<__DATA__>.
 180
 181         while( <$in> )
 182                 {
 183                 next if /^\s+#/;             # skip comment lines
 184                 last if /^__(END|DATA)__$/;  # stop at end of code marker
 185                 print $out $_;
 186                 }
 187
 188 Do the same sort of thing to delete a particular line by using C<next>
 189 to skip the lines you don't want to show up in the output. This
 190 example skips every fifth line:
 191
 192         while( <$in> )
 193                 {
 194                 next unless $. % 5;
 195                 print $out $_;
 196                 }
 197
 198 If, for some odd reason, you really want to see the whole file at once
 199 rather than processing line-by-line, you can slurp it in (as long as
 200 you can fit the whole thing in memory!):
 201
 202         open my $in,  '<',  $file      or die "Can't read old file: $!"
 203         open my $out, '>', "$file.new" or die "Can't write new file: $!";
 204
 205         my @lines = do { local $/; <$in> }; # slurp!
 206
 207                 # do your magic here
 208
 209         print $out @lines;
 210
 211 Modules such as C<File::Slurp> and C<Tie::File> can help with that
 212 too. If you can, however, avoid reading the entire file at once. Perl
 213 won't give that memory back to the operating system until the process
 214 finishes.
 215
 216 You can also use Perl one-liners to modify a file in-place. The
 217 following changes all 'Fred' to 'Barney' in F<inFile.txt>, overwriting
 218 the file with the new contents. With the C<-p> switch, Perl wraps a
 219 C<while> loop around the code you specify with C<-e>, and C<-i> turns
 220 on in-place editing. The current line is in C<$_>. With C<-p>, Perl
 221 automatically prints the value of C<$_> at the end of the loop. See
 222 L<perlrun> for more details.
 223
 224         perl -pi -e 's/Fred/Barney/' inFile.txt
 225
 226 To make a backup of C<inFile.txt>, give C<-i> a file extension to add:
 227
 228         perl -pi.bak -e 's/Fred/Barney/' inFile.txt
 229
 230 To change only the fifth line, you can add a test checking C<$.>, the
 231 input line number, then only perform the operation when the test
 232 passes:
 233
 234         perl -pi -e 's/Fred/Barney/ if $. == 5' inFile.txt
 235
 236 To add lines before a certain line, you can add a line (or lines!)
 237 before Perl prints C<$_>:
 238
 239         perl -pi -e 'print "Put before third line\n" if $. == 3' inFile.txt
 240
 241 You can even add a line to the beginning of a file, since the current
 242 line prints at the end of the loop:
 243
 244         perl -pi -e 'print "Put before first line\n" if $. == 1' inFile.txt
 245
 246 To insert a line after one already in the file, use the C<-n> switch.
 247 It's just like C<-p> except that it doesn't print C<$_> at the end of
 248 the loop, so you have to do that yourself. In this case, print C<$_>
 249 first, then print the line that you want to add.
 250
 251         perl -ni -e 'print; print "Put after fifth line\n" if $. == 5' inFile.txt
 252
 253 To delete lines, only print the ones that you want.
 254
 255         perl -ni -e 'print unless /d/' inFile.txt
 256
 257                 ... or ...
 258
 259         perl -pi -e 'next unless /d/' inFile.txt
 260
 261 =head2 How do I count the number of lines in a file?
 262 X<file, counting lines> X<lines> X<line>
 263
 264 (contributed by brian d foy)
 265
 266 Conceptually, the easiest way to count the lines in a file is to
 267 simply read them and count them:
 268
 269         my $count = 0;
 270         while( <$fh> ) { $count++; }
 271
 272 You don't really have to count them yourself, though, since Perl
 273 already does that with the C<$.> variable, which is the current line
 274 number from the last filehandle read:
 275
 276         1 while( <$fh> );
 277         my $count = $.;
 278
 279 If you want to use C<$.>, you can reduce it to a simple one-liner,
 280 like one of these:
 281
 282         % perl -lne '} print $.; {'    file
 283
 284         % perl -lne 'END { print $. }' file
 285
 286 Those can be rather inefficient though. If they aren't fast enough for
 287 you, you might just read chunks of data and count the number of
 288 newlines:
 289
 290         my $lines = 0;
 291         open my($fh), '<:raw', $filename or die "Can't open $filename: $!";
 292         while( sysread $fh, $buffer, 4096 ) {
 293                 $lines += ( $buffer =~ tr/\n// );
 294                 }
 295         close FILE;
 296
 297 However, that doesn't work if the line ending isn't a newline. You
 298 might change that C<tr///> to a C<s///> so you can count the number of
 299 times the input record separator, C<$/>, shows up:
 300
 301         my $lines = 0;
 302         open my($fh), '<:raw', $filename or die "Can't open $filename: $!";
 303         while( sysread $fh, $buffer, 4096 ) {
 304                 $lines += ( $buffer =~ s|$/||g; );
 305                 }
 306         close FILE;
 307
 308 If you don't mind shelling out, the C<wc> command is usually the
 309 fastest, even with the extra interprocess overhead. Ensure that you
 310 have an untainted filename though:
 311
 312         #!perl -T
 313
 314         $ENV{PATH} = undef;
 315
 316         my $lines;
 317         if( $filename =~ /^([0-9a-z_.]+)\z/ ) {
 318                 $lines = `/usr/bin/wc -l $1`
 319                 chomp $lines;
 320                 }
 321
 322 =head2 How do I delete the last N lines from a file?
 323 X<lines> X<file>
 324
 325 (contributed by brian d foy)
 326
 327 The easiest conceptual solution is to count the lines in the
 328 file then start at the beginning and print the number of lines
 329 (minus the last N) to a new file.
 330
 331 Most often, the real question is how you can delete the last N lines
 332 without making more than one pass over the file, or how to do it
 333 without a lot of copying. The easy concept is the hard reality when
 334 you might have millions of lines in your file.
 335
 336 One trick is to use C<File::ReadBackwards>, which starts at the end of
 337 the file. That module provides an object that wraps the real filehandle
 338 to make it easy for you to move around the file. Once you get to the
 339 spot you need, you can get the actual filehandle and work with it as
 340 normal. In this case, you get the file position at the end of the last
 341 line you want to keep and truncate the file to that point:
 342
 343         use File::ReadBackwards;
 344
 345         my $filename = 'test.txt';
 346         my $Lines_to_truncate = 2;
 347
 348         my $bw = File::ReadBackwards->new( $filename )
 349                 or die "Could not read backwards in [$filename]: $!";
 350
 351         my $lines_from_end = 0;
 352         until( $bw->eof or $lines_from_end == $Lines_to_truncate )
 353                 {
 354                 print "Got: ", $bw->readline;
 355                 $lines_from_end++;
 356                 }
 357
 358         truncate( $filename, $bw->tell );
 359
 360 The C<File::ReadBackwards> module also has the advantage of setting
 361 the input record separator to a regular expression.
 362
 363 You can also use the C<Tie::File> module which lets you access
 364 the lines through a tied array. You can use normal array operations
 365 to modify your file, including setting the last index and using
 366 C<splice>.
 367
 368 =head2 How can I use Perl's C<-i> option from within a program?
 369 X<-i> X<in-place>
 370
 371 C<-i> sets the value of Perl's C<$^I> variable, which in turn affects
 372 the behavior of C<< <> >>; see L<perlrun> for more details. By
 373 modifying the appropriate variables directly, you can get the same
 374 behavior within a larger program. For example:
 375
 376         # ...
 377         {
 378         local($^I, @ARGV) = ('.orig', glob("*.c"));
 379         while (<>) {
 380                 if ($. == 1) {
 381                         print "This line should appear at the top of each file\n";
 382                 }
 383                 s/\b(p)earl\b/${1}erl/i;        # Correct typos, preserving case
 384                 print;
 385                 close ARGV if eof;              # Reset $.
 386                 }
 387         }
 388         # $^I and @ARGV return to their old values here
 389
 390 This block modifies all the C<.c> files in the current directory,
 391 leaving a backup of the original data from each file in a new
 392 C<.c.orig> file.
 393
 394 =head2 How can I copy a file?
 395 X<copy> X<file, copy> X<File::Copy>
 396
 397 (contributed by brian d foy)
 398
 399 Use the C<File::Copy> module. It comes with Perl and can do a
 400 true copy across file systems, and it does its magic in
 401 a portable fashion.
 402
 403         use File::Copy;
 404
 405         copy( $original, $new_copy ) or die "Copy failed: $!";
 406
 407 If you can't use C<File::Copy>, you'll have to do the work yourself:
 408 open the original file, open the destination file, then print
 409 to the destination file as you read the original. You also have to
 410 remember to copy the permissions, owner, and group to the new file.
 411
 412 =head2 How do I make a temporary file name?
 413 X<file, temporary>
 414
 415 If you don't need to know the name of the file, you can use C<open()>
 416 with C<undef> in place of the file name. In Perl 5.8 or later, the
 417 C<open()> function creates an anonymous temporary file:
 418
 419         open my $tmp, '+>', undef or die $!;
 420
 421 Otherwise, you can use the File::Temp module.
 422
 423         use File::Temp qw/ tempfile tempdir /;
 424
 425         my $dir = tempdir( CLEANUP => 1 );
 426         ($fh, $filename) = tempfile( DIR => $dir );
 427
 428         # or if you don't need to know the filename
 429
 430         my $fh = tempfile( DIR => $dir );
 431
 432 The File::Temp has been a standard module since Perl 5.6.1. If you
 433 don't have a modern enough Perl installed, use the C<new_tmpfile>
 434 class method from the IO::File module to get a filehandle opened for
 435 reading and writing. Use it if you don't need to know the file's name:
 436
 437         use IO::File;
 438         my $fh = IO::File->new_tmpfile()
 439                 or die "Unable to make new temporary file: $!";
 440
 441 If you're committed to creating a temporary file by hand, use the
 442 process ID and/or the current time-value. If you need to have many
 443 temporary files in one process, use a counter:
 444
 445         BEGIN {
 446         use Fcntl;
 447         my $temp_dir = -d '/tmp' ? '/tmp' : $ENV{TMPDIR} || $ENV{TEMP};
 448         my $base_name = sprintf "%s/%d-%d-0000", $temp_dir, $$, time;
 449
 450         sub temp_file {
 451                 my $fh;
 452                 my $count = 0;
 453                 until( defined(fileno($fh)) || $count++ > 100 ) {
 454                         $base_name =~ s/-(\d+)$/"-" . (1 + $1)/e;
 455                         # O_EXCL is required for security reasons.
 456                         sysopen $fh, $base_name, O_WRONLY|O_EXCL|O_CREAT;
 457                         }
 458
 459                 if( defined fileno($fh) ) {
 460                         return ($fh, $base_name);
 461                         }
 462                 else {
 463                         return ();
 464                         }
 465                 }
 466
 467         }
 468
 469 =head2 How can I manipulate fixed-record-length files?
 470 X<fixed-length> X<file, fixed-length records>
 471
 472 The most efficient way is using L<pack()|perlfunc/"pack"> and
 473 L<unpack()|perlfunc/"unpack">. This is faster than using
 474 L<substr()|perlfunc/"substr"> when taking many, many strings. It is
 475 slower for just a few.
 476
 477 Here is a sample chunk of code to break up and put back together again
 478 some fixed-format input lines, in this case from the output of a normal,
 479 Berkeley-style ps:
 480
 481         # sample input line:
 482         #   15158 p5  T      0:00 perl /home/tchrist/scripts/now-what
 483         my $PS_T = 'A6 A4 A7 A5 A*';
 484         open my $ps, '-|', 'ps';
 485         print scalar <$ps>;
 486         my @fields = qw( pid tt stat time command );
 487         while (<$ps>) {
 488                 my %process;
 489                 @process{@fields} = unpack($PS_T, $_);
 490         for my $field ( @fields ) {
 491                 print "$field: <$process{$field}>\n";
 492         }
 493         print 'line=', pack($PS_T, @process{@fields} ), "\n";
 494         }
 495
 496 We've used a hash slice in order to easily handle the fields of each row.
 497 Storing the keys in an array means it's easy to operate on them as a
 498 group or loop over them with for. It also avoids polluting the program
 499 with global variables and using symbolic references.
 500
 501 =head2 How can I make a filehandle local to a subroutine?  How do I pass filehandles between subroutines?  How do I make an array of filehandles?
 502 X<filehandle, local> X<filehandle, passing> X<filehandle, reference>
 503
 504 As of perl5.6, open() autovivifies file and directory handles
 505 as references if you pass it an uninitialized scalar variable.
 506 You can then pass these references just like any other scalar,
 507 and use them in the place of named handles.
 508
 509         open my    $fh, $file_name;
 510
 511         open local $fh, $file_name;
 512
 513         print $fh "Hello World!\n";
 514
 515         process_file( $fh );
 516
 517 If you like, you can store these filehandles in an array or a hash.
 518 If you access them directly, they aren't simple scalars and you
 519 need to give C<print> a little help by placing the filehandle
 520 reference in braces. Perl can only figure it out on its own when
 521 the filehandle reference is a simple scalar.
 522
 523         my @fhs = ( $fh1, $fh2, $fh3 );
 524
 525         for( $i = 0; $i <= $#fhs; $i++ ) {
 526                 print {$fhs[$i]} "just another Perl answer, \n";
 527                 }
 528
 529 Before perl5.6, you had to deal with various typeglob idioms
 530 which you may see in older code.
 531
 532         open FILE, "> $filename";
 533         process_typeglob(   *FILE );
 534         process_reference( \*FILE );
 535
 536         sub process_typeglob  { local *FH = shift; print FH  "Typeglob!" }
 537         sub process_reference { local $fh = shift; print $fh "Reference!" }
 538
 539 If you want to create many anonymous handles, you should
 540 check out the Symbol or IO::Handle modules.
 541
 542 =head2 How can I use a filehandle indirectly?
 543 X<filehandle, indirect>
 544
 545 An indirect filehandle is using something other than a symbol
 546 in a place that a filehandle is expected. Here are ways
 547 to get indirect filehandles:
 548
 549         $fh =   SOME_FH;       # bareword is strict-subs hostile
 550         $fh =  "SOME_FH";      # strict-refs hostile; same package only
 551         $fh =  *SOME_FH;       # typeglob
 552         $fh = \*SOME_FH;       # ref to typeglob (bless-able)
 553         $fh =  *SOME_FH{IO};   # blessed IO::Handle from *SOME_FH typeglob
 554
 555 Or, you can use the C<new> method from one of the IO::* modules to
 556 create an anonymous filehandle, store that in a scalar variable,
 557 and use it as though it were a normal filehandle.
 558
 559         use IO::Handle;                     # 5.004 or higher
 560         my $fh = IO::Handle->new();
 561
 562 Then use any of those as you would a normal filehandle. Anywhere that
 563 Perl is expecting a filehandle, an indirect filehandle may be used
 564 instead. An indirect filehandle is just a scalar variable that contains
 565 a filehandle. Functions like C<print>, C<open>, C<seek>, or
 566 the C<< <FH> >> diamond operator will accept either a named filehandle
 567 or a scalar variable containing one:
 568
 569         ($ifh, $ofh, $efh) = (*STDIN, *STDOUT, *STDERR);
 570         print $ofh "Type it: ";
 571         my $got = <$ifh>
 572         print $efh "What was that: $got";
 573
 574 If you're passing a filehandle to a function, you can write
 575 the function in two ways:
 576
 577         sub accept_fh {
 578                 my $fh = shift;
 579                 print $fh "Sending to indirect filehandle\n";
 580         }
 581
 582 Or it can localize a typeglob and use the filehandle directly:
 583
 584         sub accept_fh {
 585                 local *FH = shift;
 586                 print  FH "Sending to localized filehandle\n";
 587         }
 588
 589 Both styles work with either objects or typeglobs of real filehandles.
 590 (They might also work with strings under some circumstances, but this
 591 is risky.)
 592
 593         accept_fh(*STDOUT);
 594         accept_fh($handle);
 595
 596 In the examples above, we assigned the filehandle to a scalar variable
 597 before using it. That is because only simple scalar variables, not
 598 expressions or subscripts of hashes or arrays, can be used with
 599 built-ins like C<print>, C<printf>, or the diamond operator. Using
 600 something other than a simple scalar variable as a filehandle is
 601 illegal and won't even compile:
 602
 603         my @fd = (*STDIN, *STDOUT, *STDERR);
 604         print $fd[1] "Type it: ";                           # WRONG
 605         my $got = <$fd[0]>                                  # WRONG
 606         print $fd[2] "What was that: $got";                 # WRONG
 607
 608 With C<print> and C<printf>, you get around this by using a block and
 609 an expression where you would place the filehandle:
 610
 611         print  { $fd[1] } "funny stuff\n";
 612         printf { $fd[1] } "Pity the poor %x.\n", 3_735_928_559;
 613         # Pity the poor deadbeef.
 614
 615 That block is a proper block like any other, so you can put more
 616 complicated code there. This sends the message out to one of two places:
 617
 618         my $ok = -x "/bin/cat";
 619         print { $ok ? $fd[1] : $fd[2] } "cat stat $ok\n";
 620         print { $fd[ 1+ ($ok || 0) ]  } "cat stat $ok\n";
 621
 622 This approach of treating C<print> and C<printf> like object methods
 623 calls doesn't work for the diamond operator. That's because it's a
 624 real operator, not just a function with a comma-less argument. Assuming
 625 you've been storing typeglobs in your structure as we did above, you
 626 can use the built-in function named C<readline> to read a record just
 627 as C<< <> >> does. Given the initialization shown above for @fd, this
 628 would work, but only because readline() requires a typeglob. It doesn't
 629 work with objects or strings, which might be a bug we haven't fixed yet.
 630
 631         $got = readline($fd[0]);
 632
 633 Let it be noted that the flakiness of indirect filehandles is not
 634 related to whether they're strings, typeglobs, objects, or anything else.
 635 It's the syntax of the fundamental operators. Playing the object
 636 game doesn't help you at all here.
 637
 638 =head2 How can I set up a footer format to be used with write()?
 639 X<footer>
 640
 641 There's no builtin way to do this, but L<perlform> has a couple of
 642 techniques to make it possible for the intrepid hacker.
 643
 644 =head2 How can I write() into a string?
 645 X<write, into a string>
 646
 647 (contributed by brian d foy)
 648
 649 If you want to C<write> into a string, you just have to <open> a
 650 filehandle to a string, which Perl has been able to do since Perl 5.6:
 651
 652         open FH, '>', \my $string;
 653         write( FH );
 654
 655 Since you want to be a good programmer, you probably want to use a lexical
 656 filehandle, even though formats are designed to work with bareword filehandles
 657 since the default format names take the filehandle name. However, you can
 658 control this with some Perl special per-filehandle variables: C<$^>, which
 659 names the top-of-page format, and C<$~> which shows the line format. You have
 660 to change the default filehandle to set these variables:
 661
 662         open my($fh), '>', \my $string;
 663
 664         { # set per-filehandle variables
 665         my $old_fh = select( $fh );
 666         $~ = 'ANIMAL';
 667         $^ = 'ANIMAL_TOP';
 668         select( $old_fh );
 669         }
 670
 671         format ANIMAL_TOP =
 672          ID  Type    Name
 673         .
 674
 675         format ANIMAL =
 676         @##   @<<<    @<<<<<<<<<<<<<<
 677         $id,  $type,  $name
 678         .
 679
 680 Although write can work with lexical or package variables, whatever variables
 681 you use have to scope in the format. That most likely means you'll want to
 682 localize some package variables:
 683
 684         {
 685         local( $id, $type, $name ) = qw( 12 cat Buster );
 686         write( $fh );
 687         }
 688
 689         print $string;
 690
 691 There are also some tricks that you can play with C<formline> and the
 692 accumulator variable C<$^A>, but you lose a lot of the value of formats
 693 since C<formline> won't handle paging and so on. You end up reimplementing
 694 formats when you use them.
 695
 696 =head2 How can I open a filehandle to a string?
 697 X<string> X<open> X<IO::String> X<filehandle>
 698
 699 (contributed by Peter J. Holzer, hjp-usenet2@hjp.at)
 700
 701 Since Perl 5.8.0 a file handle referring to a string can be created by
 702 calling open with a reference to that string instead of the filename.
 703 This file handle can then be used to read from or write to the string:
 704
 705         open(my $fh, '>', \$string) or die "Could not open string for writing";
 706         print $fh "foo\n";
 707         print $fh "bar\n";      # $string now contains "foo\nbar\n"
 708
 709         open(my $fh, '<', \$string) or die "Could not open string for reading";
 710         my $x = <$fh>;  # $x now contains "foo\n"
 711
 712 With older versions of Perl, the C<IO::String> module provides similar
 713 functionality.
 714
 715 =head2 How can I output my numbers with commas added?
 716 X<number, commify>
 717
 718 (contributed by brian d foy and Benjamin Goldberg)
 719
 720 You can use L<Number::Format> to separate places in a number.
 721 It handles locale information for those of you who want to insert
 722 full stops instead (or anything else that they want to use,
 723 really).
 724
 725 This subroutine will add commas to your number:
 726
 727         sub commify {
 728                 local $_  = shift;
 729                 1 while s/^([-+]?\d+)(\d{3})/$1,$2/;
 730                 return $_;
 731                 }
 732
 733 This regex from Benjamin Goldberg will add commas to numbers:
 734
 735         s/(^[-+]?\d+?(?=(?>(?:\d{3})+)(?!\d))|\G\d{3}(?=\d))/$1,/g;
 736
 737 It is easier to see with comments:
 738
 739         s/(
 740                 ^[-+]?             # beginning of number.
 741                 \d+?               # first digits before first comma
 742                 (?=                # followed by, (but not included in the match) :
 743                         (?>(?:\d{3})+) # some positive multiple of three digits.
 744                         (?!\d)         # an *exact* multiple, not x * 3 + 1 or whatever.
 745                 )
 746                 |                  # or:
 747                 \G\d{3}            # after the last group, get three digits
 748                 (?=\d)             # but they have to have more digits after them.
 749         )/$1,/xg;
 750
 751 =head2 How can I translate tildes (~) in a filename?
 752 X<tilde> X<tilde expansion>
 753
 754 Use the E<lt>E<gt> (C<glob()>) operator, documented in L<perlfunc>.
 755 Versions of Perl older than 5.6 require that you have a shell
 756 installed that groks tildes. Later versions of Perl have this feature
 757 built in. The C<File::KGlob> module (available from CPAN) gives more
 758 portable glob functionality.
 759
 760 Within Perl, you may use this directly:
 761
 762         $filename =~ s{
 763           ^ ~             # find a leading tilde
 764           (               # save this in $1
 765               [^/]        # a non-slash character
 766                     *     # repeated 0 or more times (0 means me)
 767           )
 768         }{
 769           $1
 770               ? (getpwnam($1))[7]
 771               : ( $ENV{HOME} || $ENV{LOGDIR} )
 772         }ex;
 773
 774 =head2 How come when I open a file read-write it wipes it out?
 775 X<clobber> X<read-write> X<clobbering> X<truncate> X<truncating>
 776
 777 Because you're using something like this, which truncates the file
 778 I<then> gives you read-write access:
 779
 780         open my $fh, '+>', '/path/name'; # WRONG (almost always)
 781
 782 Whoops. You should instead use this, which will fail if the file
 783 doesn't exist:
 784
 785         open my $fh, '+<', '/path/name'; # open for update
 786
 787 Using ">" always clobbers or creates. Using "<" never does
 788 either. The "+" doesn't change this.
 789
 790 Here are examples of many kinds of file opens. Those using C<sysopen>
 791 all assume that you've pulled in the constants from C<Fcntl>:
 792
 793         use Fcntl;
 794
 795 To open file for reading:
 796
 797         open my $fh, '<', $path                               or die $!;
 798         sysopen my $fh, $path, O_RDONLY                       or die $!;
 799
 800 To open file for writing, create new file if needed or else truncate old file:
 801
 802         open my $fh, '>', $path                               or die $!;
 803         sysopen my $fh, $path, O_WRONLY|O_TRUNC|O_CREAT       or die $!;
 804         sysopen my $fh, $path, O_WRONLY|O_TRUNC|O_CREAT, 0666 or die $!;
 805
 806 To open file for writing, create new file, file must not exist:
 807
 808         sysopen my $fh, $path, O_WRONLY|O_EXCL|O_CREAT        or die $!;
 809         sysopen my $fh, $path, O_WRONLY|O_EXCL|O_CREAT, 0666  or die $!;
 810
 811 To open file for appending, create if necessary:
 812
 813         open my $fh, '>>' $path                               or die $!;
 814         sysopen my $fh, $path, O_WRONLY|O_APPEND|O_CREAT      or die $!;
 815         sysopen my $fh, $path, O_WRONLY|O_APPEND|O_CREAT, 0666 or die $!;
 816
 817 To open file for appending, file must exist:
 818
 819         sysopen my $fh, $path, O_WRONLY|O_APPEND              or die $!;
 820
 821 To open file for update, file must exist:
 822
 823         open my $fh, '+<', $path                              or die $!;
 824         sysopen my $fh, $path, O_RDWR                         or die $!;
 825
 826 To open file for update, create file if necessary:
 827
 828         sysopen my $fh, $path, O_RDWR|O_CREAT                 or die $!;
 829         sysopen my $fh, $path, O_RDWR|O_CREAT, 0666           or die $!;
 830
 831 To open file for update, file must not exist:
 832
 833         sysopen my $fh, $path, O_RDWR|O_EXCL|O_CREAT          or die $!;
 834         sysopen my $fh, $path, O_RDWR|O_EXCL|O_CREAT, 0666    or die $!;
 835
 836 To open a file without blocking, creating if necessary:
 837
 838         sysopen my $fh, '/foo/somefile', O_WRONLY|O_NDELAY|O_CREAT
 839             or die "can't open /foo/somefile: $!":
 840
 841 Be warned that neither creation nor deletion of files is guaranteed to
 842 be an atomic operation over NFS. That is, two processes might both
 843 successfully create or unlink the same file! Therefore O_EXCL
 844 isn't as exclusive as you might wish.
 845
 846 See also the new L<perlopentut>.
 847
 848 =head2 Why do I sometimes get an "Argument list too long" when I use E<lt>*E<gt>?
 849 X<argument list too long>
 850
 851 The C<< <> >> operator performs a globbing operation (see above).
 852 In Perl versions earlier than v5.6.0, the internal glob() operator forks
 853 csh(1) to do the actual glob expansion, but
 854 csh can't handle more than 127 items and so gives the error message
 855 C<Argument list too long>. People who installed tcsh as csh won't
 856 have this problem, but their users may be surprised by it.
 857
 858 To get around this, either upgrade to Perl v5.6.0 or later, do the glob
 859 yourself with readdir() and patterns, or use a module like File::KGlob,
 860 one that doesn't use the shell to do globbing.
 861
 862 =head2 Is there a leak/bug in glob()?
 863 X<glob>
 864
 865 (contributed by brian d foy)
 866
 867 Starting with Perl 5.6.0, C<glob> is implemented internally rather
 868 than relying on an external resource. As such, memory issues with
 869 C<glob> aren't a problem in modern perls.
 870
 871 =head2 How can I open a file with a leading ">" or trailing blanks?
 872 X<filename, special characters>
 873
 874 (contributed by Brian McCauley)
 875
 876 The special two argument form of Perl's open() function ignores
 877 trailing blanks in filenames and infers the mode from certain leading
 878 characters (or a trailing "|"). In older versions of Perl this was the
 879 only version of open() and so it is prevalent in old code and books.
 880
 881 Unless you have a particular reason to use the two argument form you
 882 should use the three argument form of open() which does not treat any
 883 characters in the filename as special.
 884
 885         open my $fh, "<", "  file  ";  # filename is "   file   "
 886         open my $fh, ">", ">file";     # filename is ">file"
 887
 888 =head2 How can I reliably rename a file?
 889 X<rename> X<mv> X<move> X<file, rename>
 890
 891 If your operating system supports a proper mv(1) utility or its
 892 functional equivalent, this works:
 893
 894         rename($old, $new) or system("mv", $old, $new);
 895
 896 It may be more portable to use the C<File::Copy> module instead.
 897 You just copy to the new file to the new name (checking return
 898 values), then delete the old one. This isn't really the same
 899 semantically as a C<rename()>, which preserves meta-information like
 900 permissions, timestamps, inode info, etc.
 901
 902 =head2 How can I lock a file?
 903 X<lock> X<file, lock> X<flock>
 904
 905 Perl's builtin flock() function (see L<perlfunc> for details) will call
 906 flock(2) if that exists, fcntl(2) if it doesn't (on perl version 5.004 and
 907 later), and lockf(3) if neither of the two previous system calls exists.
 908 On some systems, it may even use a different form of native locking.
 909 Here are some gotchas with Perl's flock():
 910
 911 =over 4
 912
 913 =item 1
 914
 915 Produces a fatal error if none of the three system calls (or their
 916 close equivalent) exists.
 917
 918 =item 2
 919
 920 lockf(3) does not provide shared locking, and requires that the
 921 filehandle be open for writing (or appending, or read/writing).
 922
 923 =item 3
 924
 925 Some versions of flock() can't lock files over a network (e.g. on NFS file
 926 systems), so you'd need to force the use of fcntl(2) when you build Perl.
 927 But even this is dubious at best. See the flock entry of L<perlfunc>
 928 and the F<INSTALL> file in the source distribution for information on
 929 building Perl to do this.
 930
 931 Two potentially non-obvious but traditional flock semantics are that
 932 it waits indefinitely until the lock is granted, and that its locks are
 933 I<merely advisory>. Such discretionary locks are more flexible, but
 934 offer fewer guarantees. This means that files locked with flock() may
 935 be modified by programs that do not also use flock(). Cars that stop
 936 for red lights get on well with each other, but not with cars that don't
 937 stop for red lights. See the perlport manpage, your port's specific
 938 documentation, or your system-specific local manpages for details. It's
 939 best to assume traditional behavior if you're writing portable programs.
 940 (If you're not, you should as always feel perfectly free to write
 941 for your own system's idiosyncrasies (sometimes called "features").
 942 Slavish adherence to portability concerns shouldn't get in the way of
 943 your getting your job done.)
 944
 945 For more information on file locking, see also
 946 L<perlopentut/"File Locking"> if you have it (new for 5.6).
 947
 948 =back
 949
 950 =head2 Why can't I just open(FH, "E<gt>file.lock")?
 951 X<lock, lockfile race condition>
 952
 953 A common bit of code B<NOT TO USE> is this:
 954
 955         sleep(3) while -e 'file.lock';  # PLEASE DO NOT USE
 956         open my $lock, '>', 'file.lock'; # THIS BROKEN CODE
 957
 958 This is a classic race condition: you take two steps to do something
 959 which must be done in one. That's why computer hardware provides an
 960 atomic test-and-set instruction. In theory, this "ought" to work:
 961
 962         sysopen my $fh, "file.lock", O_WRONLY|O_EXCL|O_CREAT
 963                 or die "can't open  file.lock: $!";
 964
 965 except that lamentably, file creation (and deletion) is not atomic
 966 over NFS, so this won't work (at least, not every time) over the net.
 967 Various schemes involving link() have been suggested, but
 968 these tend to involve busy-wait, which is also less than desirable.
 969
 970 =head2 I still don't get locking. I just want to increment the number in the file. How can I do this?
 971 X<counter> X<file, counter>
 972
 973 Didn't anyone ever tell you web-page hit counters were useless?
 974 They don't count number of hits, they're a waste of time, and they serve
 975 only to stroke the writer's vanity. It's better to pick a random number;
 976 they're more realistic.
 977
 978 Anyway, this is what you can do if you can't help yourself.
 979
 980         use Fcntl qw(:DEFAULT :flock);
 981         sysopen my $fh, "numfile", O_RDWR|O_CREAT or die "can't open numfile: $!";
 982         flock $fh, LOCK_EX                        or die "can't flock numfile: $!";
 983         my $num = <$fh> || 0;
 984         seek $fh, 0, 0                            or die "can't rewind numfile: $!";
 985         truncate $fh, 0                           or die "can't truncate numfile: $!";
 986         (print $fh $num+1, "\n")                  or die "can't write numfile: $!";
 987         close $fh                                 or die "can't close numfile: $!";
 988
 989 Here's a much better web-page hit counter:
 990
 991         $hits = int( (time() - 850_000_000) / rand(1_000) );
 992
 993 If the count doesn't impress your friends, then the code might. :-)
 994
 995 =head2 All I want to do is append a small amount of text to the end of a file. Do I still have to use locking?
 996 X<append> X<file, append>
 997
 998 If you are on a system that correctly implements C<flock> and you use
 999 the example appending code from "perldoc -f flock" everything will be
1000 OK even if the OS you are on doesn't implement append mode correctly
1001 (if such a system exists.) So if you are happy to restrict yourself to
1002 OSs that implement C<flock> (and that's not really much of a
1003 restriction) then that is what you should do.
1004
1005 If you know you are only going to use a system that does correctly
1006 implement appending (i.e. not Win32) then you can omit the C<seek>
1007 from the code in the previous answer.
1008
1009 If you know you are only writing code to run on an OS and filesystem
1010 that does implement append mode correctly (a local filesystem on a
1011 modern Unix for example), and you keep the file in block-buffered mode
1012 and you write less than one buffer-full of output between each manual
1013 flushing of the buffer then each bufferload is almost guaranteed to be
1014 written to the end of the file in one chunk without getting
1015 intermingled with anyone else's output. You can also use the
1016 C<syswrite> function which is simply a wrapper around your system's
1017 C<write(2)> system call.
1018
1019 There is still a small theoretical chance that a signal will interrupt
1020 the system level C<write()> operation before completion. There is also
1021 a possibility that some STDIO implementations may call multiple system
1022 level C<write()>s even if the buffer was empty to start. There may be
1023 some systems where this probability is reduced to zero, and this is
1024 not a concern when using C<:perlio> instead of your system's STDIO.
1025
1026 =head2 How do I randomly update a binary file?
1027 X<file, binary patch>
1028
1029 If you're just trying to patch a binary, in many cases something as
1030 simple as this works:
1031
1032         perl -i -pe 's{window manager}{window mangler}g' /usr/bin/emacs
1033
1034 However, if you have fixed sized records, then you might do something more
1035 like this:
1036
1037         $RECSIZE = 220; # size of record, in bytes
1038         $recno   = 37;  # which record to update
1039         open my $fh, '+<', 'somewhere' or die "can't update somewhere: $!";
1040         seek $fh, $recno * $RECSIZE, 0;
1041         read $fh, $record, $RECSIZE == $RECSIZE or die "can't read record $recno: $!";
1042         # munge the record
1043         seek $fh, -$RECSIZE, 1;
1044         print $fh $record;
1045         close $fh;
1046
1047 Locking and error checking are left as an exercise for the reader.
1048 Don't forget them or you'll be quite sorry.
1049
1050 =head2 How do I get a file's timestamp in perl?
1051 X<timestamp> X<file, timestamp>
1052
1053 If you want to retrieve the time at which the file was last read,
1054 written, or had its meta-data (owner, etc) changed, you use the B<-A>,
1055 B<-M>, or B<-C> file test operations as documented in L<perlfunc>.
1056 These retrieve the age of the file (measured against the start-time of
1057 your program) in days as a floating point number. Some platforms may
1058 not have all of these times. See L<perlport> for details. To retrieve
1059 the "raw" time in seconds since the epoch, you would call the stat
1060 function, then use C<localtime()>, C<gmtime()>, or
1061 C<POSIX::strftime()> to convert this into human-readable form.
1062
1063 Here's an example:
1064
1065         my $write_secs = (stat($file))[9];
1066         printf "file %s updated at %s\n", $file,
1067         scalar localtime($write_secs);
1068
1069 If you prefer something more legible, use the File::stat module
1070 (part of the standard distribution in version 5.004 and later):
1071
1072         # error checking left as an exercise for reader.
1073         use File::stat;
1074         use Time::localtime;
1075         my $date_string = ctime(stat($file)->mtime);
1076         print "file $file updated at $date_string\n";
1077
1078 The POSIX::strftime() approach has the benefit of being,
1079 in theory, independent of the current locale. See L<perllocale>
1080 for details.
1081
1082 =head2 How do I set a file's timestamp in perl?
1083 X<timestamp> X<file, timestamp>
1084
1085 You use the utime() function documented in L<perlfunc/utime>.
1086 By way of example, here's a little program that copies the
1087 read and write times from its first argument to all the rest
1088 of them.
1089
1090         if (@ARGV < 2) {
1091                 die "usage: cptimes timestamp_file other_files ...\n";
1092                 }
1093         my $timestamp = shift;
1094         my($atime, $mtime) = (stat($timestamp))[8,9];
1095         utime $atime, $mtime, @ARGV;
1096
1097 Error checking is, as usual, left as an exercise for the reader.
1098
1099 The perldoc for utime also has an example that has the same
1100 effect as touch(1) on files that I<already exist>.
1101
1102 Certain file systems have a limited ability to store the times
1103 on a file at the expected level of precision. For example, the
1104 FAT and HPFS filesystem are unable to create dates on files with
1105 a finer granularity than two seconds. This is a limitation of
1106 the filesystems, not of utime().
1107
1108 =head2 How do I print to more than one file at once?
1109 X<print, to multiple files>
1110
1111 To connect one filehandle to several output filehandles,
1112 you can use the IO::Tee or Tie::FileHandle::Multiplex modules.
1113
1114 If you only have to do this once, you can print individually
1115 to each filehandle.
1116
1117         for my $fh (FH1, FH2, FH3) { print $fh "whatever\n" }
1118
1119 =head2 How can I read in an entire file all at once?
1120 X<slurp> X<file, slurping>
1121
1122 Are you sure you want to read the entire file and store it in memory?
1123 If you mmap the file, you can virtually load the entire file into a
1124 string without actually storing it in memory:
1125
1126         use File::Map qw(map_file);
1127
1128         map_file my $string, $filename;
1129
1130 Once mapped, you can treat C<$string> as you would any other string.
1131 Since you don't necessarily have to load the data, mmap-ing can be
1132 very fast and may not increase your memory footprint.
1133
1134 If you want to load the entire file, you can use the C<File::Slurp>
1135 module to do it in one one simple and efficient step:
1136
1137         use File::Slurp;
1138
1139         my $all_of_it = read_file($filename); # entire file in scalar
1140         my @all_lines = read_file($filename); # one line per element
1141
1142 The customary Perl approach for processing all the lines in a file is to
1143 do so one line at a time:
1144
1145         open my $input, '<', $file or die "can't open $file: $!";
1146         while (<$input>) {
1147                 chomp;
1148                 # do something with $_
1149                 }
1150         close $input or die "can't close $file: $!";
1151
1152 This is tremendously more efficient than reading the entire file into
1153 memory as an array of lines and then processing it one element at a time,
1154 which is often--if not almost always--the wrong approach. Whenever
1155 you see someone do this:
1156
1157         my @lines = <INPUT>;
1158
1159 You should think long and hard about why you need everything loaded at
1160 once. It's just not a scalable solution. You might also find it more
1161 fun to use the standard C<Tie::File> module, or the C<DB_File> module's
1162 C<$DB_RECNO> bindings, which allow you to tie an array to a file so that
1163 accessing an element the array actually accesses the corresponding
1164 line in the file.
1165
1166 You can read the entire filehandle contents into a scalar.
1167
1168         my $var;
1169         {
1170         local $/;
1171         open my $fh, '<', $file or die "can't open $file: $!";
1172         $var = <$fh>;
1173         }
1174
1175 That temporarily undefs your record separator, and will automatically
1176 close the file at block exit. If the file is already open, just use this:
1177
1178         my $var = do { local $/; <$fh> };
1179
1180 You can do that one better by using a localized C<@ARGV> so you can
1181 eliminate the C<open>:
1182
1183         my $var = do { local( @ARGV, $/ ) = $file; <> };
1184
1185 For ordinary files you can also use the C<read> function.
1186
1187         read( $fh, $var, -s $fh );
1188
1189 That third argument tests the byte size of the data on the C<INPUT> filehandle
1190 and reads that many bytes into the buffer C<$var>.
1191
1192 =head2 How can I read in a file by paragraphs?
1193 X<file, reading by paragraphs>
1194
1195 Use the C<$/> variable (see L<perlvar> for details). You can either
1196 set it to C<""> to eliminate empty paragraphs (C<"abc\n\n\n\ndef">,
1197 for instance, gets treated as two paragraphs and not three), or
1198 C<"\n\n"> to accept empty paragraphs.
1199
1200 Note that a blank line must have no blanks in it. Thus
1201 S<C<"fred\n \nstuff\n\n">> is one paragraph, but C<"fred\n\nstuff\n\n"> is two.
1202
1203 =head2 How can I read a single character from a file?  From the keyboard?
1204 X<getc> X<file, reading one character at a time>
1205
1206 You can use the builtin C<getc()> function for most filehandles, but
1207 it won't (easily) work on a terminal device. For STDIN, either use
1208 the Term::ReadKey module from CPAN or use the sample code in
1209 L<perlfunc/getc>.
1210
1211 If your system supports the portable operating system programming
1212 interface (POSIX), you can use the following code, which you'll note
1213 turns off echo processing as well.
1214
1215         #!/usr/bin/perl -w
1216         use strict;
1217         $| = 1;
1218         for (1..4) {
1219                 print "gimme: ";
1220                 my $got = getone();
1221                 print "--> $got\n";
1222                 }
1223     exit;
1224
1225         BEGIN {
1226         use POSIX qw(:termios_h);
1227
1228         my ($term, $oterm, $echo, $noecho, $fd_stdin);
1229
1230         my $fd_stdin = fileno(STDIN);
1231
1232         $term     = POSIX::Termios->new();
1233         $term->getattr($fd_stdin);
1234         $oterm     = $term->getlflag();
1235
1236         $echo     = ECHO | ECHOK | ICANON;
1237         $noecho   = $oterm & ~$echo;
1238
1239         sub cbreak {
1240                 $term->setlflag($noecho);
1241                 $term->setcc(VTIME, 1);
1242                 $term->setattr($fd_stdin, TCSANOW);
1243                 }
1244
1245         sub cooked {
1246                 $term->setlflag($oterm);
1247                 $term->setcc(VTIME, 0);
1248                 $term->setattr($fd_stdin, TCSANOW);
1249                 }
1250
1251         sub getone {
1252                 my $key = '';
1253                 cbreak();
1254                 sysread(STDIN, $key, 1);
1255                 cooked();
1256                 return $key;
1257                 }
1258
1259         }
1260
1261         END { cooked() }
1262
1263 The Term::ReadKey module from CPAN may be easier to use. Recent versions
1264 include also support for non-portable systems as well.
1265
1266         use Term::ReadKey;
1267         open my $tty, '<', '/dev/tty';
1268         print "Gimme a char: ";
1269         ReadMode "raw";
1270         my $key = ReadKey 0, $tty;
1271         ReadMode "normal";
1272         printf "\nYou said %s, char number %03d\n",
1273                 $key, ord $key;
1274
1275 =head2 How can I tell whether there's a character waiting on a filehandle?
1276
1277 The very first thing you should do is look into getting the Term::ReadKey
1278 extension from CPAN. As we mentioned earlier, it now even has limited
1279 support for non-portable (read: not open systems, closed, proprietary,
1280 not POSIX, not Unix, etc.) systems.
1281
1282 You should also check out the Frequently Asked Questions list in
1283 comp.unix.* for things like this: the answer is essentially the same.
1284 It's very system dependent. Here's one solution that works on BSD
1285 systems:
1286
1287         sub key_ready {
1288                 my($rin, $nfd);
1289                 vec($rin, fileno(STDIN), 1) = 1;
1290                 return $nfd = select($rin,undef,undef,0);
1291                 }
1292
1293 If you want to find out how many characters are waiting, there's
1294 also the FIONREAD ioctl call to be looked at. The I<h2ph> tool that
1295 comes with Perl tries to convert C include files to Perl code, which
1296 can be C<require>d. FIONREAD ends up defined as a function in the
1297 I<sys/ioctl.ph> file:
1298
1299         require 'sys/ioctl.ph';
1300
1301         $size = pack("L", 0);
1302         ioctl(FH, FIONREAD(), $size)    or die "Couldn't call ioctl: $!\n";
1303         $size = unpack("L", $size);
1304
1305 If I<h2ph> wasn't installed or doesn't work for you, you can
1306 I<grep> the include files by hand:
1307
1308         % grep FIONREAD /usr/include/*/*
1309         /usr/include/asm/ioctls.h:#define FIONREAD      0x541B
1310
1311 Or write a small C program using the editor of champions:
1312
1313         % cat > fionread.c
1314         #include <sys/ioctl.h>
1315         main() {
1316             printf("%#08x\n", FIONREAD);
1317         }
1318         ^D
1319         % cc -o fionread fionread.c
1320         % ./fionread
1321         0x4004667f
1322
1323 And then hard code it, leaving porting as an exercise to your successor.
1324
1325         $FIONREAD = 0x4004667f;         # XXX: opsys dependent
1326
1327         $size = pack("L", 0);
1328         ioctl(FH, $FIONREAD, $size)     or die "Couldn't call ioctl: $!\n";
1329         $size = unpack("L", $size);
1330
1331 FIONREAD requires a filehandle connected to a stream, meaning that sockets,
1332 pipes, and tty devices work, but I<not> files.
1333
1334 =head2 How do I do a C<tail -f> in perl?
1335 X<tail> X<IO::Handle> X<File::Tail> X<clearerr>
1336
1337 First try
1338
1339         seek(GWFILE, 0, 1);
1340
1341 The statement C<seek(GWFILE, 0, 1)> doesn't change the current position,
1342 but it does clear the end-of-file condition on the handle, so that the
1343 next C<< <GWFILE> >> makes Perl try again to read something.
1344
1345 If that doesn't work (it relies on features of your stdio implementation),
1346 then you need something more like this:
1347
1348         for (;;) {
1349           for ($curpos = tell(GWFILE); <GWFILE>; $curpos = tell(GWFILE)) {
1350             # search for some stuff and put it into files
1351           }
1352           # sleep for a while
1353           seek(GWFILE, $curpos, 0);  # seek to where we had been
1354         }
1355
1356 If this still doesn't work, look into the C<clearerr> method
1357 from C<IO::Handle>, which resets the error and end-of-file states
1358 on the handle.
1359
1360 There's also a C<File::Tail> module from CPAN.
1361
1362 =head2 How do I dup() a filehandle in Perl?
1363 X<dup>
1364
1365 If you check L<perlfunc/open>, you'll see that several of the ways
1366 to call open() should do the trick. For example:
1367
1368         open my $log, '>>', '/foo/logfile';
1369         open STDERR, '>&LOG';
1370
1371 Or even with a literal numeric descriptor:
1372
1373         my $fd = $ENV{MHCONTEXTFD};
1374         open $mhcontext, "<&=$fd";  # like fdopen(3S)
1375
1376 Note that "<&STDIN" makes a copy, but "<&=STDIN" make
1377 an alias. That means if you close an aliased handle, all
1378 aliases become inaccessible. This is not true with
1379 a copied one.
1380
1381 Error checking, as always, has been left as an exercise for the reader.
1382
1383 =head2 How do I close a file descriptor by number?
1384 X<file, closing file descriptors> X<POSIX> X<close>
1385
1386 If, for some reason, you have a file descriptor instead of a
1387 filehandle (perhaps you used C<POSIX::open>), you can use the
1388 C<close()> function from the C<POSIX> module:
1389
1390         use POSIX ();
1391
1392         POSIX::close( $fd );
1393
1394 This should rarely be necessary, as the Perl C<close()> function is to be
1395 used for things that Perl opened itself, even if it was a dup of a
1396 numeric descriptor as with C<MHCONTEXT> above. But if you really have
1397 to, you may be able to do this:
1398
1399         require 'sys/syscall.ph';
1400         my $rc = syscall(&SYS_close, $fd + 0);  # must force numeric
1401         die "can't sysclose $fd: $!" unless $rc == -1;
1402
1403 Or, just use the fdopen(3S) feature of C<open()>:
1404
1405         {
1406         open my( $fh ), "<&=$fd" or die "Cannot reopen fd=$fd: $!";
1407         close $fh;
1408         }
1409
1410 =head2 Why can't I use "C:\temp\foo" in DOS paths?  Why doesn't `C:\temp\foo.exe` work?
1411 X<filename, DOS issues>
1412
1413 Whoops!  You just put a tab and a formfeed into that filename!
1414 Remember that within double quoted strings ("like\this"), the
1415 backslash is an escape character. The full list of these is in
1416 L<perlop/Quote and Quote-like Operators>. Unsurprisingly, you don't
1417 have a file called "c:(tab)emp(formfeed)oo" or
1418 "c:(tab)emp(formfeed)oo.exe" on your legacy DOS filesystem.
1419
1420 Either single-quote your strings, or (preferably) use forward slashes.
1421 Since all DOS and Windows versions since something like MS-DOS 2.0 or so
1422 have treated C</> and C<\> the same in a path, you might as well use the
1423 one that doesn't clash with Perl--or the POSIX shell, ANSI C and C++,
1424 awk, Tcl, Java, or Python, just to mention a few. POSIX paths
1425 are more portable, too.
1426
1427 =head2 Why doesn't glob("*.*") get all the files?
1428 X<glob>
1429
1430 Because even on non-Unix ports, Perl's glob function follows standard
1431 Unix globbing semantics. You'll need C<glob("*")> to get all (non-hidden)
1432 files. This makes glob() portable even to legacy systems. Your
1433 port may include proprietary globbing functions as well. Check its
1434 documentation for details.
1435
1436 =head2 Why does Perl let me delete read-only files?  Why does C<-i> clobber protected files?  Isn't this a bug in Perl?
1437
1438 This is elaborately and painstakingly described in the
1439 F<file-dir-perms> article in the "Far More Than You Ever Wanted To
1440 Know" collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz .
1441
1442 The executive summary: learn how your filesystem works. The
1443 permissions on a file say what can happen to the data in that file.
1444 The permissions on a directory say what can happen to the list of
1445 files in that directory. If you delete a file, you're removing its
1446 name from the directory (so the operation depends on the permissions
1447 of the directory, not of the file). If you try to write to the file,
1448 the permissions of the file govern whether you're allowed to.
1449
1450 =head2 How do I select a random line from a file?
1451 X<file, selecting a random line>
1452
1453 Short of loading the file into a database or pre-indexing the lines in
1454 the file, there are a couple of things that you can do.
1455
1456 Here's a reservoir-sampling algorithm from the Camel Book:
1457
1458         srand;
1459         rand($.) < 1 && ($line = $_) while <>;
1460
1461 This has a significant advantage in space over reading the whole file
1462 in. You can find a proof of this method in I<The Art of Computer
1463 Programming>, Volume 2, Section 3.4.2, by Donald E. Knuth.
1464
1465 You can use the C<File::Random> module which provides a function
1466 for that algorithm:
1467
1468         use File::Random qw/random_line/;
1469         my $line = random_line($filename);
1470
1471 Another way is to use the C<Tie::File> module, which treats the entire
1472 file as an array. Simply access a random array element.
1473
1474 =head2 Why do I get weird spaces when I print an array of lines?
1475
1476 (contributed by brian d foy)
1477
1478 If you are seeing spaces between the elements of your array when
1479 you print the array, you are probably interpolating the array in
1480 double quotes:
1481
1482         my @animals = qw(camel llama alpaca vicuna);
1483         print "animals are: @animals\n";
1484
1485 It's the double quotes, not the C<print>, doing this. Whenever you
1486 interpolate an array in a double quote context, Perl joins the
1487 elements with spaces (or whatever is in C<$">, which is a space by
1488 default):
1489
1490         animals are: camel llama alpaca vicuna
1491
1492 This is different than printing the array without the interpolation:
1493
1494         my @animals = qw(camel llama alpaca vicuna);
1495         print "animals are: ", @animals, "\n";
1496
1497 Now the output doesn't have the spaces between the elements because
1498 the elements of C<@animals> simply become part of the list to
1499 C<print>:
1500
1501         animals are: camelllamaalpacavicuna
1502
1503 You might notice this when each of the elements of C<@array> end with
1504 a newline. You expect to print one element per line, but notice that
1505 every line after the first is indented:
1506
1507         this is a line
1508          this is another line
1509          this is the third line
1510
1511 That extra space comes from the interpolation of the array. If you
1512 don't want to put anything between your array elements, don't use the
1513 array in double quotes. You can send it to print without them:
1514
1515         print @lines;
1516
1517 =head2 How do I traverse a directory tree?
1518
1519 (contributed by brian d foy)
1520
1521 The C<File::Find> module, which comes with Perl, does all of the hard
1522 work to traverse a directory structure. It comes with Perl. You simply
1523 call the C<find> subroutine with a callback subroutine and the
1524 directories you want to traverse:
1525
1526         use File::Find;
1527
1528         find( \&wanted, @directories );
1529
1530         sub wanted {
1531                 # full path in $File::Find::name
1532                 # just filename in $_
1533                 ... do whatever you want to do ...
1534                 }
1535
1536 The C<File::Find::Closures>, which you can download from CPAN, provides
1537 many ready-to-use subroutines that you can use with C<File::Find>.
1538
1539 The C<File::Finder>, which you can download from CPAN, can help you
1540 create the callback subroutine using something closer to the syntax of
1541 the C<find> command-line utility:
1542
1543         use File::Find;
1544         use File::Finder;
1545
1546         my $deep_dirs = File::Finder->depth->type('d')->ls->exec('rmdir','{}');
1547
1548         find( $deep_dirs->as_options, @places );
1549
1550 The C<File::Find::Rule> module, which you can download from CPAN, has
1551 a similar interface, but does the traversal for you too:
1552
1553         use File::Find::Rule;
1554
1555         my @files = File::Find::Rule->file()
1556                                                          ->name( '*.pm' )
1557                                                          ->in( @INC );
1558
1559 =head2 How do I delete a directory tree?
1560
1561 (contributed by brian d foy)
1562
1563 If you have an empty directory, you can use Perl's built-in C<rmdir>.
1564 If the directory is not empty (so, no files or subdirectories), you
1565 either have to empty it yourself (a lot of work) or use a module to
1566 help you.
1567
1568 The C<File::Path> module, which comes with Perl, has a C<remove_tree>
1569 which can take care of all of the hard work for you:
1570
1571         use File::Path qw(remove_tree);
1572
1573         remove_tree( @directories );
1574
1575 The C<File::Path> module also has a legacy interface to the older
1576 C<rmtree> subroutine.
1577
1578 =head2 How do I copy an entire directory?
1579
1580 (contributed by Shlomi Fish)
1581
1582 To do the equivalent of C<cp -R> (i.e. copy an entire directory tree
1583 recursively) in portable Perl, you'll either need to write something yourself
1584 or find a good CPAN module such as  L<File::Copy::Recursive>.
1585
1586 =head1 AUTHOR AND COPYRIGHT
1587
1588 Copyright (c) 1997-2010 Tom Christiansen, Nathan Torkington, and
1589 other authors as noted. All rights reserved.
1590
1591 This documentation is free; you can redistribute it and/or modify it
1592 under the same terms as Perl itself.
1593
1594 Irrespective of its distribution, all code examples here are in the public
1595 domain. You are permitted and encouraged to use this code and any
1596 derivatives thereof in your own programs for fun or for profit as you
1597 see fit. A simple comment in the code giving credit to the FAQ would
1598 be courteous but is not required.