regen/mg_vtable.pl

   1 #!/usr/bin/perl -w
   2 #
   3 # Regenerate (overwriting only if changed):
   4 #
   5 #    mg_names.c
   6 #    mg_raw.h
   7 #    mg_vtable.h
   8 #    pod/perlguts.pod
   9 #
  10 # from information stored in this file.  pod/perlguts.pod is not completely
  11 # regenerated.  Only the magic table is replaced; the other parts remain
  12 # untouched.
  13 #
  14 # Accepts the standard regen_lib -q and -v args.
  15 #
  16 # This script is normally invoked from regen.pl.
  17
  18 use strict;
  19 require 5.004;
  20
  21 BEGIN {
  22     # Get function prototypes
  23     require 'regen/regen_lib.pl';
  24 }
  25
  26 my %mg =
  27     (
  28      sv => { char => '\0', vtable => 'sv', readonly_acceptable => 1,
  29              desc => 'Special scalar variable' },
  30      # overload, or type "A" magic, used to be here.  Hence overloaded is
  31      # often called AMAGIC internally, even though it does not use "A"
  32      # magic any more.
  33      overload_table => { char => 'c', vtable => 'ovrld',
  34                          desc => 'Holds overload table (AMT) on stash' },
  35      bm => { char => 'B', vtable => 'regexp', value_magic => 1,
  36              readonly_acceptable => 1,
  37              desc => 'Boyer-Moore (fast string search)' },
  38      regdata => { char => 'D', vtable => 'regdata',
  39                   desc => "Regex match position data\n(\@+ and \@- vars)" },
  40      regdatum => { char => 'd', vtable => 'regdatum',
  41                    desc => 'Regex match position data element' },
  42      env => { char => 'E', vtable => 'env', desc => '%ENV hash' },
  43      envelem => { char => 'e', vtable => 'envelem',
  44                   desc => '%ENV hash element' },
  45      fm => { char => 'f', vtable => 'regdata', value_magic => 1,
  46              readonly_acceptable => 1, desc => "Formline ('compiled' format)" },
  47      regex_global => { char => 'g', vtable => 'mglob', value_magic => 1,
  48                        readonly_acceptable => 1, desc => 'm//g target' },
  49      hints => { char => 'H', vtable => 'hints', desc => '%^H hash' },
  50      hintselem => { char => 'h', vtable => 'hintselem',
  51                     desc => '%^H hash element' },
  52      isa => { char => 'I', vtable => 'isa', desc => '@ISA array' },
  53      isaelem => { char => 'i', vtable => 'isaelem',
  54                   desc => '@ISA array element' },
  55      nkeys => { char => 'k', vtable => 'nkeys', value_magic => 1,
  56                 desc => 'scalar(keys()) lvalue' },
  57      dbfile => { char => 'L',
  58                  desc => 'Debugger %_<filename' },
  59      dbline => { char => 'l', vtable => 'dbline',
  60                  desc => 'Debugger %_<filename element' },
  61      shared => { char => 'N', desc => 'Shared between threads',
  62                  unknown_to_sv_magic => 1 },
  63      shared_scalar => { char => 'n', desc => 'Shared between threads',
  64                         unknown_to_sv_magic => 1 },
  65      collxfrm => { char => 'o', vtable => 'collxfrm', value_magic => 1,
  66                    desc => 'Locale transformation' },
  67      tied => { char => 'P', vtable => 'pack',
  68                value_magic => 1, # treat as value, so 'local @tied' isn't tied
  69                desc => 'Tied array or hash' },
  70      tiedelem => { char => 'p', vtable => 'packelem',
  71                    desc => 'Tied array or hash element' },
  72      tiedscalar => { char => 'q', vtable => 'packelem',
  73                      desc => 'Tied scalar or handle' },
  74      qr => { char => 'r', vtable => 'regexp', value_magic => 1,
  75              desc => 'precompiled qr// regex' },
  76      sig => { char => 'S', desc => '%SIG hash' },
  77      sigelem => { char => 's', vtable => 'sigelem',
  78                   desc => '%SIG hash element' },
  79      taint => { char => 't', vtable => 'taint', value_magic => 1,
  80                 desc => 'Taintedness' },
  81      uvar => { char => 'U', vtable => 'uvar',
  82                desc => 'Available for use by extensions' },
  83      uvar_elem => { char => 'u', desc => 'Reserved for use by extensions',
  84                     unknown_to_sv_magic => 1 },
  85      vec => { char => 'v', vtable => 'vec', value_magic => 1,
  86               desc => 'vec() lvalue' },
  87      vstring => { char => 'V', value_magic => 1,
  88                   desc => 'SV was vstring literal' },
  89      utf8 => { char => 'w', vtable => 'utf8', value_magic => 1,
  90                desc => 'Cached UTF-8 information' },
  91      substr => { char => 'x', vtable => 'substr',  value_magic => 1,
  92                  desc => 'substr() lvalue' },
  93      defelem => { char => 'y', vtable => 'defelem', value_magic => 1,
  94                   desc => "Shadow \"foreach\" iterator variable /\nsmart parameter vivification" },
  95      arylen => { char => '#', vtable => 'arylen', value_magic => 1,
  96                  desc => 'Array length ($#ary)' },
  97      pos => { char => '.', vtable => 'pos', value_magic => 1,
  98               desc => 'pos() lvalue' },
  99      backref => { char => '<', vtable => 'backref', value_magic => 1,
 100                   readonly_acceptable => 1, desc => 'for weak ref data' },
 101      symtab => { char => ':', value_magic => 1,
 102                  desc => 'extra data for symbol tables' },
 103      rhash => { char => '%', value_magic => 1,
 104                 desc => 'extra data for restricted hashes' },
 105      arylen_p => { char => '@', value_magic => 1,
 106                    desc => 'to move arylen out of XPVAV' },
 107      ext => { char => '~', desc => 'Available for use by extensions' },
 108      checkcall => { char => ']', value_magic => 1, vtable => 'checkcall',
 109                     desc => 'inlining/mutation of call to this CV'},
 110 );
 111
 112 # These have a subtly different "namespace" from the magic types.
 113 my %sig =
 114     (
 115      'sv' => {get => 'get', set => 'set', len => 'len'},
 116      'env' => {set => 'set_all_env', clear => 'clear_all_env'},
 117      'envelem' => {set => 'setenv', clear => 'clearenv'},
 118      'sigelem' => {get => 'getsig', set => 'setsig', clear => 'clearsig',
 119                    cond => '#ifndef PERL_MICRO'},
 120      'pack' => {len => 'sizepack', clear => 'wipepack'},
 121      'packelem' => {get => 'getpack', set => 'setpack', clear => 'clearpack'},
 122      'dbline' => {set => 'setdbline'},
 123      'isa' => {set => 'setisa', clear => 'clearisa'},
 124      'isaelem' => {set => 'setisa'},
 125      'arylen' => {get => 'getarylen', set => 'setarylen', const => 1},
 126      'arylen_p' => {clear => 'cleararylen_p', free => 'freearylen_p'},
 127      'mglob' => {set => 'setmglob'},
 128      'nkeys' => {get => 'getnkeys', set => 'setnkeys'},
 129      'taint' => {get => 'gettaint', set => 'settaint'},
 130      'substr' => {get => 'getsubstr', set => 'setsubstr'},
 131      'vec' => {get => 'getvec', set => 'setvec'},
 132      'pos' => {get => 'getpos', set => 'setpos'},
 133      'uvar' => {get => 'getuvar', set => 'setuvar'},
 134      'defelem' => {get => 'getdefelem', set => 'setdefelem'},
 135      'regexp' => {set => 'setregexp', alias => [qw(bm fm)]},
 136      'regdata' => {len => 'regdata_cnt'},
 137      'regdatum' => {get => 'regdatum_get', set => 'regdatum_set'},
 138      'backref' => {free => 'killbackrefs'},
 139      'ovrld' => {free => 'freeovrld'},
 140      'utf8' => {set => 'setutf8'},
 141      'collxfrm' => {set => 'setcollxfrm',
 142                     cond => '#ifdef USE_LOCALE_COLLATE'},
 143      'hintselem' => {set => 'sethint', clear => 'clearhint'},
 144      'hints' => {clear => 'clearhints'},
 145      'checkcall' => {copy => 'copycallchecker'},
 146 );
 147
 148 my ($vt, $raw, $names) = map {
 149     open_new($_, '>',
 150              { by => 'regen/mg_vtable.pl', file => $_, style => '*' });
 151 } 'mg_vtable.h', 'mg_raw.h', 'mg_names.c';
 152 my $guts = open_new("pod/perlguts.pod", ">");
 153
 154 print $vt <<'EOH';
 155 /* These constants should be used in preference to raw characters
 156  * when using magic. Note that some perl guts still assume
 157  * certain character properties of these constants, namely that
 158  * isUPPER() and toLOWER() may do useful mappings.
 159  */
 160
 161 EOH
 162
 163 # Of course, it would be *much* easier if we could output this table directly
 164 # here and now. However, for our sins, we try to support EBCDIC, which wouldn't
 165 # be *so* bad, except that there are (at least) 3 EBCDIC charset variants, and
 166 # they don't agree on the code point for '~'. Which we use. Great.
 167 # So we have to get the local build runtime to sort our table in character order
 168 # (And of course, just to be helpful, in POSIX BC '~' is \xFF, so we can't even
 169 # simplify the C code by assuming that the last element of the array is
 170 # predictable)
 171
 172 {
 173     my $longest = 0;
 174     foreach (keys %mg) {
 175         $longest = length $_ if length $_ > $longest;
 176     }
 177
 178     my $longest_p1 = $longest + 1;
 179
 180     my %mg_order;
 181     while (my ($name, $data) = each %mg) {
 182         my $byte = eval qq{"$data->{char}"};
 183         $data->{byte} = $byte;
 184         $mg_order{(uc $byte) . $byte} = $name;
 185     }
 186     my @rows;
 187     foreach (sort keys %mg_order) {
 188         my $name = $mg_order{$_};
 189         my $data = $mg{$name};
 190         my $i = ord $data->{byte};
 191         unless ($data->{unknown_to_sv_magic}) {
 192             my $value = $data->{vtable}
 193                 ? "want_vtbl_$data->{vtable}" : 'magic_vtable_max';
 194             $value .= ' | PERL_MAGIC_READONLY_ACCEPTABLE'
 195                 if $data->{readonly_acceptable};
 196             $value .= ' | PERL_MAGIC_VALUE_MAGIC' if $data->{value_magic};
 197             my $comment = "/* $name '$data->{char}' $data->{desc} */";
 198             $comment =~ s/([\\"])/\\$1/g;
 199             $comment =~ tr/\n/ /;
 200             print $raw qq{    { '$data->{char}', "$value",\n      "$comment" },\n};
 201         }
 202
 203         my $comment = $data->{desc};
 204         my $leader = ' ' x ($longest + 27);
 205         $comment =~ s/\n/\n$leader/s;
 206         printf $vt "#define PERL_MAGIC_%-${longest}s '%s' /* %s */\n",
 207             $name, $data->{char}, $comment;
 208
 209         my $char = $data->{char};
 210         $char =~ s/([\\"])/\\$1/g;
 211         printf $names qq[\t{ PERL_MAGIC_%-${longest_p1}s "%s(%s)" },\n],
 212             "$name,", $name, $char;
 213
 214         push @rows, [(sprintf "%-2s PERL_MAGIC_%s", $data->{char}, $name),
 215                      $data->{vtable} ? "vtbl_$data->{vtable}" : '(none)',
 216                      $data->{desc}];
 217     }
 218     select +(select($guts), do {
 219         my @header = ('(old-style char and macro)', 'MGVTBL', 'Type of magic');
 220         my @widths = (0, 0);
 221         foreach my $row (@rows) {
 222             for (0, 1) {
 223                 $widths[$_] = length $row->[$_]
 224                     if length $row->[$_] > $widths[$_];
 225             }
 226         }
 227         my $indent = ' ';
 228         my $format
 229             = sprintf "$indent%%-%ds%%-%ds%%s\n", $widths[0] + 1, $widths[1] + 1;
 230         my $desc_wrap =
 231             79 - 7 - (length $indent) - $widths[0] - $widths[1] - 2;
 232
 233         open my $oldguts, "<", "pod/perlguts.pod"
 234            or die "$0 cannot open pod/perlguts.pod for reading: $!";
 235         while (<$oldguts>) {
 236             print;
 237             last if /^=for mg_vtable.pl begin/
 238         }
 239
 240         print "\n", $indent . "mg_type\n";
 241         printf $format, @header;
 242         printf $format, map {'-' x length $_} @header;
 243         foreach (@rows) {
 244             my ($type, $vtbl, $desc) = @$_;
 245             $desc =~ tr/\n/ /;
 246             my @cont;
 247             if (length $desc > $desc_wrap) {
 248                 # If it's too long, first split on '(', if there.
 249                 # [Which, if there, is always short enough, currently.
 250                 # Make this more robust if that changes]
 251                 ($desc, @cont) = split /(?=\()/, $desc;
 252                 if (!@cont) {
 253                     ($desc, @cont) = $desc =~ /(.{1,$desc_wrap})(?: |\z)/g
 254                 }
 255             }
 256             printf $format, $type, $vtbl, $desc;
 257             printf $format, '', '', $_ foreach @cont;
 258         }
 259         print "\n";
 260
 261         while (<$oldguts>) {
 262             last if /^=for mg_vtable.pl end/;
 263         }
 264         do { print } while <$oldguts>;
 265     })[0];
 266 }
 267
 268 my @names = sort keys %sig;
 269 {
 270     my $want = join ",\n    ", (map {"want_vtbl_$_"} @names), 'magic_vtable_max';
 271     my $names = join qq{",\n    "}, @names;
 272
 273     print $vt <<"EOH";
 274
 275 enum {          /* pass one of these to get_vtbl */
 276     $want
 277 };
 278
 279 #ifdef DOINIT
 280 EXTCONST char *PL_magic_vtable_names[magic_vtable_max] = {
 281     "$names"
 282 };
 283 #else
 284 EXTCONST char *PL_magic_vtable_names[magic_vtable_max];
 285 #endif
 286
 287 EOH
 288 }
 289
 290 print $vt <<'EOH';
 291 /* These all need to be 0, not NULL, as NULL can be (void*)0, which is a
 292  * pointer to data, whereas we're assigning pointers to functions, which are
 293  * not the same beast. ANSI doesn't allow the assignment from one to the other.
 294  * (although most, but not all, compilers are prepared to do it)
 295  */
 296
 297 /* order is:
 298     get
 299     set
 300     len
 301     clear
 302     free
 303     copy
 304     dup
 305     local
 306 */
 307
 308 #ifdef DOINIT
 309 EXT_MGVTBL PL_magic_vtables[magic_vtable_max] = {
 310 EOH
 311
 312 my @vtable_names;
 313 my @aliases;
 314
 315 while (my $name = shift @names) {
 316     my $data = $sig{$name};
 317     push @vtable_names, $name;
 318     my @funcs = map {
 319         $data->{$_} ? "Perl_magic_$data->{$_}" : 0;
 320     } qw(get set len clear free copy dup local);
 321
 322     $funcs[0] = "(int (*)(pTHX_ SV *, MAGIC *))" . $funcs[0] if $data->{const};
 323     my $funcs = join ", ", @funcs;
 324
 325     # Because we can't have a , after the last {...}
 326     my $comma = @names ? ',' : '';
 327
 328     print $vt "$data->{cond}\n" if $data->{cond};
 329     print $vt "  { $funcs }$comma\n";
 330     print $vt <<"EOH" if $data->{cond};
 331 #else
 332   { 0, 0, 0, 0, 0, 0, 0, 0 }$comma
 333 #endif
 334 EOH
 335     foreach(@{$data->{alias}}) {
 336         push @aliases, "#define want_vtbl_$_ want_vtbl_$name\n";
 337         push @vtable_names, $_;
 338     }
 339 }
 340
 341 print $vt <<'EOH';
 342 };
 343 #else
 344 EXT_MGVTBL PL_magic_vtables[magic_vtable_max];
 345 #endif
 346
 347 EOH
 348
 349 print $vt (sort @aliases), "\n";
 350
 351 print $vt "#define PL_vtbl_$_ PL_magic_vtables[want_vtbl_$_]\n"
 352     foreach sort @vtable_names;
 353
 354 # 63, not 64, As we rely on the last possible value to mean "NULL vtable"
 355 die "Too many vtable names" if @vtable_names > 63;
 356
 357 read_only_bottom_close_and_rename($_) foreach $vt, $raw, $names;
 358                  close_and_rename($guts);