pod/perlrebackslash.pod

   1 =head1 NAME
   2
   3 perlrebackslash - Perl Regular Expression Backslash Sequences and Escapes
   4
   5 =head1 DESCRIPTION
   6
   7 The top level documentation about Perl regular expressions
   8 is found in L<perlre>.
   9
  10 This document describes all backslash and escape sequences. After
  11 explaining the role of the backslash, it lists all the sequences that have
  12 a special meaning in Perl regular expressions (in alphabetical order),
  13 then describes each of them.
  14
  15 Most sequences are described in detail in different documents; the primary
  16 purpose of this document is to have a quick reference guide describing all
  17 backslash and escape sequences.
  18
  19 =head2 The backslash
  20
  21 In a regular expression, the backslash can perform one of two tasks:
  22 it either takes away the special meaning of the character following it
  23 (for instance, C<\|> matches a vertical bar, it's not an alternation),
  24 or it is the start of a backslash or escape sequence.
  25
  26 The rules determining what it is are quite simple: if the character
  27 following the backslash is an ASCII punctuation (non-word) character (that is,
  28 anything that is not a letter, digit, or underscore), then the backslash just
  29 takes away any special meaning of the character following it.
  30
  31 If the character following the backslash is an ASCII letter or an ASCII digit,
  32 then the sequence may be special; if so, it's listed below. A few letters have
  33 not been used yet, so escaping them with a backslash doesn't change them to be
  34 special.  A future version of Perl may assign a special meaning to them, so if
  35 you have warnings turned on, Perl issues a warning if you use such a
  36 sequence.  [1].
  37
  38 It is however guaranteed that backslash or escape sequences never have a
  39 punctuation character following the backslash, not now, and not in a future
  40 version of Perl 5. So it is safe to put a backslash in front of a non-word
  41 character.
  42
  43 Note that the backslash itself is special; if you want to match a backslash,
  44 you have to escape the backslash with a backslash: C</\\/> matches a single
  45 backslash.
  46
  47 =over 4
  48
  49 =item [1]
  50
  51 There is one exception. If you use an alphanumeric character as the
  52 delimiter of your pattern (which you probably shouldn't do for readability
  53 reasons), you have to escape the delimiter if you want to match
  54 it. Perl won't warn then. See also L<perlop/Gory details of parsing
  55 quoted constructs>.
  56
  57 =back
  58
  59
  60 =head2 All the sequences and escapes
  61
  62 Those not usable within a bracketed character class (like C<[\da-z]>) are marked
  63 as C<Not in [].>
  64
  65  \000              Octal escape sequence.  See also \o{}.
  66  \1                Absolute backreference.  Not in [].
  67  \a                Alarm or bell.
  68  \A                Beginning of string.  Not in [].
  69  \b                Word/non-word boundary. (Backspace in []).
  70  \B                Not a word/non-word boundary.  Not in [].
  71  \cX               Control-X.
  72  \C                Single octet, even under UTF-8.  Not in [].
  73                    (Deprecated)
  74  \d                Character class for digits.
  75  \D                Character class for non-digits.
  76  \e                Escape character.
  77  \E                Turn off \Q, \L and \U processing.  Not in [].
  78  \f                Form feed.
  79  \F                Foldcase till \E.  Not in [].
  80  \g{}, \g1         Named, absolute or relative backreference.
  81                    Not in [].
  82  \G                Pos assertion.  Not in [].
  83  \h                Character class for horizontal whitespace.
  84  \H                Character class for non horizontal whitespace.
  85  \k{}, \k<>, \k''  Named backreference.  Not in [].
  86  \K                Keep the stuff left of \K.  Not in [].
  87  \l                Lowercase next character.  Not in [].
  88  \L                Lowercase till \E.  Not in [].
  89  \n                (Logical) newline character.
  90  \N                Any character but newline.  Not in [].
  91  \N{}              Named or numbered (Unicode) character or sequence.
  92  \o{}              Octal escape sequence.
  93  \p{}, \pP         Character with the given Unicode property.
  94  \P{}, \PP         Character without the given Unicode property.
  95  \Q                Quote (disable) pattern metacharacters till \E.  Not
  96                    in [].
  97  \r                Return character.
  98  \R                Generic new line.  Not in [].
  99  \s                Character class for whitespace.
 100  \S                Character class for non whitespace.
 101  \t                Tab character.
 102  \u                Titlecase next character.  Not in [].
 103  \U                Uppercase till \E.  Not in [].
 104  \v                Character class for vertical whitespace.
 105  \V                Character class for non vertical whitespace.
 106  \w                Character class for word characters.
 107  \W                Character class for non-word characters.
 108  \x{}, \x00        Hexadecimal escape sequence.
 109  \X                Unicode "extended grapheme cluster".  Not in [].
 110  \z                End of string.  Not in [].
 111  \Z                End of string.  Not in [].
 112
 113 =head2 Character Escapes
 114
 115 =head3  Fixed characters
 116
 117 A handful of characters have a dedicated I<character escape>. The following
 118 table shows them, along with their ASCII code points (in decimal and hex),
 119 their ASCII name, the control escape on ASCII platforms and a short
 120 description.  (For EBCDIC platforms, see L<perlebcdic/OPERATOR DIFFERENCES>.)
 121
 122  Seq.  Code Point  ASCII   Cntrl   Description.
 123        Dec    Hex
 124   \a     7     07    BEL    \cG    alarm or bell
 125   \b     8     08     BS    \cH    backspace [1]
 126   \e    27     1B    ESC    \c[    escape character
 127   \f    12     0C     FF    \cL    form feed
 128   \n    10     0A     LF    \cJ    line feed [2]
 129   \r    13     0D     CR    \cM    carriage return
 130   \t     9     09    TAB    \cI    tab
 131
 132 =over 4
 133
 134 =item [1]
 135
 136 C<\b> is the backspace character only inside a character class. Outside a
 137 character class, C<\b> is a word/non-word boundary.
 138
 139 =item [2]
 140
 141 C<\n> matches a logical newline. Perl converts between C<\n> and your
 142 OS's native newline character when reading from or writing to text files.
 143
 144 =back
 145
 146 =head4 Example
 147
 148  $str =~ /\t/;   # Matches if $str contains a (horizontal) tab.
 149
 150 =head3 Control characters
 151
 152 C<\c> is used to denote a control character; the character following C<\c>
 153 determines the value of the construct.  For example the value of C<\cA> is
 154 C<chr(1)>, and the value of C<\cb> is C<chr(2)>, etc.
 155 The gory details are in L<perlop/"Regexp Quote-Like Operators">.  A complete
 156 list of what C<chr(1)>, etc. means for ASCII and EBCDIC platforms is in
 157 L<perlebcdic/OPERATOR DIFFERENCES>.
 158
 159 Note that C<\c\> alone at the end of a regular expression (or doubled-quoted
 160 string) is not valid.  The backslash must be followed by another character.
 161 That is, C<\c\I<X>> means C<chr(28) . 'I<X>'> for all characters I<X>.
 162
 163 To write platform-independent code, you must use C<\N{I<NAME>}> instead, like
 164 C<\N{ESCAPE}> or C<\N{U+001B}>, see L<charnames>.
 165
 166 Mnemonic: I<c>ontrol character.
 167
 168 =head4 Example
 169
 170  $str =~ /\cK/;  # Matches if $str contains a vertical tab (control-K).
 171
 172 =head3 Named or numbered characters and character sequences
 173
 174 Unicode characters have a Unicode name and numeric code point (ordinal)
 175 value.  Use the
 176 C<\N{}> construct to specify a character by either of these values.
 177 Certain sequences of characters also have names.
 178
 179 To specify by name, the name of the character or character sequence goes
 180 between the curly braces.
 181
 182 To specify a character by Unicode code point, use the form C<\N{U+I<code
 183 point>}>, where I<code point> is a number in hexadecimal that gives the
 184 code point that Unicode has assigned to the desired character.  It is
 185 customary but not required to use leading zeros to pad the number to 4
 186 digits.  Thus C<\N{U+0041}> means C<LATIN CAPITAL LETTER A>, and you will
 187 rarely see it written without the two leading zeros.  C<\N{U+0041}> means
 188 "A" even on EBCDIC machines (where the ordinal value of "A" is not 0x41).
 189
 190 It is even possible to give your own names to characters and character
 191 sequences.  For details, see L<charnames>.
 192
 193 (There is an expanded internal form that you may see in debug output:
 194 C<\N{U+I<code point>.I<code point>...}>.
 195 The C<...> means any number of these I<code point>s separated by dots.
 196 This represents the sequence formed by the characters.  This is an internal
 197 form only, subject to change, and you should not try to use it yourself.)
 198
 199 Mnemonic: I<N>amed character.
 200
 201 Note that a character or character sequence expressed as a named
 202 or numbered character is considered a character without special
 203 meaning by the regex engine, and will match "as is".
 204
 205 =head4 Example
 206
 207  $str =~ /\N{THAI CHARACTER SO SO}/;  # Matches the Thai SO SO character
 208
 209  use charnames 'Cyrillic';            # Loads Cyrillic names.
 210  $str =~ /\N{ZHE}\N{KA}/;             # Match "ZHE" followed by "KA".
 211
 212 =head3 Octal escapes
 213
 214 There are two forms of octal escapes.  Each is used to specify a character by
 215 its code point specified in octal notation.
 216
 217 One form, available starting in Perl 5.14 looks like C<\o{...}>, where the dots
 218 represent one or more octal digits.  It can be used for any Unicode character.
 219
 220 It was introduced to avoid the potential problems with the other form,
 221 available in all Perls.  That form consists of a backslash followed by three
 222 octal digits.  One problem with this form is that it can look exactly like an
 223 old-style backreference (see
 224 L</Disambiguation rules between old-style octal escapes and backreferences>
 225 below.)  You can avoid this by making the first of the three digits always a
 226 zero, but that makes \077 the largest code point specifiable.
 227
 228 In some contexts, a backslash followed by two or even one octal digits may be
 229 interpreted as an octal escape, sometimes with a warning, and because of some
 230 bugs, sometimes with surprising results.  Also, if you are creating a regex
 231 out of smaller snippets concatenated together, and you use fewer than three
 232 digits, the beginning of one snippet may be interpreted as adding digits to the
 233 ending of the snippet before it.  See L</Absolute referencing> for more
 234 discussion and examples of the snippet problem.
 235
 236 Note that a character expressed as an octal escape is considered
 237 a character without special meaning by the regex engine, and will match
 238 "as is".
 239
 240 To summarize, the C<\o{}> form is always safe to use, and the other form is
 241 safe to use for code points through \077 when you use exactly three digits to
 242 specify them.
 243
 244 Mnemonic: I<0>ctal or I<o>ctal.
 245
 246 =head4 Examples (assuming an ASCII platform)
 247
 248  $str = "Perl";
 249  $str =~ /\o{120}/;  # Match, "\120" is "P".
 250  $str =~ /\120/;     # Same.
 251  $str =~ /\o{120}+/; # Match, "\120" is "P",
 252                      # it's repeated at least once.
 253  $str =~ /\120+/;    # Same.
 254  $str =~ /P\053/;    # No match, "\053" is "+" and taken literally.
 255  /\o{23073}/         # Black foreground, white background smiling face.
 256  /\o{4801234567}/    # Raises a warning, and yields chr(4).
 257
 258 =head4 Disambiguation rules between old-style octal escapes and backreferences
 259
 260 Octal escapes of the C<\000> form outside of bracketed character classes
 261 potentially clash with old-style backreferences (see L</Absolute referencing>
 262 below).  They both consist of a backslash followed by numbers.  So Perl has to
 263 use heuristics to determine whether it is a backreference or an octal escape.
 264 Perl uses the following rules to disambiguate:
 265
 266 =over 4
 267
 268 =item 1
 269
 270 If the backslash is followed by a single digit, it's a backreference.
 271
 272 =item 2
 273
 274 If the first digit following the backslash is a 0, it's an octal escape.
 275
 276 =item 3
 277
 278 If the number following the backslash is N (in decimal), and Perl already
 279 has seen N capture groups, Perl considers this a backreference.  Otherwise,
 280 it considers it an octal escape. If N has more than three digits, Perl
 281 takes only the first three for the octal escape; the rest are matched as is.
 282
 283  my $pat  = "(" x 999;
 284     $pat .= "a";
 285     $pat .= ")" x 999;
 286  /^($pat)\1000$/;   #  Matches 'aa'; there are 1000 capture groups.
 287  /^$pat\1000$/;     #  Matches 'a@0'; there are 999 capture groups
 288                     #  and \1000 is seen as \100 (a '@') and a '0'.
 289
 290 =back
 291
 292 You can force a backreference interpretation always by using the C<\g{...}>
 293 form.  You can the force an octal interpretation always by using the C<\o{...}>
 294 form, or for numbers up through \077 (= 63 decimal), by using three digits,
 295 beginning with a "0".
 296
 297 =head3 Hexadecimal escapes
 298
 299 Like octal escapes, there are two forms of hexadecimal escapes, but both start
 300 with the same thing, C<\x>.  This is followed by either exactly two hexadecimal
 301 digits forming a number, or a hexadecimal number of arbitrary length surrounded
 302 by curly braces. The hexadecimal number is the code point of the character you
 303 want to express.
 304
 305 Note that a character expressed as one of these escapes is considered a
 306 character without special meaning by the regex engine, and will match
 307 "as is".
 308
 309 Mnemonic: heI<x>adecimal.
 310
 311 =head4 Examples (assuming an ASCII platform)
 312
 313  $str = "Perl";
 314  $str =~ /\x50/;    # Match, "\x50" is "P".
 315  $str =~ /\x50+/;   # Match, "\x50" is "P", it is repeated at least once
 316  $str =~ /P\x2B/;   # No match, "\x2B" is "+" and taken literally.
 317
 318  /\x{2603}\x{2602}/ # Snowman with an umbrella.
 319                     # The Unicode character 2603 is a snowman,
 320                     # the Unicode character 2602 is an umbrella.
 321  /\x{263B}/         # Black smiling face.
 322  /\x{263b}/         # Same, the hex digits A - F are case insensitive.
 323
 324 =head2 Modifiers
 325
 326 A number of backslash sequences have to do with changing the character,
 327 or characters following them. C<\l> will lowercase the character following
 328 it, while C<\u> will uppercase (or, more accurately, titlecase) the
 329 character following it. They provide functionality similar to the
 330 functions C<lcfirst> and C<ucfirst>.
 331
 332 To uppercase or lowercase several characters, one might want to use
 333 C<\L> or C<\U>, which will lowercase/uppercase all characters following
 334 them, until either the end of the pattern or the next occurrence of
 335 C<\E>, whichever comes first. They provide functionality similar to what
 336 the functions C<lc> and C<uc> provide.
 337
 338 C<\Q> is used to quote (disable) pattern metacharacters, up to the next
 339 C<\E> or the end of the pattern. C<\Q> adds a backslash to any character
 340 that could have special meaning to Perl.  In the ASCII range, it quotes
 341 every character that isn't a letter, digit, or underscore.  See
 342 L<perlfunc/quotemeta> for details on what gets quoted for non-ASCII
 343 code points.  Using this ensures that any character between C<\Q> and
 344 C<\E> will be matched literally, not interpreted as a metacharacter by
 345 the regex engine.
 346
 347 C<\F> can be used to casefold all characters following, up to the next C<\E>
 348 or the end of the pattern. It provides the functionality similar to
 349 the C<fc> function.
 350
 351 Mnemonic: I<L>owercase, I<U>ppercase, I<F>old-case, I<Q>uotemeta, I<E>nd.
 352
 353 =head4 Examples
 354
 355  $sid     = "sid";
 356  $greg    = "GrEg";
 357  $miranda = "(Miranda)";
 358  $str     =~ /\u$sid/;        # Matches 'Sid'
 359  $str     =~ /\L$greg/;       # Matches 'greg'
 360  $str     =~ /\Q$miranda\E/;  # Matches '(Miranda)', as if the pattern
 361                               #   had been written as /\(Miranda\)/
 362
 363 =head2 Character classes
 364
 365 Perl regular expressions have a large range of character classes. Some of
 366 the character classes are written as a backslash sequence. We will briefly
 367 discuss those here; full details of character classes can be found in
 368 L<perlrecharclass>.
 369
 370 C<\w> is a character class that matches any single I<word> character
 371 (letters, digits, Unicode marks, and connector punctuation (like the
 372 underscore)).  C<\d> is a character class that matches any decimal
 373 digit, while the character class C<\s> matches any whitespace character.
 374 New in perl 5.10.0 are the classes C<\h> and C<\v> which match horizontal
 375 and vertical whitespace characters.
 376
 377 The exact set of characters matched by C<\d>, C<\s>, and C<\w> varies
 378 depending on various pragma and regular expression modifiers.  It is
 379 possible to restrict the match to the ASCII range by using the C</a>
 380 regular expression modifier.  See L<perlrecharclass>.
 381
 382 The uppercase variants (C<\W>, C<\D>, C<\S>, C<\H>, and C<\V>) are
 383 character classes that match, respectively, any character that isn't a
 384 word character, digit, whitespace, horizontal whitespace, or vertical
 385 whitespace.
 386
 387 Mnemonics: I<w>ord, I<d>igit, I<s>pace, I<h>orizontal, I<v>ertical.
 388
 389 =head3 Unicode classes
 390
 391 C<\pP> (where C<P> is a single letter) and C<\p{Property}> are used to
 392 match a character that matches the given Unicode property; properties
 393 include things like "letter", or "thai character". Capitalizing the
 394 sequence to C<\PP> and C<\P{Property}> make the sequence match a character
 395 that doesn't match the given Unicode property. For more details, see
 396 L<perlrecharclass/Backslash sequences> and
 397 L<perlunicode/Unicode Character Properties>.
 398
 399 Mnemonic: I<p>roperty.
 400
 401 =head2 Referencing
 402
 403 If capturing parenthesis are used in a regular expression, we can refer
 404 to the part of the source string that was matched, and match exactly the
 405 same thing. There are three ways of referring to such I<backreference>:
 406 absolutely, relatively, and by name.
 407
 408 =for later add link to perlrecapture
 409
 410 =head3 Absolute referencing
 411
 412 Either C<\gI<N>> (starting in Perl 5.10.0), or C<\I<N>> (old-style) where I<N>
 413 is a positive (unsigned) decimal number of any length is an absolute reference
 414 to a capturing group.
 415
 416 I<N> refers to the Nth set of parentheses, so C<\gI<N>> refers to whatever has
 417 been matched by that set of parentheses.  Thus C<\g1> refers to the first
 418 capture group in the regex.
 419
 420 The C<\gI<N>> form can be equivalently written as C<\g{I<N>}>
 421 which avoids ambiguity when building a regex by concatenating shorter
 422 strings.  Otherwise if you had a regex C<qr/$a$b/>, and C<$a> contained
 423 C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which is
 424 probably not what you intended.
 425
 426 In the C<\I<N>> form, I<N> must not begin with a "0", and there must be at
 427 least I<N> capturing groups, or else I<N> is considered an octal escape
 428 (but something like C<\18> is the same as C<\0018>; that is, the octal escape
 429 C<"\001"> followed by a literal digit C<"8">).
 430
 431 Mnemonic: I<g>roup.
 432
 433 =head4 Examples
 434
 435  /(\w+) \g1/;    # Finds a duplicated word, (e.g. "cat cat").
 436  /(\w+) \1/;     # Same thing; written old-style.
 437  /(.)(.)\g2\g1/;  # Match a four letter palindrome (e.g. "ABBA").
 438
 439
 440 =head3 Relative referencing
 441
 442 C<\g-I<N>> (starting in Perl 5.10.0) is used for relative addressing.  (It can
 443 be written as C<\g{-I<N>>.)  It refers to the I<N>th group before the
 444 C<\g{-I<N>}>.
 445
 446 The big advantage of this form is that it makes it much easier to write
 447 patterns with references that can be interpolated in larger patterns,
 448 even if the larger pattern also contains capture groups.
 449
 450 =head4 Examples
 451
 452  /(A)        # Group 1
 453   (          # Group 2
 454     (B)      # Group 3
 455     \g{-1}   # Refers to group 3 (B)
 456     \g{-3}   # Refers to group 1 (A)
 457   )
 458  /x;         # Matches "ABBA".
 459
 460  my $qr = qr /(.)(.)\g{-2}\g{-1}/;  # Matches 'abab', 'cdcd', etc.
 461  /$qr$qr/                           # Matches 'ababcdcd'.
 462
 463 =head3 Named referencing
 464
 465 C<\g{I<name>}> (starting in Perl 5.10.0) can be used to back refer to a
 466 named capture group, dispensing completely with having to think about capture
 467 buffer positions.
 468
 469 To be compatible with .Net regular expressions, C<\g{name}> may also be
 470 written as C<\k{name}>, C<< \k<name> >> or C<\k'name'>.
 471
 472 To prevent any ambiguity, I<name> must not start with a digit nor contain a
 473 hyphen.
 474
 475 =head4 Examples
 476
 477  /(?<word>\w+) \g{word}/ # Finds duplicated word, (e.g. "cat cat")
 478  /(?<word>\w+) \k{word}/ # Same.
 479  /(?<word>\w+) \k<word>/ # Same.
 480  /(?<letter1>.)(?<letter2>.)\g{letter2}\g{letter1}/
 481                          # Match a four letter palindrome (e.g. "ABBA")
 482
 483 =head2 Assertions
 484
 485 Assertions are conditions that have to be true; they don't actually
 486 match parts of the substring. There are six assertions that are written as
 487 backslash sequences.
 488
 489 =over 4
 490
 491 =item \A
 492
 493 C<\A> only matches at the beginning of the string. If the C</m> modifier
 494 isn't used, then C</\A/> is equivalent to C</^/>. However, if the C</m>
 495 modifier is used, then C</^/> matches internal newlines, but the meaning
 496 of C</\A/> isn't changed by the C</m> modifier. C<\A> matches at the beginning
 497 of the string regardless whether the C</m> modifier is used.
 498
 499 =item \z, \Z
 500
 501 C<\z> and C<\Z> match at the end of the string. If the C</m> modifier isn't
 502 used, then C</\Z/> is equivalent to C</$/>; that is, it matches at the
 503 end of the string, or one before the newline at the end of the string. If the
 504 C</m> modifier is used, then C</$/> matches at internal newlines, but the
 505 meaning of C</\Z/> isn't changed by the C</m> modifier. C<\Z> matches at
 506 the end of the string (or just before a trailing newline) regardless whether
 507 the C</m> modifier is used.
 508
 509 C<\z> is just like C<\Z>, except that it does not match before a trailing
 510 newline. C<\z> matches at the end of the string only, regardless of the
 511 modifiers used, and not just before a newline.  It is how to anchor the
 512 match to the true end of the string under all conditions.
 513
 514 =item \G
 515
 516 C<\G> is usually used only in combination with the C</g> modifier. If the
 517 C</g> modifier is used and the match is done in scalar context, Perl
 518 remembers where in the source string the last match ended, and the next time,
 519 it will start the match from where it ended the previous time.
 520
 521 C<\G> matches the point where the previous match on that string ended,
 522 or the beginning of that string if there was no previous match.
 523
 524 =for later add link to perlremodifiers
 525
 526 Mnemonic: I<G>lobal.
 527
 528 =item \b, \B
 529
 530 C<\b> matches at any place between a word and a non-word character; C<\B>
 531 matches at any place between characters where C<\b> doesn't match. C<\b>
 532 and C<\B> assume there's a non-word character before the beginning and after
 533 the end of the source string; so C<\b> will match at the beginning (or end)
 534 of the source string if the source string begins (or ends) with a word
 535 character. Otherwise, C<\B> will match.
 536
 537 Do not use something like C<\b=head\d\b> and expect it to match the
 538 beginning of a line.  It can't, because for there to be a boundary before
 539 the non-word "=", there must be a word character immediately previous.
 540 All boundary determinations look for word characters alone, not for
 541 non-words characters nor for string ends.  It may help to understand how
 542 <\b> and <\B> work by equating them as follows:
 543
 544     \b  really means    (?:(?<=\w)(?!\w)|(?<!\w)(?=\w))
 545     \B  really means    (?:(?<=\w)(?=\w)|(?<!\w)(?!\w))
 546
 547 Mnemonic: I<b>oundary.
 548
 549 =back
 550
 551 =head4 Examples
 552
 553   "cat"   =~ /\Acat/;     # Match.
 554   "cat"   =~ /cat\Z/;     # Match.
 555   "cat\n" =~ /cat\Z/;     # Match.
 556   "cat\n" =~ /cat\z/;     # No match.
 557
 558   "cat"   =~ /\bcat\b/;   # Matches.
 559   "cats"  =~ /\bcat\b/;   # No match.
 560   "cat"   =~ /\bcat\B/;   # No match.
 561   "cats"  =~ /\bcat\B/;   # Match.
 562
 563   while ("cat dog" =~ /(\w+)/g) {
 564       print $1;           # Prints 'catdog'
 565   }
 566   while ("cat dog" =~ /\G(\w+)/g) {
 567       print $1;           # Prints 'cat'
 568   }
 569
 570 =head2 Misc
 571
 572 Here we document the backslash sequences that don't fall in one of the
 573 categories above. These are:
 574
 575 =over 4
 576
 577 =item \C
 578
 579 (Deprecated.) C<\C> always matches a single octet, even if the source
 580 string is encoded
 581 in UTF-8 format, and the character to be matched is a multi-octet character.
 582 This is very dangerous, because it violates
 583 the logical character abstraction and can cause UTF-8 sequences to become malformed.
 584
 585 Use C<utf8::encode()> instead.
 586
 587 Mnemonic: oI<C>tet.
 588
 589 =item \K
 590
 591 This appeared in perl 5.10.0. Anything matched left of C<\K> is
 592 not included in C<$&>, and will not be replaced if the pattern is
 593 used in a substitution. This lets you write C<s/PAT1 \K PAT2/REPL/x>
 594 instead of C<s/(PAT1) PAT2/${1}REPL/x> or C<s/(?<=PAT1) PAT2/REPL/x>.
 595
 596 Mnemonic: I<K>eep.
 597
 598 =item \N
 599
 600 This feature, available starting in v5.12,  matches any character
 601 that is B<not> a newline.  It is a short-hand for writing C<[^\n]>, and is
 602 identical to the C<.> metasymbol, except under the C</s> flag, which changes
 603 the meaning of C<.>, but not C<\N>.
 604
 605 Note that C<\N{...}> can mean a
 606 L<named or numbered character
 607 |/Named or numbered characters and character sequences>.
 608
 609 Mnemonic: Complement of I<\n>.
 610
 611 =item \R
 612 X<\R>
 613
 614 C<\R> matches a I<generic newline>; that is, anything considered a
 615 linebreak sequence by Unicode. This includes all characters matched by
 616 C<\v> (vertical whitespace), and the multi character sequence C<"\x0D\x0A">
 617 (carriage return followed by a line feed, sometimes called the network
 618 newline; it's the end of line sequence used in Microsoft text files opened
 619 in binary mode). C<\R> is equivalent to C<< (?>\x0D\x0A|\v) >>.  (The
 620 reason it doesn't backtrack is that the sequence is considered
 621 inseparable.  That means that
 622
 623  "\x0D\x0A" =~ /^\R\x0A$/   # No match
 624
 625 fails, because the C<\R> matches the entire string, and won't backtrack
 626 to match just the C<"\x0D">.)  Since
 627 C<\R> can match a sequence of more than one character, it cannot be put
 628 inside a bracketed character class; C</[\R]/> is an error; use C<\v>
 629 instead.  C<\R> was introduced in perl 5.10.0.
 630
 631 Note that this does not respect any locale that might be in effect; it
 632 matches according to the platform's native character set.
 633
 634 Mnemonic: none really. C<\R> was picked because PCRE already uses C<\R>,
 635 and more importantly because Unicode recommends such a regular expression
 636 metacharacter, and suggests C<\R> as its notation.
 637
 638 =item \X
 639 X<\X>
 640
 641 This matches a Unicode I<extended grapheme cluster>.
 642
 643 C<\X> matches quite well what normal (non-Unicode-programmer) usage
 644 would consider a single character.  As an example, consider a G with some sort
 645 of diacritic mark, such as an arrow.  There is no such single character in
 646 Unicode, but one can be composed by using a G followed by a Unicode "COMBINING
 647 UPWARDS ARROW BELOW", and would be displayed by Unicode-aware software as if it
 648 were a single character.
 649
 650 The match is greedy and non-backtracking, so that the cluster is never
 651 broken up into smaller components.
 652
 653 Mnemonic: eI<X>tended Unicode character.
 654
 655 =back
 656
 657 =head4 Examples
 658
 659  $str =~ s/foo\Kbar/baz/g; # Change any 'bar' following a 'foo' to 'baz'
 660  $str =~ s/(.)\K\g1//g;    # Delete duplicated characters.
 661
 662  "\n"   =~ /^\R$/;         # Match, \n   is a generic newline.
 663  "\r"   =~ /^\R$/;         # Match, \r   is a generic newline.
 664  "\r\n" =~ /^\R$/;         # Match, \r\n is a generic newline.
 665
 666  "P\x{307}" =~ /^\X$/     # \X matches a P with a dot above.
 667
 668 =cut