pod/pod2man.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(&basename &dirname);
   5 use Cwd;
   6
   7 # List explicitly here the variables you want Configure to
   8 # generate.  Metaconfig only looks for shell variables, so you
   9 # have to mention them as if they were shell variables, not
  10 # %Config entries.  Thus you write
  11 #  $startperl
  12 # to ensure Configure will look for $Config{startperl}.
  13
  14 # This forces PL files to create target in same directory as PL file.
  15 # This is so that make depend always knows where to find PL derivatives.
  16 $origdir = cwd;
  17 chdir dirname($0);
  18 $file = basename($0, '.PL');
  19 $file .= '.com' if $^O eq 'VMS';
  20
  21 open OUT,">$file" or die "Can't create $file: $!";
  22
  23 print "Extracting $file (with variable substitutions)\n";
  24
  25 # In this section, perl variables will be expanded during extraction.
  26 # You can use $Config{...} to use Configure variables.
  27
  28 print OUT <<"!GROK!THIS!";
  29 $Config{startperl}
  30     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  31         if \$running_under_some_shell;
  32 !GROK!THIS!
  33
  34 # In the following, perl variables are not expanded during extraction.
  35
  36 print OUT <<'!NO!SUBS!';
  37
  38 # pod2man -- Convert POD data to formatted *roff input.
  39 # $Id: pod2man.PL,v 1.2 2000/03/16 21:08:23 eagle Exp $
  40 #
  41 # Copyright 1999, 2000 by Russ Allbery <rra@stanford.edu>
  42 #
  43 # This program is free software; you can redistribute it and/or modify it
  44 # under the same terms as Perl itself.
  45
  46 require 5.004;
  47
  48 use Getopt::Long qw(GetOptions);
  49 use Pod::Man ();
  50 use Pod::Usage qw(pod2usage);
  51
  52 use strict;
  53
  54 # Insert -- into @ARGV before any single dash argument to hide it from
  55 # Getopt::Long; we want to interpret it as meaning stdin (which Pod::Parser
  56 # does correctly).
  57 my $stdin;
  58 @ARGV = map { $_ eq '-' && !$stdin++ ? ('--', $_) : $_ } @ARGV;
  59
  60 # Parse our options, trying to retain backwards compatibility with pod2man
  61 # but allowing short forms as well.  --lax is currently ignored.
  62 my %options;
  63 Getopt::Long::config ('bundling_override');
  64 GetOptions (\%options, 'section|s=s', 'release|r=s', 'center|c=s',
  65             'date|d=s', 'fixed=s', 'fixedbold=s', 'fixeditalic=s',
  66             'fixedbolditalic=s', 'official|o', 'lax|l', 'help|h') or exit 1;
  67 pod2usage (0) if $options{help};
  68
  69 # Official sets --center, but don't override things explicitly set.
  70 if ($options{official} && !defined $options{center}) {
  71     $options{center} = 'Perl Programmers Reference Guide';
  72 }
  73
  74 # Initialize and run the formatter.
  75 my $parser = Pod::Man->new (%options);
  76 $parser->parse_from_file (@ARGV);
  77
  78 __END__
  79
  80 =head1 NAME
  81
  82 pod2man - Convert POD data to formatted *roff input
  83
  84 =head1 SYNOPSIS
  85
  86 pod2man [B<--section>=I<manext>] [B<--release>=I<version>]
  87 [B<--center>=I<string>] [B<--date>=I<string>] [B<--fixed>=I<font>]
  88 [B<--fixedbold>=I<font>] [B<--fixeditalic>=I<font>]
  89 [B<--fixedbolditalic>=I<font>] [B<--official>] [B<--lax>] [I<input>
  90 [I<output>]]
  91
  92 pod2man B<--help>
  93
  94 =head1 DESCRIPTION
  95
  96 B<pod2man> is a front-end for Pod::Man, using it to generate *roff input
  97 from POD source.  The resulting *roff code is suitable for display on a
  98 terminal using nroff(1), normally via man(1), or printing using troff(1).
  99
 100 I<input> is the file to read for POD source (the POD can be embedded in
 101 code).  If I<input> isn't given, it defaults to STDIN.  I<output>, if given,
 102 is the file to which to write the formatted output.  If I<output> isn't
 103 given, the formatted output is written to STDOUT.
 104
 105 B<--section>, B<--release>, B<--center>, B<--date>, and B<--official> can be
 106 used to set the headers and footers to use; if not given, Pod::Man will
 107 assume various defaults.  See below or L<Pod::Man> for details.
 108
 109 B<pod2man> assumes that your *roff formatters have a fixed-width font named
 110 CW.  If yours is called something else (like CR), use B<--fixed> to specify
 111 it.  This generally only matters for troff output for printing.  Similarly,
 112 you can set the fonts used for bold, italic, and bold italic fixed-width
 113 output.
 114
 115 Besides the obvious pod conversions, Pod::Man, and therefore pod2man also
 116 takes care of formatting func(), func(n), and simple variable references
 117 like $foo or @bar so you don't have to use code escapes for them; complex
 118 expressions like C<$fred{'stuff'}> will still need to be escaped, though.
 119 It also translates dashes that aren't used as hyphens into en dashes, makes
 120 long dashes--like this--into proper em dashes, fixes "paired quotes," and
 121 takes care of several other troff-specific tweaks.  See L<Pod::Man> for
 122 complete information.
 123
 124 =head1 OPTIONS
 125
 126 =over 4
 127
 128 =item B<-c> I<string>, B<--center>=I<string>
 129
 130 Sets the centered page header to I<string>.  The default is "User
 131 Contributed Perl Documentation", but also see B<--official> below.
 132
 133 =item B<-d> I<string>, B<--date>=I<string>
 134
 135 Set the left-hand footer string to this value.  By default, the modification
 136 date of the input file will be used, or the current date if input comes from
 137 STDIN.
 138
 139 =item B<--fixed>=I<font>
 140
 141 The fixed-width font to use for vertabim text and code.  Defaults to CW.
 142 Some systems may want CR instead.  Only matters for troff(1) output.
 143
 144 =item B<--fixedbold>=I<font>
 145
 146 Bold version of the fixed-width font.  Defaults to CB.  Only matters for
 147 troff(1) output.
 148
 149 =item B<--fixeditalic>=I<font>
 150
 151 Italic version of the fixed-width font (actually, something of a misnomer,
 152 since most fixed-width fonts only have an oblique version, not an italic
 153 version).  Defaults to CI.  Only matters for troff(1) output.
 154
 155 =item B<--fixedbolditalic>=I<font>
 156
 157 Bold italic (probably actually oblique) version of the fixed-width font.
 158 Pod::Man doesn't assume you have this, and defaults to CB.  Some systems
 159 (such as Solaris) have this font available as CX.  Only matters for troff(1)
 160 output.
 161
 162 =item B<-h>, B<--help>
 163
 164 Print out usage information.
 165
 166 =item B<-l>, B<--lax>
 167
 168 Don't complain when required sections are missing.  Not currently used, as
 169 POD checking functionality is not yet implemented in Pod::Man.
 170
 171 =item B<-o>, B<--official>
 172
 173 Set the default header to indicate that this page is part of the standard
 174 Perl release, if B<--center> is not also given.
 175
 176 =item B<-r>, B<--release>
 177
 178 Set the centered footer.  By default, this is the version of Perl you run
 179 B<pod2man> under.  Note that some system an macro sets assume that the
 180 centered footer will be a modification date and will prepend something like
 181 "Last modified: "; if this is the case, you may want to set B<--release> to
 182 the last modified date and B<--date> to the version number.
 183
 184 =item B<-s>, B<--section>
 185
 186 Set the section for the C<.TH> macro.  The standard section numbering
 187 convention is to use 1 for user commands, 2 for system calls, 3 for
 188 functions, 4 for devices, 5 for file formats, 6 for games, 7 for
 189 miscellaneous information, and 8 for administrator commands.  There is a lot
 190 of variation here, however; some systems (like Solaris) use 4 for file
 191 formats, 5 for miscellaneous information, and 7 for devices.  Still others
 192 use 1m instead of 8, or some mix of both.  About the only section numbers
 193 that are reliably consistent are 1, 2, and 3.
 194
 195 By default, section 1 will be used unless the file ends in .pm in which case
 196 section 3 will be selected.
 197
 198 =back
 199
 200 =head1 DIAGNOSTICS
 201
 202 If B<pod2man> fails with errors, see L<Pod::Man> and L<Pod::Parser> for
 203 information about what those errors might mean.
 204
 205 =head1 EXAMPLES
 206
 207     pod2man program > program.1
 208     pod2man SomeModule.pm /usr/perl/man/man3/SomeModule.3
 209     pod2man --section=7 note.pod > note.7
 210
 211 If you would like to print out a lot of man page continuously, you probably
 212 want to set the C and D registers to set contiguous page numbering and
 213 even/odd paging, at least on some versions of man(7).
 214
 215     troff -man -rC1 -rD1 perl.1 perldata.1 perlsyn.1 ...
 216
 217 To get index entries on stderr, turn on the F register, as in:
 218
 219     troff -man -rF1 perl.1
 220
 221 The indexing merely outputs messages via C<.tm> for each major page,
 222 section, subsection, item, and any C<XE<lt>E<gt>> directives.  See
 223 L<Pod::Man> for more details.
 224
 225 =head1 BUGS
 226
 227 Lots of this documentation is duplicated from L<Pod::Man>.
 228
 229 POD checking and the corresponding B<--lax> option don't work yet.
 230
 231 =head1 NOTES
 232
 233 For those not sure of the proper layout of a man page, here are some notes
 234 on writing a proper man page.
 235
 236 The name of the program being documented is conventionally written in bold
 237 (using BE<lt>E<gt>) wherever it occurs, as are all program options.
 238 Arguments should be written in italics (IE<lt>E<gt>).  Functions are
 239 traditionally written in italics; if you write a function as function(),
 240 Pod::Man will take care of this for you.  Literal code or commands should
 241 be in CE<lt>E<gt>.  References to other man pages should be in the form
 242 C<manpage(section)>, and Pod::Man will automatically format those
 243 appropriately.  As an exception, it's traditional not to use this form when
 244 referring to module documentation; use C<LE<lt>Module::NameE<gt>> instead.
 245
 246 References to other programs or functions are normally in the form of man
 247 page references so that cross-referencing tools can provide the user with
 248 links and the like.  It's possible to overdo this, though, so be careful not
 249 to clutter your documentation with too much markup.
 250
 251 The major headers should be set out using a C<=head1> directive, and are
 252 historically written in the rather startling ALL UPPER CASE format, although
 253 this is not mandatory.  Minor headers may be included using C<=head2>, and
 254 are typically in mixed case.
 255
 256 The standard sections of a manual page are:
 257
 258 =over 4
 259
 260 =item NAME
 261
 262 Mandatory section; should be a comma-separated list of programs or functions
 263 documented by this podpage, such as:
 264
 265     foo, bar - programs to do something
 266
 267 Manual page indexers are often extremely picky about the format of this
 268 section, so don't put anything in it except this line.  A single dash, and
 269 only a single dash, should separate the list of programs or functions from
 270 the description.  Functions should not be qualified with C<()> or the like.
 271 The description should ideally fit on a single line, even if a man program
 272 replaces the dash with a few tabs.
 273
 274 =item SYNOPSIS
 275
 276 A short usage summary for programs and functions.  This section is mandatory
 277 for section 3 pages.
 278
 279 =item DESCRIPTION
 280
 281 Extended description and discussion of the program or functions, or the body
 282 of the documentation for man pages that document something else.  If
 283 particularly long, it's a good idea to break this up into subsections
 284 C<=head2> directives like:
 285
 286     =head2 Normal Usage
 287
 288     =head2 Advanced Features
 289
 290     =head2 Writing Configuration Files
 291
 292 or whatever is appropriate for your documentation.
 293
 294 =item OPTIONS
 295
 296 Detailed description of each of the command-line options taken by the
 297 program.  This should be separate from the description for the use of things
 298 like L<Pod::Usage|Pod::Usage>.  This is normally presented as a list, with
 299 each option as a separate C<=item>.  The specific option string should be
 300 enclosed in BE<lt>E<gt>.  Any values that the option takes should be
 301 enclosed in IE<lt>E<gt>.  For example, the section for the option
 302 B<--section>=I<manext> would be introduced with:
 303
 304     =item B<--section>=I<manext>
 305
 306 Synonymous options (like both the short and long forms) are separated by a
 307 comma and a space on the same C<=item> line, or optionally listed as their
 308 own item with a reference to the canonical name.  For example, since
 309 B<--section> can also be written as B<-s>, the above would be:
 310
 311     =item B<-s> I<manext>, B<--section>=I<manext>
 312
 313 (Writing the short option first is arguably easier to read, since the long
 314 option is long enough to draw the eye to it anyway and the short option can
 315 otherwise get lost in visual noise.)
 316
 317 =item RETURN VALUE
 318
 319 What the program or function returns, if successful.  This section can be
 320 omitted for programs whose precise exit codes aren't important, provided
 321 they return 0 on success as is standard.  It should always be present for
 322 functions.
 323
 324 =item ERRORS
 325
 326 Exceptions, error return codes, exit statuses, and errno settings.
 327 Typically used for function documentation; program documentation uses
 328 DIAGNOSTICS instead.  The general rule of thumb is that errors printed to
 329 STDOUT or STDERR and intended for the end user are documented in DIAGNOSTICS
 330 while errors passed internal to the calling program and intended for other
 331 programmers are documented in ERRORS.  When documenting a function that sets
 332 errno, a full list of the possible errno values should be given here.
 333
 334 =item DIAGNOSTICS
 335
 336 All possible messages the program can print out--and what they mean.  You
 337 may wish to follow the same documentation style as the Perl documentation;
 338 see perldiag(1) for more details (and look at the POD source as well).
 339
 340 If applicable, please include details on what the user should do to correct
 341 the error; documenting an error as indicating "the input buffer is too
 342 small" without telling the user how to increase the size of the input buffer
 343 (or at least telling them that it isn't possible) aren't very useful.
 344
 345 =item EXAMPLES
 346
 347 Give some example uses of the program or function.  Don't skimp; users often
 348 find this the most useful part of the documentation.  The examples are
 349 generally given as verbatim paragraphs.
 350
 351 Don't just present an example without explaining what it does.  Adding a
 352 short paragraph saying what the example will do can increase the value of
 353 the example immensely.
 354
 355 =item ENVIRONMENT
 356
 357 Environment variables that the program cares about, normally presented as a
 358 list using C<=over>, C<=item>, and C<=back>.  For example:
 359
 360     =over 6
 361
 362     =item HOME
 363
 364     Used to determine the user's home directory.  F<.foorc> in this
 365     directory is read for configuration details, if it exists.
 366
 367     =back
 368
 369 Since environment variables are normally in all uppercase, no additional
 370 special formatting is generally needed; they're glaring enough as it is.
 371
 372 =item FILES
 373
 374 All files used by the program or function, normally presented as a list, and
 375 what it uses them for.  File names should be enclosed in FE<lt>E<gt>.  It's
 376 particularly important to document files that will be potentially modified.
 377
 378 =item CAVEATS
 379
 380 Things to take special care with, sometimes called WARNINGS.
 381
 382 =item BUGS
 383
 384 Things that are broken or just don't work quite right.
 385
 386 =item RESTRICTIONS
 387
 388 Bugs you don't plan to fix.  :-)
 389
 390 =item NOTES
 391
 392 Miscellaneous commentary.
 393
 394 =item SEE ALSO
 395
 396 Other man pages to check out, like man(1), man(7), makewhatis(8), or
 397 catman(8).  Normally a simple list of man pages separated by commas, or a
 398 paragraph giving the name of a reference work.  Man page references, if they
 399 use the standard C<name(section)> form, don't have to be enclosed in
 400 LE<lt>E<gt>, but other things in this section probably should be when
 401 appropriate.  You may need to use the C<LE<lt>...|...E<gt>> syntax to keep
 402 B<pod2man> and B<pod2text> from being too verbose; see perlpod(1).
 403
 404 If the package has a web site, include a URL here.
 405
 406 =item AUTHOR
 407
 408 Who wrote it (use AUTHORS for multiple people).  Including your current
 409 e-mail address (or some e-mail address to which bug reports should be sent)
 410 so that users have a way of contacting you is a good idea.  Remember that
 411 program documentation tends to roam the wild for far longer than you expect
 412 and pick an e-mail address that's likely to last if possible.
 413
 414 =item HISTORY
 415
 416 Programs derived from other sources sometimes have this, or you might keep a
 417 modification log here.
 418
 419 =back
 420
 421 In addition, some systems use CONFORMING TO to note conformance to relevant
 422 standards and MT-LEVEL to note safeness for use in threaded programs or
 423 signal handlers.  These headings are primarily useful when documenting parts
 424 of a C library.  Documentation of object-oriented libraries or modules may
 425 use CONSTRUCTORS and METHODS sections for detailed documentation of the
 426 parts of the library and save the DESCRIPTION section for an overview; other
 427 large modules may use FUNCTIONS for similar reasons.  Some people use
 428 OVERVIEW to summarize the description if it's quite long.  Sometimes there's
 429 an additional COPYRIGHT section at the bottom, for licensing terms.
 430 AVAILABILITY is sometimes added, giving the canonical download site for the
 431 software or a URL for updates.
 432
 433 Section ordering varies, although NAME should I<always> be the first section
 434 (you'll break some man page systems otherwise), and NAME, SYNOPSIS,
 435 DESCRIPTION, and OPTIONS generally always occur first and in that order if
 436 present.  In general, SEE ALSO, AUTHOR, and similar material should be left
 437 for last.  Some systems also move WARNINGS and NOTES to last.  The order
 438 given above should be reasonable for most purposes.
 439
 440 Finally, as a general note, try not to use an excessive amount of markup.
 441 As documented here and in L<Pod::Man>, you can safely leave Perl variables,
 442 function names, man page references, and the like unadorned by markup and
 443 the POD translators will figure it out for you.  This makes it much easier
 444 to later edit the documentation.  Note that many existing translators
 445 (including this one currently) will do the wrong thing with e-mail addresses
 446 or URLs when wrapped in LE<lt>E<gt>, so don't do that.
 447
 448 For additional information that may be more accurate for your specific
 449 system, see either man(5) or man(7) depending on your system manual section
 450 numbering conventions.
 451
 452 =head1 SEE ALSO
 453
 454 L<Pod::Man|Pod::Man>, L<Pod::Parser|Pod::Parser>, man(1), nroff(1),
 455 troff(1), man(7)
 456
 457 The man page documenting the an macro set may be man(5) instead of man(7) on
 458 your system.
 459
 460 =head1 AUTHOR
 461
 462 Russ Allbery E<lt>rra@stanford.eduE<gt>, based I<very> heavily on the
 463 original B<pod2man> by Larry Wall and Tom Christiansen.  Large portions of
 464 this documentation, particularly the sections on the anatomy of a proper man
 465 page, are taken from the B<pod2man> documentation by Tom.
 466
 467 =cut
 468 !NO!SUBS!
 469 #'# (cperl-mode)
 470
 471 close OUT or die "Can't close $file: $!";
 472 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
 473 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
 474 chdir $origdir;