pod/perlrebackslash.pod

   1 =head1 NAME
   2
   3 perlrebackslash - Perl Regular Expression Backslash Sequences and Escapes
   4
   5 =head1 DESCRIPTION
   6
   7 The top level documentation about Perl regular expressions
   8 is found in L<perlre>.
   9
  10 This document describes all backslash and escape sequences. After
  11 explaining the role of the backslash, it lists all the sequences that have
  12 a special meaning in Perl regular expressions (in alphabetical order),
  13 then describes each of them.
  14
  15 Most sequences are described in detail in different documents; the primary
  16 purpose of this document is to have a quick reference guide describing all
  17 backslash and escape sequences.
  18
  19 =head2 The backslash
  20
  21 In a regular expression, the backslash can perform one of two tasks:
  22 it either takes away the special meaning of the character following it
  23 (for instance, C<\|> matches a vertical bar, it's not an alternation),
  24 or it is the start of a backslash or escape sequence.
  25
  26 The rules determining what it is are quite simple: if the character
  27 following the backslash is an ASCII punctuation (non-word) character (that is,
  28 anything that is not a letter, digit or underscore), then the backslash just
  29 takes away the special meaning (if any) of the character following it.
  30
  31 If the character following the backslash is an ASCII letter or an ASCII digit,
  32 then the sequence may be special; if so, it's listed below. A few letters have
  33 not been used yet, so escaping them with a backslash doesn't change them to be
  34 special.  A future version of Perl may assign a special meaning to them, so if
  35 you have warnings turned on, Perl will issue a warning if you use such a
  36 sequence.  [1].
  37
  38 It is however guaranteed that backslash or escape sequences never have a
  39 punctuation character following the backslash, not now, and not in a future
  40 version of Perl 5. So it is safe to put a backslash in front of a non-word
  41 character.
  42
  43 Note that the backslash itself is special; if you want to match a backslash,
  44 you have to escape the backslash with a backslash: C</\\/> matches a single
  45 backslash.
  46
  47 =over 4
  48
  49 =item [1]
  50
  51 There is one exception. If you use an alphanumerical character as the
  52 delimiter of your pattern (which you probably shouldn't do for readability
  53 reasons), you will have to escape the delimiter if you want to match
  54 it. Perl won't warn then. See also L<perlop/Gory details of parsing
  55 quoted constructs>.
  56
  57 =back
  58
  59
  60 =head2 All the sequences and escapes
  61
  62 Those not usable within a bracketed character class (like C<[\da-z]>) are marked
  63 as C<Not in [].>
  64
  65  \000              Octal escape sequence.
  66  \1                Absolute backreference.  Not in [].
  67  \a                Alarm or bell.
  68  \A                Beginning of string.  Not in [].
  69  \b                Word/non-word boundary. (Backspace in []).
  70  \B                Not a word/non-word boundary.  Not in [].
  71  \cX               Control-X
  72  \C                Single octet, even under UTF-8.  Not in [].
  73  \d                Character class for digits.
  74  \D                Character class for non-digits.
  75  \e                Escape character.
  76  \E                Turn off \Q, \L and \U processing.  Not in [].
  77  \f                Form feed.
  78  \g{}, \g1         Named, absolute or relative backreference.  Not in []
  79  \G                Pos assertion.  Not in [].
  80  \h                Character class for horizontal whitespace.
  81  \H                Character class for non horizontal whitespace.
  82  \k{}, \k<>, \k''  Named backreference.  Not in [].
  83  \K                Keep the stuff left of \K.  Not in [].
  84  \l                Lowercase next character.  Not in [].
  85  \L                Lowercase till \E.  Not in [].
  86  \n                (Logical) newline character.
  87  \N                Any character but newline.  Experimental.  Not in [].
  88  \N{}              Named or numbered (Unicode) character.
  89  \p{}, \pP         Character with the given Unicode property.
  90  \P{}, \PP         Character without the given Unicode property.
  91  \Q                Quotemeta till \E.  Not in [].
  92  \r                Return character.
  93  \R                Generic new line.  Not in [].
  94  \s                Character class for whitespace.
  95  \S                Character class for non whitespace.
  96  \t                Tab character.
  97  \u                Titlecase next character.  Not in [].
  98  \U                Uppercase till \E.  Not in [].
  99  \v                Character class for vertical whitespace.
 100  \V                Character class for non vertical whitespace.
 101  \w                Character class for word characters.
 102  \W                Character class for non-word characters.
 103  \x{}, \x00        Hexadecimal escape sequence.
 104  \X                Unicode "extended grapheme cluster".  Not in [].
 105  \z                End of string.  Not in [].
 106  \Z                End of string.  Not in [].
 107
 108 =head2 Character Escapes
 109
 110 =head3  Fixed characters
 111
 112 A handful of characters have a dedicated I<character escape>. The following
 113 table shows them, along with their ASCII code points (in decimal and hex),
 114 their ASCII name, the control escape on ASCII platforms and a short
 115 description.  (For EBCDIC platforms, see L<perlebcdic/OPERATOR DIFFERENCES>.)
 116
 117  Seq.  Code Point  ASCII   Cntrl   Description.
 118        Dec    Hex
 119   \a     7     07    BEL    \cG    alarm or bell
 120   \b     8     08     BS    \cH    backspace [1]
 121   \e    27     1B    ESC    \c[    escape character
 122   \f    12     0C     FF    \cL    form feed
 123   \n    10     0A     LF    \cJ    line feed [2]
 124   \r    13     0D     CR    \cM    carriage return
 125   \t     9     09    TAB    \cI    tab
 126
 127 =over 4
 128
 129 =item [1]
 130
 131 C<\b> is only the backspace character inside a character class. Outside a
 132 character class, C<\b> is a word/non-word boundary.
 133
 134 =item [2]
 135
 136 C<\n> matches a logical newline. Perl will convert between C<\n> and your
 137 OSses native newline character when reading from or writing to text files.
 138
 139 =back
 140
 141 =head4 Example
 142
 143  $str =~ /\t/;   # Matches if $str contains a (horizontal) tab.
 144
 145 =head3 Control characters
 146
 147 C<\c> is used to denote a control character; the character following C<\c>
 148 determines the value of the construct.  For example the value of C<\cA> is
 149 C<chr(1)>, and the value of C<\cb> is C<chr(2)>, etc.
 150 The gory details are in L<perlop/"Regexp Quote-Like Operators">.  A complete
 151 list of what C<chr(1)>, etc. means for ASCII and EBCDIC platforms is in
 152 L<perlebcdic/OPERATOR DIFFERENCES>.
 153
 154 Note that C<\c\> alone at the end of a regular expression (or doubled-quoted
 155 string) is not valid.  The backslash must be followed by another character.
 156 That is, C<\c\I<X>> means C<chr(28) . 'I<X>'> for all characters I<X>.
 157
 158 To write platform-independent code, you must use C<\N{I<NAME>}> instead, like
 159 C<\N{ESCAPE}> or C<\N{U+001B}>, see L<charnames>.
 160
 161 Mnemonic: I<c>ontrol character.
 162
 163 =head4 Example
 164
 165  $str =~ /\cK/;  # Matches if $str contains a vertical tab (control-K).
 166
 167 =head3 Named or numbered characters
 168
 169 All Unicode characters have a Unicode name and numeric ordinal value.  Use the
 170 C<\N{}> construct to specify a character by either of these values.
 171
 172 To specify by name, the name of the character goes between the curly braces.
 173 In this case, you have to C<use charnames> to load the Unicode names of the
 174 characters, otherwise Perl will complain.
 175
 176 To specify by Unicode ordinal number, use the form
 177 C<\N{U+I<wide hex character>}>, where I<wide hex character> is a number in
 178 hexadecimal that gives the ordinal number that Unicode has assigned to the
 179 desired character.  It is customary (but not required) to use leading zeros to
 180 pad the number to 4 digits.  Thus C<\N{U+0041}> means
 181 C<Latin Capital Letter A>, and you will rarely see it written without the two
 182 leading zeros.  C<\N{U+0041}> means C<A> even on EBCDIC machines (where the
 183 ordinal value of C<A> is not 0x41).
 184
 185 It is even possible to give your own names to characters, and even to short
 186 sequences of characters.  For details, see L<charnames>.
 187
 188 (There is an expanded internal form that you may see in debug output:
 189 C<\N{U+I<wide hex character>.I<wide hex character>...}>.
 190 The C<...> means any number of these I<wide hex character>s separated by dots.
 191 This represents the sequence formed by the characters.  This is an internal
 192 form only, subject to change, and you should not try to use it yourself.)
 193
 194 Mnemonic: I<N>amed character.
 195
 196 Note that a character that is expressed as a named or numbered character is
 197 considered as a character without special meaning by the regex engine, and will
 198 match "as is".
 199
 200 =head4 Example
 201
 202  use charnames ':full';               # Loads the Unicode names.
 203  $str =~ /\N{THAI CHARACTER SO SO}/;  # Matches the Thai SO SO character
 204
 205  use charnames 'Cyrillic';            # Loads Cyrillic names.
 206  $str =~ /\N{ZHE}\N{KA}/;             # Match "ZHE" followed by "KA".
 207
 208 =head3 Octal escapes
 209
 210 Octal escapes consist of a backslash followed by two or three octal digits
 211 matching the code point of the character you want to use. This allows for
 212 512 characters (C<\00> up to C<\777>) that can be expressed this way (but
 213 anything above C<\377> is deprecated).
 214 Enough in pre-Unicode days, but most Unicode characters cannot be escaped
 215 this way.
 216
 217 Note that a character that is expressed as an octal escape is considered
 218 as a character without special meaning by the regex engine, and will match
 219 "as is".
 220
 221 =head4 Examples (assuming an ASCII platform)
 222
 223  $str = "Perl";
 224  $str =~ /\120/;    # Match, "\120" is "P".
 225  $str =~ /\120+/;   # Match, "\120" is "P", it is repeated at least once
 226  $str =~ /P\053/;   # No match, "\053" is "+" and taken literally.
 227
 228 =head4 Caveat
 229
 230 Octal escapes potentially clash with backreferences. They both consist
 231 of a backslash followed by numbers. So Perl has to use heuristics to
 232 determine whether it is a backreference or an octal escape. Perl uses
 233 the following rules:
 234
 235 =over 4
 236
 237 =item 1
 238
 239 If the backslash is followed by a single digit, it's a backreference.
 240
 241 =item 2
 242
 243 If the first digit following the backslash is a 0, it's an octal escape.
 244
 245 =item 3
 246
 247 If the number following the backslash is N (decimal), and Perl already has
 248 seen N capture groups, Perl will consider this to be a backreference.
 249 Otherwise, it will consider it to be an octal escape. Note that if N > 999,
 250 Perl only takes the first three digits for the octal escape; the rest is
 251 matched as is.
 252
 253  my $pat  = "(" x 999;
 254     $pat .= "a";
 255     $pat .= ")" x 999;
 256  /^($pat)\1000$/;   #  Matches 'aa'; there are 1000 capture groups.
 257  /^$pat\1000$/;     #  Matches 'a@0'; there are 999 capture groups
 258                     #    and \1000 is seen as \100 (a '@') and a '0'.
 259
 260 =back
 261
 262 =head3 Hexadecimal escapes
 263
 264 Hexadecimal escapes start with C<\x> and are then either followed by a
 265 two digit hexadecimal number, or a hexadecimal number of arbitrary length
 266 surrounded by curly braces. The hexadecimal number is the code point of
 267 the character you want to express.
 268
 269 Note that a character that is expressed as a hexadecimal escape is considered
 270 as a character without special meaning by the regex engine, and will match
 271 "as is".
 272
 273 Mnemonic: heI<x>adecimal.
 274
 275 =head4 Examples (assuming an ASCII platform)
 276
 277  $str = "Perl";
 278  $str =~ /\x50/;    # Match, "\x50" is "P".
 279  $str =~ /\x50+/;   # Match, "\x50" is "P", it is repeated at least once
 280  $str =~ /P\x2B/;   # No match, "\x2B" is "+" and taken literally.
 281
 282  /\x{2603}\x{2602}/ # Snowman with an umbrella.
 283                     # The Unicode character 2603 is a snowman,
 284                     # the Unicode character 2602 is an umbrella.
 285  /\x{263B}/         # Black smiling face.
 286  /\x{263b}/         # Same, the hex digits A - F are case insensitive.
 287
 288 =head2 Modifiers
 289
 290 A number of backslash sequences have to do with changing the character,
 291 or characters following them. C<\l> will lowercase the character following
 292 it, while C<\u> will uppercase (or, more accurately, titlecase) the
 293 character following it. (They perform similar functionality as the
 294 functions C<lcfirst> and C<ucfirst>).
 295
 296 To uppercase or lowercase several characters, one might want to use
 297 C<\L> or C<\U>, which will lowercase/uppercase all characters following
 298 them, until either the end of the pattern, or the next occurrence of
 299 C<\E>, whatever comes first. They perform similar functionality as the
 300 functions C<lc> and C<uc> do.
 301
 302 C<\Q> is used to escape all characters following, up to the next C<\E>
 303 or the end of the pattern. C<\Q> adds a backslash to any character that
 304 isn't a letter, digit or underscore. This will ensure that any character
 305 between C<\Q> and C<\E> is matched literally, and will not be interpreted
 306 by the regexp engine.
 307
 308 Mnemonic: I<L>owercase, I<U>ppercase, I<Q>uotemeta, I<E>nd.
 309
 310 =head4 Examples
 311
 312  $sid     = "sid";
 313  $greg    = "GrEg";
 314  $miranda = "(Miranda)";
 315  $str     =~ /\u$sid/;        # Matches 'Sid'
 316  $str     =~ /\L$greg/;       # Matches 'greg'
 317  $str     =~ /\Q$miranda\E/;  # Matches '(Miranda)', as if the pattern
 318                               #   had been written as /\(Miranda\)/
 319
 320 =head2 Character classes
 321
 322 Perl regular expressions have a large range of character classes. Some of
 323 the character classes are written as a backslash sequence. We will briefly
 324 discuss those here; full details of character classes can be found in
 325 L<perlrecharclass>.
 326
 327 C<\w> is a character class that matches any single I<word> character (letters,
 328 digits, underscore). C<\d> is a character class that matches any decimal digit,
 329 while the character class C<\s> matches any whitespace character.
 330 New in perl 5.10.0 are the classes C<\h> and C<\v> which match horizontal
 331 and vertical whitespace characters.
 332
 333 The uppercase variants (C<\W>, C<\D>, C<\S>, C<\H>, and C<\V>) are
 334 character classes that match any character that isn't a word character,
 335 digit, whitespace, horizontal whitespace nor vertical whitespace.
 336
 337 Mnemonics: I<w>ord, I<d>igit, I<s>pace, I<h>orizontal, I<v>ertical.
 338
 339 =head3 Unicode classes
 340
 341 C<\pP> (where C<P> is a single letter) and C<\p{Property}> are used to
 342 match a character that matches the given Unicode property; properties
 343 include things like "letter", or "thai character". Capitalizing the
 344 sequence to C<\PP> and C<\P{Property}> make the sequence match a character
 345 that doesn't match the given Unicode property. For more details, see
 346 L<perlrecharclass/Backslash sequences> and
 347 L<perlunicode/Unicode Character Properties>.
 348
 349 Mnemonic: I<p>roperty.
 350
 351
 352 =head2 Referencing
 353
 354 If capturing parenthesis are used in a regular expression, we can refer
 355 to the part of the source string that was matched, and match exactly the
 356 same thing. There are three ways of referring to such I<backreference>:
 357 absolutely, relatively, and by name.
 358
 359 =for later add link to perlrecapture
 360
 361 =head3 Absolute referencing
 362
 363 A backslash sequence that starts with a backslash and is followed by a
 364 number is an absolute reference (but be aware of the caveat mentioned above).
 365 If the number is I<N>, it refers to the Nth set of parentheses - whatever
 366 has been matched by that set of parenthesis has to be matched by the C<\N>
 367 as well.
 368
 369 =head4 Examples
 370
 371  /(\w+) \1/;    # Finds a duplicated word, (e.g. "cat cat").
 372  /(.)(.)\2\1/;  # Match a four letter palindrome (e.g. "ABBA").
 373
 374
 375 =head3 Relative referencing
 376
 377 New in perl 5.10.0 is a different way of referring to capture buffers: C<\g>.
 378 C<\g> takes a number as argument, with the number in curly braces (the
 379 braces are optional). If the number (N) does not have a sign, it's a reference
 380 to the Nth capture group (so C<\g{2}> is equivalent to C<\2> - except that
 381 C<\g> always refers to a capture group and will never be seen as an octal
 382 escape). If the number is negative, the reference is relative, referring to
 383 the Nth group before the C<\g{-N}>.
 384
 385 The big advantage of C<\g{-N}> is that it makes it much easier to write
 386 patterns with references that can be interpolated in larger patterns,
 387 even if the larger pattern also contains capture groups.
 388
 389 Mnemonic: I<g>roup.
 390
 391 =head4 Examples
 392
 393  /(A)        # Buffer 1
 394   (          # Buffer 2
 395     (B)      # Buffer 3
 396     \g{-1}   # Refers to buffer 3 (B)
 397     \g{-3}   # Refers to buffer 1 (A)
 398   )
 399  /x;         # Matches "ABBA".
 400
 401  my $qr = qr /(.)(.)\g{-2}\g{-1}/;  # Matches 'abab', 'cdcd', etc.
 402  /$qr$qr/                           # Matches 'ababcdcd'.
 403
 404 =head3 Named referencing
 405
 406 Also new in perl 5.10.0 is the use of named capture buffers, which can be
 407 referred to by name. This is done with C<\g{name}>, which is a
 408 backreference to the capture buffer with the name I<name>.
 409
 410 To be compatible with .Net regular expressions, C<\g{name}> may also be
 411 written as C<\k{name}>, C<< \k<name> >> or C<\k'name'>.
 412
 413 Note that C<\g{}> has the potential to be ambiguous, as it could be a named
 414 reference, or an absolute or relative reference (if its argument is numeric).
 415 However, names are not allowed to start with digits, nor are they allowed to
 416 contain a hyphen, so there is no ambiguity.
 417
 418 =head4 Examples
 419
 420  /(?<word>\w+) \g{word}/ # Finds duplicated word, (e.g. "cat cat")
 421  /(?<word>\w+) \k{word}/ # Same.
 422  /(?<word>\w+) \k<word>/ # Same.
 423  /(?<letter1>.)(?<letter2>.)\g{letter2}\g{letter1}/
 424                          # Match a four letter palindrome (e.g. "ABBA")
 425
 426 =head2 Assertions
 427
 428 Assertions are conditions that have to be true; they don't actually
 429 match parts of the substring. There are six assertions that are written as
 430 backslash sequences.
 431
 432 =over 4
 433
 434 =item \A
 435
 436 C<\A> only matches at the beginning of the string. If the C</m> modifier
 437 isn't used, then C</\A/> is equivalent with C</^/>. However, if the C</m>
 438 modifier is used, then C</^/> matches internal newlines, but the meaning
 439 of C</\A/> isn't changed by the C</m> modifier. C<\A> matches at the beginning
 440 of the string regardless whether the C</m> modifier is used.
 441
 442 =item \z, \Z
 443
 444 C<\z> and C<\Z> match at the end of the string. If the C</m> modifier isn't
 445 used, then C</\Z/> is equivalent with C</$/>, that is, it matches at the
 446 end of the string, or before the newline at the end of the string. If the
 447 C</m> modifier is used, then C</$/> matches at internal newlines, but the
 448 meaning of C</\Z/> isn't changed by the C</m> modifier. C<\Z> matches at
 449 the end of the string (or just before a trailing newline) regardless whether
 450 the C</m> modifier is used.
 451
 452 C<\z> is just like C<\Z>, except that it will not match before a trailing
 453 newline. C<\z> will only match at the end of the string - regardless of the
 454 modifiers used, and not before a newline.
 455
 456 =item \G
 457
 458 C<\G> is usually only used in combination with the C</g> modifier. If the
 459 C</g> modifier is used (and the match is done in scalar context), Perl will
 460 remember where in the source string the last match ended, and the next time,
 461 it will start the match from where it ended the previous time.
 462
 463 C<\G> matches the point where the previous match ended, or the beginning
 464 of the string if there was no previous match.
 465
 466 =for later add link to perlremodifiers
 467
 468 Mnemonic: I<G>lobal.
 469
 470 =item \b, \B
 471
 472 C<\b> matches at any place between a word and a non-word character; C<\B>
 473 matches at any place between characters where C<\b> doesn't match. C<\b>
 474 and C<\B> assume there's a non-word character before the beginning and after
 475 the end of the source string; so C<\b> will match at the beginning (or end)
 476 of the source string if the source string begins (or ends) with a word
 477 character. Otherwise, C<\B> will match.
 478
 479 Mnemonic: I<b>oundary.
 480
 481 =back
 482
 483 =head4 Examples
 484
 485   "cat"   =~ /\Acat/;     # Match.
 486   "cat"   =~ /cat\Z/;     # Match.
 487   "cat\n" =~ /cat\Z/;     # Match.
 488   "cat\n" =~ /cat\z/;     # No match.
 489
 490   "cat"   =~ /\bcat\b/;   # Matches.
 491   "cats"  =~ /\bcat\b/;   # No match.
 492   "cat"   =~ /\bcat\B/;   # No match.
 493   "cats"  =~ /\bcat\B/;   # Match.
 494
 495   while ("cat dog" =~ /(\w+)/g) {
 496       print $1;           # Prints 'catdog'
 497   }
 498   while ("cat dog" =~ /\G(\w+)/g) {
 499       print $1;           # Prints 'cat'
 500   }
 501
 502 =head2 Misc
 503
 504 Here we document the backslash sequences that don't fall in one of the
 505 categories above. They are:
 506
 507 =over 4
 508
 509 =item \C
 510
 511 C<\C> always matches a single octet, even if the source string is encoded
 512 in UTF-8 format, and the character to be matched is a multi-octet character.
 513 C<\C> was introduced in perl 5.6.
 514
 515 Mnemonic: oI<C>tet.
 516
 517 =item \K
 518
 519 This is new in perl 5.10.0. Anything that is matched left of C<\K> is
 520 not included in C<$&> - and will not be replaced if the pattern is
 521 used in a substitution. This will allow you to write C<s/PAT1 \K PAT2/REPL/x>
 522 instead of C<s/(PAT1) PAT2/${1}REPL/x> or C<s/(?<=PAT1) PAT2/REPL/x>.
 523
 524 Mnemonic: I<K>eep.
 525
 526 =item \N
 527
 528 This is a new experimental feature in perl 5.12.0.  It matches any character
 529 that is not a newline.  It is a short-hand for writing C<[^\n]>, and is
 530 identical to the C<.> metasymbol, except under the C</s> flag, which changes
 531 the meaning of C<.>, but not C<\N>.
 532
 533 Note that C<\N{...}> can mean a
 534 L<named or numbered character|/Named or numbered characters>.
 535
 536 Mnemonic: Complement of I<\n>.
 537
 538 =item \R
 539 X<\R>
 540
 541 C<\R> matches a I<generic newline>, that is, anything that is considered
 542 a newline by Unicode. This includes all characters matched by C<\v>
 543 (vertical whitespace), and the multi character sequence C<"\x0D\x0A">
 544 (carriage return followed by a line feed, aka the network newline, or
 545 the newline used in Windows text files). C<\R> is equivalent to
 546 C<< (?>\x0D\x0A)|\v) >>. Since C<\R> can match a sequence of more than one
 547 character, it cannot be put inside a bracketed character class; C</[\R]/> is an
 548 error; use C<\v> instead.  C<\R> was introduced in perl 5.10.0.
 549
 550 Mnemonic: none really. C<\R> was picked because PCRE already uses C<\R>,
 551 and more importantly because Unicode recommends such a regular expression
 552 metacharacter, and suggests C<\R> as the notation.
 553
 554 =item \X
 555 X<\X>
 556
 557 This matches a Unicode I<extended grapheme cluster>.
 558
 559 C<\X> matches quite well what normal (non-Unicode-programmer) usage
 560 would consider a single character.  As an example, consider a G with some sort
 561 of diacritic mark, such as an arrow.  There is no such single character in
 562 Unicode, but one can be composed by using a G followed by a Unicode "COMBINING
 563 UPWARDS ARROW BELOW", and would be displayed by Unicode-aware software as if it
 564 were a single character.
 565
 566 Mnemonic: eI<X>tended Unicode character.
 567
 568 =back
 569
 570 =head4 Examples
 571
 572  "\x{256}" =~ /^\C\C$/;    # Match as chr (256) takes 2 octets in UTF-8.
 573
 574  $str =~ s/foo\Kbar/baz/g; # Change any 'bar' following a 'foo' to 'baz'
 575  $str =~ s/(.)\K\1//g;     # Delete duplicated characters.
 576
 577  "\n"   =~ /^\R$/;         # Match, \n   is a generic newline.
 578  "\r"   =~ /^\R$/;         # Match, \r   is a generic newline.
 579  "\r\n" =~ /^\R$/;         # Match, \r\n is a generic newline.
 580
 581  "P\x{0307}" =~ /^\X$/     # \X matches a P with a dot above.
 582
 583 =cut