lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<$filename>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34).
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 use strict;
 514
 515 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
 516
 517 BEGIN {
 518     require feature;
 519     $^V =~ /^v(\d+\.\d+)/;
 520     feature->import(":$1");
 521 }
 522
 523 # Debugger for Perl 5.00x; perl5db.pl patch level:
 524 use vars qw($VERSION $header);
 525
 526 $VERSION = '1.39_05';
 527
 528 $header = "perl5db.pl version $VERSION";
 529
 530 =head1 DEBUGGER ROUTINES
 531
 532 =head2 C<DB::eval()>
 533
 534 This function replaces straight C<eval()> inside the debugger; it simplifies
 535 the process of evaluating code in the user's context.
 536
 537 The code to be evaluated is passed via the package global variable
 538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 539
 540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 543 user's current package, grabbed when C<DB::DB> got control.  This causes the
 544 proper context to be used when the eval is actually done.  Afterward, we
 545 restore C<$trace>, C<$single>, and C<$^D>.
 546
 547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 551 considered sane by the debugger. If there was an C<eval()> error, we print
 552 it on the debugger's output. If C<$onetimedump> is defined, we call
 553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 554 'methods'. Setting it to something else causes the debugger to do the eval
 555 but not print the result - handy if you want to do something else with it
 556 (the "watch expressions" code does this to get the value of the watch
 557 expression but not show it unless it matters).
 558
 559 In any case, we then return the list of output from C<eval> to the caller,
 560 and unwinding restores the former version of C<$@> in C<@saved> as well
 561 (the localization of C<$saved[0]> goes away at the end of this scope).
 562
 563 =head3 Parameters and variables influencing execution of DB::eval()
 564
 565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 567 The variables listed below influence C<DB::eval()>'s execution directly.
 568
 569 =over 4
 570
 571 =item C<$evalarg> - the thing to actually be eval'ed
 572
 573 =item C<$trace> - Current state of execution tracing
 574
 575 =item C<$single> - Current state of single-stepping
 576
 577 =item C<$onetimeDump> - what is to be displayed after the evaluation
 578
 579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 580
 581 =back
 582
 583 The following variables are altered by C<DB::eval()> during its execution. They
 584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 585
 586 =over 4
 587
 588 =item C<@res> - used to capture output from actual C<eval>.
 589
 590 =item C<$otrace> - saved value of C<$trace>.
 591
 592 =item C<$osingle> - saved value of C<$single>.
 593
 594 =item C<$od> - saved value of C<$^D>.
 595
 596 =item C<$saved[0]> - saved value of C<$@>.
 597
 598 =item $\ - for output of C<$@> if there is an evaluation error.
 599
 600 =back
 601
 602 =head3 The problem of lexicals
 603
 604 The context of C<DB::eval()> presents us with some problems. Obviously,
 605 we want to be 'sandboxed' away from the debugger's internals when we do
 606 the eval, but we need some way to control how punctuation variables and
 607 debugger globals are used.
 608
 609 We can't use local, because the code inside C<DB::eval> can see localized
 610 variables; and we can't use C<my> either for the same reason. The code
 611 in this routine compromises and uses C<my>.
 612
 613 After this routine is over, we don't have user code executing in the debugger's
 614 context, so we can use C<my> freely.
 615
 616 =cut
 617
 618 ############################################## Begin lexical danger zone
 619
 620 # 'my' variables used here could leak into (that is, be visible in)
 621 # the context that the code being evaluated is executing in. This means that
 622 # the code could modify the debugger's variables.
 623 #
 624 # Fiddling with the debugger's context could be Bad. We insulate things as
 625 # much as we can.
 626
 627 use vars qw(
 628     @args
 629     %break_on_load
 630     $CommandSet
 631     $CreateTTY
 632     $DBGR
 633     @dbline
 634     $dbline
 635     %dbline
 636     $dieLevel
 637     $filename
 638     $histfile
 639     $histsize
 640     $IN
 641     $inhibit_exit
 642     @ini_INC
 643     $ini_warn
 644     $maxtrace
 645     $od
 646     @options
 647     $osingle
 648     $otrace
 649     $pager
 650     $post
 651     %postponed
 652     $prc
 653     $pre
 654     $pretype
 655     $psh
 656     @RememberOnROptions
 657     $remoteport
 658     @res
 659     $rl
 660     @saved
 661     $signalLevel
 662     $sub
 663     $term
 664     $usercontext
 665     $warnLevel
 666 );
 667
 668 our (
 669     @cmdfhs,
 670     $evalarg,
 671     $frame,
 672     $hist,
 673     $ImmediateStop,
 674     $line,
 675     $onetimeDump,
 676     $onetimedumpDepth,
 677     %option,
 678     $OUT,
 679     $packname,
 680     $signal,
 681     $single,
 682     $start,
 683     %sub,
 684     $subname,
 685     $trace,
 686     $window,
 687 );
 688
 689 # Used to save @ARGV and extract any debugger-related flags.
 690 use vars qw(@ARGS);
 691
 692 # Used to prevent multiple entries to diesignal()
 693 # (if for instance diesignal() itself dies)
 694 use vars qw($panic);
 695
 696 # Used to prevent the debugger from running nonstop
 697 # after a restart
 698 our ($second_time);
 699
 700 sub _calc_usercontext {
 701     my ($package) = @_;
 702
 703     # Cancel strict completely for the evaluated code, so the code
 704     # the user evaluates won't be affected by it. (Shlomi Fish)
 705     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
 706     . "package $package;";    # this won't let them modify, alas
 707 }
 708
 709 sub eval {
 710
 711     # 'my' would make it visible from user code
 712     #    but so does local! --tchrist
 713     # Remember: this localizes @DB::res, not @main::res.
 714     local @res;
 715     {
 716
 717         # Try to keep the user code from messing  with us. Save these so that
 718         # even if the eval'ed code changes them, we can put them back again.
 719         # Needed because the user could refer directly to the debugger's
 720         # package globals (and any 'my' variables in this containing scope)
 721         # inside the eval(), and we want to try to stay safe.
 722         local $otrace  = $trace;
 723         local $osingle = $single;
 724         local $od      = $^D;
 725
 726         # Untaint the incoming eval() argument.
 727         { ($evalarg) = $evalarg =~ /(.*)/s; }
 728
 729         # $usercontext built in DB::DB near the comment
 730         # "set up the context for DB::eval ..."
 731         # Evaluate and save any results.
 732         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 733
 734         # Restore those old values.
 735         $trace  = $otrace;
 736         $single = $osingle;
 737         $^D     = $od;
 738     }
 739
 740     # Save the current value of $@, and preserve it in the debugger's copy
 741     # of the saved precious globals.
 742     my $at = $@;
 743
 744     # Since we're only saving $@, we only have to localize the array element
 745     # that it will be stored in.
 746     local $saved[0];    # Preserve the old value of $@
 747     eval { DB::save() };
 748
 749     # Now see whether we need to report an error back to the user.
 750     if ($at) {
 751         local $\ = '';
 752         print $OUT $at;
 753     }
 754
 755     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 756     # are package globals.
 757     elsif ($onetimeDump) {
 758         if ( $onetimeDump eq 'dump' ) {
 759             local $option{dumpDepth} = $onetimedumpDepth
 760               if defined $onetimedumpDepth;
 761             dumpit( $OUT, \@res );
 762         }
 763         elsif ( $onetimeDump eq 'methods' ) {
 764             methods( $res[0] );
 765         }
 766     } ## end elsif ($onetimeDump)
 767     @res;
 768 } ## end sub eval
 769
 770 ############################################## End lexical danger zone
 771
 772 # After this point it is safe to introduce lexicals.
 773 # The code being debugged will be executing in its own context, and
 774 # can't see the inside of the debugger.
 775 #
 776 # However, one should not overdo it: leave as much control from outside as
 777 # possible. If you make something a lexical, it's not going to be addressable
 778 # from outside the debugger even if you know its name.
 779
 780 # This file is automatically included if you do perl -d.
 781 # It's probably not useful to include this yourself.
 782 #
 783 # Before venturing further into these twisty passages, it is
 784 # wise to read the perldebguts man page or risk the ire of dragons.
 785 #
 786 # (It should be noted that perldebguts will tell you a lot about
 787 # the underlying mechanics of how the debugger interfaces into the
 788 # Perl interpreter, but not a lot about the debugger itself. The new
 789 # comments in this code try to address this problem.)
 790
 791 # Note that no subroutine call is possible until &DB::sub is defined
 792 # (for subroutines defined outside of the package DB). In fact the same is
 793 # true if $deep is not defined.
 794
 795 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 796
 797 # modified Perl debugger, to be run from Emacs in perldb-mode
 798 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 799 # Johan Vromans -- upgrade to 4.0 pl 10
 800 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 801 ########################################################################
 802
 803 =head1 DEBUGGER INITIALIZATION
 804
 805 The debugger starts up in phases.
 806
 807 =head2 BASIC SETUP
 808
 809 First, it initializes the environment it wants to run in: turning off
 810 warnings during its own compilation, defining variables which it will need
 811 to avoid warnings later, setting itself up to not exit when the program
 812 terminates, and defaulting to printing return values for the C<r> command.
 813
 814 =cut
 815
 816 # Needed for the statement after exec():
 817 #
 818 # This BEGIN block is simply used to switch off warnings during debugger
 819 # compilation. Probably it would be better practice to fix the warnings,
 820 # but this is how it's done at the moment.
 821
 822 BEGIN {
 823     $ini_warn = $^W;
 824     $^W       = 0;
 825 }    # Switch compilation warnings off until another BEGIN.
 826
 827 local ($^W) = 0;    # Switch run-time warnings off during init.
 828
 829 =head2 THREADS SUPPORT
 830
 831 If we are running under a threaded Perl, we require threads and threads::shared
 832 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 833 threaded debugger control.  C<-dt> can also be used to set this.
 834
 835 Each new thread will be announced and the debugger prompt will always inform
 836 you of each new thread created.  It will also indicate the thread id in which
 837 we are currently running within the prompt like this:
 838
 839     [tid] DB<$i>
 840
 841 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 842 command prompt.  The prompt will show: C<[0]> when running under threads, but
 843 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 844
 845 While running under threads, when you set or delete a breakpoint (etc.), this
 846 will apply to all threads, not just the currently running one.  When you are
 847 in a currently executing thread, you will stay there until it completes.  With
 848 the current implementation it is not currently possible to hop from one thread
 849 to another.
 850
 851 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 852
 853 Note that threading support was built into the debugger as of Perl version
 854 C<5.8.6> and debugger version C<1.2.8>.
 855
 856 =cut
 857
 858 BEGIN {
 859     # ensure we can share our non-threaded variables or no-op
 860     if ($ENV{PERL5DB_THREADED}) {
 861         require threads;
 862         require threads::shared;
 863         import threads::shared qw(share);
 864         $DBGR;
 865         share(\$DBGR);
 866         lock($DBGR);
 867         print "Threads support enabled\n";
 868     } else {
 869         *share = sub(\[$@%]) {};
 870     }
 871 }
 872
 873 # These variables control the execution of 'dumpvar.pl'.
 874 {
 875     package dumpvar;
 876     use vars qw(
 877     $hashDepth
 878     $arrayDepth
 879     $dumpDBFiles
 880     $dumpPackages
 881     $quoteHighBit
 882     $printUndef
 883     $globPrint
 884     $usageOnly
 885     );
 886 }
 887
 888 # used to control die() reporting in diesignal()
 889 {
 890     package Carp;
 891     use vars qw($CarpLevel);
 892 }
 893
 894 # without threads, $filename is not defined until DB::DB is called
 895 share($main::{'_<'.$filename}) if defined $filename;
 896
 897 # Command-line + PERLLIB:
 898 # Save the contents of @INC before they are modified elsewhere.
 899 @ini_INC = @INC;
 900
 901 # This was an attempt to clear out the previous values of various
 902 # trapped errors. Apparently it didn't help. XXX More info needed!
 903 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 904
 905 # We set these variables to safe values. We don't want to blindly turn
 906 # off warnings, because other packages may still want them.
 907 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 908                                    # (local $^W cannot help - other packages!).
 909
 910 # Default to not exiting when program finishes; print the return
 911 # value when the 'r' command is used to return from a subroutine.
 912 $inhibit_exit = $option{PrintRet} = 1;
 913
 914 use vars qw($trace_to_depth);
 915
 916 # Default to 1E9 so it won't be limited to a certain recursion depth.
 917 $trace_to_depth = 1E9;
 918
 919 =head1 OPTION PROCESSING
 920
 921 The debugger's options are actually spread out over the debugger itself and
 922 C<dumpvar.pl>; some of these are variables to be set, while others are
 923 subs to be called with a value. To try to make this a little easier to
 924 manage, the debugger uses a few data structures to define what options
 925 are legal and how they are to be processed.
 926
 927 First, the C<@options> array defines the I<names> of all the options that
 928 are to be accepted.
 929
 930 =cut
 931
 932 @options = qw(
 933   CommandSet   HistFile      HistSize
 934   hashDepth    arrayDepth    dumpDepth
 935   DumpDBFiles  DumpPackages  DumpReused
 936   compactDump  veryCompact   quote
 937   HighBit      undefPrint    globPrint
 938   PrintRet     UsageOnly     frame
 939   AutoTrace    TTY           noTTY
 940   ReadLine     NonStop       LineInfo
 941   maxTraceLen  recallCommand ShellBang
 942   pager        tkRunning     ornaments
 943   signalLevel  warnLevel     dieLevel
 944   inhibit_exit ImmediateStop bareStringify
 945   CreateTTY    RemotePort    windowSize
 946   DollarCaretP
 947 );
 948
 949 @RememberOnROptions = qw(DollarCaretP);
 950
 951 =pod
 952
 953 Second, C<optionVars> lists the variables that each option uses to save its
 954 state.
 955
 956 =cut
 957
 958 use vars qw(%optionVars);
 959
 960 %optionVars = (
 961     hashDepth     => \$dumpvar::hashDepth,
 962     arrayDepth    => \$dumpvar::arrayDepth,
 963     CommandSet    => \$CommandSet,
 964     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 965     DumpPackages  => \$dumpvar::dumpPackages,
 966     DumpReused    => \$dumpvar::dumpReused,
 967     HighBit       => \$dumpvar::quoteHighBit,
 968     undefPrint    => \$dumpvar::printUndef,
 969     globPrint     => \$dumpvar::globPrint,
 970     UsageOnly     => \$dumpvar::usageOnly,
 971     CreateTTY     => \$CreateTTY,
 972     bareStringify => \$dumpvar::bareStringify,
 973     frame         => \$frame,
 974     AutoTrace     => \$trace,
 975     inhibit_exit  => \$inhibit_exit,
 976     maxTraceLen   => \$maxtrace,
 977     ImmediateStop => \$ImmediateStop,
 978     RemotePort    => \$remoteport,
 979     windowSize    => \$window,
 980     HistFile      => \$histfile,
 981     HistSize      => \$histsize,
 982 );
 983
 984 =pod
 985
 986 Third, C<%optionAction> defines the subroutine to be called to process each
 987 option.
 988
 989 =cut
 990
 991 use vars qw(%optionAction);
 992
 993 %optionAction = (
 994     compactDump   => \&dumpvar::compactDump,
 995     veryCompact   => \&dumpvar::veryCompact,
 996     quote         => \&dumpvar::quote,
 997     TTY           => \&TTY,
 998     noTTY         => \&noTTY,
 999     ReadLine      => \&ReadLine,
1000     NonStop       => \&NonStop,
1001     LineInfo      => \&LineInfo,
1002     recallCommand => \&recallCommand,
1003     ShellBang     => \&shellBang,
1004     pager         => \&pager,
1005     signalLevel   => \&signalLevel,
1006     warnLevel     => \&warnLevel,
1007     dieLevel      => \&dieLevel,
1008     tkRunning     => \&tkRunning,
1009     ornaments     => \&ornaments,
1010     RemotePort    => \&RemotePort,
1011     DollarCaretP  => \&DollarCaretP,
1012 );
1013
1014 =pod
1015
1016 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1017 option is used.
1018
1019 =cut
1020
1021 # Note that this list is not complete: several options not listed here
1022 # actually require that dumpvar.pl be loaded for them to work, but are
1023 # not in the table. A subsequent patch will correct this problem; for
1024 # the moment, we're just recommenting, and we are NOT going to change
1025 # function.
1026 use vars qw(%optionRequire);
1027
1028 %optionRequire = (
1029     compactDump => 'dumpvar.pl',
1030     veryCompact => 'dumpvar.pl',
1031     quote       => 'dumpvar.pl',
1032 );
1033
1034 =pod
1035
1036 There are a number of initialization-related variables which can be set
1037 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1038 variable. These are:
1039
1040 =over 4
1041
1042 =item C<$rl> - readline control XXX needs more explanation
1043
1044 =item C<$warnLevel> - whether or not debugger takes over warning handling
1045
1046 =item C<$dieLevel> - whether or not debugger takes over die handling
1047
1048 =item C<$signalLevel> - whether or not debugger takes over signal handling
1049
1050 =item C<$pre> - preprompt actions (array reference)
1051
1052 =item C<$post> - postprompt actions (array reference)
1053
1054 =item C<$pretype>
1055
1056 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1057
1058 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1059
1060 =back
1061
1062 =cut
1063
1064 # These guys may be defined in $ENV{PERL5DB} :
1065 $rl          = 1     unless defined $rl;
1066 $warnLevel   = 1     unless defined $warnLevel;
1067 $dieLevel    = 1     unless defined $dieLevel;
1068 $signalLevel = 1     unless defined $signalLevel;
1069 $pre         = []    unless defined $pre;
1070 $post        = []    unless defined $post;
1071 $pretype     = []    unless defined $pretype;
1072 $CreateTTY   = 3     unless defined $CreateTTY;
1073 $CommandSet  = '580' unless defined $CommandSet;
1074
1075 share($rl);
1076 share($warnLevel);
1077 share($dieLevel);
1078 share($signalLevel);
1079 share($pre);
1080 share($post);
1081 share($pretype);
1082 share($rl);
1083 share($CreateTTY);
1084 share($CommandSet);
1085
1086 =pod
1087
1088 The default C<die>, C<warn>, and C<signal> handlers are set up.
1089
1090 =cut
1091
1092 warnLevel($warnLevel);
1093 dieLevel($dieLevel);
1094 signalLevel($signalLevel);
1095
1096 =pod
1097
1098 The pager to be used is needed next. We try to get it from the
1099 environment first.  If it's not defined there, we try to find it in
1100 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1101 then call the C<pager()> function to save the pager name.
1102
1103 =cut
1104
1105 # This routine makes sure $pager is set up so that '|' can use it.
1106 pager(
1107
1108     # If PAGER is defined in the environment, use it.
1109     defined $ENV{PAGER}
1110     ? $ENV{PAGER}
1111
1112       # If not, see if Config.pm defines it.
1113     : eval { require Config }
1114       && defined $Config::Config{pager}
1115     ? $Config::Config{pager}
1116
1117       # If not, fall back to 'more'.
1118     : 'more'
1119   )
1120   unless defined $pager;
1121
1122 =pod
1123
1124 We set up the command to be used to access the man pages, the command
1125 recall character (C<!> unless otherwise defined) and the shell escape
1126 character (C<!> unless otherwise defined). Yes, these do conflict, and
1127 neither works in the debugger at the moment.
1128
1129 =cut
1130
1131 setman();
1132
1133 # Set up defaults for command recall and shell escape (note:
1134 # these currently don't work in linemode debugging).
1135 recallCommand("!") unless defined $prc;
1136 shellBang("!")     unless defined $psh;
1137
1138 =pod
1139
1140 We then set up the gigantic string containing the debugger help.
1141 We also set the limit on the number of arguments we'll display during a
1142 trace.
1143
1144 =cut
1145
1146 sethelp();
1147
1148 # If we didn't get a default for the length of eval/stack trace args,
1149 # set it here.
1150 $maxtrace = 400 unless defined $maxtrace;
1151
1152 =head2 SETTING UP THE DEBUGGER GREETING
1153
1154 The debugger I<greeting> helps to inform the user how many debuggers are
1155 running, and whether the current debugger is the primary or a child.
1156
1157 If we are the primary, we just hang onto our pid so we'll have it when
1158 or if we start a child debugger. If we are a child, we'll set things up
1159 so we'll have a unique greeting and so the parent will give us our own
1160 TTY later.
1161
1162 We save the current contents of the C<PERLDB_PIDS> environment variable
1163 because we mess around with it. We'll also need to hang onto it because
1164 we'll need it if we restart.
1165
1166 Child debuggers make a label out of the current PID structure recorded in
1167 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1168 yet so the parent will give them one later via C<resetterm()>.
1169
1170 =cut
1171
1172 # Save the current contents of the environment; we're about to
1173 # much with it. We'll need this if we have to restart.
1174 use vars qw($ini_pids);
1175 $ini_pids = $ENV{PERLDB_PIDS};
1176
1177 use vars qw ($pids $term_pid);
1178
1179 if ( defined $ENV{PERLDB_PIDS} ) {
1180
1181     # We're a child. Make us a label out of the current PID structure
1182     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1183     # a term yet so the parent will give us one later via resetterm().
1184
1185     my $env_pids = $ENV{PERLDB_PIDS};
1186     $pids = "[$env_pids]";
1187
1188     # Unless we are on OpenVMS, all programs under the DCL shell run under
1189     # the same PID.
1190
1191     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1192         $term_pid         = $$;
1193     }
1194     else {
1195         $ENV{PERLDB_PIDS} .= "->$$";
1196         $term_pid = -1;
1197     }
1198
1199 } ## end if (defined $ENV{PERLDB_PIDS...
1200 else {
1201
1202     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1203     # child debugger, and mark us as the parent, so we'll know to set up
1204     # more TTY's is we have to.
1205     $ENV{PERLDB_PIDS} = "$$";
1206     $pids             = "[pid=$$]";
1207     $term_pid         = $$;
1208 }
1209
1210 use vars qw($pidprompt);
1211 $pidprompt = '';
1212
1213 # Sets up $emacs as a synonym for $slave_editor.
1214 our ($slave_editor);
1215 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1216
1217 =head2 READING THE RC FILE
1218
1219 The debugger will read a file of initialization options if supplied. If
1220 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1221
1222 =cut
1223
1224 # As noted, this test really doesn't check accurately that the debugger
1225 # is running at a terminal or not.
1226
1227 use vars qw($rcfile);
1228 {
1229     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1230     # this is the wrong metric!
1231     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1232 }
1233
1234 =pod
1235
1236 The debugger does a safety test of the file to be read. It must be owned
1237 either by the current user or root, and must only be writable by the owner.
1238
1239 =cut
1240
1241 # This wraps a safety test around "do" to read and evaluate the init file.
1242 #
1243 # This isn't really safe, because there's a race
1244 # between checking and opening.  The solution is to
1245 # open and fstat the handle, but then you have to read and
1246 # eval the contents.  But then the silly thing gets
1247 # your lexical scope, which is unfortunate at best.
1248 sub safe_do {
1249     my $file = shift;
1250
1251     # Just exactly what part of the word "CORE::" don't you understand?
1252     local $SIG{__WARN__};
1253     local $SIG{__DIE__};
1254
1255     unless ( is_safe_file($file) ) {
1256         CORE::warn <<EO_GRIPE;
1257 perldb: Must not source insecure rcfile $file.
1258         You or the superuser must be the owner, and it must not
1259         be writable by anyone but its owner.
1260 EO_GRIPE
1261         return;
1262     } ## end unless (is_safe_file($file...
1263
1264     do $file;
1265     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1266 } ## end sub safe_do
1267
1268 # This is the safety test itself.
1269 #
1270 # Verifies that owner is either real user or superuser and that no
1271 # one but owner may write to it.  This function is of limited use
1272 # when called on a path instead of upon a handle, because there are
1273 # no guarantees that filename (by dirent) whose file (by ino) is
1274 # eventually accessed is the same as the one tested.
1275 # Assumes that the file's existence is not in doubt.
1276 sub is_safe_file {
1277     my $path = shift;
1278     stat($path) || return;    # mysteriously vaporized
1279     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1280
1281     return 0 if $uid != 0 && $uid != $<;
1282     return 0 if $mode & 022;
1283     return 1;
1284 } ## end sub is_safe_file
1285
1286 # If the rcfile (whichever one we decided was the right one to read)
1287 # exists, we safely do it.
1288 if ( -f $rcfile ) {
1289     safe_do("./$rcfile");
1290 }
1291
1292 # If there isn't one here, try the user's home directory.
1293 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1294     safe_do("$ENV{HOME}/$rcfile");
1295 }
1296
1297 # Else try the login directory.
1298 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1299     safe_do("$ENV{LOGDIR}/$rcfile");
1300 }
1301
1302 # If the PERLDB_OPTS variable has options in it, parse those out next.
1303 if ( defined $ENV{PERLDB_OPTS} ) {
1304     parse_options( $ENV{PERLDB_OPTS} );
1305 }
1306
1307 =pod
1308
1309 The last thing we do during initialization is determine which subroutine is
1310 to be used to obtain a new terminal when a new debugger is started. Right now,
1311 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1312 (darwin).
1313
1314 =cut
1315
1316 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1317 # Works if you're running an xterm or xterm-like window, or you're on
1318 # OS/2, or on Mac OS X. This may need some expansion.
1319
1320 if (not defined &get_fork_TTY)       # only if no routine exists
1321 {
1322     if ( defined $remoteport ) {
1323                                                  # Expect an inetd-like server
1324         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1325     }
1326     elsif (defined $ENV{TERM}                    # If we know what kind
1327                                                  # of terminal this is,
1328         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1329         and defined $ENV{DISPLAY}                # and what display it's on,
1330       )
1331     {
1332         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1333     }
1334     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1335         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1336     }
1337     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1338             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1339             and $ENV{TERM_PROGRAM}
1340                 eq 'Apple_Terminal'              # Terminal.app
1341             )
1342     {
1343         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1344     }
1345 } ## end if (not defined &get_fork_TTY...
1346
1347 # untaint $^O, which may have been tainted by the last statement.
1348 # see bug [perl #24674]
1349 $^O =~ m/^(.*)\z/;
1350 $^O = $1;
1351
1352 # Here begin the unreadable code.  It needs fixing.
1353
1354 =head2 RESTART PROCESSING
1355
1356 This section handles the restart command. When the C<R> command is invoked, it
1357 tries to capture all of the state it can into environment variables, and
1358 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1359 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1360 the R command stuffed into the environment variables.
1361
1362   PERLDB_RESTART   - flag only, contains no restart data itself.
1363   PERLDB_HIST      - command history, if it's available
1364   PERLDB_ON_LOAD   - breakpoints set by the rc file
1365   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1366   PERLDB_VISITED   - files that had breakpoints
1367   PERLDB_FILE_...  - breakpoints for a file
1368   PERLDB_OPT       - active options
1369   PERLDB_INC       - the original @INC
1370   PERLDB_PRETYPE   - preprompt debugger actions
1371   PERLDB_PRE       - preprompt Perl code
1372   PERLDB_POST      - post-prompt Perl code
1373   PERLDB_TYPEAHEAD - typeahead captured by readline()
1374
1375 We chug through all these variables and plug the values saved in them
1376 back into the appropriate spots in the debugger.
1377
1378 =cut
1379
1380 use vars qw(%postponed_file @typeahead);
1381
1382 our (@hist, @truehist);
1383
1384 sub _restore_shared_globals_after_restart
1385 {
1386     @hist          = get_list('PERLDB_HIST');
1387     %break_on_load = get_list("PERLDB_ON_LOAD");
1388     %postponed     = get_list("PERLDB_POSTPONE");
1389
1390     share(@hist);
1391     share(@truehist);
1392     share(%break_on_load);
1393     share(%postponed);
1394 }
1395
1396 sub _restore_breakpoints_and_actions {
1397
1398     my @had_breakpoints = get_list("PERLDB_VISITED");
1399
1400     for my $file_idx ( 0 .. $#had_breakpoints ) {
1401         my $filename = $had_breakpoints[$file_idx];
1402         my %pf = get_list("PERLDB_FILE_$file_idx");
1403         $postponed_file{ $filename } = \%pf if %pf;
1404         my @lines = sort {$a <=> $b} keys(%pf);
1405         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1406         for my $line_idx (0 .. $#lines) {
1407             _set_breakpoint_enabled_status(
1408                 $filename,
1409                 $lines[$line_idx],
1410                 ($enabled_statuses[$line_idx] ? 1 : ''),
1411             );
1412         }
1413     }
1414
1415     return;
1416 }
1417
1418 sub _restore_options_after_restart
1419 {
1420     my %options_map = get_list("PERLDB_OPT");
1421
1422     while ( my ( $opt, $val ) = each %options_map ) {
1423         $val =~ s/[\\\']/\\$1/g;
1424         parse_options("$opt'$val'");
1425     }
1426
1427     return;
1428 }
1429
1430 sub _restore_globals_after_restart
1431 {
1432     # restore original @INC
1433     @INC     = get_list("PERLDB_INC");
1434     @ini_INC = @INC;
1435
1436     # return pre/postprompt actions and typeahead buffer
1437     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1438     $pre       = [ get_list("PERLDB_PRE") ];
1439     $post      = [ get_list("PERLDB_POST") ];
1440     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1441
1442     return;
1443 }
1444
1445
1446 if ( exists $ENV{PERLDB_RESTART} ) {
1447
1448     # We're restarting, so we don't need the flag that says to restart anymore.
1449     delete $ENV{PERLDB_RESTART};
1450
1451     # $restart = 1;
1452     _restore_shared_globals_after_restart();
1453
1454     _restore_breakpoints_and_actions();
1455
1456     # restore options
1457     _restore_options_after_restart();
1458
1459     _restore_globals_after_restart();
1460 } ## end if (exists $ENV{PERLDB_RESTART...
1461
1462 =head2 SETTING UP THE TERMINAL
1463
1464 Now, we'll decide how the debugger is going to interact with the user.
1465 If there's no TTY, we set the debugger to run non-stop; there's not going
1466 to be anyone there to enter commands.
1467
1468 =cut
1469
1470 use vars qw($notty $console $tty $LINEINFO);
1471 use vars qw($lineinfo $doccmd);
1472
1473 our ($runnonstop);
1474
1475 if ($notty) {
1476     $runnonstop = 1;
1477     share($runnonstop);
1478 }
1479
1480 =pod
1481
1482 If there is a TTY, we have to determine who it belongs to before we can
1483 proceed. If this is a slave editor or graphical debugger (denoted by
1484 the first command-line switch being '-emacs'), we shift this off and
1485 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1486
1487 =cut
1488
1489 else {
1490
1491     # Is Perl being run from a slave editor or graphical debugger?
1492     # If so, don't use readline, and set $slave_editor = 1.
1493     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1494         $rl = 0;
1495         shift(@main::ARGV);
1496     }
1497
1498     #require Term::ReadLine;
1499
1500 =pod
1501
1502 We then determine what the console should be on various systems:
1503
1504 =over 4
1505
1506 =item * Cygwin - We use C<stdin> instead of a separate device.
1507
1508 =cut
1509
1510     if ( $^O eq 'cygwin' ) {
1511
1512         # /dev/tty is binary. use stdin for textmode
1513         undef $console;
1514     }
1515
1516 =item * Unix - use C</dev/tty>.
1517
1518 =cut
1519
1520     elsif ( -e "/dev/tty" ) {
1521         $console = "/dev/tty";
1522     }
1523
1524 =item * Windows or MSDOS - use C<con>.
1525
1526 =cut
1527
1528     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1529         $console = "con";
1530     }
1531
1532 =item * VMS - use C<sys$command>.
1533
1534 =cut
1535
1536     else {
1537
1538         # everything else is ...
1539         $console = "sys\$command";
1540     }
1541
1542 =pod
1543
1544 =back
1545
1546 Several other systems don't use a specific console. We C<undef $console>
1547 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1548 with a slave editor).
1549
1550 =cut
1551
1552     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1553
1554         # /dev/tty is binary. use stdin for textmode
1555         $console = undef;
1556     }
1557
1558     if ( $^O eq 'NetWare' ) {
1559
1560         # /dev/tty is binary. use stdin for textmode
1561         $console = undef;
1562     }
1563
1564     # In OS/2, we need to use STDIN to get textmode too, even though
1565     # it pretty much looks like Unix otherwise.
1566     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1567     {    # In OS/2
1568         $console = undef;
1569     }
1570
1571 =pod
1572
1573 If there is a TTY hanging around from a parent, we use that as the console.
1574
1575 =cut
1576
1577     $console = $tty if defined $tty;
1578
1579 =head2 SOCKET HANDLING
1580
1581 The debugger is capable of opening a socket and carrying out a debugging
1582 session over the socket.
1583
1584 If C<RemotePort> was defined in the options, the debugger assumes that it
1585 should try to start a debugging session on that port. It builds the socket
1586 and then tries to connect the input and output filehandles to it.
1587
1588 =cut
1589
1590     # Handle socket stuff.
1591
1592     if ( defined $remoteport ) {
1593
1594         # If RemotePort was defined in the options, connect input and output
1595         # to the socket.
1596         $IN = $OUT = connect_remoteport();
1597     } ## end if (defined $remoteport)
1598
1599 =pod
1600
1601 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1602 this is probably a situation where multiple debuggers are running (for example,
1603 a backticked command that starts up another debugger). We create a new IN and
1604 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1605 and if we can.
1606
1607 =cut
1608
1609     # Non-socket.
1610     else {
1611
1612         # Two debuggers running (probably a system or a backtick that invokes
1613         # the debugger itself under the running one). create a new IN and OUT
1614         # filehandle, and do the necessary mojo to create a new tty if we
1615         # know how, and we can.
1616         create_IN_OUT(4) if $CreateTTY & 4;
1617         if ($console) {
1618
1619             # If we have a console, check to see if there are separate ins and
1620             # outs to open. (They are assumed identical if not.)
1621
1622             my ( $i, $o ) = split /,/, $console;
1623             $o = $i unless defined $o;
1624
1625             # read/write on in, or just read, or read on STDIN.
1626             open( IN,      "+<$i" )
1627               || open( IN, "<$i" )
1628               || open( IN, "<&STDIN" );
1629
1630             # read/write/create/clobber out, or write/create/clobber out,
1631             # or merge with STDERR, or merge with STDOUT.
1632                  open( OUT, "+>$o" )
1633               || open( OUT, ">$o" )
1634               || open( OUT, ">&STDERR" )
1635               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1636
1637         } ## end if ($console)
1638         elsif ( not defined $console ) {
1639
1640             # No console. Open STDIN.
1641             open( IN, "<&STDIN" );
1642
1643             # merge with STDERR, or with STDOUT.
1644             open( OUT,      ">&STDERR" )
1645               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1646             $console = 'STDIN/OUT';
1647         } ## end elsif (not defined $console)
1648
1649         # Keep copies of the filehandles so that when the pager runs, it
1650         # can close standard input without clobbering ours.
1651         if ($console or (not defined($console))) {
1652             $IN = \*IN;
1653             $OUT = \*OUT;
1654         }
1655     } ## end elsif (from if(defined $remoteport))
1656
1657     # Unbuffer DB::OUT. We need to see responses right away.
1658     $OUT->autoflush(1);
1659
1660     # Line info goes to debugger output unless pointed elsewhere.
1661     # Pointing elsewhere makes it possible for slave editors to
1662     # keep track of file and position. We have both a filehandle
1663     # and a I/O description to keep track of.
1664     $LINEINFO = $OUT     unless defined $LINEINFO;
1665     $lineinfo = $console unless defined $lineinfo;
1666     # share($LINEINFO); # <- unable to share globs
1667     share($lineinfo);   #
1668
1669 =pod
1670
1671 To finish initialization, we show the debugger greeting,
1672 and then call the C<afterinit()> subroutine if there is one.
1673
1674 =cut
1675
1676     # Show the debugger greeting.
1677     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1678     unless ($runnonstop) {
1679         local $\ = '';
1680         local $, = '';
1681         if ( $term_pid eq '-1' ) {
1682             print $OUT "\nDaughter DB session started...\n";
1683         }
1684         else {
1685             print $OUT "\nLoading DB routines from $header\n";
1686             print $OUT (
1687                 "Editor support ",
1688                 $slave_editor ? "enabled" : "available", ".\n"
1689             );
1690             print $OUT
1691 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1692         } ## end else [ if ($term_pid eq '-1')
1693     } ## end unless ($runnonstop)
1694 } ## end else [ if ($notty)
1695
1696 # XXX This looks like a bug to me.
1697 # Why copy to @ARGS and then futz with @args?
1698 @ARGS = @ARGV;
1699 # for (@args) {
1700     # Make sure backslashes before single quotes are stripped out, and
1701     # keep args unless they are numeric (XXX why?)
1702     # s/\'/\\\'/g;                      # removed while not justified understandably
1703     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1704 # }
1705
1706 # If there was an afterinit() sub defined, call it. It will get
1707 # executed in our scope, so it can fiddle with debugger globals.
1708 if ( defined &afterinit ) {    # May be defined in $rcfile
1709     afterinit();
1710 }
1711
1712 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1713 use vars qw($I_m_init);
1714
1715 $I_m_init = 1;
1716
1717 ############################################################ Subroutines
1718
1719 =head1 SUBROUTINES
1720
1721 =head2 DB
1722
1723 This gigantic subroutine is the heart of the debugger. Called before every
1724 statement, its job is to determine if a breakpoint has been reached, and
1725 stop if so; read commands from the user, parse them, and execute
1726 them, and then send execution off to the next statement.
1727
1728 Note that the order in which the commands are processed is very important;
1729 some commands earlier in the loop will actually alter the C<$cmd> variable
1730 to create other commands to be executed later. This is all highly I<optimized>
1731 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1732 see what's happening in any given command.
1733
1734 =cut
1735
1736 # $cmd cannot be an our() variable unfortunately (possible perl bug?).
1737
1738 use vars qw(
1739     $action
1740     $cmd
1741     $file
1742     $filename_ini
1743     $finished
1744     %had_breakpoints
1745     $level
1746     $max
1747     $package
1748     $try
1749 );
1750
1751 our (
1752     %alias,
1753     $doret,
1754     $end,
1755     $fall_off_end,
1756     $incr,
1757     $laststep,
1758     $rc,
1759     $sh,
1760     $stack_depth,
1761     @stack,
1762     @to_watch,
1763     @old_watch,
1764 );
1765
1766 sub _DB__determine_if_we_should_break
1767 {
1768     # if we have something here, see if we should break.
1769     # $stop is lexical and local to this block - $action on the other hand
1770     # is global.
1771     my $stop;
1772
1773     if ( $dbline{$line}
1774         && _is_breakpoint_enabled($filename, $line)
1775         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1776     {
1777
1778         # Stop if the stop criterion says to just stop.
1779         if ( $stop eq '1' ) {
1780             $signal |= 1;
1781         }
1782
1783         # It's a conditional stop; eval it in the user's context and
1784         # see if we should stop. If so, remove the one-time sigil.
1785         elsif ($stop) {
1786             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1787             DB::eval();
1788             # If the breakpoint is temporary, then delete its enabled status.
1789             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1790                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1791             }
1792         }
1793     } ## end if ($dbline{$line} && ...
1794 }
1795
1796 sub _DB__is_finished {
1797     if ($finished and $level <= 1) {
1798         end_report();
1799         return 1;
1800     }
1801     else {
1802         return;
1803     }
1804 }
1805
1806 sub _DB__read_next_cmd
1807 {
1808     my ($tid) = @_;
1809
1810     # We have a terminal, or can get one ...
1811     if (!$term) {
1812         setterm();
1813     }
1814
1815     # ... and it belogs to this PID or we get one for this PID ...
1816     if ($term_pid != $$) {
1817         resetterm(1);
1818     }
1819
1820     # ... and we got a line of command input ...
1821     $cmd = DB::readline(
1822         "$pidprompt $tid DB"
1823         . ( '<' x $level )
1824         . ( $#hist + 1 )
1825         . ( '>' x $level ) . " "
1826     );
1827
1828     return defined($cmd);
1829 }
1830
1831 sub _DB__trim_command_and_return_first_component {
1832     my ($obj) = @_;
1833
1834     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1835     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1836
1837     my ($verb, $args) = $cmd =~ m{\A(\S*)\s*(.*)}s;
1838
1839     $obj->cmd_verb($verb);
1840     $obj->cmd_args($args);
1841
1842     return;
1843 }
1844
1845 sub _DB__handle_f_command {
1846     my ($obj) = @_;
1847
1848     if ($file = $obj->cmd_args) {
1849         # help for no arguments (old-style was return from sub).
1850         if ( !$file ) {
1851             print $OUT
1852             "The old f command is now the r command.\n";    # hint
1853             print $OUT "The new f command switches filenames.\n";
1854             next CMD;
1855         } ## end if (!$file)
1856
1857         # if not in magic file list, try a close match.
1858         if ( !defined $main::{ '_<' . $file } ) {
1859             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1860                 {
1861                     $try = substr( $try, 2 );
1862                     print $OUT "Choosing $try matching '$file':\n";
1863                     $file = $try;
1864                 }
1865             } ## end if (($try) = grep(m#^_<.*$file#...
1866         } ## end if (!defined $main::{ ...
1867
1868         # If not successfully switched now, we failed.
1869         if ( !defined $main::{ '_<' . $file } ) {
1870             print $OUT "No file matching '$file' is loaded.\n";
1871             next CMD;
1872         }
1873
1874         # We switched, so switch the debugger internals around.
1875         elsif ( $file ne $filename ) {
1876             *dbline   = $main::{ '_<' . $file };
1877             $max      = $#dbline;
1878             $filename = $file;
1879             $start    = 1;
1880             $cmd      = "l";
1881         } ## end elsif ($file ne $filename)
1882
1883         # We didn't switch; say we didn't.
1884         else {
1885             print $OUT "Already in $file.\n";
1886             next CMD;
1887         }
1888     }
1889
1890     return;
1891 }
1892
1893 sub _DB__handle_dot_command {
1894     my ($obj) = @_;
1895
1896     # . command.
1897     if ($obj->_is_full('.')) {
1898         $incr = -1;    # stay at current line
1899
1900         # Reset everything to the old location.
1901         $start    = $line;
1902         $filename = $filename_ini;
1903         *dbline   = $main::{ '_<' . $filename };
1904         $max      = $#dbline;
1905
1906         # Now where are we?
1907         print_lineinfo($obj->position());
1908         next CMD;
1909     }
1910
1911     return;
1912 }
1913
1914 sub _DB__handle_y_command {
1915     my ($obj) = @_;
1916
1917     if (my ($match_level, $match_vars)
1918         = $obj->cmd_args =~ /\A(?:(\d*)\s*(.*))?\z/) {
1919
1920         # See if we've got the necessary support.
1921         if (!eval { require PadWalker; PadWalker->VERSION(0.08) }) {
1922             my $Err = $@;
1923             _db_warn(
1924                 $Err =~ /locate/
1925                 ? "PadWalker module not found - please install\n"
1926                 : $Err
1927             );
1928             next CMD;
1929         }
1930
1931         # Load up dumpvar if we don't have it. If we can, that is.
1932         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
1933         defined &main::dumpvar
1934             or print $OUT "dumpvar.pl not available.\n"
1935             and next CMD;
1936
1937         # Got all the modules we need. Find them and print them.
1938         my @vars = split( ' ', $match_vars || '' );
1939
1940         # Find the pad.
1941         my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
1942
1943         # Oops. Can't find it.
1944         if (my $Err = $@) {
1945             $Err =~ s/ at .*//;
1946             _db_warn($Err);
1947             next CMD;
1948         }
1949
1950         # Show the desired vars with dumplex().
1951         my $savout = select($OUT);
1952
1953         # Have dumplex dump the lexicals.
1954         foreach my $key (sort keys %$h) {
1955             dumpvar::dumplex( $key, $h->{$key},
1956                 defined $option{dumpDepth} ? $option{dumpDepth} : -1,
1957                 @vars );
1958         }
1959         select($savout);
1960         next CMD;
1961     }
1962 }
1963
1964 sub _DB__handle_c_command {
1965     my ($obj) = @_;
1966
1967     my $i = $obj->cmd_args;
1968
1969     if ($i =~ m#\A[\w:]*\z#) {
1970
1971         # Hey, show's over. The debugged program finished
1972         # executing already.
1973         next CMD if _DB__is_finished();
1974
1975         # Capture the place to put a one-time break.
1976         $subname = $i;
1977
1978         #  Probably not needed, since we finish an interactive
1979         #  sub-session anyway...
1980         # local $filename = $filename;
1981         # local *dbline = *dbline; # XXX Would this work?!
1982         #
1983         # The above question wonders if localizing the alias
1984         # to the magic array works or not. Since it's commented
1985         # out, we'll just leave that to speculation for now.
1986
1987         # If the "subname" isn't all digits, we'll assume it
1988         # is a subroutine name, and try to find it.
1989         if ( $subname =~ /\D/ ) {    # subroutine name
1990             # Qualify it to the current package unless it's
1991             # already qualified.
1992             $subname = $package . "::" . $subname
1993             unless $subname =~ /::/;
1994
1995             # find_sub will return "file:line_number" corresponding
1996             # to where the subroutine is defined; we call find_sub,
1997             # break up the return value, and assign it in one
1998             # operation.
1999             ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2000
2001             # Force the line number to be numeric.
2002             $i = $i + 0;
2003
2004             # If we got a line number, we found the sub.
2005             if ($i) {
2006
2007                 # Switch all the debugger's internals around so
2008                 # we're actually working with that file.
2009                 $filename = $file;
2010                 *dbline   = $main::{ '_<' . $filename };
2011
2012                 # Mark that there's a breakpoint in this file.
2013                 $had_breakpoints{$filename} |= 1;
2014
2015                 # Scan forward to the first executable line
2016                 # after the 'sub whatever' line.
2017                 $max = $#dbline;
2018                 my $_line_num = $i;
2019                 while ($dbline[$_line_num] == 0 && $_line_num< $max)
2020                 {
2021                     $_line_num++;
2022                 }
2023                 $i = $_line_num;
2024             } ## end if ($i)
2025
2026             # We didn't find a sub by that name.
2027             else {
2028                 print $OUT "Subroutine $subname not found.\n";
2029                 next CMD;
2030             }
2031         } ## end if ($subname =~ /\D/)
2032
2033         # At this point, either the subname was all digits (an
2034         # absolute line-break request) or we've scanned through
2035         # the code following the definition of the sub, looking
2036         # for an executable, which we may or may not have found.
2037         #
2038         # If $i (which we set $subname from) is non-zero, we
2039         # got a request to break at some line somewhere. On
2040         # one hand, if there wasn't any real subroutine name
2041         # involved, this will be a request to break in the current
2042         # file at the specified line, so we have to check to make
2043         # sure that the line specified really is breakable.
2044         #
2045         # On the other hand, if there was a subname supplied, the
2046         # preceding block has moved us to the proper file and
2047         # location within that file, and then scanned forward
2048         # looking for the next executable line. We have to make
2049         # sure that one was found.
2050         #
2051         # On the gripping hand, we can't do anything unless the
2052         # current value of $i points to a valid breakable line.
2053         # Check that.
2054         if ($i) {
2055
2056             # Breakable?
2057             if ( $dbline[$i] == 0 ) {
2058                 print $OUT "Line $i not breakable.\n";
2059                 next CMD;
2060             }
2061
2062             # Yes. Set up the one-time-break sigil.
2063             $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2064             _enable_breakpoint_temp_enabled_status($filename, $i);
2065         } ## end if ($i)
2066
2067         # Turn off stack tracing from here up.
2068         for my $j (0 .. $stack_depth) {
2069             $stack[ $j ] &= ~1;
2070         }
2071         last CMD;
2072     }
2073
2074     return;
2075 }
2076
2077 sub _DB__handle_forward_slash_command {
2078     my ($obj) = @_;
2079
2080     # The pattern as a string.
2081     use vars qw($inpat);
2082
2083     if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2084
2085         # Remove the final slash.
2086         $inpat =~ s:([^\\])/$:$1:;
2087
2088         # If the pattern isn't null ...
2089         if ( $inpat ne "" ) {
2090
2091             # Turn of warn and die procesing for a bit.
2092             local $SIG{__DIE__};
2093             local $SIG{__WARN__};
2094
2095             # Create the pattern.
2096             eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2097             if ( $@ ne "" ) {
2098
2099                 # Oops. Bad pattern. No biscuit.
2100                 # Print the eval error and go back for more
2101                 # commands.
2102                 print $OUT "$@";
2103                 next CMD;
2104             }
2105             $obj->pat($inpat);
2106         } ## end if ($inpat ne "")
2107
2108         # Set up to stop on wrap-around.
2109         $end = $start;
2110
2111         # Don't move off the current line.
2112         $incr = -1;
2113
2114         my $pat = $obj->pat;
2115
2116         # Done in eval so nothing breaks if the pattern
2117         # does something weird.
2118         eval
2119         {
2120             no strict q/vars/;
2121             for (;;) {
2122                 # Move ahead one line.
2123                 ++$start;
2124
2125                 # Wrap if we pass the last line.
2126                 $start = 1 if ($start > $max);
2127
2128                 # Stop if we have gotten back to this line again,
2129                 last if ($start == $end);
2130
2131                 # A hit! (Note, though, that we are doing
2132                 # case-insensitive matching. Maybe a qr//
2133                 # expression would be better, so the user could
2134                 # do case-sensitive matching if desired.
2135                 if ($dbline[$start] =~ m/$pat/i) {
2136                     if ($slave_editor) {
2137                         # Handle proper escaping in the slave.
2138                         print $OUT "\032\032$filename:$start:0\n";
2139                     }
2140                     else {
2141                         # Just print the line normally.
2142                         print $OUT "$start:\t",$dbline[$start],"\n";
2143                     }
2144                     # And quit since we found something.
2145                     last;
2146                 }
2147             }
2148         };
2149
2150         if ($@) {
2151             warn $@;
2152         }
2153
2154         # If we wrapped, there never was a match.
2155         if ( $start == $end ) {
2156             print {$OUT} "/$pat/: not found\n";
2157         }
2158         next CMD;
2159     }
2160
2161     return;
2162 }
2163
2164 sub _DB__handle_question_mark_command {
2165     my ($obj) = @_;
2166
2167     # ? - backward pattern search.
2168     if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2169
2170         # Get the pattern, remove trailing question mark.
2171         $inpat =~ s:([^\\])\?$:$1:;
2172
2173         # If we've got one ...
2174         if ( $inpat ne "" ) {
2175
2176             # Turn off die & warn handlers.
2177             local $SIG{__DIE__};
2178             local $SIG{__WARN__};
2179             eval '$inpat =~ m' . "\a$inpat\a";
2180
2181             if ( $@ ne "" ) {
2182
2183                 # Ouch. Not good. Print the error.
2184                 print $OUT $@;
2185                 next CMD;
2186             }
2187             $obj->pat($inpat);
2188         } ## end if ($inpat ne "")
2189
2190         # Where we are now is where to stop after wraparound.
2191         $end = $start;
2192
2193         # Don't move away from this line.
2194         $incr = -1;
2195
2196         my $pat = $obj->pat;
2197         # Search inside the eval to prevent pattern badness
2198         # from killing us.
2199         eval {
2200             no strict q/vars/;
2201             for (;;) {
2202                 # Back up a line.
2203                 --$start;
2204
2205                 # Wrap if we pass the first line.
2206
2207                 $start = $max if ($start <= 0);
2208
2209                 # Quit if we get back where we started,
2210                 last if ($start == $end);
2211
2212                 # Match?
2213                 if ($dbline[$start] =~ m/$pat/i) {
2214                     if ($slave_editor) {
2215                         # Yep, follow slave editor requirements.
2216                         print $OUT "\032\032$filename:$start:0\n";
2217                     }
2218                     else {
2219                         # Yep, just print normally.
2220                         print $OUT "$start:\t",$dbline[$start],"\n";
2221                     }
2222
2223                     # Found, so done.
2224                     last;
2225                 }
2226             }
2227         };
2228
2229         # Say we failed if the loop never found anything,
2230         if ( $start == $end ) {
2231             print {$OUT} "?$pat?: not found\n";
2232         }
2233         next CMD;
2234     }
2235
2236     return;
2237 }
2238
2239 sub _DB__handle_restart_and_rerun_commands {
2240     my ($obj) = @_;
2241
2242     my $cmd_cmd = $obj->cmd_verb;
2243     my $cmd_params = $obj->cmd_args;
2244     # R - restart execution.
2245     # rerun - controlled restart execution.
2246     if ($cmd_cmd eq 'rerun' or $cmd_params eq '') {
2247         my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
2248
2249         # Close all non-system fds for a clean restart.  A more
2250         # correct method would be to close all fds that were not
2251         # open when the process started, but this seems to be
2252         # hard.  See "debugger 'R'estart and open database
2253         # connections" on p5p.
2254
2255         my $max_fd = 1024; # default if POSIX can't be loaded
2256         if (eval { require POSIX }) {
2257             eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
2258         }
2259
2260         if (defined $max_fd) {
2261             foreach ($^F+1 .. $max_fd-1) {
2262                 next unless open FD_TO_CLOSE, "<&=$_";
2263                 close(FD_TO_CLOSE);
2264             }
2265         }
2266
2267         # And run Perl again.  We use exec() to keep the
2268         # PID stable (and that way $ini_pids is still valid).
2269         exec(@args) or print {$OUT} "exec failed: $!\n";
2270
2271         last CMD;
2272     }
2273
2274     return;
2275 }
2276
2277 sub _DB__handle_run_command_in_pager_command {
2278     my ($obj) = @_;
2279
2280     if ($cmd =~ m#\A\|\|?\s*[^|]#) {
2281         if ( $pager =~ /^\|/ ) {
2282
2283             # Default pager is into a pipe. Redirect I/O.
2284             open( SAVEOUT, ">&STDOUT" )
2285             || _db_warn("Can't save STDOUT");
2286             open( STDOUT, ">&OUT" )
2287             || _db_warn("Can't redirect STDOUT");
2288         } ## end if ($pager =~ /^\|/)
2289         else {
2290
2291             # Not into a pipe. STDOUT is safe.
2292             open( SAVEOUT, ">&OUT" ) || _db_warn("Can't save DB::OUT");
2293         }
2294
2295         # Fix up environment to record we have less if so.
2296         fix_less();
2297
2298         unless ( $obj->piped(scalar ( open( OUT, $pager ) ) ) ) {
2299
2300             # Couldn't open pipe to pager.
2301             _db_warn("Can't pipe output to '$pager'");
2302             if ( $pager =~ /^\|/ ) {
2303
2304                 # Redirect I/O back again.
2305                 open( OUT, ">&STDOUT" )    # XXX: lost message
2306                 || _db_warn("Can't restore DB::OUT");
2307                 open( STDOUT, ">&SAVEOUT" )
2308                 || _db_warn("Can't restore STDOUT");
2309                 close(SAVEOUT);
2310             } ## end if ($pager =~ /^\|/)
2311             else {
2312
2313                 # Redirect I/O. STDOUT already safe.
2314                 open( OUT, ">&STDOUT" )    # XXX: lost message
2315                 || _db_warn("Can't restore DB::OUT");
2316             }
2317             next CMD;
2318         } ## end unless ($piped = open(OUT,...
2319
2320         # Set up broken-pipe handler if necessary.
2321         $SIG{PIPE} = \&DB::catch
2322         if $pager =~ /^\|/
2323         && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
2324
2325         OUT->autoflush(1);
2326         # Save current filehandle, and put it back.
2327         $obj->selected(scalar( select(OUT) ));
2328         # Don't put it back if pager was a pipe.
2329         if ($cmd !~ /\A\|\|/)
2330         {
2331             select($obj->selected());
2332             $obj->selected("");
2333         }
2334
2335         # Trim off the pipe symbols and run the command now.
2336         $cmd =~ s#\A\|+\s*##;
2337         redo PIPE;
2338     }
2339
2340     return;
2341 }
2342
2343 sub _DB__handle_m_command {
2344     my ($obj) = @_;
2345
2346     if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2347         methods($1);
2348         next CMD;
2349     }
2350
2351     # m expr - set up DB::eval to do the work
2352     if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2353         $onetimeDump = 'methods';   #  method output gets used there
2354     }
2355
2356     return;
2357 }
2358
2359 sub _DB__at_end_of_every_command {
2360     my ($obj) = @_;
2361
2362     # At the end of every command:
2363     if ($obj->piped) {
2364
2365         # Unhook the pipe mechanism now.
2366         if ( $pager =~ /^\|/ ) {
2367
2368             # No error from the child.
2369             $? = 0;
2370
2371             # we cannot warn here: the handle is missing --tchrist
2372             close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
2373
2374             # most of the $? crud was coping with broken cshisms
2375             # $? is explicitly set to 0, so this never runs.
2376             if ($?) {
2377                 print SAVEOUT "Pager '$pager' failed: ";
2378                 if ( $? == -1 ) {
2379                     print SAVEOUT "shell returned -1\n";
2380                 }
2381                 elsif ( $? >> 8 ) {
2382                     print SAVEOUT ( $? & 127 )
2383                     ? " (SIG#" . ( $? & 127 ) . ")"
2384                     : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
2385                 }
2386                 else {
2387                     print SAVEOUT "status ", ( $? >> 8 ), "\n";
2388                 }
2389             } ## end if ($?)
2390
2391             # Reopen filehandle for our output (if we can) and
2392             # restore STDOUT (if we can).
2393             open( OUT, ">&STDOUT" ) || _db_warn("Can't restore DB::OUT");
2394             open( STDOUT, ">&SAVEOUT" )
2395             || _db_warn("Can't restore STDOUT");
2396
2397             # Turn off pipe exception handler if necessary.
2398             $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
2399
2400             # Will stop ignoring SIGPIPE if done like nohup(1)
2401             # does SIGINT but Perl doesn't give us a choice.
2402         } ## end if ($pager =~ /^\|/)
2403         else {
2404
2405             # Non-piped "pager". Just restore STDOUT.
2406             open( OUT, ">&SAVEOUT" ) || _db_warn("Can't restore DB::OUT");
2407         }
2408
2409         # Close filehandle pager was using, restore the normal one
2410         # if necessary,
2411         close(SAVEOUT);
2412
2413         if ($obj->selected() ne "") {
2414             select($obj->selected);
2415             $obj->selected("");
2416         }
2417
2418         # No pipes now.
2419         $obj->piped("");
2420     } ## end if ($piped)
2421
2422     return;
2423 }
2424
2425 # 't' is type.
2426 # 'm' is method.
2427 # 'v' is the value (i.e: method name or subroutine ref).
2428 # 's' is subroutine.
2429 my %cmd_lookup =
2430 (
2431     '-' => { t => 'm', v => '_handle_dash_command', },
2432     '.' => { t => 's', v => \&_DB__handle_dot_command, },
2433     '=' => { t => 'm', v => '_handle_equal_sign_command', },
2434     'H' => { t => 'm', v => '_handle_H_command', },
2435     'S' => { t => 'm', v => '_handle_S_command', },
2436     'T' => { t => 'm', v => '_handle_T_command', },
2437     'W' => { t => 'm', v => '_handle_W_command', },
2438     'c' => { t => 's', v => \&_DB__handle_c_command, },
2439     'f' => { t => 's', v => \&_DB__handle_f_command, },
2440     'm' => { t => 's', v => \&_DB__handle_m_command, },
2441     'n' => { t => 'm', v => '_handle_n_command', },
2442     'p' => { t => 'm', v => '_handle_p_command', },
2443     'q' => { t => 'm', v => '_handle_q_command', },
2444     'r' => { t => 'm', v => '_handle_r_command', },
2445     's' => { t => 'm', v => '_handle_s_command', },
2446     'save' => { t => 'm', v => '_handle_save_command', },
2447     'source' => { t => 'm', v => '_handle_source_command', },
2448     't' => { t => 'm', v => '_handle_t_command', },
2449     'w' => { t => 'm', v => '_handle_w_command', },
2450     'x' => { t => 'm', v => '_handle_x_command', },
2451     'y' => { t => 's', v => \&_DB__handle_y_command, },
2452     (map { $_ => { t => 'm', v => '_handle_V_command_and_X_command', }, }
2453         ('X', 'V')),
2454     (map { $_ => { t => 'm', v => '_handle_enable_disable_commands', }, }
2455         qw(enable disable)),
2456     (map { $_ =>
2457         { t => 's', v => \&_DB__handle_restart_and_rerun_commands, },
2458         } qw(R rerun)),
2459     (map { $_ => {t => 'm', v => '_handle_cmd_wrapper_commands' }, }
2460     qw(a A b B e E h i l L M o O P v w W)),
2461 );
2462
2463 sub DB {
2464
2465     # lock the debugger and get the thread id for the prompt
2466     lock($DBGR);
2467     my $tid;
2468     my $position;
2469     my ($prefix, $after, $infix);
2470     my $pat;
2471     my $explicit_stop;
2472     my $piped;
2473     my $selected;
2474
2475     if ($ENV{PERL5DB_THREADED}) {
2476         $tid = eval { "[".threads->tid."]" };
2477     }
2478
2479     my $cmd_verb;
2480     my $cmd_args;
2481
2482     my $obj = DB::Obj->new(
2483         {
2484             position => \$position,
2485             prefix => \$prefix,
2486             after => \$after,
2487             explicit_stop => \$explicit_stop,
2488             infix => \$infix,
2489             cmd_args => \$cmd_args,
2490             cmd_verb => \$cmd_verb,
2491             pat => \$pat,
2492             piped => \$piped,
2493             selected => \$selected,
2494         },
2495     );
2496
2497     $obj->_DB_on_init__initialize_globals(@_);
2498
2499     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
2500     # The code being debugged may have altered them.
2501     DB::save();
2502
2503     # Since DB::DB gets called after every line, we can use caller() to
2504     # figure out where we last were executing. Sneaky, eh? This works because
2505     # caller is returning all the extra information when called from the
2506     # debugger.
2507     local ( $package, $filename, $line ) = caller;
2508     $filename_ini = $filename;
2509
2510     # set up the context for DB::eval, so it can properly execute
2511     # code on behalf of the user. We add the package in so that the
2512     # code is eval'ed in the proper package (not in the debugger!).
2513     local $usercontext = _calc_usercontext($package);
2514
2515     # Create an alias to the active file magical array to simplify
2516     # the code here.
2517     local (*dbline) = $main::{ '_<' . $filename };
2518
2519     # Last line in the program.
2520     $max = $#dbline;
2521
2522     _DB__determine_if_we_should_break(@_);
2523
2524     # Preserve the current stop-or-not, and see if any of the W
2525     # (watch expressions) has changed.
2526     my $was_signal = $signal;
2527
2528     # If we have any watch expressions ...
2529     $obj->_DB__handle_watch_expressions(@_);
2530
2531 =head2 C<watchfunction()>
2532
2533 C<watchfunction()> is a function that can be defined by the user; it is a
2534 function which will be run on each entry to C<DB::DB>; it gets the
2535 current package, filename, and line as its parameters.
2536
2537 The watchfunction can do anything it likes; it is executing in the
2538 debugger's context, so it has access to all of the debugger's internal
2539 data structures and functions.
2540
2541 C<watchfunction()> can control the debugger's actions. Any of the following
2542 will cause the debugger to return control to the user's program after
2543 C<watchfunction()> executes:
2544
2545 =over 4
2546
2547 =item *
2548
2549 Returning a false value from the C<watchfunction()> itself.
2550
2551 =item *
2552
2553 Altering C<$single> to a false value.
2554
2555 =item *
2556
2557 Altering C<$signal> to a false value.
2558
2559 =item *
2560
2561 Turning off the C<4> bit in C<$trace> (this also disables the
2562 check for C<watchfunction()>. This can be done with
2563
2564     $trace &= ~4;
2565
2566 =back
2567
2568 =cut
2569
2570     # If there's a user-defined DB::watchfunction, call it with the
2571     # current package, filename, and line. The function executes in
2572     # the DB:: package.
2573     if ( $trace & 4 ) {    # User-installed watch
2574         return
2575           if watchfunction( $package, $filename, $line )
2576           and not $single
2577           and not $was_signal
2578           and not( $trace & ~4 );
2579     } ## end if ($trace & 4)
2580
2581     # Pick up any alteration to $signal in the watchfunction, and
2582     # turn off the signal now.
2583     $was_signal = $signal;
2584     $signal     = 0;
2585
2586 =head2 GETTING READY TO EXECUTE COMMANDS
2587
2588 The debugger decides to take control if single-step mode is on, the
2589 C<t> command was entered, or the user generated a signal. If the program
2590 has fallen off the end, we set things up so that entering further commands
2591 won't cause trouble, and we say that the program is over.
2592
2593 =cut
2594
2595     # Make sure that we always print if asked for explicitly regardless
2596     # of $trace_to_depth .
2597     $explicit_stop = ($single || $was_signal);
2598
2599     # Check to see if we should grab control ($single true,
2600     # trace set appropriately, or we got a signal).
2601     if ( $explicit_stop || ( $trace & 1 ) ) {
2602         $obj->_DB__grab_control(@_);
2603     } ## end if ($single || ($trace...
2604
2605 =pod
2606
2607 If there's an action to be executed for the line we stopped at, execute it.
2608 If there are any preprompt actions, execute those as well.
2609
2610 =cut
2611
2612     # If there's an action, do it now.
2613     if ($action) {
2614         $evalarg = $action;
2615         DB::eval();
2616     }
2617
2618     # Are we nested another level (e.g., did we evaluate a function
2619     # that had a breakpoint in it at the debugger prompt)?
2620     if ( $single || $was_signal ) {
2621
2622         # Yes, go down a level.
2623         local $level = $level + 1;
2624
2625         # Do any pre-prompt actions.
2626         foreach $evalarg (@$pre) {
2627             DB::eval();
2628         }
2629
2630         # Complain about too much recursion if we passed the limit.
2631         if ($single & 4) {
2632             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2633         }
2634
2635         # The line we're currently on. Set $incr to -1 to stay here
2636         # until we get a command that tells us to advance.
2637         $start = $line;
2638         $incr  = -1;      # for backward motion.
2639
2640         # Tack preprompt debugger actions ahead of any actual input.
2641         @typeahead = ( @$pretype, @typeahead );
2642
2643 =head2 WHERE ARE WE?
2644
2645 XXX Relocate this section?
2646
2647 The debugger normally shows the line corresponding to the current line of
2648 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2649 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2650
2651 C<$incr> controls by how many lines the I<current> line should move forward
2652 after a command is executed. If set to -1, this indicates that the I<current>
2653 line shouldn't change.
2654
2655 C<$start> is the I<current> line. It is used for things like knowing where to
2656 move forwards or backwards from when doing an C<L> or C<-> command.
2657
2658 C<$max> tells the debugger where the last line of the current file is. It's
2659 used to terminate loops most often.
2660
2661 =head2 THE COMMAND LOOP
2662
2663 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2664 in two parts:
2665
2666 =over 4
2667
2668 =item *
2669
2670 The outer part of the loop, starting at the C<CMD> label. This loop
2671 reads a command and then executes it.
2672
2673 =item *
2674
2675 The inner part of the loop, starting at the C<PIPE> label. This part
2676 is wholly contained inside the C<CMD> block and only executes a command.
2677 Used to handle commands running inside a pager.
2678
2679 =back
2680
2681 So why have two labels to restart the loop? Because sometimes, it's easier to
2682 have a command I<generate> another command and then re-execute the loop to do
2683 the new command. This is faster, but perhaps a bit more convoluted.
2684
2685 =cut
2686
2687         # The big command dispatch loop. It keeps running until the
2688         # user yields up control again.
2689         #
2690         # If we have a terminal for input, and we get something back
2691         # from readline(), keep on processing.
2692
2693       CMD:
2694         while (_DB__read_next_cmd($tid))
2695         {
2696
2697             share($cmd);
2698             # ... try to execute the input as debugger commands.
2699
2700             # Don't stop running.
2701             $single = 0;
2702
2703             # No signal is active.
2704             $signal = 0;
2705
2706             # Handle continued commands (ending with \):
2707             if ($cmd =~ s/\\\z/\n/) {
2708                 $cmd .= DB::readline("  cont: ");
2709                 redo CMD;
2710             }
2711
2712 =head4 The null command
2713
2714 A newline entered by itself means I<re-execute the last command>. We grab the
2715 command out of C<$laststep> (where it was recorded previously), and copy it
2716 back into C<$cmd> to be executed below. If there wasn't any previous command,
2717 we'll do nothing below (no command will match). If there was, we also save it
2718 in the command history and fall through to allow the command parsing to pick
2719 it up.
2720
2721 =cut
2722
2723             # Empty input means repeat the last command.
2724             if ($cmd eq '') {
2725                 $cmd = $laststep;
2726             }
2727             chomp($cmd);    # get rid of the annoying extra newline
2728             if (length($cmd) >= 2) {
2729                 push( @hist, $cmd );
2730             }
2731             push( @truehist, $cmd );
2732             share(@hist);
2733             share(@truehist);
2734
2735             # This is a restart point for commands that didn't arrive
2736             # via direct user input. It allows us to 'redo PIPE' to
2737             # re-execute command processing without reading a new command.
2738           PIPE: {
2739                 _DB__trim_command_and_return_first_component($obj);
2740
2741 =head3 COMMAND ALIASES
2742
2743 The debugger can create aliases for commands (these are stored in the
2744 C<%alias> hash). Before a command is executed, the command loop looks it up
2745 in the alias hash and substitutes the contents of the alias for the command,
2746 completely replacing it.
2747
2748 =cut
2749
2750                 # See if there's an alias for the command, and set it up if so.
2751                 if ( $alias{$cmd_verb} ) {
2752
2753                     # Squelch signal handling; we want to keep control here
2754                     # if something goes loco during the alias eval.
2755                     local $SIG{__DIE__};
2756                     local $SIG{__WARN__};
2757
2758                     # This is a command, so we eval it in the DEBUGGER's
2759                     # scope! Otherwise, we can't see the special debugger
2760                     # variables, or get to the debugger's subs. (Well, we
2761                     # _could_, but why make it even more complicated?)
2762                     eval "\$cmd =~ $alias{$cmd_verb}";
2763                     if ($@) {
2764                         local $\ = '';
2765                         print $OUT "Couldn't evaluate '$cmd_verb' alias: $@";
2766                         next CMD;
2767                     }
2768                     _DB__trim_command_and_return_first_component($obj);
2769                 } ## end if ($alias{$cmd_verb})
2770
2771 =head3 MAIN-LINE COMMANDS
2772
2773 All of these commands work up to and after the program being debugged has
2774 terminated.
2775
2776 =head4 C<q> - quit
2777
2778 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2779 try to execute further, cleaning any restart-related stuff out of the
2780 environment, and executing with the last value of C<$?>.
2781
2782 =cut
2783
2784                 # All of these commands were remapped in perl 5.8.0;
2785                 # we send them off to the secondary dispatcher (see below).
2786                 $obj->_handle_special_char_cmd_wrapper_commands;
2787                 _DB__trim_command_and_return_first_component($obj);
2788
2789                 if (my $cmd_rec = $cmd_lookup{$cmd_verb}) {
2790                     my $type = $cmd_rec->{t};
2791                     my $val = $cmd_rec->{v};
2792                     if ($type eq 'm') {
2793                         $obj->$val();
2794                     }
2795                     elsif ($type eq 's') {
2796                         $val->($obj);
2797                     }
2798                 }
2799
2800 =head4 C<t> - trace [n]
2801
2802 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2803 If level is specified, set C<$trace_to_depth>.
2804
2805 =head4 C<S> - list subroutines matching/not matching a pattern
2806
2807 Walks through C<%sub>, checking to see whether or not to print the name.
2808
2809 =head4 C<X> - list variables in current package
2810
2811 Since the C<V> command actually processes this, just change this to the
2812 appropriate C<V> command and fall through.
2813
2814 =head4 C<V> - list variables
2815
2816 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2817
2818 =head4 C<x> - evaluate and print an expression
2819
2820 Hands the expression off to C<DB::eval>, setting it up to print the value
2821 via C<dumpvar.pl> instead of just printing it directly.
2822
2823 =head4 C<m> - print methods
2824
2825 Just uses C<DB::methods> to determine what methods are available.
2826
2827 =head4 C<f> - switch files
2828
2829 Switch to a different filename.
2830
2831 =head4 C<.> - return to last-executed line.
2832
2833 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2834 and then we look up the line in the magical C<%dbline> hash.
2835
2836 =head4 C<-> - back one window
2837
2838 We change C<$start> to be one window back; if we go back past the first line,
2839 we set it to be the first line. We ser C<$incr> to put us back at the
2840 currently-executing line, and then put a C<l $start +> (list one window from
2841 C<$start>) in C<$cmd> to be executed later.
2842
2843 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2844
2845 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2846 problems, most notably that the default case of several commands destroying
2847 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2848 retain the old commands for those who were used to using them or who preferred
2849 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2850 deal with them instead of processing them in-line.
2851
2852 =head4 C<y> - List lexicals in higher scope
2853
2854 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2855 above the current one and then displays then using C<dumpvar.pl>.
2856
2857 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2858
2859 All of the commands below this point don't work after the program being
2860 debugged has ended. All of them check to see if the program has ended; this
2861 allows the commands to be relocated without worrying about a 'line of
2862 demarcation' above which commands can be entered anytime, and below which
2863 they can't.
2864
2865 =head4 C<n> - single step, but don't trace down into subs
2866
2867 Done by setting C<$single> to 2, which forces subs to execute straight through
2868 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2869 so a null command knows what to re-execute.
2870
2871 =head4 C<s> - single-step, entering subs
2872
2873 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2874 subs. Also saves C<s> as C<$lastcmd>.
2875
2876 =head4 C<c> - run continuously, setting an optional breakpoint
2877
2878 Most of the code for this command is taken up with locating the optional
2879 breakpoint, which is either a subroutine name or a line number. We set
2880 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2881 in this and all call levels above this one.
2882
2883 =head4 C<r> - return from a subroutine
2884
2885 For C<r> to work properly, the debugger has to stop execution again
2886 immediately after the return is executed. This is done by forcing
2887 single-stepping to be on in the call level above the current one. If
2888 we are printing return values when a C<r> is executed, set C<$doret>
2889 appropriately, and force us out of the command loop.
2890
2891 =head4 C<T> - stack trace
2892
2893 Just calls C<DB::print_trace>.
2894
2895 =head4 C<w> - List window around current line.
2896
2897 Just calls C<DB::cmd_w>.
2898
2899 =head4 C<W> - watch-expression processing.
2900
2901 Just calls C<DB::cmd_W>.
2902
2903 =head4 C</> - search forward for a string in the source
2904
2905 We take the argument and treat it as a pattern. If it turns out to be a
2906 bad one, we return the error we got from trying to C<eval> it and exit.
2907 If not, we create some code to do the search and C<eval> it so it can't
2908 mess us up.
2909
2910 =cut
2911
2912                 _DB__handle_forward_slash_command($obj);
2913
2914 =head4 C<?> - search backward for a string in the source
2915
2916 Same as for C</>, except the loop runs backwards.
2917
2918 =cut
2919
2920                 _DB__handle_question_mark_command($obj);
2921
2922 =head4 C<$rc> - Recall command
2923
2924 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2925 that the terminal supports history). It find the the command required, puts it
2926 into C<$cmd>, and redoes the loop to execute it.
2927
2928 =cut
2929
2930                 # $rc - recall command.
2931                 $obj->_handle_rc_recall_command;
2932
2933 =head4 C<$sh$sh> - C<system()> command
2934
2935 Calls the C<_db_system()> to handle the command. This keeps the C<STDIN> and
2936 C<STDOUT> from getting messed up.
2937
2938 =cut
2939
2940                 $obj->_handle_sh_command;
2941
2942 =head4 C<$rc I<pattern> $rc> - Search command history
2943
2944 Another command to manipulate C<@hist>: this one searches it with a pattern.
2945 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2946
2947 =cut
2948
2949                 $obj->_handle_rc_search_history_command;
2950
2951 =head4 C<$sh> - Invoke a shell
2952
2953 Uses C<_db_system()> to invoke a shell.
2954
2955 =cut
2956
2957 =head4 C<$sh I<command>> - Force execution of a command in a shell
2958
2959 Like the above, but the command is passed to the shell. Again, we use
2960 C<_db_system()> to avoid problems with C<STDIN> and C<STDOUT>.
2961
2962 =head4 C<H> - display commands in history
2963
2964 Prints the contents of C<@hist> (if any).
2965
2966 =head4 C<man, doc, perldoc> - look up documentation
2967
2968 Just calls C<runman()> to print the appropriate document.
2969
2970 =cut
2971
2972                 $obj->_handle_doc_command;
2973
2974 =head4 C<p> - print
2975
2976 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
2977 the bottom of the loop.
2978
2979 =head4 C<=> - define command alias
2980
2981 Manipulates C<%alias> to add or list command aliases.
2982
2983 =head4 C<source> - read commands from a file.
2984
2985 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
2986 pick it up.
2987
2988 =head4 C<enable> C<disable> - enable or disable breakpoints
2989
2990 This enables or disables breakpoints.
2991
2992 =head4 C<save> - send current history to a file
2993
2994 Takes the complete history, (not the shrunken version you see with C<H>),
2995 and saves it to the given filename, so it can be replayed using C<source>.
2996
2997 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
2998
2999 =head4 C<R> - restart
3000
3001 Restart the debugger session.
3002
3003 =head4 C<rerun> - rerun the current session
3004
3005 Return to any given position in the B<true>-history list
3006
3007 =head4 C<|, ||> - pipe output through the pager.
3008
3009 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3010 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3011 pipe to the pager (restoring the output filehandles if this fails). If this
3012 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3013 set C<$signal>, sending us back into the debugger.
3014
3015 We then trim off the pipe symbols and C<redo> the command loop at the
3016 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3017 reading another.
3018
3019 =cut
3020
3021                 # || - run command in the pager, with output to DB::OUT.
3022                 _DB__handle_run_command_in_pager_command($obj);
3023
3024 =head3 END OF COMMAND PARSING
3025
3026 Anything left in C<$cmd> at this point is a Perl expression that we want to
3027 evaluate. We'll always evaluate in the user's context, and fully qualify
3028 any variables we might want to address in the C<DB> package.
3029
3030 =cut
3031
3032             }    # PIPE:
3033
3034             # Make sure the flag that says "the debugger's running" is
3035             # still on, to make sure we get control again.
3036             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3037
3038             # Run *our* eval that executes in the caller's context.
3039             DB::eval();
3040
3041             # Turn off the one-time-dump stuff now.
3042             if ($onetimeDump) {
3043                 $onetimeDump      = undef;
3044                 $onetimedumpDepth = undef;
3045             }
3046             elsif ( $term_pid == $$ ) {
3047                 eval { # May run under miniperl, when not available...
3048                     STDOUT->flush();
3049                     STDERR->flush();
3050                 };
3051
3052                 # XXX If this is the master pid, print a newline.
3053                 print {$OUT} "\n";
3054             }
3055         } ## end while (($term || &setterm...
3056
3057 =head3 POST-COMMAND PROCESSING
3058
3059 After each command, we check to see if the command output was piped anywhere.
3060 If so, we go through the necessary code to unhook the pipe and go back to
3061 our standard filehandles for input and output.
3062
3063 =cut
3064
3065         continue {    # CMD:
3066             _DB__at_end_of_every_command($obj);
3067         }    # CMD:
3068
3069 =head3 COMMAND LOOP TERMINATION
3070
3071 When commands have finished executing, we come here. If the user closed the
3072 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3073 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3074 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3075 The interpreter will then execute the next line and then return control to us
3076 again.
3077
3078 =cut
3079
3080         # No more commands? Quit.
3081         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3082
3083         # Evaluate post-prompt commands.
3084         foreach $evalarg (@$post) {
3085             DB::eval();
3086         }
3087     }    # if ($single || $signal)
3088
3089     # Put the user's globals back where you found them.
3090     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3091     ();
3092 } ## end sub DB
3093
3094 package DB::Obj;
3095
3096 sub new {
3097     my $class = shift;
3098
3099     my $self = bless {}, $class;
3100
3101     $self->_init(@_);
3102
3103     return $self;
3104 }
3105
3106 sub _init {
3107     my ($self, $args) = @_;
3108
3109     %{$self} = (%$self, %$args);
3110
3111     return;
3112 }
3113
3114 {
3115     no strict 'refs';
3116     foreach my $slot_name (qw(
3117         after explicit_stop infix pat piped position prefix selected cmd_verb
3118         cmd_args
3119         )) {
3120         my $slot = $slot_name;
3121         *{$slot} = sub {
3122             my $self = shift;
3123
3124             if (@_) {
3125                 ${ $self->{$slot} } = shift;
3126             }
3127
3128             return ${ $self->{$slot} };
3129         };
3130
3131         *{"append_to_$slot"} = sub {
3132             my $self = shift;
3133             my $s = shift;
3134
3135             return $self->$slot($self->$slot . $s);
3136         };
3137     }
3138 }
3139
3140 sub _DB_on_init__initialize_globals
3141 {
3142     my $self = shift;
3143
3144     # Check for whether we should be running continuously or not.
3145     # _After_ the perl program is compiled, $single is set to 1:
3146     if ( $single and not $second_time++ ) {
3147
3148         # Options say run non-stop. Run until we get an interrupt.
3149         if ($runnonstop) {    # Disable until signal
3150                 # If there's any call stack in place, turn off single
3151                 # stepping into subs throughout the stack.
3152             for my $i (0 .. $stack_depth) {
3153                 $stack[ $i ] &= ~1;
3154             }
3155
3156             # And we are now no longer in single-step mode.
3157             $single = 0;
3158
3159             # If we simply returned at this point, we wouldn't get
3160             # the trace info. Fall on through.
3161             # return;
3162         } ## end if ($runnonstop)
3163
3164         elsif ($ImmediateStop) {
3165
3166             # We are supposed to stop here; XXX probably a break.
3167             $ImmediateStop = 0;    # We've processed it; turn it off
3168             $signal        = 1;    # Simulate an interrupt to force
3169                                    # us into the command loop
3170         }
3171     } ## end if ($single and not $second_time...
3172
3173     # If we're in single-step mode, or an interrupt (real or fake)
3174     # has occurred, turn off non-stop mode.
3175     $runnonstop = 0 if $single or $signal;
3176
3177     return;
3178 }
3179
3180 sub _DB__handle_watch_expressions
3181 {
3182     my $self = shift;
3183
3184     if ( $trace & 2 ) {
3185         for my $n (0 .. $#to_watch) {
3186             $evalarg = $to_watch[$n];
3187             local $onetimeDump;    # Tell DB::eval() to not output results
3188
3189             # Fix context DB::eval() wants to return an array, but
3190             # we need a scalar here.
3191             my ($val) = join( "', '", DB::eval() );
3192             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
3193
3194             # Did it change?
3195             if ( $val ne $old_watch[$n] ) {
3196
3197                 # Yep! Show the difference, and fake an interrupt.
3198                 $signal = 1;
3199                 print {$OUT} <<EOP;
3200 Watchpoint $n:\t$to_watch[$n] changed:
3201     old value:\t$old_watch[$n]
3202     new value:\t$val
3203 EOP
3204                 $old_watch[$n] = $val;
3205             } ## end if ($val ne $old_watch...
3206         } ## end for my $n (0 ..
3207     } ## end if ($trace & 2)
3208
3209     return;
3210 }
3211
3212 sub _my_print_lineinfo
3213 {
3214     my ($self, $i, $incr_pos) = @_;
3215
3216     if ($frame) {
3217         # Print it indented if tracing is on.
3218         DB::print_lineinfo( ' ' x $stack_depth,
3219             "$i:\t$DB::dbline[$i]" . $self->after );
3220     }
3221     else {
3222         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3223     }
3224 }
3225
3226 sub _curr_line {
3227     return $DB::dbline[$line];
3228 }
3229
3230 sub _is_full {
3231     my ($self, $letter) = @_;
3232
3233     return ($DB::cmd eq $letter);
3234 }
3235
3236 sub _DB__grab_control
3237 {
3238     my $self = shift;
3239
3240     # Yes, grab control.
3241     if ($slave_editor) {
3242
3243         # Tell the editor to update its position.
3244         $self->position("\032\032${DB::filename}:$line:0\n");
3245         DB::print_lineinfo($self->position());
3246     }
3247
3248 =pod
3249
3250 Special check: if we're in package C<DB::fake>, we've gone through the
3251 C<END> block at least once. We set up everything so that we can continue
3252 to enter commands and have a valid context to be in.
3253
3254 =cut
3255
3256     elsif ( $DB::package eq 'DB::fake' ) {
3257
3258         # Fallen off the end already.
3259         if (!$DB::term) {
3260             DB::setterm();
3261         }
3262
3263         DB::print_help(<<EOP);
3264 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3265 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3266 B<h q>, B<h R> or B<h o> to get additional info.
3267 EOP
3268
3269         # Set the DB::eval context appropriately.
3270         $DB::package     = 'main';
3271         $DB::usercontext = DB::_calc_usercontext($DB::package);
3272     } ## end elsif ($package eq 'DB::fake')
3273
3274 =pod
3275
3276 If the program hasn't finished executing, we scan forward to the
3277 next executable line, print that out, build the prompt from the file and line
3278 number information, and print that.
3279
3280 =cut
3281
3282     else {
3283
3284
3285         # Still somewhere in the midst of execution. Set up the
3286         #  debugger prompt.
3287         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3288                              # Perl 5 ones (sorry, we don't print Klingon
3289                              #module names)
3290
3291         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3292         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3293         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3294
3295         # Break up the prompt if it's really long.
3296         if ( length($self->prefix()) > 30 ) {
3297             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3298             $self->prefix("");
3299             $self->infix(":\t");
3300         }
3301         else {
3302             $self->infix("):\t");
3303             $self->position(
3304                 $self->prefix . $line. $self->infix
3305                 . $self->_curr_line . $self->after
3306             );
3307         }
3308
3309         # Print current line info, indenting if necessary.
3310         $self->_my_print_lineinfo($line, $self->position);
3311
3312         my $i;
3313         my $line_i = sub { return $DB::dbline[$i]; };
3314
3315         # Scan forward, stopping at either the end or the next
3316         # unbreakable line.
3317         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3318         {    #{ vi
3319
3320             # Drop out on null statements, block closers, and comments.
3321             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3322
3323             # Drop out if the user interrupted us.
3324             last if $signal;
3325
3326             # Append a newline if the line doesn't have one. Can happen
3327             # in eval'ed text, for instance.
3328             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3329
3330             # Next executable line.
3331             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3332                 . $self->after;
3333             $self->append_to_position($incr_pos);
3334             $self->_my_print_lineinfo($i, $incr_pos);
3335         } ## end for ($i = $line + 1 ; $i...
3336     } ## end else [ if ($slave_editor)
3337
3338     return;
3339 }
3340
3341 sub _handle_t_command {
3342     my $self = shift;
3343
3344     my $levels = $self->cmd_args();
3345
3346     if ((!length($levels)) or ($levels !~ /\D/)) {
3347         $trace ^= 1;
3348         local $\ = '';
3349         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3350         print {$OUT} "Trace = "
3351         . ( ( $trace & 1 )
3352             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3353             : "off" ) . "\n";
3354         next CMD;
3355     }
3356
3357     return;
3358 }
3359
3360
3361 sub _handle_S_command {
3362     my $self = shift;
3363
3364     if (my ($print_all_subs, $should_reverse, $Spatt)
3365         = $self->cmd_args =~ /\A((!)?(.+))?\z/) {
3366         # $Spatt is the pattern (if any) to use.
3367         # Reverse scan?
3368         my $Srev     = defined $should_reverse;
3369         # No args - print all subs.
3370         my $Snocheck = !defined $print_all_subs;
3371
3372         # Need to make these sane here.
3373         local $\ = '';
3374         local $, = '';
3375
3376         # Search through the debugger's magical hash of subs.
3377         # If $nocheck is true, just print the sub name.
3378         # Otherwise, check it against the pattern. We then use
3379         # the XOR trick to reverse the condition as required.
3380         foreach $subname ( sort( keys %sub ) ) {
3381             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3382                 print $OUT $subname, "\n";
3383             }
3384         }
3385         next CMD;
3386     }
3387
3388     return;
3389 }
3390
3391 sub _handle_V_command_and_X_command {
3392     my $self = shift;
3393
3394     $DB::cmd =~ s/^X\b/V $DB::package/;
3395
3396     # Bare V commands get the currently-being-debugged package
3397     # added.
3398     if ($self->_is_full('V')) {
3399         $DB::cmd = "V $DB::package";
3400     }
3401
3402     # V - show variables in package.
3403     if (my ($new_packname, $new_vars_str) =
3404         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3405
3406         # Save the currently selected filehandle and
3407         # force output to debugger's filehandle (dumpvar
3408         # just does "print" for output).
3409         my $savout = select($OUT);
3410
3411         # Grab package name and variables to dump.
3412         $packname = $new_packname;
3413         my @vars     = split( ' ', $new_vars_str );
3414
3415         # If main::dumpvar isn't here, get it.
3416         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3417         if ( defined &main::dumpvar ) {
3418
3419             # We got it. Turn off subroutine entry/exit messages
3420             # for the moment, along with return values.
3421             local $frame = 0;
3422             local $doret = -2;
3423
3424             # must detect sigpipe failures  - not catching
3425             # then will cause the debugger to die.
3426             eval {
3427                 main::dumpvar(
3428                     $packname,
3429                     defined $option{dumpDepth}
3430                     ? $option{dumpDepth}
3431                     : -1,    # assume -1 unless specified
3432                     @vars
3433                 );
3434             };
3435
3436             # The die doesn't need to include the $@, because
3437             # it will automatically get propagated for us.
3438             if ($@) {
3439                 die unless $@ =~ /dumpvar print failed/;
3440             }
3441         } ## end if (defined &main::dumpvar)
3442         else {
3443
3444             # Couldn't load dumpvar.
3445             print $OUT "dumpvar.pl not available.\n";
3446         }
3447
3448         # Restore the output filehandle, and go round again.
3449         select($savout);
3450         next CMD;
3451     }
3452
3453     return;
3454 }
3455
3456 sub _handle_dash_command {
3457     my $self = shift;
3458
3459     if ($self->_is_full('-')) {
3460
3461         # back up by a window; go to 1 if back too far.
3462         $start -= $incr + $window + 1;
3463         $start = 1 if $start <= 0;
3464         $incr  = $window - 1;
3465
3466         # Generate and execute a "l +" command (handled below).
3467         $DB::cmd = 'l ' . ($start) . '+';
3468         redo CMD;
3469     }
3470     return;
3471 }
3472
3473 sub _n_or_s_commands_generic {
3474     my ($self, $new_val) = @_;
3475     # n - next
3476     next CMD if DB::_DB__is_finished();
3477
3478     # Single step, but don't enter subs.
3479     $single = $new_val;
3480
3481     # Save for empty command (repeat last).
3482     $laststep = $DB::cmd;
3483     last CMD;
3484 }
3485
3486 sub _n_or_s {
3487     my ($self, $letter, $new_val) = @_;
3488
3489     if ($self->_is_full($letter)) {
3490         $self->_n_or_s_commands_generic($new_val);
3491     }
3492     else {
3493         $self->_n_or_s_and_arg_commands_generic($letter, $new_val);
3494     }
3495
3496     return;
3497 }
3498
3499 sub _handle_n_command {
3500     my $self = shift;
3501
3502     return $self->_n_or_s('n', 2);
3503 }
3504
3505 sub _handle_s_command {
3506     my $self = shift;
3507
3508     return $self->_n_or_s('s', 1);
3509 }
3510
3511 sub _handle_r_command {
3512     my $self = shift;
3513
3514     # r - return from the current subroutine.
3515     if ($self->_is_full('r')) {
3516
3517         # Can't do anything if the program's over.
3518         next CMD if DB::_DB__is_finished();
3519
3520         # Turn on stack trace.
3521         $stack[$stack_depth] |= 1;
3522
3523         # Print return value unless the stack is empty.
3524         $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
3525         last CMD;
3526     }
3527
3528     return;
3529 }
3530
3531 sub _handle_T_command {
3532     my $self = shift;
3533
3534     if ($self->_is_full('T')) {
3535         DB::print_trace( $OUT, 1 );    # skip DB
3536         next CMD;
3537     }
3538
3539     return;
3540 }
3541
3542 sub _handle_w_command {
3543     my $self = shift;
3544
3545     DB::cmd_w( 'w', $self->cmd_args() );
3546     next CMD;
3547
3548     return;
3549 }
3550
3551 sub _handle_W_command {
3552     my $self = shift;
3553
3554     if (my $arg = $self->cmd_args) {
3555         DB::cmd_W( 'W', $arg );
3556         next CMD;
3557     }
3558
3559     return;
3560 }
3561
3562 sub _handle_rc_recall_command {
3563     my $self = shift;
3564
3565     # $rc - recall command.
3566     if (my ($minus, $arg) = $DB::cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
3567
3568         # No arguments, take one thing off history.
3569         pop(@hist) if length($DB::cmd) > 1;
3570
3571         # Relative (- found)?
3572         #  Y - index back from most recent (by 1 if bare minus)
3573         #  N - go to that particular command slot or the last
3574         #      thing if nothing following.
3575
3576         $self->cmd_verb(
3577             scalar($minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist ))
3578         );
3579
3580         # Pick out the command desired.
3581         $DB::cmd = $hist[$self->cmd_verb];
3582
3583         # Print the command to be executed and restart the loop
3584         # with that command in the buffer.
3585         print {$OUT} $DB::cmd, "\n";
3586         redo CMD;
3587     }
3588
3589     return;
3590 }
3591
3592 sub _handle_rc_search_history_command {
3593     my $self = shift;
3594
3595     # $rc pattern $rc - find a command in the history.
3596     if (my ($arg) = $DB::cmd =~ /\A$rc([^$rc].*)\z/) {
3597
3598         # Create the pattern to use.
3599         my $pat = "^$arg";
3600         $self->pat($pat);
3601
3602         # Toss off last entry if length is >1 (and it always is).
3603         pop(@hist) if length($DB::cmd) > 1;
3604
3605         my $i;
3606
3607         # Look backward through the history.
3608         SEARCH_HIST:
3609         for ( $i = $#hist ; $i ; --$i ) {
3610             # Stop if we find it.
3611             last SEARCH_HIST if $hist[$i] =~ /$pat/;
3612         }
3613
3614         if ( !$i ) {
3615
3616             # Never found it.
3617             print $OUT "No such command!\n\n";
3618             next CMD;
3619         }
3620
3621         # Found it. Put it in the buffer, print it, and process it.
3622         $DB::cmd = $hist[$i];
3623         print $OUT $DB::cmd, "\n";
3624         redo CMD;
3625     }
3626
3627     return;
3628 }
3629
3630 sub _handle_H_command {
3631     my $self = shift;
3632
3633     if ($self->cmd_args =~ m#\A\*#) {
3634         @hist = @truehist = ();
3635         print $OUT "History cleansed\n";
3636         next CMD;
3637     }
3638
3639     if (my ($num) = $self->cmd_args =~ /\A(?:-(\d+))?/) {
3640
3641         # Anything other than negative numbers is ignored by
3642         # the (incorrect) pattern, so this test does nothing.
3643         $end = $num ? ( $#hist - $num ) : 0;
3644
3645         # Set to the minimum if less than zero.
3646         $hist = 0 if $hist < 0;
3647
3648         # Start at the end of the array.
3649         # Stay in while we're still above the ending value.
3650         # Tick back by one each time around the loop.
3651         my $i;
3652
3653         for ( $i = $#hist ; $i > $end ; $i-- ) {
3654
3655             # Print the command  unless it has no arguments.
3656             print $OUT "$i: ", $hist[$i], "\n"
3657             unless $hist[$i] =~ /^.?$/;
3658         }
3659
3660         next CMD;
3661     }
3662
3663     return;
3664 }
3665
3666 sub _handle_doc_command {
3667     my $self = shift;
3668
3669     # man, perldoc, doc - show manual pages.
3670     if (my ($man_page)
3671         = $DB::cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3672         runman($man_page);
3673         next CMD;
3674     }
3675
3676     return;
3677 }
3678
3679 sub _handle_p_command {
3680     my $self = shift;
3681
3682     my $print_cmd = 'print {$DB::OUT} ';
3683     # p - print (no args): print $_.
3684     if ($self->_is_full('p')) {
3685         $DB::cmd = $print_cmd . '$_';
3686     }
3687     else {
3688         # p - print the given expression.
3689         $DB::cmd =~ s/\Ap\b/$print_cmd /;
3690     }
3691
3692     return;
3693 }
3694
3695 sub _handle_equal_sign_command {
3696     my $self = shift;
3697
3698     if ($DB::cmd =~ s/\A=\s*//) {
3699         my @keys;
3700         if ( length $DB::cmd == 0 ) {
3701
3702             # No args, get current aliases.
3703             @keys = sort keys %alias;
3704         }
3705         elsif ( my ( $k, $v ) = ( $DB::cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3706
3707             # Creating a new alias. $k is alias name, $v is
3708             # alias value.
3709
3710             # can't use $_ or kill //g state
3711             for my $x ( $k, $v ) {
3712
3713                 # Escape "alarm" characters.
3714                 $x =~ s/\a/\\a/g;
3715             }
3716
3717             # Substitute key for value, using alarm chars
3718             # as separators (which is why we escaped them in
3719             # the command).
3720             $alias{$k} = "s\a$k\a$v\a";
3721
3722             # Turn off standard warn and die behavior.
3723             local $SIG{__DIE__};
3724             local $SIG{__WARN__};
3725
3726             # Is it valid Perl?
3727             unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3728
3729                 # Nope. Bad alias. Say so and get out.
3730                 print $OUT "Can't alias $k to $v: $@\n";
3731                 delete $alias{$k};
3732                 next CMD;
3733             }
3734
3735             # We'll only list the new one.
3736             @keys = ($k);
3737         } ## end elsif (my ($k, $v) = ($DB::cmd...
3738
3739         # The argument is the alias to list.
3740         else {
3741             @keys = ($DB::cmd);
3742         }
3743
3744         # List aliases.
3745         for my $k (@keys) {
3746
3747             # Messy metaquoting: Trim the substitution code off.
3748             # We use control-G as the delimiter because it's not
3749             # likely to appear in the alias.
3750             if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3751
3752                 # Print the alias.
3753                 print $OUT "$k\t= $1\n";
3754             }
3755             elsif ( defined $alias{$k} ) {
3756
3757                 # Couldn't trim it off; just print the alias code.
3758                 print $OUT "$k\t$alias{$k}\n";
3759             }
3760             else {
3761
3762                 # No such, dude.
3763                 print "No alias for $k\n";
3764             }
3765         } ## end for my $k (@keys)
3766         next CMD;
3767     }
3768
3769     return;
3770 }
3771
3772 sub _handle_source_command {
3773     my $self = shift;
3774
3775     # source - read commands from a file (or pipe!) and execute.
3776     if (my $sourced_fn = $self->cmd_args) {
3777         if ( open my $fh, $sourced_fn ) {
3778
3779             # Opened OK; stick it in the list of file handles.
3780             push @cmdfhs, $fh;
3781         }
3782         else {
3783
3784             # Couldn't open it.
3785             DB::_db_warn("Can't execute '$sourced_fn': $!\n");
3786         }
3787         next CMD;
3788     }
3789
3790     return;
3791 }
3792
3793 sub _handle_enable_disable_commands {
3794     my $self = shift;
3795
3796     my $which_cmd = $self->cmd_verb;
3797     my $position = $self->cmd_args;
3798
3799     if ($position !~ /\s/) {
3800         my ($fn, $line_num);
3801         if ($position =~ m{\A\d+\z})
3802         {
3803             $fn = $DB::filename;
3804             $line_num = $position;
3805         }
3806         elsif (my ($new_fn, $new_line_num)
3807             = $position =~ m{\A(.*):(\d+)\z}) {
3808             ($fn, $line_num) = ($new_fn, $new_line_num);
3809         }
3810         else
3811         {
3812             DB::_db_warn("Wrong spec for enable/disable argument.\n");
3813         }
3814
3815         if (defined($fn)) {
3816             if (DB::_has_breakpoint_data_ref($fn, $line_num)) {
3817                 DB::_set_breakpoint_enabled_status($fn, $line_num,
3818                     ($which_cmd eq 'enable' ? 1 : '')
3819                 );
3820             }
3821             else {
3822                 DB::_db_warn("No breakpoint set at ${fn}:${line_num}\n");
3823             }
3824         }
3825
3826         next CMD;
3827     }
3828
3829     return;
3830 }
3831
3832 sub _handle_save_command {
3833     my $self = shift;
3834
3835     if (my $new_fn = $self->cmd_args) {
3836         my $filename = $new_fn || '.perl5dbrc';    # default?
3837         if ( open my $fh, '>', $filename ) {
3838
3839             # chomp to remove extraneous newlines from source'd files
3840             chomp( my @truelist =
3841                 map { m/\A\s*(save|source)/ ? "#$_" : $_ }
3842                 @truehist );
3843             print {$fh} join( "\n", @truelist );
3844             print "commands saved in $filename\n";
3845         }
3846         else {
3847             DB::_db_warn("Can't save debugger commands in '$new_fn': $!\n");
3848         }
3849         next CMD;
3850     }
3851
3852     return;
3853 }
3854
3855 sub _n_or_s_and_arg_commands_generic {
3856     my ($self, $letter, $new_val) = @_;
3857
3858     # s - single-step. Remember the last command was 's'.
3859     if ($DB::cmd =~ s#\A\Q$letter\E\s#\$DB::single = $new_val;\n#) {
3860         $laststep = $letter;
3861     }
3862
3863     return;
3864 }
3865
3866 sub _handle_sh_command {
3867     my $self = shift;
3868
3869     # $sh$sh - run a shell command (if it's all ASCII).
3870     # Can't run shell commands with Unicode in the debugger, hmm.
3871     my $my_cmd = $DB::cmd;
3872     if ($my_cmd =~ m#\A$sh#gms) {
3873
3874         if ($my_cmd =~ m#\G\z#cgms) {
3875             # Run the user's shell. If none defined, run Bourne.
3876             # We resume execution when the shell terminates.
3877             DB::_db_system( $ENV{SHELL} || "/bin/sh" );
3878             next CMD;
3879         }
3880         elsif ($my_cmd =~ m#\G$sh\s*(.*)#cgms) {
3881             # System it.
3882             DB::_db_system($1);
3883             next CMD;
3884         }
3885         elsif ($my_cmd =~ m#\G\s*(.*)#cgms) {
3886             DB::_db_system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3887             next CMD;
3888         }
3889     }
3890 }
3891
3892 sub _handle_x_command {
3893     my $self = shift;
3894
3895     if ($DB::cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
3896         $onetimeDump = 'dump';    # main::dumpvar shows the output
3897
3898         # handle special  "x 3 blah" syntax XXX propagate
3899         # doc back to special variables.
3900         if ( $DB::cmd =~ s#\A\s*(\d+)(?=\s)# #) {
3901             $onetimedumpDepth = $1;
3902         }
3903     }
3904
3905     return;
3906 }
3907
3908 sub _handle_q_command {
3909     my $self = shift;
3910
3911     if ($self->_is_full('q')) {
3912         $fall_off_end = 1;
3913         DB::clean_ENV();
3914         exit $?;
3915     }
3916
3917     return;
3918 }
3919
3920 sub _handle_cmd_wrapper_commands {
3921     my $self = shift;
3922
3923     DB::cmd_wrapper( $self->cmd_verb, $self->cmd_args, $line );
3924     next CMD;
3925 }
3926
3927 sub _handle_special_char_cmd_wrapper_commands {
3928     my $self = shift;
3929
3930     # All of these commands were remapped in perl 5.8.0;
3931     # we send them off to the secondary dispatcher (see below).
3932     if (my ($cmd_letter, $my_arg) = $DB::cmd =~ /\A([<>\{]{1,2})\s*(.*)/so) {
3933         DB::cmd_wrapper( $cmd_letter, $my_arg, $line );
3934         next CMD;
3935     }
3936
3937     return;
3938 }
3939
3940 package DB;
3941
3942 # The following code may be executed now:
3943 # BEGIN {warn 4}
3944
3945 =head2 sub
3946
3947 C<sub> is called whenever a subroutine call happens in the program being
3948 debugged. The variable C<$DB::sub> contains the name of the subroutine
3949 being called.
3950
3951 The core function of this subroutine is to actually call the sub in the proper
3952 context, capturing its output. This of course causes C<DB::DB> to get called
3953 again, repeating until the subroutine ends and returns control to C<DB::sub>
3954 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3955 return value, and returns its captured copy of the return value as its own
3956 return value. The value then feeds back into the program being debugged as if
3957 C<DB::sub> hadn't been there at all.
3958
3959 C<sub> does all the work of printing the subroutine entry and exit messages
3960 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3961 and also prints the return value if needed (for the C<r> command and if
3962 the 16 bit is set in C<$frame>).
3963
3964 It also tracks the subroutine call depth by saving the current setting of
3965 C<$single> in the C<@stack> package global; if this exceeds the value in
3966 C<$deep>, C<sub> automatically turns on printing of the current depth by
3967 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3968 of stop/don't stop on entry to subs set as it currently is set.
3969
3970 =head3 C<caller()> support
3971
3972 If C<caller()> is called from the package C<DB>, it provides some
3973 additional data, in the following order:
3974
3975 =over 4
3976
3977 =item * C<$package>
3978
3979 The package name the sub was in
3980
3981 =item * C<$filename>
3982
3983 The filename it was defined in
3984
3985 =item * C<$line>
3986
3987 The line number it was defined on
3988
3989 =item * C<$subroutine>
3990
3991 The subroutine name; C<(eval)> if an C<eval>().
3992
3993 =item * C<$hasargs>
3994
3995 1 if it has arguments, 0 if not
3996
3997 =item * C<$wantarray>
3998
3999 1 if array context, 0 if scalar context
4000
4001 =item * C<$evaltext>
4002
4003 The C<eval>() text, if any (undefined for C<eval BLOCK>)
4004
4005 =item * C<$is_require>
4006
4007 frame was created by a C<use> or C<require> statement
4008
4009 =item * C<$hints>
4010
4011 pragma information; subject to change between versions
4012
4013 =item * C<$bitmask>
4014
4015 pragma information; subject to change between versions
4016
4017 =item * C<@DB::args>
4018
4019 arguments with which the subroutine was invoked
4020
4021 =back
4022
4023 =cut
4024
4025 use vars qw($deep);
4026
4027 # We need to fully qualify the name ("DB::sub") to make "use strict;"
4028 # happy. -- Shlomi Fish
4029
4030 sub _indent_print_line_info {
4031     my ($offset, $str) = @_;
4032
4033     print_lineinfo( ' ' x ($stack_depth - $offset), $str);
4034
4035     return;
4036 }
4037
4038 sub _print_frame_message {
4039     my ($al) = @_;
4040
4041     if ($frame) {
4042         if ($frame & 4) {   # Extended frame entry message
4043             _indent_print_line_info(-1, "in  ");
4044
4045             # Why -1? But it works! :-(
4046             # Because print_trace will call add 1 to it and then call
4047             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4048             # in dump_trace.
4049             #
4050             # Now it's 0 because we extracted a function.
4051             print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4052         }
4053         else {
4054             _indent_print_line_info(-1, "entering $sub$al\n" );
4055         }
4056     }
4057
4058     return;
4059 }
4060
4061 sub DB::sub {
4062     # Do not use a regex in this subroutine -> results in corrupted memory
4063     # See: [perl #66110]
4064
4065     # lock ourselves under threads
4066     lock($DBGR);
4067
4068     # Whether or not the autoloader was running, a scalar to put the
4069     # sub's return value in (if needed), and an array to put the sub's
4070     # return value in (if needed).
4071     my ( $al, $ret, @ret ) = "";
4072     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
4073         print "creating new thread\n";
4074     }
4075
4076     # If the last ten characters are '::AUTOLOAD', note we've traced
4077     # into AUTOLOAD for $sub.
4078     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4079         no strict 'refs';
4080         $al = " for $$sub" if defined $$sub;
4081     }
4082
4083     # We stack the stack pointer and then increment it to protect us
4084     # from a situation that might unwind a whole bunch of call frames
4085     # at once. Localizing the stack pointer means that it will automatically
4086     # unwind the same amount when multiple stack frames are unwound.
4087     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4088
4089     # Expand @stack.
4090     $#stack = $stack_depth;
4091
4092     # Save current single-step setting.
4093     $stack[-1] = $single;
4094
4095     # Turn off all flags except single-stepping.
4096     $single &= 1;
4097
4098     # If we've gotten really deeply recursed, turn on the flag that will
4099     # make us stop with the 'deep recursion' message.
4100     $single |= 4 if $stack_depth == $deep;
4101
4102     # If frame messages are on ...
4103
4104     _print_frame_message($al);
4105     # standard frame entry message
4106
4107     my $print_exit_msg = sub {
4108         # Check for exit trace messages...
4109         if ($frame & 2)
4110         {
4111             if ($frame & 4)    # Extended exit message
4112             {
4113                 _indent_print_line_info(0, "out ");
4114                 print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4115             }
4116             else
4117             {
4118                 _indent_print_line_info(0, "exited $sub$al\n" );
4119             }
4120         }
4121         return;
4122     };
4123
4124     # Determine the sub's return type, and capture appropriately.
4125     if (wantarray) {
4126
4127         # Called in array context. call sub and capture output.
4128         # DB::DB will recursively get control again if appropriate; we'll come
4129         # back here when the sub is finished.
4130         {
4131             no strict 'refs';
4132             @ret = &$sub;
4133         }
4134
4135         # Pop the single-step value back off the stack.
4136         $single |= $stack[ $stack_depth-- ];
4137
4138         $print_exit_msg->();
4139
4140         # Print the return info if we need to.
4141         if ( $doret eq $stack_depth or $frame & 16 ) {
4142
4143             # Turn off output record separator.
4144             local $\ = '';
4145             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4146
4147             # Indent if we're printing because of $frame tracing.
4148             if ($frame & 16)
4149             {
4150                 print {$fh} ' ' x $stack_depth;
4151             }
4152
4153             # Print the return value.
4154             print {$fh} "list context return from $sub:\n";
4155             dumpit( $fh, \@ret );
4156
4157             # And don't print it again.
4158             $doret = -2;
4159         } ## end if ($doret eq $stack_depth...
4160             # And we have to return the return value now.
4161         @ret;
4162     } ## end if (wantarray)
4163
4164     # Scalar context.
4165     else {
4166         if ( defined wantarray ) {
4167             no strict 'refs';
4168             # Save the value if it's wanted at all.
4169             $ret = &$sub;
4170         }
4171         else {
4172             no strict 'refs';
4173             # Void return, explicitly.
4174             &$sub;
4175             undef $ret;
4176         }
4177
4178         # Pop the single-step value off the stack.
4179         $single |= $stack[ $stack_depth-- ];
4180
4181         # If we're doing exit messages...
4182         $print_exit_msg->();
4183
4184         # If we are supposed to show the return value... same as before.
4185         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
4186             local $\ = '';
4187             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4188             print $fh ( ' ' x $stack_depth ) if $frame & 16;
4189             print $fh (
4190                 defined wantarray
4191                 ? "scalar context return from $sub: "
4192                 : "void context return from $sub\n"
4193             );
4194             dumpit( $fh, $ret ) if defined wantarray;
4195             $doret = -2;
4196         } ## end if ($doret eq $stack_depth...
4197
4198         # Return the appropriate scalar value.
4199         $ret;
4200     } ## end else [ if (wantarray)
4201 } ## end sub _sub
4202
4203 sub lsub : lvalue {
4204
4205     no strict 'refs';
4206
4207     # lock ourselves under threads
4208     lock($DBGR);
4209
4210     # Whether or not the autoloader was running, a scalar to put the
4211     # sub's return value in (if needed), and an array to put the sub's
4212     # return value in (if needed).
4213     my ( $al, $ret, @ret ) = "";
4214     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
4215         print "creating new thread\n";
4216     }
4217
4218     # If the last ten characters are C'::AUTOLOAD', note we've traced
4219     # into AUTOLOAD for $sub.
4220     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4221         $al = " for $$sub";
4222     }
4223
4224     # We stack the stack pointer and then increment it to protect us
4225     # from a situation that might unwind a whole bunch of call frames
4226     # at once. Localizing the stack pointer means that it will automatically
4227     # unwind the same amount when multiple stack frames are unwound.
4228     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4229
4230     # Expand @stack.
4231     $#stack = $stack_depth;
4232
4233     # Save current single-step setting.
4234     $stack[-1] = $single;
4235
4236     # Turn off all flags except single-stepping.
4237     $single &= 1;
4238
4239     # If we've gotten really deeply recursed, turn on the flag that will
4240     # make us stop with the 'deep recursion' message.
4241     $single |= 4 if $stack_depth == $deep;
4242
4243     # If frame messages are on ...
4244     _print_frame_message($al);
4245
4246     # Pop the single-step value back off the stack.
4247     $single |= $stack[ $stack_depth-- ];
4248
4249     # call the original lvalue sub.
4250     &$sub;
4251 }
4252
4253 # Abstracting common code from multiple places elsewhere:
4254 sub depth_print_lineinfo {
4255     my $always_print = shift;
4256
4257     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4258 }
4259
4260 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4261
4262 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4263 Most of the changes were to systematize the command structure and to eliminate
4264 commands that threw away user input without checking.
4265
4266 The following sections describe the code added to make it easy to support
4267 multiple command sets with conflicting command names. This section is a start
4268 at unifying all command processing to make it simpler to develop commands.
4269
4270 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4271 number, and C<$dbline> (the current line) as arguments.
4272
4273 Support functions in this section which have multiple modes of failure C<die>
4274 on error; the rest simply return a false value.
4275
4276 The user-interface functions (all of the C<cmd_*> functions) just output
4277 error messages.
4278
4279 =head2 C<%set>
4280
4281 The C<%set> hash defines the mapping from command letter to subroutine
4282 name suffix.
4283
4284 C<%set> is a two-level hash, indexed by set name and then by command name.
4285 Note that trying to set the CommandSet to C<foobar> simply results in the
4286 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4287
4288 =cut
4289
4290 ### The API section
4291
4292 my %set = (    #
4293     'pre580' => {
4294         'a' => 'pre580_a',
4295         'A' => 'pre580_null',
4296         'b' => 'pre580_b',
4297         'B' => 'pre580_null',
4298         'd' => 'pre580_null',
4299         'D' => 'pre580_D',
4300         'h' => 'pre580_h',
4301         'M' => 'pre580_null',
4302         'O' => 'o',
4303         'o' => 'pre580_null',
4304         'v' => 'M',
4305         'w' => 'v',
4306         'W' => 'pre580_W',
4307     },
4308     'pre590' => {
4309         '<'  => 'pre590_prepost',
4310         '<<' => 'pre590_prepost',
4311         '>'  => 'pre590_prepost',
4312         '>>' => 'pre590_prepost',
4313         '{'  => 'pre590_prepost',
4314         '{{' => 'pre590_prepost',
4315     },
4316 );
4317
4318 my %breakpoints_data;
4319
4320 sub _has_breakpoint_data_ref {
4321     my ($filename, $line) = @_;
4322
4323     return (
4324         exists( $breakpoints_data{$filename} )
4325             and
4326         exists( $breakpoints_data{$filename}{$line} )
4327     );
4328 }
4329
4330 sub _get_breakpoint_data_ref {
4331     my ($filename, $line) = @_;
4332
4333     return ($breakpoints_data{$filename}{$line} ||= +{});
4334 }
4335
4336 sub _delete_breakpoint_data_ref {
4337     my ($filename, $line) = @_;
4338
4339     delete($breakpoints_data{$filename}{$line});
4340     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4341         delete($breakpoints_data{$filename});
4342     }
4343
4344     return;
4345 }
4346
4347 sub _set_breakpoint_enabled_status {
4348     my ($filename, $line, $status) = @_;
4349
4350     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4351         ($status ? 1 : '')
4352         ;
4353
4354     return;
4355 }
4356
4357 sub _enable_breakpoint_temp_enabled_status {
4358     my ($filename, $line) = @_;
4359
4360     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4361
4362     return;
4363 }
4364
4365 sub _cancel_breakpoint_temp_enabled_status {
4366     my ($filename, $line) = @_;
4367
4368     my $ref = _get_breakpoint_data_ref($filename, $line);
4369
4370     delete ($ref->{'temp_enabled'});
4371
4372     if (! %$ref) {
4373         _delete_breakpoint_data_ref($filename, $line);
4374     }
4375
4376     return;
4377 }
4378
4379 sub _is_breakpoint_enabled {
4380     my ($filename, $line) = @_;
4381
4382     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4383     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4384 }
4385
4386 =head2 C<cmd_wrapper()> (API)
4387
4388 C<cmd_wrapper()> allows the debugger to switch command sets
4389 depending on the value of the C<CommandSet> option.
4390
4391 It tries to look up the command in the C<%set> package-level I<lexical>
4392 (which means external entities can't fiddle with it) and create the name of
4393 the sub to call based on the value found in the hash (if it's there). I<All>
4394 of the commands to be handled in a set have to be added to C<%set>; if they
4395 aren't found, the 5.8.0 equivalent is called (if there is one).
4396
4397 This code uses symbolic references.
4398
4399 =cut
4400
4401 sub cmd_wrapper {
4402     my $cmd      = shift;
4403     my $line     = shift;
4404     my $dblineno = shift;
4405
4406     # Assemble the command subroutine's name by looking up the
4407     # command set and command name in %set. If we can't find it,
4408     # default to the older version of the command.
4409     my $call = 'cmd_'
4410       . ( $set{$CommandSet}{$cmd}
4411           || ( $cmd =~ /\A[<>{]+/o ? 'prepost' : $cmd ) );
4412
4413     # Call the command subroutine, call it by name.
4414     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4415 } ## end sub cmd_wrapper
4416
4417 =head3 C<cmd_a> (command)
4418
4419 The C<a> command handles pre-execution actions. These are associated with a
4420 particular line, so they're stored in C<%dbline>. We default to the current
4421 line if none is specified.
4422
4423 =cut
4424
4425 sub cmd_a {
4426     my $cmd    = shift;
4427     my $line   = shift || '';    # [.|line] expr
4428     my $dbline = shift;
4429
4430     # If it's dot (here), or not all digits,  use the current line.
4431     $line =~ s/\A\./$dbline/;
4432
4433     # Should be a line number followed by an expression.
4434     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4435
4436         if (! length($lineno)) {
4437             $lineno = $dbline;
4438         }
4439
4440         # If we have an expression ...
4441         if ( length $expr ) {
4442
4443             # ... but the line isn't breakable, complain.
4444             if ( $dbline[$lineno] == 0 ) {
4445                 print $OUT
4446                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4447             }
4448             else {
4449
4450                 # It's executable. Record that the line has an action.
4451                 $had_breakpoints{$filename} |= 2;
4452
4453                 # Remove any action, temp breakpoint, etc.
4454                 $dbline{$lineno} =~ s/\0[^\0]*//;
4455
4456                 # Add the action to the line.
4457                 $dbline{$lineno} .= "\0" . action($expr);
4458
4459                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4460             }
4461         } ## end if (length $expr)
4462     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4463     else {
4464
4465         # Syntax wrong.
4466         print $OUT
4467           "Adding an action requires an optional lineno and an expression\n"
4468           ;    # hint
4469     }
4470 } ## end sub cmd_a
4471
4472 =head3 C<cmd_A> (command)
4473
4474 Delete actions. Similar to above, except the delete code is in a separate
4475 subroutine, C<delete_action>.
4476
4477 =cut
4478
4479 sub cmd_A {
4480     my $cmd    = shift;
4481     my $line   = shift || '';
4482     my $dbline = shift;
4483
4484     # Dot is this line.
4485     $line =~ s/^\./$dbline/;
4486
4487     # Call delete_action with a null param to delete them all.
4488     # The '1' forces the eval to be true. It'll be false only
4489     # if delete_action blows up for some reason, in which case
4490     # we print $@ and get out.
4491     if ( $line eq '*' ) {
4492         if (! eval { _delete_all_actions(); 1 }) {
4493             print {$OUT} $@;
4494             return;
4495         }
4496     }
4497
4498     # There's a real line  number. Pass it to delete_action.
4499     # Error trapping is as above.
4500     elsif ( $line =~ /^(\S.*)/ ) {
4501         if (! eval { delete_action($1); 1 }) {
4502             print {$OUT} $@;
4503             return;
4504         }
4505     }
4506
4507     # Swing and a miss. Bad syntax.
4508     else {
4509         print $OUT
4510           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4511     }
4512 } ## end sub cmd_A
4513
4514 =head3 C<delete_action> (API)
4515
4516 C<delete_action> accepts either a line number or C<undef>. If a line number
4517 is specified, we check for the line being executable (if it's not, it
4518 couldn't have had an  action). If it is, we just take the action off (this
4519 will get any kind of an action, including breakpoints).
4520
4521 =cut
4522
4523 sub _remove_action_from_dbline {
4524     my $i = shift;
4525
4526     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4527     delete $dbline{$i} if $dbline{$i} eq '';
4528
4529     return;
4530 }
4531
4532 sub _delete_all_actions {
4533     print {$OUT} "Deleting all actions...\n";
4534
4535     for my $file ( keys %had_breakpoints ) {
4536         local *dbline = $main::{ '_<' . $file };
4537         $max = $#dbline;
4538         my $was;
4539         for my $i (1 .. $max) {
4540             if ( defined $dbline{$i} ) {
4541                 _remove_action_from_dbline($i);
4542             }
4543         }
4544
4545         unless ( $had_breakpoints{$file} &= ~2 ) {
4546             delete $had_breakpoints{$file};
4547         }
4548     }
4549
4550     return;
4551 }
4552
4553 sub delete_action {
4554     my $i = shift;
4555
4556     if ( defined($i) ) {
4557         # Can there be one?
4558         die "Line $i has no action .\n" if $dbline[$i] == 0;
4559
4560         # Nuke whatever's there.
4561         _remove_action_from_dbline($i);
4562     }
4563     else {
4564         _delete_all_actions();
4565     }
4566 }
4567
4568 =head3 C<cmd_b> (command)
4569
4570 Set breakpoints. Since breakpoints can be set in so many places, in so many
4571 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4572 we try to parse the command type, and then shuttle it off to an appropriate
4573 subroutine to actually do the work of setting the breakpoint in the right
4574 place.
4575
4576 =cut
4577
4578 sub cmd_b {
4579     my $cmd    = shift;
4580     my $line   = shift;    # [.|line] [cond]
4581     my $dbline = shift;
4582
4583     my $default_cond = sub {
4584         my $cond = shift;
4585         return length($cond) ? $cond : '1';
4586     };
4587
4588     # Make . the current line number if it's there..
4589     $line =~ s/^\.(\s|\z)/$dbline$1/;
4590
4591     # No line number, no condition. Simple break on current line.
4592     if ( $line =~ /^\s*$/ ) {
4593         cmd_b_line( $dbline, 1 );
4594     }
4595
4596     # Break on load for a file.
4597     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4598         $file =~ s/\s+\z//;
4599         cmd_b_load($file);
4600     }
4601
4602     # b compile|postpone <some sub> [<condition>]
4603     # The interpreter actually traps this one for us; we just put the
4604     # necessary condition in the %postponed hash.
4605     elsif ( my ($action, $subname, $cond)
4606         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4607
4608         # De-Perl4-ify the name - ' separators to ::.
4609         $subname =~ s/'/::/g;
4610
4611         # Qualify it into the current package unless it's already qualified.
4612         $subname = "${package}::" . $subname unless $subname =~ /::/;
4613
4614         # Add main if it starts with ::.
4615         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4616
4617         # Save the break type for this sub.
4618         $postponed{$subname} = (($action eq 'postpone')
4619             ? ( "break +0 if " . $default_cond->($cond) )
4620             : "compile");
4621     } ## end elsif ($line =~ ...
4622     # b <filename>:<line> [<condition>]
4623     elsif (my ($filename, $line_num, $cond)
4624         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4625         cmd_b_filename_line(
4626             $filename,
4627             $line_num,
4628             (length($cond) ? $cond : '1'),
4629         );
4630     }
4631     # b <sub name> [<condition>]
4632     elsif ( my ($new_subname, $new_cond) =
4633         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4634
4635         #
4636         $subname = $new_subname;
4637         cmd_b_sub( $subname, $default_cond->($new_cond) );
4638     }
4639
4640     # b <line> [<condition>].
4641     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4642
4643         # Capture the line. If none, it's the current line.
4644         $line = $line_n || $dbline;
4645
4646         # Break on line.
4647         cmd_b_line( $line, $default_cond->($cond) );
4648     }
4649
4650     # Line didn't make sense.
4651     else {
4652         print "confused by line($line)?\n";
4653     }
4654
4655     return;
4656 } ## end sub cmd_b
4657
4658 =head3 C<break_on_load> (API)
4659
4660 We want to break when this file is loaded. Mark this file in the
4661 C<%break_on_load> hash, and note that it has a breakpoint in
4662 C<%had_breakpoints>.
4663
4664 =cut
4665
4666 sub break_on_load {
4667     my $file = shift;
4668     $break_on_load{$file} = 1;
4669     $had_breakpoints{$file} |= 1;
4670 }
4671
4672 =head3 C<report_break_on_load> (API)
4673
4674 Gives us an array of filenames that are set to break on load. Note that
4675 only files with break-on-load are in here, so simply showing the keys
4676 suffices.
4677
4678 =cut
4679
4680 sub report_break_on_load {
4681     sort keys %break_on_load;
4682 }
4683
4684 =head3 C<cmd_b_load> (command)
4685
4686 We take the file passed in and try to find it in C<%INC> (which maps modules
4687 to files they came from). We mark those files for break-on-load via
4688 C<break_on_load> and then report that it was done.
4689
4690 =cut
4691
4692 sub cmd_b_load {
4693     my $file = shift;
4694     my @files;
4695
4696     # This is a block because that way we can use a redo inside it
4697     # even without there being any looping structure at all outside it.
4698     {
4699
4700         # Save short name and full path if found.
4701         push @files, $file;
4702         push @files, $::INC{$file} if $::INC{$file};
4703
4704         # Tack on .pm and do it again unless there was a '.' in the name
4705         # already.
4706         $file .= '.pm', redo unless $file =~ /\./;
4707     }
4708
4709     # Do the real work here.
4710     break_on_load($_) for @files;
4711
4712     # All the files that have break-on-load breakpoints.
4713     @files = report_break_on_load;
4714
4715     # Normalize for the purposes of our printing this.
4716     local $\ = '';
4717     local $" = ' ';
4718     print $OUT "Will stop on load of '@files'.\n";
4719 } ## end sub cmd_b_load
4720
4721 =head3 C<$filename_error> (API package global)
4722
4723 Several of the functions we need to implement in the API need to work both
4724 on the current file and on other files. We don't want to duplicate code, so
4725 C<$filename_error> is used to contain the name of the file that's being
4726 worked on (if it's not the current one).
4727
4728 We can now build functions in pairs: the basic function works on the current
4729 file, and uses C<$filename_error> as part of its error message. Since this is
4730 initialized to C<"">, no filename will appear when we are working on the
4731 current file.
4732
4733 The second function is a wrapper which does the following:
4734
4735 =over 4
4736
4737 =item *
4738
4739 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4740
4741 =item *
4742
4743 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4744
4745 =item *
4746
4747 Calls the first function.
4748
4749 The first function works on the I<current> file (i.e., the one we changed to),
4750 and prints C<$filename_error> in the error message (the name of the other file)
4751 if it needs to. When the functions return, C<*dbline> is restored to point
4752 to the actual current file (the one we're executing in) and
4753 C<$filename_error> is restored to C<"">. This restores everything to
4754 the way it was before the second function was called at all.
4755
4756 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4757 details.
4758
4759 =back
4760
4761 =cut
4762
4763 use vars qw($filename_error);
4764 $filename_error = '';
4765
4766 =head3 breakable_line(from, to) (API)
4767
4768 The subroutine decides whether or not a line in the current file is breakable.
4769 It walks through C<@dbline> within the range of lines specified, looking for
4770 the first line that is breakable.
4771
4772 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4773 first line I<after> C<$to> that's breakable, if there is one.
4774
4775 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4776 first line I<before> C<$to> that's breakable, if there is one.
4777
4778 =cut
4779
4780 sub breakable_line {
4781
4782     my ( $from, $to ) = @_;
4783
4784     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4785     my $i = $from;
4786
4787     # If there are at least 2 arguments, we're trying to search a range.
4788     if ( @_ >= 2 ) {
4789
4790         # $delta is positive for a forward search, negative for a backward one.
4791         my $delta = $from < $to ? +1 : -1;
4792
4793         # Keep us from running off the ends of the file.
4794         my $limit = $delta > 0 ? $#dbline : 1;
4795
4796         # Clever test. If you're a mathematician, it's obvious why this
4797         # test works. If not:
4798         # If $delta is positive (going forward), $limit will be $#dbline.
4799         #    If $to is less than $limit, ($limit - $to) will be positive, times
4800         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4801         #    as the stopping point.
4802         #
4803         #    If $to is greater than $limit, ($limit - $to) is negative,
4804         #    times $delta of 1 (positive), so the result is < 0 and we should
4805         #    use $limit ($#dbline) as the stopping point.
4806         #
4807         # If $delta is negative (going backward), $limit will be 1.
4808         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4809         #    (negative) so the result is > 0, and we use $to as the stopping
4810         #    point.
4811         #
4812         #    If $to is less than zero, ($limit - $to) will be positive,
4813         #    times $delta of -1 (negative), so the result is not > 0, and
4814         #    we use $limit (1) as the stopping point.
4815         #
4816         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4817         #    (negative), still giving zero; the result is not > 0, and
4818         #    we use $limit (1) as the stopping point.
4819         #
4820         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4821         #    (negative), giving a positive (>0) value, so we'll set $limit to
4822         #    $to.
4823
4824         $limit = $to if ( $limit - $to ) * $delta > 0;
4825
4826         # The real search loop.
4827         # $i starts at $from (the point we want to start searching from).
4828         # We move through @dbline in the appropriate direction (determined
4829         # by $delta: either -1 (back) or +1 (ahead).
4830         # We stay in as long as we haven't hit an executable line
4831         # ($dbline[$i] == 0 means not executable) and we haven't reached
4832         # the limit yet (test similar to the above).
4833         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4834
4835     } ## end if (@_ >= 2)
4836
4837     # If $i points to a line that is executable, return that.
4838     return $i unless $dbline[$i] == 0;
4839
4840     # Format the message and print it: no breakable lines in range.
4841     my ( $pl, $upto ) = ( '', '' );
4842     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4843
4844     # If there's a filename in filename_error, we'll see it.
4845     # If not, not.
4846     die "Line$pl $from$upto$filename_error not breakable\n";
4847 } ## end sub breakable_line
4848
4849 =head3 breakable_line_in_filename(file, from, to) (API)
4850
4851 Like C<breakable_line>, but look in another file.
4852
4853 =cut
4854
4855 sub breakable_line_in_filename {
4856
4857     # Capture the file name.
4858     my ($f) = shift;
4859
4860     # Swap the magic line array over there temporarily.
4861     local *dbline = $main::{ '_<' . $f };
4862
4863     # If there's an error, it's in this other file.
4864     local $filename_error = " of '$f'";
4865
4866     # Find the breakable line.
4867     breakable_line(@_);
4868
4869     # *dbline and $filename_error get restored when this block ends.
4870
4871 } ## end sub breakable_line_in_filename
4872
4873 =head3 break_on_line(lineno, [condition]) (API)
4874
4875 Adds a breakpoint with the specified condition (or 1 if no condition was
4876 specified) to the specified line. Dies if it can't.
4877
4878 =cut
4879
4880 sub break_on_line {
4881     my $i = shift;
4882     my $cond = @_ ? shift(@_) : 1;
4883
4884     my $inii  = $i;
4885     my $after = '';
4886     my $pl    = '';
4887
4888     # Woops, not a breakable line. $filename_error allows us to say
4889     # if it was in a different file.
4890     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4891
4892     # Mark this file as having breakpoints in it.
4893     $had_breakpoints{$filename} |= 1;
4894
4895     # If there is an action or condition here already ...
4896     if ( $dbline{$i} ) {
4897
4898         # ... swap this condition for the existing one.
4899         $dbline{$i} =~ s/^[^\0]*/$cond/;
4900     }
4901     else {
4902
4903         # Nothing here - just add the condition.
4904         $dbline{$i} = $cond;
4905
4906         _set_breakpoint_enabled_status($filename, $i, 1);
4907     }
4908
4909     return;
4910 } ## end sub break_on_line
4911
4912 =head3 cmd_b_line(line, [condition]) (command)
4913
4914 Wrapper for C<break_on_line>. Prints the failure message if it
4915 doesn't work.
4916
4917 =cut
4918
4919 sub cmd_b_line {
4920     if (not eval { break_on_line(@_); 1 }) {
4921         local $\ = '';
4922         print $OUT $@ and return;
4923     }
4924
4925     return;
4926 } ## end sub cmd_b_line
4927
4928 =head3 cmd_b_filename_line(line, [condition]) (command)
4929
4930 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4931 doesn't work.
4932
4933 =cut
4934
4935 sub cmd_b_filename_line {
4936     if (not eval { break_on_filename_line(@_); 1 }) {
4937         local $\ = '';
4938         print $OUT $@ and return;
4939     }
4940
4941     return;
4942 }
4943
4944 =head3 break_on_filename_line(file, line, [condition]) (API)
4945
4946 Switches to the file specified and then calls C<break_on_line> to set
4947 the breakpoint.
4948
4949 =cut
4950
4951 sub break_on_filename_line {
4952     my $f = shift;
4953     my $i = shift;
4954     my $cond = @_ ? shift(@_) : 1;
4955
4956     # Switch the magical hash temporarily.
4957     local *dbline = $main::{ '_<' . $f };
4958
4959     # Localize the variables that break_on_line uses to make its message.
4960     local $filename_error = " of '$f'";
4961     local $filename       = $f;
4962
4963     # Add the breakpoint.
4964     break_on_line( $i, $cond );
4965
4966     return;
4967 } ## end sub break_on_filename_line
4968
4969 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4970
4971 Switch to another file, search the range of lines specified for an
4972 executable one, and put a breakpoint on the first one you find.
4973
4974 =cut
4975
4976 sub break_on_filename_line_range {
4977     my $f = shift;
4978     my $from = shift;
4979     my $to = shift;
4980     my $cond = @_ ? shift(@_) : 1;
4981
4982     # Find a breakable line if there is one.
4983     my $i = breakable_line_in_filename( $f, $from, $to );
4984
4985     # Add the breakpoint.
4986     break_on_filename_line( $f, $i, $cond );
4987
4988     return;
4989 } ## end sub break_on_filename_line_range
4990
4991 =head3 subroutine_filename_lines(subname, [condition]) (API)
4992
4993 Search for a subroutine within a given file. The condition is ignored.
4994 Uses C<find_sub> to locate the desired subroutine.
4995
4996 =cut
4997
4998 sub subroutine_filename_lines {
4999     my ( $subname ) = @_;
5000
5001     # Returned value from find_sub() is fullpathname:startline-endline.
5002     # The match creates the list (fullpathname, start, end).
5003     return (find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/);
5004 } ## end sub subroutine_filename_lines
5005
5006 =head3 break_subroutine(subname) (API)
5007
5008 Places a break on the first line possible in the specified subroutine. Uses
5009 C<subroutine_filename_lines> to find the subroutine, and
5010 C<break_on_filename_line_range> to place the break.
5011
5012 =cut
5013
5014 sub break_subroutine {
5015     my $subname = shift;
5016
5017     # Get filename, start, and end.
5018     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
5019       or die "Subroutine $subname not found.\n";
5020
5021
5022     # Null condition changes to '1' (always true).
5023     my $cond = @_ ? shift(@_) : 1;
5024
5025     # Put a break the first place possible in the range of lines
5026     # that make up this subroutine.
5027     break_on_filename_line_range( $file, $s, $e, $cond );
5028
5029     return;
5030 } ## end sub break_subroutine
5031
5032 =head3 cmd_b_sub(subname, [condition]) (command)
5033
5034 We take the incoming subroutine name and fully-qualify it as best we can.
5035
5036 =over 4
5037
5038 =item 1. If it's already fully-qualified, leave it alone.
5039
5040 =item 2. Try putting it in the current package.
5041
5042 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
5043
5044 =item 4. If it starts with '::', put it in 'main::'.
5045
5046 =back
5047
5048 After all this cleanup, we call C<break_subroutine> to try to set the
5049 breakpoint.
5050
5051 =cut
5052
5053 sub cmd_b_sub {
5054     my $subname = shift;
5055     my $cond = @_ ? shift : 1;
5056
5057     # If the subname isn't a code reference, qualify it so that
5058     # break_subroutine() will work right.
5059     if ( ref($subname) ne 'CODE' ) {
5060
5061         # Not Perl 4.
5062         $subname =~ s/'/::/g;
5063         my $s = $subname;
5064
5065         # Put it in this package unless it's already qualified.
5066         if ($subname !~ /::/)
5067         {
5068             $subname = $package . '::' . $subname;
5069         };
5070
5071         # Requalify it into CORE::GLOBAL if qualifying it into this
5072         # package resulted in its not being defined, but only do so
5073         # if it really is in CORE::GLOBAL.
5074         my $core_name = "CORE::GLOBAL::$s";
5075         if ((!defined(&$subname))
5076                 and ($s !~ /::/)
5077                 and (defined &{$core_name}))
5078         {
5079             $subname = $core_name;
5080         }
5081
5082         # Put it in package 'main' if it has a leading ::.
5083         if ($subname =~ /\A::/)
5084         {
5085             $subname = "main" . $subname;
5086         }
5087     } ## end if ( ref($subname) ne 'CODE' ) {
5088
5089     # Try to set the breakpoint.
5090     if (not eval { break_subroutine( $subname, $cond ); 1 }) {
5091         local $\ = '';
5092         print {$OUT} $@;
5093         return;
5094     }
5095
5096     return;
5097 } ## end sub cmd_b_sub
5098
5099 =head3 C<cmd_B> - delete breakpoint(s) (command)
5100
5101 The command mostly parses the command line and tries to turn the argument
5102 into a line spec. If it can't, it uses the current line. It then calls
5103 C<delete_breakpoint> to actually do the work.
5104
5105 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
5106 thereby deleting all the breakpoints.
5107
5108 =cut
5109
5110 sub cmd_B {
5111     my $cmd = shift;
5112
5113     # No line spec? Use dbline.
5114     # If there is one, use it if it's non-zero, or wipe it out if it is.
5115     my $line   = ( $_[0] =~ /\A\./ ) ? $dbline : (shift || '');
5116     my $dbline = shift;
5117
5118     # If the line was dot, make the line the current one.
5119     $line =~ s/^\./$dbline/;
5120
5121     # If it's * we're deleting all the breakpoints.
5122     if ( $line eq '*' ) {
5123         if (not eval { delete_breakpoint(); 1 }) {
5124             print {$OUT} $@;
5125         }
5126     }
5127
5128     # If there is a line spec, delete the breakpoint on that line.
5129     elsif ( $line =~ /\A(\S.*)/ ) {
5130         if (not eval { delete_breakpoint( $line || $dbline ); 1 }) {
5131             local $\ = '';
5132             print {$OUT} $@;
5133         }
5134     } ## end elsif ($line =~ /^(\S.*)/)
5135
5136     # No line spec.
5137     else {
5138         print {$OUT}
5139           "Deleting a breakpoint requires a line number, or '*' for all\n"
5140           ;    # hint
5141     }
5142
5143     return;
5144 } ## end sub cmd_B
5145
5146 =head3 delete_breakpoint([line]) (API)
5147
5148 This actually does the work of deleting either a single breakpoint, or all
5149 of them.
5150
5151 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
5152 just drop out with a message saying so. If it is, we remove the condition
5153 part of the 'condition\0action' that says there's a breakpoint here. If,
5154 after we've done that, there's nothing left, we delete the corresponding
5155 line in C<%dbline> to signal that no action needs to be taken for this line.
5156
5157 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
5158 which lists all currently-loaded files which have breakpoints. We then look
5159 at each line in each of these files, temporarily switching the C<%dbline>
5160 and C<@dbline> structures to point to the files in question, and do what
5161 we did in the single line case: delete the condition in C<@dbline>, and
5162 delete the key in C<%dbline> if nothing's left.
5163
5164 We then wholesale delete C<%postponed>, C<%postponed_file>, and
5165 C<%break_on_load>, because these structures contain breakpoints for files
5166 and code that haven't been loaded yet. We can just kill these off because there
5167 are no magical debugger structures associated with them.
5168
5169 =cut
5170
5171 sub _remove_breakpoint_entry {
5172     my ($fn, $i) = @_;
5173
5174     delete $dbline{$i};
5175     _delete_breakpoint_data_ref($fn, $i);
5176
5177     return;
5178 }
5179
5180 sub _delete_all_breakpoints {
5181     print {$OUT} "Deleting all breakpoints...\n";
5182
5183     # %had_breakpoints lists every file that had at least one
5184     # breakpoint in it.
5185     for my $fn ( keys %had_breakpoints ) {
5186
5187         # Switch to the desired file temporarily.
5188         local *dbline = $main::{ '_<' . $fn };
5189
5190         $max = $#dbline;
5191
5192         # For all lines in this file ...
5193         for my $i (1 .. $max) {
5194
5195             # If there's a breakpoint or action on this line ...
5196             if ( defined $dbline{$i} ) {
5197
5198                 # ... remove the breakpoint.
5199                 $dbline{$i} =~ s/\A[^\0]+//;
5200                 if ( $dbline{$i} =~ s/\A\0?\z// ) {
5201                     # Remove the entry altogether if no action is there.
5202                     _remove_breakpoint_entry($fn, $i);
5203                 }
5204             } ## end if (defined $dbline{$i...
5205         } ## end for $i (1 .. $max)
5206
5207         # If, after we turn off the "there were breakpoints in this file"
5208         # bit, the entry in %had_breakpoints for this file is zero,
5209         # we should remove this file from the hash.
5210         if ( not $had_breakpoints{$fn} &= (~1) ) {
5211             delete $had_breakpoints{$fn};
5212         }
5213     } ## end for my $fn (keys %had_breakpoints)
5214
5215     # Kill off all the other breakpoints that are waiting for files that
5216     # haven't been loaded yet.
5217     undef %postponed;
5218     undef %postponed_file;
5219     undef %break_on_load;
5220
5221     return;
5222 }
5223
5224 sub _delete_breakpoint_from_line {
5225     my ($i) = @_;
5226
5227     # Woops. This line wasn't breakable at all.
5228     die "Line $i not breakable.\n" if $dbline[$i] == 0;
5229
5230     # Kill the condition, but leave any action.
5231     $dbline{$i} =~ s/\A[^\0]*//;
5232
5233     # Remove the entry entirely if there's no action left.
5234     if ($dbline{$i} eq '') {
5235         _remove_breakpoint_entry($filename, $i);
5236     }
5237
5238     return;
5239 }
5240
5241 sub delete_breakpoint {
5242     my $i = shift;
5243
5244     # If we got a line, delete just that one.
5245     if ( defined($i) ) {
5246         _delete_breakpoint_from_line($i);
5247     }
5248     # No line; delete them all.
5249     else {
5250         _delete_all_breakpoints();
5251     }
5252
5253     return;
5254 }
5255
5256 =head3 cmd_stop (command)
5257
5258 This is meant to be part of the new command API, but it isn't called or used
5259 anywhere else in the debugger. XXX It is probably meant for use in development
5260 of new commands.
5261
5262 =cut
5263
5264 sub cmd_stop {    # As on ^C, but not signal-safy.
5265     $signal = 1;
5266 }
5267
5268 =head3 C<cmd_e> - threads
5269
5270 Display the current thread id:
5271
5272     e
5273
5274 This could be how (when implemented) to send commands to this thread id (e cmd)
5275 or that thread id (e tid cmd).
5276
5277 =cut
5278
5279 sub cmd_e {
5280     my $cmd  = shift;
5281     my $line = shift;
5282     unless (exists($INC{'threads.pm'})) {
5283         print "threads not loaded($ENV{PERL5DB_THREADED})
5284         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5285     } else {
5286         my $tid = threads->tid;
5287         print "thread id: $tid\n";
5288     }
5289 } ## end sub cmd_e
5290
5291 =head3 C<cmd_E> - list of thread ids
5292
5293 Display the list of available thread ids:
5294
5295     E
5296
5297 This could be used (when implemented) to send commands to all threads (E cmd).
5298
5299 =cut
5300
5301 sub cmd_E {
5302     my $cmd  = shift;
5303     my $line = shift;
5304     unless (exists($INC{'threads.pm'})) {
5305         print "threads not loaded($ENV{PERL5DB_THREADED})
5306         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5307     } else {
5308         my $tid = threads->tid;
5309         print "thread ids: ".join(', ',
5310             map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
5311         )."\n";
5312     }
5313 } ## end sub cmd_E
5314
5315 =head3 C<cmd_h> - help command (command)
5316
5317 Does the work of either
5318
5319 =over 4
5320
5321 =item *
5322
5323 Showing all the debugger help
5324
5325 =item *
5326
5327 Showing help for a specific command
5328
5329 =back
5330
5331 =cut
5332
5333 use vars qw($help);
5334 use vars qw($summary);
5335
5336 sub cmd_h {
5337     my $cmd = shift;
5338
5339     # If we have no operand, assume null.
5340     my $line = shift || '';
5341
5342     # 'h h'. Print the long-format help.
5343     if ( $line =~ /\Ah\s*\z/ ) {
5344         print_help($help);
5345     }
5346
5347     # 'h <something>'. Search for the command and print only its help.
5348     elsif ( my ($asked) = $line =~ /\A(\S.*)\z/ ) {
5349
5350         # support long commands; otherwise bogus errors
5351         # happen when you ask for h on <CR> for example
5352         my $qasked = quotemeta($asked);    # for searching; we don't
5353                                            # want to use it as a pattern.
5354                                            # XXX: finds CR but not <CR>
5355
5356         # Search the help string for the command.
5357         if (
5358             $help =~ /^                    # Start of a line
5359                       <?                   # Optional '<'
5360                       (?:[IB]<)            # Optional markup
5361                       $qasked              # The requested command
5362                      /mx
5363           )
5364         {
5365
5366             # It's there; pull it out and print it.
5367             while (
5368                 $help =~ /^
5369                               (<?            # Optional '<'
5370                                  (?:[IB]<)   # Optional markup
5371                                  $qasked     # The command
5372                                  ([\s\S]*?)  # Description line(s)
5373                               \n)            # End of last description line
5374                               (?!\s)         # Next line not starting with
5375                                              # whitespace
5376                              /mgx
5377               )
5378             {
5379                 print_help($1);
5380             }
5381         }
5382
5383         # Not found; not a debugger command.
5384         else {
5385             print_help("B<$asked> is not a debugger command.\n");
5386         }
5387     } ## end elsif ($line =~ /^(\S.*)$/)
5388
5389     # 'h' - print the summary help.
5390     else {
5391         print_help($summary);
5392     }
5393 } ## end sub cmd_h
5394
5395 =head3 C<cmd_i> - inheritance display
5396
5397 Display the (nested) parentage of the module or object given.
5398
5399 =cut
5400
5401 sub cmd_i {
5402     my $cmd  = shift;
5403     my $line = shift;
5404     foreach my $isa ( split( /\s+/, $line ) ) {
5405         $evalarg = $isa;
5406         ($isa) = DB::eval();
5407         no strict 'refs';
5408         print join(
5409             ', ',
5410             map {
5411                 "$_"
5412                   . (
5413                     defined( ${"$_\::VERSION"} )
5414                     ? ' ' . ${"$_\::VERSION"}
5415                     : undef )
5416               } @{mro::get_linear_isa(ref($isa) || $isa)}
5417         );
5418         print "\n";
5419     }
5420 } ## end sub cmd_i
5421
5422 =head3 C<cmd_l> - list lines (command)
5423
5424 Most of the command is taken up with transforming all the different line
5425 specification syntaxes into 'start-stop'. After that is done, the command
5426 runs a loop over C<@dbline> for the specified range of lines. It handles
5427 the printing of each line and any markers (C<==E<gt>> for current line,
5428 C<b> for break on this line, C<a> for action on this line, C<:> for this
5429 line breakable).
5430
5431 We save the last line listed in the C<$start> global for further listing
5432 later.
5433
5434 =cut
5435
5436 sub cmd_l {
5437     my $current_line = $line;
5438     my $cmd  = shift;
5439     my $line = shift;
5440
5441     # If this is '-something', delete any spaces after the dash.
5442     $line =~ s/^-\s*$/-/;
5443
5444     # If the line is '$something', assume this is a scalar containing a
5445     # line number.
5446     if ( $line =~ /^(\$.*)/s ) {
5447
5448         # Set up for DB::eval() - evaluate in *user* context.
5449         $evalarg = $1;
5450         # $evalarg = $2;
5451         my ($s) = DB::eval();
5452
5453         # Ooops. Bad scalar.
5454         if ($@) {
5455             print {$OUT} "Error: $@\n";
5456             next CMD;
5457         }
5458
5459         # Good scalar. If it's a reference, find what it points to.
5460         $s = CvGV_name($s);
5461         print {$OUT} "Interpreted as: $1 $s\n";
5462         $line = "$1 $s";
5463
5464         # Call self recursively to really do the command.
5465         cmd_l( 'l', $s );
5466     } ## end if ($line =~ /^(\$.*)/s)
5467
5468     # l name. Try to find a sub by that name.
5469     elsif ( ($subname) = $line =~ /\A([\':A-Za-z_][\':\w]*(?:\[.*\])?)/s ) {
5470         my $s = $subname;
5471
5472         # De-Perl4.
5473         $subname =~ s/\'/::/;
5474
5475         # Put it in this package unless it starts with ::.
5476         $subname = $package . "::" . $subname unless $subname =~ /::/;
5477
5478         # Put it in CORE::GLOBAL if t doesn't start with :: and
5479         # it doesn't live in this package and it lives in CORE::GLOBAL.
5480         $subname = "CORE::GLOBAL::$s"
5481           if not defined &$subname
5482           and $s !~ /::/
5483           and defined &{"CORE::GLOBAL::$s"};
5484
5485         # Put leading '::' names into 'main::'.
5486         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
5487
5488         # Get name:start-stop from find_sub, and break this up at
5489         # colons.
5490         my @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
5491
5492         # Pull off start-stop.
5493         my $subrange = pop @pieces;
5494
5495         # If the name contained colons, the split broke it up.
5496         # Put it back together.
5497         $file = join( ':', @pieces );
5498
5499         # If we're not in that file, switch over to it.
5500         if ( $file ne $filename ) {
5501             print $OUT "Switching to file '$file'.\n"
5502               unless $slave_editor;
5503
5504             # Switch debugger's magic structures.
5505             *dbline   = $main::{ '_<' . $file };
5506             $max      = $#dbline;
5507             $filename = $file;
5508         } ## end if ($file ne $filename)
5509
5510         # Subrange is 'start-stop'. If this is less than a window full,
5511         # swap it to 'start+', which will list a window from the start point.
5512         if ($subrange) {
5513             if ( eval($subrange) < -$window ) {
5514                 $subrange =~ s/-.*/+/;
5515             }
5516
5517             # Call self recursively to list the range.
5518             $line = $subrange;
5519             cmd_l( 'l', $subrange );
5520         } ## end if ($subrange)
5521
5522         # Couldn't find it.
5523         else {
5524             print $OUT "Subroutine $subname not found.\n";
5525         }
5526     } ## end elsif ($line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s)
5527
5528     # Bare 'l' command.
5529     elsif ( $line !~ /\S/ ) {
5530
5531         # Compute new range to list.
5532         $incr = $window - 1;
5533         $line = $start . '-' . ( $start + $incr );
5534
5535         # Recurse to do it.
5536         cmd_l( 'l', $line );
5537     }
5538
5539     # l [start]+number_of_lines
5540     elsif ( my ($new_start, $new_incr) = $line =~ /\A(\d*)\+(\d*)\z/ ) {
5541
5542         # Don't reset start for 'l +nnn'.
5543         $start = $new_start if $new_start;
5544
5545         # Increment for list. Use window size if not specified.
5546         # (Allows 'l +' to work.)
5547         $incr = $new_incr;
5548         $incr = $window - 1 unless $incr;
5549
5550         # Create a line range we'll understand, and recurse to do it.
5551         $line = $start . '-' . ( $start + $incr );
5552         cmd_l( 'l', $line );
5553     } ## end elsif ($line =~ /^(\d*)\+(\d*)$/)
5554
5555     # l start-stop or l start,stop
5556     elsif ( $line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/ ) {
5557
5558         # Determine end point; use end of file if not specified.
5559         my $end = ( !defined $2 ) ? $max : ( $4 ? $4 : $2 );
5560
5561         # Go on to the end, and then stop.
5562         $end = $max if $end > $max;
5563
5564         # Determine start line.
5565         my $i    = $2;
5566         $i    = $line if $i eq '.';
5567         $i    = 1 if $i < 1;
5568         $incr = $end - $i;
5569
5570         # If we're running under a slave editor, force it to show the lines.
5571         if ($slave_editor) {
5572             print $OUT "\032\032$filename:$i:0\n";
5573             $i = $end;
5574         }
5575
5576         # We're doing it ourselves. We want to show the line and special
5577         # markers for:
5578         # - the current line in execution
5579         # - whether a line is breakable or not
5580         # - whether a line has a break or not
5581         # - whether a line has an action or not
5582         else {
5583             for ( ; $i <= $end ; $i++ ) {
5584
5585                 # Check for breakpoints and actions.
5586                 my ( $stop, $action );
5587                 ( $stop, $action ) = split( /\0/, $dbline{$i} )
5588                   if $dbline{$i};
5589
5590                 # ==> if this is the current line in execution,
5591                 # : if it's breakable.
5592                 my $arrow =
5593                   ( $i == $current_line and $filename eq $filename_ini )
5594                   ? '==>'
5595                   : ( $dbline[$i] + 0 ? ':' : ' ' );
5596
5597                 # Add break and action indicators.
5598                 $arrow .= 'b' if $stop;
5599                 $arrow .= 'a' if $action;
5600
5601                 # Print the line.
5602                 print $OUT "$i$arrow\t", $dbline[$i];
5603
5604                 # Move on to the next line. Drop out on an interrupt.
5605                 $i++, last if $signal;
5606             } ## end for (; $i <= $end ; $i++)
5607
5608             # Line the prompt up; print a newline if the last line listed
5609             # didn't have a newline.
5610             print $OUT "\n" unless $dbline[ $i - 1 ] =~ /\n$/;
5611         } ## end else [ if ($slave_editor)
5612
5613         # Save the point we last listed to in case another relative 'l'
5614         # command is desired. Don't let it run off the end.
5615         $start = $i;
5616         $start = $max if $start > $max;
5617     } ## end elsif ($line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/)
5618 } ## end sub cmd_l
5619
5620 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5621
5622 To list breakpoints, the command has to look determine where all of them are
5623 first. It starts a C<%had_breakpoints>, which tells us what all files have
5624 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5625 magic source and breakpoint data structures) to the file, and then look
5626 through C<%dbline> for lines with breakpoints and/or actions, listing them
5627 out. We look through C<%postponed> not-yet-compiled subroutines that have
5628 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5629 that have breakpoints.
5630
5631 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5632
5633 =cut
5634
5635 sub cmd_L {
5636     my $cmd = shift;
5637
5638     # If no argument, list everything. Pre-5.8.0 version always lists
5639     # everything
5640     my $arg = shift || 'abw';
5641     if ($CommandSet ne '580')
5642     {
5643         $arg = 'abw';
5644     }
5645
5646     # See what is wanted.
5647     my $action_wanted = ( $arg =~ /a/ ) ? 1 : 0;
5648     my $break_wanted  = ( $arg =~ /b/ ) ? 1 : 0;
5649     my $watch_wanted  = ( $arg =~ /w/ ) ? 1 : 0;
5650
5651     # Breaks and actions are found together, so we look in the same place
5652     # for both.
5653     if ( $break_wanted or $action_wanted ) {
5654
5655         # Look in all the files with breakpoints...
5656         for my $file ( keys %had_breakpoints ) {
5657
5658             # Temporary switch to this file.
5659             local *dbline = $main::{ '_<' . $file };
5660
5661             # Set up to look through the whole file.
5662             $max = $#dbline;
5663             my $was;    # Flag: did we print something
5664                         # in this file?
5665
5666             # For each line in the file ...
5667             for my $i (1 .. $max) {
5668
5669                 # We've got something on this line.
5670                 if ( defined $dbline{$i} ) {
5671
5672                     # Print the header if we haven't.
5673                     print $OUT "$file:\n" unless $was++;
5674
5675                     # Print the line.
5676                     print $OUT " $i:\t", $dbline[$i];
5677
5678                     # Pull out the condition and the action.
5679                     my ( $stop, $action ) = split( /\0/, $dbline{$i} );
5680
5681                     # Print the break if there is one and it's wanted.
5682                     print $OUT "   break if (", $stop, ")\n"
5683                       if $stop
5684                       and $break_wanted;
5685
5686                     # Print the action if there is one and it's wanted.
5687                     print $OUT "   action:  ", $action, "\n"
5688                       if $action
5689                       and $action_wanted;
5690
5691                     # Quit if the user hit interrupt.
5692                     last if $signal;
5693                 } ## end if (defined $dbline{$i...
5694             } ## end for my $i (1 .. $max)
5695         } ## end for my $file (keys %had_breakpoints)
5696     } ## end if ($break_wanted or $action_wanted)
5697
5698     # Look for breaks in not-yet-compiled subs:
5699     if ( %postponed and $break_wanted ) {
5700         print $OUT "Postponed breakpoints in subroutines:\n";
5701         my $subname;
5702         for $subname ( keys %postponed ) {
5703             print $OUT " $subname\t$postponed{$subname}\n";
5704             last if $signal;
5705         }
5706     } ## end if (%postponed and $break_wanted)
5707
5708     # Find files that have not-yet-loaded breaks:
5709     my @have = map {    # Combined keys
5710         keys %{ $postponed_file{$_} }
5711     } keys %postponed_file;
5712
5713     # If there are any, list them.
5714     if ( @have and ( $break_wanted or $action_wanted ) ) {
5715         print $OUT "Postponed breakpoints in files:\n";
5716         for my $file ( keys %postponed_file ) {
5717             my $db = $postponed_file{$file};
5718             print $OUT " $file:\n";
5719             for my $line ( sort { $a <=> $b } keys %$db ) {
5720                 print $OUT "  $line:\n";
5721                 my ( $stop, $action ) = split( /\0/, $$db{$line} );
5722                 print $OUT "    break if (", $stop, ")\n"
5723                   if $stop
5724                   and $break_wanted;
5725                 print $OUT "    action:  ", $action, "\n"
5726                   if $action
5727                   and $action_wanted;
5728                 last if $signal;
5729             } ## end for $line (sort { $a <=>...
5730             last if $signal;
5731         } ## end for $file (keys %postponed_file)
5732     } ## end if (@have and ($break_wanted...
5733     if ( %break_on_load and $break_wanted ) {
5734         print {$OUT} "Breakpoints on load:\n";
5735         BREAK_ON_LOAD: for my $filename ( keys %break_on_load ) {
5736             print {$OUT} " $filename\n";
5737             last BREAK_ON_LOAD if $signal;
5738         }
5739     } ## end if (%break_on_load and...
5740     if ($watch_wanted and ( $trace & 2 )) {
5741         print {$OUT} "Watch-expressions:\n" if @to_watch;
5742         TO_WATCH: for my $expr (@to_watch) {
5743             print {$OUT} " $expr\n";
5744             last TO_WATCH if $signal;
5745         }
5746     }
5747 } ## end sub cmd_L
5748
5749 =head3 C<cmd_M> - list modules (command)
5750
5751 Just call C<list_modules>.
5752
5753 =cut
5754
5755 sub cmd_M {
5756     list_modules();
5757
5758     return;
5759 }
5760
5761 =head3 C<cmd_o> - options (command)
5762
5763 If this is just C<o> by itself, we list the current settings via
5764 C<dump_option>. If there's a nonblank value following it, we pass that on to
5765 C<parse_options> for processing.
5766
5767 =cut
5768
5769 sub cmd_o {
5770     my $cmd = shift;
5771     my $opt = shift || '';    # opt[=val]
5772
5773     # Nonblank. Try to parse and process.
5774     if ( $opt =~ /^(\S.*)/ ) {
5775         parse_options($1);
5776     }
5777
5778     # Blank. List the current option settings.
5779     else {
5780         for (@options) {
5781             dump_option($_);
5782         }
5783     }
5784 } ## end sub cmd_o
5785
5786 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5787
5788 Advises the user that the O command has been renamed.
5789
5790 =cut
5791
5792 sub cmd_O {
5793     print $OUT "The old O command is now the o command.\n";             # hint
5794     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5795     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5796 }
5797
5798 =head3 C<cmd_v> - view window (command)
5799
5800 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5801 move back a few lines to list the selected line in context. Uses C<cmd_l>
5802 to do the actual listing after figuring out the range of line to request.
5803
5804 =cut
5805
5806 use vars qw($preview);
5807
5808 sub cmd_v {
5809     my $cmd  = shift;
5810     my $line = shift;
5811
5812     # Extract the line to list around. (Astute readers will have noted that
5813     # this pattern will match whether or not a numeric line is specified,
5814     # which means that we'll always enter this loop (though a non-numeric
5815     # argument results in no action at all)).
5816     if ( $line =~ /^(\d*)$/ ) {
5817
5818         # Total number of lines to list (a windowful).
5819         $incr = $window - 1;
5820
5821         # Set the start to the argument given (if there was one).
5822         $start = $1 if $1;
5823
5824         # Back up by the context amount.
5825         $start -= $preview;
5826
5827         # Put together a linespec that cmd_l will like.
5828         $line = $start . '-' . ( $start + $incr );
5829
5830         # List the lines.
5831         cmd_l( 'l', $line );
5832     } ## end if ($line =~ /^(\d*)$/)
5833 } ## end sub cmd_v
5834
5835 =head3 C<cmd_w> - add a watch expression (command)
5836
5837 The 5.8 version of this command adds a watch expression if one is specified;
5838 it does nothing if entered with no operands.
5839
5840 We extract the expression, save it, evaluate it in the user's context, and
5841 save the value. We'll re-evaluate it each time the debugger passes a line,
5842 and will stop (see the code at the top of the command loop) if the value
5843 of any of the expressions changes.
5844
5845 =cut
5846
5847 sub _add_watch_expr {
5848     my $expr = shift;
5849
5850     # ... save it.
5851     push @to_watch, $expr;
5852
5853     # Parameterize DB::eval and call it to get the expression's value
5854     # in the user's context. This version can handle expressions which
5855     # return a list value.
5856     $evalarg = $expr;
5857     my ($val) = join( ' ', DB::eval() );
5858     $val = ( defined $val ) ? "'$val'" : 'undef';
5859
5860     # Save the current value of the expression.
5861     push @old_watch, $val;
5862
5863     # We are now watching expressions.
5864     $trace |= 2;
5865
5866     return;
5867 }
5868
5869 sub cmd_w {
5870     my $cmd = shift;
5871
5872     # Null expression if no arguments.
5873     my $expr = shift || '';
5874
5875     # If expression is not null ...
5876     if ( $expr =~ /\A\S/ ) {
5877         _add_watch_expr($expr);
5878     } ## end if ($expr =~ /^(\S.*)/)
5879
5880     # You have to give one to get one.
5881     else {
5882         print $OUT "Adding a watch-expression requires an expression\n";  # hint
5883     }
5884
5885     return;
5886 }
5887
5888 =head3 C<cmd_W> - delete watch expressions (command)
5889
5890 This command accepts either a watch expression to be removed from the list
5891 of watch expressions, or C<*> to delete them all.
5892
5893 If C<*> is specified, we simply empty the watch expression list and the
5894 watch expression value list. We also turn off the bit that says we've got
5895 watch expressions.
5896
5897 If an expression (or partial expression) is specified, we pattern-match
5898 through the expressions and remove the ones that match. We also discard
5899 the corresponding values. If no watch expressions are left, we turn off
5900 the I<watching expressions> bit.
5901
5902 =cut
5903
5904 sub cmd_W {
5905     my $cmd  = shift;
5906     my $expr = shift || '';
5907
5908     # Delete them all.
5909     if ( $expr eq '*' ) {
5910
5911         # Not watching now.
5912         $trace &= ~2;
5913
5914         print $OUT "Deleting all watch expressions ...\n";
5915
5916         # And all gone.
5917         @to_watch = @old_watch = ();
5918     }
5919
5920     # Delete one of them.
5921     elsif ( $expr =~ /^(\S.*)/ ) {
5922
5923         # Where we are in the list.
5924         my $i_cnt = 0;
5925
5926         # For each expression ...
5927         foreach (@to_watch) {
5928             my $val = $to_watch[$i_cnt];
5929
5930             # Does this one match the command argument?
5931             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
5932                                       # Yes. Turn it off, and its value too.
5933                 splice( @to_watch,  $i_cnt, 1 );
5934                 splice( @old_watch, $i_cnt, 1 );
5935             }
5936             $i_cnt++;
5937         } ## end foreach (@to_watch)
5938
5939         # We don't bother to turn watching off because
5940         #  a) we don't want to stop calling watchfunction() it it exists
5941         #  b) foreach over a null list doesn't do anything anyway
5942
5943     } ## end elsif ($expr =~ /^(\S.*)/)
5944
5945     # No command arguments entered.
5946     else {
5947         print $OUT
5948           "Deleting a watch-expression requires an expression, or '*' for all\n"
5949           ;    # hint
5950     }
5951 } ## end sub cmd_W
5952
5953 ### END of the API section
5954
5955 =head1 SUPPORT ROUTINES
5956
5957 These are general support routines that are used in a number of places
5958 throughout the debugger.
5959
5960 =head2 save
5961
5962 save() saves the user's versions of globals that would mess us up in C<@saved>,
5963 and installs the versions we like better.
5964
5965 =cut
5966
5967 sub save {
5968
5969     # Save eval failure, command failure, extended OS error, output field
5970     # separator, input record separator, output record separator and
5971     # the warning setting.
5972     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
5973
5974     $,  = "";      # output field separator is null string
5975     $/  = "\n";    # input record separator is newline
5976     $\  = "";      # output record separator is null string
5977     $^W = 0;       # warnings are off
5978 } ## end sub save
5979
5980 =head2 C<print_lineinfo> - show where we are now
5981
5982 print_lineinfo prints whatever it is that it is handed; it prints it to the
5983 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
5984 us to feed line information to a slave editor without messing up the
5985 debugger output.
5986
5987 =cut
5988
5989 sub print_lineinfo {
5990
5991     # Make the terminal sensible if we're not the primary debugger.
5992     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
5993     local $\ = '';
5994     local $, = '';
5995     print $LINEINFO @_;
5996 } ## end sub print_lineinfo
5997
5998 =head2 C<postponed_sub>
5999
6000 Handles setting postponed breakpoints in subroutines once they're compiled.
6001 For breakpoints, we use C<DB::find_sub> to locate the source file and line
6002 range for the subroutine, then mark the file as having a breakpoint,
6003 temporarily switch the C<*dbline> glob over to the source file, and then
6004 search the given range of lines to find a breakable line. If we find one,
6005 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
6006
6007 =cut
6008
6009 # The following takes its argument via $evalarg to preserve current @_
6010
6011 sub postponed_sub {
6012
6013     # Get the subroutine name.
6014     my $subname = shift;
6015
6016     # If this is a 'break +<n> if <condition>' ...
6017     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
6018
6019         # If there's no offset, use '+0'.
6020         my $offset = $1 || 0;
6021
6022         # find_sub's value is 'fullpath-filename:start-stop'. It's
6023         # possible that the filename might have colons in it too.
6024         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
6025         if ($i) {
6026
6027             # We got the start line. Add the offset '+<n>' from
6028             # $postponed{subname}.
6029             $i += $offset;
6030
6031             # Switch to the file this sub is in, temporarily.
6032             local *dbline = $main::{ '_<' . $file };
6033
6034             # No warnings, please.
6035             local $^W = 0;    # != 0 is magical below
6036
6037             # This file's got a breakpoint in it.
6038             $had_breakpoints{$file} |= 1;
6039
6040             # Last line in file.
6041             $max = $#dbline;
6042
6043             # Search forward until we hit a breakable line or get to
6044             # the end of the file.
6045             ++$i until $dbline[$i] != 0 or $i >= $max;
6046
6047             # Copy the breakpoint in and delete it from %postponed.
6048             $dbline{$i} = delete $postponed{$subname};
6049         } ## end if ($i)
6050
6051         # find_sub didn't find the sub.
6052         else {
6053             local $\ = '';
6054             print $OUT "Subroutine $subname not found.\n";
6055         }
6056         return;
6057     } ## end if ($postponed{$subname...
6058     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
6059
6060     #print $OUT "In postponed_sub for '$subname'.\n";
6061 } ## end sub postponed_sub
6062
6063 =head2 C<postponed>
6064
6065 Called after each required file is compiled, but before it is executed;
6066 also called if the name of a just-compiled subroutine is a key of
6067 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
6068 etc.) into the just-compiled code.
6069
6070 If this is a C<require>'d file, the incoming parameter is the glob
6071 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
6072
6073 If it's a subroutine, the incoming parameter is the subroutine name.
6074
6075 =cut
6076
6077 sub postponed {
6078
6079     # If there's a break, process it.
6080     if ($ImmediateStop) {
6081
6082         # Right, we've stopped. Turn it off.
6083         $ImmediateStop = 0;
6084
6085         # Enter the command loop when DB::DB gets called.
6086         $signal = 1;
6087     }
6088
6089     # If this is a subroutine, let postponed_sub() deal with it.
6090     if (ref(\$_[0]) ne 'GLOB') {
6091         return postponed_sub(@_);
6092     }
6093
6094     # Not a subroutine. Deal with the file.
6095     local *dbline = shift;
6096     my $filename = $dbline;
6097     $filename =~ s/^_<//;
6098     local $\ = '';
6099     $signal = 1, print $OUT "'$filename' loaded...\n"
6100       if $break_on_load{$filename};
6101     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
6102
6103     # Do we have any breakpoints to put in this file?
6104     return unless $postponed_file{$filename};
6105
6106     # Yes. Mark this file as having breakpoints.
6107     $had_breakpoints{$filename} |= 1;
6108
6109     # "Cannot be done: insufficient magic" - we can't just put the
6110     # breakpoints saved in %postponed_file into %dbline by assigning
6111     # the whole hash; we have to do it one item at a time for the
6112     # breakpoints to be set properly.
6113     #%dbline = %{$postponed_file{$filename}};
6114
6115     # Set the breakpoints, one at a time.
6116     my $key;
6117
6118     for $key ( keys %{ $postponed_file{$filename} } ) {
6119
6120         # Stash the saved breakpoint into the current file's magic line array.
6121         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
6122     }
6123
6124     # This file's been compiled; discard the stored breakpoints.
6125     delete $postponed_file{$filename};
6126
6127 } ## end sub postponed
6128
6129 =head2 C<dumpit>
6130
6131 C<dumpit> is the debugger's wrapper around dumpvar.pl.
6132
6133 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
6134 a reference to a variable (the thing to be dumped) as its input.
6135
6136 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
6137 the currently-selected filehandle, thank you very much). The current
6138 values of the package globals C<$single> and C<$trace> are backed up in
6139 lexicals, and they are turned off (this keeps the debugger from trying
6140 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
6141 preserve its current value and it is set to zero to prevent entry/exit
6142 messages from printing, and C<$doret> is localized as well and set to -2 to
6143 prevent return values from being shown.
6144
6145 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
6146 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
6147 installed version in C<@INC>, yours will be used instead. Possible security
6148 problem?).
6149
6150 It then checks to see if the subroutine C<main::dumpValue> is now defined
6151 it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
6152 localizes the globals necessary for things to be sane when C<main::dumpValue()>
6153 is called, and picks up the variable to be dumped from the parameter list.
6154
6155 It checks the package global C<%options> to see if there's a C<dumpDepth>
6156 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
6157 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
6158 structure: -1 means dump everything.
6159
6160 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
6161 warning.
6162
6163 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
6164 and we then return to the caller.
6165
6166 =cut
6167
6168 sub dumpit {
6169
6170     # Save the current output filehandle and switch to the one
6171     # passed in as the first parameter.
6172     my $savout = select(shift);
6173
6174     # Save current settings of $single and $trace, and then turn them off.
6175     my $osingle = $single;
6176     my $otrace  = $trace;
6177     $single = $trace = 0;
6178
6179     # XXX Okay, what do $frame and $doret do, again?
6180     local $frame = 0;
6181     local $doret = -2;
6182
6183     # Load dumpvar.pl unless we've already got the sub we need from it.
6184     unless ( defined &main::dumpValue ) {
6185         do 'dumpvar.pl' or die $@;
6186     }
6187
6188     # If the load succeeded (or we already had dumpvalue()), go ahead
6189     # and dump things.
6190     if ( defined &main::dumpValue ) {
6191         local $\ = '';
6192         local $, = '';
6193         local $" = ' ';
6194         my $v = shift;
6195         my $maxdepth = shift || $option{dumpDepth};
6196         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
6197         main::dumpValue( $v, $maxdepth );
6198     } ## end if (defined &main::dumpValue)
6199
6200     # Oops, couldn't load dumpvar.pl.
6201     else {
6202         local $\ = '';
6203         print $OUT "dumpvar.pl not available.\n";
6204     }
6205
6206     # Reset $single and $trace to their old values.
6207     $single = $osingle;
6208     $trace  = $otrace;
6209
6210     # Restore the old filehandle.
6211     select($savout);
6212 } ## end sub dumpit
6213
6214 =head2 C<print_trace>
6215
6216 C<print_trace>'s job is to print a stack trace. It does this via the
6217 C<dump_trace> routine, which actually does all the ferreting-out of the
6218 stack trace data. C<print_trace> takes care of formatting it nicely and
6219 printing it to the proper filehandle.
6220
6221 Parameters:
6222
6223 =over 4
6224
6225 =item *
6226
6227 The filehandle to print to.
6228
6229 =item *
6230
6231 How many frames to skip before starting trace.
6232
6233 =item *
6234
6235 How many frames to print.
6236
6237 =item *
6238
6239 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
6240
6241 =back
6242
6243 The original comment below seems to be noting that the traceback may not be
6244 correct if this routine is called in a tied method.
6245
6246 =cut
6247
6248 # Tied method do not create a context, so may get wrong message:
6249
6250 sub print_trace {
6251     local $\ = '';
6252     my $fh = shift;
6253
6254     # If this is going to a slave editor, but we're not the primary
6255     # debugger, reset it first.
6256     resetterm(1)
6257       if $fh        eq $LINEINFO    # slave editor
6258       and $LINEINFO eq $OUT         # normal output
6259       and $term_pid != $$;          # not the primary
6260
6261     # Collect the actual trace information to be formatted.
6262     # This is an array of hashes of subroutine call info.
6263     my @sub = dump_trace( $_[0] + 1, $_[1] );
6264
6265     # Grab the "short report" flag from @_.
6266     my $short = $_[2];              # Print short report, next one for sub name
6267
6268     # Run through the traceback info, format it, and print it.
6269     my $s;
6270     for my $i (0 .. $#sub) {
6271
6272         # Drop out if the user has lost interest and hit control-C.
6273         last if $signal;
6274
6275         # Set the separator so arrys print nice.
6276         local $" = ', ';
6277
6278         # Grab and stringify the arguments if they are there.
6279         my $args =
6280           defined $sub[$i]{args}
6281           ? "(@{ $sub[$i]{args} })"
6282           : '';
6283
6284         # Shorten them up if $maxtrace says they're too long.
6285         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
6286           if length $args > $maxtrace;
6287
6288         # Get the file name.
6289         my $file = $sub[$i]{file};
6290
6291         # Put in a filename header if short is off.
6292         $file = $file eq '-e' ? $file : "file '$file'" unless $short;
6293
6294         # Get the actual sub's name, and shorten to $maxtrace's requirement.
6295         $s = $sub[$i]{'sub'};
6296         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
6297
6298         # Short report uses trimmed file and sub names.
6299         if ($short) {
6300             my $sub = @_ >= 4 ? $_[3] : $s;
6301             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
6302         } ## end if ($short)
6303
6304         # Non-short report includes full names.
6305         else {
6306             print $fh "$sub[$i]{context} = $s$args"
6307               . " called from $file"
6308               . " line $sub[$i]{line}\n";
6309         }
6310     } ## end for my $i (0 .. $#sub)
6311 } ## end sub print_trace
6312
6313 =head2 dump_trace(skip[,count])
6314
6315 Actually collect the traceback information available via C<caller()>. It does
6316 some filtering and cleanup of the data, but mostly it just collects it to
6317 make C<print_trace()>'s job easier.
6318
6319 C<skip> defines the number of stack frames to be skipped, working backwards
6320 from the most current. C<count> determines the total number of frames to
6321 be returned; all of them (well, the first 10^9) are returned if C<count>
6322 is omitted.
6323
6324 This routine returns a list of hashes, from most-recent to least-recent
6325 stack frame. Each has the following keys and values:
6326
6327 =over 4
6328
6329 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
6330
6331 =item * C<sub> - subroutine name, or C<eval> information
6332
6333 =item * C<args> - undef, or a reference to an array of arguments
6334
6335 =item * C<file> - the file in which this item was defined (if any)
6336
6337 =item * C<line> - the line on which it was defined
6338
6339 =back
6340
6341 =cut
6342
6343 sub dump_trace {
6344
6345     # How many levels to skip.
6346     my $skip = shift;
6347
6348     # How many levels to show. (1e9 is a cheap way of saying "all of them";
6349     # it's unlikely that we'll have more than a billion stack frames. If you
6350     # do, you've got an awfully big machine...)
6351     my $count = shift || 1e9;
6352
6353     # We increment skip because caller(1) is the first level *back* from
6354     # the current one.  Add $skip to the count of frames so we have a
6355     # simple stop criterion, counting from $skip to $count+$skip.
6356     $skip++;
6357     $count += $skip;
6358
6359     # These variables are used to capture output from caller();
6360     my ( $p, $file, $line, $sub, $h, $context );
6361
6362     my ( $e, $r, @a, @sub, $args );
6363
6364     # XXX Okay... why'd we do that?
6365     my $nothard = not $frame & 8;
6366     local $frame = 0;
6367
6368     # Do not want to trace this.
6369     my $otrace = $trace;
6370     $trace = 0;
6371
6372     # Start out at the skip count.
6373     # If we haven't reached the number of frames requested, and caller() is
6374     # still returning something, stay in the loop. (If we pass the requested
6375     # number of stack frames, or we run out - caller() returns nothing - we
6376     # quit.
6377     # Up the stack frame index to go back one more level each time.
6378     for (
6379         my $i = $skip ;
6380         $i < $count
6381         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
6382         $i++
6383     )
6384     {
6385
6386         # Go through the arguments and save them for later.
6387         @a = ();
6388         for my $arg (@args) {
6389             my $type;
6390             if ( not defined $arg ) {    # undefined parameter
6391                 push @a, "undef";
6392             }
6393
6394             elsif ( $nothard and tied $arg ) {    # tied parameter
6395                 push @a, "tied";
6396             }
6397             elsif ( $nothard and $type = ref $arg ) {    # reference
6398                 push @a, "ref($type)";
6399             }
6400             else {                                       # can be stringified
6401                 local $_ =
6402                   "$arg";    # Safe to stringify now - should not call f().
6403
6404                 # Backslash any single-quotes or backslashes.
6405                 s/([\'\\])/\\$1/g;
6406
6407                 # Single-quote it unless it's a number or a colon-separated
6408                 # name.
6409                 s/(.*)/'$1'/s
6410                   unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
6411
6412                 # Turn high-bit characters into meta-whatever.
6413                 s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
6414
6415                 # Turn control characters into ^-whatever.
6416                 s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
6417
6418                 push( @a, $_ );
6419             } ## end else [ if (not defined $arg)
6420         } ## end for $arg (@args)
6421
6422         # If context is true, this is array (@)context.
6423         # If context is false, this is scalar ($) context.
6424         # If neither, context isn't defined. (This is apparently a 'can't
6425         # happen' trap.)
6426         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
6427
6428         # if the sub has args ($h true), make an anonymous array of the
6429         # dumped args.
6430         $args = $h ? [@a] : undef;
6431
6432         # remove trailing newline-whitespace-semicolon-end of line sequence
6433         # from the eval text, if any.
6434         $e =~ s/\n\s*\;\s*\Z// if $e;
6435
6436         # Escape backslashed single-quotes again if necessary.
6437         $e =~ s/([\\\'])/\\$1/g if $e;
6438
6439         # if the require flag is true, the eval text is from a require.
6440         if ($r) {
6441             $sub = "require '$e'";
6442         }
6443
6444         # if it's false, the eval text is really from an eval.
6445         elsif ( defined $r ) {
6446             $sub = "eval '$e'";
6447         }
6448
6449         # If the sub is '(eval)', this is a block eval, meaning we don't
6450         # know what the eval'ed text actually was.
6451         elsif ( $sub eq '(eval)' ) {
6452             $sub = "eval {...}";
6453         }
6454
6455         # Stick the collected information into @sub as an anonymous hash.
6456         push(
6457             @sub,
6458             {
6459                 context => $context,
6460                 sub     => $sub,
6461                 args    => $args,
6462                 file    => $file,
6463                 line    => $line
6464             }
6465         );
6466
6467         # Stop processing frames if the user hit control-C.
6468         last if $signal;
6469     } ## end for ($i = $skip ; $i < ...
6470
6471     # Restore the trace value again.
6472     $trace = $otrace;
6473     @sub;
6474 } ## end sub dump_trace
6475
6476 =head2 C<action()>
6477
6478 C<action()> takes input provided as the argument to an add-action command,
6479 either pre- or post-, and makes sure it's a complete command. It doesn't do
6480 any fancy parsing; it just keeps reading input until it gets a string
6481 without a trailing backslash.
6482
6483 =cut
6484
6485 sub action {
6486     my $action = shift;
6487
6488     while ( $action =~ s/\\$// ) {
6489
6490         # We have a backslash on the end. Read more.
6491         $action .= gets();
6492     } ## end while ($action =~ s/\\$//)
6493
6494     # Return the assembled action.
6495     $action;
6496 } ## end sub action
6497
6498 =head2 unbalanced
6499
6500 This routine mostly just packages up a regular expression to be used
6501 to check that the thing it's being matched against has properly-matched
6502 curly braces.
6503
6504 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
6505 speeds things up by only creating the qr//'ed expression once; if it's
6506 already defined, we don't try to define it again. A speed hack.
6507
6508 =cut
6509
6510 use vars qw($balanced_brace_re);
6511
6512 sub unbalanced {
6513
6514     # I hate using globals!
6515     $balanced_brace_re ||= qr{
6516         ^ \{
6517              (?:
6518                  (?> [^{}] + )              # Non-parens without backtracking
6519                 |
6520                  (??{ $balanced_brace_re }) # Group with matching parens
6521               ) *
6522           \} $
6523    }x;
6524     return $_[0] !~ m/$balanced_brace_re/;
6525 } ## end sub unbalanced
6526
6527 =head2 C<gets()>
6528
6529 C<gets()> is a primitive (very primitive) routine to read continuations.
6530 It was devised for reading continuations for actions.
6531 it just reads more input with C<readline()> and returns it.
6532
6533 =cut
6534
6535 sub gets {
6536     return DB::readline("cont: ");
6537 }
6538
6539 =head2 C<_db_system()> - handle calls to<system()> without messing up the debugger
6540
6541 The C<system()> function assumes that it can just go ahead and use STDIN and
6542 STDOUT, but under the debugger, we want it to use the debugger's input and
6543 outout filehandles.
6544
6545 C<_db_system()> socks away the program's STDIN and STDOUT, and then substitutes
6546 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
6547 and then puts everything back again.
6548
6549 =cut
6550
6551 sub _db_system {
6552
6553     # We save, change, then restore STDIN and STDOUT to avoid fork() since
6554     # some non-Unix systems can do system() but have problems with fork().
6555     open( SAVEIN,  "<&STDIN" )  || db_warn("Can't save STDIN");
6556     open( SAVEOUT, ">&STDOUT" ) || db_warn("Can't save STDOUT");
6557     open( STDIN,   "<&IN" )     || db_warn("Can't redirect STDIN");
6558     open( STDOUT,  ">&OUT" )    || db_warn("Can't redirect STDOUT");
6559
6560     # XXX: using csh or tcsh destroys sigint retvals!
6561     system(@_);
6562     open( STDIN,  "<&SAVEIN" )  || db_warn("Can't restore STDIN");
6563     open( STDOUT, ">&SAVEOUT" ) || db_warn("Can't restore STDOUT");
6564     close(SAVEIN);
6565     close(SAVEOUT);
6566
6567     # most of the $? crud was coping with broken cshisms
6568     if ( $? >> 8 ) {
6569         db_warn( "(Command exited ", ( $? >> 8 ), ")\n" );
6570     }
6571     elsif ($?) {
6572         db_warn(
6573             "(Command died of SIG#",
6574             ( $? & 127 ),
6575             ( ( $? & 128 ) ? " -- core dumped" : "" ),
6576             ")", "\n"
6577         );
6578     } ## end elsif ($?)
6579
6580     return $?;
6581
6582 } ## end sub system
6583
6584 *system = \&_db_system;
6585
6586 =head1 TTY MANAGEMENT
6587
6588 The subs here do some of the terminal management for multiple debuggers.
6589
6590 =head2 setterm
6591
6592 Top-level function called when we want to set up a new terminal for use
6593 by the debugger.
6594
6595 If the C<noTTY> debugger option was set, we'll either use the terminal
6596 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6597 to find one. If we're a forked debugger, we call C<resetterm> to try to
6598 get a whole new terminal if we can.
6599
6600 In either case, we set up the terminal next. If the C<ReadLine> option was
6601 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6602 the appropriate attributes. We then
6603
6604 =cut
6605
6606 use vars qw($ornaments);
6607 use vars qw($rl_attribs);
6608
6609 sub setterm {
6610
6611     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6612     local $frame = 0;
6613     local $doret = -2;
6614     require Term::ReadLine;
6615
6616     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6617     if ($notty) {
6618         if ($tty) {
6619             my ( $i, $o ) = split $tty, /,/;
6620             $o = $i unless defined $o;
6621             open( IN,  "<$i" ) or die "Cannot open TTY '$i' for read: $!";
6622             open( OUT, ">$o" ) or die "Cannot open TTY '$o' for write: $!";
6623             $IN  = \*IN;
6624             $OUT = \*OUT;
6625             $OUT->autoflush(1);
6626         } ## end if ($tty)
6627
6628         # We don't have a TTY - try to find one via Term::Rendezvous.
6629         else {
6630             require Term::Rendezvous;
6631
6632             # See if we have anything to pass to Term::Rendezvous.
6633             # Use $HOME/.perldbtty$$ if not.
6634             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6635
6636             # Rendezvous and get the filehandles.
6637             my $term_rv = Term::Rendezvous->new( $rv );
6638             $IN  = $term_rv->IN;
6639             $OUT = $term_rv->OUT;
6640         } ## end else [ if ($tty)
6641     } ## end if ($notty)
6642
6643     # We're a daughter debugger. Try to fork off another TTY.
6644     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6645         resetterm(2);
6646     }
6647
6648     # If we shouldn't use Term::ReadLine, don't.
6649     if ( !$rl ) {
6650         $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6651     }
6652
6653     # We're using Term::ReadLine. Get all the attributes for this terminal.
6654     else {
6655         $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6656
6657         $rl_attribs = $term->Attribs;
6658         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6659           if defined $rl_attribs->{basic_word_break_characters}
6660           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6661         $rl_attribs->{special_prefixes} = '$@&%';
6662         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6663         $rl_attribs->{completion_function} = \&db_complete;
6664     } ## end else [ if (!$rl)
6665
6666     # Set up the LINEINFO filehandle.
6667     $LINEINFO = $OUT     unless defined $LINEINFO;
6668     $lineinfo = $console unless defined $lineinfo;
6669
6670     $term->MinLine(2);
6671
6672     load_hist();
6673
6674     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6675         $term->SetHistory(@hist);
6676     }
6677
6678     # XXX Ornaments are turned on unconditionally, which is not
6679     # always a good thing.
6680     ornaments($ornaments) if defined $ornaments;
6681     $term_pid = $$;
6682 } ## end sub setterm
6683
6684 sub load_hist {
6685     $histfile //= option_val("HistFile", undef);
6686     return unless defined $histfile;
6687     open my $fh, "<", $histfile or return;
6688     local $/ = "\n";
6689     @hist = ();
6690     while (<$fh>) {
6691         chomp;
6692         push @hist, $_;
6693     }
6694     close $fh;
6695 }
6696
6697 sub save_hist {
6698     return unless defined $histfile;
6699     eval { require File::Path } or return;
6700     eval { require File::Basename } or return;
6701     File::Path::mkpath(File::Basename::dirname($histfile));
6702     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6703     $histsize //= option_val("HistSize",100);
6704     my @copy = grep { $_ ne '?' } @hist;
6705     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6706     for ($start .. $#copy) {
6707         print $fh "$copy[$_]\n";
6708     }
6709     close $fh or die "Could not write '$histfile': $!";
6710 }
6711
6712 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6713
6714 When the process being debugged forks, or the process invokes a command
6715 via C<system()> which starts a new debugger, we need to be able to get a new
6716 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6717 fight over the terminal, and you can never quite be sure who's going to get the
6718 input you're typing.
6719
6720 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6721 is tasked with doing all the necessary operating system mojo to get a new
6722 TTY (and probably another window) and to direct the new debugger to read and
6723 write there.
6724
6725 The debugger provides C<get_fork_TTY> functions which work for TCP
6726 socket servers, X11, OS/2, and Mac OS X. Other systems are not
6727 supported. You are encouraged to write C<get_fork_TTY> functions which
6728 work for I<your> platform and contribute them.
6729
6730 =head3 C<socket_get_fork_TTY>
6731
6732 =cut
6733
6734 sub connect_remoteport {
6735     require IO::Socket;
6736
6737     my $socket = IO::Socket::INET->new(
6738         Timeout  => '10',
6739         PeerAddr => $remoteport,
6740         Proto    => 'tcp',
6741     );
6742     if ( ! $socket ) {
6743         die "Unable to connect to remote host: $remoteport\n";
6744     }
6745     return $socket;
6746 }
6747
6748 sub socket_get_fork_TTY {
6749     $tty = $LINEINFO = $IN = $OUT = connect_remoteport();
6750
6751     # Do I need to worry about setting $term?
6752
6753     reset_IN_OUT( $IN, $OUT );
6754     return '';
6755 }
6756
6757 =head3 C<xterm_get_fork_TTY>
6758
6759 This function provides the C<get_fork_TTY> function for X11. If a
6760 program running under the debugger forks, a new <xterm> window is opened and
6761 the subsidiary debugger is directed there.
6762
6763 The C<open()> call is of particular note here. We have the new C<xterm>
6764 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6765 command (which prints the device name of the TTY we'll want to use for input
6766 and output to STDOUT, then C<sleep> for a very long time, routing this output
6767 to file number 3. This way we can simply read from the <XT> filehandle (which
6768 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6769
6770 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6771 properly set up.
6772
6773 =cut
6774
6775 sub xterm_get_fork_TTY {
6776     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6777     open XT,
6778 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6779  sleep 10000000' |];
6780
6781     # Get the output from 'tty' and clean it up a little.
6782     my $tty = <XT>;
6783     chomp $tty;
6784
6785     $pidprompt = '';    # Shown anyway in titlebar
6786
6787     # We need $term defined or we can not switch to the newly created xterm
6788     if ($tty ne '' && !defined $term) {
6789         require Term::ReadLine;
6790         if ( !$rl ) {
6791             $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6792         }
6793         else {
6794             $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6795         }
6796     }
6797     # There's our new TTY.
6798     return $tty;
6799 } ## end sub xterm_get_fork_TTY
6800
6801 =head3 C<os2_get_fork_TTY>
6802
6803 XXX It behooves an OS/2 expert to write the necessary documentation for this!
6804
6805 =cut
6806
6807 # This example function resets $IN, $OUT itself
6808 my $c_pipe = 0;
6809 sub os2_get_fork_TTY { # A simplification of the following (and works without):
6810     local $\  = '';
6811     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6812     my %opt = ( title => "Daughter Perl debugger $pids $name",
6813         ($rl ? (read_by_key => 1) : ()) );
6814     require OS2::Process;
6815     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
6816       or return;
6817     $pidprompt = '';    # Shown anyway in titlebar
6818     reset_IN_OUT($in, $out);
6819     $tty = '*reset*';
6820     return '';          # Indicate that reset_IN_OUT is called
6821 } ## end sub os2_get_fork_TTY
6822
6823 =head3 C<macosx_get_fork_TTY>
6824
6825 The Mac OS X version uses AppleScript to tell Terminal.app to create
6826 a new window.
6827
6828 =cut
6829
6830 # Notes about Terminal.app's AppleScript support,
6831 # (aka things that might break in future OS versions).
6832 #
6833 # The "do script" command doesn't return a reference to the new window
6834 # it creates, but since it appears frontmost and windows are enumerated
6835 # front to back, we can use "first window" === "window 1".
6836 #
6837 # Since "do script" is implemented by supplying the argument (plus a
6838 # return character) as terminal input, there's a potential race condition
6839 # where the debugger could beat the shell to reading the command.
6840 # To prevent this, we wait for the screen to clear before proceeding.
6841 #
6842 # 10.3 and 10.4:
6843 # There's no direct accessor for the tty device name, so we fiddle
6844 # with the window title options until it says what we want.
6845 #
6846 # 10.5:
6847 # There _is_ a direct accessor for the tty device name, _and_ there's
6848 # a new possible component of the window title (the name of the settings
6849 # set).  A separate version is needed.
6850
6851 my @script_versions=
6852
6853     ([237, <<'__LEOPARD__'],
6854 tell application "Terminal"
6855     do script "clear;exec sleep 100000"
6856     tell first tab of first window
6857         copy tty to thetty
6858         set custom title to "forked perl debugger"
6859         set title displays custom title to true
6860         repeat while (length of first paragraph of (get contents)) > 0
6861             delay 0.1
6862         end repeat
6863     end tell
6864 end tell
6865 thetty
6866 __LEOPARD__
6867
6868      [100, <<'__JAGUAR_TIGER__'],
6869 tell application "Terminal"
6870     do script "clear;exec sleep 100000"
6871     tell first window
6872         set title displays shell path to false
6873         set title displays window size to false
6874         set title displays file name to false
6875         set title displays device name to true
6876         set title displays custom title to true
6877         set custom title to ""
6878         copy "/dev/" & name to thetty
6879         set custom title to "forked perl debugger"
6880         repeat while (length of first paragraph of (get contents)) > 0
6881             delay 0.1
6882         end repeat
6883     end tell
6884 end tell
6885 thetty
6886 __JAGUAR_TIGER__
6887
6888 );
6889
6890 sub macosx_get_fork_TTY
6891 {
6892     my($version,$script,$pipe,$tty);
6893
6894     return unless $version=$ENV{TERM_PROGRAM_VERSION};
6895     foreach my $entry (@script_versions) {
6896         if ($version>=$entry->[0]) {
6897             $script=$entry->[1];
6898             last;
6899         }
6900     }
6901     return unless defined($script);
6902     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
6903     $tty=readline($pipe);
6904     close($pipe);
6905     return unless defined($tty) && $tty =~ m(^/dev/);
6906     chomp $tty;
6907     return $tty;
6908 }
6909
6910 =head2 C<create_IN_OUT($flags)>
6911
6912 Create a new pair of filehandles, pointing to a new TTY. If impossible,
6913 try to diagnose why.
6914
6915 Flags are:
6916
6917 =over 4
6918
6919 =item * 1 - Don't know how to create a new TTY.
6920
6921 =item * 2 - Debugger has forked, but we can't get a new TTY.
6922
6923 =item * 4 - standard debugger startup is happening.
6924
6925 =back
6926
6927 =cut
6928
6929 use vars qw($fork_TTY);
6930
6931 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
6932
6933     # If we know how to get a new TTY, do it! $in will have
6934     # the TTY name if get_fork_TTY works.
6935     my $in = get_fork_TTY(@_) if defined &get_fork_TTY;
6936
6937     # It used to be that
6938     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
6939
6940     if ( not defined $in ) {
6941         my $why = shift;
6942
6943         # We don't know how.
6944         print_help(<<EOP) if $why == 1;
6945 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
6946 EOP
6947
6948         # Forked debugger.
6949         print_help(<<EOP) if $why == 2;
6950 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
6951   This may be an asynchronous session, so the parent debugger may be active.
6952 EOP
6953
6954         # Note that both debuggers are fighting over the same input.
6955         print_help(<<EOP) if $why != 4;
6956   Since two debuggers fight for the same TTY, input is severely entangled.
6957
6958 EOP
6959         print_help(<<EOP);
6960   I know how to switch the output to a different window in xterms, OS/2
6961   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
6962   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
6963   B<DB::get_fork_TTY()> returning this.
6964
6965   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
6966   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
6967
6968 EOP
6969     } ## end if (not defined $in)
6970     elsif ( $in ne '' ) {
6971         TTY($in);
6972     }
6973     else {
6974         $console = '';    # Indicate no need to open-from-the-console
6975     }
6976     undef $fork_TTY;
6977 } ## end sub create_IN_OUT
6978
6979 =head2 C<resetterm>
6980
6981 Handles rejiggering the prompt when we've forked off a new debugger.
6982
6983 If the new debugger happened because of a C<system()> that invoked a
6984 program under the debugger, the arrow between the old pid and the new
6985 in the prompt has I<two> dashes instead of one.
6986
6987 We take the current list of pids and add this one to the end. If there
6988 isn't any list yet, we make one up out of the initial pid associated with
6989 the terminal and our new pid, sticking an arrow (either one-dashed or
6990 two dashed) in between them.
6991
6992 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
6993 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
6994 and try to do that.
6995
6996 =cut
6997
6998 sub resetterm {    # We forked, so we need a different TTY
6999
7000     # Needs to be passed to create_IN_OUT() as well.
7001     my $in = shift;
7002
7003     # resetterm(2): got in here because of a system() starting a debugger.
7004     # resetterm(1): just forked.
7005     my $systemed = $in > 1 ? '-' : '';
7006
7007     # If there's already a list of pids, add this to the end.
7008     if ($pids) {
7009         $pids =~ s/\]/$systemed->$$]/;
7010     }
7011
7012     # No pid list. Time to make one.
7013     else {
7014         $pids = "[$term_pid->$$]";
7015     }
7016
7017     # The prompt we're going to be using for this debugger.
7018     $pidprompt = $pids;
7019
7020     # We now 0wnz this terminal.
7021     $term_pid = $$;
7022
7023     # Just return if we're not supposed to try to create a new TTY.
7024     return unless $CreateTTY & $in;
7025
7026     # Try to create a new IN/OUT pair.
7027     create_IN_OUT($in);
7028 } ## end sub resetterm
7029
7030 =head2 C<readline>
7031
7032 First, we handle stuff in the typeahead buffer. If there is any, we shift off
7033 the next line, print a message saying we got it, add it to the terminal
7034 history (if possible), and return it.
7035
7036 If there's nothing in the typeahead buffer, check the command filehandle stack.
7037 If there are any filehandles there, read from the last one, and return the line
7038 if we got one. If not, we pop the filehandle off and close it, and try the
7039 next one up the stack.
7040
7041 If we've emptied the filehandle stack, we check to see if we've got a socket
7042 open, and we read that and return it if we do. If we don't, we just call the
7043 core C<readline()> and return its value.
7044
7045 =cut
7046
7047 sub readline {
7048
7049     # Localize to prevent it from being smashed in the program being debugged.
7050     local $.;
7051
7052     # If there are stacked filehandles to read from ...
7053     # (Handle it before the typeahead, because we may call source/etc. from
7054     # the typeahead.)
7055     while (@cmdfhs) {
7056
7057         # Read from the last one in the stack.
7058         my $line = CORE::readline( $cmdfhs[-1] );
7059
7060         # If we got a line ...
7061         defined $line
7062           ? ( print $OUT ">> $line" and return $line )    # Echo and return
7063           : close pop @cmdfhs;                            # Pop and close
7064     } ## end while (@cmdfhs)
7065
7066     # Pull a line out of the typeahead if there's stuff there.
7067     if (@typeahead) {
7068
7069         # How many lines left.
7070         my $left = @typeahead;
7071
7072         # Get the next line.
7073         my $got = shift @typeahead;
7074
7075         # Print a message saying we got input from the typeahead.
7076         local $\ = '';
7077         print $OUT "auto(-$left)", shift, $got, "\n";
7078
7079         # Add it to the terminal history (if possible).
7080         $term->AddHistory($got)
7081           if length($got) > 1
7082           and defined $term->Features->{addHistory};
7083         return $got;
7084     } ## end if (@typeahead)
7085
7086     # We really need to read some input. Turn off entry/exit trace and
7087     # return value printing.
7088     local $frame = 0;
7089     local $doret = -2;
7090
7091     # Nothing on the filehandle stack. Socket?
7092     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
7093
7094         # Send anything we have to send.
7095         $OUT->write( join( '', @_ ) );
7096
7097         # Receive anything there is to receive.
7098         my $stuff = '';
7099         my $buf;
7100         my $first_time = 1;
7101
7102         while ($first_time or (length($buf) && ($stuff .= $buf) !~ /\n/))
7103         {
7104             $first_time = 0;
7105             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
7106                                             # XXX Don't know. You tell me.
7107         }
7108
7109         # What we got.
7110         return $stuff;
7111     } ## end if (ref $OUT and UNIVERSAL::isa...
7112
7113     # No socket. Just read from the terminal.
7114     else {
7115         return $term->readline(@_);
7116     }
7117 } ## end sub readline
7118
7119 =head1 OPTIONS SUPPORT ROUTINES
7120
7121 These routines handle listing and setting option values.
7122
7123 =head2 C<dump_option> - list the current value of an option setting
7124
7125 This routine uses C<option_val> to look up the value for an option.
7126 It cleans up escaped single-quotes and then displays the option and
7127 its value.
7128
7129 =cut
7130
7131 sub dump_option {
7132     my ( $opt, $val ) = @_;
7133     $val = option_val( $opt, 'N/A' );
7134     $val =~ s/([\\\'])/\\$1/g;
7135     printf $OUT "%20s = '%s'\n", $opt, $val;
7136 } ## end sub dump_option
7137
7138 sub options2remember {
7139     foreach my $k (@RememberOnROptions) {
7140         $option{$k} = option_val( $k, 'N/A' );
7141     }
7142     return %option;
7143 }
7144
7145 =head2 C<option_val> - find the current value of an option
7146
7147 This can't just be a simple hash lookup because of the indirect way that
7148 the option values are stored. Some are retrieved by calling a subroutine,
7149 some are just variables.
7150
7151 You must supply a default value to be used in case the option isn't set.
7152
7153 =cut
7154
7155 sub option_val {
7156     my ( $opt, $default ) = @_;
7157     my $val;
7158
7159     # Does this option exist, and is it a variable?
7160     # If so, retrieve the value via the value in %optionVars.
7161     if (    defined $optionVars{$opt}
7162         and defined ${ $optionVars{$opt} } )
7163     {
7164         $val = ${ $optionVars{$opt} };
7165     }
7166
7167     # Does this option exist, and it's a subroutine?
7168     # If so, call the subroutine via the ref in %optionAction
7169     # and capture the value.
7170     elsif ( defined $optionAction{$opt}
7171         and defined &{ $optionAction{$opt} } )
7172     {
7173         $val = &{ $optionAction{$opt} }();
7174     }
7175
7176     # If there's an action or variable for the supplied option,
7177     # but no value was set, use the default.
7178     elsif (defined $optionAction{$opt} and not defined $option{$opt}
7179         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
7180     {
7181         $val = $default;
7182     }
7183
7184     # Otherwise, do the simple hash lookup.
7185     else {
7186         $val = $option{$opt};
7187     }
7188
7189     # If the value isn't defined, use the default.
7190     # Then return whatever the value is.
7191     $val = $default unless defined $val;
7192     $val;
7193 } ## end sub option_val
7194
7195 =head2 C<parse_options>
7196
7197 Handles the parsing and execution of option setting/displaying commands.
7198
7199 An option entered by itself is assumed to be I<set me to 1> (the default value)
7200 if the option is a boolean one. If not, the user is prompted to enter a valid
7201 value or to query the current value (via C<option? >).
7202
7203 If C<option=value> is entered, we try to extract a quoted string from the
7204 value (if it is quoted). If it's not, we just use the whole value as-is.
7205
7206 We load any modules required to service this option, and then we set it: if
7207 it just gets stuck in a variable, we do that; if there's a subroutine to
7208 handle setting the option, we call that.
7209
7210 Finally, if we're running in interactive mode, we display the effect of the
7211 user's command back to the terminal, skipping this if we're setting things
7212 during initialization.
7213
7214 =cut
7215
7216 sub parse_options {
7217     my ($s) = @_;
7218     local $\ = '';
7219
7220     my $option;
7221
7222     # These options need a value. Don't allow them to be clobbered by accident.
7223     my %opt_needs_val = map { ( $_ => 1 ) } qw{
7224       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
7225       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
7226     };
7227
7228     while (length($s)) {
7229         my $val_defaulted;
7230
7231         # Clean off excess leading whitespace.
7232         $s =~ s/^\s+// && next;
7233
7234         # Options are always all word characters, followed by a non-word
7235         # separator.
7236         if ($s !~ s/^(\w+)(\W?)//) {
7237             print {$OUT} "Invalid option '$s'\n";
7238             last;
7239         }
7240         my ( $opt, $sep ) = ( $1, $2 );
7241
7242         # Make sure that such an option exists.
7243         my $matches = ( grep { /^\Q$opt/ && ( $option = $_ ) } @options )
7244           || ( grep { /^\Q$opt/i && ( $option = $_ ) } @options );
7245
7246         unless ($matches) {
7247             print {$OUT} "Unknown option '$opt'\n";
7248             next;
7249         }
7250         if ($matches > 1) {
7251             print {$OUT} "Ambiguous option '$opt'\n";
7252             next;
7253         }
7254         my $val;
7255
7256         # '?' as separator means query, but must have whitespace after it.
7257         if ( "?" eq $sep ) {
7258             if ($s =~ /\A\S/) {
7259                 print {$OUT} "Option query '$opt?' followed by non-space '$s'\n" ;
7260
7261                 last;
7262             }
7263
7264             #&dump_option($opt);
7265         } ## end if ("?" eq $sep)
7266
7267         # Separator is whitespace (or just a carriage return).
7268         # They're going for a default, which we assume is 1.
7269         elsif ( $sep !~ /\S/ ) {
7270             $val_defaulted = 1;
7271             $val           = "1";   #  this is an evil default; make 'em set it!
7272         }
7273
7274         # Separator is =. Trying to set a value.
7275         elsif ( $sep eq "=" ) {
7276
7277             # If quoted, extract a quoted string.
7278             if ($s =~ s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
7279                 my $quote = $1;
7280                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
7281             }
7282
7283             # Not quoted. Use the whole thing. Warn about 'option='.
7284             else {
7285                 $s =~ s/^(\S*)//;
7286                 $val = $1;
7287                 print OUT qq(Option better cleared using $opt=""\n)
7288                   unless length $val;
7289             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
7290
7291         } ## end elsif ($sep eq "=")
7292
7293         # "Quoted" with [], <>, or {}.
7294         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
7295             my ($end) =
7296               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
7297             $s =~ s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
7298               or print( $OUT "Unclosed option value '$opt$sep$_'\n" ), last;
7299             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
7300         } ## end else [ if ("?" eq $sep)
7301
7302         # Exclude non-booleans from getting set to 1 by default.
7303         if ( $opt_needs_val{$option} && $val_defaulted ) {
7304             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
7305             print {$OUT}
7306 "Option '$opt' is non-boolean.  Use '$cmd $option=VAL' to set, '$cmd $option?' to query\n";
7307             next;
7308         } ## end if ($opt_needs_val{$option...
7309
7310         # Save the option value.
7311         $option{$option} = $val if defined $val;
7312
7313         # Load any module that this option requires.
7314         if ( defined($optionRequire{$option}) && defined($val) ) {
7315             eval qq{
7316             local \$frame = 0;
7317             local \$doret = -2;
7318             require '$optionRequire{$option}';
7319             1;
7320             } || die $@   # XXX: shouldn't happen
7321         }
7322
7323         # Set it.
7324         # Stick it in the proper variable if it goes in a variable.
7325         if (defined($optionVars{$option}) && defined($val)) {
7326             ${ $optionVars{$option} } = $val;
7327         }
7328
7329         # Call the appropriate sub if it gets set via sub.
7330         if (defined($optionAction{$option})
7331           && defined (&{ $optionAction{$option} })
7332           && defined ($val))
7333         {
7334           &{ $optionAction{$option} }($val);
7335         }
7336
7337         # Not initialization - echo the value we set it to.
7338         dump_option($option) if ($OUT ne \*STDERR);
7339     } ## end while (length)
7340 } ## end sub parse_options
7341
7342 =head1 RESTART SUPPORT
7343
7344 These routines are used to store (and restore) lists of items in environment
7345 variables during a restart.
7346
7347 =head2 set_list
7348
7349 Set_list packages up items to be stored in a set of environment variables
7350 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
7351 the values). Values outside the standard ASCII charset are stored by encoding
7352 then as hexadecimal values.
7353
7354 =cut
7355
7356 sub set_list {
7357     my ( $stem, @list ) = @_;
7358     my $val;
7359
7360     # VAR_n: how many we have. Scalar assignment gets the number of items.
7361     $ENV{"${stem}_n"} = @list;
7362
7363     # Grab each item in the list, escape the backslashes, encode the non-ASCII
7364     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
7365     for my $i ( 0 .. $#list ) {
7366         $val = $list[$i];
7367         $val =~ s/\\/\\\\/g;
7368         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
7369         $ENV{"${stem}_$i"} = $val;
7370     } ## end for $i (0 .. $#list)
7371 } ## end sub set_list
7372
7373 =head2 get_list
7374
7375 Reverse the set_list operation: grab VAR_n to see how many we should be getting
7376 back, and then pull VAR_0, VAR_1. etc. back out.
7377
7378 =cut
7379
7380 sub get_list {
7381     my $stem = shift;
7382     my @list;
7383     my $n = delete $ENV{"${stem}_n"};
7384     my $val;
7385     for my $i ( 0 .. $n - 1 ) {
7386         $val = delete $ENV{"${stem}_$i"};
7387         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
7388         push @list, $val;
7389     }
7390     @list;
7391 } ## end sub get_list
7392
7393 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
7394
7395 =head2 catch()
7396
7397 The C<catch()> subroutine is the essence of fast and low-impact. We simply
7398 set an already-existing global scalar variable to a constant value. This
7399 avoids allocating any memory possibly in the middle of something that will
7400 get all confused if we do, particularly under I<unsafe signals>.
7401
7402 =cut
7403
7404 sub catch {
7405     $signal = 1;
7406     return;    # Put nothing on the stack - malloc/free land!
7407 }
7408
7409 =head2 C<warn()>
7410
7411 C<warn> emits a warning, by joining together its arguments and printing
7412 them, with couple of fillips.
7413
7414 If the composited message I<doesn't> end with a newline, we automatically
7415 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
7416 to be set to the filehandle to be used to output warnings; it makes no
7417 assumptions about what filehandles are available.
7418
7419 =cut
7420
7421 sub _db_warn {
7422     my ($msg) = join( "", @_ );
7423     $msg .= ": $!\n" unless $msg =~ /\n$/;
7424     local $\ = '';
7425     print $OUT $msg;
7426 } ## end sub warn
7427
7428 *warn = \&_db_warn;
7429
7430 =head1 INITIALIZATION TTY SUPPORT
7431
7432 =head2 C<reset_IN_OUT>
7433
7434 This routine handles restoring the debugger's input and output filehandles
7435 after we've tried and failed to move them elsewhere.  In addition, it assigns
7436 the debugger's output filehandle to $LINEINFO if it was already open there.
7437
7438 =cut
7439
7440 sub reset_IN_OUT {
7441     my $switch_li = $LINEINFO eq $OUT;
7442
7443     # If there's a term and it's able to get a new tty, try to get one.
7444     if ( $term and $term->Features->{newTTY} ) {
7445         ( $IN, $OUT ) = ( shift, shift );
7446         $term->newTTY( $IN, $OUT );
7447     }
7448
7449     # This term can't get a new tty now. Better luck later.
7450     elsif ($term) {
7451         _db_warn("Too late to set IN/OUT filehandles, enabled on next 'R'!\n");
7452     }
7453
7454     # Set the filehndles up as they were.
7455     else {
7456         ( $IN, $OUT ) = ( shift, shift );
7457     }
7458
7459     # Unbuffer the output filehandle.
7460     $OUT->autoflush(1);
7461
7462     # Point LINEINFO to the same output filehandle if it was there before.
7463     $LINEINFO = $OUT if $switch_li;
7464 } ## end sub reset_IN_OUT
7465
7466 =head1 OPTION SUPPORT ROUTINES
7467
7468 The following routines are used to process some of the more complicated
7469 debugger options.
7470
7471 =head2 C<TTY>
7472
7473 Sets the input and output filehandles to the specified files or pipes.
7474 If the terminal supports switching, we go ahead and do it. If not, and
7475 there's already a terminal in place, we save the information to take effect
7476 on restart.
7477
7478 If there's no terminal yet (for instance, during debugger initialization),
7479 we go ahead and set C<$console> and C<$tty> to the file indicated.
7480
7481 =cut
7482
7483 sub TTY {
7484
7485     if ( @_ and $term and $term->Features->{newTTY} ) {
7486
7487         # This terminal supports switching to a new TTY.
7488         # Can be a list of two files, or on string containing both names,
7489         # comma-separated.
7490         # XXX Should this perhaps be an assignment from @_?
7491         my ( $in, $out ) = shift;
7492         if ( $in =~ /,/ ) {
7493
7494             # Split list apart if supplied.
7495             ( $in, $out ) = split /,/, $in, 2;
7496         }
7497         else {
7498
7499             # Use the same file for both input and output.
7500             $out = $in;
7501         }
7502
7503         # Open file onto the debugger's filehandles, if you can.
7504         open IN,  $in     or die "cannot open '$in' for read: $!";
7505         open OUT, ">$out" or die "cannot open '$out' for write: $!";
7506
7507         # Swap to the new filehandles.
7508         reset_IN_OUT( \*IN, \*OUT );
7509
7510         # Save the setting for later.
7511         return $tty = $in;
7512     } ## end if (@_ and $term and $term...
7513
7514     # Terminal doesn't support new TTY, or doesn't support readline.
7515     # Can't do it now, try restarting.
7516     if ($term and @_) {
7517         _db_warn("Too late to set TTY, enabled on next 'R'!\n");
7518     }
7519
7520     # Useful if done through PERLDB_OPTS:
7521     $console = $tty = shift if @_;
7522
7523     # Return whatever the TTY is.
7524     $tty or $console;
7525 } ## end sub TTY
7526
7527 =head2 C<noTTY>
7528
7529 Sets the C<$notty> global, controlling whether or not the debugger tries to
7530 get a terminal to read from. If called after a terminal is already in place,
7531 we save the value to use it if we're restarted.
7532
7533 =cut
7534
7535 sub noTTY {
7536     if ($term) {
7537         _db_warn("Too late to set noTTY, enabled on next 'R'!\n") if @_;
7538     }
7539     $notty = shift if @_;
7540     $notty;
7541 } ## end sub noTTY
7542
7543 =head2 C<ReadLine>
7544
7545 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
7546 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
7547 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
7548 the value in case a restart is done so we can change it then.
7549
7550 =cut
7551
7552 sub ReadLine {
7553     if ($term) {
7554         _db_warn("Too late to set ReadLine, enabled on next 'R'!\n") if @_;
7555     }
7556     $rl = shift if @_;
7557     $rl;
7558 } ## end sub ReadLine
7559
7560 =head2 C<RemotePort>
7561
7562 Sets the port that the debugger will try to connect to when starting up.
7563 If the terminal's already been set up, we can't do it, but we remember the
7564 setting in case the user does a restart.
7565
7566 =cut
7567
7568 sub RemotePort {
7569     if ($term) {
7570         _db_warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
7571     }
7572     $remoteport = shift if @_;
7573     $remoteport;
7574 } ## end sub RemotePort
7575
7576 =head2 C<tkRunning>
7577
7578 Checks with the terminal to see if C<Tk> is running, and returns true or
7579 false. Returns false if the current terminal doesn't support C<readline>.
7580
7581 =cut
7582
7583 sub tkRunning {
7584     if ( ${ $term->Features }{tkRunning} ) {
7585         return $term->tkRunning(@_);
7586     }
7587     else {
7588         local $\ = '';
7589         print $OUT "tkRunning not supported by current ReadLine package.\n";
7590         0;
7591     }
7592 } ## end sub tkRunning
7593
7594 =head2 C<NonStop>
7595
7596 Sets nonstop mode. If a terminal's already been set up, it's too late; the
7597 debugger remembers the setting in case you restart, though.
7598
7599 =cut
7600
7601 sub NonStop {
7602     if ($term) {
7603         _db_warn("Too late to set up NonStop mode, enabled on next 'R'!\n")
7604           if @_;
7605     }
7606     $runnonstop = shift if @_;
7607     $runnonstop;
7608 } ## end sub NonStop
7609
7610 sub DollarCaretP {
7611     if ($term) {
7612         _db_warn("Some flag changes could not take effect until next 'R'!\n")
7613           if @_;
7614     }
7615     $^P = parse_DollarCaretP_flags(shift) if @_;
7616     expand_DollarCaretP_flags($^P);
7617 }
7618
7619 =head2 C<pager>
7620
7621 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
7622 there already.
7623
7624 =cut
7625
7626 sub pager {
7627     if (@_) {
7628         $pager = shift;
7629         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
7630     }
7631     $pager;
7632 } ## end sub pager
7633
7634 =head2 C<shellBang>
7635
7636 Sets the shell escape command, and generates a printable copy to be used
7637 in the help.
7638
7639 =cut
7640
7641 sub shellBang {
7642
7643     # If we got an argument, meta-quote it, and add '\b' if it
7644     # ends in a word character.
7645     if (@_) {
7646         $sh = quotemeta shift;
7647         $sh .= "\\b" if $sh =~ /\w$/;
7648     }
7649
7650     # Generate the printable version for the help:
7651     $psh = $sh;    # copy it
7652     $psh =~ s/\\b$//;        # Take off trailing \b if any
7653     $psh =~ s/\\(.)/$1/g;    # De-escape
7654     $psh;                    # return the printable version
7655 } ## end sub shellBang
7656
7657 =head2 C<ornaments>
7658
7659 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7660 was passed as the argument. (This means you can't override the terminal's
7661 ornaments.)
7662
7663 =cut
7664
7665 sub ornaments {
7666     if ( defined $term ) {
7667
7668         # We don't want to show warning backtraces, but we do want die() ones.
7669         local $warnLevel = 0;
7670         local $dieLevel = 1;
7671
7672         # No ornaments if the terminal doesn't support them.
7673         if (not $term->Features->{ornaments}) {
7674             return '';
7675         }
7676
7677         return (eval { $term->ornaments(@_) } || '');
7678     }
7679
7680     # Use what was passed in if we can't determine it ourselves.
7681     else {
7682         $ornaments = shift;
7683
7684         return $ornaments;
7685     }
7686
7687 } ## end sub ornaments
7688
7689 =head2 C<recallCommand>
7690
7691 Sets the recall command, and builds a printable version which will appear in
7692 the help text.
7693
7694 =cut
7695
7696 sub recallCommand {
7697
7698     # If there is input, metaquote it. Add '\b' if it ends with a word
7699     # character.
7700     if (@_) {
7701         $rc = quotemeta shift;
7702         $rc .= "\\b" if $rc =~ /\w$/;
7703     }
7704
7705     # Build it into a printable version.
7706     $prc = $rc;              # Copy it
7707     $prc =~ s/\\b$//;        # Remove trailing \b
7708     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7709     return $prc;             # Return the printable version
7710 } ## end sub recallCommand
7711
7712 =head2 C<LineInfo> - where the line number information goes
7713
7714 Called with no arguments, returns the file or pipe that line info should go to.
7715
7716 Called with an argument (a file or a pipe), it opens that onto the
7717 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7718 file or pipe again to the caller.
7719
7720 =cut
7721
7722 sub LineInfo {
7723     if (@_) {
7724         $lineinfo = shift;
7725
7726         #  If this is a valid "thing to be opened for output", tack a
7727         # '>' onto the front.
7728         my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7729
7730         # If this is a pipe, the stream points to a slave editor.
7731         $slave_editor = ( $stream =~ /^\|/ );
7732
7733         my $new_lineinfo_fh;
7734         # Open it up and unbuffer it.
7735         open ($new_lineinfo_fh , $stream )
7736             or _db_warn("Cannot open '$stream' for write");
7737         $LINEINFO = $new_lineinfo_fh;
7738         $LINEINFO->autoflush(1);
7739     }
7740
7741     return $lineinfo;
7742 } ## end sub LineInfo
7743
7744 =head1 COMMAND SUPPORT ROUTINES
7745
7746 These subroutines provide functionality for various commands.
7747
7748 =head2 C<list_modules>
7749
7750 For the C<M> command: list modules loaded and their versions.
7751 Essentially just runs through the keys in %INC, picks each package's
7752 C<$VERSION> variable, gets the file name, and formats the information
7753 for output.
7754
7755 =cut
7756
7757 sub list_modules {    # versions
7758     my %version;
7759     my $file;
7760
7761     # keys are the "as-loaded" name, values are the fully-qualified path
7762     # to the file itself.
7763     for ( keys %INC ) {
7764         $file = $_;                                # get the module name
7765         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
7766         s,/,::,g;                                  # change '/' to '::'
7767         s/^perl5db$/DB/;                           # Special case: debugger
7768                                                    # moves to package DB
7769         s/^Term::ReadLine::readline$/readline/;    # simplify readline
7770
7771         # If the package has a $VERSION package global (as all good packages
7772         # should!) decode it and save as partial message.
7773         my $pkg_version = do { no strict 'refs'; ${ $_ . '::VERSION' } };
7774         if ( defined $pkg_version ) {
7775             $version{$file} = "$pkg_version from ";
7776         }
7777
7778         # Finish up the message with the file the package came from.
7779         $version{$file} .= $INC{$file};
7780     } ## end for (keys %INC)
7781
7782     # Hey, dumpit() formats a hash nicely, so why not use it?
7783     dumpit( $OUT, \%version );
7784 } ## end sub list_modules
7785
7786 =head2 C<sethelp()>
7787
7788 Sets up the monster string used to format and print the help.
7789
7790 =head3 HELP MESSAGE FORMAT
7791
7792 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
7793 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
7794 easy to parse and portable, but which still allows the help to be a little
7795 nicer than just plain text.
7796
7797 Essentially, you define the command name (usually marked up with C<< B<> >>
7798 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
7799 newline. The descriptive text can also be marked up in the same way. If you
7800 need to continue the descriptive text to another line, start that line with
7801 just tabs and then enter the marked-up text.
7802
7803 If you are modifying the help text, I<be careful>. The help-string parser is
7804 not very sophisticated, and if you don't follow these rules it will mangle the
7805 help beyond hope until you fix the string.
7806
7807 =cut
7808
7809 use vars qw($pre580_help);
7810 use vars qw($pre580_summary);
7811
7812 sub sethelp {
7813
7814     # XXX: make sure there are tabs between the command and explanation,
7815     #      or print_help will screw up your formatting if you have
7816     #      eeevil ornaments enabled.  This is an insane mess.
7817
7818     $help = "
7819 Help is currently only available for the new 5.8 command set.
7820 No help is available for the old command set.
7821 We assume you know what you're doing if you switch to it.
7822
7823 B<T>        Stack trace.
7824 B<s> [I<expr>]    Single step [in I<expr>].
7825 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7826 <B<CR>>        Repeat last B<n> or B<s> command.
7827 B<r>        Return from current subroutine.
7828 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7829         at the specified position.
7830 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7831 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7832 B<l> I<line>        List single I<line>.
7833 B<l> I<subname>    List first window of lines from subroutine.
7834 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7835 B<l>        List next window of lines.
7836 B<->        List previous window of lines.
7837 B<v> [I<line>]    View window around I<line>.
7838 B<.>        Return to the executed line.
7839 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7840         I<filename> may be either the full name of the file, or a regular
7841         expression matching the full file name:
7842         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7843         Evals (with saved bodies) are considered to be filenames:
7844         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7845         (in the order of execution).
7846 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7847 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7848 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
7849 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7850 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth).
7851 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
7852 B<b>        Sets breakpoint on current line)
7853 B<b> [I<line>] [I<condition>]
7854         Set breakpoint; I<line> defaults to the current execution line;
7855         I<condition> breaks if it evaluates to true, defaults to '1'.
7856 B<b> I<subname> [I<condition>]
7857         Set breakpoint at first line of subroutine.
7858 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7859 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7860 B<b> B<postpone> I<subname> [I<condition>]
7861         Set breakpoint at first line of subroutine after
7862         it is compiled.
7863 B<b> B<compile> I<subname>
7864         Stop after the subroutine is compiled.
7865 B<B> [I<line>]    Delete the breakpoint for I<line>.
7866 B<B> I<*>             Delete all breakpoints.
7867 B<a> [I<line>] I<command>
7868         Set an action to be done before the I<line> is executed;
7869         I<line> defaults to the current execution line.
7870         Sequence is: check for breakpoint/watchpoint, print line
7871         if necessary, do action, prompt user if necessary,
7872         execute line.
7873 B<a>        Does nothing
7874 B<A> [I<line>]    Delete the action for I<line>.
7875 B<A> I<*>             Delete all actions.
7876 B<w> I<expr>        Add a global watch-expression.
7877 B<w>             Does nothing
7878 B<W> I<expr>        Delete a global watch-expression.
7879 B<W> I<*>             Delete all watch-expressions.
7880 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7881         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7882 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7883 B<x> I<expr>        Evals expression in list context, dumps the result.
7884 B<m> I<expr>        Evals expression in list context, prints methods callable
7885         on the first element of the result.
7886 B<m> I<class>        Prints methods callable via the given class.
7887 B<M>        Show versions of loaded modules.
7888 B<i> I<class>       Prints nested parents of given class.
7889 B<e>         Display current thread id.
7890 B<E>         Display all thread ids the current one will be identified: <n>.
7891 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7892
7893 B<<> ?            List Perl commands to run before each prompt.
7894 B<<> I<expr>        Define Perl command to run before each prompt.
7895 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7896 B<< *>                Delete the list of perl commands to run before each prompt.
7897 B<>> ?            List Perl commands to run after each prompt.
7898 B<>> I<expr>        Define Perl command to run after each prompt.
7899 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7900 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
7901 B<{> I<db_command>    Define debugger command to run before each prompt.
7902 B<{> ?            List debugger commands to run before each prompt.
7903 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7904 B<{ *>             Delete the list of debugger commands to run before each prompt.
7905 B<$prc> I<number>    Redo a previous command (default previous command).
7906 B<$prc> I<-number>    Redo number'th-to-last command.
7907 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7908         See 'B<O> I<recallCommand>' too.
7909 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7910       . (
7911         $rc eq $sh
7912         ? ""
7913         : "
7914 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7915       ) . "
7916         See 'B<O> I<shellBang>' too.
7917 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
7918 B<save> I<file>       Save current debugger session (actual history) to I<file>.
7919 B<rerun>           Rerun session to current position.
7920 B<rerun> I<n>         Rerun session to numbered command.
7921 B<rerun> I<-n>        Rerun session to number'th-to-last command.
7922 B<H> I<-number>    Display last number commands (default all).
7923 B<H> I<*>          Delete complete history.
7924 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7925 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7926 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarily select()ed as well.
7927 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7928 I<command>        Execute as a perl statement in current package.
7929 B<R>        Pure-man-restart of debugger, some of debugger state
7930         and command-line options may be lost.
7931         Currently the following settings are preserved:
7932         history, breakpoints and actions, debugger B<O>ptions
7933         and the following command-line options: I<-w>, I<-I>, I<-e>.
7934
7935 B<o> [I<opt>] ...    Set boolean option to true
7936 B<o> [I<opt>B<?>]    Query options
7937 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7938         Set options.  Use quotes if spaces in value.
7939     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7940     I<pager>            program for output of \"|cmd\";
7941     I<tkRunning>            run Tk while prompting (with ReadLine);
7942     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7943     I<inhibit_exit>        Allows stepping off the end of the script.
7944     I<ImmediateStop>        Debugger should stop as early as possible.
7945     I<RemotePort>            Remote hostname:port for remote debugging
7946   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7947     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7948     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7949     I<globPrint>             whether to print contents of globs;
7950     I<DumpDBFiles>         dump arrays holding debugged files;
7951     I<DumpPackages>         dump symbol tables of packages;
7952     I<DumpReused>             dump contents of \"reused\" addresses;
7953     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7954     I<bareStringify>         Do not print the overload-stringified value;
7955   Other options include:
7956     I<PrintRet>        affects printing of return value after B<r> command,
7957     I<frame>        affects printing messages on subroutine entry/exit.
7958     I<AutoTrace>    affects printing messages on possible breaking points.
7959     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7960     I<ornaments>     affects screen appearance of the command line.
7961     I<CreateTTY>     bits control attempts to create a new TTY on events:
7962             1: on fork()    2: debugger is started inside debugger
7963             4: on startup
7964     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7965     You can put additional initialization options I<TTY>, I<noTTY>,
7966     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7967     B<R> after you set them).
7968
7969 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7970 B<h>        Summary of debugger commands.
7971 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7972 B<h h>        Long help for debugger commands
7973 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7974         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7975         Set B<\$DB::doccmd> to change viewer.
7976
7977 Type '|h h' for a paged display if this was too hard to read.
7978
7979 ";    # Fix balance of vi % matching: }}}}
7980
7981     #  note: tabs in the following section are not-so-helpful
7982     $summary = <<"END_SUM";
7983 I<List/search source lines:>               I<Control script execution:>
7984   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7985   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7986   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
7987   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7988   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7989   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
7990 I<Debugger controls:>                        B<L>           List break/watch/actions
7991   B<o> [...]     Set debugger options        B<t> [I<n>] [I<expr>] Toggle trace [max depth] ][trace expr]
7992   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7993   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
7994   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7995   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
7996   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
7997   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
7998   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7999   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
8000 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
8001   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
8002   B<p> I<expr>         Print expression (uses script's current package).
8003   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
8004   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
8005   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
8006   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8007   B<e>     Display thread id     B<E> Display all thread ids.
8008 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
8009 END_SUM
8010
8011     # ')}}; # Fix balance of vi % matching
8012
8013     # and this is really numb...
8014     $pre580_help = "
8015 B<T>        Stack trace.
8016 B<s> [I<expr>]    Single step [in I<expr>].
8017 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
8018 B<CR>>        Repeat last B<n> or B<s> command.
8019 B<r>        Return from current subroutine.
8020 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
8021         at the specified position.
8022 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
8023 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
8024 B<l> I<line>        List single I<line>.
8025 B<l> I<subname>    List first window of lines from subroutine.
8026 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
8027 B<l>        List next window of lines.
8028 B<->        List previous window of lines.
8029 B<w> [I<line>]    List window around I<line>.
8030 B<.>        Return to the executed line.
8031 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
8032         I<filename> may be either the full name of the file, or a regular
8033         expression matching the full file name:
8034         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
8035         Evals (with saved bodies) are considered to be filenames:
8036         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
8037         (in the order of execution).
8038 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
8039 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
8040 B<L>        List all breakpoints and actions.
8041 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
8042 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth) .
8043 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
8044 B<b> [I<line>] [I<condition>]
8045         Set breakpoint; I<line> defaults to the current execution line;
8046         I<condition> breaks if it evaluates to true, defaults to '1'.
8047 B<b> I<subname> [I<condition>]
8048         Set breakpoint at first line of subroutine.
8049 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
8050 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
8051 B<b> B<postpone> I<subname> [I<condition>]
8052         Set breakpoint at first line of subroutine after
8053         it is compiled.
8054 B<b> B<compile> I<subname>
8055         Stop after the subroutine is compiled.
8056 B<d> [I<line>]    Delete the breakpoint for I<line>.
8057 B<D>        Delete all breakpoints.
8058 B<a> [I<line>] I<command>
8059         Set an action to be done before the I<line> is executed;
8060         I<line> defaults to the current execution line.
8061         Sequence is: check for breakpoint/watchpoint, print line
8062         if necessary, do action, prompt user if necessary,
8063         execute line.
8064 B<a> [I<line>]    Delete the action for I<line>.
8065 B<A>        Delete all actions.
8066 B<W> I<expr>        Add a global watch-expression.
8067 B<W>        Delete all watch-expressions.
8068 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
8069         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
8070 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
8071 B<x> I<expr>        Evals expression in list context, dumps the result.
8072 B<m> I<expr>        Evals expression in list context, prints methods callable
8073         on the first element of the result.
8074 B<m> I<class>        Prints methods callable via the given class.
8075
8076 B<<> ?            List Perl commands to run before each prompt.
8077 B<<> I<expr>        Define Perl command to run before each prompt.
8078 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
8079 B<>> ?            List Perl commands to run after each prompt.
8080 B<>> I<expr>        Define Perl command to run after each prompt.
8081 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
8082 B<{> I<db_command>    Define debugger command to run before each prompt.
8083 B<{> ?            List debugger commands to run before each prompt.
8084 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
8085 B<$prc> I<number>    Redo a previous command (default previous command).
8086 B<$prc> I<-number>    Redo number'th-to-last command.
8087 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
8088         See 'B<O> I<recallCommand>' too.
8089 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
8090       . (
8091         $rc eq $sh
8092         ? ""
8093         : "
8094 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
8095       ) . "
8096         See 'B<O> I<shellBang>' too.
8097 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
8098 B<H> I<-number>    Display last number commands (default all).
8099 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
8100 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
8101 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
8102 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
8103 I<command>        Execute as a perl statement in current package.
8104 B<v>        Show versions of loaded modules.
8105 B<R>        Pure-man-restart of debugger, some of debugger state
8106         and command-line options may be lost.
8107         Currently the following settings are preserved:
8108         history, breakpoints and actions, debugger B<O>ptions
8109         and the following command-line options: I<-w>, I<-I>, I<-e>.
8110
8111 B<O> [I<opt>] ...    Set boolean option to true
8112 B<O> [I<opt>B<?>]    Query options
8113 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
8114         Set options.  Use quotes if spaces in value.
8115     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
8116     I<pager>            program for output of \"|cmd\";
8117     I<tkRunning>            run Tk while prompting (with ReadLine);
8118     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
8119     I<inhibit_exit>        Allows stepping off the end of the script.
8120     I<ImmediateStop>        Debugger should stop as early as possible.
8121     I<RemotePort>            Remote hostname:port for remote debugging
8122   The following options affect what happens with B<V>, B<X>, and B<x> commands:
8123     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
8124     I<compactDump>, I<veryCompact>     change style of array and hash dump;
8125     I<globPrint>             whether to print contents of globs;
8126     I<DumpDBFiles>         dump arrays holding debugged files;
8127     I<DumpPackages>         dump symbol tables of packages;
8128     I<DumpReused>             dump contents of \"reused\" addresses;
8129     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
8130     I<bareStringify>         Do not print the overload-stringified value;
8131   Other options include:
8132     I<PrintRet>        affects printing of return value after B<r> command,
8133     I<frame>        affects printing messages on subroutine entry/exit.
8134     I<AutoTrace>    affects printing messages on possible breaking points.
8135     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
8136     I<ornaments>     affects screen appearance of the command line.
8137     I<CreateTTY>     bits control attempts to create a new TTY on events:
8138             1: on fork()    2: debugger is started inside debugger
8139             4: on startup
8140     During startup options are initialized from \$ENV{PERLDB_OPTS}.
8141     You can put additional initialization options I<TTY>, I<noTTY>,
8142     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
8143     B<R> after you set them).
8144
8145 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
8146 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
8147 B<h h>        Summary of debugger commands.
8148 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
8149         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
8150         Set B<\$DB::doccmd> to change viewer.
8151
8152 Type '|h' for a paged display if this was too hard to read.
8153
8154 ";    # Fix balance of vi % matching: }}}}
8155
8156     #  note: tabs in the following section are not-so-helpful
8157     $pre580_summary = <<"END_SUM";
8158 I<List/search source lines:>               I<Control script execution:>
8159   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
8160   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
8161   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
8162   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
8163   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
8164   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
8165 I<Debugger controls:>                        B<L>           List break/watch/actions
8166   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
8167   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
8168   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
8169   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
8170   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
8171   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
8172   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
8173   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
8174 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
8175   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
8176   B<p> I<expr>         Print expression (uses script's current package).
8177   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
8178   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
8179   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
8180   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8181 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
8182 END_SUM
8183
8184     # ')}}; # Fix balance of vi % matching
8185
8186 } ## end sub sethelp
8187
8188 =head2 C<print_help()>
8189
8190 Most of what C<print_help> does is just text formatting. It finds the
8191 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
8192 terminal control characters to simulate them (courtesy of
8193 C<Term::ReadLine::TermCap>).
8194
8195 =cut
8196
8197 sub print_help {
8198     my $help_str = shift;
8199
8200     # Restore proper alignment destroyed by eeevil I<> and B<>
8201     # ornaments: A pox on both their houses!
8202     #
8203     # A help command will have everything up to and including
8204     # the first tab sequence padded into a field 16 (or if indented 20)
8205     # wide.  If it's wider than that, an extra space will be added.
8206     $help_str =~ s{
8207         ^                       # only matters at start of line
8208           ( \040{4} | \t )*     # some subcommands are indented
8209           ( < ?                 # so <CR> works
8210             [BI] < [^\t\n] + )  # find an eeevil ornament
8211           ( \t+ )               # original separation, discarded
8212           ( .* )                # this will now start (no earlier) than
8213                                 # column 16
8214     } {
8215         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
8216         my $clean = $command;
8217         $clean =~ s/[BI]<([^>]*)>/$1/g;
8218
8219         # replace with this whole string:
8220         ($leadwhite ? " " x 4 : "")
8221       . $command
8222       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
8223       . $text;
8224
8225     }mgex;
8226
8227     $help_str =~ s{                          # handle bold ornaments
8228        B < ( [^>] + | > ) >
8229     } {
8230           $Term::ReadLine::TermCap::rl_term_set[2]
8231         . $1
8232         . $Term::ReadLine::TermCap::rl_term_set[3]
8233     }gex;
8234
8235     $help_str =~ s{                         # handle italic ornaments
8236        I < ( [^>] + | > ) >
8237     } {
8238           $Term::ReadLine::TermCap::rl_term_set[0]
8239         . $1
8240         . $Term::ReadLine::TermCap::rl_term_set[1]
8241     }gex;
8242
8243     local $\ = '';
8244     print {$OUT} $help_str;
8245
8246     return;
8247 } ## end sub print_help
8248
8249 =head2 C<fix_less>
8250
8251 This routine does a lot of gyrations to be sure that the pager is C<less>.
8252 It checks for C<less> masquerading as C<more> and records the result in
8253 C<$fixed_less> so we don't have to go through doing the stats again.
8254
8255 =cut
8256
8257 use vars qw($fixed_less);
8258
8259 sub _calc_is_less {
8260     if ($pager =~ /\bless\b/)
8261     {
8262         return 1;
8263     }
8264     elsif ($pager =~ /\bmore\b/)
8265     {
8266         # Nope, set to more. See what's out there.
8267         my @st_more = stat('/usr/bin/more');
8268         my @st_less = stat('/usr/bin/less');
8269
8270         # is it really less, pretending to be more?
8271         return (
8272             @st_more
8273             && @st_less
8274             && $st_more[0] == $st_less[0]
8275             && $st_more[1] == $st_less[1]
8276         );
8277     }
8278     else {
8279         return;
8280     }
8281 }
8282
8283 sub fix_less {
8284
8285     # We already know if this is set.
8286     return if $fixed_less;
8287
8288     # changes environment!
8289     # 'r' added so we don't do (slow) stats again.
8290     $fixed_less = 1 if _calc_is_less();
8291
8292     return;
8293 } ## end sub fix_less
8294
8295 =head1 DIE AND WARN MANAGEMENT
8296
8297 =head2 C<diesignal>
8298
8299 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
8300 to debug a debugger problem.
8301
8302 It does its best to report the error that occurred, and then forces the
8303 program, debugger, and everything to die.
8304
8305 =cut
8306
8307 sub diesignal {
8308
8309     # No entry/exit messages.
8310     local $frame = 0;
8311
8312     # No return value prints.
8313     local $doret = -2;
8314
8315     # set the abort signal handling to the default (just terminate).
8316     $SIG{'ABRT'} = 'DEFAULT';
8317
8318     # If we enter the signal handler recursively, kill myself with an
8319     # abort signal (so we just terminate).
8320     kill 'ABRT', $$ if $panic++;
8321
8322     # If we can show detailed info, do so.
8323     if ( defined &Carp::longmess ) {
8324
8325         # Don't recursively enter the warn handler, since we're carping.
8326         local $SIG{__WARN__} = '';
8327
8328         # Skip two levels before reporting traceback: we're skipping
8329         # mydie and confess.
8330         local $Carp::CarpLevel = 2;    # mydie + confess
8331
8332         # Tell us all about it.
8333         _db_warn( Carp::longmess("Signal @_") );
8334     }
8335
8336     # No Carp. Tell us about the signal as best we can.
8337     else {
8338         local $\ = '';
8339         print $DB::OUT "Got signal @_\n";
8340     }
8341
8342     # Drop dead.
8343     kill 'ABRT', $$;
8344 } ## end sub diesignal
8345
8346 =head2 C<dbwarn>
8347
8348 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
8349 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
8350
8351 =cut
8352
8353 sub dbwarn {
8354
8355     # No entry/exit trace.
8356     local $frame = 0;
8357
8358     # No return value printing.
8359     local $doret = -2;
8360
8361     # Turn off warn and die handling to prevent recursive entries to this
8362     # routine.
8363     local $SIG{__WARN__} = '';
8364     local $SIG{__DIE__}  = '';
8365
8366     # Load Carp if we can. If $^S is false (current thing being compiled isn't
8367     # done yet), we may not be able to do a require.
8368     eval { require Carp }
8369       if defined $^S;    # If error/warning during compilation,
8370                          # require may be broken.
8371
8372     # Use the core warn() unless Carp loaded OK.
8373     CORE::warn( @_,
8374         "\nCannot print stack trace, load with -MCarp option to see stack" ),
8375       return
8376       unless defined &Carp::longmess;
8377
8378     # Save the current values of $single and $trace, and then turn them off.
8379     my ( $mysingle, $mytrace ) = ( $single, $trace );
8380     $single = 0;
8381     $trace  = 0;
8382
8383     # We can call Carp::longmess without its being "debugged" (which we
8384     # don't want - we just want to use it!). Capture this for later.
8385     my $mess = Carp::longmess(@_);
8386
8387     # Restore $single and $trace to their original values.
8388     ( $single, $trace ) = ( $mysingle, $mytrace );
8389
8390     # Use the debugger's own special way of printing warnings to print
8391     # the stack trace message.
8392     _db_warn($mess);
8393 } ## end sub dbwarn
8394
8395 =head2 C<dbdie>
8396
8397 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
8398 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
8399 single stepping and tracing during the call to C<Carp::longmess> to avoid
8400 debugging it - we just want to use it.
8401
8402 If C<dieLevel> is zero, we let the program being debugged handle the
8403 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
8404 the debugger takes over all exception handling, printing a backtrace and
8405 displaying the exception via its C<dbwarn()> routine.
8406
8407 =cut
8408
8409 sub dbdie {
8410     local $frame         = 0;
8411     local $doret         = -2;
8412     local $SIG{__DIE__}  = '';
8413     local $SIG{__WARN__} = '';
8414     if ( $dieLevel > 2 ) {
8415         local $SIG{__WARN__} = \&dbwarn;
8416         _db_warn(@_);    # Yell no matter what
8417         return;
8418     }
8419     if ( $dieLevel < 2 ) {
8420         die @_ if $^S;    # in eval propagate
8421     }
8422
8423     # The code used to check $^S to see if compilation of the current thing
8424     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
8425     eval { require Carp };
8426
8427     die( @_,
8428         "\nCannot print stack trace, load with -MCarp option to see stack" )
8429       unless defined &Carp::longmess;
8430
8431     # We do not want to debug this chunk (automatic disabling works
8432     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
8433     # get the stack trace from Carp::longmess (if possible), restore $signal
8434     # and $trace, and then die with the stack trace.
8435     my ( $mysingle, $mytrace ) = ( $single, $trace );
8436     $single = 0;
8437     $trace  = 0;
8438     my $mess = "@_";
8439     {
8440
8441         package Carp;    # Do not include us in the list
8442         eval { $mess = Carp::longmess(@_); };
8443     }
8444     ( $single, $trace ) = ( $mysingle, $mytrace );
8445     die $mess;
8446 } ## end sub dbdie
8447
8448 =head2 C<warnlevel()>
8449
8450 Set the C<$DB::warnLevel> variable that stores the value of the
8451 C<warnLevel> option. Calling C<warnLevel()> with a positive value
8452 results in the debugger taking over all warning handlers. Setting
8453 C<warnLevel> to zero leaves any warning handlers set up by the program
8454 being debugged in place.
8455
8456 =cut
8457
8458 sub warnLevel {
8459     if (@_) {
8460         my $prevwarn = $SIG{__WARN__} unless $warnLevel;
8461         $warnLevel = shift;
8462         if ($warnLevel) {
8463             $SIG{__WARN__} = \&DB::dbwarn;
8464         }
8465         elsif ($prevwarn) {
8466             $SIG{__WARN__} = $prevwarn;
8467         } else {
8468             undef $SIG{__WARN__};
8469         }
8470     } ## end if (@_)
8471     $warnLevel;
8472 } ## end sub warnLevel
8473
8474 =head2 C<dielevel>
8475
8476 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
8477 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
8478 zero lets you use your own C<die()> handler.
8479
8480 =cut
8481
8482 sub dieLevel {
8483     local $\ = '';
8484     if (@_) {
8485         my $prevdie = $SIG{__DIE__} unless $dieLevel;
8486         $dieLevel = shift;
8487         if ($dieLevel) {
8488
8489             # Always set it to dbdie() for non-zero values.
8490             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
8491
8492             # No longer exists, so don't try  to use it.
8493             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
8494
8495             # If we've finished initialization, mention that stack dumps
8496             # are enabled, If dieLevel is 1, we won't stack dump if we die
8497             # in an eval().
8498             print $OUT "Stack dump during die enabled",
8499               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
8500               if $I_m_init;
8501
8502             # XXX This is probably obsolete, given that diehard() is gone.
8503             print $OUT "Dump printed too.\n" if $dieLevel > 2;
8504         } ## end if ($dieLevel)
8505
8506         # Put the old one back if there was one.
8507         elsif ($prevdie) {
8508             $SIG{__DIE__} = $prevdie;
8509             print $OUT "Default die handler restored.\n";
8510         } else {
8511             undef $SIG{__DIE__};
8512             print $OUT "Die handler removed.\n";
8513         }
8514     } ## end if (@_)
8515     $dieLevel;
8516 } ## end sub dieLevel
8517
8518 =head2 C<signalLevel>
8519
8520 Number three in a series: set C<signalLevel> to zero to keep your own
8521 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
8522 takes over and handles them with C<DB::diesignal()>.
8523
8524 =cut
8525
8526 sub signalLevel {
8527     if (@_) {
8528         my $prevsegv = $SIG{SEGV} unless $signalLevel;
8529         my $prevbus  = $SIG{BUS}  unless $signalLevel;
8530         $signalLevel = shift;
8531         if ($signalLevel) {
8532             $SIG{SEGV} = \&DB::diesignal;
8533             $SIG{BUS}  = \&DB::diesignal;
8534         }
8535         else {
8536             $SIG{SEGV} = $prevsegv;
8537             $SIG{BUS}  = $prevbus;
8538         }
8539     } ## end if (@_)
8540     $signalLevel;
8541 } ## end sub signalLevel
8542
8543 =head1 SUBROUTINE DECODING SUPPORT
8544
8545 These subroutines are used during the C<x> and C<X> commands to try to
8546 produce as much information as possible about a code reference. They use
8547 L<Devel::Peek> to try to find the glob in which this code reference lives
8548 (if it does) - this allows us to actually code references which correspond
8549 to named subroutines (including those aliased via glob assignment).
8550
8551 =head2 C<CvGV_name()>
8552
8553 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
8554 via that routine. If this fails, return the reference again (when the
8555 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
8556
8557 =cut
8558
8559 sub CvGV_name {
8560     my $in   = shift;
8561     my $name = CvGV_name_or_bust($in);
8562     defined $name ? $name : $in;
8563 }
8564
8565 =head2 C<CvGV_name_or_bust> I<coderef>
8566
8567 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
8568 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
8569 find a glob for this ref.
8570
8571 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
8572
8573 =cut
8574
8575 use vars qw($skipCvGV);
8576
8577 sub CvGV_name_or_bust {
8578     my $in = shift;
8579     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
8580     return unless ref $in;
8581     $in = \&$in;            # Hard reference...
8582     eval { require Devel::Peek; 1 } or return;
8583     my $gv = Devel::Peek::CvGV($in) or return;
8584     *$gv{PACKAGE} . '::' . *$gv{NAME};
8585 } ## end sub CvGV_name_or_bust
8586
8587 =head2 C<find_sub>
8588
8589 A utility routine used in various places; finds the file where a subroutine
8590 was defined, and returns that filename and a line-number range.
8591
8592 Tries to use C<@sub> first; if it can't find it there, it tries building a
8593 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
8594 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
8595 this way, it brute-force searches C<%sub>, checking for identical references.
8596
8597 =cut
8598
8599 sub _find_sub_helper {
8600     my $subr = shift;
8601
8602     return unless defined &$subr;
8603     my $name = CvGV_name_or_bust($subr);
8604     my $data;
8605     $data = $sub{$name} if defined $name;
8606     return $data if defined $data;
8607
8608     # Old stupid way...
8609     $subr = \&$subr;    # Hard reference
8610     my $s;
8611     for ( keys %sub ) {
8612         $s = $_, last if $subr eq \&$_;
8613     }
8614     if ($s)
8615     {
8616         return $sub{$s};
8617     }
8618     else
8619     {
8620         return;
8621     }
8622
8623 }
8624
8625 sub find_sub {
8626     my $subr = shift;
8627     return ( $sub{$subr} || _find_sub_helper($subr) );
8628 } ## end sub find_sub
8629
8630 =head2 C<methods>
8631
8632 A subroutine that uses the utility function C<methods_via> to find all the
8633 methods in the class corresponding to the current reference and in
8634 C<UNIVERSAL>.
8635
8636 =cut
8637
8638 use vars qw(%seen);
8639
8640 sub methods {
8641
8642     # Figure out the class - either this is the class or it's a reference
8643     # to something blessed into that class.
8644     my $class = shift;
8645     $class = ref $class if ref $class;
8646
8647     local %seen;
8648
8649     # Show the methods that this class has.
8650     methods_via( $class, '', 1 );
8651
8652     # Show the methods that UNIVERSAL has.
8653     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
8654 } ## end sub methods
8655
8656 =head2 C<methods_via($class, $prefix, $crawl_upward)>
8657
8658 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
8659 all the parent class methods. C<$class> is the name of the next class to
8660 try; C<$prefix> is the message prefix, which gets built up as we go up the
8661 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
8662 higher in the C<@ISA> tree, 0 if we should stop.
8663
8664 =cut
8665
8666 sub methods_via {
8667
8668     # If we've processed this class already, just quit.
8669     my $class = shift;
8670     return if $seen{$class}++;
8671
8672     # This is a package that is contributing the methods we're about to print.
8673     my $prefix  = shift;
8674     my $prepend = $prefix ? "via $prefix: " : '';
8675     my @to_print;
8676
8677     # Extract from all the symbols in this class.
8678     my $class_ref = do { no strict "refs"; \%{$class . '::'} };
8679     while (my ($name, $glob) = each %$class_ref) {
8680         # references directly in the symbol table are Proxy Constant
8681         # Subroutines, and are by their very nature defined
8682         # Otherwise, check if the thing is a typeglob, and if it is, it decays
8683         # to a subroutine reference, which can be tested by defined.
8684         # $glob might also be the value -1  (from sub foo;)
8685         # or (say) '$$' (from sub foo ($$);)
8686         # \$glob will be SCALAR in both cases.
8687         if ((ref $glob || ($glob && ref \$glob eq 'GLOB' && defined &$glob))
8688             && !$seen{$name}++) {
8689             push @to_print, "$prepend$name\n";
8690         }
8691     }
8692
8693     {
8694         local $\ = '';
8695         local $, = '';
8696         print $DB::OUT $_ foreach sort @to_print;
8697     }
8698
8699     # If the $crawl_upward argument is false, just quit here.
8700     return unless shift;
8701
8702     # $crawl_upward true: keep going up the tree.
8703     # Find all the classes this one is a subclass of.
8704     my $class_ISA_ref = do { no strict "refs"; \@{"${class}::ISA"} };
8705     for my $name ( @$class_ISA_ref ) {
8706
8707         # Set up the new prefix.
8708         $prepend = $prefix ? $prefix . " -> $name" : $name;
8709
8710         # Crawl up the tree and keep trying to crawl up.
8711         methods_via( $name, $prepend, 1 );
8712     }
8713 } ## end sub methods_via
8714
8715 =head2 C<setman> - figure out which command to use to show documentation
8716
8717 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8718
8719 =cut
8720
8721 sub setman {
8722     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|NetWare)\z/s
8723       ? "man"         # O Happy Day!
8724       : "perldoc";    # Alas, poor unfortunates
8725 } ## end sub setman
8726
8727 =head2 C<runman> - run the appropriate command to show documentation
8728
8729 Accepts a man page name; runs the appropriate command to display it (set up
8730 during debugger initialization). Uses C<_db_system()> to avoid mucking up the
8731 program's STDIN and STDOUT.
8732
8733 =cut
8734
8735 my %_is_in_pods = (map { $_ => 1 }
8736     qw(
8737     5004delta
8738     5005delta
8739     561delta
8740     56delta
8741     570delta
8742     571delta
8743     572delta
8744     573delta
8745     58delta
8746     581delta
8747     582delta
8748     583delta
8749     584delta
8750     590delta
8751     591delta
8752     592delta
8753     aix
8754     amiga
8755     apio
8756     api
8757     artistic
8758     beos
8759     book
8760     boot
8761     bot
8762     bs2000
8763     call
8764     ce
8765     cheat
8766     clib
8767     cn
8768     compile
8769     cygwin
8770     data
8771     dbmfilter
8772     debguts
8773     debtut
8774     debug
8775     delta
8776     dgux
8777     diag
8778     doc
8779     dos
8780     dsc
8781     ebcdic
8782     embed
8783     faq1
8784     faq2
8785     faq3
8786     faq4
8787     faq5
8788     faq6
8789     faq7
8790     faq8
8791     faq9
8792     faq
8793     filter
8794     fork
8795     form
8796     freebsd
8797     func
8798     gpl
8799     guts
8800     hack
8801     hist
8802     hpux
8803     hurd
8804     intern
8805     intro
8806     iol
8807     ipc
8808     irix
8809     jp
8810     ko
8811     lexwarn
8812     locale
8813     lol
8814     macos
8815     macosx
8816     modinstall
8817     modlib
8818     mod
8819     modstyle
8820     netware
8821     newmod
8822     number
8823     obj
8824     opentut
8825     op
8826     os2
8827     os390
8828     os400
8829     packtut
8830     plan9
8831     pod
8832     podspec
8833     port
8834     qnx
8835     ref
8836     reftut
8837     re
8838     requick
8839     reref
8840     retut
8841     run
8842     sec
8843     solaris
8844     style
8845     sub
8846     syn
8847     thrtut
8848     tie
8849     toc
8850     todo
8851     tooc
8852     toot
8853     trap
8854     tru64
8855     tw
8856     unicode
8857     uniintro
8858     util
8859     uts
8860     var
8861     vms
8862     vos
8863     win32
8864     xs
8865     xstut
8866     )
8867 );
8868
8869 sub runman {
8870     my $page = shift;
8871     unless ($page) {
8872         _db_system("$doccmd $doccmd");
8873         return;
8874     }
8875
8876     # this way user can override, like with $doccmd="man -Mwhatever"
8877     # or even just "man " to disable the path check.
8878     if ( $doccmd ne 'man' ) {
8879         _db_system("$doccmd $page");
8880         return;
8881     }
8882
8883     $page = 'perl' if lc($page) eq 'help';
8884
8885     require Config;
8886     my $man1dir = $Config::Config{'man1dir'};
8887     my $man3dir = $Config::Config{'man3dir'};
8888     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
8889     my $manpath = '';
8890     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
8891     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
8892     chop $manpath if $manpath;
8893
8894     # harmless if missing, I figure
8895     my $oldpath = $ENV{MANPATH};
8896     $ENV{MANPATH} = $manpath if $manpath;
8897     my $nopathopt = $^O =~ /dunno what goes here/;
8898     if (
8899         CORE::system(
8900             $doccmd,
8901
8902             # I just *know* there are men without -M
8903             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8904             split ' ', $page
8905         )
8906       )
8907     {
8908         unless ( $page =~ /^perl\w/ ) {
8909 # do it this way because its easier to slurp in to keep up to date - clunky though.
8910             if (exists($_is_in_pods{$page})) {
8911                 CORE::system( $doccmd,
8912                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8913                     "perl$page" );
8914             }
8915         }
8916     } ## end if (CORE::system($doccmd...
8917     if ( defined $oldpath ) {
8918         $ENV{MANPATH} = $manpath;
8919     }
8920     else {
8921         delete $ENV{MANPATH};
8922     }
8923 } ## end sub runman
8924
8925 #use Carp;                          # This did break, left for debugging
8926
8927 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
8928
8929 Because of the way the debugger interface to the Perl core is designed, any
8930 debugger package globals that C<DB::sub()> requires have to be defined before
8931 any subroutines can be called. These are defined in the second C<BEGIN> block.
8932
8933 This block sets things up so that (basically) the world is sane
8934 before the debugger starts executing. We set up various variables that the
8935 debugger has to have set up before the Perl core starts running:
8936
8937 =over 4
8938
8939 =item *
8940
8941 The debugger's own filehandles (copies of STD and STDOUT for now).
8942
8943 =item *
8944
8945 Characters for shell escapes, the recall command, and the history command.
8946
8947 =item *
8948
8949 The maximum recursion depth.
8950
8951 =item *
8952
8953 The size of a C<w> command's window.
8954
8955 =item *
8956
8957 The before-this-line context to be printed in a C<v> (view a window around this line) command.
8958
8959 =item *
8960
8961 The fact that we're not in a sub at all right now.
8962
8963 =item *
8964
8965 The default SIGINT handler for the debugger.
8966
8967 =item *
8968
8969 The appropriate value of the flag in C<$^D> that says the debugger is running
8970
8971 =item *
8972
8973 The current debugger recursion level
8974
8975 =item *
8976
8977 The list of postponed items and the C<$single> stack (XXX define this)
8978
8979 =item *
8980
8981 That we want no return values and no subroutine entry/exit trace.
8982
8983 =back
8984
8985 =cut
8986
8987 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
8988
8989 use vars qw($db_stop);
8990
8991 BEGIN {    # This does not compile, alas. (XXX eh?)
8992     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
8993     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
8994
8995     # Define characters used by command parsing.
8996     $sh       = '!';      # Shell escape (does not work)
8997     $rc       = ',';      # Recall command (does not work)
8998     @hist     = ('?');    # Show history (does not work)
8999     @truehist = ();       # Can be saved for replay (per session)
9000
9001     # This defines the point at which you get the 'deep recursion'
9002     # warning. It MUST be defined or the debugger will not load.
9003     $deep = 100;
9004
9005     # Number of lines around the current one that are shown in the
9006     # 'w' command.
9007     $window = 10;
9008
9009     # How much before-the-current-line context the 'v' command should
9010     # use in calculating the start of the window it will display.
9011     $preview = 3;
9012
9013     # We're not in any sub yet, but we need this to be a defined value.
9014     $sub = '';
9015
9016     # Set up the debugger's interrupt handler. It simply sets a flag
9017     # ($signal) that DB::DB() will check before each command is executed.
9018     $SIG{INT} = \&DB::catch;
9019
9020     # The following lines supposedly, if uncommented, allow the debugger to
9021     # debug itself. Perhaps we can try that someday.
9022     # This may be enabled to debug debugger:
9023     #$warnLevel = 1 unless defined $warnLevel;
9024     #$dieLevel = 1 unless defined $dieLevel;
9025     #$signalLevel = 1 unless defined $signalLevel;
9026
9027     # This is the flag that says "a debugger is running, please call
9028     # DB::DB and DB::sub". We will turn it on forcibly before we try to
9029     # execute anything in the user's context, because we always want to
9030     # get control back.
9031     $db_stop = 0;          # Compiler warning ...
9032     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
9033
9034     # This variable records how many levels we're nested in debugging. Used
9035     # Used in the debugger prompt, and in determining whether it's all over or
9036     # not.
9037     $level = 0;            # Level of recursive debugging
9038
9039     # "Triggers bug (?) in perl if we postpone this until runtime."
9040     # XXX No details on this yet, or whether we should fix the bug instead
9041     # of work around it. Stay tuned.
9042     @stack = (0);
9043
9044     # Used to track the current stack depth using the auto-stacked-variable
9045     # trick.
9046     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
9047
9048     # Don't print return values on exiting a subroutine.
9049     $doret = -2;
9050
9051     # No extry/exit tracing.
9052     $frame = 0;
9053
9054 } ## end BEGIN
9055
9056 BEGIN { $^W = $ini_warn; }    # Switch warnings back
9057
9058 =head1 READLINE SUPPORT - COMPLETION FUNCTION
9059
9060 =head2 db_complete
9061
9062 C<readline> support - adds command completion to basic C<readline>.
9063
9064 Returns a list of possible completions to C<readline> when invoked. C<readline>
9065 will print the longest common substring following the text already entered.
9066
9067 If there is only a single possible completion, C<readline> will use it in full.
9068
9069 This code uses C<map> and C<grep> heavily to create lists of possible
9070 completion. Think LISP in this section.
9071
9072 =cut
9073
9074 sub db_complete {
9075
9076     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
9077     # $text is the text to be completed.
9078     # $line is the incoming line typed by the user.
9079     # $start is the start of the text to be completed in the incoming line.
9080     my ( $text, $line, $start ) = @_;
9081
9082     # Save the initial text.
9083     # The search pattern is current package, ::, extract the next qualifier
9084     # Prefix and pack are set to undef.
9085     my ( $itext, $search, $prefix, $pack ) =
9086       ( $text, "^\Q${package}::\E([^:]+)\$" );
9087
9088 =head3 C<b postpone|compile>
9089
9090 =over 4
9091
9092 =item *
9093
9094 Find all the subroutines that might match in this package
9095
9096 =item *
9097
9098 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
9099
9100 =item *
9101
9102 Include all the rest of the subs that are known
9103
9104 =item *
9105
9106 C<grep> out the ones that match the text we have so far
9107
9108 =item *
9109
9110 Return this as the list of possible completions
9111
9112 =back
9113
9114 =cut
9115
9116     return sort grep /^\Q$text/, ( keys %sub ),
9117       qw(postpone load compile),    # subroutines
9118       ( map { /$search/ ? ($1) : () } keys %sub )
9119       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
9120
9121 =head3 C<b load>
9122
9123 Get all the possible files from C<@INC> as it currently stands and
9124 select the ones that match the text so far.
9125
9126 =cut
9127
9128     return sort grep /^\Q$text/, values %INC    # files
9129       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
9130
9131 =head3  C<V> (list variable) and C<m> (list modules)
9132
9133 There are two entry points for these commands:
9134
9135 =head4 Unqualified package names
9136
9137 Get the top-level packages and grab everything that matches the text
9138 so far. For each match, recursively complete the partial packages to
9139 get all possible matching packages. Return this sorted list.
9140
9141 =cut
9142
9143     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
9144       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
9145       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
9146
9147 =head4 Qualified package names
9148
9149 Take a partially-qualified package and find all subpackages for it
9150 by getting all the subpackages for the package so far, matching all
9151 the subpackages against the text, and discarding all of them which
9152 start with 'main::'. Return this list.
9153
9154 =cut
9155
9156     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
9157       grep !/^main::/, grep /^\Q$text/,
9158       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () }
9159       do { no strict 'refs'; keys %{ $prefix . '::' } }
9160       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
9161       and $text =~ /^(.*[^:])::?(\w*)$/
9162       and $prefix = $1;
9163
9164 =head3 C<f> - switch files
9165
9166 Here, we want to get a fully-qualified filename for the C<f> command.
9167 Possibilities are:
9168
9169 =over 4
9170
9171 =item 1. The original source file itself
9172
9173 =item 2. A file from C<@INC>
9174
9175 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
9176
9177 =back
9178
9179 =cut
9180
9181     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
9182            # We might possibly want to switch to an eval (which has a "filename"
9183            # like '(eval 9)'), so we may need to clean up the completion text
9184            # before proceeding.
9185         $prefix = length($1) - length($text);
9186         $text   = $1;
9187
9188 =pod
9189
9190 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
9191 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
9192 out of C<%main::>, add the initial source file, and extract the ones that
9193 match the completion text so far.
9194
9195 =cut
9196
9197         return sort
9198           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
9199           $0;
9200     } ## end if ($line =~ /^\|*f\s+(.*)/)
9201
9202 =head3 Subroutine name completion
9203
9204 We look through all of the defined subs (the keys of C<%sub>) and
9205 return both all the possible matches to the subroutine name plus
9206 all the matches qualified to the current package.
9207
9208 =cut
9209
9210     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
9211         $text = substr $text, 1;
9212         $prefix = "&";
9213         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
9214           (
9215             map { /$search/ ? ($1) : () }
9216               keys %sub
9217           );
9218     } ## end if ((substr $text, 0, ...
9219
9220 =head3  Scalar, array, and hash completion: partially qualified package
9221
9222 Much like the above, except we have to do a little more cleanup:
9223
9224 =cut
9225
9226     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
9227
9228 =pod
9229
9230 =over 4
9231
9232 =item *
9233
9234 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
9235
9236 =cut
9237
9238         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
9239
9240 =pod
9241
9242 =item *
9243
9244 Figure out the prefix vs. what needs completing.
9245
9246 =cut
9247
9248         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
9249         $text   = $2;
9250
9251 =pod
9252
9253 =item *
9254
9255 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
9256
9257 =cut
9258
9259         my @out = do {
9260             no strict 'refs';
9261             map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
9262             keys %$pack;
9263         };
9264
9265 =pod
9266
9267 =item *
9268
9269 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
9270
9271 =cut
9272
9273         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9274             return db_complete( $out[0], $line, $start );
9275         }
9276
9277         # Return the list of possibles.
9278         return sort @out;
9279
9280     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
9281
9282 =pod
9283
9284 =back
9285
9286 =head3 Symbol completion: current package or package C<main>.
9287
9288 =cut
9289
9290     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
9291 =pod
9292
9293 =over 4
9294
9295 =item *
9296
9297 If it's C<main>, delete main to just get C<::> leading.
9298
9299 =cut
9300
9301         $pack = ( $package eq 'main' ? '' : $package ) . '::';
9302
9303 =pod
9304
9305 =item *
9306
9307 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
9308
9309 =cut
9310
9311         $prefix = substr $text, 0, 1;
9312         $text   = substr $text, 1;
9313
9314         my @out;
9315
9316 =pod
9317
9318 =item *
9319
9320 We look for the lexical scope above DB::DB and auto-complete lexical variables
9321 if PadWalker could be loaded.
9322
9323 =cut
9324
9325         if (not $text =~ /::/ and eval { require PadWalker } ) {
9326             my $level = 1;
9327             while (1) {
9328                 my @info = caller($level);
9329                 $level++;
9330                 $level = -1, last
9331                   if not @info;
9332                 last if $info[3] eq 'DB::DB';
9333             }
9334             if ($level > 0) {
9335                 my $lexicals = PadWalker::peek_my($level);
9336                 push @out, grep /^\Q$prefix$text/, keys %$lexicals;
9337             }
9338         }
9339
9340 =pod
9341
9342 =item *
9343
9344 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
9345
9346 =cut
9347
9348         push @out, map "$prefix$_", grep /^\Q$text/,
9349           ( grep /^_?[a-zA-Z]/, keys %$pack ),
9350           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
9351
9352 =item *
9353
9354 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
9355
9356 =back
9357
9358 =cut
9359
9360         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9361             return db_complete( $out[0], $line, $start );
9362         }
9363
9364         # Return the list of possibles.
9365         return sort @out;
9366     } ## end if ($text =~ /^[\$@%]/)
9367
9368 =head3 Options
9369
9370 We use C<option_val()> to look up the current value of the option. If there's
9371 only a single value, we complete the command in such a way that it is a
9372 complete command for setting the option in question. If there are multiple
9373 possible values, we generate a command consisting of the option plus a trailing
9374 question mark, which, if executed, will list the current value of the option.
9375
9376 =cut
9377
9378     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
9379     {    # Options after space
9380            # We look for the text to be matched in the list of possible options,
9381            # and fetch the current value.
9382         my @out = grep /^\Q$text/, @options;
9383         my $val = option_val( $out[0], undef );
9384
9385         # Set up a 'query option's value' command.
9386         my $out = '? ';
9387         if ( not defined $val or $val =~ /[\n\r]/ ) {
9388
9389             # There's really nothing else we can do.
9390         }
9391
9392         # We have a value. Create a proper option-setting command.
9393         elsif ( $val =~ /\s/ ) {
9394
9395             # XXX This may be an extraneous variable.
9396             my $found;
9397
9398             # We'll want to quote the string (because of the embedded
9399             # whtespace), but we want to make sure we don't end up with
9400             # mismatched quote characters. We try several possibilities.
9401             foreach my $l ( split //, qq/\"\'\#\|/ ) {
9402
9403                 # If we didn't find this quote character in the value,
9404                 # quote it using this quote character.
9405                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
9406             }
9407         } ## end elsif ($val =~ /\s/)
9408
9409         # Don't need any quotes.
9410         else {
9411             $out = "=$val ";
9412         }
9413
9414         # If there were multiple possible values, return '? ', which
9415         # makes the command into a query command. If there was just one,
9416         # have readline append that.
9417         $rl_attribs->{completer_terminator_character} =
9418           ( @out == 1 ? $out : '? ' );
9419
9420         # Return list of possibilities.
9421         return sort @out;
9422     } ## end if ((substr $line, 0, ...
9423
9424 =head3 Filename completion
9425
9426 For entering filenames. We simply call C<readline>'s C<filename_list()>
9427 method with the completion text to get the possible completions.
9428
9429 =cut
9430
9431     return $term->filename_list($text);    # filenames
9432
9433 } ## end sub db_complete
9434
9435 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
9436
9437 Functions that possibly ought to be somewhere else.
9438
9439 =head2 end_report
9440
9441 Say we're done.
9442
9443 =cut
9444
9445 sub end_report {
9446     local $\ = '';
9447     print $OUT "Use 'q' to quit or 'R' to restart.  'h q' for details.\n";
9448 }
9449
9450 =head2 clean_ENV
9451
9452 If we have $ini_pids, save it in the environment; else remove it from the
9453 environment. Used by the C<R> (restart) command.
9454
9455 =cut
9456
9457 sub clean_ENV {
9458     if ( defined($ini_pids) ) {
9459         $ENV{PERLDB_PIDS} = $ini_pids;
9460     }
9461     else {
9462         delete( $ENV{PERLDB_PIDS} );
9463     }
9464 } ## end sub clean_ENV
9465
9466 # PERLDBf_... flag names from perl.h
9467 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
9468
9469 BEGIN {
9470     %DollarCaretP_flags = (
9471         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
9472         PERLDBf_LINE      => 0x02,     # Keep line #
9473         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
9474         PERLDBf_INTER     => 0x08,     # Preserve more data
9475         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
9476         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
9477         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
9478         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
9479         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
9480         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
9481         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
9482         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
9483     );
9484     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
9485     # doesn't need to set it. It's provided for the benefit of profilers and
9486     # other code analysers.
9487
9488     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
9489 }
9490
9491 sub parse_DollarCaretP_flags {
9492     my $flags = shift;
9493     $flags =~ s/^\s+//;
9494     $flags =~ s/\s+$//;
9495     my $acu = 0;
9496     foreach my $f ( split /\s*\|\s*/, $flags ) {
9497         my $value;
9498         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
9499             $value = hex $1;
9500         }
9501         elsif ( $f =~ /^(\d+)$/ ) {
9502             $value = int $1;
9503         }
9504         elsif ( $f =~ /^DEFAULT$/i ) {
9505             $value = $DollarCaretP_flags{PERLDB_ALL};
9506         }
9507         else {
9508             $f =~ /^(?:PERLDBf_)?(.*)$/i;
9509             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
9510             unless ( defined $value ) {
9511                 print $OUT (
9512                     "Unrecognized \$^P flag '$f'!\n",
9513                     "Acceptable flags are: "
9514                       . join( ', ', sort keys %DollarCaretP_flags ),
9515                     ", and hexadecimal and decimal numbers.\n"
9516                 );
9517                 return undef;
9518             }
9519         }
9520         $acu |= $value;
9521     }
9522     $acu;
9523 }
9524
9525 sub expand_DollarCaretP_flags {
9526     my $DollarCaretP = shift;
9527     my @bits         = (
9528         map {
9529             my $n = ( 1 << $_ );
9530             ( $DollarCaretP & $n )
9531               ? ( $DollarCaretP_flags_r{$n}
9532                   || sprintf( '0x%x', $n ) )
9533               : ()
9534           } 0 .. 31
9535     );
9536     return @bits ? join( '|', @bits ) : 0;
9537 }
9538
9539 =over 4
9540
9541 =item rerun
9542
9543 Rerun the current session to:
9544
9545     rerun        current position
9546
9547     rerun 4      command number 4
9548
9549     rerun -4     current command minus 4 (go back 4 steps)
9550
9551 Whether this always makes sense, in the current context is unknowable, and is
9552 in part left as a useful exercise for the reader.  This sub returns the
9553 appropriate arguments to rerun the current session.
9554
9555 =cut
9556
9557 sub rerun {
9558     my $i = shift;
9559     my @args;
9560     pop(@truehist);                      # strim
9561     unless (defined $truehist[$i]) {
9562         print "Unable to return to non-existent command: $i\n";
9563     } else {
9564         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
9565         my @temp = @truehist;            # store
9566         push(@DB::typeahead, @truehist); # saved
9567         @truehist = @hist = ();          # flush
9568         @args = restart();              # setup
9569         get_list("PERLDB_HIST");        # clean
9570         set_list("PERLDB_HIST", @temp); # reset
9571     }
9572     return @args;
9573 }
9574
9575 =item restart
9576
9577 Restarting the debugger is a complex operation that occurs in several phases.
9578 First, we try to reconstruct the command line that was used to invoke Perl
9579 and the debugger.
9580
9581 =cut
9582
9583 sub restart {
9584     # I may not be able to resurrect you, but here goes ...
9585     print $OUT
9586 "Warning: some settings and command-line options may be lost!\n";
9587     my ( @script, @flags, $cl );
9588
9589     # If warn was on before, turn it on again.
9590     push @flags, '-w' if $ini_warn;
9591
9592     # Rebuild the -I flags that were on the initial
9593     # command line.
9594     for (@ini_INC) {
9595         push @flags, '-I', $_;
9596     }
9597
9598     # Turn on taint if it was on before.
9599     push @flags, '-T' if ${^TAINT};
9600
9601     # Arrange for setting the old INC:
9602     # Save the current @init_INC in the environment.
9603     set_list( "PERLDB_INC", @ini_INC );
9604
9605     # If this was a perl one-liner, go to the "file"
9606     # corresponding to the one-liner read all the lines
9607     # out of it (except for the first one, which is going
9608     # to be added back on again when 'perl -d' runs: that's
9609     # the 'require perl5db.pl;' line), and add them back on
9610     # to the command line to be executed.
9611     if ( $0 eq '-e' ) {
9612         my $lines = *{$main::{'_<-e'}}{ARRAY};
9613         for ( 1 .. $#$lines ) {  # The first line is PERL5DB
9614             chomp( $cl = $lines->[$_] );
9615             push @script, '-e', $cl;
9616         }
9617     } ## end if ($0 eq '-e')
9618
9619     # Otherwise we just reuse the original name we had
9620     # before.
9621     else {
9622         @script = $0;
9623     }
9624
9625 =pod
9626
9627 After the command line  has been reconstructed, the next step is to save
9628 the debugger's status in environment variables. The C<DB::set_list> routine
9629 is used to save aggregate variables (both hashes and arrays); scalars are
9630 just popped into environment variables directly.
9631
9632 =cut
9633
9634     # If the terminal supported history, grab it and
9635     # save that in the environment.
9636     set_list( "PERLDB_HIST",
9637           $term->Features->{getHistory}
9638         ? $term->GetHistory
9639         : @hist );
9640
9641     # Find all the files that were visited during this
9642     # session (i.e., the debugger had magic hashes
9643     # corresponding to them) and stick them in the environment.
9644     my @had_breakpoints = keys %had_breakpoints;
9645     set_list( "PERLDB_VISITED", @had_breakpoints );
9646
9647     # Save the debugger options we chose.
9648     set_list( "PERLDB_OPT", %option );
9649     # set_list( "PERLDB_OPT", options2remember() );
9650
9651     # Save the break-on-loads.
9652     set_list( "PERLDB_ON_LOAD", %break_on_load );
9653
9654 =pod
9655
9656 The most complex part of this is the saving of all of the breakpoints. They
9657 can live in an awful lot of places, and we have to go through all of them,
9658 find the breakpoints, and then save them in the appropriate environment
9659 variable via C<DB::set_list>.
9660
9661 =cut
9662
9663     # Go through all the breakpoints and make sure they're
9664     # still valid.
9665     my @hard;
9666     for ( 0 .. $#had_breakpoints ) {
9667
9668         # We were in this file.
9669         my $file = $had_breakpoints[$_];
9670
9671         # Grab that file's magic line hash.
9672         *dbline = $main::{ '_<' . $file };
9673
9674         # Skip out if it doesn't exist, or if the breakpoint
9675         # is in a postponed file (we'll do postponed ones
9676         # later).
9677         next unless %dbline or $postponed_file{$file};
9678
9679         # In an eval. This is a little harder, so we'll
9680         # do more processing on that below.
9681         ( push @hard, $file ), next
9682           if $file =~ /^\(\w*eval/;
9683
9684         # XXX I have no idea what this is doing. Yet.
9685         my @add;
9686         @add = %{ $postponed_file{$file} }
9687           if $postponed_file{$file};
9688
9689         # Save the list of all the breakpoints for this file.
9690         set_list( "PERLDB_FILE_$_", %dbline, @add );
9691
9692         # Serialize the extra data %breakpoints_data hash.
9693         # That's a bug fix.
9694         set_list( "PERLDB_FILE_ENABLED_$_",
9695             map { _is_breakpoint_enabled($file, $_) ? 1 : 0 }
9696             sort { $a <=> $b } keys(%dbline)
9697         )
9698     } ## end for (0 .. $#had_breakpoints)
9699
9700     # The breakpoint was inside an eval. This is a little
9701     # more difficult. XXX and I don't understand it.
9702     for (@hard) {
9703         # Get over to the eval in question.
9704         *dbline = $main::{ '_<' . $_ };
9705         my ( $quoted, $sub, %subs, $line ) = quotemeta $_;
9706         for $sub ( keys %sub ) {
9707             next unless $sub{$sub} =~ /^$quoted:(\d+)-(\d+)$/;
9708             $subs{$sub} = [ $1, $2 ];
9709         }
9710         unless (%subs) {
9711             print $OUT
9712               "No subroutines in $_, ignoring breakpoints.\n";
9713             next;
9714         }
9715       LINES: for $line ( keys %dbline ) {
9716
9717             # One breakpoint per sub only:
9718             my ( $offset, $sub, $found );
9719           SUBS: for $sub ( keys %subs ) {
9720                 if (
9721                     $subs{$sub}->[1] >=
9722                     $line    # Not after the subroutine
9723                     and (
9724                         not defined $offset    # Not caught
9725                         or $offset < 0
9726                     )
9727                   )
9728                 {                              # or badly caught
9729                     $found  = $sub;
9730                     $offset = $line - $subs{$sub}->[0];
9731                     $offset = "+$offset", last SUBS
9732                       if $offset >= 0;
9733                 } ## end if ($subs{$sub}->[1] >=...
9734             } ## end for $sub (keys %subs)
9735             if ( defined $offset ) {
9736                 $postponed{$found} =
9737                   "break $offset if $dbline{$line}";
9738             }
9739             else {
9740                 print $OUT
9741 "Breakpoint in $_:$line ignored: after all the subroutines.\n";
9742             }
9743         } ## end for $line (keys %dbline)
9744     } ## end for (@hard)
9745
9746     # Save the other things that don't need to be
9747     # processed.
9748     set_list( "PERLDB_POSTPONE",  %postponed );
9749     set_list( "PERLDB_PRETYPE",   @$pretype );
9750     set_list( "PERLDB_PRE",       @$pre );
9751     set_list( "PERLDB_POST",      @$post );
9752     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9753
9754     # We are officially restarting.
9755     $ENV{PERLDB_RESTART} = 1;
9756
9757     # We are junking all child debuggers.
9758     delete $ENV{PERLDB_PIDS};    # Restore ini state
9759
9760     # Set this back to the initial pid.
9761     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9762
9763 =pod
9764
9765 After all the debugger status has been saved, we take the command we built up
9766 and then return it, so we can C<exec()> it. The debugger will spot the
9767 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9768 from the environment.
9769
9770 =cut
9771
9772     # And run Perl again. Add the "-d" flag, all the
9773     # flags we built up, the script (whether a one-liner
9774     # or a file), add on the -emacs flag for a slave editor,
9775     # and then the old arguments.
9776
9777     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9778
9779 };  # end restart
9780
9781 =back
9782
9783 =head1 END PROCESSING - THE C<END> BLOCK
9784
9785 Come here at the very end of processing. We want to go into a
9786 loop where we allow the user to enter commands and interact with the
9787 debugger, but we don't want anything else to execute.
9788
9789 First we set the C<$finished> variable, so that some commands that
9790 shouldn't be run after the end of program quit working.
9791
9792 We then figure out whether we're truly done (as in the user entered a C<q>
9793 command, or we finished execution while running nonstop). If we aren't,
9794 we set C<$single> to 1 (causing the debugger to get control again).
9795
9796 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9797 message and returns control to the debugger. Repeat.
9798
9799 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9800 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9801 break, run to completion.).
9802
9803 =cut
9804
9805 END {
9806     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9807     $fall_off_end = 1 unless $inhibit_exit;
9808
9809     # Do not stop in at_exit() and destructors on exit:
9810     if ($fall_off_end or $runnonstop) {
9811         save_hist();
9812     } else {
9813         $DB::single = 1;
9814         DB::fake::at_exit();
9815     }
9816 } ## end END
9817
9818 =head1 PRE-5.8 COMMANDS
9819
9820 Some of the commands changed function quite a bit in the 5.8 command
9821 realignment, so much so that the old code had to be replaced completely.
9822 Because we wanted to retain the option of being able to go back to the
9823 former command set, we moved the old code off to this section.
9824
9825 There's an awful lot of duplicated code here. We've duplicated the
9826 comments to keep things clear.
9827
9828 =head2 Null command
9829
9830 Does nothing. Used to I<turn off> commands.
9831
9832 =cut
9833
9834 sub cmd_pre580_null {
9835
9836     # do nothing...
9837 }
9838
9839 =head2 Old C<a> command.
9840
9841 This version added actions if you supplied them, and deleted them
9842 if you didn't.
9843
9844 =cut
9845
9846 sub cmd_pre580_a {
9847     my $xcmd = shift;
9848     my $cmd  = shift;
9849
9850     # Argument supplied. Add the action.
9851     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9852
9853         # If the line isn't there, use the current line.
9854         my $i = $1 || $line;
9855         my $j = $2;
9856
9857         # If there is an action ...
9858         if ( length $j ) {
9859
9860             # ... but the line isn't breakable, skip it.
9861             if ( $dbline[$i] == 0 ) {
9862                 print $OUT "Line $i may not have an action.\n";
9863             }
9864             else {
9865
9866                 # ... and the line is breakable:
9867                 # Mark that there's an action in this file.
9868                 $had_breakpoints{$filename} |= 2;
9869
9870                 # Delete any current action.
9871                 $dbline{$i} =~ s/\0[^\0]*//;
9872
9873                 # Add the new action, continuing the line as needed.
9874                 $dbline{$i} .= "\0" . action($j);
9875             }
9876         } ## end if (length $j)
9877
9878         # No action supplied.
9879         else {
9880
9881             # Delete the action.
9882             $dbline{$i} =~ s/\0[^\0]*//;
9883
9884             # Mark as having no break or action if nothing's left.
9885             delete $dbline{$i} if $dbline{$i} eq '';
9886         }
9887     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
9888 } ## end sub cmd_pre580_a
9889
9890 =head2 Old C<b> command
9891
9892 Add breakpoints.
9893
9894 =cut
9895
9896 sub cmd_pre580_b {
9897     my $xcmd   = shift;
9898     my $cmd    = shift;
9899     my $dbline = shift;
9900
9901     # Break on load.
9902     if ( $cmd =~ /^load\b\s*(.*)/ ) {
9903         my $file = $1;
9904         $file =~ s/\s+$//;
9905         cmd_b_load($file);
9906     }
9907
9908     # b compile|postpone <some sub> [<condition>]
9909     # The interpreter actually traps this one for us; we just put the
9910     # necessary condition in the %postponed hash.
9911     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
9912
9913         # Capture the condition if there is one. Make it true if none.
9914         my $cond = length $3 ? $3 : '1';
9915
9916         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
9917         # if it was 'compile'.
9918         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
9919
9920         # De-Perl4-ify the name - ' separators to ::.
9921         $subname =~ s/\'/::/g;
9922
9923         # Qualify it into the current package unless it's already qualified.
9924         $subname = "${package}::" . $subname
9925           unless $subname =~ /::/;
9926
9927         # Add main if it starts with ::.
9928         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
9929
9930         # Save the break type for this sub.
9931         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
9932     } ## end elsif ($cmd =~ ...
9933
9934     # b <sub name> [<condition>]
9935     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
9936         my $subname = $1;
9937         my $cond = length $2 ? $2 : '1';
9938         cmd_b_sub( $subname, $cond );
9939     }
9940     # b <line> [<condition>].
9941     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9942         my $i = $1 || $dbline;
9943         my $cond = length $2 ? $2 : '1';
9944         cmd_b_line( $i, $cond );
9945     }
9946 } ## end sub cmd_pre580_b
9947
9948 =head2 Old C<D> command.
9949
9950 Delete all breakpoints unconditionally.
9951
9952 =cut
9953
9954 sub cmd_pre580_D {
9955     my $xcmd = shift;
9956     my $cmd  = shift;
9957     if ( $cmd =~ /^\s*$/ ) {
9958         print $OUT "Deleting all breakpoints...\n";
9959
9960         # %had_breakpoints lists every file that had at least one
9961         # breakpoint in it.
9962         my $file;
9963         for $file ( keys %had_breakpoints ) {
9964
9965             # Switch to the desired file temporarily.
9966             local *dbline = $main::{ '_<' . $file };
9967
9968             $max = $#dbline;
9969             my $was;
9970
9971             # For all lines in this file ...
9972             for my $i (1 .. $max) {
9973
9974                 # If there's a breakpoint or action on this line ...
9975                 if ( defined $dbline{$i} ) {
9976
9977                     # ... remove the breakpoint.
9978                     $dbline{$i} =~ s/^[^\0]+//;
9979                     if ( $dbline{$i} =~ s/^\0?$// ) {
9980
9981                         # Remove the entry altogether if no action is there.
9982                         delete $dbline{$i};
9983                     }
9984                 } ## end if (defined $dbline{$i...
9985             } ## end for my $i (1 .. $max)
9986
9987             # If, after we turn off the "there were breakpoints in this file"
9988             # bit, the entry in %had_breakpoints for this file is zero,
9989             # we should remove this file from the hash.
9990             if ( not $had_breakpoints{$file} &= ~1 ) {
9991                 delete $had_breakpoints{$file};
9992             }
9993         } ## end for $file (keys %had_breakpoints)
9994
9995         # Kill off all the other breakpoints that are waiting for files that
9996         # haven't been loaded yet.
9997         undef %postponed;
9998         undef %postponed_file;
9999         undef %break_on_load;
10000     } ## end if ($cmd =~ /^\s*$/)
10001 } ## end sub cmd_pre580_D
10002
10003 =head2 Old C<h> command
10004
10005 Print help. Defaults to printing the long-form help; the 5.8 version
10006 prints the summary by default.
10007
10008 =cut
10009
10010 sub cmd_pre580_h {
10011     my $xcmd = shift;
10012     my $cmd  = shift;
10013
10014     # Print the *right* help, long format.
10015     if ( $cmd =~ /^\s*$/ ) {
10016         print_help($pre580_help);
10017     }
10018
10019     # 'h h' - explicitly-requested summary.
10020     elsif ( $cmd =~ /^h\s*/ ) {
10021         print_help($pre580_summary);
10022     }
10023
10024     # Find and print a command's help.
10025     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
10026         my $asked  = $1;                   # for proper errmsg
10027         my $qasked = quotemeta($asked);    # for searching
10028                                            # XXX: finds CR but not <CR>
10029         if (
10030             $pre580_help =~ /^
10031                               <?           # Optional '<'
10032                               (?:[IB]<)    # Optional markup
10033                               $qasked      # The command name
10034                             /mx
10035           )
10036         {
10037
10038             while (
10039                 $pre580_help =~ /^
10040                                   (             # The command help:
10041                                    <?           # Optional '<'
10042                                    (?:[IB]<)    # Optional markup
10043                                    $qasked      # The command name
10044                                    ([\s\S]*?)   # Lines starting with tabs
10045                                    \n           # Final newline
10046                                   )
10047                                   (?!\s)/mgx
10048               )    # Line not starting with space
10049                    # (Next command's help)
10050             {
10051                 print_help($1);
10052             }
10053         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
10054
10055         # Help not found.
10056         else {
10057             print_help("B<$asked> is not a debugger command.\n");
10058         }
10059     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
10060 } ## end sub cmd_pre580_h
10061
10062 =head2 Old C<W> command
10063
10064 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
10065
10066 =cut
10067
10068 sub cmd_pre580_W {
10069     my $xcmd = shift;
10070     my $cmd  = shift;
10071
10072     # Delete all watch expressions.
10073     if ( $cmd =~ /^$/ ) {
10074
10075         # No watching is going on.
10076         $trace &= ~2;
10077
10078         # Kill all the watch expressions and values.
10079         @to_watch = @old_watch = ();
10080     }
10081
10082     # Add a watch expression.
10083     elsif ( $cmd =~ /^(.*)/s ) {
10084
10085         # add it to the list to be watched.
10086         push @to_watch, $1;
10087
10088         # Get the current value of the expression.
10089         # Doesn't handle expressions returning list values!
10090         $evalarg = $1;
10091         my ($val) = DB::eval();
10092         $val = ( defined $val ) ? "'$val'" : 'undef';
10093
10094         # Save it.
10095         push @old_watch, $val;
10096
10097         # We're watching stuff.
10098         $trace |= 2;
10099
10100     } ## end elsif ($cmd =~ /^(.*)/s)
10101 } ## end sub cmd_pre580_W
10102
10103 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
10104
10105 The debugger used to have a bunch of nearly-identical code to handle
10106 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
10107 C<cmd_prepost> unify all this into one set of code to handle the
10108 appropriate actions.
10109
10110 =head2 C<cmd_pre590_prepost>
10111
10112 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
10113 do something destructive. In pre 5.8 debuggers, the default action was to
10114 delete all the actions.
10115
10116 =cut
10117
10118 sub cmd_pre590_prepost {
10119     my $cmd    = shift;
10120     my $line   = shift || '*';
10121     my $dbline = shift;
10122
10123     return cmd_prepost( $cmd, $line, $dbline );
10124 } ## end sub cmd_pre590_prepost
10125
10126 =head2 C<cmd_prepost>
10127
10128 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
10129 Since the lists of actions are all held in arrays that are pointed to by
10130 references anyway, all we have to do is pick the right array reference and
10131 then use generic code to all, delete, or list actions.
10132
10133 =cut
10134
10135 sub cmd_prepost {
10136     my $cmd = shift;
10137
10138     # No action supplied defaults to 'list'.
10139     my $line = shift || '?';
10140
10141     # Figure out what to put in the prompt.
10142     my $which = '';
10143
10144     # Make sure we have some array or another to address later.
10145     # This means that if ssome reason the tests fail, we won't be
10146     # trying to stash actions or delete them from the wrong place.
10147     my $aref = [];
10148
10149     # < - Perl code to run before prompt.
10150     if ( $cmd =~ /^\</o ) {
10151         $which = 'pre-perl';
10152         $aref  = $pre;
10153     }
10154
10155     # > - Perl code to run after prompt.
10156     elsif ( $cmd =~ /^\>/o ) {
10157         $which = 'post-perl';
10158         $aref  = $post;
10159     }
10160
10161     # { - first check for properly-balanced braces.
10162     elsif ( $cmd =~ /^\{/o ) {
10163         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
10164             print $OUT
10165 "$cmd is now a debugger command\nuse ';$cmd' if you mean Perl code\n";
10166         }
10167
10168         # Properly balanced. Pre-prompt debugger actions.
10169         else {
10170             $which = 'pre-debugger';
10171             $aref  = $pretype;
10172         }
10173     } ## end elsif ( $cmd =~ /^\{/o )
10174
10175     # Did we find something that makes sense?
10176     unless ($which) {
10177         print $OUT "Confused by command: $cmd\n";
10178     }
10179
10180     # Yes.
10181     else {
10182
10183         # List actions.
10184         if ( $line =~ /^\s*\?\s*$/o ) {
10185             unless (@$aref) {
10186
10187                 # Nothing there. Complain.
10188                 print $OUT "No $which actions.\n";
10189             }
10190             else {
10191
10192                 # List the actions in the selected list.
10193                 print $OUT "$which commands:\n";
10194                 foreach my $action (@$aref) {
10195                     print $OUT "\t$cmd -- $action\n";
10196                 }
10197             } ## end else
10198         } ## end if ( $line =~ /^\s*\?\s*$/o)
10199
10200         # Might be a delete.
10201         else {
10202             if ( length($cmd) == 1 ) {
10203                 if ( $line =~ /^\s*\*\s*$/o ) {
10204
10205                     # It's a delete. Get rid of the old actions in the
10206                     # selected list..
10207                     @$aref = ();
10208                     print $OUT "All $cmd actions cleared.\n";
10209                 }
10210                 else {
10211
10212                     # Replace all the actions. (This is a <, >, or {).
10213                     @$aref = action($line);
10214                 }
10215             } ## end if ( length($cmd) == 1)
10216             elsif ( length($cmd) == 2 ) {
10217
10218                 # Add the action to the line. (This is a <<, >>, or {{).
10219                 push @$aref, action($line);
10220             }
10221             else {
10222
10223                 # <<<, >>>>, {{{{{{ ... something not a command.
10224                 print $OUT
10225                   "Confused by strange length of $which command($cmd)...\n";
10226             }
10227         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
10228     } ## end else
10229 } ## end sub cmd_prepost
10230
10231 =head1 C<DB::fake>
10232
10233 Contains the C<at_exit> routine that the debugger uses to issue the
10234 C<Debugged program terminated ...> message after the program completes. See
10235 the C<END> block documentation for more details.
10236
10237 =cut
10238
10239 package DB::fake;
10240
10241 sub at_exit {
10242     "Debugged program terminated.  Use 'q' to quit or 'R' to restart.";
10243 }
10244
10245 package DB;    # Do not trace this 1; below!
10246
10247 1;
10248
10249