pod/perluniintro.pod

   1 =head1 NAME
   2
   3 perluniintro - Perl Unicode introduction
   4
   5 =head1 DESCRIPTION
   6
   7 This document gives a general idea of Unicode and how to use Unicode
   8 in Perl.  See L</Further Resources> for references to more in-depth
   9 treatments of Unicode.
  10
  11 =head2 Unicode
  12
  13 Unicode is a character set standard which plans to codify all of the
  14 writing systems of the world, plus many other symbols.
  15
  16 Unicode and ISO/IEC 10646 are coordinated standards that unify
  17 almost all other modern character set standards,
  18 covering more than 80 writing systems and hundreds of languages,
  19 including all commercially-important modern languages.  All characters
  20 in the largest Chinese, Japanese, and Korean dictionaries are also
  21 encoded. The standards will eventually cover almost all characters in
  22 more than 250 writing systems and thousands of languages.
  23 Unicode 1.0 was released in October 1991, and 6.0 in October 2010.
  24
  25 A Unicode I<character> is an abstract entity.  It is not bound to any
  26 particular integer width, especially not to the C language C<char>.
  27 Unicode is language-neutral and display-neutral: it does not encode the
  28 language of the text, and it does not generally define fonts or other graphical
  29 layout details.  Unicode operates on characters and on text built from
  30 those characters.
  31
  32 Unicode defines characters like C<LATIN CAPITAL LETTER A> or C<GREEK
  33 SMALL LETTER ALPHA> and unique numbers for the characters, in this
  34 case 0x0041 and 0x03B1, respectively.  These unique numbers are called
  35 I<code points>.  A code point is essentially the position of the
  36 character within the set of all possible Unicode characters, and thus in
  37 Perl, the term I<ordinal> is often used interchangeably with it.
  38
  39 The Unicode standard prefers using hexadecimal notation for the code
  40 points.  If numbers like C<0x0041> are unfamiliar to you, take a peek
  41 at a later section, L</"Hexadecimal Notation">.  The Unicode standard
  42 uses the notation C<U+0041 LATIN CAPITAL LETTER A>, to give the
  43 hexadecimal code point and the normative name of the character.
  44
  45 Unicode also defines various I<properties> for the characters, like
  46 "uppercase" or "lowercase", "decimal digit", or "punctuation";
  47 these properties are independent of the names of the characters.
  48 Furthermore, various operations on the characters like uppercasing,
  49 lowercasing, and collating (sorting) are defined.
  50
  51 A Unicode I<logical> "character" can actually consist of more than one internal
  52 I<actual> "character" or code point.  For Western languages, this is adequately
  53 modelled by a I<base character> (like C<LATIN CAPITAL LETTER A>) followed
  54 by one or more I<modifiers> (like C<COMBINING ACUTE ACCENT>).  This sequence of
  55 base character and modifiers is called a I<combining character
  56 sequence>.  Some non-western languages require more complicated
  57 models, so Unicode created the I<grapheme cluster> concept, which was
  58 later further refined into the I<extended grapheme cluster>.  For
  59 example, a Korean Hangul syllable is considered a single logical
  60 character, but most often consists of three actual
  61 Unicode characters: a leading consonant followed by an interior vowel followed
  62 by a trailing consonant.
  63
  64 Whether to call these extended grapheme clusters "characters" depends on your
  65 point of view. If you are a programmer, you probably would tend towards seeing
  66 each element in the sequences as one unit, or "character".  However from
  67 the user's point of view, the whole sequence could be seen as one
  68 "character" since that's probably what it looks like in the context of the
  69 user's language.  In this document, we take the programmer's point of
  70 view: one "character" is one Unicode code point.
  71
  72 For some combinations of base character and modifiers, there are
  73 I<precomposed> characters.  There is a single character equivalent, for
  74 example, for the sequence C<LATIN CAPITAL LETTER A> followed by
  75 C<COMBINING ACUTE ACCENT>.  It is called  C<LATIN CAPITAL LETTER A WITH
  76 ACUTE>.  These precomposed characters are, however, only available for
  77 some combinations, and are mainly meant to support round-trip
  78 conversions between Unicode and legacy standards (like ISO 8859).  Using
  79 sequences, as Unicode does, allows for needing fewer basic building blocks
  80 (code points) to express many more potential grapheme clusters.  To
  81 support conversion between equivalent forms, various I<normalization
  82 forms> are also defined.  Thus, C<LATIN CAPITAL LETTER A WITH ACUTE> is
  83 in I<Normalization Form Composed>, (abbreviated NFC), and the sequence
  84 C<LATIN CAPITAL LETTER A> followed by C<COMBINING ACUTE ACCENT>
  85 represents the same character in I<Normalization Form Decomposed> (NFD).
  86
  87 Because of backward compatibility with legacy encodings, the "a unique
  88 number for every character" idea breaks down a bit: instead, there is
  89 "at least one number for every character".  The same character could
  90 be represented differently in several legacy encodings.  The
  91 converse is not true: some code points do not have an assigned
  92 character.  Firstly, there are unallocated code points within
  93 otherwise used blocks.  Secondly, there are special Unicode control
  94 characters that do not represent true characters.
  95
  96 When Unicode was first conceived, it was thought that all the world's
  97 characters could be represented using a 16-bit word; that is a maximum of
  98 C<0x10000> (or 65,536) characters would be needed, from C<0x0000> to
  99 C<0xFFFF>.  This soon proved to be wrong, and since Unicode 2.0 (July
 100 1996), Unicode has been defined all the way up to 21 bits (C<0x10FFFF>),
 101 and Unicode 3.1 (March 2001) defined the first characters above C<0xFFFF>.
 102 The first C<0x10000> characters are called the I<Plane 0>, or the
 103 I<Basic Multilingual Plane> (BMP).  With Unicode 3.1, 17 (yes,
 104 seventeen) planes in all were defined--but they are nowhere near full of
 105 defined characters, yet.
 106
 107 When a new language is being encoded, Unicode generally will choose a
 108 C<block> of consecutive unallocated code points for its characters.  So
 109 far, the number of code points in these blocks has always been evenly
 110 divisible by 16.  Extras in a block, not currently needed, are left
 111 unallocated, for future growth.  But there have been occasions when
 112 a later release needed more code points than the available extras, and a
 113 new block had to allocated somewhere else, not contiguous to the initial
 114 one, to handle the overflow.  Thus, it became apparent early on that
 115 "block" wasn't an adequate organizing principle, and so the C<Script>
 116 property was created.  (Later an improved script property was added as
 117 well, the C<Script_Extensions> property.)  Those code points that are in
 118 overflow blocks can still
 119 have the same script as the original ones.  The script concept fits more
 120 closely with natural language: there is C<Latin> script, C<Greek>
 121 script, and so on; and there are several artificial scripts, like
 122 C<Common> for characters that are used in multiple scripts, such as
 123 mathematical symbols.  Scripts usually span varied parts of several
 124 blocks.  For more information about scripts, see L<perlunicode/Scripts>.
 125 The division into blocks exists, but it is almost completely
 126 accidental--an artifact of how the characters have been and still are
 127 allocated.  (Note that this paragraph has oversimplified things for the
 128 sake of this being an introduction.  Unicode doesn't really encode
 129 languages, but the writing systems for them--their scripts; and one
 130 script can be used by many languages.  Unicode also encodes things that
 131 aren't really about languages, such as symbols like C<BAGGAGE CLAIM>.)
 132
 133 The Unicode code points are just abstract numbers.  To input and
 134 output these abstract numbers, the numbers must be I<encoded> or
 135 I<serialised> somehow.  Unicode defines several I<character encoding
 136 forms>, of which I<UTF-8> is the most popular.  UTF-8 is a
 137 variable length encoding that encodes Unicode characters as 1 to 4
 138 bytes.  Other encodings
 139 include UTF-16 and UTF-32 and their big- and little-endian variants
 140 (UTF-8 is byte-order independent).  The ISO/IEC 10646 defines the UCS-2
 141 and UCS-4 encoding forms.
 142
 143 For more information about encodings--for instance, to learn what
 144 I<surrogates> and I<byte order marks> (BOMs) are--see L<perlunicode>.
 145
 146 =head2 Perl's Unicode Support
 147
 148 Starting from Perl v5.6.0, Perl has had the capacity to handle Unicode
 149 natively.  Perl v5.8.0, however, is the first recommended release for
 150 serious Unicode work.  The maintenance release 5.6.1 fixed many of the
 151 problems of the initial Unicode implementation, but for example
 152 regular expressions still do not work with Unicode in 5.6.1.
 153 Perl v5.14.0 is the first release where Unicode support is
 154 (almost) seamlessly integrable without some gotchas (the exception being
 155 some differences in L<quotemeta|perlfunc/quotemeta>, and that is fixed
 156 starting in Perl 5.16.0).   To enable this
 157 seamless support, you should C<use feature 'unicode_strings'> (which is
 158 automatically selected if you C<use 5.012> or higher).  See L<feature>.
 159 (5.14 also fixes a number of bugs and departures from the Unicode
 160 standard.)
 161
 162 Before Perl v5.8.0, the use of C<use utf8> was used to declare
 163 that operations in the current block or file would be Unicode-aware.
 164 This model was found to be wrong, or at least clumsy: the "Unicodeness"
 165 is now carried with the data, instead of being attached to the
 166 operations.
 167 Starting with Perl v5.8.0, only one case remains where an explicit C<use
 168 utf8> is needed: if your Perl script itself is encoded in UTF-8, you can
 169 use UTF-8 in your identifier names, and in string and regular expression
 170 literals, by saying C<use utf8>.  This is not the default because
 171 scripts with legacy 8-bit data in them would break.  See L<utf8>.
 172
 173 =head2 Perl's Unicode Model
 174
 175 Perl supports both pre-5.6 strings of eight-bit native bytes, and
 176 strings of Unicode characters.  The general principle is that Perl tries
 177 to keep its data as eight-bit bytes for as long as possible, but as soon
 178 as Unicodeness cannot be avoided, the data is transparently upgraded
 179 to Unicode.  Prior to Perl v5.14.0, the upgrade was not completely
 180 transparent (see L<perlunicode/The "Unicode Bug">), and for backwards
 181 compatibility, full transparency is not gained unless C<use feature
 182 'unicode_strings'> (see L<feature>) or C<use 5.012> (or higher) is
 183 selected.
 184
 185 Internally, Perl currently uses either whatever the native eight-bit
 186 character set of the platform (for example Latin-1) is, defaulting to
 187 UTF-8, to encode Unicode strings. Specifically, if all code points in
 188 the string are C<0xFF> or less, Perl uses the native eight-bit
 189 character set.  Otherwise, it uses UTF-8.
 190
 191 A user of Perl does not normally need to know nor care how Perl
 192 happens to encode its internal strings, but it becomes relevant when
 193 outputting Unicode strings to a stream without a PerlIO layer (one with
 194 the "default" encoding).  In such a case, the raw bytes used internally
 195 (the native character set or UTF-8, as appropriate for each string)
 196 will be used, and a "Wide character" warning will be issued if those
 197 strings contain a character beyond 0x00FF.
 198
 199 For example,
 200
 201       perl -e 'print "\x{DF}\n", "\x{0100}\x{DF}\n"'
 202
 203 produces a fairly useless mixture of native bytes and UTF-8, as well
 204 as a warning:
 205
 206      Wide character in print at ...
 207
 208 To output UTF-8, use the C<:encoding> or C<:utf8> output layer.  Prepending
 209
 210       binmode(STDOUT, ":utf8");
 211
 212 to this sample program ensures that the output is completely UTF-8,
 213 and removes the program's warning.
 214
 215 You can enable automatic UTF-8-ification of your standard file
 216 handles, default C<open()> layer, and C<@ARGV> by using either
 217 the C<-C> command line switch or the C<PERL_UNICODE> environment
 218 variable, see L<perlrun> for the documentation of the C<-C> switch.
 219
 220 Note that this means that Perl expects other software to work the same
 221 way:
 222 if Perl has been led to believe that STDIN should be UTF-8, but then
 223 STDIN coming in from another command is not UTF-8, Perl will likely
 224 complain about the malformed UTF-8.
 225
 226 All features that combine Unicode and I/O also require using the new
 227 PerlIO feature.  Almost all Perl 5.8 platforms do use PerlIO, though:
 228 you can see whether yours is by running "perl -V" and looking for
 229 C<useperlio=define>.
 230
 231 =head2 Unicode and EBCDIC
 232
 233 Perl 5.8.0 added support for Unicode on EBCDIC platforms.  This support
 234 was allowed to lapse in later releases, but was revived in 5.22.
 235 Unicode support is somewhat more complex to implement since additional
 236 conversions are needed.  See L<perlebcdic> for more information.
 237
 238 On EBCDIC platforms, the internal Unicode encoding form is UTF-EBCDIC
 239 instead of UTF-8.  The difference is that as UTF-8 is "ASCII-safe" in
 240 that ASCII characters encode to UTF-8 as-is, while UTF-EBCDIC is
 241 "EBCDIC-safe", in that all the basic characters (which includes all
 242 those that have ASCII equivalents (like C<"A">, C<"0">, C<"%">, I<etc.>)
 243 are the same in both EBCDIC and UTF-EBCDIC.  Often, documentation
 244 will use the term "UTF-8" to mean UTF-EBCDIC as well.  This is the case
 245 in this document.
 246
 247 =head2 Creating Unicode
 248
 249 This section applies fully to Perls starting with v5.22.  Various
 250 caveats for earlier releases are in the L</Earlier releases caveats>
 251 subsection below.
 252
 253 To create Unicode characters in literals,
 254 use the C<\N{...}> notation in double-quoted strings:
 255
 256  my $smiley_from_name = "\N{WHITE SMILING FACE}";
 257  my $smiley_from_code_point = "\N{U+263a}";
 258
 259 Similarly, they can be used in regular expression literals
 260
 261  $smiley =~ /\N{WHITE SMILING FACE}/;
 262  $smiley =~ /\N{U+263a}/;
 263
 264 At run-time you can use:
 265
 266  use charnames ();
 267  my $hebrew_alef_from_name
 268                       = charnames::string_vianame("HEBREW LETTER ALEF");
 269  my $hebrew_alef_from_code_point = charnames::string_vianame("U+05D0");
 270
 271 Naturally, C<ord()> will do the reverse: it turns a character into
 272 a code point.
 273
 274 There are other runtime options as well.  You can use C<pack()>:
 275
 276  my $hebrew_alef_from_code_point = pack("U", 0x05d0);
 277
 278 Or you can use C<chr()>, though it is less convenient in the general
 279 case:
 280
 281  $hebrew_alef_from_code_point = chr(utf8::unicode_to_native(0x05d0));
 282  utf8::upgrade($hebrew_alef_from_code_point);
 283
 284 The C<utf8::unicode_to_native()> and C<utf8::upgrade()> aren't needed if
 285 the argument is above 0xFF, so the above could have been written as
 286
 287  $hebrew_alef_from_code_point = chr(0x05d0);
 288
 289 since 0x5d0 is above 255.
 290
 291 C<\x{}> and C<\o{}> can also be used to specify code points at compile
 292 time in double-quotish strings, but, for backward compatibility with
 293 older Perls, the same rules apply as with C<chr()> for code points less
 294 than 256.
 295
 296 C<utf8::unicode_to_native()> is used so that the Perl code is portable
 297 to EBCDIC platforms.  You can omit it if you're I<really> sure no one
 298 will ever want to use your code on a non-ASCII platform.  Starting in
 299 Perl v5.22, calls to it on ASCII platforms are optimized out, so there's
 300 no performance penalty at all in adding it.  Or you can simply use the
 301 other constructs that don't require it.
 302
 303 See L</"Further Resources"> for how to find all these names and numeric
 304 codes.
 305
 306 =head3 Earlier releases caveats
 307
 308 On EBCDIC platforms, prior to v5.22, using C<\N{U+...}> doesn't work
 309 properly.
 310
 311 Prior to v5.16, using C<\N{...}> with a character name (as opposed to a
 312 C<U+...> code point) required a S<C<use charnames :full>>.
 313
 314 Prior to v5.14, there were some bugs in C<\N{...}> with a character name
 315 (as opposed to a C<U+...> code point).
 316
 317 C<charnames::string_vianame()> was introduced in v5.14.  Prior to that,
 318 C<charnames::vianame()> should work, but only if the argument is of the
 319 form C<"U+...">.  Your best bet there for runtime Unicode by character
 320 name is probably:
 321
 322  use charnames ();
 323  my $hebrew_alef_from_name
 324                   = pack("U", charnames::vianame("HEBREW LETTER ALEF"));
 325
 326 =head2 Handling Unicode
 327
 328 Handling Unicode is for the most part transparent: just use the
 329 strings as usual.  Functions like C<index()>, C<length()>, and
 330 C<substr()> will work on the Unicode characters; regular expressions
 331 will work on the Unicode characters (see L<perlunicode> and L<perlretut>).
 332
 333 Note that Perl considers grapheme clusters to be separate characters, so for
 334 example
 335
 336  print length("\N{LATIN CAPITAL LETTER A}\N{COMBINING ACUTE ACCENT}"),
 337        "\n";
 338
 339 will print 2, not 1.  The only exception is that regular expressions
 340 have C<\X> for matching an extended grapheme cluster.  (Thus C<\X> in a
 341 regular expression would match the entire sequence of both the example
 342 characters.)
 343
 344 Life is not quite so transparent, however, when working with legacy
 345 encodings, I/O, and certain special cases:
 346
 347 =head2 Legacy Encodings
 348
 349 When you combine legacy data and Unicode, the legacy data needs
 350 to be upgraded to Unicode.  Normally the legacy data is assumed to be
 351 ISO 8859-1 (or EBCDIC, if applicable).
 352
 353 The C<Encode> module knows about many encodings and has interfaces
 354 for doing conversions between those encodings:
 355
 356     use Encode 'decode';
 357     $data = decode("iso-8859-3", $data); # convert from legacy to utf-8
 358
 359 =head2 Unicode I/O
 360
 361 Normally, writing out Unicode data
 362
 363     print FH $some_string_with_unicode, "\n";
 364
 365 produces raw bytes that Perl happens to use to internally encode the
 366 Unicode string.  Perl's internal encoding depends on the system as
 367 well as what characters happen to be in the string at the time. If
 368 any of the characters are at code points C<0x100> or above, you will get
 369 a warning.  To ensure that the output is explicitly rendered in the
 370 encoding you desire--and to avoid the warning--open the stream with
 371 the desired encoding. Some examples:
 372
 373     open FH, ">:utf8", "file";
 374
 375     open FH, ">:encoding(ucs2)",      "file";
 376     open FH, ">:encoding(UTF-8)",     "file";
 377     open FH, ">:encoding(shift_jis)", "file";
 378
 379 and on already open streams, use C<binmode()>:
 380
 381     binmode(STDOUT, ":utf8");
 382
 383     binmode(STDOUT, ":encoding(ucs2)");
 384     binmode(STDOUT, ":encoding(UTF-8)");
 385     binmode(STDOUT, ":encoding(shift_jis)");
 386
 387 The matching of encoding names is loose: case does not matter, and
 388 many encodings have several aliases.  Note that the C<:utf8> layer
 389 must always be specified exactly like that; it is I<not> subject to
 390 the loose matching of encoding names. Also note that currently C<:utf8> is unsafe for
 391 input, because it accepts the data without validating that it is indeed valid
 392 UTF-8; you should instead use C<:encoding(utf-8)> (with or without a
 393 hyphen).
 394
 395 See L<PerlIO> for the C<:utf8> layer, L<PerlIO::encoding> and
 396 L<Encode::PerlIO> for the C<:encoding()> layer, and
 397 L<Encode::Supported> for many encodings supported by the C<Encode>
 398 module.
 399
 400 Reading in a file that you know happens to be encoded in one of the
 401 Unicode or legacy encodings does not magically turn the data into
 402 Unicode in Perl's eyes.  To do that, specify the appropriate
 403 layer when opening files
 404
 405     open(my $fh,'<:encoding(utf8)', 'anything');
 406     my $line_of_unicode = <$fh>;
 407
 408     open(my $fh,'<:encoding(Big5)', 'anything');
 409     my $line_of_unicode = <$fh>;
 410
 411 The I/O layers can also be specified more flexibly with
 412 the C<open> pragma.  See L<open>, or look at the following example.
 413
 414     use open ':encoding(utf8)'; # input/output default encoding will be
 415                                 # UTF-8
 416     open X, ">file";
 417     print X chr(0x100), "\n";
 418     close X;
 419     open Y, "<file";
 420     printf "%#x\n", ord(<Y>); # this should print 0x100
 421     close Y;
 422
 423 With the C<open> pragma you can use the C<:locale> layer
 424
 425     BEGIN { $ENV{LC_ALL} = $ENV{LANG} = 'ru_RU.KOI8-R' }
 426     # the :locale will probe the locale environment variables like
 427     # LC_ALL
 428     use open OUT => ':locale'; # russki parusski
 429     open(O, ">koi8");
 430     print O chr(0x430); # Unicode CYRILLIC SMALL LETTER A = KOI8-R 0xc1
 431     close O;
 432     open(I, "<koi8");
 433     printf "%#x\n", ord(<I>), "\n"; # this should print 0xc1
 434     close I;
 435
 436 These methods install a transparent filter on the I/O stream that
 437 converts data from the specified encoding when it is read in from the
 438 stream.  The result is always Unicode.
 439
 440 The L<open> pragma affects all the C<open()> calls after the pragma by
 441 setting default layers.  If you want to affect only certain
 442 streams, use explicit layers directly in the C<open()> call.
 443
 444 You can switch encodings on an already opened stream by using
 445 C<binmode()>; see L<perlfunc/binmode>.
 446
 447 The C<:locale> does not currently work with
 448 C<open()> and C<binmode()>, only with the C<open> pragma.  The
 449 C<:utf8> and C<:encoding(...)> methods do work with all of C<open()>,
 450 C<binmode()>, and the C<open> pragma.
 451
 452 Similarly, you may use these I/O layers on output streams to
 453 automatically convert Unicode to the specified encoding when it is
 454 written to the stream. For example, the following snippet copies the
 455 contents of the file "text.jis" (encoded as ISO-2022-JP, aka JIS) to
 456 the file "text.utf8", encoded as UTF-8:
 457
 458     open(my $nihongo, '<:encoding(iso-2022-jp)', 'text.jis');
 459     open(my $unicode, '>:utf8',                  'text.utf8');
 460     while (<$nihongo>) { print $unicode $_ }
 461
 462 The naming of encodings, both by the C<open()> and by the C<open>
 463 pragma allows for flexible names: C<koi8-r> and C<KOI8R> will both be
 464 understood.
 465
 466 Common encodings recognized by ISO, MIME, IANA, and various other
 467 standardisation organisations are recognised; for a more detailed
 468 list see L<Encode::Supported>.
 469
 470 C<read()> reads characters and returns the number of characters.
 471 C<seek()> and C<tell()> operate on byte counts, as do C<sysread()>
 472 and C<sysseek()>.
 473
 474 Notice that because of the default behaviour of not doing any
 475 conversion upon input if there is no default layer,
 476 it is easy to mistakenly write code that keeps on expanding a file
 477 by repeatedly encoding the data:
 478
 479     # BAD CODE WARNING
 480     open F, "file";
 481     local $/; ## read in the whole file of 8-bit characters
 482     $t = <F>;
 483     close F;
 484     open F, ">:encoding(utf8)", "file";
 485     print F $t; ## convert to UTF-8 on output
 486     close F;
 487
 488 If you run this code twice, the contents of the F<file> will be twice
 489 UTF-8 encoded.  A C<use open ':encoding(utf8)'> would have avoided the
 490 bug, or explicitly opening also the F<file> for input as UTF-8.
 491
 492 B<NOTE>: the C<:utf8> and C<:encoding> features work only if your
 493 Perl has been built with L<PerlIO>, which is the default
 494 on most systems.
 495
 496 =head2 Displaying Unicode As Text
 497
 498 Sometimes you might want to display Perl scalars containing Unicode as
 499 simple ASCII (or EBCDIC) text.  The following subroutine converts
 500 its argument so that Unicode characters with code points greater than
 501 255 are displayed as C<\x{...}>, control characters (like C<\n>) are
 502 displayed as C<\x..>, and the rest of the characters as themselves:
 503
 504  sub nice_string {
 505         join("",
 506         map { $_ > 255                    # if wide character...
 507               ? sprintf("\\x{%04X}", $_)  # \x{...}
 508               : chr($_) =~ /[[:cntrl:]]/  # else if control character...
 509                 ? sprintf("\\x%02X", $_)  # \x..
 510                 : quotemeta(chr($_))      # else quoted or as themselves
 511         } unpack("W*", $_[0]));           # unpack Unicode characters
 512    }
 513
 514 For example,
 515
 516    nice_string("foo\x{100}bar\n")
 517
 518 returns the string
 519
 520    'foo\x{0100}bar\x0A'
 521
 522 which is ready to be printed.
 523
 524 (C<\\x{}> is used here instead of C<\\N{}>, since it's most likely that
 525 you want to see what the native values are.)
 526
 527 =head2 Special Cases
 528
 529 =over 4
 530
 531 =item *
 532
 533 Bit Complement Operator ~ And vec()
 534
 535 The bit complement operator C<~> may produce surprising results if
 536 used on strings containing characters with ordinal values above
 537 255. In such a case, the results are consistent with the internal
 538 encoding of the characters, but not with much else. So don't do
 539 that. Similarly for C<vec()>: you will be operating on the
 540 internally-encoded bit patterns of the Unicode characters, not on
 541 the code point values, which is very probably not what you want.
 542
 543 =item *
 544
 545 Peeking At Perl's Internal Encoding
 546
 547 Normal users of Perl should never care how Perl encodes any particular
 548 Unicode string (because the normal ways to get at the contents of a
 549 string with Unicode--via input and output--should always be via
 550 explicitly-defined I/O layers). But if you must, there are two
 551 ways of looking behind the scenes.
 552
 553 One way of peeking inside the internal encoding of Unicode characters
 554 is to use C<unpack("C*", ...> to get the bytes of whatever the string
 555 encoding happens to be, or C<unpack("U0..", ...)> to get the bytes of the
 556 UTF-8 encoding:
 557
 558     # this prints  c4 80  for the UTF-8 bytes 0xc4 0x80
 559     print join(" ", unpack("U0(H2)*", pack("U", 0x100))), "\n";
 560
 561 Yet another way would be to use the Devel::Peek module:
 562
 563     perl -MDevel::Peek -e 'Dump(chr(0x100))'
 564
 565 That shows the C<UTF8> flag in FLAGS and both the UTF-8 bytes
 566 and Unicode characters in C<PV>.  See also later in this document
 567 the discussion about the C<utf8::is_utf8()> function.
 568
 569 =back
 570
 571 =head2 Advanced Topics
 572
 573 =over 4
 574
 575 =item *
 576
 577 String Equivalence
 578
 579 The question of string equivalence turns somewhat complicated
 580 in Unicode: what do you mean by "equal"?
 581
 582 (Is C<LATIN CAPITAL LETTER A WITH ACUTE> equal to
 583 C<LATIN CAPITAL LETTER A>?)
 584
 585 The short answer is that by default Perl compares equivalence (C<eq>,
 586 C<ne>) based only on code points of the characters.  In the above
 587 case, the answer is no (because 0x00C1 != 0x0041).  But sometimes, any
 588 CAPITAL LETTER A's should be considered equal, or even A's of any case.
 589
 590 The long answer is that you need to consider character normalization
 591 and casing issues: see L<Unicode::Normalize>, Unicode Technical Report #15,
 592 L<Unicode Normalization Forms|http://www.unicode.org/unicode/reports/tr15> and
 593 sections on case mapping in the L<Unicode Standard|http://www.unicode.org>.
 594
 595 As of Perl 5.8.0, the "Full" case-folding of I<Case
 596 Mappings/SpecialCasing> is implemented, but bugs remain in C<qr//i> with them,
 597 mostly fixed by 5.14, and essentially entirely by 5.18.
 598
 599 =item *
 600
 601 String Collation
 602
 603 People like to see their strings nicely sorted--or as Unicode
 604 parlance goes, collated.  But again, what do you mean by collate?
 605
 606 (Does C<LATIN CAPITAL LETTER A WITH ACUTE> come before or after
 607 C<LATIN CAPITAL LETTER A WITH GRAVE>?)
 608
 609 The short answer is that by default, Perl compares strings (C<lt>,
 610 C<le>, C<cmp>, C<ge>, C<gt>) based only on the code points of the
 611 characters.  In the above case, the answer is "after", since
 612 C<0x00C1> > C<0x00C0>.
 613
 614 The long answer is that "it depends", and a good answer cannot be
 615 given without knowing (at the very least) the language context.
 616 See L<Unicode::Collate>, and I<Unicode Collation Algorithm>
 617 L<http://www.unicode.org/unicode/reports/tr10/>
 618
 619 =back
 620
 621 =head2 Miscellaneous
 622
 623 =over 4
 624
 625 =item *
 626
 627 Character Ranges and Classes
 628
 629 Character ranges in regular expression bracketed character classes ( e.g.,
 630 C</[a-z]/>) and in the C<tr///> (also known as C<y///>) operator are not
 631 magically Unicode-aware.  What this means is that C<[A-Za-z]> will not
 632 magically start to mean "all alphabetic letters" (not that it does mean that
 633 even for 8-bit characters; for those, if you are using locales (L<perllocale>),
 634 use C</[[:alpha:]]/>; and if not, use the 8-bit-aware property C<\p{alpha}>).
 635
 636 All the properties that begin with C<\p> (and its inverse C<\P>) are actually
 637 character classes that are Unicode-aware.  There are dozens of them, see
 638 L<perluniprops>.
 639
 640 Starting in v5.22, you can use Unicode code points as the end points of
 641 regular expression pattern character ranges, and the range will include
 642 all Unicode code points that lie between those end points, inclusive.
 643
 644  qr/ [\N{U+03]-\N{U+20}] /x
 645
 646 includes the code points
 647 C<\N{U+03}>, C<\N{U+04}>, ..., C<\N{U+20}>.
 648
 649 (It is planned to extend this behavior to ranges in C<tr///> in Perl
 650 v5.24.)
 651
 652 =item *
 653
 654 String-To-Number Conversions
 655
 656 Unicode does define several other decimal--and numeric--characters
 657 besides the familiar 0 to 9, such as the Arabic and Indic digits.
 658 Perl does not support string-to-number conversion for digits other
 659 than ASCII C<0> to C<9> (and ASCII C<a> to C<f> for hexadecimal).
 660 To get safe conversions from any Unicode string, use
 661 L<Unicode::UCD/num()>.
 662
 663 =back
 664
 665 =head2 Questions With Answers
 666
 667 =over 4
 668
 669 =item *
 670
 671 Will My Old Scripts Break?
 672
 673 Very probably not.  Unless you are generating Unicode characters
 674 somehow, old behaviour should be preserved.  About the only behaviour
 675 that has changed and which could start generating Unicode is the old
 676 behaviour of C<chr()> where supplying an argument more than 255
 677 produced a character modulo 255.  C<chr(300)>, for example, was equal
 678 to C<chr(45)> or "-" (in ASCII), now it is LATIN CAPITAL LETTER I WITH
 679 BREVE.
 680
 681 =item *
 682
 683 How Do I Make My Scripts Work With Unicode?
 684
 685 Very little work should be needed since nothing changes until you
 686 generate Unicode data.  The most important thing is getting input as
 687 Unicode; for that, see the earlier I/O discussion.
 688 To get full seamless Unicode support, add
 689 C<use feature 'unicode_strings'> (or C<use 5.012> or higher) to your
 690 script.
 691
 692 =item *
 693
 694 How Do I Know Whether My String Is In Unicode?
 695
 696 You shouldn't have to care.  But you may if your Perl is before 5.14.0
 697 or you haven't specified C<use feature 'unicode_strings'> or C<use
 698 5.012> (or higher) because otherwise the rules for the code points
 699 in the range 128 to 255 are different depending on
 700 whether the string they are contained within is in Unicode or not.
 701 (See L<perlunicode/When Unicode Does Not Happen>.)
 702
 703 To determine if a string is in Unicode, use:
 704
 705     print utf8::is_utf8($string) ? 1 : 0, "\n";
 706
 707 But note that this doesn't mean that any of the characters in the
 708 string are necessary UTF-8 encoded, or that any of the characters have
 709 code points greater than 0xFF (255) or even 0x80 (128), or that the
 710 string has any characters at all.  All the C<is_utf8()> does is to
 711 return the value of the internal "utf8ness" flag attached to the
 712 C<$string>.  If the flag is off, the bytes in the scalar are interpreted
 713 as a single byte encoding.  If the flag is on, the bytes in the scalar
 714 are interpreted as the (variable-length, potentially multi-byte) UTF-8 encoded
 715 code points of the characters.  Bytes added to a UTF-8 encoded string are
 716 automatically upgraded to UTF-8.  If mixed non-UTF-8 and UTF-8 scalars
 717 are merged (double-quoted interpolation, explicit concatenation, or
 718 printf/sprintf parameter substitution), the result will be UTF-8 encoded
 719 as if copies of the byte strings were upgraded to UTF-8: for example,
 720
 721     $a = "ab\x80c";
 722     $b = "\x{100}";
 723     print "$a = $b\n";
 724
 725 the output string will be UTF-8-encoded C<ab\x80c = \x{100}\n>, but
 726 C<$a> will stay byte-encoded.
 727
 728 Sometimes you might really need to know the byte length of a string
 729 instead of the character length. For that use either the
 730 C<Encode::encode_utf8()> function or the C<bytes> pragma
 731 and the C<length()> function:
 732
 733     my $unicode = chr(0x100);
 734     print length($unicode), "\n"; # will print 1
 735     require Encode;
 736     print length(Encode::encode_utf8($unicode)),"\n"; # will print 2
 737     use bytes;
 738     print length($unicode), "\n"; # will also print 2
 739                                   # (the 0xC4 0x80 of the UTF-8)
 740     no bytes;
 741
 742 =item *
 743
 744 How Do I Find Out What Encoding a File Has?
 745
 746 You might try L<Encode::Guess>, but it has a number of limitations.
 747
 748 =item *
 749
 750 How Do I Detect Data That's Not Valid In a Particular Encoding?
 751
 752 Use the C<Encode> package to try converting it.
 753 For example,
 754
 755     use Encode 'decode_utf8';
 756
 757     if (eval { decode_utf8($string, Encode::FB_CROAK); 1 }) {
 758         # $string is valid utf8
 759     } else {
 760         # $string is not valid utf8
 761     }
 762
 763 Or use C<unpack> to try decoding it:
 764
 765     use warnings;
 766     @chars = unpack("C0U*", $string_of_bytes_that_I_think_is_utf8);
 767
 768 If invalid, a C<Malformed UTF-8 character> warning is produced. The "C0" means
 769 "process the string character per character".  Without that, the
 770 C<unpack("U*", ...)> would work in C<U0> mode (the default if the format
 771 string starts with C<U>) and it would return the bytes making up the UTF-8
 772 encoding of the target string, something that will always work.
 773
 774 =item *
 775
 776 How Do I Convert Binary Data Into a Particular Encoding, Or Vice Versa?
 777
 778 This probably isn't as useful as you might think.
 779 Normally, you shouldn't need to.
 780
 781 In one sense, what you are asking doesn't make much sense: encodings
 782 are for characters, and binary data are not "characters", so converting
 783 "data" into some encoding isn't meaningful unless you know in what
 784 character set and encoding the binary data is in, in which case it's
 785 not just binary data, now is it?
 786
 787 If you have a raw sequence of bytes that you know should be
 788 interpreted via a particular encoding, you can use C<Encode>:
 789
 790     use Encode 'from_to';
 791     from_to($data, "iso-8859-1", "utf-8"); # from latin-1 to utf-8
 792
 793 The call to C<from_to()> changes the bytes in C<$data>, but nothing
 794 material about the nature of the string has changed as far as Perl is
 795 concerned.  Both before and after the call, the string C<$data>
 796 contains just a bunch of 8-bit bytes. As far as Perl is concerned,
 797 the encoding of the string remains as "system-native 8-bit bytes".
 798
 799 You might relate this to a fictional 'Translate' module:
 800
 801    use Translate;
 802    my $phrase = "Yes";
 803    Translate::from_to($phrase, 'english', 'deutsch');
 804    ## phrase now contains "Ja"
 805
 806 The contents of the string changes, but not the nature of the string.
 807 Perl doesn't know any more after the call than before that the
 808 contents of the string indicates the affirmative.
 809
 810 Back to converting data.  If you have (or want) data in your system's
 811 native 8-bit encoding (e.g. Latin-1, EBCDIC, etc.), you can use
 812 pack/unpack to convert to/from Unicode.
 813
 814     $native_string  = pack("W*", unpack("U*", $Unicode_string));
 815     $Unicode_string = pack("U*", unpack("W*", $native_string));
 816
 817 If you have a sequence of bytes you B<know> is valid UTF-8,
 818 but Perl doesn't know it yet, you can make Perl a believer, too:
 819
 820     use Encode 'decode_utf8';
 821     $Unicode = decode_utf8($bytes);
 822
 823 or:
 824
 825     $Unicode = pack("U0a*", $bytes);
 826
 827 You can find the bytes that make up a UTF-8 sequence with
 828
 829     @bytes = unpack("C*", $Unicode_string)
 830
 831 and you can create well-formed Unicode with
 832
 833     $Unicode_string = pack("U*", 0xff, ...)
 834
 835 =item *
 836
 837 How Do I Display Unicode?  How Do I Input Unicode?
 838
 839 See L<http://www.alanwood.net/unicode/> and
 840 L<http://www.cl.cam.ac.uk/~mgk25/unicode.html>
 841
 842 =item *
 843
 844 How Does Unicode Work With Traditional Locales?
 845
 846 If your locale is a UTF-8 locale, starting in Perl v5.20, Perl works
 847 well for all categories except C<LC_COLLATE> dealing with sorting and
 848 the C<cmp> operator.
 849
 850 For other locales, starting in Perl 5.16, you can specify
 851
 852     use locale ':not_characters';
 853
 854 to get Perl to work well with them.  The catch is that you
 855 have to translate from the locale character set to/from Unicode
 856 yourself.  See L</Unicode IE<sol>O> above for how to
 857
 858     use open ':locale';
 859
 860 to accomplish this, but full details are in L<perllocale/Unicode and
 861 UTF-8>, including gotchas that happen if you don't specify
 862 C<:not_characters>.
 863
 864 =back
 865
 866 =head2 Hexadecimal Notation
 867
 868 The Unicode standard prefers using hexadecimal notation because
 869 that more clearly shows the division of Unicode into blocks of 256 characters.
 870 Hexadecimal is also simply shorter than decimal.  You can use decimal
 871 notation, too, but learning to use hexadecimal just makes life easier
 872 with the Unicode standard.  The C<U+HHHH> notation uses hexadecimal,
 873 for example.
 874
 875 The C<0x> prefix means a hexadecimal number, the digits are 0-9 I<and>
 876 a-f (or A-F, case doesn't matter).  Each hexadecimal digit represents
 877 four bits, or half a byte.  C<print 0x..., "\n"> will show a
 878 hexadecimal number in decimal, and C<printf "%x\n", $decimal> will
 879 show a decimal number in hexadecimal.  If you have just the
 880 "hex digits" of a hexadecimal number, you can use the C<hex()> function.
 881
 882     print 0x0009, "\n";    # 9
 883     print 0x000a, "\n";    # 10
 884     print 0x000f, "\n";    # 15
 885     print 0x0010, "\n";    # 16
 886     print 0x0011, "\n";    # 17
 887     print 0x0100, "\n";    # 256
 888
 889     print 0x0041, "\n";    # 65
 890
 891     printf "%x\n",  65;    # 41
 892     printf "%#x\n", 65;    # 0x41
 893
 894     print hex("41"), "\n"; # 65
 895
 896 =head2 Further Resources
 897
 898 =over 4
 899
 900 =item *
 901
 902 Unicode Consortium
 903
 904 L<http://www.unicode.org/>
 905
 906 =item *
 907
 908 Unicode FAQ
 909
 910 L<http://www.unicode.org/unicode/faq/>
 911
 912 =item *
 913
 914 Unicode Glossary
 915
 916 L<http://www.unicode.org/glossary/>
 917
 918 =item *
 919
 920 Unicode Recommended Reading List
 921
 922 The Unicode Consortium has a list of articles and books, some of which
 923 give a much more in depth treatment of Unicode:
 924 L<http://unicode.org/resources/readinglist.html>
 925
 926 =item *
 927
 928 Unicode Useful Resources
 929
 930 L<http://www.unicode.org/unicode/onlinedat/resources.html>
 931
 932 =item *
 933
 934 Unicode and Multilingual Support in HTML, Fonts, Web Browsers and Other Applications
 935
 936 L<http://www.alanwood.net/unicode/>
 937
 938 =item *
 939
 940 UTF-8 and Unicode FAQ for Unix/Linux
 941
 942 L<http://www.cl.cam.ac.uk/~mgk25/unicode.html>
 943
 944 =item *
 945
 946 Legacy Character Sets
 947
 948 L<http://www.czyborra.com/>
 949 L<http://www.eki.ee/letter/>
 950
 951 =item *
 952
 953 You can explore various information from the Unicode data files using
 954 the C<Unicode::UCD> module.
 955
 956 =back
 957
 958 =head1 UNICODE IN OLDER PERLS
 959
 960 If you cannot upgrade your Perl to 5.8.0 or later, you can still
 961 do some Unicode processing by using the modules C<Unicode::String>,
 962 C<Unicode::Map8>, and C<Unicode::Map>, available from CPAN.
 963 If you have the GNU recode installed, you can also use the
 964 Perl front-end C<Convert::Recode> for character conversions.
 965
 966 The following are fast conversions from ISO 8859-1 (Latin-1) bytes
 967 to UTF-8 bytes and back, the code works even with older Perl 5 versions.
 968
 969     # ISO 8859-1 to UTF-8
 970     s/([\x80-\xFF])/chr(0xC0|ord($1)>>6).chr(0x80|ord($1)&0x3F)/eg;
 971
 972     # UTF-8 to ISO 8859-1
 973     s/([\xC2\xC3])([\x80-\xBF])/chr(ord($1)<<6&0xC0|ord($2)&0x3F)/eg;
 974
 975 =head1 SEE ALSO
 976
 977 L<perlunitut>, L<perlunicode>, L<Encode>, L<open>, L<utf8>, L<bytes>,
 978 L<perlretut>, L<perlrun>, L<Unicode::Collate>, L<Unicode::Normalize>,
 979 L<Unicode::UCD>
 980
 981 =head1 ACKNOWLEDGMENTS
 982
 983 Thanks to the kind readers of the perl5-porters@perl.org,
 984 perl-unicode@perl.org, linux-utf8@nl.linux.org, and unicore@unicode.org
 985 mailing lists for their valuable feedback.
 986
 987 =head1 AUTHOR, COPYRIGHT, AND LICENSE
 988
 989 Copyright 2001-2011 Jarkko Hietaniemi E<lt>jhi@iki.fiE<gt>.
 990 Now maintained by Perl 5 Porters.
 991
 992 This document may be distributed under the same terms as Perl itself.