pod/perlrequick.pod

   1 =head1 NAME
   2
   3 perlrequick - Perl regular expressions quick start
   4
   5 =head1 DESCRIPTION
   6
   7 This page covers the very basics of understanding, creating and
   8 using regular expressions ('regexes') in Perl.
   9
  10
  11 =head1 The Guide
  12
  13 =head2 Simple word matching
  14
  15 The simplest regex is simply a word, or more generally, a string of
  16 characters.  A regex consisting of a word matches any string that
  17 contains that word:
  18
  19     "Hello World" =~ /World/;  # matches
  20
  21 In this statement, C<World> is a regex and the C<//> enclosing
  22 C</World/> tells Perl to search a string for a match.  The operator
  23 C<=~> associates the string with the regex match and produces a true
  24 value if the regex matched, or false if the regex did not match.  In
  25 our case, C<World> matches the second word in C<"Hello World">, so the
  26 expression is true.  This idea has several variations.
  27
  28 Expressions like this are useful in conditionals:
  29
  30     print "It matches\n" if "Hello World" =~ /World/;
  31
  32 The sense of the match can be reversed by using C<!~> operator:
  33
  34     print "It doesn't match\n" if "Hello World" !~ /World/;
  35
  36 The literal string in the regex can be replaced by a variable:
  37
  38     $greeting = "World";
  39     print "It matches\n" if "Hello World" =~ /$greeting/;
  40
  41 If you're matching against C<$_>, the C<$_ =~> part can be omitted:
  42
  43     $_ = "Hello World";
  44     print "It matches\n" if /World/;
  45
  46 Finally, the C<//> default delimiters for a match can be changed to
  47 arbitrary delimiters by putting an C<'m'> out front:
  48
  49     "Hello World" =~ m!World!;   # matches, delimited by '!'
  50     "Hello World" =~ m{World};   # matches, note the matching '{}'
  51     "/usr/bin/perl" =~ m"/perl"; # matches after '/usr/bin',
  52                                  # '/' becomes an ordinary char
  53
  54 Regexes must match a part of the string I<exactly> in order for the
  55 statement to be true:
  56
  57     "Hello World" =~ /world/;  # doesn't match, case sensitive
  58     "Hello World" =~ /o W/;    # matches, ' ' is an ordinary char
  59     "Hello World" =~ /World /; # doesn't match, no ' ' at end
  60
  61 Perl will always match at the earliest possible point in the string:
  62
  63     "Hello World" =~ /o/;       # matches 'o' in 'Hello'
  64     "That hat is red" =~ /hat/; # matches 'hat' in 'That'
  65
  66 Not all characters can be used 'as is' in a match.  Some characters,
  67 called B<metacharacters>, are reserved for use in regex notation.
  68 The metacharacters are
  69
  70     {}[]()^$.|*+?\
  71
  72 A metacharacter can be matched by putting a backslash before it:
  73
  74     "2+2=4" =~ /2+2/;    # doesn't match, + is a metacharacter
  75     "2+2=4" =~ /2\+2/;   # matches, \+ is treated like an ordinary +
  76     'C:\WIN32' =~ /C:\\WIN/;                       # matches
  77     "/usr/bin/perl" =~ /\/usr\/bin\/perl/;  # matches
  78
  79 In the last regex, the forward slash C<'/'> is also backslashed,
  80 because it is used to delimit the regex.
  81
  82 Non-printable ASCII characters are represented by B<escape sequences>.
  83 Common examples are C<\t> for a tab, C<\n> for a newline, and C<\r>
  84 for a carriage return.  Arbitrary bytes are represented by octal
  85 escape sequences, e.g., C<\033>, or hexadecimal escape sequences,
  86 e.g., C<\x1B>:
  87
  88     "1000\t2000" =~ m(0\t2)  # matches
  89     "cat" =~ /\143\x61\x74/  # matches in ASCII, but
  90                              # a weird way to spell cat
  91
  92 Regexes are treated mostly as double-quoted strings, so variable
  93 substitution works:
  94
  95     $foo = 'house';
  96     'cathouse' =~ /cat$foo/;   # matches
  97     'housecat' =~ /${foo}cat/; # matches
  98
  99 With all of the regexes above, if the regex matched anywhere in the
 100 string, it was considered a match.  To specify I<where> it should
 101 match, we would use the B<anchor> metacharacters C<^> and C<$>.  The
 102 anchor C<^> means match at the beginning of the string and the anchor
 103 C<$> means match at the end of the string, or before a newline at the
 104 end of the string.  Some examples:
 105
 106     "housekeeper" =~ /keeper/;         # matches
 107     "housekeeper" =~ /^keeper/;        # doesn't match
 108     "housekeeper" =~ /keeper$/;        # matches
 109     "housekeeper\n" =~ /keeper$/;      # matches
 110     "housekeeper" =~ /^housekeeper$/;  # matches
 111
 112 =head2 Using character classes
 113
 114 A B<character class> allows a set of possible characters, rather than
 115 just a single character, to match at a particular point in a regex.
 116 Character classes are denoted by brackets C<[...]>, with the set of
 117 characters to be possibly matched inside.  Here are some examples:
 118
 119     /cat/;            # matches 'cat'
 120     /[bcr]at/;        # matches 'bat', 'cat', or 'rat'
 121     "abc" =~ /[cab]/; # matches 'a'
 122
 123 In the last statement, even though C<'c'> is the first character in
 124 the class, the earliest point at which the regex can match is C<'a'>.
 125
 126     /[yY][eE][sS]/; # match 'yes' in a case-insensitive way
 127                     # 'yes', 'Yes', 'YES', etc.
 128     /yes/i;         # also match 'yes' in a case-insensitive way
 129
 130 The last example shows a match with an C<'i'> B<modifier>, which makes
 131 the match case-insensitive.
 132
 133 Character classes also have ordinary and special characters, but the
 134 sets of ordinary and special characters inside a character class are
 135 different than those outside a character class.  The special
 136 characters for a character class are C<-]\^$> and are matched using an
 137 escape:
 138
 139    /[\]c]def/; # matches ']def' or 'cdef'
 140    $x = 'bcr';
 141    /[$x]at/;   # matches 'bat, 'cat', or 'rat'
 142    /[\$x]at/;  # matches '$at' or 'xat'
 143    /[\\$x]at/; # matches '\at', 'bat, 'cat', or 'rat'
 144
 145 The special character C<'-'> acts as a range operator within character
 146 classes, so that the unwieldy C<[0123456789]> and C<[abc...xyz]>
 147 become the svelte C<[0-9]> and C<[a-z]>:
 148
 149     /item[0-9]/;  # matches 'item0' or ... or 'item9'
 150     /[0-9a-fA-F]/;  # matches a hexadecimal digit
 151
 152 If C<'-'> is the first or last character in a character class, it is
 153 treated as an ordinary character.
 154
 155 The special character C<^> in the first position of a character class
 156 denotes a B<negated character class>, which matches any character but
 157 those in the brackets.  Both C<[...]> and C<[^...]> must match a
 158 character, or the match fails.  Then
 159
 160     /[^a]at/;  # doesn't match 'aat' or 'at', but matches
 161                # all other 'bat', 'cat, '0at', '%at', etc.
 162     /[^0-9]/;  # matches a non-numeric character
 163     /[a^]at/;  # matches 'aat' or '^at'; here '^' is ordinary
 164
 165 Perl has several abbreviations for common character classes. (These
 166 definitions are those that Perl uses in ASCII-safe mode with the C</a> modifier.
 167 Otherwise they could match many more non-ASCII Unicode characters as
 168 well.  See L<perlrecharclass/Backslash sequences> for details.)
 169
 170 =over 4
 171
 172 =item *
 173
 174 \d is a digit and represents
 175
 176     [0-9]
 177
 178 =item *
 179
 180 \s is a whitespace character and represents
 181
 182     [\ \t\r\n\f]
 183
 184 =item *
 185
 186 \w is a word character (alphanumeric or _) and represents
 187
 188     [0-9a-zA-Z_]
 189
 190 =item *
 191
 192 \D is a negated \d; it represents any character but a digit
 193
 194     [^0-9]
 195
 196 =item *
 197
 198 \S is a negated \s; it represents any non-whitespace character
 199
 200     [^\s]
 201
 202 =item *
 203
 204 \W is a negated \w; it represents any non-word character
 205
 206     [^\w]
 207
 208 =item *
 209
 210 The period '.' matches any character but "\n"
 211
 212 =back
 213
 214 The C<\d\s\w\D\S\W> abbreviations can be used both inside and outside
 215 of character classes.  Here are some in use:
 216
 217     /\d\d:\d\d:\d\d/; # matches a hh:mm:ss time format
 218     /[\d\s]/;         # matches any digit or whitespace character
 219     /\w\W\w/;         # matches a word char, followed by a
 220                       # non-word char, followed by a word char
 221     /..rt/;           # matches any two chars, followed by 'rt'
 222     /end\./;          # matches 'end.'
 223     /end[.]/;         # same thing, matches 'end.'
 224
 225 The S<B<word anchor> > C<\b> matches a boundary between a word
 226 character and a non-word character C<\w\W> or C<\W\w>:
 227
 228     $x = "Housecat catenates house and cat";
 229     $x =~ /\bcat/;  # matches cat in 'catenates'
 230     $x =~ /cat\b/;  # matches cat in 'housecat'
 231     $x =~ /\bcat\b/;  # matches 'cat' at end of string
 232
 233 In the last example, the end of the string is considered a word
 234 boundary.
 235
 236 For natural language processing (so that, for example, apostrophes are
 237 included in words), use instead C<\b{wb}>
 238
 239     "don't" =~ / .+? \b{wb} /x;  # matches the whole string
 240
 241 =head2 Matching this or that
 242
 243 We can match different character strings with the B<alternation>
 244 metacharacter C<'|'>.  To match C<dog> or C<cat>, we form the regex
 245 C<dog|cat>.  As before, Perl will try to match the regex at the
 246 earliest possible point in the string.  At each character position,
 247 Perl will first try to match the first alternative, C<dog>.  If
 248 C<dog> doesn't match, Perl will then try the next alternative, C<cat>.
 249 If C<cat> doesn't match either, then the match fails and Perl moves to
 250 the next position in the string.  Some examples:
 251
 252     "cats and dogs" =~ /cat|dog|bird/;  # matches "cat"
 253     "cats and dogs" =~ /dog|cat|bird/;  # matches "cat"
 254
 255 Even though C<dog> is the first alternative in the second regex,
 256 C<cat> is able to match earlier in the string.
 257
 258     "cats"          =~ /c|ca|cat|cats/; # matches "c"
 259     "cats"          =~ /cats|cat|ca|c/; # matches "cats"
 260
 261 At a given character position, the first alternative that allows the
 262 regex match to succeed will be the one that matches. Here, all the
 263 alternatives match at the first string position, so the first matches.
 264
 265 =head2 Grouping things and hierarchical matching
 266
 267 The B<grouping> metacharacters C<()> allow a part of a regex to be
 268 treated as a single unit.  Parts of a regex are grouped by enclosing
 269 them in parentheses.  The regex C<house(cat|keeper)> means match
 270 C<house> followed by either C<cat> or C<keeper>.  Some more examples
 271 are
 272
 273     /(a|b)b/;    # matches 'ab' or 'bb'
 274     /(^a|b)c/;   # matches 'ac' at start of string or 'bc' anywhere
 275
 276     /house(cat|)/;  # matches either 'housecat' or 'house'
 277     /house(cat(s|)|)/;  # matches either 'housecats' or 'housecat' or
 278                         # 'house'.  Note groups can be nested.
 279
 280     "20" =~ /(19|20|)\d\d/;  # matches the null alternative '()\d\d',
 281                              # because '20\d\d' can't match
 282
 283 =head2 Extracting matches
 284
 285 The grouping metacharacters C<()> also allow the extraction of the
 286 parts of a string that matched.  For each grouping, the part that
 287 matched inside goes into the special variables C<$1>, C<$2>, etc.
 288 They can be used just as ordinary variables:
 289
 290     # extract hours, minutes, seconds
 291     $time =~ /(\d\d):(\d\d):(\d\d)/;  # match hh:mm:ss format
 292     $hours = $1;
 293     $minutes = $2;
 294     $seconds = $3;
 295
 296 In list context, a match C</regex/> with groupings will return the
 297 list of matched values C<($1,$2,...)>.  So we could rewrite it as
 298
 299     ($hours, $minutes, $second) = ($time =~ /(\d\d):(\d\d):(\d\d)/);
 300
 301 If the groupings in a regex are nested, C<$1> gets the group with the
 302 leftmost opening parenthesis, C<$2> the next opening parenthesis,
 303 etc.  For example, here is a complex regex and the matching variables
 304 indicated below it:
 305
 306     /(ab(cd|ef)((gi)|j))/;
 307      1  2      34
 308
 309 Associated with the matching variables C<$1>, C<$2>, ... are
 310 the B<backreferences> C<\g1>, C<\g2>, ...  Backreferences are
 311 matching variables that can be used I<inside> a regex:
 312
 313     /(\w\w\w)\s\g1/; # find sequences like 'the the' in string
 314
 315 C<$1>, C<$2>, ... should only be used outside of a regex, and C<\g1>,
 316 C<\g2>, ... only inside a regex.
 317
 318 =head2 Matching repetitions
 319
 320 The B<quantifier> metacharacters C<?>, C<*>, C<+>, and C<{}> allow us
 321 to determine the number of repeats of a portion of a regex we
 322 consider to be a match.  Quantifiers are put immediately after the
 323 character, character class, or grouping that we want to specify.  They
 324 have the following meanings:
 325
 326 =over 4
 327
 328 =item *
 329
 330 C<a?> = match 'a' 1 or 0 times
 331
 332 =item *
 333
 334 C<a*> = match 'a' 0 or more times, i.e., any number of times
 335
 336 =item *
 337
 338 C<a+> = match 'a' 1 or more times, i.e., at least once
 339
 340 =item *
 341
 342 C<a{n,m}> = match at least C<n> times, but not more than C<m>
 343 times.
 344
 345 =item *
 346
 347 C<a{n,}> = match at least C<n> or more times
 348
 349 =item *
 350
 351 C<a{n}> = match exactly C<n> times
 352
 353 =back
 354
 355 Here are some examples:
 356
 357     /[a-z]+\s+\d*/;  # match a lowercase word, at least some space, and
 358                      # any number of digits
 359     /(\w+)\s+\g1/;    # match doubled words of arbitrary length
 360     $year =~ /^\d{2,4}$/;  # make sure year is at least 2 but not more
 361                            # than 4 digits
 362     $year =~ /^\d{4}$|^\d{2}$/; # better match; throw out 3 digit dates
 363
 364 These quantifiers will try to match as much of the string as possible,
 365 while still allowing the regex to match.  So we have
 366
 367     $x = 'the cat in the hat';
 368     $x =~ /^(.*)(at)(.*)$/; # matches,
 369                             # $1 = 'the cat in the h'
 370                             # $2 = 'at'
 371                             # $3 = ''   (0 matches)
 372
 373 The first quantifier C<.*> grabs as much of the string as possible
 374 while still having the regex match. The second quantifier C<.*> has
 375 no string left to it, so it matches 0 times.
 376
 377 =head2 More matching
 378
 379 There are a few more things you might want to know about matching
 380 operators.
 381 The global modifier C<//g> allows the matching operator to match
 382 within a string as many times as possible.  In scalar context,
 383 successive matches against a string will have C<//g> jump from match
 384 to match, keeping track of position in the string as it goes along.
 385 You can get or set the position with the C<pos()> function.
 386 For example,
 387
 388     $x = "cat dog house"; # 3 words
 389     while ($x =~ /(\w+)/g) {
 390         print "Word is $1, ends at position ", pos $x, "\n";
 391     }
 392
 393 prints
 394
 395     Word is cat, ends at position 3
 396     Word is dog, ends at position 7
 397     Word is house, ends at position 13
 398
 399 A failed match or changing the target string resets the position.  If
 400 you don't want the position reset after failure to match, add the
 401 C<//c>, as in C</regex/gc>.
 402
 403 In list context, C<//g> returns a list of matched groupings, or if
 404 there are no groupings, a list of matches to the whole regex.  So
 405
 406     @words = ($x =~ /(\w+)/g);  # matches,
 407                                 # $word[0] = 'cat'
 408                                 # $word[1] = 'dog'
 409                                 # $word[2] = 'house'
 410
 411 =head2 Search and replace
 412
 413 Search and replace is performed using C<s/regex/replacement/modifiers>.
 414 The C<replacement> is a Perl double-quoted string that replaces in the
 415 string whatever is matched with the C<regex>.  The operator C<=~> is
 416 also used here to associate a string with C<s///>.  If matching
 417 against C<$_>, the S<C<$_ =~>> can be dropped.  If there is a match,
 418 C<s///> returns the number of substitutions made; otherwise it returns
 419 false.  Here are a few examples:
 420
 421     $x = "Time to feed the cat!";
 422     $x =~ s/cat/hacker/;   # $x contains "Time to feed the hacker!"
 423     $y = "'quoted words'";
 424     $y =~ s/^'(.*)'$/$1/;  # strip single quotes,
 425                            # $y contains "quoted words"
 426
 427 With the C<s///> operator, the matched variables C<$1>, C<$2>, etc.
 428 are immediately available for use in the replacement expression. With
 429 the global modifier, C<s///g> will search and replace all occurrences
 430 of the regex in the string:
 431
 432     $x = "I batted 4 for 4";
 433     $x =~ s/4/four/;   # $x contains "I batted four for 4"
 434     $x = "I batted 4 for 4";
 435     $x =~ s/4/four/g;  # $x contains "I batted four for four"
 436
 437 The non-destructive modifier C<s///r> causes the result of the substitution
 438 to be returned instead of modifying C<$_> (or whatever variable the
 439 substitute was bound to with C<=~>):
 440
 441     $x = "I like dogs.";
 442     $y = $x =~ s/dogs/cats/r;
 443     print "$x $y\n"; # prints "I like dogs. I like cats."
 444
 445     $x = "Cats are great.";
 446     print $x =~ s/Cats/Dogs/r =~ s/Dogs/Frogs/r =~
 447         s/Frogs/Hedgehogs/r, "\n";
 448     # prints "Hedgehogs are great."
 449
 450     @foo = map { s/[a-z]/X/r } qw(a b c 1 2 3);
 451     # @foo is now qw(X X X 1 2 3)
 452
 453 The evaluation modifier C<s///e> wraps an C<eval{...}> around the
 454 replacement string and the evaluated result is substituted for the
 455 matched substring.  Some examples:
 456
 457     # reverse all the words in a string
 458     $x = "the cat in the hat";
 459     $x =~ s/(\w+)/reverse $1/ge;   # $x contains "eht tac ni eht tah"
 460
 461     # convert percentage to decimal
 462     $x = "A 39% hit rate";
 463     $x =~ s!(\d+)%!$1/100!e;       # $x contains "A 0.39 hit rate"
 464
 465 The last example shows that C<s///> can use other delimiters, such as
 466 C<s!!!> and C<s{}{}>, and even C<s{}//>.  If single quotes are used
 467 C<s'''>, then the regex and replacement are treated as single-quoted
 468 strings.
 469
 470 =head2 The split operator
 471
 472 C<split /regex/, string> splits C<string> into a list of substrings
 473 and returns that list.  The regex determines the character sequence
 474 that C<string> is split with respect to.  For example, to split a
 475 string into words, use
 476
 477     $x = "Calvin and Hobbes";
 478     @word = split /\s+/, $x;  # $word[0] = 'Calvin'
 479                               # $word[1] = 'and'
 480                               # $word[2] = 'Hobbes'
 481
 482 To extract a comma-delimited list of numbers, use
 483
 484     $x = "1.618,2.718,   3.142";
 485     @const = split /,\s*/, $x;  # $const[0] = '1.618'
 486                                 # $const[1] = '2.718'
 487                                 # $const[2] = '3.142'
 488
 489 If the empty regex C<//> is used, the string is split into individual
 490 characters.  If the regex has groupings, then the list produced contains
 491 the matched substrings from the groupings as well:
 492
 493     $x = "/usr/bin";
 494     @parts = split m!(/)!, $x;  # $parts[0] = ''
 495                                 # $parts[1] = '/'
 496                                 # $parts[2] = 'usr'
 497                                 # $parts[3] = '/'
 498                                 # $parts[4] = 'bin'
 499
 500 Since the first character of $x matched the regex, C<split> prepended
 501 an empty initial element to the list.
 502
 503 =head2 C<use re 'strict'>
 504
 505 New in v5.22, this applies stricter rules than otherwise when compiling
 506 regular expression patterns.  It can find things that, while legal, may
 507 not be what you intended.
 508
 509 See L<'strict' in re|re/'strict' mode>.
 510
 511 =head1 BUGS
 512
 513 None.
 514
 515 =head1 SEE ALSO
 516
 517 This is just a quick start guide.  For a more in-depth tutorial on
 518 regexes, see L<perlretut> and for the reference page, see L<perlre>.
 519
 520 =head1 AUTHOR AND COPYRIGHT
 521
 522 Copyright (c) 2000 Mark Kvale
 523 All rights reserved.
 524
 525 This document may be distributed under the same terms as Perl itself.
 526
 527 =head2 Acknowledgments
 528
 529 The author would like to thank Mark-Jason Dominus, Tom Christiansen,
 530 Ilya Zakharevich, Brad Hughes, and Mike Giroux for all their helpful
 531 comments.
 532
 533 =cut
 534