3 perldata - Perl data types
8 X<variable, name> X<variable name> X<data type> X<type>
10 Perl has three built-in data types: scalars, arrays of scalars, and
11 associative arrays of scalars, known as "hashes". A scalar is a
12 single string (of any size, limited only by the available memory),
13 number, or a reference to something (which will be discussed
14 in L<perlref>). Normal arrays are ordered lists of scalars indexed
15 by number, starting with 0. Hashes are unordered collections of scalar
16 values indexed by their associated string key.
18 Values are usually referred to by name, or through a named reference.
19 The first character of the name tells you to what sort of data
20 structure it refers. The rest of the name tells you the particular
21 value to which it refers. Usually this name is a single I<identifier>,
22 that is, a string beginning with a letter or underscore, and
23 containing letters, underscores, and digits. In some cases, it may
24 be a chain of identifiers, separated by C<::> (or by the slightly
25 archaic C<'>); all but the last are interpreted as names of packages,
26 to locate the namespace in which to look up the final identifier
27 (see L<perlmod/Packages> for details). For a more in-depth discussion
28 on identifiers, see L</Identifier parsing>. It's possible to
29 substitute for a simple identifier, an expression that produces a reference
30 to the value at runtime. This is described in more detail below
34 Perl also has its own built-in variables whose names don't follow
35 these rules. They have strange names so they don't accidentally
36 collide with one of your normal variables. Strings that match
37 parenthesized parts of a regular expression are saved under names
38 containing only digits after the C<$> (see L<perlop> and L<perlre>).
39 In addition, several special variables that provide windows into
40 the inner working of Perl have names containing punctuation characters.
41 These are documented in L<perlvar>.
44 Scalar values are always named with '$', even when referring to a
45 scalar that is part of an array or a hash. The '$' symbol works
46 semantically like the English word "the" in that it indicates a
47 single value is expected.
50 $days # the simple scalar value "days"
51 $days[28] # the 29th element of array @days
52 $days{'Feb'} # the 'Feb' value from hash %days
53 $#days # the last index of array @days
55 Entire arrays (and slices of arrays and hashes) are denoted by '@',
56 which works much as the word "these" or "those" does in English,
57 in that it indicates multiple values are expected.
60 @days # ($days[0], $days[1],... $days[n])
61 @days[3,4,5] # same as ($days[3],$days[4],$days[5])
62 @days{'a','c'} # same as ($days{'a'},$days{'c'})
64 Entire hashes are denoted by '%':
67 %days # (key1, val1, key2, val2 ...)
69 In addition, subroutines are named with an initial '&', though this
70 is optional when unambiguous, just as the word "do" is often redundant
71 in English. Symbol table entries can be named with an initial '*',
72 but you don't really care about that yet (if ever :-).
74 Every variable type has its own namespace, as do several
75 non-variable identifiers. This means that you can, without fear
76 of conflict, use the same name for a scalar variable, an array, or
77 a hash--or, for that matter, for a filehandle, a directory handle, a
78 subroutine name, a format name, or a label. This means that $foo
79 and @foo are two different variables. It also means that C<$foo[1]>
80 is a part of @foo, not a part of $foo. This may seem a bit weird,
81 but that's okay, because it is weird.
84 Because variable references always start with '$', '@', or '%', the
85 "reserved" words aren't in fact reserved with respect to variable
86 names. They I<are> reserved with respect to labels and filehandles,
87 however, which don't have an initial special character. You can't
88 have a filehandle named "log", for instance. Hint: you could say
89 C<open(LOG,'logfile')> rather than C<open(log,'logfile')>. Using
90 uppercase filehandles also improves readability and protects you
91 from conflict with future reserved words. Case I<is> significant--"FOO",
92 "Foo", and "foo" are all different names. Names that start with a
93 letter or underscore may also contain digits and underscores.
94 X<identifier, case sensitivity>
97 It is possible to replace such an alphanumeric name with an expression
98 that returns a reference to the appropriate type. For a description
99 of this, see L<perlref>.
101 Names that start with a digit may contain only more digits. Names
102 that do not start with a letter, underscore, digit or a caret are
103 limited to one character, e.g., C<$%> or
104 C<$$>. (Most of these one character names have a predefined
105 significance to Perl. For instance, C<$$> is the current process
106 id. And all such names are reserved for Perl's possible use.)
108 =head2 Identifier parsing
111 Up until Perl 5.18, the actual rules of what a valid identifier
112 was were a bit fuzzy. However, in general, anything defined here should
113 work on previous versions of Perl, while the opposite -- edge cases
114 that work in previous versions, but aren't defined here -- probably
115 won't work on newer versions.
116 As an important side note, please note that the following only applies
117 to bareword identifiers as found in Perl source code, not identifiers
118 introduced through symbolic references, which have much fewer
120 If working under the effect of the C<use utf8;> pragma, the following
123 / (?[ ( \p{Word} & \p{XID_Start} ) + [_] ])
124 (?[ ( \p{Word} & \p{XID_Continue} ) ]) * /x
126 That is, a "start" character followed by any number of "continue"
127 characters. Perl requires every character in an identifier to also
128 match C<\w> (this prevents some problematic cases); and Perl
129 additionally accepts identifier names beginning with an underscore.
131 If not under C<use utf8>, the source is treated as ASCII + 128 extra
132 generic characters, and identifiers should match
134 / (?aa) (?!\d) \w+ /x
136 That is, any word character in the ASCII range, as long as the first
137 character is not a digit.
139 There are two package separators in Perl: A double colon (C<::>) and a single
140 quote (C<'>). Normal identifiers can start or end with a double colon, and
141 can contain several parts delimited by double colons.
142 Single quotes have similar rules, but with the exception that they are not
143 legal at the end of an identifier: That is, C<$'foo> and C<$foo'bar> are
144 legal, but C<$foo'bar'> is not.
146 Additionally, if the identifier is preceded by a sigil --
147 that is, if the identifier is part of a variable name -- it
148 may optionally be enclosed in braces.
150 While you can mix double colons with singles quotes, the quotes must come
151 after the colons: C<$::::'foo> and C<$foo::'bar> are legal, but C<$::'::foo>
152 and C<$foo'::bar> are not.
154 Put together, a grammar to match a basic identifier becomes
161 (?&normal_identifier)
162 | \{ \s* (?&normal_identifier) \s* \}
165 (?<normal_identifier>
168 (?: (?= (?: :: )+ '? | (?: :: )* ' ) (?&normal_identifier) )?
173 (?(?{ (caller(0))[8] & $utf8::hint_bits })
174 (?&Perl_XIDS) (?&Perl_XIDC)*
178 (?<sigil> [&*\$\@\%])
179 (?<Perl_XIDS> (?[ ( \p{Word} & \p{XID_Start} ) + [_] ]) )
180 (?<Perl_XIDC> (?[ \p{Word} & \p{XID_Continue} ]) )
184 Meanwhile, special identifiers don't follow the above rules; For the most
185 part, all of the identifiers in this category have a special meaning given
186 by Perl. Because they have special parsing rules, these generally can't be
187 fully-qualified. They come in six forms (but don't use forms 5 and 6):
193 A sigil, followed solely by digits matching C<\p{POSIX_Digit}>, like
194 C<$0>, C<$1>, or C<$10000>.
198 A sigil followed by a single character matching the C<\p{POSIX_Punct}>
199 property, like C<$!> or C<%+>, except the character C<"{"> doesn't work.
203 A sigil, followed by a caret and any one of the characters
204 C<[][A-Z^_?\]>, like C<$^V> or C<$^]>.
208 Similar to the above, a sigil, followed by bareword text in braces,
209 where the first character is a caret. The next character is any one of
210 the characters C<[][A-Z^_?\]>, followed by ASCII word characters. An
211 example is C<${^GLOBAL_PHASE}>.
215 A sigil, followed by any single character in the range C<[\xA1-\xAC\xAE-\xFF]>
216 when not under C<S<"use utf8">>. (Under C<S<"use utf8">>, the normal
217 identifier rules given earlier in this section apply.) Use of
218 non-graphic characters (the C1 controls, the NO-BREAK SPACE, and the
219 SOFT HYPHEN) has been disallowed since v5.26.0.
220 The use of the other characters is unwise, as these are all
221 reserved to have special meaning to Perl, and none of them currently
222 do have special meaning, though this could change without notice.
224 Note that an implication of this form is that there are identifiers only
225 legal under C<S<"use utf8">>, and vice-versa, for example the identifier
226 C<$E<233>tat> is legal under C<S<"use utf8">>, but is otherwise
227 considered to be the single character variable C<$E<233>> followed by
228 the bareword C<"tat">, the combination of which is a syntax error.
232 This is a combination of the previous two forms. It is valid only when
233 not under S<C<"use utf8">> (normal identifier rules apply when under
234 S<C<"use utf8">>). The form is a sigil, followed by text in braces,
235 where the first character is any one of the characters in the range
236 C<[\x80-\xFF]> followed by ASCII word characters up to the trailing
239 The same caveats as the previous form apply: The non-graphic
240 characters are no longer allowed with S<"use utf8">, it is unwise
241 to use this form at all, and utf8ness makes a big difference.
245 Prior to Perl v5.24, non-graphical ASCII control characters were also
246 allowed in some situations; this had been deprecated since v5.20.
249 X<context> X<scalar context> X<list context>
251 The interpretation of operations and values in Perl sometimes depends
252 on the requirements of the context around the operation or value.
253 There are two major contexts: list and scalar. Certain operations
254 return list values in contexts wanting a list, and scalar values
255 otherwise. If this is true of an operation it will be mentioned in
256 the documentation for that operation. In other words, Perl overloads
257 certain operations based on whether the expected return value is
258 singular or plural. Some words in English work this way, like "fish"
261 In a reciprocal fashion, an operation provides either a scalar or a
262 list context to each of its arguments. For example, if you say
266 the integer operation provides scalar context for the <>
267 operator, which responds by reading one line from STDIN and passing it
268 back to the integer operation, which will then find the integer value
269 of that line and return that. If, on the other hand, you say
273 then the sort operation provides list context for <>, which
274 will proceed to read every line available up to the end of file, and
275 pass that list of lines back to the sort routine, which will then
276 sort those lines and return them as a list to whatever the context
279 Assignment is a little bit special in that it uses its left argument
280 to determine the context for the right argument. Assignment to a
281 scalar evaluates the right-hand side in scalar context, while
282 assignment to an array or hash evaluates the righthand side in list
283 context. Assignment to a list (or slice, which is just a list
284 anyway) also evaluates the right-hand side in list context.
286 When you use the C<use warnings> pragma or Perl's B<-w> command-line
287 option, you may see warnings
288 about useless uses of constants or functions in "void context".
289 Void context just means the value has been discarded, such as a
290 statement containing only C<"fred";> or C<getpwuid(0);>. It still
291 counts as scalar context for functions that care whether or not
292 they're being called in list context.
294 User-defined subroutines may choose to care whether they are being
295 called in a void, scalar, or list context. Most subroutines do not
296 need to bother, though. That's because both scalars and lists are
297 automatically interpolated into lists. See L<perlfunc/wantarray>
298 for how you would dynamically discern your function's calling
302 X<scalar> X<number> X<string> X<reference>
304 All data in Perl is a scalar, an array of scalars, or a hash of
305 scalars. A scalar may contain one single value in any of three
306 different flavors: a number, a string, or a reference. In general,
307 conversion from one form to another is transparent. Although a
308 scalar may not directly hold multiple values, it may contain a
309 reference to an array or hash which in turn contains multiple values.
311 Scalars aren't necessarily one thing or another. There's no place
312 to declare a scalar variable to be of type "string", type "number",
313 type "reference", or anything else. Because of the automatic
314 conversion of scalars, operations that return scalars don't need
315 to care (and in fact, cannot care) whether their caller is looking
316 for a string, a number, or a reference. Perl is a contextually
317 polymorphic language whose scalars can be strings, numbers, or
318 references (which includes objects). Although strings and numbers
319 are considered pretty much the same thing for nearly all purposes,
320 references are strongly-typed, uncastable pointers with builtin
321 reference-counting and destructor invocation.
323 X<truth> X<falsehood> X<true> X<false> X<!> X<not> X<negation> X<0>
325 A scalar value is interpreted as FALSE in the Boolean sense
326 if it is undefined, the null string or the number 0 (or its
327 string equivalent, "0"), and TRUE if it is anything else. The
328 Boolean context is just a special kind of scalar context where no
329 conversion to a string or a number is ever performed.
330 Negation of a true value by C<!> or C<not> returns a special false value.
331 When evaluated as a string it is treated as C<"">, but as a number, it
332 is treated as 0. Most Perl operators
333 that return true or false behave this way.
335 There are actually two varieties of null strings (sometimes referred
336 to as "empty" strings), a defined one and an undefined one. The
337 defined version is just a string of length zero, such as C<"">.
338 The undefined version is the value that indicates that there is
339 no real value for something, such as when there was an error, or
340 at end of file, or when you refer to an uninitialized variable or
341 element of an array or hash. Although in early versions of Perl,
342 an undefined scalar could become defined when first used in a
343 place expecting a defined value, this no longer happens except for
344 rare cases of autovivification as explained in L<perlref>. You can
345 use the defined() operator to determine whether a scalar value is
346 defined (this has no meaning on arrays or hashes), and the undef()
347 operator to produce an undefined value.
348 X<defined> X<undefined> X<undef> X<null> X<string, null>
350 To find out whether a given string is a valid non-zero number, it's
351 sometimes enough to test it against both numeric 0 and also lexical
352 "0" (although this will cause noises if warnings are on). That's
353 because strings that aren't numbers count as 0, just as they do in B<awk>:
355 if ($str == 0 && $str ne "0") {
356 warn "That doesn't look like a number";
359 That method may be best because otherwise you won't treat IEEE
360 notations like C<NaN> or C<Infinity> properly. At other times, you
361 might prefer to determine whether string data can be used numerically
362 by calling the POSIX::strtod() function or by inspecting your string
363 with a regular expression (as documented in L<perlre>).
365 warn "has nondigits" if /\D/;
366 warn "not a natural number" unless /^\d+$/; # rejects -3
367 warn "not an integer" unless /^-?\d+$/; # rejects +3
368 warn "not an integer" unless /^[+-]?\d+$/;
369 warn "not a decimal number" unless /^-?\d+\.?\d*$/; # rejects .2
370 warn "not a decimal number" unless /^-?(?:\d+(?:\.\d*)?|\.\d+)$/;
372 unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/;
374 The length of an array is a scalar value. You may find the length
375 of array @days by evaluating C<$#days>, as in B<csh>. However, this
376 isn't the length of the array; it's the subscript of the last element,
377 which is a different value since there is ordinarily a 0th element.
378 Assigning to C<$#days> actually changes the length of the array.
379 Shortening an array this way destroys intervening values. Lengthening
380 an array that was previously shortened does not recover values
381 that were in those elements.
382 X<$#> X<array, length>
384 You can also gain some minuscule measure of efficiency by pre-extending
385 an array that is going to get big. You can also extend an array
386 by assigning to an element that is off the end of the array. You
387 can truncate an array down to nothing by assigning the null list
388 () to it. The following are equivalent:
393 If you evaluate an array in scalar context, it returns the length
394 of the array. (Note that this is not true of lists, which return
395 the last value, like the C comma operator, nor of built-in functions,
396 which return whatever they feel like returning.) The following is
400 scalar(@whatever) == $#whatever + 1;
402 Some programmers choose to use an explicit conversion so as to
403 leave nothing to doubt:
405 $element_count = scalar(@whatever);
407 If you evaluate a hash in scalar context, it returns a false value if
408 the hash is empty. If there are any key/value pairs, it returns a
409 true value. A more precise definition is version dependent.
411 Prior to Perl 5.25 the value returned was a string consisting of the
412 number of used buckets and the number of allocated buckets, separated
413 by a slash. This is pretty much useful only to find out whether
414 Perl's internal hashing algorithm is performing poorly on your data
415 set. For example, you stick 10,000 things in a hash, but evaluating
416 %HASH in scalar context reveals C<"1/16">, which means only one out
417 of sixteen buckets has been touched, and presumably contains all
418 10,000 of your items. This isn't supposed to happen.
420 As of Perl 5.25 the return was changed to be the count of keys in the
421 hash. If you need access to the old behavior you can use
422 C<Hash::Util::bucket_ratio()> instead.
424 If a tied hash is evaluated in scalar context, the C<SCALAR> method is
425 called (with a fallback to C<FIRSTKEY>).
426 X<hash, scalar context> X<hash, bucket> X<bucket>
428 You can preallocate space for a hash by assigning to the keys() function.
429 This rounds up the allocated buckets to the next power of two:
431 keys(%users) = 1000; # allocate 1024 buckets
433 =head2 Scalar value constructors
434 X<scalar, literal> X<scalar, constant>
436 Numeric literals are specified in any of the following floating point or
441 .23E-10 # a very small number
442 3.14_15_92 # a very important number
443 4_294_967_296 # underscore for legibility
445 0xdead_beef # more hex
446 0377 # octal (only numbers, begins with 0)
447 0o12_345 # alternative octal (introduced in Perl 5.33.5)
449 0x1.999ap-4 # hexadecimal floating point (the 'p' is required)
451 You are allowed to use underscores (underbars) in numeric literals
452 between digits for legibility (but not multiple underscores in a row:
453 C<23__500> is not legal; C<23_500> is).
454 You could, for example, group binary
455 digits by threes (as for a Unix-style mode argument such as 0b110_100_100)
456 or by fours (to represent nibbles, as in 0b1010_0110) or in other groups.
459 String literals are usually delimited by either single or double
460 quotes. They work much like quotes in the standard Unix shells:
461 double-quoted string literals are subject to backslash and variable
462 substitution; single-quoted strings are not (except for C<\'> and
463 C<\\>). The usual C-style backslash rules apply for making
464 characters such as newline, tab, etc., as well as some more exotic
465 forms. See L<perlop/"Quote and Quote-like Operators"> for a list.
468 Hexadecimal, octal, or binary, representations in string literals
469 (e.g. '0xff') are not automatically converted to their integer
470 representation. The hex() and oct() functions make these conversions
471 for you. See L<perlfunc/hex> and L<perlfunc/oct> for more details.
473 Hexadecimal floating point can start just like a hexadecimal literal,
474 and it can be followed by an optional fractional hexadecimal part,
475 but it must be followed by C<p>, an optional sign, and a power of two.
476 The format is useful for accurately presenting floating point values,
477 avoiding conversions to or from decimal floating point, and therefore
478 avoiding possible loss in precision. Notice that while most current
479 platforms use the 64-bit IEEE 754 floating point, not all do. Another
480 potential source of (low-order) differences are the floating point
481 rounding modes, which can differ between CPUs, operating systems,
482 and compilers, and which Perl doesn't control.
484 You can also embed newlines directly in your strings, i.e., they can end
485 on a different line than they begin. This is nice, but if you forget
486 your trailing quote, the error will not be reported until Perl finds
487 another line containing the quote character, which may be much further
488 on in the script. Variable substitution inside strings is limited to
489 scalar variables, arrays, and array or hash slices. (In other words,
490 names beginning with $ or @, followed by an optional bracketed
491 expression as a subscript.) The following code segment prints out "The
495 $Price = '$100'; # not interpolated
496 print "The price is $Price.\n"; # interpolated
498 There is no double interpolation in Perl, so the C<$100> is left as is.
500 By default floating point numbers substituted inside strings use the
501 dot (".") as the decimal separator. If C<use locale> is in effect,
502 and POSIX::setlocale() has been called, the character used for the
503 decimal separator is affected by the LC_NUMERIC locale.
504 See L<perllocale> and L<POSIX>.
506 As in some shells, you can enclose the variable name in braces to
507 disambiguate it from following alphanumerics (and underscores).
509 this when interpolating a variable into a string to separate the
510 variable name from a following double-colon or an apostrophe, since
511 these would be otherwise treated as a package separator:
515 print PASSWD "${who}::0:0:Superuser:/:/bin/perl\n";
516 print "We use ${who}speak when ${who}'s here.\n";
518 Without the braces, Perl would have looked for a $whospeak, a
519 C<$who::0>, and a C<$who's> variable. The last two would be the
520 $0 and the $s variables in the (presumably) non-existent package
523 In fact, a simple identifier within such curlies is forced to be
524 a string, and likewise within a hash subscript. Neither need
525 quoting. Our earlier example, C<$days{'Feb'}> can be written as
526 C<$days{Feb}> and the quotes will be assumed automatically. But
527 anything more complicated in the subscript will be interpreted as an
528 expression. This means for example that C<$version{2.0}++> is
529 equivalent to C<$version{2}++>, not to C<$version{'2.0'}++>.
531 =head3 Special floating point: infinity (Inf) and not-a-number (NaN)
533 Floating point values include the special values C<Inf> and C<NaN>,
534 for infinity and not-a-number. The infinity can be also negative.
536 The infinity is the result of certain math operations that overflow
537 the floating point range, like 9**9**9. The not-a-number is the
538 result when the result is undefined or unrepresentable. Though note
539 that you cannot get C<NaN> from some common "undefined" or
540 "out-of-range" operations like dividing by zero, or square root of
541 a negative number, since Perl generates fatal errors for those.
543 The infinity and not-a-number have their own special arithmetic rules.
544 The general rule is that they are "contagious": C<Inf> plus one is
545 C<Inf>, and C<NaN> plus one is C<NaN>. Where things get interesting
546 is when you combine infinities and not-a-numbers: C<Inf> minus C<Inf>
547 and C<Inf> divided by C<Inf> are C<NaN> (while C<Inf> plus C<Inf> is
548 C<Inf> and C<Inf> times C<Inf> is C<Inf>). C<NaN> is also curious
549 in that it does not equal any number, I<including> itself:
552 Perl doesn't understand C<Inf> and C<NaN> as numeric literals, but
553 you can have them as strings, and Perl will convert them as needed:
554 "Inf" + 1. (You can, however, import them from the POSIX extension;
555 C<use POSIX qw(Inf NaN);> and then use them as literals.)
557 Note that on input (string to number) Perl accepts C<Inf> and C<NaN>
558 in many forms. Case is ignored, and the Win32-specific forms like
559 C<1.#INF> are understood, but on output the values are normalized to
562 =head3 Version Strings
563 X<version string> X<vstring> X<v-string>
565 A literal of the form C<v1.20.300.4000> is parsed as a string composed
566 of characters with the specified ordinals. This form, known as
567 v-strings, provides an alternative, more readable way to construct
568 strings, rather than use the somewhat less readable interpolation form
569 C<"\x{1}\x{14}\x{12c}\x{fa0}">. This is useful for representing
570 Unicode strings, and for comparing version "numbers" using the string
571 comparison operators, C<cmp>, C<gt>, C<lt> etc. If there are two or
572 more dots in the literal, the leading C<v> may be omitted.
574 print v9786; # prints SMILEY, "\x{263a}"
575 print v102.111.111; # prints "foo"
576 print 102.111.111; # same
578 Such literals are accepted by both C<require> and C<use> for
579 doing a version check. Note that using the v-strings for IPv4
580 addresses is not portable unless you also use the
581 inet_aton()/inet_ntoa() routines of the Socket package.
583 Note that since Perl 5.8.1 the single-number v-strings (like C<v65>)
584 are not v-strings before the C<< => >> operator (which is usually used
585 to separate a hash key from a hash value); instead they are interpreted
586 as literal strings ('v65'). They were v-strings from Perl 5.6.0 to
587 Perl 5.8.0, but that caused more confusion and breakage than good.
588 Multi-number v-strings like C<v65.66> and C<65.66.67> continue to
591 =head3 Special Literals
592 X<special literal> X<__END__> X<__DATA__> X<END> X<DATA>
593 X<end> X<data> X<^D> X<^Z>
595 The special literals __FILE__, __LINE__, and __PACKAGE__
596 represent the current filename, line number, and package name at that
597 point in your program. __SUB__ gives a reference to the current
598 subroutine. They may be used only as separate tokens; they
599 will not be interpolated into strings. If there is no current package
600 (due to an empty C<package;> directive), __PACKAGE__ is the undefined
601 value. (But the empty C<package;> is no longer supported, as of version
602 5.10.) Outside of a subroutine, __SUB__ is the undefined value. __SUB__
603 is only available in 5.16 or higher, and only with a C<use v5.16> or
604 C<use feature "current_sub"> declaration.
605 X<__FILE__> X<__LINE__> X<__PACKAGE__> X<__SUB__>
606 X<line> X<file> X<package>
608 The two control characters ^D and ^Z, and the tokens __END__ and __DATA__
609 may be used to indicate the logical end of the script before the actual
610 end of file. Any following text is ignored by the interpreter unless
611 read by the program as described below.
613 Text after __DATA__ may be read via the filehandle C<PACKNAME::DATA>,
614 where C<PACKNAME> is the package that was current when the __DATA__
615 token was encountered. The filehandle is left open pointing to the
616 line after __DATA__. The program should C<close DATA> when it is done
617 reading from it. (Leaving it open leaks filehandles if the module is
618 reloaded for any reason, so it's a safer practice to close it.) For
619 compatibility with older scripts written before __DATA__ was
620 introduced, __END__ behaves like __DATA__ in the top level script (but
621 not in files loaded with C<require> or C<do>) and leaves the remaining
622 contents of the file accessible via C<main::DATA>.
624 while (my $line = <DATA>) { print $line; }
629 The C<DATA> file handle by default has whatever PerlIO layers were
630 in place when Perl read the file to parse the source. Normally that
631 means that the file is being read bytewise, as if it were encoded in
632 Latin-1, but there are two major ways for it to be otherwise. Firstly,
633 if the C<__END__>/C<__DATA__> token is in the scope of a C<use utf8>
634 pragma then the C<DATA> handle will be in UTF-8 mode. And secondly,
635 if the source is being read from perl's standard input then the C<DATA>
636 file handle is actually aliased to the C<STDIN> file handle, and may
637 be in UTF-8 mode because of the C<PERL_UNICODE> environment variable or
638 perl's command-line switches.
640 See L<SelfLoader> for more description of __DATA__, and
641 an example of its use. Note that you cannot read from the DATA
642 filehandle in a BEGIN block: the BEGIN block is executed as soon
643 as it is seen (during compilation), at which point the corresponding
644 __DATA__ (or __END__) token has not yet been seen.
649 A word that has no other interpretation in the grammar will
650 be treated as if it were a quoted string. These are known as
651 "barewords". As with filehandles and labels, a bareword that consists
652 entirely of lowercase letters risks conflict with future reserved
653 words, and if you use the C<use warnings> pragma or the B<-w> switch,
654 Perl will warn you about any such words. Perl limits barewords (like
655 identifiers) to about 250 characters. Future versions of Perl are likely
656 to eliminate these arbitrary limitations.
658 Some people may wish to outlaw barewords entirely. If you
663 then any bareword that would NOT be interpreted as a subroutine call
664 produces a compile-time error instead. The restriction lasts to the
665 end of the enclosing block. An inner block may countermand this
666 by saying C<no strict 'subs'>.
668 =head3 Array Interpolation
669 X<array, interpolation> X<interpolation, array> X<$">
671 Arrays and slices are interpolated into double-quoted strings
672 by joining the elements with the delimiter specified in the C<$">
673 variable (C<$LIST_SEPARATOR> if "use English;" is specified),
674 space by default. The following are equivalent:
676 $temp = join($", @ARGV);
681 Within search patterns (which also undergo double-quotish substitution)
682 there is an unfortunate ambiguity: Is C</$foo[bar]/> to be interpreted as
683 C</${foo}[bar]/> (where C<[bar]> is a character class for the regular
684 expression) or as C</${foo[bar]}/> (where C<[bar]> is the subscript to array
685 @foo)? If @foo doesn't otherwise exist, then it's obviously a
686 character class. If @foo exists, Perl takes a good guess about C<[bar]>,
687 and is almost always right. If it does guess wrong, or if you're just
688 plain paranoid, you can force the correct interpretation with curly
691 If you're looking for the information on how to use here-documents,
692 which used to be here, that's been moved to
693 L<perlop/Quote and Quote-like Operators>.
695 =head2 List value constructors
698 List values are denoted by separating individual values by commas
699 (and enclosing the list in parentheses where precedence requires it):
703 In a context not requiring a list value, the value of what appears
704 to be a list literal is simply the value of the final element, as
705 with the C comma operator. For example,
707 @foo = ('cc', '-E', $bar);
709 assigns the entire list value to array @foo, but
711 $foo = ('cc', '-E', $bar);
713 assigns the value of variable $bar to the scalar variable $foo.
714 Note that the value of an actual array in scalar context is the
715 length of the array; the following assigns the value 3 to $foo:
717 @foo = ('cc', '-E', $bar);
718 $foo = @foo; # $foo gets 3
720 You may have an optional comma before the closing parenthesis of a
721 list literal, so that you can say:
729 To use a here-document to assign an array, one line per element,
730 you might use an approach like this:
732 @sauces = <<End_Lines =~ m/(\S.*\S)/g;
740 LISTs do automatic interpolation of sublists. That is, when a LIST is
741 evaluated, each element of the list is evaluated in list context, and
742 the resulting list value is interpolated into LIST just as if each
743 individual element were a member of LIST. Thus arrays and hashes lose their
744 identity in a LIST--the list
746 (@foo,@bar,&SomeSub,%glarch)
748 contains all the elements of @foo followed by all the elements of @bar,
749 followed by all the elements returned by the subroutine named SomeSub
750 called in list context, followed by the key/value pairs of %glarch.
751 To make a list reference that does I<NOT> interpolate, see L<perlref>.
753 The null list is represented by (). Interpolating it in a list
754 has no effect. Thus ((),(),()) is equivalent to (). Similarly,
755 interpolating an array with no elements is the same as if no
756 array had been interpolated at that point.
758 This interpolation combines with the facts that the opening
759 and closing parentheses are optional (except when necessary for
760 precedence) and lists may end with an optional comma to mean that
761 multiple commas within lists are legal syntax. The list C<1,,3> is a
762 concatenation of two lists, C<1,> and C<3>, the first of which ends
763 with that optional comma. C<1,,3> is C<(1,),(3)> is C<1,3> (And
764 similarly for C<1,,,3> is C<(1,),(,),3> is C<1,3> and so on.) Not that
765 we'd advise you to use this obfuscation.
767 A list value may also be subscripted like a normal array. You must
768 put the list in parentheses to avoid ambiguity. For example:
770 # Stat returns list value.
771 $time = (stat($file))[8];
774 $time = stat($file)[8]; # OOPS, FORGOT PARENTHESES
777 $hexdigit = ('a','b','c','d','e','f')[$digit-10];
779 # A "reverse comma operator".
780 return (pop(@foo),pop(@foo))[0];
782 Lists may be assigned to only when each element of the list
783 is itself legal to assign to:
785 ($x, $y, $z) = (1, 2, 3);
787 ($map{'red'}, $map{'blue'}, $map{'green'}) = (0x00f, 0x0f0, 0xf00);
789 An exception to this is that you may assign to C<undef> in a list.
790 This is useful for throwing away some of the return values of a
793 ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
795 As of Perl 5.22, you can also use C<(undef)x2> instead of C<undef, undef>.
796 (You can also do C<($x) x 2>, which is less useful, because it assigns to
797 the same variable twice, clobbering the first value assigned.)
799 When you assign a list of scalars to an array, all previous values in that
800 array are wiped out and the number of elements in the array will now be equal to
801 the number of elements in the right-hand list -- the list from which
802 assignment was made. The array will automatically resize itself to precisely
803 accommodate each element in the right-hand list.
806 my (@xyz, $x, $y, $z);
809 print "@xyz\n"; # 1 2 3
811 @xyz = ('al', 'be', 'ga', 'de');
812 print "@xyz\n"; # al be ga de
815 print "@xyz\n"; # 101 102
817 When, however, you assign a list of scalars to another list of scalars, the
818 results differ according to whether the left-hand list -- the list being
819 assigned to -- has the same, more or fewer elements than the right-hand list.
821 ($x, $y, $z) = (1, 2, 3);
822 print "$x $y $z\n"; # 1 2 3
824 ($x, $y, $z) = ('al', 'be', 'ga', 'de');
825 print "$x $y $z\n"; # al be ga
827 ($x, $y, $z) = (101, 102);
828 print "$x $y $z\n"; # 101 102
829 # Use of uninitialized value $z in concatenation (.)
830 # or string at [program] line [line number].
832 If the number of scalars in the left-hand list is less than that in the
833 right-hand list, the "extra" scalars in the right-hand list will simply not be
836 If the number of scalars in the left-hand list is greater than that in the
837 left-hand list, the "missing" scalars will become undefined.
839 ($x, $y, $z) = (101, 102);
840 for my $el ($x, $y, $z) {
841 (defined $el) ? print "$el " : print "<undef>";
846 List assignment in scalar context returns the number of elements
847 produced by the expression on the right side of the assignment:
849 $x = (($foo,$bar) = (3,2,1)); # set $x to 3, not 2
850 $x = (($foo,$bar) = f()); # set $x to f()'s return count
852 This is handy when you want to do a list assignment in a Boolean
853 context, because most list functions return a null list when finished,
854 which when assigned produces a 0, which is interpreted as FALSE.
856 It's also the source of a useful idiom for executing a function or
857 performing an operation in list context and then counting the number of
858 return values, by assigning to an empty list and then using that
859 assignment in scalar context. For example, this code:
861 $count = () = $string =~ /\d+/g;
863 will place into $count the number of digit groups found in $string.
864 This happens because the pattern match is in list context (since it
865 is being assigned to the empty list), and will therefore return a list
866 of all matching parts of the string. The list assignment in scalar
867 context will translate that into the number of elements (here, the
868 number of times the pattern matched) and assign that to $count. Note
871 $count = $string =~ /\d+/g;
873 would not have worked, since a pattern match in scalar context will
874 only return true or false, rather than a count of matches.
876 The final element of a list assignment may be an array or a hash:
878 ($x, $y, @rest) = split;
879 my($x, $y, %rest) = @_;
881 You can actually put an array or hash anywhere in the list, but the first one
882 in the list will soak up all the values, and anything after it will become
883 undefined. This may be useful in a my() or local().
885 A hash can be initialized using a literal list holding pairs of
886 items to be interpreted as a key and a value:
888 # same as map assignment above
889 %map = ('red',0x00f,'blue',0x0f0,'green',0xf00);
891 While literal lists and named arrays are often interchangeable, that's
892 not the case for hashes. Just because you can subscript a list value like
893 a normal array does not mean that you can subscript a list value as a
894 hash. Likewise, hashes included as parts of other lists (including
895 parameters lists and return lists from functions) always flatten out into
896 key/value pairs. That's why it's good to use references sometimes.
898 It is often more readable to use the C<< => >> operator between key/value
899 pairs. The C<< => >> operator is mostly just a more visually distinctive
900 synonym for a comma, but it also arranges for its left-hand operand to be
901 interpreted as a string if it's a bareword that would be a legal simple
902 identifier. C<< => >> doesn't quote compound identifiers, that contain
903 double colons. This makes it nice for initializing hashes:
911 or for initializing hash references to be used as records:
914 witch => 'Mable the Merciless',
915 cat => 'Fluffy the Ferocious',
916 date => '10/31/1776',
919 or for using call-by-named-parameter to complicated functions:
921 $field = $query->radio_group(
922 name => 'group_name',
923 values => ['eenie','meenie','minie'],
929 Note that just because a hash is initialized in that order doesn't
930 mean that it comes out in that order. See L<perlfunc/sort> for examples
931 of how to arrange for an output ordering.
933 If a key appears more than once in the initializer list of a hash, the last
940 color => [0xDF, 0xFF, 0x00],
947 color => [0xDF, 0xFF, 0x00],
951 This can be used to provide overridable configuration defaults:
953 # values in %args take priority over %config_defaults
954 %config = (%config_defaults, %args);
958 An array can be accessed one scalar at a
959 time by specifying a dollar sign (C<$>), then the
960 name of the array (without the leading C<@>), then the subscript inside
961 square brackets. For example:
963 @myarray = (5, 50, 500, 5000);
964 print "The Third Element is", $myarray[2], "\n";
966 The array indices start with 0. A negative subscript retrieves its
967 value from the end. In our example, C<$myarray[-1]> would have been
968 5000, and C<$myarray[-2]> would have been 500.
970 Hash subscripts are similar, only instead of square brackets curly brackets
971 are used. For example:
976 "Einstein" => "Albert",
977 "Darwin" => "Charles",
978 "Feynman" => "Richard",
981 print "Darwin's First Name is ", $scientists{"Darwin"}, "\n";
983 You can also subscript a list to get a single element from it:
985 $dir = (getpwnam("daemon"))[7];
987 =head2 Multi-dimensional array emulation
989 Multidimensional arrays may be emulated by subscripting a hash with a
990 list. The elements of the list are joined with the subscript separator
997 $foo{join($;, $x, $y, $z)}
999 The default subscript separator is "\034", the same as SUBSEP in B<awk>.
1002 X<slice> X<array, slice> X<hash, slice>
1004 A slice accesses several elements of a list, an array, or a hash
1005 simultaneously using a list of subscripts. It's more convenient
1006 than writing out the individual elements as a list of separate
1009 ($him, $her) = @folks[0,-1]; # array slice
1010 @them = @folks[0 .. 3]; # array slice
1011 ($who, $home) = @ENV{"USER", "HOME"}; # hash slice
1012 ($uid, $dir) = (getpwnam("daemon"))[2,7]; # list slice
1014 Since you can assign to a list of variables, you can also assign to
1015 an array or hash slice.
1017 @days[3..5] = qw/Wed Thu Fri/;
1018 @colors{'red','blue','green'}
1019 = (0xff0000, 0x0000ff, 0x00ff00);
1020 @folks[0, -1] = @folks[-1, 0];
1022 The previous assignments are exactly equivalent to
1024 ($days[3], $days[4], $days[5]) = qw/Wed Thu Fri/;
1025 ($colors{'red'}, $colors{'blue'}, $colors{'green'})
1026 = (0xff0000, 0x0000ff, 0x00ff00);
1027 ($folks[0], $folks[-1]) = ($folks[-1], $folks[0]);
1029 Since changing a slice changes the original array or hash that it's
1030 slicing, a C<foreach> construct will alter some--or even all--of the
1031 values of the array or hash.
1033 foreach (@array[ 4 .. 10 ]) { s/peter/paul/ }
1035 foreach (@hash{qw[key1 key2]}) {
1036 s/^\s+//; # trim leading whitespace
1037 s/\s+$//; # trim trailing whitespace
1038 s/(\w+)/\u\L$1/g; # "titlecase" words
1041 As a special exception, when you slice a list (but not an array or a hash),
1042 if the list evaluates to empty, then taking a slice of that empty list will
1043 always yield the empty list in turn. Thus:
1045 @a = ()[0,1]; # @a has no elements
1046 @b = (@a)[0,1]; # @b has no elements
1047 @c = (sub{}->())[0,1]; # @c has no elements
1048 @d = ('a','b')[0,1]; # @d has two elements
1049 @e = (@d)[0,1,8,9]; # @e has four elements
1050 @f = (@d)[8,9]; # @f has two elements
1052 This makes it easy to write loops that terminate when a null list
1055 while ( ($home, $user) = (getpwent)[7,0] ) {
1056 printf "%-8s %s\n", $user, $home;
1059 As noted earlier in this document, the scalar sense of list assignment
1060 is the number of elements on the right-hand side of the assignment.
1061 The null list contains no elements, so when the password file is
1062 exhausted, the result is 0, not 2.
1064 Slices in scalar context return the last item of the slice.
1066 @a = qw/first second third/;
1067 %h = (first => 'A', second => 'B');
1068 $t = @a[0, 1]; # $t is now 'second'
1069 $u = @h{'first', 'second'}; # $u is now 'B'
1071 If you're confused about why you use an '@' there on a hash slice
1072 instead of a '%', think of it like this. The type of bracket (square
1073 or curly) governs whether it's an array or a hash being looked at.
1074 On the other hand, the leading symbol ('$' or '@') on the array or
1075 hash indicates whether you are getting back a singular value (a
1076 scalar) or a plural one (a list).
1078 =head3 Key/Value Hash Slices
1080 Starting in Perl 5.20, a hash slice operation
1081 with the % symbol is a variant of slice operation
1082 returning a list of key/value pairs rather than just values:
1084 %h = (blonk => 2, foo => 3, squink => 5, bar => 8);
1085 %subset = %h{'foo', 'bar'}; # key/value hash slice
1086 # %subset is now (foo => 3, bar => 8)
1087 %removed = delete %h{'foo', 'bar'};
1088 # %removed is now (foo => 3, bar => 8)
1089 # %h is now (blonk => 2, squink => 5)
1091 However, the result of such a slice cannot be localized or assigned to.
1092 These are otherwise very much consistent with hash slices
1095 =head3 Index/Value Array Slices
1097 Similar to key/value hash slices (and also introduced
1098 in Perl 5.20), the % array slice syntax returns a list
1099 of index/value pairs:
1103 # @list is now (3, "d", 4, "e", 6, "g")
1104 @removed = delete %a[3,4,6]
1105 # @removed is now (3, "d", 4, "e", 6, "g")
1106 # @list[3,4,6] are now undef
1108 Note that calling L<C<delete>|perlfunc/delete EXPR> on array values is
1109 strongly discouraged.
1111 =head2 Typeglobs and Filehandles
1112 X<typeglob> X<filehandle> X<*>
1114 Perl uses an internal type called a I<typeglob> to hold an entire
1115 symbol table entry. The type prefix of a typeglob is a C<*>, because
1116 it represents all types. This used to be the preferred way to
1117 pass arrays and hashes by reference into a function, but now that
1118 we have real references, this is seldom needed.
1120 The main use of typeglobs in modern Perl is create symbol table aliases.
1125 makes $this an alias for $that, @this an alias for @that, %this an alias
1126 for %that, &this an alias for &that, etc. Much safer is to use a reference.
1129 local *Here::blue = \$There::green;
1131 temporarily makes $Here::blue an alias for $There::green, but doesn't
1132 make @Here::blue an alias for @There::green, or %Here::blue an alias for
1133 %There::green, etc. See L<perlmod/"Symbol Tables"> for more examples
1134 of this. Strange though this may seem, this is the basis for the whole
1135 module import/export system.
1137 Another use for typeglobs is to pass filehandles into a function or
1138 to create new filehandles. If you need to use a typeglob to save away
1139 a filehandle, do it this way:
1143 or perhaps as a real reference, like this:
1147 See L<perlsub> for examples of using these as indirect filehandles
1150 Typeglobs are also a way to create a local filehandle using the local()
1151 operator. These last until their block is exited, but may be passed back.
1156 local *FH; # not my!
1157 open (FH, $path) or return undef;
1160 $fh = newopen('/etc/passwd');
1162 Now that we have the C<*foo{THING}> notation, typeglobs aren't used as much
1163 for filehandle manipulations, although they're still needed to pass brand
1164 new file and directory handles into or out of functions. That's because
1165 C<*HANDLE{IO}> only works if HANDLE has already been used as a handle.
1166 In other words, C<*FH> must be used to create new symbol table entries;
1167 C<*foo{THING}> cannot. When in doubt, use C<*FH>.
1169 All functions that are capable of creating filehandles (open(),
1170 opendir(), pipe(), socketpair(), sysopen(), socket(), and accept())
1171 automatically create an anonymous filehandle if the handle passed to
1172 them is an uninitialized scalar variable. This allows the constructs
1173 such as C<open(my $fh, ...)> and C<open(local $fh,...)> to be used to
1174 create filehandles that will conveniently be closed automatically when
1175 the scope ends, provided there are no other references to them. This
1176 largely eliminates the need for typeglobs when opening filehandles
1177 that must be passed around, as in the following example:
1181 or die "Can't open '@_': $!";
1186 my $f = myopen("</etc/motd");
1188 # $f implicitly closed here
1191 Note that if an initialized scalar variable is used instead the
1192 result is different: C<my $fh='zzz'; open($fh, ...)> is equivalent
1193 to C<open( *{'zzz'}, ...)>.
1194 C<use strict 'refs'> forbids such practice.
1196 Another way to create anonymous filehandles is with the Symbol
1197 module or with the IO::Handle module and its ilk. These modules
1198 have the advantage of not hiding different types of the same name
1199 during the local(). See the bottom of L<perlfunc/open> for an
1204 See L<perlvar> for a description of Perl's built-in variables and
1205 a discussion of legal variable names. See L<perlref>, L<perlsub>,
1206 and L<perlmod/"Symbol Tables"> for more discussion on typeglobs and
1207 the C<*foo{THING}> syntax.