vos/compile_perl.cm

   1 & This command macro creates the appropriate subdirectory
   2 & for the specified processor type and then runs the
   3 & build macro in that subdirectory to create the perl
   4 & executable program module file.
   5 & Written 99-02-03 by Paul Green (Paul_Green@stratus.com)
   6 & Modified 00-10-24 by Paul Green
   7 &
   8 &begin_parameters
   9      cpu       option(-processor)name,allow(mc68020,i80860,pa7100,pa8000),=pa7100
  10      recompile switch(-recompile),=1
  11      rebind    switch(-rebind),=1
  12      module    option(-module)module_name,='(current_module)'
  13      tgt_mod   option(-target_module)module_name,='(current_module)'
  14      version   option(-version)name,allow(alpha,ga),=ga
  15      compiler  option(-compiler)name,allow(cc,gcc)=cc
  16 &end_parameters
  17 &echo command_lines
  18 &
  19 &if &recompile&
  20 &then &set_string recompile -recompile
  21 &else &set_string recompile -no_recompile
  22 &
  23 &if &rebind&
  24 &then &set_string rebind -rebind
  25 &else &set_string rebind -no_rebind
  26 &
  27 &if &cpu& = mc68020
  28 &then &set_string obj ''
  29 &if &cpu& = i80860
  30 &then &set_string obj .860
  31 &if &cpu& = pa7100
  32 &then &set_string obj .7100
  33 &if &cpu& = pa8000
  34 &then &set_string obj .8000
  35 &
  36 &if &compiler& = gcc & &version& = alpha
  37 &then &do
  38  &display_line GCC is not supported by the alpha version of POSIX support.
  39  &return e$translation_failed
  40 &end
  41 &if &cpu& = mc68020 & &version& = ga
  42 &then &do
  43  &display_line The mc68020 CPU is not supported by the GA version of POSIX support.
  44  &return e$translation_failed
  45 &end
  46 &if &cpu& = i80860 & &version& = ga
  47 &then &do
  48  &display_line The i80860 CPU is not supported by the GA version of POSIX support.
  49  &return e$translation_failed
  50 &end
  51 &if &cpu& = pa8000 & &compiler& = gcc
  52 &then &do
  53  &display_line The pa8000 CPU is not supported by the GNU GCC compiler.
  54  &return e$translation_failed
  55 &end
  56 &if ^ (exists obj&obj& -directory)
  57 &then !create_dir obj&obj&
  58 &
  59 &if ^ (exists obj&obj&>build.out)
  60 &then !create_file obj&obj&>build.out ; set_implicit_locking obj&obj&>build.out
  61 &
  62 !configure_perl -version &version&
  63 &
  64 !change_current_dir obj&obj&
  65 !start_process (string <build -processor &cpu& &recompile& &rebind& &+
  66      -target_module &tgt_mod& -version &version& -compiler &compiler&) &+
  67      -module &module&
  68 !change_current_dir <