make_ext.pl

   1 #!./miniperl
   2 use strict;
   3 use warnings;
   4 use Config;
   5 use Cwd;
   6
   7 # This script acts as a simple interface for building extensions.
   8
   9 # It's actually a cut and shut of the Unix version ext/utils/makeext and the
  10 # Windows version win32/build_ext.pl hence the two invocation styles.
  11
  12 # On Unix, it primarily used by the perl Makefile one extention at a time:
  13 #
  14 # d_dummy $(dynamic_ext): miniperl preplibrary FORCE
  15 #       @$(RUN) ./miniperl make_ext.pl --target=dynamic $@ MAKE=$(MAKE) LIBPERL_A=$(LIBPERL)
  16 #
  17 # On Windows,
  18 # If '--static' is specified, static extensions will be built.
  19 # If '--dynamic' is specified, dynamic (and nonxs) extensions will be built.
  20 # If '--all' is specified, all extensions will be built.
  21 #
  22 #    make_ext.pl "MAKE=make [-make_opts]" --dir=directory [--target=target] [--static|--dynamic|--all] +ext2 !ext1
  23 #
  24 # E.g.
  25 #
  26 #     make_ext.pl "MAKE=nmake -nologo" --dir=..\ext
  27 #
  28 #     make_ext.pl "MAKE=nmake -nologo" --dir=..\ext --target=clean
  29 #
  30 #     make_ext.pl MAKE=dmake --dir=..\ext
  31 #
  32 #     make_ext.pl MAKE=dmake --dir=..\ext --target=clean
  33 #
  34 # Will skip building extensions which are marked with an '!' char.
  35 # Mostly because they still not ported to specified platform.
  36 #
  37 # If any extensions are listed with a '+' char then only those
  38 # extensions will be built, but only if they arent countermanded
  39 # by an '!ext' and are appropriate to the type of building being done.
  40
  41 # It may be deleted in a later release of perl so try to
  42 # avoid using it for other purposes.
  43
  44 my $is_Win32 = $^O eq 'MSWin32';
  45 my $is_VMS = $^O eq 'VMS';
  46 my $is_Unix = !$is_Win32 && !$is_VMS;
  47
  48 require FindExt if $is_Win32;
  49
  50 my (%excl, %incl, %opts, @extspec, @pass_through);
  51
  52 foreach (@ARGV) {
  53     if (/^!(.*)$/) {
  54         $excl{$1} = 1;
  55     } elsif (/^\+(.*)$/) {
  56         $incl{$1} = 1;
  57     } elsif (/^--([\w\-]+)$/) {
  58         $opts{$1} = 1;
  59     } elsif (/^--([\w\-]+)=(.*)$/) {
  60         $opts{$1} = $2;
  61     } elsif (/=/) {
  62         push @pass_through, $_;
  63     } elsif (length) {
  64         push @extspec, $_;
  65     }
  66 }
  67
  68 my $static = $opts{static} || $opts{all};
  69 my $dynamic = $opts{dynamic} || $opts{all};
  70
  71 # The Perl Makefile.SH will expand all extensions to
  72 #       lib/auto/X/X.a  (or lib/auto/X/Y/Y.a if nested)
  73 # A user wishing to run make_ext might use
  74 #       X (or X/Y or X::Y if nested)
  75
  76 # canonise into X/Y form (pname)
  77
  78 foreach (@extspec) {
  79     if (s{^lib/auto/}{}) {
  80         # Remove lib/auto prefix and /*.* suffix
  81         s{/[^/]+\.[^/]+$}{};
  82     } elsif (s{^ext/}{}) {
  83         # Remove ext/ prefix and /pm_to_blib suffix
  84         s{/pm_to_blib$}{};
  85     } elsif (s{::}{\/}g) {
  86         # Convert :: to /
  87     } else {
  88         s/\..*o//;
  89     }
  90 }
  91
  92 my $makecmd  = shift @pass_through; # Should be something like MAKE=make
  93 unshift @pass_through, 'PERL_CORE=1';
  94
  95 my $dir  = $opts{dir} || 'ext';
  96 my $target   = $opts{target};
  97 $target = 'all' unless defined $target;
  98
  99 # Previously, $make was taken from config.sh.  However, the user might
 100 # instead be running a possibly incompatible make.  This might happen if
 101 # the user types "gmake" instead of a plain "make", for example.  The
 102 # correct current value of MAKE will come through from the main perl
 103 # makefile as MAKE=/whatever/make in $makecmd.  We'll be cautious in
 104 # case third party users of this script (are there any?) don't have the
 105 # MAKE=$(MAKE) argument, which was added after 5.004_03.
 106 unless(defined $makecmd and $makecmd =~ /^MAKE=(.*)$/) {
 107     die "$0:  WARNING:  Please include MAKE=\$(MAKE) in \@ARGV\n";
 108 }
 109
 110 # This isn't going to cope with anything fancy, such as spaces inside command
 111 # names, but neither did what it replaced. Once there is a use case that needs
 112 # it, please supply patches. Until then, I'm sticking to KISS
 113 my @make = split ' ', $1 || $Config{make} || $ENV{MAKE};
 114 # Using an array of 0 or 1 elements makes the subsequent code simpler.
 115 my @run = $Config{run};
 116 @run = () if not defined $run[0] or $run[0] eq '';
 117
 118
 119 if ($target eq '') {
 120     die "make_ext: no make target specified (eg all or clean)\n";
 121 } elsif ($target !~ /(?:^all|clean)$/) {
 122     # for the time being we are strict about what make_ext is used for
 123     die "$0: unknown make target '$target'\n";
 124 }
 125
 126 if (!@extspec and !$static and !$dynamic)  {
 127     die "$0: no extension specified\n";
 128 }
 129
 130 my $perl;
 131 my %extra_passthrough;
 132
 133 if ($is_Win32) {
 134     (my $here = getcwd()) =~ s{/}{\\}g;
 135     $perl = $^X;
 136     if ($perl =~ m#^\.\.#) {
 137         $perl = "$here\\$perl";
 138     }
 139     (my $topdir = $perl) =~ s/\\[^\\]+$//;
 140     # miniperl needs to find perlglob and pl2bat
 141     $ENV{PATH} = "$topdir;$topdir\\win32\\bin;$ENV{PATH}";
 142     my $pl2bat = "$topdir\\win32\\bin\\pl2bat";
 143     unless (-f "$pl2bat.bat") {
 144         my @args = ($perl, ("$pl2bat.pl") x 2);
 145         print "@args\n";
 146         system(@args) unless defined $::Cross::platform;
 147     }
 148
 149     print "In ", getcwd();
 150     chdir($dir) || die "Cannot cd to $dir\n";
 151     (my $ext = getcwd()) =~ s{/}{\\}g;
 152     FindExt::scan_ext($ext);
 153     FindExt::set_static_extensions(split ' ', $Config{static_ext});
 154
 155     my @ext;
 156     push @ext, FindExt::static_ext() if $static;
 157     push @ext, FindExt::dynamic_ext(), FindExt::nonxs_ext() if $dynamic;
 158
 159     foreach (sort @ext) {
 160         if (%incl and !exists $incl{$_}) {
 161             #warn "Skipping extension $ext\\$_, not in inclusion list\n";
 162             next;
 163         }
 164         if (exists $excl{$_}) {
 165             warn "Skipping extension $ext\\$_, not ported to current platform";
 166             next;
 167         }
 168         push @extspec, $_;
 169         if(FindExt::is_static($_)) {
 170             push @{$extra_passthrough{$_}}, 'LINKTYPE=static';
 171         }
 172     }
 173     chdir '..'; # now in the Perl build directory
 174 }
 175
 176 foreach my $spec (@extspec)  {
 177     my $mname = $spec;
 178     $mname =~ s!/!::!g;
 179     my $ext_pathname;
 180     if (-d "ext/$spec") {
 181         # Old style ext/Data/Dumper/
 182         $ext_pathname = "ext/$spec";
 183     } else {
 184         # New style ext/Data-Dumper/
 185         my $copy = $spec;
 186         $copy =~ tr!/!-!;
 187         $ext_pathname = "ext/$copy";
 188     }
 189     my $up = $ext_pathname;
 190     $up =~ s![^/]+!..!g;
 191
 192     if ($Config{osname} eq 'catamount') {
 193         # Snowball's chance of building extensions.
 194         die "This is $Config{osname}, not building $mname, sorry.\n";
 195     }
 196
 197     print "\tMaking $mname ($target)\n";
 198
 199     build_extension('ext', $ext_pathname, $up, $perl || "$up/miniperl",
 200                     "$up/lib",
 201                     [@pass_through, @{$extra_passthrough{$spec} || []}]);
 202 }
 203
 204 sub build_extension {
 205     my ($ext, $ext_dir, $return_dir, $perl, $lib_dir, $pass_through) = @_;
 206     unless (chdir "$ext_dir") {
 207         warn "Cannot cd to $ext_dir: $!";
 208         return;
 209     }
 210
 211     if (!-f 'Makefile') {
 212         print "\nRunning Makefile.PL in $ext_dir\n";
 213
 214         # Presumably this can be simplified
 215         my @cross;
 216         if (defined $::Cross::platform) {
 217             # Inherited from win32/buildext.pl
 218             @cross = "-MCross=$::Cross::platform";
 219         } elsif ($opts{cross}) {
 220             # Inherited from make_ext.pl
 221             @cross = '-MCross';
 222         }
 223
 224         my @perl = (@run, $perl, "-I$lib_dir", @cross, 'Makefile.PL',
 225                     'INSTALLDIRS=perl', 'INSTALLMAN3DIR=none',
 226                     @$pass_through);
 227         print join(' ', @perl), "\n";
 228         my $code = system @perl;
 229         warn "$code from $ext_dir\'s Makefile.PL" if $code;
 230
 231         # Right. The reason for this little hack is that we're sitting inside
 232         # a program run by ./miniperl, but there are tasks we need to perform
 233         # when the 'realclean', 'distclean' or 'veryclean' targets are run.
 234         # Unfortunately, they can be run *after* 'clean', which deletes
 235         # ./miniperl
 236         # So we do our best to leave a set of instructions identical to what
 237         # we would do if we are run directly as 'realclean' etc
 238         # Whilst we're perfect, unfortunately the targets we call are not, as
 239         # some of them rely on a $(PERL) for their own distclean targets.
 240         # But this always used to be a problem with the old /bin/sh version of
 241         # this.
 242         if ($is_Unix) {
 243             my $suffix = '.sh';
 244             foreach my $clean_target ('realclean', 'veryclean') {
 245                 my $file = "$return_dir/$clean_target$suffix";
 246                 open my $fh, '>>', $file or die "open $file: $!";
 247                 # Quite possible that we're being run in parallel here.
 248                 # Can't use Fcntl this early to get the LOCK_EX
 249                 flock $fh, 2 or warn "flock $file: $!";
 250                 print $fh <<"EOS";
 251 cd $ext_dir
 252 if test ! -f Makefile -a -f Makefile.old; then
 253     echo "Note: Using Makefile.old"
 254     make -f Makefile.old $clean_target MAKE='@make' @pass_through
 255 else
 256     if test ! -f Makefile ; then
 257         echo "Warning: No Makefile!"
 258     fi
 259     make $clean_target MAKE='@make' @pass_through
 260 fi
 261 cd $return_dir
 262 EOS
 263                 close $fh or die "close $file: $!";
 264             }
 265         }
 266     }
 267
 268     if (not -f 'Makefile') {
 269         print "Warning: No Makefile!\n";
 270     }
 271
 272     if (!$target or $target !~ /clean$/) {
 273         # Give makefile an opportunity to rewrite itself.
 274         # reassure users that life goes on...
 275         my @config = (@run, @make, 'config', @$pass_through);
 276         system @config and print "@config failed, continuing anyway...\n";
 277     }
 278     my @targ = (@run, @make, $target, @$pass_through);
 279     print "Making $target in $ext_dir\n@targ\n";
 280     my $code = system @targ;
 281     die "Unsuccessful make($ext_dir): code=$code" if $code != 0;
 282
 283     chdir $return_dir || die "Cannot cd to $return_dir: $!";
 284 }