t/TEST

   1 #!./perl
   2
   3 # This is written in a peculiar style, since we're trying to avoid
   4 # most of the constructs we'll be testing for.  (This comment is
   5 # probably obsolete on the avoidance side, though still current
   6 # on the peculiarity side.)
   7
   8 # t/TEST and t/harness need to share code. The logical way to do this would be
   9 # to have the common code in a file both require or use. However, t/TEST needs
  10 # to still work, to generate test results, even if require isn't working, so
  11 # we cannot do that. t/harness has no such restriction, so it is quite
  12 # acceptable to have it require t/TEST.
  13
  14 # In which case, we need to stop t/TEST actually running tests, as all
  15 # t/harness needs are its subroutines.
  16
  17 # If we're doing deparse tests, ignore failures for these
  18 my $deparse_failures;
  19
  20 # And skip even running these
  21 my $deparse_skips;
  22
  23 # directories with special sets of test switches
  24 my %dir_to_switch =
  25     (base => '',
  26      comp => '',
  27      run => '',
  28      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
  29      );
  30
  31 # "not absolute" is the default, as it saves some fakery within TestInit
  32 # which can perturb tests, and takes CPU. Working with the upstream author of
  33 # any of these, to figure out how to remove them from this list, considered
  34 # "a good thing".
  35 my %abs = (
  36            '../cpan/Archive-Tar' => 1,
  37            '../cpan/AutoLoader' => 1,
  38            '../cpan/CPAN' => 1,
  39            '../cpan/Devel-PPPort' => 1,
  40            '../cpan/Encode' => 1,
  41            '../cpan/ExtUtils-Constant' => 1,
  42            '../cpan/ExtUtils-MakeMaker' => 1,
  43            '../cpan/File-Fetch' => 1,
  44            '../cpan/IPC-Cmd' => 1,
  45            '../cpan/IPC-SysV' => 1,
  46            '../cpan/Locale-Codes' => 1,
  47            '../cpan/Module-Load' => 1,
  48            '../cpan/Module-Load-Conditional' => 1,
  49            '../cpan/Parse-CPAN-Meta' => 1,
  50            '../cpan/Pod-Simple' => 1,
  51            '../cpan/Test-Simple' => 1,
  52            '../cpan/podlators' => 1,
  53            '../dist/Cwd' => 1,
  54            '../dist/ExtUtils-Command' => 1,
  55            '../dist/ExtUtils-Install' => 1,
  56            '../dist/ExtUtils-Manifest' => 1,
  57            '../dist/ExtUtils-ParseXS' => 1,
  58            '../dist/Tie-File' => 1,
  59           );
  60
  61 my %temp_no_core =
  62     ('../cpan/B-Debug' => 1,
  63      '../cpan/Compress-Raw-Bzip2' => 1,
  64      '../cpan/Compress-Raw-Zlib' => 1,
  65      '../cpan/Devel-PPPort' => 1,
  66      '../cpan/Getopt-Long' => 1,
  67      '../cpan/IO-Compress' => 1,
  68      '../cpan/MIME-Base64' => 1,
  69      '../cpan/parent' => 1,
  70      '../cpan/Parse-CPAN-Meta' => 1,
  71      '../cpan/Pod-Simple' => 1,
  72      '../cpan/podlators' => 1,
  73      '../cpan/Test-Simple' => 1,
  74      '../cpan/Tie-RefHash' => 1,
  75      '../cpan/Unicode-Collate' => 1,
  76      '../cpan/Unicode-Normalize' => 1,
  77     );
  78
  79 # delete env vars that may influence the results
  80 # but allow override via *_TEST env var if wanted
  81 # (e.g. PERL5OPT_TEST=-d:NYTProf)
  82 my @bad_env_vars = qw(
  83     PERL5LIB PERLLIB PERL5OPT
  84     PERL_YAML_BACKEND PERL_JSON_BACKEND
  85 );
  86
  87 for my $envname (@bad_env_vars) {
  88     my $override = $ENV{"${envname}_TEST"};
  89     if (defined $override) {
  90         warn "$0: $envname=$override\n";
  91         $ENV{$envname} = $override;
  92     }
  93     else {
  94         delete $ENV{$envname};
  95     }
  96 }
  97
  98 # Location to put the Valgrind log.
  99 our $Valgrind_Log;
 100
 101 my %skip = (
 102             '.' => 1,
 103             '..' => 1,
 104             'CVS' => 1,
 105             'RCS' => 1,
 106             'SCCS' => 1,
 107             '.svn' => 1,
 108            );
 109
 110
 111 if ($::do_nothing) {
 112     return 1;
 113 }
 114
 115 $| = 1;
 116
 117 # for testing TEST only
 118 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
 119 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
 120
 121 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
 122 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
 123 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
 124
 125 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
 126 # can't rely on require working.
 127 {
 128     my @argv = ();
 129     foreach my $idx (0..$#ARGV) {
 130         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
 131         $::benchmark = 1 if $1 eq 'benchmark';
 132         $::core    = 1 if $1 eq 'core';
 133         $::verbose = 1 if $1 eq 'v';
 134         $::torture = 1 if $1 eq 'torture';
 135         $::with_utf8 = 1 if $1 eq 'utf8';
 136         $::with_utf16 = 1 if $1 eq 'utf16';
 137         $::taintwarn = 1 if $1 eq 'taintwarn';
 138         if ($1 =~ /^deparse(,.+)?$/) {
 139             $::deparse = 1;
 140             $::deparse_opts = $1;
 141             _process_deparse_config();
 142         }
 143     }
 144     @ARGV = @argv;
 145 }
 146
 147 chdir 't' if -f 't/TEST';
 148 if (-f 'TEST' && -f 'harness' && -d '../lib') {
 149     @INC = '../lib';
 150 }
 151
 152 die "You need to run \"make test\" first to set things up.\n"
 153   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
 154
 155 # check leakage for embedders
 156 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
 157 # check existence of all symbols
 158 $ENV{PERL_DL_NONLAZY} = 1 unless exists $ENV{PERL_DL_NONLAZY};
 159
 160 $ENV{EMXSHELL} = 'sh';        # For OS/2
 161
 162 if ($show_elapsed_time) { require Time::HiRes }
 163 my %timings = (); # testname => [@et] pairs if $show_elapsed_time.
 164
 165 # Roll your own File::Find!
 166 sub _find_tests { our @found=(); push @ARGV, _find_files('\.t$', $_[0]) }
 167 sub _find_files {
 168     my($patt, @dirs) = @_;
 169     for my $dir (@dirs) {
 170         opendir DIR, $dir or die "Trouble opening $dir: $!";
 171         foreach my $f (sort { $a cmp $b } readdir DIR) {
 172             next if $skip{$f};
 173
 174             my $fullpath = "$dir/$f";
 175
 176             if (-d $fullpath) {
 177                 _find_files($patt, $fullpath);
 178             } elsif ($f =~ /$patt/) {
 179                 push @found, $fullpath;
 180             }
 181         }
 182     }
 183     @found;
 184 }
 185
 186
 187 # Scan the text of the test program to find switches and special options
 188 # we might need to apply.
 189 sub _scan_test {
 190     my($test, $type) = @_;
 191
 192     open(my $script, "<", $test) or die "Can't read $test.\n";
 193     my $first_line = <$script>;
 194
 195     $first_line =~ tr/\0//d if $::with_utf16;
 196
 197     my $switch = "";
 198     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
 199         $switch = "-$1";
 200     } else {
 201         if ($::taintwarn) {
 202             # not all tests are expected to pass with this option
 203             $switch = '-t';
 204         } else {
 205             $switch = '';
 206         }
 207     }
 208
 209     my $file_opts = "";
 210     if ($type eq 'deparse') {
 211         # Look for #line directives which change the filename
 212         while (<$script>) {
 213             $file_opts = $file_opts . ",-f$3$4"
 214               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
 215         }
 216     }
 217
 218     close $script;
 219
 220     my $perl = './perl';
 221     my $lib  = '../lib';
 222     my $run_dir;
 223     my $return_dir;
 224
 225     $test =~ /^(.+)\/[^\/]+/;
 226     my $dir = $1;
 227     my $testswitch = $dir_to_switch{$dir};
 228     if (!defined $testswitch) {
 229         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
 230             $run_dir = $1;
 231             $return_dir = '../../t';
 232             $lib = '../../lib';
 233             $perl = '../../t/perl';
 234             $testswitch = "-I../.. -MTestInit=U2T";
 235             if ($2 eq 'cpan' || $2 eq 'dist') {
 236                 if($abs{$run_dir}) {
 237                     $testswitch = $testswitch . ',A';
 238                 }
 239                 if ($temp_no_core{$run_dir}) {
 240                     $testswitch = $testswitch . ',NC';
 241                 }
 242             }
 243         } elsif ($test =~ m!^\.\./lib!) {
 244             $testswitch = '-I.. -MTestInit=U1'; # -T will remove . from @INC
 245         } else {
 246             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
 247         }
 248     }
 249
 250     my $utf8 = ($::with_utf8 || $::with_utf16) ? "-I$lib -Mutf8" : '';
 251
 252     my %options = (
 253         perl => $perl,
 254         lib => $lib,
 255         test => $test,
 256         run_dir => $run_dir,
 257         return_dir => $return_dir,
 258         testswitch => $testswitch,
 259         utf8 => $utf8,
 260         file => $file_opts,
 261         switch => $switch,
 262     );
 263
 264     return \%options;
 265 }
 266
 267 sub _cmd {
 268     my($options, $type) = @_;
 269
 270     my $test = $options->{test};
 271
 272     my $cmd;
 273     if ($type eq 'deparse') {
 274         my $perl = "$options->{perl} $options->{testswitch}";
 275         my $lib = $options->{lib};
 276
 277         $cmd = (
 278           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
 279           "-l$::deparse_opts$options->{file} ".
 280           "$test > $test.dp ".
 281           "&& $perl $options->{switch} -I$lib $test.dp"
 282         );
 283     }
 284     elsif ($type eq 'perl') {
 285         my $perl = $options->{perl};
 286         my $redir = $^O eq 'VMS' ? '2>&1' : '';
 287
 288         if ($ENV{PERL_VALGRIND}) {
 289             my $perl_supp = $options->{return_dir} ? "$options->{return_dir}/perl.supp" : "perl.supp";
 290             my $valgrind_exe = $ENV{VALGRIND} // 'valgrind';
 291             if ($options->{run_dir}) {
 292                 $Valgrind_Log = "$options->{run_dir}/$Valgrind_Log";
 293             }
 294             my $vg_opts = $ENV{VG_OPTS}
 295                //   "--log-file=$Valgrind_Log "
 296                   . "--suppressions=$perl_supp --leak-check=yes "
 297                   . "--leak-resolution=high --show-reachable=yes "
 298                   . "--num-callers=50 --track-origins=yes";
 299             # Force logging if not asked for (so cachegrind reporting works below)
 300             if ($vg_opts !~ /--log-file/) {
 301                 $vg_opts = "--log-file=$Valgrind_Log $vg_opts";
 302             }
 303             $perl = "$valgrind_exe $vg_opts $perl";
 304         }
 305
 306         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
 307         $cmd = $perl . _quote_args($args) . " $test $redir";
 308     }
 309     return $cmd;
 310 }
 311
 312 sub _before_fork {
 313     my ($options) = @_;
 314
 315     if ($options->{run_dir}) {
 316         my $run_dir = $options->{run_dir};
 317         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
 318     }
 319
 320     # Remove previous valgrind output otherwise it will interfere
 321     my $test = $options->{test};
 322
 323     (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
 324
 325     if ($ENV{PERL_VALGRIND} && -e $Valgrind_Log) {
 326         unlink $Valgrind_Log
 327             or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
 328     }
 329
 330     return;
 331 }
 332
 333 sub _after_fork {
 334     my ($options) = @_;
 335
 336     if ($options->{return_dir}) {
 337         my $return_dir = $options->{return_dir};
 338         chdir $return_dir
 339            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
 340     }
 341
 342     return;
 343 }
 344
 345 sub _run_test {
 346     my ($test, $type) = @_;
 347
 348     my $options = _scan_test($test, $type);
 349     # $test might have changed if we're in ext/Foo, so don't use it anymore
 350     # from now on. Use $options->{test} instead.
 351
 352     _before_fork($options);
 353
 354     my $cmd = _cmd($options, $type);
 355
 356     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
 357
 358     _after_fork($options);
 359
 360     # Our environment may force us to use UTF-8, but we can't be sure that
 361     # anything we're reading from will be generating (well formed) UTF-8
 362     # This may not be the best way - possibly we should unset ${^OPEN} up
 363     # top?
 364     binmode $results;
 365
 366     return $results;
 367 }
 368
 369 sub _quote_args {
 370     my ($args) = @_;
 371     my $argstring = '';
 372
 373     foreach (split(/\s+/,$args)) {
 374        # In VMS protect with doublequotes because otherwise
 375        # DCL will lowercase -- unless already doublequoted.
 376        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
 377        $argstring = $argstring . ' ' . $_;
 378     }
 379     return $argstring;
 380 }
 381
 382 sub _populate_hash {
 383     return unless defined $_[0];
 384     return map {$_, 1} split /\s+/, $_[0];
 385 }
 386
 387 sub _tests_from_manifest {
 388     my ($extensions, $known_extensions) = @_;
 389     my %skip;
 390     my %extensions = _populate_hash($extensions);
 391     my %known_extensions = _populate_hash($known_extensions);
 392
 393     foreach (keys %known_extensions) {
 394         $skip{$_} = 1 unless $extensions{$_};
 395     }
 396
 397     my @results;
 398     my $mani = '../MANIFEST';
 399     if (open(MANI, $mani)) {
 400         while (<MANI>) {
 401             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
 402                 my $t = $1;
 403                 my $extension = $2;
 404                 if (!$::core || $t =~ m!^lib/[a-z]!) {
 405                     if (defined $extension) {
 406                         $extension =~ s!/t(:?/\S+)*$!!;
 407                         # XXX Do I want to warn that I'm skipping these?
 408                         next if $skip{$extension};
 409                         my $flat_extension = $extension;
 410                         $flat_extension =~ s!-!/!g;
 411                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
 412                     }
 413                     my $path = "../$t";
 414                     push @results, $path;
 415                     $::path_to_name{$path} = $t;
 416                 }
 417             }
 418         }
 419         close MANI;
 420     } else {
 421         warn "$0: cannot open $mani: $!\n";
 422     }
 423     return @results;
 424 }
 425
 426 unless (@ARGV) {
 427     # base first, as TEST bails out if that can't run
 428     # then comp, to validate that require works
 429     # then run, to validate that -M works
 430     # then we know we can -MTestInit for everything else, making life simpler
 431     foreach my $dir (qw(base comp run cmd io re opbasic op uni mro)) {
 432         _find_tests($dir);
 433     }
 434     unless ($::core) {
 435         _find_tests('porting');
 436         _find_tests("lib");
 437     }
 438     # Config.pm may be broken for make minitest. And this is only a refinement
 439     # for skipping tests on non-default builds, so it is allowed to fail.
 440     # What we want to to is make a list of extensions which we did not build.
 441     my $configsh = '../config.sh';
 442     my ($extensions, $known_extensions);
 443     if (-f $configsh) {
 444         open FH, $configsh or die "Can't open $configsh: $!";
 445         while (<FH>) {
 446             if (/^extensions=['"](.*)['"]$/) {
 447                 $extensions = $1;
 448             }
 449             elsif (/^known_extensions=['"](.*)['"]$/) {
 450                 $known_extensions = $1;
 451             }
 452         }
 453         if (!defined $known_extensions) {
 454             warn "No known_extensions line found in $configsh";
 455         }
 456         if (!defined $extensions) {
 457             warn "No extensions line found in $configsh";
 458         }
 459     }
 460     # The "complex" constructions of list return from a subroutine, and push of
 461     # a list, might fail if perl is really hosed, but they aren't needed for
 462     # make minitest, and the building of extensions will likely also fail if
 463     # something is that badly wrong.
 464     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
 465     unless ($::core) {
 466         _find_tests('japh') if $::torture;
 467         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
 468         _find_tests('bigmem') if $ENV{PERL_TEST_MEMORY};
 469     }
 470 }
 471
 472 if ($::deparse) {
 473     _testprogs('deparse', '',   @ARGV);
 474 }
 475 elsif ($::with_utf16) {
 476     for my $e (0, 1) {
 477         for my $b (0, 1) {
 478             print STDERR "# ENDIAN $e BOM $b\n";
 479             my @UARGV;
 480             for my $a (@ARGV) {
 481                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
 482                 my $f = $e ? "v" : "n";
 483                 push @UARGV, $u;
 484                 unlink($u);
 485                 if (open(A, $a)) {
 486                     if (open(U, ">$u")) {
 487                         print U pack("$f", 0xFEFF) if $b;
 488                         while (<A>) {
 489                             print U pack("$f*", unpack("C*", $_));
 490                         }
 491                         close(U);
 492                     }
 493                     close(A);
 494                 }
 495             }
 496             _testprogs('perl', '', @UARGV);
 497             unlink(@UARGV);
 498         }
 499     }
 500 }
 501 else {
 502     _testprogs('perl',    '',   @ARGV);
 503 }
 504
 505 sub _testprogs {
 506     my ($type, $args, @tests) = @_;
 507
 508     print <<'EOT' if ($type eq 'deparse');
 509 ------------------------------------------------------------------------------
 510 TESTING DEPARSER
 511 ------------------------------------------------------------------------------
 512 EOT
 513
 514     $::bad_files = 0;
 515
 516     foreach my $t (@tests) {
 517       unless (exists $::path_to_name{$t}) {
 518         my $tname = "t/$t";
 519         $::path_to_name{$t} = $tname;
 520       }
 521     }
 522     my $maxlen = 0;
 523     foreach (@::path_to_name{@tests}) {
 524         s/\.\w+\z/ /; # space gives easy doubleclick to select fname
 525         my $len = length ;
 526         $maxlen = $len if $len > $maxlen;
 527     }
 528     # + 3 : we want three dots between the test name and the "ok"
 529     my $dotdotdot = $maxlen + 3 ;
 530     my $grind_ct = 0;           # count of non-empty valgrind reports
 531     my $total_files = @tests;
 532     my $good_files = 0;
 533     my $tested_files  = 0;
 534     my $totmax = 0;
 535     my %failed_tests;
 536     my $toolnm;         # valgrind, cachegrind, perf
 537
 538     while (my $test = shift @tests) {
 539         my ($test_start_time, @starttimes) = 0;
 540         if ($show_elapsed_time) {
 541             $test_start_time = Time::HiRes::time();
 542             # times() reports usage by TEST, but we want usage of each
 543             # testprog it calls, so record accumulated times now,
 544             # subtract them out afterwards.  Ideally, we'd take times
 545             # in BEGIN/END blocks (giving better visibility of self vs
 546             # children of each testprog), but that would require some
 547             # IPC to send results back here, or a completely different
 548             # collection scheme (Storable isn't tuned for incremental use)
 549             @starttimes = times;
 550         }
 551         if ($test =~ /^$/) {
 552             next;
 553         }
 554         if ($type eq 'deparse' && $test =~ $deparse_skips) {
 555             next;
 556         }
 557         my $te = $::path_to_name{$test} . '.'
 558                     x ($dotdotdot - length($::path_to_name{$test})) .' ';
 559
 560         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
 561             print $te;
 562             $te = '';
 563         }
 564
 565         (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
 566
 567         my $results = _run_test($test, $type);
 568
 569         my $failure;
 570         my $next = 0;
 571         my $seen_leader = 0;
 572         my $seen_ok = 0;
 573         my $trailing_leader = 0;
 574         my $max;
 575         my %todo;
 576         while (<$results>) {
 577             next if /^\s*$/; # skip blank lines
 578             if (/^1..$/ && ($^O eq 'VMS')) {
 579                 # VMS pipe bug inserts blank lines.
 580                 my $l2 = <$results>;
 581                 if ($l2 =~ /^\s*$/) {
 582                     $l2 = <$results>;
 583                 }
 584                 $_ = '1..' . $l2;
 585             }
 586             if ($::verbose) {
 587                 print $_;
 588             }
 589             unless (/^\#/) {
 590                 if ($trailing_leader) {
 591                     # shouldn't be anything following a postfix 1..n
 592                     $failure = 'FAILED--extra output after trailing 1..n';
 593                     last;
 594                 }
 595                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
 596                     if ($seen_leader) {
 597                         $failure = 'FAILED--seen duplicate leader';
 598                         last;
 599                     }
 600                     $max = $1;
 601                     %todo = map { $_ => 1 } split / /, $3 if $3;
 602                     $totmax = $totmax + $max;
 603                     $tested_files = $tested_files + 1;
 604                     if ($seen_ok) {
 605                         # 1..n appears at end of file
 606                         $trailing_leader = 1;
 607                         if ($next != $max) {
 608                             $failure = "FAILED--expected $max tests, saw $next";
 609                             last;
 610                         }
 611                     }
 612                     else {
 613                         $next = 0;
 614                     }
 615                     $seen_leader = 1;
 616                 }
 617                 else {
 618                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
 619                         unless ($seen_leader) {
 620                             unless ($seen_ok) {
 621                                 $next = 0;
 622                             }
 623                         }
 624                         $seen_ok = 1;
 625                         $next = $next + 1;
 626                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
 627                         $num = $next unless $num;
 628
 629                         if ($num == $next) {
 630
 631                             # SKIP is essentially the same as TODO for t/TEST
 632                             # this still conforms to TAP:
 633                             # http://testanything.org/wiki/index.php/TAP_specification
 634                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
 635                             $istodo = 1 if $todo{$num};
 636
 637                             if( $not && !$istodo ) {
 638                                 $failure = "FAILED at test $num";
 639                                 last;
 640                             }
 641                         }
 642                         else {
 643                             $failure ="FAILED--expected test $next, saw test $num";
 644                             last;
 645                         }
 646                     }
 647                     elsif (/^Bail out!\s*(.*)/i) { # magic words
 648                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
 649                     }
 650                     else {
 651                         # module tests are allowed extra output,
 652                         # because Test::Harness allows it
 653                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
 654                         $failure = "FAILED--unexpected output at test $next";
 655                         last;
 656                     }
 657                 }
 658             }
 659         }
 660         close $results;
 661
 662         if (not defined $failure) {
 663             $failure = 'FAILED--no leader found' unless $seen_leader;
 664         }
 665
 666         _check_valgrind(\$toolnm, \$grind_ct, \$test);
 667
 668         if ($type eq 'deparse' && !$ENV{KEEP_DEPARSE_FILES}) {
 669             unlink "./$test.dp";
 670         }
 671         if (not defined $failure and $next != $max) {
 672             $failure="FAILED--expected $max tests, saw $next";
 673         }
 674
 675         if( !defined $failure  # don't mask a test failure
 676             and $? )
 677         {
 678             $failure = "FAILED--non-zero wait status: $?";
 679         }
 680
 681         # Deparse? Should it have passed or failed?
 682         if ($type eq 'deparse' && $test =~ $deparse_failures) {
 683             if (!$failure) {
 684                 # Wait, it didn't fail? Great news! Tell someone!
 685                 $failure = "FAILED--all tests passed but test should have failed";
 686             } else {
 687                 # Bah, still failing. Mask it.
 688                 print "${te}skipped\n";
 689                 $tested_files = $tested_files - 1;
 690                 next;
 691             }
 692         }
 693
 694         if (defined $failure) {
 695             print "${te}$failure\n";
 696             $::bad_files = $::bad_files + 1;
 697             if ($test =~ /^base/ && ! defined &DynaLoader::boot_DynaLoader) {
 698                 # Die if running under minitest (no DynaLoader).  Otherwise
 699                 # keep going, as  we know that Perl basically works, or we
 700                 # would not have been able to actually compile it all the way.
 701                 die "Failed a basic test ($test) under minitest -- cannot continue.\n";
 702             }
 703             $failed_tests{$test} = 1;
 704         }
 705         else {
 706             if ($max) {
 707                 my ($elapsed, $etms) = ("", 0);
 708                 if ( $show_elapsed_time ) {
 709                     $etms = (Time::HiRes::time() - $test_start_time) * 1000;
 710                     $elapsed = sprintf(" %8.0f ms", $etms);
 711
 712                     my (@endtimes) = times;
 713                     $endtimes[$_] -= $starttimes[$_] for 0..$#endtimes;
 714                     splice @endtimes, 0, 2;    # drop self/harness times
 715                     $_ *= 1000 for @endtimes;  # and scale to ms
 716                     $timings{$test} = [$etms,@endtimes];
 717                     $elapsed .= sprintf(" %5.0f ms", $_) for @endtimes;
 718                 }
 719                 print "${te}ok$elapsed\n";
 720                 $good_files = $good_files + 1;
 721             }
 722             else {
 723                 print "${te}skipped\n";
 724                 $tested_files = $tested_files - 1;
 725             }
 726         }
 727     } # while tests
 728
 729     if ($::bad_files == 0) {
 730         if ($good_files) {
 731             print "All tests successful.\n";
 732             # XXX add mention of 'perlbug -ok' ?
 733         }
 734         else {
 735             die "FAILED--no tests were run for some reason.\n";
 736         }
 737     }
 738     else {
 739         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
 740         my $s = $::bad_files == 1 ? "" : "s";
 741         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
 742         for my $test ( sort keys %failed_tests ) {
 743             print "\t$test\n";
 744         }
 745         warn <<'SHRDLU_1';
 746 ### Since not all tests were successful, you may want to run some of
 747 ### them individually and examine any diagnostic messages they produce.
 748 ### See the INSTALL document's section on "make test".
 749 SHRDLU_1
 750         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
 751 ### You have a good chance to get more information by running
 752 ###   ./perl harness
 753 ### in the 't' directory since most (>=80%) of the tests succeeded.
 754 SHRDLU_2
 755         if (eval {require Config; import Config; 1}) {
 756             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
 757                 warn <<SHRDLU_3;
 758 ### You may have to set your dynamic library search path,
 759 ### $p, to point to the build directory:
 760 SHRDLU_3
 761                 if (exists $ENV{$p} && $ENV{$p} ne '') {
 762                     warn <<SHRDLU_4a;
 763 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
 764 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
 765 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
 766 SHRDLU_4a
 767                 } else {
 768                     warn <<SHRDLU_4b;
 769 ###   setenv $p `pwd`; cd t; ./perl harness
 770 ###   $p=`pwd`; export $p; cd t; ./perl harness
 771 ###   export $p=`pwd`; cd t; ./perl harness
 772 SHRDLU_4b
 773                 }
 774                 warn <<SHRDLU_5;
 775 ### for csh-style shells, like tcsh; or for traditional/modern
 776 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
 777 SHRDLU_5
 778             }
 779         }
 780     }
 781     my ($user,$sys,$cuser,$csys) = times;
 782     my $tot = sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d",
 783                       $user,$sys,$cuser,$csys,$tested_files,$totmax);
 784     print "$tot\n";
 785     if ($good_files) {
 786         if (-d $show_elapsed_time) {
 787             # HARNESS_TIMER = <a-directory>.  Save timings etc to
 788             # storable file there.  NB: the test cds to ./t/, so
 789             # relative path must account for that, ie ../../perf
 790             # points to dir next to source tree.
 791             require Storable;
 792             my @dt = localtime;
 793             $dt[5] += 1900; $dt[4] += 1; # fix year, month
 794             my $fn = "$show_elapsed_time/".join('-', @dt[5,4,3,2,1]).".ttimes";
 795             Storable::store({ perf => \%timings,
 796                               gather_conf_platform_info(),
 797                               total => $tot,
 798                             }, $fn);
 799             print "wrote storable file: $fn\n";
 800         }
 801     }
 802
 803     _cleanup_valgrind(\$toolnm, \$grind_ct);
 804 }
 805 exit ($::bad_files != 0);
 806
 807 # Collect platform, config data that should allow comparing
 808 # performance data between different machines.  With enough data,
 809 # and/or clever statistical analysis, it should be possible to
 810 # determine the effect of config choices, more memory, etc
 811
 812 sub gather_conf_platform_info {
 813     # currently rather quick & dirty, and subject to change
 814     # for both content and format.
 815     require Config;
 816     my (%conf, @platform) = ();
 817     $conf{$_} = $Config::Config{$_} for
 818         grep /cc|git|config_arg\d+/, keys %Config::Config;
 819     if (-f '/proc/cpuinfo') {
 820         open my $fh, '/proc/cpuinfo' or warn "$!: /proc/cpuinfo\n";
 821         @platform = grep /name|cpu/, <$fh>;
 822         chomp $_ for @platform;
 823     }
 824     unshift @platform, $^O;
 825
 826     return (
 827         conf => \%conf,
 828         platform => {cpu => \@platform,
 829                      mem => [ grep s/\s+/ /,
 830                               grep chomp, `free` ],
 831                      load => [ grep chomp, `uptime` ],
 832         },
 833         host => (grep chomp, `hostname -f`),
 834         version => '0.03', # bump for conf, platform, or data collection changes
 835         );
 836 }
 837
 838 sub _check_valgrind {
 839     return unless $ENV{PERL_VALGRIND};
 840
 841     my ($toolnm, $grind_ct, $test) = @_;
 842
 843     $$toolnm = $ENV{VALGRIND};
 844     $$toolnm =~ s|.*/||;  # keep basename
 845     my @valgrind;       # gets content of file
 846     if (-e $Valgrind_Log) {
 847         if (open(V, $Valgrind_Log)) {
 848             @valgrind = <V>;
 849             close V;
 850         } else {
 851             warn "$0: Failed to open '$Valgrind_Log': $!\n";
 852         }
 853     }
 854     if ($ENV{VG_OPTS} =~ /(cachegrind)/ or $$toolnm =~ /(perf)/) {
 855         $$toolnm = $1;
 856         if ($$toolnm eq 'perf') {
 857             # append perfs subcommand, not just stat
 858             my ($sub) = split /\s/, $ENV{VG_OPTS};
 859             $$toolnm .= "-$sub";
 860         }
 861         if (rename $Valgrind_Log, "$$test.$$toolnm") {
 862             $$grind_ct++;
 863         } else {
 864             warn "$0: Failed to create '$$test.$$toolnm': $!\n";
 865         }
 866     }
 867     elsif (@valgrind) {
 868         my $leaks = 0;
 869         my $errors = 0;
 870         for my $i (0..$#valgrind) {
 871             local $_ = $valgrind[$i];
 872             if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
 873                 $errors = $errors + $1;   # there may be multiple error summaries
 874             } elsif (/^==\d+== LEAK SUMMARY:/) {
 875                 for my $off (1 .. 4) {
 876                     if ($valgrind[$i+$off] =~
 877                         /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
 878                             $leaks = $leaks + $1;
 879                     }
 880                 }
 881             }
 882         }
 883         if ($errors or $leaks) {
 884             if (rename $Valgrind_Log, "$$test.valgrind") {
 885                 $$grind_ct = $$grind_ct + 1;
 886             } else {
 887                 warn "$0: Failed to create '$$test.valgrind': $!\n";
 888             }
 889         }
 890     } else {
 891         # Quiet wasn't asked for? Something may be amiss
 892         if ($ENV{VG_OPTS} && $ENV{VG_OPTS} !~ /(^|\s)(-q|--quiet)(\s|$)/) {
 893             warn "No valgrind output?\n";
 894         }
 895     }
 896     if (-e $Valgrind_Log) {
 897         unlink $Valgrind_Log
 898             or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
 899     }
 900 }
 901
 902 sub _cleanup_valgrind {
 903     return unless $ENV{PERL_VALGRIND};
 904
 905     my ($toolnm, $grind_ct) = @_;
 906     my $s = $$grind_ct == 1 ? '' : 's';
 907     print "$$grind_ct valgrind report$s created.\n", ;
 908     if ($$toolnm eq 'cachegrind') {
 909         # cachegrind leaves a lot of cachegrind.out.$pid litter
 910         # around the tree, find and delete them
 911         unlink _find_files('cachegrind.out.\d+$',
 912                      qw ( ../t ../cpan ../ext ../dist/ ));
 913     }
 914 }
 915
 916 # Generate regexps of known bad filenames / skips from Porting/deparse-skips.txt
 917 my $in;
 918
 919 sub _process_deparse_config {
 920     my @deparse_failures;
 921     my @deparse_skips;
 922
 923     my $f = '../Porting/deparse-skips.txt';
 924
 925     my $skips;
 926     if (!open($skips, '<', $f)) {
 927         warn "Failed to find $f: $!\n";
 928         return;
 929     }
 930
 931     while(<$skips>) {
 932         if (/__DEPARSE_FAILURES__/) {
 933             $in = \@deparse_failures; next;
 934         } elsif (/__DEPARSE_SKIPS__/) {
 935             $in = \@deparse_skips; next;
 936         } elsif (!$in) {
 937             next;
 938         }
 939
 940         s/#.*$//; # Kill comments
 941         s/\s+$//; # And trailing whitespace
 942
 943         next unless $_;
 944
 945         push @$in, $_;
 946     }
 947
 948     for my $f (@deparse_failures, @deparse_skips) {
 949         if ($f =~ m|/$|) { # Dir? Skip everything below it
 950             $f = qr/\Q$f\E.*/;
 951         } else {
 952             $f = qr/\Q$f\E/;
 953         }
 954     }
 955
 956     $deparse_failures = join('|', @deparse_failures);
 957     $deparse_failures = qr/^(?:$deparse_failures)$/;
 958
 959     $deparse_skips = join('|', @deparse_skips);
 960     $deparse_skips = qr/^(?:$deparse_skips)$/;
 961 }
 962
 963 # ex: set ts=8 sts=4 sw=4 noet: