4 perlrecharclass - Perl Regular Expression Character Classes
8 The top level documentation about Perl regular expressions
11 This manual page discusses the syntax and use of character
12 classes in Perl regular expressions.
14 A character class is a way of denoting a set of characters
15 in such a way that one character of the set is matched.
16 It's important to remember that: matching a character class
17 consumes exactly one character in the source string. (The source
18 string is the string the regular expression is matched against.)
20 There are three types of character classes in Perl regular
21 expressions: the dot, backslash sequences, and the form enclosed in square
22 brackets. Keep in mind, though, that often the term "character class" is used
23 to mean just the bracketed form. Certainly, most Perl documentation does that.
27 The dot (or period), C<.> is probably the most used, and certainly
28 the most well-known character class. By default, a dot matches any
29 character, except for the newline. The default can be changed to
30 add matching the newline by using the I<single line> modifier: either
31 for the entire regular expression with the C</s> modifier, or
32 locally with C<(?s)>. (The experimental C<\N> backslash sequence, described
33 below, matches any character except newline without regard to the
34 I<single line> modifier.)
36 Here are some examples:
40 "" =~ /./ # No match (dot has to match a character)
41 "\n" =~ /./ # No match (dot does not match a newline)
42 "\n" =~ /./s # Match (global 'single line' modifier)
43 "\n" =~ /(?s:.)/ # Match (local 'single line' modifier)
44 "ab" =~ /^.$/ # No match (dot matches one character)
46 =head2 Backslash sequences
47 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\p> X<\P>
48 X<\N> X<\v> X<\V> X<\h> X<\H>
51 A backslash sequence is a sequence of characters, the first one of which is a
52 backslash. Perl ascribes special meaning to many such sequences, and some of
53 these are character classes. That is, they match a single character each,
54 provided that the character belongs to the specific set of characters defined
57 Here's a list of the backslash sequences that are character classes. They
58 are discussed in more detail below. (For the backslash sequences that aren't
59 character classes, see L<perlrebackslash>.)
61 \d Match a decimal digit character.
62 \D Match a non-decimal-digit character.
63 \w Match a "word" character.
64 \W Match a non-"word" character.
65 \s Match a whitespace character.
66 \S Match a non-whitespace character.
67 \h Match a horizontal whitespace character.
68 \H Match a character that isn't horizontal whitespace.
69 \v Match a vertical whitespace character.
70 \V Match a character that isn't vertical whitespace.
71 \N Match a character that isn't a newline. Experimental.
72 \pP, \p{Prop} Match a character that has the given Unicode property.
73 \PP, \P{Prop} Match a character that doesn't have the Unicode property
77 C<\d> matches a single character considered to be a decimal I<digit>.
78 What is considered a decimal digit depends on several factors, detailed
79 below in L</Locale, EBCDIC, Unicode and UTF-8>. If those factors
80 indicate a Unicode interpretation, C<\d> not only matches the digits
81 '0' - '9', but also Arabic, Devanagari, and digits from other languages.
82 Otherwise, if a locale is in effect, it matches whatever characters that
83 locale considers decimal digits. Only when neither a Unicode interpretation
84 nor locale prevails does C<\d> match only the digits '0' to '9' alone.
86 Unicode digits may cause some confusion, and some security issues. In UTF-8
87 strings, unless the C<"a"> regular expression modifier is specified,
88 C<\d> matches the same characters matched by
89 C<\p{General_Category=Decimal_Number}>, or synonymously,
90 C<\p{General_Category=Digit}>. Starting with Unicode version 4.1, this is the
91 same set of characters matched by C<\p{Numeric_Type=Decimal}>.
93 But Unicode also has a different property with a similar name,
94 C<\p{Numeric_Type=Digit}>, which matches a completely different set of
95 characters. These characters are things such as subscripts.
97 The design intent is for C<\d> to match all digits (and no other characters)
98 that can be used with "normal" big-endian positional decimal syntax, whereby a
99 sequence of such digits {N0, N1, N2, ...Nn} has the numeric value (...(N0 * 10
100 + N1) * 10 + N2) * 10 ... + Nn). In Unicode 5.2, the Tamil digits (U+0BE6 -
101 U+0BEF) can also legally be used in old-style Tamil numbers in which they would
102 appear no more than one in a row, separated by characters that mean "times 10",
103 "times 100", etc. (See L<http://www.unicode.org/notes/tn21>.)
105 Some non-European digits that C<\d> matches look like European ones, but
106 have different values. For example, BENGALI DIGIT FOUR (U+09EA) looks
107 very much like an ASCII DIGIT EIGHT (U+0038).
109 It may be useful for security purposes for an application to require that all
110 digits in a row be from the same script. See L<Unicode::UCD/charscript()>.
112 Any character not matched by C<\d> is matched by C<\D>.
114 =head3 Word characters
116 A C<\w> matches a single alphanumeric character (an alphabetic character, or a
117 decimal digit) or a connecting punctuation character, such as an
118 underscore ("_"). It does not match a whole word. To match a whole
119 word, use C<\w+>. This isn't the same thing as matching an English word, but
120 in the ASCII range it is the same as a string of Perl-identifier
121 characters. What is considered a
122 word character depends on several factors, detailed below in L</Locale,
123 EBCDIC, Unicode and UTF-8>. If those factors indicate a Unicode
124 interpretation, C<\w> matches the characters considered word
125 characters in the Unicode database. That is, it not only matches ASCII letters,
126 but also Thai letters, Greek letters, etc. This includes connector
127 punctuation (like the underscore) which connect two words together, or
128 diacritics, such as a C<COMBINING TILDE> and the modifier letters, which
129 are generally used to add auxiliary markings to letters. If a Unicode
130 interpretation is not indicated, C<\w> matches those characters considered
131 word characters by the current locale or EBCDIC code page. Without a
132 locale or EBCDIC code page, C<\w> matches the underscore and ASCII letters
135 There are a number of security issues with the full Unicode list of word
136 characters. See L<http://unicode.org/reports/tr36>.
138 Also, for a somewhat finer-grained set of characters that are in programming
139 language identifiers beyond the ASCII range, you may wish to instead use the
140 more customized Unicode properties, "ID_Start", ID_Continue", "XID_Start", and
141 "XID_Continue". See L<http://unicode.org/reports/tr31>.
143 Any character not matched by C<\w> is matched by C<\W>.
147 C<\s> matches any single character considered whitespace. The exact
148 set of characters matched by C<\s> depends on several factors, detailed
149 below in L</Locale, EBCDIC, Unicode and UTF-8>. If those factors
150 indicate a Unicode interpretation, C<\s> matches what is considered
151 whitespace in the Unicode database; the complete list is in the table
152 below. Otherwise, if a locale or EBCDIC code page is in effect,
153 C<\s> matches whatever is considered whitespace by the current locale or
154 EBCDIC code page. Without a locale or EBCDIC code page, C<\s> matches
155 the horizontal tab (C<\t>), the newline (C<\n>), the form feed (C<\f>),
156 the carriage return (C<\r>), and the space. (Note that it doesn't match
157 the vertical tab, C<\cK>.) Perhaps the most notable possible surprise
158 is that C<\s> matches a non-breaking space B<only> if a Unicode
159 interpretation is indicated, or the locale or EBCDIC code page that is
160 in effect happens to have that character.
162 Any character not matched by C<\s> is matched by C<\S>.
164 C<\h> matches any character considered horizontal whitespace;
165 this includes the space and tab characters and several others
166 listed in the table below. C<\H> matches any character
167 not considered horizontal whitespace.
169 C<\v> matches any character considered vertical whitespace;
170 this includes the carriage return and line feed characters (newline)
171 plus several other characters, all listed in the table below.
172 C<\V> matches any character not considered vertical whitespace.
174 C<\R> matches anything that can be considered a newline under Unicode
175 rules. It's not a character class, as it can match a multi-character
176 sequence. Therefore, it cannot be used inside a bracketed character
177 class; use C<\v> instead (vertical whitespace).
178 Details are discussed in L<perlrebackslash>.
180 Note that unlike C<\s>, C<\d> and C<\w>, C<\h> and C<\v> always match
181 the same characters, without regard to other factors, such as whether the
182 source string is in UTF-8 format.
184 One might think that C<\s> is equivalent to C<[\h\v]>. This is not true. The
185 vertical tab (C<"\x0b">) is not matched by C<\s>, it is however considered
186 vertical whitespace. Furthermore, if the source string is not in UTF-8 format,
187 and any locale or EBCDIC code page that is in effect doesn't include them, the
188 next line (ASCII-platform C<"\x85">) and the no-break space (ASCII-platform
189 C<"\xA0">) characters are not matched by C<\s>, but are by C<\v> and C<\h>
190 respectively. If the C<"a"> modifier is not in effect and the source
191 string is in UTF-8 format, both the next line and the no-break space
192 are matched by C<\s>.
194 The following table is a complete listing of characters matched by
195 C<\s>, C<\h> and C<\v> as of Unicode 5.2.
197 The first column gives the code point of the character (in hex format),
198 the second column gives the (Unicode) name. The third column indicates
199 by which class(es) the character is matched (assuming no locale or EBCDIC code
200 page is in effect that changes the C<\s> matching).
202 0x00009 CHARACTER TABULATION h s
203 0x0000a LINE FEED (LF) vs
204 0x0000b LINE TABULATION v
205 0x0000c FORM FEED (FF) vs
206 0x0000d CARRIAGE RETURN (CR) vs
208 0x00085 NEXT LINE (NEL) vs [1]
209 0x000a0 NO-BREAK SPACE h s [1]
210 0x01680 OGHAM SPACE MARK h s
211 0x0180e MONGOLIAN VOWEL SEPARATOR h s
216 0x02004 THREE-PER-EM SPACE h s
217 0x02005 FOUR-PER-EM SPACE h s
218 0x02006 SIX-PER-EM SPACE h s
219 0x02007 FIGURE SPACE h s
220 0x02008 PUNCTUATION SPACE h s
221 0x02009 THIN SPACE h s
222 0x0200a HAIR SPACE h s
223 0x02028 LINE SEPARATOR vs
224 0x02029 PARAGRAPH SEPARATOR vs
225 0x0202f NARROW NO-BREAK SPACE h s
226 0x0205f MEDIUM MATHEMATICAL SPACE h s
227 0x03000 IDEOGRAPHIC SPACE h s
233 NEXT LINE and NO-BREAK SPACE only match C<\s> if the source string is in
234 UTF-8 format and the C<"a"> modifier is not in effect, or if the locale
235 or EBCDIC code page in effect includes them.
239 It is worth noting that C<\d>, C<\w>, etc, match single characters, not
240 complete numbers or words. To match a number (that consists of digits),
241 use C<\d+>; to match a word, use C<\w+>.
245 C<\N> is new in 5.12, and is experimental. It, like the dot, matches any
246 character that is not a newline. The difference is that C<\N> is not influenced
247 by the I<single line> regular expression modifier (see L</The dot> above). Note
248 that the form C<\N{...}> may mean something completely different. When the
249 C<{...}> is a L<quantifier|perlre/Quantifiers>, it means to match a non-newline
250 character that many times. For example, C<\N{3}> means to match 3
251 non-newlines; C<\N{5,}> means to match 5 or more non-newlines. But if C<{...}>
252 is not a legal quantifier, it is presumed to be a named character. See
253 L<charnames> for those. For example, none of C<\N{COLON}>, C<\N{4F}>, and
254 C<\N{F4}> contain legal quantifiers, so Perl will try to find characters whose
255 names are respectively C<COLON>, C<4F>, and C<F4>.
257 =head3 Unicode Properties
259 C<\pP> and C<\p{Prop}> are character classes to match characters that fit given
260 Unicode properties. One letter property names can be used in the C<\pP> form,
261 with the property name following the C<\p>, otherwise, braces are required.
262 When using braces, there is a single form, which is just the property name
263 enclosed in the braces, and a compound form which looks like C<\p{name=value}>,
264 which means to match if the property "name" for the character has that particular
266 For instance, a match for a number can be written as C</\pN/> or as
267 C</\p{Number}/>, or as C</\p{Number=True}/>.
268 Lowercase letters are matched by the property I<Lowercase_Letter> which
269 has as short form I<Ll>. They need the braces, so are written as C</\p{Ll}/> or
270 C</\p{Lowercase_Letter}/>, or C</\p{General_Category=Lowercase_Letter}/>
271 (the underscores are optional).
272 C</\pLl/> is valid, but means something different.
273 It matches a two character string: a letter (Unicode property C<\pL>),
274 followed by a lowercase C<l>.
276 Note that almost all properties are immune to case-insensitive matching.
277 That is, adding a C</i> regular expression modifier does not change what
278 they match. There are two sets affected. The first set is
281 and C<Titlecase_Letter>,
282 all of which match C<Cased_Letter> under C</i> matching.
287 all of which match C<Cased> under C</i> matching.
288 (The difference between these sets is that some things, such as Roman
289 Numerals, come in both upper and lower case so they are C<Cased>, but
290 aren't considered to be letters, so they aren't C<Cased_Letter>s. They're
291 actually C<Letter_Number>s.)
292 This set also includes its subsets C<PosixUpper> and C<PosixLower>, both
293 of which under C</i> matching match C<PosixAlpha>.
295 For more details on Unicode properties, see L<perlunicode/Unicode
296 Character Properties>; for a
297 complete list of possible properties, see
298 L<perluniprops/Properties accessible through \p{} and \P{}>,
299 which notes all forms that have C</i> differences.
300 It is also possible to define your own properties. This is discussed in
301 L<perlunicode/User-Defined Character Properties>.
305 "a" =~ /\w/ # Match, "a" is a 'word' character.
306 "7" =~ /\w/ # Match, "7" is a 'word' character as well.
307 "a" =~ /\d/ # No match, "a" isn't a digit.
308 "7" =~ /\d/ # Match, "7" is a digit.
309 " " =~ /\s/ # Match, a space is whitespace.
310 "a" =~ /\D/ # Match, "a" is a non-digit.
311 "7" =~ /\D/ # No match, "7" is not a non-digit.
312 " " =~ /\S/ # No match, a space is not non-whitespace.
314 " " =~ /\h/ # Match, space is horizontal whitespace.
315 " " =~ /\v/ # No match, space is not vertical whitespace.
316 "\r" =~ /\v/ # Match, a return is vertical whitespace.
318 "a" =~ /\pL/ # Match, "a" is a letter.
319 "a" =~ /\p{Lu}/ # No match, /\p{Lu}/ matches upper case letters.
321 "\x{0e0b}" =~ /\p{Thai}/ # Match, \x{0e0b} is the character
322 # 'THAI CHARACTER SO SO', and that's in
323 # Thai Unicode class.
324 "a" =~ /\P{Lao}/ # Match, as "a" is not a Laotian character.
327 =head2 Bracketed Character Classes
329 The third form of character class you can use in Perl regular expressions
330 is the bracketed character class. In its simplest form, it lists the characters
331 that may be matched, surrounded by square brackets, like this: C<[aeiou]>.
332 This matches one of C<a>, C<e>, C<i>, C<o> or C<u>. Like the other
333 character classes, exactly one character is matched. To match
334 a longer string consisting of characters mentioned in the character
335 class, follow the character class with a L<quantifier|perlre/Quantifiers>. For
336 instance, C<[aeiou]+> matches one or more lowercase English vowels.
338 Repeating a character in a character class has no
339 effect; it's considered to be in the set only once.
343 "e" =~ /[aeiou]/ # Match, as "e" is listed in the class.
344 "p" =~ /[aeiou]/ # No match, "p" is not listed in the class.
345 "ae" =~ /^[aeiou]$/ # No match, a character class only matches
346 # a single character.
347 "ae" =~ /^[aeiou]+$/ # Match, due to the quantifier.
349 =head3 Special Characters Inside a Bracketed Character Class
351 Most characters that are meta characters in regular expressions (that
352 is, characters that carry a special meaning like C<.>, C<*>, or C<(>) lose
353 their special meaning and can be used inside a character class without
354 the need to escape them. For instance, C<[()]> matches either an opening
355 parenthesis, or a closing parenthesis, and the parens inside the character
356 class don't group or capture.
358 Characters that may carry a special meaning inside a character class are:
359 C<\>, C<^>, C<->, C<[> and C<]>, and are discussed below. They can be
360 escaped with a backslash, although this is sometimes not needed, in which
361 case the backslash may be omitted.
363 The sequence C<\b> is special inside a bracketed character class. While
364 outside the character class, C<\b> is an assertion indicating a point
365 that does not have either two word characters or two non-word characters
366 on either side, inside a bracketed character class, C<\b> matches a
376 C<\N{U+I<hex char>}>,
381 are also special and have the same meanings as they do outside a
382 bracketed character class. (However, inside a bracketed character
383 class, if C<\N{I<NAME>}> expands to a sequence of characters, only the first
384 one in the sequence is used, with a warning.)
386 Also, a backslash followed by two or three octal digits is considered an octal
389 A C<[> is not special inside a character class, unless it's the start of a
390 POSIX character class (see L</POSIX Character Classes> below). It normally does
393 A C<]> is normally either the end of a POSIX character class (see
394 L</POSIX Character Classes> below), or it signals the end of the bracketed
395 character class. If you want to include a C<]> in the set of characters, you
396 must generally escape it.
398 However, if the C<]> is the I<first> (or the second if the first
399 character is a caret) character of a bracketed character class, it
400 does not denote the end of the class (as you cannot have an empty class)
401 and is considered part of the set of characters that can be matched without
406 "+" =~ /[+?*]/ # Match, "+" in a character class is not special.
407 "\cH" =~ /[\b]/ # Match, \b inside in a character class
408 # is equivalent to a backspace.
409 "]" =~ /[][]/ # Match, as the character class contains.
411 "[]" =~ /[[]]/ # Match, the pattern contains a character class
412 # containing just ], and the character class is
415 =head3 Character Ranges
417 It is not uncommon to want to match a range of characters. Luckily, instead
418 of listing all characters in the range, one may use the hyphen (C<->).
419 If inside a bracketed character class you have two characters separated
420 by a hyphen, it's treated as if all characters between the two were in
421 the class. For instance, C<[0-9]> matches any ASCII digit, and C<[a-m]>
422 matches any lowercase letter from the first half of the old ASCII alphabet.
424 Note that the two characters on either side of the hyphen are not
425 necessarily both letters or both digits. Any character is possible,
426 although not advisable. C<['-?]> contains a range of characters, but
427 most people will not know which characters that means. Furthermore,
428 such ranges may lead to portability problems if the code has to run on
429 a platform that uses a different character set, such as EBCDIC.
431 If a hyphen in a character class cannot syntactically be part of a range, for
432 instance because it is the first or the last character of the character class,
433 or if it immediately follows a range, the hyphen isn't special, and so is
434 considered a character to be matched literally. If you want a hyphen in
435 your set of characters to be matched and its position in the class is such
436 that it could be considered part of a range, you must escape that hyphen
441 [a-z] # Matches a character that is a lower case ASCII letter.
442 [a-fz] # Matches any letter between 'a' and 'f' (inclusive) or
444 [-z] # Matches either a hyphen ('-') or the letter 'z'.
445 [a-f-m] # Matches any letter between 'a' and 'f' (inclusive), the
446 # hyphen ('-'), or the letter 'm'.
447 ['-?] # Matches any of the characters '()*+,-./0123456789:;<=>?
448 # (But not on an EBCDIC platform).
453 It is also possible to instead list the characters you do not want to
454 match. You can do so by using a caret (C<^>) as the first character in the
455 character class. For instance, C<[^a-z]> matches any character that is not a
456 lowercase ASCII letter, which therefore includes almost a hundred thousand
459 This syntax make the caret a special character inside a bracketed character
460 class, but only if it is the first character of the class. So if you want
461 the caret as one of the characters to match, either escape the caret or
462 else not list it first.
466 "e" =~ /[^aeiou]/ # No match, the 'e' is listed.
467 "x" =~ /[^aeiou]/ # Match, as 'x' isn't a lowercase vowel.
468 "^" =~ /[^^]/ # No match, matches anything that isn't a caret.
469 "^" =~ /[x^]/ # Match, caret is not special here.
471 =head3 Backslash Sequences
473 You can put any backslash sequence character class (with the exception of
474 C<\N> and C<\R>) inside a bracketed character class, and it will act just
475 as if you had put all characters matched by the backslash sequence inside the
476 character class. For instance, C<[a-f\d]> matches any decimal digit, or any
477 of the lowercase letters between 'a' and 'f' inclusive.
479 C<\N> within a bracketed character class must be of the forms C<\N{I<name>}>
480 or C<\N{U+I<hex char>}>, and NOT be the form that matches non-newlines,
481 for the same reason that a dot C<.> inside a bracketed character class loses
482 its special meaning: it matches nearly anything, which generally isn't what you
488 /[\p{Thai}\d]/ # Matches a character that is either a Thai
489 # character, or a digit.
490 /[^\p{Arabic}()]/ # Matches a character that is neither an Arabic
491 # character, nor a parenthesis.
493 Backslash sequence character classes cannot form one of the endpoints
494 of a range. Thus, you can't say:
496 /[\p{Thai}-\d]/ # Wrong!
498 =head3 POSIX Character Classes
499 X<character class> X<\p> X<\p{}>
500 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
501 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
503 POSIX character classes have the form C<[:class:]>, where I<class> is
504 name, and the C<[:> and C<:]> delimiters. POSIX character classes only appear
505 I<inside> bracketed character classes, and are a convenient and descriptive
506 way of listing a group of characters, though they can suffer from
507 portability issues (see below and L<Locale, EBCDIC, Unicode and UTF-8>).
509 Be careful about the syntax,
512 $string =~ /[[:alpha:]]/
514 # Incorrect (will warn):
515 $string =~ /[:alpha:]/
517 The latter pattern would be a character class consisting of a colon,
518 and the letters C<a>, C<l>, C<p> and C<h>.
519 POSIX character classes can be part of a larger bracketed character class.
524 is valid and matches '0', '1', any alphabetic character, and the percent sign.
526 Perl recognizes the following POSIX character classes:
528 alpha Any alphabetical character ("[A-Za-z]").
529 alnum Any alphanumeric character. ("[A-Za-z0-9]")
530 ascii Any character in the ASCII character set.
531 blank A GNU extension, equal to a space or a horizontal tab ("\t").
532 cntrl Any control character. See Note [2] below.
533 digit Any decimal digit ("[0-9]"), equivalent to "\d".
534 graph Any printable character, excluding a space. See Note [3] below.
535 lower Any lowercase character ("[a-z]").
536 print Any printable character, including a space. See Note [4] below.
537 punct Any graphical character excluding "word" characters. Note [5].
538 space Any whitespace character. "\s" plus the vertical tab ("\cK").
539 upper Any uppercase character ("[A-Z]").
540 word A Perl extension ("[A-Za-z0-9_]"), equivalent to "\w".
541 xdigit Any hexadecimal digit ("[0-9a-fA-F]").
543 Most POSIX character classes have two Unicode-style C<\p> property
544 counterparts. (They are not official Unicode properties, but Perl extensions
545 derived from official Unicode properties.) The table below shows the relation
546 between POSIX character classes and these counterparts.
548 One counterpart, in the column labelled "ASCII-range Unicode" in
549 the table, matches only characters in the ASCII character set.
551 The other counterpart, in the column labelled "Full-range Unicode", matches any
552 appropriate characters in the full Unicode character set. For example,
553 C<\p{Alpha}> matches not just the ASCII alphabetic characters, but any
554 character in the entire Unicode character set considered alphabetic.
555 The column labelled "backslash sequence" is a (short) synonym for
556 the Full-range Unicode form.
558 (Each of the counterparts has various synonyms as well.
559 L<perluniprops/Properties accessible through \p{} and \P{}> lists all
560 synonyms, plus all characters matched by each ASCII-range property.
561 For example, C<\p{AHex}> is a synonym for C<\p{ASCII_Hex_Digit}>,
562 and any C<\p> property name can be prefixed with "Is" such as C<\p{IsAlpha}>.)
564 Both the C<\p> forms are unaffected by any locale in effect, or whether
565 the string is in UTF-8 format or not, or whether the platform is EBCDIC or not.
566 In contrast, the POSIX character classes are affected, unless the
567 regular expression is compiled with the C<"a"> modifier. If the C<"a">
568 modifier is not in effect, and the source string is in UTF-8 format, the
569 POSIX classes behave like their "Full-range" Unicode counterparts. If
570 C<"a"> modifier is in effect; or the source string is not in UTF-8
571 format, and no locale is in effect, and the platform is not EBCDIC, all
572 the POSIX classes behave like their ASCII-range counterparts.
573 Otherwise, they behave based on the rules of the locale or EBCDIC code
576 It is proposed to change this behavior in a future release of Perl so that the
577 the UTF-8-ness of the source string will be irrelevant to the behavior of the
578 POSIX character classes. This means they will always behave in strict
579 accordance with the official POSIX standard. That is, if either locale or
580 EBCDIC code page is present, they will behave in accordance with those; if
581 absent, the classes will match only their ASCII-range counterparts. If you
582 wish to comment on this proposal, send email to C<perl5-porters@perl.org>.
584 [[:...:]] ASCII-range Full-range backslash Note
585 Unicode Unicode sequence
586 -----------------------------------------------------
587 alpha \p{PosixAlpha} \p{XPosixAlpha}
588 alnum \p{PosixAlnum} \p{XPosixAlnum}
590 blank \p{PosixBlank} \p{XPosixBlank} \h [1]
591 or \p{HorizSpace} [1]
592 cntrl \p{PosixCntrl} \p{XPosixCntrl} [2]
593 digit \p{PosixDigit} \p{XPosixDigit} \d
594 graph \p{PosixGraph} \p{XPosixGraph} [3]
595 lower \p{PosixLower} \p{XPosixLower}
596 print \p{PosixPrint} \p{XPosixPrint} [4]
597 punct \p{PosixPunct} \p{XPosixPunct} [5]
598 \p{PerlSpace} \p{XPerlSpace} \s [6]
599 space \p{PosixSpace} \p{XPosixSpace} [6]
600 upper \p{PosixUpper} \p{XPosixUpper}
601 word \p{PosixWord} \p{XPosixWord} \w
602 xdigit \p{ASCII_Hex_Digit} \p{XPosixXDigit}
608 C<\p{Blank}> and C<\p{HorizSpace}> are synonyms.
612 Control characters don't produce output as such, but instead usually control
613 the terminal somehow: for example, newline and backspace are control characters.
614 In the ASCII range, characters whose ordinals are between 0 and 31 inclusive,
615 plus 127 (C<DEL>) are control characters.
617 On EBCDIC platforms, it is likely that the code page will define C<[[:cntrl:]]>
618 to be the EBCDIC equivalents of the ASCII controls, plus the controls
619 that in Unicode have ordinals from 128 through 159.
623 Any character that is I<graphical>, that is, visible. This class consists
624 of all alphanumeric characters and all punctuation characters.
628 All printable characters, which is the set of all graphical characters
629 plus those whitespace characters which are not also controls.
633 C<\p{PosixPunct}> and C<[[:punct:]]> in the ASCII range match all
634 non-controls, non-alphanumeric, non-space characters:
635 C<[-!"#$%&'()*+,./:;<=E<gt>?@[\\\]^_`{|}~]> (although if a locale is in effect,
636 it could alter the behavior of C<[[:punct:]]>).
638 The similarly named property, C<\p{Punct}>, matches a somewhat different
639 set in the ASCII range, namely
640 C<[-!"#%&'()*,./:;?@[\\\]_{}]>. That is, it is missing C<[$+E<lt>=E<gt>^`|~]>.
641 This is because Unicode splits what POSIX considers to be punctuation into two
642 categories, Punctuation and Symbols.
644 C<\p{XPosixPunct}> and (in Unicode mode) C<[[:punct:]]>, match what
645 C<\p{PosixPunct}> matches in the ASCII range, plus what C<\p{Punct}>
646 matches. This is different than strictly matching according to
647 C<\p{Punct}>. Another way to say it is that
648 for a UTF-8 string, C<[[:punct:]]> matches all characters that Unicode
649 considers punctuation, plus all ASCII-range characters that Unicode
654 C<\p{SpacePerl}> and C<\p{Space}> differ only in that C<\p{Space}> additionally
655 matches the vertical tab, C<\cK>. Same for the two ASCII-only range forms.
659 There are various other synonyms that can be used for these besides
660 C<\p{HorizSpace}> and \C<\p{XPosixBlank}>. For example,
661 C<\p{PosixAlpha}> can be written as C<\p{Alpha}>. All are listed
662 in L<perluniprops/Properties accessible through \p{} and \P{}>.
665 X<character class, negation>
667 A Perl extension to the POSIX character class is the ability to
668 negate it. This is done by prefixing the class name with a caret (C<^>).
671 POSIX ASCII-range Full-range backslash
672 Unicode Unicode sequence
673 -----------------------------------------------------
674 [[:^digit:]] \P{PosixDigit} \P{XPosixDigit} \D
675 [[:^space:]] \P{PosixSpace} \P{XPosixSpace}
676 \P{PerlSpace} \P{XPerlSpace} \S
677 [[:^word:]] \P{PerlWord} \P{XPosixWord} \W
679 The backslash sequence can mean either ASCII- or Full-range Unicode,
680 depending on various factors. See L</Locale, EBCDIC, Unicode and UTF-8>
683 =head4 [= =] and [. .]
685 Perl recognizes the POSIX character classes C<[=class=]> and
686 C<[.class.]>, but does not (yet?) support them. Any attempt to use
687 either construct raises an exception.
691 /[[:digit:]]/ # Matches a character that is a digit.
692 /[01[:lower:]]/ # Matches a character that is either a
693 # lowercase letter, or '0' or '1'.
694 /[[:digit:][:^xdigit:]]/ # Matches a character that can be anything
695 # except the letters 'a' to 'f'. This is
696 # because the main character class is composed
697 # of two POSIX character classes that are ORed
698 # together, one that matches any digit, and
699 # the other that matches anything that isn't a
700 # hex digit. The result matches all
701 # characters except the letters 'a' to 'f' and
705 =head2 Locale, EBCDIC, Unicode and UTF-8
707 Some of the character classes have a somewhat different behaviour
708 depending on the internal encoding of the source string, whether the regular
709 expression is marked as having Unicode semantics, whatever locale is in
710 effect, and whether the program is running on an EBCDIC platform.
712 C<\w>, C<\d>, C<\s> and the POSIX character classes (and their
713 negations, including C<\W>, C<\D>, C<\S>) have this behaviour. (Since
714 the backslash sequences C<\b> and C<\B> are defined in terms of C<\w>
715 and C<\W>, they also are affected.)
717 Starting in Perl 5.14, if the regular expression is compiled with the
718 C<"a"> modifier, the behavior doesn't differ regardless of any other
719 factors. C<\d> matches the 10 digits 0-9; C<\D> any character but those
720 10; C<\s>, exactly the five characters "[ \f\n\r\t]"; C<\w> only the 63
721 characters "[A-Za-z0-9_]"; and the C<"[[:posix:]]"> classes only the
722 appropriate ASCII characters, the same characters as are matched by the
723 corresponding C<\p{}> property given in the "ASCII-range Unicode" column
724 in the table above. (The behavior of all of their complements follows
727 Otherwise, a regular expression is marked for Unicode semantics if it is
728 encoded in utf8 (usually as a result of including a literal character
729 whose code point is above 255), or if it contains a C<\N{U+...}> or
730 C<\N{I<name>}> construct, or (starting in Perl 5.14) if it was compiled
731 in the scope of a C<S<use feature "unicode_strings">> pragma and not in
732 the scope of a C<S<use locale>> pragma, or has the C<"u"> regular
735 Note that one can specify C<"use re '/l'"> for example, for any regular
736 expression modifier, and this has precedence over either of the
737 C<S<use feature "unicode_strings">> or C<S<use locale>> pragmas.
739 The differences in behavior between locale and non-locale semantics
740 can affect any character whose code point is 255 or less. The
741 differences in behavior between Unicode and non-Unicode semantics
742 affects only ASCII platforms, and only when matching against characters
743 whose code points are between 128 and 255 inclusive. See
744 L<perlunicode/The "Unicode Bug">.
746 For portability reasons, unless the C<"a"> modifier is specified,
747 it may be better to not use C<\w>, C<\d>, C<\s> or the POSIX character
748 classes and use the Unicode properties instead.
750 That way you can control whether you want matching of characters in
751 the ASCII character set alone, or whether to match Unicode characters.
752 C<S<use feature "unicode_strings">> allows seamless Unicode behavior
753 no matter the internal encodings, but won't allow restricting
754 to ASCII characters only.
758 $str = "\xDF"; # $str is not in UTF-8 format.
759 $str =~ /^\w/; # No match, as $str isn't in UTF-8 format.
760 $str .= "\x{0e0b}"; # Now $str is in UTF-8 format.
761 $str =~ /^\w/; # Match! $str is now in UTF-8 format.
763 $str =~ /^\w/; # Still a match! $str remains in UTF-8 format.