installperl

   1 #!./perl
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '..\lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8 }
   9
  10 use strict;
  11 my ($Is_VMS, $Is_W32, $Is_OS2, $Is_Cygwin, $Is_Darwin,
  12     $nonono, $dostrip, $versiononly, $silent, $verbose, $force,
  13     $otherperls, $archname, $Is_NetWare, $nwinstall, $nopods);
  14 use vars qw /$depth/;
  15
  16 BEGIN {
  17     $Is_VMS = $^O eq 'VMS';
  18     $Is_W32 = $^O eq 'MSWin32';
  19     $Is_OS2 = $^O eq 'os2';
  20     $Is_Cygwin = $^O eq 'cygwin';
  21     $Is_Darwin = $^O eq 'darwin';
  22     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  23 }
  24
  25 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  26
  27 use File::Find;
  28 use File::Compare;
  29 use File::Copy ();
  30 use File::Path ();
  31 use ExtUtils::Packlist;
  32 use Config;
  33 use subs qw(unlink link chmod);
  34
  35 if ($Config{d_umask}) {
  36     umask(022); # umasks like 077 aren't that useful for installations
  37 }
  38
  39 $Is_NetWare = $Config{osname} eq 'NetWare';
  40 if ($Is_NetWare) {
  41     $Is_W32 = 0;
  42     $scr_ext = '.pl';
  43 }
  44
  45 # override the ones in the rest of the script
  46 sub mkpath {
  47     File::Path::mkpath(@_) unless $nonono;
  48 }
  49
  50 my $mainperldir = "/usr/bin";
  51 my $exe_ext = $Config{exe_ext};
  52
  53 # Allow ``make install PERLNAME=something_besides_perl'':
  54 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  55
  56 # This is the base used for versioned names, like "perl5.6.0".
  57 # It's separate because a common use of $PERLNAME is to install
  58 # perl as "perl5", if that's used as base for versioned files you
  59 # get "perl55.6.0".
  60 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  61                     ? $ENV{PERLNAME_VERBASE}
  62                     : $perl;
  63 my $dbg = '';
  64 my $ndbg = '';
  65 if ( $Is_VMS ) {
  66     if ( defined $Config{usevmsdebug} ) {
  67         if ( $Config{usevmsdebug} eq 'define' ) {
  68             $dbg = 'dbg';
  69             $ndbg = 'ndbg';
  70         }
  71     }
  72 }
  73
  74 $otherperls = 1;
  75 my $destdir = '';
  76 while (@ARGV) {
  77     $nonono = 1 if $ARGV[0] eq '-n';
  78     $dostrip = 1 if $ARGV[0] eq '-s';
  79     $versiononly = 1 if $ARGV[0] eq '-v';
  80     $versiononly = 0 if $ARGV[0] eq '+v';
  81     $silent = 1 if $ARGV[0] eq '-S';
  82     $otherperls = 0 if $ARGV[0] eq '-o';
  83     $force = 1 if $ARGV[0] eq '-f';
  84     $verbose = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
  85     $archname = 1 if $ARGV[0] eq '-A';
  86     $nwinstall = 1 if $ARGV[0] eq '-netware';
  87     $nopods = 1 if $ARGV[0] eq '-p';
  88     $destdir = $1 if $ARGV[0] =~ /^-?-destdir=(.*)$/;
  89     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
  90         print <<"EOT";
  91 Usage $0: [switches]
  92   -n        Don't actually run any commands; just print them.
  93   -s        Run strip on installed binaries.
  94   -v        Only install perl as a binary with the version number in the name.
  95             (Override whatever config.sh says)
  96   +v        Install perl as "perl" and as a binary with the version number in
  97             the name.  (Override whatever config.sh says)
  98   -S        Silent mode.
  99   -f        Force installation (don't check if same version is there)
 100   -o        Skip checking for other copies of perl in your PATH.
 101   -V        Verbose mode.
 102   -A        Also install perl with the architecture's name in the perl binary's
 103             name.
 104   -p        Don't install the pod files. [This will break use diagnostics;]
 105   -netware  Install correctly on a Netware server.
 106 EOT
 107         exit;
 108     }
 109     shift;
 110 }
 111
 112 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
 113 my (@scripts, @tolink);
 114 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
 115 while (<SCRIPTS>) {
 116     next if /^#/;
 117     s/\s*#\s*pod\s*=.*//; # install script regardless of pod location
 118     next if /a2p/; # a2p is binary, to be installed separately
 119     chomp;
 120     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
 121         push @scripts, $1;
 122         push @tolink, [$1, $2];
 123     } else {
 124         push @scripts, $_;
 125     }
 126 }
 127 close SCRIPTS;
 128
 129 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
 130
 131 my @pods = $nopods ? () : (<pod/*.pod>);
 132
 133 # Specify here any .pm files that are actually architecture-dependent.
 134 # (Those included with XS extensions under ext/ are automatically
 135 # added later.)
 136 # Now that the default privlib has the full perl version number included,
 137 # we no longer have to play the trick of sticking version-specific .pm
 138 # files under the archlib directory.
 139 my %archpms = (
 140     Config => 1,
 141     lib => 1,
 142     Cwd => 1,
 143 );
 144
 145 if ($^O eq 'dos') {
 146     push(@scripts,'djgpp/fixpmain');
 147     $archpms{config} = $archpms{filehand} = 1;
 148 }
 149
 150 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
 151     push(@scripts, map("$_.exe", @scripts));
 152 }
 153
 154 find(sub {
 155     if ("$File::Find::dir/$_" =~ m{^ext\b(.*)/([^/]+)\.pm$}) {
 156         my($path, $modname) = ($1,$2);
 157
 158         # strip trailing component first
 159         $path =~ s{/[^/]*$}{};
 160
 161         # strip optional "/lib";
 162         $path =~ s{/lib\b}{};
 163
 164         # strip any leading /
 165         $path =~ s{^/}{};
 166
 167         # reconstitute canonical module name
 168         $modname = "$path/$modname" if length $path;
 169
 170         # remember it
 171         $archpms{$modname} = 1;
 172     }
 173 }, 'ext');
 174
 175 # print "[$_]\n" for sort keys %archpms;
 176
 177 my $ver = $Config{version};
 178 my $release = substr($],0,3);   # Not used currently.
 179 my $patchlevel = substr($],3,2);
 180 die "Patchlevel of perl ($patchlevel)",
 181     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 182         if $patchlevel != $Config{'PERL_VERSION'};
 183
 184 # Fetch some frequently-used items from %Config
 185 my $installbin = "$destdir$Config{installbin}";
 186 my $installscript = "$destdir$Config{installscript}";
 187 my $installprivlib = "$destdir$Config{installprivlib}";
 188 my $installarchlib = "$destdir$Config{installarchlib}";
 189 my $installsitelib = "$destdir$Config{installsitelib}";
 190 my $installsitearch = "$destdir$Config{installsitearch}";
 191 my $installman1dir = "$destdir$Config{installman1dir}";
 192 my $man1ext = $Config{man1ext};
 193 my $libperl = $Config{libperl};
 194 # Shared library and dynamic loading suffixes.
 195 my $so = $Config{so};
 196 my $dlext = $Config{dlext};
 197 my $dlsrc = $Config{dlsrc};
 198 if ($^O eq 'os390') {
 199     my $pwd;
 200     chomp($pwd=`pwd`);
 201     my $archlibexp = $Config{archlibexp};
 202     my $usedl = $Config{usedl};
 203     if ($usedl eq 'define') {
 204         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
 205     }
 206 }
 207
 208 if ($nwinstall) {
 209     # This is required only if we are installing on a NetWare server
 210     $installscript = $Config{installnwscripts};
 211     $installprivlib = $Config{installnwlib};
 212     $installarchlib = $Config{installnwlib};
 213     $installsitelib = $Config{installnwlib};
 214 }
 215
 216 my $d_dosuid = $Config{d_dosuid};
 217 my $binexp = $Config{binexp};
 218
 219 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 220     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 221               \$installarchlib, \$installsitelib, \$installsitearch,
 222               \$installman1dir ) {
 223         $$_ = unixify($$_);  $$_ =~ s:/$::;
 224     }
 225 }
 226
 227 # Do some quick sanity checks.
 228
 229 if (!$nonono && $d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 230
 231    $installbin          || die "No installbin directory in config.sh\n";
 232 -d $installbin          || mkpath($installbin, $verbose, 0777);
 233 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 234 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 235         unless $installbin =~ m#^/afs/# || $nonono;
 236
 237 if (!$Is_NetWare) {
 238 if (!$Is_VMS) {
 239 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 240 }
 241 else {
 242 -x $ndbg . 'perl' . $exe_ext    || die "${ndbg}perl$exe_ext isn't executable!\n";
 243     if ($dbg) {
 244         -x $dbg . 'perl' . $exe_ext     || die "${dbg}perl$exe_ext isn't executable!\n";
 245     }
 246 }
 247 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 248
 249 -f 't/rantests'         || $Is_W32
 250                         || warn "WARNING: You've never run 'make test' or",
 251                                 " some tests failed! (Installing anyway.)\n";
 252 } #if (!$Is_NetWare)
 253
 254 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
 255     my $perldll;
 256
 257     if ($Is_Cygwin) {
 258         $perldll = $libperl;
 259         my $v_e_r_s = $ver; $v_e_r_s =~ tr/./_/;
 260         $perldll =~ s/(\..*)?$/$v_e_r_s.$dlext/;
 261         $perldll =~ s/^lib/cyg/;
 262         if ($Config{useshrplib} eq 'true') {
 263             # install ld2 and perlld as well
 264             foreach ('ld2', 'perlld') {
 265                 safe_unlink("$installbin/$_");
 266                 copy("$_", "$installbin/$_");
 267                 chmod(0755, "$installbin/$_");
 268             };
 269             open (LD2, ">$installbin/ld2");
 270             print LD2 <<SHELL;
 271 #!/bin/sh
 272 #
 273 # ld wrapper, passes all args to perlld;
 274 #
 275 for trythis in $installbin/perl
 276 do
 277   if [ -x \$trythis ]
 278   then
 279     \$trythis $installbin/perlld "\$\@"
 280     exit \$?
 281   fi
 282 done
 283 # hard luck!
 284 echo I see no perl executable around there
 285 echo perl is required to build dynamic libraries
 286 echo look if the path to perl in /bin/ld2 is correct
 287 exit 1
 288 SHELL
 289             close LD2;
 290             chmod(0755, "$installbin/ld2");
 291         };
 292     } else {
 293         $perldll = 'perl59.' . $dlext;
 294     }
 295
 296     if ($dlsrc ne "dl_none.xs") {
 297         -f $perldll || die "No perl DLL built\n";
 298     }
 299
 300     # Install the DLL
 301     safe_unlink("$installbin/$perldll");
 302     copy("$perldll", "$installbin/$perldll");
 303     chmod(0755, "$installbin/$perldll");
 304 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
 305
 306 # This will be used to store the packlist
 307 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 308
 309 # First we install the version-numbered executables.
 310
 311 if ($Is_VMS) {
 312     safe_unlink("$installbin/perl_setup.com");
 313     copy("perl_setup.com", "$installbin/perl_setup.com");
 314     chmod(0755, "$installbin/perl_setup.com");
 315     safe_unlink("$installbin/$dbg$perl$exe_ext");
 316     copy("$dbg$perl$exe_ext", "$installbin/$dbg$perl$exe_ext");
 317     chmod(0755, "$installbin/$dbg$perl$exe_ext");
 318     safe_unlink("$installbin/$dbg${perl}shr$exe_ext");
 319     copy("$dbg${perl}shr$exe_ext", "$installbin/$dbg${perl}shr$exe_ext");
 320     chmod(0755, "$installbin/$dbg${perl}shr$exe_ext");
 321     if ($ndbg) {
 322         safe_unlink("$installbin/$ndbg$perl$exe_ext");
 323         copy("$ndbg$perl$exe_ext", "$installbin/$ndbg$perl$exe_ext");
 324         chmod(0755, "$installbin/$ndbg$perl$exe_ext");
 325         safe_unlink("$installbin/${dbg}a2p$exe_ext");
 326         copy("x2p/${dbg}a2p$exe_ext", "$installbin/${dbg}a2p$exe_ext");
 327         chmod(0755, "$installbin/${dbg}a2p$exe_ext");
 328     }
 329 }
 330 elsif ($^O eq 'mpeix') {
 331     # MPE lacks hard links and requires that executables with special
 332     # capabilities reside in the MPE namespace.
 333     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 334     # Install the primary executable into the MPE namespace as perlpath.
 335     copy("perl$exe_ext", $Config{perlpath});
 336     chmod(0755, $Config{perlpath});
 337     # Create a backup copy with the version number.
 338     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 339 }
 340 elsif ($^O ne 'dos') {
 341     if (!$Is_NetWare) {
 342         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 343         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 344         strip("$installbin/$perl_verbase$ver$exe_ext");
 345         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 346     }
 347     else {
 348         # If installing onto a NetWare server
 349         if ($nwinstall) {
 350             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
 351             mkpath($Config{installnwsystem}, 1, 0777);
 352             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
 353             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
 354             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
 355             copy("x2p\\a2p.nlm", $Config{installnwsystem});
 356             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
 357             mkpath($Config{installnwlcgi}, 1, 0777);
 358             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
 359         }
 360     } #if (!$Is_NetWare)
 361 }
 362 else {
 363     safe_unlink("$installbin/$perl.exe");
 364     copy("perl.exe", "$installbin/$perl.exe");
 365 }
 366
 367 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
 368 if ($d_dosuid) {
 369     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
 370     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
 371 }
 372
 373 # Install library files.
 374
 375 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 376
 377 mkpath($installprivlib, $verbose, 0777);
 378 mkpath($installarchlib, $verbose, 0777);
 379 mkpath($installsitelib, $verbose, 0777) if ($installsitelib);
 380 mkpath($installsitearch, $verbose, 0777) if ($installsitearch);
 381
 382 if (chdir "lib") {
 383     $do_installarchlib = ! samepath($installarchlib, '.');
 384     $do_installprivlib = ! samepath($installprivlib, '.');
 385     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$ver/);
 386
 387     if ($do_installarchlib || $do_installprivlib) {
 388         find(\&installlib, '.');
 389     }
 390     chdir ".." || die "Can't cd back to source directory: $!\n";
 391 }
 392 else {
 393     warn "Can't cd to lib to install lib files: $!\n";
 394 }
 395
 396 # Install header files and libraries.
 397 mkpath("$installarchlib/CORE", $verbose, 0777);
 398 my @corefiles;
 399 if ($Is_VMS) {  # We did core file selection during build
 400     my $coredir = "lib/$Config{archname}/$ver/CORE";
 401     $coredir =~ tr/./_/;
 402     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 403 }
 404 else {
 405     # [als] hard-coded 'libperl' name... not good!
 406     @corefiles = <*.h libperl*.*>;
 407
 408     # AIX needs perl.exp installed as well.
 409     push(@corefiles,'perl.exp') if $^O eq 'aix';
 410     if ($^O eq 'mpeix') {
 411         # MPE needs mpeixish.h installed as well.
 412         mkpath("$installarchlib/CORE/mpeix", $verbose, 0777);
 413         push(@corefiles,'mpeix/mpeixish.h');
 414     }
 415     # If they have built sperl.o...
 416     push(@corefiles,'sperl.o') if -f 'sperl.o';
 417 }
 418 foreach my $file (@corefiles) {
 419     # HP-UX (at least) needs to maintain execute permissions
 420     # on dynamically-loadable libraries. So we do it for all.
 421     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 422         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 423             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
 424             chmod(0555, "$installarchlib/CORE/$file");
 425         } else {
 426             chmod(0444, "$installarchlib/CORE/$file");
 427         }
 428     }
 429 }
 430
 431 # Install main perl executables
 432 # Make links to ordinary names if installbin directory isn't current directory.
 433
 434 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
 435     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 436     if ($^O eq 'mpeix') {
 437         # MPE doesn't support hard links, so use a symlink.
 438         # We don't want another cloned copy.
 439         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 440     } elsif ($^O eq 'vos') {
 441         # VOS doesn't support hard links, so use a symlink.
 442         symlink("$installbin/$perl_verbase$ver$exe_ext",
 443                 "$installbin/$perl$exe_ext");
 444     } else {
 445         link("$installbin/$perl_verbase$ver$exe_ext",
 446                 "$installbin/$perl$exe_ext");
 447     }
 448     link("$installbin/s$perl_verbase$ver$exe_ext",
 449             "$installbin/suid$perl$exe_ext")
 450       if $d_dosuid;
 451 }
 452
 453 # For development purposes it can be very useful to have multiple perls
 454 # build for different "architectures" (eg threading or not) simultaneously.
 455 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 456     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
 457     safe_unlink("$installbin/$archperl");
 458     if ($^O eq 'mpeix') {
 459         # MPE doesn't support hard links, so use a symlink.
 460         # We don't want another cloned copy.
 461         symlink($Config{perlpath}, "$installbin/$archperl");
 462     } elsif ($^O eq 'vos') {
 463         # VOS doesn't support hard links, so use a symlink.
 464         symlink("$installbin/$perl_verbase$ver$exe_ext",
 465                 "$installbin/$archperl");
 466     } else {
 467         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
 468     }
 469 }
 470
 471 # Offer to install perl in a "standard" location
 472
 473 my $mainperl_is_instperl = 0;
 474
 475 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 476     !$versiononly && !$nonono && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
 477         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 478     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 479     my($instperl)       = "$installbin/$perl$exe_ext";
 480     my($expinstperl)    = "$binexp/$perl$exe_ext";
 481
 482     # First make sure $usrbinperl is not already the same as the perl we
 483     # just installed.
 484     if (-x $usrbinperl) {
 485         # Try to be clever about mainperl being a symbolic link
 486         # to binexp/perl if binexp and installbin are different.
 487         $mainperl_is_instperl =
 488             samepath($usrbinperl, $instperl) ||
 489             samepath($usrbinperl, $expinstperl) ||
 490              (($binexp ne $installbin) &&
 491               (-l $usrbinperl) &&
 492               ((readlink $usrbinperl) eq $expinstperl));
 493     }
 494     if (! $mainperl_is_instperl) {
 495         unlink($usrbinperl);
 496         ( $Config{'d_link'} eq 'define' &&
 497           eval { CORE::link $instperl, $usrbinperl } )  ||
 498         eval { symlink $expinstperl, $usrbinperl }      ||
 499         copy($instperl, $usrbinperl);
 500
 501         $mainperl_is_instperl = 1;
 502     }
 503 }
 504
 505 # Make links to ordinary names if installbin directory isn't current directory.
 506 if (!$Is_NetWare && $dbg eq '') {
 507     if (! samepath($installbin, 'x2p')) {
 508         my $base = 'a2p';
 509         $base .= $ver if $versiononly;
 510         safe_unlink("$installbin/$base$exe_ext");
 511         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
 512         strip("$installbin/$base$exe_ext");
 513         chmod(0755, "$installbin/$base$exe_ext");
 514     }
 515 }
 516
 517 # cppstdin is just a script, but it is architecture-dependent, so
 518 # it can't safely be shared.  Place it in $installbin.
 519 # Note that Configure doesn't build cppstin if it isn't needed, so
 520 # we skip this if cppstdin doesn't exist.
 521 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 522     safe_unlink("$installbin/cppstdin");
 523     copy("cppstdin", "$installbin/cppstdin");
 524     chmod(0755, "$installbin/cppstdin");
 525 }
 526
 527 sub script_alias {
 528     my ($installscript, $orig, $alias, $scr_ext) = @_;
 529
 530     safe_unlink("$installscript/$alias$scr_ext");
 531     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 532         copy("$installscript/$orig$scr_ext",
 533              "$installscript/$alias$scr_ext");
 534     } elsif ($^O eq 'vos') {
 535         symlink("$installscript/$orig$scr_ext",
 536                 "$installscript/$alias$scr_ext");
 537     } else {
 538         link("$installscript/$orig$scr_ext",
 539              "$installscript/$alias$scr_ext");
 540     }
 541 }
 542
 543 # Install scripts.
 544 mkpath($installscript, $verbose, 0777);
 545 if ($versiononly) {
 546     for (@scripts) {
 547         (my $base = $_) =~ s#.*/##;
 548         $base .= $ver;
 549         copy($_,    "$installscript/$base");
 550         chmod(0755, "$installscript/$base");
 551     }
 552
 553     for (@tolink) {
 554         my ($from, $to) = map { "$_$ver" } @$_;
 555         (my $frbase = $from) =~ s#.*/##;
 556         (my $tobase = $to) =~ s#.*/##;
 557         script_alias($installscript, $frbase, $tobase, $scr_ext);
 558     }
 559 } else {
 560     for (@scripts) {
 561         (my $base = $_) =~ s#.*/##;
 562         copy($_, "$installscript/$base");
 563         chmod(0755, "$installscript/$base");
 564     }
 565
 566     for (@tolink) {
 567         my ($from, $to) = @$_;
 568         (my $frbase = $from) =~ s#.*/##;
 569         (my $tobase = $to) =~ s#.*/##;
 570         script_alias($installscript, $frbase, $tobase, $scr_ext);
 571     }
 572 }
 573
 574 # Install pod pages.  Where? I guess in $installprivlib/pod
 575 # ($installprivlib/pods for cygwin).
 576
 577 my $pod = ($Is_Cygwin || $Is_Darwin) ? 'pods' : 'pod';
 578 if ( !$versiononly || ($installprivlib =~ m/\Q$ver/)) {
 579     mkpath("${installprivlib}/$pod", $verbose, 0777);
 580
 581     # If Perl 5.003's perldiag.pod is there, rename it.
 582     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
 583         read POD, $_, 4000;
 584         close POD;
 585         # Some of Perl 5.003's diagnostic messages ended with periods.
 586         if (/^=.*\.$/m) {
 587             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
 588                                "${installprivlib}/$pod/perldiag-5.003.pod");
 589             print "  rename $from $to";
 590             rename($from, $to)
 591                 or warn "Couldn't rename $from to $to: $!\n"
 592                 unless $nonono;
 593         }
 594     }
 595
 596     for (@pods) {
 597         # $_ is a name like  pod/perl.pod
 598         (my $base = $_) =~ s#.*/##;
 599         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 600     }
 601
 602 }
 603
 604 # Check to make sure there aren't other perls around in installer's
 605 # path.  This is probably UNIX-specific.  Check all absolute directories
 606 # in the path except for where public executables are supposed to live.
 607 # Also skip $mainperl if the user opted to have it be a link to the
 608 # installed perl.
 609
 610 if (!$versiononly && $otherperls) {
 611     my ($path, @path);
 612     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
 613     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 614     @path = split(/$dirsep/, $path);
 615     if ($Is_VMS) {
 616         my $i = 0;
 617         while (exists $ENV{'DCL$PATH' . $i}) {
 618             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 619             push(@path,$dir);
 620         }
 621     }
 622     my @otherperls;
 623     my %otherperls;
 624     for (@path) {
 625         next unless m,^/,;
 626         # Use &samepath here because some systems have other dirs linked
 627         # to $mainperldir (like SunOS)
 628         next if samepath($_, $binexp);
 629         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 630         my $otherperl = "$_/$perl$exe_ext";
 631         next if $otherperls{$otherperl}++;
 632         push(@otherperls, $otherperl)
 633             if (-x $otherperl && ! -d $otherperl);
 634     }
 635     if (@otherperls) {
 636         warn "\nWarning: $perl appears in your path in the following " .
 637             "locations beyond where\nwe just installed it:\n";
 638         for (@otherperls) {
 639             warn "    ", $_, "\n";
 640         }
 641         warn "\n";
 642     }
 643
 644 }
 645
 646 $packlist->write() unless $nonono;
 647 print "  Installation complete\n" if $verbose;
 648
 649 exit 0;
 650
 651 ###############################################################################
 652
 653 sub yn {
 654     my($prompt) = @_;
 655     my($answer);
 656     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 657     print STDERR $prompt;
 658     chop($answer = <STDIN>);
 659     $answer = $default if $answer =~ m/^\s*$/;
 660     ($answer =~ m/^[yY]/);
 661 }
 662
 663 sub unlink {
 664     my(@names) = @_;
 665     my($cnt) = 0;
 666
 667     return scalar(@names) if $Is_VMS;
 668
 669     foreach my $name (@names) {
 670         next unless -e $name;
 671         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin || $Is_NetWare);
 672         print "  unlink $name\n" if $verbose;
 673         ( CORE::unlink($name) and ++$cnt
 674           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 675     }
 676     return $cnt;
 677 }
 678
 679 sub safe_unlink {
 680     return if $nonono or $Is_VMS;
 681     my @names = @_;
 682     foreach my $name (@names) {
 683         next unless -e $name;
 684         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
 685         print "  unlink $name\n" if $verbose;
 686         next if CORE::unlink($name);
 687         warn "Couldn't unlink $name: $!\n";
 688         if ($! =~ /busy/i) {
 689             print "  mv $name $name.old\n" if $verbose;
 690             safe_rename($name, "$name.old")
 691                 or warn "Couldn't rename $name: $!\n";
 692         }
 693     }
 694 }
 695
 696 sub safe_rename {
 697     my($from,$to) = @_;
 698     if (-f $to and not unlink($to)) {
 699         my($i);
 700         for ($i = 1; $i < 50; $i++) {
 701             last if rename($to, "$to.$i");
 702         }
 703         warn("Cannot rename to `$to.$i': $!"), return 0
 704            if $i >= 50; # Give up!
 705     }
 706     link($from,$to) || return 0;
 707     unlink($from);
 708 }
 709
 710 sub link {
 711     my($from,$to) = @_;
 712     my($success) = 0;
 713
 714     my $xfrom = $from;
 715     $xfrom =~ s/^\Q$destdir\E// if $destdir;
 716     my $xto = $to;
 717     $xto =~ s/^\Q$destdir\E// if $destdir;
 718     print $verbose ? "  ln $xfrom $xto\n" : "  $xto\n" unless $silent;
 719     eval {
 720         CORE::link($from, $to)
 721             ? $success++
 722             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 723               ? die "AFS"  # okay inside eval {}
 724               : die "Couldn't link $from to $to: $!\n"
 725           unless $nonono;
 726         $packlist->{$xto} = { from => $xfrom, type => 'link' };
 727     };
 728     if ($@) {
 729         warn $@;
 730         print $verbose ? "  cp $from $xto\n" : "  $xto\n" unless $silent;
 731         print "  creating new version of $xto\n"
 732                  if $Is_VMS and -e $to and !$silent;
 733         File::Copy::copy($from, $to)
 734             ? $success++
 735             : warn "Couldn't copy $from to $to: $!\n"
 736           unless $nonono;
 737         $packlist->{$xto} = { type => 'file' };
 738     }
 739     $success;
 740 }
 741
 742 sub chmod {
 743     my($mode,$name) = @_;
 744
 745     return if ($^O eq 'dos');
 746     printf "  chmod %o %s\n", $mode, $name if $verbose;
 747     CORE::chmod($mode,$name)
 748         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 749       unless $nonono;
 750 }
 751
 752 sub copy {
 753     my($from,$to) = @_;
 754
 755     my $xto = $to;
 756     $xto =~ s/^\Q$destdir\E// if $destdir;
 757     print $verbose ? "  cp $from $xto\n" : "  $xto\n" unless $silent;
 758     print "  creating new version of $xto\n" if $Is_VMS and -e $to and !$silent;
 759     File::Copy::copy($from, $to)
 760         || warn "Couldn't copy $from to $to: $!\n"
 761       unless $nonono;
 762     $packlist->{$xto} = { type => 'file' };
 763 }
 764
 765 sub samepath {
 766     my($p1, $p2) = @_;
 767
 768     return (lc($p1) eq lc($p2)) if ($Is_W32 || $Is_NetWare);
 769
 770     if ($p1 ne $p2) {
 771         my($dev1, $ino1, $dev2, $ino2);
 772         ($dev1, $ino1) = stat($p1);
 773         ($dev2, $ino2) = stat($p2);
 774         ($dev1 == $dev2 && $ino1 == $ino2);
 775     }
 776     else {
 777         1;
 778     }
 779 }
 780
 781 sub installlib {
 782     my $dir = $File::Find::dir;
 783     $dir =~ s#^\.(?![^/])/?##;
 784     local($depth) = $dir ? "lib/$dir" : "lib";
 785
 786     my $name = $_;
 787
 788     # Ignore version control directories.
 789     if (($name eq 'CVS' or $name eq 'RCS' or $name eq '.svn') and -d $name) {
 790         $File::Find::prune = 1;
 791         return;
 792     }
 793
 794     # ignore patch backups, RCS files, emacs backup & temp files and the
 795     # .exists files, .PL files, and test files.
 796     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.plc$|\.t$|^test\.pl$} ||
 797               $dir  =~ m{/t(?:/|$)};
 798     # ignore the cpan script in lib/CPAN/bin (installed later with other utils)
 799     return if $name eq 'cpan';
 800     # ignore the test extensions
 801     return if $dir =~ m{ext/XS/(?:APItest|Typemap)/};
 802
 803     $name = "$dir/$name" if $dir ne '';
 804
 805     my $installlib = $installprivlib;
 806     if ($dir =~ /^auto/ ||
 807           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 808           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare))
 809        ) {
 810         $installlib = $installarchlib;
 811         return unless $do_installarchlib;
 812     } else {
 813         return unless $do_installprivlib;
 814     }
 815
 816     if (-f $_) {
 817         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
 818             $installlib = $installprivlib;
 819             #We're installing *.al and *.ix files into $installprivlib,
 820             #but we have to delete old *.al and *.ix files from the 5.000
 821             #distribution:
 822             #This might not work because $archname might have changed.
 823             unlink("$installarchlib/$name");
 824         }
 825         my $xname = "$installlib/$name";
 826         $xname =~ s/^\Q$destdir\E// if $destdir;
 827         $packlist->{$xname} = { type => 'file' };
 828         if ($force || compare($_, "$installlib/$name") || $nonono) {
 829             unlink("$installlib/$name");
 830             mkpath("$installlib/$dir", $verbose, 0777);
 831             # HP-UX (at least) needs to maintain execute permissions
 832             # on dynamically-loaded libraries.
 833             if ($Is_NetWare && !$nwinstall) {
 834                 # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
 835                 # if copied will give problems when building new extensions.
 836                 # Has to be copied if we are installing on a NetWare server and hence
 837                 # the check !$nwinstall
 838                 if (!(/\.(?:nlp|nlm|bs)$/)) {
 839                     copy_if_diff($_, "$installlib/$name")
 840                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 841                                   "$installlib/$name");
 842                 }
 843            } else {
 844                 if (copy_if_diff($_, "$installlib/$name")) {
 845                     if ($name =~ /\.(so|$dlext)$/o) {
 846                         strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
 847                         chmod(0555, "$installlib/$name");
 848                     } else {
 849                         strip("-S", "$installlib/$name")
 850                             if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
 851                         chmod(0444, "$installlib/$name");
 852                     }
 853                 }
 854             } #if ($Is_NetWare)
 855         }
 856     }
 857 }
 858
 859 # Copy $from to $to, only if $from is different than $to.
 860 # Also preserve modification times for .a libraries.
 861 # On some systems, if you do
 862 #   ranlib libperl.a
 863 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 864 # and then try to link against the installed libperl.a, you might
 865 # get an error message to the effect that the symbol table is older
 866 # than the library.
 867 # Return true if copying occurred.
 868
 869 sub copy_if_diff {
 870     my($from,$to)=@_;
 871     return 1 if (($^O eq 'VMS') && (-d $from));
 872     my $xto = $to;
 873     $xto =~ s/^\Q$destdir\E// if $destdir;
 874     my $perlpodbadsymlink;
 875     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
 876         -l $from &&
 877         ! -e $from) {
 878         # Some Linux implementations have problems traversing over
 879         # multiple symlinks (when going over NFS?) and fail to read
 880         # the symlink target.  Combine this with the fact that some
 881         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
 882         # and you end up with those pods not getting installed.
 883         $perlpodbadsymlink = 1;
 884     }
 885     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
 886     $packlist->{$xto} = { type => 'file' };
 887     if ($force || compare($from, $to) || $nonono) {
 888         safe_unlink($to);   # In case we don't have write permissions.
 889         if ($nonono) {
 890             $from = $depth . "/" . $from if $depth;
 891         }
 892         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
 893             $from = "README.$1";
 894         }
 895         copy($from, $to);
 896         # Restore timestamps if it's a .a library or for OS/2.
 897         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
 898             my ($atime, $mtime) = (stat $from)[8,9];
 899             utime $atime, $mtime, $to;
 900         }
 901         1;
 902     }
 903 }
 904
 905 sub strip
 906 {
 907     my(@args) = @_;
 908
 909     return unless $dostrip;
 910
 911     my @opts;
 912     while (@args && $args[0] =~ /^(-\w+)$/) {
 913         push @opts, shift @args;
 914     }
 915
 916     foreach my $file (@args) {
 917         if (-f $file) {
 918             if ($verbose) {
 919                 print "  strip " . join(' ', @opts);
 920                 print " " if (@opts);
 921                 print "$file\n";
 922             }
 923             system("strip", @opts, $file);
 924         } else {
 925             print "# file '$file' skipped\n" if $verbose;
 926         }
 927     }
 928 }