Porting/corelist.pl

   1 #!perl
   2 # Generates info for Module::CoreList from this perl tree
   3 # run this from the root of a perl tree
   4 #
   5 # Data is on STDOUT.
   6 #
   7 # With an optional arg specifying the root of a CPAN mirror, outputs the
   8 # %upstream and %bug_tracker hashes too.
   9
  10 use strict;
  11 use warnings;
  12 use File::Find;
  13 use ExtUtils::MM_Unix;
  14 use version;
  15 use lib "Porting";
  16 use Maintainers qw(%Modules files_to_modules);
  17 use File::Spec;
  18 use Parse::CPAN::Meta;
  19 use IPC::Cmd 'can_run';
  20
  21 my $corelist_file = 'dist/Module-CoreList/lib/Module/CoreList.pm';
  22
  23 my %lines;
  24 my %module_to_file;
  25 my %modlist;
  26
  27 die "usage: $0 [ cpan-mirror/ ] [ 5.x.y] \n" unless @ARGV <= 2;
  28 my $cpan         = shift;
  29 my $raw_version  = shift || $];
  30 my $perl_version = version->parse("$raw_version");
  31 my $perl_vnum    = $perl_version->numify;
  32 my $perl_vstring = $perl_version->normal; # how do we get version.pm to not give us leading v?
  33 $perl_vstring =~ s/^v//;
  34
  35 if ( !-f 'MANIFEST' ) {
  36     die "Must be run from the root of a clean perl tree\n";
  37 }
  38
  39 open( my $corelist_fh, '<', $corelist_file ) || die "Could not open $corelist_file: $!";
  40 my $corelist = join( '', <$corelist_fh> );
  41
  42 if ($cpan) {
  43     my $modlistfile = File::Spec->catfile( $cpan, 'modules', '02packages.details.txt' );
  44     my $content;
  45
  46     my $fh;
  47     if ( -e $modlistfile ) {
  48         warn "Reading the module list from $modlistfile";
  49         open $fh, '<', $modlistfile or die "Couldn't open $modlistfile: $!";
  50     } elsif ( -e $modlistfile . ".gz" ) {
  51         my $zcat = can_run('gzcat') || can_run('zcat') or die "Can't find gzcat or zcat";
  52         warn "Reading the module list from $modlistfile.gz";
  53         open $fh, '-|', "$zcat $modlistfile.gz" or die "Couldn't zcat $modlistfile.gz: $!";
  54     } else {
  55         warn "About to fetch 02packages from ftp.funet.fi. This may take a few minutes\n";
  56         $content = fetch_url('http://ftp.funet.fi/pub/CPAN/modules/02packages.details.txt');
  57         unless ($content) {
  58             die "Unable to read 02packages.details.txt from either your CPAN mirror or ftp.funet.fi";
  59         }
  60     }
  61
  62     if ( $fh and !$content ) {
  63         local $/ = "\n";
  64         $content = join( '', <$fh> );
  65     }
  66
  67     die "Incompatible modlist format"
  68         unless $content =~ /^Columns: +package name, version, path/m;
  69
  70     # Converting the file to a hash is about 5 times faster than a regexp flat
  71     # lookup.
  72     for ( split( qr/\n/, $content ) ) {
  73         next unless /^([A-Za-z_:0-9]+) +[-0-9.undefHASHVERSIONvsetwhenloadingbogus]+ +(\S+)/;
  74         $modlist{$1} = $2;
  75     }
  76 }
  77
  78 find(
  79     sub {
  80         /(\.pm|_pm\.PL)$/ or return;
  81         /PPPort\.pm$/ and return;
  82         my $module = $File::Find::name;
  83         $module =~ /\b(demo|t|private)\b/ and return;    # demo or test modules
  84         my $version = MM->parse_version($_);
  85         defined $version or $version = 'undef';
  86         $version =~ /\d/ and $version = "'$version'";
  87
  88         # some heuristics to figure out the module name from the file name
  89         $module =~ s{^(lib|cpan|dist|(?:vms/|symbian/)?ext)/}{}
  90                         and $1 ne 'lib'
  91             and (
  92             $module =~ s{\b(\w+)/\1\b}{$1},
  93             $module =~ s{^B/O}{O},
  94             $module =~ s{^Devel-PPPort}{Devel},
  95             $module =~ s{^libnet/}{},
  96             $module =~ s{^Encode/encoding}{encoding},
  97             $module =~ s{^IPC-SysV/}{IPC/},
  98             $module =~ s{^MIME-Base64/QuotedPrint}{MIME/QuotedPrint},
  99             $module =~ s{^(?:DynaLoader|Errno|Opcode)/}{},
 100             );
 101                 $module =~ s{^lib/}{}g;
 102         $module =~ s{/}{::}g;
 103         $module =~ s{-}{::}g;
 104                 $module =~ s{^.*::lib::}{}; # turns Foo/lib/Foo.pm into Foo.pm
 105         $module =~ s/(\.pm|_pm\.PL)$//;
 106         $lines{$module}          = $version;
 107         $module_to_file{$module} = $File::Find::name;
 108     },
 109     'vms/ext',
 110     'symbian/ext',
 111     'lib',
 112     'ext',
 113         'cpan',
 114         'dist'
 115 );
 116
 117 -e 'configpm' and $lines{Config} = 'undef';
 118
 119 if ( open my $ucdv, "<", "lib/unicore/version" ) {
 120     chomp( my $ucd = <$ucdv> );
 121     $lines{Unicode} = "'$ucd'";
 122     close $ucdv;
 123 }
 124
 125 my $versions_in_release = "    " . $perl_vnum . " => {\n";
 126 foreach my $key ( sort keys %lines ) {
 127     $versions_in_release .= sprintf "\t%-24s=> %s,\n", "'$key'", $lines{$key};
 128 }
 129 $versions_in_release .= "    },\n";
 130
 131 $corelist =~ s/^(%version\s*=\s*.*?)(^\);)$/$1$versions_in_release$2/xism;
 132
 133 exit unless %modlist;
 134
 135 # We have to go through this two stage lookup, given how Maintainers.pl keys its
 136 # data by "Module", which is really a dist.
 137 my $file_to_M = files_to_modules( values %module_to_file );
 138
 139 my %module_to_upstream;
 140 my %module_to_dist;
 141 my %dist_to_meta_YAML;
 142 my %module_to_deprecated;
 143 while ( my ( $module, $file ) = each %module_to_file ) {
 144     my $M = $file_to_M->{$file};
 145     next unless $M;
 146     next if $Modules{$M}{MAINTAINER} eq 'p5p';
 147     $module_to_upstream{$module} = $Modules{$M}{UPSTREAM};
 148     $module_to_deprecated{$module} = 1 if $Modules{$M}{DEPRECATED};
 149     next
 150         if defined $module_to_upstream{$module}
 151             && $module_to_upstream{$module} =~ /^(?:blead|first-come)$/;
 152     my $dist = $modlist{$module};
 153     unless ($dist) {
 154         warn "Can't find a distribution for $module\n";
 155         next;
 156     }
 157     $module_to_dist{$module} = $dist;
 158
 159     next if exists $dist_to_meta_YAML{$dist};
 160
 161     $dist_to_meta_YAML{$dist} = undef;
 162
 163     # Like it or lump it, this has to be Unix format.
 164     my $meta_YAML_path = "authors/id/$dist";
 165     $meta_YAML_path =~ s/(?:tar\.gz|tar\.bz2|zip)$/meta/ or die "$meta_YAML_path";
 166     my $meta_YAML_url = 'http://ftp.funet.fi/pub/CPAN/' . $meta_YAML_path;
 167
 168     if ( -e "$cpan/$meta_YAML_path" ) {
 169         $dist_to_meta_YAML{$dist} = Parse::CPAN::Meta::LoadFile( $cpan . "/" . $meta_YAML_path );
 170     } elsif ( my $content = fetch_url($meta_YAML_url) ) {
 171         unless ($content) {
 172             warn "Failed to fetch $meta_YAML_url\n";
 173             next;
 174         }
 175         eval { $dist_to_meta_YAML{$dist} = Parse::CPAN::Meta::Load($content); };
 176         if ( my $err = $@ ) {
 177             warn "$meta_YAML_path: ".$err;
 178             next;
 179         }
 180     } else {
 181         warn "$meta_YAML_path does not exist for $module\n";
 182
 183         # I tried code to open the tarballs with Archive::Tar to find and
 184         # extract META.yml, but only Text-Tabs+Wrap-2006.1117.tar.gz had one,
 185         # so it's not worth including.
 186         next;
 187     }
 188 }
 189
 190 my $upstream_stanza = "%upstream = (\n";
 191 foreach my $module ( sort keys %module_to_upstream ) {
 192     my $upstream = defined $module_to_upstream{$module} ? "'$module_to_upstream{$module}'" : 'undef';
 193     $upstream_stanza .= sprintf "    %-24s=> %s,\n", "'$module'", $upstream;
 194 }
 195 $upstream_stanza .= ");";
 196
 197 $corelist =~ s/^%upstream .*? ;$/$upstream_stanza/ismx;
 198
 199 # Deprecation generation
 200 my $deprecated_stanza = "    " . $perl_vnum . " => {\n";
 201 foreach my $module ( sort keys %module_to_deprecated ) {
 202     my $deprecated = defined $module_to_deprecated{$module} ? "'$module_to_deprecated{$module}'" : 'undef';
 203     $deprecated_stanza .= sprintf "\t%-24s=> %s,\n", "'$module'", $deprecated;
 204 }
 205 $deprecated_stanza .= "    },\n";
 206 $corelist =~ s/^(%deprecated\s*=\s*.*?)(^\);)$/$1$deprecated_stanza$2/xism;
 207
 208 my $tracker = "%bug_tracker = (\n";
 209 foreach my $module ( sort keys %module_to_upstream ) {
 210     my $upstream = defined $module_to_upstream{$module};
 211     next
 212         if defined $upstream
 213             and $upstream eq 'blead' || $upstream eq 'first-come';
 214
 215     my $bug_tracker;
 216
 217     my $dist = $module_to_dist{$module};
 218     $bug_tracker = $dist_to_meta_YAML{$dist}->{resources}{bugtracker}
 219         if $dist;
 220
 221     $bug_tracker = defined $bug_tracker ? "'$bug_tracker'" : 'undef';
 222         next if $bug_tracker eq "'http://rt.perl.org/perlbug/'";
 223     $tracker .= sprintf "    %-24s=> %s,\n", "'$module'", $bug_tracker;
 224 }
 225 $tracker .= ");";
 226
 227 $corelist =~ s/^%bug_tracker .*? ;/$tracker/eismx;
 228
 229 unless ( $corelist =~ /and $perl_vstring releases of perl/ ) {
 230     warn "Adding $perl_vstring to the list of perl versions covered by Module::CoreList\n";
 231     $corelist =~ s/\s*and (.*?) releases of perl/, $1 and $perl_vstring releases of perl/ism;
 232 }
 233
 234 unless (
 235     $corelist =~ /^%released \s* = \s* \(
 236         .*?
 237         $perl_vnum => .*?
 238         \);/ismx
 239     )
 240 {
 241     warn "Adding $perl_vnum to the list of released perl versions. Please consider adding a release date.\n";
 242     $corelist =~ s/^(%released \s* = \s* .*?) ( \) )
 243                 /$1  $perl_vnum => '????-??-??',\n  $2/ismx;
 244 }
 245
 246 write_corelist($corelist);
 247
 248 warn "All done. Please check over $corelist_file carefully before committing. Thanks!\n";
 249
 250
 251 sub write_corelist {
 252     my $content = shift;
 253     open (my $clfh, ">", $corelist_file) || die "Failed to open $corelist_file for writing: $!";
 254     print $clfh $content || die "Failed to write the new CoreList.pm: $!";
 255     close($clfh);
 256 }
 257
 258 sub fetch_url {
 259     my $url = shift;
 260     eval { require LWP::Simple };
 261     if ( LWP::Simple->can('get') ) {
 262         return LWP::Simple->get($url);
 263     } elsif (`which curl`) {
 264         return `curl -s $url`;
 265     } elsif (`which wget`) {
 266         return `wget -q -O - $url`;
 267     }
 268 }