lib/overload.pm

   1 package overload;
   2
   3 our $VERSION = '1.02';
   4
   5 $overload::hint_bits = 0x20000; # HINT_LOCALIZE_HH
   6
   7 sub nil {}
   8
   9 sub OVERLOAD {
  10   $package = shift;
  11   my %arg = @_;
  12   my ($sub, $fb);
  13   $ {$package . "::OVERLOAD"}{dummy}++; # Register with magic by touching.
  14   *{$package . "::()"} = \&nil; # Make it findable via fetchmethod.
  15   for (keys %arg) {
  16     if ($_ eq 'fallback') {
  17       $fb = $arg{$_};
  18     } else {
  19       $sub = $arg{$_};
  20       if (not ref $sub and $sub !~ /::/) {
  21         $ {$package . "::(" . $_} = $sub;
  22         $sub = \&nil;
  23       }
  24       #print STDERR "Setting `$ {'package'}::\cO$_' to \\&`$sub'.\n";
  25       *{$package . "::(" . $_} = \&{ $sub };
  26     }
  27   }
  28   ${$package . "::()"} = $fb; # Make it findable too (fallback only).
  29 }
  30
  31 sub import {
  32   $package = (caller())[0];
  33   # *{$package . "::OVERLOAD"} = \&OVERLOAD;
  34   shift;
  35   $package->overload::OVERLOAD(@_);
  36 }
  37
  38 sub unimport {
  39   $package = (caller())[0];
  40   ${$package . "::OVERLOAD"}{dummy}++; # Upgrade the table
  41   shift;
  42   for (@_) {
  43     if ($_ eq 'fallback') {
  44       undef $ {$package . "::()"};
  45     } else {
  46       delete $ {$package . "::"}{"(" . $_};
  47     }
  48   }
  49 }
  50
  51 sub Overloaded {
  52   my $package = shift;
  53   $package = ref $package if ref $package;
  54   $package->can('()');
  55 }
  56
  57 sub ov_method {
  58   my $globref = shift;
  59   return undef unless $globref;
  60   my $sub = \&{*$globref};
  61   return $sub if $sub ne \&nil;
  62   return shift->can($ {*$globref});
  63 }
  64
  65 sub OverloadedStringify {
  66   my $package = shift;
  67   $package = ref $package if ref $package;
  68   #$package->can('(""')
  69   ov_method mycan($package, '(""'), $package
  70     or ov_method mycan($package, '(0+'), $package
  71     or ov_method mycan($package, '(bool'), $package
  72     or ov_method mycan($package, '(nomethod'), $package;
  73 }
  74
  75 sub Method {
  76   my $package = shift;
  77   $package = ref $package if ref $package;
  78   #my $meth = $package->can('(' . shift);
  79   ov_method mycan($package, '(' . shift), $package;
  80   #return $meth if $meth ne \&nil;
  81   #return $ {*{$meth}};
  82 }
  83
  84 sub AddrRef {
  85   my $package = ref $_[0];
  86   return "$_[0]" unless $package;
  87
  88         require Scalar::Util;
  89         my $class = Scalar::Util::blessed($_[0]);
  90         my $class_prefix = defined($class) ? "$class=" : "";
  91         my $type = Scalar::Util::reftype($_[0]);
  92         my $addr = Scalar::Util::refaddr($_[0]);
  93         return sprintf("$class_prefix$type(0x%x)", $addr);
  94 }
  95
  96 sub StrVal {
  97   (ref $_[0] && OverloadedStringify($_[0]) or ref($_[0]) eq 'Regexp') ?
  98     (AddrRef(shift)) :
  99     "$_[0]";
 100 }
 101
 102 sub mycan {                             # Real can would leave stubs.
 103   my ($package, $meth) = @_;
 104   return \*{$package . "::$meth"} if defined &{$package . "::$meth"};
 105   my $p;
 106   foreach $p (@{$package . "::ISA"}) {
 107     my $out = mycan($p, $meth);
 108     return $out if $out;
 109   }
 110   return undef;
 111 }
 112
 113 %constants = (
 114               'integer'   =>  0x1000, # HINT_NEW_INTEGER
 115               'float'     =>  0x2000, # HINT_NEW_FLOAT
 116               'binary'    =>  0x4000, # HINT_NEW_BINARY
 117               'q'         =>  0x8000, # HINT_NEW_STRING
 118               'qr'        => 0x10000, # HINT_NEW_RE
 119              );
 120
 121 %ops = ( with_assign      => "+ - * / % ** << >> x .",
 122          assign           => "+= -= *= /= %= **= <<= >>= x= .=",
 123          num_comparison   => "< <= >  >= == !=",
 124          '3way_comparison'=> "<=> cmp",
 125          str_comparison   => "lt le gt ge eq ne",
 126          binary           => "& | ^",
 127          unary            => "neg ! ~",
 128          mutators         => '++ --',
 129          func             => "atan2 cos sin exp abs log sqrt int",
 130          conversion       => 'bool "" 0+',
 131          iterators        => '<>',
 132          dereferencing    => '${} @{} %{} &{} *{}',
 133          special          => 'nomethod fallback =');
 134
 135 use warnings::register;
 136 sub constant {
 137   # Arguments: what, sub
 138   while (@_) {
 139     if (@_ == 1) {
 140         warnings::warnif ("Odd number of arguments for overload::constant");
 141         last;
 142     }
 143     elsif (!exists $constants {$_ [0]}) {
 144         warnings::warnif ("`$_[0]' is not an overloadable type");
 145     }
 146     elsif (!ref $_ [1] || "$_[1]" !~ /CODE\(0x[\da-f]+\)$/) {
 147         # Can't use C<ref $_[1] eq "CODE"> above as code references can be
 148         # blessed, and C<ref> would return the package the ref is blessed into.
 149         if (warnings::enabled) {
 150             $_ [1] = "undef" unless defined $_ [1];
 151             warnings::warn ("`$_[1]' is not a code reference");
 152         }
 153     }
 154     else {
 155         $^H{$_[0]} = $_[1];
 156         $^H |= $constants{$_[0]} | $overload::hint_bits;
 157     }
 158     shift, shift;
 159   }
 160 }
 161
 162 sub remove_constant {
 163   # Arguments: what, sub
 164   while (@_) {
 165     delete $^H{$_[0]};
 166     $^H &= ~ $constants{$_[0]};
 167     shift, shift;
 168   }
 169 }
 170
 171 1;
 172
 173 __END__
 174
 175 =head1 NAME
 176
 177 overload - Package for overloading perl operations
 178
 179 =head1 SYNOPSIS
 180
 181     package SomeThing;
 182
 183     use overload
 184         '+' => \&myadd,
 185         '-' => \&mysub;
 186         # etc
 187     ...
 188
 189     package main;
 190     $a = new SomeThing 57;
 191     $b=5+$a;
 192     ...
 193     if (overload::Overloaded $b) {...}
 194     ...
 195     $strval = overload::StrVal $b;
 196
 197 =head1 DESCRIPTION
 198
 199 =head2 Declaration of overloaded functions
 200
 201 The compilation directive
 202
 203     package Number;
 204     use overload
 205         "+" => \&add,
 206         "*=" => "muas";
 207
 208 declares function Number::add() for addition, and method muas() in
 209 the "class" C<Number> (or one of its base classes)
 210 for the assignment form C<*=> of multiplication.
 211
 212 Arguments of this directive come in (key, value) pairs.  Legal values
 213 are values legal inside a C<&{ ... }> call, so the name of a
 214 subroutine, a reference to a subroutine, or an anonymous subroutine
 215 will all work.  Note that values specified as strings are
 216 interpreted as methods, not subroutines.  Legal keys are listed below.
 217
 218 The subroutine C<add> will be called to execute C<$a+$b> if $a
 219 is a reference to an object blessed into the package C<Number>, or if $a is
 220 not an object from a package with defined mathemagic addition, but $b is a
 221 reference to a C<Number>.  It can also be called in other situations, like
 222 C<$a+=7>, or C<$a++>.  See L<MAGIC AUTOGENERATION>.  (Mathemagical
 223 methods refer to methods triggered by an overloaded mathematical
 224 operator.)
 225
 226 Since overloading respects inheritance via the @ISA hierarchy, the
 227 above declaration would also trigger overloading of C<+> and C<*=> in
 228 all the packages which inherit from C<Number>.
 229
 230 =head2 Calling Conventions for Binary Operations
 231
 232 The functions specified in the C<use overload ...> directive are called
 233 with three (in one particular case with four, see L<Last Resort>)
 234 arguments.  If the corresponding operation is binary, then the first
 235 two arguments are the two arguments of the operation.  However, due to
 236 general object calling conventions, the first argument should always be
 237 an object in the package, so in the situation of C<7+$a>, the
 238 order of the arguments is interchanged.  It probably does not matter
 239 when implementing the addition method, but whether the arguments
 240 are reversed is vital to the subtraction method.  The method can
 241 query this information by examining the third argument, which can take
 242 three different values:
 243
 244 =over 7
 245
 246 =item FALSE
 247
 248 the order of arguments is as in the current operation.
 249
 250 =item TRUE
 251
 252 the arguments are reversed.
 253
 254 =item C<undef>
 255
 256 the current operation is an assignment variant (as in
 257 C<$a+=7>), but the usual function is called instead.  This additional
 258 information can be used to generate some optimizations.  Compare
 259 L<Calling Conventions for Mutators>.
 260
 261 =back
 262
 263 =head2 Calling Conventions for Unary Operations
 264
 265 Unary operation are considered binary operations with the second
 266 argument being C<undef>.  Thus the functions that overloads C<{"++"}>
 267 is called with arguments C<($a,undef,'')> when $a++ is executed.
 268
 269 =head2 Calling Conventions for Mutators
 270
 271 Two types of mutators have different calling conventions:
 272
 273 =over
 274
 275 =item C<++> and C<-->
 276
 277 The routines which implement these operators are expected to actually
 278 I<mutate> their arguments.  So, assuming that $obj is a reference to a
 279 number,
 280
 281   sub incr { my $n = $ {$_[0]}; ++$n; $_[0] = bless \$n}
 282
 283 is an appropriate implementation of overloaded C<++>.  Note that
 284
 285   sub incr { ++$ {$_[0]} ; shift }
 286
 287 is OK if used with preincrement and with postincrement. (In the case
 288 of postincrement a copying will be performed, see L<Copy Constructor>.)
 289
 290 =item C<x=> and other assignment versions
 291
 292 There is nothing special about these methods.  They may change the
 293 value of their arguments, and may leave it as is.  The result is going
 294 to be assigned to the value in the left-hand-side if different from
 295 this value.
 296
 297 This allows for the same method to be used as overloaded C<+=> and
 298 C<+>.  Note that this is I<allowed>, but not recommended, since by the
 299 semantic of L<"Fallback"> Perl will call the method for C<+> anyway,
 300 if C<+=> is not overloaded.
 301
 302 =back
 303
 304 B<Warning.>  Due to the presence of assignment versions of operations,
 305 routines which may be called in assignment context may create
 306 self-referential structures.  Currently Perl will not free self-referential
 307 structures until cycles are C<explicitly> broken.  You may get problems
 308 when traversing your structures too.
 309
 310 Say,
 311
 312   use overload '+' => sub { bless [ \$_[0], \$_[1] ] };
 313
 314 is asking for trouble, since for code C<$obj += $foo> the subroutine
 315 is called as C<$obj = add($obj, $foo, undef)>, or C<$obj = [\$obj,
 316 \$foo]>.  If using such a subroutine is an important optimization, one
 317 can overload C<+=> explicitly by a non-"optimized" version, or switch
 318 to non-optimized version if C<not defined $_[2]> (see
 319 L<Calling Conventions for Binary Operations>).
 320
 321 Even if no I<explicit> assignment-variants of operators are present in
 322 the script, they may be generated by the optimizer.  Say, C<",$obj,"> or
 323 C<',' . $obj . ','> may be both optimized to
 324
 325   my $tmp = ',' . $obj;    $tmp .= ',';
 326
 327 =head2 Overloadable Operations
 328
 329 The following symbols can be specified in C<use overload> directive:
 330
 331 =over 5
 332
 333 =item * I<Arithmetic operations>
 334
 335     "+", "+=", "-", "-=", "*", "*=", "/", "/=", "%", "%=",
 336     "**", "**=", "<<", "<<=", ">>", ">>=", "x", "x=", ".", ".=",
 337
 338 For these operations a substituted non-assignment variant can be called if
 339 the assignment variant is not available.  Methods for operations C<+>,
 340 C<->, C<+=>, and C<-=> can be called to automatically generate
 341 increment and decrement methods.  The operation C<-> can be used to
 342 autogenerate missing methods for unary minus or C<abs>.
 343
 344 See L<"MAGIC AUTOGENERATION">, L<"Calling Conventions for Mutators"> and
 345 L<"Calling Conventions for Binary Operations">) for details of these
 346 substitutions.
 347
 348 =item * I<Comparison operations>
 349
 350     "<",  "<=", ">",  ">=", "==", "!=", "<=>",
 351     "lt", "le", "gt", "ge", "eq", "ne", "cmp",
 352
 353 If the corresponding "spaceship" variant is available, it can be
 354 used to substitute for the missing operation.  During C<sort>ing
 355 arrays, C<cmp> is used to compare values subject to C<use overload>.
 356
 357 =item * I<Bit operations>
 358
 359     "&", "^", "|", "neg", "!", "~",
 360
 361 C<neg> stands for unary minus.  If the method for C<neg> is not
 362 specified, it can be autogenerated using the method for
 363 subtraction. If the method for C<!> is not specified, it can be
 364 autogenerated using the methods for C<bool>, or C<"">, or C<0+>.
 365
 366 =item * I<Increment and decrement>
 367
 368     "++", "--",
 369
 370 If undefined, addition and subtraction methods can be
 371 used instead.  These operations are called both in prefix and
 372 postfix form.
 373
 374 =item * I<Transcendental functions>
 375
 376     "atan2", "cos", "sin", "exp", "abs", "log", "sqrt", "int"
 377
 378 If C<abs> is unavailable, it can be autogenerated using methods
 379 for "E<lt>" or "E<lt>=E<gt>" combined with either unary minus or subtraction.
 380
 381 Note that traditionally the Perl function L<int> rounds to 0, thus for
 382 floating-point-like types one should follow the same semantic.  If
 383 C<int> is unavailable, it can be autogenerated using the overloading of
 384 C<0+>.
 385
 386 =item * I<Boolean, string and numeric conversion>
 387
 388     'bool', '""', '0+',
 389
 390 If one or two of these operations are not overloaded, the remaining ones can
 391 be used instead.  C<bool> is used in the flow control operators
 392 (like C<while>) and for the ternary C<?:> operation.  These functions can
 393 return any arbitrary Perl value.  If the corresponding operation for this value
 394 is overloaded too, that operation will be called again with this value.
 395
 396 As a special case if the overload returns the object itself then it will
 397 be used directly. An overloaded conversion returning the object is
 398 probably a bug, because you're likely to get something that looks like
 399 C<YourPackage=HASH(0x8172b34)>.
 400
 401 =item * I<Iteration>
 402
 403     "<>"
 404
 405 If not overloaded, the argument will be converted to a filehandle or
 406 glob (which may require a stringification).  The same overloading
 407 happens both for the I<read-filehandle> syntax C<E<lt>$varE<gt>> and
 408 I<globbing> syntax C<E<lt>${var}E<gt>>.
 409
 410 B<BUGS> Even in list context, the iterator is currently called only
 411 once and with scalar context.
 412
 413 =item * I<Dereferencing>
 414
 415     '${}', '@{}', '%{}', '&{}', '*{}'.
 416
 417 If not overloaded, the argument will be dereferenced I<as is>, thus
 418 should be of correct type.  These functions should return a reference
 419 of correct type, or another object with overloaded dereferencing.
 420
 421 As a special case if the overload returns the object itself then it
 422 will be used directly (provided it is the correct type).
 423
 424 The dereference operators must be specified explicitly they will not be passed to
 425 "nomethod".
 426
 427 =item * I<Special>
 428
 429     "nomethod", "fallback", "=",
 430
 431 see L<SPECIAL SYMBOLS FOR C<use overload>>.
 432
 433 =back
 434
 435 See L<"Fallback"> for an explanation of when a missing method can be
 436 autogenerated.
 437
 438 A computer-readable form of the above table is available in the hash
 439 %overload::ops, with values being space-separated lists of names:
 440
 441  with_assign      => '+ - * / % ** << >> x .',
 442  assign           => '+= -= *= /= %= **= <<= >>= x= .=',
 443  num_comparison   => '< <= > >= == !=',
 444  '3way_comparison'=> '<=> cmp',
 445  str_comparison   => 'lt le gt ge eq ne',
 446  binary           => '& | ^',
 447  unary            => 'neg ! ~',
 448  mutators         => '++ --',
 449  func             => 'atan2 cos sin exp abs log sqrt',
 450  conversion       => 'bool "" 0+',
 451  iterators        => '<>',
 452  dereferencing    => '${} @{} %{} &{} *{}',
 453  special          => 'nomethod fallback ='
 454
 455 =head2 Inheritance and overloading
 456
 457 Inheritance interacts with overloading in two ways.
 458
 459 =over
 460
 461 =item Strings as values of C<use overload> directive
 462
 463 If C<value> in
 464
 465   use overload key => value;
 466
 467 is a string, it is interpreted as a method name.
 468
 469 =item Overloading of an operation is inherited by derived classes
 470
 471 Any class derived from an overloaded class is also overloaded.  The
 472 set of overloaded methods is the union of overloaded methods of all
 473 the ancestors. If some method is overloaded in several ancestor, then
 474 which description will be used is decided by the usual inheritance
 475 rules:
 476
 477 If C<A> inherits from C<B> and C<C> (in this order), C<B> overloads
 478 C<+> with C<\&D::plus_sub>, and C<C> overloads C<+> by C<"plus_meth">,
 479 then the subroutine C<D::plus_sub> will be called to implement
 480 operation C<+> for an object in package C<A>.
 481
 482 =back
 483
 484 Note that since the value of the C<fallback> key is not a subroutine,
 485 its inheritance is not governed by the above rules.  In the current
 486 implementation, the value of C<fallback> in the first overloaded
 487 ancestor is used, but this is accidental and subject to change.
 488
 489 =head1 SPECIAL SYMBOLS FOR C<use overload>
 490
 491 Three keys are recognized by Perl that are not covered by the above
 492 description.
 493
 494 =head2 Last Resort
 495
 496 C<"nomethod"> should be followed by a reference to a function of four
 497 parameters.  If defined, it is called when the overloading mechanism
 498 cannot find a method for some operation.  The first three arguments of
 499 this function coincide with the arguments for the corresponding method if
 500 it were found, the fourth argument is the symbol
 501 corresponding to the missing method.  If several methods are tried,
 502 the last one is used.  Say, C<1-$a> can be equivalent to
 503
 504         &nomethodMethod($a,1,1,"-")
 505
 506 if the pair C<"nomethod" =E<gt> "nomethodMethod"> was specified in the
 507 C<use overload> directive.
 508
 509 The C<"nomethod"> mechanism is I<not> used for the dereference operators
 510 ( ${} @{} %{} &{} *{} ).
 511
 512
 513 If some operation cannot be resolved, and there is no function
 514 assigned to C<"nomethod">, then an exception will be raised via die()--
 515 unless C<"fallback"> was specified as a key in C<use overload> directive.
 516
 517
 518 =head2 Fallback
 519
 520 The key C<"fallback"> governs what to do if a method for a particular
 521 operation is not found.  Three different cases are possible depending on
 522 the value of C<"fallback">:
 523
 524 =over 16
 525
 526 =item * C<undef>
 527
 528 Perl tries to use a
 529 substituted method (see L<MAGIC AUTOGENERATION>).  If this fails, it
 530 then tries to calls C<"nomethod"> value; if missing, an exception
 531 will be raised.
 532
 533 =item * TRUE
 534
 535 The same as for the C<undef> value, but no exception is raised.  Instead,
 536 it silently reverts to what it would have done were there no C<use overload>
 537 present.
 538
 539 =item * defined, but FALSE
 540
 541 No autogeneration is tried.  Perl tries to call
 542 C<"nomethod"> value, and if this is missing, raises an exception.
 543
 544 =back
 545
 546 B<Note.> C<"fallback"> inheritance via @ISA is not carved in stone
 547 yet, see L<"Inheritance and overloading">.
 548
 549 =head2 Copy Constructor
 550
 551 The value for C<"="> is a reference to a function with three
 552 arguments, i.e., it looks like the other values in C<use
 553 overload>. However, it does not overload the Perl assignment
 554 operator. This would go against Camel hair.
 555
 556 This operation is called in the situations when a mutator is applied
 557 to a reference that shares its object with some other reference, such
 558 as
 559
 560         $a=$b;
 561         ++$a;
 562
 563 To make this change $a and not change $b, a copy of C<$$a> is made,
 564 and $a is assigned a reference to this new object.  This operation is
 565 done during execution of the C<++$a>, and not during the assignment,
 566 (so before the increment C<$$a> coincides with C<$$b>).  This is only
 567 done if C<++> is expressed via a method for C<'++'> or C<'+='> (or
 568 C<nomethod>).  Note that if this operation is expressed via C<'+'>
 569 a nonmutator, i.e., as in
 570
 571         $a=$b;
 572         $a=$a+1;
 573
 574 then C<$a> does not reference a new copy of C<$$a>, since $$a does not
 575 appear as lvalue when the above code is executed.
 576
 577 If the copy constructor is required during the execution of some mutator,
 578 but a method for C<'='> was not specified, it can be autogenerated as a
 579 string copy if the object is a plain scalar.
 580
 581 =over 5
 582
 583 =item B<Example>
 584
 585 The actually executed code for
 586
 587         $a=$b;
 588         Something else which does not modify $a or $b....
 589         ++$a;
 590
 591 may be
 592
 593         $a=$b;
 594         Something else which does not modify $a or $b....
 595         $a = $a->clone(undef,"");
 596         $a->incr(undef,"");
 597
 598 if $b was mathemagical, and C<'++'> was overloaded with C<\&incr>,
 599 C<'='> was overloaded with C<\&clone>.
 600
 601 =back
 602
 603 Same behaviour is triggered by C<$b = $a++>, which is consider a synonym for
 604 C<$b = $a; ++$a>.
 605
 606 =head1 MAGIC AUTOGENERATION
 607
 608 If a method for an operation is not found, and the value for  C<"fallback"> is
 609 TRUE or undefined, Perl tries to autogenerate a substitute method for
 610 the missing operation based on the defined operations.  Autogenerated method
 611 substitutions are possible for the following operations:
 612
 613 =over 16
 614
 615 =item I<Assignment forms of arithmetic operations>
 616
 617 C<$a+=$b> can use the method for C<"+"> if the method for C<"+=">
 618 is not defined.
 619
 620 =item I<Conversion operations>
 621
 622 String, numeric, and boolean conversion are calculated in terms of one
 623 another if not all of them are defined.
 624
 625 =item I<Increment and decrement>
 626
 627 The C<++$a> operation can be expressed in terms of C<$a+=1> or C<$a+1>,
 628 and C<$a--> in terms of C<$a-=1> and C<$a-1>.
 629
 630 =item C<abs($a)>
 631
 632 can be expressed in terms of C<$aE<lt>0> and C<-$a> (or C<0-$a>).
 633
 634 =item I<Unary minus>
 635
 636 can be expressed in terms of subtraction.
 637
 638 =item I<Negation>
 639
 640 C<!> and C<not> can be expressed in terms of boolean conversion, or
 641 string or numerical conversion.
 642
 643 =item I<Concatenation>
 644
 645 can be expressed in terms of string conversion.
 646
 647 =item I<Comparison operations>
 648
 649 can be expressed in terms of its "spaceship" counterpart: either
 650 C<E<lt>=E<gt>> or C<cmp>:
 651
 652     <, >, <=, >=, ==, !=        in terms of <=>
 653     lt, gt, le, ge, eq, ne      in terms of cmp
 654
 655 =item I<Iterator>
 656
 657     <>                          in terms of builtin operations
 658
 659 =item I<Dereferencing>
 660
 661     ${} @{} %{} &{} *{}         in terms of builtin operations
 662
 663 =item I<Copy operator>
 664
 665 can be expressed in terms of an assignment to the dereferenced value, if this
 666 value is a scalar and not a reference.
 667
 668 =back
 669
 670 =head1 Losing overloading
 671
 672 The restriction for the comparison operation is that even if, for example,
 673 `C<cmp>' should return a blessed reference, the autogenerated `C<lt>'
 674 function will produce only a standard logical value based on the
 675 numerical value of the result of `C<cmp>'.  In particular, a working
 676 numeric conversion is needed in this case (possibly expressed in terms of
 677 other conversions).
 678
 679 Similarly, C<.=>  and C<x=> operators lose their mathemagical properties
 680 if the string conversion substitution is applied.
 681
 682 When you chop() a mathemagical object it is promoted to a string and its
 683 mathemagical properties are lost.  The same can happen with other
 684 operations as well.
 685
 686 =head1 Run-time Overloading
 687
 688 Since all C<use> directives are executed at compile-time, the only way to
 689 change overloading during run-time is to
 690
 691     eval 'use overload "+" => \&addmethod';
 692
 693 You can also use
 694
 695     eval 'no overload "+", "--", "<="';
 696
 697 though the use of these constructs during run-time is questionable.
 698
 699 =head1 Public functions
 700
 701 Package C<overload.pm> provides the following public functions:
 702
 703 =over 5
 704
 705 =item overload::StrVal(arg)
 706
 707 Gives string value of C<arg> as in absence of stringify overloading.
 708
 709 =item overload::Overloaded(arg)
 710
 711 Returns true if C<arg> is subject to overloading of some operations.
 712
 713 =item overload::Method(obj,op)
 714
 715 Returns C<undef> or a reference to the method that implements C<op>.
 716
 717 =back
 718
 719 =head1 Overloading constants
 720
 721 For some application Perl parser mangles constants too much.  It is possible
 722 to hook into this process via overload::constant() and overload::remove_constant()
 723 functions.
 724
 725 These functions take a hash as an argument.  The recognized keys of this hash
 726 are
 727
 728 =over 8
 729
 730 =item integer
 731
 732 to overload integer constants,
 733
 734 =item float
 735
 736 to overload floating point constants,
 737
 738 =item binary
 739
 740 to overload octal and hexadecimal constants,
 741
 742 =item q
 743
 744 to overload C<q>-quoted strings, constant pieces of C<qq>- and C<qx>-quoted
 745 strings and here-documents,
 746
 747 =item qr
 748
 749 to overload constant pieces of regular expressions.
 750
 751 =back
 752
 753 The corresponding values are references to functions which take three arguments:
 754 the first one is the I<initial> string form of the constant, the second one
 755 is how Perl interprets this constant, the third one is how the constant is used.
 756 Note that the initial string form does not
 757 contain string delimiters, and has backslashes in backslash-delimiter
 758 combinations stripped (thus the value of delimiter is not relevant for
 759 processing of this string).  The return value of this function is how this
 760 constant is going to be interpreted by Perl.  The third argument is undefined
 761 unless for overloaded C<q>- and C<qr>- constants, it is C<q> in single-quote
 762 context (comes from strings, regular expressions, and single-quote HERE
 763 documents), it is C<tr> for arguments of C<tr>/C<y> operators,
 764 it is C<s> for right-hand side of C<s>-operator, and it is C<qq> otherwise.
 765
 766 Since an expression C<"ab$cd,,"> is just a shortcut for C<'ab' . $cd . ',,'>,
 767 it is expected that overloaded constant strings are equipped with reasonable
 768 overloaded catenation operator, otherwise absurd results will result.
 769 Similarly, negative numbers are considered as negations of positive constants.
 770
 771 Note that it is probably meaningless to call the functions overload::constant()
 772 and overload::remove_constant() from anywhere but import() and unimport() methods.
 773 From these methods they may be called as
 774
 775         sub import {
 776           shift;
 777           return unless @_;
 778           die "unknown import: @_" unless @_ == 1 and $_[0] eq ':constant';
 779           overload::constant integer => sub {Math::BigInt->new(shift)};
 780         }
 781
 782 B<BUGS> Currently overloaded-ness of constants does not propagate
 783 into C<eval '...'>.
 784
 785 =head1 IMPLEMENTATION
 786
 787 What follows is subject to change RSN.
 788
 789 The table of methods for all operations is cached in magic for the
 790 symbol table hash for the package.  The cache is invalidated during
 791 processing of C<use overload>, C<no overload>, new function
 792 definitions, and changes in @ISA. However, this invalidation remains
 793 unprocessed until the next C<bless>ing into the package. Hence if you
 794 want to change overloading structure dynamically, you'll need an
 795 additional (fake) C<bless>ing to update the table.
 796
 797 (Every SVish thing has a magic queue, and magic is an entry in that
 798 queue.  This is how a single variable may participate in multiple
 799 forms of magic simultaneously.  For instance, environment variables
 800 regularly have two forms at once: their %ENV magic and their taint
 801 magic. However, the magic which implements overloading is applied to
 802 the stashes, which are rarely used directly, thus should not slow down
 803 Perl.)
 804
 805 If an object belongs to a package using overload, it carries a special
 806 flag.  Thus the only speed penalty during arithmetic operations without
 807 overloading is the checking of this flag.
 808
 809 In fact, if C<use overload> is not present, there is almost no overhead
 810 for overloadable operations, so most programs should not suffer
 811 measurable performance penalties.  A considerable effort was made to
 812 minimize the overhead when overload is used in some package, but the
 813 arguments in question do not belong to packages using overload.  When
 814 in doubt, test your speed with C<use overload> and without it.  So far
 815 there have been no reports of substantial speed degradation if Perl is
 816 compiled with optimization turned on.
 817
 818 There is no size penalty for data if overload is not used. The only
 819 size penalty if overload is used in some package is that I<all> the
 820 packages acquire a magic during the next C<bless>ing into the
 821 package. This magic is three-words-long for packages without
 822 overloading, and carries the cache table if the package is overloaded.
 823
 824 Copying (C<$a=$b>) is shallow; however, a one-level-deep copying is
 825 carried out before any operation that can imply an assignment to the
 826 object $a (or $b) refers to, like C<$a++>.  You can override this
 827 behavior by defining your own copy constructor (see L<"Copy Constructor">).
 828
 829 It is expected that arguments to methods that are not explicitly supposed
 830 to be changed are constant (but this is not enforced).
 831
 832 =head1 Metaphor clash
 833
 834 One may wonder why the semantic of overloaded C<=> is so counter intuitive.
 835 If it I<looks> counter intuitive to you, you are subject to a metaphor
 836 clash.
 837
 838 Here is a Perl object metaphor:
 839
 840 I<  object is a reference to blessed data>
 841
 842 and an arithmetic metaphor:
 843
 844 I<  object is a thing by itself>.
 845
 846 The I<main> problem of overloading C<=> is the fact that these metaphors
 847 imply different actions on the assignment C<$a = $b> if $a and $b are
 848 objects.  Perl-think implies that $a becomes a reference to whatever
 849 $b was referencing.  Arithmetic-think implies that the value of "object"
 850 $a is changed to become the value of the object $b, preserving the fact
 851 that $a and $b are separate entities.
 852
 853 The difference is not relevant in the absence of mutators.  After
 854 a Perl-way assignment an operation which mutates the data referenced by $a
 855 would change the data referenced by $b too.  Effectively, after
 856 C<$a = $b> values of $a and $b become I<indistinguishable>.
 857
 858 On the other hand, anyone who has used algebraic notation knows the
 859 expressive power of the arithmetic metaphor.  Overloading works hard
 860 to enable this metaphor while preserving the Perlian way as far as
 861 possible.  Since it is not possible to freely mix two contradicting
 862 metaphors, overloading allows the arithmetic way to write things I<as
 863 far as all the mutators are called via overloaded access only>.  The
 864 way it is done is described in L<Copy Constructor>.
 865
 866 If some mutator methods are directly applied to the overloaded values,
 867 one may need to I<explicitly unlink> other values which references the
 868 same value:
 869
 870     $a = new Data 23;
 871     ...
 872     $b = $a;            # $b is "linked" to $a
 873     ...
 874     $a = $a->clone;     # Unlink $b from $a
 875     $a->increment_by(4);
 876
 877 Note that overloaded access makes this transparent:
 878
 879     $a = new Data 23;
 880     $b = $a;            # $b is "linked" to $a
 881     $a += 4;            # would unlink $b automagically
 882
 883 However, it would not make
 884
 885     $a = new Data 23;
 886     $a = 4;             # Now $a is a plain 4, not 'Data'
 887
 888 preserve "objectness" of $a.  But Perl I<has> a way to make assignments
 889 to an object do whatever you want.  It is just not the overload, but
 890 tie()ing interface (see L<perlfunc/tie>).  Adding a FETCH() method
 891 which returns the object itself, and STORE() method which changes the
 892 value of the object, one can reproduce the arithmetic metaphor in its
 893 completeness, at least for variables which were tie()d from the start.
 894
 895 (Note that a workaround for a bug may be needed, see L<"BUGS">.)
 896
 897 =head1 Cookbook
 898
 899 Please add examples to what follows!
 900
 901 =head2 Two-face scalars
 902
 903 Put this in F<two_face.pm> in your Perl library directory:
 904
 905   package two_face;             # Scalars with separate string and
 906                                 # numeric values.
 907   sub new { my $p = shift; bless [@_], $p }
 908   use overload '""' => \&str, '0+' => \&num, fallback => 1;
 909   sub num {shift->[1]}
 910   sub str {shift->[0]}
 911
 912 Use it as follows:
 913
 914   require two_face;
 915   my $seven = new two_face ("vii", 7);
 916   printf "seven=$seven, seven=%d, eight=%d\n", $seven, $seven+1;
 917   print "seven contains `i'\n" if $seven =~ /i/;
 918
 919 (The second line creates a scalar which has both a string value, and a
 920 numeric value.)  This prints:
 921
 922   seven=vii, seven=7, eight=8
 923   seven contains `i'
 924
 925 =head2 Two-face references
 926
 927 Suppose you want to create an object which is accessible as both an
 928 array reference and a hash reference.
 929
 930   package two_refs;
 931   use overload '%{}' => \&gethash, '@{}' => sub { $ {shift()} };
 932   sub new {
 933     my $p = shift;
 934     bless \ [@_], $p;
 935   }
 936   sub gethash {
 937     my %h;
 938     my $self = shift;
 939     tie %h, ref $self, $self;
 940     \%h;
 941   }
 942
 943   sub TIEHASH { my $p = shift; bless \ shift, $p }
 944   my %fields;
 945   my $i = 0;
 946   $fields{$_} = $i++ foreach qw{zero one two three};
 947   sub STORE {
 948     my $self = ${shift()};
 949     my $key = $fields{shift()};
 950     defined $key or die "Out of band access";
 951     $$self->[$key] = shift;
 952   }
 953   sub FETCH {
 954     my $self = ${shift()};
 955     my $key = $fields{shift()};
 956     defined $key or die "Out of band access";
 957     $$self->[$key];
 958   }
 959
 960 Now one can access an object using both the array and hash syntax:
 961
 962   my $bar = new two_refs 3,4,5,6;
 963   $bar->[2] = 11;
 964   $bar->{two} == 11 or die 'bad hash fetch';
 965
 966 Note several important features of this example.  First of all, the
 967 I<actual> type of $bar is a scalar reference, and we do not overload
 968 the scalar dereference.  Thus we can get the I<actual> non-overloaded
 969 contents of $bar by just using C<$$bar> (what we do in functions which
 970 overload dereference).  Similarly, the object returned by the
 971 TIEHASH() method is a scalar reference.
 972
 973 Second, we create a new tied hash each time the hash syntax is used.
 974 This allows us not to worry about a possibility of a reference loop,
 975 which would lead to a memory leak.
 976
 977 Both these problems can be cured.  Say, if we want to overload hash
 978 dereference on a reference to an object which is I<implemented> as a
 979 hash itself, the only problem one has to circumvent is how to access
 980 this I<actual> hash (as opposed to the I<virtual> hash exhibited by the
 981 overloaded dereference operator).  Here is one possible fetching routine:
 982
 983   sub access_hash {
 984     my ($self, $key) = (shift, shift);
 985     my $class = ref $self;
 986     bless $self, 'overload::dummy'; # Disable overloading of %{}
 987     my $out = $self->{$key};
 988     bless $self, $class;        # Restore overloading
 989     $out;
 990   }
 991
 992 To remove creation of the tied hash on each access, one may an extra
 993 level of indirection which allows a non-circular structure of references:
 994
 995   package two_refs1;
 996   use overload '%{}' => sub { ${shift()}->[1] },
 997                '@{}' => sub { ${shift()}->[0] };
 998   sub new {
 999     my $p = shift;
1000     my $a = [@_];
1001     my %h;
1002     tie %h, $p, $a;
1003     bless \ [$a, \%h], $p;
1004   }
1005   sub gethash {
1006     my %h;
1007     my $self = shift;
1008     tie %h, ref $self, $self;
1009     \%h;
1010   }
1011
1012   sub TIEHASH { my $p = shift; bless \ shift, $p }
1013   my %fields;
1014   my $i = 0;
1015   $fields{$_} = $i++ foreach qw{zero one two three};
1016   sub STORE {
1017     my $a = ${shift()};
1018     my $key = $fields{shift()};
1019     defined $key or die "Out of band access";
1020     $a->[$key] = shift;
1021   }
1022   sub FETCH {
1023     my $a = ${shift()};
1024     my $key = $fields{shift()};
1025     defined $key or die "Out of band access";
1026     $a->[$key];
1027   }
1028
1029 Now if $baz is overloaded like this, then C<$baz> is a reference to a
1030 reference to the intermediate array, which keeps a reference to an
1031 actual array, and the access hash.  The tie()ing object for the access
1032 hash is a reference to a reference to the actual array, so
1033
1034 =over
1035
1036 =item *
1037
1038 There are no loops of references.
1039
1040 =item *
1041
1042 Both "objects" which are blessed into the class C<two_refs1> are
1043 references to a reference to an array, thus references to a I<scalar>.
1044 Thus the accessor expression C<$$foo-E<gt>[$ind]> involves no
1045 overloaded operations.
1046
1047 =back
1048
1049 =head2 Symbolic calculator
1050
1051 Put this in F<symbolic.pm> in your Perl library directory:
1052
1053   package symbolic;             # Primitive symbolic calculator
1054   use overload nomethod => \&wrap;
1055
1056   sub new { shift; bless ['n', @_] }
1057   sub wrap {
1058     my ($obj, $other, $inv, $meth) = @_;
1059     ($obj, $other) = ($other, $obj) if $inv;
1060     bless [$meth, $obj, $other];
1061   }
1062
1063 This module is very unusual as overloaded modules go: it does not
1064 provide any usual overloaded operators, instead it provides the L<Last
1065 Resort> operator C<nomethod>.  In this example the corresponding
1066 subroutine returns an object which encapsulates operations done over
1067 the objects: C<new symbolic 3> contains C<['n', 3]>, C<2 + new
1068 symbolic 3> contains C<['+', 2, ['n', 3]]>.
1069
1070 Here is an example of the script which "calculates" the side of
1071 circumscribed octagon using the above package:
1072
1073   require symbolic;
1074   my $iter = 1;                 # 2**($iter+2) = 8
1075   my $side = new symbolic 1;
1076   my $cnt = $iter;
1077
1078   while ($cnt--) {
1079     $side = (sqrt(1 + $side**2) - 1)/$side;
1080   }
1081   print "OK\n";
1082
1083 The value of $side is
1084
1085   ['/', ['-', ['sqrt', ['+', 1, ['**', ['n', 1], 2]],
1086                        undef], 1], ['n', 1]]
1087
1088 Note that while we obtained this value using a nice little script,
1089 there is no simple way to I<use> this value.  In fact this value may
1090 be inspected in debugger (see L<perldebug>), but ony if
1091 C<bareStringify> B<O>ption is set, and not via C<p> command.
1092
1093 If one attempts to print this value, then the overloaded operator
1094 C<""> will be called, which will call C<nomethod> operator.  The
1095 result of this operator will be stringified again, but this result is
1096 again of type C<symbolic>, which will lead to an infinite loop.
1097
1098 Add a pretty-printer method to the module F<symbolic.pm>:
1099
1100   sub pretty {
1101     my ($meth, $a, $b) = @{+shift};
1102     $a = 'u' unless defined $a;
1103     $b = 'u' unless defined $b;
1104     $a = $a->pretty if ref $a;
1105     $b = $b->pretty if ref $b;
1106     "[$meth $a $b]";
1107   }
1108
1109 Now one can finish the script by
1110
1111   print "side = ", $side->pretty, "\n";
1112
1113 The method C<pretty> is doing object-to-string conversion, so it
1114 is natural to overload the operator C<""> using this method.  However,
1115 inside such a method it is not necessary to pretty-print the
1116 I<components> $a and $b of an object.  In the above subroutine
1117 C<"[$meth $a $b]"> is a catenation of some strings and components $a
1118 and $b.  If these components use overloading, the catenation operator
1119 will look for an overloaded operator C<.>; if not present, it will
1120 look for an overloaded operator C<"">.  Thus it is enough to use
1121
1122   use overload nomethod => \&wrap, '""' => \&str;
1123   sub str {
1124     my ($meth, $a, $b) = @{+shift};
1125     $a = 'u' unless defined $a;
1126     $b = 'u' unless defined $b;
1127     "[$meth $a $b]";
1128   }
1129
1130 Now one can change the last line of the script to
1131
1132   print "side = $side\n";
1133
1134 which outputs
1135
1136   side = [/ [- [sqrt [+ 1 [** [n 1 u] 2]] u] 1] [n 1 u]]
1137
1138 and one can inspect the value in debugger using all the possible
1139 methods.
1140
1141 Something is still amiss: consider the loop variable $cnt of the
1142 script.  It was a number, not an object.  We cannot make this value of
1143 type C<symbolic>, since then the loop will not terminate.
1144
1145 Indeed, to terminate the cycle, the $cnt should become false.
1146 However, the operator C<bool> for checking falsity is overloaded (this
1147 time via overloaded C<"">), and returns a long string, thus any object
1148 of type C<symbolic> is true.  To overcome this, we need a way to
1149 compare an object to 0.  In fact, it is easier to write a numeric
1150 conversion routine.
1151
1152 Here is the text of F<symbolic.pm> with such a routine added (and
1153 slightly modified str()):
1154
1155   package symbolic;             # Primitive symbolic calculator
1156   use overload
1157     nomethod => \&wrap, '""' => \&str, '0+' => \&num;
1158
1159   sub new { shift; bless ['n', @_] }
1160   sub wrap {
1161     my ($obj, $other, $inv, $meth) = @_;
1162     ($obj, $other) = ($other, $obj) if $inv;
1163     bless [$meth, $obj, $other];
1164   }
1165   sub str {
1166     my ($meth, $a, $b) = @{+shift};
1167     $a = 'u' unless defined $a;
1168     if (defined $b) {
1169       "[$meth $a $b]";
1170     } else {
1171       "[$meth $a]";
1172     }
1173   }
1174   my %subr = ( n => sub {$_[0]},
1175                sqrt => sub {sqrt $_[0]},
1176                '-' => sub {shift() - shift()},
1177                '+' => sub {shift() + shift()},
1178                '/' => sub {shift() / shift()},
1179                '*' => sub {shift() * shift()},
1180                '**' => sub {shift() ** shift()},
1181              );
1182   sub num {
1183     my ($meth, $a, $b) = @{+shift};
1184     my $subr = $subr{$meth}
1185       or die "Do not know how to ($meth) in symbolic";
1186     $a = $a->num if ref $a eq __PACKAGE__;
1187     $b = $b->num if ref $b eq __PACKAGE__;
1188     $subr->($a,$b);
1189   }
1190
1191 All the work of numeric conversion is done in %subr and num().  Of
1192 course, %subr is not complete, it contains only operators used in the
1193 example below.  Here is the extra-credit question: why do we need an
1194 explicit recursion in num()?  (Answer is at the end of this section.)
1195
1196 Use this module like this:
1197
1198   require symbolic;
1199   my $iter = new symbolic 2;    # 16-gon
1200   my $side = new symbolic 1;
1201   my $cnt = $iter;
1202
1203   while ($cnt) {
1204     $cnt = $cnt - 1;            # Mutator `--' not implemented
1205     $side = (sqrt(1 + $side**2) - 1)/$side;
1206   }
1207   printf "%s=%f\n", $side, $side;
1208   printf "pi=%f\n", $side*(2**($iter+2));
1209
1210 It prints (without so many line breaks)
1211
1212   [/ [- [sqrt [+ 1 [** [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1]
1213                           [n 1]] 2]]] 1]
1214      [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1] [n 1]]]=0.198912
1215   pi=3.182598
1216
1217 The above module is very primitive.  It does not implement
1218 mutator methods (C<++>, C<-=> and so on), does not do deep copying
1219 (not required without mutators!), and implements only those arithmetic
1220 operations which are used in the example.
1221
1222 To implement most arithmetic operations is easy; one should just use
1223 the tables of operations, and change the code which fills %subr to
1224
1225   my %subr = ( 'n' => sub {$_[0]} );
1226   foreach my $op (split " ", $overload::ops{with_assign}) {
1227     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1228   }
1229   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1230   foreach my $op (split " ", "@overload::ops{ @bins }") {
1231     $subr{$op} = eval "sub {shift() $op shift()}";
1232   }
1233   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1234     print "defining `$op'\n";
1235     $subr{$op} = eval "sub {$op shift()}";
1236   }
1237
1238 Due to L<Calling Conventions for Mutators>, we do not need anything
1239 special to make C<+=> and friends work, except filling C<+=> entry of
1240 %subr, and defining a copy constructor (needed since Perl has no
1241 way to know that the implementation of C<'+='> does not mutate
1242 the argument, compare L<Copy Constructor>).
1243
1244 To implement a copy constructor, add C<< '=' => \&cpy >> to C<use overload>
1245 line, and code (this code assumes that mutators change things one level
1246 deep only, so recursive copying is not needed):
1247
1248   sub cpy {
1249     my $self = shift;
1250     bless [@$self], ref $self;
1251   }
1252
1253 To make C<++> and C<--> work, we need to implement actual mutators,
1254 either directly, or in C<nomethod>.  We continue to do things inside
1255 C<nomethod>, thus add
1256
1257     if ($meth eq '++' or $meth eq '--') {
1258       @$obj = ($meth, (bless [@$obj]), 1); # Avoid circular reference
1259       return $obj;
1260     }
1261
1262 after the first line of wrap().  This is not a most effective
1263 implementation, one may consider
1264
1265   sub inc { $_[0] = bless ['++', shift, 1]; }
1266
1267 instead.
1268
1269 As a final remark, note that one can fill %subr by
1270
1271   my %subr = ( 'n' => sub {$_[0]} );
1272   foreach my $op (split " ", $overload::ops{with_assign}) {
1273     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1274   }
1275   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1276   foreach my $op (split " ", "@overload::ops{ @bins }") {
1277     $subr{$op} = eval "sub {shift() $op shift()}";
1278   }
1279   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1280     $subr{$op} = eval "sub {$op shift()}";
1281   }
1282   $subr{'++'} = $subr{'+'};
1283   $subr{'--'} = $subr{'-'};
1284
1285 This finishes implementation of a primitive symbolic calculator in
1286 50 lines of Perl code.  Since the numeric values of subexpressions
1287 are not cached, the calculator is very slow.
1288
1289 Here is the answer for the exercise: In the case of str(), we need no
1290 explicit recursion since the overloaded C<.>-operator will fall back
1291 to an existing overloaded operator C<"">.  Overloaded arithmetic
1292 operators I<do not> fall back to numeric conversion if C<fallback> is
1293 not explicitly requested.  Thus without an explicit recursion num()
1294 would convert C<['+', $a, $b]> to C<$a + $b>, which would just rebuild
1295 the argument of num().
1296
1297 If you wonder why defaults for conversion are different for str() and
1298 num(), note how easy it was to write the symbolic calculator.  This
1299 simplicity is due to an appropriate choice of defaults.  One extra
1300 note: due to the explicit recursion num() is more fragile than sym():
1301 we need to explicitly check for the type of $a and $b.  If components
1302 $a and $b happen to be of some related type, this may lead to problems.
1303
1304 =head2 I<Really> symbolic calculator
1305
1306 One may wonder why we call the above calculator symbolic.  The reason
1307 is that the actual calculation of the value of expression is postponed
1308 until the value is I<used>.
1309
1310 To see it in action, add a method
1311
1312   sub STORE {
1313     my $obj = shift;
1314     $#$obj = 1;
1315     @$obj->[0,1] = ('=', shift);
1316   }
1317
1318 to the package C<symbolic>.  After this change one can do
1319
1320   my $a = new symbolic 3;
1321   my $b = new symbolic 4;
1322   my $c = sqrt($a**2 + $b**2);
1323
1324 and the numeric value of $c becomes 5.  However, after calling
1325
1326   $a->STORE(12);  $b->STORE(5);
1327
1328 the numeric value of $c becomes 13.  There is no doubt now that the module
1329 symbolic provides a I<symbolic> calculator indeed.
1330
1331 To hide the rough edges under the hood, provide a tie()d interface to the
1332 package C<symbolic> (compare with L<Metaphor clash>).  Add methods
1333
1334   sub TIESCALAR { my $pack = shift; $pack->new(@_) }
1335   sub FETCH { shift }
1336   sub nop {  }          # Around a bug
1337
1338 (the bug is described in L<"BUGS">).  One can use this new interface as
1339
1340   tie $a, 'symbolic', 3;
1341   tie $b, 'symbolic', 4;
1342   $a->nop;  $b->nop;    # Around a bug
1343
1344   my $c = sqrt($a**2 + $b**2);
1345
1346 Now numeric value of $c is 5.  After C<$a = 12; $b = 5> the numeric value
1347 of $c becomes 13.  To insulate the user of the module add a method
1348
1349   sub vars { my $p = shift; tie($_, $p), $_->nop foreach @_; }
1350
1351 Now
1352
1353   my ($a, $b);
1354   symbolic->vars($a, $b);
1355   my $c = sqrt($a**2 + $b**2);
1356
1357   $a = 3; $b = 4;
1358   printf "c5  %s=%f\n", $c, $c;
1359
1360   $a = 12; $b = 5;
1361   printf "c13  %s=%f\n", $c, $c;
1362
1363 shows that the numeric value of $c follows changes to the values of $a
1364 and $b.
1365
1366 =head1 AUTHOR
1367
1368 Ilya Zakharevich E<lt>F<ilya@math.mps.ohio-state.edu>E<gt>.
1369
1370 =head1 DIAGNOSTICS
1371
1372 When Perl is run with the B<-Do> switch or its equivalent, overloading
1373 induces diagnostic messages.
1374
1375 Using the C<m> command of Perl debugger (see L<perldebug>) one can
1376 deduce which operations are overloaded (and which ancestor triggers
1377 this overloading). Say, if C<eq> is overloaded, then the method C<(eq>
1378 is shown by debugger. The method C<()> corresponds to the C<fallback>
1379 key (in fact a presence of this method shows that this package has
1380 overloading enabled, and it is what is used by the C<Overloaded>
1381 function of module C<overload>).
1382
1383 The module might issue the following warnings:
1384
1385 =over 4
1386
1387 =item Odd number of arguments for overload::constant
1388
1389 (W) The call to overload::constant contained an odd number of arguments.
1390 The arguments should come in pairs.
1391
1392 =item `%s' is not an overloadable type
1393
1394 (W) You tried to overload a constant type the overload package is unaware of.
1395
1396 =item `%s' is not a code reference
1397
1398 (W) The second (fourth, sixth, ...) argument of overload::constant needs
1399 to be a code reference. Either an anonymous subroutine, or a reference
1400 to a subroutine.
1401
1402 =back
1403
1404 =head1 BUGS
1405
1406 Because it is used for overloading, the per-package hash %OVERLOAD now
1407 has a special meaning in Perl. The symbol table is filled with names
1408 looking like line-noise.
1409
1410 For the purpose of inheritance every overloaded package behaves as if
1411 C<fallback> is present (possibly undefined). This may create
1412 interesting effects if some package is not overloaded, but inherits
1413 from two overloaded packages.
1414
1415 Relation between overloading and tie()ing is broken.  Overloading is
1416 triggered or not basing on the I<previous> class of tie()d value.
1417
1418 This happens because the presence of overloading is checked too early,
1419 before any tie()d access is attempted.  If the FETCH()ed class of the
1420 tie()d value does not change, a simple workaround is to access the value
1421 immediately after tie()ing, so that after this call the I<previous> class
1422 coincides with the current one.
1423
1424 B<Needed:> a way to fix this without a speed penalty.
1425
1426 Barewords are not covered by overloaded string constants.
1427
1428 This document is confusing.  There are grammos and misleading language
1429 used in places.  It would seem a total rewrite is needed.
1430
1431 =cut
1432