t/test.pl

   1 #
   2 # t/test.pl - most of Test::More functionality without the fuss, plus
   3 # has mappings native_to_latin1 and latin1_to_native so that fewer tests
   4 # on non ASCII-ish platforms need to be skipped
   5
   6
   7 # NOTE:
   8 #
   9 # Increment ($x++) has a certain amount of cleverness for things like
  10 #
  11 #   $x = 'zz';
  12 #   $x++; # $x eq 'aaa';
  13 #
  14 # stands more chance of breaking than just a simple
  15 #
  16 #   $x = $x + 1
  17 #
  18 # In this file, we use the latter "Baby Perl" approach, and increment
  19 # will be worked over by t/op/inc.t
  20
  21 $Level = 1;
  22 my $test = 1;
  23 my $planned;
  24 my $noplan;
  25 my $Perl;       # Safer version of $^X set by which_perl()
  26
  27 $TODO = 0;
  28 $NO_ENDING = 0;
  29 $Tests_Are_Passing = 1;
  30
  31 # Use this instead of print to avoid interference while testing globals.
  32 sub _print {
  33     local($\, $", $,) = (undef, ' ', '');
  34     print STDOUT @_;
  35 }
  36
  37 sub _print_stderr {
  38     local($\, $", $,) = (undef, ' ', '');
  39     print STDERR @_;
  40 }
  41
  42 sub plan {
  43     my $n;
  44     if (@_ == 1) {
  45         $n = shift;
  46         if ($n eq 'no_plan') {
  47           undef $n;
  48           $noplan = 1;
  49         }
  50     } else {
  51         my %plan = @_;
  52         $n = $plan{tests};
  53     }
  54     _print "1..$n\n" unless $noplan;
  55     $planned = $n;
  56 }
  57
  58
  59 # Set the plan at the end.  See Test::More::done_testing.
  60 sub done_testing {
  61     my $n = $test - 1;
  62     $n = shift if @_;
  63
  64     _print "1..$n\n";
  65     $planned = $n;
  66 }
  67
  68
  69 END {
  70     my $ran = $test - 1;
  71     if (!$NO_ENDING) {
  72         if (defined $planned && $planned != $ran) {
  73             _print_stderr
  74                 "# Looks like you planned $planned tests but ran $ran.\n";
  75         } elsif ($noplan) {
  76             _print "1..$ran\n";
  77         }
  78     }
  79 }
  80
  81 sub _diag {
  82     return unless @_;
  83     my @mess = _comment(@_);
  84     $TODO ? _print(@mess) : _print_stderr(@mess);
  85 }
  86
  87 # Use this instead of "print STDERR" when outputting failure diagnostic
  88 # messages
  89 sub diag {
  90     _diag(@_);
  91 }
  92
  93 # Use this instead of "print" when outputting informational messages
  94 sub note {
  95     return unless @_;
  96     _print( _comment(@_) );
  97 }
  98
  99 sub _comment {
 100     return map { /^#/ ? "$_\n" : "# $_\n" }
 101            map { split /\n/ } @_;
 102 }
 103
 104 sub skip_all {
 105     if (@_) {
 106         _print "1..0 # Skip @_\n";
 107     } else {
 108         _print "1..0\n";
 109     }
 110     exit(0);
 111 }
 112
 113 sub _ok {
 114     my ($pass, $where, $name, @mess) = @_;
 115     # Do not try to microoptimize by factoring out the "not ".
 116     # VMS will avenge.
 117     my $out;
 118     if ($name) {
 119         # escape out '#' or it will interfere with '# skip' and such
 120         $name =~ s/#/\\#/g;
 121         $out = $pass ? "ok $test - $name" : "not ok $test - $name";
 122     } else {
 123         $out = $pass ? "ok $test" : "not ok $test";
 124     }
 125
 126     if ($TODO) {
 127         $out = $out . " # TODO $TODO";
 128     } else {
 129         $Tests_Are_Passing = 0 unless $pass;
 130     }
 131
 132     _print "$out\n";
 133
 134     unless ($pass) {
 135         _diag "# Failed $where\n";
 136     }
 137
 138     # Ensure that the message is properly escaped.
 139     _diag @mess;
 140
 141     $test = $test + 1; # don't use ++
 142
 143     return $pass;
 144 }
 145
 146 sub _where {
 147     my @caller = caller($Level);
 148     return "at $caller[1] line $caller[2]";
 149 }
 150
 151 # DON'T use this for matches. Use like() instead.
 152 sub ok ($@) {
 153     my ($pass, $name, @mess) = @_;
 154     _ok($pass, _where(), $name, @mess);
 155 }
 156
 157 sub _q {
 158     my $x = shift;
 159     return 'undef' unless defined $x;
 160     my $q = $x;
 161     $q =~ s/\\/\\\\/g;
 162     $q =~ s/'/\\'/g;
 163     return "'$q'";
 164 }
 165
 166 sub _qq {
 167     my $x = shift;
 168     return defined $x ? '"' . display ($x) . '"' : 'undef';
 169 };
 170
 171 # keys are the codes \n etc map to, values are 2 char strings such as \n
 172 my %backslash_escape;
 173 foreach my $x (split //, 'nrtfa\\\'"') {
 174     $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
 175 }
 176 # A way to display scalars containing control characters and Unicode.
 177 # Trying to avoid setting $_, or relying on local $_ to work.
 178 sub display {
 179     my @result;
 180     foreach my $x (@_) {
 181         if (defined $x and not ref $x) {
 182             my $y = '';
 183             foreach my $c (unpack("U*", $x)) {
 184                 if ($c > 255) {
 185                     $y = $y . sprintf "\\x{%x}", $c;
 186                 } elsif ($backslash_escape{$c}) {
 187                     $y = $y . $backslash_escape{$c};
 188                 } else {
 189                     my $z = chr $c; # Maybe we can get away with a literal...
 190                     if ($z =~ /[[:^print:]]/) {
 191
 192                         # Use octal for characters traditionally expressed as
 193                         # such: the low controls
 194                         if ($c <= 037) {
 195                             $z = sprintf "\\%03o", $c;
 196                         } else {
 197                             $z = sprintf "\\x{%x}", $c;
 198                         }
 199                     }
 200                     $y = $y . $z;
 201                 }
 202             }
 203             $x = $y;
 204         }
 205         return $x unless wantarray;
 206         push @result, $x;
 207     }
 208     return @result;
 209 }
 210
 211 sub is ($$@) {
 212     my ($got, $expected, $name, @mess) = @_;
 213
 214     my $pass;
 215     if( !defined $got || !defined $expected ) {
 216         # undef only matches undef
 217         $pass = !defined $got && !defined $expected;
 218     }
 219     else {
 220         $pass = $got eq $expected;
 221     }
 222
 223     unless ($pass) {
 224         unshift(@mess, "#      got "._qq($got)."\n",
 225                        "# expected "._qq($expected)."\n");
 226     }
 227     _ok($pass, _where(), $name, @mess);
 228 }
 229
 230 sub isnt ($$@) {
 231     my ($got, $isnt, $name, @mess) = @_;
 232
 233     my $pass;
 234     if( !defined $got || !defined $isnt ) {
 235         # undef only matches undef
 236         $pass = defined $got || defined $isnt;
 237     }
 238     else {
 239         $pass = $got ne $isnt;
 240     }
 241
 242     unless( $pass ) {
 243         unshift(@mess, "# it should not be "._qq($got)."\n",
 244                        "# but it is.\n");
 245     }
 246     _ok($pass, _where(), $name, @mess);
 247 }
 248
 249 sub cmp_ok ($$$@) {
 250     my($got, $type, $expected, $name, @mess) = @_;
 251
 252     my $pass;
 253     {
 254         local $^W = 0;
 255         local($@,$!);   # don't interfere with $@
 256                         # eval() sometimes resets $!
 257         $pass = eval "\$got $type \$expected";
 258     }
 259     unless ($pass) {
 260         # It seems Irix long doubles can have 2147483648 and 2147483648
 261         # that stringify to the same thing but are actually numerically
 262         # different. Display the numbers if $type isn't a string operator,
 263         # and the numbers are stringwise the same.
 264         # (all string operators have alphabetic names, so tr/a-z// is true)
 265         # This will also show numbers for some unneeded cases, but will
 266         # definitely be helpful for things such as == and <= that fail
 267         if ($got eq $expected and $type !~ tr/a-z//) {
 268             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
 269         }
 270         unshift(@mess, "#      got "._qq($got)."\n",
 271                        "# expected $type "._qq($expected)."\n");
 272     }
 273     _ok($pass, _where(), $name, @mess);
 274 }
 275
 276 # Check that $got is within $range of $expected
 277 # if $range is 0, then check it's exact
 278 # else if $expected is 0, then $range is an absolute value
 279 # otherwise $range is a fractional error.
 280 # Here $range must be numeric, >= 0
 281 # Non numeric ranges might be a useful future extension. (eg %)
 282 sub within ($$$@) {
 283     my ($got, $expected, $range, $name, @mess) = @_;
 284     my $pass;
 285     if (!defined $got or !defined $expected or !defined $range) {
 286         # This is a fail, but doesn't need extra diagnostics
 287     } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
 288         # This is a fail
 289         unshift @mess, "# got, expected and range must be numeric\n";
 290     } elsif ($range < 0) {
 291         # This is also a fail
 292         unshift @mess, "# range must not be negative\n";
 293     } elsif ($range == 0) {
 294         # Within 0 is ==
 295         $pass = $got == $expected;
 296     } elsif ($expected == 0) {
 297         # If expected is 0, treat range as absolute
 298         $pass = ($got <= $range) && ($got >= - $range);
 299     } else {
 300         my $diff = $got - $expected;
 301         $pass = abs ($diff / $expected) < $range;
 302     }
 303     unless ($pass) {
 304         if ($got eq $expected) {
 305             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
 306         }
 307         unshift@mess, "#      got "._qq($got)."\n",
 308                       "# expected "._qq($expected)." (within "._qq($range).")\n";
 309     }
 310     _ok($pass, _where(), $name, @mess);
 311 }
 312
 313 # Note: this isn't quite as fancy as Test::More::like().
 314
 315 sub like   ($$@) { like_yn (0,@_) }; # 0 for -
 316 sub unlike ($$@) { like_yn (1,@_) }; # 1 for un-
 317
 318 sub like_yn ($$$@) {
 319     my ($flip, $got, $expected, $name, @mess) = @_;
 320     my $pass;
 321     $pass = $got =~ /$expected/ if !$flip;
 322     $pass = $got !~ /$expected/ if $flip;
 323     unless ($pass) {
 324         unshift(@mess, "#      got '$got'\n",
 325                 $flip
 326                 ? "# expected !~ /$expected/\n" : "# expected /$expected/\n");
 327     }
 328     local $Level = $Level + 1;
 329     _ok($pass, _where(), $name, @mess);
 330 }
 331
 332 sub pass {
 333     _ok(1, '', @_);
 334 }
 335
 336 sub fail {
 337     _ok(0, _where(), @_);
 338 }
 339
 340 sub curr_test {
 341     $test = shift if @_;
 342     return $test;
 343 }
 344
 345 sub next_test {
 346   my $retval = $test;
 347   $test = $test + 1; # don't use ++
 348   $retval;
 349 }
 350
 351 # Note: can't pass multipart messages since we try to
 352 # be compatible with Test::More::skip().
 353 sub skip {
 354     my $why = shift;
 355     my $n    = @_ ? shift : 1;
 356     for (1..$n) {
 357         _print "ok $test # skip $why\n";
 358         $test = $test + 1;
 359     }
 360     local $^W = 0;
 361     last SKIP;
 362 }
 363
 364 sub todo_skip {
 365     my $why = shift;
 366     my $n   = @_ ? shift : 1;
 367
 368     for (1..$n) {
 369         _print "not ok $test # TODO & SKIP $why\n";
 370         $test = $test + 1;
 371     }
 372     local $^W = 0;
 373     last TODO;
 374 }
 375
 376 sub eq_array {
 377     my ($ra, $rb) = @_;
 378     return 0 unless $#$ra == $#$rb;
 379     for my $i (0..$#$ra) {
 380         next     if !defined $ra->[$i] && !defined $rb->[$i];
 381         return 0 if !defined $ra->[$i];
 382         return 0 if !defined $rb->[$i];
 383         return 0 unless $ra->[$i] eq $rb->[$i];
 384     }
 385     return 1;
 386 }
 387
 388 sub eq_hash {
 389   my ($orig, $suspect) = @_;
 390   my $fail;
 391   while (my ($key, $value) = each %$suspect) {
 392     # Force a hash recompute if this perl's internals can cache the hash key.
 393     $key = "" . $key;
 394     if (exists $orig->{$key}) {
 395       if ($orig->{$key} ne $value) {
 396         _print "# key ", _qq($key), " was ", _qq($orig->{$key}),
 397                      " now ", _qq($value), "\n";
 398         $fail = 1;
 399       }
 400     } else {
 401       _print "# key ", _qq($key), " is ", _qq($value),
 402                    ", not in original.\n";
 403       $fail = 1;
 404     }
 405   }
 406   foreach (keys %$orig) {
 407     # Force a hash recompute if this perl's internals can cache the hash key.
 408     $_ = "" . $_;
 409     next if (exists $suspect->{$_});
 410     _print "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
 411     $fail = 1;
 412   }
 413   !$fail;
 414 }
 415
 416 sub require_ok ($) {
 417     my ($require) = @_;
 418     eval <<REQUIRE_OK;
 419 require $require;
 420 REQUIRE_OK
 421     _ok(!$@, _where(), "require $require");
 422 }
 423
 424 sub use_ok ($) {
 425     my ($use) = @_;
 426     eval <<USE_OK;
 427 use $use;
 428 USE_OK
 429     _ok(!$@, _where(), "use $use");
 430 }
 431
 432 # runperl - Runs a separate perl interpreter.
 433 # Arguments :
 434 #   switches => [ command-line switches ]
 435 #   nolib    => 1 # don't use -I../lib (included by default)
 436 #   non_portable => Don't warn if a one liner contains quotes
 437 #   prog     => one-liner (avoid quotes)
 438 #   progs    => [ multi-liner (avoid quotes) ]
 439 #   progfile => perl script
 440 #   stdin    => string to feed the stdin
 441 #   stderr   => redirect stderr to stdout
 442 #   args     => [ command-line arguments to the perl program ]
 443 #   verbose  => print the command line
 444
 445 my $is_mswin    = $^O eq 'MSWin32';
 446 my $is_netware  = $^O eq 'NetWare';
 447 my $is_vms      = $^O eq 'VMS';
 448 my $is_cygwin   = $^O eq 'cygwin';
 449
 450 sub _quote_args {
 451     my ($runperl, $args) = @_;
 452
 453     foreach (@$args) {
 454         # In VMS protect with doublequotes because otherwise
 455         # DCL will lowercase -- unless already doublequoted.
 456        $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
 457        $runperl = $runperl . ' ' . $_;
 458     }
 459     return $runperl;
 460 }
 461
 462 sub _create_runperl { # Create the string to qx in runperl().
 463     my %args = @_;
 464     my $runperl = which_perl();
 465     if ($runperl =~ m/\s/) {
 466         $runperl = qq{"$runperl"};
 467     }
 468     #- this allows, for example, to set PERL_RUNPERL_DEBUG=/usr/bin/valgrind
 469     if ($ENV{PERL_RUNPERL_DEBUG}) {
 470         $runperl = "$ENV{PERL_RUNPERL_DEBUG} $runperl";
 471     }
 472     unless ($args{nolib}) {
 473         $runperl = $runperl . ' "-I../lib"'; # doublequotes because of VMS
 474     }
 475     if ($args{switches}) {
 476         local $Level = 2;
 477         die "test.pl:runperl(): 'switches' must be an ARRAYREF " . _where()
 478             unless ref $args{switches} eq "ARRAY";
 479         $runperl = _quote_args($runperl, $args{switches});
 480     }
 481     if (defined $args{prog}) {
 482         die "test.pl:runperl(): both 'prog' and 'progs' cannot be used " . _where()
 483             if defined $args{progs};
 484         $args{progs} = [$args{prog}]
 485     }
 486     if (defined $args{progs}) {
 487         die "test.pl:runperl(): 'progs' must be an ARRAYREF " . _where()
 488             unless ref $args{progs} eq "ARRAY";
 489         foreach my $prog (@{$args{progs}}) {
 490             if ($prog =~ tr/'"// && !$args{non_portable}) {
 491                 warn "quotes in prog >>$prog<< are not portable";
 492             }
 493             if ($is_mswin || $is_netware || $is_vms) {
 494                 $runperl = $runperl . qq ( -e "$prog" );
 495             }
 496             else {
 497                 $runperl = $runperl . qq ( -e '$prog' );
 498             }
 499         }
 500     } elsif (defined $args{progfile}) {
 501         $runperl = $runperl . qq( "$args{progfile}");
 502     } else {
 503         # You probably didn't want to be sucking in from the upstream stdin
 504         die "test.pl:runperl(): none of prog, progs, progfile, args, "
 505             . " switches or stdin specified"
 506             unless defined $args{args} or defined $args{switches}
 507                 or defined $args{stdin};
 508     }
 509     if (defined $args{stdin}) {
 510         # so we don't try to put literal newlines and crs onto the
 511         # command line.
 512         $args{stdin} =~ s/\n/\\n/g;
 513         $args{stdin} =~ s/\r/\\r/g;
 514
 515         if ($is_mswin || $is_netware || $is_vms) {
 516             $runperl = qq{$Perl -e "print qq(} .
 517                 $args{stdin} . q{)" | } . $runperl;
 518         }
 519         else {
 520             $runperl = qq{$Perl -e 'print qq(} .
 521                 $args{stdin} . q{)' | } . $runperl;
 522         }
 523     }
 524     if (defined $args{args}) {
 525         $runperl = _quote_args($runperl, $args{args});
 526     }
 527     $runperl = $runperl . ' 2>&1' if $args{stderr};
 528     if ($args{verbose}) {
 529         my $runperldisplay = $runperl;
 530         $runperldisplay =~ s/\n/\n\#/g;
 531         _print_stderr "# $runperldisplay\n";
 532     }
 533     return $runperl;
 534 }
 535
 536 sub runperl {
 537     die "test.pl:runperl() does not take a hashref"
 538         if ref $_[0] and ref $_[0] eq 'HASH';
 539     my $runperl = &_create_runperl;
 540     my $result;
 541
 542     my $tainted = ${^TAINT};
 543     my %args = @_;
 544     exists $args{switches} && grep m/^-T$/, @{$args{switches}} and $tainted = $tainted + 1;
 545
 546     if ($tainted) {
 547         # We will assume that if you're running under -T, you really mean to
 548         # run a fresh perl, so we'll brute force launder everything for you
 549         my $sep;
 550
 551         if (! eval 'require Config; 1') {
 552             warn "test.pl had problems loading Config: $@";
 553             $sep = ':';
 554         } else {
 555             $sep = $Config::Config{path_sep};
 556         }
 557
 558         my @keys = grep {exists $ENV{$_}} qw(CDPATH IFS ENV BASH_ENV);
 559         local @ENV{@keys} = ();
 560         # Untaint, plus take out . and empty string:
 561         local $ENV{'DCL$PATH'} = $1 if $is_vms && exists($ENV{'DCL$PATH'}) && ($ENV{'DCL$PATH'} =~ /(.*)/s);
 562         $ENV{PATH} =~ /(.*)/s;
 563         local $ENV{PATH} =
 564             join $sep, grep { $_ ne "" and $_ ne "." and -d $_ and
 565                 ($is_mswin or $is_vms or !(stat && (stat _)[2]&0022)) }
 566                     split quotemeta ($sep), $1;
 567         if ($is_cygwin) {   # Must have /bin under Cygwin
 568             if (length $ENV{PATH}) {
 569                 $ENV{PATH} = $ENV{PATH} . $sep;
 570             }
 571             $ENV{PATH} = $ENV{PATH} . '/bin';
 572         }
 573         $runperl =~ /(.*)/s;
 574         $runperl = $1;
 575
 576         $result = `$runperl`;
 577     } else {
 578         $result = `$runperl`;
 579     }
 580     $result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
 581     return $result;
 582 }
 583
 584 # Nice alias
 585 *run_perl = *run_perl = \&runperl; # shut up "used only once" warning
 586
 587 sub DIE {
 588     _print_stderr "# @_\n";
 589     exit 1;
 590 }
 591
 592 # A somewhat safer version of the sometimes wrong $^X.
 593 sub which_perl {
 594     unless (defined $Perl) {
 595         $Perl = $^X;
 596
 597         # VMS should have 'perl' aliased properly
 598         return $Perl if $is_vms;
 599
 600         my $exe;
 601         if (! eval 'require Config; 1') {
 602             warn "test.pl had problems loading Config: $@";
 603             $exe = '';
 604         } else {
 605             $exe = $Config::Config{_exe};
 606         }
 607        $exe = '' unless defined $exe;
 608
 609         # This doesn't absolutize the path: beware of future chdirs().
 610         # We could do File::Spec->abs2rel() but that does getcwd()s,
 611         # which is a bit heavyweight to do here.
 612
 613         if ($Perl =~ /^perl\Q$exe\E$/i) {
 614             my $perl = "perl$exe";
 615             if (! eval 'require File::Spec; 1') {
 616                 warn "test.pl had problems loading File::Spec: $@";
 617                 $Perl = "./$perl";
 618             } else {
 619                 $Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
 620             }
 621         }
 622
 623         # Build up the name of the executable file from the name of
 624         # the command.
 625
 626         if ($Perl !~ /\Q$exe\E$/i) {
 627             $Perl = $Perl . $exe;
 628         }
 629
 630         warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
 631
 632         # For subcommands to use.
 633         $ENV{PERLEXE} = $Perl;
 634     }
 635     return $Perl;
 636 }
 637
 638 sub unlink_all {
 639     my $count = 0;
 640     foreach my $file (@_) {
 641         1 while unlink $file;
 642         if( -f $file ){
 643             _print_stderr "# Couldn't unlink '$file': $!\n";
 644         }else{
 645             ++$count;
 646         }
 647     }
 648     $count;
 649 }
 650
 651 my %tmpfiles;
 652 END { unlink_all keys %tmpfiles }
 653
 654 # A regexp that matches the tempfile names
 655 $::tempfile_regexp = 'tmp\d+[A-Z][A-Z]?';
 656
 657 # Avoid ++, avoid ranges, avoid split //
 658 my @letters = qw(A B C D E F G H I J K L M N O P Q R S T U V W X Y Z);
 659 sub tempfile {
 660     my $count = 0;
 661     do {
 662         my $temp = $count;
 663         my $try = "tmp$$";
 664         do {
 665             $try = $try . $letters[$temp % 26];
 666             $temp = int ($temp / 26);
 667         } while $temp;
 668         # Need to note all the file names we allocated, as a second request may
 669         # come before the first is created.
 670         if (!-e $try && !$tmpfiles{$try}) {
 671             # We have a winner
 672             $tmpfiles{$try} = 1;
 673             return $try;
 674         }
 675         $count = $count + 1;
 676     } while $count < 26 * 26;
 677     die "Can't find temporary file name starting 'tmp$$'";
 678 }
 679
 680 # This is the temporary file for _fresh_perl
 681 my $tmpfile = tempfile();
 682
 683 #
 684 # _fresh_perl
 685 #
 686 # The $resolve must be a subref that tests the first argument
 687 # for success, or returns the definition of success (e.g. the
 688 # expected scalar) if given no arguments.
 689 #
 690
 691 sub _fresh_perl {
 692     my($prog, $resolve, $runperl_args, $name) = @_;
 693
 694     # Given the choice of the mis-parsable {}
 695     # (we want an anon hash, but a borked lexer might think that it's a block)
 696     # or relying on taking a reference to a lexical
 697     # (\ might be mis-parsed, and the reference counting on the pad may go
 698     #  awry)
 699     # it feels like the least-worse thing is to assume that auto-vivification
 700     # works. At least, this is only going to be a run-time failure, so won't
 701     # affect tests using this file but not this function.
 702     $runperl_args->{progfile} = $tmpfile;
 703     $runperl_args->{stderr} = 1;
 704
 705     open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";
 706
 707     # VMS adjustments
 708     if( $is_vms ) {
 709         $prog =~ s#/dev/null#NL:#;
 710
 711         # VMS file locking
 712         $prog =~ s{if \(-e _ and -f _ and -r _\)}
 713                   {if (-e _ and -f _)}
 714     }
 715
 716     print TEST $prog;
 717     close TEST or die "Cannot close $tmpfile: $!";
 718
 719     my $results = runperl(%$runperl_args);
 720     my $status = $?;
 721
 722     # Clean up the results into something a bit more predictable.
 723     $results  =~ s/\n+$//;
 724     $results =~ s/at\s+$::tempfile_regexp\s+line/at - line/g;
 725     $results =~ s/of\s+$::tempfile_regexp\s+aborted/of - aborted/g;
 726
 727     # bison says 'parse error' instead of 'syntax error',
 728     # various yaccs may or may not capitalize 'syntax'.
 729     $results =~ s/^(syntax|parse) error/syntax error/mig;
 730
 731     if ($is_vms) {
 732         # some tests will trigger VMS messages that won't be expected
 733         $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
 734
 735         # pipes double these sometimes
 736         $results =~ s/\n\n/\n/g;
 737     }
 738
 739     my $pass = $resolve->($results);
 740     unless ($pass) {
 741         _diag "# PROG: \n$prog\n";
 742         _diag "# EXPECTED:\n", $resolve->(), "\n";
 743         _diag "# GOT:\n$results\n";
 744         _diag "# STATUS: $status\n";
 745     }
 746
 747     # Use the first line of the program as a name if none was given
 748     unless( $name ) {
 749         ($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
 750         $name = $name . '...' if length $first_line > length $name;
 751     }
 752
 753     _ok($pass, _where(), "fresh_perl - $name");
 754 }
 755
 756 #
 757 # fresh_perl_is
 758 #
 759 # Combination of run_perl() and is().
 760 #
 761
 762 sub fresh_perl_is {
 763     my($prog, $expected, $runperl_args, $name) = @_;
 764
 765     # _fresh_perl() is going to clip the trailing newlines off the result.
 766     # This will make it so the test author doesn't have to know that.
 767     $expected =~ s/\n+$//;
 768
 769     local $Level = 2;
 770     _fresh_perl($prog,
 771                 sub { @_ ? $_[0] eq $expected : $expected },
 772                 $runperl_args, $name);
 773 }
 774
 775 #
 776 # fresh_perl_like
 777 #
 778 # Combination of run_perl() and like().
 779 #
 780
 781 sub fresh_perl_like {
 782     my($prog, $expected, $runperl_args, $name) = @_;
 783     local $Level = 2;
 784     _fresh_perl($prog,
 785                 sub { @_ ? $_[0] =~ $expected : $expected },
 786                 $runperl_args, $name);
 787 }
 788
 789 sub can_ok ($@) {
 790     my($proto, @methods) = @_;
 791     my $class = ref $proto || $proto;
 792
 793     unless( @methods ) {
 794         return _ok( 0, _where(), "$class->can(...)" );
 795     }
 796
 797     my @nok = ();
 798     foreach my $method (@methods) {
 799         local($!, $@);  # don't interfere with caller's $@
 800                         # eval sometimes resets $!
 801         eval { $proto->can($method) } || push @nok, $method;
 802     }
 803
 804     my $name;
 805     $name = @methods == 1 ? "$class->can('$methods[0]')"
 806                           : "$class->can(...)";
 807
 808     _ok( !@nok, _where(), $name );
 809 }
 810
 811
 812 # Call $class->new( @$args ); and run the result through isa_ok.
 813 # See Test::More::new_ok
 814 sub new_ok {
 815     my($class, $args, $obj_name) = @_;
 816     $args ||= [];
 817     $object_name = "The object" unless defined $obj_name;
 818
 819     local $Level = $Level + 1;
 820
 821     my $obj;
 822     my $ok = eval { $obj = $class->new(@$args); 1 };
 823     my $error = $@;
 824
 825     if($ok) {
 826         isa_ok($obj, $class, $object_name);
 827     }
 828     else {
 829         ok( 0, "new() died" );
 830         diag("Error was:  $@");
 831     }
 832
 833     return $obj;
 834
 835 }
 836
 837
 838 sub isa_ok ($$;$) {
 839     my($object, $class, $obj_name) = @_;
 840
 841     my $diag;
 842     $obj_name = 'The object' unless defined $obj_name;
 843     my $name = "$obj_name isa $class";
 844     if( !defined $object ) {
 845         $diag = "$obj_name isn't defined";
 846     }
 847     elsif( !ref $object ) {
 848         $diag = "$obj_name isn't a reference";
 849     }
 850     else {
 851         # We can't use UNIVERSAL::isa because we want to honor isa() overrides
 852         local($@, $!);  # eval sometimes resets $!
 853         my $rslt = eval { $object->isa($class) };
 854         if( $@ ) {
 855             if( $@ =~ /^Can't call method "isa" on unblessed reference/ ) {
 856                 if( !UNIVERSAL::isa($object, $class) ) {
 857                     my $ref = ref $object;
 858                     $diag = "$obj_name isn't a '$class' it's a '$ref'";
 859                 }
 860             } else {
 861                 die <<WHOA;
 862 WHOA! I tried to call ->isa on your object and got some weird error.
 863 This should never happen.  Please contact the author immediately.
 864 Here's the error.
 865 $@
 866 WHOA
 867             }
 868         }
 869         elsif( !$rslt ) {
 870             my $ref = ref $object;
 871             $diag = "$obj_name isn't a '$class' it's a '$ref'";
 872         }
 873     }
 874
 875     _ok( !$diag, _where(), $name );
 876 }
 877
 878 # Set a watchdog to timeout the entire test file
 879 # NOTE:  If the test file uses 'threads', then call the watchdog() function
 880 #        _AFTER_ the 'threads' module is loaded.
 881 sub watchdog ($;$)
 882 {
 883     my $timeout = shift;
 884     my $method  = shift || "";
 885     my $timeout_msg = 'Test process timed out - terminating';
 886
 887     # Valgrind slows perl way down so give it more time before dying.
 888     $timeout *= 10 if $ENV{PERL_VALGRIND};
 889
 890     my $pid_to_kill = $$;   # PID for this process
 891
 892     if ($method eq "alarm") {
 893         goto WATCHDOG_VIA_ALARM;
 894     }
 895
 896     # shut up use only once warning
 897     my $threads_on = $threads::threads && $threads::threads;
 898
 899     # Don't use a watchdog process if 'threads' is loaded -
 900     #   use a watchdog thread instead
 901     if (!$threads_on) {
 902
 903         # On Windows and VMS, try launching a watchdog process
 904         #   using system(1, ...) (see perlport.pod)
 905         if ($is_mswin || $is_vms) {
 906             # On Windows, try to get the 'real' PID
 907             if ($is_mswin) {
 908                 eval { require Win32; };
 909                 if (defined(&Win32::GetCurrentProcessId)) {
 910                     $pid_to_kill = Win32::GetCurrentProcessId();
 911                 }
 912             }
 913
 914             # If we still have a fake PID, we can't use this method at all
 915             return if ($pid_to_kill <= 0);
 916
 917             # Launch watchdog process
 918             my $watchdog;
 919             eval {
 920                 local $SIG{'__WARN__'} = sub {
 921                     _diag("Watchdog warning: $_[0]");
 922                 };
 923                 my $sig = $is_vms ? 'TERM' : 'KILL';
 924                 my $cmd = _create_runperl( prog =>  "sleep($timeout);" .
 925                                                     "warn qq/# $timeout_msg" . '\n/;' .
 926                                                     "kill($sig, $pid_to_kill);");
 927                 $watchdog = system(1, $cmd);
 928             };
 929             if ($@ || ($watchdog <= 0)) {
 930                 _diag('Failed to start watchdog');
 931                 _diag($@) if $@;
 932                 undef($watchdog);
 933                 return;
 934             }
 935
 936             # Add END block to parent to terminate and
 937             #   clean up watchdog process
 938             eval "END { local \$! = 0; local \$? = 0;
 939                         wait() if kill('KILL', $watchdog); };";
 940             return;
 941         }
 942
 943         # Try using fork() to generate a watchdog process
 944         my $watchdog;
 945         eval { $watchdog = fork() };
 946         if (defined($watchdog)) {
 947             if ($watchdog) {   # Parent process
 948                 # Add END block to parent to terminate and
 949                 #   clean up watchdog process
 950                 eval "END { local \$! = 0; local \$? = 0;
 951                             wait() if kill('KILL', $watchdog); };";
 952                 return;
 953             }
 954
 955             ### Watchdog process code
 956
 957             # Load POSIX if available
 958             eval { require POSIX; };
 959
 960             # Execute the timeout
 961             sleep($timeout - 2) if ($timeout > 2);   # Workaround for perlbug #49073
 962             sleep(2);
 963
 964             # Kill test process if still running
 965             if (kill(0, $pid_to_kill)) {
 966                 _diag($timeout_msg);
 967                 kill('KILL', $pid_to_kill);
 968             }
 969
 970             # Don't execute END block (added at beginning of this file)
 971             $NO_ENDING = 1;
 972
 973             # Terminate ourself (i.e., the watchdog)
 974             POSIX::_exit(1) if (defined(&POSIX::_exit));
 975             exit(1);
 976         }
 977
 978         # fork() failed - fall through and try using a thread
 979     }
 980
 981     # Use a watchdog thread because either 'threads' is loaded,
 982     #   or fork() failed
 983     if (eval 'require threads; 1') {
 984         'threads'->create(sub {
 985                 # Load POSIX if available
 986                 eval { require POSIX; };
 987
 988                 # Execute the timeout
 989                 my $time_left = $timeout;
 990                 do {
 991                     $time_left = $time_left - sleep($time_left);
 992                 } while ($time_left > 0);
 993
 994                 # Kill the parent (and ourself)
 995                 select(STDERR); $| = 1;
 996                 _diag($timeout_msg);
 997                 POSIX::_exit(1) if (defined(&POSIX::_exit));
 998                 my $sig = $is_vms ? 'TERM' : 'KILL';
 999                 kill($sig, $pid_to_kill);
1000             })->detach();
1001         return;
1002     }
1003
1004     # If everything above fails, then just use an alarm timeout
1005 WATCHDOG_VIA_ALARM:
1006     if (eval { alarm($timeout); 1; }) {
1007         # Load POSIX if available
1008         eval { require POSIX; };
1009
1010         # Alarm handler will do the actual 'killing'
1011         $SIG{'ALRM'} = sub {
1012             select(STDERR); $| = 1;
1013             _diag($timeout_msg);
1014             POSIX::_exit(1) if (defined(&POSIX::_exit));
1015             my $sig = $is_vms ? 'TERM' : 'KILL';
1016             kill($sig, $pid_to_kill);
1017         };
1018     }
1019 }
1020
1021 my $cp_0037 =   # EBCDIC code page 0037
1022     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x25\x0B\x0C\x0D\x0E\x0F' .
1023     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1024     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1025     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1026     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1027     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xBA\xE0\xBB\xB0\x6D' .
1028     '\x79\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1029     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xC0\x4F\xD0\xA1\x07' .
1030     '\x20\x21\x22\x23\x24\x15\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1031     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\xFF' .
1032     '\x41\xAA\x4A\xB1\x9F\xB2\x6A\xB5\xBD\xB4\x9A\x8A\x5F\xCA\xAF\xBC' .
1033     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1034     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1035     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xFD\xFE\xFB\xFC\xAD\xAE\x59' .
1036     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1037     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xDD\xDE\xDB\xDC\x8D\x8E\xDF';
1038
1039 my $cp_1047 =   # EBCDIC code page 1047
1040     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x15\x0B\x0C\x0D\x0E\x0F' .
1041     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1042     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1043     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1044     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1045     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xAD\xE0\xBD\x5F\x6D' .
1046     '\x79\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1047     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xC0\x4F\xD0\xA1\x07' .
1048     '\x20\x21\x22\x23\x24\x25\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1049     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\xFF' .
1050     '\x41\xAA\x4A\xB1\x9F\xB2\x6A\xB5\xBB\xB4\x9A\x8A\xB0\xCA\xAF\xBC' .
1051     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1052     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1053     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xFD\xFE\xFB\xFC\xBA\xAE\x59' .
1054     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1055     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xDD\xDE\xDB\xDC\x8D\x8E\xDF';
1056
1057 my $cp_bc = # EBCDIC code page POSiX-BC
1058     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x15\x0B\x0C\x0D\x0E\x0F' .
1059     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1060     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1061     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1062     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1063     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xBB\xBC\xBD\x6A\x6D' .
1064     '\x4A\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1065     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xFB\x4F\xFD\xFF\x07' .
1066     '\x20\x21\x22\x23\x24\x25\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1067     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\x5F' .
1068     '\x41\xAA\xB0\xB1\x9F\xB2\xD0\xB5\x79\xB4\x9A\x8A\xBA\xCA\xAF\xA1' .
1069     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1070     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1071     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xE0\xFE\xDD\xFC\xAD\xAE\x59' .
1072     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1073     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xC0\xDE\xDB\xDC\x8D\x8E\xDF';
1074
1075 my $straight =  # Avoid ranges
1076     '\x00\x01\x02\x03\x04\x05\x06\x07\x08\x09\x0A\x0B\x0C\x0D\x0E\x0F' .
1077     '\x10\x11\x12\x13\x14\x15\x16\x17\x18\x19\x1A\x1B\x1C\x1D\x1E\x1F' .
1078     '\x20\x21\x22\x23\x24\x25\x26\x27\x28\x29\x2A\x2B\x2C\x2D\x2E\x2F' .
1079     '\x30\x31\x32\x33\x34\x35\x36\x37\x38\x39\x3A\x3B\x3C\x3D\x3E\x3F' .
1080     '\x40\x41\x42\x43\x44\x45\x46\x47\x48\x49\x4A\x4B\x4C\x4D\x4E\x4F' .
1081     '\x50\x51\x52\x53\x54\x55\x56\x57\x58\x59\x5A\x5B\x5C\x5D\x5E\x5F' .
1082     '\x60\x61\x62\x63\x64\x65\x66\x67\x68\x69\x6A\x6B\x6C\x6D\x6E\x6F' .
1083     '\x70\x71\x72\x73\x74\x75\x76\x77\x78\x79\x7A\x7B\x7C\x7D\x7E\x7F' .
1084     '\x80\x81\x82\x83\x84\x85\x86\x87\x88\x89\x8A\x8B\x8C\x8D\x8E\x8F' .
1085     '\x90\x91\x92\x93\x94\x95\x96\x97\x98\x99\x9A\x9B\x9C\x9D\x9E\x9F' .
1086     '\xA0\xA1\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xAA\xAB\xAC\xAD\xAE\xAF' .
1087     '\xB0\xB1\xB2\xB3\xB4\xB5\xB6\xB7\xB8\xB9\xBA\xBB\xBC\xBD\xBE\xBF' .
1088     '\xC0\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xCA\xCB\xCC\xCD\xCE\xCF' .
1089     '\xD0\xD1\xD2\xD3\xD4\xD5\xD6\xD7\xD8\xD9\xDA\xDB\xDC\xDD\xDE\xDF' .
1090     '\xE0\xE1\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xEA\xEB\xEC\xED\xEE\xEF' .
1091     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\xFA\xFB\xFC\xFD\xFE\xFF';
1092
1093 # The following 2 functions allow tests to work on both EBCDIC and
1094 # ASCII-ish platforms.  They convert string scalars between the native
1095 # character set and the set of 256 characters which is usually called
1096 # Latin1.
1097 #
1098 # These routines don't work on UTF-EBCDIC and UTF-8.
1099
1100 sub native_to_latin1($) {
1101     my $string = shift;
1102
1103     return $string if ord('^') == 94;   # ASCII, Latin1
1104     my $cp;
1105     if (ord('^') == 95) {    # EBCDIC 1047
1106         $cp = \$cp_1047;
1107     }
1108     elsif (ord('^') == 106) {   # EBCDIC POSIX-BC
1109         $cp = \$cp_bc;
1110     }
1111     elsif (ord('^') == 176)  {   # EBCDIC 037 */
1112         $cp = \$cp_0037;
1113     }
1114     else {
1115         die "Unknown native character set";
1116     }
1117
1118     eval '$string =~ tr/' . $$cp . '/' . $straight . '/';
1119     return $string;
1120 }
1121
1122 sub latin1_to_native($) {
1123     my $string = shift;
1124
1125     return $string if ord('^') == 94;   # ASCII, Latin1
1126     my $cp;
1127     if (ord('^') == 95) {    # EBCDIC 1047
1128         $cp = \$cp_1047;
1129     }
1130     elsif (ord('^') == 106) {   # EBCDIC POSIX-BC
1131         $cp = \$cp_bc;
1132     }
1133     elsif (ord('^') == 176)  {   # EBCDIC 037 */
1134         $cp = \$cp_0037;
1135     }
1136     else {
1137         die "Unknown native character set";
1138     }
1139
1140     eval '$string =~ tr/' . $straight . '/' . $$cp . '/';
1141     return $string;
1142 }
1143
1144 sub ord_latin1_to_native {
1145     # given an input code point, return the platform's native
1146     # equivalent value.  Anything above latin1 is itself.
1147
1148     my $ord = shift;
1149     return $ord if $ord > 255;
1150     return ord latin1_to_native(chr $ord);
1151 }
1152
1153 sub ord_native_to_latin1 {
1154     # given an input platform code point, return the latin1 equivalent value.
1155     # Anything above latin1 is itself.
1156
1157     my $ord = shift;
1158     return $ord if $ord > 255;
1159     return ord native_to_latin1(chr $ord);
1160 }
1161
1162 1;