3 perldata - Perl data types
8 X<variable, name> X<variable name> X<data type> X<type>
10 Perl has three built-in data types: scalars, arrays of scalars, and
11 associative arrays of scalars, known as "hashes". A scalar is a
12 single string (of any size, limited only by the available memory),
13 number, or a reference to something (which will be discussed
14 in L<perlref>). Normal arrays are ordered lists of scalars indexed
15 by number, starting with 0. Hashes are unordered collections of scalar
16 values indexed by their associated string key.
18 Values are usually referred to by name, or through a named reference.
19 The first character of the name tells you to what sort of data
20 structure it refers. The rest of the name tells you the particular
21 value to which it refers. Usually this name is a single I<identifier>,
22 that is, a string beginning with a letter or underscore, and
23 containing letters, underscores, and digits. In some cases, it may
24 be a chain of identifiers, separated by C<::> (or by the slightly
25 archaic C<'>); all but the last are interpreted as names of packages,
26 to locate the namespace in which to look up the final identifier
27 (see L<perlmod/Packages> for details). For a more in-depth discussion
28 on identifiers, see L<Identifier parsing>. It's possible to
29 substitute for a simple identifier, an expression that produces a reference
30 to the value at runtime. This is described in more detail below
34 Perl also has its own built-in variables whose names don't follow
35 these rules. They have strange names so they don't accidentally
36 collide with one of your normal variables. Strings that match
37 parenthesized parts of a regular expression are saved under names
38 containing only digits after the C<$> (see L<perlop> and L<perlre>).
39 In addition, several special variables that provide windows into
40 the inner working of Perl have names containing punctuation characters
41 and control characters. These are documented in L<perlvar>.
44 Scalar values are always named with '$', even when referring to a
45 scalar that is part of an array or a hash. The '$' symbol works
46 semantically like the English word "the" in that it indicates a
47 single value is expected.
50 $days # the simple scalar value "days"
51 $days[28] # the 29th element of array @days
52 $days{'Feb'} # the 'Feb' value from hash %days
53 $#days # the last index of array @days
55 Entire arrays (and slices of arrays and hashes) are denoted by '@',
56 which works much as the word "these" or "those" does in English,
57 in that it indicates multiple values are expected.
60 @days # ($days[0], $days[1],... $days[n])
61 @days[3,4,5] # same as ($days[3],$days[4],$days[5])
62 @days{'a','c'} # same as ($days{'a'},$days{'c'})
64 Entire hashes are denoted by '%':
67 %days # (key1, val1, key2, val2 ...)
69 In addition, subroutines are named with an initial '&', though this
70 is optional when unambiguous, just as the word "do" is often redundant
71 in English. Symbol table entries can be named with an initial '*',
72 but you don't really care about that yet (if ever :-).
74 Every variable type has its own namespace, as do several
75 non-variable identifiers. This means that you can, without fear
76 of conflict, use the same name for a scalar variable, an array, or
77 a hash--or, for that matter, for a filehandle, a directory handle, a
78 subroutine name, a format name, or a label. This means that $foo
79 and @foo are two different variables. It also means that C<$foo[1]>
80 is a part of @foo, not a part of $foo. This may seem a bit weird,
81 but that's okay, because it is weird.
84 Because variable references always start with '$', '@', or '%', the
85 "reserved" words aren't in fact reserved with respect to variable
86 names. They I<are> reserved with respect to labels and filehandles,
87 however, which don't have an initial special character. You can't
88 have a filehandle named "log", for instance. Hint: you could say
89 C<open(LOG,'logfile')> rather than C<open(log,'logfile')>. Using
90 uppercase filehandles also improves readability and protects you
91 from conflict with future reserved words. Case I<is> significant--"FOO",
92 "Foo", and "foo" are all different names. Names that start with a
93 letter or underscore may also contain digits and underscores.
94 X<identifier, case sensitivity>
97 It is possible to replace such an alphanumeric name with an expression
98 that returns a reference to the appropriate type. For a description
99 of this, see L<perlref>.
101 Names that start with a digit may contain only more digits. Names
102 that do not start with a letter, underscore, digit or a caret (i.e.
103 a control character) are limited to one character, e.g., C<$%> or
104 C<$$>. (Most of these one character names have a predefined
105 significance to Perl. For instance, C<$$> is the current process
108 =head2 Identifier parsing
111 Up until Perl 5.18, the actual rules of what a valid identifier
112 was were a bit fuzzy. However, in general, anything defined here should
113 work on previous versions of Perl, while the opposite -- edge cases
114 that work in previous versions, but aren't defined here -- probably
115 won't work on newer versions.
116 As an important side note, please note that the following only applies
117 to bareword identifiers as found in Perl source code, not identifiers
118 introduced through symbolic references, which have much fewer
120 If working under the effect of the C<use utf8;> pragma, the following
123 / (?[ ( \p{Word} & \p{XID_Start} ) + [_] ]) \p{XID_Continue}* /x
125 If not under C<use utf8>, the source is treated as ASCII + 128 extra
126 controls, and identifiers should match
128 / (?aa) (?!\d) \w+ /x
130 That is, any word character in the ASCII range, as long as the first
131 character is not a digit.
133 There are two package separators in Perl: A double colon (C<::>) and a single
134 quote (C<'>). Normal identifiers can start or end with a double colon, and
135 can contain several parts delimited by double colons.
136 Single quotes have similar rules, but with the exception that they are not
137 legal at the end of an identifier: That is, C<$'foo> and C<$foo'bar> are
138 legal, but C<$foo'bar'> are not.
141 Finally, if the identifier is preceded by a sigil --
142 More so, normal identifiers can start or end with any number
143 of double colons (::), and can contain several parts delimited
145 And additionally, if the identifier is preceded by a sigil --
146 that is, if the identifier is part of a variable name -- it
147 may optionally be enclosed in braces.
149 While you can mix double colons with singles quotes, the quotes must come
150 after the colons: C<$::::'foo> and C<$foo::'bar> are legal, but C<$::'::foo>
151 and C<$foo'::bar> are not.
153 Put together, a grammar to match a basic identifier becomes
160 (?&normal_identifier)
161 | \{ \s* (?&normal_identifier) \s* \}
164 (?<normal_identifier>
167 (?: (?= (?: :: )+ '? | (?: :: )* ' ) (?&normal_identifier) )?
172 (?(?{ (caller(0))[8] & $utf8::hint_bits })
173 (?&Perl_XIDS) \p{XID_Continue}*
177 (?<sigil> [&*\$\@\%])
178 (?<Perl_XIDS> (?[ ( \p{Word} & \p{XID_Start} ) + [_] ]) )
182 Meanwhile, special identifiers don't follow the above rules; For the most
183 part, all of the identifiers in this category have a special meaning given
184 by Perl. Because they have special parsing rules, these generally can't be
185 fully-qualified. They come in four forms:
189 =item A sigil, followed solely by digits matching \p{POSIX_Digit}, like C<$0>,
192 =item A sigil, followed by either a caret and a single POSIX uppercase letter,
193 like C<$^V> or C<$^W>, or a sigil followed by a literal control character
194 matching the C<\p{POSIX_Cntrl}> property. Due to a historical oddity, if not
195 running under C<use utf8>, the 128 extra controls in the C<[0x80-0xff]> range
196 may also be used in length one variables.
198 =item Similar to the above, a sigil, followed by bareword text in brackets,
199 where the first character is either a caret followed by an uppercase letter,
200 or a literal control, like C<${^GLOBAL_PHASE}> or C<${\7LOBAL_PHASE}>.
202 =item A sigil followed by a single character matching the C<\p{POSIX_Punct}>
203 property, like C<$!> or C<%+>.
208 X<context> X<scalar context> X<list context>
210 The interpretation of operations and values in Perl sometimes depends
211 on the requirements of the context around the operation or value.
212 There are two major contexts: list and scalar. Certain operations
213 return list values in contexts wanting a list, and scalar values
214 otherwise. If this is true of an operation it will be mentioned in
215 the documentation for that operation. In other words, Perl overloads
216 certain operations based on whether the expected return value is
217 singular or plural. Some words in English work this way, like "fish"
220 In a reciprocal fashion, an operation provides either a scalar or a
221 list context to each of its arguments. For example, if you say
225 the integer operation provides scalar context for the <>
226 operator, which responds by reading one line from STDIN and passing it
227 back to the integer operation, which will then find the integer value
228 of that line and return that. If, on the other hand, you say
232 then the sort operation provides list context for <>, which
233 will proceed to read every line available up to the end of file, and
234 pass that list of lines back to the sort routine, which will then
235 sort those lines and return them as a list to whatever the context
238 Assignment is a little bit special in that it uses its left argument
239 to determine the context for the right argument. Assignment to a
240 scalar evaluates the right-hand side in scalar context, while
241 assignment to an array or hash evaluates the righthand side in list
242 context. Assignment to a list (or slice, which is just a list
243 anyway) also evaluates the right-hand side in list context.
245 When you use the C<use warnings> pragma or Perl's B<-w> command-line
246 option, you may see warnings
247 about useless uses of constants or functions in "void context".
248 Void context just means the value has been discarded, such as a
249 statement containing only C<"fred";> or C<getpwuid(0);>. It still
250 counts as scalar context for functions that care whether or not
251 they're being called in list context.
253 User-defined subroutines may choose to care whether they are being
254 called in a void, scalar, or list context. Most subroutines do not
255 need to bother, though. That's because both scalars and lists are
256 automatically interpolated into lists. See L<perlfunc/wantarray>
257 for how you would dynamically discern your function's calling
261 X<scalar> X<number> X<string> X<reference>
263 All data in Perl is a scalar, an array of scalars, or a hash of
264 scalars. A scalar may contain one single value in any of three
265 different flavors: a number, a string, or a reference. In general,
266 conversion from one form to another is transparent. Although a
267 scalar may not directly hold multiple values, it may contain a
268 reference to an array or hash which in turn contains multiple values.
270 Scalars aren't necessarily one thing or another. There's no place
271 to declare a scalar variable to be of type "string", type "number",
272 type "reference", or anything else. Because of the automatic
273 conversion of scalars, operations that return scalars don't need
274 to care (and in fact, cannot care) whether their caller is looking
275 for a string, a number, or a reference. Perl is a contextually
276 polymorphic language whose scalars can be strings, numbers, or
277 references (which includes objects). Although strings and numbers
278 are considered pretty much the same thing for nearly all purposes,
279 references are strongly-typed, uncastable pointers with builtin
280 reference-counting and destructor invocation.
282 A scalar value is interpreted as FALSE in the Boolean sense
283 if it is undefined, the null string or the number 0 (or its
284 string equivalent, "0"), and TRUE if it is anything else. The
285 Boolean context is just a special kind of scalar context where no
286 conversion to a string or a number is ever performed.
287 X<boolean> X<bool> X<true> X<false> X<truth>
289 There are actually two varieties of null strings (sometimes referred
290 to as "empty" strings), a defined one and an undefined one. The
291 defined version is just a string of length zero, such as C<"">.
292 The undefined version is the value that indicates that there is
293 no real value for something, such as when there was an error, or
294 at end of file, or when you refer to an uninitialized variable or
295 element of an array or hash. Although in early versions of Perl,
296 an undefined scalar could become defined when first used in a
297 place expecting a defined value, this no longer happens except for
298 rare cases of autovivification as explained in L<perlref>. You can
299 use the defined() operator to determine whether a scalar value is
300 defined (this has no meaning on arrays or hashes), and the undef()
301 operator to produce an undefined value.
302 X<defined> X<undefined> X<undef> X<null> X<string, null>
304 To find out whether a given string is a valid non-zero number, it's
305 sometimes enough to test it against both numeric 0 and also lexical
306 "0" (although this will cause noises if warnings are on). That's
307 because strings that aren't numbers count as 0, just as they do in B<awk>:
309 if ($str == 0 && $str ne "0") {
310 warn "That doesn't look like a number";
313 That method may be best because otherwise you won't treat IEEE
314 notations like C<NaN> or C<Infinity> properly. At other times, you
315 might prefer to determine whether string data can be used numerically
316 by calling the POSIX::strtod() function or by inspecting your string
317 with a regular expression (as documented in L<perlre>).
319 warn "has nondigits" if /\D/;
320 warn "not a natural number" unless /^\d+$/; # rejects -3
321 warn "not an integer" unless /^-?\d+$/; # rejects +3
322 warn "not an integer" unless /^[+-]?\d+$/;
323 warn "not a decimal number" unless /^-?\d+\.?\d*$/; # rejects .2
324 warn "not a decimal number" unless /^-?(?:\d+(?:\.\d*)?|\.\d+)$/;
326 unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/;
328 The length of an array is a scalar value. You may find the length
329 of array @days by evaluating C<$#days>, as in B<csh>. However, this
330 isn't the length of the array; it's the subscript of the last element,
331 which is a different value since there is ordinarily a 0th element.
332 Assigning to C<$#days> actually changes the length of the array.
333 Shortening an array this way destroys intervening values. Lengthening
334 an array that was previously shortened does not recover values
335 that were in those elements.
336 X<$#> X<array, length>
338 You can also gain some minuscule measure of efficiency by pre-extending
339 an array that is going to get big. You can also extend an array
340 by assigning to an element that is off the end of the array. You
341 can truncate an array down to nothing by assigning the null list
342 () to it. The following are equivalent:
347 If you evaluate an array in scalar context, it returns the length
348 of the array. (Note that this is not true of lists, which return
349 the last value, like the C comma operator, nor of built-in functions,
350 which return whatever they feel like returning.) The following is
354 scalar(@whatever) == $#whatever + 1;
356 Some programmers choose to use an explicit conversion so as to
357 leave nothing to doubt:
359 $element_count = scalar(@whatever);
361 If you evaluate a hash in scalar context, it returns false if the
362 hash is empty. If there are any key/value pairs, it returns true;
363 more precisely, the value returned is a string consisting of the
364 number of used buckets and the number of allocated buckets, separated
365 by a slash. This is pretty much useful only to find out whether
366 Perl's internal hashing algorithm is performing poorly on your data
367 set. For example, you stick 10,000 things in a hash, but evaluating
368 %HASH in scalar context reveals C<"1/16">, which means only one out
369 of sixteen buckets has been touched, and presumably contains all
370 10,000 of your items. This isn't supposed to happen. If a tied hash
371 is evaluated in scalar context, the C<SCALAR> method is called (with a
372 fallback to C<FIRSTKEY>).
373 X<hash, scalar context> X<hash, bucket> X<bucket>
375 You can preallocate space for a hash by assigning to the keys() function.
376 This rounds up the allocated buckets to the next power of two:
378 keys(%users) = 1000; # allocate 1024 buckets
380 =head2 Scalar value constructors
381 X<scalar, literal> X<scalar, constant>
383 Numeric literals are specified in any of the following floating point or
388 .23E-10 # a very small number
389 3.14_15_92 # a very important number
390 4_294_967_296 # underscore for legibility
392 0xdead_beef # more hex
393 0377 # octal (only numbers, begins with 0)
396 You are allowed to use underscores (underbars) in numeric literals
397 between digits for legibility (but not multiple underscores in a row:
398 C<23__500> is not legal; C<23_500> is).
399 You could, for example, group binary
400 digits by threes (as for a Unix-style mode argument such as 0b110_100_100)
401 or by fours (to represent nibbles, as in 0b1010_0110) or in other groups.
404 String literals are usually delimited by either single or double
405 quotes. They work much like quotes in the standard Unix shells:
406 double-quoted string literals are subject to backslash and variable
407 substitution; single-quoted strings are not (except for C<\'> and
408 C<\\>). The usual C-style backslash rules apply for making
409 characters such as newline, tab, etc., as well as some more exotic
410 forms. See L<perlop/"Quote and Quote-like Operators"> for a list.
413 Hexadecimal, octal, or binary, representations in string literals
414 (e.g. '0xff') are not automatically converted to their integer
415 representation. The hex() and oct() functions make these conversions
416 for you. See L<perlfunc/hex> and L<perlfunc/oct> for more details.
418 You can also embed newlines directly in your strings, i.e., they can end
419 on a different line than they begin. This is nice, but if you forget
420 your trailing quote, the error will not be reported until Perl finds
421 another line containing the quote character, which may be much further
422 on in the script. Variable substitution inside strings is limited to
423 scalar variables, arrays, and array or hash slices. (In other words,
424 names beginning with $ or @, followed by an optional bracketed
425 expression as a subscript.) The following code segment prints out "The
429 $Price = '$100'; # not interpolated
430 print "The price is $Price.\n"; # interpolated
432 There is no double interpolation in Perl, so the C<$100> is left as is.
434 By default floating point numbers substituted inside strings use the
435 dot (".") as the decimal separator. If C<use locale> is in effect,
436 and POSIX::setlocale() has been called, the character used for the
437 decimal separator is affected by the LC_NUMERIC locale.
438 See L<perllocale> and L<POSIX>.
440 As in some shells, you can enclose the variable name in braces to
441 disambiguate it from following alphanumerics (and underscores).
443 this when interpolating a variable into a string to separate the
444 variable name from a following double-colon or an apostrophe, since
445 these would be otherwise treated as a package separator:
449 print PASSWD "${who}::0:0:Superuser:/:/bin/perl\n";
450 print "We use ${who}speak when ${who}'s here.\n";
452 Without the braces, Perl would have looked for a $whospeak, a
453 C<$who::0>, and a C<$who's> variable. The last two would be the
454 $0 and the $s variables in the (presumably) non-existent package
457 In fact, a simple identifier within such curlies is forced to be
458 a string, and likewise within a hash subscript. Neither need
459 quoting. Our earlier example, C<$days{'Feb'}> can be written as
460 C<$days{Feb}> and the quotes will be assumed automatically. But
461 anything more complicated in the subscript will be interpreted as an
462 expression. This means for example that C<$version{2.0}++> is
463 equivalent to C<$version{2}++>, not to C<$version{'2.0'}++>.
465 =head3 Version Strings
466 X<version string> X<vstring> X<v-string>
468 A literal of the form C<v1.20.300.4000> is parsed as a string composed
469 of characters with the specified ordinals. This form, known as
470 v-strings, provides an alternative, more readable way to construct
471 strings, rather than use the somewhat less readable interpolation form
472 C<"\x{1}\x{14}\x{12c}\x{fa0}">. This is useful for representing
473 Unicode strings, and for comparing version "numbers" using the string
474 comparison operators, C<cmp>, C<gt>, C<lt> etc. If there are two or
475 more dots in the literal, the leading C<v> may be omitted.
477 print v9786; # prints SMILEY, "\x{263a}"
478 print v102.111.111; # prints "foo"
479 print 102.111.111; # same
481 Such literals are accepted by both C<require> and C<use> for
482 doing a version check. Note that using the v-strings for IPv4
483 addresses is not portable unless you also use the
484 inet_aton()/inet_ntoa() routines of the Socket package.
486 Note that since Perl 5.8.1 the single-number v-strings (like C<v65>)
487 are not v-strings before the C<< => >> operator (which is usually used
488 to separate a hash key from a hash value); instead they are interpreted
489 as literal strings ('v65'). They were v-strings from Perl 5.6.0 to
490 Perl 5.8.0, but that caused more confusion and breakage than good.
491 Multi-number v-strings like C<v65.66> and C<65.66.67> continue to
494 =head3 Special Literals
495 X<special literal> X<__END__> X<__DATA__> X<END> X<DATA>
496 X<end> X<data> X<^D> X<^Z>
498 The special literals __FILE__, __LINE__, and __PACKAGE__
499 represent the current filename, line number, and package name at that
500 point in your program. __SUB__ gives a reference to the current
501 subroutine. They may be used only as separate tokens; they
502 will not be interpolated into strings. If there is no current package
503 (due to an empty C<package;> directive), __PACKAGE__ is the undefined
504 value. (But the empty C<package;> is no longer supported, as of version
505 5.10.) Outside of a subroutine, __SUB__ is the undefined value. __SUB__
506 is only available in 5.16 or higher, and only with a C<use v5.16> or
507 C<use feature "current_sub"> declaration.
508 X<__FILE__> X<__LINE__> X<__PACKAGE__> X<__SUB__>
509 X<line> X<file> X<package>
511 The two control characters ^D and ^Z, and the tokens __END__ and __DATA__
512 may be used to indicate the logical end of the script before the actual
513 end of file. Any following text is ignored.
515 Text after __DATA__ may be read via the filehandle C<PACKNAME::DATA>,
516 where C<PACKNAME> is the package that was current when the __DATA__
517 token was encountered. The filehandle is left open pointing to the
518 line after __DATA__. The program should C<close DATA> when it is done
519 reading from it. (Leaving it open leaks filehandles if the module is
520 reloaded for any reason, so it's a safer practice to close it.) For
521 compatibility with older scripts written before __DATA__ was
522 introduced, __END__ behaves like __DATA__ in the top level script (but
523 not in files loaded with C<require> or C<do>) and leaves the remaining
524 contents of the file accessible via C<main::DATA>.
526 See L<SelfLoader> for more description of __DATA__, and
527 an example of its use. Note that you cannot read from the DATA
528 filehandle in a BEGIN block: the BEGIN block is executed as soon
529 as it is seen (during compilation), at which point the corresponding
530 __DATA__ (or __END__) token has not yet been seen.
535 A word that has no other interpretation in the grammar will
536 be treated as if it were a quoted string. These are known as
537 "barewords". As with filehandles and labels, a bareword that consists
538 entirely of lowercase letters risks conflict with future reserved
539 words, and if you use the C<use warnings> pragma or the B<-w> switch,
540 Perl will warn you about any such words. Perl limits barewords (like
541 identifiers) to about 250 characters. Future versions of Perl are likely
542 to eliminate these arbitrary limitations.
544 Some people may wish to outlaw barewords entirely. If you
549 then any bareword that would NOT be interpreted as a subroutine call
550 produces a compile-time error instead. The restriction lasts to the
551 end of the enclosing block. An inner block may countermand this
552 by saying C<no strict 'subs'>.
554 =head3 Array Interpolation
555 X<array, interpolation> X<interpolation, array> X<$">
557 Arrays and slices are interpolated into double-quoted strings
558 by joining the elements with the delimiter specified in the C<$">
559 variable (C<$LIST_SEPARATOR> if "use English;" is specified),
560 space by default. The following are equivalent:
562 $temp = join($", @ARGV);
567 Within search patterns (which also undergo double-quotish substitution)
568 there is an unfortunate ambiguity: Is C</$foo[bar]/> to be interpreted as
569 C</${foo}[bar]/> (where C<[bar]> is a character class for the regular
570 expression) or as C</${foo[bar]}/> (where C<[bar]> is the subscript to array
571 @foo)? If @foo doesn't otherwise exist, then it's obviously a
572 character class. If @foo exists, Perl takes a good guess about C<[bar]>,
573 and is almost always right. If it does guess wrong, or if you're just
574 plain paranoid, you can force the correct interpretation with curly
577 If you're looking for the information on how to use here-documents,
578 which used to be here, that's been moved to
579 L<perlop/Quote and Quote-like Operators>.
581 =head2 List value constructors
584 List values are denoted by separating individual values by commas
585 (and enclosing the list in parentheses where precedence requires it):
589 In a context not requiring a list value, the value of what appears
590 to be a list literal is simply the value of the final element, as
591 with the C comma operator. For example,
593 @foo = ('cc', '-E', $bar);
595 assigns the entire list value to array @foo, but
597 $foo = ('cc', '-E', $bar);
599 assigns the value of variable $bar to the scalar variable $foo.
600 Note that the value of an actual array in scalar context is the
601 length of the array; the following assigns the value 3 to $foo:
603 @foo = ('cc', '-E', $bar);
604 $foo = @foo; # $foo gets 3
606 You may have an optional comma before the closing parenthesis of a
607 list literal, so that you can say:
615 To use a here-document to assign an array, one line per element,
616 you might use an approach like this:
618 @sauces = <<End_Lines =~ m/(\S.*\S)/g;
626 LISTs do automatic interpolation of sublists. That is, when a LIST is
627 evaluated, each element of the list is evaluated in list context, and
628 the resulting list value is interpolated into LIST just as if each
629 individual element were a member of LIST. Thus arrays and hashes lose their
630 identity in a LIST--the list
632 (@foo,@bar,&SomeSub,%glarch)
634 contains all the elements of @foo followed by all the elements of @bar,
635 followed by all the elements returned by the subroutine named SomeSub
636 called in list context, followed by the key/value pairs of %glarch.
637 To make a list reference that does I<NOT> interpolate, see L<perlref>.
639 The null list is represented by (). Interpolating it in a list
640 has no effect. Thus ((),(),()) is equivalent to (). Similarly,
641 interpolating an array with no elements is the same as if no
642 array had been interpolated at that point.
644 This interpolation combines with the facts that the opening
645 and closing parentheses are optional (except when necessary for
646 precedence) and lists may end with an optional comma to mean that
647 multiple commas within lists are legal syntax. The list C<1,,3> is a
648 concatenation of two lists, C<1,> and C<3>, the first of which ends
649 with that optional comma. C<1,,3> is C<(1,),(3)> is C<1,3> (And
650 similarly for C<1,,,3> is C<(1,),(,),3> is C<1,3> and so on.) Not that
651 we'd advise you to use this obfuscation.
653 A list value may also be subscripted like a normal array. You must
654 put the list in parentheses to avoid ambiguity. For example:
656 # Stat returns list value.
657 $time = (stat($file))[8];
660 $time = stat($file)[8]; # OOPS, FORGOT PARENTHESES
663 $hexdigit = ('a','b','c','d','e','f')[$digit-10];
665 # A "reverse comma operator".
666 return (pop(@foo),pop(@foo))[0];
668 Lists may be assigned to only when each element of the list
669 is itself legal to assign to:
671 ($a, $b, $c) = (1, 2, 3);
673 ($map{'red'}, $map{'blue'}, $map{'green'}) = (0x00f, 0x0f0, 0xf00);
675 An exception to this is that you may assign to C<undef> in a list.
676 This is useful for throwing away some of the return values of a
679 ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
681 List assignment in scalar context returns the number of elements
682 produced by the expression on the right side of the assignment:
684 $x = (($foo,$bar) = (3,2,1)); # set $x to 3, not 2
685 $x = (($foo,$bar) = f()); # set $x to f()'s return count
687 This is handy when you want to do a list assignment in a Boolean
688 context, because most list functions return a null list when finished,
689 which when assigned produces a 0, which is interpreted as FALSE.
691 It's also the source of a useful idiom for executing a function or
692 performing an operation in list context and then counting the number of
693 return values, by assigning to an empty list and then using that
694 assignment in scalar context. For example, this code:
696 $count = () = $string =~ /\d+/g;
698 will place into $count the number of digit groups found in $string.
699 This happens because the pattern match is in list context (since it
700 is being assigned to the empty list), and will therefore return a list
701 of all matching parts of the string. The list assignment in scalar
702 context will translate that into the number of elements (here, the
703 number of times the pattern matched) and assign that to $count. Note
706 $count = $string =~ /\d+/g;
708 would not have worked, since a pattern match in scalar context will
709 only return true or false, rather than a count of matches.
711 The final element of a list assignment may be an array or a hash:
713 ($a, $b, @rest) = split;
714 my($a, $b, %rest) = @_;
716 You can actually put an array or hash anywhere in the list, but the first one
717 in the list will soak up all the values, and anything after it will become
718 undefined. This may be useful in a my() or local().
720 A hash can be initialized using a literal list holding pairs of
721 items to be interpreted as a key and a value:
723 # same as map assignment above
724 %map = ('red',0x00f,'blue',0x0f0,'green',0xf00);
726 While literal lists and named arrays are often interchangeable, that's
727 not the case for hashes. Just because you can subscript a list value like
728 a normal array does not mean that you can subscript a list value as a
729 hash. Likewise, hashes included as parts of other lists (including
730 parameters lists and return lists from functions) always flatten out into
731 key/value pairs. That's why it's good to use references sometimes.
733 It is often more readable to use the C<< => >> operator between key/value
734 pairs. The C<< => >> operator is mostly just a more visually distinctive
735 synonym for a comma, but it also arranges for its left-hand operand to be
736 interpreted as a string if it's a bareword that would be a legal simple
737 identifier. C<< => >> doesn't quote compound identifiers, that contain
738 double colons. This makes it nice for initializing hashes:
746 or for initializing hash references to be used as records:
749 witch => 'Mable the Merciless',
750 cat => 'Fluffy the Ferocious',
751 date => '10/31/1776',
754 or for using call-by-named-parameter to complicated functions:
756 $field = $query->radio_group(
757 name => 'group_name',
758 values => ['eenie','meenie','minie'],
764 Note that just because a hash is initialized in that order doesn't
765 mean that it comes out in that order. See L<perlfunc/sort> for examples
766 of how to arrange for an output ordering.
768 If a key appears more than once in the initializer list of a hash, the last
775 color => [0xDF, 0xFF, 0x00],
782 color => [0xDF, 0xFF, 0x00],
786 This can be used to provide overridable configuration defaults:
788 # values in %args take priority over %config_defaults
789 %config = (%config_defaults, %args);
793 An array can be accessed one scalar at a
794 time by specifying a dollar sign (C<$>), then the
795 name of the array (without the leading C<@>), then the subscript inside
796 square brackets. For example:
798 @myarray = (5, 50, 500, 5000);
799 print "The Third Element is", $myarray[2], "\n";
801 The array indices start with 0. A negative subscript retrieves its
802 value from the end. In our example, C<$myarray[-1]> would have been
803 5000, and C<$myarray[-2]> would have been 500.
805 Hash subscripts are similar, only instead of square brackets curly brackets
806 are used. For example:
811 "Einstein" => "Albert",
812 "Darwin" => "Charles",
813 "Feynman" => "Richard",
816 print "Darwin's First Name is ", $scientists{"Darwin"}, "\n";
818 You can also subscript a list to get a single element from it:
820 $dir = (getpwnam("daemon"))[7];
822 =head2 Multi-dimensional array emulation
824 Multidimensional arrays may be emulated by subscripting a hash with a
825 list. The elements of the list are joined with the subscript separator
832 $foo{join($;, $a, $b, $c)}
834 The default subscript separator is "\034", the same as SUBSEP in B<awk>.
837 X<slice> X<array, slice> X<hash, slice>
839 A slice accesses several elements of a list, an array, or a hash
840 simultaneously using a list of subscripts. It's more convenient
841 than writing out the individual elements as a list of separate
844 ($him, $her) = @folks[0,-1]; # array slice
845 @them = @folks[0 .. 3]; # array slice
846 ($who, $home) = @ENV{"USER", "HOME"}; # hash slice
847 ($uid, $dir) = (getpwnam("daemon"))[2,7]; # list slice
849 Since you can assign to a list of variables, you can also assign to
850 an array or hash slice.
852 @days[3..5] = qw/Wed Thu Fri/;
853 @colors{'red','blue','green'}
854 = (0xff0000, 0x0000ff, 0x00ff00);
855 @folks[0, -1] = @folks[-1, 0];
857 The previous assignments are exactly equivalent to
859 ($days[3], $days[4], $days[5]) = qw/Wed Thu Fri/;
860 ($colors{'red'}, $colors{'blue'}, $colors{'green'})
861 = (0xff0000, 0x0000ff, 0x00ff00);
862 ($folks[0], $folks[-1]) = ($folks[-1], $folks[0]);
864 Since changing a slice changes the original array or hash that it's
865 slicing, a C<foreach> construct will alter some--or even all--of the
866 values of the array or hash.
868 foreach (@array[ 4 .. 10 ]) { s/peter/paul/ }
870 foreach (@hash{qw[key1 key2]}) {
871 s/^\s+//; # trim leading whitespace
872 s/\s+$//; # trim trailing whitespace
873 s/(\w+)/\u\L$1/g; # "titlecase" words
876 A slice of an empty list is still an empty list. Thus:
878 @a = ()[1,0]; # @a has no elements
879 @b = (@a)[0,1]; # @b has no elements
883 @a = (1)[1,0]; # @a has two elements
884 @b = (1,undef)[1,0,2]; # @b has three elements
886 More generally, a slice yields the empty list if it indexes only
887 beyond the end of a list:
889 @a = (1)[ 1,2]; # @a has no elements
890 @b = (1)[0,1,2]; # @b has three elements
892 This makes it easy to write loops that terminate when a null list
895 while ( ($home, $user) = (getpwent)[7,0]) {
896 printf "%-8s %s\n", $user, $home;
899 As noted earlier in this document, the scalar sense of list assignment
900 is the number of elements on the right-hand side of the assignment.
901 The null list contains no elements, so when the password file is
902 exhausted, the result is 0, not 2.
904 Slices in scalar context return the last item of the slice.
906 @a = qw/first second third/;
907 %h = (first => 'A', second => 'B');
908 $t = @a[0, 1]; # $t is now 'second'
909 $u = @h{'first', 'second'}; # $u is now 'B'
911 If you're confused about why you use an '@' there on a hash slice
912 instead of a '%', think of it like this. The type of bracket (square
913 or curly) governs whether it's an array or a hash being looked at.
914 On the other hand, the leading symbol ('$' or '@') on the array or
915 hash indicates whether you are getting back a singular value (a
916 scalar) or a plural one (a list).
918 =head2 Typeglobs and Filehandles
919 X<typeglob> X<filehandle> X<*>
921 Perl uses an internal type called a I<typeglob> to hold an entire
922 symbol table entry. The type prefix of a typeglob is a C<*>, because
923 it represents all types. This used to be the preferred way to
924 pass arrays and hashes by reference into a function, but now that
925 we have real references, this is seldom needed.
927 The main use of typeglobs in modern Perl is create symbol table aliases.
932 makes $this an alias for $that, @this an alias for @that, %this an alias
933 for %that, &this an alias for &that, etc. Much safer is to use a reference.
936 local *Here::blue = \$There::green;
938 temporarily makes $Here::blue an alias for $There::green, but doesn't
939 make @Here::blue an alias for @There::green, or %Here::blue an alias for
940 %There::green, etc. See L<perlmod/"Symbol Tables"> for more examples
941 of this. Strange though this may seem, this is the basis for the whole
942 module import/export system.
944 Another use for typeglobs is to pass filehandles into a function or
945 to create new filehandles. If you need to use a typeglob to save away
946 a filehandle, do it this way:
950 or perhaps as a real reference, like this:
954 See L<perlsub> for examples of using these as indirect filehandles
957 Typeglobs are also a way to create a local filehandle using the local()
958 operator. These last until their block is exited, but may be passed back.
964 open (FH, $path) or return undef;
967 $fh = newopen('/etc/passwd');
969 Now that we have the C<*foo{THING}> notation, typeglobs aren't used as much
970 for filehandle manipulations, although they're still needed to pass brand
971 new file and directory handles into or out of functions. That's because
972 C<*HANDLE{IO}> only works if HANDLE has already been used as a handle.
973 In other words, C<*FH> must be used to create new symbol table entries;
974 C<*foo{THING}> cannot. When in doubt, use C<*FH>.
976 All functions that are capable of creating filehandles (open(),
977 opendir(), pipe(), socketpair(), sysopen(), socket(), and accept())
978 automatically create an anonymous filehandle if the handle passed to
979 them is an uninitialized scalar variable. This allows the constructs
980 such as C<open(my $fh, ...)> and C<open(local $fh,...)> to be used to
981 create filehandles that will conveniently be closed automatically when
982 the scope ends, provided there are no other references to them. This
983 largely eliminates the need for typeglobs when opening filehandles
984 that must be passed around, as in the following example:
988 or die "Can't open '@_': $!";
993 my $f = myopen("</etc/motd");
995 # $f implicitly closed here
998 Note that if an initialized scalar variable is used instead the
999 result is different: C<my $fh='zzz'; open($fh, ...)> is equivalent
1000 to C<open( *{'zzz'}, ...)>.
1001 C<use strict 'refs'> forbids such practice.
1003 Another way to create anonymous filehandles is with the Symbol
1004 module or with the IO::Handle module and its ilk. These modules
1005 have the advantage of not hiding different types of the same name
1006 during the local(). See the bottom of L<perlfunc/open> for an
1011 See L<perlvar> for a description of Perl's built-in variables and
1012 a discussion of legal variable names. See L<perlref>, L<perlsub>,
1013 and L<perlmod/"Symbol Tables"> for more discussion on typeglobs and
1014 the C<*foo{THING}> syntax.