t/op/stat.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require './test.pl';        # for which_perl() etc
   7 }
   8
   9 use Config;
  10 use File::Spec;
  11
  12 plan tests => 107;
  13
  14 my $Perl = which_perl();
  15
  16 $Is_Amiga   = $^O eq 'amigaos';
  17 $Is_Cygwin  = $^O eq 'cygwin';
  18 $Is_Darwin  = $^O eq 'darwin';
  19 $Is_Dos     = $^O eq 'dos';
  20 $Is_MPE     = $^O eq 'mpeix';
  21 $Is_MSWin32 = $^O eq 'MSWin32';
  22 $Is_NetWare = $^O eq 'NetWare';
  23 $Is_OS2     = $^O eq 'os2';
  24 $Is_Solaris = $^O eq 'solaris';
  25 $Is_VMS     = $^O eq 'VMS';
  26 $Is_DGUX    = $^O eq 'dgux';
  27 $Is_MPRAS   = $^O =~ /svr4/ && -f '/etc/.relid';
  28 $Is_Rhapsody= $^O eq 'rhapsody';
  29
  30 $Is_Dosish  = $Is_Dos || $Is_OS2 || $Is_MSWin32 || $Is_NetWare || $Is_Cygwin;
  31
  32 $Is_UFS     = $Is_Darwin && (() = `df -t ufs . 2>/dev/null`) == 2;
  33
  34 my($DEV, $INO, $MODE, $NLINK, $UID, $GID, $RDEV, $SIZE,
  35    $ATIME, $MTIME, $CTIME, $BLKSIZE, $BLOCKS) = (0..12);
  36
  37 my $Curdir = File::Spec->curdir;
  38
  39
  40 my $tmpfile = tempfile();
  41 my $tmpfile_link = tempfile();
  42
  43 chmod 0666, $tmpfile;
  44 1 while unlink $tmpfile;
  45 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  46 close FOO;
  47
  48 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  49
  50 my($nlink, $mtime, $ctime) = (stat(FOO))[$NLINK, $MTIME, $CTIME];
  51
  52 # The clock on a network filesystem might be different from the
  53 # system clock.
  54 my $Filesystem_Time_Offset = abs($mtime - time);
  55
  56 #nlink should if link support configured in Perl.
  57 SKIP: {
  58     skip "No link count - Hard link support not built in.", 1
  59         unless $Config{d_link};
  60
  61     is($nlink, 1, 'nlink on regular file');
  62 }
  63
  64 SKIP: {
  65   skip "mtime and ctime not reliable", 2
  66     if $Is_MSWin32 or $Is_NetWare or $Is_Cygwin or $Is_Dos or $Is_Darwin;
  67
  68   ok( $mtime,           'mtime' );
  69   is( $mtime, $ctime,   'mtime == ctime' );
  70 }
  71
  72
  73 # Cygwin seems to have a 3 second granularity on its timestamps.
  74 my $funky_FAT_timestamps = $Is_Cygwin;
  75 sleep 3 if $funky_FAT_timestamps;
  76
  77 print FOO "Now is the time for all good men to come to.\n";
  78 close(FOO);
  79
  80 sleep 2;
  81
  82
  83 SKIP: {
  84     unlink $tmpfile_link;
  85     my $lnk_result = eval { link $tmpfile, $tmpfile_link };
  86     skip "link() unimplemented", 6 if $@ =~ /unimplemented/;
  87
  88     is( $@, '',         'link() implemented' );
  89     ok( $lnk_result,    'linked tmp testfile' );
  90     ok( chmod(0644, $tmpfile),             'chmoded tmp testfile' );
  91
  92     my($nlink, $mtime, $ctime) = (stat($tmpfile))[$NLINK, $MTIME, $CTIME];
  93
  94     SKIP: {
  95         skip "No link count", 1 if $Config{dont_use_nlink};
  96         skip "Cygwin9X fakes hard links by copying", 1
  97           if $Config{myuname} =~ /^cygwin_(?:9\d|me)\b/i;
  98
  99         is($nlink, 2,     'Link count on hard linked file' );
 100     }
 101
 102     SKIP: {
 103         my $cwd = File::Spec->rel2abs($Curdir);
 104         skip "Solaris tmpfs has different mtime/ctime link semantics", 2
 105                                      if $Is_Solaris and $cwd =~ m#^/tmp# and
 106                                         $mtime && $mtime == $ctime;
 107         skip "AFS has different mtime/ctime link semantics", 2
 108                                      if $cwd =~ m#$Config{'afsroot'}/#;
 109         skip "AmigaOS has different mtime/ctime link semantics", 2
 110                                      if $Is_Amiga;
 111         # Win32 could pass $mtime test but as FAT and NTFS have
 112         # no ctime concept $ctime is ALWAYS == $mtime
 113         # expect netware to be the same ...
 114         skip "No ctime concept on this OS", 2
 115                                      if $Is_MSWin32 ||
 116                                         ($Is_Darwin && $Is_UFS);
 117
 118         if( !ok($mtime, 'hard link mtime') ||
 119             !isnt($mtime, $ctime, 'hard link ctime != mtime') ) {
 120             print STDERR <<DIAG;
 121 # Check if you are on a tmpfs of some sort.  Building in /tmp sometimes
 122 # has this problem.  Building on the ClearCase VOBS filesystem may also
 123 # cause this failure.
 124 #
 125 # Darwin's UFS doesn't have a ctime concept, and thus is expected to fail
 126 # this test.
 127 DIAG
 128         }
 129     }
 130
 131 }
 132
 133 # truncate and touch $tmpfile.
 134 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 135 ok(-z \*F,     '-z on empty filehandle');
 136 ok(! -s \*F,   '   and -s');
 137 close F;
 138
 139 ok(-z $tmpfile,     '-z on empty file');
 140 ok(! -s $tmpfile,   '   and -s');
 141
 142 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 143 print F "hi\n";
 144 close F;
 145
 146 open(F, "<$tmpfile") || DIE("Can't open temp test file: $!");
 147 ok(!-z *F,     '-z on empty filehandle');
 148 ok( -s *F,   '   and -s');
 149 close F;
 150
 151 ok(! -z $tmpfile,   '-z on non-empty file');
 152 ok(-s $tmpfile,     '   and -s');
 153
 154
 155 # Strip all access rights from the file.
 156 ok( chmod(0000, $tmpfile),     'chmod 0000' );
 157
 158 SKIP: {
 159     skip "-r, -w and -x have different meanings on VMS", 3 if $Is_VMS;
 160
 161     SKIP: {
 162         # Going to try to switch away from root.  Might not work.
 163         my $olduid = $>;
 164         eval { $> = 1; };
 165         skip "Can't test -r or -w meaningfully if you're superuser", 2
 166           if $> == 0;
 167
 168         SKIP: {
 169             skip "Can't test -r meaningfully?", 1 if $Is_Dos || $Is_Cygwin;
 170             ok(!-r $tmpfile,    "   -r");
 171         }
 172
 173         ok(!-w $tmpfile,    "   -w");
 174
 175         # switch uid back (may not be implemented)
 176         eval { $> = $olduid; };
 177     }
 178
 179     ok(! -x $tmpfile,   '   -x');
 180 }
 181
 182
 183
 184 ok(chmod(0700,$tmpfile),    'chmod 0700');
 185 ok(-r $tmpfile,     '   -r');
 186 ok(-w $tmpfile,     '   -w');
 187
 188 SKIP: {
 189     skip "-x simply determines if a file ends in an executable suffix", 1
 190       if $Is_Dosish;
 191
 192     ok(-x $tmpfile,     '   -x');
 193 }
 194
 195 ok(  -f $tmpfile,   '   -f');
 196 ok(! -d $tmpfile,   '   !-d');
 197
 198 # Is this portable?
 199 ok(  -d $Curdir,          '-d cwd' );
 200 ok(! -f $Curdir,          '!-f cwd' );
 201
 202
 203 SKIP: {
 204     unlink($tmpfile_link);
 205     my $symlink_rslt = eval { symlink $tmpfile, $tmpfile_link };
 206     skip "symlink not implemented", 3 if $@ =~ /unimplemented/;
 207
 208     is( $@, '',     'symlink() implemented' );
 209     ok( $symlink_rslt,      'symlink() ok' );
 210     ok(-l $tmpfile_link,    '-l');
 211 }
 212
 213 ok(-o $tmpfile,     '-o');
 214
 215 ok(-e $tmpfile,     '-e');
 216
 217 unlink($tmpfile_link);
 218 ok(! -e $tmpfile_link,  '   -e on unlinked file');
 219
 220 SKIP: {
 221     skip "No character, socket or block special files", 6
 222       if $Is_MSWin32 || $Is_NetWare || $Is_Dos;
 223     skip "/dev isn't available to test against", 6
 224       unless -d '/dev' && -r '/dev' && -x '/dev';
 225     skip "Skipping: unexpected ls output in MP-RAS", 6
 226       if $Is_MPRAS;
 227
 228     # VMS problem:  If GNV or other UNIX like tool is installed, then
 229     # sometimes Perl will find /bin/ls, and will try to run it.
 230     # But since Perl on VMS does not know to run it under Bash, it will
 231     # try to run the DCL verb LS.  And if the VMS product Language
 232     # Sensitive Editor is installed, or some other LS verb, that will
 233     # be run instead.  So do not do this until we can teach Perl
 234     # when to use BASH on VMS.
 235     skip "ls command not available to Perl in OpenVMS right now.", 6
 236       if $Is_VMS;
 237
 238     my $LS  = $Config{d_readlink} ? "ls -lL" : "ls -l";
 239     my $CMD = "$LS /dev 2>/dev/null";
 240     my $DEV = qx($CMD);
 241
 242     skip "$CMD failed", 6 if $DEV eq '';
 243
 244     my @DEV = do { my $dev; opendir($dev, "/dev") ? readdir($dev) : () };
 245
 246     skip "opendir failed: $!", 6 if @DEV == 0;
 247
 248     # /dev/stdout might be either character special or a named pipe,
 249     # or a symlink, or a socket, depending on which OS and how are
 250     # you running the test, so let's censor that one away.
 251     # Similar remarks hold for stderr.
 252     $DEV =~ s{^[cpls].+?\sstdout$}{}m;
 253     @DEV =  grep { $_ ne 'stdout' } @DEV;
 254     $DEV =~ s{^[cpls].+?\sstderr$}{}m;
 255     @DEV =  grep { $_ ne 'stderr' } @DEV;
 256
 257     # /dev/printer is also naughty: in IRIX it shows up as
 258     # Srwx-----, not srwx------.
 259     $DEV =~ s{^.+?\sprinter$}{}m;
 260     @DEV =  grep { $_ ne 'printer' } @DEV;
 261
 262     # If running as root, we will see .files in the ls result,
 263     # and readdir() will see them always.  Potential for conflict,
 264     # so let's weed them out.
 265     $DEV =~ s{^.+?\s\..+?$}{}m;
 266     @DEV =  grep { ! m{^\..+$} } @DEV;
 267
 268     # Irix ls -l marks sockets with 'S' while 's' is a 'XENIX semaphore'.
 269     if ($^O eq 'irix') {
 270         $DEV =~ s{^S(.+?)}{s$1}mg;
 271     }
 272
 273     my $try = sub {
 274         my @c1 = eval qq[\$DEV =~ /^$_[0].*/mg];
 275         my @c2 = eval qq[grep { $_[1] "/dev/\$_" } \@DEV];
 276         my $c1 = scalar @c1;
 277         my $c2 = scalar @c2;
 278         is($c1, $c2, "ls and $_[1] agreeing on /dev ($c1 $c2)");
 279     };
 280
 281 SKIP: {
 282     skip("DG/UX ls -L broken", 3) if $Is_DGUX;
 283
 284     $try->('b', '-b');
 285     $try->('c', '-c');
 286     $try->('s', '-S');
 287
 288 }
 289
 290 ok(! -b $Curdir,    '!-b cwd');
 291 ok(! -c $Curdir,    '!-c cwd');
 292 ok(! -S $Curdir,    '!-S cwd');
 293
 294 }
 295
 296 SKIP: {
 297     my($cnt, $uid);
 298     $cnt = $uid = 0;
 299
 300     # Find a set of directories that's very likely to have setuid files
 301     # but not likely to be *all* setuid files.
 302     my @bin = grep {-d && -r && -x} qw(/sbin /usr/sbin /bin /usr/bin);
 303     skip "Can't find a setuid file to test with", 3 unless @bin;
 304
 305     for my $bin (@bin) {
 306         opendir BIN, $bin or die "Can't opendir $bin: $!";
 307         while (defined($_ = readdir BIN)) {
 308             $_ = "$bin/$_";
 309             $cnt++;
 310             $uid++ if -u;
 311             last if $uid && $uid < $cnt;
 312         }
 313     }
 314     closedir BIN;
 315
 316     skip "No setuid programs", 3 if $uid == 0;
 317
 318     isnt($cnt, 0,    'found some programs');
 319     isnt($uid, 0,    '  found some setuid programs');
 320     ok($uid < $cnt,  "    they're not all setuid");
 321 }
 322
 323
 324 # To assist in automated testing when a controlling terminal (/dev/tty)
 325 # may not be available (at, cron  rsh etc), the PERL_SKIP_TTY_TEST env var
 326 # can be set to skip the tests that need a tty.
 327 SKIP: {
 328     skip "These tests require a TTY", 4 if $ENV{PERL_SKIP_TTY_TEST};
 329
 330     my $TTY = $Is_Rhapsody ? "/dev/ttyp0" : "/dev/tty";
 331
 332     SKIP: {
 333         skip "Test uses unixisms", 2 if $Is_MSWin32 || $Is_NetWare;
 334         skip "No TTY to test -t with", 2 unless -e $TTY;
 335
 336         open(TTY, $TTY) ||
 337           warn "Can't open $TTY--run t/TEST outside of make.\n";
 338         ok(-t TTY,  '-t');
 339         ok(-c TTY,  'tty is -c');
 340         close(TTY);
 341     }
 342     ok(! -t TTY,    '!-t on closed TTY filehandle');
 343
 344     {
 345         local $TODO = 'STDIN not a tty when output is to pipe' if $Is_VMS;
 346         ok(-t,          '-t on STDIN');
 347     }
 348 }
 349
 350 my $Null = File::Spec->devnull;
 351 SKIP: {
 352     skip "No null device to test with", 1 unless -e $Null;
 353     skip "We know Win32 thinks '$Null' is a TTY", 1 if $Is_MSWin32;
 354
 355     open(NULL, $Null) or DIE("Can't open $Null: $!");
 356     ok(! -t NULL,   'null device is not a TTY');
 357     close(NULL);
 358 }
 359
 360
 361 # These aren't strictly "stat" calls, but so what?
 362 my $statfile = File::Spec->catfile($Curdir, 'op', 'stat.t');
 363 ok(  -T $statfile,    '-T');
 364 ok(! -B $statfile,    '!-B');
 365
 366 SKIP: {
 367      skip("DG/UX", 1) if $Is_DGUX;
 368 ok(-B $Perl,      '-B');
 369 }
 370
 371 ok(! -T $Perl,    '!-T');
 372
 373 open(FOO,$statfile);
 374 SKIP: {
 375     eval { -T FOO; };
 376     skip "-T/B on filehandle not implemented", 15 if $@ =~ /not implemented/;
 377
 378     is( $@, '',     '-T on filehandle causes no errors' );
 379
 380     ok(-T FOO,      '   -T');
 381     ok(! -B FOO,    '   !-B');
 382
 383     $_ = <FOO>;
 384     like($_, qr/perl/, 'after readline');
 385     ok(-T FOO,      '   still -T');
 386     ok(! -B FOO,    '   still -B');
 387     close(FOO);
 388
 389     open(FOO,$statfile);
 390     $_ = <FOO>;
 391     like($_, qr/perl/,      'reopened and after readline');
 392     ok(-T FOO,      '   still -T');
 393     ok(! -B FOO,    '   still !-B');
 394
 395     ok(seek(FOO,0,0),   'after seek');
 396     ok(-T FOO,          '   still -T');
 397     ok(! -B FOO,        '   still !-B');
 398
 399     # It's documented this way in perlfunc *shrug*
 400     () = <FOO>;
 401     ok(eof FOO,         'at EOF');
 402     ok(-T FOO,          '   still -T');
 403     ok(-B FOO,          '   now -B');
 404 }
 405 close(FOO);
 406
 407
 408 SKIP: {
 409     skip "No null device to test with", 2 unless -e $Null;
 410
 411     ok(-T $Null,  'null device is -T');
 412     ok(-B $Null,  '    and -B');
 413 }
 414
 415
 416 # and now, a few parsing tests:
 417 $_ = $tmpfile;
 418 ok(-f,      'bare -f   uses $_');
 419 ok(-f(),    '     -f() "');
 420
 421 unlink $tmpfile or print "# unlink failed: $!\n";
 422
 423 # bug id 20011101.069
 424 my @r = \stat($Curdir);
 425 is(scalar @r, 13,   'stat returns full 13 elements');
 426
 427 stat $0;
 428 eval { lstat _ };
 429 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 430     'lstat _ croaks after stat' );
 431 eval { -l _ };
 432 like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 433     '-l _ croaks after stat' );
 434
 435 lstat $0;
 436 eval { lstat _ };
 437 is( "$@", "", "lstat _ ok after lstat" );
 438 eval { -l _ };
 439 is( "$@", "", "-l _ ok after lstat" );
 440
 441 SKIP: {
 442     skip "No lstat", 2 unless $Config{d_lstat};
 443
 444     # bug id 20020124.004
 445     # If we have d_lstat, we should have symlink()
 446     my $linkname = 'dolzero';
 447     symlink $0, $linkname or die "# Can't symlink $0: $!";
 448     lstat $linkname;
 449     -T _;
 450     eval { lstat _ };
 451     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 452         'lstat croaks after -T _' );
 453     eval { -l _ };
 454     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 455         '-l _ croaks after -T _' );
 456     unlink $linkname or print "# unlink $linkname failed: $!\n";
 457 }
 458
 459 SKIP: {
 460     skip "Too much clock skew between system and filesystem", 5
 461         if ($Filesystem_Time_Offset > 5);
 462     print "# Zzz...\n";
 463     sleep($Filesystem_Time_Offset+1);
 464     my $f = 'tstamp.tmp';
 465     unlink $f;
 466     ok (open(S, "> $f"), 'can create tmp file');
 467     close S or die;
 468     my @a = stat $f;
 469     print "# time=$^T, stat=(@a)\n";
 470     my @b = (-M _, -A _, -C _);
 471     print "# -MAC=(@b)\n";
 472     ok( (-M _) < 0, 'negative -M works');
 473     ok( (-A _) < 0, 'negative -A works');
 474     ok( (-C _) < 0, 'negative -C works');
 475     ok(unlink($f), 'unlink tmp file');
 476 }
 477
 478 {
 479     ok(open(F, ">", $tmpfile), 'can create temp file');
 480     close F;
 481     chmod 0077, $tmpfile;
 482     my @a = stat($tmpfile);
 483     my $s1 = -s _;
 484     -T _;
 485     my $s2 = -s _;
 486     is($s1, $s2, q(-T _ doesn't break the statbuffer));
 487     unlink $tmpfile;
 488 }
 489
 490 SKIP: {
 491     skip "No dirfd()", 9 unless $Config{d_dirfd} || $Config{d_dir_dd_fd};
 492     ok(opendir(DIR, "."), 'Can open "." dir') || diag "Can't open '.':  $!";
 493     ok(stat(DIR), "stat() on dirhandle works");
 494     ok(-d -r _ , "chained -x's on dirhandle");
 495     ok(-d DIR, "-d on a dirhandle works");
 496
 497     # And now for the ambigious bareword case
 498     {
 499         no warnings 'deprecated';
 500         ok(open(DIR, "TEST"), 'Can open "TEST" dir')
 501             || diag "Can't open 'TEST':  $!";
 502     }
 503     my $size = (stat(DIR))[7];
 504     ok(defined $size, "stat() on bareword works");
 505     is($size, -s "TEST", "size returned by stat of bareword is for the file");
 506     ok(-f _, "ambiguous bareword uses file handle, not dir handle");
 507     ok(-f DIR);
 508     closedir DIR or die $!;
 509     close DIR or die $!;
 510 }
 511
 512 {
 513     # RT #8244: *FILE{IO} does not behave like *FILE for stat() and -X() operators
 514     ok(open(F, ">", $tmpfile), 'can create temp file');
 515     my @thwap = stat *F{IO};
 516     ok(@thwap, "stat(*F{IO}) works");
 517     ok( -f *F{IO} , "single file tests work with *F{IO}");
 518     close F;
 519     unlink $tmpfile;
 520
 521     #PVIO's hold dirhandle information, so let's test them too.
 522
 523     SKIP: {
 524         skip "No dirfd()", 9 unless $Config{d_dirfd} || $Config{d_dir_dd_fd};
 525         ok(opendir(DIR, "."), 'Can open "." dir') || diag "Can't open '.':  $!";
 526         ok(stat(*DIR{IO}), "stat() on *DIR{IO} works");
 527         ok(-d _ , "The special file handle _ is set correctly");
 528         ok(-d -r *DIR{IO} , "chained -x's on *DIR{IO}");
 529
 530         # And now for the ambigious bareword case
 531         {
 532             no warnings 'deprecated';
 533             ok(open(DIR, "TEST"), 'Can open "TEST" dir')
 534                 || diag "Can't open 'TEST':  $!";
 535         }
 536         my $size = (stat(*DIR{IO}))[7];
 537         ok(defined $size, "stat() on *THINGY{IO} works");
 538         is($size, -s "TEST",
 539            "size returned by stat of *THINGY{IO} is for the file");
 540         ok(-f _, "ambiguous *THINGY{IO} uses file handle, not dir handle");
 541         ok(-f *DIR{IO});
 542         closedir DIR or die $!;
 543         close DIR or die $!;
 544     }
 545 }
 546
 547 END {
 548     chmod 0666, $tmpfile;
 549     1 while unlink $tmpfile;
 550 }