lib/File/Path.pm

   1 package File::Path;
   2
   3 =head1 NAME
   4
   5 File::Path - create or remove a series of directories
   6
   7 =head1 SYNOPSIS
   8
   9 C<use File::Path>
  10
  11 C<mkpath(['/foo/bar/baz', 'blurfl/quux'], 1, 0711);>
  12
  13 C<rmtree(['foo/bar/baz', 'blurfl/quux'], 1, 1);>
  14
  15 =head1 DESCRIPTION
  16
  17 The C<mkpath> function provides a convenient way to create directories, even if
  18 your C<mkdir> kernel call won't create more than one level of directory at a
  19 time.  C<mkpath> takes three arguments:
  20
  21 =over 4
  22
  23 =item *
  24
  25 the name of the path to create, or a reference
  26 to a list of paths to create,
  27
  28 =item *
  29
  30 a boolean value, which if TRUE will cause C<mkpath>
  31 to print the name of each directory as it is created
  32 (defaults to FALSE), and
  33
  34 =item *
  35
  36 the numeric mode to use when creating the directories
  37 (defaults to 0777)
  38
  39 =back
  40
  41 It returns a list of all directories (including intermediates, determined using
  42 the Unix '/' separator) created.
  43
  44 Similarly, the C<rmtree> function provides a convenient way to delete a
  45 subtree from the directory structure, much like the Unix command C<rm -r>.
  46 C<rmtree> takes three arguments:
  47
  48 =over 4
  49
  50 =item *
  51
  52 the root of the subtree to delete, or a reference to
  53 a list of roots.  All of the files and directories
  54 below each root, as well as the roots themselves,
  55 will be deleted.
  56
  57 =item *
  58
  59 a boolean value, which if TRUE will cause C<rmtree> to
  60 print a message each time it examines a file, giving the
  61 name of the file, and indicating whether it's using C<rmdir>
  62 or C<unlink> to remove it, or that it's skipping it.
  63 (defaults to FALSE)
  64
  65 =item *
  66
  67 a boolean value, which if TRUE will cause C<rmtree> to
  68 skip any files to which you do not have delete access
  69 (if running under VMS) or write access (if running
  70 under another OS).  This will change in the future when
  71 a criterion for 'delete permission' under OSs other
  72 than VMS is settled. (defaults to FALSE)
  73
  74 =back
  75
  76 It returns the number of files successfully deleted. Symlinks are
  77 treated as ordinary files.
  78
  79 =head1 AUTHORS
  80
  81 Tim Bunce E<lt>F<Tim.Bunce@ig.co.uk>E<gt>
  82 Charles Bailey E<lt>F<bailey@genetics.upenn.edu>E<gt>
  83
  84 =head1 REVISION
  85
  86 This module was last revised 14-Feb-1996, for perl 5.002.
  87 $VERSION is 1.0101.
  88
  89 =cut
  90
  91 require 5.000;
  92 use Carp;
  93 use File::Basename;
  94 require Exporter;
  95
  96 use vars qw( $VERSION @ISA @EXPORT );
  97 $VERSION = "1.0101";
  98 @ISA = qw( Exporter );
  99 @EXPORT = qw( mkpath rmtree );
 100
 101 my $Is_VMS = $^O eq 'VMS';
 102 my $force_writeable = ($^O eq 'os2' || $^O eq 'msdos' || $^O eq 'MSWin32'
 103                        || $^O eq 'amigaos');
 104
 105 sub mkpath {
 106     my($paths, $verbose, $mode) = @_;
 107     # $paths   -- either a path string or ref to list of paths
 108     # $verbose -- optional print "mkdir $path" for each directory created
 109     # $mode    -- optional permissions, defaults to 0777
 110     local($")="/";
 111     $mode = 0777 unless defined($mode);
 112     $paths = [$paths] unless ref $paths;
 113     my(@created);
 114     foreach $path (@$paths) {
 115         next if -d $path;
 116         my $parent = dirname($path);
 117         push(@created,mkpath($parent, $verbose, $mode)) unless (-d $parent);
 118         print "mkdir $path\n" if $verbose;
 119         mkdir($path,$mode) || croak "mkdir $path: $!";
 120         push(@created, $path);
 121     }
 122     @created;
 123 }
 124
 125 sub rmtree {
 126     my($roots, $verbose, $safe) = @_;
 127     my(@files);
 128     my($count) = 0;
 129     $roots = [$roots] unless ref $roots;
 130
 131     foreach $root (@{$roots}) {
 132        $root =~ s#/$##;
 133        if (not -l $root and -d _) {
 134            opendir(D,$root);
 135            @files = readdir(D);
 136            closedir(D);
 137            # Deleting large numbers of files from VMS Files-11 filesystems
 138            # is faster if done in reverse ASCIIbetical order
 139            @files = reverse @files if $Is_VMS;
 140            ($root = VMS::Filespec::unixify($root)) =~ s#\.dir$## if $Is_VMS;
 141            @files = map("$root/$_", grep $_!~/^\.{1,2}$/,@files);
 142            $count += rmtree(\@files,$verbose,$safe);
 143            if ($safe &&
 144                ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 145                print "skipped $root\n" if $verbose;
 146                next;
 147            }
 148            chmod 0777, $root or carp "Can't make directory $root writeable: $!"
 149                if $force_writeable;
 150            print "rmdir $root\n" if $verbose;
 151            (rmdir $root && ++$count) or carp "Can't remove directory $root: $!";
 152         }
 153         else {
 154            if ($safe &&
 155                ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 156                print "skipped $root\n" if $verbose;
 157                next;
 158            }
 159            chmod 0666, $root or carp "Can't make file $root writeable: $!"
 160                if $force_writeable;
 161            print "unlink $root\n" if $verbose;
 162            while (-e $root || -l $root) { # delete all versions under VMS
 163                (unlink($root) && ++$count)
 164                    or croak "Can't unlink file $root: $!";
 165            }
 166         }
 167     }
 168
 169     $count;
 170 }
 171
 172 1;
 173
 174 __END__