4 perltie - how to hide an object class in a simple variable
8 tie VARIABLE, CLASSNAME, LIST
10 $object = tied VARIABLE
16 Prior to release 5.0 of Perl, a programmer could use dbmopen()
17 to connect an on-disk database in the standard Unix dbm(3x)
18 format magically to a %HASH in their program. However, their Perl was either
19 built with one particular dbm library or another, but not both, and
20 you couldn't extend this mechanism to other packages or types of variables.
24 The tie() function binds a variable to a class (package) that will provide
25 the implementation for access methods for that variable. Once this magic
26 has been performed, accessing a tied variable automatically triggers
27 method calls in the proper class. The complexity of the class is
28 hidden behind magic methods calls. The method names are in ALL CAPS,
29 which is a convention that Perl uses to indicate that they're called
30 implicitly rather than explicitly--just like the BEGIN() and END()
33 In the tie() call, C<VARIABLE> is the name of the variable to be
34 enchanted. C<CLASSNAME> is the name of a class implementing objects of
35 the correct type. Any additional arguments in the C<LIST> are passed to
36 the appropriate constructor method for that class--meaning TIESCALAR(),
37 TIEARRAY(), TIEHASH(), or TIEHANDLE(). (Typically these are arguments
38 such as might be passed to the dbminit() function of C.) The object
39 returned by the "new" method is also returned by the tie() function,
40 which would be useful if you wanted to access other methods in
41 C<CLASSNAME>. (You don't actually have to return a reference to a right
42 "type" (e.g., HASH or C<CLASSNAME>) so long as it's a properly blessed
43 object.) You can also retrieve a reference to the underlying object
44 using the tied() function.
46 Unlike dbmopen(), the tie() function will not C<use> or C<require> a module
47 for you--you need to do that explicitly yourself.
52 A class implementing a tied scalar should define the following methods:
53 TIESCALAR, FETCH, STORE, and possibly UNTIE and/or DESTROY.
55 Let's look at each in turn, using as an example a tie class for
56 scalars that allows the user to do something like:
58 tie $his_speed, 'Nice', getppid();
59 tie $my_speed, 'Nice', $$;
61 And now whenever either of those variables is accessed, its current
62 system priority is retrieved and returned. If those variables are set,
63 then the process's priority is changed!
65 We'll use Jarkko Hietaniemi <F<jhi@iki.fi>>'s BSD::Resource class (not
66 included) to access the PRIO_PROCESS, PRIO_MIN, and PRIO_MAX constants
67 from your system, as well as the getpriority() and setpriority() system
68 calls. Here's the preamble of the class.
74 $Nice::DEBUG = 0 unless defined $Nice::DEBUG;
78 =item TIESCALAR classname, LIST
81 This is the constructor for the class. That means it is
82 expected to return a blessed reference to a new scalar
83 (probably anonymous) that it's creating. For example:
87 my $pid = shift || $$; # 0 means me
89 if ($pid !~ /^\d+$/) {
90 carp "Nice::Tie::Scalar got non-numeric pid $pid" if $^W;
94 unless (kill 0, $pid) { # EPERM or ERSCH, no doubt
95 carp "Nice::Tie::Scalar got bad pid $pid: $!" if $^W;
99 return bless \$pid, $class;
102 This tie class has chosen to return an error rather than raising an
103 exception if its constructor should fail. While this is how dbmopen() works,
104 other classes may well not wish to be so forgiving. It checks the global
105 variable C<$^W> to see whether to emit a bit of noise anyway.
110 This method will be triggered every time the tied variable is accessed
111 (read). It takes no arguments beyond its self reference, which is the
112 object representing the scalar we're dealing with. Because in this case
113 we're using just a SCALAR ref for the tied scalar object, a simple $$self
114 allows the method to get at the real value stored there. In our example
115 below, that real value is the process ID to which we've tied our variable.
119 confess "wrong type" unless ref $self;
120 croak "usage error" if @_;
123 $nicety = getpriority(PRIO_PROCESS, $$self);
124 if ($!) { croak "getpriority failed: $!" }
128 This time we've decided to blow up (raise an exception) if the renice
129 fails--there's no place for us to return an error otherwise, and it's
130 probably the right thing to do.
132 =item STORE this, value
135 This method will be triggered every time the tied variable is set
136 (assigned). Beyond its self reference, it also expects one (and only one)
137 argument: the new value the user is trying to assign. Don't worry about
138 returning a value from STORE; the semantic of assignment returning the
139 assigned value is implemented with FETCH.
143 confess "wrong type" unless ref $self;
144 my $new_nicety = shift;
145 croak "usage error" if @_;
147 if ($new_nicety < PRIO_MIN) {
149 "WARNING: priority %d less than minimum system priority %d",
150 $new_nicety, PRIO_MIN if $^W;
151 $new_nicety = PRIO_MIN;
154 if ($new_nicety > PRIO_MAX) {
156 "WARNING: priority %d greater than maximum system priority %d",
157 $new_nicety, PRIO_MAX if $^W;
158 $new_nicety = PRIO_MAX;
161 unless (defined setpriority(PRIO_PROCESS,
165 confess "setpriority failed: $!";
172 This method will be triggered when the C<untie> occurs. This can be useful
173 if the class needs to know when no further calls will be made. (Except DESTROY
174 of course.) See L</The C<untie> Gotcha> below for more details.
179 This method will be triggered when the tied variable needs to be destructed.
180 As with other object classes, such a method is seldom necessary, because Perl
181 deallocates its moribund object's memory for you automatically--this isn't
182 C++, you know. We'll use a DESTROY method here for debugging purposes only.
186 confess "wrong type" unless ref $self;
187 carp "[ Nice::DESTROY pid $$self ]" if $Nice::DEBUG;
192 That's about all there is to it. Actually, it's more than all there
193 is to it, because we've done a few nice things here for the sake
194 of completeness, robustness, and general aesthetics. Simpler
195 TIESCALAR classes are certainly possible.
200 A class implementing a tied ordinary array should define the following
201 methods: TIEARRAY, FETCH, STORE, FETCHSIZE, STORESIZE, CLEAR
202 and perhaps UNTIE and/or DESTROY.
204 FETCHSIZE and STORESIZE are used to provide C<$#array> and
205 equivalent C<scalar(@array)> access.
207 The methods POP, PUSH, SHIFT, UNSHIFT, SPLICE, DELETE, and EXISTS are
208 required if the perl operator with the corresponding (but lowercase) name
209 is to operate on the tied array. The B<Tie::Array> class can be used as a
210 base class to implement the first five of these in terms of the basic
211 methods above. The default implementations of DELETE and EXISTS in
212 B<Tie::Array> simply C<croak>.
214 In addition EXTEND will be called when perl would have pre-extended
215 allocation in a real array.
217 For this discussion, we'll implement an array whose elements are a fixed
218 size at creation. If you try to create an element larger than the fixed
219 size, you'll take an exception. For example:
222 tie @array, 'FixedElem_Array', 3;
223 $array[0] = 'cat'; # ok.
224 $array[1] = 'dogs'; # exception, length('dogs') > 3.
226 The preamble code for the class is as follows:
228 package FixedElem_Array;
234 =item TIEARRAY classname, LIST
237 This is the constructor for the class. That means it is expected to
238 return a blessed reference through which the new array (probably an
239 anonymous ARRAY ref) will be accessed.
241 In our example, just to show you that you don't I<really> have to return an
242 ARRAY reference, we'll choose a HASH reference to represent our object.
243 A HASH works out well as a generic record type: the C<{ELEMSIZE}> field will
244 store the maximum element size allowed, and the C<{ARRAY}> field will hold the
245 true ARRAY ref. If someone outside the class tries to dereference the
246 object returned (doubtless thinking it an ARRAY ref), they'll blow up.
247 This just goes to show you that you should respect an object's privacy.
251 my $elemsize = shift;
252 if ( @_ || $elemsize =~ /\D/ ) {
253 croak "usage: tie ARRAY, '" . __PACKAGE__ . "', elem_size";
256 ELEMSIZE => $elemsize,
261 =item FETCH this, index
264 This method will be triggered every time an individual element the tied array
265 is accessed (read). It takes one argument beyond its self reference: the
266 index whose value we're trying to fetch.
271 return $self->{ARRAY}->[$index];
274 If a negative array index is used to read from an array, the index
275 will be translated to a positive one internally by calling FETCHSIZE
276 before being passed to FETCH. You may disable this feature by
277 assigning a true value to the variable C<$NEGATIVE_INDICES> in the
280 As you may have noticed, the name of the FETCH method (et al.) is the same
281 for all accesses, even though the constructors differ in names (TIESCALAR
282 vs TIEARRAY). While in theory you could have the same class servicing
283 several tied types, in practice this becomes cumbersome, and it's easiest
284 to keep them at simply one tie type per class.
286 =item STORE this, index, value
289 This method will be triggered every time an element in the tied array is set
290 (written). It takes two arguments beyond its self reference: the index at
291 which we're trying to store something and the value we're trying to put
294 In our example, C<undef> is really C<$self-E<gt>{ELEMSIZE}> number of
295 spaces so we have a little more work to do here:
299 my( $index, $value ) = @_;
300 if ( length $value > $self->{ELEMSIZE} ) {
301 croak "length of $value is greater than $self->{ELEMSIZE}";
304 $self->EXTEND( $index ) if $index > $self->FETCHSIZE();
305 # right justify to keep element size for smaller elements
306 $self->{ARRAY}->[$index] = sprintf "%$self->{ELEMSIZE}s", $value;
309 Negative indexes are treated the same as with FETCH.
314 Returns the total number of items in the tied array associated with
315 object I<this>. (Equivalent to C<scalar(@array)>). For example:
319 return scalar @{$self->{ARRAY}};
322 =item STORESIZE this, count
325 Sets the total number of items in the tied array associated with
326 object I<this> to be I<count>. If this makes the array larger then
327 class's mapping of C<undef> should be returned for new positions.
328 If the array becomes smaller then entries beyond count should be
331 In our example, 'undef' is really an element containing
332 C<$self-E<gt>{ELEMSIZE}> number of spaces. Observe:
337 if ( $count > $self->FETCHSIZE() ) {
338 foreach ( $count - $self->FETCHSIZE() .. $count ) {
339 $self->STORE( $_, '' );
341 } elsif ( $count < $self->FETCHSIZE() ) {
342 foreach ( 0 .. $self->FETCHSIZE() - $count - 2 ) {
348 =item EXTEND this, count
351 Informative call that array is likely to grow to have I<count> entries.
352 Can be used to optimize allocation. This method need do nothing.
354 In our example, we want to make sure there are no blank (C<undef>)
355 entries, so C<EXTEND> will make use of C<STORESIZE> to fill elements
361 $self->STORESIZE( $count );
364 =item EXISTS this, key
367 Verify that the element at index I<key> exists in the tied array I<this>.
369 In our example, we will determine that if an element consists of
370 C<$self-E<gt>{ELEMSIZE}> spaces only, it does not exist:
375 return 0 if ! defined $self->{ARRAY}->[$index] ||
376 $self->{ARRAY}->[$index] eq ' ' x $self->{ELEMSIZE};
380 =item DELETE this, key
383 Delete the element at index I<key> from the tied array I<this>.
385 In our example, a deleted item is C<$self-E<gt>{ELEMSIZE}> spaces:
390 return $self->STORE( $index, '' );
396 Clear (remove, delete, ...) all values from the tied array associated with
397 object I<this>. For example:
401 return $self->{ARRAY} = [];
404 =item PUSH this, LIST
407 Append elements of I<LIST> to the array. For example:
412 my $last = $self->FETCHSIZE();
413 $self->STORE( $last + $_, $list[$_] ) foreach 0 .. $#list;
414 return $self->FETCHSIZE();
420 Remove last element of the array and return it. For example:
424 return pop @{$self->{ARRAY}};
430 Remove the first element of the array (shifting other elements down)
431 and return it. For example:
435 return shift @{$self->{ARRAY}};
438 =item UNSHIFT this, LIST
441 Insert LIST elements at the beginning of the array, moving existing elements
442 up to make room. For example:
447 my $size = scalar( @list );
448 # make room for our list
449 @{$self->{ARRAY}}[ $size .. $#{$self->{ARRAY}} + $size ]
451 $self->STORE( $_, $list[$_] ) foreach 0 .. $#list;
454 =item SPLICE this, offset, length, LIST
457 Perform the equivalent of C<splice> on the array.
459 I<offset> is optional and defaults to zero, negative values count back
460 from the end of the array.
462 I<length> is optional and defaults to rest of the array.
464 I<LIST> may be empty.
466 Returns a list of the original I<length> elements at I<offset>.
468 In our example, we'll use a little shortcut if there is a I<LIST>:
472 my $offset = shift || 0;
473 my $length = shift || $self->FETCHSIZE() - $offset;
476 tie @list, __PACKAGE__, $self->{ELEMSIZE};
479 return splice @{$self->{ARRAY}}, $offset, $length, @list;
485 Will be called when C<untie> happens. (See L</The C<untie> Gotcha> below.)
490 This method will be triggered when the tied variable needs to be destructed.
491 As with the scalar tie class, this is almost never needed in a
492 language that does its own garbage collection, so this time we'll
500 Hashes were the first Perl data type to be tied (see dbmopen()). A class
501 implementing a tied hash should define the following methods: TIEHASH is
502 the constructor. FETCH and STORE access the key and value pairs. EXISTS
503 reports whether a key is present in the hash, and DELETE deletes one.
504 CLEAR empties the hash by deleting all the key and value pairs. FIRSTKEY
505 and NEXTKEY implement the keys() and each() functions to iterate over all
506 the keys. SCALAR is triggered when the tied hash is evaluated in scalar
507 context, and in 5.28 onwards, by C<keys> in boolean context. UNTIE is
508 called when C<untie> happens, and DESTROY is called when the tied variable
509 is garbage collected.
511 If this seems like a lot, then feel free to inherit from merely the
512 standard Tie::StdHash module for most of your methods, redefining only the
513 interesting ones. See L<Tie::Hash> for details.
515 Remember that Perl distinguishes between a key not existing in the hash,
516 and the key existing in the hash but having a corresponding value of
517 C<undef>. The two possibilities can be tested with the C<exists()> and
518 C<defined()> functions.
520 Here's an example of a somewhat interesting tied hash class: it gives you
521 a hash representing a particular user's dot files. You index into the hash
522 with the name of the file (minus the dot) and you get back that dot file's
523 contents. For example:
526 tie %dot, 'DotFiles';
527 if ( $dot{profile} =~ /MANPATH/ ||
528 $dot{login} =~ /MANPATH/ ||
529 $dot{cshrc} =~ /MANPATH/ )
531 print "you seem to set your MANPATH\n";
534 Or here's another sample of using our tied class:
536 tie %him, 'DotFiles', 'daemon';
537 foreach $f ( keys %him ) {
538 printf "daemon dot file %s is size %d\n",
542 In our tied hash DotFiles example, we use a regular
543 hash for the object containing several important
544 fields, of which only the C<{LIST}> field will be what the
545 user thinks of as the real hash.
551 whose dot files this object represents
555 where those dot files live
559 whether we should try to change or remove those dot files
563 the hash of dot file names and content mappings
567 Here's the start of F<Dotfiles.pm>:
571 sub whowasi { (caller(1))[3] . '()' }
573 sub debug { $DEBUG = @_ ? shift : 1 }
575 For our example, we want to be able to emit debugging info to help in tracing
576 during development. We keep also one convenience function around
577 internally to help print out warnings; whowasi() returns the function name
580 Here are the methods for the DotFiles tied hash.
584 =item TIEHASH classname, LIST
587 This is the constructor for the class. That means it is expected to
588 return a blessed reference through which the new object (probably but not
589 necessarily an anonymous hash) will be accessed.
591 Here's the constructor:
595 my $user = shift || $>;
596 my $dotdir = shift || '';
597 croak "usage: @{[&whowasi]} [USER [DOTDIR]]" if @_;
598 $user = getpwuid($user) if $user =~ /^\d+$/;
599 my $dir = (getpwnam($user))[7]
600 || croak "@{[&whowasi]}: no user $user";
601 $dir .= "/$dotdir" if $dotdir;
611 || croak "@{[&whowasi]}: can't opendir $dir: $!";
612 foreach $dot ( grep /^\./ && -f "$dir/$_", readdir(DIR)) {
614 $node->{LIST}{$dot} = undef;
617 return bless $node, $self;
620 It's probably worth mentioning that if you're going to filetest the
621 return values out of a readdir, you'd better prepend the directory
622 in question. Otherwise, because we didn't chdir() there, it would
623 have been testing the wrong file.
625 =item FETCH this, key
628 This method will be triggered every time an element in the tied hash is
629 accessed (read). It takes one argument beyond its self reference: the key
630 whose value we're trying to fetch.
632 Here's the fetch for our DotFiles example.
635 carp &whowasi if $DEBUG;
638 my $dir = $self->{HOME};
639 my $file = "$dir/.$dot";
641 unless (exists $self->{LIST}->{$dot} || -f $file) {
642 carp "@{[&whowasi]}: no $dot file" if $DEBUG;
646 if (defined $self->{LIST}->{$dot}) {
647 return $self->{LIST}->{$dot};
649 return $self->{LIST}->{$dot} = `cat $dir/.$dot`;
653 It was easy to write by having it call the Unix cat(1) command, but it
654 would probably be more portable to open the file manually (and somewhat
655 more efficient). Of course, because dot files are a Unixy concept, we're
658 =item STORE this, key, value
661 This method will be triggered every time an element in the tied hash is set
662 (written). It takes two arguments beyond its self reference: the index at
663 which we're trying to store something, and the value we're trying to put
666 Here in our DotFiles example, we'll be careful not to let
667 them try to overwrite the file unless they've called the clobber()
668 method on the original object reference returned by tie().
671 carp &whowasi if $DEBUG;
675 my $file = $self->{HOME} . "/.$dot";
676 my $user = $self->{USER};
678 croak "@{[&whowasi]}: $file not clobberable"
679 unless $self->{CLOBBER};
681 open(my $f, '>', $file) || croak "can't open $file: $!";
686 If they wanted to clobber something, they might say:
688 $ob = tie %daemon_dots, 'daemon';
690 $daemon_dots{signature} = "A true daemon\n";
692 Another way to lay hands on a reference to the underlying object is to
693 use the tied() function, so they might alternately have set clobber
696 tie %daemon_dots, 'daemon';
697 tied(%daemon_dots)->clobber(1);
699 The clobber method is simply:
703 $self->{CLOBBER} = @_ ? shift : 1;
706 =item DELETE this, key
709 This method is triggered when we remove an element from the hash,
710 typically by using the delete() function. Again, we'll
711 be careful to check whether they really want to clobber files.
714 carp &whowasi if $DEBUG;
718 my $file = $self->{HOME} . "/.$dot";
719 croak "@{[&whowasi]}: won't remove file $file"
720 unless $self->{CLOBBER};
721 delete $self->{LIST}->{$dot};
722 my $success = unlink($file);
723 carp "@{[&whowasi]}: can't unlink $file: $!" unless $success;
727 The value returned by DELETE becomes the return value of the call
728 to delete(). If you want to emulate the normal behavior of delete(),
729 you should return whatever FETCH would have returned for this key.
730 In this example, we have chosen instead to return a value which tells
731 the caller whether the file was successfully deleted.
736 This method is triggered when the whole hash is to be cleared, usually by
737 assigning the empty list to it.
739 In our example, that would remove all the user's dot files! It's such a
740 dangerous thing that they'll have to set CLOBBER to something higher than
744 carp &whowasi if $DEBUG;
746 croak "@{[&whowasi]}: won't remove all dot files for $self->{USER}"
747 unless $self->{CLOBBER} > 1;
749 foreach $dot ( keys %{$self->{LIST}}) {
754 =item EXISTS this, key
757 This method is triggered when the user uses the exists() function
758 on a particular hash. In our example, we'll look at the C<{LIST}>
759 hash element for this:
762 carp &whowasi if $DEBUG;
765 return exists $self->{LIST}->{$dot};
771 This method will be triggered when the user is going
772 to iterate through the hash, such as via a keys(), values(), or each() call.
775 carp &whowasi if $DEBUG;
777 my $a = keys %{$self->{LIST}}; # reset each() iterator
778 each %{$self->{LIST}}
781 FIRSTKEY is always called in scalar context and it should just
782 return the first key. values(), and each() in list context,
783 will call FETCH for the returned keys.
785 =item NEXTKEY this, lastkey
788 This method gets triggered during a keys(), values(), or each() iteration. It has a
789 second argument which is the last key that had been accessed. This is
790 useful if you're caring about ordering or calling the iterator from more
791 than one sequence, or not really storing things in a hash anywhere.
793 NEXTKEY is always called in scalar context and it should just
794 return the next key. values(), and each() in list context,
795 will call FETCH for the returned keys.
797 For our example, we're using a real hash so we'll do just the simple
798 thing, but we'll have to go through the LIST field indirectly.
801 carp &whowasi if $DEBUG;
803 return each %{ $self->{LIST} }
809 This is called when the hash is evaluated in scalar context, and in 5.28
810 onwards, by C<keys> in boolean context. In order to mimic the behaviour of
811 untied hashes, this method must return a value which when used as boolean,
812 indicates whether the tied hash is considered empty. If this method does
813 not exist, perl will make some educated guesses and return true when
814 the hash is inside an iteration. If this isn't the case, FIRSTKEY is
815 called, and the result will be a false value if FIRSTKEY returns the empty
816 list, true otherwise.
818 However, you should B<not> blindly rely on perl always doing the right
819 thing. Particularly, perl will mistakenly return true when you clear the
820 hash by repeatedly calling DELETE until it is empty. You are therefore
821 advised to supply your own SCALAR method when you want to be absolutely
822 sure that your hash behaves nicely in scalar context.
824 In our example we can just call C<scalar> on the underlying hash
825 referenced by C<$self-E<gt>{LIST}>:
828 carp &whowasi if $DEBUG;
830 return scalar %{ $self->{LIST} }
833 NOTE: In perl 5.25 the behavior of scalar %hash on an untied hash changed
834 to return the count of keys. Prior to this it returned a string containing
835 information about the bucket setup of the hash. See
836 L<Hash::Util/bucket_ratio> for a backwards compatibility path.
841 This is called when C<untie> occurs. See L</The C<untie> Gotcha> below.
846 This method is triggered when a tied hash is about to go out of
847 scope. You don't really need it unless you're trying to add debugging
848 or have auxiliary state to clean up. Here's a very simple function:
851 carp &whowasi if $DEBUG;
856 Note that functions such as keys() and values() may return huge lists
857 when used on large objects, like DBM files. You may prefer to use the
858 each() function to iterate over such. Example:
860 # print out history file offsets
862 tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
863 while (($key,$val) = each %HIST) {
864 print $key, ' = ', unpack('L',$val), "\n";
868 =head2 Tying FileHandles
871 This is partially implemented now.
873 A class implementing a tied filehandle should define the following
874 methods: TIEHANDLE, at least one of PRINT, PRINTF, WRITE, READLINE, GETC,
875 READ, and possibly CLOSE, UNTIE and DESTROY. The class can also provide: BINMODE,
876 OPEN, EOF, FILENO, SEEK, TELL - if the corresponding perl operators are
879 When STDERR is tied, its PRINT method will be called to issue warnings
880 and error messages. This feature is temporarily disabled during the call,
881 which means you can use C<warn()> inside PRINT without starting a recursive
882 loop. And just like C<__WARN__> and C<__DIE__> handlers, STDERR's PRINT
883 method may be called to report parser errors, so the caveats mentioned under
884 L<perlvar/%SIG> apply.
886 All of this is especially useful when perl is embedded in some other
887 program, where output to STDOUT and STDERR may have to be redirected
888 in some special way. See nvi and the Apache module for examples.
890 When tying a handle, the first argument to C<tie> should begin with an
891 asterisk. So, if you are tying STDOUT, use C<*STDOUT>. If you have
892 assigned it to a scalar variable, say C<$handle>, use C<*$handle>.
893 C<tie $handle> ties the scalar variable C<$handle>, not the handle inside
896 In our example we're going to create a shouting handle.
902 =item TIEHANDLE classname, LIST
905 This is the constructor for the class. That means it is expected to
906 return a blessed reference of some sort. The reference can be used to
907 hold some internal information.
909 sub TIEHANDLE { print "<shout>\n"; my $i; bless \$i, shift }
911 =item WRITE this, LIST
914 This method will be called when the handle is written to via the
915 C<syswrite> function.
919 my($buf,$len,$offset) = @_;
920 print "WRITE called, \$buf=$buf, \$len=$len, \$offset=$offset";
923 =item PRINT this, LIST
926 This method will be triggered every time the tied handle is printed to
927 with the C<print()> or C<say()> functions. Beyond its self reference
928 it also expects the list that was passed to the print function.
930 sub PRINT { $r = shift; $$r++; print join($,,map(uc($_),@_)),$\ }
932 C<say()> acts just like C<print()> except $\ will be localized to C<\n> so
933 you need do nothing special to handle C<say()> in C<PRINT()>.
935 =item PRINTF this, LIST
938 This method will be triggered every time the tied handle is printed to
939 with the C<printf()> function.
940 Beyond its self reference it also expects the format and list that was
941 passed to the printf function.
946 print sprintf($fmt, @_);
949 =item READ this, LIST
952 This method will be called when the handle is read from via the C<read>
953 or C<sysread> functions.
958 my(undef,$len,$offset) = @_;
959 print "READ called, \$buf=$bufref, \$len=$len, \$offset=$offset";
960 # add to $$bufref, set $len to number of characters read
967 This method is called when the handle is read via C<E<lt>HANDLEE<gt>>
968 or C<readline HANDLE>.
970 As per L<C<readline>|perlfunc/readline>, in scalar context it should return
971 the next line, or C<undef> for no more data. In list context it should
972 return all remaining lines, or an empty list for no more data. The strings
973 returned should include the input record separator C<$/> (see L<perlvar>),
974 unless it is C<undef> (which means "slurp" mode).
979 return ("all remaining\n",
983 return "READLINE called " . ++$$r . " times\n";
990 This method will be called when the C<getc> function is called.
992 sub GETC { print "Don't GETC, Get Perl"; return "a"; }
997 This method will be called when the C<eof> function is called.
999 Starting with Perl 5.12, an additional integer parameter will be passed. It
1000 will be zero if C<eof> is called without parameter; C<1> if C<eof> is given
1001 a filehandle as a parameter, e.g. C<eof(FH)>; and C<2> in the very special
1002 case that the tied filehandle is C<ARGV> and C<eof> is called with an empty
1003 parameter list, e.g. C<eof()>.
1005 sub EOF { not length $stringbuf }
1010 This method will be called when the handle is closed via the C<close>
1013 sub CLOSE { print "CLOSE called.\n" }
1018 As with the other types of ties, this method will be called when C<untie> happens.
1019 It may be appropriate to "auto CLOSE" when this occurs. See
1020 L</The C<untie> Gotcha> below.
1025 As with the other types of ties, this method will be called when the
1026 tied handle is about to be destroyed. This is useful for debugging and
1027 possibly cleaning up.
1029 sub DESTROY { print "</shout>\n" }
1033 Here's how to use our little example:
1036 print FOO "hello\n";
1038 print FOO $a, " plus ", $b, " equals ", $a + $b, "\n";
1044 You can define for all tie types an UNTIE method that will be called
1045 at untie(). See L</The C<untie> Gotcha> below.
1047 =head2 The C<untie> Gotcha
1050 If you intend making use of the object returned from either tie() or
1051 tied(), and if the tie's target class defines a destructor, there is a
1052 subtle gotcha you I<must> guard against.
1054 As setup, consider this (admittedly rather contrived) example of a
1055 tie; all it does is use a file to keep a log of the values assigned to
1066 my $filename = shift;
1067 my $handle = IO::File->new( "> $filename" )
1068 or die "Cannot open $filename: $!\n";
1070 print $handle "The Start\n";
1071 bless {FH => $handle, Value => 0}, $class;
1076 return $self->{Value};
1082 my $handle = $self->{FH};
1083 print $handle "$value\n";
1084 $self->{Value} = $value;
1089 my $handle = $self->{FH};
1090 print $handle "The End\n";
1096 Here is an example that makes use of this tie:
1102 tie $fred, 'Remember', 'myfile.txt';
1107 system "cat myfile.txt";
1109 This is the output when it is executed:
1117 So far so good. Those of you who have been paying attention will have
1118 spotted that the tied object hasn't been used so far. So lets add an
1119 extra method to the Remember class to allow comments to be included in
1120 the file; say, something like this:
1125 my $handle = $self->{FH};
1126 print $handle $text, "\n";
1129 And here is the previous example modified to use the C<comment> method
1130 (which requires the tied object):
1136 $x = tie $fred, 'Remember', 'myfile.txt';
1139 comment $x "changing...";
1142 system "cat myfile.txt";
1144 When this code is executed there is no output. Here's why:
1146 When a variable is tied, it is associated with the object which is the
1147 return value of the TIESCALAR, TIEARRAY, or TIEHASH function. This
1148 object normally has only one reference, namely, the implicit reference
1149 from the tied variable. When untie() is called, that reference is
1150 destroyed. Then, as in the first example above, the object's
1151 destructor (DESTROY) is called, which is normal for objects that have
1152 no more valid references; and thus the file is closed.
1154 In the second example, however, we have stored another reference to
1155 the tied object in $x. That means that when untie() gets called
1156 there will still be a valid reference to the object in existence, so
1157 the destructor is not called at that time, and thus the file is not
1158 closed. The reason there is no output is because the file buffers
1159 have not been flushed to disk.
1161 Now that you know what the problem is, what can you do to avoid it?
1162 Prior to the introduction of the optional UNTIE method the only way
1163 was the good old C<-w> flag. Which will spot any instances where you call
1164 untie() and there are still valid references to the tied object. If
1165 the second script above this near the top C<use warnings 'untie'>
1166 or was run with the C<-w> flag, Perl prints this
1169 untie attempted while 1 inner references still exist
1171 To get the script to work properly and silence the warning make sure
1172 there are no valid references to the tied object I<before> untie() is
1178 Now that UNTIE exists the class designer can decide which parts of the
1179 class functionality are really associated with C<untie> and which with
1180 the object being destroyed. What makes sense for a given class depends
1181 on whether the inner references are being kept so that non-tie-related
1182 methods can be called on the object. But in most cases it probably makes
1183 sense to move the functionality that would have been in DESTROY to the UNTIE
1186 If the UNTIE method exists then the warning above does not occur. Instead the
1187 UNTIE method is passed the count of "extra" references and can issue its own
1188 warning if appropriate. e.g. to replicate the no UNTIE case this method can
1193 my ($obj,$count) = @_;
1194 carp "untie attempted while $count inner references still exist"
1200 See L<DB_File> or L<Config> for some interesting tie() implementations.
1201 A good starting point for many tie() implementations is with one of the
1202 modules L<Tie::Scalar>, L<Tie::Array>, L<Tie::Hash>, or L<Tie::Handle>.
1206 The normal return provided by C<scalar(%hash)> is not
1207 available. What this means is that using %tied_hash in boolean
1208 context doesn't work right (currently this always tests false,
1209 regardless of whether the hash is empty or hash elements).
1210 [ This paragraph needs review in light of changes in 5.25 ]
1212 Localizing tied arrays or hashes does not work. After exiting the
1213 scope the arrays or the hashes are not restored.
1215 Counting the number of entries in a hash via C<scalar(keys(%hash))>
1216 or C<scalar(values(%hash)>) is inefficient since it needs to iterate
1217 through all the entries with FIRSTKEY/NEXTKEY.
1219 Tied hash/array slices cause multiple FETCH/STORE pairs, there are no
1220 tie methods for slice operations.
1222 You cannot easily tie a multilevel data structure (such as a hash of
1223 hashes) to a dbm file. The first problem is that all but GDBM and
1224 Berkeley DB have size limitations, but beyond that, you also have problems
1225 with how references are to be represented on disk. One
1226 module that does attempt to address this need is DBM::Deep. Check your
1227 nearest CPAN site as described in L<perlmodlib> for source code. Note
1228 that despite its name, DBM::Deep does not use dbm. Another earlier attempt
1229 at solving the problem is MLDBM, which is also available on the CPAN, but
1230 which has some fairly serious limitations.
1232 Tied filehandles are still incomplete. sysopen(), truncate(),
1233 flock(), fcntl(), stat() and -X can't currently be trapped.
1239 TIEHANDLE by Sven Verdoolaege <F<skimo@dns.ufsia.ac.be>> and Doug MacEachern <F<dougm@osf.org>>
1241 UNTIE by Nick Ing-Simmons <F<nick@ing-simmons.net>>
1243 SCALAR by Tassilo von Parseval <F<tassilo.von.parseval@rwth-aachen.de>>
1245 Tying Arrays by Casey West <F<casey@geeknest.com>>