cpan/Sys-Syslog/Syslog.pm

   1 package Sys::Syslog;
   2 use strict;
   3 use warnings;
   4 use warnings::register;
   5 use Carp;
   6 use Exporter        qw< import >;
   7 use File::Basename;
   8 use POSIX           qw< strftime setlocale LC_TIME >;
   9 use Socket          qw< :all >;
  10 require 5.005;
  11
  12
  13 {   no strict 'vars';
  14     $VERSION = '0.33';
  15
  16     %EXPORT_TAGS = (
  17         standard => [qw(openlog syslog closelog setlogmask)],
  18         extended => [qw(setlogsock)],
  19         macros => [
  20             # levels
  21             qw(
  22                 LOG_ALERT LOG_CRIT LOG_DEBUG LOG_EMERG LOG_ERR
  23                 LOG_INFO LOG_NOTICE LOG_WARNING
  24             ),
  25
  26             # standard facilities
  27             qw(
  28                 LOG_AUTH LOG_AUTHPRIV LOG_CRON LOG_DAEMON LOG_FTP LOG_KERN
  29                 LOG_LOCAL0 LOG_LOCAL1 LOG_LOCAL2 LOG_LOCAL3 LOG_LOCAL4
  30                 LOG_LOCAL5 LOG_LOCAL6 LOG_LOCAL7 LOG_LPR LOG_MAIL LOG_NEWS
  31                 LOG_SYSLOG LOG_USER LOG_UUCP
  32             ),
  33             # Mac OS X specific facilities
  34             qw( LOG_INSTALL LOG_LAUNCHD LOG_NETINFO LOG_RAS LOG_REMOTEAUTH ),
  35             # modern BSD specific facilities
  36             qw( LOG_CONSOLE LOG_NTP LOG_SECURITY ),
  37             # IRIX specific facilities
  38             qw( LOG_AUDIT LOG_LFMT ),
  39
  40             # options
  41             qw(
  42                 LOG_CONS LOG_PID LOG_NDELAY LOG_NOWAIT LOG_ODELAY LOG_PERROR
  43             ),
  44
  45             # others macros
  46             qw(
  47                 LOG_FACMASK LOG_NFACILITIES LOG_PRIMASK
  48                 LOG_MASK LOG_UPTO
  49             ),
  50         ],
  51     );
  52
  53     @EXPORT = (
  54         @{$EXPORT_TAGS{standard}},
  55     );
  56
  57     @EXPORT_OK = (
  58         @{$EXPORT_TAGS{extended}},
  59         @{$EXPORT_TAGS{macros}},
  60     );
  61
  62     eval {
  63         require XSLoader;
  64         XSLoader::load('Sys::Syslog', $VERSION);
  65         1
  66     } or do {
  67         require DynaLoader;
  68         push @ISA, 'DynaLoader';
  69         bootstrap Sys::Syslog $VERSION;
  70     };
  71 }
  72
  73
  74 #
  75 # Public variables
  76 #
  77 use vars qw($host);             # host to send syslog messages to (see notes at end)
  78
  79 #
  80 # Prototypes
  81 #
  82 sub silent_eval (&);
  83
  84 #
  85 # Global variables
  86 #
  87 use vars qw($facility);
  88 my $connected       = 0;        # flag to indicate if we're connected or not
  89 my $syslog_send;                # coderef of the function used to send messages
  90 my $syslog_path     = undef;    # syslog path for "stream" and "unix" mechanisms
  91 my $syslog_xobj     = undef;    # if defined, holds the external object used to send messages
  92 my $transmit_ok     = 0;        # flag to indicate if the last message was transmitted
  93 my $sock_port       = undef;    # socket port
  94 my $sock_timeout    = 0;        # socket timeout, see below
  95 my $current_proto   = undef;    # current mechanism used to transmit messages
  96 my $ident           = '';       # identifiant prepended to each message
  97 $facility           = '';       # current facility
  98 my $maskpri         = LOG_UPTO(&LOG_DEBUG);     # current log mask
  99
 100 my %options = (
 101     ndelay  => 0,
 102     noeol   => 0,
 103     nofatal => 0,
 104     nonul   => 0,
 105     nowait  => 0,
 106     perror  => 0,
 107     pid     => 0,
 108 );
 109
 110 # Default is now to first use the native mechanism, so Perl programs
 111 # behave like other normal Unix programs, then try other mechanisms.
 112 my @connectMethods = qw(native tcp udp unix pipe stream console);
 113 if ($^O eq "freebsd" or $^O eq "linux") {
 114     @connectMethods = grep { $_ ne 'udp' } @connectMethods;
 115 }
 116
 117 # And on Win32 systems, we try to use the native mechanism for this
 118 # platform, the events logger, available through Win32::EventLog.
 119 EVENTLOG: {
 120     my $is_Win32 = $^O =~ /Win32/i;
 121
 122     if (can_load("Sys::Syslog::Win32", $is_Win32)) {
 123         unshift @connectMethods, 'eventlog';
 124     }
 125 }
 126
 127 my @defaultMethods = @connectMethods;
 128 my @fallbackMethods = ();
 129
 130 # The timeout in connection_ok() was pushed up to 0.25 sec in
 131 # Sys::Syslog v0.19 in order to address a heisenbug on MacOSX:
 132 # http://london.pm.org/pipermail/london.pm/Week-of-Mon-20061211/005961.html
 133 #
 134 # However, this also had the effect of slowing this test for
 135 # all other operating systems, which apparently impacted some
 136 # users (cf. CPAN-RT #34753). So, in order to make everybody
 137 # happy, the timeout is now zero by default on all systems
 138 # except on OSX where it is set to 250 msec, and can be set
 139 # with the infamous setlogsock() function.
 140 #
 141 # Update 2011-08: this issue is also been seen on multiprocessor
 142 # Debian GNU/kFreeBSD systems. See http://bugs.debian.org/627821
 143 # and https://rt.cpan.org/Ticket/Display.html?id=69997
 144 # Also, lowering the delay to 1 ms, which should be enough.
 145
 146 $sock_timeout = 0.001 if $^O =~ /darwin|gnukfreebsd/;
 147
 148
 149 # Perl 5.6.0's warnings.pm doesn't have warnings::warnif()
 150 if (not defined &warnings::warnif) {
 151     *warnings::warnif = sub {
 152         goto &warnings::warn if warnings::enabled(__PACKAGE__)
 153     }
 154 }
 155
 156 # coderef for a nicer handling of errors
 157 my $err_sub = $options{nofatal} ? \&warnings::warnif : \&croak;
 158
 159
 160 sub AUTOLOAD {
 161     # This AUTOLOAD is used to 'autoload' constants from the constant()
 162     # XS function.
 163     no strict 'vars';
 164     my $constname;
 165     ($constname = $AUTOLOAD) =~ s/.*:://;
 166     croak "Sys::Syslog::constant() not defined" if $constname eq 'constant';
 167     my ($error, $val) = constant($constname);
 168     croak $error if $error;
 169     no strict 'refs';
 170     *$AUTOLOAD = sub { $val };
 171     goto &$AUTOLOAD;
 172 }
 173
 174
 175 sub openlog {
 176     ($ident, my $logopt, $facility) = @_;
 177
 178     # default values
 179     $ident    ||= basename($0) || getlogin() || getpwuid($<) || 'syslog';
 180     $logopt   ||= '';
 181     $facility ||= LOG_USER();
 182
 183     for my $opt (split /\b/, $logopt) {
 184         $options{$opt} = 1 if exists $options{$opt}
 185     }
 186
 187     $err_sub = delete $options{nofatal} ? \&warnings::warnif : \&croak;
 188     return 1 unless $options{ndelay};
 189     connect_log();
 190 }
 191
 192 sub closelog {
 193     disconnect_log() if $connected;
 194     $options{$_} = 0 for keys %options;
 195     $facility = $ident = "";
 196     $connected = 0;
 197     return 1
 198 }
 199
 200 sub setlogmask {
 201     my $oldmask = $maskpri;
 202     $maskpri = shift unless $_[0] == 0;
 203     $oldmask;
 204 }
 205
 206
 207 my %mechanism = (
 208     console => {
 209         check   => sub { 1 },
 210     },
 211     eventlog => {
 212         check   => sub { return can_load("Win32::EventLog") },
 213         err_msg => "no Win32 API available",
 214     },
 215     inet => {
 216         check   => sub { 1 },
 217     },
 218     native => {
 219         check   => sub { 1 },
 220     },
 221     pipe => {
 222         check   => sub {
 223             ($syslog_path) = grep { defined && length && -p && -w _ }
 224                                 $syslog_path, &_PATH_LOG, "/dev/log";
 225             return $syslog_path ? 1 : 0
 226         },
 227         err_msg => "path not available",
 228     },
 229     stream => {
 230         check   => sub {
 231             if (not defined $syslog_path) {
 232                 my @try = qw(/dev/log /dev/conslog);
 233                 unshift @try, &_PATH_LOG  if length &_PATH_LOG;
 234                 ($syslog_path) = grep { -w } @try;
 235             }
 236             return defined $syslog_path && -w $syslog_path
 237         },
 238         err_msg => "could not find any writable device",
 239     },
 240     tcp => {
 241         check   => sub {
 242             return 1 if defined $sock_port;
 243
 244             if (getservbyname('syslog', 'tcp') || getservbyname('syslogng', 'tcp')) {
 245                 $host = $syslog_path;
 246                 return 1
 247             }
 248             else {
 249                 return
 250             }
 251         },
 252         err_msg => "TCP service unavailable",
 253     },
 254     udp => {
 255         check   => sub {
 256             return 1 if defined $sock_port;
 257
 258             if (getservbyname('syslog', 'udp')) {
 259                 $host = $syslog_path;
 260                 return 1
 261             }
 262             else {
 263                 return
 264             }
 265         },
 266         err_msg => "UDP service unavailable",
 267     },
 268     unix => {
 269         check   => sub {
 270             my @try = ($syslog_path, &_PATH_LOG);
 271             ($syslog_path) = grep { defined && length && -w } @try;
 272             return defined $syslog_path && -w $syslog_path
 273         },
 274         err_msg => "path not available",
 275     },
 276 );
 277
 278 sub setlogsock {
 279     my %opt;
 280
 281     # handle arguments
 282     # - old API: setlogsock($sock_type, $sock_path, $sock_timeout)
 283     # - new API: setlogsock(\%options)
 284     croak "setlogsock(): Invalid number of arguments"
 285         unless @_ >= 1 and @_ <= 3;
 286
 287     if (my $ref = ref $_[0]) {
 288         if ($ref eq "HASH") {
 289             %opt = %{ $_[0] };
 290             croak "setlogsock(): No argument given" unless keys %opt;
 291         }
 292         elsif ($ref eq "ARRAY") {
 293             @opt{qw< type path timeout >} = @_;
 294         }
 295         else {
 296             croak "setlogsock(): Unexpected \L$ref\E reference"
 297         }
 298     }
 299     else {
 300         @opt{qw< type path timeout >} = @_;
 301     }
 302
 303     # check socket type, remove invalid ones
 304     my $diag_invalid_type = "setlogsock(): Invalid type%s; must be one of "
 305                           . join ", ", map { "'$_'" } sort keys %mechanism;
 306     croak sprintf $diag_invalid_type, "" unless defined $opt{type};
 307     my @sock_types = ref $opt{type} eq "ARRAY" ? @{$opt{type}} : ($opt{type});
 308     my @tmp;
 309
 310     for my $sock_type (@sock_types) {
 311         carp sprintf $diag_invalid_type, " '$sock_type'" and next
 312             unless exists $mechanism{$sock_type};
 313         push @tmp, "tcp", "udp" and next  if $sock_type eq "inet";
 314         push @tmp, $sock_type;
 315     }
 316
 317     @sock_types = @tmp;
 318
 319     # set global options
 320     $syslog_path  = $opt{path}    if defined $opt{path};
 321     $host         = $opt{host}    if defined $opt{host};
 322     $sock_timeout = $opt{timeout} if defined $opt{timeout};
 323     $sock_port    = $opt{port}    if defined $opt{port};
 324
 325     disconnect_log() if $connected;
 326     $transmit_ok = 0;
 327     @fallbackMethods = ();
 328     @connectMethods = ();
 329     my $found = 0;
 330
 331     # check each given mechanism and test if it can be used on the current system
 332     for my $sock_type (@sock_types) {
 333         if ( $mechanism{$sock_type}{check}->() ) {
 334             push @connectMethods, $sock_type;
 335             $found = 1;
 336         }
 337         else {
 338             warnings::warnif("setlogsock(): type='$sock_type': "
 339                            . $mechanism{$sock_type}{err_msg});
 340         }
 341     }
 342
 343     # if no mechanism worked from the given ones, use the default ones
 344     @connectMethods = @defaultMethods unless @connectMethods;
 345
 346     return $found;
 347 }
 348
 349 sub syslog {
 350     my ($priority, $mask, @args) = @_;
 351     my ($message, $buf);
 352     my (@words, $num, $numpri, $numfac, $sum);
 353     my $failed = undef;
 354     my $fail_time = undef;
 355     my $error = $!;
 356
 357     # if $ident is undefined, it means openlog() wasn't previously called
 358     # so do it now in order to have sensible defaults
 359     openlog() unless $ident;
 360
 361     local $facility = $facility;    # may need to change temporarily.
 362
 363     croak "syslog: expecting argument \$priority" unless defined $priority;
 364     croak "syslog: expecting argument \$format"   unless defined $mask;
 365
 366     if ($priority =~ /^\d+$/) {
 367         $numpri = LOG_PRI($priority);
 368         $numfac = LOG_FAC($priority) << 3;
 369     }
 370     elsif ($priority =~ /^\w+/) {
 371         # Allow "level" or "level|facility".
 372         @words = split /\W+/, $priority, 2;
 373
 374         undef $numpri;
 375         undef $numfac;
 376
 377         for my $word (@words) {
 378             next if length $word == 0;
 379
 380             # Translate word to number.
 381             $num = xlate($word);
 382
 383             if ($num < 0) {
 384                 croak "syslog: invalid level/facility: $word"
 385             }
 386             elsif ($num <= LOG_PRIMASK() and $word ne "kern") {
 387                 croak "syslog: too many levels given: $word"
 388                     if defined $numpri;
 389                 $numpri = $num;
 390             }
 391             else {
 392                 croak "syslog: too many facilities given: $word"
 393                     if defined $numfac;
 394                 $facility = $word if $word =~ /^[A-Za-z]/;
 395                 $numfac = $num;
 396             }
 397         }
 398     }
 399     else {
 400         croak "syslog: invalid level/facility: $priority"
 401     }
 402
 403     croak "syslog: level must be given" unless defined $numpri;
 404
 405     # don't log if priority is below mask level
 406     return 0 unless LOG_MASK($numpri) & $maskpri;
 407
 408     if (not defined $numfac) {  # Facility not specified in this call.
 409         $facility = 'user' unless $facility;
 410         $numfac = xlate($facility);
 411     }
 412
 413     connect_log() unless $connected;
 414
 415     if ($mask =~ /%m/) {
 416         # escape percent signs for sprintf()
 417         $error =~ s/%/%%/g if @args;
 418         # replace %m with $error, if preceded by an even number of percent signs
 419         $mask =~ s/(?<!%)((?:%%)*)%m/$1$error/g;
 420     }
 421
 422     $mask .= "\n" unless $mask =~ /\n$/;
 423     $message = @args ? sprintf($mask, @args) : $mask;
 424
 425     if ($current_proto eq 'native') {
 426         $buf = $message;
 427     }
 428     elsif ($current_proto eq 'eventlog') {
 429         $buf = $message;
 430     }
 431     else {
 432         my $whoami = $ident;
 433         $whoami .= "[$$]" if $options{pid};
 434
 435         $sum = $numpri + $numfac;
 436         my $oldlocale = setlocale(LC_TIME);
 437         setlocale(LC_TIME, 'C');
 438         my $timestamp = strftime "%b %d %H:%M:%S", localtime;
 439         setlocale(LC_TIME, $oldlocale);
 440
 441         # construct the stream that will be transmitted
 442         $buf = "<$sum>$timestamp $whoami: $message";
 443
 444         # add (or not) a newline
 445         $buf .= "\n" if !$options{noeol} and rindex($buf, "\n") == -1;
 446
 447         # add (or not) a NUL character
 448         $buf .= "\0" if !$options{nonul};
 449     }
 450
 451     # handle PERROR option
 452     # "native" mechanism already handles it by itself
 453     if ($options{perror} and $current_proto ne 'native') {
 454         my $whoami = $ident;
 455         $whoami .= "[$$]" if $options{pid};
 456         print STDERR "$whoami: $message\n";
 457     }
 458
 459     # it's possible that we'll get an error from sending
 460     # (e.g. if method is UDP and there is no UDP listener,
 461     # then we'll get ECONNREFUSED on the send). So what we
 462     # want to do at this point is to fallback onto a different
 463     # connection method.
 464     while (scalar @fallbackMethods || $syslog_send) {
 465         if ($failed && (time - $fail_time) > 60) {
 466             # it's been a while... maybe things have been fixed
 467             @fallbackMethods = ();
 468             disconnect_log();
 469             $transmit_ok = 0; # make it look like a fresh attempt
 470             connect_log();
 471         }
 472
 473         if ($connected && !connection_ok()) {
 474             # Something was OK, but has now broken. Remember coz we'll
 475             # want to go back to what used to be OK.
 476             $failed = $current_proto unless $failed;
 477             $fail_time = time;
 478             disconnect_log();
 479         }
 480
 481         connect_log() unless $connected;
 482         $failed = undef if ($current_proto && $failed && $current_proto eq $failed);
 483
 484         if ($syslog_send) {
 485             if ($syslog_send->($buf, $numpri, $numfac)) {
 486                 $transmit_ok++;
 487                 return 1;
 488             }
 489             # typically doesn't happen, since errors are rare from write().
 490             disconnect_log();
 491         }
 492     }
 493     # could not send, could not fallback onto a working
 494     # connection method. Lose.
 495     return 0;
 496 }
 497
 498 sub _syslog_send_console {
 499     my ($buf) = @_;
 500
 501     # The console print is a method which could block
 502     # so we do it in a child process and always return success
 503     # to the caller.
 504     if (my $pid = fork) {
 505
 506         if ($options{nowait}) {
 507             return 1;
 508         } else {
 509             if (waitpid($pid, 0) >= 0) {
 510                 return ($? >> 8);
 511             } else {
 512                 # it's possible that the caller has other
 513                 # plans for SIGCHLD, so let's not interfere
 514                 return 1;
 515             }
 516         }
 517     } else {
 518         if (open(CONS, ">/dev/console")) {
 519             my $ret = print CONS $buf . "\r";  # XXX: should this be \x0A ?
 520             POSIX::_exit($ret) if defined $pid;
 521             close CONS;
 522         }
 523
 524         POSIX::_exit(0) if defined $pid;
 525     }
 526 }
 527
 528 sub _syslog_send_stream {
 529     my ($buf) = @_;
 530     # XXX: this only works if the OS stream implementation makes a write
 531     # look like a putmsg() with simple header. For instance it works on
 532     # Solaris 8 but not Solaris 7.
 533     # To be correct, it should use a STREAMS API, but perl doesn't have one.
 534     return syswrite(SYSLOG, $buf, length($buf));
 535 }
 536
 537 sub _syslog_send_pipe {
 538     my ($buf) = @_;
 539     return print SYSLOG $buf;
 540 }
 541
 542 sub _syslog_send_socket {
 543     my ($buf) = @_;
 544     return syswrite(SYSLOG, $buf, length($buf));
 545     #return send(SYSLOG, $buf, 0);
 546 }
 547
 548 sub _syslog_send_native {
 549     my ($buf, $numpri, $numfac) = @_;
 550     syslog_xs($numpri|$numfac, $buf);
 551     return 1;
 552 }
 553
 554
 555 # xlate()
 556 # -----
 557 # private function to translate names to numeric values
 558 #
 559 sub xlate {
 560     my ($name) = @_;
 561
 562     return $name+0 if $name =~ /^\s*\d+\s*$/;
 563     $name = uc $name;
 564     $name = "LOG_$name" unless $name =~ /^LOG_/;
 565
 566     # ExtUtils::Constant 0.20 introduced a new way to implement
 567     # constants, called ProxySubs.  When it was used to generate
 568     # the C code, the constant() function no longer returns the
 569     # correct value.  Therefore, we first try a direct call to
 570     # constant(), and if the value is an error we try to call the
 571     # constant by its full name.
 572     my $value = constant($name);
 573
 574     if (index($value, "not a valid") >= 0) {
 575         $name = "Sys::Syslog::$name";
 576         $value = eval { no strict "refs"; &$name };
 577         $value = $@ unless defined $value;
 578     }
 579
 580     $value = -1 if index($value, "not a valid") >= 0;
 581
 582     return defined $value ? $value : -1;
 583 }
 584
 585
 586 # connect_log()
 587 # -----------
 588 # This function acts as a kind of front-end: it tries to connect to
 589 # a syslog service using the selected methods, trying each one in the
 590 # selected order.
 591 #
 592 sub connect_log {
 593     @fallbackMethods = @connectMethods unless scalar @fallbackMethods;
 594
 595     if ($transmit_ok && $current_proto) {
 596         # Retry what we were on, because it has worked in the past.
 597         unshift(@fallbackMethods, $current_proto);
 598     }
 599
 600     $connected = 0;
 601     my @errs = ();
 602     my $proto = undef;
 603
 604     while ($proto = shift @fallbackMethods) {
 605         no strict 'refs';
 606         my $fn = "connect_$proto";
 607         $connected = &$fn(\@errs) if defined &$fn;
 608         last if $connected;
 609     }
 610
 611     $transmit_ok = 0;
 612     if ($connected) {
 613         $current_proto = $proto;
 614         my ($old) = select(SYSLOG); $| = 1; select($old);
 615     } else {
 616         @fallbackMethods = ();
 617         $err_sub->(join "\n\t- ", "no connection to syslog available", @errs);
 618         return undef;
 619     }
 620 }
 621
 622 sub connect_tcp {
 623     my ($errs) = @_;
 624
 625     my $proto = getprotobyname('tcp');
 626     if (!defined $proto) {
 627         push @$errs, "getprotobyname failed for tcp";
 628         return 0;
 629     }
 630
 631     my $port = $sock_port || getservbyname('syslog', 'tcp');
 632     $port = getservbyname('syslogng', 'tcp') unless defined $port;
 633     if (!defined $port) {
 634         push @$errs, "getservbyname failed for syslog/tcp and syslogng/tcp";
 635         return 0;
 636     }
 637
 638     my $addr;
 639     if (defined $host) {
 640         $addr = inet_aton($host);
 641         if (!$addr) {
 642             push @$errs, "can't lookup $host";
 643             return 0;
 644         }
 645     } else {
 646         $addr = INADDR_LOOPBACK;
 647     }
 648     $addr = sockaddr_in($port, $addr);
 649
 650     if (!socket(SYSLOG, AF_INET, SOCK_STREAM, $proto)) {
 651         push @$errs, "tcp socket: $!";
 652         return 0;
 653     }
 654
 655     setsockopt(SYSLOG, SOL_SOCKET, SO_KEEPALIVE, 1);
 656     if (silent_eval { IPPROTO_TCP() }) {
 657         # These constants don't exist in 5.005. They were added in 1999
 658         setsockopt(SYSLOG, IPPROTO_TCP(), TCP_NODELAY(), 1);
 659     }
 660     if (!connect(SYSLOG, $addr)) {
 661         push @$errs, "tcp connect: $!";
 662         return 0;
 663     }
 664
 665     $syslog_send = \&_syslog_send_socket;
 666
 667     return 1;
 668 }
 669
 670 sub connect_udp {
 671     my ($errs) = @_;
 672
 673     my $proto = getprotobyname('udp');
 674     if (!defined $proto) {
 675         push @$errs, "getprotobyname failed for udp";
 676         return 0;
 677     }
 678
 679     my $port = $sock_port || getservbyname('syslog', 'udp');
 680     if (!defined $port) {
 681         push @$errs, "getservbyname failed for syslog/udp";
 682         return 0;
 683     }
 684
 685     my $addr;
 686     if (defined $host) {
 687         $addr = inet_aton($host);
 688         if (!$addr) {
 689             push @$errs, "can't lookup $host";
 690             return 0;
 691         }
 692     } else {
 693         $addr = INADDR_LOOPBACK;
 694     }
 695     $addr = sockaddr_in($port, $addr);
 696
 697     if (!socket(SYSLOG, AF_INET, SOCK_DGRAM, $proto)) {
 698         push @$errs, "udp socket: $!";
 699         return 0;
 700     }
 701     if (!connect(SYSLOG, $addr)) {
 702         push @$errs, "udp connect: $!";
 703         return 0;
 704     }
 705
 706     # We want to check that the UDP connect worked. However the only
 707     # way to do that is to send a message and see if an ICMP is returned
 708     _syslog_send_socket("");
 709     if (!connection_ok()) {
 710         push @$errs, "udp connect: nobody listening";
 711         return 0;
 712     }
 713
 714     $syslog_send = \&_syslog_send_socket;
 715
 716     return 1;
 717 }
 718
 719 sub connect_stream {
 720     my ($errs) = @_;
 721     # might want syslog_path to be variable based on syslog.h (if only
 722     # it were in there!)
 723     $syslog_path = '/dev/conslog' unless defined $syslog_path;
 724
 725     if (!-w $syslog_path) {
 726         push @$errs, "stream $syslog_path is not writable";
 727         return 0;
 728     }
 729
 730     require Fcntl;
 731
 732     if (!sysopen(SYSLOG, $syslog_path, Fcntl::O_WRONLY(), 0400)) {
 733         push @$errs, "stream can't open $syslog_path: $!";
 734         return 0;
 735     }
 736
 737     $syslog_send = \&_syslog_send_stream;
 738
 739     return 1;
 740 }
 741
 742 sub connect_pipe {
 743     my ($errs) = @_;
 744
 745     $syslog_path ||= &_PATH_LOG || "/dev/log";
 746
 747     if (not -w $syslog_path) {
 748         push @$errs, "$syslog_path is not writable";
 749         return 0;
 750     }
 751
 752     if (not open(SYSLOG, ">$syslog_path")) {
 753         push @$errs, "can't write to $syslog_path: $!";
 754         return 0;
 755     }
 756
 757     $syslog_send = \&_syslog_send_pipe;
 758
 759     return 1;
 760 }
 761
 762 sub connect_unix {
 763     my ($errs) = @_;
 764
 765     $syslog_path ||= _PATH_LOG() if length _PATH_LOG();
 766
 767     if (not defined $syslog_path) {
 768         push @$errs, "_PATH_LOG not available in syslog.h and no user-supplied socket path";
 769         return 0;
 770     }
 771
 772     if (not (-S $syslog_path or -c _)) {
 773         push @$errs, "$syslog_path is not a socket";
 774         return 0;
 775     }
 776
 777     my $addr = sockaddr_un($syslog_path);
 778     if (!$addr) {
 779         push @$errs, "can't locate $syslog_path";
 780         return 0;
 781     }
 782     if (!socket(SYSLOG, AF_UNIX, SOCK_STREAM, 0)) {
 783         push @$errs, "unix stream socket: $!";
 784         return 0;
 785     }
 786
 787     if (!connect(SYSLOG, $addr)) {
 788         if (!socket(SYSLOG, AF_UNIX, SOCK_DGRAM, 0)) {
 789             push @$errs, "unix dgram socket: $!";
 790             return 0;
 791         }
 792         if (!connect(SYSLOG, $addr)) {
 793             push @$errs, "unix dgram connect: $!";
 794             return 0;
 795         }
 796     }
 797
 798     $syslog_send = \&_syslog_send_socket;
 799
 800     return 1;
 801 }
 802
 803 sub connect_native {
 804     my ($errs) = @_;
 805     my $logopt = 0;
 806
 807     # reconstruct the numeric equivalent of the options
 808     for my $opt (keys %options) {
 809         $logopt += xlate($opt) if $options{$opt}
 810     }
 811
 812     openlog_xs($ident, $logopt, xlate($facility));
 813     $syslog_send = \&_syslog_send_native;
 814
 815     return 1;
 816 }
 817
 818 sub connect_eventlog {
 819     my ($errs) = @_;
 820
 821     $syslog_xobj = Sys::Syslog::Win32::_install();
 822     $syslog_send = \&Sys::Syslog::Win32::_syslog_send;
 823
 824     return 1;
 825 }
 826
 827 sub connect_console {
 828     my ($errs) = @_;
 829     if (!-w '/dev/console') {
 830         push @$errs, "console is not writable";
 831         return 0;
 832     }
 833     $syslog_send = \&_syslog_send_console;
 834     return 1;
 835 }
 836
 837 # To test if the connection is still good, we need to check if any
 838 # errors are present on the connection. The errors will not be raised
 839 # by a write. Instead, sockets are made readable and the next read
 840 # would cause the error to be returned. Unfortunately the syslog
 841 # 'protocol' never provides anything for us to read. But with
 842 # judicious use of select(), we can see if it would be readable...
 843 sub connection_ok {
 844     return 1 if defined $current_proto and (
 845         $current_proto eq 'native' or $current_proto eq 'console'
 846         or $current_proto eq 'eventlog'
 847     );
 848
 849     my $rin = '';
 850     vec($rin, fileno(SYSLOG), 1) = 1;
 851     my $ret = select $rin, undef, $rin, $sock_timeout;
 852     return ($ret ? 0 : 1);
 853 }
 854
 855 sub disconnect_log {
 856     $connected = 0;
 857     $syslog_send = undef;
 858
 859     if (defined $current_proto and $current_proto eq 'native') {
 860         closelog_xs();
 861         unshift @fallbackMethods, $current_proto;
 862         $current_proto = undef;
 863         return 1;
 864     }
 865     elsif (defined $current_proto and $current_proto eq 'eventlog') {
 866         $syslog_xobj->Close();
 867         unshift @fallbackMethods, $current_proto;
 868         $current_proto = undef;
 869         return 1;
 870     }
 871
 872     return close SYSLOG;
 873 }
 874
 875
 876 #
 877 # Wrappers around eval() that makes sure that nobody, and I say NOBODY,
 878 # ever knows that I wanted to test if something was here or not.
 879 # It is needed because some applications are trying to be too smart,
 880 # do it wrong, and it ends up in EPIC FAIL.
 881 # Yes I'm speaking of YOU, SpamAssassin.
 882 #
 883 sub silent_eval (&) {
 884     local($SIG{__DIE__}, $SIG{__WARN__}, $@);
 885     return eval { $_[0]->() }
 886 }
 887
 888 sub can_load {
 889     my ($module, $verbose) = @_;
 890     local($SIG{__DIE__}, $SIG{__WARN__}, $@);
 891     my $loaded = eval "use $module; 1";
 892     warn $@ if not $loaded and $verbose;
 893     return $loaded
 894 }
 895
 896
 897 "Eighth Rule: read the documentation."
 898
 899 __END__
 900
 901 =head1 NAME
 902
 903 Sys::Syslog - Perl interface to the UNIX syslog(3) calls
 904
 905 =head1 VERSION
 906
 907 This is the documentation of version 0.33
 908
 909 =head1 SYNOPSIS
 910
 911     use Sys::Syslog;                        # all except setlogsock()
 912     use Sys::Syslog qw(:standard :macros);  # standard functions & macros
 913
 914     openlog($ident, $logopt, $facility);    # don't forget this
 915     syslog($priority, $format, @args);
 916     $oldmask = setlogmask($mask_priority);
 917     closelog();
 918
 919
 920 =head1 DESCRIPTION
 921
 922 C<Sys::Syslog> is an interface to the UNIX C<syslog(3)> program.
 923 Call C<syslog()> with a string priority and a list of C<printf()> args
 924 just like C<syslog(3)>.
 925
 926
 927 =head1 EXPORTS
 928
 929 C<Sys::Syslog> exports the following C<Exporter> tags:
 930
 931 =over 4
 932
 933 =item *
 934
 935 C<:standard> exports the standard C<syslog(3)> functions:
 936
 937     openlog closelog setlogmask syslog
 938
 939 =item *
 940
 941 C<:extended> exports the Perl specific functions for C<syslog(3)>:
 942
 943     setlogsock
 944
 945 =item *
 946
 947 C<:macros> exports the symbols corresponding to most of your C<syslog(3)>
 948 macros and the C<LOG_UPTO()> and C<LOG_MASK()> functions.
 949 See L<"CONSTANTS"> for the supported constants and their meaning.
 950
 951 =back
 952
 953 By default, C<Sys::Syslog> exports the symbols from the C<:standard> tag.
 954
 955
 956 =head1 FUNCTIONS
 957
 958 =over 4
 959
 960 =item B<openlog($ident, $logopt, $facility)>
 961
 962 Opens the syslog.
 963 C<$ident> is prepended to every message.  C<$logopt> contains zero or
 964 more of the options detailed below.  C<$facility> specifies the part
 965 of the system to report about, for example C<LOG_USER> or C<LOG_LOCAL0>:
 966 see L<"Facilities"> for a list of well-known facilities, and your
 967 C<syslog(3)> documentation for the facilities available in your system.
 968 Check L<"SEE ALSO"> for useful links. Facility can be given as a string
 969 or a numeric macro.
 970
 971 This function will croak if it can't connect to the syslog daemon.
 972
 973 Note that C<openlog()> now takes three arguments, just like C<openlog(3)>.
 974
 975 B<You should use C<openlog()> before calling C<syslog()>.>
 976
 977 B<Options>
 978
 979 =over 4
 980
 981 =item *
 982
 983 C<cons> - This option is ignored, since the failover mechanism will drop
 984 down to the console automatically if all other media fail.
 985
 986 =item *
 987
 988 C<ndelay> - Open the connection immediately (normally, the connection is
 989 opened when the first message is logged).
 990
 991 =item *
 992
 993 C<noeol> - When set to true, no end of line character (C<\n>) will be
 994 appended to the message. This can be useful for some buggy syslog daemons.
 995
 996 =item *
 997
 998 C<nofatal> - When set to true, C<openlog()> and C<syslog()> will only
 999 emit warnings instead of dying if the connection to the syslog can't
