lib/ExtUtils/Mksymlists.pm

   1 package ExtUtils::Mksymlists;
   2 use strict qw[ subs refs ];
   3 # no strict 'vars';  # until filehandles are exempted
   4
   5 use Carp;
   6 use Exporter;
   7 use vars qw( @ISA @EXPORT $VERSION );
   8 @ISA = 'Exporter';
   9 @EXPORT = '&Mksymlists';
  10 $VERSION = substr q$Revision: 1.17 $, 10;
  11
  12 sub Mksymlists {
  13     my(%spec) = @_;
  14     my($osname) = $^O;
  15
  16     croak("Insufficient information specified to Mksymlists")
  17         unless ( $spec{NAME} or
  18                  ($spec{FILE} and ($spec{DL_FUNCS} or $spec{FUNCLIST})) );
  19
  20     $spec{DL_VARS} = [] unless $spec{DL_VARS};
  21     ($spec{FILE} = $spec{NAME}) =~ s/.*::// unless $spec{FILE};
  22     $spec{FUNCLIST} = [] unless $spec{FUNCLIST};
  23     $spec{DL_FUNCS} = { $spec{NAME} => [] }
  24         unless ( ($spec{DL_FUNCS} and keys %{$spec{DL_FUNCS}}) or
  25                  @{$spec{FUNCLIST}});
  26     if (defined $spec{DL_FUNCS}) {
  27         my($package);
  28         foreach $package (keys %{$spec{DL_FUNCS}}) {
  29             my($packprefix,$sym,$bootseen);
  30             ($packprefix = $package) =~ s/\W/_/g;
  31             foreach $sym (@{$spec{DL_FUNCS}->{$package}}) {
  32                 if ($sym =~ /^boot_/) {
  33                     push(@{$spec{FUNCLIST}},$sym);
  34                     $bootseen++;
  35                 }
  36                 else { push(@{$spec{FUNCLIST}},"XS_${packprefix}_$sym"); }
  37             }
  38             push(@{$spec{FUNCLIST}},"boot_$packprefix") unless $bootseen;
  39         }
  40     }
  41
  42 #    We'll need this if we ever add any OS which uses mod2fname
  43 #    not as pseudo-builtin.
  44 #    require DynaLoader;
  45     if (defined &DynaLoader::mod2fname and not $spec{DLBASE}) {
  46         $spec{DLBASE} = DynaLoader::mod2fname([ split(/::/,$spec{NAME}) ]);
  47     }
  48
  49     if    ($osname eq 'aix') { _write_aix(\%spec); }
  50     elsif ($osname eq 'VMS') { _write_vms(\%spec) }
  51     elsif ($osname eq 'os2') { _write_os2(\%spec) }
  52     elsif ($osname eq 'MSWin32') { _write_win32(\%spec) }
  53     else { croak("Don't know how to create linker option file for $osname\n"); }
  54 }
  55
  56
  57 sub _write_aix {
  58     my($data) = @_;
  59
  60     rename "$data->{FILE}.exp", "$data->{FILE}.exp_old";
  61
  62     open(EXP,">$data->{FILE}.exp")
  63         or croak("Can't create $data->{FILE}.exp: $!\n");
  64     print EXP join("\n",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  65     print EXP join("\n",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  66     close EXP;
  67 }
  68
  69
  70 sub _write_os2 {
  71     my($data) = @_;
  72     require Config;
  73     my $threaded = ($Config::Config{archname} =~ /-thread/ ? " threaded" : "");
  74
  75     if (not $data->{DLBASE}) {
  76         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
  77         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
  78     }
  79     my $distname = $data->{DISTNAME} || $data->{NAME};
  80     $distname = "Distribution $distname";
  81     my $comment = "Perl (v$]$threaded) module $data->{NAME}";
  82     if ($data->{INSTALLDIRS} and $data->{INSTALLDIRS} eq 'perl') {
  83         $distname = 'perl5-porters@perl.org';
  84         $comment = "Core $comment";
  85     }
  86     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
  87
  88     open(DEF,">$data->{FILE}.def")
  89         or croak("Can't create $data->{FILE}.def: $!\n");
  90     print DEF "LIBRARY '$data->{DLBASE}' INITINSTANCE TERMINSTANCE\n";
  91     print DEF "DESCRIPTION '\@#$distname:$data->{VERSION}#\@ $comment'\n";
  92     print DEF "CODE LOADONCALL\n";
  93     print DEF "DATA LOADONCALL NONSHARED MULTIPLE\n";
  94     print DEF "EXPORTS\n  ";
  95     print DEF join("\n  ",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  96     print DEF join("\n  ",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  97     if (%{$data->{IMPORTS}}) {
  98         print DEF "IMPORTS\n";
  99         my ($name, $exp);
 100         while (($name, $exp)= each %{$data->{IMPORTS}}) {
 101             print DEF "  $name=$exp\n";
 102         }
 103     }
 104     close DEF;
 105 }
 106
 107 sub _write_win32 {
 108     my($data) = @_;
 109
 110     require Config;
 111     if (not $data->{DLBASE}) {
 112         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
 113         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
 114     }
 115     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
 116
 117     open(DEF,">$data->{FILE}.def")
 118         or croak("Can't create $data->{FILE}.def: $!\n");
 119     # put library name in quotes (it could be a keyword, like 'Alias')
 120     if ($Config::Config{'cc'} !~ /^gcc/i) {
 121       print DEF "LIBRARY \"$data->{DLBASE}\"\n";
 122     }
 123     print DEF "EXPORTS\n  ";
 124     my @syms;
 125     # Export public symbols both with and without underscores to
 126     # ensure compatibility between DLLs from different compilers
 127     # NOTE: DynaLoader itself only uses the names without underscores,
 128     # so this is only to cover the case when the extension DLL may be
 129     # linked to directly from C. GSAR 97-07-10
 130     if ($Config::Config{'cc'} =~ /^bcc/i) {
 131         for (@{$data->{DL_VARS}}, @{$data->{FUNCLIST}}) {
 132             push @syms, "_$_", "$_ = _$_";
 133         }
 134     }
 135     else {
 136         for (@{$data->{DL_VARS}}, @{$data->{FUNCLIST}}) {
 137             push @syms, "$_", "_$_ = $_";
 138         }
 139     }
 140     print DEF join("\n  ",@syms, "\n") if @syms;
 141     if (%{$data->{IMPORTS}}) {
 142         print DEF "IMPORTS\n";
 143         my ($name, $exp);
 144         while (($name, $exp)= each %{$data->{IMPORTS}}) {
 145             print DEF "  $name=$exp\n";
 146         }
 147     }
 148     close DEF;
 149 }
 150
 151
 152 sub _write_vms {
 153     my($data) = @_;
 154
 155     require Config; # a reminder for once we do $^O
 156     require ExtUtils::XSSymSet;
 157
 158     my($isvax) = $Config::Config{'arch'} =~ /VAX/i;
 159     my($set) = new ExtUtils::XSSymSet;
 160     my($sym);
 161
 162     rename "$data->{FILE}.opt", "$data->{FILE}.opt_old";
 163
 164     open(OPT,">$data->{FILE}.opt")
 165         or croak("Can't create $data->{FILE}.opt: $!\n");
 166
 167     # Options file declaring universal symbols
 168     # Used when linking shareable image for dynamic extension,
 169     # or when linking PerlShr into which we've added this package
 170     # as a static extension
 171     # We don't do anything to preserve order, so we won't relax
 172     # the GSMATCH criteria for a dynamic extension
 173
 174     foreach $sym (@{$data->{FUNCLIST}}) {
 175         my $safe = $set->addsym($sym);
 176         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 177         else        { print OPT "SYMBOL_VECTOR=($safe=PROCEDURE)\n"; }
 178     }
 179     foreach $sym (@{$data->{DL_VARS}}) {
 180         my $safe = $set->addsym($sym);
 181         print OPT "PSECT_ATTR=${sym},PIC,OVR,RD,NOEXE,WRT,NOSHR\n";
 182         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 183         else        { print OPT "SYMBOL_VECTOR=($safe=DATA)\n"; }
 184     }
 185     close OPT;
 186
 187 }
 188
 189 1;
 190
 191 __END__
 192
 193 =head1 NAME
 194
 195 ExtUtils::Mksymlists - write linker options files for dynamic extension
 196
 197 =head1 SYNOPSIS
 198
 199     use ExtUtils::Mksymlists;
 200     Mksymlists({ NAME     => $name ,
 201                  DL_VARS  => [ $var1, $var2, $var3 ],
 202                  DL_FUNCS => { $pkg1 => [ $func1, $func2 ],
 203                                $pkg2 => [ $func3 ] });
 204
 205 =head1 DESCRIPTION
 206
 207 C<ExtUtils::Mksymlists> produces files used by the linker under some OSs
 208 during the creation of shared libraries for dynamic extensions.  It is
 209 normally called from a MakeMaker-generated Makefile when the extension
 210 is built.  The linker option file is generated by calling the function
 211 C<Mksymlists>, which is exported by default from C<ExtUtils::Mksymlists>.
 212 It takes one argument, a list of key-value pairs, in which the following
 213 keys are recognized:
 214
 215 =over
 216
 217 =item DLBASE
 218
 219 This item specifies the name by which the linker knows the
 220 extension, which may be different from the name of the
 221 extension itself (for instance, some linkers add an '_' to the
 222 name of the extension).  If it is not specified, it is derived
 223 from the NAME attribute.  It is presently used only by OS2 and Win32.
 224
 225 =item DL_FUNCS
 226
 227 This is identical to the DL_FUNCS attribute available via MakeMaker,
 228 from which it is usually taken.  Its value is a reference to an
 229 associative array, in which each key is the name of a package, and
 230 each value is an a reference to an array of function names which
 231 should be exported by the extension.  For instance, one might say
 232 C<DL_FUNCS =E<gt> { Homer::Iliad =E<gt> [ qw(trojans greeks) ],
 233 Homer::Odyssey =E<gt> [ qw(travellers family suitors) ] }>.  The
 234 function names should be identical to those in the XSUB code;
 235 C<Mksymlists> will alter the names written to the linker option
 236 file to match the changes made by F<xsubpp>.  In addition, if
 237 none of the functions in a list begin with the string B<boot_>,
 238 C<Mksymlists> will add a bootstrap function for that package,
 239 just as xsubpp does.  (If a B<boot_E<lt>pkgE<gt>> function is
 240 present in the list, it is passed through unchanged.)  If
 241 DL_FUNCS is not specified, it defaults to the bootstrap
 242 function for the extension specified in NAME.
 243
 244 =item DL_VARS
 245
 246 This is identical to the DL_VARS attribute available via MakeMaker,
 247 and, like DL_FUNCS, it is usually specified via MakeMaker.  Its
 248 value is a reference to an array of variable names which should
 249 be exported by the extension.
 250
 251 =item FILE
 252
 253 This key can be used to specify the name of the linker option file
 254 (minus the OS-specific extension), if for some reason you do not
 255 want to use the default value, which is the last word of the NAME
 256 attribute (I<e.g.> for C<Tk::Canvas>, FILE defaults to C<Canvas>).
 257
 258 =item FUNCLIST
 259
 260 This provides an alternate means to specify function names to be
 261 exported from the extension.  Its value is a reference to an
 262 array of function names to be exported by the extension.  These
 263 names are passed through unaltered to the linker options file.
 264 Specifying a value for the FUNCLIST attribute suppresses automatic
 265 generation of the bootstrap function for the package. To still create
 266 the bootstrap name you have to specify the package name in the
 267 DL_FUNCS hash:
 268
 269     Mksymlists({ NAME     => $name ,
 270                  FUNCLIST => [ $func1, $func2 ],
 271                  DL_FUNCS => { $pkg => [] } });
 272
 273
 274 =item IMPORTS
 275
 276 This attribute is used to specify names to be imported into the
 277 extension. It is currently only used by OS/2 and Win32.
 278
 279 =item NAME
 280
 281 This gives the name of the extension (I<e.g.> C<Tk::Canvas>) for which
 282 the linker option file will be produced.
 283
 284 =back
 285
 286 When calling C<Mksymlists>, one should always specify the NAME
 287 attribute.  In most cases, this is all that's necessary.  In
 288 the case of unusual extensions, however, the other attributes
 289 can be used to provide additional information to the linker.
 290
 291 =head1 AUTHOR
 292
 293 Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>>
 294
 295 =head1 REVISION
 296
 297 Last revised 14-Feb-1996, for Perl 5.002.