t/op/glob.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = qw(. ../lib);
   6 }
   7
   8 require 'test.pl';
   9 plan( tests => 15 );
  10
  11 @oops = @ops = <op/*>;
  12
  13 if ($^O eq 'MSWin32') {
  14   map { $files{lc($_)}++ } <op/*>;
  15   map { delete $files{"op/$_"} } split /[\s\n]/, `dir /b /l op & dir /b /l /ah op 2>nul`,
  16 }
  17 elsif ($^O eq 'VMS') {
  18   map { $files{lc($_)}++ } <[.op]*>;
  19   map { s/;.*$//; delete $files{lc($_)}; } split /[\n]/, `directory/noheading/notrailing/versions=1 [.op]`,
  20 }
  21 else {
  22   map { $files{$_}++ } <op/*>;
  23   map { delete $files{$_} } split /[\s\n]/, `echo op/*`;
  24 }
  25 ok( !(keys(%files)),'leftover op/* files' ) or diag(join(' ',sort keys %files));
  26
  27 cmp_ok($/,'eq',"\n",'sane input record separator');
  28
  29 $not = '';
  30 while (<jskdfjskdfj* op/* jskdjfjkosvk*>) {
  31     $not = "not " unless $_ eq shift @ops;
  32     $not = "not at all " if $/ eq "\0";
  33 }
  34 ok(!$not,"glob amid garbage [$not]");
  35
  36 cmp_ok($/,'eq',"\n",'input record separator still sane');
  37
  38 $_ = "op/*";
  39 @glops = glob $_;
  40 cmp_ok("@glops",'eq',"@oops",'glob operator 1');
  41
  42 @glops = glob;
  43 cmp_ok("@glops",'eq',"@oops",'glob operator 2');
  44
  45 # glob should still work even after the File::Glob stash has gone away
  46 # (this used to dump core)
  47 my $i = 0;
  48 for (1..2) {
  49     eval "<.>";
  50     ok(!length($@),"eval'ed a glob $_");
  51     undef %File::Glob::;
  52     ++$i;
  53 }
  54 cmp_ok($i,'==',2,'remore File::Glob stash');
  55
  56 # ... while ($var = glob(...)) should test definedness not truth
  57
  58 SKIP: {
  59     skip('no File::Glob to emulate Unix-ism', 1)
  60         unless $INC{'File/Glob.pm'};
  61     my $ok = 0;
  62     $ok = 1 while my $var = glob("0");
  63     ok($ok,'define versus truth');
  64 }
  65
  66 # The formerly-broken test for the situation above would accidentally
  67 # test definedness for an assignment with a LOGOP on the right:
  68 {
  69     my $f = 0;
  70     my $ok = 1;
  71     $ok = 0, undef $f while $x = $f||$f;
  72     ok($ok,'test definedness with LOGOP');
  73 }
  74
  75 cmp_ok(scalar(@oops),'>',0,'glob globbed something');
  76
  77 *aieee = 4;
  78 pass('Can assign integers to typeglobs');
  79 *aieee = 3.14;
  80 pass('Can assign floats to typeglobs');
  81 *aieee = 'pi';
  82 pass('Can assign strings to typeglobs');