regen/opcode.pl

   1 #!/usr/bin/perl -w
   2 #
   3 # Regenerate (overwriting only if changed):
   4 #
   5 #    opcode.h
   6 #    opnames.h
   7 #    pp_proto.h
   8 #
   9 # from information stored in regen/opcodes, plus the
  10 # values hardcoded into this script in @raw_alias.
  11 #
  12 # Accepts the standard regen_lib -q and -v args.
  13 #
  14 # This script is normally invoked from regen.pl.
  15
  16 use strict;
  17
  18 BEGIN {
  19     # Get function prototypes
  20     require 'regen/regen_lib.pl';
  21 }
  22
  23 my $oc = open_new('opcode.h', '>',
  24                   {by => 'regen/opcode.pl', from => 'its data',
  25                    file => 'opcode.h', style => '*',
  26                    copyright => [1993 .. 2007]});
  27
  28 my $on = open_new('opnames.h', '>',
  29                   { by => 'regen/opcode.pl', from => 'its data', style => '*',
  30                     file => 'opnames.h', copyright => [1999 .. 2008] });
  31
  32 # Read data.
  33
  34 my %seen;
  35 my (@ops, %desc, %check, %ckname, %flags, %args, %opnum);
  36
  37 open OPS, 'regen/opcodes' or die $!;
  38
  39 while (<OPS>) {
  40     chop;
  41     next unless $_;
  42     next if /^#/;
  43     my ($key, $desc, $check, $flags, $args) = split(/\t+/, $_, 5);
  44     $args = '' unless defined $args;
  45
  46     warn qq[Description "$desc" duplicates $seen{$desc}\n]
  47      if $seen{$desc} and $key ne "transr";
  48     die qq[Opcode "$key" duplicates $seen{$key}\n] if $seen{$key};
  49     $seen{$desc} = qq[description of opcode "$key"];
  50     $seen{$key} = qq[opcode "$key"];
  51
  52     push(@ops, $key);
  53     $opnum{$key} = $#ops;
  54     $desc{$key} = $desc;
  55     $check{$key} = $check;
  56     $ckname{$check}++;
  57     $flags{$key} = $flags;
  58     $args{$key} = $args;
  59 }
  60
  61 # Set up aliases
  62
  63 my %alias;
  64
  65 # Format is "this function" => "does these op names"
  66 my @raw_alias = (
  67                  Perl_do_kv => [qw( keys values )],
  68                  Perl_unimplemented_op => [qw(padany mapstart custom)],
  69                  # All the ops with a body of { return NORMAL; }
  70                  Perl_pp_null => [qw(scalar regcmaybe lineseq scope)],
  71
  72                  Perl_pp_goto => ['dump'],
  73                  Perl_pp_require => ['dofile'],
  74                  Perl_pp_untie => ['dbmclose'],
  75                  Perl_pp_sysread => {read => '', recv => '#ifdef HAS_SOCKET'},
  76                  Perl_pp_sysseek => ['seek'],
  77                  Perl_pp_ioctl => ['fcntl'],
  78                  Perl_pp_ssockopt => {gsockopt => '#ifdef HAS_SOCKET'},
  79                  Perl_pp_getpeername => {getsockname => '#ifdef HAS_SOCKET'},
  80                  Perl_pp_stat => ['lstat'],
  81                  Perl_pp_ftrowned => [qw(fteowned ftzero ftsock ftchr ftblk
  82                                          ftfile ftdir ftpipe ftsuid ftsgid
  83                                          ftsvtx)],
  84                  Perl_pp_fttext => ['ftbinary'],
  85                  Perl_pp_gmtime => ['localtime'],
  86                  Perl_pp_semget => [qw(shmget msgget)],
  87                  Perl_pp_semctl => [qw(shmctl msgctl)],
  88                  Perl_pp_ghostent => [qw(ghbyname ghbyaddr)],
  89                  Perl_pp_gnetent => [qw(gnbyname gnbyaddr)],
  90                  Perl_pp_gprotoent => [qw(gpbyname gpbynumber)],
  91                  Perl_pp_gservent => [qw(gsbyname gsbyport)],
  92                  Perl_pp_gpwent => [qw(gpwnam gpwuid)],
  93                  Perl_pp_ggrent => [qw(ggrnam ggrgid)],
  94                  Perl_pp_ftis => [qw(ftsize ftmtime ftatime ftctime)],
  95                  Perl_pp_chown => [qw(unlink chmod utime kill)],
  96                  Perl_pp_link => ['symlink'],
  97                  Perl_pp_ftrread => [qw(ftrwrite ftrexec fteread ftewrite
  98                                         fteexec)],
  99                  Perl_pp_shmwrite => [qw(shmread msgsnd msgrcv semop)],
 100                  Perl_pp_syswrite => {send => '#ifdef HAS_SOCKET'},
 101                  Perl_pp_defined => [qw(dor dorassign)],
 102                  Perl_pp_and => ['andassign'],
 103                  Perl_pp_or => ['orassign'],
 104                  Perl_pp_ucfirst => ['lcfirst'],
 105                  Perl_pp_sle => [qw(slt sgt sge)],
 106                  Perl_pp_print => ['say'],
 107                  Perl_pp_index => ['rindex'],
 108                  Perl_pp_oct => ['hex'],
 109                  Perl_pp_shift => ['pop'],
 110                  Perl_pp_sin => [qw(cos exp log sqrt)],
 111                  Perl_pp_bit_or => ['bit_xor'],
 112                  Perl_pp_rv2av => ['rv2hv'],
 113                  Perl_pp_akeys => ['avalues'],
 114                  Perl_pp_rkeys => [qw(rvalues reach)],
 115                  Perl_pp_trans => [qw(trans transr)],
 116                  Perl_pp_chop => [qw(chop chomp)],
 117                  Perl_pp_schop => [qw(schop schomp)],
 118                  Perl_pp_bind => {connect => '#ifdef HAS_SOCKET'},
 119                  Perl_pp_preinc => ['i_preinc', 'predec', 'i_predec'],
 120                  Perl_pp_postinc => ['i_postinc', 'postdec', 'i_postdec'],
 121                  Perl_pp_ehostent => [qw(enetent eprotoent eservent
 122                                          spwent epwent sgrent egrent)],
 123                  Perl_pp_shostent => [qw(snetent sprotoent sservent)],
 124                  Perl_pp_aelemfast => ['aelemfast_lex'],
 125                 );
 126
 127 while (my ($func, $names) = splice @raw_alias, 0, 2) {
 128     if (ref $names eq 'ARRAY') {
 129         foreach (@$names) {
 130             $alias{$_} = [$func, ''];
 131         }
 132     } else {
 133         while (my ($opname, $cond) = each %$names) {
 134             $alias{$opname} = [$func, $cond];
 135         }
 136     }
 137 }
 138
 139 foreach my $sock_func (qw(socket bind listen accept shutdown
 140                           ssockopt getpeername)) {
 141     $alias{$sock_func} = ["Perl_pp_$sock_func", '#ifdef HAS_SOCKET'],
 142 }
 143
 144 # Emit defines.
 145
 146 print $oc    "#ifndef PERL_GLOBAL_STRUCT_INIT\n\n";
 147
 148 {
 149     my $last_cond = '';
 150     my @unimplemented;
 151
 152     sub unimplemented {
 153         if (@unimplemented) {
 154             print $oc "#else\n";
 155             foreach (@unimplemented) {
 156                 print $oc "#define $_ Perl_unimplemented_op\n";
 157             }
 158             print $oc "#endif\n";
 159             @unimplemented = ();
 160         }
 161
 162     }
 163
 164     for (@ops) {
 165         my ($impl, $cond) = @{$alias{$_} || ["Perl_pp_$_", '']};
 166         my $op_func = "Perl_pp_$_";
 167
 168         if ($cond ne $last_cond) {
 169             # A change in condition. (including to or from no condition)
 170             unimplemented();
 171             $last_cond = $cond;
 172             if ($last_cond) {
 173                 print $oc "$last_cond\n";
 174             }
 175         }
 176         push @unimplemented, $op_func if $last_cond;
 177         print $oc "#define $op_func $impl\n" if $impl ne $op_func;
 178     }
 179     # If the last op was conditional, we need to close it out:
 180     unimplemented();
 181 }
 182
 183 print $on "typedef enum opcode {\n";
 184
 185 my $i = 0;
 186 for (@ops) {
 187       print $on "\t", tab(3,"OP_\U$_"), " = ", $i++, ",\n";
 188 }
 189 print $on "\t", tab(3,"OP_max"), "\n";
 190 print $on "} opcode;\n";
 191 print $on "\n#define MAXO ", scalar @ops, "\n";
 192
 193 # Emit op names and descriptions.
 194
 195 print $oc <<'END';
 196 START_EXTERN_C
 197
 198 #ifndef DOINIT
 199 EXTCONST char* const PL_op_name[];
 200 #else
 201 EXTCONST char* const PL_op_name[] = {
 202 END
 203
 204 for (@ops) {
 205     print $oc qq(\t"$_",\n);
 206 }
 207
 208 print $oc <<'END';
 209 };
 210 #endif
 211
 212 #ifndef DOINIT
 213 EXTCONST char* const PL_op_desc[];
 214 #else
 215 EXTCONST char* const PL_op_desc[] = {
 216 END
 217
 218 for (@ops) {
 219     my($safe_desc) = $desc{$_};
 220
 221     # Have to escape double quotes and escape characters.
 222     $safe_desc =~ s/([\\"])/\\$1/g;
 223
 224     print $oc qq(\t"$safe_desc",\n);
 225 }
 226
 227 print $oc <<'END';
 228 };
 229 #endif
 230
 231 END_EXTERN_C
 232
 233 #endif /* !PERL_GLOBAL_STRUCT_INIT */
 234 END
 235
 236 # Emit ppcode switch array.
 237
 238 print $oc <<'END';
 239
 240 START_EXTERN_C
 241
 242 #ifdef PERL_GLOBAL_STRUCT_INIT
 243 #  define PERL_PPADDR_INITED
 244 static const Perl_ppaddr_t Gppaddr[]
 245 #else
 246 #  ifndef PERL_GLOBAL_STRUCT
 247 #    define PERL_PPADDR_INITED
 248 EXT Perl_ppaddr_t PL_ppaddr[] /* or perlvars.h */
 249 #  endif
 250 #endif /* PERL_GLOBAL_STRUCT */
 251 #if (defined(DOINIT) && !defined(PERL_GLOBAL_STRUCT)) || defined(PERL_GLOBAL_STRUCT_INIT)
 252 #  define PERL_PPADDR_INITED
 253 = {
 254 END
 255
 256 for (@ops) {
 257     my $op_func = "Perl_pp_$_";
 258     my $name = $alias{$_};
 259     if ($name && $name->[0] ne $op_func) {
 260         print $oc "\t$op_func,\t/* implemented by $name->[0] */\n";
 261     }
 262     else {
 263         print $oc "\t$op_func,\n";
 264     }
 265 }
 266
 267 print $oc <<'END';
 268 }
 269 #endif
 270 #ifdef PERL_PPADDR_INITED
 271 ;
 272 #endif
 273
 274 #ifdef PERL_GLOBAL_STRUCT_INIT
 275 #  define PERL_CHECK_INITED
 276 static const Perl_check_t Gcheck[]
 277 #else
 278 #  ifndef PERL_GLOBAL_STRUCT
 279 #    define PERL_CHECK_INITED
 280 EXT Perl_check_t PL_check[] /* or perlvars.h */
 281 #  endif
 282 #endif
 283 #if (defined(DOINIT) && !defined(PERL_GLOBAL_STRUCT)) || defined(PERL_GLOBAL_STRUCT_INIT)
 284 #  define PERL_CHECK_INITED
 285 = {
 286 END
 287
 288 for (@ops) {
 289     print $oc "\t", tab(3, "Perl_$check{$_},"), "\t/* $_ */\n";
 290 }
 291
 292 print $oc <<'END';
 293 }
 294 #endif
 295 #ifdef PERL_CHECK_INITED
 296 ;
 297 #endif /* #ifdef PERL_CHECK_INITED */
 298
 299 #ifndef PERL_GLOBAL_STRUCT_INIT
 300
 301 #ifndef DOINIT
 302 EXTCONST U32 PL_opargs[];
 303 #else
 304 EXTCONST U32 PL_opargs[] = {
 305 END
 306
 307 # Emit allowed argument types.
 308
 309 my $ARGBITS = 32;
 310
 311 my %argnum = (
 312     'S',  1,            # scalar
 313     'L',  2,            # list
 314     'A',  3,            # array value
 315     'H',  4,            # hash value
 316     'C',  5,            # code value
 317     'F',  6,            # file value
 318     'R',  7,            # scalar reference
 319 );
 320
 321 my %opclass = (
 322     '0',  0,            # baseop
 323     '1',  1,            # unop
 324     '2',  2,            # binop
 325     '|',  3,            # logop
 326     '@',  4,            # listop
 327     '/',  5,            # pmop
 328     '$',  6,            # svop_or_padop
 329     '#',  7,            # padop
 330     '"',  8,            # pvop_or_svop
 331     '{',  9,            # loop
 332     ';',  10,           # cop
 333     '%',  11,           # baseop_or_unop
 334     '-',  12,           # filestatop
 335     '}',  13,           # loopexop
 336 );
 337
 338 my %opflags = (
 339     'm' =>   1,         # needs stack mark
 340     'f' =>   2,         # fold constants
 341     's' =>   4,         # always produces scalar
 342     't' =>   8,         # needs target scalar
 343     'T' =>   8 | 16,    # ... which may be lexical
 344     'i' =>   0,         # always produces integer (unused since e7311069)
 345     'I' =>  32,         # has corresponding int op
 346     'd' =>  64,         # danger, unknown side effects
 347     'u' => 128,         # defaults to $_
 348 );
 349
 350 my %OP_IS_SOCKET;       # /Fs/
 351 my %OP_IS_FILETEST;     # /F-/
 352 my %OP_IS_FT_ACCESS;    # /F-+/
 353 my %OP_IS_NUMCOMPARE;   # /S</
 354 my %OP_IS_DIRHOP;       # /Fd/
 355
 356 my $OCSHIFT = 8;
 357 my $OASHIFT = 12;
 358
 359 for my $op (@ops) {
 360     my $argsum = 0;
 361     my $flags = $flags{$op};
 362     for my $flag (keys %opflags) {
 363         if ($flags =~ s/$flag//) {
 364             die "Flag collision for '$op' ($flags{$op}, $flag)\n"
 365                 if $argsum & $opflags{$flag};
 366             $argsum |= $opflags{$flag};
 367         }
 368     }
 369     die qq[Opcode '$op' has no class indicator ($flags{$op} => $flags)\n]
 370         unless exists $opclass{$flags};
 371     $argsum |= $opclass{$flags} << $OCSHIFT;
 372     my $argshift = $OASHIFT;
 373     for my $arg (split(' ',$args{$op})) {
 374         if ($arg =~ s/^D//) {
 375             # handle 1st, just to put D 1st.
 376             $OP_IS_DIRHOP{$op}   = $opnum{$op};
 377         }
 378         if ($arg =~ /^F/) {
 379             # record opnums of these opnames
 380             $OP_IS_SOCKET{$op}   = $opnum{$op} if $arg =~ s/s//;
 381             $OP_IS_FILETEST{$op} = $opnum{$op} if $arg =~ s/-//;
 382             $OP_IS_FT_ACCESS{$op} = $opnum{$op} if $arg =~ s/\+//;
 383         }
 384         elsif ($arg =~ /^S</) {
 385             $OP_IS_NUMCOMPARE{$op} = $opnum{$op} if $arg =~ s/<//;
 386         }
 387         my $argnum = ($arg =~ s/\?//) ? 8 : 0;
 388         die "op = $op, arg = $arg\n"
 389             unless exists $argnum{$arg};
 390         $argnum += $argnum{$arg};
 391         die "Argument overflow for '$op'\n"
 392             if $argshift >= $ARGBITS ||
 393                $argnum > ((1 << ($ARGBITS - $argshift)) - 1);
 394         $argsum += $argnum << $argshift;
 395         $argshift += 4;
 396     }
 397     $argsum = sprintf("0x%08x", $argsum);
 398     print $oc "\t", tab(3, "$argsum,"), "/* $op */\n";
 399 }
 400
 401 print $oc <<'END';
 402 };
 403 #endif
 404
 405 #endif /* !PERL_GLOBAL_STRUCT_INIT */
 406
 407 END_EXTERN_C
 408 END
 409
 410 # Emit OP_IS_* macros
 411
 412 print $on <<'EO_OP_IS_COMMENT';
 413
 414 /* the OP_IS_* macros are optimized to a simple range check because
 415     all the member OPs are contiguous in regen/opcodes table.
 416     opcode.pl verifies the range contiguity, or generates an OR-equals
 417     expression */
 418 EO_OP_IS_COMMENT
 419
 420 gen_op_is_macro( \%OP_IS_SOCKET, 'OP_IS_SOCKET');
 421 gen_op_is_macro( \%OP_IS_FILETEST, 'OP_IS_FILETEST');
 422 gen_op_is_macro( \%OP_IS_FT_ACCESS, 'OP_IS_FILETEST_ACCESS');
 423 gen_op_is_macro( \%OP_IS_NUMCOMPARE, 'OP_IS_NUMCOMPARE');
 424 gen_op_is_macro( \%OP_IS_DIRHOP, 'OP_IS_DIRHOP');
 425
 426 sub gen_op_is_macro {
 427     my ($op_is, $macname) = @_;
 428     if (keys %$op_is) {
 429
 430         # get opnames whose numbers are lowest and highest
 431         my ($first, @rest) = sort {
 432             $op_is->{$a} <=> $op_is->{$b}
 433         } keys %$op_is;
 434
 435         my $last = pop @rest;   # @rest slurped, get its last
 436         die "Invalid range of ops: $first .. $last\n" unless $last;
 437
 438         print $on "\n#define $macname(op)       \\\n\t(";
 439
 440         # verify that op-ct matches 1st..last range (and fencepost)
 441         # (we know there are no dups)
 442         if ( $op_is->{$last} - $op_is->{$first} == scalar @rest + 1) {
 443
 444             # contiguous ops -> optimized version
 445             print $on "(op) >= OP_" . uc($first)
 446                 . " && (op) <= OP_" . uc($last);
 447         }
 448         else {
 449             print $on join(" || \\\n\t ",
 450                            map { "(op) == OP_" . uc() } sort keys %$op_is);
 451         }
 452         print $on ")\n";
 453     }
 454 }
 455
 456 my $pp = open_new('pp_proto.h', '>',
 457                   { by => 'opcode.pl', from => 'its data' });
 458
 459 {
 460     my %funcs;
 461     for (@ops) {
 462         my $name = $alias{$_} ? $alias{$_}[0] : "Perl_pp_$_";
 463         ++$funcs{$name};
 464     }
 465     print $pp "PERL_CALLCONV OP *$_(pTHX);\n" foreach sort keys %funcs;
 466 }
 467 foreach ($oc, $on, $pp) {
 468     read_only_bottom_close_and_rename($_);
 469 }
 470
 471 # Some comments about 'T' opcode classifier:
 472
 473 # Safe to set if the ppcode uses:
 474 #       tryAMAGICbin, tryAMAGICun, SETn, SETi, SETu, PUSHn, PUSHTARG, SETTARG,
 475 #       SETs(TARG), XPUSHn, XPUSHu,
 476
 477 # Unsafe to set if the ppcode uses dTARG or [X]RETPUSH[YES|NO|UNDEF]
 478
 479 # lt and friends do SETs (including ncmp, but not scmp)
 480
 481 # Additional mode of failure: the opcode can modify TARG before it "used"
 482 # all the arguments (or may call an external function which does the same).
 483 # If the target coincides with one of the arguments ==> kaboom.
 484
 485 # pp.c  pos substr each not OK (RETPUSHUNDEF)
 486 #       substr vec also not OK due to LV to target (are they???)
 487 #       ref not OK (RETPUSHNO)
 488 #       trans not OK (dTARG; TARG = sv_newmortal();)
 489 #       ucfirst etc not OK: TMP arg processed inplace
 490 #       quotemeta not OK (unsafe when TARG == arg)
 491 #       each repeat not OK too due to list context
 492 #       pack split - unknown whether they are safe
 493 #       sprintf: is calling do_sprintf(TARG,...) which can act on TARG
 494 #         before other args are processed.
 495
 496 #       Suspicious wrt "additional mode of failure" (and only it):
 497 #       schop, chop, postinc/dec, bit_and etc, negate, complement.
 498
 499 #       Also suspicious: 4-arg substr, sprintf, uc/lc (POK_only), reverse, pack.
 500
 501 #       substr/vec: doing TAINT_off()???
 502
 503 # pp_hot.c
 504 #       readline - unknown whether it is safe
 505 #       match subst not OK (dTARG)
 506 #       grepwhile not OK (not always setting)
 507 #       join not OK (unsafe when TARG == arg)
 508
 509 #       Suspicious wrt "additional mode of failure": concat (dealt with
 510 #       in ck_sassign()), join (same).
 511
 512 # pp_ctl.c
 513 #       mapwhile flip caller not OK (not always setting)
 514
 515 # pp_sys.c
 516 #       backtick glob warn die not OK (not always setting)
 517 #       warn not OK (RETPUSHYES)
 518 #       open fileno getc sysread syswrite ioctl accept shutdown
 519 #        ftsize(etc) readlink telldir fork alarm getlogin not OK (RETPUSHUNDEF)
 520 #       umask select not OK (XPUSHs(&PL_sv_undef);)
 521 #       fileno getc sysread syswrite tell not OK (meth("FILENO" "GETC"))
 522 #       sselect shm* sem* msg* syscall - unknown whether they are safe
 523 #       gmtime not OK (list context)
 524
 525 #       Suspicious wrt "additional mode of failure": warn, die, select.