1000 be established.
1001
1002 =item *
1003
1004 C<nonul> - When set to true, no C<NUL> character (C<\0>) will be
1005 appended to the message. This can be useful for some buggy syslog daemons.
1006
1007 =item *
1008
1009 C<nowait> - Don't wait for child processes that may have been created
1010 while logging the message.  (The GNU C library does not create a child
1011 process, so this option has no effect on Linux.)
1012
1013 =item *
1014
1015 C<perror> - Write the message to standard error output as well to the
1016 system log (added in C<Sys::Syslog> 0.22).
1017
1018 =item *
1019
1020 C<pid> - Include PID with each message.
1021
1022 =back
1023
1024 B<Examples>
1025
1026 Open the syslog with options C<ndelay> and C<pid>, and with facility C<LOCAL0>:
1027
1028     openlog($name, "ndelay,pid", "local0");
1029
1030 Same thing, but this time using the macro corresponding to C<LOCAL0>:
1031
1032     openlog($name, "ndelay,pid", LOG_LOCAL0);
1033
1034
1035 =item B<syslog($priority, $message)>
1036
1037 =item B<syslog($priority, $format, @args)>
1038
1039 If C<$priority> permits, logs C<$message> or C<sprintf($format, @args)>
1040 with the addition that C<%m> in $message or C<$format> is replaced with
1041 C<"$!"> (the latest error message).
1042
1043 C<$priority> can specify a level, or a level and a facility.  Levels and
1044 facilities can be given as strings or as macros.  When using the C<eventlog>
1045 mechanism, priorities C<DEBUG> and C<INFO> are mapped to event type
1046 C<informational>, C<NOTICE> and C<WARNING> to C<warning> and C<ERR> to
1047 C<EMERG> to C<error>.
1048
1049 If you didn't use C<openlog()> before using C<syslog()>, C<syslog()> will
1050 try to guess the C<$ident> by extracting the shortest prefix of
1051 C<$format> that ends in a C<":">.
1052
1053 B<Examples>
1054
1055     # informational level
1056     syslog("info", $message);
1057     syslog(LOG_INFO, $message);
1058
1059     # information level, Local0 facility
1060     syslog("info|local0", $message);
1061     syslog(LOG_INFO|LOG_LOCAL0, $message);
1062
1063 =over 4
1064
1065 =item B<Note>
1066
1067 C<Sys::Syslog> version v0.07 and older passed the C<$message> as the
1068 formatting string to C<sprintf()> even when no formatting arguments
1069 were provided.  If the code calling C<syslog()> might execute with
1070 older versions of this module, make sure to call the function as
1071 C<syslog($priority, "%s", $message)> instead of C<syslog($priority,
1072 $message)>.  This protects against hostile formatting sequences that
1073 might show up if $message contains tainted data.
1074
1075 =back
1076
1077
1078 =item B<setlogmask($mask_priority)>
1079
1080 Sets the log mask for the current process to C<$mask_priority> and
1081 returns the old mask.  If the mask argument is 0, the current log mask
1082 is not modified.  See L<"Levels"> for the list of available levels.
1083 You can use the C<LOG_UPTO()> function to allow all levels up to a
1084 given priority (but it only accept the numeric macros as arguments).
1085
1086 B<Examples>
1087
1088 Only log errors:
1089
1090     setlogmask( LOG_MASK(LOG_ERR) );
1091
1092 Log everything except informational messages:
1093
1094     setlogmask( ~(LOG_MASK(LOG_INFO)) );
1095
1096 Log critical messages, errors and warnings:
1097
1098     setlogmask( LOG_MASK(LOG_CRIT)
1099               | LOG_MASK(LOG_ERR)
1100               | LOG_MASK(LOG_WARNING) );
1101
1102 Log all messages up to debug:
1103
1104     setlogmask( LOG_UPTO(LOG_DEBUG) );
1105
1106
1107 =item B<setlogsock()>
1108
1109 Sets the socket type and options to be used for the next call to C<openlog()>
1110 or C<syslog()>.  Returns true on success, C<undef> on failure.
1111
1112 Being Perl-specific, this function has evolved along time.  It can currently
1113 be called as follow:
1114
1115 =over
1116
1117 =item *
1118
1119 C<setlogsock($sock_type)>
1120
1121 =item *
1122
1123 C<setlogsock($sock_type, $stream_location)> (added in Perl 5.004_02)
1124
1125 =item *
1126
1127 C<setlogsock($sock_type, $stream_location, $sock_timeout)> (added in
1128 C<Sys::Syslog> 0.25)
1129
1130 =item *
1131
1132 C<setlogsock(\%options)> (added in C<Sys::Syslog> 0.28)
1133
1134 =back
1135
1136 The available options are:
1137
1138 =over
1139
1140 =item *
1141
1142 C<type> - equivalent to C<$sock_type>, selects the socket type (or
1143 "mechanism").  An array reference can be passed to specify several
1144 mechanisms to try, in the given order.
1145
1146 =item *
1147
1148 C<path> - equivalent to C<$stream_location>, sets the stream location.
1149 Defaults to standard Unix location, or C<_PATH_LOG>.
1150
1151 =item *
1152
1153 C<timeout> - equivalent to C<$sock_timeout>, sets the socket timeout
1154 in seconds.  Defaults to 0 on all systems except S<Mac OS X> where it
1155 is set to 0.25 sec.
1156
1157 =item *
1158
1159 C<host> - sets the hostname to send the messages to.  Defaults to
1160 the local host.
1161
1162 =item *
1163
1164 C<port> - sets the TCP or UDP port to connect to.  Defaults to the
1165 first standard syslog port available on the system.
1166
1167 =back
1168
1169
1170 The available mechanisms are:
1171
1172 =over
1173
1174 =item *
1175
1176 C<"native"> - use the native C functions from your C<syslog(3)> library
1177 (added in C<Sys::Syslog> 0.15).
1178
1179 =item *
1180
1181 C<"eventlog"> - send messages to the Win32 events logger (Win32 only;
1182 added in C<Sys::Syslog> 0.19).
1183
1184 =item *
1185
1186 C<"tcp"> - connect to a TCP socket, on the C<syslog/tcp> or C<syslogng/tcp>
1187 service.  See also the C<host>, C<port> and C<timeout> options.
1188
1189 =item *
1190
1191 C<"udp"> - connect to a UDP socket, on the C<syslog/udp> service.
1192 See also the C<host>, C<port> and C<timeout> options.
1193
1194 =item *
1195
1196 C<"inet"> - connect to an INET socket, either TCP or UDP, tried in that
1197 order.  See also the C<host>, C<port> and C<timeout> options.
1198
1199 =item *
1200
1201 C<"unix"> - connect to a UNIX domain socket (in some systems a character
1202 special device).  The name of that socket is given by the C<path> option
1203 or, if omitted, the value returned by the C<_PATH_LOG> macro (if your
1204 system defines it), F</dev/log> or F</dev/conslog>, whichever is writable.
1205
1206 =item *
1207
1208 C<"stream"> - connect to the stream indicated by the C<path> option, or,
1209 if omitted, the value returned by the C<_PATH_LOG> macro (if your system
1210 defines it), F</dev/log> or F</dev/conslog>, whichever is writable.  For
1211 example Solaris and IRIX system may prefer C<"stream"> instead of C<"unix">.
1212
1213 =item *
1214
1215 C<"pipe"> - connect to the named pipe indicated by the C<path> option,
1216 or, if omitted, to the value returned by the C<_PATH_LOG> macro (if your
1217 system defines it), or F</dev/log> (added in C<Sys::Syslog> 0.21).
1218 HP-UX is a system which uses such a named pipe.
1219
1220 =item *
1221
1222 C<"console"> - send messages directly to the console, as for the C<"cons">
1223 option of C<openlog()>.
1224
1225 =back
1226
1227 The default is to try C<native>, C<tcp>, C<udp>, C<unix>, C<pipe>, C<stream>,
1228 C<console>.
1229 Under systems with the Win32 API, C<eventlog> will be added as the first
1230 mechanism to try if C<Win32::EventLog> is available.
1231
1232 Giving an invalid value for C<$sock_type> will C<croak>.
1233
1234 B<Examples>
1235
1236 Select the UDP socket mechanism:
1237
1238     setlogsock("udp");
1239
1240 Send messages using the TCP socket mechanism on a custom port:
1241
1242     setlogsock({ type => "tcp", port => 2486 });
1243
1244 Send messages to a remote host using the TCP socket mechanism:
1245
1246     setlogsock({ type => "tcp", host => $loghost });
1247
1248 Try the native, UDP socket then UNIX domain socket mechanisms:
1249
1250     setlogsock(["native", "udp", "unix"]);
1251
1252 =over
1253
1254 =item B<Note>
1255
1256 Now that the "native" mechanism is supported by C<Sys::Syslog> and selected
1257 by default, the use of the C<setlogsock()> function is discouraged because
1258 other mechanisms are less portable across operating systems.  Authors of
1259 modules and programs that use this function, especially its cargo-cult form
1260 C<setlogsock("unix")>, are advised to remove any occurrence of it unless they
1261 specifically want to use a given mechanism (like TCP or UDP to connect to
1262 a remote host).
1263
1264 =back
1265
1266 =item B<closelog()>
1267
1268 Closes the log file and returns true on success.
1269
1270 =back
1271
1272
1273 =head1 THE RULES OF SYS::SYSLOG
1274
1275 I<The First Rule of Sys::Syslog is:>
1276 You do not call C<setlogsock>.
1277
1278 I<The Second Rule of Sys::Syslog is:>
1279 You B<do not> call C<setlogsock>.
1280
1281 I<The Third Rule of Sys::Syslog is:>
1282 The program crashes, C<die>s, calls C<closelog>, the log is over.
1283
1284 I<The Fourth Rule of Sys::Syslog is:>
1285 One facility, one priority.
1286
1287 I<The Fifth Rule of Sys::Syslog is:>
1288 One log at a time.
1289
1290 I<The Sixth Rule of Sys::Syslog is:>
1291 No C<syslog> before C<openlog>.
1292
1293 I<The Seventh Rule of Sys::Syslog is:>
1294 Logs will go on as long as they have to.
1295
1296 I<The Eighth, and Final Rule of Sys::Syslog is:>
1297 If this is your first use of Sys::Syslog, you must read the doc.
1298
1299
1300 =head1 EXAMPLES
1301
1302 An example:
1303
1304     openlog($program, 'cons,pid', 'user');
1305     syslog('info', '%s', 'this is another test');
1306     syslog('mail|warning', 'this is a better test: %d', time);
1307     closelog();
1308
1309     syslog('debug', 'this is the last test');
1310
1311 Another example:
1312
1313     openlog("$program $$", 'ndelay', 'user');
1314     syslog('notice', 'fooprogram: this is really done');
1315
1316 Example of use of C<%m>:
1317
1318     $! = 55;
1319     syslog('info', 'problem was %m');   # %m == $! in syslog(3)
1320
1321 Log to UDP port on C<$remotehost> instead of logging locally:
1322
1323     setlogsock("udp", $remotehost);
1324     openlog($program, 'ndelay', 'user');
1325     syslog('info', 'something happened over here');
1326
1327
1328 =head1 CONSTANTS
1329
1330 =head2 Facilities
1331
1332 =over 4
1333
1334 =item *
1335
1336 C<LOG_AUDIT> - audit daemon (IRIX); falls back to C<LOG_AUTH>
1337
1338 =item *
1339
1340 C<LOG_AUTH> - security/authorization messages
1341
1342 =item *
1343
1344 C<LOG_AUTHPRIV> - security/authorization messages (private)
1345
1346 =item *
1347
1348 C<LOG_CONSOLE> - C</dev/console> output (FreeBSD); falls back to C<LOG_USER>
1349
1350 =item *
1351
1352 C<LOG_CRON> - clock daemons (B<cron> and B<at>)
1353
1354 =item *
1355
1356 C<LOG_DAEMON> - system daemons without separate facility value
1357
1358 =item *
1359
1360 C<LOG_FTP> - FTP daemon
1361
1362 =item *
1363
1364 C<LOG_KERN> - kernel messages
1365
1366 =item *
1367
1368 C<LOG_INSTALL> - installer subsystem (Mac OS X); falls back to C<LOG_USER>
1369
1370 =item *
1371
1372 C<LOG_LAUNCHD> - launchd - general bootstrap daemon (Mac OS X);
1373 falls back to C<LOG_DAEMON>
1374
1375 =item *
1376
1377 C<LOG_LFMT> - logalert facility; falls back to C<LOG_USER>
1378
1379 =item *
1380
1381 C<LOG_LOCAL0> through C<LOG_LOCAL7> - reserved for local use
1382
1383 =item *
1384
1385 C<LOG_LPR> - line printer subsystem
1386
1387 =item *
1388
1389 C<LOG_MAIL> - mail subsystem
1390
1391 =item *
1392
1393 C<LOG_NETINFO> - NetInfo subsystem (Mac OS X); falls back to C<LOG_DAEMON>
1394
1395 =item *
1396
1397 C<LOG_NEWS> - USENET news subsystem
1398
1399 =item *
1400
1401 C<LOG_NTP> - NTP subsystem (FreeBSD, NetBSD); falls back to C<LOG_DAEMON>
1402
1403 =item *
1404
1405 C<LOG_RAS> - Remote Access Service (VPN / PPP) (Mac OS X);
1406 falls back to C<LOG_AUTH>
1407
1408 =item *
1409
1410 C<LOG_REMOTEAUTH> - remote authentication/authorization (Mac OS X);
1411 falls back to C<LOG_AUTH>
1412
1413 =item *
1414
1415 C<LOG_SECURITY> - security subsystems (firewalling, etc.) (FreeBSD);
1416 falls back to C<LOG_AUTH>
1417
1418 =item *
1419
1420 C<LOG_SYSLOG> - messages generated internally by B<syslogd>
1421
1422 =item *
1423
1424 C<LOG_USER> (default) - generic user-level messages
1425
1426 =item *
1427
1428 C<LOG_UUCP> - UUCP subsystem
1429
1430 =back
1431
1432
1433 =head2 Levels
1434
1435 =over 4
1436
1437 =item *
1438
1439 C<LOG_EMERG> - system is unusable
1440
1441 =item *
1442
1443 C<LOG_ALERT> - action must be taken immediately
1444
1445 =item *
1446
1447 C<LOG_CRIT> - critical conditions
1448
1449 =item *
1450
1451 C<LOG_ERR> - error conditions
1452
1453 =item *
1454
1455 C<LOG_WARNING> - warning conditions
1456
1457 =item *
1458
1459 C<LOG_NOTICE> - normal, but significant, condition
1460
1461 =item *
1462
1463 C<LOG_INFO> - informational message
1464
1465 =item *
1466
1467 C<LOG_DEBUG> - debug-level message
1468
1469 =back
1470
1471
1472 =head1 DIAGNOSTICS
1473
1474 =over
1475
1476 =item C<Invalid argument passed to setlogsock>
1477
1478 B<(F)> You gave C<setlogsock()> an invalid value for C<$sock_type>.
1479
1480 =item C<eventlog passed to setlogsock, but no Win32 API available>
1481
1482 B<(W)> You asked C<setlogsock()> to use the Win32 event logger but the
1483 operating system running the program isn't Win32 or does not provides Win32
1484 compatible facilities.
1485
1486 =item C<no connection to syslog available>
1487
1488 B<(F)> C<syslog()> failed to connect to the specified socket.
1489
1490 =item C<stream passed to setlogsock, but %s is not writable>
1491
1492 B<(W)> You asked C<setlogsock()> to use a stream socket, but the given
1493 path is not writable.
1494
1495 =item C<stream passed to setlogsock, but could not find any device>
1496
1497 B<(W)> You asked C<setlogsock()> to use a stream socket, but didn't
1498 provide a path, and C<Sys::Syslog> was unable to find an appropriate one.
1499
1500 =item C<tcp passed to setlogsock, but tcp service unavailable>
1501
1502 B<(W)> You asked C<setlogsock()> to use a TCP socket, but the service
1503 is not available on the system.
1504
1505 =item C<syslog: expecting argument %s>
1506
1507 B<(F)> You forgot to give C<syslog()> the indicated argument.
1508
1509 =item C<syslog: invalid level/facility: %s>
1510
1511 B<(F)> You specified an invalid level or facility.
1512
1513 =item C<syslog: too many levels given: %s>
1514
1515 B<(F)> You specified too many levels.
1516
1517 =item C<syslog: too many facilities given: %s>
1518
1519 B<(F)> You specified too many facilities.
1520
1521 =item C<syslog: level must be given>
1522
1523 B<(F)> You forgot to specify a level.
1524
1525 =item C<udp passed to setlogsock, but udp service unavailable>
1526
1527 B<(W)> You asked C<setlogsock()> to use a UDP socket, but the service
1528 is not available on the system.
1529
1530 =item C<unix passed to setlogsock, but path not available>
1531
1532 B<(W)> You asked C<setlogsock()> to use a UNIX socket, but C<Sys::Syslog>
1533 was unable to find an appropriate an appropriate device.
1534
1535 =back
1536
1537
1538 =head1 HISTORY
1539
1540 C<Sys::Syslog> is a core module, part of the standard Perl distribution
1541 since 1990.  At this time, modules as we know them didn't exist, the
1542 Perl library was a collection of F<.pl> files, and the one for sending
1543 syslog messages with was simply F<lib/syslog.pl>, included with Perl 3.0.
1544 It was converted as a module with Perl 5.0, but had a version number
1545 only starting with Perl 5.6.  Here is a small table with the matching
1546 Perl and C<Sys::Syslog> versions.
1547
1548     Sys::Syslog     Perl
1549     -----------     ----
1550        undef        5.0.0 ~ 5.5.4
1551        0.01         5.6.*
1552        0.03         5.8.0
1553        0.04         5.8.1, 5.8.2, 5.8.3
1554        0.05         5.8.4, 5.8.5, 5.8.6
1555        0.06         5.8.7
1556        0.13         5.8.8
1557        0.22         5.10.0
1558        0.27         5.8.9, 5.10.1 ~ 5.14.2
1559        0.29         5.16.0, 5.16.1
1560
1561
1562 =head1 SEE ALSO
1563
1564 =head2 Other modules
1565
1566 L<Log::Log4perl> - Perl implementation of the Log4j API
1567
1568 L<Log::Dispatch> - Dispatches messages to one or more outputs
1569
1570 L<Log::Report> - Report a problem, with exceptions and language support
1571
1572 =head2 Manual Pages
1573
1574 L<syslog(3)>
1575
1576 SUSv3 issue 6, IEEE Std 1003.1, 2004 edition,
1577 L<http://www.opengroup.org/onlinepubs/000095399/basedefs/syslog.h.html>
1578
1579 GNU C Library documentation on syslog,
1580 L<http://www.gnu.org/software/libc/manual/html_node/Syslog.html>
1581
1582 Solaris 10 documentation on syslog,
1583 L<http://docs.sun.com/app/docs/doc/816-5168/syslog-3c?a=view>
1584
1585 Mac OS X documentation on syslog,
1586 L<http://developer.apple.com/documentation/Darwin/Reference/ManPages/man3/syslog.3.html>
1587
1588 IRIX 6.5 documentation on syslog,
1589 L<http://techpubs.sgi.com/library/tpl/cgi-bin/getdoc.cgi?coll=0650&db=man&fname=3c+syslog>
1590
1591 AIX 5L 5.3 documentation on syslog,
1592 L<http://publib.boulder.ibm.com/infocenter/pseries/v5r3/index.jsp?topic=/com.ibm.aix.basetechref/doc/basetrf2/syslog.htm>
1593
1594 HP-UX 11i documentation on syslog,
1595 L<http://docs.hp.com/en/B2355-60130/syslog.3C.html>
1596
1597 Tru64 5.1 documentation on syslog,
1598 L<http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51_HTML/MAN/MAN3/0193____.HTM>
1599
1600 Stratus VOS 15.1,
1601 L<http://stratadoc.stratus.com/vos/15.1.1/r502-01/wwhelp/wwhimpl/js/html/wwhelp.htm?context=r502-01&file=ch5r502-01bi.html>
1602
1603 =head2 RFCs
1604
1605 I<RFC 3164 - The BSD syslog Protocol>, L<http://www.faqs.org/rfcs/rfc3164.html>
1606 -- Please note that this is an informational RFC, and therefore does not
1607 specify a standard of any kind.
1608
1609 I<RFC 3195 - Reliable Delivery for syslog>, L<http://www.faqs.org/rfcs/rfc3195.html>
1610
1611 =head2 Articles
1612
1613 I<Syslogging with Perl>, L<http://lexington.pm.org/meetings/022001.html>
1614
1615 =head2 Event Log
1616
1617 Windows Event Log,
1618 L<http://msdn.microsoft.com/library/default.asp?url=/library/en-us/wes/wes/windows_event_log.asp>
1619
1620
1621 =head1 AUTHORS & ACKNOWLEDGEMENTS
1622
1623 Tom Christiansen E<lt>F<tchrist (at) perl.com>E<gt> and Larry Wall
1624 E<lt>F<larry (at) wall.org>E<gt>.
1625
1626 UNIX domain sockets added by Sean Robinson
1627 E<lt>F<robinson_s (at) sc.maricopa.edu>E<gt> with support from Tim Bunce
1628 E<lt>F<Tim.Bunce (at) ig.co.uk>E<gt> and the C<perl5-porters> mailing list.
1629
1630 Dependency on F<syslog.ph> replaced with XS code by Tom Hughes
1631 E<lt>F<tom (at) compton.nu>E<gt>.
1632
1633 Code for C<constant()>s regenerated by Nicholas Clark E<lt>F<nick (at) ccl4.org>E<gt>.
1634
1635 Failover to different communication modes by Nick Williams
1636 E<lt>F<Nick.Williams (at) morganstanley.com>E<gt>.
1637
1638 Extracted from core distribution for publishing on the CPAN by
1639 SE<eacute>bastien Aperghis-Tramoni E<lt>sebastien (at) aperghis.netE<gt>.
1640
1641 XS code for using native C functions borrowed from C<L<Unix::Syslog>>,
1642 written by Marcus Harnisch E<lt>F<marcus.harnisch (at) gmx.net>E<gt>.
1643
1644 Yves Orton suggested and helped for making C<Sys::Syslog> use the native
1645 event logger under Win32 systems.
1646
1647 Jerry D. Hedden and Reini Urban provided greatly appreciated help to
1648 debug and polish C<Sys::Syslog> under Cygwin.
1649
1650
1651 =head1 BUGS
1652
1653 Please report any bugs or feature requests to
1654 C<bug-sys-syslog (at) rt.cpan.org>, or through the web interface at
1655 L<http://rt.cpan.org/Public/Dist/Display.html?Name=Sys-Syslog>.
1656 I will be notified, and then you'll automatically be notified of progress on
1657 your bug as I make changes.
1658
1659
1660 =head1 SUPPORT
1661
1662 You can find documentation for this module with the perldoc command.
1663
1664     perldoc Sys::Syslog
1665
1666 You can also look for information at:
1667
1668 =over 4
1669
1670 =item * AnnoCPAN: Annotated CPAN documentation
1671
1672 L<http://annocpan.org/dist/Sys-Syslog>
1673
1674 =item * CPAN Ratings
1675
1676 L<http://cpanratings.perl.org/d/Sys-Syslog>
1677
1678 =item * RT: CPAN's request tracker
1679
1680 L<http://rt.cpan.org/Dist/Display.html?Queue=Sys-Syslog>
1681
1682 =item * Search CPAN
1683
1684 L<http://search.cpan.org/dist/Sys-Syslog/>
1685
1686 =item * MetaCPAN
1687
1688 L<https://metacpan.org/module/Sys::Syslog>
1689
1690 =item * Perl Documentation
1691
1692 L<http://perldoc.perl.org/Sys/Syslog.html>
1693
1694 =back
1695
1696
1697 =head1 COPYRIGHT
1698
1699 Copyright (C) 1990-2012 by Larry Wall and others.
1700
1701
1702 =head1 LICENSE
1703
1704 This program is free software; you can redistribute it and/or modify it
1705 under the same terms as Perl itself.
1706
1707 =cut
1708
1709 =begin comment
1710
1711 Notes for the future maintainer (even if it's still me..)
1712 - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
1713
1714 Using Google Code Search, I search who on Earth was relying on $host being
1715 public. It found 5 hits:
1716
1717 * First was inside Indigo Star Perl2exe documentation. Just an old version
1718 of Sys::Syslog.
1719
1720
1721 * One real hit was inside DalWeathDB, a weather related program. It simply
1722 does a
1723
1724     $Sys::Syslog::host = '127.0.0.1';
1725
1726 - L<http://www.gallistel.net/nparker/weather/code/>
1727
1728
1729 * Two hits were in TPC, a fax server thingy. It does a
1730
1731     $Sys::Syslog::host = $TPC::LOGHOST;
1732
1733 but also has this strange piece of code:
1734
1735     # work around perl5.003 bug
1736     sub Sys::Syslog::hostname {}
1737
1738 I don't know what bug the author referred to.
1739
1740 - L<http://www.tpc.int/>
1741 - L<ftp://ftp-usa.tpc.int/pub/tpc/server/UNIX/>
1742
1743
1744 * Last hit was in Filefix, which seems to be a FIDOnet mail program (!).
1745 This one does not use $host, but has the following piece of code:
1746
1747     sub Sys::Syslog::hostname
1748     {
1749         use Sys::Hostname;
1750         return hostname;
1751     }
1752
1753 I guess this was a more elaborate form of the previous bit, maybe because
1754 of a bug in Sys::Syslog back then?
1755
1756 - L<ftp://ftp.kiae.su/pub/unix/fido/>
1757
1758
1759 Links
1760 -----
1761 Linux Fast-STREAMS
1762 - L<http://www.openss7.org/streams.html>
1763
1764 II12021: SYSLOGD HOWTO TCPIPINFO (z/OS, OS/390, MVS)
1765 - L<http://www-1.ibm.com/support/docview.wss?uid=isg1II12021>
1766
1767 Getting the most out of the Event Viewer
1768 - L<http://www.codeproject.com/dotnet/evtvwr.asp?print=true>
1769
1770 Log events to the Windows NT Event Log with JNI
1771 - L<http://www.javaworld.com/javaworld/jw-09-2001/jw-0928-ntmessages.html>
1772
1773 =end comment
1774