pod/perlsyn.pod

   1 =head1 NAME
   2
   3 perlsyn - Perl syntax
   4
   5 =head1 DESCRIPTION
   6
   7 A Perl script consists of a sequence of declarations and statements.
   8 The sequence of statements is executed just once, unlike in B<sed>
   9 and B<awk> scripts, where the sequence of statements is executed
  10 for each input line.  While this means that you must explicitly
  11 loop over the lines of your input file (or files), it also means
  12 you have much more control over which files and which lines you look at.
  13 (Actually, I'm lying--it is possible to do an implicit loop with
  14 either the B<-n> or B<-p> switch.  It's just not the mandatory
  15 default like it is in B<sed> and B<awk>.)
  16
  17 Perl is, for the most part, a free-form language.  (The only exception
  18 to this is format declarations, for obvious reasons.)  Text from a
  19 C<"#"> character until the end of the line is a comment, and is
  20 ignored.  If you attempt to use C</* */> C-style comments, it will be
  21 interpreted either as division or pattern matching, depending on the
  22 context, and C++ C<//> comments just look like a null regular
  23 expression, so don't do that.
  24
  25 =head2 Declarations
  26
  27 The only things you need to declare in Perl are report formats
  28 and subroutines--and even undefined subroutines can be handled
  29 through AUTOLOAD.  A variable holds the undefined value (C<undef>)
  30 until it has been assigned a defined value, which is anything
  31 other than C<undef>.  When used as a number, C<undef> is treated
  32 as C<0>; when used as a string, it is treated the empty string,
  33 C<"">; and when used as a reference that isn't being assigned
  34 to, it is treated as an error.  If you enable warnings, you'll
  35 be notified of an uninitialized value whenever you treat C<undef>
  36 as a string or a number.  Well, usually.  Boolean ("don't-care")
  37 contexts and operators such as C<++>, C<-->, C<+=>, C<-=>, and
  38 C<.=> are always exempt from such warnings.
  39
  40 A declaration can be put anywhere a statement can, but has no effect on
  41 the execution of the primary sequence of statements--declarations all
  42 take effect at compile time.  Typically all the declarations are put at
  43 the beginning or the end of the script.  However, if you're using
  44 lexically-scoped private variables created with C<my()>, you'll
  45 have to make sure
  46 your format or subroutine definition is within the same block scope
  47 as the my if you expect to be able to access those private variables.
  48
  49 Declaring a subroutine allows a subroutine name to be used as if it were a
  50 list operator from that point forward in the program.  You can declare a
  51 subroutine without defining it by saying C<sub name>, thus:
  52
  53     sub myname;
  54     $me = myname $0             or die "can't get myname";
  55
  56 Note that myname() functions as a list operator, not as a unary operator;
  57 so be careful to use C<or> instead of C<||> in this case.  However, if
  58 you were to declare the subroutine as C<sub myname ($)>, then
  59 C<myname> would function as a unary operator, so either C<or> or
  60 C<||> would work.
  61
  62 Subroutines declarations can also be loaded up with the C<require> statement
  63 or both loaded and imported into your namespace with a C<use> statement.
  64 See L<perlmod> for details on this.
  65
  66 A statement sequence may contain declarations of lexically-scoped
  67 variables, but apart from declaring a variable name, the declaration acts
  68 like an ordinary statement, and is elaborated within the sequence of
  69 statements as if it were an ordinary statement.  That means it actually
  70 has both compile-time and run-time effects.
  71
  72 =head2 Simple statements
  73
  74 The only kind of simple statement is an expression evaluated for its
  75 side effects.  Every simple statement must be terminated with a
  76 semicolon, unless it is the final statement in a block, in which case
  77 the semicolon is optional.  (A semicolon is still encouraged there if the
  78 block takes up more than one line, because you may eventually add another line.)
  79 Note that there are some operators like C<eval {}> and C<do {}> that look
  80 like compound statements, but aren't (they're just TERMs in an expression),
  81 and thus need an explicit termination if used as the last item in a statement.
  82
  83 Any simple statement may optionally be followed by a I<SINGLE> modifier,
  84 just before the terminating semicolon (or block ending).  The possible
  85 modifiers are:
  86
  87     if EXPR
  88     unless EXPR
  89     while EXPR
  90     until EXPR
  91     foreach EXPR
  92
  93 The C<if> and C<unless> modifiers have the expected semantics,
  94 presuming you're a speaker of English.  The C<foreach> modifier is an
  95 iterator:  For each value in EXPR, it aliases C<$_> to the value and
  96 executes the statement.  The C<while> and C<until> modifiers have the
  97 usual "C<while> loop" semantics (conditional evaluated first), except
  98 when applied to a C<do>-BLOCK (or to the deprecated C<do>-SUBROUTINE
  99 statement), in which case the block executes once before the
 100 conditional is evaluated.  This is so that you can write loops like:
 101
 102     do {
 103         $line = <STDIN>;
 104         ...
 105     } until $line  eq ".\n";
 106
 107 See L<perlfunc/do>.  Note also that the loop control statements described
 108 later will I<NOT> work in this construct, because modifiers don't take
 109 loop labels.  Sorry.  You can always put another block inside of it
 110 (for C<next>) or around it (for C<last>) to do that sort of thing.
 111 For C<next>, just double the braces:
 112
 113     do {{
 114         next if $x == $y;
 115         # do something here
 116     }} until $x++ > $z;
 117
 118 For C<last>, you have to be more elaborate:
 119
 120     LOOP: {
 121             do {
 122                 last if $x = $y**2;
 123                 # do something here
 124             } while $x++ <= $z;
 125     }
 126
 127 =head2 Compound statements
 128
 129 In Perl, a sequence of statements that defines a scope is called a block.
 130 Sometimes a block is delimited by the file containing it (in the case
 131 of a required file, or the program as a whole), and sometimes a block
 132 is delimited by the extent of a string (in the case of an eval).
 133
 134 But generally, a block is delimited by curly brackets, also known as braces.
 135 We will call this syntactic construct a BLOCK.
 136
 137 The following compound statements may be used to control flow:
 138
 139     if (EXPR) BLOCK
 140     if (EXPR) BLOCK else BLOCK
 141     if (EXPR) BLOCK elsif (EXPR) BLOCK ... else BLOCK
 142     LABEL while (EXPR) BLOCK
 143     LABEL while (EXPR) BLOCK continue BLOCK
 144     LABEL for (EXPR; EXPR; EXPR) BLOCK
 145     LABEL foreach VAR (LIST) BLOCK
 146     LABEL foreach VAR (LIST) BLOCK continue BLOCK
 147     LABEL BLOCK continue BLOCK
 148
 149 Note that, unlike C and Pascal, these are defined in terms of BLOCKs,
 150 not statements.  This means that the curly brackets are I<required>--no
 151 dangling statements allowed.  If you want to write conditionals without
 152 curly brackets there are several other ways to do it.  The following
 153 all do the same thing:
 154
 155     if (!open(FOO)) { die "Can't open $FOO: $!"; }
 156     die "Can't open $FOO: $!" unless open(FOO);
 157     open(FOO) or die "Can't open $FOO: $!";     # FOO or bust!
 158     open(FOO) ? 'hi mom' : die "Can't open $FOO: $!";
 159                         # a bit exotic, that last one
 160
 161 The C<if> statement is straightforward.  Because BLOCKs are always
 162 bounded by curly brackets, there is never any ambiguity about which
 163 C<if> an C<else> goes with.  If you use C<unless> in place of C<if>,
 164 the sense of the test is reversed.
 165
 166 The C<while> statement executes the block as long as the expression is
 167 true (does not evaluate to the null string C<""> or C<0> or C<"0">).
 168 The LABEL is optional, and if present, consists of an identifier followed
 169 by a colon.  The LABEL identifies the loop for the loop control
 170 statements C<next>, C<last>, and C<redo>.
 171 If the LABEL is omitted, the loop control statement
 172 refers to the innermost enclosing loop.  This may include dynamically
 173 looking back your call-stack at run time to find the LABEL.  Such
 174 desperate behavior triggers a warning if you use the C<use warnings>
 175 pragma or the B<-w> flag.
 176 Unlike a C<foreach> statement, a C<while> statement never implicitly
 177 localises any variables.
 178
 179 If there is a C<continue> BLOCK, it is always executed just before the
 180 conditional is about to be evaluated again, just like the third part of a
 181 C<for> loop in C.  Thus it can be used to increment a loop variable, even
 182 when the loop has been continued via the C<next> statement (which is
 183 similar to the C C<continue> statement).
 184
 185 =head2 Loop Control
 186
 187 The C<next> command is like the C<continue> statement in C; it starts
 188 the next iteration of the loop:
 189
 190     LINE: while (<STDIN>) {
 191         next LINE if /^#/;      # discard comments
 192         ...
 193     }
 194
 195 The C<last> command is like the C<break> statement in C (as used in
 196 loops); it immediately exits the loop in question.  The
 197 C<continue> block, if any, is not executed:
 198
 199     LINE: while (<STDIN>) {
 200         last LINE if /^$/;      # exit when done with header
 201         ...
 202     }
 203
 204 The C<redo> command restarts the loop block without evaluating the
 205 conditional again.  The C<continue> block, if any, is I<not> executed.
 206 This command is normally used by programs that want to lie to themselves
 207 about what was just input.
 208
 209 For example, when processing a file like F</etc/termcap>.
 210 If your input lines might end in backslashes to indicate continuation, you
 211 want to skip ahead and get the next record.
 212
 213     while (<>) {
 214         chomp;
 215         if (s/\\$//) {
 216             $_ .= <>;
 217             redo unless eof();
 218         }
 219         # now process $_
 220     }
 221
 222 which is Perl short-hand for the more explicitly written version:
 223
 224     LINE: while (defined($line = <ARGV>)) {
 225         chomp($line);
 226         if ($line =~ s/\\$//) {
 227             $line .= <ARGV>;
 228             redo LINE unless eof(); # not eof(ARGV)!
 229         }
 230         # now process $line
 231     }
 232
 233 Note that if there were a C<continue> block on the above code, it would
 234 get executed only on lines discarded by the regex (since redo skips the
 235 continue block). A continue block is often used to reset line counters
 236 or C<?pat?> one-time matches:
 237
 238     # inspired by :1,$g/fred/s//WILMA/
 239     while (<>) {
 240         ?(fred)?    && s//WILMA $1 WILMA/;
 241         ?(barney)?  && s//BETTY $1 BETTY/;
 242         ?(homer)?   && s//MARGE $1 MARGE/;
 243     } continue {
 244         print "$ARGV $.: $_";
 245         close ARGV  if eof();           # reset $.
 246         reset       if eof();           # reset ?pat?
 247     }
 248
 249 If the word C<while> is replaced by the word C<until>, the sense of the
 250 test is reversed, but the conditional is still tested before the first
 251 iteration.
 252
 253 The loop control statements don't work in an C<if> or C<unless>, since
 254 they aren't loops.  You can double the braces to make them such, though.
 255
 256     if (/pattern/) {{
 257         next if /fred/;
 258         next if /barney/;
 259         # so something here
 260     }}
 261
 262 The form C<while/if BLOCK BLOCK>, available in Perl 4, is no longer
 263 available.   Replace any occurrence of C<if BLOCK> by C<if (do BLOCK)>.
 264
 265 =head2 For Loops
 266
 267 Perl's C-style C<for> loop works like the corresponding C<while> loop;
 268 that means that this:
 269
 270     for ($i = 1; $i < 10; $i++) {
 271         ...
 272     }
 273
 274 is the same as this:
 275
 276     $i = 1;
 277     while ($i < 10) {
 278         ...
 279     } continue {
 280         $i++;
 281     }
 282
 283 There is one minor difference: if variables are declared with C<my>
 284 in the initialization section of the C<for>, the lexical scope of
 285 those variables is exactly the C<for> loop (the body of the loop
 286 and the control sections).
 287
 288 Besides the normal array index looping, C<for> can lend itself
 289 to many other interesting applications.  Here's one that avoids the
 290 problem you get into if you explicitly test for end-of-file on
 291 an interactive file descriptor causing your program to appear to
 292 hang.
 293
 294     $on_a_tty = -t STDIN && -t STDOUT;
 295     sub prompt { print "yes? " if $on_a_tty }
 296     for ( prompt(); <STDIN>; prompt() ) {
 297         # do something
 298     }
 299
 300 =head2 Foreach Loops
 301
 302 The C<foreach> loop iterates over a normal list value and sets the
 303 variable VAR to be each element of the list in turn.  If the variable
 304 is preceded with the keyword C<my>, then it is lexically scoped, and
 305 is therefore visible only within the loop.  Otherwise, the variable is
 306 implicitly local to the loop and regains its former value upon exiting
 307 the loop.  If the variable was previously declared with C<my>, it uses
 308 that variable instead of the global one, but it's still localized to
 309 the loop.
 310
 311 The C<foreach> keyword is actually a synonym for the C<for> keyword, so
 312 you can use C<foreach> for readability or C<for> for brevity.  (Or because
 313 the Bourne shell is more familiar to you than I<csh>, so writing C<for>
 314 comes more naturally.)  If VAR is omitted, C<$_> is set to each value.
 315
 316 If any element of LIST is an lvalue, you can modify it by modifying
 317 VAR inside the loop.  Conversely, if any element of LIST is NOT an
 318 lvalue, any attempt to modify that element will fail.  In other words,
 319 the C<foreach> loop index variable is an implicit alias for each item
 320 in the list that you're looping over.
 321
 322 If any part of LIST is an array, C<foreach> will get very confused if
 323 you add or remove elements within the loop body, for example with
 324 C<splice>.   So don't do that.
 325
 326 C<foreach> probably won't do what you expect if VAR is a tied or other
 327 special variable.   Don't do that either.
 328
 329 Examples:
 330
 331     for (@ary) { s/foo/bar/ }
 332
 333     for my $elem (@elements) {
 334         $elem *= 2;
 335     }
 336
 337     for $count (10,9,8,7,6,5,4,3,2,1,'BOOM') {
 338         print $count, "\n"; sleep(1);
 339     }
 340
 341     for (1..15) { print "Merry Christmas\n"; }
 342
 343     foreach $item (split(/:[\\\n:]*/, $ENV{TERMCAP})) {
 344         print "Item: $item\n";
 345     }
 346
 347 Here's how a C programmer might code up a particular algorithm in Perl:
 348
 349     for (my $i = 0; $i < @ary1; $i++) {
 350         for (my $j = 0; $j < @ary2; $j++) {
 351             if ($ary1[$i] > $ary2[$j]) {
 352                 last; # can't go to outer :-(
 353             }
 354             $ary1[$i] += $ary2[$j];
 355         }
 356         # this is where that last takes me
 357     }
 358
 359 Whereas here's how a Perl programmer more comfortable with the idiom might
 360 do it:
 361
 362     OUTER: for my $wid (@ary1) {
 363     INNER:   for my $jet (@ary2) {
 364                 next OUTER if $wid > $jet;
 365                 $wid += $jet;
 366              }
 367           }
 368
 369 See how much easier this is?  It's cleaner, safer, and faster.  It's
 370 cleaner because it's less noisy.  It's safer because if code gets added
 371 between the inner and outer loops later on, the new code won't be
 372 accidentally executed.  The C<next> explicitly iterates the other loop
 373 rather than merely terminating the inner one.  And it's faster because
 374 Perl executes a C<foreach> statement more rapidly than it would the
 375 equivalent C<for> loop.
 376
 377 =head2 Basic BLOCKs and Switch Statements
 378
 379 A BLOCK by itself (labeled or not) is semantically equivalent to a
 380 loop that executes once.  Thus you can use any of the loop control
 381 statements in it to leave or restart the block.  (Note that this is
 382 I<NOT> true in C<eval{}>, C<sub{}>, or contrary to popular belief
 383 C<do{}> blocks, which do I<NOT> count as loops.)  The C<continue>
 384 block is optional.
 385
 386 The BLOCK construct is particularly nice for doing case
 387 structures.
 388
 389     SWITCH: {
 390         if (/^abc/) { $abc = 1; last SWITCH; }
 391         if (/^def/) { $def = 1; last SWITCH; }
 392         if (/^xyz/) { $xyz = 1; last SWITCH; }
 393         $nothing = 1;
 394     }
 395
 396 There is no official C<switch> statement in Perl, because there are
 397 already several ways to write the equivalent.
 398
 399 However, starting from Perl 5.8 to get switch and case one can use
 400 the Switch extension and say:
 401
 402         use Switch;
 403
 404 after which one has switch and case.  It is not as fast as it could be
 405 because it's not really part of the language (it's done using source
 406 filters) but it is available, and it's very flexible.
 407
 408 In addition to the above BLOCK construct, you could write
 409
 410     SWITCH: {
 411         $abc = 1, last SWITCH  if /^abc/;
 412         $def = 1, last SWITCH  if /^def/;
 413         $xyz = 1, last SWITCH  if /^xyz/;
 414         $nothing = 1;
 415     }
 416
 417 (That's actually not as strange as it looks once you realize that you can
 418 use loop control "operators" within an expression,  That's just the normal
 419 C comma operator.)
 420
 421 or
 422
 423     SWITCH: {
 424         /^abc/ && do { $abc = 1; last SWITCH; };
 425         /^def/ && do { $def = 1; last SWITCH; };
 426         /^xyz/ && do { $xyz = 1; last SWITCH; };
 427         $nothing = 1;
 428     }
 429
 430 or formatted so it stands out more as a "proper" C<switch> statement:
 431
 432     SWITCH: {
 433         /^abc/      && do {
 434                             $abc = 1;
 435                             last SWITCH;
 436                        };
 437
 438         /^def/      && do {
 439                             $def = 1;
 440                             last SWITCH;
 441                        };
 442
 443         /^xyz/      && do {
 444                             $xyz = 1;
 445                             last SWITCH;
 446                         };
 447         $nothing = 1;
 448     }
 449
 450 or
 451
 452     SWITCH: {
 453         /^abc/ and $abc = 1, last SWITCH;
 454         /^def/ and $def = 1, last SWITCH;
 455         /^xyz/ and $xyz = 1, last SWITCH;
 456         $nothing = 1;
 457     }
 458
 459 or even, horrors,
 460
 461     if (/^abc/)
 462         { $abc = 1 }
 463     elsif (/^def/)
 464         { $def = 1 }
 465     elsif (/^xyz/)
 466         { $xyz = 1 }
 467     else
 468         { $nothing = 1 }
 469
 470 A common idiom for a C<switch> statement is to use C<foreach>'s aliasing to make
 471 a temporary assignment to C<$_> for convenient matching:
 472
 473     SWITCH: for ($where) {
 474                 /In Card Names/     && do { push @flags, '-e'; last; };
 475                 /Anywhere/          && do { push @flags, '-h'; last; };
 476                 /In Rulings/        && do {                    last; };
 477                 die "unknown value for form variable where: `$where'";
 478             }
 479
 480 Another interesting approach to a switch statement is arrange
 481 for a C<do> block to return the proper value:
 482
 483     $amode = do {
 484         if     ($flag & O_RDONLY) { "r" }       # XXX: isn't this 0?
 485         elsif  ($flag & O_WRONLY) { ($flag & O_APPEND) ? "a" : "w" }
 486         elsif  ($flag & O_RDWR)   {
 487             if ($flag & O_CREAT)  { "w+" }
 488             else                  { ($flag & O_APPEND) ? "a+" : "r+" }
 489         }
 490     };
 491
 492 Or
 493
 494         print do {
 495             ($flags & O_WRONLY) ? "write-only"          :
 496             ($flags & O_RDWR)   ? "read-write"          :
 497                                   "read-only";
 498         };
 499
 500 Or if you are certain that all the C<&&> clauses are true, you can use
 501 something like this, which "switches" on the value of the
 502 C<HTTP_USER_AGENT> environment variable.
 503
 504     #!/usr/bin/perl
 505     # pick out jargon file page based on browser
 506     $dir = 'http://www.wins.uva.nl/~mes/jargon';
 507     for ($ENV{HTTP_USER_AGENT}) {
 508         $page  =    /Mac/            && 'm/Macintrash.html'
 509                  || /Win(dows )?NT/  && 'e/evilandrude.html'
 510                  || /Win|MSIE|WebTV/ && 'm/MicroslothWindows.html'
 511                  || /Linux/          && 'l/Linux.html'
 512                  || /HP-UX/          && 'h/HP-SUX.html'
 513                  || /SunOS/          && 's/ScumOS.html'
 514                  ||                     'a/AppendixB.html';
 515     }
 516     print "Location: $dir/$page\015\012\015\012";
 517
 518 That kind of switch statement only works when you know the C<&&> clauses
 519 will be true.  If you don't, the previous C<?:> example should be used.
 520
 521 You might also consider writing a hash of subroutine references
 522 instead of synthesizing a C<switch> statement.
 523
 524 =head2 Goto
 525
 526 Although not for the faint of heart, Perl does support a C<goto>
 527 statement.  There are three forms: C<goto>-LABEL, C<goto>-EXPR, and
 528 C<goto>-&NAME.  A loop's LABEL is not actually a valid target for
 529 a C<goto>; it's just the name of the loop.
 530
 531 The C<goto>-LABEL form finds the statement labeled with LABEL and resumes
 532 execution there.  It may not be used to go into any construct that
 533 requires initialization, such as a subroutine or a C<foreach> loop.  It
 534 also can't be used to go into a construct that is optimized away.  It
 535 can be used to go almost anywhere else within the dynamic scope,
 536 including out of subroutines, but it's usually better to use some other
 537 construct such as C<last> or C<die>.  The author of Perl has never felt the
 538 need to use this form of C<goto> (in Perl, that is--C is another matter).
 539
 540 The C<goto>-EXPR form expects a label name, whose scope will be resolved
 541 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
 542 necessarily recommended if you're optimizing for maintainability:
 543
 544     goto(("FOO", "BAR", "GLARCH")[$i]);
 545
 546 The C<goto>-&NAME form is highly magical, and substitutes a call to the
 547 named subroutine for the currently running subroutine.  This is used by
 548 C<AUTOLOAD()> subroutines that wish to load another subroutine and then
 549 pretend that the other subroutine had been called in the first place
 550 (except that any modifications to C<@_> in the current subroutine are
 551 propagated to the other subroutine.)  After the C<goto>, not even C<caller()>
 552 will be able to tell that this routine was called first.
 553
 554 In almost all cases like this, it's usually a far, far better idea to use the
 555 structured control flow mechanisms of C<next>, C<last>, or C<redo> instead of
 556 resorting to a C<goto>.  For certain applications, the catch and throw pair of
 557 C<eval{}> and die() for exception processing can also be a prudent approach.
 558
 559 =head2 PODs: Embedded Documentation
 560
 561 Perl has a mechanism for intermixing documentation with source code.
 562 While it's expecting the beginning of a new statement, if the compiler
 563 encounters a line that begins with an equal sign and a word, like this
 564
 565     =head1 Here There Be Pods!
 566
 567 Then that text and all remaining text up through and including a line
 568 beginning with C<=cut> will be ignored.  The format of the intervening
 569 text is described in L<perlpod>.
 570
 571 This allows you to intermix your source code
 572 and your documentation text freely, as in
 573
 574     =item snazzle($)
 575
 576     The snazzle() function will behave in the most spectacular
 577     form that you can possibly imagine, not even excepting
 578     cybernetic pyrotechnics.
 579
 580     =cut back to the compiler, nuff of this pod stuff!
 581
 582     sub snazzle($) {
 583         my $thingie = shift;
 584         .........
 585     }
 586
 587 Note that pod translators should look at only paragraphs beginning
 588 with a pod directive (it makes parsing easier), whereas the compiler
 589 actually knows to look for pod escapes even in the middle of a
 590 paragraph.  This means that the following secret stuff will be
 591 ignored by both the compiler and the translators.
 592
 593     $a=3;
 594     =secret stuff
 595      warn "Neither POD nor CODE!?"
 596     =cut back
 597     print "got $a\n";
 598
 599 You probably shouldn't rely upon the C<warn()> being podded out forever.
 600 Not all pod translators are well-behaved in this regard, and perhaps
 601 the compiler will become pickier.
 602
 603 One may also use pod directives to quickly comment out a section
 604 of code.
 605
 606 =head2 Plain Old Comments (Not!)
 607
 608 Much like the C preprocessor, Perl can process line directives.  Using
 609 this, one can control Perl's idea of filenames and line numbers in
 610 error or warning messages (especially for strings that are processed
 611 with C<eval()>).  The syntax for this mechanism is the same as for most
 612 C preprocessors: it matches the regular expression
 613 C</^#\s*line\s+(\d+)\s*(?:\s"([^"]+)")?\s*$/> with C<$1> being the line
 614 number for the next line, and C<$2> being the optional filename
 615 (specified within quotes).
 616
 617 There is a fairly obvious gotcha included with the line directive:
 618 Debuggers and profilers will only show the last source line to appear
 619 at a particular line number in a given file.  Care should be taken not
 620 to cause line number collisions in code you'd like to debug later.
 621
 622 Here are some examples that you should be able to type into your command
 623 shell:
 624
 625     % perl
 626     # line 200 "bzzzt"
 627     # the `#' on the previous line must be the first char on line
 628     die 'foo';
 629     __END__
 630     foo at bzzzt line 201.
 631
 632     % perl
 633     # line 200 "bzzzt"
 634     eval qq[\n#line 2001 ""\ndie 'foo']; print $@;
 635     __END__
 636     foo at - line 2001.
 637
 638     % perl
 639     eval qq[\n#line 200 "foo bar"\ndie 'foo']; print $@;
 640     __END__
 641     foo at foo bar line 200.
 642
 643     % perl
 644     # line 345 "goop"
 645     eval "\n#line " . __LINE__ . ' "' . __FILE__ ."\"\ndie 'foo'";
 646     print $@;
 647     __END__
 648     foo at goop line 345.
 649
 650 =cut